qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/all.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications.qh"
  29 #include "../common/physics.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/all.qh"
  37 #include "../common/weapons/all.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {SELFPARAM();
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         self.nextthink = time + delta;
  53
  54         e = edict_num(self.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new(pingplreport);
  85         make_pure(pingplreport);
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if(autocvar_g_running_guns)
 100         {
 101                 default_player_alpha = -1;
 102                 default_weapon_alpha = +1;
 103         }
 104         else if(g_cloaked)
 105         {
 106                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 107                 default_weapon_alpha = default_player_alpha;
 108         }
 109         else
 110         {
 111                 default_player_alpha = autocvar_g_player_alpha;
 112                 if(default_player_alpha == 0)
 113                         default_player_alpha = 1;
 114                 default_weapon_alpha = default_player_alpha;
 115         }
 116 }
 117
 118 void GotoFirstMap()
 119 {SELFPARAM();
 120         float n;
 121         if(autocvar__sv_init)
 122         {
 123                 // cvar_set("_sv_init", "0");
 124                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 125                 // to this "init" map on a dedicated server will cause no permanent
 126                 // harm
 127                 if(autocvar_g_maplist_shuffle)
 128                         ShuffleMaplist();
 129                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 130                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 131
 132                 MapInfo_Enumerate();
 133                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 134
 135                 if(!DoNextMapOverride(1))
 136                         GotoNextMap(1);
 137
 138                 return;
 139         }
 140
 141         if(time < 5)
 142         {
 143                 self.nextthink = time;
 144         }
 145         else
 146         {
 147                 self.nextthink = time + 1;
 148                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 149         }
 150 }
 151
 152 void cvar_changes_init()
 153 {
 154         float h;
 155         string k, v, d;
 156         float n, i, adding, pureadding;
 157
 158         if(cvar_changes)
 159                 strunzone(cvar_changes);
 160         cvar_changes = string_null;
 161         if(cvar_purechanges)
 162                 strunzone(cvar_purechanges);
 163         cvar_purechanges = string_null;
 164         cvar_purechanges_count = 0;
 165
 166         h = buf_create();
 167         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 168         n = buf_getsize(h);
 169
 170         adding = true;
 171         pureadding = true;
 172
 173         for(i = 0; i < n; ++i)
 174         {
 175                 k = bufstr_get(h, i);
 176
 177 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 178 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 179 #define BADCVAR(p) if(k == p) continue
 180
 181                 // general excludes and namespaces for server admin used cvars
 182                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 183
 184                 // internal
 185                 BADPREFIX("csqc_");
 186                 BADPREFIX("cvar_check_");
 187                 BADCVAR("gamecfg");
 188                 BADCVAR("g_configversion");
 189                 BADCVAR("g_maplist_index");
 190                 BADCVAR("halflifebsp");
 191                 BADCVAR("sv_mapformat_is_quake2");
 192                 BADCVAR("sv_mapformat_is_quake3");
 193                 BADPREFIX("sv_world");
 194
 195                 // client
 196                 BADPREFIX("chase_");
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("scoreboard_");
 200                 BADPREFIX("g_campaign");
 201                 BADPREFIX("g_waypointsprite_");
 202                 BADPREFIX("gl_");
 203                 BADPREFIX("joy");
 204                 BADPREFIX("hud_");
 205                 BADPREFIX("m_");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("snd_");
 212                 BADPREFIX("show");
 213                 BADPREFIX("sensitivity");
 214                 BADPREFIX("userbind");
 215                 BADPREFIX("v_");
 216                 BADPREFIX("vid_");
 217                 BADPREFIX("crosshair");
 218                 BADCVAR("mod_q3bsp_lightmapmergepower");
 219                 BADCVAR("mod_q3bsp_nolightmaps");
 220                 BADCVAR("fov");
 221                 BADCVAR("mastervolume");
 222                 BADCVAR("volume");
 223                 BADCVAR("bgmvolume");
 224
 225                 // private
 226                 BADCVAR("developer");
 227                 BADCVAR("log_dest_udp");
 228                 BADCVAR("net_address");
 229                 BADCVAR("net_address_ipv6");
 230                 BADCVAR("port");
 231                 BADCVAR("savedgamecfg");
 232                 BADCVAR("serverconfig");
 233                 BADCVAR("sv_autoscreenshot");
 234                 BADCVAR("sv_heartbeatperiod");
 235                 BADCVAR("sv_vote_master_password");
 236                 BADCVAR("sys_colortranslation");
 237                 BADCVAR("sys_specialcharactertranslation");
 238                 BADCVAR("timeformat");
 239                 BADCVAR("timestamps");
 240                 BADPREFIX("developer_");
 241                 BADPREFIX("g_ban_");
 242                 BADPREFIX("g_banned_list");
 243                 BADPREFIX("g_chat_flood_");
 244                 BADPREFIX("g_ghost_items");
 245                 BADPREFIX("g_playerstats_");
 246                 BADPREFIX("g_respawn_ghosts");
 247                 BADPREFIX("g_voice_flood_");
 248                 BADPREFIX("log_file");
 249                 BADPREFIX("rcon_");
 250                 BADPREFIX("sv_allowdownloads");
 251                 BADPREFIX("sv_autodemo");
 252                 BADPREFIX("sv_curl_");
 253                 BADPREFIX("sv_eventlog");
 254                 BADPREFIX("sv_logscores_");
 255                 BADPREFIX("sv_master");
 256                 BADPREFIX("sv_weaponstats_");
 257                 BADPREFIX("sv_waypointsprite_");
 258                 BADCVAR("rescan_pending");
 259
 260                 // these can contain player IDs, so better hide
 261                 BADPREFIX("g_forced_team_");
 262
 263                 // mapinfo
 264                 BADCVAR("fraglimit");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_ctf");
 269                 BADCVAR("g_cts");
 270                 BADCVAR("g_dm");
 271                 BADCVAR("g_domination");
 272                 BADCVAR("g_domination_default_teams");
 273                 BADCVAR("g_freezetag");
 274                 BADCVAR("g_freezetag_teams");
 275                 BADCVAR("g_invasion_teams");
 276                 BADCVAR("g_keepaway");
 277                 BADCVAR("g_keyhunt");
 278                 BADCVAR("g_keyhunt_teams");
 279                 BADCVAR("g_lms");
 280                 BADCVAR("g_nexball");
 281                 BADCVAR("g_onslaught");
 282                 BADCVAR("g_race");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_tdm");
 285                 BADCVAR("g_tdm_teams");
 286                 BADCVAR("leadlimit");
 287                 BADCVAR("nextmap");
 288                 BADCVAR("teamplay");
 289                 BADCVAR("timelimit");
 290
 291                 // long
 292                 BADCVAR("hostname");
 293                 BADCVAR("g_maplist");
 294                 BADCVAR("g_maplist_mostrecent");
 295                 BADCVAR("sv_motd");
 296
 297                 v = cvar_string(k);
 298                 d = cvar_defstring(k);
 299                 if(v == d)
 300                         continue;
 301
 302                 if(adding)
 303                 {
 304                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 305                         if(strlen(cvar_changes) > 16384)
 306                         {
 307                                 cvar_changes = "// too many settings have been changed to show them here\n";
 308                                 adding = 0;
 309                         }
 310                 }
 311
 312                 // now check if the changes are actually gameplay relevant
 313
 314                 // does nothing visible
 315                 BADCVAR("captureleadlimit_override");
 316                 BADCVAR("g_balance_kill_delay");
 317                 BADCVAR("g_ca_point_limit");
 318                 BADCVAR("g_ca_point_leadlimit");
 319                 BADCVAR("g_ctf_captimerecord_always");
 320                 BADCVAR("g_ctf_flag_glowtrails");
 321                 BADCVAR("g_ctf_flag_pickup_verbosename");
 322                 BADCVAR("g_domination_point_leadlimit");
 323                 BADCVAR("g_forced_respawn");
 324                 BADCVAR("g_freezetag_point_limit");
 325                 BADCVAR("g_freezetag_point_leadlimit");
 326                 BADCVAR("g_keyhunt_point_leadlimit");
 327                 BADPREFIX("g_mod_");
 328                 BADCVAR("g_invasion_point_limit");
 329                 BADCVAR("g_nexball_goalleadlimit");
 330                 BADCVAR("g_tdm_point_limit");
 331                 BADCVAR("g_tdm_point_leadlimit");
 332                 BADCVAR("leadlimit_and_fraglimit");
 333                 BADCVAR("leadlimit_override");
 334                 BADCVAR("pausable");
 335                 BADCVAR("sv_allow_fullbright");
 336                 BADCVAR("sv_checkforpacketsduringsleep");
 337                 BADCVAR("sv_timeout");
 338                 BADPREFIX("sv_timeout_");
 339                 BADPREFIX("crypto_");
 340                 BADPREFIX("g_chat_");
 341                 BADPREFIX("g_ctf_captimerecord_");
 342                 BADPREFIX("g_maplist_votable_");
 343                 BADPREFIX("net_");
 344                 BADPREFIX("prvm_");
 345                 BADPREFIX("skill_");
 346                 BADPREFIX("sv_cullentities_");
 347                 BADPREFIX("sv_maxidle_");
 348                 BADPREFIX("sv_vote_");
 349                 BADPREFIX("timelimit_");
 350                 BADCVAR("gameversion");
 351                 BADPREFIX("gameversion_");
 352                 BADCVAR("sv_minigames");
 353                 BADPREFIX("sv_minigames_");
 354                 BADCVAR("sv_namechangetimer");
 355
 356                 // allowed changes to server admins (please sync this to server.cfg)
 357                 // vi commands:
 358                 //   :/"impure"/,$d
 359                 //   :g!,^\/\/[^ /],d
 360                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 361                 //   :%!sort
 362                 // yes, this does contain some redundant stuff, don't really care
 363                 BADCVAR("bot_config_file");
 364                 BADCVAR("bot_number");
 365                 BADCVAR("bot_prefix");
 366                 BADCVAR("bot_suffix");
 367                 BADCVAR("capturelimit_override");
 368                 BADCVAR("fraglimit_override");
 369                 BADCVAR("gametype");
 370                 BADCVAR("g_antilag");
 371                 BADCVAR("g_balance_teams");
 372                 BADCVAR("g_balance_teams_prevent_imbalance");
 373                 BADCVAR("g_balance_teams_scorefactor");
 374                 BADCVAR("g_ban_sync_trusted_servers");
 375                 BADCVAR("g_ban_sync_uri");
 376                 BADCVAR("g_ca_teams_override");
 377                 BADCVAR("g_ctf_ignore_frags");
 378                 BADCVAR("g_domination_point_limit");
 379                 BADCVAR("g_domination_teams_override");
 380                 BADCVAR("g_freezetag_teams_override");
 381                 BADCVAR("g_friendlyfire");
 382                 BADCVAR("g_fullbrightitems");
 383                 BADCVAR("g_fullbrightplayers");
 384                 BADCVAR("g_keyhunt_point_limit");
 385                 BADCVAR("g_keyhunt_teams_override");
 386                 BADCVAR("g_lms_lives_override");
 387                 BADCVAR("g_maplist");
 388                 BADCVAR("g_maplist_check_waypoints");
 389                 BADCVAR("g_maplist_mostrecent_count");
 390                 BADCVAR("g_maplist_shuffle");
 391                 BADCVAR("g_maplist_votable");
 392                 BADCVAR("g_maplist_votable_abstain");
 393                 BADCVAR("g_maplist_votable_nodetail");
 394                 BADCVAR("g_maplist_votable_suggestions");
 395                 BADCVAR("g_maxplayers");
 396                 BADCVAR("g_mirrordamage");
 397                 BADCVAR("g_nexball_goallimit");
 398                 BADCVAR("g_powerups");
 399                 BADCVAR("g_start_delay");
 400                 BADCVAR("g_tdm_teams_override");
 401                 BADCVAR("g_warmup");
 402                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 403                 BADCVAR("hostname");
 404                 BADCVAR("log_file");
 405                 BADCVAR("maxplayers");
 406                 BADCVAR("minplayers");
 407                 BADCVAR("net_address");
 408                 BADCVAR("port");
 409                 BADCVAR("rcon_password");
 410                 BADCVAR("rcon_restricted_commands");
 411                 BADCVAR("rcon_restricted_password");
 412                 BADCVAR("skill");
 413                 BADCVAR("sv_adminnick");
 414                 BADCVAR("sv_autoscreenshot");
 415                 BADCVAR("sv_autotaunt");
 416                 BADCVAR("sv_curl_defaulturl");
 417                 BADCVAR("sv_defaultcharacter");
 418                 BADCVAR("sv_defaultplayercolors");
 419                 BADCVAR("sv_defaultplayermodel");
 420                 BADCVAR("sv_defaultplayerskin");
 421                 BADCVAR("sv_maxidle");
 422                 BADCVAR("sv_maxrate");
 423                 BADCVAR("sv_motd");
 424                 BADCVAR("sv_public");
 425                 BADCVAR("sv_ready_restart");
 426                 BADCVAR("sv_status_privacy");
 427                 BADCVAR("sv_taunt");
 428                 BADCVAR("sv_vote_call");
 429                 BADCVAR("sv_vote_commands");
 430                 BADCVAR("sv_vote_majority_factor");
 431                 BADCVAR("sv_vote_master");
 432                 BADCVAR("sv_vote_master_commands");
 433                 BADCVAR("sv_vote_master_password");
 434                 BADCVAR("sv_vote_simple_majority_factor");
 435                 BADCVAR("teamplay_mode");
 436                 BADCVAR("timelimit_override");
 437                 BADCVAR("g_spawnshieldtime");
 438                 BADPREFIX("g_warmup_");
 439                 BADPREFIX("sv_ready_restart_");
 440
 441                 // mutators that announce themselves properly to the server browser
 442                 BADCVAR("g_instagib");
 443                 BADCVAR("g_new_toys");
 444                 BADCVAR("g_nix");
 445                 BADCVAR("g_grappling_hook");
 446                 BADCVAR("g_jetpack");
 447
 448 #undef BADPREFIX
 449 #undef BADCVAR
 450
 451                 if(pureadding)
 452                 {
 453                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 454                         if(strlen(cvar_purechanges) > 16384)
 455                         {
 456                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 457                                 pureadding = 0;
 458                         }
 459                 }
 460                 ++cvar_purechanges_count;
 461                 // WARNING: this variable is used for the server list
 462                 // NEVER dare to skip this code!
 463                 // Hacks to intentionally appearing as "pure server" even though you DO have
 464                 // modified settings may be punished by removal from the server list.
 465                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 466                 // though.
 467         }
 468         buf_del(h);
 469         if(cvar_changes == "")
 470                 cvar_changes = "// this server runs at default server settings\n";
 471         else
 472                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 473         cvar_changes = strzone(cvar_changes);
 474         if(cvar_purechanges == "")
 475                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 476         else
 477                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 478         cvar_purechanges = strzone(cvar_purechanges);
 479 }
 480
 481 void detect_maptype()
 482 {
 483 #if 0
 484         vector o, v;
 485         float i;
 486
 487         for (;;)
 488         {
 489                 o = world.mins;
 490                 o.x += random() * (world.maxs.x - world.mins.x);
 491                 o.y += random() * (world.maxs.y - world.mins.y);
 492                 o.z += random() * (world.maxs.z - world.mins.z);
 493
 494                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 495                 if(trace_fraction == 1)
 496                         continue;
 497
 498                 v = trace_endpos;
 499
 500                 for(i = 0; i < 64; i += 4)
 501                 {
 502                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 503         if(trace_fraction == 1)
 504                 continue;
 505                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 506                 }
 507
 508                 break;
 509         }
 510 #endif
 511 }
 512
 513 entity randomseed;
 514 bool RandomSeed_Send(entity this, entity to, int sf)
 515 {
 516         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 517         WriteShort(MSG_ENTITY, self.cnt);
 518         return true;
 519 }
 520 void RandomSeed_Think()
 521 {SELFPARAM();
 522         self.cnt = bound(0, floor(random() * 65536), 65535);
 523         self.nextthink = time + 5;
 524
 525         self.SendFlags |= 1;
 526 }
 527 void RandomSeed_Spawn()
 528 {SELFPARAM();
 529         randomseed = new(randomseed);
 530         make_pure(randomseed);
 531         randomseed.think = RandomSeed_Think;
 532         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 533
 534         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 535 }
 536
 537 spawnfunc(__init_dedicated_server)
 538 {
 539         // handler for _init/_init map (only for dedicated server initialization)
 540
 541         world_initialized = -1; // don't complain
 542         cvar = cvar_normal;
 543         cvar_string = cvar_string_normal;
 544         cvar_set = cvar_set_normal;
 545
 546         remove = remove_unsafely;
 547
 548         entity e = spawn();
 549         e.think = GotoFirstMap;
 550         e.nextthink = time; // this is usually 1 at this point
 551
 552         e = new(info_player_deathmatch);  // safeguard against player joining
 553
 554         self.classname = "worldspawn"; // safeguard against various stuff ;)
 555
 556         // needs to be done so early because of the constants they create
 557         static_init();
 558         static_init_late();
 559         static_init_precache();
 560
 561         MapInfo_Enumerate();
 562         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 563 }
 564
 565 void Map_MarkAsRecent(string m);
 566 float world_already_spawned;
 567 void Nagger_Init();
 568 void ClientInit_Spawn();
 569 void WeaponStats_Init();
 570 void WeaponStats_Shutdown();
 571 void Physics_AddStats();
 572 spawnfunc(worldspawn)
 573 {
 574         float fd, l, j, n;
 575         string s;
 576
 577         cvar = cvar_normal;
 578         cvar_string = cvar_string_normal;
 579         cvar_set = cvar_set_normal;
 580
 581         if(world_already_spawned)
 582                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 583         world_already_spawned = true;
 584
 585         remove = remove_safely; // during spawning, watch what you remove!
 586
 587         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 588
 589         compressShortVector_init();
 590
 591         entity head;
 592         head = nextent(world);
 593         maxclients = 0;
 594         while(head)
 595         {
 596                 ++maxclients;
 597                 head = nextent(head);
 598         }
 599
 600         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 601
 602         // needs to be done so early because of the constants they create
 603         static_init();
 604
 605         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 606
 607         TemporaryDB = db_create();
 608
 609         // 0 normal
 610         lightstyle(0, "m");
 611
 612         // 1 FLICKER (first variety)
 613         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 614
 615         // 2 SLOW STRONG PULSE
 616         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 617
 618         // 3 CANDLE (first variety)
 619         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 620
 621         // 4 FAST STROBE
 622         lightstyle(4, "mamamamamama");
 623
 624         // 5 GENTLE PULSE 1
 625         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 626
 627         // 6 FLICKER (second variety)
 628         lightstyle(6, "nmonqnmomnmomomno");
 629
 630         // 7 CANDLE (second variety)
 631         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 632
 633         // 8 CANDLE (third variety)
 634         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 635
 636         // 9 SLOW STROBE (fourth variety)
 637         lightstyle(9, "aaaaaaaazzzzzzzz");
 638
 639         // 10 FLUORESCENT FLICKER
 640         lightstyle(10, "mmamammmmammamamaaamammma");
 641
 642         // 11 SLOW PULSE NOT FADE TO BLACK
 643         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 644
 645         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 646
 647         // 63 testing
 648         lightstyle(63, "a");
 649
 650         if(autocvar_g_campaign)
 651                 CampaignPreInit();
 652
 653         Map_MarkAsRecent(mapname);
 654
 655         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 656
 657         InitGameplayMode();
 658         static_init_late();
 659         static_init_precache();
 660         readlevelcvars();
 661         GrappleHookInit();
 662
 663         player_count = 0;
 664         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 665         if(bot_waypoints_for_items == 1)
 666                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 667                         bot_waypoints_for_items = 0;
 668
 669         precache();
 670
 671         WaypointSprite_Init();
 672
 673         GameLogInit(); // prepare everything
 674         // NOTE for matchid:
 675         // changing the logic generating it is okay. But:
 676         // it HAS to stay <= 64 chars
 677         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 678         if(autocvar_sv_eventlog)
 679         {
 680                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 681                 matchid = strzone(s);
 682
 683                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 684                 s = ":gameinfo:mutators:LIST";
 685
 686                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 687                 s = ret_string;
 688
 689                 // initialiation stuff, not good in the mutator system
 690                 if(!autocvar_g_use_ammunition)
 691                         s = strcat(s, ":no_use_ammunition");
 692
 693                 // initialiation stuff, not good in the mutator system
 694                 if(autocvar_g_pickup_items == 0)
 695                         s = strcat(s, ":no_pickup_items");
 696                 if(autocvar_g_pickup_items > 0)
 697                         s = strcat(s, ":pickup_items");
 698
 699                 // initialiation stuff, not good in the mutator system
 700                 if(autocvar_g_weaponarena != "0")
 701                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 702
 703                 // TODO to mutator system
 704                 if(autocvar_g_norecoil)
 705                         s = strcat(s, ":norecoil");
 706
 707                 // TODO to mutator system
 708                 if(autocvar_g_powerups == 0)
 709                         s = strcat(s, ":no_powerups");
 710                 if(autocvar_g_powerups > 0)
 711                         s = strcat(s, ":powerups");
 712
 713                 GameLogEcho(s);
 714                 GameLogEcho(":gameinfo:end");
 715         }
 716         else
 717                 matchid = strzone(ftos(random()));
 718
 719         cvar_set("nextmap", "");
 720
 721         SetDefaultAlpha();
 722
 723         if(autocvar_g_campaign)
 724                 CampaignPostInit();
 725
 726         Ban_LoadBans();
 727
 728         MapInfo_Enumerate();
 729         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 730
 731         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 732         {
 733                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 734                 if(fd != -1)
 735                 {
 736                         while((s = fgets(fd)))
 737                         {
 738                                 l = tokenize_console(s);
 739                                 if(l < 2)
 740                                         continue;
 741                                 if(argv(0) == "cd")
 742                                 {
 743                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 744                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) == "fog")
 747                                 {
 748                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 749                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 750                                 }
 751                                 else if(argv(0) == "set")
 752                                 {
 753                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 754                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 755                                 }
 756                                 else if(argv(0) != "//")
 757                                 {
 758                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 759                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 760                                 }
 761                         }
 762                         fclose(fd);
 763                 }
 764         }
 765
 766         WeaponStats_Init();
 767
 768         WepSet_AddStat();
 769         WepSet_AddStat_InMap();
 770         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 771         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 772         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 773         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 774         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 775         Nagger_Init();
 776
 777         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 778         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 779         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 780         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 781         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 782         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 783         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 784         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 785         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 786         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 787         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 788         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 789         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 790         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 791         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 792
 793         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 794         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 795
 796         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 797
 798         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 799
 800         // freeze attacks
 801         addstat(STAT_FROZEN, AS_INT, frozen);
 802         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 803
 804         // physics
 805         Physics_AddStats();
 806
 807         // new properties
 808         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 809         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 810         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 811         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 812         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 813         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 814         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 815         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 816         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 817         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 818         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 819         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 820         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 821         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 822         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 823         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 824         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 825         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 826         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 827
 828         // secrets
 829         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 830         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 831
 832         // monsters
 833         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 834         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 835
 836         // misc
 837         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 838
 839         next_pingtime = time + 5;
 840
 841         detect_maptype();
 842
 843         // set up information replies for clients and server to use
 844         maplist_reply = strzone(getmaplist());
 845         lsmaps_reply = strzone(getlsmaps());
 846         monsterlist_reply = strzone(getmonsterlist());
 847         for(int i = 0; i < 10; ++i)
 848         {
 849                 s = getrecords(i);
 850                 if (s)
 851                         records_reply[i] = strzone(s);
 852         }
 853         ladder_reply = strzone(getladder());
 854         rankings_reply = strzone(getrankings());
 855
 856         // begin other init
 857         ClientInit_Spawn();
 858         RandomSeed_Spawn();
 859         PingPLReport_Spawn();
 860
 861         CheatInit();
 862
 863         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 864
 865         // fill sv_curl_serverpackages from .serverpackage files
 866         if(autocvar_sv_curl_serverpackages_auto)
 867         {
 868                 s = "";
 869                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 870                 for(int i = 0; i < n; ++i)
 871                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 872                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 873                                 s = strcat(s, " ", argv(i));
 874                 fd = search_begin("*-serverpackage.txt", true, false);
 875                 if(fd >= 0)
 876                 {
 877                         j = search_getsize(fd);
 878                         for(int i = 0; i < j; ++i)
 879                                 s = strcat(s, " ", search_getfilename(fd, i));
 880                         search_end(fd);
 881                 }
 882                 fd = search_begin("*.serverpackage", true, false);
 883                 if(fd >= 0)
 884                 {
 885                         j = search_getsize(fd);
 886                         for(int i = 0; i < j; ++i)
 887                                 s = strcat(s, " ", search_getfilename(fd, i));
 888                         search_end(fd);
 889                 }
 890                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 891         }
 892
 893         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 894         modname = "Xonotic";
 895         // physics/balance/config changes that count as mod
 896         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 897                 modname = cvar_string("g_mod_physics");
 898         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 899                 modname = cvar_string("g_mod_balance");
 900         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 901                 modname = cvar_string("g_mod_config");
 902         // extra mutators that deserve to count as mod
 903         MUTATOR_CALLHOOK(SetModname);
 904
 905         // save it for later
 906         modname = strzone(modname);
 907
 908         WinningConditionHelper(); // set worldstatus
 909
 910         world_initialized = 1;
 911 }
 912
 913 spawnfunc(light)
 914 {
 915         //makestatic (self); // Who the f___ did that?
 916         remove(self);
 917 }
 918
 919 string GetGametype()
 920 {
 921         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 922 }
 923
 924 string GetMapname()
 925 {
 926         return mapname;
 927 }
 928
 929 float Map_Count, Map_Current;
 930 string Map_Current_Name;
 931
 932 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 933 float GetMaplistPosition()
 934 {
 935         float pos, idx;
 936         string map;
 937
 938         map = GetMapname();
 939         idx = autocvar_g_maplist_index;
 940
 941         if(idx >= 0)
 942                 if(idx < Map_Count)
 943                         if(map == argv(idx))
 944                                 return idx;
 945
 946         for(pos = 0; pos < Map_Count; ++pos)
 947                 if(map == argv(pos))
 948                         return pos;
 949
 950         // resume normal maplist rotation if current map is not in g_maplist
 951         return idx;
 952 }
 953
 954 float MapHasRightSize(string map)
 955 {
 956         float fh;
 957         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 958         if(autocvar_g_maplist_check_waypoints)
 959         {
 960                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 961                 if(!fexists(strcat("maps/", map, ".waypoints")))
 962                 {
 963                         LOG_TRACE(": no waypoints\n");
 964                         return false;
 965                 }
 966                 LOG_TRACE(": has waypoints\n");
 967         }
 968
 969         // open map size restriction file
 970         LOG_TRACE("opensize "); LOG_TRACE(map);
 971         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 972         if(fh >= 0)
 973         {
 974                 float mapmin, mapmax;
 975                 LOG_TRACE(": ok, ");
 976                 mapmin = stof(fgets(fh));
 977                 mapmax = stof(fgets(fh));
 978                 fclose(fh);
 979                 if(player_count < mapmin)
 980                 {
 981                         LOG_TRACE("not enough\n");
 982                         return false;
 983                 }
 984                 if(player_count > mapmax)
 985                 {
 986                         LOG_TRACE("too many\n");
 987                         return false;
 988                 }
 989                 LOG_TRACE("right size\n");
 990                 return true;
 991         }
 992         LOG_TRACE(": not found\n");
 993         return true;
 994 }
 995
 996 string Map_Filename(float position)
 997 {
 998         return strcat("maps/", argv(position), ".bsp");
 999 }
