qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include <server/mutators/_mod.qh>
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "scores_rules.qh"
  20 #include "teamplay.qh"
  21 #include "weapons/weaponstats.qh"
  22 #include "../common/constants.qh"
  23 #include <common/net_linked.qh>
  24 #include "../common/deathtypes/all.qh"
  25 #include "../common/gamemodes/sv_rules.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/_mod.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/vehicles/all.qh"
  30 #include "../common/notifications/all.qh"
  31 #include "../common/physics/player.qh"
  32 #include "../common/playerstats.qh"
  33 #include "../common/stats.qh"
  34 #include "../common/teams.qh"
  35 #include "../common/mapobjects/trigger/secret.qh"
  36 #include "../common/mapobjects/target/music.qh"
  37 #include "../common/util.qh"
  38 #include "../common/items/_mod.qh"
  39 #include <common/weapons/_all.qh>
  40 #include "../common/state.qh"
  41
  42 const float LATENCY_THINKRATE = 10;
  43 .float latency_sum;
  44 .float latency_cnt;
  45 .float latency_time;
  46 entity pingplreport;
  47 void PingPLReport_Think(entity this)
  48 {
  49         float delta;
  50         entity e;
  51
  52         delta = 3 / maxclients;
  53         if(delta < sys_frametime)
  54                 delta = 0;
  55         this.nextthink = time + delta;
  56
  57         e = edict_num(this.cnt + 1);
  58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  59         {
  60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  61                 WriteByte(MSG_BROADCAST, this.cnt);
  62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  65
  66                 // record latency times for clients throughout the match so we can report it to playerstats
  67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  68                 {
  69                         CS(e).latency_sum += CS(e).ping;
  70                         CS(e).latency_cnt += 1;
  71                         CS(e).latency_time = time;
  72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  73                 }
  74         }
  75         else
  76         {
  77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  78                 WriteByte(MSG_BROADCAST, this.cnt);
  79                 WriteShort(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81                 WriteByte(MSG_BROADCAST, 0);
  82         }
  83         this.cnt = (this.cnt + 1) % maxclients;
  84 }
  85 void PingPLReport_Spawn()
  86 {
  87         pingplreport = new_pure(pingplreport);
  88         setthink(pingplreport, PingPLReport_Think);
  89         pingplreport.nextthink = time;
  90 }
  91
  92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  93 string redirection_target;
  94 float world_initialized;
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         strfree(cvar_changes);
 148         strfree(cvar_purechanges);
 149         cvar_purechanges_count = 0;
 150
 151         h = buf_create();
 152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 153         n = buf_getsize(h);
 154
 155         adding = true;
 156         pureadding = true;
 157
 158         for(i = 0; i < n; ++i)
 159         {
 160                 k = bufstr_get(h, i);
 161
 162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 164 #define BADCVAR(p) if(k == p) continue
 165
 166                 // general excludes and namespaces for server admin used cvars
 167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 168
 169                 // internal
 170                 BADPREFIX("csqc_");
 171                 BADPREFIX("cvar_check_");
 172                 BADCVAR("gamecfg");
 173                 BADCVAR("g_configversion");
 174                 BADCVAR("halflifebsp");
 175                 BADCVAR("sv_mapformat_is_quake2");
 176                 BADCVAR("sv_mapformat_is_quake3");
 177                 BADPREFIX("sv_world");
 178
 179                 // client
 180                 BADPREFIX("chase_");
 181                 BADPREFIX("cl_");
 182                 BADPREFIX("con_");
 183                 BADPREFIX("scoreboard_");
 184                 BADPREFIX("g_campaign");
 185                 BADPREFIX("g_waypointsprite_");
 186                 BADPREFIX("gl_");
 187                 BADPREFIX("joy");
 188                 BADPREFIX("hud_");
 189                 BADPREFIX("m_");
 190                 BADPREFIX("menu_");
 191                 BADPREFIX("net_slist_");
 192                 BADPREFIX("r_");
 193                 BADPREFIX("sbar_");
 194                 BADPREFIX("scr_");
 195                 BADPREFIX("snd_");
 196                 BADPREFIX("show");
 197                 BADPREFIX("sensitivity");
 198                 BADPREFIX("userbind");
 199                 BADPREFIX("v_");
 200                 BADPREFIX("vid_");
 201                 BADPREFIX("crosshair");
 202                 BADCVAR("mod_q3bsp_lightmapmergepower");
 203                 BADCVAR("mod_q3bsp_nolightmaps");
 204                 BADCVAR("fov");
 205                 BADCVAR("mastervolume");
 206                 BADCVAR("volume");
 207                 BADCVAR("bgmvolume");
 208                 BADCVAR("in_pitch_min");
 209                 BADCVAR("in_pitch_max");
 210
 211                 // private
 212                 BADCVAR("developer");
 213                 BADCVAR("log_dest_udp");
 214                 BADCVAR("net_address");
 215                 BADCVAR("net_address_ipv6");
 216                 BADCVAR("port");
 217                 BADCVAR("savedgamecfg");
 218                 BADCVAR("serverconfig");
 219                 BADCVAR("sv_autoscreenshot");
 220                 BADCVAR("sv_heartbeatperiod");
 221                 BADCVAR("sv_vote_master_password");
 222                 BADCVAR("sys_colortranslation");
 223                 BADCVAR("sys_specialcharactertranslation");
 224                 BADCVAR("timeformat");
 225                 BADCVAR("timestamps");
 226                 BADCVAR("g_require_stats");
 227                 BADPREFIX("developer_");
 228                 BADPREFIX("g_ban_");
 229                 BADPREFIX("g_banned_list");
 230                 BADPREFIX("g_require_stats_");
 231                 BADPREFIX("g_chat_flood_");
 232                 BADPREFIX("g_ghost_items");
 233                 BADPREFIX("g_playerstats_");
 234                 BADPREFIX("g_voice_flood_");
 235                 BADPREFIX("log_file");
 236                 BADPREFIX("quit_");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250                 BADCVAR("sv_muteban_list");
 251                 BADCVAR("sv_voteban_list");
 252                 BADCVAR("sv_allow_customplayermodels_idlist");
 253                 BADCVAR("sv_allow_customplayermodels_speciallist");
 254
 255                 // mapinfo
 256                 BADCVAR("fraglimit");
 257                 BADCVAR("g_arena");
 258                 BADCVAR("g_assault");
 259                 BADCVAR("g_ca");
 260                 BADCVAR("g_ca_teams");
 261                 BADCVAR("g_conquest");
 262                 BADCVAR("g_ctf");
 263                 BADCVAR("g_cts");
 264                 BADCVAR("g_dotc");
 265                 BADCVAR("g_dm");
 266                 BADCVAR("g_domination");
 267                 BADCVAR("g_domination_default_teams");
 268                 BADCVAR("g_duel");
 269                 BADCVAR("g_duel_not_dm_maps");
 270                 BADCVAR("g_freezetag");
 271                 BADCVAR("g_freezetag_teams");
 272                 BADCVAR("g_invasion_teams");
 273                 BADCVAR("g_invasion_type");
 274                 BADCVAR("g_jailbreak");
 275                 BADCVAR("g_jailbreak_teams");
 276                 BADCVAR("g_keepaway");
 277                 BADCVAR("g_keyhunt");
 278                 BADCVAR("g_keyhunt_teams");
 279                 BADCVAR("g_lms");
 280                 BADCVAR("g_nexball");
 281                 BADCVAR("g_onslaught");
 282                 BADCVAR("g_race");
 283                 BADCVAR("g_race_laps_limit");
 284                 BADCVAR("g_race_qualifying_timelimit");
 285                 BADCVAR("g_race_qualifying_timelimit_override");
 286                 BADCVAR("g_runematch");
 287                 BADCVAR("g_shootfromeye");
 288                 BADCVAR("g_snafu");
 289                 BADCVAR("g_tdm");
 290                 BADCVAR("g_tdm_on_dm_maps");
 291                 BADCVAR("g_tdm_teams");
 292                 BADCVAR("g_vip");
 293                 BADCVAR("leadlimit");
 294                 BADCVAR("nextmap");
 295                 BADCVAR("teamplay");
 296                 BADCVAR("timelimit");
 297                 BADCVAR("g_mapinfo_ignore_warnings");
 298                 BADCVAR("g_maplist_ignore_sizes");
 299                 BADCVAR("g_maplist_sizes_count_bots");
 300
 301                 // long
 302                 BADCVAR("hostname");
 303                 BADCVAR("g_maplist");
 304                 BADCVAR("g_maplist_mostrecent");
 305                 BADCVAR("sv_motd");
 306
 307                 v = cvar_string(k);
 308                 d = cvar_defstring(k);
 309                 if(v == d)
 310                         continue;
 311
 312                 if(adding)
 313                 {
 314                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 315                         if(strlen(cvar_changes) > 16384)
 316                         {
 317                                 cvar_changes = "// too many settings have been changed to show them here\n";
 318                                 adding = 0;
 319                         }
 320                 }
 321
 322                 // now check if the changes are actually gameplay relevant
 323
 324                 // does nothing gameplay relevant
 325                 BADCVAR("captureleadlimit_override");
 326                 BADCVAR("condump_stripcolors");
 327                 BADCVAR("gameversion");
 328                 BADCVAR("fs_gamedir");
 329                 BADCVAR("g_allow_oldvortexbeam");
 330                 BADCVAR("g_balance_kill_delay");
 331                 BADCVAR("g_buffs_pickup_anyway");
 332                 BADCVAR("g_buffs_randomize");
 333                 BADCVAR("g_buffs_randomize_teamplay");
 334                 BADCVAR("g_campcheck_distance");
 335                 BADCVAR("g_chatsounds");
 336                 BADCVAR("g_ca_point_leadlimit");
 337                 BADCVAR("g_ca_point_limit");
 338                 BADCVAR("g_ctf_captimerecord_always");
 339                 BADCVAR("g_ctf_flag_glowtrails");
 340                 BADCVAR("g_ctf_dynamiclights");
 341                 BADCVAR("g_ctf_flag_pickup_verbosename");
 342                 BADPRESUFFIX("g_ctf_flag_", "_model");
 343                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 344                 BADCVAR("g_domination_point_leadlimit");
 345                 BADCVAR("g_forced_respawn");
 346                 BADCVAR("g_freezetag_point_leadlimit");
 347                 BADCVAR("g_freezetag_point_limit");
 348                 BADCVAR("g_glowtrails");
 349                 BADCVAR("g_hats");
 350                 BADCVAR("g_invasion_point_limit");
 351                 BADCVAR("g_jump_grunt");
 352                 BADCVAR("g_keepaway_ballcarrier_effects");
 353                 BADCVAR("g_keepawayball_effects");
 354                 BADCVAR("g_keyhunt_point_leadlimit");
 355                 BADCVAR("g_nexball_goalleadlimit");
 356                 BADCVAR("g_new_toys_autoreplace");
 357                 BADCVAR("g_new_toys_use_pickupsound");
 358                 BADCVAR("g_physics_predictall");
 359                 BADCVAR("g_piggyback");
 360                 BADCVAR("g_playerclip_collisions");
 361                 BADCVAR("g_spawn_alloweffects");
 362                 BADCVAR("g_tdm_point_leadlimit");
 363                 BADCVAR("g_tdm_point_limit");
 364                 BADCVAR("leadlimit_and_fraglimit");
 365                 BADCVAR("leadlimit_override");
 366                 BADCVAR("pausable");
 367                 BADCVAR("sv_announcer");
 368                 BADCVAR("sv_checkforpacketsduringsleep");
 369                 BADCVAR("sv_damagetext");
 370                 BADCVAR("sv_db_saveasdump");
 371                 BADCVAR("sv_intermission_cdtrack");
 372                 BADCVAR("sv_mapchange_delay");
 373                 BADCVAR("sv_minigames");
 374                 BADCVAR("sv_namechangetimer");
 375                 BADCVAR("sv_precacheplayermodels");
 376                 BADCVAR("sv_radio");
 377                 BADCVAR("sv_stepheight");
 378                 BADCVAR("sv_timeout");
 379                 BADCVAR("sv_weapons_modeloverride");
 380                 BADCVAR("w_prop_interval");
 381                 BADPREFIX("chat_");
 382                 BADPREFIX("crypto_");
 383                 BADPREFIX("gameversion_");
 384                 BADPREFIX("g_chat_");
 385                 BADPREFIX("g_ctf_captimerecord_");
 386                 BADPREFIX("g_hats_");
 387                 BADPREFIX("g_maplist_");
 388                 BADPREFIX("g_mod_");
 389                 BADPREFIX("g_respawn_");
 390                 BADPREFIX("net_");
 391                 BADPREFIX("notification_");
 392                 BADPREFIX("prvm_");
 393                 BADPREFIX("skill_");
 394                 BADPREFIX("sv_allow_");
 395                 BADPREFIX("sv_cullentities_");
 396                 BADPREFIX("sv_maxidle_");
 397                 BADPREFIX("sv_minigames_");
 398                 BADPREFIX("sv_radio_");
 399                 BADPREFIX("sv_timeout_");
 400                 BADPREFIX("sv_vote_");
 401                 BADPREFIX("timelimit_");
 402
 403                 // allowed changes to server admins (please sync this to server.cfg)
 404                 // vi commands:
 405                 //   :/"impure"/,$d
 406                 //   :g!,^\/\/[^ /],d
 407                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 408                 //   :%!sort
 409                 // yes, this does contain some redundant stuff, don't really care
 410                 BADPREFIX("bot_ai_");
 411                 BADCVAR("bot_config_file");
 412                 BADCVAR("bot_number");
 413                 BADCVAR("bot_prefix");
 414                 BADCVAR("bot_suffix");
 415                 BADCVAR("capturelimit_override");
 416                 BADCVAR("fraglimit_override");
 417                 BADCVAR("gametype");
 418                 BADCVAR("g_antilag");
 419                 BADCVAR("g_balance_teams");
 420                 BADCVAR("g_balance_teams_prevent_imbalance");
 421                 BADCVAR("g_balance_teams_scorefactor");
 422                 BADCVAR("g_ban_sync_trusted_servers");
 423                 BADCVAR("g_ban_sync_uri");
 424                 BADCVAR("g_buffs");
 425                 BADCVAR("g_ca_teams_override");
 426                 BADCVAR("g_ctf_fullbrightflags");
 427                 BADCVAR("g_ctf_ignore_frags");
 428                 BADCVAR("g_ctf_leaderboard");
 429                 BADCVAR("g_domination_point_limit");
 430                 BADCVAR("g_domination_teams_override");
 431                 BADCVAR("g_freezetag_teams_override");
 432                 BADCVAR("g_friendlyfire");
 433                 BADCVAR("g_fullbrightitems");
 434                 BADCVAR("g_fullbrightplayers");
 435                 BADCVAR("g_keyhunt_point_limit");
 436                 BADCVAR("g_keyhunt_teams_override");
 437                 BADCVAR("g_lms_lives_override");
 438                 BADCVAR("g_maplist");
 439                 BADCVAR("g_maxplayers");
 440                 BADCVAR("g_mirrordamage");
 441                 BADCVAR("g_nexball_goallimit");
 442                 BADCVAR("g_norecoil");
 443                 BADCVAR("g_physics_clientselect");
 444                 BADCVAR("g_pinata");
 445                 BADCVAR("g_powerups");
 446                 BADCVAR("g_player_brightness");
 447                 BADCVAR("g_rocket_flying");
 448                 BADCVAR("g_rocket_flying_disabledelays");
 449                 BADCVAR("g_spawnshieldtime");
 450                 BADCVAR("g_start_delay");
 451                 BADCVAR("g_superspectate");
 452                 BADCVAR("g_tdm_teams_override");
 453                 BADCVAR("g_warmup");
 454                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 455                 BADCVAR("hostname");
 456                 BADCVAR("log_file");
 457                 BADCVAR("maxplayers");
 458                 BADCVAR("minplayers");
 459                 BADCVAR("minplayers_per_team");
 460                 BADCVAR("net_address");
 461                 BADCVAR("port");
 462                 BADCVAR("rcon_password");
 463                 BADCVAR("rcon_restricted_commands");
 464                 BADCVAR("rcon_restricted_password");
 465                 BADCVAR("skill");
 466                 BADCVAR("sv_adminnick");
 467                 BADCVAR("sv_autoscreenshot");
 468                 BADCVAR("sv_autotaunt");
 469                 BADCVAR("sv_curl_defaulturl");
 470                 BADCVAR("sv_defaultcharacter");
 471                 BADCVAR("sv_defaultcharacterskin");
 472                 BADCVAR("sv_defaultplayercolors");
 473                 BADCVAR("sv_defaultplayermodel");
 474                 BADCVAR("sv_defaultplayerskin");
 475                 BADCVAR("sv_maxidle");
 476                 BADCVAR("sv_maxrate");
 477                 BADCVAR("sv_motd");
 478                 BADCVAR("sv_public");
 479                 BADCVAR("sv_ready_restart");
 480                 BADCVAR("sv_status_privacy");
 481                 BADCVAR("sv_taunt");
 482                 BADCVAR("sv_vote_call");
 483                 BADCVAR("sv_vote_commands");
 484                 BADCVAR("sv_vote_majority_factor");
 485                 BADCVAR("sv_vote_master");
 486                 BADCVAR("sv_vote_master_commands");
 487                 BADCVAR("sv_vote_master_password");
 488                 BADCVAR("sv_vote_simple_majority_factor");
 489                 BADCVAR("teamplay_mode");
 490                 BADCVAR("timelimit_override");
 491                 BADPREFIX("g_warmup_");
 492                 BADPREFIX("sv_info_");
 493                 BADPREFIX("sv_ready_restart_");
 494
 495                 // mutators that announce themselves properly to the server browser
 496                 BADCVAR("g_instagib");
 497                 BADCVAR("g_new_toys");
 498                 BADCVAR("g_nix");
 499                 BADCVAR("g_grappling_hook");
 500                 BADCVAR("g_jetpack");
 501
 502                 // temporary for testing
 503                 // TODO remove before 0.8.3 release
 504                 BADCVAR("g_ca_weaponarena");
 505                 BADCVAR("g_freezetag_weaponarena");
 506                 BADCVAR("g_lms_weaponarena");
 507                 BADCVAR("g_ctf_stalemate_time");
 508
 509                 if(cvar_string("g_mod_balance") == "Testing")
 510                 {
 511                         // (temporary) while using the Testing balance, any weapon balance cvars are allowed to be changed
 512                         BADPREFIX("g_balance_");
 513                 }
 514
 515 #undef BADPRESUFFIX
 516 #undef BADPREFIX
 517 #undef BADCVAR
 518
 519                 if(pureadding)
 520                 {
 521                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 522                         if(strlen(cvar_purechanges) > 16384)
 523                         {
 524                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 525                                 pureadding = 0;
 526                         }
 527                 }
 528                 ++cvar_purechanges_count;
 529                 // WARNING: this variable is used for the server list
 530                 // NEVER dare to skip this code!
 531                 // Hacks to intentionally appearing as "pure server" even though you DO have
 532                 // modified settings may be punished by removal from the server list.
 533                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 534                 // though.
 535         }
 536         buf_del(h);
 537         if(cvar_changes == "")
 538                 cvar_changes = "// this server runs at default server settings\n";
 539         else
 540                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 541         cvar_changes = strzone(cvar_changes);
 542         if(cvar_purechanges == "")
 543                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 544         else
 545                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 546         cvar_purechanges = strzone(cvar_purechanges);
 547 }
 548
 549 entity randomseed;
 550 bool RandomSeed_Send(entity this, entity to, int sf)
 551 {
 552         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 553         WriteShort(MSG_ENTITY, this.cnt);
 554         return true;
 555 }
 556 void RandomSeed_Think(entity this)
 557 {
 558         this.cnt = bound(0, floor(random() * 65536), 65535);
 559         this.nextthink = time + 5;
 560
 561         this.SendFlags |= 1;
 562 }
 563 void RandomSeed_Spawn()
 564 {
 565         randomseed = new_pure(randomseed);
 566         setthink(randomseed, RandomSeed_Think);
 567         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 568
 569         getthink(randomseed)(randomseed); // sets random seed and nextthink
 570 }
 571
 572 spawnfunc(__init_dedicated_server)
 573 {
 574         // handler for _init/_init map (only for dedicated server initialization)
 575
 576         world_initialized = -1; // don't complain
 577
 578         delete_fn = remove_unsafely;
 579
 580         entity e = spawn();
 581         setthink(e, GotoFirstMap);
 582         e.nextthink = time; // this is usually 1 at this point
 583
 584         e = new(info_player_deathmatch);  // safeguard against player joining
 585
 586     // assign reflectively to avoid "assignment to world" warning
 587     for (int i = 0, n = numentityfields(); i < n; ++i) {
 588         string k = entityfieldname(i);
 589         if (k == "classname") {
 590             // safeguard against various stuff ;)
 591             putentityfieldstring(i, this, "worldspawn");
 592             break;
 593         }
 594     }
 595
 596         // needs to be done so early because of the constants they create
 597         static_init();
 598         static_init_late();
 599         static_init_precache();
 600
 601         IL_PUSH(g_spawnpoints, e); // just incase
 602
 603         MapInfo_Enumerate();
 604         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 605 }
 606
 607 void __init_dedicated_server_shutdown() {
 608         MapInfo_Shutdown();
 609 }
 610
 611 STATIC_INIT_EARLY(maxclients)
 612 {
 613         maxclients = 0;
 614         for (entity head = nextent(NULL); head; head = nextent(head)) {
 615                 ++maxclients;
 616         }
 617 }
 618
 619 void default_delayedinit(entity this)
 620 {
 621         if(!scores_initialized)
 622                 ScoreRules_generic();
 623 }
 624
 625 void InitGameplayMode()
 626 {
 627         VoteReset();
 628
 629         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 630         get_mi_min_max(1);
 631         // assign reflectively to avoid "assignment to world" warning
 632         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 633             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 634             if (v) {
 635             putentityfieldstring(i, world, sprintf("%v", v));
 636             if (++done == 2) break;
 637         }
 638         }
 639         // currently, NetRadiant's limit is 131072 qu for each side
 640         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 641         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 642         // in case somebody makes extremely large maps
 643         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 644
 645         MapInfo_LoadMapSettings(mapname);
 646         GameRules_teams(false);
 647
 648         if (!cvar_value_issafe(world.fog))
 649         {
 650                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 651                 world.fog = string_null;
 652         }
 653         if(MapInfo_Map_fog != "")
 654         {
 655                 if(MapInfo_Map_fog == "none")
 656                         world.fog = string_null;
 657                 else
 658                         world.fog = strzone(MapInfo_Map_fog);
 659         }
 660         clientstuff = strzone(MapInfo_Map_clientstuff);
 661
 662         MapInfo_ClearTemps();
 663
 664         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 665
 666         cache_mutatormsg = strzone("");
 667         cache_lastmutatormsg = strzone("");
 668
 669         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 670 }
 671
 672 void Map_MarkAsRecent(string m);
 673 float world_already_spawned;
 674 spawnfunc(worldspawn)
 675 {
 676         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 677
 678         bool wantrestart = false;
 679         {
 680                 if (!server_is_dedicated)
 681                 {
 682                         // force unloading of server pk3 files when starting a listen server
 683                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 684                         // restore csqc_progname too
 685                         string expect = "csprogs.dat";
 686                         wantrestart = cvar_string("csqc_progname") != expect;
 687                         cvar_set("csqc_progname", expect);
 688                 }
 689                 else
 690                 {
 691                         // Try to use versioned csprogs from pk3
 692                         // Only ever use versioned csprogs.dat files on dedicated servers;
 693                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 694                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 695                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 696                         string select = "csprogs.dat";
 697                         if (fexists(pk3csprogs)) select = pk3csprogs;
 698                         if (cvar_string("csqc_progname") != select)
 699                         {
 700                                 cvar_set("csqc_progname", select);
 701                                 wantrestart = true;
 702                         }
 703                         // Check for updates on startup
 704                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 705                         int sentinel = fopen("progs.txt", FILE_READ);
 706                         if (sentinel >= 0)
 707                         {
 708                                 string switchversion = fgets(sentinel);
 709                                 fclose(sentinel);
 710                                 if (switchversion != "" && switchversion != WATERMARK)
 711                                 {
 712                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 713                                         // if it doesn't exist, assume either:
 714                                         //   a) the current program was overwritten
 715                                         //   b) this is a client only update
 716                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 717                                         if (fexists(newprogs))
 718                                         {
 719                                                 cvar_set("sv_progs", newprogs);
 720                                                 wantrestart = true;
 721                                         }
 722                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 723                                         if (fexists(newcsprogs))
 724                                         {
 725                                                 cvar_set("csqc_progname", newcsprogs);
 726                                                 wantrestart = true;
 727                                         }
 728                                 }
 729                         }
 730                 }
 731                 if (wantrestart)
 732                 {
 733                         LOG_INFO("Restart requested");
 734                         changelevel(mapname);
 735                         // let initialization continue, shutdown depends on it
 736                 }
 737         }
 738
 739         if(world_already_spawned)
 740                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 741         world_already_spawned = true;
 742
 743         delete_fn = remove_safely; // during spawning, watch what you remove!
 744
 745         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 746
 747         // needs to be done so early because of the constants they create
 748         static_init();
 749
 750         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 751
 752         TemporaryDB = db_create();
 753
 754         // 0 normal
 755         lightstyle(0, "m");
 756
 757         // 1 FLICKER (first variety)
 758         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 759
 760         // 2 SLOW STRONG PULSE
 761         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 762
 763         // 3 CANDLE (first variety)
 764         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 765
 766         // 4 FAST STROBE
 767         lightstyle(4, "mamamamamama");
 768
 769         // 5 GENTLE PULSE 1
 770         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 771
 772         // 6 FLICKER (second variety)
 773         lightstyle(6, "nmonqnmomnmomomno");
 774
 775         // 7 CANDLE (second variety)
 776         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 777
 778         // 8 CANDLE (third variety)
 779         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 780
 781         // 9 SLOW STROBE (fourth variety)
 782         lightstyle(9, "aaaaaaaazzzzzzzz");
 783
 784         // 10 FLUORESCENT FLICKER
 785         lightstyle(10, "mmamammmmammamamaaamammma");
 786
 787         // 11 SLOW PULSE NOT FADE TO BLACK
 788         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 789
 790         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 791
 792         // 63 testing
 793         lightstyle(63, "a");
 794
 795         if(autocvar_g_campaign)
 796                 CampaignPreInit();
 797
 798         Map_MarkAsRecent(mapname);
 799
 800         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 801
 802         InitGameplayMode();
 803         static_init_late();
 804         static_init_precache();
 805         readlevelcvars();
 806         GrappleHookInit();
 807
 808         GameRules_limit_fallbacks();
 809
 810         if(warmup_limit == 0)
 811                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 812
 813         player_count = 0;
 814         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 815         if(bot_waypoints_for_items == 1)
 816                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 817                         bot_waypoints_for_items = 0;
 818
 819         WaypointSprite_Init();
 820
 821         GameLogInit(); // prepare everything
 822         // NOTE for matchid:
 823         // changing the logic generating it is okay. But:
 824         // it HAS to stay <= 64 chars
 825         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 826         if(autocvar_sv_eventlog)
 827         {
 828                 string s = sprintf("%s.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 829                 matchid = strzone(s);
 830
 831                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 832                 s = ":gameinfo:mutators:LIST";
 833
 834                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 835                 s = M_ARGV(0, string);
 836
 837                 // initialiation stuff, not good in the mutator system
 838                 if(!autocvar_g_use_ammunition)
 839                         s = strcat(s, ":no_use_ammunition");
 840
 841                 // initialiation stuff, not good in the mutator system
 842                 if(autocvar_g_pickup_items == 0)
 843                         s = strcat(s, ":no_pickup_items");
 844                 if(autocvar_g_pickup_items > 0)
 845                         s = strcat(s, ":pickup_items");
 846
 847                 // initialiation stuff, not good in the mutator system
 848                 if(autocvar_g_weaponarena != "0")
 849                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 850
 851                 // TODO to mutator system
 852                 if(autocvar_g_norecoil)
 853                         s = strcat(s, ":norecoil");
 854
 855                 // TODO to mutator system
 856                 if(autocvar_g_powerups == 0)
 857                         s = strcat(s, ":no_powerups");
 858                 if(autocvar_g_powerups > 0)
 859                         s = strcat(s, ":powerups");
 860
 861                 GameLogEcho(s);
 862                 GameLogEcho(":gameinfo:end");
 863         }
 864         else
 865                 matchid = strzone(ftos(random()));
 866
 867         cvar_set("nextmap", "");
 868
 869         SetDefaultAlpha();
 870
 871         if(autocvar_g_campaign)
 872                 CampaignPostInit();
 873
 874         Ban_LoadBans();
 875
 876         MapInfo_Enumerate();
 877         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 878
 879         if(fexists(strcat("scripts/", mapname, ".arena")))
 880                 cvar_settemp("sv_q3acompat_machineshotgunswap", "1");
 881
 882         if(fexists(strcat("scripts/", mapname, ".defi")))
 883                 cvar_settemp("sv_q3defragcompat", "1");
 884
 885         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 886         {
 887                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 888                 if(fd != -1)
 889                 {
 890                         string s;
 891                         while((s = fgets(fd)))
 892                         {
 893                                 int l = tokenize_console(s);
 894                                 if(l < 2)
 895                                         continue;
 896                                 if(argv(0) == "cd")
 897                                 {
 898                                         string trackname = argv(2);
 899                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 900                                         LOG_INFO("  cdtrack ", trackname);
 901                                         if (cvar_value_issafe(trackname))
 902                                         {
 903                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 904                                                 strcpy(clientstuff, newstuff);
 905                                         }
 906                                 }
 907                                 else if(argv(0) == "fog")
 908                                 {
 909                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 910                                         LOG_INFO("  \"fog\" \"", s, "\"");
 911                                 }
 912                                 else if(argv(0) == "set")
 913                                 {
 914                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 915                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 916                                 }
 917                                 else if(argv(0) != "//")
 918                                 {
 919                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 920                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 921                                 }
 922                         }
 923                         fclose(fd);
 924                 }
 925         }
 926
 927         WeaponStats_Init();
 928
 929         Nagger_Init();
 930
 931         next_pingtime = time + 5;
 932
 933         // set up information replies for clients and server to use
 934         maplist_reply = strzone(getmaplist());
 935         lsmaps_reply = strzone(getlsmaps());
 936         monsterlist_reply = strzone(getmonsterlist());
 937         for(int i = 0; i < 10; ++i)
 938         {
 939                 string s = getrecords(i);
 940                 if (s)
 941                         records_reply[i] = strzone(s);
 942         }
 943         ladder_reply = strzone(getladder());
 944         rankings_reply = strzone(getrankings());
 945
 946         // begin other init
 947         ClientInit_Spawn();
 948         RandomSeed_Spawn();
 949         PingPLReport_Spawn();
 950
 951         CheatInit();
 952
 953         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 954
 955         // fill sv_curl_serverpackages from .serverpackage files
 956         if (autocvar_sv_curl_serverpackages_auto)
 957         {
 958                 string s = "csprogs-" WATERMARK ".txt";
 959                 // remove automatically managed files from the list to prevent duplicates
 960                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 961                 {
 962                         string pkg = argv(i);
 963                         if (startsWith(pkg, "csprogs-")) continue;
 964                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 965                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 966                         s = cons(s, pkg);
 967                 }
 968                 // add automatically managed files to the list
 969                 #define X(match) MACRO_BEGIN \
 970                         int fd = search_begin(match, true, false); \
 971                         if (fd >= 0) \
 972                         { \
 973                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 974                                 { \
 975                                         s = cons(s, search_getfilename(fd, i)); \
 976                                 } \
 977                                 search_end(fd); \
 978                         } \
 979                 MACRO_END
 980                 X("*-serverpackage.txt");
 981                 X("*.serverpackage");
 982                 #undef X
 983                 cvar_set("sv_curl_serverpackages", s);
 984         }
 985
 986         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 987         modname = "Xonotic";
 988         // physics/balance/config changes that count as mod
 989         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 990                 modname = cvar_string("g_mod_physics");
 991         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
 992                 modname = cvar_string("g_mod_balance");
 993         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 994                 modname = cvar_string("g_mod_config");
 995         // extra mutators that deserve to count as mod
 996         MUTATOR_CALLHOOK(SetModname, modname);
 997         modname = M_ARGV(0, string);
 998
 999         // save it for later
1000         modname = strzone(modname);
1001
1002         WinningConditionHelper(this); // set worldstatus
1003
1004         world_initialized = 1;
1005         __spawnfunc_spawn_all();
1006 }
1007
1008 spawnfunc(light)
1009 {
1010         //makestatic (this); // Who the f___ did that?
1011         delete(this);
1012 }
1013
1014 string GetGametype()
1015 {
1016         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1017 }
1018
1019 string GetMapname()
1020 {
1021         return mapname;
1022 }
1023
1024 float Map_Count, Map_Current;
1025 string Map_Current_Name;
1026
1027 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1028 int GetMaplistPosition()
1029 {
1030         string map = GetMapname();
1031         int idx = autocvar_g_maplist_index;
1032
1033         if(idx >= 0)
1034         {
1035                 if(idx < Map_Count)
1036                 {
1037                         if(map == argv(idx))
1038                         {
1039                                 return idx;
1040                         }
1041                 }
1042         }
1043
1044         for(int pos = 0; pos < Map_Count; ++pos)
1045         {
1046                 if(map == argv(pos))
1047                         return pos;
1048         }
1049
1050         // resume normal maplist rotation if current map is not in g_maplist
1051         return idx;
1052 }
1053
1054 bool MapHasRightSize(string map)
1055 {
1056         int minplayers = max(0, floor(autocvar_minplayers));
1057         if (teamplay)
1058                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1059         if (autocvar_g_maplist_check_waypoints
1060                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1061         {
1062                 string checkwp_msg = strcat("checkwp ", map);
1063                 if(!fexists(strcat("maps/", map, ".waypoints")))
1064                 {
1065                         LOG_TRACE(checkwp_msg, ": no waypoints");
1066                         return false;
1067                 }
1068                 LOG_TRACE(checkwp_msg, ": has waypoints");
1069         }
1070
1071         if(autocvar_g_maplist_ignore_sizes)
1072                 return true;
1073
1074         // open map size restriction file
1075         string opensize_msg = strcat("opensize ", map);
1076         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1077         int player_limit = ((autocvar_g_maplist_sizes_count_maxplayers) ? GetPlayerLimit() : 0);
1078         int pcount = ((player_limit > 0) ? min(player_count, player_limit) : player_count); // bind it to the player limit so that forced spectators don't influence the limits
1079         if(!autocvar_g_maplist_sizes_count_bots)
1080                 pcount -= currentbots;
1081         if(fh >= 0)
1082         {
1083                 opensize_msg = strcat(opensize_msg, ": ok, ");
1084                 int mapmin = stoi(fgets(fh));
1085                 int mapmax = stoi(fgets(fh));
1086                 fclose(fh);
1087                 if(pcount < mapmin)
1088                 {
1089                         LOG_TRACE(opensize_msg, "not enough");
1090                         return false;
1091                 }
1092                 if(mapmax && pcount > mapmax)
1093                 {
1094                         LOG_TRACE(opensize_msg, "too many");
1095                         return false;
1096                 }
1097                 LOG_TRACE(opensize_msg, "right size");
1098                 return true;
1099         }
1100         LOG_TRACE(opensize_msg, ": not found");
1101         return true;
1102 }
1103
1104 string Map_Filename(float position)
1105 {
1106         return strcat("maps/", argv(position), ".bsp");
1107 }
1108
1109 void Map_MarkAsRecent(string m)
1110 {
1111         cvar_set("g_maplist_mostrecent", strwords(cons(m, autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1112 }
1113
1114 float Map_IsRecent(string m)
1115 {
1116         return strhasword(autocvar_g_maplist_mostrecent, m);
1117 }
1118
1119 float Map_Check(float position, float pass)
1120 {
1121         string filename;
1122         string map_next;
1123         map_next = argv(position);
1124         if(pass <= 1)
1125         {
1126                 if(Map_IsRecent(map_next))
1127                         return 0;
1128         }
1129         filename = Map_Filename(position);
1130         if(MapInfo_CheckMap(map_next))
1131         {
1132                 if(pass == 2)
1133                         return 1;
1134                 if(MapHasRightSize(map_next))
1135                         return 1;
1136                 return 0;
1137         }
1138         else
1139                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1140
1141         return 0;
1142 }
1143
1144 void Map_Goto_SetStr(string nextmapname)
1145 {
1146         if(getmapname_stored != "")
1147                 strunzone(getmapname_stored);
1148         if(nextmapname == "")
1149                 getmapname_stored = "";
1150         else
1151                 getmapname_stored = strzone(nextmapname);
1152 }
1153
1154 void Map_Goto_SetFloat(float position)
1155 {
1156         cvar_set("g_maplist_index", ftos(position));
1157         Map_Goto_SetStr(argv(position));
1158 }
1159
1160 void Map_Goto(float reinit)
1161 {
1162         MapInfo_LoadMap(getmapname_stored, reinit);
1163 }
1164
1165 // return codes of map selectors:
1166 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1167 //   -2 = permanent failure
1168 float MaplistMethod_Iterate() // usual method
1169 {
1170         float pass, i;
1171
1172         LOG_TRACE("Trying MaplistMethod_Iterate");
1173
1174         for(pass = 1; pass <= 2; ++pass)
1175         {
1176                 for(i = 1; i < Map_Count; ++i)
1177                 {
1178                         float mapindex;
1179                         mapindex = (i + Map_Current) % Map_Count;
1180                         if(Map_Check(mapindex, pass))
1181                                 return mapindex;
1182                 }
1183         }
1184         return -1;
1185 }
1186
1187 float MaplistMethod_Repeat() // fallback method
1188 {
1189         LOG_TRACE("Trying MaplistMethod_Repeat");
1190
1191         if(Map_Check(Map_Current, 2))
1192                 return Map_Current;
1193         return -2;
1194 }
1195
1196 float MaplistMethod_Random() // random map selection
1197 {
1198         float i, imax;
1199
1200         LOG_TRACE("Trying MaplistMethod_Random");
1201
1202         imax = 42;
1203
1204         for(i = 0; i <= imax; ++i)
1205         {
1206                 float mapindex;
1207                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1208                 if(Map_Check(mapindex, 1))
1209                         return mapindex;
1210         }
1211         return -1;
1212 }
1213
1214 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1215 // the exponent sets a bias on the map selection:
1216 // the higher the exponent, the less likely "shortly repeated" same maps are
1217 {
1218         float i, j, imax, insertpos;
1219
1220         LOG_TRACE("Trying MaplistMethod_Shuffle");
1221
1222         imax = 42;
1223
1224         for(i = 0; i <= imax; ++i)
1225         {
1226                 string newlist;
1227
1228                 // now reinsert this at another position
1229                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1230                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1231                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1232                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1233
1234                 // insert the current map there
1235                 newlist = "";
1236                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1237                         newlist = strcat(newlist, " ", argv(j));
1238                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1239                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1240                         newlist = strcat(newlist, " ", argv(j));
1241                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1242                 cvar_set("g_maplist", newlist);
1243                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1244
1245                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1246                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1247                 if(Map_Check(Map_Current, 1))
1248                         return Map_Current;
1249         }
1250         return -1;
1251 }
1252
1253 void Maplist_Init()
1254 {
1255         float i = Map_Count = 0;
1256         if(autocvar_g_maplist != "")
1257         {
1258                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1259                 for (i = 0; i < Map_Count; ++i)
1260                 {
1261                         if (Map_Check(i, 2))
1262                                 break;
1263                 }
1264         }
1265
1266         if (i == Map_Count)
1267         {
1268                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1269                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1270                 if(autocvar_g_maplist_shuffle)
1271                         ShuffleMaplist();
1272                 if(!server_is_dedicated)
1273                         localcmd("\nmenu_cmd sync\n");
1274                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1275         }
1276         if(Map_Count == 0)
1277                 error("empty maplist, cannot select a new map");
1278         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1279
1280         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1281         // this may or may not be correct, but who cares, in the worst case a map
1282         // isn't chosen in the first pass that should have been
1283 }
1284
1285 string GetNextMap()
1286 {
1287         Maplist_Init();
1288         float nextMap = -1;
1289
1290         if(nextMap == -1)
1291                 if(autocvar_g_maplist_shuffle > 0)
1292                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1293
1294         if(nextMap == -1)
1295                 if(autocvar_g_maplist_selectrandom)
1296                         nextMap = MaplistMethod_Random();
1297
1298         if(nextMap == -1)
1299                 nextMap = MaplistMethod_Iterate();
1300
1301         if(nextMap == -1)
1302                 nextMap = MaplistMethod_Repeat();
1303
1304         if(nextMap >= 0)
1305         {
1306                 Map_Goto_SetFloat(nextMap);
1307                 return getmapname_stored;
1308         }
1309
1310         return "";
1311 }
1312
1313 float DoNextMapOverride(float reinit)
1314 {
1315         if(autocvar_g_campaign)
1316         {
1317                 CampaignPostIntermission();
1318                 alreadychangedlevel = true;
1319                 return true;
1320         }
1321         if(autocvar_quit_when_empty)
1322         {
1323                 if(player_count <= currentbots)
1324                 {
1325                         localcmd("quit\n");
1326                         alreadychangedlevel = true;
1327                         return true;
1328                 }
1329         }
1330         if(autocvar_quit_and_redirect != "")
1331         {
1332                 redirection_target = strzone(autocvar_quit_and_redirect);
1333                 alreadychangedlevel = true;
1334                 return true;
1335         }
1336         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1337         {
1338                 localcmd("restart\n");
1339                 alreadychangedlevel = true;
1340                 return true;
1341         }
1342         if(autocvar_nextmap != "")
1343         {
1344                 string m;
1345                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1346                 cvar_set("nextmap",m);
1347
1348                 if(!m || gametypevote)
1349                         return false;
1350                 if(autocvar_sv_vote_gametype)
1351                 {
1352                         Map_Goto_SetStr(m);
1353                         return false;
1354                 }
1355
1356                 if(MapInfo_CheckMap(m))
1357                 {
1358                         Map_Goto_SetStr(m);
1359                         Map_Goto(reinit);
1360                         alreadychangedlevel = true;
1361                         return true;
1362                 }
1363         }
1364         if(!reinit && autocvar_lastlevel)
1365         {
1366                 cvar_settemp_restore();
1367                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1368                 alreadychangedlevel = true;
1369                 return true;
1370         }
1371         return false;
1372 }
1373
1374 void GotoNextMap(float reinit)
1375 {
1376         //string nextmap;
1377         //float n, nummaps;
1378         //string s;
1379         if (alreadychangedlevel)
1380                 return;
1381         alreadychangedlevel = true;
1382
1383         string nextMap = GetNextMap();
1384         if(nextMap == "")
1385                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1386         Map_Goto(reinit);
1387 }
1388
1389
1390 /*
1391 ============
1392 IntermissionThink
1393
1394 When the player presses attack or jump, change to the next level
1395 ============
1396 */
1397 .float autoscreenshot;
1398 void IntermissionThink(entity this)
1399 {
1400         FixIntermissionClient(this);
1401
1402         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1403         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1404
1405         if( (server_screenshot || client_screenshot)
1406                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1407         {
1408                 this.autoscreenshot = -1;
1409                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1410                 return;
1411         }
1412
1413         if (time < intermission_exittime)
1414                 return;
1415
1416         if(!mapvote_initialized)
1417                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1418                         return;
1419
1420         MapVote_Start();
1421 }
1422
1423 /*
1424 ===============================================================================
1425
1426 RULES
1427
1428 ===============================================================================
1429 */
1430
1431 void DumpStats(float final)
1432 {
1433         float file;
1434         string s;
1435         float to_console;
1436         float to_eventlog;
1437         float to_file;
1438         float i;
1439
1440         to_console = autocvar_sv_logscores_console;
1441         to_eventlog = autocvar_sv_eventlog;
1442         to_file = autocvar_sv_logscores_file;
1443
1444         if(!final)
1445         {
1446                 to_console = true; // always print printstats replies
1447                 to_eventlog = false; // but never print them to the event log
1448         }
1449
1450         if(to_eventlog)
1451                 if(autocvar_sv_eventlog_console)
1452                         to_console = false; // otherwise we get the output twice
1453
1454         if(final)
1455                 s = ":scores:";
1456         else
1457                 s = ":status:";
1458         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1459
1460         if(to_console)
1461                 LOG_INFO(s);
1462         if(to_eventlog)
1463                 GameLogEcho(s);
1464
1465         file = -1;
1466         if(to_file)
1467         {
1468                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1469                 if(file == -1)
1470                         to_file = false;
1471                 else
1472                         fputs(file, strcat(s, "\n"));
1473         }
1474
1475         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1476         if(to_console)
1477                 LOG_INFO(s);
1478         if(to_eventlog)
1479                 GameLogEcho(s);
1480         if(to_file)
1481                 fputs(file, strcat(s, "\n"));
1482
1483         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1484                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1485                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1486                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1487                         s = strcat(s, ftos(it.team), ":");
1488                 else
1489                         s = strcat(s, "spectator:");
1490
1491                 if(to_console)
1492                         LOG_INFO(s, playername(it, false));
1493                 if(to_eventlog)
1494                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1495                 if(to_file)
1496                         fputs(file, strcat(s, playername(it, false), "\n"));
1497         });
1498
1499         if(teamplay)
1500         {
1501                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1502                 if(to_console)
1503                         LOG_INFO(s);
1504                 if(to_eventlog)
1505                         GameLogEcho(s);
1506                 if(to_file)
1507                         fputs(file, strcat(s, "\n"));
1508
1509                 for(i = 1; i < 16; ++i)
1510                 {
1511                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1512                         s = strcat(s, ":", ftos(i));
1513                         if(to_console)
1514                                 LOG_INFO(s);
1515                         if(to_eventlog)
1516                                 GameLogEcho(s);
1517                         if(to_file)
1518                                 fputs(file, strcat(s, "\n"));
1519                 }
1520         }
1521
1522         if(to_console)
1523                 LOG_INFO(":end");
1524         if(to_eventlog)
1525                 GameLogEcho(":end");
1526         if(to_file)
1527         {
1528                 fputs(file, ":end\n");
1529                 fclose(file);
1530         }
1531 }
1532
1533 void FixIntermissionClient(entity e)
1534 {
1535         if(!e.autoscreenshot) // initial call
1536         {
1537                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1538                 SetResourceExplicit(e, RES_HEALTH, -2342);
1539                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1540                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1541                 {
1542                     .entity weaponentity = weaponentities[slot];
1543                         if(e.(weaponentity))
1544                         {
1545                                 e.(weaponentity).effects = EF_NODRAW;
1546                                 if (e.(weaponentity).weaponchild)
1547                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1548                         }
1549                 }
1550                 if(IS_REAL_CLIENT(e))
1551                 {
1552                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1553                         RandomSelection_Init();
1554                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1555                                 RandomSelection_AddString(it, 1, 1);
1556                         });
1557                         if (RandomSelection_chosen_string != "")
1558                         {
1559                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1560                         }
1561                         msg_entity = e;
1562                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1563                 }
1564         }
1565 }
1566
1567 /*
1568 go to the next level for deathmatch
1569 only called if a time or frag limit has expired
1570 */
1571 void NextLevel()
1572 {
1573         game_stopped = true;
1574         intermission_running = 1; // game over
1575
1576         // enforce a wait time before allowing changelevel
1577         if(player_count > 0)
1578                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1579         else
1580                 intermission_exittime = -1;
1581
1582         /*
1583         WriteByte (MSG_ALL, SVC_CDTRACK);
1584         WriteByte (MSG_ALL, 3);
1585         WriteByte (MSG_ALL, 3);
1586         // done in FixIntermission
1587         */
1588
1589         //pos = FindIntermission ();
1590
1591         VoteReset();
1592
1593         DumpStats(true);
1594
1595         // send statistics
1596         PlayerStats_GameReport(true);
1597         WeaponStats_Shutdown();
1598
1599         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1600
1601         if(autocvar_sv_eventlog)
1602                 GameLogEcho(":gameover");
1603
1604         GameLogClose();
1605
1606         FOREACH_CLIENT(IS_PLAYER(it), {
1607                 FixIntermissionClient(it);
1608                 if(it.winning)
1609                         bprint(playername(it, false), " ^7wins.\n");
1610         });
1611
1612         target_music_kill();
1613
1614         if(autocvar_g_campaign)
1615                 CampaignPreIntermission();
1616
1617         MUTATOR_CALLHOOK(MatchEnd);
1618
1619         localcmd("\nsv_hook_gameend\n");
1620 }
1621
1622
1623 float InitiateSuddenDeath()
1624 {
1625         // Check first whether normal overtimes could be added before initiating suddendeath mode
1626         // - for this timelimit_overtime needs to be >0 of course
1627         // - also check the winning condition calculated in the previous frame and only add normal overtime
1628         //   again, if at the point at which timelimit would be extended again, still no winner was found
1629         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1630                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1631                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1632         {
1633                 return 1; // need to call InitiateOvertime later
1634         }
1635         else
1636         {
1637                 if(!checkrules_suddendeathend)
1638                 {
1639                         if(autocvar_g_campaign)
1640                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1641                         else
1642                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1643                         if(g_race && !g_race_qualifying)
1644                                 race_StartCompleting();
1645                 }
1646                 return 0;
1647         }
1648 }
1649
1650 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1651 {
1652         ++checkrules_overtimesadded;
1653         //add one more overtime by simply extending the timelimit
1654         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1655         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1656 }
1657
1658 float GetWinningCode(float fraglimitreached, float equality)
1659 {
1660         if(autocvar_g_campaign == 1)
1661         {
1662                 if(fraglimitreached)
1663                         return WINNING_YES;
1664                 else
1665                         return WINNING_NO;
1666         }
1667         else
1668         {
1669                 if(equality)
1670                 {
1671                         if(fraglimitreached)
1672                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1673                         else
1674                                 return WINNING_NEVER;
1675                 }
1676                 else
1677                 {
1678                         if(fraglimitreached)
1679                                 return WINNING_YES;
1680                         else
1681                                 return WINNING_NO;
1682                 }
1683         }
1684 }
1685
1686 // set the .winning flag for exactly those players with a given field value
1687 void SetWinners(.float field, float value)
1688 {
1689         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1690 }
1691
1692 // set the .winning flag for those players with a given field value
1693 void AddWinners(.float field, float value)
1694 {
1695         FOREACH_CLIENT(IS_PLAYER(it), {
1696                 if(it.(field) == value)
1697                         it.winning = 1;
1698         });
1699 }
1700
1701 // clear the .winning flags
1702 void ClearWinners()
1703 {
1704         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1705 }
1706
1707 void ShuffleMaplist()
1708 {
1709         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1710 }
1711
1712 int fragsleft_last;
1713 float WinningCondition_Scores(float limit, float leadlimit)
1714 {
1715         // TODO make everything use THIS winning condition (except LMS)
1716         WinningConditionHelper(NULL);
1717
1718         if(teamplay)
1719         {
1720                 for (int i = 1; i < 5; ++i)
1721                 {
1722                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1723                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1724                 }
1725         }
1726
1727         ClearWinners();
1728         if(WinningConditionHelper_winner)
1729                 WinningConditionHelper_winner.winning = 1;
1730         if(WinningConditionHelper_winnerteam >= 0)
1731                 SetWinners(team, WinningConditionHelper_winnerteam);
1732
1733         if(WinningConditionHelper_lowerisbetter)
1734         {
1735                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1736                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1737                 limit = -limit;
1738         }
1739
1740         if(WinningConditionHelper_zeroisworst)
1741                 leadlimit = 0; // not supported in this mode
1742
1743         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1744         {
1745                 float fragsleft;
1746                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1747                 {
1748                         fragsleft = 1;
1749                 }
1750                 else
1751                 {
1752                         fragsleft = FLOAT_MAX;
1753                         float leadingfragsleft = FLOAT_MAX;
1754                         if (limit)
1755                                 fragsleft = limit - WinningConditionHelper_topscore;
1756                         if (leadlimit)
1757                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1758
1759                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1760                                 fragsleft = max(fragsleft, leadingfragsleft);
1761                         else
1762                                 fragsleft = min(fragsleft, leadingfragsleft);
1763                 }
1764
1765                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1766                 {
1767                         if (fragsleft == 1)
1768                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1769                         else if (fragsleft == 2)
1770                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1771                         else if (fragsleft == 3)
1772                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1773
1774                         fragsleft_last = fragsleft;
1775                 }
1776         }
1777
1778         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1779         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1780
1781         bool limit_reached;
1782         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1783         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1784                 limit_reached = (fraglimit_reached && leadlimit_reached);
1785         else
1786                 limit_reached = (fraglimit_reached || leadlimit_reached);
1787
1788         return GetWinningCode(
1789                 WinningConditionHelper_topscore && limit_reached,
1790                 WinningConditionHelper_equality
1791         );
1792 }
1793
1794 float WinningCondition_RanOutOfSpawns()
1795 {
1796         if(have_team_spawns <= 0)
1797                 return WINNING_NO;
1798
1799         if(!autocvar_g_spawn_useallspawns)
1800                 return WINNING_NO;
1801
1802         if(!some_spawn_has_been_used)
1803                 return WINNING_NO;
1804
1805         for (int i = 1; i < 5; ++i)
1806         {
1807                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1808         }
1809
1810         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1811         {
1812                 if (Team_IsValidTeam(it.team))
1813                 {
1814                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1815                 }
1816         });
1817
1818         IL_EACH(g_spawnpoints, true,
1819         {
1820                 if (Team_IsValidTeam(it.team))
1821                 {
1822                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1823                 }
1824         });
1825
1826         ClearWinners();
1827         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1828         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1829         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1830         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1831         if(team1_score + team2_score + team3_score + team4_score == 0)
1832         {
1833                 checkrules_equality = true;
1834                 return WINNING_YES;
1835         }
1836         else if(team1_score + team2_score + team3_score + team4_score == 1)
1837         {
1838                 float t, i;
1839                 if(team1_score)
1840                         t = 1;
1841                 else if(team2_score)
1842                         t = 2;
1843                 else if(team3_score)
1844                         t = 3;
1845                 else // if(team4_score)
1846                         t = 4;
1847                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1848                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1849                 {
1850                         for (int j = 1; j <= NUM_TEAMS; ++j)
1851                         {
1852                                 if (t == j)
1853                                 {
1854                                         continue;
1855                                 }
1856                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1857                                 {
1858                                         continue;
1859                                 }
1860                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1861                         }
1862                 }
1863
1864                 AddWinners(team, t);
1865                 return WINNING_YES;
1866         }
1867         else
1868                 return WINNING_NO;
1869 }
1870
1871 /*
1872 ============
1873 CheckRules_World
1874
1875 Exit deathmatch games upon conditions
1876 ============
1877 */
1878 void CheckRules_World()
1879 {
1880         VoteThink();
1881         MapVote_Think();
1882
1883         SetDefaultAlpha();
1884
1885         if (intermission_running) // someone else quit the game already
1886         {
1887                 if(player_count == 0) // Nobody there? Then let's go to the next map
1888                         MapVote_Start();
1889                         // this will actually check the player count in the next frame
1890                         // again, but this shouldn't hurt
1891                 return;
1892         }
1893
1894         float timelimit = autocvar_timelimit * 60;
1895         float fraglimit = autocvar_fraglimit;
1896         float leadlimit = autocvar_leadlimit;
1897         if (leadlimit < 0) leadlimit = 0;
1898
1899         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1900         {
1901                 if(timelimit > 0)
1902                         timelimit = 0; // timelimit is not made for warmup
1903                 if(fraglimit > 0)
1904                         fraglimit = 0; // no fraglimit for now
1905                 leadlimit = 0; // no leadlimit for now
1906         }
1907
1908         if(timelimit > 0)
1909         {
1910                 timelimit += game_starttime;
1911         }
1912         else if (timelimit < 0)
1913         {
1914                 // endmatch
1915                 NextLevel();
1916                 return;
1917         }
1918
1919         float wantovertime;
1920         wantovertime = 0;
1921
1922         if(checkrules_suddendeathend)
1923         {
1924                 if(!checkrules_suddendeathwarning)
1925                 {
1926                         checkrules_suddendeathwarning = true;
1927                         if(g_race && !g_race_qualifying)
1928                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1929                         else
1930                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1931                 }
1932         }
1933         else
1934         {
1935                 if (timelimit && time >= timelimit)
1936                 {
1937                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1938                         {
1939                                 float totalplayers;
1940                                 float playerswithlaps;
1941                                 float readyplayers;
1942                                 totalplayers = playerswithlaps = readyplayers = 0;
1943                                 FOREACH_CLIENT(IS_PLAYER(it), {
1944                                         ++totalplayers;
1945                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1946                                                 ++playerswithlaps;
1947                                         if(it.ready)
1948                                                 ++readyplayers;
1949                                 });
1950
1951                                 // at least 2 of the players have completed a lap: start the RACE
1952                                 // otherwise, the players should end the qualifying on their own
1953                                 if(readyplayers || playerswithlaps >= 2)
1954                                 {
1955                                         checkrules_suddendeathend = 0;
1956                                         ReadyRestart(); // go to race
1957                                         return;
1958                                 }
1959                                 else
1960                                         wantovertime |= InitiateSuddenDeath();
1961                         }
1962                         else
1963                                 wantovertime |= InitiateSuddenDeath();
1964                 }
1965         }
1966
1967         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1968         {
1969                 NextLevel();
1970                 return;
1971         }
1972
1973         int checkrules_status = WinningCondition_RanOutOfSpawns();
1974         if(checkrules_status == WINNING_YES)
1975                 bprint("Hey! Someone ran out of spawns!\n");
1976         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1977                 checkrules_status = M_ARGV(0, float);
1978         else
1979                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1980
1981         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1982         {
1983                 checkrules_status = WINNING_NEVER;
1984                 checkrules_overtimesadded = -1;
1985                 wantovertime |= InitiateSuddenDeath();
1986         }
1987
1988         if(checkrules_status == WINNING_NEVER)
1989                 // equality cases! Nobody wins if the overtime ends in a draw.
1990                 ClearWinners();
1991
1992         if(wantovertime)
1993         {
1994                 if(checkrules_status == WINNING_NEVER)
1995                         InitiateOvertime();
1996                 else
1997                         checkrules_status = WINNING_YES;
1998         }
1999
2000         if(checkrules_suddendeathend)
2001                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2002                         checkrules_status = WINNING_YES;
2003
2004         if(checkrules_status == WINNING_YES)
2005         {
2006                 //print("WINNING\n");
2007                 NextLevel();
2008         }
2009 }
2010
2011 string GotoMap(string m)
2012 {
2013         m = GameTypeVote_MapInfo_FixName(m);
2014         if (!m)
2015                 return "The map you suggested is not available on this server.";
2016         if (!autocvar_sv_vote_gametype)
2017         if(!MapInfo_CheckMap(m))
2018                 return "The map you suggested does not support the current game mode.";
2019         cvar_set("nextmap", m);
2020         cvar_set("timelimit", "-1");
2021         if(mapvote_initialized || alreadychangedlevel)
2022         {
2023                 if(DoNextMapOverride(0))
2024                         return "Map switch initiated.";
2025                 else
2026                         return "Hm... no. For some reason I like THIS map more.";
2027         }
2028         else
2029                 return "Map switch will happen after scoreboard.";
2030 }
2031
2032 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2033 void RunThink(entity this)
2034 {
2035         // don't let things stay in the past.
2036         // it is possible to start that way by a trigger with a local time.
2037         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2038                 return;
2039
2040         float oldtime = time; // do we need to save this?
2041
2042         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2043         {
2044                 time = max(oldtime, this.nextthink);
2045                 this.nextthink = 0;
2046
2047                 if(getthink(this))
2048                         getthink(this)(this);
2049                 // mods often set nextthink to time to cause a think every frame,
2050                 // we don't want to loop in that case, so exit if the new nextthink is
2051                 // <= the time the qc was told, also exit if it is past the end of the
2052                 // frame
2053                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2054                         break;
2055         }
2056
2057         time = oldtime;
2058 }
2059
2060 bool autocvar_sv_freezenonclients;
2061 bool autocvar_sv_gameplayfix_delayprojectiles = false;
2062 void Physics_Frame()
2063 {
2064         if(autocvar_sv_freezenonclients)
2065                 return;
2066
2067         IL_EACH(g_moveables, true,
2068         {
2069                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2070                         continue;
2071
2072                 //set_movetype(it, it.move_movetype);
2073                 // inline the set_movetype function, since this is called a lot
2074                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2075
2076                 if(it.move_movetype == MOVETYPE_NONE)
2077                         continue;
2078
2079                 if(it.move_qcphysics)
2080                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2081
2082                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2083                 {
2084                         // handle thinking here
2085                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2086                                 RunThink(it);
2087                 }
2088         });
2089
2090         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2091                 return;
2092
2093         IL_EACH(g_moveables, it.move_qcphysics,
2094         {
2095                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2096                         continue;
2097                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2098         });
2099 }
2100
2101 void systems_update();
2102 void EndFrame()
2103 {
2104         anticheat_endframe();
2105
2106         Physics_Frame();
2107
2108         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2109                 entity e = IS_SPEC(it) ? it.enemy : it;
2110                 if (e.typehitsound) {
2111                         STAT(TYPEHIT_TIME, it) = time;
2112                 } else if (e.killsound) {
2113                         STAT(KILL_TIME, it) = time;
2114                 } else if (e.damage_dealt) {
2115                         STAT(HIT_TIME, it) = time;
2116                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2117                 }
2118         });
2119         // add 1 frametime because after this, engine SV_Physics
2120         // increases time by a frametime and then networks the frame
2121         // add another frametime because client shows everything with
2122         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2123         // needed!
2124         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2125         FOREACH_CLIENT(true, {
2126                 it.typehitsound = false;
2127                 it.damage_dealt = 0;
2128                 it.killsound = false;
2129                 antilag_record(it, CS(it), altime);
2130         });
2131         IL_EACH(g_monsters, true,
2132         {
2133                 antilag_record(it, it, altime);
2134         });
2135         IL_EACH(g_projectiles, it.classname == "nade",
2136         {
2137                 antilag_record(it, it, altime);
2138         });
2139         systems_update();
2140         IL_ENDFRAME();
2141 }
2142
2143
2144 /*
2145  * RedirectionThink:
2146  * returns true if redirecting
2147  */
2148 float redirection_timeout;
2149 float redirection_nextthink;
2150 float RedirectionThink()
2151 {
2152         float clients_found;
2153
2154         if(redirection_target == "")
2155                 return false;
2156
2157         if(!redirection_timeout)
2158         {
2159                 cvar_set("sv_public", "-2");
2160                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2161                 if(redirection_target == "self")
2162                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2163                 else
2164                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2165         }
2166
2167         if(time < redirection_nextthink)
2168                 return true;
2169
2170         redirection_nextthink = time + 1;
2171
2172         clients_found = 0;
2173         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2174                 // TODO add timer
2175                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2176                 if(redirection_target == "self")
2177                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2178                 else
2179                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2180                 ++clients_found;
2181         });
2182
2183         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2184
2185         if(time > redirection_timeout || clients_found == 0)
2186                 localcmd("\nwait; wait; wait; quit\n");
2187
2188         return true;
2189 }
2190
2191 void RestoreGame()
2192 {
2193         // Loaded from a save game
2194         // some things then break, so let's work around them...
2195
2196         // Progs DB (capture records)
2197         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2198
2199         // Mapinfo
2200         MapInfo_Shutdown();
2201         MapInfo_Enumerate();
2202         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2203         WeaponStats_Init();
2204
2205         TargetMusic_RestoreGame();
2206 }
2207
2208 void Shutdown()
2209 {
2210         game_stopped = 2;
2211
2212         if(world_initialized > 0)
2213         {
2214                 world_initialized = 0;
2215                 LOG_TRACE("Saving persistent data...");
2216                 Ban_SaveBans();
2217
2218                 // playerstats with unfinished match
2219                 PlayerStats_GameReport(false);
2220
2221                 if(!cheatcount_total)
2222                 {
2223                         if(autocvar_sv_db_saveasdump)
2224                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2225                         else
2226                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2227                 }
2228                 if(autocvar_developer > 0)
2229                 {
2230                         if(autocvar_sv_db_saveasdump)
2231                                 db_dump(TemporaryDB, "server-temp.db");
2232                         else
2233                                 db_save(TemporaryDB, "server-temp.db");
2234                 }
2235                 CheatShutdown(); // must be after cheatcount check
2236                 db_close(ServerProgsDB);
2237                 db_close(TemporaryDB);
2238                 LOG_TRACE("Saving persistent data... done!");
2239                 // tell the bot system the game is ending now
2240                 bot_endgame();
2241
2242                 WeaponStats_Shutdown();
2243                 MapInfo_Shutdown();
2244         }
2245         else if(world_initialized == 0)
2246         {
2247                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2248         }
2249         else
2250         {
2251                 __init_dedicated_server_shutdown();
2252         }
2253 }