Transifex autosync
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 #include "g_world.qh"
2
3 #include "anticheat.qh"
4 #include "antilag.qh"
5 #include "bot/api.qh"
6 #include "campaign.qh"
7 #include "cheats.qh"
8 #include "client.qh"
9 #include "command/common.qh"
10 #include "command/getreplies.qh"
11 #include "command/sv_cmd.qh"
12 #include "command/vote.qh"
13 #include "g_hook.qh"
14 #include "ipban.qh"
15 #include "mapvoting.qh"
16 #include <server/mutators/_mod.qh>
17 #include "race.qh"
18 #include "scores.qh"
19 #include "teamplay.qh"
20 #include "weapons/weaponstats.qh"
21 #include "../common/constants.qh"
22 #include <common/net_linked.qh>
23 #include "../common/deathtypes/all.qh"
24 #include "../common/gamemodes/sv_rules.qh"
25 #include "../common/mapinfo.qh"
26 #include "../common/monsters/_mod.qh"
27 #include "../common/monsters/sv_monsters.qh"
28 #include "../common/vehicles/all.qh"
29 #include "../common/notifications/all.qh"
30 #include "../common/physics/player.qh"
31 #include "../common/playerstats.qh"
32 #include "../common/stats.qh"
33 #include "../common/teams.qh"
34 #include "../common/mapobjects/trigger/secret.qh"
35 #include "../common/mapobjects/target/music.qh"
36 #include "../common/util.qh"
37 #include "../common/items/_mod.qh"
38 #include <common/weapons/_all.qh>
39 #include "../common/state.qh"
40
41 const float LATENCY_THINKRATE = 10;
42 .float latency_sum;
43 .float latency_cnt;
44 .float latency_time;
45 entity pingplreport;
46 void PingPLReport_Think(entity this)
47 {
48         float delta;
49         entity e;
50
51         delta = 3 / maxclients;
52         if(delta < sys_frametime)
53                 delta = 0;
54         this.nextthink = time + delta;
55
56         e = edict_num(this.cnt + 1);
57         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
58         {
59                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
60                 WriteByte(MSG_BROADCAST, this.cnt);
61                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
62                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
64
65                 // record latency times for clients throughout the match so we can report it to playerstats
66                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
67                 {
68                         CS(e).latency_sum += CS(e).ping;
69                         CS(e).latency_cnt += 1;
70                         CS(e).latency_time = time;
71                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
72                 }
73         }
74         else
75         {
76                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
77                 WriteByte(MSG_BROADCAST, this.cnt);
78                 WriteShort(MSG_BROADCAST, 0);
79                 WriteByte(MSG_BROADCAST, 0);
80                 WriteByte(MSG_BROADCAST, 0);
81         }
82         this.cnt = (this.cnt + 1) % maxclients;
83 }
84 void PingPLReport_Spawn()
85 {
86         pingplreport = new_pure(pingplreport);
87         setthink(pingplreport, PingPLReport_Think);
88         pingplreport.nextthink = time;
89 }
90
91 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
92 string redirection_target;
93 float world_initialized;
94
95 void SetDefaultAlpha()
96 {
97         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
98         {
99                 default_player_alpha = autocvar_g_player_alpha;
100                 if(default_player_alpha == 0)
101                         default_player_alpha = 1;
102                 default_weapon_alpha = default_player_alpha;
103         }
104 }
105
106 void GotoFirstMap(entity this)
107 {
108         float n;
109         if(autocvar__sv_init)
110         {
111                 // cvar_set("_sv_init", "0");
112                 // we do NOT set this to 0 any more, so someone "accidentally" changing
113                 // to this "init" map on a dedicated server will cause no permanent
114                 // harm
115                 if(autocvar_g_maplist_shuffle)
116                         ShuffleMaplist();
117                 n = tokenizebyseparator(autocvar_g_maplist, " ");
118                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
119
120                 MapInfo_Enumerate();
121                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
122
123                 if(!DoNextMapOverride(1))
124                         GotoNextMap(1);
125
126                 return;
127         }
128
129         if(time < 5)
130         {
131                 this.nextthink = time;
132         }
133         else
134         {
135                 this.nextthink = time + 1;
136                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
137         }
138 }
139
140 void cvar_changes_init()
141 {
142         float h;
143         string k, v, d;
144         float n, i, adding, pureadding;
145
146         strfree(cvar_changes);
147         strfree(cvar_purechanges);
148         cvar_purechanges_count = 0;
149
150         h = buf_create();
151         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
152         n = buf_getsize(h);
153
154         adding = true;
155         pureadding = true;
156
157         for(i = 0; i < n; ++i)
158         {
159                 k = bufstr_get(h, i);
160
161 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
162 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
163 #define BADCVAR(p) if(k == p) continue
164
165                 // general excludes and namespaces for server admin used cvars
166                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
167
168                 // internal
169                 BADPREFIX("csqc_");
170                 BADPREFIX("cvar_check_");
171                 BADCVAR("gamecfg");
172                 BADCVAR("g_configversion");
173                 BADCVAR("halflifebsp");
174                 BADCVAR("sv_mapformat_is_quake2");
175                 BADCVAR("sv_mapformat_is_quake3");
176                 BADPREFIX("sv_world");
177
178                 // client
179                 BADPREFIX("chase_");
180                 BADPREFIX("cl_");
181                 BADPREFIX("con_");
182                 BADPREFIX("scoreboard_");
183                 BADPREFIX("g_campaign");
184                 BADPREFIX("g_waypointsprite_");
185                 BADPREFIX("gl_");
186                 BADPREFIX("joy");
187                 BADPREFIX("hud_");
188                 BADPREFIX("m_");
189                 BADPREFIX("menu_");
190                 BADPREFIX("net_slist_");
191                 BADPREFIX("r_");
192                 BADPREFIX("sbar_");
193                 BADPREFIX("scr_");
194                 BADPREFIX("snd_");
195                 BADPREFIX("show");
196                 BADPREFIX("sensitivity");
197                 BADPREFIX("userbind");
198                 BADPREFIX("v_");
199                 BADPREFIX("vid_");
200                 BADPREFIX("crosshair");
201                 BADCVAR("mod_q3bsp_lightmapmergepower");
202                 BADCVAR("mod_q3bsp_nolightmaps");
203                 BADCVAR("fov");
204                 BADCVAR("mastervolume");
205                 BADCVAR("volume");
206                 BADCVAR("bgmvolume");
207                 BADCVAR("in_pitch_min");
208                 BADCVAR("in_pitch_max");
209
210                 // private
211                 BADCVAR("developer");
212                 BADCVAR("log_dest_udp");
213                 BADCVAR("net_address");
214                 BADCVAR("net_address_ipv6");
215                 BADCVAR("port");
216                 BADCVAR("savedgamecfg");
217                 BADCVAR("serverconfig");
218                 BADCVAR("sv_autoscreenshot");
219                 BADCVAR("sv_heartbeatperiod");
220                 BADCVAR("sv_vote_master_password");
221                 BADCVAR("sys_colortranslation");
222                 BADCVAR("sys_specialcharactertranslation");
223                 BADCVAR("timeformat");
224                 BADCVAR("timestamps");
225                 BADCVAR("g_require_stats");
226                 BADPREFIX("developer_");
227                 BADPREFIX("g_ban_");
228                 BADPREFIX("g_banned_list");
229                 BADPREFIX("g_require_stats_");
230                 BADPREFIX("g_chat_flood_");
231                 BADPREFIX("g_ghost_items");
232                 BADPREFIX("g_playerstats_");
233                 BADPREFIX("g_voice_flood_");
234                 BADPREFIX("log_file");
235                 BADPREFIX("quit_");
236                 BADPREFIX("rcon_");
237                 BADPREFIX("sv_allowdownloads");
238                 BADPREFIX("sv_autodemo");
239                 BADPREFIX("sv_curl_");
240                 BADPREFIX("sv_eventlog");
241                 BADPREFIX("sv_logscores_");
242                 BADPREFIX("sv_master");
243                 BADPREFIX("sv_weaponstats_");
244                 BADPREFIX("sv_waypointsprite_");
245                 BADCVAR("rescan_pending");
246
247                 // these can contain player IDs, so better hide
248                 BADPREFIX("g_forced_team_");
249                 BADCVAR("sv_muteban_list");
250                 BADCVAR("sv_voteban_list");
251                 BADCVAR("sv_allow_customplayermodels_idlist");
252                 BADCVAR("sv_allow_customplayermodels_speciallist");
253
254                 // mapinfo
255                 BADCVAR("fraglimit");
256                 BADCVAR("g_arena");
257                 BADCVAR("g_assault");
258                 BADCVAR("g_ca");
259                 BADCVAR("g_ca_teams");
260                 BADCVAR("g_conquest");
261                 BADCVAR("g_ctf");
262                 BADCVAR("g_cts");
263                 BADCVAR("g_dotc");
264                 BADCVAR("g_dm");
265                 BADCVAR("g_domination");
266                 BADCVAR("g_domination_default_teams");
267                 BADCVAR("g_freezetag");
268                 BADCVAR("g_freezetag_teams");
269                 BADCVAR("g_invasion_teams");
270                 BADCVAR("g_invasion_type");
271                 BADCVAR("g_jailbreak");
272                 BADCVAR("g_jailbreak_teams");
273                 BADCVAR("g_keepaway");
274                 BADCVAR("g_keyhunt");
275                 BADCVAR("g_keyhunt_teams");
276                 BADCVAR("g_lms");
277                 BADCVAR("g_nexball");
278                 BADCVAR("g_onslaught");
279                 BADCVAR("g_race");
280                 BADCVAR("g_race_laps_limit");
281                 BADCVAR("g_race_qualifying_timelimit");
282                 BADCVAR("g_race_qualifying_timelimit_override");
283                 BADCVAR("g_runematch");
284                 BADCVAR("g_snafu");
285                 BADCVAR("g_tdm");
286                 BADCVAR("g_tdm_teams");
287                 BADCVAR("g_vip");
288                 BADCVAR("leadlimit");
289                 BADCVAR("nextmap");
290                 BADCVAR("teamplay");
291                 BADCVAR("timelimit");
292                 BADCVAR("g_mapinfo_ignore_warnings");
293
294                 // long
295                 BADCVAR("hostname");
296                 BADCVAR("g_maplist");
297                 BADCVAR("g_maplist_mostrecent");
298                 BADCVAR("sv_motd");
299
300                 v = cvar_string(k);
301                 d = cvar_defstring(k);
302                 if(v == d)
303                         continue;
304
305                 if(adding)
306                 {
307                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
308                         if(strlen(cvar_changes) > 16384)
309                         {
310                                 cvar_changes = "// too many settings have been changed to show them here\n";
311                                 adding = 0;
312                         }
313                 }
314
315                 // now check if the changes are actually gameplay relevant
316
317                 // does nothing gameplay relevant
318                 BADCVAR("captureleadlimit_override");
319                 BADCVAR("condump_stripcolors");
320                 BADCVAR("gameversion");
321                 BADCVAR("g_allow_oldvortexbeam");
322                 BADCVAR("g_balance_kill_delay");
323                 BADCVAR("g_buffs_pickup_anyway");
324                 BADCVAR("g_buffs_randomize");
325                 BADCVAR("g_campcheck_distance");
326                 BADCVAR("g_ca_point_leadlimit");
327                 BADCVAR("g_ca_point_limit");
328                 BADCVAR("g_ctf_captimerecord_always");
329                 BADCVAR("g_ctf_flag_glowtrails");
330                 BADCVAR("g_ctf_flag_pickup_verbosename");
331                 BADCVAR("g_domination_point_leadlimit");
332                 BADCVAR("g_forced_respawn");
333                 BADCVAR("g_freezetag_point_leadlimit");
334                 BADCVAR("g_freezetag_point_limit");
335                 BADCVAR("g_hats");
336                 BADCVAR("g_invasion_point_limit");
337                 BADCVAR("g_jump_grunt");
338                 BADCVAR("g_keyhunt_point_leadlimit");
339                 BADCVAR("g_nexball_goalleadlimit");
340                 BADCVAR("g_new_toys_use_pickupsound");
341                 BADCVAR("g_physics_predictall");
342                 BADCVAR("g_piggyback");
343                 BADCVAR("g_playerclip_collisions");
344                 BADCVAR("g_tdm_point_leadlimit");
345                 BADCVAR("g_tdm_point_limit");
346                 BADCVAR("leadlimit_and_fraglimit");
347                 BADCVAR("leadlimit_override");
348                 BADCVAR("pausable");
349                 BADCVAR("sv_checkforpacketsduringsleep");
350                 BADCVAR("sv_damagetext");
351                 BADCVAR("sv_db_saveasdump");
352                 BADCVAR("sv_intermission_cdtrack");
353                 BADCVAR("sv_minigames");
354                 BADCVAR("sv_namechangetimer");
355                 BADCVAR("sv_precacheplayermodels");
356                 BADCVAR("sv_stepheight");
357                 BADCVAR("sv_timeout");
358                 BADCVAR("sv_weapons_modeloverride");
359                 BADCVAR("w_prop_interval");
360                 BADPREFIX("crypto_");
361                 BADPREFIX("gameversion_");
362                 BADPREFIX("g_chat_");
363                 BADPREFIX("g_ctf_captimerecord_");
364                 BADPREFIX("g_hats_");
365                 BADPREFIX("g_maplist_");
366                 BADPREFIX("g_mod_");
367                 BADPREFIX("g_respawn_");
368                 BADPREFIX("net_");
369                 BADPREFIX("notification_");
370                 BADPREFIX("prvm_");
371                 BADPREFIX("skill_");
372                 BADPREFIX("sv_allow_");
373                 BADPREFIX("sv_cullentities_");
374                 BADPREFIX("sv_maxidle_");
375                 BADPREFIX("sv_minigames_");
376                 BADPREFIX("sv_radio_");
377                 BADPREFIX("sv_timeout_");
378                 BADPREFIX("sv_vote_");
379                 BADPREFIX("timelimit_");
380
381                 // allowed changes to server admins (please sync this to server.cfg)
382                 // vi commands:
383                 //   :/"impure"/,$d
384                 //   :g!,^\/\/[^ /],d
385                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
386                 //   :%!sort
387                 // yes, this does contain some redundant stuff, don't really care
388                 BADCVAR("bot_config_file");
389                 BADCVAR("bot_number");
390                 BADCVAR("bot_prefix");
391                 BADCVAR("bot_suffix");
392                 BADCVAR("capturelimit_override");
393                 BADCVAR("fraglimit_override");
394                 BADCVAR("gametype");
395                 BADCVAR("g_antilag");
396                 BADCVAR("g_balance_teams");
397                 BADCVAR("g_balance_teams_prevent_imbalance");
398                 BADCVAR("g_balance_teams_scorefactor");
399                 BADCVAR("g_ban_sync_trusted_servers");
400                 BADCVAR("g_ban_sync_uri");
401                 BADCVAR("g_buffs");
402                 BADCVAR("g_ca_teams_override");
403                 BADCVAR("g_ctf_ignore_frags");
404                 BADCVAR("g_ctf_leaderboard");
405                 BADCVAR("g_domination_point_limit");
406                 BADCVAR("g_domination_teams_override");
407                 BADCVAR("g_freezetag_teams_override");
408                 BADCVAR("g_friendlyfire");
409                 BADCVAR("g_fullbrightitems");
410                 BADCVAR("g_fullbrightplayers");
411                 BADCVAR("g_keyhunt_point_limit");
412                 BADCVAR("g_keyhunt_teams_override");
413                 BADCVAR("g_lms_lives_override");
414                 BADCVAR("g_maplist");
415                 BADCVAR("g_maxplayers");
416                 BADCVAR("g_mirrordamage");
417                 BADCVAR("g_nexball_goallimit");
418                 BADCVAR("g_norecoil");
419                 BADCVAR("g_physics_clientselect");
420                 BADCVAR("g_pinata");
421                 BADCVAR("g_powerups");
422                 BADCVAR("g_spawnshieldtime");
423                 BADCVAR("g_start_delay");
424                 BADCVAR("g_superspectate");
425                 BADCVAR("g_tdm_teams_override");
426                 BADCVAR("g_warmup");
427                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
428                 BADCVAR("hostname");
429                 BADCVAR("log_file");
430                 BADCVAR("maxplayers");
431                 BADCVAR("minplayers");
432                 BADCVAR("net_address");
433                 BADCVAR("port");
434                 BADCVAR("rcon_password");
435                 BADCVAR("rcon_restricted_commands");
436                 BADCVAR("rcon_restricted_password");
437                 BADCVAR("skill");
438                 BADCVAR("sv_adminnick");
439                 BADCVAR("sv_autoscreenshot");
440                 BADCVAR("sv_autotaunt");
441                 BADCVAR("sv_curl_defaulturl");
442                 BADCVAR("sv_defaultcharacter");
443                 BADCVAR("sv_defaultcharacterskin");
444                 BADCVAR("sv_defaultplayercolors");
445                 BADCVAR("sv_defaultplayermodel");
446                 BADCVAR("sv_defaultplayerskin");
447                 BADCVAR("sv_maxidle");
448                 BADCVAR("sv_maxrate");
449                 BADCVAR("sv_motd");
450                 BADCVAR("sv_public");
451                 BADCVAR("sv_ready_restart");
452                 BADCVAR("sv_status_privacy");
453                 BADCVAR("sv_taunt");
454                 BADCVAR("sv_vote_call");
455                 BADCVAR("sv_vote_commands");
456                 BADCVAR("sv_vote_majority_factor");
457                 BADCVAR("sv_vote_master");
458                 BADCVAR("sv_vote_master_commands");
459                 BADCVAR("sv_vote_master_password");
460                 BADCVAR("sv_vote_simple_majority_factor");
461                 BADCVAR("teamplay_mode");
462                 BADCVAR("timelimit_override");
463                 BADPREFIX("g_warmup_");
464                 BADPREFIX("sv_info_");
465                 BADPREFIX("sv_ready_restart_");
466
467                 // mutators that announce themselves properly to the server browser
468                 BADCVAR("g_instagib");
469                 BADCVAR("g_new_toys");
470                 BADCVAR("g_nix");
471                 BADCVAR("g_grappling_hook");
472                 BADCVAR("g_jetpack");
473
474 #undef BADPRESUFFIX
475 #undef BADPREFIX
476 #undef BADCVAR
477
478                 if(pureadding)
479                 {
480                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
481                         if(strlen(cvar_purechanges) > 16384)
482                         {
483                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
484                                 pureadding = 0;
485                         }
486                 }
487                 ++cvar_purechanges_count;
488                 // WARNING: this variable is used for the server list
489                 // NEVER dare to skip this code!
490                 // Hacks to intentionally appearing as "pure server" even though you DO have
491                 // modified settings may be punished by removal from the server list.
492                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
493                 // though.
494         }
495         buf_del(h);
496         if(cvar_changes == "")
497                 cvar_changes = "// this server runs at default server settings\n";
498         else
499                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
500         cvar_changes = strzone(cvar_changes);
501         if(cvar_purechanges == "")
502                 cvar_purechanges = "// this server runs at default gameplay settings\n";
503         else
504                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
505         cvar_purechanges = strzone(cvar_purechanges);
506 }
507
508 entity randomseed;
509 bool RandomSeed_Send(entity this, entity to, int sf)
510 {
511         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
512         WriteShort(MSG_ENTITY, this.cnt);
513         return true;
514 }
515 void RandomSeed_Think(entity this)
516 {
517         this.cnt = bound(0, floor(random() * 65536), 65535);
518         this.nextthink = time + 5;
519
520         this.SendFlags |= 1;
521 }
522 void RandomSeed_Spawn()
523 {
524         randomseed = new_pure(randomseed);
525         setthink(randomseed, RandomSeed_Think);
526         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
527
528         getthink(randomseed)(randomseed); // sets random seed and nextthink
529 }
530
531 spawnfunc(__init_dedicated_server)
532 {
533         // handler for _init/_init map (only for dedicated server initialization)
534
535         world_initialized = -1; // don't complain
536         cvar = cvar_normal;
537         cvar_string = cvar_string_normal;
538         cvar_set = cvar_set_normal;
539
540         delete_fn = remove_unsafely;
541
542         entity e = spawn();
543         setthink(e, GotoFirstMap);
544         e.nextthink = time; // this is usually 1 at this point
545
546         e = new(info_player_deathmatch);  // safeguard against player joining
547
548     // assign reflectively to avoid "assignment to world" warning
549     for (int i = 0, n = numentityfields(); i < n; ++i) {
550         string k = entityfieldname(i);
551         if (k == "classname") {
552             // safeguard against various stuff ;)
553             putentityfieldstring(i, this, "worldspawn");
554             break;
555         }
556     }
557
558         // needs to be done so early because of the constants they create
559         static_init();
560         static_init_late();
561         static_init_precache();
562
563         IL_PUSH(g_spawnpoints, e); // just incase
564
565         MapInfo_Enumerate();
566         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
567 }
568
569 void __init_dedicated_server_shutdown() {
570         MapInfo_Shutdown();
571 }
572
573 STATIC_INIT_EARLY(maxclients)
574 {
575         maxclients = 0;
576         for (entity head = nextent(NULL); head; head = nextent(head)) {
577                 ++maxclients;
578         }
579 }
580
581 float world_already_spawned;
582 spawnfunc(worldspawn)
583 {
584         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
585
586     bool wantrestart = false;
587         {
588                 if (!server_is_dedicated)
589                 {
590                         // force unloading of server pk3 files when starting a listen server
591                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
592                         // restore csqc_progname too
593                         string expect = "csprogs.dat";
594                         wantrestart = cvar_string_normal("csqc_progname") != expect;
595                         cvar_set_normal("csqc_progname", expect);
596                 }
597                 else
598                 {
599                         // Try to use versioned csprogs from pk3
600                         // Only ever use versioned csprogs.dat files on dedicated servers;
601                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
602                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
603                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
604                         string select = "csprogs.dat";
605                         if (fexists(pk3csprogs)) select = pk3csprogs;
606                         if (cvar_string_normal("csqc_progname") != select)
607                         {
608                                 cvar_set_normal("csqc_progname", select);
609                                 wantrestart = true;
610                         }
611                         // Check for updates on startup
612                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
613                         int sentinel = fopen("progs.txt", FILE_READ);
614                         if (sentinel >= 0)
615                         {
616                                 string switchversion = fgets(sentinel);
617                                 fclose(sentinel);
618                                 if (switchversion != "" && switchversion != WATERMARK)
619                                 {
620                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
621                                         // if it doesn't exist, assume either:
622                                         //   a) the current program was overwritten
623                                         //   b) this is a client only update
624                                         string newprogs = sprintf("progs-%s.dat", switchversion);
625                                         if (fexists(newprogs))
626                                         {
627                                                 cvar_set_normal("sv_progs", newprogs);
628                                                 wantrestart = true;
629                                         }
630                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
631                                         if (fexists(newcsprogs))
632                                         {
633                                                 cvar_set_normal("csqc_progname", newcsprogs);
634                                                 wantrestart = true;
635                                         }
636                                 }
637                         }
638                 }
639                 if (wantrestart)
640                 {
641                         LOG_INFOF("Restart requested");
642                         changelevel(mapname);
643                         // let initialization continue, shutdown depends on it
644                 }
645         }
646
647         cvar = cvar_normal;
648         cvar_string = cvar_string_normal;
649         cvar_set = cvar_set_normal;
650
651         if(world_already_spawned)
652                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
653         world_already_spawned = true;
654
655         delete_fn = remove_safely; // during spawning, watch what you remove!
656
657         cvar_changes_init(); // do this very early now so it REALLY matches the server config
658
659         // needs to be done so early because of the constants they create
660         static_init();
661
662         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
663
664         TemporaryDB = db_create();
665
666         // 0 normal
667         lightstyle(0, "m");
668
669         // 1 FLICKER (first variety)
670         lightstyle(1, "mmnmmommommnonmmonqnmmo");
671
672         // 2 SLOW STRONG PULSE
673         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
674
675         // 3 CANDLE (first variety)
676         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
677
678         // 4 FAST STROBE
679         lightstyle(4, "mamamamamama");
680
681         // 5 GENTLE PULSE 1
682         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
683
684         // 6 FLICKER (second variety)
685         lightstyle(6, "nmonqnmomnmomomno");
686
687         // 7 CANDLE (second variety)
688         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
689
690         // 8 CANDLE (third variety)
691         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
692
693         // 9 SLOW STROBE (fourth variety)
694         lightstyle(9, "aaaaaaaazzzzzzzz");
695
696         // 10 FLUORESCENT FLICKER
697         lightstyle(10, "mmamammmmammamamaaamammma");
698
699         // 11 SLOW PULSE NOT FADE TO BLACK
700         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
701
702         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
703
704         // 63 testing
705         lightstyle(63, "a");
706
707         if(autocvar_g_campaign)
708                 CampaignPreInit();
709
710         Map_MarkAsRecent(mapname);
711
712         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
713
714         InitGameplayMode();
715         static_init_late();
716         static_init_precache();
717         readlevelcvars();
718         GrappleHookInit();
719
720     GameRules_limit_fallbacks();
721
722         if(warmup_limit == 0)
723                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
724
725         player_count = 0;
726         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
727         if(bot_waypoints_for_items == 1)
728                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
729                         bot_waypoints_for_items = 0;
730
731         precache();
732
733         WaypointSprite_Init();
734
735         GameLogInit(); // prepare everything
736         // NOTE for matchid:
737         // changing the logic generating it is okay. But:
738         // it HAS to stay <= 64 chars
739         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
740         if(autocvar_sv_eventlog)
741         {
742                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
743                 matchid = strzone(s);
744
745                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
746                 s = ":gameinfo:mutators:LIST";
747
748                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
749                 s = M_ARGV(0, string);
750
751                 // initialiation stuff, not good in the mutator system
752                 if(!autocvar_g_use_ammunition)
753                         s = strcat(s, ":no_use_ammunition");
754
755                 // initialiation stuff, not good in the mutator system
756                 if(autocvar_g_pickup_items == 0)
757                         s = strcat(s, ":no_pickup_items");
758                 if(autocvar_g_pickup_items > 0)
759                         s = strcat(s, ":pickup_items");
760
761                 // initialiation stuff, not good in the mutator system
762                 if(autocvar_g_weaponarena != "0")
763                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
764
765                 // TODO to mutator system
766                 if(autocvar_g_norecoil)
767                         s = strcat(s, ":norecoil");
768
769                 // TODO to mutator system
770                 if(autocvar_g_powerups == 0)
771                         s = strcat(s, ":no_powerups");
772                 if(autocvar_g_powerups > 0)
773                         s = strcat(s, ":powerups");
774
775                 GameLogEcho(s);
776                 GameLogEcho(":gameinfo:end");
777         }
778         else
779                 matchid = strzone(ftos(random()));
780
781         cvar_set("nextmap", "");
782
783         SetDefaultAlpha();
784
785         if(autocvar_g_campaign)
786                 CampaignPostInit();
787
788         Ban_LoadBans();
789
790         MapInfo_Enumerate();
791         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
792
793         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
794         {
795                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
796                 if(fd != -1)
797                 {
798                         string s;
799                         while((s = fgets(fd)))
800                         {
801                                 int l = tokenize_console(s);
802                                 if(l < 2)
803                                         continue;
804                                 if(argv(0) == "cd")
805                                 {
806                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
807                                         LOG_INFO("  cdtrack ", argv(2));
808                                 }
809                                 else if(argv(0) == "fog")
810                                 {
811                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
812                                         LOG_INFO("  \"fog\" \"", s, "\"");
813                                 }
814                                 else if(argv(0) == "set")
815                                 {
816                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
817                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
818                                 }
819                                 else if(argv(0) != "//")
820                                 {
821                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
822                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
823                                 }
824                         }
825                         fclose(fd);
826                 }
827         }
828
829         WeaponStats_Init();
830
831         Nagger_Init();
832
833         next_pingtime = time + 5;
834
835         // set up information replies for clients and server to use
836         maplist_reply = strzone(getmaplist());
837         lsmaps_reply = strzone(getlsmaps());
838         monsterlist_reply = strzone(getmonsterlist());
839         for(int i = 0; i < 10; ++i)
840         {
841                 string s = getrecords(i);
842                 if (s)
843                         records_reply[i] = strzone(s);
844         }
845         ladder_reply = strzone(getladder());
846         rankings_reply = strzone(getrankings());
847
848         // begin other init
849         ClientInit_Spawn();
850         RandomSeed_Spawn();
851         PingPLReport_Spawn();
852
853         CheatInit();
854
855         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
856
857         // fill sv_curl_serverpackages from .serverpackage files
858         if (autocvar_sv_curl_serverpackages_auto)
859         {
860                 string s = "csprogs-" WATERMARK ".txt";
861                 // remove automatically managed files from the list to prevent duplicates
862                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
863                 {
864                         string pkg = argv(i);
865                         if (startsWith(pkg, "csprogs-")) continue;
866                         if (endsWith(pkg, "-serverpackage.txt")) continue;
867                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
868                         s = cons(s, pkg);
869                 }
870                 // add automatically managed files to the list
871                 #define X(match) MACRO_BEGIN { \
872                         int fd = search_begin(match, true, false); \
873                         if (fd >= 0) \
874                         { \
875                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
876                                 { \
877                                         s = cons(s, search_getfilename(fd, i)); \
878                                 } \
879                                 search_end(fd); \
880                         } \
881                 } MACRO_END
882                 X("*-serverpackage.txt");
883                 X("*.serverpackage");
884                 #undef X
885                 cvar_set("sv_curl_serverpackages", s);
886         }
887
888         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
889         modname = "Xonotic";
890         // physics/balance/config changes that count as mod
891         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
892                 modname = cvar_string("g_mod_physics");
893         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
894                 modname = cvar_string("g_mod_balance");
895         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
896                 modname = cvar_string("g_mod_config");
897         // extra mutators that deserve to count as mod
898         MUTATOR_CALLHOOK(SetModname, modname);
899         modname = M_ARGV(0, string);
900
901         // save it for later
902         modname = strzone(modname);
903
904         WinningConditionHelper(this); // set worldstatus
905
906         world_initialized = 1;
907         __spawnfunc_spawn_all();
908 }
909
910 spawnfunc(light)
911 {
912         //makestatic (this); // Who the f___ did that?
913         delete(this);
914 }
915
916 string GetGametype()
917 {
918         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
919 }
920
921 string GetMapname()
922 {
923         return mapname;
924 }
925
926 float Map_Count, Map_Current;
927 string Map_Current_Name;
928
929 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
930 float GetMaplistPosition()
931 {
932         float pos, idx;
933         string map;
934
935         map = GetMapname();
936         idx = autocvar_g_maplist_index;
937
938         if(idx >= 0)
939                 if(idx < Map_Count)
940                         if(map == argv(idx))
941                                 return idx;
942
943         for(pos = 0; pos < Map_Count; ++pos)
944                 if(map == argv(pos))
945                         return pos;
946
947         // resume normal maplist rotation if current map is not in g_maplist
948         return idx;
949 }
950
951 bool MapHasRightSize(string map)
952 {
953         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
954         if(autocvar_g_maplist_check_waypoints)
955         {
956                 string checkwp_msg = strcat("checkwp ", map);
957                 if(!fexists(strcat("maps/", map, ".waypoints")))
958                 {
959                         LOG_TRACE(checkwp_msg, ": no waypoints");
960                         return false;
961                 }
962                 LOG_TRACE(checkwp_msg, ": has waypoints");
963         }
964
965         // open map size restriction file
966         string opensize_msg = strcat("opensize ", map);
967         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
968         if(fh >= 0)
969         {
970                 opensize_msg = strcat(opensize_msg, ": ok, ");
971                 int mapmin = stoi(fgets(fh));
972                 int mapmax = stoi(fgets(fh));
973                 fclose(fh);
974                 if(player_count < mapmin)
975                 {
976                         LOG_TRACE(opensize_msg, "not enough");
977                         return false;
978                 }
979                 if(mapmax && player_count > mapmax)
980                 {
981                         LOG_TRACE(opensize_msg, "too many");
982                         return false;
983                 }
984                 LOG_TRACE(opensize_msg, "right size");
985                 return true;
986         }
987         LOG_TRACE(opensize_msg, ": not found");
988         return true;
989 }
990
991 string Map_Filename(float position)
992 {
993         return strcat("maps/", argv(position), ".bsp");
994 }
995
996 void Map_MarkAsRecent(string m)
997 {
998         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
999 }
1000
1001 float Map_IsRecent(string m)
1002 {
1003         return strhasword(autocvar_g_maplist_mostrecent, m);
1004 }
1005
1006 float Map_Check(float position, float pass)
1007 {
1008         string filename;
1009         string map_next;
1010         map_next = argv(position);
1011         if(pass <= 1)
1012         {
1013                 if(Map_IsRecent(map_next))
1014                         return 0;
1015         }
1016         filename = Map_Filename(position);
1017         if(MapInfo_CheckMap(map_next))
1018         {
1019                 if(pass == 2)
1020                         return 1;
1021                 if(MapHasRightSize(map_next))
1022                         return 1;
1023                 return 0;
1024         }
1025         else
1026                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1027
1028         return 0;
1029 }
1030
1031 void Map_Goto_SetStr(string nextmapname)
1032 {
1033         if(getmapname_stored != "")
1034                 strunzone(getmapname_stored);
1035         if(nextmapname == "")
1036                 getmapname_stored = "";
1037         else
1038                 getmapname_stored = strzone(nextmapname);
1039 }
1040
1041 void Map_Goto_SetFloat(float position)
1042 {
1043         cvar_set("g_maplist_index", ftos(position));
1044         Map_Goto_SetStr(argv(position));
1045 }
1046
1047 void Map_Goto(float reinit)
1048 {
1049         MapInfo_LoadMap(getmapname_stored, reinit);
1050 }
1051
1052 // return codes of map selectors:
1053 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1054 //   -2 = permanent failure
1055 float MaplistMethod_Iterate() // usual method
1056 {
1057         float pass, i;
1058
1059         LOG_TRACE("Trying MaplistMethod_Iterate");
1060
1061         for(pass = 1; pass <= 2; ++pass)
1062         {
1063                 for(i = 1; i < Map_Count; ++i)
1064                 {
1065                         float mapindex;
1066                         mapindex = (i + Map_Current) % Map_Count;
1067                         if(Map_Check(mapindex, pass))
1068                                 return mapindex;
1069                 }
1070         }
1071         return -1;
1072 }
1073
1074 float MaplistMethod_Repeat() // fallback method
1075 {
1076         LOG_TRACE("Trying MaplistMethod_Repeat");
1077
1078         if(Map_Check(Map_Current, 2))
1079                 return Map_Current;
1080         return -2;
1081 }
1082
1083 float MaplistMethod_Random() // random map selection
1084 {
1085         float i, imax;
1086
1087         LOG_TRACE("Trying MaplistMethod_Random");
1088
1089         imax = 42;
1090
1091         for(i = 0; i <= imax; ++i)
1092         {
1093                 float mapindex;
1094                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1095                 if(Map_Check(mapindex, 1))
1096                         return mapindex;
1097         }
1098         return -1;
1099 }
1100
1101 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1102 // the exponent sets a bias on the map selection:
1103 // the higher the exponent, the less likely "shortly repeated" same maps are
1104 {
1105         float i, j, imax, insertpos;
1106
1107         LOG_TRACE("Trying MaplistMethod_Shuffle");
1108
1109         imax = 42;
1110
1111         for(i = 0; i <= imax; ++i)
1112         {
1113                 string newlist;
1114
1115                 // now reinsert this at another position
1116                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1117                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1118                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1119                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1120
1121                 // insert the current map there
1122                 newlist = "";
1123                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1124                         newlist = strcat(newlist, " ", argv(j));
1125                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1126                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1127                         newlist = strcat(newlist, " ", argv(j));
1128                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1129                 cvar_set("g_maplist", newlist);
1130                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1131
1132                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1133                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1134                 if(Map_Check(Map_Current, 1))
1135                         return Map_Current;
1136         }
1137         return -1;
1138 }
1139
1140 void Maplist_Init()
1141 {
1142         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1143         float i;
1144         for (i = 0; i < Map_Count; ++i)
1145                 if (Map_Check(i, 2))
1146                         break;
1147         if (i == Map_Count)
1148         {
1149                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1150                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1151                 if(autocvar_g_maplist_shuffle)
1152                         ShuffleMaplist();
1153                 localcmd("\nmenu_cmd sync\n");
1154                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1155         }
1156         if(Map_Count == 0)
1157                 error("empty maplist, cannot select a new map");
1158         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1159
1160         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1161         // this may or may not be correct, but who cares, in the worst case a map
1162         // isn't chosen in the first pass that should have been
1163 }
1164
1165 string GetNextMap()
1166 {
1167         float nextMap;
1168
1169         Maplist_Init();
1170         nextMap = -1;
1171
1172         if(nextMap == -1)
1173                 if(autocvar_g_maplist_shuffle > 0)
1174                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1175
1176         if(nextMap == -1)
1177                 if(autocvar_g_maplist_selectrandom)
1178                         nextMap = MaplistMethod_Random();
1179
1180         if(nextMap == -1)
1181                 nextMap = MaplistMethod_Iterate();
1182
1183         if(nextMap == -1)
1184                 nextMap = MaplistMethod_Repeat();
1185
1186         if(nextMap >= 0)
1187         {
1188                 Map_Goto_SetFloat(nextMap);
1189                 return getmapname_stored;
1190         }
1191
1192         return "";
1193 }
1194
1195 float DoNextMapOverride(float reinit)
1196 {
1197         if(autocvar_g_campaign)
1198         {
1199                 CampaignPostIntermission();
1200                 alreadychangedlevel = true;
1201                 return true;
1202         }
1203         if(autocvar_quit_when_empty)
1204         {
1205                 if(player_count <= currentbots)
1206                 {
1207                         localcmd("quit\n");
1208                         alreadychangedlevel = true;
1209                         return true;
1210                 }
1211         }
1212         if(autocvar_quit_and_redirect != "")
1213         {
1214                 redirection_target = strzone(autocvar_quit_and_redirect);
1215                 alreadychangedlevel = true;
1216                 return true;
1217         }
1218         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1219         {
1220                 localcmd("restart\n");
1221                 alreadychangedlevel = true;
1222                 return true;
1223         }
1224         if(autocvar_nextmap != "")
1225         {
1226                 string m;
1227                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1228                 cvar_set("nextmap",m);
1229
1230                 if(!m || gametypevote)
1231                         return false;
1232                 if(autocvar_sv_vote_gametype)
1233                 {
1234                         Map_Goto_SetStr(m);
1235                         return false;
1236                 }
1237
1238                 if(MapInfo_CheckMap(m))
1239                 {
1240                         Map_Goto_SetStr(m);
1241                         Map_Goto(reinit);
1242                         alreadychangedlevel = true;
1243                         return true;
1244                 }
1245         }
1246         if(!reinit && autocvar_lastlevel)
1247         {
1248                 cvar_settemp_restore();
1249                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1250                 alreadychangedlevel = true;
1251                 return true;
1252         }
1253         return false;
1254 }
1255
1256 void GotoNextMap(float reinit)
1257 {
1258         //string nextmap;
1259         //float n, nummaps;
1260         //string s;
1261         if (alreadychangedlevel)
1262                 return;
1263         alreadychangedlevel = true;
1264
1265         string nextMap;
1266
1267         nextMap = GetNextMap();
1268         if(nextMap == "")
1269                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1270         Map_Goto(reinit);
1271 }
1272
1273
1274 /*
1275 ============
1276 IntermissionThink
1277
1278 When the player presses attack or jump, change to the next level
1279 ============
1280 */
1281 .float autoscreenshot;
1282 void IntermissionThink(entity this)
1283 {
1284         FixIntermissionClient(this);
1285
1286         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1287         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1288
1289         if( (server_screenshot || client_screenshot)
1290                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1291         {
1292                 this.autoscreenshot = -1;
1293                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1294                 return;
1295         }
1296
1297         if (time < intermission_exittime)
1298                 return;
1299
1300         if(!mapvote_initialized)
1301                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1302                         return;
1303
1304         MapVote_Start();
1305 }
1306
1307 /*
1308 ============
1309 FindIntermission
1310
1311 Returns the entity to view from
1312 ============
1313 */
1314 /*
1315 entity FindIntermission()
1316 {
1317         local   entity spot;
1318         local   float cyc;
1319
1320 // look for info_intermission first
1321         spot = find(NULL, classname, "info_intermission");
1322         if (spot)
1323         {       // pick a random one
1324                 cyc = random() * 4;
1325                 while (cyc > 1)
1326                 {
1327                         spot = find(spot, classname, "info_intermission");
1328                         if (!spot)
1329                                 spot = find(spot, classname, "info_intermission");
1330                         cyc = cyc - 1;
1331                 }
1332                 return spot;
1333         }
1334
1335 // then look for the start position
1336         spot = find(NULL, classname, "info_player_start");
1337         if (spot)
1338                 return spot;
1339
1340 // testinfo_player_start is only found in regioned levels
1341         spot = find(NULL, classname, "testplayerstart");
1342         if (spot)
1343                 return spot;
1344
1345 // then look for the start position
1346         spot = find(NULL, classname, "info_player_deathmatch");
1347         if (spot)
1348                 return spot;
1349
1350         //objerror ("FindIntermission: no spot");
1351         return NULL;
1352 }
1353 */
1354
1355 /*
1356 ===============================================================================
1357
1358 RULES
1359
1360 ===============================================================================
1361 */
1362
1363 void DumpStats(float final)
1364 {
1365         float file;
1366         string s;
1367         float to_console;
1368         float to_eventlog;
1369         float to_file;
1370         float i;
1371
1372         to_console = autocvar_sv_logscores_console;
1373         to_eventlog = autocvar_sv_eventlog;
1374         to_file = autocvar_sv_logscores_file;
1375
1376         if(!final)
1377         {
1378                 to_console = true; // always print printstats replies
1379                 to_eventlog = false; // but never print them to the event log
1380         }
1381
1382         if(to_eventlog)
1383                 if(autocvar_sv_eventlog_console)
1384                         to_console = false; // otherwise we get the output twice
1385
1386         if(final)
1387                 s = ":scores:";
1388         else
1389                 s = ":status:";
1390         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1391
1392         if(to_console)
1393                 LOG_INFO(s);
1394         if(to_eventlog)
1395                 GameLogEcho(s);
1396
1397         file = -1;
1398         if(to_file)
1399         {
1400                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1401                 if(file == -1)
1402                         to_file = false;
1403                 else
1404                         fputs(file, strcat(s, "\n"));
1405         }
1406
1407         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1408         if(to_console)
1409                 LOG_INFO(s);
1410         if(to_eventlog)
1411                 GameLogEcho(s);
1412         if(to_file)
1413                 fputs(file, strcat(s, "\n"));
1414
1415         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1416                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1417                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1418                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1419                         s = strcat(s, ftos(it.team), ":");
1420                 else
1421                         s = strcat(s, "spectator:");
1422
1423                 if(to_console)
1424                         LOG_INFO(s, playername(it, false));
1425                 if(to_eventlog)
1426                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1427                 if(to_file)
1428                         fputs(file, strcat(s, playername(it, false), "\n"));
1429         });
1430
1431         if(teamplay)
1432         {
1433                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1434                 if(to_console)
1435                         LOG_INFO(s);
1436                 if(to_eventlog)
1437                         GameLogEcho(s);
1438                 if(to_file)
1439                         fputs(file, strcat(s, "\n"));
1440
1441                 for(i = 1; i < 16; ++i)
1442                 {
1443                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1444                         s = strcat(s, ":", ftos(i));
1445                         if(to_console)
1446                                 LOG_INFO(s);
1447                         if(to_eventlog)
1448                                 GameLogEcho(s);
1449                         if(to_file)
1450                                 fputs(file, strcat(s, "\n"));
1451                 }
1452         }
1453
1454         if(to_console)
1455                 LOG_INFO(":end");
1456         if(to_eventlog)
1457                 GameLogEcho(":end");
1458         if(to_file)
1459         {
1460                 fputs(file, ":end\n");
1461                 fclose(file);
1462         }
1463 }
1464
1465 void FixIntermissionClient(entity e)
1466 {
1467         if(!e.autoscreenshot) // initial call
1468         {
1469                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1470                 SetResourceAmountExplicit(e, RESOURCE_HEALTH, -2342);
1471                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1472                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1473                 {
1474                     .entity weaponentity = weaponentities[slot];
1475                         if(e.(weaponentity))
1476                         {
1477                                 e.(weaponentity).effects = EF_NODRAW;
1478                                 if (e.(weaponentity).weaponchild)
1479                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1480                         }
1481                 }
1482                 if(IS_REAL_CLIENT(e))
1483                 {
1484                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1485                         RandomSelection_Init();
1486                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1487                                 RandomSelection_AddString(it, 1, 1);
1488                         });
1489                         if (RandomSelection_chosen_string != "")
1490                         {
1491                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1492                         }
1493                         msg_entity = e;
1494                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1495                 }
1496         }
1497 }
1498
1499 /*
1500 go to the next level for deathmatch
1501 only called if a time or frag limit has expired
1502 */
1503 void NextLevel()
1504 {
1505         game_stopped = true;
1506         intermission_running = 1; // game over
1507
1508         // enforce a wait time before allowing changelevel
1509         if(player_count > 0)
1510                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1511         else
1512                 intermission_exittime = -1;
1513
1514         /*
1515         WriteByte (MSG_ALL, SVC_CDTRACK);
1516         WriteByte (MSG_ALL, 3);
1517         WriteByte (MSG_ALL, 3);
1518         // done in FixIntermission
1519         */
1520
1521         //pos = FindIntermission ();
1522
1523         VoteReset();
1524
1525         DumpStats(true);
1526
1527         // send statistics
1528         PlayerStats_GameReport(true);
1529         WeaponStats_Shutdown();
1530
1531         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1532
1533         if(autocvar_sv_eventlog)
1534                 GameLogEcho(":gameover");
1535
1536         GameLogClose();
1537
1538         FOREACH_CLIENT(IS_PLAYER(it), {
1539                 FixIntermissionClient(it);
1540                 if(it.winning)
1541                         bprint(playername(it, false), " ^7wins.\n");
1542         });
1543
1544         target_music_kill();
1545
1546         if(autocvar_g_campaign)
1547                 CampaignPreIntermission();
1548
1549         MUTATOR_CALLHOOK(MatchEnd);
1550
1551         localcmd("\nsv_hook_gameend\n");
1552 }
1553
1554
1555 float InitiateSuddenDeath()
1556 {
1557         // Check first whether normal overtimes could be added before initiating suddendeath mode
1558         // - for this timelimit_overtime needs to be >0 of course
1559         // - also check the winning condition calculated in the previous frame and only add normal overtime
1560         //   again, if at the point at which timelimit would be extended again, still no winner was found
1561         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1562         {
1563                 return 1; // need to call InitiateOvertime later
1564         }
1565         else
1566         {
1567                 if(!checkrules_suddendeathend)
1568                 {
1569                         if(autocvar_g_campaign)
1570                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1571                         else
1572                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1573                         if(g_race && !g_race_qualifying)
1574                                 race_StartCompleting();
1575                 }
1576                 return 0;
1577         }
1578 }
1579
1580 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1581 {
1582         ++checkrules_overtimesadded;
1583         //add one more overtime by simply extending the timelimit
1584         float tl;
1585         tl = autocvar_timelimit;
1586         tl += autocvar_timelimit_overtime;
1587         cvar_set("timelimit", ftos(tl));
1588
1589         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1590 }
1591
1592 float GetWinningCode(float fraglimitreached, float equality)
1593 {
1594         if(autocvar_g_campaign == 1)
1595                 if(fraglimitreached)
1596                         return WINNING_YES;
1597                 else
1598                         return WINNING_NO;
1599
1600         else
1601                 if(equality)
1602                         if(fraglimitreached)
1603                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1604                         else
1605                                 return WINNING_NEVER;
1606                 else
1607                         if(fraglimitreached)
1608                                 return WINNING_YES;
1609                         else
1610                                 return WINNING_NO;
1611 }
1612
1613 // set the .winning flag for exactly those players with a given field value
1614 void SetWinners(.float field, float value)
1615 {
1616         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1617 }
1618
1619 // set the .winning flag for those players with a given field value
1620 void AddWinners(.float field, float value)
1621 {
1622         FOREACH_CLIENT(IS_PLAYER(it), {
1623                 if(it.(field) == value)
1624                         it.winning = 1;
1625         });
1626 }
1627
1628 // clear the .winning flags
1629 void ClearWinners()
1630 {
1631         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1632 }
1633
1634 void ShuffleMaplist()
1635 {
1636         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1637 }
1638
1639 float leaderfrags;
1640 float WinningCondition_Scores(float limit, float leadlimit)
1641 {
1642         float limitreached;
1643
1644         // TODO make everything use THIS winning condition (except LMS)
1645         WinningConditionHelper(NULL);
1646
1647         if(teamplay)
1648         {
1649                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1650                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1651                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1652                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1653         }
1654
1655         ClearWinners();
1656         if(WinningConditionHelper_winner)
1657                 WinningConditionHelper_winner.winning = 1;
1658         if(WinningConditionHelper_winnerteam >= 0)
1659                 SetWinners(team, WinningConditionHelper_winnerteam);
1660
1661         if(WinningConditionHelper_lowerisbetter)
1662         {
1663                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1664                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1665                 limit = -limit;
1666         }
1667
1668         if(WinningConditionHelper_zeroisworst)
1669                 leadlimit = 0; // not supported in this mode
1670
1671         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1672         // these modes always score in increments of 1, thus this makes sense
1673         {
1674                 if(leaderfrags != WinningConditionHelper_topscore)
1675                 {
1676                         leaderfrags = WinningConditionHelper_topscore;
1677
1678                         if (limit)
1679                         if (leaderfrags == limit - 1)
1680                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1681                         else if (leaderfrags == limit - 2)
1682                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1683                         else if (leaderfrags == limit - 3)
1684                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1685                 }
1686         }
1687
1688         limitreached = false;
1689         if(limit)
1690                 if(WinningConditionHelper_topscore >= limit)
1691                         limitreached = true;
1692         if(leadlimit)
1693         {
1694                 float leadlimitreached;
1695                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1696                 if(autocvar_leadlimit_and_fraglimit)
1697                         limitreached = (limitreached && leadlimitreached);
1698                 else
1699                         limitreached = (limitreached || leadlimitreached);
1700         }
1701
1702         if(limit)
1703                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1704
1705         return GetWinningCode(
1706                 WinningConditionHelper_topscore && limitreached,
1707                 WinningConditionHelper_equality
1708         );
1709 }
1710
1711 float WinningCondition_RanOutOfSpawns()
1712 {
1713         if(have_team_spawns <= 0)
1714                 return WINNING_NO;
1715
1716         if(!autocvar_g_spawn_useallspawns)
1717                 return WINNING_NO;
1718
1719         if(!some_spawn_has_been_used)
1720                 return WINNING_NO;
1721
1722         team1_score = team2_score = team3_score = team4_score = 0;
1723
1724         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
1725                 switch(it.team)
1726                 {
1727                         case NUM_TEAM_1: team1_score = 1; break;
1728                         case NUM_TEAM_2: team2_score = 1; break;
1729                         case NUM_TEAM_3: team3_score = 1; break;
1730                         case NUM_TEAM_4: team4_score = 1; break;
1731                 }
1732         });
1733
1734         IL_EACH(g_spawnpoints, true,
1735         {
1736                 switch(it.team)
1737                 {
1738                         case NUM_TEAM_1: team1_score = 1; break;
1739                         case NUM_TEAM_2: team2_score = 1; break;
1740                         case NUM_TEAM_3: team3_score = 1; break;
1741                         case NUM_TEAM_4: team4_score = 1; break;
1742                 }
1743         });
1744
1745         ClearWinners();
1746         if(team1_score + team2_score + team3_score + team4_score == 0)
1747         {
1748                 checkrules_equality = true;
1749                 return WINNING_YES;
1750         }
1751         else if(team1_score + team2_score + team3_score + team4_score == 1)
1752         {
1753                 float t, i;
1754                 if(team1_score)
1755                         t = NUM_TEAM_1;
1756                 else if(team2_score)
1757                         t = NUM_TEAM_2;
1758                 else if(team3_score)
1759                         t = NUM_TEAM_3;
1760                 else // if(team4_score)
1761                         t = NUM_TEAM_4;
1762                 CheckAllowedTeams(NULL);
1763                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1764                 {
1765                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1766                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1767                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1768                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1769                 }
1770
1771                 AddWinners(team, t);
1772                 return WINNING_YES;
1773         }
1774         else
1775                 return WINNING_NO;
1776 }
1777
1778 /*
1779 ============
1780 CheckRules_World
1781
1782 Exit deathmatch games upon conditions
1783 ============
1784 */
1785 void CheckRules_World()
1786 {
1787         float timelimit;
1788         float fraglimit;
1789         float leadlimit;
1790
1791         VoteThink();
1792         MapVote_Think();
1793
1794         SetDefaultAlpha();
1795
1796         if (intermission_running) // someone else quit the game already
1797         {
1798                 if(player_count == 0) // Nobody there? Then let's go to the next map
1799                         MapVote_Start();
1800                         // this will actually check the player count in the next frame
1801                         // again, but this shouldn't hurt
1802                 return;
1803         }
1804
1805         timelimit = autocvar_timelimit * 60;
1806         fraglimit = autocvar_fraglimit;
1807         leadlimit = autocvar_leadlimit;
1808
1809         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1810         {
1811                 if(timelimit > 0)
1812                         timelimit = 0; // timelimit is not made for warmup
1813                 if(fraglimit > 0)
1814                         fraglimit = 0; // no fraglimit for now
1815                 leadlimit = 0; // no leadlimit for now
1816         }
1817
1818         if(timelimit > 0)
1819         {
1820                 timelimit += game_starttime;
1821         }
1822         else if (timelimit < 0)
1823         {
1824                 // endmatch
1825                 NextLevel();
1826                 return;
1827         }
1828
1829         float wantovertime;
1830         wantovertime = 0;
1831
1832         if(timelimit > game_starttime)
1833                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1834         else
1835                 game_completion_ratio = 0;
1836
1837         if(checkrules_suddendeathend)
1838         {
1839                 if(!checkrules_suddendeathwarning)
1840                 {
1841                         checkrules_suddendeathwarning = true;
1842                         if(g_race && !g_race_qualifying)
1843                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1844                         else
1845                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1846                 }
1847         }
1848         else
1849         {
1850                 if (timelimit && time >= timelimit)
1851                 {
1852                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1853                         {
1854                                 float totalplayers;
1855                                 float playerswithlaps;
1856                                 float readyplayers;
1857                                 totalplayers = playerswithlaps = readyplayers = 0;
1858                                 FOREACH_CLIENT(IS_PLAYER(it), {
1859                                         ++totalplayers;
1860                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1861                                                 ++playerswithlaps;
1862                                         if(it.ready)
1863                                                 ++readyplayers;
1864                                 });
1865
1866                                 // at least 2 of the players have completed a lap: start the RACE
1867                                 // otherwise, the players should end the qualifying on their own
1868                                 if(readyplayers || playerswithlaps >= 2)
1869                                 {
1870                                         checkrules_suddendeathend = 0;
1871                                         ReadyRestart(); // go to race
1872                                         return;
1873                                 }
1874                                 else
1875                                         wantovertime |= InitiateSuddenDeath();
1876                         }
1877                         else
1878                                 wantovertime |= InitiateSuddenDeath();
1879                 }
1880         }
1881
1882         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1883         {
1884                 NextLevel();
1885                 return;
1886         }
1887
1888         int checkrules_status = WinningCondition_RanOutOfSpawns();
1889         if(checkrules_status == WINNING_YES)
1890                 bprint("Hey! Someone ran out of spawns!\n");
1891         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1892                 checkrules_status = M_ARGV(0, float);
1893         else
1894                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1895
1896         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1897         {
1898                 checkrules_status = WINNING_NEVER;
1899                 checkrules_overtimesadded = -1;
1900                 wantovertime |= InitiateSuddenDeath();
1901         }
1902
1903         if(checkrules_status == WINNING_NEVER)
1904                 // equality cases! Nobody wins if the overtime ends in a draw.
1905                 ClearWinners();
1906
1907         if(wantovertime)
1908         {
1909                 if(checkrules_status == WINNING_NEVER)
1910                         InitiateOvertime();
1911                 else
1912                         checkrules_status = WINNING_YES;
1913         }
1914
1915         if(checkrules_suddendeathend)
1916                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1917                         checkrules_status = WINNING_YES;
1918
1919         if(checkrules_status == WINNING_YES)
1920         {
1921                 //print("WINNING\n");
1922                 NextLevel();
1923         }
1924 }
1925
1926 string GotoMap(string m)
1927 {
1928         m = GameTypeVote_MapInfo_FixName(m);
1929         if (!m)
1930                 return "The map you suggested is not available on this server.";
1931         if (!autocvar_sv_vote_gametype)
1932         if(!MapInfo_CheckMap(m))
1933                 return "The map you suggested does not support the current game mode.";
1934         cvar_set("nextmap", m);
1935         cvar_set("timelimit", "-1");
1936         if(mapvote_initialized || alreadychangedlevel)
1937         {
1938                 if(DoNextMapOverride(0))
1939                         return "Map switch initiated.";
1940                 else
1941                         return "Hm... no. For some reason I like THIS map more.";
1942         }
1943         else
1944                 return "Map switch will happen after scoreboard.";
1945 }
1946
1947 bool autocvar_sv_gameplayfix_multiplethinksperframe;
1948 void RunThink(entity this)
1949 {
1950         // don't let things stay in the past.
1951         // it is possible to start that way by a trigger with a local time.
1952         if(this.nextthink <= 0 || this.nextthink > time + frametime)
1953                 return;
1954
1955         float oldtime = time; // do we need to save this?
1956
1957         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
1958         {
1959                 time = max(oldtime, this.nextthink);
1960                 this.nextthink = 0;
1961
1962                 if(getthink(this))
1963                         getthink(this)(this);
1964                 // mods often set nextthink to time to cause a think every frame,
1965                 // we don't want to loop in that case, so exit if the new nextthink is
1966                 // <= the time the qc was told, also exit if it is past the end of the
1967                 // frame
1968                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
1969                         break;
1970         }
1971
1972         time = oldtime;
1973 }
1974
1975 bool autocvar_sv_freezenonclients;
1976 bool autocvar_sv_gameplayfix_delayprojectiles;
1977 void Physics_Frame()
1978 {
1979         if(autocvar_sv_freezenonclients)
1980                 return;
1981
1982         FOREACH_ENTITY_FLOAT(pure_data, false,
1983         {
1984                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
1985                         continue;
1986
1987                 //set_movetype(it, it.move_movetype);
1988                 // inline the set_movetype function, since this is called a lot
1989                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
1990
1991                 if(it.move_movetype == MOVETYPE_NONE)
1992                         continue;
1993
1994                 if(it.move_qcphysics)
1995                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
1996
1997                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
1998                 {
1999                         // handle thinking here
2000                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2001                                 RunThink(it);
2002                 }
2003         });
2004
2005         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2006                 return;
2007
2008         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2009         {
2010                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2011                         continue;
2012                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2013         });
2014 }
2015
2016 void systems_update();
2017 void EndFrame()
2018 {
2019         anticheat_endframe();
2020
2021         Physics_Frame();
2022
2023         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2024                 entity e = IS_SPEC(it) ? it.enemy : it;
2025                 if (e.typehitsound) {
2026                         STAT(TYPEHIT_TIME, it) = time;
2027                 } else if (e.killsound) {
2028                         STAT(KILL_TIME, it) = time;
2029                 } else if (e.damage_dealt) {
2030                         STAT(HIT_TIME, it) = time;
2031                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2032                 }
2033         });
2034         // add 1 frametime because after this, engine SV_Physics
2035         // increases time by a frametime and then networks the frame
2036         // add another frametime because client shows everything with
2037         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2038         // needed!
2039         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2040         FOREACH_CLIENT(true, {
2041                 it.typehitsound = false;
2042                 it.damage_dealt = 0;
2043                 it.killsound = false;
2044                 antilag_record(it, CS(it), altime);
2045         });
2046         IL_EACH(g_monsters, true,
2047         {
2048                 antilag_record(it, it, altime);
2049         });
2050         IL_EACH(g_projectiles, it.classname == "nade",
2051         {
2052                 antilag_record(it, it, altime);
2053         });
2054         systems_update();
2055         IL_ENDFRAME();
2056 }
2057
2058
2059 /*
2060  * RedirectionThink:
2061  * returns true if redirecting
2062  */
2063 float redirection_timeout;
2064 float redirection_nextthink;
2065 float RedirectionThink()
2066 {
2067         float clients_found;
2068
2069         if(redirection_target == "")
2070                 return false;
2071
2072         if(!redirection_timeout)
2073         {
2074                 cvar_set("sv_public", "-2");
2075                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2076                 if(redirection_target == "self")
2077                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2078                 else
2079                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2080         }
2081
2082         if(time < redirection_nextthink)
2083                 return true;
2084
2085         redirection_nextthink = time + 1;
2086
2087         clients_found = 0;
2088         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2089                 // TODO add timer
2090                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2091                 if(redirection_target == "self")
2092                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2093                 else
2094                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2095                 ++clients_found;
2096         });
2097
2098         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2099
2100         if(time > redirection_timeout || clients_found == 0)
2101                 localcmd("\nwait; wait; wait; quit\n");
2102
2103         return true;
2104 }
2105
2106 void RestoreGame()
2107 {
2108         // Loaded from a save game
2109         // some things then break, so let's work around them...
2110
2111         // Progs DB (capture records)
2112         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2113
2114         // Mapinfo
2115         MapInfo_Shutdown();
2116         MapInfo_Enumerate();
2117         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2118         WeaponStats_Init();
2119
2120         TargetMusic_RestoreGame();
2121 }
2122
2123 void Shutdown()
2124 {
2125         game_stopped = 2;
2126
2127         if(world_initialized > 0)
2128         {
2129                 world_initialized = 0;
2130                 LOG_TRACE("Saving persistent data...");
2131                 Ban_SaveBans();
2132
2133                 // playerstats with unfinished match
2134                 PlayerStats_GameReport(false);
2135
2136                 if(!cheatcount_total)
2137                 {
2138                         if(autocvar_sv_db_saveasdump)
2139                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2140                         else
2141                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2142                 }
2143                 if(autocvar_developer)
2144                 {
2145                         if(autocvar_sv_db_saveasdump)
2146                                 db_dump(TemporaryDB, "server-temp.db");
2147                         else
2148                                 db_save(TemporaryDB, "server-temp.db");
2149                 }
2150                 CheatShutdown(); // must be after cheatcount check
2151                 db_close(ServerProgsDB);
2152                 db_close(TemporaryDB);
2153                 LOG_TRACE("Saving persistent data... done!");
2154                 // tell the bot system the game is ending now
2155                 bot_endgame();
2156
2157                 WeaponStats_Shutdown();
2158                 MapInfo_Shutdown();
2159         }
2160         else if(world_initialized == 0)
2161         {
2162                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2163         }
2164         else
2165         {
2166                 __init_dedicated_server_shutdown();
2167         }
2168 }