qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include "../common/deathtypes/all.qh"
  23 #include "../common/mapinfo.qh"
  24 #include "../common/monsters/all.qh"
  25 #include "../common/monsters/sv_monsters.qh"
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/notifications/all.qh"
  28 #include "../common/physics/player.qh"
  29 #include "../common/playerstats.qh"
  30 #include "../common/stats.qh"
  31 #include "../common/teams.qh"
  32 #include "../common/triggers/trigger/secret.qh"
  33 #include "../common/triggers/target/music.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/all.qh"
  36 #include "../common/weapons/all.qh"
  37 #include "../common/state.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {SELFPARAM();
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         this.nextthink = time + delta;
  53
  54         e = edict_num(this.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, this.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, this.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         this.cnt = (this.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new_pure(pingplreport);
  85         pingplreport.think = PingPLReport_Think;
  86         pingplreport.nextthink = time;
  87 }
  88
  89 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  90 string redirection_target;
  91 float world_initialized;
  92
  93 string GetGametype();
  94 void ShuffleMaplist();
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap()
 108 {SELFPARAM();
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 self.nextthink = time;
 133         }
 134         else
 135         {
 136                 self.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         if(cvar_changes)
 148                 strunzone(cvar_changes);
 149         cvar_changes = string_null;
 150         if(cvar_purechanges)
 151                 strunzone(cvar_purechanges);
 152         cvar_purechanges = string_null;
 153         cvar_purechanges_count = 0;
 154
 155         h = buf_create();
 156         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 157         n = buf_getsize(h);
 158
 159         adding = true;
 160         pureadding = true;
 161
 162         for(i = 0; i < n; ++i)
 163         {
 164                 k = bufstr_get(h, i);
 165
 166 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 167 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 168 #define BADCVAR(p) if(k == p) continue
 169
 170                 // general excludes and namespaces for server admin used cvars
 171                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 172
 173                 // internal
 174                 BADPREFIX("csqc_");
 175                 BADPREFIX("cvar_check_");
 176                 BADCVAR("gamecfg");
 177                 BADCVAR("g_configversion");
 178                 BADCVAR("g_maplist_index");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213
 214                 // private
 215                 BADCVAR("developer");
 216                 BADCVAR("log_dest_udp");
 217                 BADCVAR("net_address");
 218                 BADCVAR("net_address_ipv6");
 219                 BADCVAR("port");
 220                 BADCVAR("savedgamecfg");
 221                 BADCVAR("serverconfig");
 222                 BADCVAR("sv_autoscreenshot");
 223                 BADCVAR("sv_heartbeatperiod");
 224                 BADCVAR("sv_vote_master_password");
 225                 BADCVAR("sys_colortranslation");
 226                 BADCVAR("sys_specialcharactertranslation");
 227                 BADCVAR("timeformat");
 228                 BADCVAR("timestamps");
 229                 BADPREFIX("developer_");
 230                 BADPREFIX("g_ban_");
 231                 BADPREFIX("g_banned_list");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_voice_flood_");
 236                 BADPREFIX("log_file");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250
 251                 // mapinfo
 252                 BADCVAR("fraglimit");
 253                 BADCVAR("g_assault");
 254                 BADCVAR("g_ca");
 255                 BADCVAR("g_ca_teams");
 256                 BADCVAR("g_ctf");
 257                 BADCVAR("g_cts");
 258                 BADCVAR("g_dm");
 259                 BADCVAR("g_domination");
 260                 BADCVAR("g_domination_default_teams");
 261                 BADCVAR("g_freezetag");
 262                 BADCVAR("g_freezetag_teams");
 263                 BADCVAR("g_invasion_teams");
 264                 BADCVAR("g_keepaway");
 265                 BADCVAR("g_keyhunt");
 266                 BADCVAR("g_keyhunt_teams");
 267                 BADCVAR("g_lms");
 268                 BADCVAR("g_nexball");
 269                 BADCVAR("g_onslaught");
 270                 BADCVAR("g_race");
 271                 BADCVAR("g_race_laps_limit");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_race_qualifying_timelimit_override");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing gameplay relevant
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("gameversion");
 307                 BADCVAR("g_allow_oldvortexbeam");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_campcheck_distance");
 310                 BADCVAR("g_ca_point_leadlimit");
 311                 BADCVAR("g_ca_point_limit");
 312                 BADCVAR("g_ctf_captimerecord_always");
 313                 BADCVAR("g_ctf_flag_glowtrails");
 314                 BADCVAR("g_ctf_flag_pickup_verbosename");
 315                 BADCVAR("g_domination_point_leadlimit");
 316                 BADCVAR("g_forced_respawn");
 317                 BADCVAR("g_freezetag_point_leadlimit");
 318                 BADCVAR("g_freezetag_point_limit");
 319                 BADCVAR("g_hats");
 320                 BADCVAR("g_invasion_point_limit");
 321                 BADCVAR("g_keyhunt_point_leadlimit");
 322                 BADCVAR("g_nexball_goalleadlimit");
 323                 BADCVAR("g_tdm_point_leadlimit");
 324                 BADCVAR("g_tdm_point_limit");
 325                 BADCVAR("leadlimit_and_fraglimit");
 326                 BADCVAR("leadlimit_override");
 327                 BADCVAR("pausable");
 328                 BADCVAR("sv_allow_fullbright");
 329                 BADCVAR("sv_checkforpacketsduringsleep");
 330                 BADCVAR("sv_intermission_cdtrack");
 331                 BADCVAR("sv_minigames");
 332                 BADCVAR("sv_namechangetimer");
 333                 BADCVAR("sv_precacheplayermodels");
 334                 BADCVAR("sv_timeout");
 335                 BADPREFIX("crypto_");
 336                 BADPREFIX("gameversion_");
 337                 BADPREFIX("g_chat_");
 338                 BADPREFIX("g_ctf_captimerecord_");
 339                 BADPREFIX("g_maplist_votable_");
 340                 BADPREFIX("g_mod_");
 341                 BADPREFIX("g_respawn_");
 342                 BADPREFIX("net_");
 343                 BADPREFIX("prvm_");
 344                 BADPREFIX("skill_");
 345                 BADPREFIX("sv_cullentities_");
 346                 BADPREFIX("sv_maxidle_");
 347                 BADPREFIX("sv_minigames_");
 348                 BADPREFIX("sv_timeout_");
 349                 BADPREFIX("sv_vote_");
 350                 BADPREFIX("timelimit_");
 351
 352                 // allowed changes to server admins (please sync this to server.cfg)
 353                 // vi commands:
 354                 //   :/"impure"/,$d
 355                 //   :g!,^\/\/[^ /],d
 356                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 357                 //   :%!sort
 358                 // yes, this does contain some redundant stuff, don't really care
 359                 BADCVAR("bot_config_file");
 360                 BADCVAR("bot_number");
 361                 BADCVAR("bot_prefix");
 362                 BADCVAR("bot_suffix");
 363                 BADCVAR("capturelimit_override");
 364                 BADCVAR("fraglimit_override");
 365                 BADCVAR("gametype");
 366                 BADCVAR("g_antilag");
 367                 BADCVAR("g_balance_teams");
 368                 BADCVAR("g_balance_teams_prevent_imbalance");
 369                 BADCVAR("g_balance_teams_scorefactor");
 370                 BADCVAR("g_ban_sync_trusted_servers");
 371                 BADCVAR("g_ban_sync_uri");
 372                 BADCVAR("g_ca_teams_override");
 373                 BADCVAR("g_ctf_ignore_frags");
 374                 BADCVAR("g_domination_point_limit");
 375                 BADCVAR("g_domination_teams_override");
 376                 BADCVAR("g_freezetag_teams_override");
 377                 BADCVAR("g_friendlyfire");
 378                 BADCVAR("g_fullbrightitems");
 379                 BADCVAR("g_fullbrightplayers");
 380                 BADCVAR("g_keyhunt_point_limit");
 381                 BADCVAR("g_keyhunt_teams_override");
 382                 BADCVAR("g_lms_lives_override");
 383                 BADCVAR("g_maplist");
 384                 BADCVAR("g_maplist_check_waypoints");
 385                 BADCVAR("g_maplist_mostrecent_count");
 386                 BADCVAR("g_maplist_shuffle");
 387                 BADCVAR("g_maplist_votable");
 388                 BADCVAR("g_maplist_votable_abstain");
 389                 BADCVAR("g_maplist_votable_nodetail");
 390                 BADCVAR("g_maplist_votable_suggestions");
 391                 BADCVAR("g_maxplayers");
 392                 BADCVAR("g_mirrordamage");
 393                 BADCVAR("g_nexball_goallimit");
 394                 BADCVAR("g_powerups");
 395                 BADCVAR("g_spawnshieldtime");
 396                 BADCVAR("g_start_delay");
 397                 BADCVAR("g_superspectate");
 398                 BADCVAR("g_tdm_teams_override");
 399                 BADCVAR("g_warmup");
 400                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 401                 BADCVAR("hostname");
 402                 BADCVAR("log_file");
 403                 BADCVAR("maxplayers");
 404                 BADCVAR("minplayers");
 405                 BADCVAR("net_address");
 406                 BADCVAR("port");
 407                 BADCVAR("rcon_password");
 408                 BADCVAR("rcon_restricted_commands");
 409                 BADCVAR("rcon_restricted_password");
 410                 BADCVAR("skill");
 411                 BADCVAR("sv_adminnick");
 412                 BADCVAR("sv_autoscreenshot");
 413                 BADCVAR("sv_autotaunt");
 414                 BADCVAR("sv_curl_defaulturl");
 415                 BADCVAR("sv_defaultcharacter");
 416                 BADCVAR("sv_defaultplayercolors");
 417                 BADCVAR("sv_defaultplayermodel");
 418                 BADCVAR("sv_defaultplayerskin");
 419                 BADCVAR("sv_maxidle");
 420                 BADCVAR("sv_maxrate");
 421                 BADCVAR("sv_motd");
 422                 BADCVAR("sv_public");
 423                 BADCVAR("sv_ready_restart");
 424                 BADCVAR("sv_status_privacy");
 425                 BADCVAR("sv_taunt");
 426                 BADCVAR("sv_vote_call");
 427                 BADCVAR("sv_vote_commands");
 428                 BADCVAR("sv_vote_majority_factor");
 429                 BADCVAR("sv_vote_master");
 430                 BADCVAR("sv_vote_master_commands");
 431                 BADCVAR("sv_vote_master_password");
 432                 BADCVAR("sv_vote_simple_majority_factor");
 433                 BADCVAR("teamplay_mode");
 434                 BADCVAR("timelimit_override");
 435                 BADPREFIX("g_warmup_");
 436                 BADPREFIX("sv_ready_restart_");
 437
 438                 // mutators that announce themselves properly to the server browser
 439                 BADCVAR("g_instagib");
 440                 BADCVAR("g_new_toys");
 441                 BADCVAR("g_nix");
 442                 BADCVAR("g_grappling_hook");
 443                 BADCVAR("g_jetpack");
 444
 445 #undef BADPREFIX
 446 #undef BADCVAR
 447
 448                 if(pureadding)
 449                 {
 450                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 451                         if(strlen(cvar_purechanges) > 16384)
 452                         {
 453                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 454                                 pureadding = 0;
 455                         }
 456                 }
 457                 ++cvar_purechanges_count;
 458                 // WARNING: this variable is used for the server list
 459                 // NEVER dare to skip this code!
 460                 // Hacks to intentionally appearing as "pure server" even though you DO have
 461                 // modified settings may be punished by removal from the server list.
 462                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 463                 // though.
 464         }
 465         buf_del(h);
 466         if(cvar_changes == "")
 467                 cvar_changes = "// this server runs at default server settings\n";
 468         else
 469                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 470         cvar_changes = strzone(cvar_changes);
 471         if(cvar_purechanges == "")
 472                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 473         else
 474                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 475         cvar_purechanges = strzone(cvar_purechanges);
 476 }
 477
 478 void detect_maptype()
 479 {
 480 #if 0
 481         vector o, v;
 482         float i;
 483
 484         for (;;)
 485         {
 486                 o = world.mins;
 487                 o.x += random() * (world.maxs.x - world.mins.x);
 488                 o.y += random() * (world.maxs.y - world.mins.y);
 489                 o.z += random() * (world.maxs.z - world.mins.z);
 490
 491                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, world);
 492                 if(trace_fraction == 1)
 493                         continue;
 494
 495                 v = trace_endpos;
 496
 497                 for(i = 0; i < 64; i += 4)
 498                 {
 499                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 500         if(trace_fraction == 1)
 501                 continue;
 502                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 503                 }
 504
 505                 break;
 506         }
 507 #endif
 508 }
 509
 510 entity randomseed;
 511 bool RandomSeed_Send(entity this, entity to, int sf)
 512 {
 513         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 514         WriteShort(MSG_ENTITY, this.cnt);
 515         return true;
 516 }
 517 void RandomSeed_Think()
 518 {SELFPARAM();
 519         this.cnt = bound(0, floor(random() * 65536), 65535);
 520         this.nextthink = time + 5;
 521
 522         this.SendFlags |= 1;
 523 }
 524 void RandomSeed_Spawn()
 525 {SELFPARAM();
 526         randomseed = new_pure(randomseed);
 527         randomseed.think = RandomSeed_Think;
 528         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 529
 530         WITHSELF(randomseed, randomseed.think()); // sets random seed and nextthink
 531 }
 532
 533 spawnfunc(__init_dedicated_server)
 534 {
 535         // handler for _init/_init map (only for dedicated server initialization)
 536
 537         world_initialized = -1; // don't complain
 538         cvar = cvar_normal;
 539         cvar_string = cvar_string_normal;
 540         cvar_set = cvar_set_normal;
 541
 542         remove = remove_unsafely;
 543
 544         entity e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = new(info_player_deathmatch);  // safeguard against player joining
 549
 550         self.classname = "worldspawn"; // safeguard against various stuff ;)
 551
 552         // needs to be done so early because of the constants they create
 553         static_init();
 554         static_init_late();
 555         static_init_precache();
 556
 557         MapInfo_Enumerate();
 558         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 559 }
 560
 561 void __init_dedicated_server_shutdown() {
 562         MapInfo_Shutdown();
 563 }
 564
 565 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override)
 566 {
 567         if(!autocvar_g_campaign)
 568         {
 569                 if(fraglimit_override >= 0) cvar_set("fraglimit", ftos(fraglimit_override));
 570                 if(timelimit_override >= 0) cvar_set("timelimit", ftos(timelimit_override));
 571                 if(leadlimit_override >= 0) cvar_set("leadlimit", ftos(leadlimit_override));
 572                 if(qualifying_override >= 0) cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 573         }
 574         limits_are_set = true;
 575 }
 576
 577 void Map_MarkAsRecent(string m);
 578 float world_already_spawned;
 579 void Nagger_Init();
 580 void ClientInit_Spawn();
 581 void WeaponStats_Init();
 582 void WeaponStats_Shutdown();
 583 spawnfunc(worldspawn)
 584 {
 585         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 586
 587     bool wantrestart = false;
 588         {
 589                 if (!server_is_dedicated)
 590                 {
 591                         // force unloading of server pk3 files when starting a listen server
 592                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 593                         // restore csqc_progname too
 594                         string expect = "csprogs.dat";
 595                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 596                         cvar_set_normal("csqc_progname", expect);
 597                 }
 598                 else
 599                 {
 600                         // Try to use versioned csprogs from pk3
 601                         // Only ever use versioned csprogs.dat files on dedicated servers;
 602                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 603                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 604                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 605                         string select = "csprogs.dat";
 606                         if (fexists(pk3csprogs)) select = pk3csprogs;
 607                         if (cvar_string_normal("csqc_progname") != select)
 608                         {
 609                                 cvar_set_normal("csqc_progname", select);
 610                                 wantrestart = true;
 611                         }
 612                         // Check for updates on startup
 613                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 614                         int sentinel = fopen("progs.txt", FILE_READ);
 615                         if (sentinel >= 0)
 616                         {
 617                                 string switchversion = fgets(sentinel);
 618                                 fclose(sentinel);
 619                                 if (switchversion != "" && switchversion != WATERMARK)
 620                                 {
 621                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 622                                         // if it doesn't exist, assume either:
 623                                         //   a) the current program was overwritten
 624                                         //   b) this is a client only update
 625                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 626                                         if (fexists(newprogs))
 627                                         {
 628                                                 cvar_set_normal("sv_progs", newprogs);
 629                                                 wantrestart = true;
 630                                         }
 631                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 632                                         if (fexists(newcsprogs))
 633                                         {
 634                                                 cvar_set_normal("csqc_progname", newcsprogs);
 635                                                 wantrestart = true;
 636                                         }
 637                                 }
 638                         }
 639                 }
 640                 if (wantrestart)
 641                 {
 642                         LOG_INFOF("Restart requested\n");
 643                         changelevel(mapname);
 644                         // let initialization continue, shutdown depends on it
 645                 }
 646         }
 647
 648         float fd, l;
 649         string s;
 650
 651         cvar = cvar_normal;
 652         cvar_string = cvar_string_normal;
 653         cvar_set = cvar_set_normal;
 654
 655         if(world_already_spawned)
 656                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 657         world_already_spawned = true;
 658
 659         remove = remove_safely; // during spawning, watch what you remove!
 660
 661         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 662
 663         compressShortVector_init();
 664
 665         maxclients = 0;
 666         for (entity head = nextent(world); head; head = nextent(head))
 667         {
 668                 ++maxclients;
 669         }
 670
 671         // needs to be done so early because of the constants they create
 672         static_init();
 673
 674         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 675
 676         TemporaryDB = db_create();
 677
 678         // 0 normal
 679         lightstyle(0, "m");
 680
 681         // 1 FLICKER (first variety)
 682         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 683
 684         // 2 SLOW STRONG PULSE
 685         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 686
 687         // 3 CANDLE (first variety)
 688         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 689
 690         // 4 FAST STROBE
 691         lightstyle(4, "mamamamamama");
 692
 693         // 5 GENTLE PULSE 1
 694         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 695
 696         // 6 FLICKER (second variety)
 697         lightstyle(6, "nmonqnmomnmomomno");
 698
 699         // 7 CANDLE (second variety)
 700         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 701
 702         // 8 CANDLE (third variety)
 703         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 704
 705         // 9 SLOW STROBE (fourth variety)
 706         lightstyle(9, "aaaaaaaazzzzzzzz");
 707
 708         // 10 FLUORESCENT FLICKER
 709         lightstyle(10, "mmamammmmammamamaaamammma");
 710
 711         // 11 SLOW PULSE NOT FADE TO BLACK
 712         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 713
 714         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 715
 716         // 63 testing
 717         lightstyle(63, "a");
 718
 719         if(autocvar_g_campaign)
 720                 CampaignPreInit();
 721
 722         Map_MarkAsRecent(mapname);
 723
 724         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 725
 726         InitGameplayMode();
 727         static_init_late();
 728         static_init_precache();
 729         readlevelcvars();
 730         GrappleHookInit();
 731
 732         if(!limits_are_set)
 733                 SetLimits(autocvar_fraglimit_override, autocvar_leadlimit_override, autocvar_timelimit_override, -1);
 734
 735         if(warmup_limit == 0)
 736                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 737
 738         player_count = 0;
 739         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 740         if(bot_waypoints_for_items == 1)
 741                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 742                         bot_waypoints_for_items = 0;
 743
 744         precache();
 745
 746         WaypointSprite_Init();
 747
 748         GameLogInit(); // prepare everything
 749         // NOTE for matchid:
 750         // changing the logic generating it is okay. But:
 751         // it HAS to stay <= 64 chars
 752         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 753         if(autocvar_sv_eventlog)
 754         {
 755                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 756                 matchid = strzone(s);
 757
 758                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 759                 s = ":gameinfo:mutators:LIST";
 760
 761                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 762                 s = ret_string;
 763
 764                 // initialiation stuff, not good in the mutator system
 765                 if(!autocvar_g_use_ammunition)
 766                         s = strcat(s, ":no_use_ammunition");
 767
 768                 // initialiation stuff, not good in the mutator system
 769                 if(autocvar_g_pickup_items == 0)
 770                         s = strcat(s, ":no_pickup_items");
 771                 if(autocvar_g_pickup_items > 0)
 772                         s = strcat(s, ":pickup_items");
 773
 774                 // initialiation stuff, not good in the mutator system
 775                 if(autocvar_g_weaponarena != "0")
 776                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 777
 778                 // TODO to mutator system
 779                 if(autocvar_g_norecoil)
 780                         s = strcat(s, ":norecoil");
 781
 782                 // TODO to mutator system
 783                 if(autocvar_g_powerups == 0)
 784                         s = strcat(s, ":no_powerups");
 785                 if(autocvar_g_powerups > 0)
 786                         s = strcat(s, ":powerups");
 787
 788                 GameLogEcho(s);
 789                 GameLogEcho(":gameinfo:end");
 790         }
 791         else
 792                 matchid = strzone(ftos(random()));
 793
 794         cvar_set("nextmap", "");
 795
 796         SetDefaultAlpha();
 797
 798         if(autocvar_g_campaign)
 799                 CampaignPostInit();
 800
 801         Ban_LoadBans();
 802
 803         MapInfo_Enumerate();
 804         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 805
 806         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 807         {
 808                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 809                 if(fd != -1)
 810                 {
 811                         while((s = fgets(fd)))
 812                         {
 813                                 l = tokenize_console(s);
 814                                 if(l < 2)
 815                                         continue;
 816                                 if(argv(0) == "cd")
 817                                 {
 818                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 819                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 820                                 }
 821                                 else if(argv(0) == "fog")
 822                                 {
 823                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 824                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 825                                 }
 826                                 else if(argv(0) == "set")
 827                                 {
 828                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 829                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 830                                 }
 831                                 else if(argv(0) != "//")
 832                                 {
 833                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 834                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 835                                 }
 836                         }
 837                         fclose(fd);
 838                 }
 839         }
 840
 841         WeaponStats_Init();
 842
 843         Nagger_Init();
 844
 845         next_pingtime = time + 5;
 846
 847         detect_maptype();
 848
 849         // set up information replies for clients and server to use
 850         maplist_reply = strzone(getmaplist());
 851         lsmaps_reply = strzone(getlsmaps());
 852         monsterlist_reply = strzone(getmonsterlist());
 853         for(int i = 0; i < 10; ++i)
 854         {
 855                 s = getrecords(i);
 856                 if (s)
 857                         records_reply[i] = strzone(s);
 858         }
 859         ladder_reply = strzone(getladder());
 860         rankings_reply = strzone(getrankings());
 861
 862         // begin other init
 863         ClientInit_Spawn();
 864         RandomSeed_Spawn();
 865         PingPLReport_Spawn();
 866
 867         CheatInit();
 868
 869         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 870
 871         // fill sv_curl_serverpackages from .serverpackage files
 872         if (autocvar_sv_curl_serverpackages_auto)
 873         {
 874                 s = "csprogs-" WATERMARK ".txt";
 875                 // remove automatically managed files from the list to prevent duplicates
 876                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 877                 {
 878                         string pkg = argv(i);
 879                         if (startsWith(pkg, "csprogs-")) continue;
 880                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 881                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 882                         s = cons(s, pkg);
 883                 }
 884                 // add automatically managed files to the list
 885                 #define X(match) MACRO_BEGIN { \
 886                         fd = search_begin(match, true, false); \
 887                         if (fd >= 0) \
 888                         { \
 889                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 890                                 { \
 891                                         s = cons(s, search_getfilename(fd, i)); \
 892                                 } \
 893                                 search_end(fd); \
 894                         } \
 895                 } MACRO_END
 896                 X("*-serverpackage.txt");
 897                 X("*.serverpackage");
 898                 #undef X
 899                 cvar_set("sv_curl_serverpackages", s);
 900         }
 901
 902         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 903         modname = "Xonotic";
 904         // physics/balance/config changes that count as mod
 905         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 906                 modname = cvar_string("g_mod_physics");
 907         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 908                 modname = cvar_string("g_mod_balance");
 909         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 910                 modname = cvar_string("g_mod_config");
 911         // extra mutators that deserve to count as mod
 912         MUTATOR_CALLHOOK(SetModname);
 913
 914         // save it for later
 915         modname = strzone(modname);
 916
 917         WinningConditionHelper(); // set worldstatus
 918
 919         world_initialized = 1;
 920 }
 921
 922 spawnfunc(light)
 923 {
 924         //makestatic (self); // Who the f___ did that?
 925         remove(self);
 926 }
 927
 928 string GetGametype()
 929 {
 930         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 931 }
 932
 933 string GetMapname()
 934 {
 935         return mapname;
 936 }
 937
 938 float Map_Count, Map_Current;
 939 string Map_Current_Name;
 940
 941 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 942 float GetMaplistPosition()
 943 {
 944         float pos, idx;
 945         string map;
 946
 947         map = GetMapname();
 948         idx = autocvar_g_maplist_index;
 949
 950         if(idx >= 0)
 951                 if(idx < Map_Count)
 952                         if(map == argv(idx))
 953                                 return idx;
 954
 955         for(pos = 0; pos < Map_Count; ++pos)
 956                 if(map == argv(pos))
 957                         return pos;
 958
 959         // resume normal maplist rotation if current map is not in g_maplist
 960         return idx;
 961 }
 962
 963 float MapHasRightSize(string map)
 964 {
 965         float fh;
 966         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 967         if(autocvar_g_maplist_check_waypoints)
 968         {
 969                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 970                 if(!fexists(strcat("maps/", map, ".waypoints")))
 971                 {
 972                         LOG_TRACE(": no waypoints\n");
 973                         return false;
 974                 }
 975                 LOG_TRACE(": has waypoints\n");
 976         }
 977
 978         // open map size restriction file
 979         LOG_TRACE("opensize "); LOG_TRACE(map);
 980         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 981         if(fh >= 0)
 982         {
 983                 float mapmin, mapmax;
 984                 LOG_TRACE(": ok, ");
 985                 mapmin = stof(fgets(fh));
 986                 mapmax = stof(fgets(fh));
 987                 fclose(fh);
 988                 if(player_count < mapmin)
 989                 {
 990                         LOG_TRACE("not enough\n");
 991                         return false;
 992                 }
 993                 if(player_count > mapmax)
 994                 {
 995                         LOG_TRACE("too many\n");
 996                         return false;
 997                 }
 998                 LOG_TRACE("right size\n");
 999                 return true;
1000         }
1001         LOG_TRACE(": not found\n");
1002         return true;
1003 }
1004
1005 string Map_Filename(float position)
1006 {
1007         return strcat("maps/", argv(position), ".bsp");
1008 }
1009
1010 void Map_MarkAsRecent(string m)
1011 {
1012         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1013 }
1014
1015 float Map_IsRecent(string m)
1016 {
1017         return strhasword(autocvar_g_maplist_mostrecent, m);
1018 }
1019
1020 float Map_Check(float position, float pass)
1021 {
1022         string filename;
1023         string map_next;
1024         map_next = argv(position);
1025         if(pass <= 1)
1026         {
1027                 if(Map_IsRecent(map_next))
1028                         return 0;
1029         }
1030         filename = Map_Filename(position);
1031         if(MapInfo_CheckMap(map_next))
1032         {
1033                 if(pass == 2)
1034                         return 1;
1035                 if(MapHasRightSize(map_next))
1036                         return 1;
1037                 return 0;
1038         }
1039         else
1040                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1041
1042         return 0;
1043 }
1044
1045 void Map_Goto_SetStr(string nextmapname)
1046 {
1047         if(getmapname_stored != "")
1048                 strunzone(getmapname_stored);
1049         if(nextmapname == "")
1050                 getmapname_stored = "";
1051         else
1052                 getmapname_stored = strzone(nextmapname);
1053 }
1054
1055 void Map_Goto_SetFloat(float position)
1056 {
1057         cvar_set("g_maplist_index", ftos(position));
1058         Map_Goto_SetStr(argv(position));
1059 }
1060
1061 void Map_Goto(float reinit)
1062 {
1063         MapInfo_LoadMap(getmapname_stored, reinit);
1064 }
1065
1066 // return codes of map selectors:
1067 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1068 //   -2 = permanent failure
1069 float() MaplistMethod_Iterate = // usual method
1070 {
1071         float pass, i;
1072
1073         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1074
1075         for(pass = 1; pass <= 2; ++pass)
1076         {
1077                 for(i = 1; i < Map_Count; ++i)
1078                 {
1079                         float mapindex;
1080                         mapindex = (i + Map_Current) % Map_Count;
1081                         if(Map_Check(mapindex, pass))
1082                                 return mapindex;
1083                 }
1084         }
1085         return -1;
1086 }
1087
1088 float() MaplistMethod_Repeat = // fallback method
1089 {
1090         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1091
1092         if(Map_Check(Map_Current, 2))
1093                 return Map_Current;
1094         return -2;
1095 }
1096
1097 float() MaplistMethod_Random = // random map selection
1098 {
1099         float i, imax;
1100
1101         LOG_TRACE("Trying MaplistMethod_Random\n");
1102
1103         imax = 42;
1104
1105         for(i = 0; i <= imax; ++i)
1106         {
1107                 float mapindex;
1108                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1109                 if(Map_Check(mapindex, 1))
1110                         return mapindex;
1111         }
1112         return -1;
1113 }
1114
1115 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1116 // the exponent sets a bias on the map selection:
1117 // the higher the exponent, the less likely "shortly repeated" same maps are
1118 {
1119         float i, j, imax, insertpos;
1120
1121         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1122
1123         imax = 42;
1124
1125         for(i = 0; i <= imax; ++i)
1126         {
1127                 string newlist;
1128
1129                 // now reinsert this at another position
1130                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1131                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1132                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1133                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1134
1135                 // insert the current map there
1136                 newlist = "";
1137                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1138                         newlist = strcat(newlist, " ", argv(j));
1139                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1140                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1141                         newlist = strcat(newlist, " ", argv(j));
1142                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1143                 cvar_set("g_maplist", newlist);
1144                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1145
1146                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1147                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1148                 if(Map_Check(Map_Current, 1))
1149                         return Map_Current;
1150         }
1151         return -1;
1152 }
1153
1154 void Maplist_Init()
1155 {
1156         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1157         float i;
1158         for (i = 0; i < Map_Count; ++i)
1159                 if (Map_Check(i, 2))
1160                         break;
1161         if (i == Map_Count)
1162         {
1163                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1164                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1165                 if(autocvar_g_maplist_shuffle)
1166                         ShuffleMaplist();
1167                 localcmd("\nmenu_cmd sync\n");
1168                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1169         }
1170         if(Map_Count == 0)
1171                 error("empty maplist, cannot select a new map");
1172         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1173
1174         if(Map_Current_Name)
1175                 strunzone(Map_Current_Name);
1176         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1177         // this may or may not be correct, but who cares, in the worst case a map
1178         // isn't chosen in the first pass that should have been
1179 }
1180
1181 string GetNextMap()
1182 {
1183         float nextMap;
1184
1185         Maplist_Init();
1186         nextMap = -1;
1187
1188         if(nextMap == -1)
1189                 if(autocvar_g_maplist_shuffle > 0)
1190                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1191
1192         if(nextMap == -1)
1193                 if(autocvar_g_maplist_selectrandom)
1194                         nextMap = MaplistMethod_Random();
1195
1196         if(nextMap == -1)
1197                 nextMap = MaplistMethod_Iterate();
1198
1199         if(nextMap == -1)
1200                 nextMap = MaplistMethod_Repeat();
1201
1202         if(nextMap >= 0)
1203         {
1204                 Map_Goto_SetFloat(nextMap);
1205                 return getmapname_stored;
1206         }
1207
1208         return "";
1209 }
1210
1211 float DoNextMapOverride(float reinit)
1212 {
1213         if(autocvar_g_campaign)
1214         {
1215                 CampaignPostIntermission();
1216                 alreadychangedlevel = true;
1217                 return true;
1218         }
1219         if(autocvar_quit_when_empty)
1220         {
1221                 if(player_count <= currentbots)
1222                 {
1223                         localcmd("quit\n");
1224                         alreadychangedlevel = true;
1225                         return true;
1226                 }
1227         }
1228         if(autocvar_quit_and_redirect != "")
1229         {
1230                 redirection_target = strzone(autocvar_quit_and_redirect);
1231                 alreadychangedlevel = true;
1232                 return true;
1233         }
1234         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1235         {
1236                 localcmd("restart\n");
1237                 alreadychangedlevel = true;
1238                 return true;
1239         }
1240         if(autocvar_nextmap != "")
1241         {
1242                 string m;
1243                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1244                 cvar_set("nextmap",m);
1245
1246                 if(!m || gametypevote)
1247                         return false;
1248                 if(autocvar_sv_vote_gametype)
1249                 {
1250                         Map_Goto_SetStr(m);
1251                         return false;
1252                 }
1253
1254                 if(MapInfo_CheckMap(m))
1255                 {
1256                         Map_Goto_SetStr(m);
1257                         Map_Goto(reinit);
1258                         alreadychangedlevel = true;
1259                         return true;
1260                 }
1261         }
1262         if(!reinit && autocvar_lastlevel)
1263         {
1264                 cvar_settemp_restore();
1265                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1266                 alreadychangedlevel = true;
1267                 return true;
1268         }
1269         return false;
1270 }
1271
1272 void GotoNextMap(float reinit)
1273 {
1274         //string nextmap;
1275         //float n, nummaps;
1276         //string s;
1277         if (alreadychangedlevel)
1278                 return;
1279         alreadychangedlevel = true;
1280
1281         string nextMap;
1282
1283         nextMap = GetNextMap();
1284         if(nextMap == "")
1285                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1286         Map_Goto(reinit);
1287 }
1288
1289
1290 /*
1291 ============
1292 IntermissionThink
1293
1294 When the player presses attack or jump, change to the next level
1295 ============
1296 */
1297 .float autoscreenshot;
1298 void IntermissionThink()
1299 {SELFPARAM();
1300         FixIntermissionClient(self);
1301
1302         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1303         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1304
1305         if( (server_screenshot || client_screenshot)
1306                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1307         {
1308                 self.autoscreenshot = -1;
1309                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1310                 return;
1311         }
1312
1313         if (time < intermission_exittime)
1314                 return;
1315
1316         if(!mapvote_initialized)
1317                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(self) || PHYS_INPUT_BUTTON_JUMP(self) || PHYS_INPUT_BUTTON_ATCK2(self) || PHYS_INPUT_BUTTON_HOOK(self) || PHYS_INPUT_BUTTON_USE(self)))
1318                         return;
1319
1320         MapVote_Start();
1321 }
1322
1323 /*
1324 ============
1325 FindIntermission
1326
1327 Returns the entity to view from
1328 ============
1329 */
1330 /*
1331 entity FindIntermission()
1332 {
1333         local   entity spot;
1334         local   float cyc;
1335
1336 // look for info_intermission first
1337         spot = find (world, classname, "info_intermission");
1338         if (spot)
1339         {       // pick a random one
1340                 cyc = random() * 4;
1341                 while (cyc > 1)
1342                 {
1343                         spot = find (spot, classname, "info_intermission");
1344                         if (!spot)
1345                                 spot = find (spot, classname, "info_intermission");
1346                         cyc = cyc - 1;
1347                 }
1348                 return spot;
1349         }
1350
1351 // then look for the start position
1352         spot = find (world, classname, "info_player_start");
1353         if (spot)
1354                 return spot;
1355
1356 // testinfo_player_start is only found in regioned levels
1357         spot = find (world, classname, "testplayerstart");
1358         if (spot)
1359                 return spot;
1360
1361 // then look for the start position
1362         spot = find (world, classname, "info_player_deathmatch");
1363         if (spot)
1364                 return spot;
1365
1366         //objerror ("FindIntermission: no spot");
1367         return world;
1368 }
1369 */
1370
1371 /*
1372 ===============================================================================
1373
1374 RULES
1375
1376 ===============================================================================
1377 */
1378
1379 void DumpStats(float final)
1380 {
1381         float file;
1382         string s;
1383         float to_console;
1384         float to_eventlog;
1385         float to_file;
1386         float i;
1387
1388         to_console = autocvar_sv_logscores_console;
1389         to_eventlog = autocvar_sv_eventlog;
1390         to_file = autocvar_sv_logscores_file;
1391
1392         if(!final)
1393         {
1394                 to_console = true; // always print printstats replies
1395                 to_eventlog = false; // but never print them to the event log
1396         }
1397
1398         if(to_eventlog)
1399                 if(autocvar_sv_eventlog_console)
1400                         to_console = false; // otherwise we get the output twice
1401
1402         if(final)
1403                 s = ":scores:";
1404         else
1405                 s = ":status:";
1406         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1407
1408         if(to_console)
1409                 LOG_INFO(s, "\n");
1410         if(to_eventlog)
1411                 GameLogEcho(s);
1412
1413         file = -1;
1414         if(to_file)
1415         {
1416                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1417                 if(file == -1)
1418                         to_file = false;
1419                 else
1420                         fputs(file, strcat(s, "\n"));
1421         }
1422
1423         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1424         if(to_console)
1425                 LOG_INFO(s, "\n");
1426         if(to_eventlog)
1427                 GameLogEcho(s);
1428         if(to_file)
1429                 fputs(file, strcat(s, "\n"));
1430
1431         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1432                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1433                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1434                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it, s))
1435                         s = strcat(s, ftos(it.team), ":");
1436                 else
1437                         s = strcat(s, "spectator:");
1438
1439                 if(to_console)
1440                         LOG_INFO(s, it.netname, "\n");
1441                 if(to_eventlog)
1442                         GameLogEcho(strcat(s, ftos(it.playerid), ":", it.netname));
1443                 if(to_file)
1444                         fputs(file, strcat(s, it.netname, "\n"));
1445         ));
1446
1447         if(teamplay)
1448         {
1449                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1450                 if(to_console)
1451                         LOG_INFO(s, "\n");
1452                 if(to_eventlog)
1453                         GameLogEcho(s);
1454                 if(to_file)
1455                         fputs(file, strcat(s, "\n"));
1456
1457                 for(i = 1; i < 16; ++i)
1458                 {
1459                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1460                         s = strcat(s, ":", ftos(i));
1461                         if(to_console)
1462                                 LOG_INFO(s, "\n");
1463                         if(to_eventlog)
1464                                 GameLogEcho(s);
1465                         if(to_file)
1466                                 fputs(file, strcat(s, "\n"));
1467                 }
1468         }
1469
1470         if(to_console)
1471                 LOG_INFO(":end\n");
1472         if(to_eventlog)
1473                 GameLogEcho(":end");
1474         if(to_file)
1475         {
1476                 fputs(file, ":end\n");
1477                 fclose(file);
1478         }
1479 }
1480
1481 void FixIntermissionClient(entity e)
1482 {
1483         if(!e.autoscreenshot) // initial call
1484         {
1485                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1486                 e.health = -2342;
1487                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1488                 e.solid = SOLID_NOT;
1489                 e.movetype = MOVETYPE_NONE;
1490                 e.takedamage = DAMAGE_NO;
1491                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1492                 {
1493                     .entity weaponentity = weaponentities[slot];
1494                         if(e.(weaponentity))
1495                         {
1496                                 e.(weaponentity).effects = EF_NODRAW;
1497                                 if (e.(weaponentity).weaponchild)
1498                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1499                         }
1500                 }
1501                 if(IS_REAL_CLIENT(e))
1502                 {
1503                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1504                         RandomSelection_Init();
1505                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1506                                 RandomSelection_Add(NULL, 0, it, 1, 1);
1507                         ));
1508                         if (RandomSelection_chosen_string != "")
1509                         {
1510                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1511                         }
1512                         msg_entity = e;
1513                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1514                 }
1515         }
1516 }
1517
1518 /*
1519 go to the next level for deathmatch
1520 only called if a time or frag limit has expired
1521 */
1522 void NextLevel()
1523 {
1524     SELFPARAM();
1525         gameover = true;
1526
1527         intermission_running = 1;
1528
1529 // enforce a wait time before allowing changelevel
1530         if(player_count > 0)
1531                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1532         else
1533                 intermission_exittime = -1;
1534
1535         /*
1536         WriteByte (MSG_ALL, SVC_CDTRACK);
1537         WriteByte (MSG_ALL, 3);
1538         WriteByte (MSG_ALL, 3);
1539         // done in FixIntermission
1540         */
1541
1542         //pos = FindIntermission ();
1543
1544         VoteReset();
1545
1546         DumpStats(true);
1547
1548         // send statistics
1549         PlayerStats_GameReport(true);
1550         WeaponStats_Shutdown();
1551
1552         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_Null); // kill all centerprints now
1553
1554         if(autocvar_sv_eventlog)
1555                 GameLogEcho(":gameover");
1556
1557         GameLogClose();
1558
1559         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1560                 FixIntermissionClient(it);
1561                 if(it.winning)
1562                         bprint(it.netname, " ^7wins.\n");
1563         ));
1564
1565         WITHSELF(NULL, target_music_kill());
1566
1567         if(autocvar_g_campaign)
1568                 CampaignPreIntermission();
1569
1570         MUTATOR_CALLHOOK(MatchEnd);
1571
1572         localcmd("\nsv_hook_gameend\n");
1573 }
1574
1575 /*
1576 ============
1577 CheckRules_Player
1578
1579 Exit deathmatch games upon conditions
1580 ============
1581 */
1582 void CheckRules_Player()
1583 {SELFPARAM();
1584         if (gameover)   // someone else quit the game already
1585                 return;
1586
1587         if(!IS_DEAD(this))
1588                 this.play_time += frametime;
1589
1590         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1591         //   (div0: and that in CheckRules_World please)
1592 }
1593
1594
1595 float InitiateSuddenDeath()
1596 {
1597         // Check first whether normal overtimes could be added before initiating suddendeath mode
1598         // - for this timelimit_overtime needs to be >0 of course
1599         // - also check the winning condition calculated in the previous frame and only add normal overtime
1600         //   again, if at the point at which timelimit would be extended again, still no winner was found
1601         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1602         {
1603                 return 1; // need to call InitiateOvertime later
1604         }
1605         else
1606         {
1607                 if(!checkrules_suddendeathend)
1608                 {
1609                         if(autocvar_g_campaign)
1610                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1611                         else
1612                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1613                         if(g_race && !g_race_qualifying)
1614                                 race_StartCompleting();
1615                 }
1616                 return 0;
1617         }
1618 }
1619
1620 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1621 {
1622         ++checkrules_overtimesadded;
1623         //add one more overtime by simply extending the timelimit
1624         float tl;
1625         tl = autocvar_timelimit;
1626         tl += autocvar_timelimit_overtime;
1627         cvar_set("timelimit", ftos(tl));
1628
1629         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1630 }
1631
1632 float GetWinningCode(float fraglimitreached, float equality)
1633 {
1634         if(autocvar_g_campaign == 1)
1635                 if(fraglimitreached)
1636                         return WINNING_YES;
1637                 else
1638                         return WINNING_NO;
1639
1640         else
1641                 if(equality)
1642                         if(fraglimitreached)
1643                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1644                         else
1645                                 return WINNING_NEVER;
1646                 else
1647                         if(fraglimitreached)
1648                                 return WINNING_YES;
1649                         else
1650                                 return WINNING_NO;
1651 }
1652
1653 // set the .winning flag for exactly those players with a given field value
1654 void SetWinners(.float field, float value)
1655 {
1656         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1657 }
1658
1659 // set the .winning flag for those players with a given field value
1660 void AddWinners(.float field, float value)
1661 {
1662         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1663                 if(it.(field) == value)
1664                         it.winning = 1;
1665         ));
1666 }
1667
1668 // clear the .winning flags
1669 void ClearWinners()
1670 {
1671         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1672 }
1673
1674 void ShuffleMaplist()
1675 {
1676         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1677 }
1678
1679 float leaderfrags;
1680 float WinningCondition_Scores(float limit, float leadlimit)
1681 {
1682         float limitreached;
1683
1684         // TODO make everything use THIS winning condition (except LMS)
1685         WinningConditionHelper();
1686
1687         if(teamplay)
1688         {
1689                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1690                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1691                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1692                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1693         }
1694
1695         ClearWinners();
1696         if(WinningConditionHelper_winner)
1697                 WinningConditionHelper_winner.winning = 1;
1698         if(WinningConditionHelper_winnerteam >= 0)
1699                 SetWinners(team, WinningConditionHelper_winnerteam);
1700
1701         if(WinningConditionHelper_lowerisbetter)
1702         {
1703                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1704                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1705                 limit = -limit;
1706         }
1707
1708         if(WinningConditionHelper_zeroisworst)
1709                 leadlimit = 0; // not supported in this mode
1710
1711         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1712         // these modes always score in increments of 1, thus this makes sense
1713         {
1714                 if(leaderfrags != WinningConditionHelper_topscore)
1715                 {
1716                         leaderfrags = WinningConditionHelper_topscore;
1717
1718                         if (limit)
1719                         if (leaderfrags == limit - 1)
1720                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1721                         else if (leaderfrags == limit - 2)
1722                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1723                         else if (leaderfrags == limit - 3)
1724                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1725                 }
1726         }
1727
1728         limitreached = false;
1729         if(limit)
1730                 if(WinningConditionHelper_topscore >= limit)
1731                         limitreached = true;
1732         if(leadlimit)
1733         {
1734                 float leadlimitreached;
1735                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1736                 if(autocvar_leadlimit_and_fraglimit)
1737                         limitreached = (limitreached && leadlimitreached);
1738                 else
1739                         limitreached = (limitreached || leadlimitreached);
1740         }
1741
1742         if(limit)
1743                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1744
1745         return GetWinningCode(
1746                 WinningConditionHelper_topscore && limitreached,
1747                 WinningConditionHelper_equality
1748         );
1749 }
1750
1751 float WinningCondition_RanOutOfSpawns()
1752 {
1753         if(have_team_spawns <= 0)
1754                 return WINNING_NO;
1755
1756         if(!autocvar_g_spawn_useallspawns)
1757                 return WINNING_NO;
1758
1759         if(!some_spawn_has_been_used)
1760                 return WINNING_NO;
1761
1762         team1_score = team2_score = team3_score = team4_score = 0;
1763
1764         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1765                 switch(it.team)
1766                 {
1767                         case NUM_TEAM_1: team1_score = 1; break;
1768                         case NUM_TEAM_2: team2_score = 1; break;
1769                         case NUM_TEAM_3: team3_score = 1; break;
1770                         case NUM_TEAM_4: team4_score = 1; break;
1771                 }
1772         ));
1773
1774         FOREACH_ENTITY_CLASS("info_player_deathmatch", true, LAMBDA(
1775                 switch(it.team)
1776                 {
1777                         case NUM_TEAM_1: team1_score = 1; break;
1778                         case NUM_TEAM_2: team2_score = 1; break;
1779                         case NUM_TEAM_3: team3_score = 1; break;
1780                         case NUM_TEAM_4: team4_score = 1; break;
1781                 }
1782         ));
1783
1784         ClearWinners();
1785         if(team1_score + team2_score + team3_score + team4_score == 0)
1786         {
1787                 checkrules_equality = true;
1788                 return WINNING_YES;
1789         }
1790         else if(team1_score + team2_score + team3_score + team4_score == 1)
1791         {
1792                 float t, i;
1793                 if(team1_score)
1794                         t = NUM_TEAM_1;
1795                 else if(team2_score)
1796                         t = NUM_TEAM_2;
1797                 else if(team3_score)
1798                         t = NUM_TEAM_3;
1799                 else // if(team4_score)
1800                         t = NUM_TEAM_4;
1801                 CheckAllowedTeams(world);
1802                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1803                 {
1804                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1805                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1806                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1807                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1808                 }
1809
1810                 AddWinners(team, t);
1811                 return WINNING_YES;
1812         }
1813         else
1814                 return WINNING_NO;
1815 }
1816
1817 /*
1818 ============
1819 CheckRules_World
1820
1821 Exit deathmatch games upon conditions
1822 ============
1823 */
1824 void CheckRules_World()
1825 {
1826         float timelimit;
1827         float fraglimit;
1828         float leadlimit;
1829
1830         VoteThink();
1831         MapVote_Think();
1832
1833         SetDefaultAlpha();
1834
1835         if (gameover)   // someone else quit the game already
1836         {
1837                 if(player_count == 0) // Nobody there? Then let's go to the next map
1838                         MapVote_Start();
1839                         // this will actually check the player count in the next frame
1840                         // again, but this shouldn't hurt
1841                 return;
1842         }
1843
1844         timelimit = autocvar_timelimit * 60;
1845         fraglimit = autocvar_fraglimit;
1846         leadlimit = autocvar_leadlimit;
1847
1848         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1849         {
1850                 if(timelimit > 0)
1851                         timelimit = 0; // timelimit is not made for warmup
1852                 if(fraglimit > 0)
1853                         fraglimit = 0; // no fraglimit for now
1854                 leadlimit = 0; // no leadlimit for now
1855         }
1856
1857         if(timelimit > 0)
1858         {
1859                 timelimit += game_starttime;
1860         }
1861         else if (timelimit < 0)
1862         {
1863                 // endmatch
1864                 NextLevel();
1865                 return;
1866         }
1867
1868         float wantovertime;
1869         wantovertime = 0;
1870
1871         if(timelimit > game_starttime)
1872                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1873         else
1874                 game_completion_ratio = 0;
1875
1876         if(checkrules_suddendeathend)
1877         {
1878                 if(!checkrules_suddendeathwarning)
1879                 {
1880                         checkrules_suddendeathwarning = true;
1881                         if(g_race && !g_race_qualifying)
1882                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1883                         else
1884                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1885                 }
1886         }
1887         else
1888         {
1889                 if (timelimit && time >= timelimit)
1890                 {
1891                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1892                         {
1893                                 float totalplayers;
1894                                 float playerswithlaps;
1895                                 float readyplayers;
1896                                 totalplayers = playerswithlaps = readyplayers = 0;
1897                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1898                                         ++totalplayers;
1899                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1900                                                 ++playerswithlaps;
1901                                         if(it.ready)
1902                                                 ++readyplayers;
1903                                 ));
1904
1905                                 // at least 2 of the players have completed a lap: start the RACE
1906                                 // otherwise, the players should end the qualifying on their own
1907                                 if(readyplayers || playerswithlaps >= 2)
1908                                 {
1909                                         checkrules_suddendeathend = 0;
1910                                         ReadyRestart(); // go to race
1911                                         return;
1912                                 }
1913                                 else
1914                                         wantovertime |= InitiateSuddenDeath();
1915                         }
1916                         else
1917                                 wantovertime |= InitiateSuddenDeath();
1918                 }
1919         }
1920
1921         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1922         {
1923                 NextLevel();
1924                 return;
1925         }
1926
1927         int checkrules_status = WinningCondition_RanOutOfSpawns();
1928         if(checkrules_status == WINNING_YES)
1929                 bprint("Hey! Someone ran out of spawns!\n");
1930         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1931                 checkrules_status = ret_float;
1932         else
1933                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1934
1935         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1936         {
1937                 checkrules_status = WINNING_NEVER;
1938                 checkrules_overtimesadded = -1;
1939                 wantovertime |= InitiateSuddenDeath();
1940         }
1941
1942         if(checkrules_status == WINNING_NEVER)
1943                 // equality cases! Nobody wins if the overtime ends in a draw.
1944                 ClearWinners();
1945
1946         if(wantovertime)
1947         {
1948                 if(checkrules_status == WINNING_NEVER)
1949                         InitiateOvertime();
1950                 else
1951                         checkrules_status = WINNING_YES;
1952         }
1953
1954         if(checkrules_suddendeathend)
1955                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1956                         checkrules_status = WINNING_YES;
1957
1958         if(checkrules_status == WINNING_YES)
1959         {
1960                 //print("WINNING\n");
1961                 NextLevel();
1962         }
1963 }
1964
1965 string GotoMap(string m)
1966 {
1967         m = GameTypeVote_MapInfo_FixName(m);
1968         if (!m)
1969                 return "The map you suggested is not available on this server.";
1970         if (!autocvar_sv_vote_gametype)
1971         if(!MapInfo_CheckMap(m))
1972                 return "The map you suggested does not support the current game mode.";
1973         cvar_set("nextmap", m);
1974         cvar_set("timelimit", "-1");
1975         if(mapvote_initialized || alreadychangedlevel)
1976         {
1977                 if(DoNextMapOverride(0))
1978                         return "Map switch initiated.";
1979                 else
1980                         return "Hm... no. For some reason I like THIS map more.";
1981         }
1982         else
1983                 return "Map switch will happen after scoreboard.";
1984 }
1985
1986
1987 void EndFrame()
1988 {
1989         anticheat_endframe();
1990
1991         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
1992                 entity e = IS_SPEC(it) ? it.enemy : it;
1993                 if (e.typehitsound) {
1994                         it.typehit_time = time;
1995                 } else if (e.damage_dealt) {
1996                         it.hit_time = time;
1997                         it.damage_dealt_total += ceil(e.damage_dealt);
1998                 }
1999         });
2000         // add 1 frametime because after this, engine SV_Physics
2001         // increases time by a frametime and then networks the frame
2002         // add another frametime because client shows everything with
2003         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2004         // needed!
2005         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2006         FOREACH_CLIENT(true, {
2007                 it.typehitsound = false;
2008                 it.damage_dealt = 0;
2009                 antilag_record(it, CS(it), altime);
2010         });
2011         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, {
2012                 antilag_record(it, it, altime);
2013         });
2014         FOREACH_CLIENT(PS(it), {
2015                 PlayerState s = PS(it);
2016                 s.ps_push(s, it);
2017         });
2018 }
2019
2020
2021 /*
2022  * RedirectionThink:
2023  * returns true if redirecting
2024  */
2025 float redirection_timeout;
2026 float redirection_nextthink;
2027 float RedirectionThink()
2028 {SELFPARAM();
2029         float clients_found;
2030
2031         if(redirection_target == "")
2032                 return false;
2033
2034         if(!redirection_timeout)
2035         {
2036                 cvar_set("sv_public", "-2");
2037                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2038                 if(redirection_target == "self")
2039                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2040                 else
2041                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2042         }
2043
2044         if(time < redirection_nextthink)
2045                 return true;
2046
2047         redirection_nextthink = time + 1;
2048
2049         clients_found = 0;
2050         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2051                 setself(it);
2052                 // TODO add timer
2053                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2054                 if(redirection_target == "self")
2055                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2056                 else
2057                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2058                 ++clients_found;
2059         ));
2060
2061         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2062
2063         if(time > redirection_timeout || clients_found == 0)
2064                 localcmd("\nwait; wait; wait; quit\n");
2065
2066         return true;
2067 }
2068
2069 void TargetMusic_RestoreGame();
2070 void RestoreGame()
2071 {
2072         // Loaded from a save game
2073         // some things then break, so let's work around them...
2074
2075         // Progs DB (capture records)
2076         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2077
2078         // Mapinfo
2079         MapInfo_Shutdown();
2080         MapInfo_Enumerate();
2081         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2082         WeaponStats_Init();
2083
2084         TargetMusic_RestoreGame();
2085 }
2086
2087 void Shutdown()
2088 {
2089         gameover = 2;
2090
2091         if(world_initialized > 0)
2092         {
2093                 world_initialized = 0;
2094                 LOG_TRACE("Saving persistent data...\n");
2095                 Ban_SaveBans();
2096
2097                 // playerstats with unfinished match
2098                 PlayerStats_GameReport(false);
2099
2100                 if(!cheatcount_total)
2101                 {
2102                         if(autocvar_sv_db_saveasdump)
2103                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2104                         else
2105                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2106                 }
2107                 if(autocvar_developer)
2108                 {
2109                         if(autocvar_sv_db_saveasdump)
2110                                 db_dump(TemporaryDB, "server-temp.db");
2111                         else
2112                                 db_save(TemporaryDB, "server-temp.db");
2113                 }
2114                 CheatShutdown(); // must be after cheatcount check
2115                 db_close(ServerProgsDB);
2116                 db_close(TemporaryDB);
2117                 LOG_TRACE("Saving persistent data... done!\n");
2118                 // tell the bot system the game is ending now
2119                 bot_endgame();
2120
2121                 WeaponStats_Shutdown();
2122                 MapInfo_Shutdown();
2123         }
2124         else if(world_initialized == 0)
2125         {
2126                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2127         }
2128         else
2129         {
2130                 __init_dedicated_server_shutdown();
2131         }
2132 }