1000
1001 void Map_MarkAsRecent(string m)
1002 {
1003         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1004 }
1005
1006 float Map_IsRecent(string m)
1007 {
1008         return strhasword(autocvar_g_maplist_mostrecent, m);
1009 }
1010
1011 float Map_Check(float position, float pass)
1012 {
1013         string filename;
1014         string map_next;
1015         map_next = argv(position);
1016         if(pass <= 1)
1017         {
1018                 if(Map_IsRecent(map_next))
1019                         return 0;
1020         }
1021         filename = Map_Filename(position);
1022         if(MapInfo_CheckMap(map_next))
1023         {
1024                 if(pass == 2)
1025                         return 1;
1026                 if(MapHasRightSize(map_next))
1027                         return 1;
1028                 return 0;
1029         }
1030         else
1031                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1032
1033         return 0;
1034 }
1035
1036 void Map_Goto_SetStr(string nextmapname)
1037 {
1038         if(getmapname_stored != "")
1039                 strunzone(getmapname_stored);
1040         if(nextmapname == "")
1041                 getmapname_stored = "";
1042         else
1043                 getmapname_stored = strzone(nextmapname);
1044 }
1045
1046 void Map_Goto_SetFloat(float position)
1047 {
1048         cvar_set("g_maplist_index", ftos(position));
1049         Map_Goto_SetStr(argv(position));
1050 }
1051
1052 void Map_Goto(float reinit)
1053 {
1054         MapInfo_LoadMap(getmapname_stored, reinit);
1055 }
1056
1057 // return codes of map selectors:
1058 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1059 //   -2 = permanent failure
1060 float() MaplistMethod_Iterate = // usual method
1061 {
1062         float pass, i;
1063
1064         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1065
1066         for(pass = 1; pass <= 2; ++pass)
1067         {
1068                 for(i = 1; i < Map_Count; ++i)
1069                 {
1070                         float mapindex;
1071                         mapindex = (i + Map_Current) % Map_Count;
1072                         if(Map_Check(mapindex, pass))
1073                                 return mapindex;
1074                 }
1075         }
1076         return -1;
1077 }
1078
1079 float() MaplistMethod_Repeat = // fallback method
1080 {
1081         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1082
1083         if(Map_Check(Map_Current, 2))
1084                 return Map_Current;
1085         return -2;
1086 }
1087
1088 float() MaplistMethod_Random = // random map selection
1089 {
1090         float i, imax;
1091
1092         LOG_TRACE("Trying MaplistMethod_Random\n");
1093
1094         imax = 42;
1095
1096         for(i = 0; i <= imax; ++i)
1097         {
1098                 float mapindex;
1099                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1100                 if(Map_Check(mapindex, 1))
1101                         return mapindex;
1102         }
1103         return -1;
1104 }
1105
1106 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1107 // the exponent sets a bias on the map selection:
1108 // the higher the exponent, the less likely "shortly repeated" same maps are
1109 {
1110         float i, j, imax, insertpos;
1111
1112         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1113
1114         imax = 42;
1115
1116         for(i = 0; i <= imax; ++i)
1117         {
1118                 string newlist;
1119
1120                 // now reinsert this at another position
1121                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1122                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1123                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1124                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1125
1126                 // insert the current map there
1127                 newlist = "";
1128                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1129                         newlist = strcat(newlist, " ", argv(j));
1130                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1131                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1132                         newlist = strcat(newlist, " ", argv(j));
1133                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1134                 cvar_set("g_maplist", newlist);
1135                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1136
1137                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1138                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1139                 if(Map_Check(Map_Current, 1))
1140                         return Map_Current;
1141         }
1142         return -1;
1143 }
1144
1145 void Maplist_Init()
1146 {
1147         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1148         float i;
1149         for (i = 0; i < Map_Count; ++i)
1150                 if (Map_Check(i, 2))
1151                         break;
1152         if (i == Map_Count)
1153         {
1154                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1155                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1156                 if(autocvar_g_maplist_shuffle)
1157                         ShuffleMaplist();
1158                 localcmd("\nmenu_cmd sync\n");
1159                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1160         }
1161         if(Map_Count == 0)
1162                 error("empty maplist, cannot select a new map");
1163         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1164
1165         if(Map_Current_Name)
1166                 strunzone(Map_Current_Name);
1167         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1168         // this may or may not be correct, but who cares, in the worst case a map
1169         // isn't chosen in the first pass that should have been
1170 }
1171
1172 string GetNextMap()
1173 {
1174         float nextMap;
1175
1176         Maplist_Init();
1177         nextMap = -1;
1178
1179         if(nextMap == -1)
1180                 if(autocvar_g_maplist_shuffle > 0)
1181                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1182
1183         if(nextMap == -1)
1184                 if(autocvar_g_maplist_selectrandom)
1185                         nextMap = MaplistMethod_Random();
1186
1187         if(nextMap == -1)
1188                 nextMap = MaplistMethod_Iterate();
1189
1190         if(nextMap == -1)
1191                 nextMap = MaplistMethod_Repeat();
1192
1193         if(nextMap >= 0)
1194         {
1195                 Map_Goto_SetFloat(nextMap);
1196                 return getmapname_stored;
1197         }
1198
1199         return "";
1200 }
1201
1202 float DoNextMapOverride(float reinit)
1203 {
1204         if(autocvar_g_campaign)
1205         {
1206                 CampaignPostIntermission();
1207                 alreadychangedlevel = true;
1208                 return true;
1209         }
1210         if(autocvar_quit_when_empty)
1211         {
1212                 if(player_count <= currentbots)
1213                 {
1214                         localcmd("quit\n");
1215                         alreadychangedlevel = true;
1216                         return true;
1217                 }
1218         }
1219         if(autocvar_quit_and_redirect != "")
1220         {
1221                 redirection_target = strzone(autocvar_quit_and_redirect);
1222                 alreadychangedlevel = true;
1223                 return true;
1224         }
1225         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1226         {
1227                 localcmd("restart\n");
1228                 alreadychangedlevel = true;
1229                 return true;
1230         }
1231         if(autocvar_nextmap != "")
1232         {
1233                 string m;
1234                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1235                 cvar_set("nextmap",m);
1236
1237                 if(!m || gametypevote)
1238                         return false;
1239                 if(autocvar_sv_vote_gametype)
1240                 {
1241                         Map_Goto_SetStr(m);
1242                         return false;
1243                 }
1244
1245                 if(MapInfo_CheckMap(m))
1246                 {
1247                         Map_Goto_SetStr(m);
1248                         Map_Goto(reinit);
1249                         alreadychangedlevel = true;
1250                         return true;
1251                 }
1252         }
1253         if(!reinit && autocvar_lastlevel)
1254         {
1255                 cvar_settemp_restore();
1256                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1257                 alreadychangedlevel = true;
1258                 return true;
1259         }
1260         return false;
1261 }
1262
1263 void GotoNextMap(float reinit)
1264 {
1265         //string nextmap;
1266         //float n, nummaps;
1267         //string s;
1268         if (alreadychangedlevel)
1269                 return;
1270         alreadychangedlevel = true;
1271
1272         string nextMap;
1273
1274         nextMap = GetNextMap();
1275         if(nextMap == "")
1276                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1277         Map_Goto(reinit);
1278 }
1279
1280
1281 /*
1282 ============
1283 IntermissionThink
1284
1285 When the player presses attack or jump, change to the next level
1286 ============
1287 */
1288 .float autoscreenshot;
1289 void IntermissionThink()
1290 {SELFPARAM();
1291         FixIntermissionClient(self);
1292
1293         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1294         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1295
1296         if( (server_screenshot || client_screenshot)
1297                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1298         {
1299                 self.autoscreenshot = -1;
1300                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1301                 return;
1302         }
1303
1304         if (time < intermission_exittime)
1305                 return;
1306
1307         if(!mapvote_initialized)
1308                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1309                         return;
1310
1311         MapVote_Start();
1312 }
1313
1314 /*
1315 ============
1316 FindIntermission
1317
1318 Returns the entity to view from
1319 ============
1320 */
1321 /*
1322 entity FindIntermission()
1323 {
1324         local   entity spot;
1325         local   float cyc;
1326
1327 // look for info_intermission first
1328         spot = find (world, classname, "info_intermission");
1329         if (spot)
1330         {       // pick a random one
1331                 cyc = random() * 4;
1332                 while (cyc > 1)
1333                 {
1334                         spot = find (spot, classname, "info_intermission");
1335                         if (!spot)
1336                                 spot = find (spot, classname, "info_intermission");
1337                         cyc = cyc - 1;
1338                 }
1339                 return spot;
1340         }
1341
1342 // then look for the start position
1343         spot = find (world, classname, "info_player_start");
1344         if (spot)
1345                 return spot;
1346
1347 // testinfo_player_start is only found in regioned levels
1348         spot = find (world, classname, "testplayerstart");
1349         if (spot)
1350                 return spot;
1351
1352 // then look for the start position
1353         spot = find (world, classname, "info_player_deathmatch");
1354         if (spot)
1355                 return spot;
1356
1357         //objerror ("FindIntermission: no spot");
1358         return world;
1359 }
1360 */
1361
1362 /*
1363 ===============================================================================
1364
1365 RULES
1366
1367 ===============================================================================
1368 */
1369
1370 void DumpStats(float final)
1371 {
1372         float file;
1373         string s;
1374         float to_console;
1375         float to_eventlog;
1376         float to_file;
1377         float i;
1378
1379         to_console = autocvar_sv_logscores_console;
1380         to_eventlog = autocvar_sv_eventlog;
1381         to_file = autocvar_sv_logscores_file;
1382
1383         if(!final)
1384         {
1385                 to_console = true; // always print printstats replies
1386                 to_eventlog = false; // but never print them to the event log
1387         }
1388
1389         if(to_eventlog)
1390                 if(autocvar_sv_eventlog_console)
1391                         to_console = false; // otherwise we get the output twice
1392
1393         if(final)
1394                 s = ":scores:";
1395         else
1396                 s = ":status:";
1397         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1398
1399         if(to_console)
1400                 LOG_INFO(s, "\n");
1401         if(to_eventlog)
1402                 GameLogEcho(s);
1403
1404         file = -1;
1405         if(to_file)
1406         {
1407                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1408                 if(file == -1)
1409                         to_file = false;
1410                 else
1411                         fputs(file, strcat(s, "\n"));
1412         }
1413
1414         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1415         if(to_console)
1416                 LOG_INFO(s, "\n");
1417         if(to_eventlog)
1418                 GameLogEcho(s);
1419         if(to_file)
1420                 fputs(file, strcat(s, "\n"));
1421
1422         FOR_EACH_CLIENT(other)
1423         {
1424                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1425                 {
1426                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1427                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1428                         if(IS_PLAYER(other) || MUTATOR_CALLHOOK(GetPlayerStatus, other, s))
1429                                 s = strcat(s, ftos(other.team), ":");
1430                         else
1431                                 s = strcat(s, "spectator:");
1432
1433                         if(to_console)
1434                                 LOG_INFO(s, other.netname, "\n");
1435                         if(to_eventlog)
1436                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1437                         if(to_file)
1438                                 fputs(file, strcat(s, other.netname, "\n"));
1439                 }
1440         }
1441
1442         if(teamplay)
1443         {
1444                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1445                 if(to_console)
1446                         LOG_INFO(s, "\n");
1447                 if(to_eventlog)
1448                         GameLogEcho(s);
1449                 if(to_file)
1450                         fputs(file, strcat(s, "\n"));
1451
1452                 for(i = 1; i < 16; ++i)
1453                 {
1454                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1455                         s = strcat(s, ":", ftos(i));
1456                         if(to_console)
1457                                 LOG_INFO(s, "\n");
1458                         if(to_eventlog)
1459                                 GameLogEcho(s);
1460                         if(to_file)
1461                                 fputs(file, strcat(s, "\n"));
1462                 }
1463         }
1464
1465         if(to_console)
1466                 LOG_INFO(":end\n");
1467         if(to_eventlog)
1468                 GameLogEcho(":end");
1469         if(to_file)
1470         {
1471                 fputs(file, ":end\n");
1472                 fclose(file);
1473         }
1474 }
1475
1476 void FixIntermissionClient(entity e)
1477 {
1478         string s;
1479         if(!e.autoscreenshot) // initial call
1480         {
1481                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1482                 e.health = -2342;
1483                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1484                 e.solid = SOLID_NOT;
1485                 e.movetype = MOVETYPE_NONE;
1486                 e.takedamage = DAMAGE_NO;
1487                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1488                 {
1489                     .entity weaponentity = weaponentities[slot];
1490                         if(e.(weaponentity))
1491                         {
1492                                 e.(weaponentity).effects = EF_NODRAW;
1493                                 if (e.(weaponentity).(weaponentity))
1494                                         e.(weaponentity).(weaponentity).effects = EF_NODRAW;
1495                         }
1496                 }
1497                 if(IS_REAL_CLIENT(e))
1498                 {
1499                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1500                         s = autocvar_sv_intermission_cdtrack;
1501                         if(s != "")
1502                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1503                         msg_entity = e;
1504                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1505                 }
1506         }
1507 }
1508
1509 /*
1510 go to the next level for deathmatch
1511 only called if a time or frag limit has expired
1512 */
1513 void NextLevel()
1514 {
1515         gameover = true;
1516
1517         intermission_running = 1;
1518
1519 // enforce a wait time before allowing changelevel
1520         if(player_count > 0)
1521                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1522         else
1523                 intermission_exittime = -1;
1524
1525         /*
1526         WriteByte (MSG_ALL, SVC_CDTRACK);
1527         WriteByte (MSG_ALL, 3);
1528         WriteByte (MSG_ALL, 3);
1529         // done in FixIntermission
1530         */
1531
1532         //pos = FindIntermission ();
1533
1534         VoteReset();
1535
1536         DumpStats(true);
1537
1538         // send statistics
1539         PlayerStats_GameReport(true);
1540         WeaponStats_Shutdown();
1541
1542         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1543
1544         if(autocvar_sv_eventlog)
1545                 GameLogEcho(":gameover");
1546
1547         GameLogClose();
1548
1549         FOR_EACH_PLAYER(other) {
1550                 FixIntermissionClient(other);
1551                 if(other.winning)
1552                         bprint(other.netname, " ^7wins.\n");
1553         }
1554
1555         entity oldself = self;
1556         target_music_kill();
1557         self = oldself;
1558
1559         if(autocvar_g_campaign)
1560                 CampaignPreIntermission();
1561
1562         MUTATOR_CALLHOOK(MatchEnd);
1563
1564         localcmd("\nsv_hook_gameend\n");
1565 }
1566
1567 /*
1568 ============
1569 CheckRules_Player
1570
1571 Exit deathmatch games upon conditions
1572 ============
1573 */
1574 void CheckRules_Player()
1575 {SELFPARAM();
1576         if (gameover)   // someone else quit the game already
1577                 return;
1578
1579         if(self.deadflag == DEAD_NO)
1580                 self.play_time += frametime;
1581
1582         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1583         //   (div0: and that in CheckRules_World please)
1584 }
1585
1586
1587 float InitiateSuddenDeath()
1588 {
1589         // Check first whether normal overtimes could be added before initiating suddendeath mode
1590         // - for this timelimit_overtime needs to be >0 of course
1591         // - also check the winning condition calculated in the previous frame and only add normal overtime
1592         //   again, if at the point at which timelimit would be extended again, still no winner was found
1593         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1594         {
1595                 return 1; // need to call InitiateOvertime later
1596         }
1597         else
1598         {
1599                 if(!checkrules_suddendeathend)
1600                 {
1601                         if(autocvar_g_campaign)
1602                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1603                         else
1604                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1605                         if(g_race && !g_race_qualifying)
1606                                 race_StartCompleting();
1607                 }
1608                 return 0;
1609         }
1610 }
1611
1612 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1613 {
1614         ++checkrules_overtimesadded;
1615         //add one more overtime by simply extending the timelimit
1616         float tl;
1617         tl = autocvar_timelimit;
1618         tl += autocvar_timelimit_overtime;
1619         cvar_set("timelimit", ftos(tl));
1620
1621         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1622 }
1623
1624 float GetWinningCode(float fraglimitreached, float equality)
1625 {
1626         if(autocvar_g_campaign == 1)
1627                 if(fraglimitreached)
1628                         return WINNING_YES;
1629                 else
1630                         return WINNING_NO;
1631
1632         else
1633                 if(equality)
1634                         if(fraglimitreached)
1635                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1636                         else
1637                                 return WINNING_NEVER;
1638                 else
1639                         if(fraglimitreached)
1640                                 return WINNING_YES;
1641                         else
1642                                 return WINNING_NO;
1643 }
1644
1645 // set the .winning flag for exactly those players with a given field value
1646 void SetWinners(.float field, float value)
1647 {
1648         entity head;
1649         FOR_EACH_PLAYER(head)
1650                 head.winning = (head.(field) == value);
1651 }
1652
1653 // set the .winning flag for those players with a given field value
1654 void AddWinners(.float field, float value)
1655 {
1656         entity head;
1657         FOR_EACH_PLAYER(head)
1658                 if (head.(field) == value)
1659                         head.winning = 1;
1660 }
1661
1662 // clear the .winning flags
1663 void ClearWinners(void)
1664 {
1665         entity head;
1666         FOR_EACH_PLAYER(head)
1667                 head.winning = 0;
1668 }
1669
1670 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1671 // they win. Otherwise the defending team wins once the timelimit passes.
1672 void assault_new_round();
1673 float WinningCondition_Assault()
1674 {SELFPARAM();
1675         float status;
1676
1677         WinningConditionHelper(); // set worldstatus
1678
1679         status = WINNING_NO;
1680         // as the timelimit has not yet passed just assume the defending team will win
1681         if(assault_attacker_team == NUM_TEAM_1)
1682         {
1683                 SetWinners(team, NUM_TEAM_2);
1684         }
1685         else
1686         {
1687                 SetWinners(team, NUM_TEAM_1);
1688         }
1689
1690         entity ent;
1691         ent = find(world, classname, "target_assault_roundend");
1692         if(ent)
1693         {
1694                 if(ent.winning) // round end has been triggered by attacking team
1695                 {
1696                         bprint("ASSAULT: round completed...\n");
1697                         SetWinners(team, assault_attacker_team);
1698
1699                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1700
1701                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1702                         {
1703                                 status = WINNING_YES;
1704                         }
1705                         else
1706                         {
1707                                 WITH(entity, self, ent, assault_new_round());
1708                         }
1709                 }
1710         }
1711
1712         return status;
1713 }
1714
1715 void ShuffleMaplist()
1716 {
1717         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1718 }
1719
1720 float leaderfrags;
1721 float WinningCondition_Scores(float limit, float leadlimit)
1722 {
1723         float limitreached;
1724
1725         // TODO make everything use THIS winning condition (except LMS)
1726         WinningConditionHelper();
1727
1728         if(teamplay)
1729         {
1730                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1731                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1732                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1733                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1734         }
1735
1736         ClearWinners();
1737         if(WinningConditionHelper_winner)
1738                 WinningConditionHelper_winner.winning = 1;
1739         if(WinningConditionHelper_winnerteam >= 0)
1740                 SetWinners(team, WinningConditionHelper_winnerteam);
1741
1742         if(WinningConditionHelper_lowerisbetter)
1743         {
1744                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1745                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1746                 limit = -limit;
1747         }
1748
1749         if(WinningConditionHelper_zeroisworst)
1750                 leadlimit = 0; // not supported in this mode
1751
1752         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1753         // these modes always score in increments of 1, thus this makes sense
1754         {
1755                 if(leaderfrags != WinningConditionHelper_topscore)
1756                 {
1757                         leaderfrags = WinningConditionHelper_topscore;
1758
1759                         if (limit)
1760                         if (leaderfrags == limit - 1)
1761                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1762                         else if (leaderfrags == limit - 2)
1763                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1764                         else if (leaderfrags == limit - 3)
1765                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1766                 }
1767         }
1768
1769         limitreached = false;
1770         if(limit)
1771                 if(WinningConditionHelper_topscore >= limit)
1772                         limitreached = true;
1773         if(leadlimit)
1774         {
1775                 float leadlimitreached;
1776                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1777                 if(autocvar_leadlimit_and_fraglimit)
1778                         limitreached = (limitreached && leadlimitreached);
1779                 else
1780                         limitreached = (limitreached || leadlimitreached);
1781         }
1782
1783         if(limit)
1784                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1785
1786         return GetWinningCode(
1787                 WinningConditionHelper_topscore && limitreached,
1788                 WinningConditionHelper_equality
1789         );
1790 }
1791
1792 float WinningCondition_Race(float fraglimit)
1793 {
1794         float wc;
1795         entity p;
1796         float n, c;
1797
1798         n = 0;
1799         c = 0;
1800         FOR_EACH_PLAYER(p)
1801         {
1802                 ++n;
1803                 if(p.race_completed)
1804                         ++c;
1805         }
1806         if(n && (n == c))
1807                 return WINNING_YES;
1808         wc = WinningCondition_Scores(fraglimit, 0);
1809
1810         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1811         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1812         // do NOT support equality when the laps are all raced!
1813                 return WINNING_STARTSUDDENDEATHOVERTIME;
1814         else
1815                 return WINNING_NEVER;
1816 }
1817
1818 float WinningCondition_QualifyingThenRace(float limit)
1819 {
1820         float wc;
1821         wc = WinningCondition_Scores(limit, 0);
1822
1823         // NEVER initiate overtime
1824         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1825         {
1826                 return WINNING_YES;
1827         }
1828
1829         return wc;
1830 }
1831
1832 float WinningCondition_RanOutOfSpawns()
1833 {
1834         entity head;
1835
1836         if(have_team_spawns <= 0)
1837                 return WINNING_NO;
1838
1839         if(!autocvar_g_spawn_useallspawns)
1840                 return WINNING_NO;
1841
1842         if(!some_spawn_has_been_used)
1843                 return WINNING_NO;
1844
1845         team1_score = team2_score = team3_score = team4_score = 0;
1846
1847         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1848         {
1849                 if(head.team == NUM_TEAM_1)
1850                         team1_score = 1;
1851                 else if(head.team == NUM_TEAM_2)
1852                         team2_score = 1;
1853                 else if(head.team == NUM_TEAM_3)
1854                         team3_score = 1;
1855                 else if(head.team == NUM_TEAM_4)
1856                         team4_score = 1;
1857         }
1858
1859         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1860         {
1861                 if(head.team == NUM_TEAM_1)
1862                         team1_score = 1;
1863                 else if(head.team == NUM_TEAM_2)
1864                         team2_score = 1;
1865                 else if(head.team == NUM_TEAM_3)
1866                         team3_score = 1;
1867                 else if(head.team == NUM_TEAM_4)
1868                         team4_score = 1;
1869         }
1870
1871         ClearWinners();
1872         if(team1_score + team2_score + team3_score + team4_score == 0)
1873         {
1874                 checkrules_equality = true;
1875                 return WINNING_YES;
1876         }
1877         else if(team1_score + team2_score + team3_score + team4_score == 1)
1878         {
1879                 float t, i;
1880                 if(team1_score)
1881                         t = NUM_TEAM_1;
1882                 else if(team2_score)
1883                         t = NUM_TEAM_2;
1884                 else if(team3_score)
1885                         t = NUM_TEAM_3;
1886                 else // if(team4_score)
1887                         t = NUM_TEAM_4;
1888                 CheckAllowedTeams(world);
1889                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1890                 {
1891                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1892                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1893                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1894                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1895                 }
1896
1897                 AddWinners(team, t);
1898                 return WINNING_YES;
1899         }
1900         else
1901                 return WINNING_NO;
1902 }
1903
1904 /*
1905 ============
1906 CheckRules_World
1907
1908 Exit deathmatch games upon conditions
1909 ============
1910 */
1911 void CheckRules_World()
1912 {
1913         float timelimit;
1914         float fraglimit;
1915         float leadlimit;
1916
1917         VoteThink();
1918         MapVote_Think();
1919
1920         SetDefaultAlpha();
1921
1922         if (gameover)   // someone else quit the game already
1923         {
1924                 if(player_count == 0) // Nobody there? Then let's go to the next map
1925                         MapVote_Start();
1926                         // this will actually check the player count in the next frame
1927                         // again, but this shouldn't hurt
1928                 return;
1929         }
1930
1931         timelimit = autocvar_timelimit * 60;
1932         fraglimit = autocvar_fraglimit;
1933         leadlimit = autocvar_leadlimit;
1934
1935         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1936         {
1937                 if(timelimit > 0)
1938                         timelimit = 0; // timelimit is not made for warmup
1939                 if(fraglimit > 0)
1940                         fraglimit = 0; // no fraglimit for now
1941                 leadlimit = 0; // no leadlimit for now
1942         }
1943
1944         if(timelimit > 0)
1945         {
1946                 timelimit += game_starttime;
1947         }
1948         else if (timelimit < 0)
1949         {
1950                 // endmatch
1951                 NextLevel();
1952                 return;
1953         }
1954
1955         float wantovertime;
1956         wantovertime = 0;
1957
1958         if(timelimit > game_starttime)
1959                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1960         else
1961                 game_completion_ratio = 0;
1962
1963         if(checkrules_suddendeathend)
1964         {
1965                 if(!checkrules_suddendeathwarning)
1966                 {
1967                         checkrules_suddendeathwarning = true;
1968                         if(g_race && !g_race_qualifying)
1969                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1970                         else
1971                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1972                 }
1973         }
1974         else
1975         {
1976                 if (timelimit && time >= timelimit)
1977                 {
1978                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1979                         {
1980                                 float totalplayers;
1981                                 float playerswithlaps;
1982                                 float readyplayers;
1983                                 entity head;
1984                                 totalplayers = playerswithlaps = readyplayers = 0;
1985                                 FOR_EACH_PLAYER(head)
1986                                 {
1987                                         ++totalplayers;
1988                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1989                                                 ++playerswithlaps;
1990                                         if(head.ready)
1991                                                 ++readyplayers;
1992                                 }
1993
1994                                 // at least 2 of the players have completed a lap: start the RACE
1995                                 // otherwise, the players should end the qualifying on their own
1996                                 if(readyplayers || playerswithlaps >= 2)
1997                                 {
1998                                         checkrules_suddendeathend = 0;
1999                                         ReadyRestart(); // go to race
2000                                         return;
2001                                 }
2002                                 else
2003                                         wantovertime |= InitiateSuddenDeath();
2004                         }
2005                         else
2006                                 wantovertime |= InitiateSuddenDeath();
2007                 }
2008         }
2009
2010         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2011         {
2012                 NextLevel();
2013                 return;
2014         }
2015
2016         int checkrules_status = WinningCondition_RanOutOfSpawns();
2017         if(checkrules_status == WINNING_YES)
2018                 bprint("Hey! Someone ran out of spawns!\n");
2019         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
2020                 checkrules_status = ret_float;
2021         else
2022                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2023
2024         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2025         {
2026                 checkrules_status = WINNING_NEVER;
2027                 checkrules_overtimesadded = -1;
2028                 wantovertime |= InitiateSuddenDeath();
2029         }
2030
2031         if(checkrules_status == WINNING_NEVER)
2032                 // equality cases! Nobody wins if the overtime ends in a draw.
2033                 ClearWinners();
2034
2035         if(wantovertime)
2036         {
2037                 if(checkrules_status == WINNING_NEVER)
2038                         InitiateOvertime();
2039                 else
2040                         checkrules_status = WINNING_YES;
2041         }
2042
2043         if(checkrules_suddendeathend)
2044                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2045                         checkrules_status = WINNING_YES;
2046
2047         if(checkrules_status == WINNING_YES)
2048         {
2049                 //print("WINNING\n");
2050                 NextLevel();
2051         }
2052 }
2053
2054 string GotoMap(string m)
2055 {
2056         m = GameTypeVote_MapInfo_FixName(m);
2057         if (!m)
2058                 return "The map you suggested is not available on this server.";
2059         if (!autocvar_sv_vote_gametype)
2060         if(!MapInfo_CheckMap(m))
2061                 return "The map you suggested does not support the current game mode.";
2062         cvar_set("nextmap", m);
2063         cvar_set("timelimit", "-1");
2064         if(mapvote_initialized || alreadychangedlevel)
2065         {
2066                 if(DoNextMapOverride(0))
2067                         return "Map switch initiated.";
2068                 else
2069                         return "Hm... no. For some reason I like THIS map more.";
2070         }
2071         else
2072                 return "Map switch will happen after scoreboard.";
2073 }
2074
2075
2076 void EndFrame()
2077 {SELFPARAM();
2078         anticheat_endframe();
2079
2080         float altime;
2081         entity e_;
2082         FOR_EACH_REALCLIENT(e_)
2083         {
2084                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2085                 if(e.typehitsound)
2086                         e_.typehit_time = time;
2087                 else if(e.damage_dealt)
2088                 {
2089                         e_.hit_time = time;
2090                         e_.damage_dealt_total += ceil(e.damage_dealt);
2091                 }
2092         }
2093         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2094         // add 1 frametime because after this, engine SV_Physics
2095         // increases time by a frametime and then networks the frame
2096         // add another frametime because client shows everything with
2097         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2098         // needed!
2099         FOR_EACH_CLIENT(e_)
2100         {
2101                 e_.typehitsound = false;
2102                 e_.damage_dealt = 0;
2103                 setself(e_);
2104                 antilag_record(e_, altime);
2105         }
2106         FOR_EACH_MONSTER(e_)
2107         {
2108                 setself(e_);
2109                 antilag_record(e_, altime);
2110         }
2111 }
2112
2113
2114 /*
2115  * RedirectionThink:
2116  * returns true if redirecting
2117  */
2118 float redirection_timeout;
2119 float redirection_nextthink;
2120 float RedirectionThink()
2121 {SELFPARAM();
2122         float clients_found;
2123
2124         if(redirection_target == "")
2125                 return false;
2126
2127         if(!redirection_timeout)
2128         {
2129                 cvar_set("sv_public", "-2");
2130                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2131                 if(redirection_target == "self")
2132                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2133                 else
2134                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2135         }
2136
2137         if(time < redirection_nextthink)
2138                 return true;
2139
2140         redirection_nextthink = time + 1;
2141
2142         clients_found = 0;
2143         entity e;
2144         FOR_EACH_REALCLIENT(e)
2145         {
2146                 setself(e);
2147                 // TODO add timer
2148                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2149                 if(redirection_target == "self")
2150                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2151                 else
2152                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2153                 ++clients_found;
2154         }
2155
2156         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2157
2158         if(time > redirection_timeout || clients_found == 0)
2159                 localcmd("\nwait; wait; wait; quit\n");
2160
2161         return true;
2162 }
2163
2164 void TargetMusic_RestoreGame();
2165 void RestoreGame()
2166 {
2167         // Loaded from a save game
2168         // some things then break, so let's work around them...
2169
2170         // Progs DB (capture records)
2171         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2172
2173         // Mapinfo
2174         MapInfo_Shutdown();
2175         MapInfo_Enumerate();
2176         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2177         WeaponStats_Init();
2178
2179         TargetMusic_RestoreGame();
2180 }
2181
2182 void Shutdown()
2183 {
2184         gameover = 2;
2185
2186         if(world_initialized > 0)
2187         {
2188                 world_initialized = 0;
2189                 LOG_INFO("Saving persistent data...\n");
2190                 Ban_SaveBans();
2191
2192                 // playerstats with unfinished match
2193                 PlayerStats_GameReport(false);
2194
2195                 if(!cheatcount_total)
2196                 {
2197                         if(autocvar_sv_db_saveasdump)
2198                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2199                         else
2200                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2201                 }
2202                 if(autocvar_developer)
2203                 {
2204                         if(autocvar_sv_db_saveasdump)
2205                                 db_dump(TemporaryDB, "server-temp.db");
2206                         else
2207                                 db_save(TemporaryDB, "server-temp.db");
2208                 }
2209                 CheatShutdown(); // must be after cheatcount check
2210                 db_close(ServerProgsDB);
2211                 db_close(TemporaryDB);
2212                 LOG_INFO("done!\n");
2213                 // tell the bot system the game is ending now
2214                 bot_endgame();
2215
2216                 WeaponStats_Shutdown();
2217                 MapInfo_Shutdown();
2218         }
2219         else if(world_initialized == 0)
2220         {
2221                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2222         }
2223 }