qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/all.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications.qh"
  29 #include "../common/physics.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/all.qh"
  37 #include "../common/weapons/all.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {SELFPARAM();
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         self.nextthink = time + delta;
  53
  54         e = edict_num(self.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new(pingplreport);
  85         make_pure(pingplreport);
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap()
 109 {SELFPARAM();
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 self.nextthink = time;
 134         }
 135         else
 136         {
 137                 self.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("g_maplist_index");
 180                 BADCVAR("halflifebsp");
 181                 BADCVAR("sv_mapformat_is_quake2");
 182                 BADCVAR("sv_mapformat_is_quake3");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_invasion_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_limit");
 308                 BADCVAR("g_ca_point_leadlimit");
 309                 BADCVAR("g_ctf_captimerecord_always");
 310                 BADCVAR("g_ctf_flag_glowtrails");
 311                 BADCVAR("g_ctf_flag_pickup_verbosename");
 312                 BADCVAR("g_domination_point_leadlimit");
 313                 BADCVAR("g_forced_respawn");
 314                 BADCVAR("g_freezetag_point_limit");
 315                 BADCVAR("g_freezetag_point_leadlimit");
 316                 BADCVAR("g_keyhunt_point_leadlimit");
 317                 BADPREFIX("g_mod_");
 318                 BADCVAR("g_invasion_point_limit");
 319                 BADCVAR("g_nexball_goalleadlimit");
 320                 BADCVAR("g_tdm_point_limit");
 321                 BADCVAR("g_tdm_point_leadlimit");
 322                 BADCVAR("leadlimit_and_fraglimit");
 323                 BADCVAR("leadlimit_override");
 324                 BADCVAR("pausable");
 325                 BADCVAR("sv_allow_fullbright");
 326                 BADCVAR("sv_checkforpacketsduringsleep");
 327                 BADCVAR("sv_timeout");
 328                 BADPREFIX("sv_timeout_");
 329                 BADPREFIX("crypto_");
 330                 BADPREFIX("g_chat_");
 331                 BADPREFIX("g_ctf_captimerecord_");
 332                 BADPREFIX("g_maplist_votable_");
 333                 BADPREFIX("net_");
 334                 BADPREFIX("prvm_");
 335                 BADPREFIX("skill_");
 336                 BADPREFIX("sv_cullentities_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_minigames");
 343                 BADPREFIX("sv_minigames_");
 344                 BADCVAR("sv_namechangetimer");
 345
 346                 // allowed changes to server admins (please sync this to server.cfg)
 347                 // vi commands:
 348                 //   :/"impure"/,$d
 349                 //   :g!,^\/\/[^ /],d
 350                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 351                 //   :%!sort
 352                 // yes, this does contain some redundant stuff, don't really care
 353                 BADCVAR("bot_config_file");
 354                 BADCVAR("bot_number");
 355                 BADCVAR("bot_prefix");
 356                 BADCVAR("bot_suffix");
 357                 BADCVAR("capturelimit_override");
 358                 BADCVAR("fraglimit_override");
 359                 BADCVAR("gametype");
 360                 BADCVAR("g_antilag");
 361                 BADCVAR("g_balance_teams");
 362                 BADCVAR("g_balance_teams_prevent_imbalance");
 363                 BADCVAR("g_balance_teams_scorefactor");
 364                 BADCVAR("g_ban_sync_trusted_servers");
 365                 BADCVAR("g_ban_sync_uri");
 366                 BADCVAR("g_ca_teams_override");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_domination_teams_override");
 370                 BADCVAR("g_freezetag_teams_override");
 371                 BADCVAR("g_friendlyfire");
 372                 BADCVAR("g_fullbrightitems");
 373                 BADCVAR("g_fullbrightplayers");
 374                 BADCVAR("g_keyhunt_point_limit");
 375                 BADCVAR("g_keyhunt_teams_override");
 376                 BADCVAR("g_lms_lives_override");
 377                 BADCVAR("g_maplist");
 378                 BADCVAR("g_maplist_check_waypoints");
 379                 BADCVAR("g_maplist_mostrecent_count");
 380                 BADCVAR("g_maplist_shuffle");
 381                 BADCVAR("g_maplist_votable");
 382                 BADCVAR("g_maplist_votable_abstain");
 383                 BADCVAR("g_maplist_votable_nodetail");
 384                 BADCVAR("g_maplist_votable_suggestions");
 385                 BADCVAR("g_maxplayers");
 386                 BADCVAR("g_mirrordamage");
 387                 BADCVAR("g_nexball_goallimit");
 388                 BADCVAR("g_powerups");
 389                 BADCVAR("g_start_delay");
 390                 BADCVAR("g_tdm_teams_override");
 391                 BADCVAR("g_warmup");
 392                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 393                 BADCVAR("hostname");
 394                 BADCVAR("log_file");
 395                 BADCVAR("maxplayers");
 396                 BADCVAR("minplayers");
 397                 BADCVAR("net_address");
 398                 BADCVAR("port");
 399                 BADCVAR("rcon_password");
 400                 BADCVAR("rcon_restricted_commands");
 401                 BADCVAR("rcon_restricted_password");
 402                 BADCVAR("skill");
 403                 BADCVAR("sv_adminnick");
 404                 BADCVAR("sv_autoscreenshot");
 405                 BADCVAR("sv_autotaunt");
 406                 BADCVAR("sv_curl_defaulturl");
 407                 BADCVAR("sv_defaultcharacter");
 408                 BADCVAR("sv_defaultplayercolors");
 409                 BADCVAR("sv_defaultplayermodel");
 410                 BADCVAR("sv_defaultplayerskin");
 411                 BADCVAR("sv_maxidle");
 412                 BADCVAR("sv_maxrate");
 413                 BADCVAR("sv_motd");
 414                 BADCVAR("sv_public");
 415                 BADCVAR("sv_ready_restart");
 416                 BADCVAR("sv_status_privacy");
 417                 BADCVAR("sv_taunt");
 418                 BADCVAR("sv_vote_call");
 419                 BADCVAR("sv_vote_commands");
 420                 BADCVAR("sv_vote_majority_factor");
 421                 BADCVAR("sv_vote_master");
 422                 BADCVAR("sv_vote_master_commands");
 423                 BADCVAR("sv_vote_master_password");
 424                 BADCVAR("sv_vote_simple_majority_factor");
 425                 BADCVAR("teamplay_mode");
 426                 BADCVAR("timelimit_override");
 427                 BADCVAR("g_spawnshieldtime");
 428                 BADPREFIX("g_warmup_");
 429                 BADPREFIX("sv_ready_restart_");
 430
 431                 // mutators that announce themselves properly to the server browser
 432                 BADCVAR("g_instagib");
 433                 BADCVAR("g_new_toys");
 434                 BADCVAR("g_nix");
 435                 BADCVAR("g_grappling_hook");
 436                 BADCVAR("g_jetpack");
 437
 438 #undef BADPREFIX
 439 #undef BADCVAR
 440
 441                 if(pureadding)
 442                 {
 443                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 444                         if(strlen(cvar_purechanges) > 16384)
 445                         {
 446                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 447                                 pureadding = 0;
 448                         }
 449                 }
 450                 ++cvar_purechanges_count;
 451                 // WARNING: this variable is used for the server list
 452                 // NEVER dare to skip this code!
 453                 // Hacks to intentionally appearing as "pure server" even though you DO have
 454                 // modified settings may be punished by removal from the server list.
 455                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 456                 // though.
 457         }
 458         buf_del(h);
 459         if(cvar_changes == "")
 460                 cvar_changes = "// this server runs at default server settings\n";
 461         else
 462                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 463         cvar_changes = strzone(cvar_changes);
 464         if(cvar_purechanges == "")
 465                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 466         else
 467                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 468         cvar_purechanges = strzone(cvar_purechanges);
 469 }
 470
 471 void detect_maptype()
 472 {
 473 #if 0
 474         vector o, v;
 475         float i;
 476
 477         for (;;)
 478         {
 479                 o = world.mins;
 480                 o.x += random() * (world.maxs.x - world.mins.x);
 481                 o.y += random() * (world.maxs.y - world.mins.y);
 482                 o.z += random() * (world.maxs.z - world.mins.z);
 483
 484                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 485                 if(trace_fraction == 1)
 486                         continue;
 487
 488                 v = trace_endpos;
 489
 490                 for(i = 0; i < 64; i += 4)
 491                 {
 492                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 493         if(trace_fraction == 1)
 494                 continue;
 495                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 496                 }
 497
 498                 break;
 499         }
 500 #endif
 501 }
 502
 503 entity randomseed;
 504 bool RandomSeed_Send(entity this, entity to, int sf)
 505 {
 506         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 507         WriteShort(MSG_ENTITY, self.cnt);
 508         return true;
 509 }
 510 void RandomSeed_Think()
 511 {SELFPARAM();
 512         self.cnt = bound(0, floor(random() * 65536), 65535);
 513         self.nextthink = time + 5;
 514
 515         self.SendFlags |= 1;
 516 }
 517 void RandomSeed_Spawn()
 518 {SELFPARAM();
 519         randomseed = new(randomseed);
 520         make_pure(randomseed);
 521         randomseed.think = RandomSeed_Think;
 522         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 523
 524         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 525 }
 526
 527 spawnfunc(__init_dedicated_server)
 528 {
 529         // handler for _init/_init map (only for dedicated server initialization)
 530
 531         world_initialized = -1; // don't complain
 532         cvar = cvar_normal;
 533         cvar_string = cvar_string_normal;
 534         cvar_set = cvar_set_normal;
 535
 536         remove = remove_unsafely;
 537
 538         entity e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = new(info_player_deathmatch);  // safeguard against player joining
 543
 544         self.classname = "worldspawn"; // safeguard against various stuff ;)
 545
 546         // needs to be done so early because of the constants they create
 547         static_init();
 548         static_init_late();
 549         static_init_precache();
 550
 551         MapInfo_Enumerate();
 552         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 553 }
 554
 555 void Map_MarkAsRecent(string m);
 556 float world_already_spawned;
 557 void Nagger_Init();
 558 void ClientInit_Spawn();
 559 void WeaponStats_Init();
 560 void WeaponStats_Shutdown();
 561 void Physics_AddStats();
 562 spawnfunc(worldspawn)
 563 {
 564         float fd, l, j, n;
 565         string s;
 566
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         if(world_already_spawned)
 572                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 573         world_already_spawned = true;
 574
 575         remove = remove_safely; // during spawning, watch what you remove!
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 591
 592         // needs to be done so early because of the constants they create
 593         static_init();
 594
 595         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 596
 597         TemporaryDB = db_create();
 598
 599         // 0 normal
 600         lightstyle(0, "m");
 601
 602         // 1 FLICKER (first variety)
 603         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 604
 605         // 2 SLOW STRONG PULSE
 606         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 607
 608         // 3 CANDLE (first variety)
 609         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 610
 611         // 4 FAST STROBE
 612         lightstyle(4, "mamamamamama");
 613
 614         // 5 GENTLE PULSE 1
 615         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 616
 617         // 6 FLICKER (second variety)
 618         lightstyle(6, "nmonqnmomnmomomno");
 619
 620         // 7 CANDLE (second variety)
 621         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 622
 623         // 8 CANDLE (third variety)
 624         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 625
 626         // 9 SLOW STROBE (fourth variety)
 627         lightstyle(9, "aaaaaaaazzzzzzzz");
 628
 629         // 10 FLUORESCENT FLICKER
 630         lightstyle(10, "mmamammmmammamamaaamammma");
 631
 632         // 11 SLOW PULSE NOT FADE TO BLACK
 633         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 634
 635         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 636
 637         // 63 testing
 638         lightstyle(63, "a");
 639
 640         if(autocvar_g_campaign)
 641                 CampaignPreInit();
 642
 643         Map_MarkAsRecent(mapname);
 644
 645         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 646
 647         InitGameplayMode();
 648         static_init_late();
 649         static_init_precache();
 650         readlevelcvars();
 651         GrappleHookInit();
 652
 653         player_count = 0;
 654         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 655         if(bot_waypoints_for_items == 1)
 656                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 657                         bot_waypoints_for_items = 0;
 658
 659         precache();
 660
 661         WaypointSprite_Init();
 662
 663         GameLogInit(); // prepare everything
 664         // NOTE for matchid:
 665         // changing the logic generating it is okay. But:
 666         // it HAS to stay <= 64 chars
 667         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 668         if(autocvar_sv_eventlog)
 669         {
 670                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 671                 matchid = strzone(s);
 672
 673                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 674                 s = ":gameinfo:mutators:LIST";
 675
 676                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 677                 s = ret_string;
 678
 679                 // initialiation stuff, not good in the mutator system
 680                 if(!autocvar_g_use_ammunition)
 681                         s = strcat(s, ":no_use_ammunition");
 682
 683                 // initialiation stuff, not good in the mutator system
 684                 if(autocvar_g_pickup_items == 0)
 685                         s = strcat(s, ":no_pickup_items");
 686                 if(autocvar_g_pickup_items > 0)
 687                         s = strcat(s, ":pickup_items");
 688
 689                 // initialiation stuff, not good in the mutator system
 690                 if(autocvar_g_weaponarena != "0")
 691                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 692
 693                 // TODO to mutator system
 694                 if(autocvar_g_norecoil)
 695                         s = strcat(s, ":norecoil");
 696
 697                 // TODO to mutator system
 698                 if(autocvar_g_powerups == 0)
 699                         s = strcat(s, ":no_powerups");
 700                 if(autocvar_g_powerups > 0)
 701                         s = strcat(s, ":powerups");
 702
 703                 GameLogEcho(s);
 704                 GameLogEcho(":gameinfo:end");
 705         }
 706         else
 707                 matchid = strzone(ftos(random()));
 708
 709         cvar_set("nextmap", "");
 710
 711         SetDefaultAlpha();
 712
 713         if(autocvar_g_campaign)
 714                 CampaignPostInit();
 715
 716         Ban_LoadBans();
 717
 718         MapInfo_Enumerate();
 719         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 720
 721         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 722         {
 723                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 724                 if(fd != -1)
 725                 {
 726                         while((s = fgets(fd)))
 727                         {
 728                                 l = tokenize_console(s);
 729                                 if(l < 2)
 730                                         continue;
 731                                 if(argv(0) == "cd")
 732                                 {
 733                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 734                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 735                                 }
 736                                 else if(argv(0) == "fog")
 737                                 {
 738                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 739                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 740                                 }
 741                                 else if(argv(0) == "set")
 742                                 {
 743                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 744                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) != "//")
 747                                 {
 748                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 749                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 750                                 }
 751                         }
 752                         fclose(fd);
 753                 }
 754         }
 755
 756         WeaponStats_Init();
 757
 758         WepSet_AddStat();
 759         WepSet_AddStat_InMap();
 760         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 761         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 762         addstat(STAT_WEAPON_NEXTTHINK, AS_FLOAT, weapon_nextthink);
 763         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 764         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 765         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 766         Nagger_Init();
 767
 768         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 769         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 770         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 771         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 772         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 773         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 774         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 775         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 776         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 777         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 778         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 779         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 780         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 781         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 782         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 783
 784         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 785         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 786
 787         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 788
 789         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 790
 791         // freeze attacks
 792         addstat(STAT_FROZEN, AS_INT, frozen);
 793         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 794
 795         // physics
 796         Physics_AddStats();
 797
 798         // new properties
 799         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 800         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 801         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 802         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 803         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 804         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 805         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 806         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 807         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 808         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 809         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 810         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 811         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 812         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 813         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 814         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 815         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 816         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 817         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 818
 819         // secrets
 820         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 821         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 822
 823         // monsters
 824         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 825         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 826
 827         // misc
 828         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 829
 830         next_pingtime = time + 5;
 831
 832         detect_maptype();
 833
 834         // set up information replies for clients and server to use
 835         maplist_reply = strzone(getmaplist());
 836         lsmaps_reply = strzone(getlsmaps());
 837         monsterlist_reply = strzone(getmonsterlist());
 838         for(int i = 0; i < 10; ++i)
 839         {
 840                 s = getrecords(i);
 841                 if (s)
 842                         records_reply[i] = strzone(s);
 843         }
 844         ladder_reply = strzone(getladder());
 845         rankings_reply = strzone(getrankings());
 846
 847         // begin other init
 848         ClientInit_Spawn();
 849         RandomSeed_Spawn();
 850         PingPLReport_Spawn();
 851
 852         CheatInit();
 853
 854         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 855
 856         // fill sv_curl_serverpackages from .serverpackage files
 857         if(autocvar_sv_curl_serverpackages_auto)
 858         {
 859                 s = "";
 860                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 861                 for(int i = 0; i < n; ++i)
 862                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 863                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 864                                 s = strcat(s, " ", argv(i));
 865                 fd = search_begin("*-serverpackage.txt", true, false);
 866                 if(fd >= 0)
 867                 {
 868                         j = search_getsize(fd);
 869                         for(int i = 0; i < j; ++i)
 870                                 s = strcat(s, " ", search_getfilename(fd, i));
 871                         search_end(fd);
 872                 }
 873                 fd = search_begin("*.serverpackage", true, false);
 874                 if(fd >= 0)
 875                 {
 876                         j = search_getsize(fd);
 877                         for(int i = 0; i < j; ++i)
 878                                 s = strcat(s, " ", search_getfilename(fd, i));
 879                         search_end(fd);
 880                 }
 881                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 882         }
 883
 884         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 885         modname = "Xonotic";
 886         // physics/balance/config changes that count as mod
 887         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 888                 modname = cvar_string("g_mod_physics");
 889         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 890                 modname = cvar_string("g_mod_balance");
 891         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 892                 modname = cvar_string("g_mod_config");
 893         // extra mutators that deserve to count as mod
 894         MUTATOR_CALLHOOK(SetModname);
 895
 896         // save it for later
 897         modname = strzone(modname);
 898
 899         WinningConditionHelper(); // set worldstatus
 900
 901         world_initialized = 1;
 902 }
 903
 904 spawnfunc(light)
 905 {
 906         //makestatic (self); // Who the f___ did that?
 907         remove(self);
 908 }
 909
 910 string GetGametype()
 911 {
 912         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 913 }
 914
 915 string GetMapname()
 916 {
 917         return mapname;
 918 }
 919
 920 float Map_Count, Map_Current;
 921 string Map_Current_Name;
 922
 923 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 924 float GetMaplistPosition()
 925 {
 926         float pos, idx;
 927         string map;
 928
 929         map = GetMapname();
 930         idx = autocvar_g_maplist_index;
 931
 932         if(idx >= 0)
 933                 if(idx < Map_Count)
 934                         if(map == argv(idx))
 935                                 return idx;
 936
 937         for(pos = 0; pos < Map_Count; ++pos)
 938                 if(map == argv(pos))
 939                         return pos;
 940
 941         // resume normal maplist rotation if current map is not in g_maplist
 942         return idx;
 943 }
 944
 945 float MapHasRightSize(string map)
 946 {
 947         float fh;
 948         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 949         if(autocvar_g_maplist_check_waypoints)
 950         {
 951                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 952                 if(!fexists(strcat("maps/", map, ".waypoints")))
 953                 {
 954                         LOG_TRACE(": no waypoints\n");
 955                         return false;
 956                 }
 957                 LOG_TRACE(": has waypoints\n");
 958         }
 959
 960         // open map size restriction file
 961         LOG_TRACE("opensize "); LOG_TRACE(map);
 962         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 963         if(fh >= 0)
 964         {
 965                 float mapmin, mapmax;
 966                 LOG_TRACE(": ok, ");
 967                 mapmin = stof(fgets(fh));
 968                 mapmax = stof(fgets(fh));
 969                 fclose(fh);
 970                 if(player_count < mapmin)
 971                 {
 972                         LOG_TRACE("not enough\n");
 973                         return false;
 974                 }
 975                 if(player_count > mapmax)
 976                 {
 977                         LOG_TRACE("too many\n");
 978                         return false;
 979                 }
 980                 LOG_TRACE("right size\n");
 981                 return true;
 982         }
 983         LOG_TRACE(": not found\n");
 984         return true;
 985 }
 986
 987 string Map_Filename(float position)
 988 {
 989         return strcat("maps/", argv(position), ".bsp");
 990 }
 991
 992 void Map_MarkAsRecent(string m)
 993 {
 994         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 995 }
 996
 997 float Map_IsRecent(string m)
 998 {
 999         return strhasword(autocvar_g_maplist_mostrecent, m);
1000 }
1001
1002 float Map_Check(float position, float pass)
1003 {
1004         string filename;
1005         string map_next;
1006         map_next = argv(position);
1007         if(pass <= 1)
1008         {
1009                 if(Map_IsRecent(map_next))
1010                         return 0;
1011         }
1012         filename = Map_Filename(position);
1013         if(MapInfo_CheckMap(map_next))
1014         {
1015                 if(pass == 2)
1016                         return 1;
1017                 if(MapHasRightSize(map_next))
1018                         return 1;
1019                 return 0;
1020         }
1021         else
1022                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1023
1024         return 0;
1025 }
1026
1027 void Map_Goto_SetStr(string nextmapname)
1028 {
1029         if(getmapname_stored != "")
1030                 strunzone(getmapname_stored);
1031         if(nextmapname == "")
1032                 getmapname_stored = "";
1033         else
1034                 getmapname_stored = strzone(nextmapname);
1035 }
1036
1037 void Map_Goto_SetFloat(float position)
1038 {
1039         cvar_set("g_maplist_index", ftos(position));
1040         Map_Goto_SetStr(argv(position));
1041 }
1042
1043 void Map_Goto(float reinit)
1044 {
1045         MapInfo_LoadMap(getmapname_stored, reinit);
1046 }
1047
1048 // return codes of map selectors:
1049 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1050 //   -2 = permanent failure
1051 float() MaplistMethod_Iterate = // usual method
1052 {
1053         float pass, i;
1054
1055         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1056
1057         for(pass = 1; pass <= 2; ++pass)
1058         {
1059                 for(i = 1; i < Map_Count; ++i)
1060                 {
1061                         float mapindex;
1062                         mapindex = (i + Map_Current) % Map_Count;
1063                         if(Map_Check(mapindex, pass))
1064                                 return mapindex;
1065                 }
1066         }
1067         return -1;
1068 }
1069
1070 float() MaplistMethod_Repeat = // fallback method
1071 {
1072         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1073
1074         if(Map_Check(Map_Current, 2))
1075                 return Map_Current;
1076         return -2;
1077 }
1078
1079 float() MaplistMethod_Random = // random map selection
1080 {
1081         float i, imax;
1082
1083         LOG_TRACE("Trying MaplistMethod_Random\n");
1084
1085         imax = 42;
1086
1087         for(i = 0; i <= imax; ++i)
1088         {
1089                 float mapindex;
1090                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1091                 if(Map_Check(mapindex, 1))
1092                         return mapindex;
1093         }
1094         return -1;
1095 }
1096
1097 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1098 // the exponent sets a bias on the map selection:
1099 // the higher the exponent, the less likely "shortly repeated" same maps are
1100 {
1101         float i, j, imax, insertpos;
1102
1103         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1104
1105         imax = 42;
1106
1107         for(i = 0; i <= imax; ++i)
1108         {
1109                 string newlist;
1110
1111                 // now reinsert this at another position
1112                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1113                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1114                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1115                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1116
1117                 // insert the current map there
1118                 newlist = "";
1119                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1120                         newlist = strcat(newlist, " ", argv(j));
1121                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1122                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1123                         newlist = strcat(newlist, " ", argv(j));
1124                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1125                 cvar_set("g_maplist", newlist);
1126                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1127
1128                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1129                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1130                 if(Map_Check(Map_Current, 1))
1131                         return Map_Current;
1132         }
1133         return -1;
1134 }
1135
1136 void Maplist_Init()
1137 {
1138         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1139         float i;
1140         for (i = 0; i < Map_Count; ++i)
1141                 if (Map_Check(i, 2))
1142                         break;
1143         if (i == Map_Count)
1144         {
1145                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1146                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1147                 if(autocvar_g_maplist_shuffle)
1148                         ShuffleMaplist();
1149                 localcmd("\nmenu_cmd sync\n");
1150                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1151         }
1152         if(Map_Count == 0)
1153                 error("empty maplist, cannot select a new map");
1154         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1155
1156         if(Map_Current_Name)
1157                 strunzone(Map_Current_Name);
1158         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1159         // this may or may not be correct, but who cares, in the worst case a map
1160         // isn't chosen in the first pass that should have been
1161 }
1162
1163 string GetNextMap()
1164 {
1165         float nextMap;
1166
1167         Maplist_Init();
1168         nextMap = -1;
1169
1170         if(nextMap == -1)
1171                 if(autocvar_g_maplist_shuffle > 0)
1172                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1173
1174         if(nextMap == -1)
1175                 if(autocvar_g_maplist_selectrandom)
1176                         nextMap = MaplistMethod_Random();
1177
1178         if(nextMap == -1)
1179                 nextMap = MaplistMethod_Iterate();
1180
1181         if(nextMap == -1)
1182                 nextMap = MaplistMethod_Repeat();
1183
1184         if(nextMap >= 0)
1185         {
1186                 Map_Goto_SetFloat(nextMap);
1187                 return getmapname_stored;
1188         }
1189
1190         return "";
1191 }
1192
1193 float DoNextMapOverride(float reinit)
1194 {
1195         if(autocvar_g_campaign)
1196         {
1197                 CampaignPostIntermission();
1198                 alreadychangedlevel = true;
1199                 return true;
1200         }
1201         if(autocvar_quit_when_empty)
1202         {
1203                 if(player_count <= currentbots)
1204                 {
1205                         localcmd("quit\n");
1206                         alreadychangedlevel = true;
1207                         return true;
1208                 }
1209         }
1210         if(autocvar_quit_and_redirect != "")
1211         {
1212                 redirection_target = strzone(autocvar_quit_and_redirect);
1213                 alreadychangedlevel = true;
1214                 return true;
1215         }
1216         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1217         {
1218                 localcmd("restart\n");
1219                 alreadychangedlevel = true;
1220                 return true;
1221         }
1222         if(autocvar_nextmap != "")
1223         {
1224                 string m;
1225                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1226                 cvar_set("nextmap",m);
1227
1228                 if(!m || gametypevote)
1229                         return false;
1230                 if(autocvar_sv_vote_gametype)
1231                 {
1232                         Map_Goto_SetStr(m);
1233                         return false;
1234                 }
1235
1236                 if(MapInfo_CheckMap(m))
1237                 {
1238                         Map_Goto_SetStr(m);
1239                         Map_Goto(reinit);
1240                         alreadychangedlevel = true;
1241                         return true;
1242                 }
1243         }
1244         if(!reinit && autocvar_lastlevel)
1245         {
1246                 cvar_settemp_restore();
1247                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1248                 alreadychangedlevel = true;
1249                 return true;
1250         }
1251         return false;
1252 }
1253
1254 void GotoNextMap(float reinit)
1255 {
1256         //string nextmap;
1257         //float n, nummaps;
1258         //string s;
1259         if (alreadychangedlevel)
1260                 return;
1261         alreadychangedlevel = true;
1262
1263         string nextMap;
1264
1265         nextMap = GetNextMap();
1266         if(nextMap == "")
1267                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1268         Map_Goto(reinit);
1269 }
1270
1271
1272 /*
1273 ============
1274 IntermissionThink
1275
1276 When the player presses attack or jump, change to the next level
1277 ============
1278 */
1279 .float autoscreenshot;
1280 void IntermissionThink()
1281 {SELFPARAM();
1282         FixIntermissionClient(self);
1283
1284         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1285         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1286
1287         if( (server_screenshot || client_screenshot)
1288                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1289         {
1290                 self.autoscreenshot = -1;
1291                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1292                 return;
1293         }
1294
1295         if (time < intermission_exittime)
1296                 return;
1297
1298         if(!mapvote_initialized)
1299                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1300                         return;
1301
1302         MapVote_Start();
1303 }
1304
1305 /*
1306 ============
1307 FindIntermission
1308
1309 Returns the entity to view from
1310 ============
1311 */
1312 /*
1313 entity FindIntermission()
1314 {
1315         local   entity spot;
1316         local   float cyc;
1317
1318 // look for info_intermission first
1319         spot = find (world, classname, "info_intermission");
1320         if (spot)
1321         {       // pick a random one
1322                 cyc = random() * 4;
1323                 while (cyc > 1)
1324                 {
1325                         spot = find (spot, classname, "info_intermission");
1326                         if (!spot)
1327                                 spot = find (spot, classname, "info_intermission");
1328                         cyc = cyc - 1;
1329                 }
1330                 return spot;
1331         }
1332
1333 // then look for the start position
1334         spot = find (world, classname, "info_player_start");
1335         if (spot)
1336                 return spot;
1337
1338 // testinfo_player_start is only found in regioned levels
1339         spot = find (world, classname, "testplayerstart");
1340         if (spot)
1341                 return spot;
1342
1343 // then look for the start position
1344         spot = find (world, classname, "info_player_deathmatch");
1345         if (spot)
1346                 return spot;
1347
1348         //objerror ("FindIntermission: no spot");
1349         return world;
1350 }
1351 */
1352
1353 /*
1354 ===============================================================================
1355
1356 RULES
1357
1358 ===============================================================================
1359 */
1360
1361 void DumpStats(float final)
1362 {
1363         float file;
1364         string s;
1365         float to_console;
1366         float to_eventlog;
1367         float to_file;
1368         float i;
1369
1370         to_console = autocvar_sv_logscores_console;
1371         to_eventlog = autocvar_sv_eventlog;
1372         to_file = autocvar_sv_logscores_file;
1373
1374         if(!final)
1375         {
1376                 to_console = true; // always print printstats replies
1377                 to_eventlog = false; // but never print them to the event log
1378         }
1379
1380         if(to_eventlog)
1381                 if(autocvar_sv_eventlog_console)
1382                         to_console = false; // otherwise we get the output twice
1383
1384         if(final)
1385                 s = ":scores:";
1386         else
1387                 s = ":status:";
1388         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1389
1390         if(to_console)
1391                 LOG_INFO(s, "\n");
1392         if(to_eventlog)
1393                 GameLogEcho(s);
1394
1395         file = -1;
1396         if(to_file)
1397         {
1398                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1399                 if(file == -1)
1400                         to_file = false;
1401                 else
1402                         fputs(file, strcat(s, "\n"));
1403         }
1404
1405         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1406         if(to_console)
1407                 LOG_INFO(s, "\n");
1408         if(to_eventlog)
1409                 GameLogEcho(s);
1410         if(to_file)
1411                 fputs(file, strcat(s, "\n"));
1412
1413         FOR_EACH_CLIENT(other)
1414         {
1415                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1416                 {
1417                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1418                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1419                         if(IS_PLAYER(other) || MUTATOR_CALLHOOK(GetPlayerStatus, other, s))
1420                                 s = strcat(s, ftos(other.team), ":");
1421                         else
1422                                 s = strcat(s, "spectator:");
1423
1424                         if(to_console)
1425                                 LOG_INFO(s, other.netname, "\n");
1426                         if(to_eventlog)
1427                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1428                         if(to_file)
1429                                 fputs(file, strcat(s, other.netname, "\n"));
1430                 }
1431         }
1432
1433         if(teamplay)
1434         {
1435                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1436                 if(to_console)
1437                         LOG_INFO(s, "\n");
1438                 if(to_eventlog)
1439                         GameLogEcho(s);
1440                 if(to_file)
1441                         fputs(file, strcat(s, "\n"));
1442
1443                 for(i = 1; i < 16; ++i)
1444                 {
1445                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1446                         s = strcat(s, ":", ftos(i));
1447                         if(to_console)
1448                                 LOG_INFO(s, "\n");
1449                         if(to_eventlog)
1450                                 GameLogEcho(s);
1451                         if(to_file)
1452                                 fputs(file, strcat(s, "\n"));
1453                 }
1454         }
1455
1456         if(to_console)
1457                 LOG_INFO(":end\n");
1458         if(to_eventlog)
1459                 GameLogEcho(":end");
1460         if(to_file)
1461         {
1462                 fputs(file, ":end\n");
1463                 fclose(file);
1464         }
1465 }
1466
1467 void FixIntermissionClient(entity e)
1468 {
1469         string s;
1470         if(!e.autoscreenshot) // initial call
1471         {
1472                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1473                 e.health = -2342;
1474                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1475                 e.solid = SOLID_NOT;
1476                 e.movetype = MOVETYPE_NONE;
1477                 e.takedamage = DAMAGE_NO;
1478                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1479                 {
1480                     .entity weaponentity = weaponentities[slot];
1481                         if(e.(weaponentity))
1482                         {
1483                                 e.(weaponentity).effects = EF_NODRAW;
1484                                 if (e.(weaponentity).weaponchild)
1485                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1486                         }
1487                 }
1488                 if(IS_REAL_CLIENT(e))
1489                 {
1490                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1491                         s = autocvar_sv_intermission_cdtrack;
1492                         if(s != "")
1493                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1494                         msg_entity = e;
1495                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1496                 }
1497         }
1498 }
1499
1500 /*
1501 go to the next level for deathmatch
1502 only called if a time or frag limit has expired
1503 */
1504 void NextLevel()
1505 {
1506         gameover = true;
1507
1508         intermission_running = 1;
1509
1510 // enforce a wait time before allowing changelevel
1511         if(player_count > 0)
1512                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1513         else
1514                 intermission_exittime = -1;
1515
1516         /*
1517         WriteByte (MSG_ALL, SVC_CDTRACK);
1518         WriteByte (MSG_ALL, 3);
1519         WriteByte (MSG_ALL, 3);
1520         // done in FixIntermission
1521         */
1522
1523         //pos = FindIntermission ();
1524
1525         VoteReset();
1526
1527         DumpStats(true);
1528
1529         // send statistics
1530         PlayerStats_GameReport(true);
1531         WeaponStats_Shutdown();
1532
1533         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1534
1535         if(autocvar_sv_eventlog)
1536                 GameLogEcho(":gameover");
1537
1538         GameLogClose();
1539
1540         FOR_EACH_PLAYER(other) {
1541                 FixIntermissionClient(other);
1542                 if(other.winning)
1543                         bprint(other.netname, " ^7wins.\n");
1544         }
1545
1546         entity oldself = self;
1547         target_music_kill();
1548         self = oldself;
1549
1550         if(autocvar_g_campaign)
1551                 CampaignPreIntermission();
1552
1553         MUTATOR_CALLHOOK(MatchEnd);
1554
1555         localcmd("\nsv_hook_gameend\n");
1556 }
1557
1558 /*
1559 ============
1560 CheckRules_Player
1561
1562 Exit deathmatch games upon conditions
1563 ============
1564 */
1565 void CheckRules_Player()
1566 {SELFPARAM();
1567         if (gameover)   // someone else quit the game already
1568                 return;
1569
1570         if(self.deadflag == DEAD_NO)
1571                 self.play_time += frametime;
1572
1573         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1574         //   (div0: and that in CheckRules_World please)
1575 }
1576
1577
1578 float InitiateSuddenDeath()
1579 {
1580         // Check first whether normal overtimes could be added before initiating suddendeath mode
1581         // - for this timelimit_overtime needs to be >0 of course
1582         // - also check the winning condition calculated in the previous frame and only add normal overtime
1583         //   again, if at the point at which timelimit would be extended again, still no winner was found
1584         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1585         {
1586                 return 1; // need to call InitiateOvertime later
1587         }
1588         else
1589         {
1590                 if(!checkrules_suddendeathend)
1591                 {
1592                         if(autocvar_g_campaign)
1593                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1594                         else
1595                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1596                         if(g_race && !g_race_qualifying)
1597                                 race_StartCompleting();
1598                 }
1599                 return 0;
1600         }
1601 }
1602
1603 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1604 {
1605         ++checkrules_overtimesadded;
1606         //add one more overtime by simply extending the timelimit
1607         float tl;
1608         tl = autocvar_timelimit;
1609         tl += autocvar_timelimit_overtime;
1610         cvar_set("timelimit", ftos(tl));
1611
1612         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1613 }
1614
1615 float GetWinningCode(float fraglimitreached, float equality)
1616 {
1617         if(autocvar_g_campaign == 1)
1618                 if(fraglimitreached)
1619                         return WINNING_YES;
1620                 else
1621                         return WINNING_NO;
1622
1623         else
1624                 if(equality)
1625                         if(fraglimitreached)
1626                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1627                         else
1628                                 return WINNING_NEVER;
1629                 else
1630                         if(fraglimitreached)
1631                                 return WINNING_YES;
1632                         else
1633                                 return WINNING_NO;
1634 }
1635
1636 // set the .winning flag for exactly those players with a given field value
1637 void SetWinners(.float field, float value)
1638 {
1639         entity head;
1640         FOR_EACH_PLAYER(head)
1641                 head.winning = (head.(field) == value);
1642 }
1643
1644 // set the .winning flag for those players with a given field value
1645 void AddWinners(.float field, float value)
1646 {
1647         entity head;
1648         FOR_EACH_PLAYER(head)
1649                 if (head.(field) == value)
1650                         head.winning = 1;
1651 }
1652
1653 // clear the .winning flags
1654 void ClearWinners()
1655 {
1656         entity head;
1657         FOR_EACH_PLAYER(head)
1658                 head.winning = 0;
1659 }
1660
1661 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1662 // they win. Otherwise the defending team wins once the timelimit passes.
1663 void assault_new_round();
1664 float WinningCondition_Assault()
1665 {SELFPARAM();
1666         float status;
1667
1668         WinningConditionHelper(); // set worldstatus
1669
1670         status = WINNING_NO;
1671         // as the timelimit has not yet passed just assume the defending team will win
1672         if(assault_attacker_team == NUM_TEAM_1)
1673         {
1674                 SetWinners(team, NUM_TEAM_2);
1675         }
1676         else
1677         {
1678                 SetWinners(team, NUM_TEAM_1);
1679         }
1680
1681         entity ent;
1682         ent = find(world, classname, "target_assault_roundend");
1683         if(ent)
1684         {
1685                 if(ent.winning) // round end has been triggered by attacking team
1686                 {
1687                         bprint("ASSAULT: round completed...\n");
1688                         SetWinners(team, assault_attacker_team);
1689
1690                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1691
1692                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1693                         {
1694                                 status = WINNING_YES;
1695                         }
1696                         else
1697                         {
1698                                 WITH(entity, self, ent, assault_new_round());
1699                         }
1700                 }
1701         }
1702
1703         return status;
1704 }
1705
1706 void ShuffleMaplist()
1707 {
1708         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1709 }
1710
1711 float leaderfrags;
1712 float WinningCondition_Scores(float limit, float leadlimit)
1713 {
1714         float limitreached;
1715
1716         // TODO make everything use THIS winning condition (except LMS)
1717         WinningConditionHelper();
1718
1719         if(teamplay)
1720         {
1721                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1722                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1723                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1724                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1725         }
1726
1727         ClearWinners();
1728         if(WinningConditionHelper_winner)
1729                 WinningConditionHelper_winner.winning = 1;
1730         if(WinningConditionHelper_winnerteam >= 0)
1731                 SetWinners(team, WinningConditionHelper_winnerteam);
1732
1733         if(WinningConditionHelper_lowerisbetter)
1734         {
1735                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1736                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1737                 limit = -limit;
1738         }
1739
1740         if(WinningConditionHelper_zeroisworst)
1741                 leadlimit = 0; // not supported in this mode
1742
1743         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1744         // these modes always score in increments of 1, thus this makes sense
1745         {
1746                 if(leaderfrags != WinningConditionHelper_topscore)
1747                 {
1748                         leaderfrags = WinningConditionHelper_topscore;
1749
1750                         if (limit)
1751                         if (leaderfrags == limit - 1)
1752                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1753                         else if (leaderfrags == limit - 2)
1754                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1755                         else if (leaderfrags == limit - 3)
1756                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1757                 }
1758         }
1759
1760         limitreached = false;
1761         if(limit)
1762                 if(WinningConditionHelper_topscore >= limit)
1763                         limitreached = true;
1764         if(leadlimit)
1765         {
1766                 float leadlimitreached;
1767                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1768                 if(autocvar_leadlimit_and_fraglimit)
1769                         limitreached = (limitreached && leadlimitreached);
1770                 else
1771                         limitreached = (limitreached || leadlimitreached);
1772         }
1773
1774         if(limit)
1775                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1776
1777         return GetWinningCode(
1778                 WinningConditionHelper_topscore && limitreached,
1779                 WinningConditionHelper_equality
1780         );
1781 }
1782
1783 float WinningCondition_Race(float fraglimit)
1784 {
1785         float wc;
1786         entity p;
1787         float n, c;
1788
1789         n = 0;
1790         c = 0;
1791         FOR_EACH_PLAYER(p)
1792         {
1793                 ++n;
1794                 if(p.race_completed)
1795                         ++c;
1796         }
1797         if(n && (n == c))
1798                 return WINNING_YES;
1799         wc = WinningCondition_Scores(fraglimit, 0);
1800
1801         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1802         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1803         // do NOT support equality when the laps are all raced!
1804                 return WINNING_STARTSUDDENDEATHOVERTIME;
1805         else
1806                 return WINNING_NEVER;
1807 }
1808
1809 float WinningCondition_QualifyingThenRace(float limit)
1810 {
1811         float wc;
1812         wc = WinningCondition_Scores(limit, 0);
1813
1814         // NEVER initiate overtime
1815         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1816         {
1817                 return WINNING_YES;
1818         }
1819
1820         return wc;
1821 }
1822
1823 float WinningCondition_RanOutOfSpawns()
1824 {
1825         entity head;
1826
1827         if(have_team_spawns <= 0)
1828                 return WINNING_NO;
1829
1830         if(!autocvar_g_spawn_useallspawns)
1831                 return WINNING_NO;
1832
1833         if(!some_spawn_has_been_used)
1834                 return WINNING_NO;
1835
1836         team1_score = team2_score = team3_score = team4_score = 0;
1837
1838         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1839         {
1840                 if(head.team == NUM_TEAM_1)
1841                         team1_score = 1;
1842                 else if(head.team == NUM_TEAM_2)
1843                         team2_score = 1;
1844                 else if(head.team == NUM_TEAM_3)
1845                         team3_score = 1;
1846                 else if(head.team == NUM_TEAM_4)
1847                         team4_score = 1;
1848         }
1849
1850         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1851         {
1852                 if(head.team == NUM_TEAM_1)
1853                         team1_score = 1;
1854                 else if(head.team == NUM_TEAM_2)
1855                         team2_score = 1;
1856                 else if(head.team == NUM_TEAM_3)
1857                         team3_score = 1;
1858                 else if(head.team == NUM_TEAM_4)
1859                         team4_score = 1;
1860         }
1861
1862         ClearWinners();
1863         if(team1_score + team2_score + team3_score + team4_score == 0)
1864         {
1865                 checkrules_equality = true;
1866                 return WINNING_YES;
1867         }
1868         else if(team1_score + team2_score + team3_score + team4_score == 1)
1869         {
1870                 float t, i;
1871                 if(team1_score)
1872                         t = NUM_TEAM_1;
1873                 else if(team2_score)
1874                         t = NUM_TEAM_2;
1875                 else if(team3_score)
1876                         t = NUM_TEAM_3;
1877                 else // if(team4_score)
1878                         t = NUM_TEAM_4;
1879                 CheckAllowedTeams(world);
1880                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1881                 {
1882                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1883                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1884                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1885                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1886                 }
1887
1888                 AddWinners(team, t);
1889                 return WINNING_YES;
1890         }
1891         else
1892                 return WINNING_NO;
1893 }
1894
1895 /*
1896 ============
1897 CheckRules_World
1898
1899 Exit deathmatch games upon conditions
1900 ============
1901 */
1902 void CheckRules_World()
1903 {
1904         float timelimit;
1905         float fraglimit;
1906         float leadlimit;
1907
1908         VoteThink();
1909         MapVote_Think();
1910
1911         SetDefaultAlpha();
1912
1913         if (gameover)   // someone else quit the game already
1914         {
1915                 if(player_count == 0) // Nobody there? Then let's go to the next map
1916                         MapVote_Start();
1917                         // this will actually check the player count in the next frame
1918                         // again, but this shouldn't hurt
1919                 return;
1920         }
1921
1922         timelimit = autocvar_timelimit * 60;
1923         fraglimit = autocvar_fraglimit;
1924         leadlimit = autocvar_leadlimit;
1925
1926         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1927         {
1928                 if(timelimit > 0)
1929                         timelimit = 0; // timelimit is not made for warmup
1930                 if(fraglimit > 0)
1931                         fraglimit = 0; // no fraglimit for now
1932                 leadlimit = 0; // no leadlimit for now
1933         }
1934
1935         if(timelimit > 0)
1936         {
1937                 timelimit += game_starttime;
1938         }
1939         else if (timelimit < 0)
1940         {
1941                 // endmatch
1942                 NextLevel();
1943                 return;
1944         }
1945
1946         float wantovertime;
1947         wantovertime = 0;
1948
1949         if(timelimit > game_starttime)
1950                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1951         else
1952                 game_completion_ratio = 0;
1953
1954         if(checkrules_suddendeathend)
1955         {
1956                 if(!checkrules_suddendeathwarning)
1957                 {
1958                         checkrules_suddendeathwarning = true;
1959                         if(g_race && !g_race_qualifying)
1960                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1961                         else
1962                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1963                 }
1964         }
1965         else
1966         {
1967                 if (timelimit && time >= timelimit)
1968                 {
1969                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1970                         {
1971                                 float totalplayers;
1972                                 float playerswithlaps;
1973                                 float readyplayers;
1974                                 entity head;
1975                                 totalplayers = playerswithlaps = readyplayers = 0;
1976                                 FOR_EACH_PLAYER(head)
1977                                 {
1978                                         ++totalplayers;
1979                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1980                                                 ++playerswithlaps;
1981                                         if(head.ready)
1982                                                 ++readyplayers;
1983                                 }
1984
1985                                 // at least 2 of the players have completed a lap: start the RACE
1986                                 // otherwise, the players should end the qualifying on their own
1987                                 if(readyplayers || playerswithlaps >= 2)
1988                                 {
1989                                         checkrules_suddendeathend = 0;
1990                                         ReadyRestart(); // go to race
1991                                         return;
1992                                 }
1993                                 else
1994                                         wantovertime |= InitiateSuddenDeath();
1995                         }
1996                         else
1997                                 wantovertime |= InitiateSuddenDeath();
1998                 }
1999         }
2000
2001         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2002         {
2003                 NextLevel();
2004                 return;
2005         }
2006
2007         int checkrules_status = WinningCondition_RanOutOfSpawns();
2008         if(checkrules_status == WINNING_YES)
2009                 bprint("Hey! Someone ran out of spawns!\n");
2010         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
2011                 checkrules_status = ret_float;
2012         else
2013                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2014
2015         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2016         {
2017                 checkrules_status = WINNING_NEVER;
2018                 checkrules_overtimesadded = -1;
2019                 wantovertime |= InitiateSuddenDeath();
2020         }
2021
2022         if(checkrules_status == WINNING_NEVER)
2023                 // equality cases! Nobody wins if the overtime ends in a draw.
2024                 ClearWinners();
2025
2026         if(wantovertime)
2027         {
2028                 if(checkrules_status == WINNING_NEVER)
2029                         InitiateOvertime();
2030                 else
2031                         checkrules_status = WINNING_YES;
2032         }
2033
2034         if(checkrules_suddendeathend)
2035                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2036                         checkrules_status = WINNING_YES;
2037
2038         if(checkrules_status == WINNING_YES)
2039         {
2040                 //print("WINNING\n");
2041                 NextLevel();
2042         }
2043 }
2044
2045 string GotoMap(string m)
2046 {
2047         m = GameTypeVote_MapInfo_FixName(m);
2048         if (!m)
2049                 return "The map you suggested is not available on this server.";
2050         if (!autocvar_sv_vote_gametype)
2051         if(!MapInfo_CheckMap(m))
2052                 return "The map you suggested does not support the current game mode.";
2053         cvar_set("nextmap", m);
2054         cvar_set("timelimit", "-1");
2055         if(mapvote_initialized || alreadychangedlevel)
2056         {
2057                 if(DoNextMapOverride(0))
2058                         return "Map switch initiated.";
2059                 else
2060                         return "Hm... no. For some reason I like THIS map more.";
2061         }
2062         else
2063                 return "Map switch will happen after scoreboard.";
2064 }
2065
2066
2067 void EndFrame()
2068 {SELFPARAM();
2069         anticheat_endframe();
2070
2071         float altime;
2072         entity e_;
2073         FOR_EACH_REALCLIENT(e_)
2074         {
2075                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2076                 if(e.typehitsound)
2077                         e_.typehit_time = time;
2078                 else if(e.damage_dealt)
2079                 {
2080                         e_.hit_time = time;
2081                         e_.damage_dealt_total += ceil(e.damage_dealt);
2082                 }
2083         }
2084         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2085         // add 1 frametime because after this, engine SV_Physics
2086         // increases time by a frametime and then networks the frame
2087         // add another frametime because client shows everything with
2088         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2089         // needed!
2090         FOR_EACH_CLIENT(e_)
2091         {
2092                 e_.typehitsound = false;
2093                 e_.damage_dealt = 0;
2094                 setself(e_);
2095                 antilag_record(e_, altime);
2096         }
2097         FOR_EACH_MONSTER(e_)
2098         {
2099                 setself(e_);
2100                 antilag_record(e_, altime);
2101         }
2102 }
2103
2104
2105 /*
2106  * RedirectionThink:
2107  * returns true if redirecting
2108  */
2109 float redirection_timeout;
2110 float redirection_nextthink;
2111 float RedirectionThink()
2112 {SELFPARAM();
2113         float clients_found;
2114
2115         if(redirection_target == "")
2116                 return false;
2117
2118         if(!redirection_timeout)
2119         {
2120                 cvar_set("sv_public", "-2");
2121                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2122                 if(redirection_target == "self")
2123                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2124                 else
2125                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2126         }
2127
2128         if(time < redirection_nextthink)
2129                 return true;
2130
2131         redirection_nextthink = time + 1;
2132
2133         clients_found = 0;
2134         entity e;
2135         FOR_EACH_REALCLIENT(e)
2136         {
2137                 setself(e);
2138                 // TODO add timer
2139                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2140                 if(redirection_target == "self")
2141                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2142                 else
2143                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2144                 ++clients_found;
2145         }
2146
2147         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2148
2149         if(time > redirection_timeout || clients_found == 0)
2150                 localcmd("\nwait; wait; wait; quit\n");
2151
2152         return true;
2153 }
2154
2155 void TargetMusic_RestoreGame();
2156 void RestoreGame()
2157 {
2158         // Loaded from a save game
2159         // some things then break, so let's work around them...
2160
2161         // Progs DB (capture records)
2162         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2163
2164         // Mapinfo
2165         MapInfo_Shutdown();
2166         MapInfo_Enumerate();
2167         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2168         WeaponStats_Init();
2169
2170         TargetMusic_RestoreGame();
2171 }
2172
2173 void Shutdown()
2174 {
2175         gameover = 2;
2176
2177         if(world_initialized > 0)
2178         {
2179                 world_initialized = 0;
2180                 LOG_INFO("Saving persistent data...\n");
2181                 Ban_SaveBans();
2182
2183                 // playerstats with unfinished match
2184                 PlayerStats_GameReport(false);
2185
2186                 if(!cheatcount_total)
2187                 {
2188                         if(autocvar_sv_db_saveasdump)
2189                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2190                         else
2191                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2192                 }
2193                 if(autocvar_developer)
2194                 {
2195                         if(autocvar_sv_db_saveasdump)
2196                                 db_dump(TemporaryDB, "server-temp.db");
2197                         else
2198                                 db_save(TemporaryDB, "server-temp.db");
2199                 }
2200                 CheatShutdown(); // must be after cheatcount check
2201                 db_close(ServerProgsDB);
2202                 db_close(TemporaryDB);
2203                 LOG_INFO("done!\n");
2204                 // tell the bot system the game is ending now
2205                 bot_endgame();
2206
2207                 WeaponStats_Shutdown();
2208                 MapInfo_Shutdown();
2209         }
2210         else if(world_initialized == 0)
2211         {
2212                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2213         }
2214 }