qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include <server/gamelog.qh>
  15 #include "ipban.qh"
  16 #include "mapvoting.qh"
  17 #include <server/mutators/_mod.qh>
  18 #include "race.qh"
  19 #include "scores.qh"
  20 #include "scores_rules.qh"
  21 #include "teamplay.qh"
  22 #include "weapons/weaponstats.qh"
  23 #include "../common/constants.qh"
  24 #include <common/net_linked.qh>
  25 #include "../common/deathtypes/all.qh"
  26 #include <common/gamemodes/_mod.qh>
  27 #include "../common/gamemodes/sv_rules.qh"
  28 #include "../common/mapinfo.qh"
  29 #include "../common/monsters/_mod.qh"
  30 #include "../common/monsters/sv_monsters.qh"
  31 #include "../common/vehicles/all.qh"
  32 #include "../common/notifications/all.qh"
  33 #include "../common/physics/player.qh"
  34 #include "../common/playerstats.qh"
  35 #include "../common/stats.qh"
  36 #include "../common/teams.qh"
  37 #include "../common/mapobjects/trigger/secret.qh"
  38 #include "../common/mapobjects/target/music.qh"
  39 #include "../common/util.qh"
  40 #include "../common/items/_mod.qh"
  41 #include <common/weapons/_all.qh>
  42 #include "../common/state.qh"
  43
  44 const float LATENCY_THINKRATE = 10;
  45 .float latency_sum;
  46 .float latency_cnt;
  47 .float latency_time;
  48 entity pingplreport;
  49 void PingPLReport_Think(entity this)
  50 {
  51         float delta;
  52         entity e;
  53
  54         delta = 3 / maxclients;
  55         if(delta < sys_frametime)
  56                 delta = 0;
  57         this.nextthink = time + delta;
  58
  59         e = edict_num(this.cnt + 1);
  60         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  61         {
  62                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  63                 WriteByte(MSG_BROADCAST, this.cnt);
  64                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  65                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  66                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  67
  68                 // record latency times for clients throughout the match so we can report it to playerstats
  69                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  70                 {
  71                         CS(e).latency_sum += CS(e).ping;
  72                         CS(e).latency_cnt += 1;
  73                         CS(e).latency_time = time;
  74                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  75                 }
  76         }
  77         else
  78         {
  79                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  80                 WriteByte(MSG_BROADCAST, this.cnt);
  81                 WriteShort(MSG_BROADCAST, 0);
  82                 WriteByte(MSG_BROADCAST, 0);
  83                 WriteByte(MSG_BROADCAST, 0);
  84         }
  85         this.cnt = (this.cnt + 1) % maxclients;
  86 }
  87 void PingPLReport_Spawn()
  88 {
  89         pingplreport = new_pure(pingplreport);
  90         setthink(pingplreport, PingPLReport_Think);
  91         pingplreport.nextthink = time;
  92 }
  93
  94 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  95 string redirection_target;
  96 float world_initialized;
  97
  98 void SetDefaultAlpha()
  99 {
 100         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 101         {
 102                 default_player_alpha = autocvar_g_player_alpha;
 103                 if(default_player_alpha == 0)
 104                         default_player_alpha = 1;
 105                 default_weapon_alpha = default_player_alpha;
 106         }
 107 }
 108
 109 void GotoFirstMap(entity this)
 110 {
 111         float n;
 112         if(autocvar__sv_init)
 113         {
 114                 // cvar_set("_sv_init", "0");
 115                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 116                 // to this "init" map on a dedicated server will cause no permanent
 117                 // harm
 118                 if(autocvar_g_maplist_shuffle)
 119                         ShuffleMaplist();
 120                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 121                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 122
 123                 MapInfo_Enumerate();
 124                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 125
 126                 if(!DoNextMapOverride(1))
 127                         GotoNextMap(1);
 128
 129                 return;
 130         }
 131
 132         if(time < 5)
 133         {
 134                 this.nextthink = time;
 135         }
 136         else
 137         {
 138                 this.nextthink = time + 1;
 139                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 140         }
 141 }
 142
 143 void cvar_changes_init()
 144 {
 145         float h;
 146         string k, v, d;
 147         float n, i, adding, pureadding;
 148
 149         strfree(cvar_changes);
 150         strfree(cvar_purechanges);
 151         cvar_purechanges_count = 0;
 152
 153         h = buf_create();
 154         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 155         n = buf_getsize(h);
 156
 157         adding = true;
 158         pureadding = true;
 159
 160         for(i = 0; i < n; ++i)
 161         {
 162                 k = bufstr_get(h, i);
 163
 164 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 165 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 166 #define BADCVAR(p) if(k == p) continue
 167
 168                 // general excludes and namespaces for server admin used cvars
 169                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 170
 171                 // internal
 172                 BADPREFIX("csqc_");
 173                 BADPREFIX("cvar_check_");
 174                 BADCVAR("gamecfg");
 175                 BADCVAR("g_configversion");
 176                 BADCVAR("halflifebsp");
 177                 BADCVAR("sv_mapformat_is_quake2");
 178                 BADCVAR("sv_mapformat_is_quake3");
 179                 BADPREFIX("sv_world");
 180
 181                 // client
 182                 BADPREFIX("chase_");
 183                 BADPREFIX("cl_");
 184                 BADPREFIX("con_");
 185                 BADPREFIX("scoreboard_");
 186                 BADPREFIX("g_campaign");
 187                 BADPREFIX("g_waypointsprite_");
 188                 BADPREFIX("gl_");
 189                 BADPREFIX("joy");
 190                 BADPREFIX("hud_");
 191                 BADPREFIX("m_");
 192                 BADPREFIX("menu_");
 193                 BADPREFIX("net_slist_");
 194                 BADPREFIX("r_");
 195                 BADPREFIX("sbar_");
 196                 BADPREFIX("scr_");
 197                 BADPREFIX("snd_");
 198                 BADPREFIX("show");
 199                 BADPREFIX("sensitivity");
 200                 BADPREFIX("userbind");
 201                 BADPREFIX("v_");
 202                 BADPREFIX("vid_");
 203                 BADPREFIX("crosshair");
 204                 BADCVAR("mod_q3bsp_lightmapmergepower");
 205                 BADCVAR("mod_q3bsp_nolightmaps");
 206                 BADCVAR("fov");
 207                 BADCVAR("mastervolume");
 208                 BADCVAR("volume");
 209                 BADCVAR("bgmvolume");
 210                 BADCVAR("in_pitch_min");
 211                 BADCVAR("in_pitch_max");
 212
 213                 // private
 214                 BADCVAR("developer");
 215                 BADCVAR("log_dest_udp");
 216                 BADCVAR("net_address");
 217                 BADCVAR("net_address_ipv6");
 218                 BADCVAR("port");
 219                 BADCVAR("savedgamecfg");
 220                 BADCVAR("serverconfig");
 221                 BADCVAR("sv_autoscreenshot");
 222                 BADCVAR("sv_heartbeatperiod");
 223                 BADCVAR("sv_vote_master_password");
 224                 BADCVAR("sys_colortranslation");
 225                 BADCVAR("sys_specialcharactertranslation");
 226                 BADCVAR("timeformat");
 227                 BADCVAR("timestamps");
 228                 BADCVAR("g_require_stats");
 229                 BADPREFIX("developer_");
 230                 BADPREFIX("g_ban_");
 231                 BADPREFIX("g_banned_list");
 232                 BADPREFIX("g_require_stats_");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_voice_flood_");
 237                 BADPREFIX("log_file");
 238                 BADPREFIX("quit_");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252                 BADCVAR("sv_muteban_list");
 253                 BADCVAR("sv_voteban_list");
 254                 BADCVAR("sv_allow_customplayermodels_idlist");
 255                 BADCVAR("sv_allow_customplayermodels_speciallist");
 256
 257                 // mapinfo
 258                 BADCVAR("fraglimit");
 259                 BADCVAR("g_arena");
 260                 BADCVAR("g_assault");
 261                 BADCVAR("g_ca");
 262                 BADCVAR("g_ca_teams");
 263                 BADCVAR("g_conquest");
 264                 BADCVAR("g_conquest_teams");
 265                 BADCVAR("g_ctf");
 266                 BADCVAR("g_cts");
 267                 BADCVAR("g_dotc");
 268                 BADCVAR("g_dm");
 269                 BADCVAR("g_domination");
 270                 BADCVAR("g_domination_default_teams");
 271                 BADCVAR("g_duel");
 272                 BADCVAR("g_duel_not_dm_maps");
 273                 BADCVAR("g_freezetag");
 274                 BADCVAR("g_freezetag_teams");
 275                 BADCVAR("g_invasion_teams");
 276                 BADCVAR("g_invasion_type");
 277                 BADCVAR("g_jailbreak");
 278                 BADCVAR("g_jailbreak_teams");
 279                 BADCVAR("g_keepaway");
 280                 BADCVAR("g_keyhunt");
 281                 BADCVAR("g_keyhunt_teams");
 282                 BADCVAR("g_lms");
 283                 BADCVAR("g_nexball");
 284                 BADCVAR("g_onslaught");
 285                 BADCVAR("g_race");
 286                 BADCVAR("g_race_laps_limit");
 287                 BADCVAR("g_race_qualifying_timelimit");
 288                 BADCVAR("g_race_qualifying_timelimit_override");
 289                 BADCVAR("g_runematch");
 290                 BADCVAR("g_shootfromeye");
 291                 BADCVAR("g_snafu");
 292                 BADCVAR("g_survival");
 293                 BADCVAR("g_survival_not_dm_maps");
 294                 BADCVAR("g_tdm");
 295                 BADCVAR("g_tdm_on_dm_maps");
 296                 BADCVAR("g_tdm_teams");
 297                 BADCVAR("g_vip");
 298                 BADCVAR("leadlimit");
 299                 BADCVAR("nextmap");
 300                 BADCVAR("teamplay");
 301                 BADCVAR("timelimit");
 302                 BADCVAR("g_mapinfo_settemp_acl");
 303                 BADCVAR("g_mapinfo_ignore_warnings");
 304                 BADCVAR("g_maplist_ignore_sizes");
 305                 BADCVAR("g_maplist_sizes_count_bots");
 306
 307                 // long
 308                 BADCVAR("hostname");
 309                 BADCVAR("g_maplist");
 310                 BADCVAR("g_maplist_mostrecent");
 311                 BADCVAR("sv_motd");
 312
 313                 v = cvar_string(k);
 314                 d = cvar_defstring(k);
 315                 if(v == d)
 316                         continue;
 317
 318                 if(adding)
 319                 {
 320                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 321                         if(strlen(cvar_changes) > 16384)
 322                         {
 323                                 cvar_changes = "// too many settings have been changed to show them here\n";
 324                                 adding = 0;
 325                         }
 326                 }
 327
 328                 // now check if the changes are actually gameplay relevant
 329
 330                 // does nothing gameplay relevant
 331                 BADCVAR("captureleadlimit_override");
 332                 BADCVAR("condump_stripcolors");
 333                 BADCVAR("gameversion");
 334                 BADCVAR("fs_gamedir");
 335                 BADCVAR("g_allow_oldvortexbeam");
 336                 BADCVAR("g_balance_kill_delay");
 337                 BADCVAR("g_buffs_pickup_anyway");
 338                 BADCVAR("g_buffs_randomize");
 339                 BADCVAR("g_buffs_randomize_teamplay");
 340                 BADCVAR("g_campcheck_distance");
 341                 BADCVAR("g_chatsounds");
 342                 BADCVAR("g_ca_point_leadlimit");
 343                 BADCVAR("g_ca_point_limit");
 344                 BADCVAR("g_ctf_captimerecord_always");
 345                 BADCVAR("g_ctf_flag_glowtrails");
 346                 BADCVAR("g_ctf_dynamiclights");
 347                 BADCVAR("g_ctf_flag_pickup_verbosename");
 348                 BADPRESUFFIX("g_ctf_flag_", "_model");
 349                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 350                 BADCVAR("g_domination_point_leadlimit");
 351                 BADCVAR("g_forced_respawn");
 352                 BADCVAR("g_freezetag_point_leadlimit");
 353                 BADCVAR("g_freezetag_point_limit");
 354                 BADCVAR("g_glowtrails");
 355                 BADCVAR("g_hats");
 356                 BADCVAR("g_casings");
 357                 BADCVAR("g_invasion_point_limit");
 358                 BADCVAR("g_jump_grunt");
 359                 BADCVAR("g_keepaway_ballcarrier_effects");
 360                 BADCVAR("g_keepawayball_effects");
 361                 BADCVAR("g_keyhunt_point_leadlimit");
 362                 BADCVAR("g_nexball_goalleadlimit");
 363                 BADCVAR("g_new_toys_autoreplace");
 364                 BADCVAR("g_new_toys_use_pickupsound");
 365                 BADCVAR("g_physics_predictall");
 366                 BADCVAR("g_piggyback");
 367                 BADCVAR("g_playerclip_collisions");
 368                 BADCVAR("g_spawn_alloweffects");
 369                 BADCVAR("g_tdm_point_leadlimit");
 370                 BADCVAR("g_tdm_point_limit");
 371                 BADCVAR("leadlimit_and_fraglimit");
 372                 BADCVAR("leadlimit_override");
 373                 BADCVAR("pausable");
 374                 BADCVAR("sv_announcer");
 375                 BADCVAR("sv_checkforpacketsduringsleep");
 376                 BADCVAR("sv_damagetext");
 377                 BADCVAR("sv_db_saveasdump");
 378                 BADCVAR("sv_intermission_cdtrack");
 379                 BADCVAR("sv_mapchange_delay");
 380                 BADCVAR("sv_minigames");
 381                 BADCVAR("sv_namechangetimer");
 382                 BADCVAR("sv_precacheplayermodels");
 383                 BADCVAR("sv_radio");
 384                 BADCVAR("sv_stepheight");
 385                 BADCVAR("sv_timeout");
 386                 BADCVAR("sv_weapons_modeloverride");
 387                 BADCVAR("w_prop_interval");
 388                 BADPREFIX("chat_");
 389                 BADPREFIX("crypto_");
 390                 BADPREFIX("gameversion_");
 391                 BADPREFIX("g_chat_");
 392                 BADPREFIX("g_ctf_captimerecord_");
 393                 BADPREFIX("g_hats_");
 394                 BADPREFIX("g_maplist_");
 395                 BADPREFIX("g_mod_");
 396                 BADPREFIX("g_respawn_");
 397                 BADPREFIX("net_");
 398                 BADPREFIX("notification_");
 399                 BADPREFIX("prvm_");
 400                 BADPREFIX("skill_");
 401                 BADPREFIX("sv_allow_");
 402                 BADPREFIX("sv_cullentities_");
 403                 BADPREFIX("sv_maxidle_");
 404                 BADPREFIX("sv_minigames_");
 405                 BADPREFIX("sv_radio_");
 406                 BADPREFIX("sv_timeout_");
 407                 BADPREFIX("sv_vote_");
 408                 BADPREFIX("timelimit_");
 409
 410                 // allowed changes to server admins (please sync this to server.cfg)
 411                 // vi commands:
 412                 //   :/"impure"/,$d
 413                 //   :g!,^\/\/[^ /],d
 414                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 415                 //   :%!sort
 416                 // yes, this does contain some redundant stuff, don't really care
 417                 BADPREFIX("bot_ai_");
 418                 BADCVAR("bot_config_file");
 419                 BADCVAR("bot_number");
 420                 BADCVAR("bot_prefix");
 421                 BADCVAR("bot_suffix");
 422                 BADCVAR("capturelimit_override");
 423                 BADCVAR("fraglimit_override");
 424                 BADCVAR("gametype");
 425                 BADCVAR("g_antilag");
 426                 BADCVAR("g_balance_teams");
 427                 BADCVAR("g_balance_teams_prevent_imbalance");
 428                 BADCVAR("g_balance_teams_scorefactor");
 429                 BADCVAR("g_ban_sync_trusted_servers");
 430                 BADCVAR("g_ban_sync_uri");
 431                 BADCVAR("g_buffs");
 432                 BADCVAR("g_ca_teams_override");
 433                 BADCVAR("g_ctf_fullbrightflags");
 434                 BADCVAR("g_ctf_ignore_frags");
 435                 BADCVAR("g_ctf_leaderboard");
 436                 BADCVAR("g_domination_point_limit");
 437                 BADCVAR("g_domination_teams_override");
 438                 BADCVAR("g_freezetag_teams_override");
 439                 BADCVAR("g_friendlyfire");
 440                 BADCVAR("g_fullbrightitems");
 441                 BADCVAR("g_fullbrightplayers");
 442                 BADCVAR("g_keyhunt_point_limit");
 443                 BADCVAR("g_keyhunt_teams_override");
 444                 BADCVAR("g_lms_lives_override");
 445                 BADCVAR("g_maplist");
 446                 BADCVAR("g_maxplayers");
 447                 BADCVAR("g_mirrordamage");
 448                 BADCVAR("g_nexball_goallimit");
 449                 BADCVAR("g_norecoil");
 450                 BADCVAR("g_physics_clientselect");
 451                 BADCVAR("g_pinata");
 452                 BADCVAR("g_powerups");
 453                 BADCVAR("g_player_brightness");
 454                 BADCVAR("g_rocket_flying");
 455                 BADCVAR("g_rocket_flying_disabledelays");
 456                 BADCVAR("g_spawnshieldtime");
 457                 BADCVAR("g_start_delay");
 458                 BADCVAR("g_superspectate");
 459                 BADCVAR("g_tdm_teams_override");
 460                 BADCVAR("g_warmup");
 461                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 462                 BADCVAR("hostname");
 463                 BADCVAR("log_file");
 464                 BADCVAR("maxplayers");
 465                 BADCVAR("minplayers");
 466                 BADCVAR("minplayers_per_team");
 467                 BADCVAR("net_address");
 468                 BADCVAR("port");
 469                 BADCVAR("rcon_password");
 470                 BADCVAR("rcon_restricted_commands");
 471                 BADCVAR("rcon_restricted_password");
 472                 BADCVAR("skill");
 473                 BADCVAR("sv_adminnick");
 474                 BADCVAR("sv_autoscreenshot");
 475                 BADCVAR("sv_autotaunt");
 476                 BADCVAR("sv_curl_defaulturl");
 477                 BADCVAR("sv_defaultcharacter");
 478                 BADCVAR("sv_defaultcharacterskin");
 479                 BADCVAR("sv_defaultplayercolors");
 480                 BADCVAR("sv_defaultplayermodel");
 481                 BADCVAR("sv_defaultplayerskin");
 482                 BADCVAR("sv_maxidle");
 483                 BADCVAR("sv_maxrate");
 484                 BADCVAR("sv_motd");
 485                 BADCVAR("sv_public");
 486                 BADCVAR("sv_ready_restart");
 487                 BADCVAR("sv_status_privacy");
 488                 BADCVAR("sv_taunt");
 489                 BADCVAR("sv_vote_call");
 490                 BADCVAR("sv_vote_commands");
 491                 BADCVAR("sv_vote_majority_factor");
 492                 BADCVAR("sv_vote_master");
 493                 BADCVAR("sv_vote_master_commands");
 494                 BADCVAR("sv_vote_master_password");
 495                 BADCVAR("sv_vote_simple_majority_factor");
 496                 BADCVAR("teamplay_mode");
 497                 BADCVAR("timelimit_override");
 498                 BADPREFIX("g_warmup_");
 499                 BADPREFIX("sv_info_");
 500                 BADPREFIX("sv_ready_restart_");
 501
 502                 // mutators that announce themselves properly to the server browser
 503                 BADCVAR("g_instagib");
 504                 BADCVAR("g_new_toys");
 505                 BADCVAR("g_nix");
 506                 BADCVAR("g_grappling_hook");
 507                 BADCVAR("g_jetpack");
 508
 509                 // temporary for testing
 510                 // TODO remove before 0.8.3 release
 511                 BADCVAR("g_ca_weaponarena");
 512                 BADCVAR("g_freezetag_weaponarena");
 513                 BADCVAR("g_lms_weaponarena");
 514                 BADCVAR("g_ctf_stalemate_time");
 515
 516                 if(cvar_string("g_mod_balance") == "Testing")
 517                 {
 518                         // (temporary) while using the Testing balance, any weapon balance cvars are allowed to be changed
 519                         BADPREFIX("g_balance_");
 520                 }
 521
 522 #undef BADPRESUFFIX
 523 #undef BADPREFIX
 524 #undef BADCVAR
 525
 526                 if(pureadding)
 527                 {
 528                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 529                         if(strlen(cvar_purechanges) > 16384)
 530                         {
 531                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 532                                 pureadding = 0;
 533                         }
 534                 }
 535                 ++cvar_purechanges_count;
 536                 // WARNING: this variable is used for the server list
 537                 // NEVER dare to skip this code!
 538                 // Hacks to intentionally appearing as "pure server" even though you DO have
 539                 // modified settings may be punished by removal from the server list.
 540                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 541                 // though.
 542         }
 543         buf_del(h);
 544         if(cvar_changes == "")
 545                 cvar_changes = "// this server runs at default server settings\n";
 546         else
 547                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 548         cvar_changes = strzone(cvar_changes);
 549         if(cvar_purechanges == "")
 550                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 551         else
 552                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 553         cvar_purechanges = strzone(cvar_purechanges);
 554 }
 555
 556 entity randomseed;
 557 bool RandomSeed_Send(entity this, entity to, int sf)
 558 {
 559         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 560         WriteShort(MSG_ENTITY, this.cnt);
 561         return true;
 562 }
 563 void RandomSeed_Think(entity this)
 564 {
 565         this.cnt = bound(0, floor(random() * 65536), 65535);
 566         this.nextthink = time + 5;
 567
 568         this.SendFlags |= 1;
 569 }
 570 void RandomSeed_Spawn()
 571 {
 572         randomseed = new_pure(randomseed);
 573         setthink(randomseed, RandomSeed_Think);
 574         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 575
 576         getthink(randomseed)(randomseed); // sets random seed and nextthink
 577 }
 578
 579 spawnfunc(__init_dedicated_server)
 580 {
 581         // handler for _init/_init map (only for dedicated server initialization)
 582
 583         world_initialized = -1; // don't complain
 584
 585         delete_fn = remove_unsafely;
 586
 587         entity e = spawn();
 588         setthink(e, GotoFirstMap);
 589         e.nextthink = time; // this is usually 1 at this point
 590
 591         e = new(info_player_deathmatch);  // safeguard against player joining
 592
 593     // assign reflectively to avoid "assignment to world" warning
 594     for (int i = 0, n = numentityfields(); i < n; ++i) {
 595         string k = entityfieldname(i);
 596         if (k == "classname") {
 597             // safeguard against various stuff ;)
 598             putentityfieldstring(i, this, "worldspawn");
 599             break;
 600         }
 601     }
 602
 603         // needs to be done so early because of the constants they create
 604         static_init();
 605         static_init_late();
 606         static_init_precache();
 607
 608         IL_PUSH(g_spawnpoints, e); // just incase
 609
 610         MapInfo_Enumerate();
 611         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 612 }
 613
 614 void __init_dedicated_server_shutdown() {
 615         MapInfo_Shutdown();
 616 }
 617
 618 STATIC_INIT_EARLY(maxclients)
 619 {
 620         maxclients = 0;
 621         for (entity head = nextent(NULL); head; head = nextent(head)) {
 622                 ++maxclients;
 623         }
 624 }
 625
 626 void default_delayedinit(entity this)
 627 {
 628         if(!scores_initialized)
 629                 ScoreRules_generic();
 630 }
 631
 632 void InitGameplayMode()
 633 {
 634         VoteReset();
 635
 636         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 637         get_mi_min_max(1);
 638         // assign reflectively to avoid "assignment to world" warning
 639         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 640             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 641             if (v) {
 642             putentityfieldstring(i, world, sprintf("%v", v));
 643             if (++done == 2) break;
 644         }
 645         }
 646         // currently, NetRadiant's limit is 131072 qu for each side
 647         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 648         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 649         // in case somebody makes extremely large maps
 650         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 651
 652         MapInfo_LoadMapSettings(mapname);
 653         GameRules_teams(false);
 654
 655         if (!cvar_value_issafe(world.fog))
 656         {
 657                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 658                 world.fog = string_null;
 659         }
 660         if(MapInfo_Map_fog != "")
 661         {
 662                 if(MapInfo_Map_fog == "none")
 663                         world.fog = string_null;
 664                 else
 665                         world.fog = strzone(MapInfo_Map_fog);
 666         }
 667         clientstuff = strzone(MapInfo_Map_clientstuff);
 668
 669         MapInfo_ClearTemps();
 670
 671         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 672
 673         cache_mutatormsg = strzone("");
 674         cache_lastmutatormsg = strzone("");
 675
 676         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 677 }
 678
 679 void Map_MarkAsRecent(string m);
 680 float world_already_spawned;
 681 spawnfunc(worldspawn)
 682 {
 683         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 684
 685         bool wantrestart = false;
 686         {
 687                 if (!server_is_dedicated)
 688                 {
 689                         // force unloading of server pk3 files when starting a listen server
 690                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 691                         // restore csqc_progname too
 692                         string expect = "csprogs.dat";
 693                         wantrestart = cvar_string("csqc_progname") != expect;
 694                         cvar_set("csqc_progname", expect);
 695                 }
 696                 else
 697                 {
 698                         // Try to use versioned csprogs from pk3
 699                         // Only ever use versioned csprogs.dat files on dedicated servers;
 700                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 701                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 702                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 703                         string select = "csprogs.dat";
 704                         if (fexists(pk3csprogs)) select = pk3csprogs;
 705                         if (cvar_string("csqc_progname") != select)
 706                         {
 707                                 cvar_set("csqc_progname", select);
 708                                 wantrestart = true;
 709                         }
 710                         // Check for updates on startup
 711                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 712                         int sentinel = fopen("progs.txt", FILE_READ);
 713                         if (sentinel >= 0)
 714                         {
 715                                 string switchversion = fgets(sentinel);
 716                                 fclose(sentinel);
 717                                 if (switchversion != "" && switchversion != WATERMARK)
 718                                 {
 719                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 720                                         // if it doesn't exist, assume either:
 721                                         //   a) the current program was overwritten
 722                                         //   b) this is a client only update
 723                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 724                                         if (fexists(newprogs))
 725                                         {
 726                                                 cvar_set("sv_progs", newprogs);
 727                                                 wantrestart = true;
 728                                         }
 729                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 730                                         if (fexists(newcsprogs))
 731                                         {
 732                                                 cvar_set("csqc_progname", newcsprogs);
 733                                                 wantrestart = true;
 734                                         }
 735                                 }
 736                         }
 737                 }
 738                 if (wantrestart)
 739                 {
 740                         LOG_INFO("Restart requested");
 741                         changelevel(mapname);
 742                         // let initialization continue, shutdown depends on it
 743                 }
 744         }
 745
 746         if(world_already_spawned)
 747                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 748         world_already_spawned = true;
 749
 750         delete_fn = remove_safely; // during spawning, watch what you remove!
 751
 752         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 753
 754         // needs to be done so early because of the constants they create
 755         static_init();
 756
 757         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 758
 759         TemporaryDB = db_create();
 760
 761         // 0 normal
 762         lightstyle(0, "m");
 763
 764         // 1 FLICKER (first variety)
 765         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 766
 767         // 2 SLOW STRONG PULSE
 768         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 769
 770         // 3 CANDLE (first variety)
 771         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 772
 773         // 4 FAST STROBE
 774         lightstyle(4, "mamamamamama");
 775
 776         // 5 GENTLE PULSE 1
 777         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 778
 779         // 6 FLICKER (second variety)
 780         lightstyle(6, "nmonqnmomnmomomno");
 781
 782         // 7 CANDLE (second variety)
 783         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 784
 785         // 8 CANDLE (third variety)
 786         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 787
 788         // 9 SLOW STROBE (fourth variety)
 789         lightstyle(9, "aaaaaaaazzzzzzzz");
 790
 791         // 10 FLUORESCENT FLICKER
 792         lightstyle(10, "mmamammmmammamamaaamammma");
 793
 794         // 11 SLOW PULSE NOT FADE TO BLACK
 795         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 796
 797         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 798
 799         // 63 testing
 800         lightstyle(63, "a");
 801
 802         if(autocvar_g_campaign)
 803                 CampaignPreInit();
 804
 805         Map_MarkAsRecent(mapname);
 806
 807         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 808
 809         InitGameplayMode();
 810         static_init_late();
 811         static_init_precache();
 812         readlevelcvars();
 813         GrappleHookInit();
 814
 815         GameRules_limit_fallbacks();
 816
 817         if(warmup_limit == 0)
 818                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 819
 820         player_count = 0;
 821         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 822         if(bot_waypoints_for_items == 1)
 823                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 824                         bot_waypoints_for_items = 0;
 825
 826         WaypointSprite_Init();
 827
 828         GameLogInit(); // prepare everything
 829         // NOTE for matchid:
 830         // changing the logic generating it is okay. But:
 831         // it HAS to stay <= 64 chars
 832         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 833         if(autocvar_sv_eventlog)
 834         {
 835                 string s = sprintf("%s.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 836                 matchid = strzone(s);
 837
 838                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 839                 s = ":gameinfo:mutators:LIST";
 840
 841                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 842                 s = M_ARGV(0, string);
 843
 844                 // initialiation stuff, not good in the mutator system
 845                 if(!autocvar_g_use_ammunition)
 846                         s = strcat(s, ":no_use_ammunition");
 847
 848                 // initialiation stuff, not good in the mutator system
 849                 if(autocvar_g_pickup_items == 0)
 850                         s = strcat(s, ":no_pickup_items");
 851                 if(autocvar_g_pickup_items > 0)
 852                         s = strcat(s, ":pickup_items");
 853
 854                 // initialiation stuff, not good in the mutator system
 855                 if(autocvar_g_weaponarena != "0")
 856                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 857
 858                 // TODO to mutator system
 859                 if(autocvar_g_norecoil)
 860                         s = strcat(s, ":norecoil");
 861
 862                 // TODO to mutator system
 863                 if(autocvar_g_powerups == 0)
 864                         s = strcat(s, ":no_powerups");
 865                 if(autocvar_g_powerups > 0)
 866                         s = strcat(s, ":powerups");
 867
 868                 GameLogEcho(s);
 869                 GameLogEcho(":gameinfo:end");
 870         }
 871         else
 872                 matchid = strzone(ftos(random()));
 873
 874         cvar_set("nextmap", "");
 875
 876         SetDefaultAlpha();
 877
 878         if(autocvar_g_campaign)
 879                 CampaignPostInit();
 880
 881         Ban_LoadBans();
 882
 883         MapInfo_Enumerate();
 884         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 885
 886         q3compat = BITSET(q3compat, BIT(0), fexists(strcat("scripts/", mapname, ".arena")));
 887         q3compat = BITSET(q3compat, BIT(1), fexists(strcat("scripts/", mapname, ".defi")));
 888
 889         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 890         {
 891                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 892                 if(fd != -1)
 893                 {
 894                         string s;
 895                         while((s = fgets(fd)))
 896                         {
 897                                 int l = tokenize_console(s);
 898                                 if(l < 2)
 899                                         continue;
 900                                 if(argv(0) == "cd")
 901                                 {
 902                                         string trackname = argv(2);
 903                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 904                                         LOG_INFO("  cdtrack ", trackname);
 905                                         if (cvar_value_issafe(trackname))
 906                                         {
 907                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 908                                                 strcpy(clientstuff, newstuff);
 909                                         }
 910                                 }
 911                                 else if(argv(0) == "fog")
 912                                 {
 913                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 914                                         LOG_INFO("  \"fog\" \"", s, "\"");
 915                                 }
 916                                 else if(argv(0) == "set")
 917                                 {
 918                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 919                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 920                                 }
 921                                 else if(argv(0) != "//")
 922                                 {
 923                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 924                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 925                                 }
 926                         }
 927                         fclose(fd);
 928                 }
 929         }
 930
 931         WeaponStats_Init();
 932
 933         Nagger_Init();
 934
 935         // set up information replies for clients and server to use
 936         maplist_reply = strzone(getmaplist());
 937         lsmaps_reply = strzone(getlsmaps());
 938         monsterlist_reply = strzone(getmonsterlist());
 939         for(int i = 0; i < 10; ++i)
 940         {
 941                 string s = getrecords(i);
 942                 if (s)
 943                         records_reply[i] = strzone(s);
 944         }
 945         ladder_reply = strzone(getladder());
 946         rankings_reply = strzone(getrankings());
 947
 948         // begin other init
 949         ClientInit_Spawn();
 950         RandomSeed_Spawn();
 951         PingPLReport_Spawn();
 952
 953         CheatInit();
 954
 955         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 956
 957         // fill sv_curl_serverpackages from .serverpackage files
 958         if (autocvar_sv_curl_serverpackages_auto)
 959         {
 960                 string s = "csprogs-" WATERMARK ".txt";
 961                 // remove automatically managed files from the list to prevent duplicates
 962                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 963                 {
 964                         string pkg = argv(i);
 965                         if (startsWith(pkg, "csprogs-")) continue;
 966                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 967                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 968                         s = cons(s, pkg);
 969                 }
 970                 // add automatically managed files to the list
 971                 #define X(match) MACRO_BEGIN \
 972                         int fd = search_begin(match, true, false); \
 973                         if (fd >= 0) \
 974                         { \
 975                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 976                                 { \
 977                                         s = cons(s, search_getfilename(fd, i)); \
 978                                 } \
 979                                 search_end(fd); \
 980                         } \
 981                 MACRO_END
 982                 X("*-serverpackage.txt");
 983                 X("*.serverpackage");
 984                 #undef X
 985                 cvar_set("sv_curl_serverpackages", s);
 986         }
 987
 988         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 989         modname = "Xonotic";
 990         // physics/balance/config changes that count as mod
 991         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 992                 modname = cvar_string("g_mod_physics");
 993         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
 994                 modname = cvar_string("g_mod_balance");
 995         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 996                 modname = cvar_string("g_mod_config");
 997         // extra mutators that deserve to count as mod
 998         MUTATOR_CALLHOOK(SetModname, modname);
 999         modname = M_ARGV(0, string);
1000
1001         // save it for later
1002         modname = strzone(modname);
1003
1004         WinningConditionHelper(this); // set worldstatus
1005
1006         world_initialized = 1;
1007         __spawnfunc_spawn_all();
1008 }
1009
1010 spawnfunc(light)
1011 {
1012         //makestatic (this); // Who the f___ did that?
1013         delete(this);
1014 }
1015
1016 string GetGametype()
1017 {
1018         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1019 }
1020
1021 string GetMapname()
1022 {
1023         return mapname;
1024 }
1025
1026 float Map_Count, Map_Current;
1027 string Map_Current_Name;
1028
1029 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1030 int GetMaplistPosition()
1031 {
1032         string map = GetMapname();
1033         int idx = autocvar_g_maplist_index;
1034
1035         if(idx >= 0)
1036         {
1037                 if(idx < Map_Count)
1038                 {
1039                         if(map == argv(idx))
1040                         {
1041                                 return idx;
1042                         }
1043                 }
1044         }
1045
1046         for(int pos = 0; pos < Map_Count; ++pos)
1047         {
1048                 if(map == argv(pos))
1049                         return pos;
1050         }
1051
1052         // resume normal maplist rotation if current map is not in g_maplist
1053         return idx;
1054 }
1055
1056 bool MapHasRightSize(string map)
1057 {
1058         int minplayers = max(0, floor(autocvar_minplayers));
1059         if (teamplay)
1060                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1061         if (autocvar_g_maplist_check_waypoints
1062                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1063         {
1064                 string checkwp_msg = strcat("checkwp ", map);
1065                 if(!fexists(strcat("maps/", map, ".waypoints")))
1066                 {
1067                         LOG_TRACE(checkwp_msg, ": no waypoints");
1068                         return false;
1069                 }
1070                 LOG_TRACE(checkwp_msg, ": has waypoints");
1071         }
1072
1073         if(autocvar_g_maplist_ignore_sizes)
1074                 return true;
1075
1076         // open map size restriction file
1077         string opensize_msg = strcat("opensize ", map);
1078         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1079         int player_limit = ((autocvar_g_maplist_sizes_count_maxplayers) ? GetPlayerLimit() : 0);
1080         int pcount = ((player_limit > 0) ? min(player_count, player_limit) : player_count); // bind it to the player limit so that forced spectators don't influence the limits
1081         if(!autocvar_g_maplist_sizes_count_bots)
1082                 pcount -= currentbots;
1083         if(fh >= 0)
1084         {
1085                 opensize_msg = strcat(opensize_msg, ": ok, ");
1086                 int mapmin = stoi(fgets(fh));
1087                 int mapmax = stoi(fgets(fh));
1088                 fclose(fh);
1089                 if(pcount < mapmin)
1090                 {
1091                         LOG_TRACE(opensize_msg, "not enough");
1092                         return false;
1093                 }
1094                 if(mapmax && pcount > mapmax)
1095                 {
1096                         LOG_TRACE(opensize_msg, "too many");
1097                         return false;
1098                 }
1099                 LOG_TRACE(opensize_msg, "right size");
1100                 return true;
1101         }
1102         LOG_TRACE(opensize_msg, ": not found");
1103         return true;
1104 }
1105
1106 string Map_Filename(float position)
1107 {
1108         return strcat("maps/", argv(position), ".bsp");
1109 }
1110
1111 void Map_MarkAsRecent(string m)
1112 {
1113         cvar_set("g_maplist_mostrecent", strwords(cons(m, autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1114 }
1115
1116 float Map_IsRecent(string m)
1117 {
1118         return strhasword(autocvar_g_maplist_mostrecent, m);
1119 }
1120
1121 float Map_Check(float position, float pass)
1122 {
1123         string filename;
1124         string map_next;
1125         map_next = argv(position);
1126         if(pass <= 1)
1127         {
1128                 if(Map_IsRecent(map_next))
1129                         return 0;
1130         }
1131         filename = Map_Filename(position);
1132         if(MapInfo_CheckMap(map_next))
1133         {
1134                 if(pass == 2)
1135                         return 1;
1136                 if(MapHasRightSize(map_next))
1137                         return 1;
1138                 return 0;
1139         }
1140         else
1141                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1142
1143         return 0;
1144 }
1145
1146 void Map_Goto_SetStr(string nextmapname)
1147 {
1148         if(getmapname_stored != "")
1149                 strunzone(getmapname_stored);
1150         if(nextmapname == "")
1151                 getmapname_stored = "";
1152         else
1153                 getmapname_stored = strzone(nextmapname);
1154 }
1155
1156 void Map_Goto_SetFloat(float position)
1157 {
1158         cvar_set("g_maplist_index", ftos(position));
1159         Map_Goto_SetStr(argv(position));
1160 }
1161
1162 void Map_Goto(float reinit)
1163 {
1164         MapInfo_LoadMap(getmapname_stored, reinit);
1165 }
1166
1167 // return codes of map selectors:
1168 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1169 //   -2 = permanent failure
1170 float MaplistMethod_Iterate() // usual method
1171 {
1172         float pass, i;
1173
1174         LOG_TRACE("Trying MaplistMethod_Iterate");
1175
1176         for(pass = 1; pass <= 2; ++pass)
1177         {
1178                 for(i = 1; i < Map_Count; ++i)
1179                 {
1180                         float mapindex;
1181                         mapindex = (i + Map_Current) % Map_Count;
1182                         if(Map_Check(mapindex, pass))
1183                                 return mapindex;
1184                 }
1185         }
1186         return -1;
1187 }
1188
1189 float MaplistMethod_Repeat() // fallback method
1190 {
1191         LOG_TRACE("Trying MaplistMethod_Repeat");
1192
1193         if(Map_Check(Map_Current, 2))
1194                 return Map_Current;
1195         return -2;
1196 }
1197
1198 float MaplistMethod_Random() // random map selection
1199 {
1200         float i, imax;
1201
1202         LOG_TRACE("Trying MaplistMethod_Random");
1203
1204         imax = 42;
1205
1206         for(i = 0; i <= imax; ++i)
1207         {
1208                 float mapindex;
1209                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1210                 if(Map_Check(mapindex, 1))
1211                         return mapindex;
1212         }
1213         return -1;
1214 }
1215
1216 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1217 // the exponent sets a bias on the map selection:
1218 // the higher the exponent, the less likely "shortly repeated" same maps are
1219 {
1220         float i, j, imax, insertpos;
1221
1222         LOG_TRACE("Trying MaplistMethod_Shuffle");
1223
1224         imax = 42;
1225
1226         for(i = 0; i <= imax; ++i)
1227         {
1228                 string newlist;
1229
1230                 // now reinsert this at another position
1231                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1232                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1233                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1234                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1235
1236                 // insert the current map there
1237                 newlist = "";
1238                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1239                         newlist = strcat(newlist, " ", argv(j));
1240                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1241                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1242                         newlist = strcat(newlist, " ", argv(j));
1243                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1244                 cvar_set("g_maplist", newlist);
1245                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1246
1247                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1248                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1249                 if(Map_Check(Map_Current, 1))
1250                         return Map_Current;
1251         }
1252         return -1;
1253 }
1254
1255 void Maplist_Init()
1256 {
1257         float i = Map_Count = 0;
1258         if(autocvar_g_maplist != "")
1259         {
1260                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1261                 for (i = 0; i < Map_Count; ++i)
1262                 {
1263                         if (Map_Check(i, 2))
1264                                 break;
1265                 }
1266         }
1267
1268         if (i == Map_Count)
1269         {
1270                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1271                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1272                 if(autocvar_g_maplist_shuffle)
1273                         ShuffleMaplist();
1274                 if(!server_is_dedicated)
1275                         localcmd("\nmenu_cmd sync\n");
1276                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1277         }
1278         if(Map_Count == 0)
1279                 error("empty maplist, cannot select a new map");
1280         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1281
1282         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1283         // this may or may not be correct, but who cares, in the worst case a map
1284         // isn't chosen in the first pass that should have been
1285 }
1286
1287 string GetNextMap()
1288 {
1289         Maplist_Init();
1290         float nextMap = -1;
1291
1292         if(nextMap == -1)
1293                 if(autocvar_g_maplist_shuffle > 0)
1294                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1295
1296         if(nextMap == -1)
1297                 if(autocvar_g_maplist_selectrandom)
1298                         nextMap = MaplistMethod_Random();
1299
1300         if(nextMap == -1)
1301                 nextMap = MaplistMethod_Iterate();
1302
1303         if(nextMap == -1)
1304                 nextMap = MaplistMethod_Repeat();
1305
1306         if(nextMap >= 0)
1307         {
1308                 Map_Goto_SetFloat(nextMap);
1309                 return getmapname_stored;
1310         }
1311
1312         return "";
1313 }
1314
1315 float DoNextMapOverride(float reinit)
1316 {
1317         if(autocvar_g_campaign)
1318         {
1319                 CampaignPostIntermission();
1320                 alreadychangedlevel = true;
1321                 return true;
1322         }
1323         if(autocvar_quit_when_empty)
1324         {
1325                 if(player_count <= currentbots)
1326                 {
1327                         localcmd("quit\n");
1328                         alreadychangedlevel = true;
1329                         return true;
1330                 }
1331         }
1332         if(autocvar_quit_and_redirect != "")
1333         {
1334                 redirection_target = strzone(autocvar_quit_and_redirect);
1335                 alreadychangedlevel = true;
1336                 return true;
1337         }
1338         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1339         {
1340                 localcmd("restart\n");
1341                 alreadychangedlevel = true;
1342                 return true;
1343         }
1344         if(autocvar_nextmap != "")
1345         {
1346                 string m;
1347                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1348                 cvar_set("nextmap",m);
1349
1350                 if(!m || gametypevote)
1351                         return false;
1352                 if(autocvar_sv_vote_gametype)
1353                 {
1354                         Map_Goto_SetStr(m);
1355                         return false;
1356                 }
1357
1358                 if(MapInfo_CheckMap(m))
1359                 {
1360                         Map_Goto_SetStr(m);
1361                         Map_Goto(reinit);
1362                         alreadychangedlevel = true;
1363                         return true;
1364                 }
1365         }
1366         if(!reinit && autocvar_lastlevel)
1367         {
1368                 cvar_settemp_restore();
1369                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1370                 alreadychangedlevel = true;
1371                 return true;
1372         }
1373         return false;
1374 }
1375
1376 void GotoNextMap(float reinit)
1377 {
1378         //string nextmap;
1379         //float n, nummaps;
1380         //string s;
1381         if (alreadychangedlevel)
1382                 return;
1383         alreadychangedlevel = true;
1384
1385         string nextMap = GetNextMap();
1386         if(nextMap == "")
1387                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1388         Map_Goto(reinit);
1389 }
1390
1391
1392 /*
1393 ============
1394 IntermissionThink
1395
1396 When the player presses attack or jump, change to the next level
1397 ============
1398 */
1399 .float autoscreenshot;
1400 void IntermissionThink(entity this)
1401 {
1402         FixIntermissionClient(this);
1403
1404         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1405         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1406
1407         if( (server_screenshot || client_screenshot)
1408                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1409         {
1410                 this.autoscreenshot = -1;
1411                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1412                 return;
1413         }
1414
1415         if (time < intermission_exittime)
1416                 return;
1417
1418         if(!mapvote_initialized)
1419                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1420                         return;
1421
1422         MapVote_Start();
1423 }
1424
1425 /*
1426 ===============================================================================
1427
1428 RULES
1429
1430 ===============================================================================
1431 */
1432
1433 void DumpStats(float final)
1434 {
1435         float file;
1436         string s;
1437         float to_console;
1438         float to_eventlog;
1439         float to_file;
1440         float i;
1441
1442         to_console = autocvar_sv_logscores_console;
1443         to_eventlog = autocvar_sv_eventlog;
1444         to_file = autocvar_sv_logscores_file;
1445
1446         if(!final)
1447         {
1448                 to_console = true; // always print printstats replies
1449                 to_eventlog = false; // but never print them to the event log
1450         }
1451
1452         if(to_eventlog)
1453                 if(autocvar_sv_eventlog_console)
1454                         to_console = false; // otherwise we get the output twice
1455
1456         if(final)
1457                 s = ":scores:";
1458         else
1459                 s = ":status:";
1460         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1461
1462         if(to_console)
1463                 LOG_INFO(s);
1464         if(to_eventlog)
1465                 GameLogEcho(s);
1466
1467         file = -1;
1468         if(to_file)
1469         {
1470                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1471                 if(file == -1)
1472                         to_file = false;
1473                 else
1474                         fputs(file, strcat(s, "\n"));
1475         }
1476
1477         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1478         if(to_console)
1479                 LOG_INFO(s);
1480         if(to_eventlog)
1481                 GameLogEcho(s);
1482         if(to_file)
1483                 fputs(file, strcat(s, "\n"));
1484
1485         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1486                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1487                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1488                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1489                         s = strcat(s, ftos(it.team), ":");
1490                 else
1491                         s = strcat(s, "spectator:");
1492
1493                 if(to_console)
1494                         LOG_INFO(s, playername(it, false));
1495                 if(to_eventlog)
1496                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1497                 if(to_file)
1498                         fputs(file, strcat(s, playername(it, false), "\n"));
1499         });
1500
1501         if(teamplay)
1502         {
1503                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1504                 if(to_console)
1505                         LOG_INFO(s);
1506                 if(to_eventlog)
1507                         GameLogEcho(s);
1508                 if(to_file)
1509                         fputs(file, strcat(s, "\n"));
1510
1511                 for(i = 1; i < 16; ++i)
1512                 {
1513                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1514                         s = strcat(s, ":", ftos(i));
1515                         if(to_console)
1516                                 LOG_INFO(s);
1517                         if(to_eventlog)
1518                                 GameLogEcho(s);
1519                         if(to_file)
1520                                 fputs(file, strcat(s, "\n"));
1521                 }
1522         }
1523
1524         if(to_console)
1525                 LOG_INFO(":end");
1526         if(to_eventlog)
1527                 GameLogEcho(":end");
1528         if(to_file)
1529         {
1530                 fputs(file, ":end\n");
1531                 fclose(file);
1532         }
1533 }
1534
1535 void FixIntermissionClient(entity e)
1536 {
1537         if(!e.autoscreenshot) // initial call
1538         {
1539                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1540                 SetResourceExplicit(e, RES_HEALTH, -2342);
1541                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1542                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1543                 {
1544                     .entity weaponentity = weaponentities[slot];
1545                         if(e.(weaponentity))
1546                         {
1547                                 e.(weaponentity).effects = EF_NODRAW;
1548                                 if (e.(weaponentity).weaponchild)
1549                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1550                         }
1551                 }
1552                 if(IS_REAL_CLIENT(e))
1553                 {
1554                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1555                         RandomSelection_Init();
1556                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1557                                 RandomSelection_AddString(it, 1, 1);
1558                         });
1559                         if (RandomSelection_chosen_string != "")
1560                         {
1561                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1562                         }
1563                         msg_entity = e;
1564                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1565                 }
1566         }
1567 }
1568
1569 /*
1570 go to the next level for deathmatch
1571 only called if a time or frag limit has expired
1572 */
1573 void NextLevel()
1574 {
1575         game_stopped = true;
1576         intermission_running = 1; // game over
1577
1578         // enforce a wait time before allowing changelevel
1579         if(player_count > 0)
1580                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1581         else
1582                 intermission_exittime = -1;
1583
1584         /*
1585         WriteByte (MSG_ALL, SVC_CDTRACK);
1586         WriteByte (MSG_ALL, 3);
1587         WriteByte (MSG_ALL, 3);
1588         // done in FixIntermission
1589         */
1590
1591         //pos = FindIntermission ();
1592
1593         VoteReset();
1594
1595         DumpStats(true);
1596
1597         // send statistics
1598         PlayerStats_GameReport(true);
1599         WeaponStats_Shutdown();
1600
1601         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1602
1603         if(autocvar_sv_eventlog)
1604                 GameLogEcho(":gameover");
1605
1606         GameLogClose();
1607
1608         FOREACH_CLIENT(IS_PLAYER(it), {
1609                 FixIntermissionClient(it);
1610                 if(it.winning)
1611                         bprint(playername(it, false), " ^7wins.\n");
1612         });
1613
1614         target_music_kill();
1615
1616         if(autocvar_g_campaign)
1617                 CampaignPreIntermission();
1618
1619         MUTATOR_CALLHOOK(MatchEnd);
1620
1621         localcmd("\nsv_hook_gameend\n");
1622 }
1623
1624
1625 float InitiateSuddenDeath()
1626 {
1627         // Check first whether normal overtimes could be added before initiating suddendeath mode
1628         // - for this timelimit_overtime needs to be >0 of course
1629         // - also check the winning condition calculated in the previous frame and only add normal overtime
1630         //   again, if at the point at which timelimit would be extended again, still no winner was found
1631         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1632                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1633                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1634         {
1635                 return 1; // need to call InitiateOvertime later
1636         }
1637         else
1638         {
1639                 if(!checkrules_suddendeathend)
1640                 {
1641                         if(autocvar_g_campaign)
1642                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1643                         else
1644                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1645                         if(g_race && !g_race_qualifying)
1646                                 race_StartCompleting();
1647                 }
1648                 return 0;
1649         }
1650 }
1651
1652 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1653 {
1654         ++checkrules_overtimesadded;
1655         //add one more overtime by simply extending the timelimit
1656         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1657         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1658 }
1659
1660 float GetWinningCode(float fraglimitreached, float equality)
1661 {
1662         if(autocvar_g_campaign == 1)
1663         {
1664                 if(fraglimitreached)
1665                         return WINNING_YES;
1666                 else
1667                         return WINNING_NO;
1668         }
1669         else
1670         {
1671                 if(equality)
1672                 {
1673                         if(fraglimitreached)
1674                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1675                         else
1676                                 return WINNING_NEVER;
1677                 }
1678                 else
1679                 {
1680                         if(fraglimitreached)
1681                                 return WINNING_YES;
1682                         else
1683                                 return WINNING_NO;
1684                 }
1685         }
1686 }
1687
1688 // set the .winning flag for exactly those players with a given field value
1689 void SetWinners(.float field, float value)
1690 {
1691         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1692 }
1693
1694 // set the .winning flag for those players with a given field value
1695 void AddWinners(.float field, float value)
1696 {
1697         FOREACH_CLIENT(IS_PLAYER(it), {
1698                 if(it.(field) == value)
1699                         it.winning = 1;
1700         });
1701 }
1702
1703 // clear the .winning flags
1704 void ClearWinners()
1705 {
1706         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1707 }
1708
1709 void ShuffleMaplist()
1710 {
1711         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1712 }
1713
1714 int fragsleft_last;
1715 float WinningCondition_Scores(float limit, float leadlimit)
1716 {
1717         // TODO make everything use THIS winning condition (except LMS)
1718         WinningConditionHelper(NULL);
1719
1720         if(teamplay)
1721         {
1722                 for (int i = 1; i < 5; ++i)
1723                 {
1724                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1725                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1726                 }
1727         }
1728
1729         ClearWinners();
1730         if(WinningConditionHelper_winner)
1731                 WinningConditionHelper_winner.winning = 1;
1732         if(WinningConditionHelper_winnerteam >= 0)
1733                 SetWinners(team, WinningConditionHelper_winnerteam);
1734
1735         if(WinningConditionHelper_lowerisbetter)
1736         {
1737                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1738                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1739                 limit = -limit;
1740         }
1741
1742         if(WinningConditionHelper_zeroisworst)
1743                 leadlimit = 0; // not supported in this mode
1744
1745         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1746         {
1747                 float fragsleft;
1748                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1749                 {
1750                         fragsleft = 1;
1751                 }
1752                 else
1753                 {
1754                         fragsleft = FLOAT_MAX;
1755                         float leadingfragsleft = FLOAT_MAX;
1756                         if (limit)
1757                                 fragsleft = limit - WinningConditionHelper_topscore;
1758                         if (leadlimit)
1759                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1760
1761                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1762                                 fragsleft = max(fragsleft, leadingfragsleft);
1763                         else
1764                                 fragsleft = min(fragsleft, leadingfragsleft);
1765                 }
1766
1767                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1768                 {
1769                         if (fragsleft == 1)
1770                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1771                         else if (fragsleft == 2)
1772                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1773                         else if (fragsleft == 3)
1774                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1775
1776                         fragsleft_last = fragsleft;
1777                 }
1778         }
1779
1780         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1781         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1782
1783         bool limit_reached;
1784         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1785         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1786                 limit_reached = (fraglimit_reached && leadlimit_reached);
1787         else
1788                 limit_reached = (fraglimit_reached || leadlimit_reached);
1789
1790         return GetWinningCode(
1791                 WinningConditionHelper_topscore && limit_reached,
1792                 WinningConditionHelper_equality
1793         );
1794 }
1795
1796 float WinningCondition_RanOutOfSpawns()
1797 {
1798         if(have_team_spawns <= 0)
1799                 return WINNING_NO;
1800
1801         if(!autocvar_g_spawn_useallspawns)
1802                 return WINNING_NO;
1803
1804         if(!some_spawn_has_been_used)
1805                 return WINNING_NO;
1806
1807         for (int i = 1; i < 5; ++i)
1808         {
1809                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1810         }
1811
1812         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1813         {
1814                 if (Team_IsValidTeam(it.team))
1815                 {
1816                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1817                 }
1818         });
1819
1820         IL_EACH(g_spawnpoints, true,
1821         {
1822                 if (Team_IsValidTeam(it.team))
1823                 {
1824                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1825                 }
1826         });
1827
1828         ClearWinners();
1829         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1830         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1831         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1832         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1833         if(team1_score + team2_score + team3_score + team4_score == 0)
1834         {
1835                 checkrules_equality = true;
1836                 return WINNING_YES;
1837         }
1838         else if(team1_score + team2_score + team3_score + team4_score == 1)
1839         {
1840                 float t, i;
1841                 if(team1_score)
1842                         t = 1;
1843                 else if(team2_score)
1844                         t = 2;
1845                 else if(team3_score)
1846                         t = 3;
1847                 else // if(team4_score)
1848                         t = 4;
1849                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1850                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1851                 {
1852                         for (int j = 1; j <= NUM_TEAMS; ++j)
1853                         {
1854                                 if (t == j)
1855                                 {
1856                                         continue;
1857                                 }
1858                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1859                                 {
1860                                         continue;
1861                                 }
1862                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1863                         }
1864                 }
1865
1866                 AddWinners(team, t);
1867                 return WINNING_YES;
1868         }
1869         else
1870                 return WINNING_NO;
1871 }
1872
1873 /*
1874 ============
1875 CheckRules_World
1876
1877 Exit deathmatch games upon conditions
1878 ============
1879 */
1880 void CheckRules_World()
1881 {
1882         VoteThink();
1883         MapVote_Think();
1884
1885         SetDefaultAlpha();
1886
1887         if (intermission_running) // someone else quit the game already
1888         {
1889                 if(player_count == 0) // Nobody there? Then let's go to the next map
1890                         MapVote_Start();
1891                         // this will actually check the player count in the next frame
1892                         // again, but this shouldn't hurt
1893                 return;
1894         }
1895
1896         float timelimit = autocvar_timelimit * 60;
1897         float fraglimit = autocvar_fraglimit;
1898         float leadlimit = autocvar_leadlimit;
1899         if (leadlimit < 0) leadlimit = 0;
1900
1901         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1902         {
1903                 if(timelimit > 0)
1904                         timelimit = 0; // timelimit is not made for warmup
1905                 if(fraglimit > 0)
1906                         fraglimit = 0; // no fraglimit for now
1907                 leadlimit = 0; // no leadlimit for now
1908         }
1909
1910         if(timelimit > 0)
1911         {
1912                 timelimit += game_starttime;
1913         }
1914         else if (timelimit < 0)
1915         {
1916                 // endmatch
1917                 NextLevel();
1918                 return;
1919         }
1920
1921         float wantovertime;
1922         wantovertime = 0;
1923
1924         if(checkrules_suddendeathend)
1925         {
1926                 if(!checkrules_suddendeathwarning)
1927                 {
1928                         checkrules_suddendeathwarning = true;
1929                         if(g_race && !g_race_qualifying)
1930                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1931                         else
1932                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1933                 }
1934         }
1935         else
1936         {
1937                 if (timelimit && time >= timelimit)
1938                 {
1939                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1940                         {
1941                                 float totalplayers;
1942                                 float playerswithlaps;
1943                                 float readyplayers;
1944                                 totalplayers = playerswithlaps = readyplayers = 0;
1945                                 FOREACH_CLIENT(IS_PLAYER(it), {
1946                                         ++totalplayers;
1947                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1948                                                 ++playerswithlaps;
1949                                         if(it.ready)
1950                                                 ++readyplayers;
1951                                 });
1952
1953                                 // at least 2 of the players have completed a lap: start the RACE
1954                                 // otherwise, the players should end the qualifying on their own
1955                                 if(readyplayers || playerswithlaps >= 2)
1956                                 {
1957                                         checkrules_suddendeathend = 0;
1958                                         ReadyRestart(); // go to race
1959                                         return;
1960                                 }
1961                                 else
1962                                         wantovertime |= InitiateSuddenDeath();
1963                         }
1964                         else
1965                                 wantovertime |= InitiateSuddenDeath();
1966                 }
1967         }
1968
1969         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1970         {
1971                 NextLevel();
1972                 return;
1973         }
1974
1975         int checkrules_status = WinningCondition_RanOutOfSpawns();
1976         if(checkrules_status == WINNING_YES)
1977                 bprint("Hey! Someone ran out of spawns!\n");
1978         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1979                 checkrules_status = M_ARGV(0, float);
1980         else
1981                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1982
1983         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1984         {
1985                 checkrules_status = WINNING_NEVER;
1986                 checkrules_overtimesadded = -1;
1987                 wantovertime |= InitiateSuddenDeath();
1988         }
1989
1990         if(checkrules_status == WINNING_NEVER)
1991                 // equality cases! Nobody wins if the overtime ends in a draw.
1992                 ClearWinners();
1993
1994         if(wantovertime)
1995         {
1996                 if(checkrules_status == WINNING_NEVER)
1997                         InitiateOvertime();
1998                 else
1999                         checkrules_status = WINNING_YES;
2000         }
2001
2002         if(checkrules_suddendeathend)
2003                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2004                         checkrules_status = WINNING_YES;
2005
2006         if(checkrules_status == WINNING_YES)
2007         {
2008                 //print("WINNING\n");
2009                 NextLevel();
2010         }
2011 }
2012
2013 string GotoMap(string m)
2014 {
2015         m = GameTypeVote_MapInfo_FixName(m);
2016         if (!m)
2017                 return "The map you suggested is not available on this server.";
2018         if (!autocvar_sv_vote_gametype)
2019         if(!MapInfo_CheckMap(m))
2020                 return "The map you suggested does not support the current game mode.";
2021         cvar_set("nextmap", m);
2022         cvar_set("timelimit", "-1");
2023         if(mapvote_initialized || alreadychangedlevel)
2024         {
2025                 if(DoNextMapOverride(0))
2026                         return "Map switch initiated.";
2027                 else
2028                         return "Hm... no. For some reason I like THIS map more.";
2029         }
2030         else
2031                 return "Map switch will happen after scoreboard.";
2032 }
2033
2034 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2035 void RunThink(entity this)
2036 {
2037         // don't let things stay in the past.
2038         // it is possible to start that way by a trigger with a local time.
2039         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2040                 return;
2041
2042         float oldtime = time; // do we need to save this?
2043
2044         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2045         {
2046                 time = max(oldtime, this.nextthink);
2047                 this.nextthink = 0;
2048
2049                 if(getthink(this))
2050                         getthink(this)(this);
2051                 // mods often set nextthink to time to cause a think every frame,
2052                 // we don't want to loop in that case, so exit if the new nextthink is
2053                 // <= the time the qc was told, also exit if it is past the end of the
2054                 // frame
2055                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2056                         break;
2057         }
2058
2059         time = oldtime;
2060 }
2061
2062 bool autocvar_sv_freezenonclients;
2063 bool autocvar_sv_gameplayfix_delayprojectiles = false;
2064 void Physics_Frame()
2065 {
2066         if(autocvar_sv_freezenonclients)
2067                 return;
2068
2069         IL_EACH(g_moveables, true,
2070         {
2071                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PHYSICS)
2072                         continue;
2073
2074                 //set_movetype(it, it.move_movetype);
2075                 // inline the set_movetype function, since this is called a lot
2076                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2077
2078                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2079                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2080
2081                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2082                 {
2083                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2084                                 continue; // these movetypes have no regular think function
2085                         // handle thinking here
2086                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2087                                 RunThink(it);
2088                 }
2089         });
2090
2091         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2092                 return;
2093
2094         IL_EACH(g_moveables, it.move_qcphysics,
2095         {
2096                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2097                         continue;
2098                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2099         });
2100 }
2101
2102 void systems_update();
2103 void EndFrame()
2104 {
2105         anticheat_endframe();
2106
2107         Physics_Frame();
2108
2109         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2110                 entity e = IS_SPEC(it) ? it.enemy : it;
2111                 if (e.typehitsound) {
2112                         STAT(TYPEHIT_TIME, it) = time;
2113                 } else if (e.killsound) {
2114                         STAT(KILL_TIME, it) = time;
2115                 } else if (e.damage_dealt) {
2116                         STAT(HIT_TIME, it) = time;
2117                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2118                 }
2119         });
2120         // add 1 frametime because after this, engine SV_Physics
2121         // increases time by a frametime and then networks the frame
2122         // add another frametime because client shows everything with
2123         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2124         // needed!
2125         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2126         FOREACH_CLIENT(true, {
2127                 it.typehitsound = false;
2128                 it.damage_dealt = 0;
2129                 it.killsound = false;
2130                 antilag_record(it, CS(it), altime);
2131         });
2132         IL_EACH(g_monsters, true,
2133         {
2134                 antilag_record(it, it, altime);
2135         });
2136         IL_EACH(g_projectiles, it.classname == "nade",
2137         {
2138                 antilag_record(it, it, altime);
2139         });
2140         systems_update();
2141         IL_ENDFRAME();
2142 }
2143
2144
2145 /*
2146  * RedirectionThink:
2147  * returns true if redirecting
2148  */
2149 float redirection_timeout;
2150 float redirection_nextthink;
2151 float RedirectionThink()
2152 {
2153         float clients_found;
2154
2155         if(redirection_target == "")
2156                 return false;
2157
2158         if(!redirection_timeout)
2159         {
2160                 cvar_set("sv_public", "-2");
2161                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2162                 if(redirection_target == "self")
2163                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2164                 else
2165                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2166         }
2167
2168         if(time < redirection_nextthink)
2169                 return true;
2170
2171         redirection_nextthink = time + 1;
2172
2173         clients_found = 0;
2174         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2175                 // TODO add timer
2176                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2177                 if(redirection_target == "self")
2178                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2179                 else
2180                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2181                 ++clients_found;
2182         });
2183
2184         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2185
2186         if(time > redirection_timeout || clients_found == 0)
2187                 localcmd("\nwait; wait; wait; quit\n");
2188
2189         return true;
2190 }
2191
2192 void RestoreGame()
2193 {
2194         // Loaded from a save game
2195         // some things then break, so let's work around them...
2196
2197         // Progs DB (capture records)
2198         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2199
2200         // Mapinfo
2201         MapInfo_Shutdown();
2202         MapInfo_Enumerate();
2203         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2204         WeaponStats_Init();
2205
2206         TargetMusic_RestoreGame();
2207 }
2208
2209 void Shutdown()
2210 {
2211         game_stopped = 2;
2212
2213         if(world_initialized > 0)
2214         {
2215                 world_initialized = 0;
2216
2217                 // if a timeout is active, reset the slowmo value to normal
2218                 if(timeout_status == TIMEOUT_ACTIVE)
2219                         cvar_set("slowmo", ftos(orig_slowmo));
2220
2221                 LOG_TRACE("Saving persistent data...");
2222                 Ban_SaveBans();
2223
2224                 // playerstats with unfinished match
2225                 PlayerStats_GameReport(false);
2226
2227                 if(!cheatcount_total)
2228                 {
2229                         if(autocvar_sv_db_saveasdump)
2230                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2231                         else
2232                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2233                 }
2234                 if(autocvar_developer > 0)
2235                 {
2236                         if(autocvar_sv_db_saveasdump)
2237                                 db_dump(TemporaryDB, "server-temp.db");
2238                         else
2239                                 db_save(TemporaryDB, "server-temp.db");
2240                 }
2241                 CheatShutdown(); // must be after cheatcount check
2242                 db_close(ServerProgsDB);
2243                 db_close(TemporaryDB);
2244                 LOG_TRACE("Saving persistent data... done!");
2245                 // tell the bot system the game is ending now
2246                 bot_endgame();
2247
2248                 WeaponStats_Shutdown();
2249                 MapInfo_Shutdown();
2250         }
2251         else if(world_initialized == 0)
2252         {
2253                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2254         }
2255         else
2256         {
2257                 __init_dedicated_server_shutdown();
2258         }
2259 }