qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("developer");
 276                 BADCVAR("g_banned_list");
 277                 BADCVAR("log_dest_udp");
 278                 BADCVAR("log_file");
 279                 BADCVAR("net_address");
 280                 BADCVAR("net_address_ipv6");
 281                 BADCVAR("port");
 282                 BADCVAR("savedgamecfg");
 283                 BADCVAR("serverconfig");
 284                 BADCVAR("sv_heartbeatperiod");
 285                 BADCVAR("sv_vote_master_password");
 286                 BADCVAR("sys_colortranslation");
 287                 BADCVAR("sys_specialcharactertranslation");
 288                 BADCVAR("timestamps");
 289                 BADPREFIX("developer_");
 290                 BADPREFIX("g_ban_");
 291                 BADPREFIX("g_chat_flood_");
 292                 BADPREFIX("g_voice_flood_");
 293                 BADPREFIX("rcon_");
 294                 BADPREFIX("settemp_");
 295                 BADPREFIX("sv_allowdownloads_");
 296                 BADPREFIX("sv_autodemo");
 297                 BADPREFIX("sv_curl_");
 298                 BADPREFIX("sv_eventlog");
 299                 BADPREFIX("sv_logscores_");
 300                 BADPREFIX("sv_master");
 301                 BADPREFIX("sv_weaponstats_");
 302
 303                 // these can contain player IDs, so better hide
 304                 BADCVAR("g_forced_team_red");
 305                 BADCVAR("g_forced_team_blue");
 306                 BADCVAR("g_forced_team_yellow");
 307                 BADCVAR("g_forced_team_pink");
 308
 309                 // mapinfo
 310                 BADCVAR("timelimit");
 311                 BADCVAR("fraglimit");
 312                 BADCVAR("leadlimit");
 313                 BADCVAR("g_tdm_teams");
 314                 BADCVAR("g_keyhunt_teams");
 315                 BADCVAR("g_domination_default_teams");
 316                 BADCVAR("g_race_qualifying_timelimit");
 317                 BADCVAR("g_lms");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_ca");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_dm");
 323                 BADCVAR("g_domination");
 324                 BADCVAR("g_keyhunt");
 325                 BADCVAR("g_keyhunt_teams");
 326                 BADCVAR("g_onslaught");
 327                 BADCVAR("g_race");
 328                 BADCVAR("g_cts");
 329                 BADCVAR("g_runematch");
 330                 BADCVAR("g_tdm");
 331                 BADCVAR("g_nexball");
 332                 BADCVAR("teamplay");
 333
 334                 // long
 335                 BADCVAR("hostname");
 336                 BADCVAR("g_maplist");
 337                 BADCVAR("g_maplist_mostrecent");
 338                 BADCVAR("sv_motd");
 339
 340                 v = cvar_string(k);
 341                 d = cvar_defstring(k);
 342                 if(v == d)
 343                         continue;
 344
 345                 if(adding)
 346                 {
 347                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 348                         if(strlen(cvar_changes) > 16384)
 349                         {
 350                                 cvar_changes = "// too many settings have been changed to show them here\n";
 351                                 adding = 0;
 352                         }
 353                 }
 354
 355                 // now check if the changes are actually gameplay relevant
 356
 357                 // does nothing visible
 358                 BADCVAR("captureleadlimit_override");
 359                 BADCVAR("g_arena_point_leadlimit");
 360                 BADCVAR("g_ca_point_leadlimit");
 361                 BADCVAR("g_ctf_capture_leadlimit");
 362                 BADCVAR("g_domination_point_leadlimit");
 363                 BADCVAR("g_keyhunt_point_leadlimit");
 364                 BADCVAR("g_nexball_goalleadlimit");
 365                 BADCVAR("g_runematch_point_leadlimit");
 366                 BADCVAR("leadlimit_and_fraglimit");
 367                 BADCVAR("leadlimit_override");
 368                 BADCVAR("sv_checkforpacketsduringsleep");
 369                 BADPREFIX("crypto_");
 370                 BADPREFIX("g_chat_");
 371                 BADPREFIX("net_");
 372                 BADPREFIX("prvm_");
 373                 BADPREFIX("sv_fragmessage_");
 374                 BADPREFIX("sv_vote_");
 375                 BADPREFIX("timelimit_");
 376
 377                 // allowed changes to server admins (please sync this to server.cfg)
 378                 // vi commands:
 379                 //   :/"impure"/,$d
 380                 //   :g!,^\/\/[^ /],d
 381                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 382                 //   :%!sort
 383                 // yes, this does contain some redundant stuff, don't really care
 384                 BADCVAR("bot_number");
 385                 BADCVAR("bot_prefix");
 386                 BADCVAR("bot_suffix");
 387                 BADCVAR("capturelimit_override");
 388                 BADCVAR("fraglimit_override");
 389                 BADCVAR("gametype");
 390                 BADCVAR("g_antilag");
 391                 BADCVAR("g_balance_teams");
 392                 BADCVAR("g_balance_teams_force");
 393                 BADCVAR("g_ban_sync_trusted_servers");
 394                 BADCVAR("g_ban_sync_uri");
 395                 BADCVAR("g_ctf_capture_limit");
 396                 BADCVAR("g_ctf_ignore_frags");
 397                 BADCVAR("g_ctf_win_mode");
 398                 BADCVAR("g_domination_point_limit");
 399                 BADCVAR("g_fullbrightitems");
 400                 BADCVAR("g_fullbrightplayers");
 401                 BADCVAR("g_keyhunt_point_limit");
 402                 BADCVAR("g_keyhunt_teams_override");
 403                 BADCVAR("g_lms_lives_override");
 404                 BADCVAR("g_maplist");
 405                 BADCVAR("g_maplist_check_waypoints");
 406                 BADCVAR("g_maplist_mostrecent_count");
 407                 BADCVAR("g_maplist_shuffle");
 408                 BADCVAR("g_maplist_votable");
 409                 BADCVAR("g_maplist_votable_abstain");
 410                 BADCVAR("g_maplist_votable_nodetail");
 411                 BADCVAR("g_maplist_votable_suggestions");
 412                 BADCVAR("g_minstagib");
 413                 BADCVAR("g_nexball_goallimit");
 414                 BADCVAR("g_runematch_point_limit");
 415                 BADCVAR("g_start_delay");
 416                 BADCVAR("hostname");
 417                 BADCVAR("log_file");
 418                 BADCVAR("maxplayers");
 419                 BADCVAR("minplayers");
 420                 BADCVAR("net_address");
 421                 BADCVAR("port");
 422                 BADCVAR("rcon_password");
 423                 BADCVAR("rcon_restricted_commands");
 424                 BADCVAR("rcon_restricted_password");
 425                 BADCVAR("skill");
 426                 BADCVAR("sv_adminnick");
 427                 BADCVAR("sv_autoscreenshot");
 428                 BADCVAR("sv_curl_defaulturl");
 429                 BADCVAR("sv_defaultcharacter");
 430                 BADCVAR("sv_defaultplayercolors");
 431                 BADCVAR("sv_defaultplayermodel");
 432                 BADCVAR("sv_defaultplayerskin");
 433                 BADCVAR("sv_maxidle");
 434                 BADCVAR("sv_maxrate");
 435                 BADCVAR("sv_motd");
 436                 BADCVAR("sv_public");
 437                 BADCVAR("sv_ready_restart");
 438                 BADCVAR("sv_status_privacy");
 439                 BADCVAR("sv_vote_call");
 440                 BADCVAR("sv_vote_commands");
 441                 BADCVAR("sv_vote_majority_factor");
 442                 BADCVAR("sv_vote_master");
 443                 BADCVAR("sv_vote_master_commands");
 444                 BADCVAR("sv_vote_master_password");
 445                 BADCVAR("sv_vote_simple_majority_factor");
 446                 BADCVAR("timelimit_override");
 447
 448                 if(cvar("g_minstagib"))
 449                 {
 450                         BADCVAR("g_grappling_hook");
 451                         BADCVAR("g_jetpack");
 452                 }
 453 #undef BADPREFIX
 454 #undef BADCVAR
 455
 456                 if(pureadding)
 457                 {
 458                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 459                         if(strlen(cvar_purechanges) > 16384)
 460                         {
 461                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 462                                 pureadding = 0;
 463                         }
 464                 }
 465                 ++cvar_purechanges_count;
 466                 // WARNING: this variable is used for the server list
 467                 // NEVER dare to skip this code!
 468                 // Hacks to intentionally appearing as "pure server" even though you DO have
 469                 // modified settings may be punished by removal from the server list.
 470                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 471                 // though.
 472         }
 473         buf_del(h);
 474         if(cvar_changes == "")
 475                 cvar_changes = "// this server runs at default server settings\n";
 476         else
 477                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 478         cvar_changes = strzone(cvar_changes);
 479         if(cvar_purechanges == "")
 480                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 481         else
 482                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 483         cvar_purechanges = strzone(cvar_purechanges);
 484 }
 485
 486 void detect_maptype()
 487 {
 488 #if 0
 489         vector o, v;
 490         float i;
 491
 492         for(;;)
 493         {
 494                 o = world.mins;
 495                 o_x += random() * (world.maxs_x - world.mins_x);
 496                 o_y += random() * (world.maxs_y - world.mins_y);
 497                 o_z += random() * (world.maxs_z - world.mins_z);
 498
 499                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 500                 if(trace_fraction == 1)
 501                         continue;
 502
 503                 v = trace_endpos;
 504
 505                 for(i = 0; i < 64; i += 4)
 506                 {
 507                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 508         if(trace_fraction == 1)
 509                 continue;
 510                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 511                 }
 512
 513                 break;
 514         }
 515 #endif
 516 }
 517
 518 entity randomseed;
 519 float RandomSeed_Send(entity to, float sf)
 520 {
 521         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 522         WriteShort(MSG_ENTITY, self.cnt);
 523         return TRUE;
 524 }
 525 void RandomSeed_Think()
 526 {
 527         self.cnt = bound(0, floor(random() * 65536), 65535);
 528         self.nextthink = time + 5;
 529
 530         self.SendFlags |= 1;
 531 }
 532 void RandomSeed_Spawn()
 533 {
 534         randomseed = spawn();
 535         randomseed.think = RandomSeed_Think;
 536         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 537
 538         entity oldself;
 539         oldself = self;
 540         self = randomseed;
 541         self.think(); // sets random seed and nextthink
 542         self = oldself;
 543 }
 544
 545 void spawnfunc___init_dedicated_server(void)
 546 {
 547         // handler for _init/_init map (only for dedicated server initialization)
 548
 549         world_initialized = -1; // don't complain
 550         cvar = cvar_normal;
 551         cvar_string = cvar_string_normal;
 552         cvar_set = cvar_set_normal;
 553
 554         remove = remove_unsafely;
 555
 556         entity e;
 557         e = spawn();
 558         e.think = GotoFirstMap;
 559         e.nextthink = time; // this is usually 1 at this point
 560
 561         e = spawn();
 562         e.classname = "info_player_deathmatch"; // safeguard against player joining
 563
 564         self.classname = "worldspawn"; // safeguard against various stuff ;)
 565
 566         MapInfo_Enumerate();
 567         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 568 }
 569
 570 void Map_MarkAsRecent(string m);
 571 float world_already_spawned;
 572 void RegisterWeapons();
 573 void Nagger_Init();
 574 void ClientInit_Spawn();
 575 void WeaponStats_Init();
 576 void WeaponStats_Shutdown();
 577 void spawnfunc_worldspawn (void)
 578 {
 579         float fd, l, i, j, n;
 580         string s, col;
 581
 582         cvar = cvar_normal;
 583         cvar_string = cvar_string_normal;
 584         cvar_set = cvar_set_normal;
 585
 586         if(world_already_spawned)
 587                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 588         world_already_spawned = TRUE;
 589
 590         remove = remove_safely; // during spawning, watch what you remove!
 591
 592         check_unacceptable_compiler_bugs();
 593
 594         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 595
 596         compressShortVector_init();
 597
 598         allowed_to_spawn = TRUE;
 599
 600         local entity head;
 601         head = nextent(world);
 602         maxclients = 0;
 603         while(head)
 604         {
 605                 ++maxclients;
 606                 head = nextent(head);
 607         }
 608
 609         // needs to be done so early as they would still spawn
 610         RegisterWeapons();
 611
 612         ServerProgsDB = db_load("server.db");
 613
 614         TemporaryDB = db_create();
 615
 616         /*
 617         TODO sound pack system
 618         // initialize sound pack system
 619         soundpack = cvar_string("g_soundpack");
 620         if(soundpack != "")
 621                 soundpack = strcat(soundpack, "/");
 622         soundpack = strzone(soundpack);
 623         */
 624
 625         // 0 normal
 626         lightstyle(0, "m");
 627
 628         // 1 FLICKER (first variety)
 629         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 630
 631         // 2 SLOW STRONG PULSE
 632         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 633
 634         // 3 CANDLE (first variety)
 635         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 636
 637         // 4 FAST STROBE
 638         lightstyle(4, "mamamamamama");
 639
 640         // 5 GENTLE PULSE 1
 641         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 642
 643         // 6 FLICKER (second variety)
 644         lightstyle(6, "nmonqnmomnmomomno");
 645
 646         // 7 CANDLE (second variety)
 647         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 648
 649         // 8 CANDLE (third variety)
 650         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 651
 652         // 9 SLOW STROBE (fourth variety)
 653         lightstyle(9, "aaaaaaaazzzzzzzz");
 654
 655         // 10 FLUORESCENT FLICKER
 656         lightstyle(10, "mmamammmmammamamaaamammma");
 657
 658         // 11 SLOW PULSE NOT FADE TO BLACK
 659         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 660
 661         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 662
 663         // 63 testing
 664         lightstyle(63, "a");
 665
 666         if(cvar("g_campaign"))
 667                 CampaignPreInit();
 668
 669         Map_MarkAsRecent(mapname);
 670
 671         precache_model ("null"); // we need this one before InitGameplayMode
 672         InitGameplayMode();
 673         readlevelcvars();
 674         GrappleHookInit();
 675         ElectroInit();
 676         LaserInit();
 677
 678         player_count = 0;
 679         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 680         if(bot_waypoints_for_items == 1)
 681                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 682                         bot_waypoints_for_items = 0;
 683
 684         // for setting by mapinfo
 685         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 686         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 687
 688         precache();
 689
 690         WaypointSprite_Init();
 691
 692         //if (g_domination)
 693         //      dom_init();
 694
 695         GameLogInit(); // prepare everything
 696         if(cvar("sv_eventlog"))
 697         {
 698                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 699                 s = strcat(s, ftos(random()));
 700                 matchid = strzone(s);
 701
 702                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 703                 s = ":gameinfo:mutators:LIST";
 704
 705                 ret_string = s;
 706                 MUTATOR_CALLHOOK(BuildMutatorsString);
 707                 s = ret_string;
 708
 709                 // simple, probably not good in the mutator system
 710                 if(cvar("g_grappling_hook"))
 711                         s = strcat(s, ":grappling_hook");
 712
 713                 // initialiation stuff, not good in the mutator system
 714                 if(!cvar("g_use_ammunition"))
 715                         s = strcat(s, ":no_use_ammunition");
 716
 717                 // initialiation stuff, not good in the mutator system
 718                 if(!cvar("g_pickup_items"))
 719                         s = strcat(s, ":no_pickup_items");
 720
 721                 // initialiation stuff, not good in the mutator system
 722                 if(cvar_string("g_weaponarena") != "0")
 723                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 724
 725                 // TODO to mutator system
 726                 if(cvar("g_norecoil"))
 727                         s = strcat(s, ":norecoil");
 728
 729                 // TODO to mutator system
 730                 if(cvar("g_midair"))
 731                         s = strcat(s, ":midair");
 732
 733                 // TODO to mutator system
 734                 if(cvar("g_minstagib"))
 735                         s = strcat(s, ":minstagib");
 736
 737                 GameLogEcho(s);
 738                 GameLogEcho(":gameinfo:end");
 739         }
 740         else
 741                 matchid = strzone(ftos(random()));
 742
 743         cvar_set("nextmap", "");
 744
 745         SetDefaultAlpha();
 746
 747         if(cvar("g_campaign"))
 748                 CampaignPostInit();
 749
 750         fteqcc_testbugs();
 751
 752         Ban_LoadBans();
 753
 754         MapInfo_Enumerate();
 755         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 756
 757         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 758         {
 759                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 760                 if(fd != -1)
 761                 {
 762                         while((s = fgets(fd)))
 763                         {
 764                                 l = tokenize_console(s);
 765                                 if(l < 2)
 766                                         continue;
 767                                 if(argv(0) == "cd")
 768                                 {
 769                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 770                                         print("  cdtrack ", argv(2), "\n");
 771                                 }
 772                                 else if(argv(0) == "fog")
 773                                 {
 774                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 775                                         print("  \"fog\" \"", s, "\"\n");
 776                                 }
 777                                 else if(argv(0) == "set")
 778                                 {
 779                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 780                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 781                                 }
 782                                 else if(argv(0) != "//")
 783                                 {
 784                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 785                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 786                                 }
 787                         }
 788                         fclose(fd);
 789                 }
 790         }
 791
 792         WeaponStats_Init();
 793
 794         addstat(STAT_WEAPONS, AS_INT, weapons);
 795         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 796         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 797         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 798         Nagger_Init();
 799
 800         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 801         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 802         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 803         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 804         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 805         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 806         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 807         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 808
 809         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 810         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_charge_pool_ammo);
 811
 812         if(g_ca)
 813         {
 814                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 815                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 816         }
 817         // g_movementspeed hack
 818         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 819         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 820         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 821         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 822
 823         next_pingtime = time + 5;
 824
 825         detect_maptype();
 826
 827         lsmaps_reply = "^7Maps available: ";
 828         lsnewmaps_reply = "^7Maps without a record set: ";
 829         for(i = 0, j = 0; i < MapInfo_count; ++i)
 830         {
 831                 if(MapInfo_Get_ByID(i))
 832                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 833                         {
 834                                 if(mod(i, 2))
 835                                         col = "^2";
 836                                 else
 837                                         col = "^3";
 838                                 ++j;
 839                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 840                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 841                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 842                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 843                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 844                         }
 845         }
 846         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 847         if (!g_race && !g_cts)
 848                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 849         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 850
 851         maplist_reply = "^7Maps in list: ";
 852         n = tokenize_console(cvar_string("g_maplist"));
 853         for(i = 0, j = 0; i < n; ++i)
 854         {
 855                 if(MapInfo_CheckMap(argv(i)))
 856                 {
 857                         if(mod(j, 2))
 858                                 col = "^2";
 859                         else
 860                                 col = "^3";
 861                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 862                         ++j;
 863                 }
 864         }
 865         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 866         MapInfo_ClearTemps();
 867
 868         for(i = 0; i < 10; ++i)
 869         {
 870                 records_reply[i] = strzone(getrecords(i));
 871         }
 872         if(g_cts)
 873                 ladder_reply = strzone(getladder());
 874
 875         rankings_reply = strzone(getrankings());
 876
 877         ClientInit_Spawn();
 878         RandomSeed_Spawn();
 879         PingPLReport_Spawn();
 880
 881         CheatInit();
 882
 883         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 884
 885         // fill sv_curl_serverpackages from .serverpackage files
 886         if(cvar("sv_curl_serverpackages_auto"))
 887         {
 888                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 889                 s = "";
 890                 if(fd >= 0)
 891                 {
 892                         j = search_getsize(fd);
 893                         for(i = 0; i < j; ++i)
 894                                 s = strcat(s, " ", search_getfilename(fd, i));
 895                         search_end(fd);
 896                 }
 897                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 898         }
 899
 900         PlayerStats_Init();
 901
 902         world_initialized = 1;
 903 }
 904
 905 void spawnfunc_light (void)
 906 {
 907         //makestatic (self); // Who the f___ did that?
 908         remove(self);
 909 }
 910
 911 float TryFile( string pFilename )
 912 {
 913         local float lHandle;
 914         dprint("TryFile(\"", pFilename, "\")\n");
 915         lHandle = fopen( pFilename, FILE_READ );
 916         if( lHandle != -1 ) {
 917                 fclose( lHandle );
 918                 return TRUE;
 919         } else {
 920                 return FALSE;
 921         }
 922 };
 923
 924 string GetGametype()
 925 {
 926         return GametypeNameFromType(game);
 927 }
 928
 929 string getmapname_stored;
 930 string GetMapname()
 931 {
 932         return mapname;
 933 }
 934
 935 float Map_Count, Map_Current;
 936 string Map_Current_Name;
 937
 938 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 939 float GetMaplistPosition()
 940 {
 941         float pos, idx;
 942         string map;
 943
 944         map = GetMapname();
 945         idx = cvar("g_maplist_index");
 946
 947         if(idx >= 0)
 948                 if(idx < Map_Count)
 949                         if(map == argv(idx))
 950                                 return idx;
 951
 952         for(pos = 0; pos < Map_Count; ++pos)
 953                 if(map == argv(pos))
 954                         return pos;
 955
 956         // resume normal maplist rotation if current map is not in g_maplist
 957         return idx;
 958 }
 959
 960 float MapHasRightSize(string map)
 961 {
 962         float fh;
 963         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 964         if(cvar("g_maplist_check_waypoints"))
 965         {
 966                 dprint("checkwp "); dprint(map);
 967                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 968                 if(fh < 0)
 969                 {
 970                         dprint(": no waypoints\n");
 971                         return FALSE;
 972                 }
 973                 dprint(": has waypoints\n");
 974                 fclose(fh);
 975         }
 976
 977         // open map size restriction file
 978         dprint("opensize "); dprint(map);
 979         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 980         if(fh >= 0)
 981         {
 982                 float mapmin, mapmax;
 983                 dprint(": ok, ");
 984                 mapmin = stof(fgets(fh));
 985                 mapmax = stof(fgets(fh));
 986                 fclose(fh);
 987                 if(player_count < mapmin)
 988                 {
 989                         dprint("not enough\n");
 990                         return FALSE;
 991                 }
 992                 if(player_count > mapmax)
 993                 {
 994                         dprint("too many\n");
 995                         return FALSE;
 996                 }
 997                 dprint("right size\n");
 998                 return TRUE;
 999         }
1000         dprint(": not found\n");
1001         return TRUE;
1002 }
1003
1004 string Map_Filename(float position)
1005 {
1006         return strcat("maps/", argv(position), ".bsp");
1007 }
1008
1009 string strwords(string s, float w)
1010 {
1011         float endpos;
1012         for(endpos = 0; w && endpos >= 0; --w)
1013                 endpos = strstrofs(s, " ", endpos + 1);
1014         if(endpos < 0)
1015                 return s;
1016         else
1017                 return substring(s, 0, endpos);
1018 }
1019
1020 float strhasword(string s, string w)
1021 {
1022         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1023 }
1024
1025 void Map_MarkAsRecent(string m)
1026 {
1027         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
1028 }
1029
1030 float Map_IsRecent(string m)
1031 {
1032         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1033 }
1034
1035 float Map_Check(float position, float pass)
1036 {
1037         string filename;
1038         string map_next;
1039         map_next = argv(position);
1040         if(pass <= 1)
1041         {
1042                 if(Map_IsRecent(map_next))
1043                         return 0;
1044         }
1045         filename = Map_Filename(position);
1046         if(MapInfo_CheckMap(map_next))
1047         {
1048                 if(pass == 2)
1049                         return 1;
1050                 if(MapHasRightSize(map_next))
1051                         return 1;
1052                 return 0;
1053         }
1054         else
1055                 dprint( "Couldn't select '", filename, "'..\n" );
1056
1057         return 0;
1058 }
1059
1060 void Map_Goto_SetStr(string nextmapname)
1061 {
1062         if(getmapname_stored != "")
1063                 strunzone(getmapname_stored);
1064         if(nextmapname == "")
1065                 getmapname_stored = "";
1066         else
1067                 getmapname_stored = strzone(nextmapname);
1068 }
1069
1070 void Map_Goto_SetFloat(float position)
1071 {
1072         cvar_set("g_maplist_index", ftos(position));
1073         Map_Goto_SetStr(argv(position));
1074 }
1075
1076 void GameResetCfg()
1077 {
1078         // settings persist, except...
1079         localcmd("\nsettemp_restore\n");
1080 };
1081
1082 void Map_Goto()
1083 {
1084         GameResetCfg();
1085         MapInfo_LoadMap(getmapname_stored);
1086 }
1087
1088 // return codes of map selectors:
1089 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1090 //   -2 = permanent failure
1091 float() MaplistMethod_Iterate = // usual method
1092 {
1093         float pass, i;
1094
1095         for(pass = 1; pass <= 2; ++pass)
1096         {
1097                 for(i = 1; i < Map_Count; ++i)
1098                 {
1099                         float mapindex;
1100                         mapindex = mod(i + Map_Current, Map_Count);
1101                         if(Map_Check(mapindex, pass))
1102                                 return mapindex;
1103                 }
1104         }
1105         return -1;
1106 }
1107
1108 float() MaplistMethod_Repeat = // fallback method
1109 {
1110         if(Map_Check(Map_Current, 2))
1111                 return Map_Current;
1112         return -2;
1113 }
1114
1115 float() MaplistMethod_Random = // random map selection
1116 {
1117         float i, imax;
1118
1119         imax = 42;
1120
1121         for(i = 0; i <= imax; ++i)
1122         {
1123                 float mapindex;
1124                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1125                 if(Map_Check(mapindex, 1))
1126                         return mapindex;
1127         }
1128         return -1;
1129 }
1130
1131 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1132 // the exponent sets a bias on the map selection:
1133 // the higher the exponent, the less likely "shortly repeated" same maps are
1134 {
1135         float i, j, imax, insertpos;
1136
1137         imax = 42;
1138
1139         for(i = 0; i <= imax; ++i)
1140         {
1141                 string newlist;
1142
1143                 // now reinsert this at another position
1144                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1145                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1146                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1147                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1148
1149                 // insert the current map there
1150                 newlist = "";
1151                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1152                         newlist = strcat(newlist, " ", argv(j));
1153                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1154                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1155                         newlist = strcat(newlist, " ", argv(j));
1156                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1157                 cvar_set("g_maplist", newlist);
1158                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1159
1160                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1161                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1162                 if(Map_Check(Map_Current, 1))
1163                         return Map_Current;
1164         }
1165         return -1;
1166 }
1167
1168 void Maplist_Init()
1169 {
1170         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1171         if(Map_Count == 0)
1172         {
1173                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1174                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1175                 if(cvar("g_maplist_shuffle"))
1176                         ShuffleMaplist();
1177                 localcmd("\nmenu_cmd sync\n");
1178                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1179         }
1180         if(Map_Count == 0)
1181                 error("empty maplist, cannot select a new map");
1182         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1183
1184         if(Map_Current_Name)
1185                 strunzone(Map_Current_Name);
1186         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1187         // this may or may not be correct, but who cares, in the worst case a map
1188         // isn't chosen in the first pass that should have been
1189 }
1190
1191 string GetNextMap()
1192 {
1193         float nextMap;
1194
1195         Maplist_Init();
1196         nextMap = -1;
1197
1198         if(nextMap == -1)
1199                 if(cvar("g_maplist_shuffle") > 0)
1200                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1201
1202         if(nextMap == -1)
1203                 if(cvar("g_maplist_selectrandom"))
1204                         nextMap = MaplistMethod_Random();
1205
1206         if(nextMap == -1)
1207                 nextMap = MaplistMethod_Iterate();
1208
1209         if(nextMap == -1)
1210                 nextMap = MaplistMethod_Repeat();
1211
1212         if(nextMap >= 0)
1213         {
1214                 Map_Goto_SetFloat(nextMap);
1215                 return getmapname_stored;
1216         }
1217
1218         return "";
1219 };
1220
1221 float DoNextMapOverride()
1222 {
1223         if(cvar("g_campaign"))
1224         {
1225                 CampaignPostIntermission();
1226                 alreadychangedlevel = TRUE;
1227                 return TRUE;
1228         }
1229         if(cvar("quit_when_empty"))
1230         {
1231                 if(player_count <= currentbots)
1232                 {
1233                         localcmd("quit\n");
1234                         alreadychangedlevel = TRUE;
1235                         return TRUE;
1236                 }
1237         }
1238         if(cvar_string("quit_and_redirect") != "")
1239         {
1240                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1241                 alreadychangedlevel = TRUE;
1242                 return TRUE;
1243         }
1244         if (cvar("samelevel")) // if samelevel is set, stay on same level
1245         {
1246                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1247                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1248                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1249                 localcmd("restart\n");
1250                 //changelevel (mapname);
1251                 alreadychangedlevel = TRUE;
1252                 return TRUE;
1253         }
1254         if(cvar_string("nextmap") != "")
1255                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1256                 {
1257                         Map_Goto_SetStr(cvar_string("nextmap"));
1258                         Map_Goto();
1259                         alreadychangedlevel = TRUE;
1260                         return TRUE;
1261                 }
1262         if(cvar("lastlevel"))
1263         {
1264                 GameResetCfg();
1265                 localcmd("set lastlevel 0\ntogglemenu\n");
1266                 alreadychangedlevel = TRUE;
1267                 return TRUE;
1268         }
1269         return FALSE;
1270 };
1271
1272 void GotoNextMap()
1273 {
1274         //local string nextmap;
1275         //local float n, nummaps;
1276         //local string s;
1277         if (alreadychangedlevel)
1278                 return;
1279         alreadychangedlevel = TRUE;
1280
1281         {
1282                 string nextMap;
1283                 float allowReset;
1284
1285                 for(allowReset = 1; allowReset >= 0; --allowReset)
1286                 {
1287                         nextMap = GetNextMap();
1288                         if(nextMap != "")
1289                                 break;
1290
1291                         if(allowReset)
1292                         {
1293                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1294                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1295                                 if(cvar("g_maplist_shuffle"))
1296                                         ShuffleMaplist();
1297                                 localcmd("\nmenu_cmd sync\n");
1298                         }
1299                         else
1300                         {
1301                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1302                         }
1303                 }
1304                 Map_Goto();
1305         }
1306 };
1307
1308
1309 /*
1310 ============
1311 IntermissionThink
1312
1313 When the player presses attack or jump, change to the next level
1314 ============
1315 */
1316 .float autoscreenshot;
1317 void() MapVote_Start;
1318 void() MapVote_Think;
1319 float mapvote_initialized;
1320 void IntermissionThink()
1321 {
1322         FixIntermissionClient(self);
1323
1324         if(cvar("sv_autoscreenshot"))
1325         if(self.autoscreenshot > 0)
1326         if(time > self.autoscreenshot)
1327         {
1328                 self.autoscreenshot = -1;
1329                 if(clienttype(self) == CLIENTTYPE_REAL)
1330                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1331                 return;
1332         }
1333
1334         if (time < intermission_exittime)
1335                 return;
1336
1337         if(!mapvote_initialized)
1338                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1339                         return;
1340
1341         MapVote_Start();
1342 };
1343
1344 /*
1345 ============
1346 FindIntermission
1347
1348 Returns the entity to view from
1349 ============
1350 */
1351 /*
1352 entity FindIntermission()
1353 {
1354         local   entity spot;
1355         local   float cyc;
1356
1357 // look for info_intermission first
1358         spot = find (world, classname, "info_intermission");
1359         if (spot)
1360         {       // pick a random one
1361                 cyc = random() * 4;
1362                 while (cyc > 1)
1363                 {
1364                         spot = find (spot, classname, "info_intermission");
1365                         if (!spot)
1366                                 spot = find (spot, classname, "info_intermission");
1367                         cyc = cyc - 1;
1368                 }
1369                 return spot;
1370         }
1371
1372 // then look for the start position
1373         spot = find (world, classname, "info_player_start");
1374         if (spot)
1375                 return spot;
1376
1377 // testinfo_player_start is only found in regioned levels
1378         spot = find (world, classname, "testplayerstart");
1379         if (spot)
1380                 return spot;
1381
1382 // then look for the start position
1383         spot = find (world, classname, "info_player_deathmatch");
1384         if (spot)
1385                 return spot;
1386
1387         //objerror ("FindIntermission: no spot");
1388         return world;
1389 };
1390 */
1391
1392 /*
1393 ===============================================================================
1394
1395 RULES
1396
1397 ===============================================================================
1398 */
1399
1400 void DumpStats(float final)
1401 {
1402         float file;
1403         string s;
1404         float to_console;
1405         float to_eventlog;
1406         float to_file;
1407         float i;
1408         entity e;
1409
1410         to_console = cvar("sv_logscores_console");
1411         to_eventlog = cvar("sv_eventlog");
1412         to_file = cvar("sv_logscores_file");
1413
1414         if(!final)
1415         {
1416                 to_console = TRUE; // always print printstats replies
1417                 to_eventlog = FALSE; // but never print them to the event log
1418         }
1419
1420         if(to_eventlog)
1421                 if(cvar("sv_eventlog_console"))
1422                         to_console = FALSE; // otherwise we get the output twice
1423
1424         if(final)
1425                 s = ":scores:";
1426         else
1427                 s = ":status:";
1428         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1429
1430         if(to_console)
1431                 print(s, "\n");
1432         if(to_eventlog)
1433                 GameLogEcho(s);
1434         if(to_file)
1435         {
1436                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1437                 if(file == -1)
1438                         to_file = FALSE;
1439                 else
1440                         fputs(file, strcat(s, "\n"));
1441         }
1442
1443         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1444         if(to_console)
1445                 print(s, "\n");
1446         if(to_eventlog)
1447                 GameLogEcho(s);
1448         if(to_file)
1449                 fputs(file, strcat(s, "\n"));
1450
1451         FOR_EACH_CLIENT(other)
1452         {
1453                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1454                 {
1455                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1456                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1457                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1458                                 s = strcat(s, ftos(other.team), ":");
1459                         else
1460                                 s = strcat(s, "spectator:");
1461
1462                         if(to_console)
1463                                 print(s, other.netname, "\n");
1464                         if(to_eventlog)
1465                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1466                         if(to_file)
1467                                 fputs(file, strcat(s, other.netname, "\n"));
1468                 }
1469         }
1470
1471         if(teams_matter)
1472         {
1473                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1474                 if(to_console)
1475                         print(s, "\n");
1476                 if(to_eventlog)
1477                         GameLogEcho(s);
1478                 if(to_file)
1479                         fputs(file, strcat(s, "\n"));
1480
1481                 for(i = 1; i < 16; ++i)
1482                 {
1483                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1484                         s = strcat(s, ":", ftos(i));
1485                         if(to_console)
1486                                 print(s, "\n");
1487                         if(to_eventlog)
1488                                 GameLogEcho(s);
1489                         if(to_file)
1490                                 fputs(file, strcat(s, "\n"));
1491                 }
1492         }
1493
1494         if(to_console)
1495                 print(":end\n");
1496         if(to_eventlog)
1497                 GameLogEcho(":end");
1498         if(to_file)
1499         {
1500                 fputs(file, ":end\n");
1501                 fclose(file);
1502         }
1503
1504         // send statistics
1505         FOR_EACH_CLIENT(e)
1506                 PlayerStats_AddGlobalInfo(e);
1507         PlayerStats_Shutdown();
1508 }
1509
1510 void FixIntermissionClient(entity e)
1511 {
1512         string s;
1513         if(!e.autoscreenshot) // initial call
1514         {
1515                 e.angles = e.v_angle;
1516                 e.angles_x = -e.angles_x;
1517                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1518                 e.health = -2342;
1519                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1520                 e.solid = SOLID_NOT;
1521                 e.movetype = MOVETYPE_NONE;
1522                 e.takedamage = DAMAGE_NO;
1523                 if(e.weaponentity)
1524                 {
1525                         e.weaponentity.effects = EF_NODRAW;
1526                         if (e.weaponentity.weaponentity)
1527                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1528                 }
1529                 if(clienttype(e) == CLIENTTYPE_REAL)
1530                 {
1531                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1532                         s = cvar_string("sv_intermission_cdtrack");
1533                         if(s != "")
1534                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1535                         msg_entity = e;
1536                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1537                 }
1538         }
1539
1540         //e.velocity = '0 0 0';
1541         //e.fixangle = TRUE;
1542
1543         // TODO halt weapon animation
1544 }
1545
1546
1547 /*
1548 go to the next level for deathmatch
1549 only called if a time or frag limit has expired
1550 */
1551 void NextLevel()
1552 {
1553         gameover = TRUE;
1554
1555         intermission_running = 1;
1556
1557 // enforce a wait time before allowing changelevel
1558         if(player_count > 0)
1559                 intermission_exittime = time + cvar("sv_mapchange_delay");
1560         else
1561                 intermission_exittime = -1;
1562
1563         /*
1564         WriteByte (MSG_ALL, SVC_CDTRACK);
1565         WriteByte (MSG_ALL, 3);
1566         WriteByte (MSG_ALL, 3);
1567         // done in FixIntermission
1568         */
1569
1570         //pos = FindIntermission ();
1571
1572         VoteReset();
1573
1574         DumpStats(TRUE);
1575
1576         if(cvar("sv_eventlog"))
1577                 GameLogEcho(":gameover");
1578
1579         GameLogClose();
1580
1581         FOR_EACH_PLAYER(other) {
1582                 FixIntermissionClient(other);
1583                 if(other.winning)
1584                         bprint(other.netname, " ^7wins.\n");
1585         }
1586
1587         if(cvar("g_campaign"))
1588                 CampaignPreIntermission();
1589
1590         localcmd("\nsv_hook_gameend\n");
1591 }
1592
1593 /*
1594 ============
1595 CheckRules_Player
1596
1597 Exit deathmatch games upon conditions
1598 ============
1599 */
1600 void CheckRules_Player()
1601 {
1602         if (gameover)   // someone else quit the game already
1603                 return;
1604
1605         if(self.deadflag == DEAD_NO)
1606                 self.play_time += frametime;
1607
1608         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1609         //   (div0: and that in CheckRules_World please)
1610 };
1611
1612 float checkrules_equality;
1613 float checkrules_suddendeathwarning;
1614 float checkrules_suddendeathend;
1615 float checkrules_overtimesadded; //how many overtimes have been already added
1616
1617 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1618 float WINNING_YES = 1; // winner found
1619 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1620 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1621
1622 float InitiateSuddenDeath()
1623 {
1624         // Check first whether normal overtimes could be added before initiating suddendeath mode
1625         // - for this timelimit_overtime needs to be >0 of course
1626         // - also check the winning condition calculated in the previous frame and only add normal overtime
1627         //   again, if at the point at which timelimit would be extended again, still no winner was found
1628         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1629         {
1630                 return 1; // need to call InitiateOvertime later
1631         }
1632         else
1633         {
1634                 if(!checkrules_suddendeathend)
1635                 {
1636                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1637                         if(g_race && !g_race_qualifying)
1638                                 race_StartCompleting();
1639                 }
1640                 return 0;
1641         }
1642 }
1643
1644 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1645 {
1646         ++checkrules_overtimesadded;
1647         //add one more overtime by simply extending the timelimit
1648         float tl;
1649         tl = cvar("timelimit");
1650         tl += cvar("timelimit_overtime");
1651         cvar_set("timelimit", ftos(tl));
1652         string minutesPlural;
1653         if (cvar("timelimit_overtime") == 1)
1654                 minutesPlural = " ^3minute";
1655         else
1656                 minutesPlural = " ^3minutes";
1657
1658         bcenterprint(
1659                 strcat(
1660                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1661                         ftos(cvar("timelimit_overtime")),
1662                         minutesPlural,
1663                         " to the game!"
1664                 )
1665         );
1666 }
1667
1668 float GetWinningCode(float fraglimitreached, float equality)
1669 {
1670         if(cvar("g_campaign") == 1)
1671                 if(fraglimitreached)
1672                         return WINNING_YES;
1673                 else
1674                         return WINNING_NO;
1675
1676         else
1677                 if(equality)
1678                         if(fraglimitreached)
1679                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1680                         else
1681                                 return WINNING_NEVER;
1682                 else
1683                         if(fraglimitreached)
1684                                 return WINNING_YES;
1685                         else
1686                                 return WINNING_NO;
1687 }
1688
1689 // set the .winning flag for exactly those players with a given field value
1690 void SetWinners(.float field, float value)
1691 {
1692         entity head;
1693         FOR_EACH_PLAYER(head)
1694                 head.winning = (head.field == value);
1695 }
1696
1697 // set the .winning flag for those players with a given field value
1698 void AddWinners(.float field, float value)
1699 {
1700         entity head;
1701         FOR_EACH_PLAYER(head)
1702                 if(head.field == value)
1703                         head.winning = 1;
1704 }
1705
1706 // clear the .winning flags
1707 void ClearWinners(void)
1708 {
1709         entity head;
1710         FOR_EACH_PLAYER(head)
1711                 head.winning = 0;
1712 }
1713
1714 // Onslaught winning condition:
1715 // game terminates if only one team has a working generator (or none)
1716 float WinningCondition_Onslaught()
1717 {
1718         entity head;
1719         local float t1, t2, t3, t4;
1720
1721         WinningConditionHelper(); // set worldstatus
1722
1723         if(inWarmupStage)
1724                 return WINNING_NO;
1725
1726         // first check if the game has ended
1727         t1 = t2 = t3 = t4 = 0;
1728         head = find(world, classname, "onslaught_generator");
1729         while (head)
1730         {
1731                 if (head.health > 0)
1732                 {
1733                         if (head.team == COLOR_TEAM1) t1 = 1;
1734                         if (head.team == COLOR_TEAM2) t2 = 1;
1735                         if (head.team == COLOR_TEAM3) t3 = 1;
1736                         if (head.team == COLOR_TEAM4) t4 = 1;
1737                 }
1738                 head = find(head, classname, "onslaught_generator");
1739         }
1740         if (t1 + t2 + t3 + t4 < 2)
1741         {
1742                 // game over, only one team remains (or none)
1743                 ClearWinners();
1744                 if (t1) SetWinners(team, COLOR_TEAM1);
1745                 if (t2) SetWinners(team, COLOR_TEAM2);
1746                 if (t3) SetWinners(team, COLOR_TEAM3);
1747                 if (t4) SetWinners(team, COLOR_TEAM4);
1748                 dprint("Have a winner, ending game.\n");
1749                 return WINNING_YES;
1750         }
1751
1752         // Two or more teams remain
1753         return WINNING_NO;
1754 }
1755
1756 float LMS_NewPlayerLives()
1757 {
1758         float fl;
1759         fl = cvar("fraglimit");
1760         if(fl == 0)
1761                 fl = 999;
1762
1763         // first player has left the game for dying too much? Nobody else can get in.
1764         if(lms_lowest_lives < 1)
1765                 return 0;
1766
1767         if(!cvar("g_lms_join_anytime"))
1768                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1769                         return 0;
1770
1771         return bound(1, lms_lowest_lives, fl);
1772 }
1773
1774 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1775 // they win. Otherwise the defending team wins once the timelimit passes.
1776 void assault_new_round();
1777 float WinningCondition_Assault()
1778 {
1779         local float status;
1780
1781         WinningConditionHelper(); // set worldstatus
1782
1783         status = WINNING_NO;
1784         // as the timelimit has not yet passed just assume the defending team will win
1785         if(assault_attacker_team == COLOR_TEAM1)
1786         {
1787                 SetWinners(team, COLOR_TEAM2);
1788         }
1789         else
1790         {
1791                 SetWinners(team, COLOR_TEAM1);
1792         }
1793
1794         local entity ent;
1795         ent = find(world, classname, "target_assault_roundend");
1796         if(ent)
1797         {
1798                 if(ent.winning) // round end has been triggered by attacking team
1799                 {
1800                         bprint("ASSAULT: round completed...\n");
1801                         SetWinners(team, assault_attacker_team);
1802
1803                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1804
1805                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1806                         {
1807                                 status = WINNING_YES;
1808                         }
1809                         else
1810                         {
1811                                 local entity oldself;
1812                                 oldself = self;
1813                                 self = ent;
1814                                 assault_new_round();
1815                                 self = oldself;
1816                         }
1817                 }
1818         }
1819
1820         return status;
1821 }
1822
1823 // LMS winning condition: game terminates if and only if there's at most one
1824 // one player who's living lives. Top two scores being equal cancels the time
1825 // limit.
1826 float WinningCondition_LMS()
1827 {
1828         entity head, head2;
1829         float have_player;
1830         float have_players;
1831         float l;
1832
1833         have_player = FALSE;
1834         have_players = FALSE;
1835         l = LMS_NewPlayerLives();
1836
1837         head = find(world, classname, "player");
1838         if(head)
1839                 have_player = TRUE;
1840         head2 = find(head, classname, "player");
1841         if(head2)
1842                 have_players = TRUE;
1843
1844         if(have_player)
1845         {
1846                 // we have at least one player
1847                 if(have_players)
1848                 {
1849                         // two or more active players - continue with the game
1850                 }
1851                 else
1852                 {
1853                         // exactly one player?
1854
1855                         ClearWinners();
1856                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1857
1858                         if(l)
1859                         {
1860                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1861                                 return WINNING_NO;
1862                         }
1863                         else
1864                         {
1865                                 // a winner!
1866                                 // and assign him his first place
1867                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1868                                 return WINNING_YES;
1869                         }
1870                 }
1871         }
1872         else
1873         {
1874                 // nobody is playing at all...
1875                 if(l)
1876                 {
1877                         // wait for players...
1878                 }
1879                 else
1880                 {
1881                         // SNAFU (maybe a draw game?)
1882                         ClearWinners();
1883                         dprint("No players, ending game.\n");
1884                         return WINNING_YES;
1885                 }
1886         }
1887
1888         // When we get here, we have at least two players who are actually LIVING,
1889         // now check if the top two players have equal score.
1890         WinningConditionHelper();
1891
1892         ClearWinners();
1893         if(WinningConditionHelper_winner)
1894                 WinningConditionHelper_winner.winning = TRUE;
1895         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1896                 return WINNING_NEVER;
1897
1898         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1899         return WINNING_NO;
1900 }
1901
1902 void ShuffleMaplist()
1903 {
1904         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1905 }
1906
1907 float leaderfrags;
1908 float WinningCondition_Scores(float limit, float leadlimit)
1909 {
1910         float limitreached;
1911
1912         // TODO make everything use THIS winning condition (except LMS)
1913         WinningConditionHelper();
1914
1915         if(teams_matter)
1916         {
1917                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1918                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1919                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1920                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1921         }
1922
1923         ClearWinners();
1924         if(WinningConditionHelper_winner)
1925                 WinningConditionHelper_winner.winning = 1;
1926         if(WinningConditionHelper_winnerteam >= 0)
1927                 SetWinners(team, WinningConditionHelper_winnerteam);
1928
1929         if(WinningConditionHelper_lowerisbetter)
1930         {
1931                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1932                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1933                 limit = -limit;
1934         }
1935
1936         if(WinningConditionHelper_zeroisworst)
1937                 leadlimit = 0; // not supported in this mode
1938
1939         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1940         // these modes always score in increments of 1, thus this makes sense
1941         {
1942                 if(leaderfrags != WinningConditionHelper_topscore)
1943                 {
1944                         leaderfrags = WinningConditionHelper_topscore;
1945
1946                         if (limit)
1947                         if (leaderfrags == limit - 1)
1948                                 Announce("1fragleft");
1949                         else if (leaderfrags == limit - 2)
1950                                 Announce("2fragsleft");
1951                         else if (leaderfrags == limit - 3)
1952                                 Announce("3fragsleft");
1953                 }
1954         }
1955
1956         limitreached = FALSE;
1957         if(limit)
1958                 if(WinningConditionHelper_topscore >= limit)
1959                         limitreached = TRUE;
1960         if(leadlimit)
1961         {
1962                 float leadlimitreached;
1963                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1964                 if(cvar("leadlimit_and_fraglimit"))
1965                         limitreached = (limitreached && leadlimitreached);
1966                 else
1967                         limitreached = (limitreached || leadlimitreached);
1968         }
1969
1970         return GetWinningCode(
1971                 WinningConditionHelper_topscore && limitreached,
1972                 WinningConditionHelper_equality
1973         );
1974 }
1975
1976 float WinningCondition_Race(float fraglimit)
1977 {
1978         float wc;
1979         entity p;
1980         float n, c;
1981
1982         n = 0;
1983         c = 0;
1984         FOR_EACH_PLAYER(p)
1985         {
1986                 ++n;
1987                 if(p.race_completed)
1988                         ++c;
1989         }
1990         if(n && (n == c))
1991                 return WINNING_YES;
1992         wc = WinningCondition_Scores(fraglimit, 0);
1993
1994         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1995         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1996         // do NOT support equality when the laps are all raced!
1997                 return WINNING_STARTSUDDENDEATHOVERTIME;
1998         else
1999                 return WINNING_NEVER;
2000         return wc;
2001 }
2002
2003 void ReadyRestart();
2004 float WinningCondition_QualifyingThenRace(float limit)
2005 {
2006         float wc;
2007         wc = WinningCondition_Scores(limit, 0);
2008
2009         // NEVER initiate overtime
2010         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2011         {
2012                 return WINNING_YES;
2013         }
2014
2015         return wc;
2016 }
2017
2018 float WinningCondition_RanOutOfSpawns()
2019 {
2020         entity head;
2021
2022         if(have_team_spawns <= 0)
2023                 return WINNING_NO;
2024
2025         if(!some_spawn_has_been_used)
2026                 return WINNING_NO;
2027
2028         team1_score = team2_score = team3_score = team4_score = 0;
2029
2030         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2031         {
2032                 if(head.team == COLOR_TEAM1)
2033                         team1_score = 1;
2034                 else if(head.team == COLOR_TEAM2)
2035                         team2_score = 1;
2036                 else if(head.team == COLOR_TEAM3)
2037                         team3_score = 1;
2038                 else if(head.team == COLOR_TEAM4)
2039                         team4_score = 1;
2040         }
2041
2042         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2043         {
2044                 if(head.team == COLOR_TEAM1)
2045                         team1_score = 1;
2046                 else if(head.team == COLOR_TEAM2)
2047                         team2_score = 1;
2048                 else if(head.team == COLOR_TEAM3)
2049                         team3_score = 1;
2050                 else if(head.team == COLOR_TEAM4)
2051                         team4_score = 1;
2052         }
2053
2054         ClearWinners();
2055         if(team1_score + team2_score + team3_score + team4_score == 0)
2056         {
2057                 checkrules_equality = TRUE;
2058                 return WINNING_YES;
2059         }
2060         else if(team1_score + team2_score + team3_score + team4_score == 1)
2061         {
2062                 float t, i;
2063                 if(team1_score) t = COLOR_TEAM1;
2064                 if(team2_score) t = COLOR_TEAM2;
2065                 if(team3_score) t = COLOR_TEAM3;
2066                 if(team4_score) t = COLOR_TEAM4;
2067                 CheckAllowedTeams(world);
2068                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2069                 {
2070                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2071                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2072                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2073                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2074                 }
2075
2076                 AddWinners(team, t);
2077                 return WINNING_YES;
2078         }
2079         else
2080                 return WINNING_NO;
2081 }
2082
2083 /*
2084 ============
2085 CheckRules_World
2086
2087 Exit deathmatch games upon conditions
2088 ============
2089 */
2090 void CheckRules_World()
2091 {
2092         float timelimit;
2093         float fraglimit;
2094         float leadlimit;
2095
2096         VoteThink();
2097         MapVote_Think();
2098
2099         SetDefaultAlpha();
2100
2101         /*
2102         MapVote_Think should now do that part
2103         if (intermission_running)
2104                 if (time >= intermission_exittime + 60)
2105                 {
2106                         if(!DoNextMapOverride())
2107                                 GotoNextMap();
2108                         return;
2109                 }
2110         */
2111
2112         if (gameover)   // someone else quit the game already
2113         {
2114                 if(player_count == 0) // Nobody there? Then let's go to the next map
2115                         MapVote_Start();
2116                         // this will actually check the player count in the next frame
2117                         // again, but this shouldn't hurt
2118                 return;
2119         }
2120
2121         timelimit = cvar("timelimit") * 60;
2122         fraglimit = cvar("fraglimit");
2123         leadlimit = cvar("leadlimit");
2124
2125         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2126         {
2127                 if(timelimit > 0)
2128                         timelimit = 0; // timelimit is not made for warmup
2129                 if(fraglimit > 0)
2130                         fraglimit = 0; // no fraglimit for now
2131                 leadlimit = 0; // no leadlimit for now
2132         }
2133
2134         if(g_onslaught)
2135                 timelimit = 0; // ONS has its own overtime rule
2136
2137         if(timelimit > 0)
2138         {
2139                 timelimit += game_starttime;
2140         }
2141         else if (timelimit < 0)
2142         {
2143                 // endmatch
2144                 NextLevel();
2145                 return;
2146         }
2147
2148         float wantovertime;
2149         wantovertime = 0;
2150
2151         if(checkrules_suddendeathend)
2152         {
2153                 if(!checkrules_suddendeathwarning)
2154                 {
2155                         checkrules_suddendeathwarning = TRUE;
2156                         if(g_race && !g_race_qualifying)
2157                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2158                         else
2159                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2160                 }
2161         }
2162         else
2163         {
2164                 if (timelimit && time >= timelimit)
2165                 {
2166                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2167                         {
2168                                 float totalplayers;
2169                                 float playerswithlaps;
2170                                 float readyplayers;
2171                                 entity head;
2172                                 totalplayers = playerswithlaps = readyplayers = 0;
2173                                 FOR_EACH_PLAYER(head)
2174                                 {
2175                                         ++totalplayers;
2176                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2177                                                 ++playerswithlaps;
2178                                         if(head.ready)
2179                                                 ++readyplayers;
2180                                 }
2181
2182                                 // at least 2 of the players have completed a lap: start the RACE
2183                                 // otherwise, the players should end the qualifying on their own
2184                                 if(readyplayers || playerswithlaps >= 2)
2185                                 {
2186                                         checkrules_suddendeathend = 0;
2187                                         ReadyRestart(); // go to race
2188                                         return;
2189                                 }
2190                                 else
2191                                         wantovertime |= InitiateSuddenDeath();
2192                         }
2193                         else
2194                                 wantovertime |= InitiateSuddenDeath();
2195                 }
2196         }
2197
2198         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2199         {
2200                 NextLevel();
2201                 return;
2202         }
2203
2204         float checkrules_status;
2205         checkrules_status = WinningCondition_RanOutOfSpawns();
2206         if(checkrules_status == WINNING_YES)
2207         {
2208                 bprint("Hey! Someone ran out of spawns!\n");
2209         }
2210         else if(g_race && !g_race_qualifying && timelimit >= 0)
2211         {
2212                 checkrules_status = WinningCondition_Race(fraglimit);
2213                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2214         }
2215         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2216         {
2217                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2218                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2219         }
2220         else if(g_assault)
2221         {
2222                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2223         }
2224         else if(g_lms)
2225         {
2226                 checkrules_status = WinningCondition_LMS();
2227         }
2228         else if (g_onslaught)
2229         {
2230                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2231         }
2232         else
2233         {
2234                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2235                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2236         }
2237
2238         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2239         {
2240                 checkrules_status = WINNING_NEVER;
2241                 checkrules_overtimesadded = -1;
2242                 wantovertime |= InitiateSuddenDeath();
2243         }
2244
2245         if(checkrules_status == WINNING_NEVER)
2246                 // equality cases! Nobody wins if the overtime ends in a draw.
2247                 ClearWinners();
2248
2249         if(wantovertime)
2250         {
2251                 if(checkrules_status == WINNING_NEVER)
2252                         InitiateOvertime();
2253                 else
2254                         checkrules_status = WINNING_YES;
2255         }
2256
2257         if(checkrules_suddendeathend)
2258                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2259                         checkrules_status = WINNING_YES;
2260
2261         if(checkrules_status == WINNING_YES)
2262         {
2263                 //print("WINNING\n");
2264                 NextLevel();
2265         }
2266 };
2267
2268 float mapvote_nextthink;
2269 float mapvote_initialized;
2270 float mapvote_keeptwotime;
2271 float mapvote_timeout;
2272 string mapvote_message;
2273 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2274 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2275 float mapvote_screenshot_dirs_count;
2276
2277 float mapvote_count;
2278 float mapvote_count_real;
2279 string mapvote_maps[MAPVOTE_COUNT];
2280 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2281 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2282 float mapvote_maps_suggested[MAPVOTE_COUNT];
2283 string mapvote_suggestions[MAPVOTE_COUNT];
2284 float mapvote_suggestion_ptr;
2285 float mapvote_maxlen;
2286 float mapvote_voters;
2287 float mapvote_votes[MAPVOTE_COUNT];
2288 float mapvote_run;
2289 float mapvote_detail;
2290 float mapvote_abstain;
2291 .float mapvote;
2292
2293 void MapVote_ClearAllVotes()
2294 {
2295         FOR_EACH_CLIENT(other)
2296                 other.mapvote = 0;
2297 }
2298
2299 string MapVote_Suggest(string m)
2300 {
2301         float i;
2302         if(m == "")
2303                 return "That's not how to use this command.";
2304         if(!cvar("g_maplist_votable_suggestions"))
2305                 return "Suggestions are not accepted on this server.";
2306         if(mapvote_initialized)
2307                 return "Can't suggest - voting is already in progress!";
2308         m = MapInfo_FixName(m);
2309         if(!m)
2310                 return "The map you suggested is not available on this server.";
2311         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2312                 if(Map_IsRecent(m))
2313                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2314
2315         if(!MapInfo_CheckMap(m))
2316                 return "The map you suggested does not support the current game mode.";
2317         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2318                 if(mapvote_suggestions[i] == m)
2319                         return "This map was already suggested.";
2320         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2321         {
2322                 i = floor(random() * mapvote_suggestion_ptr);
2323         }
2324         else
2325         {
2326                 i = mapvote_suggestion_ptr;
2327                 mapvote_suggestion_ptr += 1;
2328         }
2329         if(mapvote_suggestions[i] != "")
2330                 strunzone(mapvote_suggestions[i]);
2331         mapvote_suggestions[i] = strzone(m);
2332         if(cvar("sv_eventlog"))
2333                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2334         return strcat("Suggestion of ", m, " accepted.");
2335 }
2336
2337 void MapVote_AddVotable(string nextMap, float isSuggestion)
2338 {
2339         float j, i, o;
2340         string pakfile, mapfile;
2341
2342         if(nextMap == "")
2343                 return;
2344         for(j = 0; j < mapvote_count; ++j)
2345                 if(mapvote_maps[j] == nextMap)
2346                         return;
2347         if(strlen(nextMap) > mapvote_maxlen)
2348                 mapvote_maxlen = strlen(nextMap);
2349         mapvote_maps[mapvote_count] = strzone(nextMap);
2350         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2351
2352         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2353         {
2354                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2355                 pakfile = whichpack(strcat(mapfile, ".tga"));
2356                 if(pakfile == "")
2357                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2358                 if(pakfile == "")
2359                         pakfile = whichpack(strcat(mapfile, ".png"));
2360                 if(pakfile != "")
2361                         break;
2362         }
2363         if(i >= mapvote_screenshot_dirs_count)
2364                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2365         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2366                 pakfile = substring(pakfile, o, -1);
2367
2368         mapvote_maps_screenshot_dir[mapvote_count] = i;
2369         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2370
2371         mapvote_count += 1;
2372 }
2373
2374 void MapVote_Spawn();
2375 void MapVote_Init()
2376 {
2377         float i;
2378         float nmax, smax;
2379
2380         MapVote_ClearAllVotes();
2381
2382         mapvote_count = 0;
2383         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2384         mapvote_abstain = cvar("g_maplist_votable_abstain");
2385
2386         if(mapvote_abstain)
2387                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2388         else
2389                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2390         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2391
2392         // we need this for AddVotable, as that cycles through the screenshot dirs
2393         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2394         if(mapvote_screenshot_dirs_count == 0)
2395                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2396         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2397         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2398                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2399
2400         if(mapvote_suggestion_ptr)
2401                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2402                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2403
2404         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2405                 MapVote_AddVotable(GetNextMap(), FALSE);
2406
2407         if(mapvote_count == 0)
2408         {
2409                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2410                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2411                 if(cvar("g_maplist_shuffle"))
2412                         ShuffleMaplist();
2413                 localcmd("\nmenu_cmd sync\n");
2414                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2415                         MapVote_AddVotable(GetNextMap(), FALSE);
2416         }
2417
2418         mapvote_count_real = mapvote_count;
2419         if(mapvote_abstain)
2420                 MapVote_AddVotable("don't care", 0);
2421
2422         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2423
2424         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2425         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2426         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2427                 mapvote_keeptwotime = 0;
2428         mapvote_message = "Choose a map and press its key!";
2429
2430         MapVote_Spawn();
2431 }
2432
2433 void MapVote_SendPicture(float id)
2434 {
2435         msg_entity = self;
2436         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2437         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2438         WriteByte(MSG_ONE, id);
2439         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2440 }
2441
2442 float GameCommand_MapVote(string cmd)
2443 {
2444         if(!intermission_running)
2445                 return FALSE;
2446
2447         if(cmd == "mv_getpic")
2448         {
2449                 MapVote_SendPicture(stof(argv(1)));
2450                 return TRUE;
2451         }
2452
2453         return FALSE;
2454 }
2455
2456 float MapVote_GetMapMask()
2457 {
2458         float mask, i, power;
2459         mask = 0;
2460         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2461                 if(mapvote_maps[i] != "")
2462                         mask |= power;
2463         return mask;
2464 }
2465
2466 entity mapvote_ent;
2467 float MapVote_SendEntity(entity to, float sf)
2468 {
2469         float i;
2470
2471         if(sf & 1)
2472                 sf &~= 2; // if we send 1, we don't need to also send 2
2473
2474         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2475         WriteByte(MSG_ENTITY, sf);
2476
2477         if(sf & 1)
2478         {
2479                 // flag 1 == initialization
2480                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2481                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2482                 WriteString(MSG_ENTITY, "");
2483                 WriteByte(MSG_ENTITY, mapvote_count);
2484                 WriteByte(MSG_ENTITY, mapvote_abstain);
2485                 WriteByte(MSG_ENTITY, mapvote_detail);
2486                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2487                 if(mapvote_count <= 8)
2488                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2489                 else
2490                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2491                 for(i = 0; i < mapvote_count; ++i)
2492                         if(mapvote_maps[i] != "")
2493                         {
2494                                 if(mapvote_abstain && i == mapvote_count - 1)
2495                                 {
2496                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2497                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2498                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2499                                 }
2500                                 else
2501                                 {
2502                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2503                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2504                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2505                                 }
2506                         }
2507         }
2508
2509         if(sf & 2)
2510         {
2511                 // flag 2 == update of mask
2512                 if(mapvote_count <= 8)
2513                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2514                 else
2515                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2516         }
2517
2518         if(sf & 4)
2519         {
2520                 if(mapvote_detail)
2521                         for(i = 0; i < mapvote_count; ++i)
2522                                 if(mapvote_maps[i] != "")
2523                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2524
2525                 WriteByte(MSG_ENTITY, to.mapvote);
2526         }
2527
2528         return TRUE;
2529 }
2530
2531 void MapVote_Spawn()
2532 {
2533         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2534 }
2535
2536 void MapVote_TouchMask()
2537 {
2538         mapvote_ent.SendFlags |= 2;
2539 }
2540
2541 void MapVote_TouchVotes(entity voter)
2542 {
2543         mapvote_ent.SendFlags |= 4;
2544 }
2545
2546 float MapVote_Finished(float mappos)
2547 {
2548         string result;
2549         float i;
2550         float didntvote;
2551
2552         if(cvar("sv_eventlog"))
2553         {
2554                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2555                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2556                 didntvote = mapvote_voters;
2557                 for(i = 0; i < mapvote_count; ++i)
2558                         if(mapvote_maps[i] != "")
2559                         {
2560                                 didntvote -= mapvote_votes[i];
2561                                 if(i != mappos)
2562                                 {
2563                                         result = strcat(result, ":", mapvote_maps[i]);
2564                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2565                                 }
2566                         }
2567                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2568
2569                 GameLogEcho(result);
2570                 if(mapvote_maps_suggested[mappos])
2571                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2572         }
2573
2574         FOR_EACH_REALCLIENT(other)
2575                 FixClientCvars(other);
2576
2577         Map_Goto_SetStr(mapvote_maps[mappos]);
2578         Map_Goto();
2579         alreadychangedlevel = TRUE;
2580         return TRUE;
2581 }
2582 void MapVote_CheckRules_1()
2583 {
2584         float i;
2585
2586         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2587         {
2588                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2589                 mapvote_votes[i] = 0;
2590         }
2591
2592         mapvote_voters = 0;
2593         FOR_EACH_REALCLIENT(other)
2594         {
2595                 ++mapvote_voters;
2596                 if(other.mapvote)
2597                 {
2598                         i = other.mapvote - 1;
2599                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2600                         mapvote_votes[i] = mapvote_votes[i] + 1;
2601                 }
2602         }
2603 }
2604
2605 float MapVote_CheckRules_2()
2606 {
2607         float i;
2608         float firstPlace, secondPlace;
2609         float firstPlaceVotes, secondPlaceVotes;
2610         float mapvote_voters_real;
2611         string result;
2612
2613         if(mapvote_count_real == 1)
2614                 return MapVote_Finished(0);
2615
2616         mapvote_voters_real = mapvote_voters;
2617         if(mapvote_abstain)
2618                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2619
2620         RandomSelection_Init();
2621         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2622                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2623         firstPlace = RandomSelection_chosen_float;
2624         firstPlaceVotes = RandomSelection_best_priority;
2625         //dprint("First place: ", ftos(firstPlace), "\n");
2626         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2627
2628         RandomSelection_Init();
2629         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2630                 if(i != firstPlace)
2631                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2632         secondPlace = RandomSelection_chosen_float;
2633         secondPlaceVotes = RandomSelection_best_priority;
2634         //dprint("Second place: ", ftos(secondPlace), "\n");
2635         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2636
2637         if(firstPlace == -1)
2638                 error("No first place in map vote... WTF?");
2639
2640         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2641                 return MapVote_Finished(firstPlace);
2642
2643         if(mapvote_keeptwotime)
2644                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2645                 {
2646                         float didntvote;
2647                         MapVote_TouchMask();
2648                         mapvote_message = "Now decide between the TOP TWO!";
2649                         mapvote_keeptwotime = 0;
2650                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2651                         result = strcat(result, ":", ftos(firstPlaceVotes));
2652                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2653                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2654                         didntvote = mapvote_voters;
2655                         for(i = 0; i < mapvote_count; ++i)
2656                                 if(mapvote_maps[i] != "")
2657                                 {
2658                                         didntvote -= mapvote_votes[i];
2659                                         if(i != firstPlace)
2660                                                 if(i != secondPlace)
2661                                                 {
2662                                                         result = strcat(result, ":", mapvote_maps[i]);
2663                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2664                                                         if(i < mapvote_count_real)
2665                                                         {
2666                                                                 strunzone(mapvote_maps[i]);
2667                                                                 mapvote_maps[i] = "";
2668                                                                 strunzone(mapvote_maps_pakfile[i]);
2669                                                                 mapvote_maps_pakfile[i] = "";
2670                                                         }
2671                                                 }
2672                                 }
2673                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2674                         if(cvar("sv_eventlog"))
2675                                 GameLogEcho(result);
2676                 }
2677
2678         return FALSE;
2679 }
2680 void MapVote_Tick()
2681 {
2682         float keeptwo;
2683         float totalvotes;
2684
2685         keeptwo = mapvote_keeptwotime;
2686         MapVote_CheckRules_1(); // count
2687         if(MapVote_CheckRules_2()) // decide
2688                 return;
2689
2690         totalvotes = 0;
2691         FOR_EACH_REALCLIENT(other)
2692         {
2693                 // hide scoreboard again
2694                 if(other.health != 2342)
2695                 {
2696                         other.health = 2342;
2697                         other.impulse = 0;
2698                         if(clienttype(other) == CLIENTTYPE_REAL)
2699                         {
2700                                 msg_entity = other;
2701                                 WriteByte(MSG_ONE, SVC_FINALE);
2702                                 WriteString(MSG_ONE, "");
2703                         }
2704                 }
2705
2706                 // clear possibly invalid votes
2707                 if(mapvote_maps[other.mapvote - 1] == "")
2708                         other.mapvote = 0;
2709                 // use impulses as new vote
2710                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2711                         if(mapvote_maps[other.impulse - 1] != "")
2712                         {
2713                                 other.mapvote = other.impulse;
2714                                 MapVote_TouchVotes(other);
2715                         }
2716                 other.impulse = 0;
2717
2718                 if(other.mapvote)
2719                         ++totalvotes;
2720         }
2721
2722         MapVote_CheckRules_1(); // just count
2723 }
2724 void MapVote_Start()
2725 {
2726         if(mapvote_run)
2727                 return;
2728
2729         // wait for stats to be sent first
2730         if(!playerstats_sent)
2731                 return;
2732
2733         MapInfo_Enumerate();
2734         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2735                 mapvote_run = TRUE;
2736 }
2737 void MapVote_Think()
2738 {
2739         if(!mapvote_run)
2740                 return;
2741
2742         if(alreadychangedlevel)
2743                 return;
2744
2745         if(time < mapvote_nextthink)
2746                 return;
2747         //dprint("tick\n");
2748
2749         mapvote_nextthink = time + 0.5;
2750
2751         if(!mapvote_initialized)
2752         {
2753                 if(cvar("rescan_pending") == 1)
2754                 {
2755                         cvar_set("rescan_pending", "2");
2756                         localcmd("fs_rescan\nrescan_pending 3\n");
2757                         return;
2758                 }
2759                 else if(cvar("rescan_pending") == 2)
2760                 {
2761                         return;
2762                 }
2763                 else if(cvar("rescan_pending") == 3)
2764                 {
2765                         // now build missing mapinfo files
2766                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2767                                 return;
2768
2769                         // we're done, start the timer
2770                         cvar_set("rescan_pending", "0");
2771                 }
2772
2773                 mapvote_initialized = TRUE;
2774                 if(DoNextMapOverride())
2775                         return;
2776                 if(!cvar("g_maplist_votable") || player_count <= 0)
2777                 {
2778                         GotoNextMap();
2779                         return;
2780                 }
2781                 MapVote_Init();
2782         }
2783
2784         MapVote_Tick();
2785 };
2786
2787 string GotoMap(string m)
2788 {
2789         if(!MapInfo_CheckMap(m))
2790                 return "The map you chose is not available on this server.";
2791         cvar_set("nextmap", m);
2792         cvar_set("timelimit", "-1");
2793         if(mapvote_initialized || alreadychangedlevel)
2794         {
2795                 if(DoNextMapOverride())
2796                         return "Map switch initiated.";
2797                 else
2798                         return "Hm... no. For some reason I like THIS map more.";
2799         }
2800         else
2801                 return "Map switch will happen after scoreboard.";
2802 }
2803
2804
2805 void EndFrame()
2806 {
2807         float altime;
2808         FOR_EACH_REALCLIENT(self)
2809         {
2810                 if(self.classname == "spectator")
2811                 {
2812                         if(self.enemy.typehitsound)
2813                                 play2(self, "misc/typehit.wav");
2814                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2815                                 play2(self, "misc/hit.wav");
2816                 }
2817                 else
2818                 {
2819                         if(self.typehitsound)
2820                                 play2(self, "misc/typehit.wav");
2821                         else if(self.hitsound && self.cvar_cl_hitsound)
2822                                 play2(self, "misc/hit.wav");
2823                 }
2824         }
2825         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2826         // add 1 frametime because after this, engine SV_Physics
2827         // increases time by a frametime and then networks the frame
2828         // add another frametime because client shows everything with
2829         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2830         // needed!
2831         FOR_EACH_CLIENT(self)
2832         {
2833                 self.hitsound = FALSE;
2834                 self.typehitsound = FALSE;
2835                 antilag_record(self, altime);
2836         }
2837 }
2838
2839
2840 /*
2841  * RedirectionThink:
2842  * returns TRUE if redirecting
2843  */
2844 float redirection_timeout;
2845 float redirection_nextthink;
2846 float RedirectionThink()
2847 {
2848         float clients_found;
2849
2850         if(redirection_target == "")
2851                 return FALSE;
2852
2853         if(!redirection_timeout)
2854         {
2855                 cvar_set("sv_public", "-2");
2856                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2857                 if(redirection_target == "self")
2858                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2859                 else
2860                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2861         }
2862
2863         if(time < redirection_nextthink)
2864                 return TRUE;
2865
2866         redirection_nextthink = time + 1;
2867
2868         clients_found = 0;
2869         FOR_EACH_REALCLIENT(self)
2870         {
2871                 print("Redirecting: sending connect command to ", self.netname, "\n");
2872                 if(redirection_target == "self")
2873                         stuffcmd(self, "\ndisconnect; reconnect\n");
2874                 else
2875                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2876                 ++clients_found;
2877         }
2878
2879         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2880
2881         if(time > redirection_timeout || clients_found == 0)
2882                 localcmd("\nwait; wait; wait; quit\n");
2883
2884         return TRUE;
2885 }
2886
2887 void TargetMusic_RestoreGame();
2888 void RestoreGame()
2889 {
2890         // Loaded from a save game
2891         // some things then break, so let's work around them...
2892
2893         // Progs DB (capture records)
2894         ServerProgsDB = db_load("server.db");
2895
2896         // Mapinfo
2897         MapInfo_Shutdown();
2898         MapInfo_Enumerate();
2899         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2900         WeaponStats_Init();
2901
2902         TargetMusic_RestoreGame();
2903 }
2904
2905 void SV_Shutdown()
2906 {
2907         entity e;
2908
2909         if(gameover > 1) // shutting down already?
2910                 return;
2911
2912         gameover = 2; // 2 = server shutting down
2913
2914         if(world_initialized > 0)
2915         {
2916                 world_initialized = 0;
2917                 print("Saving persistent data...\n");
2918                 Ban_SaveBans();
2919
2920                 FOR_EACH_CLIENT(e)
2921                         PlayerStats_AddGlobalInfo(e);
2922                 PlayerStats_Shutdown();
2923
2924                 if(!cheatcount_total)
2925                 {
2926                         if(cvar("sv_db_saveasdump"))
2927                                 db_dump(ServerProgsDB, "server.db");
2928                         else
2929                                 db_save(ServerProgsDB, "server.db");
2930                 }
2931                 if(cvar("developer"))
2932                 {
2933                         if(cvar("sv_db_saveasdump"))
2934                                 db_dump(TemporaryDB, "server-temp.db");
2935                         else
2936                                 db_save(TemporaryDB, "server-temp.db");
2937                 }
2938                 CheatShutdown(); // must be after cheatcount check
2939                 db_close(ServerProgsDB);
2940                 db_close(TemporaryDB);
2941                 print("done!\n");
2942                 // tell the bot system the game is ending now
2943                 bot_endgame();
2944
2945                 WeaponStats_Shutdown();
2946                 MapInfo_Shutdown();
2947         }
2948         else if(world_initialized == 0)
2949         {
2950                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2951         }
2952 }