c5abb52f592ed30d817fa21574035e64b9f7a207
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 entity pingplreport;
2 void PingPLReport_Think()
3 {
4         float delta;
5         entity e;
6
7         delta = 3 / maxclients;
8         if(delta < sys_frametime)
9                 delta = 0;
10         self.nextthink = time + delta;
11
12         e = edict_num(self.cnt + 1);
13         if(clienttype(e) == CLIENTTYPE_REAL)
14         {
15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
17                 WriteByte(MSG_BROADCAST, self.cnt);
18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
21         }
22         else
23         {
24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
26                 WriteByte(MSG_BROADCAST, self.cnt);
27                 WriteShort(MSG_BROADCAST, 0);
28                 WriteByte(MSG_BROADCAST, 0);
29                 WriteByte(MSG_BROADCAST, 0);
30         }
31         self.cnt = mod(self.cnt + 1, maxclients);
32 }
33 void PingPLReport_Spawn()
34 {
35         pingplreport = spawn();
36         pingplreport.classname = "pingplreport";
37         pingplreport.think = PingPLReport_Think;
38         pingplreport.nextthink = time;
39 }
40
41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
42 string redirection_target;
43 float world_initialized;
44
45 string GetMapname();
46 string GetGametype();
47 void GotoNextMap();
48 void ShuffleMaplist()
49 float() DoNextMapOverride;
50
51 void SetDefaultAlpha()
52 {
53         if(cvar("g_running_guns"))
54         {
55                 default_player_alpha = -1;
56                 default_weapon_alpha = +1;
57         }
58         else if(g_cloaked)
59         {
60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
61                 default_weapon_alpha = default_player_alpha;
62         }
63         else
64         {
65                 default_player_alpha = cvar("g_player_alpha");
66                 if(default_player_alpha == 0)
67                         default_player_alpha = 1;
68                 default_weapon_alpha = default_player_alpha;
69         }
70 }
71
72 void fteqcc_testbugs()
73 {
74         float a, b;
75
76         if(!cvar("developer_fteqccbugs"))
77                 return;
78
79         dprint("*** fteqcc test: checking for bugs...\n");
80
81         a = 1;
82         b = 5;
83         if(sqrt(a) - sqrt(b - a) == 0)
84                 dprint("*** fteqcc test: found same-function-twice bug\n");
85         else
86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
87
88         world.cnt = -10;
89         world.enemy = world;
90         world.enemy.cnt += 10;
91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
92                 dprint("*** fteqcc test: found += bug\n");
93         else
94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
95         world.cnt = 0;
96 }
97
98 /**
99  * Takes care of pausing and unpausing the game.
100  * Centerprints the information about an upcoming or active timeout to all active
101  * players. Also plays reminder sounds.
102  */
103 void timeoutHandler_Think() {
104         local string timeStr;
105         local entity plr;
106         if (timeoutStatus == 1) {
107                 if (remainingLeadTime > 0) {
108                         //centerprint the information to every player
109                         timeStr = getTimeoutText(0);
110                         FOR_EACH_REALCLIENT(plr) {
111                                 if(plr.classname == "player") {
112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
113                                 }
114                         }
115                         remainingLeadTime -= 1;
116                         //think again in 1 second:
117                         self.nextthink = time + 1;
118                 }
119                 else {
120                         //now pause the game:
121                         timeoutStatus = 2;
122                         //reset all the flood variables
123                         FOR_EACH_CLIENT(plr) {
124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
125                         }
126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
128                         FOR_EACH_REALPLAYER(plr) {
129                                 plr.lastV_angle = plr.v_angle;
130                         }
131                         self.nextthink = time;
132                 }
133         }
134         else if (timeoutStatus == 2) {
135                 if (remainingTimeoutTime > 0) {
136                         timeStr = getTimeoutText(0);
137                         FOR_EACH_REALCLIENT(plr) {
138                                 if(plr.classname == "player") {
139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
140                                 }
141                         }
142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
143                                 Announce("prepareforbattle");
144                         }
145                         remainingTimeoutTime -= 1;
146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
147                 }
148                 else {
149                         //unpause the game again
150                         remainingTimeoutTime = timeoutStatus = 0;
151                         cvar_set("slowmo", ftos(orig_slowmo));
152                         //and unlock the fixed view again once there is no timeout active anymore
153                         FOR_EACH_REALPLAYER(plr) {
154                                 plr.fixangle = FALSE;
155                         }
156                         //get rid of the countdown message
157                         FOR_EACH_REALCLIENT(plr) {
158                                 if(plr.classname == "player") {
159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
160                                 }
161                         }
162                         remove(self);
163                         return;
164                 }
165
166         }
167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
168                 FOR_EACH_REALCLIENT(plr) {
169                         if(plr.classname == "player") {
170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
171                         }
172                 }
173                 remove(self);
174                 return;
175         }
176 }
177
178 void GotoFirstMap()
179 {
180         float n;
181         if(cvar("_sv_init"))
182         {
183                 // cvar_set("_sv_init", "0");
184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
185                 // to this "init" map on a dedicated server will cause no permanent
186                 // harm
187                 if(cvar("g_maplist_shuffle"))
188                         ShuffleMaplist();
189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
191
192                 MapInfo_Enumerate();
193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
194
195                 if(!DoNextMapOverride())
196                         GotoNextMap();
197
198                 return;
199         }
200
201         if(time < 5)
202         {
203                 self.nextthink = time;
204         }
205         else
206         {
207                 self.nextthink = time + 1;
208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
209         }
210 }
211
212 void cvar_changes_init()
213 {
214         float h;
215         string k, v, d;
216         float n, i, adding, pureadding;
217
218         if(cvar_changes)
219                 strunzone(cvar_changes);
220         cvar_changes = string_null;
221         if(cvar_purechanges)
222                 strunzone(cvar_purechanges);
223         cvar_purechanges = string_null;
224         cvar_purechanges_count = 0;
225
226         h = buf_create();
227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
228         n = buf_getsize(h);
229
230         adding = TRUE;
231         pureadding = TRUE;
232
233         for(i = 0; i < n; ++i)
234         {
235                 k = bufstr_get(h, i);
236
237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
238 #define BADCVAR(p) if(k == p) continue
239                 // internal
240                 BADPREFIX("csqc_");
241                 BADPREFIX("cvar_check_");
242                 BADCVAR("gamecfg");
243                 BADCVAR("g_configversion");
244                 BADCVAR("g_maplist_index");
245                 BADCVAR("halflifebsp");
246                 BADPREFIX("sv_world");
247
248                 // client
249                 BADPREFIX("chase_");
250                 BADPREFIX("cl_");
251                 BADPREFIX("con_");
252                 BADPREFIX("scoreboard_");
253                 BADPREFIX("g_campaign");
254                 BADPREFIX("gl_");
255                 BADPREFIX("joy");
256                 BADPREFIX("hud_");
257                 BADPREFIX("menu_");
258                 BADPREFIX("net_slist_");
259                 BADPREFIX("r_");
260                 BADPREFIX("sbar_");
261                 BADPREFIX("scr_");
262                 BADPREFIX("snd_");
263                 BADPREFIX("userbind");
264                 BADPREFIX("v_");
265                 BADPREFIX("vid_");
266                 BADPREFIX("crosshair");
267                 BADCVAR("mod_q3bsp_lightmapmergepower");
268                 BADCVAR("mod_q3bsp_nolightmaps");
269                 BADCVAR("fov");
270                 BADCVAR("mastervolume");
271                 BADCVAR("volume");
272                 BADCVAR("bgmvolume");
273
274                 // private
275                 BADCVAR("serverconfig");
276                 BADPREFIX("g_ban_");
277                 BADPREFIX("g_chat_flood_");
278                 BADPREFIX("g_voice_flood_");
279                 BADPREFIX("rcon_");
280                 BADPREFIX("settemp_");
281                 BADPREFIX("sv_allowdownloads_");
282                 BADPREFIX("sv_autodemo");
283                 BADPREFIX("sv_curl_");
284                 BADPREFIX("sv_eventlog");
285                 BADPREFIX("sv_logscores_");
286                 BADPREFIX("sv_master");
287                 BADCVAR("g_banned_list");
288                 BADCVAR("log_dest_udp");
289                 BADCVAR("log_file");
290                 BADCVAR("net_address");
291                 BADCVAR("port");
292                 BADCVAR("savedgamecfg");
293                 BADCVAR("sv_heartbeatperiod");
294                 BADCVAR("sv_vote_master_password");
295                 BADCVAR("sys_colortranslation");
296                 BADCVAR("sys_specialcharactertranslation");
297                 BADCVAR("timestamps");
298                 BADCVAR("net_address");
299                 BADCVAR("net_address_ipv6");
300                 BADPREFIX("sv_weaponstats_");
301                 BADCVAR("developer");
302                 BADPREFIX("developer_");
303
304                 // mapinfo
305                 BADCVAR("timelimit");
306                 BADCVAR("fraglimit");
307                 BADCVAR("leadlimit");
308                 BADCVAR("g_tdm_teams");
309                 BADCVAR("g_keyhunt_teams");
310                 BADCVAR("g_domination_default_teams");
311                 BADCVAR("g_race_qualifying_timelimit");
312                 BADCVAR("g_lms");
313                 BADCVAR("g_arena");
314                 BADCVAR("g_ca");
315                 BADCVAR("g_assault");
316                 BADCVAR("g_ctf");
317                 BADCVAR("g_dm");
318                 BADCVAR("g_domination");
319                 BADCVAR("g_keyhunt");
320                 BADCVAR("g_keyhunt_teams");
321                 BADCVAR("g_onslaught");
322                 BADCVAR("g_race");
323                 BADCVAR("g_cts");
324                 BADCVAR("g_runematch");
325                 BADCVAR("g_tdm");
326                 BADCVAR("g_nexball");
327                 BADCVAR("teamplay");
328
329                 // long
330                 BADCVAR("hostname");
331                 BADCVAR("g_maplist");
332                 BADCVAR("g_maplist_mostrecent");
333                 BADCVAR("sv_motd");
334
335                 v = cvar_string(k);
336                 d = cvar_defstring(k);
337                 if(v == d)
338                         continue;
339
340                 if(adding)
341                 {
342                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
343                         if(strlen(cvar_changes) > 16384)
344                         {
345                                 cvar_changes = "// too many settings have been changed to show them here\n";
346                                 adding = 0;
347                         }
348                 }
349
350                 // now check if the changes are actually gameplay relevant
351
352                 // does nothing visible
353                 BADCVAR("captureleadlimit_override");
354                 BADCVAR("g_arena_point_leadlimit");
355                 BADCVAR("g_ca_point_leadlimit");
356                 BADCVAR("g_ctf_capture_leadlimit");
357                 BADCVAR("g_domination_point_leadlimit");
358                 BADCVAR("g_keyhunt_point_leadlimit");
359                 BADCVAR("g_nexball_goalleadlimit");
360                 BADCVAR("g_runematch_point_leadlimit");
361                 BADCVAR("leadlimit_and_fraglimit");
362                 BADCVAR("leadlimit_override");
363                 BADCVAR("sv_checkforpacketsduringsleep");
364                 BADPREFIX("crypto_");
365                 BADPREFIX("g_chat_");
366                 BADPREFIX("prvm_");
367                 BADPREFIX("sv_fragmessage_");
368                 BADPREFIX("sv_vote_");
369                 BADPREFIX("timelimit_");
370
371                 // allowed changes to server admins (please sync this to server.cfg)
372                 // vi commands:
373                 //   :/"impure"/,$d
374                 //   :g!,^\/\/[^ /],d
375                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
376                 //   :%!sort
377                 // yes, this does contain some redundant stuff, don't really care
378                 BADCVAR("bot_number");
379                 BADCVAR("bot_prefix");
380                 BADCVAR("bot_suffix");
381                 BADCVAR("capturelimit_override");
382                 BADCVAR("fraglimit_override");
383                 BADCVAR("gametype");
384                 BADCVAR("g_antilag");
385                 BADCVAR("g_balance_teams");
386                 BADCVAR("g_balance_teams_force");
387                 BADCVAR("g_ban_sync_trusted_servers");
388                 BADCVAR("g_ban_sync_uri");
389                 BADCVAR("g_ctf_capture_limit");
390                 BADCVAR("g_ctf_ignore_frags");
391                 BADCVAR("g_ctf_win_mode");
392                 BADCVAR("g_domination_point_limit");
393                 BADCVAR("g_fullbrightitems");
394                 BADCVAR("g_fullbrightplayers");
395                 BADCVAR("g_keyhunt_point_limit");
396                 BADCVAR("g_keyhunt_teams_override");
397                 BADCVAR("g_lms_lives_override");
398                 BADCVAR("g_maplist");
399                 BADCVAR("g_maplist_check_waypoints");
400                 BADCVAR("g_maplist_mostrecent_count");
401                 BADCVAR("g_maplist_shuffle");
402                 BADCVAR("g_maplist_votable");
403                 BADCVAR("g_maplist_votable_abstain");
404                 BADCVAR("g_maplist_votable_nodetail");
405                 BADCVAR("g_maplist_votable_suggestions");
406                 BADCVAR("g_minstagib");
407                 BADCVAR("g_nexball_goallimit");
408                 BADCVAR("g_runematch_point_limit");
409                 BADCVAR("g_start_delay");
410                 BADCVAR("hostname");
411                 BADCVAR("log_file");
412                 BADCVAR("maxplayers");
413                 BADCVAR("minplayers");
414                 BADCVAR("net_address");
415                 BADCVAR("port");
416                 BADCVAR("rcon_password");
417                 BADCVAR("rcon_restricted_commands");
418                 BADCVAR("rcon_restricted_password");
419                 BADCVAR("skill");
420                 BADCVAR("sv_adminnick");
421                 BADCVAR("sv_autoscreenshot");
422                 BADCVAR("sv_curl_defaulturl");
423                 BADCVAR("sv_defaultcharacter");
424                 BADCVAR("sv_defaultplayermodel");
425                 BADCVAR("sv_defaultplayerskin");
426                 BADCVAR("sv_maxidle");
427                 BADCVAR("sv_maxrate");
428                 BADCVAR("sv_motd");
429                 BADCVAR("sv_public");
430                 BADCVAR("sv_ready_restart");
431                 BADCVAR("sv_status_privacy");
432                 BADCVAR("sv_vote_call");
433                 BADCVAR("sv_vote_commands");
434                 BADCVAR("sv_vote_majority_factor");
435                 BADCVAR("sv_vote_master");
436                 BADCVAR("sv_vote_master_commands");
437                 BADCVAR("sv_vote_master_password");
438                 BADCVAR("sv_vote_simple_majority_factor");
439                 BADCVAR("timelimit_override");
440 #undef BADPREFIX
441 #undef BADCVAR
442
443                 if(pureadding)
444                 {
445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
446                         if(strlen(cvar_purechanges) > 16384)
447                         {
448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
449                                 pureadding = 0;
450                         }
451                 }
452                 ++cvar_purechanges_count;
453                 // WARNING: this variable is used for the server list
454                 // NEVER dare to skip this code!
455                 // Hacks to intentionally appearing as "pure server" even though you DO have
456                 // modified settings may be punished by removal from the server list.
457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
458                 // though.
459         }
460         buf_del(h);
461         if(cvar_changes == "")
462                 cvar_changes = "// this server runs at default server settings\n";
463         else
464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
465         cvar_changes = strzone(cvar_changes);
466         if(cvar_purechanges == "")
467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
468         else
469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
470         cvar_purechanges = strzone(cvar_purechanges);
471 }
472
473 void detect_maptype()
474 {
475 #if 0
476         vector o, v;
477         float i;
478
479         for(;;)
480         {
481                 o = world.mins;
482                 o_x += random() * (world.maxs_x - world.mins_x);
483                 o_y += random() * (world.maxs_y - world.mins_y);
484                 o_z += random() * (world.maxs_z - world.mins_z);
485
486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
487                 if(trace_fraction == 1)
488                         continue;
489
490                 v = trace_endpos;
491
492                 for(i = 0; i < 64; i += 4)
493                 {
494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
495         if(trace_fraction == 1)
496                 continue;
497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
498                 }
499
500                 break;
501         }
502 #endif
503 }
504
505 entity randomseed;
506 float RandomSeed_Send(entity to, float sf)
507 {
508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
509         WriteShort(MSG_ENTITY, self.cnt);
510         return TRUE;
511 }
512 void RandomSeed_Think()
513 {
514         self.cnt = bound(0, floor(random() * 65536), 65535);
515         self.nextthink = time + 5;
516
517         self.SendFlags |= 1;
518 }
519 void RandomSeed_Spawn()
520 {
521         randomseed = spawn();
522         randomseed.think = RandomSeed_Think;
523         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
524
525         entity oldself;
526         oldself = self;
527         self = randomseed;
528         self.think(); // sets random seed and nextthink
529         self = oldself;
530 }
531
532 void spawnfunc___init_dedicated_server(void)
533 {
534         // handler for _init/_init map (only for dedicated server initialization)
535
536         world_initialized = -1; // don't complain
537         cvar = cvar_normal;
538         cvar_string = cvar_string_normal;
539         cvar_set = cvar_set_normal;
540
541         remove = remove_unsafely;
542
543         entity e;
544         e = spawn();
545         e.think = GotoFirstMap;
546         e.nextthink = time; // this is usually 1 at this point
547
548         e = spawn();
549         e.classname = "info_player_deathmatch"; // safeguard against player joining
550
551         self.classname = "worldspawn"; // safeguard against various stuff ;)
552
553         MapInfo_Enumerate();
554         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
555 }
556
557 void Map_MarkAsRecent(string m);
558 float world_already_spawned;
559 void RegisterWeapons();
560 void Nagger_Init();
561 void ClientInit_Spawn();
562 void WeaponStats_Init();
563 void WeaponStats_Shutdown();
564 void spawnfunc_worldspawn (void)
565 {
566         float fd, l, i, j, n;
567         string s, col;
568
569         cvar = cvar_normal;
570         cvar_string = cvar_string_normal;
571         cvar_set = cvar_set_normal;
572
573         if(world_already_spawned)
574                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
575         world_already_spawned = TRUE;
576
577         remove = remove_safely; // during spawning, watch what you remove!
578
579         check_unacceptable_compiler_bugs();
580
581         cvar_changes_init(); // do this very early now so it REALLY matches the server config
582
583         compressShortVector_init();
584
585         allowed_to_spawn = TRUE;
586
587         local entity head;
588         head = nextent(world);
589         maxclients = 0;
590         while(head)
591         {
592                 ++maxclients;
593                 head = nextent(head);
594         }
595
596         // needs to be done so early as they would still spawn
597         RegisterWeapons();
598
599         ServerProgsDB = db_load("server.db");
600
601         TemporaryDB = db_create();
602
603         /*
604         TODO sound pack system
605         // initialize sound pack system
606         soundpack = cvar_string("g_soundpack");
607         if(soundpack != "")
608                 soundpack = strcat(soundpack, "/");
609         soundpack = strzone(soundpack);
610         */
611
612         // 0 normal
613         lightstyle(0, "m");
614
615         // 1 FLICKER (first variety)
616         lightstyle(1, "mmnmmommommnonmmonqnmmo");
617
618         // 2 SLOW STRONG PULSE
619         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
620
621         // 3 CANDLE (first variety)
622         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
623
624         // 4 FAST STROBE
625         lightstyle(4, "mamamamamama");
626
627         // 5 GENTLE PULSE 1
628         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
629
630         // 6 FLICKER (second variety)
631         lightstyle(6, "nmonqnmomnmomomno");
632
633         // 7 CANDLE (second variety)
634         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
635
636         // 8 CANDLE (third variety)
637         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
638
639         // 9 SLOW STROBE (fourth variety)
640         lightstyle(9, "aaaaaaaazzzzzzzz");
641
642         // 10 FLUORESCENT FLICKER
643         lightstyle(10, "mmamammmmammamamaaamammma");
644
645         // 11 SLOW PULSE NOT FADE TO BLACK
646         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
647
648         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
649
650         // 63 testing
651         lightstyle(63, "a");
652
653         if(cvar("g_campaign"))
654                 CampaignPreInit();
655
656         Map_MarkAsRecent(mapname);
657
658         precache_model ("null"); // we need this one before InitGameplayMode
659         InitGameplayMode();
660         readlevelcvars();
661         GrappleHookInit();
662         ElectroInit();
663         LaserInit();
664
665         player_count = 0;
666         bot_waypoints_for_items = cvar("g_waypoints_for_items");
667         if(bot_waypoints_for_items == 1)
668                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
669                         bot_waypoints_for_items = 0;
670
671         // for setting by mapinfo
672         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
673         cvar_set("sv_q3acompat_machineshotgunswap", "0");
674
675         precache();
676
677         WaypointSprite_Init();
678
679         //if (g_domination)
680         //      dom_init();
681
682         GameLogInit(); // prepare everything
683         if(cvar("sv_eventlog"))
684         {
685                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
686                 s = strcat(s, ftos(random()));
687                 matchid = strzone(s);
688
689                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
690                 s = ":gameinfo:mutators:LIST";
691
692                 ret_string = s;
693                 MUTATOR_CALLHOOK(BuildMutatorsString);
694                 s = ret_string;
695
696                 if(cvar("g_grappling_hook"))
697                         s = strcat(s, ":grappling_hook");
698                 if(!cvar("g_use_ammunition"))
699                         s = strcat(s, ":no_use_ammunition");
700                 if(!cvar("g_pickup_items"))
701                         s = strcat(s, ":no_pickup_items");
702                 if(cvar_string("g_weaponarena") != "0")
703                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
704                 if(cvar("g_vampire"))
705                         s = strcat(s, ":vampire");
706                 if(cvar("g_laserguided_missile"))
707                         s = strcat(s, ":laserguided_missile");
708                 if(cvar("g_norecoil"))
709                         s = strcat(s, ":norecoil");
710                 if(cvar("g_midair"))
711                         s = strcat(s, ":midair");
712                 if(cvar("g_minstagib"))
713                         s = strcat(s, ":minstagib");
714                 GameLogEcho(s);
715                 GameLogEcho(":gameinfo:end");
716         }
717         else
718                 matchid = strzone(ftos(random()));
719
720         cvar_set("nextmap", "");
721
722         SetDefaultAlpha();
723
724         if(cvar("g_campaign"))
725                 CampaignPostInit();
726
727         fteqcc_testbugs();
728
729         Ban_LoadBans();
730
731         MapInfo_Enumerate();
732         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
733
734         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
735         {
736                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
737                 if(fd != -1)
738                 {
739                         while((s = fgets(fd)))
740                         {
741                                 l = tokenize_console(s);
742                                 if(l < 2)
743                                         continue;
744                                 if(argv(0) == "cd")
745                                 {
746                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
747                                         print("  cdtrack ", argv(2), "\n");
748                                 }
749                                 else if(argv(0) == "fog")
750                                 {
751                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
752                                         print("  \"fog\" \"", s, "\"\n");
753                                 }
754                                 else if(argv(0) == "set")
755                                 {
756                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
757                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
758                                 }
759                                 else if(argv(0) != "//")
760                                 {
761                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
762                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
763                                 }
764                         }
765                         fclose(fd);
766                 }
767         }
768
769         WeaponStats_Init();
770
771         addstat(STAT_WEAPONS, AS_INT, weapons);
772         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
773         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
774         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
775         Nagger_Init();
776
777         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
778         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
779         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
780         addstat(STAT_FUEL, AS_INT, ammo_fuel);
781         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
782         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
783         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
784         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
785         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
786         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
787
788         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
789
790         if(g_ca)
791         {
792                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
793                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
794         }
795         // g_movementspeed hack
796         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
797         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
798         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
799
800         next_pingtime = time + 5;
801
802         detect_maptype();
803
804         lsmaps_reply = "^7Maps available: ";
805         lsnewmaps_reply = "^7Maps without a record set: ";
806         for(i = 0, j = 0; i < MapInfo_count; ++i)
807         {
808                 if(MapInfo_Get_ByID(i))
809                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
810                         {
811                                 if(mod(i, 2))
812                                         col = "^2";
813                                 else
814                                         col = "^3";
815                                 ++j;
816                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
817                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
818                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
819                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
820                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
821                         }
822         }
823         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
824         if (!g_race && !g_cts)
825                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
826         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
827
828         maplist_reply = "^7Maps in list: ";
829         n = tokenize_console(cvar_string("g_maplist"));
830         for(i = 0, j = 0; i < n; ++i)
831         {
832                 if(MapInfo_CheckMap(argv(i)))
833                 {
834                         if(mod(j, 2))
835                                 col = "^2";
836                         else
837                                 col = "^3";
838                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
839                         ++j;
840                 }
841         }
842         maplist_reply = strzone(strcat(maplist_reply, "\n"));
843         MapInfo_ClearTemps();
844
845         for(i = 0; i < 10; ++i)
846         {
847                 records_reply[i] = strzone(getrecords(i));
848         }
849         if(g_cts)
850                 ladder_reply = strzone(getladder());
851
852         rankings_reply = strzone(getrankings());
853
854         ClientInit_Spawn();
855         RandomSeed_Spawn();
856         PingPLReport_Spawn();
857
858         CheatInit();
859
860         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
861
862         // fill sv_curl_serverpackages from .serverpackage files
863         if(cvar("sv_curl_serverpackages_auto"))
864         {
865                 fd = search_begin("*.serverpackage", TRUE, FALSE);
866                 s = "";
867                 if(fd >= 0)
868                 {
869                         j = search_getsize(fd);
870                         for(i = 0; i < j; ++i)
871                                 s = strcat(s, " ", search_getfilename(fd, i));
872                         search_end(fd);
873                 }
874                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
875         }
876
877         world_initialized = 1;
878 }
879
880 void spawnfunc_light (void)
881 {
882         //makestatic (self); // Who the f___ did that?
883         remove(self);
884 }
885
886 float TryFile( string pFilename )
887 {
888         local float lHandle;
889         dprint("TryFile(\"", pFilename, "\")\n");
890         lHandle = fopen( pFilename, FILE_READ );
891         if( lHandle != -1 ) {
892                 fclose( lHandle );
893                 return TRUE;
894         } else {
895                 return FALSE;
896         }
897 };
898
899 string GetGametype()
900 {
901         return GametypeNameFromType(game);
902 }
903
904 string getmapname_stored;
905 string GetMapname()
906 {
907         return mapname;
908 }
909
910 float Map_Count, Map_Current;
911 string Map_Current_Name;
912
913 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
914 float GetMaplistPosition()
915 {
916         float pos, idx;
917         string map;
918
919         map = GetMapname();
920         idx = cvar("g_maplist_index");
921
922         if(idx >= 0)
923                 if(idx < Map_Count)
924                         if(map == argv(idx))
925                                 return idx;
926
927         for(pos = 0; pos < Map_Count; ++pos)
928                 if(map == argv(pos))
929                         return pos;
930
931         // resume normal maplist rotation if current map is not in g_maplist
932         return idx;
933 }
934
935 float MapHasRightSize(string map)
936 {
937         float fh;
938         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
939         if(cvar("g_maplist_check_waypoints"))
940         {
941                 dprint("checkwp "); dprint(map);
942                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
943                 if(fh < 0)
944                 {
945                         dprint(": no waypoints\n");
946                         return FALSE;
947                 }
948                 dprint(": has waypoints\n");
949                 fclose(fh);
950         }
951
952         // open map size restriction file
953         dprint("opensize "); dprint(map);
954         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
955         if(fh >= 0)
956         {
957                 float mapmin, mapmax;
958                 dprint(": ok, ");
959                 mapmin = stof(fgets(fh));
960                 mapmax = stof(fgets(fh));
961                 fclose(fh);
962                 if(player_count < mapmin)
963                 {
964                         dprint("not enough\n");
965                         return FALSE;
966                 }
967                 if(player_count > mapmax)
968                 {
969                         dprint("too many\n");
970                         return FALSE;
971                 }
972                 dprint("right size\n");
973                 return TRUE;
974         }
975         dprint(": not found\n");
976         return TRUE;
977 }
978
979 string Map_Filename(float position)
980 {
981         return strcat("maps/", argv(position), ".bsp");
982 }
983
984 string strwords(string s, float w)
985 {
986         float endpos;
987         for(endpos = 0; w && endpos >= 0; --w)
988                 endpos = strstrofs(s, " ", endpos + 1);
989         if(endpos < 0)
990                 return s;
991         else
992                 return substring(s, 0, endpos);
993 }
994
995 float strhasword(string s, string w)
996 {
997         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
998 }
999
1000 void Map_MarkAsRecent(string m)
1001 {
1002         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
1003 }
1004
1005 float Map_IsRecent(string m)
1006 {
1007         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1008 }
1009
1010 float Map_Check(float position, float pass)
1011 {
1012         string filename;
1013         string map_next;
1014         map_next = argv(position);
1015         if(pass <= 1)
1016         {
1017                 if(Map_IsRecent(map_next))
1018                         return 0;
1019         }
1020         filename = Map_Filename(position);
1021         if(MapInfo_CheckMap(map_next))
1022         {
1023                 if(pass == 2)
1024                         return 1;
1025                 if(MapHasRightSize(map_next))
1026                         return 1;
1027                 return 0;
1028         }
1029         else
1030                 dprint( "Couldn't select '", filename, "'..\n" );
1031
1032         return 0;
1033 }
1034
1035 void Map_Goto_SetStr(string nextmapname)
1036 {
1037         if(getmapname_stored != "")
1038                 strunzone(getmapname_stored);
1039         if(nextmapname == "")
1040                 getmapname_stored = "";
1041         else
1042                 getmapname_stored = strzone(nextmapname);
1043 }
1044
1045 void Map_Goto_SetFloat(float position)
1046 {
1047         cvar_set("g_maplist_index", ftos(position));
1048         Map_Goto_SetStr(argv(position));
1049 }
1050
1051 void GameResetCfg()
1052 {
1053         // settings persist, except...
1054         localcmd("\nsettemp_restore\n");
1055 };
1056
1057 void Map_Goto()
1058 {
1059         GameResetCfg();
1060         MapInfo_LoadMap(getmapname_stored);
1061 }
1062
1063 // return codes of map selectors:
1064 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1065 //   -2 = permanent failure
1066 float() MaplistMethod_Iterate = // usual method
1067 {
1068         float pass, i;
1069
1070         for(pass = 1; pass <= 2; ++pass)
1071         {
1072                 for(i = 1; i < Map_Count; ++i)
1073                 {
1074                         float mapindex;
1075                         mapindex = mod(i + Map_Current, Map_Count);
1076                         if(Map_Check(mapindex, pass))
1077                                 return mapindex;
1078                 }
1079         }
1080         return -1;
1081 }
1082
1083 float() MaplistMethod_Repeat = // fallback method
1084 {
1085         if(Map_Check(Map_Current, 2))
1086                 return Map_Current;
1087         return -2;
1088 }
1089
1090 float() MaplistMethod_Random = // random map selection
1091 {
1092         float i, imax;
1093
1094         imax = 42;
1095
1096         for(i = 0; i <= imax; ++i)
1097         {
1098                 float mapindex;
1099                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1100                 if(Map_Check(mapindex, 1))
1101                         return mapindex;
1102         }
1103         return -1;
1104 }
1105
1106 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1107 // the exponent sets a bias on the map selection:
1108 // the higher the exponent, the less likely "shortly repeated" same maps are
1109 {
1110         float i, j, imax, insertpos;
1111
1112         imax = 42;
1113
1114         for(i = 0; i <= imax; ++i)
1115         {
1116                 string newlist;
1117
1118                 // now reinsert this at another position
1119                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1120                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1121                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1122                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1123
1124                 // insert the current map there
1125                 newlist = "";
1126                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1127                         newlist = strcat(newlist, " ", argv(j));
1128                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1129                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1130                         newlist = strcat(newlist, " ", argv(j));
1131                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1132                 cvar_set("g_maplist", newlist);
1133                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1134
1135                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1136                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1137                 if(Map_Check(Map_Current, 1))
1138                         return Map_Current;
1139         }
1140         return -1;
1141 }
1142
1143 void Maplist_Init()
1144 {
1145         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1146         if(Map_Count == 0)
1147         {
1148                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1149                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1150                 if(cvar("g_maplist_shuffle"))
1151                         ShuffleMaplist();
1152                 localcmd("\nmenu_cmd sync\n");
1153                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1154         }
1155         if(Map_Count == 0)
1156                 error("empty maplist, cannot select a new map");
1157         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1158
1159         if(Map_Current_Name)
1160                 strunzone(Map_Current_Name);
1161         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1162         // this may or may not be correct, but who cares, in the worst case a map
1163         // isn't chosen in the first pass that should have been
1164 }
1165
1166 string GetNextMap()
1167 {
1168         float nextMap;
1169
1170         Maplist_Init();
1171         nextMap = -1;
1172
1173         if(nextMap == -1)
1174                 if(cvar("g_maplist_shuffle") > 0)
1175                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1176
1177         if(nextMap == -1)
1178                 if(cvar("g_maplist_selectrandom"))
1179                         nextMap = MaplistMethod_Random();
1180
1181         if(nextMap == -1)
1182                 nextMap = MaplistMethod_Iterate();
1183
1184         if(nextMap == -1)
1185                 nextMap = MaplistMethod_Repeat();
1186
1187         if(nextMap >= 0)
1188         {
1189                 Map_Goto_SetFloat(nextMap);
1190                 return getmapname_stored;
1191         }
1192
1193         return "";
1194 };
1195
1196 float DoNextMapOverride()
1197 {
1198         if(cvar("g_campaign"))
1199         {
1200                 CampaignPostIntermission();
1201                 alreadychangedlevel = TRUE;
1202                 return TRUE;
1203         }
1204         if(cvar("quit_when_empty"))
1205         {
1206                 if(player_count <= currentbots)
1207                 {
1208                         localcmd("quit\n");
1209                         alreadychangedlevel = TRUE;
1210                         return TRUE;
1211                 }
1212         }
1213         if(cvar_string("quit_and_redirect") != "")
1214         {
1215                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1216                 alreadychangedlevel = TRUE;
1217                 return TRUE;
1218         }
1219         if (cvar("samelevel")) // if samelevel is set, stay on same level
1220         {
1221                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1222                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1223                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1224                 localcmd("restart\n");
1225                 //changelevel (mapname);
1226                 alreadychangedlevel = TRUE;
1227                 return TRUE;
1228         }
1229         if(cvar_string("nextmap") != "")
1230                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1231                 {
1232                         Map_Goto_SetStr(cvar_string("nextmap"));
1233                         Map_Goto();
1234                         alreadychangedlevel = TRUE;
1235                         return TRUE;
1236                 }
1237         if(cvar("lastlevel"))
1238         {
1239                 GameResetCfg();
1240                 localcmd("set lastlevel 0\ntogglemenu\n");
1241                 alreadychangedlevel = TRUE;
1242                 return TRUE;
1243         }
1244         return FALSE;
1245 };
1246
1247 void GotoNextMap()
1248 {
1249         //local string nextmap;
1250         //local float n, nummaps;
1251         //local string s;
1252         if (alreadychangedlevel)
1253                 return;
1254         alreadychangedlevel = TRUE;
1255
1256         {
1257                 string nextMap;
1258                 float allowReset;
1259
1260                 for(allowReset = 1; allowReset >= 0; --allowReset)
1261                 {
1262                         nextMap = GetNextMap();
1263                         if(nextMap != "")
1264                                 break;
1265
1266                         if(allowReset)
1267                         {
1268                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1269                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1270                                 if(cvar("g_maplist_shuffle"))
1271                                         ShuffleMaplist();
1272                                 localcmd("\nmenu_cmd sync\n");
1273                         }
1274                         else
1275                         {
1276                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1277                         }
1278                 }
1279                 Map_Goto();
1280         }
1281 };
1282
1283
1284 /*
1285 ============
1286 IntermissionThink
1287
1288 When the player presses attack or jump, change to the next level
1289 ============
1290 */
1291 .float autoscreenshot;
1292 void() MapVote_Start;
1293 void() MapVote_Think;
1294 float mapvote_initialized;
1295 void IntermissionThink()
1296 {
1297         FixIntermissionClient(self);
1298
1299         if(cvar("sv_autoscreenshot"))
1300         if(self.autoscreenshot > 0)
1301         if(time > self.autoscreenshot)
1302         {
1303                 self.autoscreenshot = -1;
1304                 if(clienttype(self) == CLIENTTYPE_REAL)
1305                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1306                 return;
1307         }
1308
1309         if (time < intermission_exittime)
1310                 return;
1311
1312         if(!mapvote_initialized)
1313                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1314                         return;
1315
1316         MapVote_Start();
1317 };
1318
1319 /*
1320 ============
1321 FindIntermission
1322
1323 Returns the entity to view from
1324 ============
1325 */
1326 /*
1327 entity FindIntermission()
1328 {
1329         local   entity spot;
1330         local   float cyc;
1331
1332 // look for info_intermission first
1333         spot = find (world, classname, "info_intermission");
1334         if (spot)
1335         {       // pick a random one
1336                 cyc = random() * 4;
1337                 while (cyc > 1)
1338                 {
1339                         spot = find (spot, classname, "info_intermission");
1340                         if (!spot)
1341                                 spot = find (spot, classname, "info_intermission");
1342                         cyc = cyc - 1;
1343                 }
1344                 return spot;
1345         }
1346
1347 // then look for the start position
1348         spot = find (world, classname, "info_player_start");
1349         if (spot)
1350                 return spot;
1351
1352 // testinfo_player_start is only found in regioned levels
1353         spot = find (world, classname, "testplayerstart");
1354         if (spot)
1355                 return spot;
1356
1357 // then look for the start position
1358         spot = find (world, classname, "info_player_deathmatch");
1359         if (spot)
1360                 return spot;
1361
1362         //objerror ("FindIntermission: no spot");
1363         return world;
1364 };
1365 */
1366
1367 /*
1368 ===============================================================================
1369
1370 RULES
1371
1372 ===============================================================================
1373 */
1374
1375 void DumpStats(float final)
1376 {
1377         local float file;
1378         local string s;
1379         local float to_console;
1380         local float to_eventlog;
1381         local float to_file;
1382         local float i;
1383
1384         to_console = cvar("sv_logscores_console");
1385         to_eventlog = cvar("sv_eventlog");
1386         to_file = cvar("sv_logscores_file");
1387
1388         if(!final)
1389         {
1390                 to_console = TRUE; // always print printstats replies
1391                 to_eventlog = FALSE; // but never print them to the event log
1392         }
1393
1394         if(to_eventlog)
1395                 if(cvar("sv_eventlog_console"))
1396                         to_console = FALSE; // otherwise we get the output twice
1397
1398         if(final)
1399                 s = ":scores:";
1400         else
1401                 s = ":status:";
1402         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1403
1404         if(to_console)
1405                 print(s, "\n");
1406         if(to_eventlog)
1407                 GameLogEcho(s);
1408         if(to_file)
1409         {
1410                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1411                 if(file == -1)
1412                         to_file = FALSE;
1413                 else
1414                         fputs(file, strcat(s, "\n"));
1415         }
1416
1417         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1418         if(to_console)
1419                 print(s, "\n");
1420         if(to_eventlog)
1421                 GameLogEcho(s);
1422         if(to_file)
1423                 fputs(file, strcat(s, "\n"));
1424
1425         FOR_EACH_CLIENT(other)
1426         {
1427                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1428                 {
1429                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1430                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1431                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1432                                 s = strcat(s, ftos(other.team), ":");
1433                         else
1434                                 s = strcat(s, "spectator:");
1435
1436                         if(to_console)
1437                                 print(s, other.netname, "\n");
1438                         if(to_eventlog)
1439                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1440                         if(to_file)
1441                                 fputs(file, strcat(s, other.netname, "\n"));
1442                 }
1443         }
1444
1445         if(teams_matter)
1446         {
1447                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1448                 if(to_console)
1449                         print(s, "\n");
1450                 if(to_eventlog)
1451                         GameLogEcho(s);
1452                 if(to_file)
1453                         fputs(file, strcat(s, "\n"));
1454
1455                 for(i = 1; i < 16; ++i)
1456                 {
1457                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1458                         s = strcat(s, ":", ftos(i));
1459                         if(to_console)
1460                                 print(s, "\n");
1461                         if(to_eventlog)
1462                                 GameLogEcho(s);
1463                         if(to_file)
1464                                 fputs(file, strcat(s, "\n"));
1465                 }
1466         }
1467
1468         if(to_console)
1469                 print(":end\n");
1470         if(to_eventlog)
1471                 GameLogEcho(":end");
1472         if(to_file)
1473         {
1474                 fputs(file, ":end\n");
1475                 fclose(file);
1476         }
1477 }
1478
1479 void FixIntermissionClient(entity e)
1480 {
1481         string s;
1482         if(!e.autoscreenshot) // initial call
1483         {
1484                 e.angles = e.v_angle;
1485                 e.angles_x = -e.angles_x;
1486                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1487                 e.health = -2342;
1488                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1489                 e.solid = SOLID_NOT;
1490                 e.movetype = MOVETYPE_NONE;
1491                 e.takedamage = DAMAGE_NO;
1492                 if(e.weaponentity)
1493                 {
1494                         e.weaponentity.effects = EF_NODRAW;
1495                         if (e.weaponentity.weaponentity)
1496                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1497                 }
1498                 if(clienttype(e) == CLIENTTYPE_REAL)
1499                 {
1500                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1501                         s = cvar_string("sv_intermission_cdtrack");
1502                         if(s != "")
1503                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1504                         msg_entity = e;
1505                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1506                 }
1507         }
1508
1509         //e.velocity = '0 0 0';
1510         //e.fixangle = TRUE;
1511
1512         // TODO halt weapon animation
1513 }
1514
1515
1516 /*
1517 go to the next level for deathmatch
1518 only called if a time or frag limit has expired
1519 */
1520 void NextLevel()
1521 {
1522         float i;
1523
1524         gameover = TRUE;
1525
1526         intermission_running = 1;
1527
1528 // enforce a wait time before allowing changelevel
1529         if(player_count > 0)
1530                 intermission_exittime = time + cvar("sv_mapchange_delay");
1531         else
1532                 intermission_exittime = -1;
1533
1534         /*
1535         WriteByte (MSG_ALL, SVC_CDTRACK);
1536         WriteByte (MSG_ALL, 3);
1537         WriteByte (MSG_ALL, 3);
1538         // done in FixIntermission
1539         */
1540
1541         //pos = FindIntermission ();
1542
1543         VoteReset();
1544
1545         DumpStats(TRUE);
1546
1547         if(cvar("sv_eventlog"))
1548                 GameLogEcho(":gameover");
1549
1550         GameLogClose();
1551
1552 // TO DO
1553
1554 // save the stats to a text file on the client
1555 // stuffcmd(other, log_stats "stats/file_name");
1556 // bprint stats
1557 // stuffcmd(other, log_stats "");
1558 // use a filename similar to the demo name
1559         // string file_name;
1560         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1561
1562 // write a stats parser for the menu
1563
1564         if(cvar("sv_accuracy_data_send")) {
1565                 string stats_to_send;
1566
1567                 FOR_EACH_CLIENT(other) {  // make the string to send
1568                         FixIntermissionClient(other);
1569
1570                         if(other.cvar_cl_accuracy_data_share) {
1571                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1572
1573                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1574                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1575
1576                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1577
1578                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1579                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1580
1581                                 stats_to_send = strcat(stats_to_send, "\n");
1582                         }
1583                 }
1584
1585                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1586                         Score_NicePrint(other);  // print the score
1587
1588                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1589                                 bprint(stats_to_send);
1590                 }
1591         } else { // ye olde message
1592                 FOR_EACH_PLAYER(other) {
1593                         FixIntermissionClient(other);
1594
1595                         if(other.winning)
1596                                 bprint(other.netname, " ^7wins.\n");
1597                 }
1598         }
1599
1600         if(cvar("g_campaign"))
1601                 CampaignPreIntermission();
1602
1603         localcmd("\nsv_hook_gameend\n");
1604 }
1605
1606 /*
1607 ============
1608 CheckRules_Player
1609
1610 Exit deathmatch games upon conditions
1611 ============
1612 */
1613 void CheckRules_Player()
1614 {
1615         if (gameover)   // someone else quit the game already
1616                 return;
1617
1618         if(self.deadflag == DEAD_NO)
1619                 self.play_time += frametime;
1620
1621         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1622         //   (div0: and that in CheckRules_World please)
1623 };
1624
1625 float checkrules_equality;
1626 float checkrules_suddendeathwarning;
1627 float checkrules_suddendeathend;
1628 float checkrules_overtimesadded; //how many overtimes have been already added
1629
1630 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1631 float WINNING_YES = 1; // winner found
1632 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1633 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1634
1635 float InitiateSuddenDeath()
1636 {
1637         // Check first whether normal overtimes could be added before initiating suddendeath mode
1638         // - for this timelimit_overtime needs to be >0 of course
1639         // - also check the winning condition calculated in the previous frame and only add normal overtime
1640         //   again, if at the point at which timelimit would be extended again, still no winner was found
1641         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1642         {
1643                 return 1; // need to call InitiateOvertime later
1644         }
1645         else
1646         {
1647                 if(!checkrules_suddendeathend)
1648                 {
1649                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1650                         if(g_race && !g_race_qualifying)
1651                                 race_StartCompleting();
1652                 }
1653                 return 0;
1654         }
1655 }
1656
1657 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1658 {
1659         ++checkrules_overtimesadded;
1660         //add one more overtime by simply extending the timelimit
1661         float tl;
1662         tl = cvar("timelimit");
1663         tl += cvar("timelimit_overtime");
1664         cvar_set("timelimit", ftos(tl));
1665         string minutesPlural;
1666         if (cvar("timelimit_overtime") == 1)
1667                 minutesPlural = " ^3minute";
1668         else
1669                 minutesPlural = " ^3minutes";
1670
1671         bcenterprint(
1672                 strcat(
1673                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1674                         ftos(cvar("timelimit_overtime")),
1675                         minutesPlural,
1676                         " to the game!"
1677                 )
1678         );
1679 }
1680
1681 float GetWinningCode(float fraglimitreached, float equality)
1682 {
1683         if(cvar("g_campaign") == 1)
1684                 if(fraglimitreached)
1685                         return WINNING_YES;
1686                 else
1687                         return WINNING_NO;
1688
1689         else
1690                 if(equality)
1691                         if(fraglimitreached)
1692                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1693                         else
1694                                 return WINNING_NEVER;
1695                 else
1696                         if(fraglimitreached)
1697                                 return WINNING_YES;
1698                         else
1699                                 return WINNING_NO;
1700 }
1701
1702 // set the .winning flag for exactly those players with a given field value
1703 void SetWinners(.float field, float value)
1704 {
1705         entity head;
1706         FOR_EACH_PLAYER(head)
1707                 head.winning = (head.field == value);
1708 }
1709
1710 // set the .winning flag for those players with a given field value
1711 void AddWinners(.float field, float value)
1712 {
1713         entity head;
1714         FOR_EACH_PLAYER(head)
1715                 if(head.field == value)
1716                         head.winning = 1;
1717 }
1718
1719 // clear the .winning flags
1720 void ClearWinners(void)
1721 {
1722         entity head;
1723         FOR_EACH_PLAYER(head)
1724                 head.winning = 0;
1725 }
1726
1727 // Onslaught winning condition:
1728 // game terminates if only one team has a working generator (or none)
1729 float WinningCondition_Onslaught()
1730 {
1731         entity head;
1732         local float t1, t2, t3, t4;
1733
1734         WinningConditionHelper(); // set worldstatus
1735
1736         if(inWarmupStage)
1737                 return WINNING_NO;
1738
1739         // first check if the game has ended
1740         t1 = t2 = t3 = t4 = 0;
1741         head = find(world, classname, "onslaught_generator");
1742         while (head)
1743         {
1744                 if (head.health > 0)
1745                 {
1746                         if (head.team == COLOR_TEAM1) t1 = 1;
1747                         if (head.team == COLOR_TEAM2) t2 = 1;
1748                         if (head.team == COLOR_TEAM3) t3 = 1;
1749                         if (head.team == COLOR_TEAM4) t4 = 1;
1750                 }
1751                 head = find(head, classname, "onslaught_generator");
1752         }
1753         if (t1 + t2 + t3 + t4 < 2)
1754         {
1755                 // game over, only one team remains (or none)
1756                 ClearWinners();
1757                 if (t1) SetWinners(team, COLOR_TEAM1);
1758                 if (t2) SetWinners(team, COLOR_TEAM2);
1759                 if (t3) SetWinners(team, COLOR_TEAM3);
1760                 if (t4) SetWinners(team, COLOR_TEAM4);
1761                 dprint("Have a winner, ending game.\n");
1762                 return WINNING_YES;
1763         }
1764
1765         // Two or more teams remain
1766         return WINNING_NO;
1767 }
1768
1769 float LMS_NewPlayerLives()
1770 {
1771         float fl;
1772         fl = cvar("fraglimit");
1773         if(fl == 0)
1774                 fl = 999;
1775
1776         // first player has left the game for dying too much? Nobody else can get in.
1777         if(lms_lowest_lives < 1)
1778                 return 0;
1779
1780         if(!cvar("g_lms_join_anytime"))
1781                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1782                         return 0;
1783
1784         return bound(1, lms_lowest_lives, fl);
1785 }
1786
1787 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1788 // they win. Otherwise the defending team wins once the timelimit passes.
1789 void assault_new_round();
1790 float WinningCondition_Assault()
1791 {
1792         local float status;
1793
1794         WinningConditionHelper(); // set worldstatus
1795
1796         status = WINNING_NO;
1797         // as the timelimit has not yet passed just assume the defending team will win
1798         if(assault_attacker_team == COLOR_TEAM1)
1799         {
1800                 SetWinners(team, COLOR_TEAM2);
1801         }
1802         else
1803         {
1804                 SetWinners(team, COLOR_TEAM1);
1805         }
1806
1807         local entity ent;
1808         ent = find(world, classname, "target_assault_roundend");
1809         if(ent)
1810         {
1811                 if(ent.winning) // round end has been triggered by attacking team
1812                 {
1813                         bprint("ASSAULT: round completed...\n");
1814                         SetWinners(team, assault_attacker_team);
1815
1816                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1817
1818                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1819                         {
1820                                 status = WINNING_YES;
1821                         }
1822                         else
1823                         {
1824                                 local entity oldself;
1825                                 oldself = self;
1826                                 self = ent;
1827                                 assault_new_round();
1828                                 self = oldself;
1829                         }
1830                 }
1831         }
1832
1833         return status;
1834 }
1835
1836 // LMS winning condition: game terminates if and only if there's at most one
1837 // one player who's living lives. Top two scores being equal cancels the time
1838 // limit.
1839 float WinningCondition_LMS()
1840 {
1841         entity head, head2;
1842         float have_player;
1843         float have_players;
1844         float l;
1845
1846         have_player = FALSE;
1847         have_players = FALSE;
1848         l = LMS_NewPlayerLives();
1849
1850         head = find(world, classname, "player");
1851         if(head)
1852                 have_player = TRUE;
1853         head2 = find(head, classname, "player");
1854         if(head2)
1855                 have_players = TRUE;
1856
1857         if(have_player)
1858         {
1859                 // we have at least one player
1860                 if(have_players)
1861                 {
1862                         // two or more active players - continue with the game
1863                 }
1864                 else
1865                 {
1866                         // exactly one player?
1867
1868                         ClearWinners();
1869                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1870
1871                         if(l)
1872                         {
1873                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1874                                 return WINNING_NO;
1875                         }
1876                         else
1877                         {
1878                                 // a winner!
1879                                 // and assign him his first place
1880                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1881                                 return WINNING_YES;
1882                         }
1883                 }
1884         }
1885         else
1886         {
1887                 // nobody is playing at all...
1888                 if(l)
1889                 {
1890                         // wait for players...
1891                 }
1892                 else
1893                 {
1894                         // SNAFU (maybe a draw game?)
1895                         ClearWinners();
1896                         dprint("No players, ending game.\n");
1897                         return WINNING_YES;
1898                 }
1899         }
1900
1901         // When we get here, we have at least two players who are actually LIVING,
1902         // now check if the top two players have equal score.
1903         WinningConditionHelper();
1904
1905         ClearWinners();
1906         if(WinningConditionHelper_winner)
1907                 WinningConditionHelper_winner.winning = TRUE;
1908         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1909                 return WINNING_NEVER;
1910
1911         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1912         return WINNING_NO;
1913 }
1914
1915 void ShuffleMaplist()
1916 {
1917         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1918 }
1919
1920 float leaderfrags;
1921 float WinningCondition_Scores(float limit, float leadlimit)
1922 {
1923         float limitreached;
1924
1925         // TODO make everything use THIS winning condition (except LMS)
1926         WinningConditionHelper();
1927
1928         if(teams_matter)
1929         {
1930                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1931                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1932                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1933                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1934         }
1935
1936         ClearWinners();
1937         if(WinningConditionHelper_winner)
1938                 WinningConditionHelper_winner.winning = 1;
1939         if(WinningConditionHelper_winnerteam >= 0)
1940                 SetWinners(team, WinningConditionHelper_winnerteam);
1941
1942         if(WinningConditionHelper_lowerisbetter)
1943         {
1944                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1945                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1946                 limit = -limit;
1947         }
1948
1949         if(WinningConditionHelper_zeroisworst)
1950                 leadlimit = 0; // not supported in this mode
1951
1952         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1953         // these modes always score in increments of 1, thus this makes sense
1954         {
1955                 if(leaderfrags != WinningConditionHelper_topscore)
1956                 {
1957                         leaderfrags = WinningConditionHelper_topscore;
1958
1959                         if (limit)
1960                         if (leaderfrags == limit - 1)
1961                                 Announce("1fragleft");
1962                         else if (leaderfrags == limit - 2)
1963                                 Announce("2fragsleft");
1964                         else if (leaderfrags == limit - 3)
1965                                 Announce("3fragsleft");
1966                 }
1967         }
1968
1969         limitreached = FALSE;
1970         if(limit)
1971                 if(WinningConditionHelper_topscore >= limit)
1972                         limitreached = TRUE;
1973         if(leadlimit)
1974         {
1975                 float leadlimitreached;
1976                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1977                 if(cvar("leadlimit_and_fraglimit"))
1978                         limitreached = (limitreached && leadlimitreached);
1979                 else
1980                         limitreached = (limitreached || leadlimitreached);
1981         }
1982
1983         return GetWinningCode(
1984                 WinningConditionHelper_topscore && limitreached,
1985                 WinningConditionHelper_equality
1986         );
1987 }
1988
1989 float WinningCondition_Race(float fraglimit)
1990 {
1991         float wc;
1992         entity p;
1993         float n, c;
1994
1995         n = 0;
1996         c = 0;
1997         FOR_EACH_PLAYER(p)
1998         {
1999                 ++n;
2000                 if(p.race_completed)
2001                         ++c;
2002         }
2003         if(n && (n == c))
2004                 return WINNING_YES;
2005         wc = WinningCondition_Scores(fraglimit, 0);
2006
2007         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2008         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2009         // do NOT support equality when the laps are all raced!
2010                 return WINNING_STARTSUDDENDEATHOVERTIME;
2011         else
2012                 return WINNING_NEVER;
2013         return wc;
2014 }
2015
2016 void ReadyRestart();
2017 float WinningCondition_QualifyingThenRace(float limit)
2018 {
2019         float wc;
2020         wc = WinningCondition_Scores(limit, 0);
2021
2022         // NEVER initiate overtime
2023         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2024         {
2025                 return WINNING_YES;
2026         }
2027
2028         return wc;
2029 }
2030
2031 float WinningCondition_RanOutOfSpawns()
2032 {
2033         entity head;
2034
2035         if(have_team_spawns <= 0)
2036                 return WINNING_NO;
2037
2038         if(!some_spawn_has_been_used)
2039                 return WINNING_NO;
2040
2041         team1_score = team2_score = team3_score = team4_score = 0;
2042
2043         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2044         {
2045                 if(head.team == COLOR_TEAM1)
2046                         team1_score = 1;
2047                 else if(head.team == COLOR_TEAM2)
2048                         team2_score = 1;
2049                 else if(head.team == COLOR_TEAM3)
2050                         team3_score = 1;
2051                 else if(head.team == COLOR_TEAM4)
2052                         team4_score = 1;
2053         }
2054
2055         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2056         {
2057                 if(head.team == COLOR_TEAM1)
2058                         team1_score = 1;
2059                 else if(head.team == COLOR_TEAM2)
2060                         team2_score = 1;
2061                 else if(head.team == COLOR_TEAM3)
2062                         team3_score = 1;
2063                 else if(head.team == COLOR_TEAM4)
2064                         team4_score = 1;
2065         }
2066
2067         ClearWinners();
2068         if(team1_score + team2_score + team3_score + team4_score == 0)
2069         {
2070                 checkrules_equality = TRUE;
2071                 return WINNING_YES;
2072         }
2073         else if(team1_score + team2_score + team3_score + team4_score == 1)
2074         {
2075                 float t, i;
2076                 if(team1_score) t = COLOR_TEAM1;
2077                 if(team2_score) t = COLOR_TEAM2;
2078                 if(team3_score) t = COLOR_TEAM3;
2079                 if(team4_score) t = COLOR_TEAM4;
2080                 CheckAllowedTeams(world);
2081                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2082                 {
2083                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2084                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2085                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2086                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2087                 }
2088
2089                 AddWinners(team, t);
2090                 return WINNING_YES;
2091         }
2092         else
2093                 return WINNING_NO;
2094 }
2095
2096 /*
2097 ============
2098 CheckRules_World
2099
2100 Exit deathmatch games upon conditions
2101 ============
2102 */
2103 void CheckRules_World()
2104 {
2105         float timelimit;
2106         float fraglimit;
2107         float leadlimit;
2108
2109         VoteThink();
2110         MapVote_Think();
2111
2112         SetDefaultAlpha();
2113
2114         /*
2115         MapVote_Think should now do that part
2116         if (intermission_running)
2117                 if (time >= intermission_exittime + 60)
2118                 {
2119                         if(!DoNextMapOverride())
2120                                 GotoNextMap();
2121                         return;
2122                 }
2123         */
2124
2125         if (gameover)   // someone else quit the game already
2126         {
2127                 if(player_count == 0) // Nobody there? Then let's go to the next map
2128                         MapVote_Start();
2129                         // this will actually check the player count in the next frame
2130                         // again, but this shouldn't hurt
2131                 return;
2132         }
2133
2134         timelimit = cvar("timelimit") * 60;
2135         fraglimit = cvar("fraglimit");
2136         leadlimit = cvar("leadlimit");
2137
2138         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2139         {
2140                 if(timelimit > 0)
2141                         timelimit = 0; // timelimit is not made for warmup
2142                 if(fraglimit > 0)
2143                         fraglimit = 0; // no fraglimit for now
2144                 leadlimit = 0; // no leadlimit for now
2145         }
2146
2147         if(g_onslaught)
2148                 timelimit = 0; // ONS has its own overtime rule
2149
2150         if(timelimit > 0)
2151         {
2152                 timelimit += game_starttime;
2153         }
2154         else if (timelimit < 0)
2155         {
2156                 // endmatch
2157                 NextLevel();
2158                 return;
2159         }
2160
2161         float wantovertime;
2162         wantovertime = 0;
2163
2164         if(checkrules_suddendeathend)
2165         {
2166                 if(!checkrules_suddendeathwarning)
2167                 {
2168                         checkrules_suddendeathwarning = TRUE;
2169                         if(g_race && !g_race_qualifying)
2170                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2171                         else
2172                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2173                 }
2174         }
2175         else
2176         {
2177                 if (timelimit && time >= timelimit)
2178                 {
2179                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2180                         {
2181                                 float totalplayers;
2182                                 float playerswithlaps;
2183                                 float readyplayers;
2184                                 entity head;
2185                                 totalplayers = playerswithlaps = readyplayers = 0;
2186                                 FOR_EACH_PLAYER(head)
2187                                 {
2188                                         ++totalplayers;
2189                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2190                                                 ++playerswithlaps;
2191                                         if(head.ready)
2192                                                 ++readyplayers;
2193                                 }
2194
2195                                 // at least 2 of the players have completed a lap: start the RACE
2196                                 // otherwise, the players should end the qualifying on their own
2197                                 if(readyplayers || playerswithlaps >= 2)
2198                                 {
2199                                         checkrules_suddendeathend = 0;
2200                                         ReadyRestart(); // go to race
2201                                         return;
2202                                 }
2203                                 else
2204                                         wantovertime |= InitiateSuddenDeath();
2205                         }
2206                         else
2207                                 wantovertime |= InitiateSuddenDeath();
2208                 }
2209         }
2210
2211         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2212         {
2213                 NextLevel();
2214                 return;
2215         }
2216
2217         float checkrules_status;
2218         checkrules_status = WinningCondition_RanOutOfSpawns();
2219         if(checkrules_status == WINNING_YES)
2220         {
2221                 bprint("Hey! Someone ran out of spawns!\n");
2222         }
2223         else if(g_race && !g_race_qualifying && timelimit >= 0)
2224         {
2225                 checkrules_status = WinningCondition_Race(fraglimit);
2226                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2227         }
2228         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2229         {
2230                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2231                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2232         }
2233         else if(g_assault)
2234         {
2235                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2236         }
2237         else if(g_lms)
2238         {
2239                 checkrules_status = WinningCondition_LMS();
2240         }
2241         else if (g_onslaught)
2242         {
2243                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2244         }
2245         else
2246         {
2247                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2248                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2249         }
2250
2251         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2252         {
2253                 checkrules_status = WINNING_NEVER;
2254                 checkrules_overtimesadded = -1;
2255                 wantovertime |= InitiateSuddenDeath();
2256         }
2257
2258         if(checkrules_status == WINNING_NEVER)
2259                 // equality cases! Nobody wins if the overtime ends in a draw.
2260                 ClearWinners();
2261
2262         if(wantovertime)
2263         {
2264                 if(checkrules_status == WINNING_NEVER)
2265                         InitiateOvertime();
2266                 else
2267                         checkrules_status = WINNING_YES;
2268         }
2269
2270         if(checkrules_suddendeathend)
2271                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2272                         checkrules_status = WINNING_YES;
2273
2274         if(checkrules_status == WINNING_YES)
2275         {
2276                 //print("WINNING\n");
2277                 NextLevel();
2278         }
2279 };
2280
2281 float mapvote_nextthink;
2282 float mapvote_initialized;
2283 float mapvote_keeptwotime;
2284 float mapvote_timeout;
2285 string mapvote_message;
2286 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2287 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2288 float mapvote_screenshot_dirs_count;
2289
2290 float mapvote_count;
2291 float mapvote_count_real;
2292 string mapvote_maps[MAPVOTE_COUNT];
2293 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2294 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2295 float mapvote_maps_suggested[MAPVOTE_COUNT];
2296 string mapvote_suggestions[MAPVOTE_COUNT];
2297 float mapvote_suggestion_ptr;
2298 float mapvote_maxlen;
2299 float mapvote_voters;
2300 float mapvote_votes[MAPVOTE_COUNT];
2301 float mapvote_run;
2302 float mapvote_detail;
2303 float mapvote_abstain;
2304 .float mapvote;
2305
2306 void MapVote_ClearAllVotes()
2307 {
2308         FOR_EACH_CLIENT(other)
2309                 other.mapvote = 0;
2310 }
2311
2312 string MapVote_Suggest(string m)
2313 {
2314         float i;
2315         if(m == "")
2316                 return "That's not how to use this command.";
2317         if(!cvar("g_maplist_votable_suggestions"))
2318                 return "Suggestions are not accepted on this server.";
2319         if(mapvote_initialized)
2320                 return "Can't suggest - voting is already in progress!";
2321         m = MapInfo_FixName(m);
2322         if(!m)
2323                 return "The map you suggested is not available on this server.";
2324         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2325                 if(Map_IsRecent(m))
2326                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2327
2328         if(!MapInfo_CheckMap(m))
2329                 return "The map you suggested does not support the current game mode.";
2330         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2331                 if(mapvote_suggestions[i] == m)
2332                         return "This map was already suggested.";
2333         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2334         {
2335                 i = floor(random() * mapvote_suggestion_ptr);
2336         }
2337         else
2338         {
2339                 i = mapvote_suggestion_ptr;
2340                 mapvote_suggestion_ptr += 1;
2341         }
2342         if(mapvote_suggestions[i] != "")
2343                 strunzone(mapvote_suggestions[i]);
2344         mapvote_suggestions[i] = strzone(m);
2345         if(cvar("sv_eventlog"))
2346                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2347         return strcat("Suggestion of ", m, " accepted.");
2348 }
2349
2350 void MapVote_AddVotable(string nextMap, float isSuggestion)
2351 {
2352         float j, i, o;
2353         string pakfile, mapfile;
2354
2355         if(nextMap == "")
2356                 return;
2357         for(j = 0; j < mapvote_count; ++j)
2358                 if(mapvote_maps[j] == nextMap)
2359                         return;
2360         if(strlen(nextMap) > mapvote_maxlen)
2361                 mapvote_maxlen = strlen(nextMap);
2362         mapvote_maps[mapvote_count] = strzone(nextMap);
2363         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2364
2365         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2366         {
2367                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2368                 pakfile = whichpack(strcat(mapfile, ".tga"));
2369                 if(pakfile == "")
2370                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2371                 if(pakfile == "")
2372                         pakfile = whichpack(strcat(mapfile, ".png"));
2373                 if(pakfile != "")
2374                         break;
2375         }
2376         if(i >= mapvote_screenshot_dirs_count)
2377                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2378         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2379                 pakfile = substring(pakfile, o, -1);
2380
2381         mapvote_maps_screenshot_dir[mapvote_count] = i;
2382         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2383
2384         mapvote_count += 1;
2385 }
2386
2387 void MapVote_Spawn();
2388 void MapVote_Init()
2389 {
2390         float i;
2391         float nmax, smax;
2392
2393         MapVote_ClearAllVotes();
2394
2395         mapvote_count = 0;
2396         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2397         mapvote_abstain = cvar("g_maplist_votable_abstain");
2398
2399         if(mapvote_abstain)
2400                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2401         else
2402                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2403         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2404
2405         // we need this for AddVotable, as that cycles through the screenshot dirs
2406         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2407         if(mapvote_screenshot_dirs_count == 0)
2408                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2409         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2410         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2411                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2412
2413         if(mapvote_suggestion_ptr)
2414                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2415                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2416
2417         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2418                 MapVote_AddVotable(GetNextMap(), FALSE);
2419
2420         if(mapvote_count == 0)
2421         {
2422                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2423                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2424                 if(cvar("g_maplist_shuffle"))
2425                         ShuffleMaplist();
2426                 localcmd("\nmenu_cmd sync\n");
2427                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2428                         MapVote_AddVotable(GetNextMap(), FALSE);
2429         }
2430
2431         mapvote_count_real = mapvote_count;
2432         if(mapvote_abstain)
2433                 MapVote_AddVotable("don't care", 0);
2434
2435         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2436
2437         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2438         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2439         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2440                 mapvote_keeptwotime = 0;
2441         mapvote_message = "Choose a map and press its key!";
2442
2443         MapVote_Spawn();
2444 }
2445
2446 void MapVote_SendPicture(float id)
2447 {
2448         msg_entity = self;
2449         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2450         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2451         WriteByte(MSG_ONE, id);
2452         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2453 }
2454
2455 float GameCommand_MapVote(string cmd)
2456 {
2457         if(!intermission_running)
2458                 return FALSE;
2459
2460         if(cmd == "mv_getpic")
2461         {
2462                 MapVote_SendPicture(stof(argv(1)));
2463                 return TRUE;
2464         }
2465
2466         return FALSE;
2467 }
2468
2469 float MapVote_GetMapMask()
2470 {
2471         float mask, i, power;
2472         mask = 0;
2473         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2474                 if(mapvote_maps[i] != "")
2475                         mask |= power;
2476         return mask;
2477 }
2478
2479 entity mapvote_ent;
2480 float MapVote_SendEntity(entity to, float sf)
2481 {
2482         float i;
2483
2484         if(sf & 1)
2485                 sf &~= 2; // if we send 1, we don't need to also send 2
2486
2487         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2488         WriteByte(MSG_ENTITY, sf);
2489
2490         if(sf & 1)
2491         {
2492                 // flag 1 == initialization
2493                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2494                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2495                 WriteString(MSG_ENTITY, "");
2496                 WriteByte(MSG_ENTITY, mapvote_count);
2497                 WriteByte(MSG_ENTITY, mapvote_abstain);
2498                 WriteByte(MSG_ENTITY, mapvote_detail);
2499                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2500                 if(mapvote_count <= 8)
2501                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2502                 else
2503                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2504                 for(i = 0; i < mapvote_count; ++i)
2505                         if(mapvote_maps[i] != "")
2506                         {
2507                                 if(mapvote_abstain && i == mapvote_count - 1)
2508                                 {
2509                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2510                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2511                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2512                                 }
2513                                 else
2514                                 {
2515                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2516                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2517                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2518                                 }
2519                         }
2520         }
2521
2522         if(sf & 2)
2523         {
2524                 // flag 2 == update of mask
2525                 if(mapvote_count <= 8)
2526                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2527                 else
2528                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2529         }
2530
2531         if(sf & 4)
2532         {
2533                 if(mapvote_detail)
2534                         for(i = 0; i < mapvote_count; ++i)
2535                                 if(mapvote_maps[i] != "")
2536                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2537
2538                 WriteByte(MSG_ENTITY, to.mapvote);
2539         }
2540
2541         return TRUE;
2542 }
2543
2544 void MapVote_Spawn()
2545 {
2546         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2547 }
2548
2549 void MapVote_TouchMask()
2550 {
2551         mapvote_ent.SendFlags |= 2;
2552 }
2553
2554 void MapVote_TouchVotes(entity voter)
2555 {
2556         mapvote_ent.SendFlags |= 4;
2557 }
2558
2559 float MapVote_Finished(float mappos)
2560 {
2561         string result;
2562         float i;
2563         float didntvote;
2564
2565         if(cvar("sv_eventlog"))
2566         {
2567                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2568                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2569                 didntvote = mapvote_voters;
2570                 for(i = 0; i < mapvote_count; ++i)
2571                         if(mapvote_maps[i] != "")
2572                         {
2573                                 didntvote -= mapvote_votes[i];
2574                                 if(i != mappos)
2575                                 {
2576                                         result = strcat(result, ":", mapvote_maps[i]);
2577                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2578                                 }
2579                         }
2580                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2581
2582                 GameLogEcho(result);
2583                 if(mapvote_maps_suggested[mappos])
2584                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2585         }
2586
2587         FOR_EACH_REALCLIENT(other)
2588                 FixClientCvars(other);
2589
2590         Map_Goto_SetStr(mapvote_maps[mappos]);
2591         Map_Goto();
2592         alreadychangedlevel = TRUE;
2593         return TRUE;
2594 }
2595 void MapVote_CheckRules_1()
2596 {
2597         float i;
2598
2599         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2600         {
2601                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2602                 mapvote_votes[i] = 0;
2603         }
2604
2605         mapvote_voters = 0;
2606         FOR_EACH_REALCLIENT(other)
2607         {
2608                 ++mapvote_voters;
2609                 if(other.mapvote)
2610                 {
2611                         i = other.mapvote - 1;
2612                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2613                         mapvote_votes[i] = mapvote_votes[i] + 1;
2614                 }
2615         }
2616 }
2617
2618 float MapVote_CheckRules_2()
2619 {
2620         float i;
2621         float firstPlace, secondPlace;
2622         float firstPlaceVotes, secondPlaceVotes;
2623         float mapvote_voters_real;
2624         string result;
2625
2626         if(mapvote_count_real == 1)
2627                 return MapVote_Finished(0);
2628
2629         mapvote_voters_real = mapvote_voters;
2630         if(mapvote_abstain)
2631                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2632
2633         RandomSelection_Init();
2634         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2635                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2636         firstPlace = RandomSelection_chosen_float;
2637         firstPlaceVotes = RandomSelection_best_priority;
2638         //dprint("First place: ", ftos(firstPlace), "\n");
2639         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2640
2641         RandomSelection_Init();
2642         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2643                 if(i != firstPlace)
2644                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2645         secondPlace = RandomSelection_chosen_float;
2646         secondPlaceVotes = RandomSelection_best_priority;
2647         //dprint("Second place: ", ftos(secondPlace), "\n");
2648         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2649
2650         if(firstPlace == -1)
2651                 error("No first place in map vote... WTF?");
2652
2653         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2654                 return MapVote_Finished(firstPlace);
2655
2656         if(mapvote_keeptwotime)
2657                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2658                 {
2659                         float didntvote;
2660                         MapVote_TouchMask();
2661                         mapvote_message = "Now decide between the TOP TWO!";
2662                         mapvote_keeptwotime = 0;
2663                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2664                         result = strcat(result, ":", ftos(firstPlaceVotes));
2665                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2666                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2667                         didntvote = mapvote_voters;
2668                         for(i = 0; i < mapvote_count; ++i)
2669                                 if(mapvote_maps[i] != "")
2670                                 {
2671                                         didntvote -= mapvote_votes[i];
2672                                         if(i != firstPlace)
2673                                                 if(i != secondPlace)
2674                                                 {
2675                                                         result = strcat(result, ":", mapvote_maps[i]);
2676                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2677                                                         if(i < mapvote_count_real)
2678                                                         {
2679                                                                 strunzone(mapvote_maps[i]);
2680                                                                 mapvote_maps[i] = "";
2681                                                                 strunzone(mapvote_maps_pakfile[i]);
2682                                                                 mapvote_maps_pakfile[i] = "";
2683                                                         }
2684                                                 }
2685                                 }
2686                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2687                         if(cvar("sv_eventlog"))
2688                                 GameLogEcho(result);
2689                 }
2690
2691         return FALSE;
2692 }
2693 void MapVote_Tick()
2694 {
2695         float keeptwo;
2696         float totalvotes;
2697
2698         keeptwo = mapvote_keeptwotime;
2699         MapVote_CheckRules_1(); // count
2700         if(MapVote_CheckRules_2()) // decide
2701                 return;
2702
2703         totalvotes = 0;
2704         FOR_EACH_REALCLIENT(other)
2705         {
2706                 // hide scoreboard again
2707                 if(other.health != 2342)
2708                 {
2709                         other.health = 2342;
2710                         other.impulse = 0;
2711                         if(clienttype(other) == CLIENTTYPE_REAL)
2712                         {
2713                                 msg_entity = other;
2714                                 WriteByte(MSG_ONE, SVC_FINALE);
2715                                 WriteString(MSG_ONE, "");
2716                         }
2717                 }
2718
2719                 // clear possibly invalid votes
2720                 if(mapvote_maps[other.mapvote - 1] == "")
2721                         other.mapvote = 0;
2722                 // use impulses as new vote
2723                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2724                         if(mapvote_maps[other.impulse - 1] != "")
2725                         {
2726                                 other.mapvote = other.impulse;
2727                                 MapVote_TouchVotes(other);
2728                         }
2729                 other.impulse = 0;
2730
2731                 if(other.mapvote)
2732                         ++totalvotes;
2733         }
2734
2735         MapVote_CheckRules_1(); // just count
2736 }
2737 void MapVote_Start()
2738 {
2739         if(mapvote_run)
2740                 return;
2741
2742         MapInfo_Enumerate();
2743         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2744                 mapvote_run = TRUE;
2745 }
2746 void MapVote_Think()
2747 {
2748         if(!mapvote_run)
2749                 return;
2750
2751         if(alreadychangedlevel)
2752                 return;
2753
2754         if(time < mapvote_nextthink)
2755                 return;
2756         //dprint("tick\n");
2757
2758         mapvote_nextthink = time + 0.5;
2759
2760         if(!mapvote_initialized)
2761         {
2762                 if(cvar("rescan_pending") == 1)
2763                 {
2764                         cvar_set("rescan_pending", "2");
2765                         localcmd("fs_rescan\nrescan_pending 3\n");
2766                         return;
2767                 }
2768                 else if(cvar("rescan_pending") == 2)
2769                 {
2770                         return;
2771                 }
2772                 else if(cvar("rescan_pending") == 3)
2773                 {
2774                         // now build missing mapinfo files
2775                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2776                                 return;
2777
2778                         // we're done, start the timer
2779                         cvar_set("rescan_pending", "0");
2780                 }
2781
2782                 mapvote_initialized = TRUE;
2783                 if(DoNextMapOverride())
2784                         return;
2785                 if(!cvar("g_maplist_votable") || player_count <= 0)
2786                 {
2787                         GotoNextMap();
2788                         return;
2789                 }
2790                 MapVote_Init();
2791         }
2792
2793         MapVote_Tick();
2794 };
2795
2796 string GotoMap(string m)
2797 {
2798         if(!MapInfo_CheckMap(m))
2799                 return "The map you chose is not available on this server.";
2800         cvar_set("nextmap", m);
2801         cvar_set("timelimit", "-1");
2802         if(mapvote_initialized || alreadychangedlevel)
2803         {
2804                 if(DoNextMapOverride())
2805                         return "Map switch initiated.";
2806                 else
2807                         return "Hm... no. For some reason I like THIS map more.";
2808         }
2809         else
2810                 return "Map switch will happen after scoreboard.";
2811 }
2812
2813
2814 void EndFrame()
2815 {
2816         float altime;
2817         FOR_EACH_REALCLIENT(self)
2818         {
2819                 if(self.classname == "spectator")
2820                 {
2821                         if(self.enemy.typehitsound)
2822                                 play2(self, "misc/typehit.wav");
2823                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2824                                 play2(self, "misc/hit.wav");
2825                 }
2826                 else
2827                 {
2828                         if(self.typehitsound)
2829                                 play2(self, "misc/typehit.wav");
2830                         else if(self.hitsound && self.cvar_cl_hitsound)
2831                                 play2(self, "misc/hit.wav");
2832                 }
2833         }
2834         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2835         // add 1 frametime because after this, engine SV_Physics
2836         // increases time by a frametime and then networks the frame
2837         // add another frametime because client shows everything with
2838         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2839         // needed!
2840         FOR_EACH_CLIENT(self)
2841         {
2842                 self.hitsound = FALSE;
2843                 self.typehitsound = FALSE;
2844                 antilag_record(self, altime);
2845         }
2846 }
2847
2848
2849 /*
2850  * RedirectionThink:
2851  * returns TRUE if redirecting
2852  */
2853 float redirection_timeout;
2854 float redirection_nextthink;
2855 float RedirectionThink()
2856 {
2857         float clients_found;
2858
2859         if(redirection_target == "")
2860                 return FALSE;
2861
2862         if(!redirection_timeout)
2863         {
2864                 cvar_set("sv_public", "-2");
2865                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2866                 if(redirection_target == "self")
2867                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2868                 else
2869                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2870         }
2871
2872         if(time < redirection_nextthink)
2873                 return TRUE;
2874
2875         redirection_nextthink = time + 1;
2876
2877         clients_found = 0;
2878         FOR_EACH_REALCLIENT(self)
2879         {
2880                 print("Redirecting: sending connect command to ", self.netname, "\n");
2881                 if(redirection_target == "self")
2882                         stuffcmd(self, "\ndisconnect; reconnect\n");
2883                 else
2884                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2885                 ++clients_found;
2886         }
2887
2888         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2889
2890         if(time > redirection_timeout || clients_found == 0)
2891                 localcmd("\nwait; wait; wait; quit\n");
2892
2893         return TRUE;
2894 }
2895
2896 void TargetMusic_RestoreGame();
2897 void RestoreGame()
2898 {
2899         // Loaded from a save game
2900         // some things then break, so let's work around them...
2901
2902         // Progs DB (capture records)
2903         ServerProgsDB = db_load("server.db");
2904
2905         // Mapinfo
2906         MapInfo_Shutdown();
2907         MapInfo_Enumerate();
2908         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2909         WeaponStats_Init();
2910
2911         TargetMusic_RestoreGame();
2912 }
2913
2914 void SV_Shutdown()
2915 {
2916         if(gameover > 1) // shutting down already?
2917                 return;
2918
2919         gameover = 2; // 2 = server shutting down
2920
2921         if(world_initialized > 0)
2922         {
2923                 world_initialized = 0;
2924                 print("Saving persistent data...\n");
2925                 Ban_SaveBans();
2926                 if(!cheatcount_total)
2927                 {
2928                         if(cvar("sv_db_saveasdump"))
2929                                 db_dump(ServerProgsDB, "server.db");
2930                         else
2931                                 db_save(ServerProgsDB, "server.db");
2932                 }
2933                 if(cvar("developer"))
2934                 {
2935                         if(cvar("sv_db_saveasdump"))
2936                                 db_dump(TemporaryDB, "server-temp.db");
2937                         else
2938                                 db_save(TemporaryDB, "server-temp.db");
2939                 }
2940                 CheatShutdown(); // must be after cheatcount check
2941                 db_close(ServerProgsDB);
2942                 db_close(TemporaryDB);
2943                 print("done!\n");
2944                 // tell the bot system the game is ending now
2945                 bot_endgame();
2946
2947                 WeaponStats_Shutdown();
2948                 MapInfo_Shutdown();
2949         }
2950         else if(world_initialized == 0)
2951         {
2952                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2953         }
2954 }