qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("gl_");
 257                 BADPREFIX("joy");
 258                 BADPREFIX("hud_");
 259                 BADPREFIX("m_");
 260                 BADPREFIX("menu_");
 261                 BADPREFIX("net_slist_");
 262                 BADPREFIX("r_");
 263                 BADPREFIX("sbar_");
 264                 BADPREFIX("scr_");
 265                 BADPREFIX("snd_");
 266                 BADPREFIX("show");
 267                 BADPREFIX("sensitivity");
 268                 BADPREFIX("userbind");
 269                 BADPREFIX("v_");
 270                 BADPREFIX("vid_");
 271                 BADPREFIX("crosshair");
 272                 BADCVAR("mod_q3bsp_lightmapmergepower");
 273                 BADCVAR("mod_q3bsp_nolightmaps");
 274                 BADCVAR("fov");
 275                 BADCVAR("mastervolume");
 276                 BADCVAR("volume");
 277                 BADCVAR("bgmvolume");
 278
 279                 // private
 280                 BADCVAR("developer");
 281                 BADCVAR("g_banned_list");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_heartbeatperiod");
 290                 BADCVAR("sv_vote_master_password");
 291                 BADCVAR("sys_colortranslation");
 292                 BADCVAR("sys_specialcharactertranslation");
 293                 BADCVAR("timeformat");
 294                 BADCVAR("timestamps");
 295                 BADPREFIX("developer_");
 296                 BADPREFIX("g_ban_");
 297                 BADPREFIX("g_chat_flood_");
 298                 BADPREFIX("g_playerstats_");
 299                 BADPREFIX("g_voice_flood_");
 300                 BADPREFIX("rcon_");
 301                 BADPREFIX("settemp_");
 302                 BADPREFIX("sv_allowdownloads_");
 303                 BADPREFIX("sv_autodemo");
 304                 BADPREFIX("sv_curl_");
 305                 BADPREFIX("sv_eventlog");
 306                 BADPREFIX("sv_logscores_");
 307                 BADPREFIX("sv_master");
 308                 BADPREFIX("sv_weaponstats_");
 309
 310                 // these can contain player IDs, so better hide
 311                 BADPREFIX("g_forced_team_");
 312
 313                 // mapinfo
 314                 BADCVAR("fraglimit");
 315                 BADCVAR("g_arena");
 316                 BADCVAR("g_assault");
 317                 BADCVAR("g_ca");
 318                 BADCVAR("g_ctf");
 319                 BADCVAR("g_cts");
 320                 BADCVAR("g_dm");
 321                 BADCVAR("g_domination");
 322                 BADCVAR("g_domination_default_teams");
 323                 BADCVAR("g_freezetag");
 324                 BADCVAR("g_keepaway");
 325                 BADCVAR("g_keyhunt");
 326                 BADCVAR("g_keyhunt_teams");
 327                 BADCVAR("g_keyhunt_teams");
 328                 BADCVAR("g_lms");
 329                 BADCVAR("g_nexball");
 330                 BADCVAR("g_onslaught");
 331                 BADCVAR("g_race");
 332                 BADCVAR("g_race_qualifying_timelimit");
 333                 BADCVAR("g_runematch");
 334                 BADCVAR("g_tdm");
 335                 BADCVAR("g_tdm_teams");
 336                 BADCVAR("leadlimit");
 337                 BADCVAR("nextmap");
 338                 BADCVAR("teamplay");
 339                 BADCVAR("timelimit");
 340
 341                 // long
 342                 BADCVAR("hostname");
 343                 BADCVAR("g_maplist");
 344                 BADCVAR("g_maplist_mostrecent");
 345                 BADCVAR("sv_motd");
 346
 347                 v = cvar_string(k);
 348                 d = cvar_defstring(k);
 349                 if(v == d)
 350                         continue;
 351
 352                 if(adding)
 353                 {
 354                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 355                         if(strlen(cvar_changes) > 16384)
 356                         {
 357                                 cvar_changes = "// too many settings have been changed to show them here\n";
 358                                 adding = 0;
 359                         }
 360                 }
 361
 362                 // now check if the changes are actually gameplay relevant
 363
 364                 // does nothing visible
 365                 BADCVAR("captureleadlimit_override");
 366                 BADCVAR("g_arena_point_leadlimit");
 367                 BADCVAR("g_balance_kill_delay");
 368                 BADCVAR("g_ca_point_leadlimit");
 369                 BADCVAR("g_ctf_captimerecord_always");
 370                 BADCVAR("g_ctf_capture_leadlimit");
 371                 BADCVAR("g_ctf_flag_capture_effects");
 372                 BADCVAR("g_ctf_flag_glowtrails");
 373                 BADCVAR("g_ctf_flag_pickup_effects");
 374                 BADCVAR("g_domination_point_leadlimit");
 375                 BADCVAR("g_forced_respawn");
 376                 BADCVAR("g_keyhunt_point_leadlimit");
 377                 BADCVAR("g_nexball_goalleadlimit");
 378                 BADCVAR("g_runematch_point_leadlimit");
 379                 BADCVAR("leadlimit_and_fraglimit");
 380                 BADCVAR("leadlimit_override");
 381                 BADCVAR("pausable");
 382                 BADCVAR("sv_checkforpacketsduringsleep");
 383                 BADCVAR("sv_timeout");
 384                 BADCVAR("welcome_message_time");
 385                 BADPREFIX("crypto_");
 386                 BADPREFIX("g_chat_");
 387                 BADPREFIX("g_ctf_captimerecord_");
 388                 BADPREFIX("g_maplist_votable_");
 389                 BADPREFIX("net_");
 390                 BADPREFIX("prvm_");
 391                 BADPREFIX("skill_");
 392                 BADPREFIX("sv_fragmessage_");
 393                 BADPREFIX("sv_maxidle_");
 394                 BADPREFIX("sv_vote_");
 395                 BADPREFIX("timelimit_");
 396                 BADCVAR("gameversion");
 397                 BADPREFIX("gameversion_");
 398
 399                 // allowed changes to server admins (please sync this to server.cfg)
 400                 // vi commands:
 401                 //   :/"impure"/,$d
 402                 //   :g!,^\/\/[^ /],d
 403                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 404                 //   :%!sort
 405                 // yes, this does contain some redundant stuff, don't really care
 406                 BADCVAR("bot_number");
 407                 BADCVAR("bot_prefix");
 408                 BADCVAR("bot_suffix");
 409                 BADCVAR("bot_config_file");
 410                 BADCVAR("capturelimit_override");
 411                 BADCVAR("fraglimit_override");
 412                 BADCVAR("gametype");
 413                 BADCVAR("g_antilag");
 414                 BADCVAR("g_balance_teams");
 415                 BADCVAR("g_balance_teams_force");
 416                 BADCVAR("g_ban_sync_trusted_servers");
 417                 BADCVAR("g_ban_sync_uri");
 418                 BADCVAR("g_ctf_capture_limit");
 419                 BADCVAR("g_ctf_ignore_frags");
 420                 BADCVAR("g_ctf_win_mode");
 421                 BADCVAR("g_domination_point_limit");
 422                 BADCVAR("g_friendlyfire");
 423                 BADCVAR("g_fullbrightitems");
 424                 BADCVAR("g_fullbrightplayers");
 425                 BADCVAR("g_keyhunt_point_limit");
 426                 BADCVAR("g_keyhunt_teams_override");
 427                 BADCVAR("g_lms_lives_override");
 428                 BADCVAR("g_maplist");
 429                 BADCVAR("g_maplist_check_waypoints");
 430                 BADCVAR("g_maplist_mostrecent_count");
 431                 BADCVAR("g_maplist_shuffle");
 432                 BADCVAR("g_maplist_votable");
 433                 BADCVAR("g_maplist_votable_abstain");
 434                 BADCVAR("g_maplist_votable_nodetail");
 435                 BADCVAR("g_maplist_votable_suggestions");
 436                 BADCVAR("g_maxplayers");
 437                 BADCVAR("g_minstagib");
 438                 BADCVAR("g_mirrordamage");
 439                 BADCVAR("g_nexball_goallimit");
 440                 BADCVAR("g_runematch_point_limit");
 441                 BADCVAR("g_start_delay");
 442                 BADCVAR("g_warmup");
 443                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 444                 BADCVAR("hostname");
 445                 BADCVAR("log_file");
 446                 BADCVAR("maxplayers");
 447                 BADCVAR("minplayers");
 448                 BADCVAR("net_address");
 449                 BADCVAR("port");
 450                 BADCVAR("rcon_password");
 451                 BADCVAR("rcon_restricted_commands");
 452                 BADCVAR("rcon_restricted_password");
 453                 BADCVAR("skill");
 454                 BADCVAR("sv_adminnick");
 455                 BADCVAR("sv_autoscreenshot");
 456                 BADCVAR("sv_curl_defaulturl");
 457                 BADCVAR("sv_defaultcharacter");
 458                 BADCVAR("sv_defaultplayercolors");
 459                 BADCVAR("sv_defaultplayermodel");
 460                 BADCVAR("sv_defaultplayerskin");
 461                 BADCVAR("sv_maxidle");
 462                 BADCVAR("sv_maxrate");
 463                 BADCVAR("sv_motd");
 464                 BADCVAR("sv_public");
 465                 BADCVAR("sv_ready_restart");
 466                 BADCVAR("sv_status_privacy");
 467                 BADCVAR("sv_vote_call");
 468                 BADCVAR("sv_vote_commands");
 469                 BADCVAR("sv_vote_majority_factor");
 470                 BADCVAR("sv_vote_master");
 471                 BADCVAR("sv_vote_master_commands");
 472                 BADCVAR("sv_vote_master_password");
 473                 BADCVAR("sv_vote_simple_majority_factor");
 474                 BADCVAR("sys_ticrate");
 475                 BADCVAR("teamplay_mode");
 476                 BADCVAR("timelimit_override");
 477                 BADPREFIX("g_warmup_");
 478
 479                 if(autocvar_g_minstagib)
 480                 {
 481                         BADCVAR("g_grappling_hook");
 482                         BADCVAR("g_jetpack");
 483                 }
 484 #undef BADPREFIX
 485 #undef BADCVAR
 486
 487                 if(pureadding)
 488                 {
 489                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 490                         if(strlen(cvar_purechanges) > 16384)
 491                         {
 492                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 493                                 pureadding = 0;
 494                         }
 495                 }
 496                 ++cvar_purechanges_count;
 497                 // WARNING: this variable is used for the server list
 498                 // NEVER dare to skip this code!
 499                 // Hacks to intentionally appearing as "pure server" even though you DO have
 500                 // modified settings may be punished by removal from the server list.
 501                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 502                 // though.
 503         }
 504         buf_del(h);
 505         if(cvar_changes == "")
 506                 cvar_changes = "// this server runs at default server settings\n";
 507         else
 508                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 509         cvar_changes = strzone(cvar_changes);
 510         if(cvar_purechanges == "")
 511                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 512         else
 513                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 514         cvar_purechanges = strzone(cvar_purechanges);
 515 }
 516
 517 void detect_maptype()
 518 {
 519 #if 0
 520         vector o, v;
 521         float i;
 522
 523         for(;;)
 524         {
 525                 o = world.mins;
 526                 o_x += random() * (world.maxs_x - world.mins_x);
 527                 o_y += random() * (world.maxs_y - world.mins_y);
 528                 o_z += random() * (world.maxs_z - world.mins_z);
 529
 530                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 531                 if(trace_fraction == 1)
 532                         continue;
 533
 534                 v = trace_endpos;
 535
 536                 for(i = 0; i < 64; i += 4)
 537                 {
 538                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 539         if(trace_fraction == 1)
 540                 continue;
 541                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 542                 }
 543
 544                 break;
 545         }
 546 #endif
 547 }
 548
 549 entity randomseed;
 550 float RandomSeed_Send(entity to, float sf)
 551 {
 552         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 553         WriteShort(MSG_ENTITY, self.cnt);
 554         return TRUE;
 555 }
 556 void RandomSeed_Think()
 557 {
 558         self.cnt = bound(0, floor(random() * 65536), 65535);
 559         self.nextthink = time + 5;
 560
 561         self.SendFlags |= 1;
 562 }
 563 void RandomSeed_Spawn()
 564 {
 565         randomseed = spawn();
 566         randomseed.think = RandomSeed_Think;
 567         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 568
 569         entity oldself;
 570         oldself = self;
 571         self = randomseed;
 572         self.think(); // sets random seed and nextthink
 573         self = oldself;
 574 }
 575
 576 void spawnfunc___init_dedicated_server(void)
 577 {
 578         // handler for _init/_init map (only for dedicated server initialization)
 579
 580         world_initialized = -1; // don't complain
 581         cvar = cvar_normal;
 582         cvar_string = cvar_string_normal;
 583         cvar_set = cvar_set_normal;
 584
 585         remove = remove_unsafely;
 586
 587         entity e;
 588         e = spawn();
 589         e.think = GotoFirstMap;
 590         e.nextthink = time; // this is usually 1 at this point
 591
 592         e = spawn();
 593         e.classname = "info_player_deathmatch"; // safeguard against player joining
 594
 595         self.classname = "worldspawn"; // safeguard against various stuff ;)
 596
 597         MapInfo_Enumerate();
 598         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 599 }
 600
 601 void Map_MarkAsRecent(string m);
 602 float world_already_spawned;
 603 void RegisterWeapons();
 604 void Nagger_Init();
 605 void ClientInit_Spawn();
 606 void WeaponStats_Init();
 607 void WeaponStats_Shutdown();
 608 void spawnfunc_worldspawn (void)
 609 {
 610         float fd, l, i, j, n;
 611         string s, col;
 612
 613         cvar = cvar_normal;
 614         cvar_string = cvar_string_normal;
 615         cvar_set = cvar_set_normal;
 616
 617         if(world_already_spawned)
 618                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 619         world_already_spawned = TRUE;
 620
 621         remove = remove_safely; // during spawning, watch what you remove!
 622
 623         check_unacceptable_compiler_bugs();
 624
 625         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 626
 627         compressShortVector_init();
 628
 629         allowed_to_spawn = TRUE;
 630
 631         local entity head;
 632         head = nextent(world);
 633         maxclients = 0;
 634         while(head)
 635         {
 636                 ++maxclients;
 637                 head = nextent(head);
 638         }
 639
 640         // needs to be done so early as they would still spawn
 641         RegisterWeapons();
 642
 643         ServerProgsDB = db_load("server.db");
 644
 645         TemporaryDB = db_create();
 646
 647         // 0 normal
 648         lightstyle(0, "m");
 649
 650         // 1 FLICKER (first variety)
 651         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 652
 653         // 2 SLOW STRONG PULSE
 654         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 655
 656         // 3 CANDLE (first variety)
 657         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 658
 659         // 4 FAST STROBE
 660         lightstyle(4, "mamamamamama");
 661
 662         // 5 GENTLE PULSE 1
 663         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 664
 665         // 6 FLICKER (second variety)
 666         lightstyle(6, "nmonqnmomnmomomno");
 667
 668         // 7 CANDLE (second variety)
 669         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 670
 671         // 8 CANDLE (third variety)
 672         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 673
 674         // 9 SLOW STROBE (fourth variety)
 675         lightstyle(9, "aaaaaaaazzzzzzzz");
 676
 677         // 10 FLUORESCENT FLICKER
 678         lightstyle(10, "mmamammmmammamamaaamammma");
 679
 680         // 11 SLOW PULSE NOT FADE TO BLACK
 681         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 682
 683         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 684
 685         // 63 testing
 686         lightstyle(63, "a");
 687
 688         if(autocvar_g_campaign)
 689                 CampaignPreInit();
 690
 691         Map_MarkAsRecent(mapname);
 692
 693         precache_model ("null"); // we need this one before InitGameplayMode
 694         InitGameplayMode();
 695         readlevelcvars();
 696         GrappleHookInit();
 697         ElectroInit();
 698         LaserInit();
 699
 700         player_count = 0;
 701         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 702         if(bot_waypoints_for_items == 1)
 703                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 704                         bot_waypoints_for_items = 0;
 705
 706         precache();
 707
 708         WaypointSprite_Init();
 709
 710         //if (g_domination)
 711         //      dom_init();
 712
 713         GameLogInit(); // prepare everything
 714         if(autocvar_sv_eventlog)
 715         {
 716                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 717                 matchid = strzone(s);
 718
 719                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 720                 s = ":gameinfo:mutators:LIST";
 721
 722                 ret_string = s;
 723                 MUTATOR_CALLHOOK(BuildMutatorsString);
 724                 s = ret_string;
 725
 726                 // simple, probably not good in the mutator system
 727                 if(autocvar_g_grappling_hook)
 728                         s = strcat(s, ":grappling_hook");
 729
 730                 // initialiation stuff, not good in the mutator system
 731                 if(!autocvar_g_use_ammunition)
 732                         s = strcat(s, ":no_use_ammunition");
 733
 734                 // initialiation stuff, not good in the mutator system
 735                 if(!autocvar_g_pickup_items)
 736                         s = strcat(s, ":no_pickup_items");
 737
 738                 // initialiation stuff, not good in the mutator system
 739                 if(autocvar_g_weaponarena != "0")
 740                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 741
 742                 // TODO to mutator system
 743                 if(autocvar_g_norecoil)
 744                         s = strcat(s, ":norecoil");
 745
 746                 // TODO to mutator system
 747                 if(autocvar_g_midair)
 748                         s = strcat(s, ":midair");
 749
 750                 // TODO to mutator system
 751                 if(autocvar_g_minstagib)
 752                         s = strcat(s, ":minstagib");
 753
 754                 GameLogEcho(s);
 755                 GameLogEcho(":gameinfo:end");
 756         }
 757         else
 758                 matchid = strzone(ftos(random()));
 759
 760         cvar_set("nextmap", "");
 761
 762         SetDefaultAlpha();
 763
 764         if(autocvar_g_campaign)
 765                 CampaignPostInit();
 766
 767         fteqcc_testbugs();
 768
 769         Ban_LoadBans();
 770
 771         MapInfo_Enumerate();
 772         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 773
 774         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 775         {
 776                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 777                 if(fd != -1)
 778                 {
 779                         while((s = fgets(fd)))
 780                         {
 781                                 l = tokenize_console(s);
 782                                 if(l < 2)
 783                                         continue;
 784                                 if(argv(0) == "cd")
 785                                 {
 786                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 787                                         print("  cdtrack ", argv(2), "\n");
 788                                 }
 789                                 else if(argv(0) == "fog")
 790                                 {
 791                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 792                                         print("  \"fog\" \"", s, "\"\n");
 793                                 }
 794                                 else if(argv(0) == "set")
 795                                 {
 796                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 797                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 798                                 }
 799                                 else if(argv(0) != "//")
 800                                 {
 801                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 802                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 803                                 }
 804                         }
 805                         fclose(fd);
 806                 }
 807         }
 808
 809         WeaponStats_Init();
 810
 811         addstat(STAT_WEAPONS, AS_INT, weapons);
 812         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 813         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 814         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 815         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 816         Nagger_Init();
 817
 818         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 819         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 820         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 821         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 822         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 823         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 824         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 825         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 826         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 827         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 828         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 829         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 830
 831         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 832         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 833
 834         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 835
 836         if(g_ca || g_freezetag)
 837         {
 838                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 839                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 840                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 841                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 842         }
 843         if(g_freezetag)
 844         {
 845                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 846                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 847         }
 848
 849         // g_movementspeed hack
 850         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 851         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 852         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 853         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 854
 855         next_pingtime = time + 5;
 856
 857         detect_maptype();
 858
 859         lsmaps_reply = "^7Maps available: ";
 860         lsnewmaps_reply = "^7Maps without a record set: ";
 861         for(i = 0, j = 0; i < MapInfo_count; ++i)
 862         {
 863                 if(MapInfo_Get_ByID(i))
 864                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 865                         {
 866                                 if(mod(i, 2))
 867                                         col = "^2";
 868                                 else
 869                                         col = "^3";
 870                                 ++j;
 871                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 872                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 873                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 874                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 875                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 876                         }
 877         }
 878         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 879         if (!g_race && !g_cts)
 880                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 881         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 882
 883         maplist_reply = "^7Maps in list: ";
 884         n = tokenize_console(autocvar_g_maplist);
 885         for(i = 0, j = 0; i < n; ++i)
 886         {
 887                 if(MapInfo_CheckMap(argv(i)))
 888                 {
 889                         if(mod(j, 2))
 890                                 col = "^2";
 891                         else
 892                                 col = "^3";
 893                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 894                         ++j;
 895                 }
 896         }
 897         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 898         MapInfo_ClearTemps();
 899
 900         for(i = 0; i < 10; ++i)
 901         {
 902                 records_reply[i] = strzone(getrecords(i));
 903         }
 904         if(g_cts)
 905                 ladder_reply = strzone(getladder());
 906
 907         rankings_reply = strzone(getrankings());
 908
 909         ClientInit_Spawn();
 910         RandomSeed_Spawn();
 911         PingPLReport_Spawn();
 912
 913         CheatInit();
 914
 915         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 916
 917         // fill sv_curl_serverpackages from .serverpackage files
 918         if(autocvar_sv_curl_serverpackages_auto)
 919         {
 920                 s = "";
 921                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 922                 for(i = 0; i < n; ++i)
 923                         if(substring(argv(i), -14, -1) != ".serverpackage")
 924                                 s = strcat(s, " ", argv(i));
 925                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 926                 if(fd >= 0)
 927                 {
 928                         j = search_getsize(fd);
 929                         for(i = 0; i < j; ++i)
 930                                 s = strcat(s, " ", search_getfilename(fd, i));
 931                         search_end(fd);
 932                 }
 933                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 934         }
 935
 936         PlayerStats_Init();
 937
 938         world_initialized = 1;
 939 }
 940
 941 void spawnfunc_light (void)
 942 {
 943         //makestatic (self); // Who the f___ did that?
 944         remove(self);
 945 }
 946
 947 string GetGametype()
 948 {
 949         return GametypeNameFromType(game);
 950 }
 951
 952 string getmapname_stored;
 953 string GetMapname()
 954 {
 955         return mapname;
 956 }
 957
 958 float Map_Count, Map_Current;
 959 string Map_Current_Name;
 960
 961 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 962 float GetMaplistPosition()
 963 {
 964         float pos, idx;
 965         string map;
 966
 967         map = GetMapname();
 968         idx = autocvar_g_maplist_index;
 969
 970         if(idx >= 0)
 971                 if(idx < Map_Count)
 972                         if(map == argv(idx))
 973                                 return idx;
 974
 975         for(pos = 0; pos < Map_Count; ++pos)
 976                 if(map == argv(pos))
 977                         return pos;
 978
 979         // resume normal maplist rotation if current map is not in g_maplist
 980         return idx;
 981 }
 982
 983 float MapHasRightSize(string map)
 984 {
 985         float fh;
 986         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 987         if(autocvar_g_maplist_check_waypoints)
 988         {
 989                 dprint("checkwp "); dprint(map);
 990                 if(!fexists(strcat("maps/", map, ".waypoints")))
 991                 {
 992                         dprint(": no waypoints\n");
 993                         return FALSE;
 994                 }
 995                 dprint(": has waypoints\n");
 996         }
 997
 998         // open map size restriction file
 999         dprint("opensize "); dprint(map);
1000         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1001         if(fh >= 0)
1002         {
1003                 float mapmin, mapmax;
1004                 dprint(": ok, ");
1005                 mapmin = stof(fgets(fh));
1006                 mapmax = stof(fgets(fh));
1007                 fclose(fh);
1008                 if(player_count < mapmin)
1009                 {
1010                         dprint("not enough\n");
1011                         return FALSE;
1012                 }
1013                 if(player_count > mapmax)
1014                 {
1015                         dprint("too many\n");
1016                         return FALSE;
1017                 }
1018                 dprint("right size\n");
1019                 return TRUE;
1020         }
1021         dprint(": not found\n");
1022         return TRUE;
1023 }
1024
1025 string Map_Filename(float position)
1026 {
1027         return strcat("maps/", argv(position), ".bsp");
1028 }
1029
1030 string strwords(string s, float w)
1031 {
1032         float endpos;
1033         for(endpos = 0; w && endpos >= 0; --w)
1034                 endpos = strstrofs(s, " ", endpos + 1);
1035         if(endpos < 0)
1036                 return s;
1037         else
1038                 return substring(s, 0, endpos);
1039 }
1040
1041 float strhasword(string s, string w)
1042 {
1043         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1044 }
1045
1046 void Map_MarkAsRecent(string m)
1047 {
1048         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1049 }
1050
1051 float Map_IsRecent(string m)
1052 {
1053         return strhasword(autocvar_g_maplist_mostrecent, m);
1054 }
1055
1056 float Map_Check(float position, float pass)
1057 {
1058         string filename;
1059         string map_next;
1060         map_next = argv(position);
1061         if(pass <= 1)
1062         {
1063                 if(Map_IsRecent(map_next))
1064                         return 0;
1065         }
1066         filename = Map_Filename(position);
1067         if(MapInfo_CheckMap(map_next))
1068         {
1069                 if(pass == 2)
1070                         return 1;
1071                 if(MapHasRightSize(map_next))
1072                         return 1;
1073                 return 0;
1074         }
1075         else
1076                 dprint( "Couldn't select '", filename, "'..\n" );
1077
1078         return 0;
1079 }
1080
1081 void Map_Goto_SetStr(string nextmapname)
1082 {
1083         if(getmapname_stored != "")
1084                 strunzone(getmapname_stored);
1085         if(nextmapname == "")
1086                 getmapname_stored = "";
1087         else
1088                 getmapname_stored = strzone(nextmapname);
1089 }
1090
1091 void Map_Goto_SetFloat(float position)
1092 {
1093         cvar_set("g_maplist_index", ftos(position));
1094         Map_Goto_SetStr(argv(position));
1095 }
1096
1097 void GameResetCfg()
1098 {
1099         // settings persist, except...
1100         localcmd("\nsettemp_restore\n");
1101 };
1102
1103 void Map_Goto()
1104 {
1105         GameResetCfg();
1106         MapInfo_LoadMap(getmapname_stored);
1107 }
1108
1109 // return codes of map selectors:
1110 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1111 //   -2 = permanent failure
1112 float() MaplistMethod_Iterate = // usual method
1113 {
1114         float pass, i;
1115
1116         for(pass = 1; pass <= 2; ++pass)
1117         {
1118                 for(i = 1; i < Map_Count; ++i)
1119                 {
1120                         float mapindex;
1121                         mapindex = mod(i + Map_Current, Map_Count);
1122                         if(Map_Check(mapindex, pass))
1123                                 return mapindex;
1124                 }
1125         }
1126         return -1;
1127 }
1128
1129 float() MaplistMethod_Repeat = // fallback method
1130 {
1131         if(Map_Check(Map_Current, 2))
1132                 return Map_Current;
1133         return -2;
1134 }
1135
1136 float() MaplistMethod_Random = // random map selection
1137 {
1138         float i, imax;
1139
1140         imax = 42;
1141
1142         for(i = 0; i <= imax; ++i)
1143         {
1144                 float mapindex;
1145                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1146                 if(Map_Check(mapindex, 1))
1147                         return mapindex;
1148         }
1149         return -1;
1150 }
1151
1152 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1153 // the exponent sets a bias on the map selection:
1154 // the higher the exponent, the less likely "shortly repeated" same maps are
1155 {
1156         float i, j, imax, insertpos;
1157
1158         imax = 42;
1159
1160         for(i = 0; i <= imax; ++i)
1161         {
1162                 string newlist;
1163
1164                 // now reinsert this at another position
1165                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1166                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1167                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1168                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1169
1170                 // insert the current map there
1171                 newlist = "";
1172                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1173                         newlist = strcat(newlist, " ", argv(j));
1174                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1175                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1176                         newlist = strcat(newlist, " ", argv(j));
1177                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1178                 cvar_set("g_maplist", newlist);
1179                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1180
1181                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1182                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1183                 if(Map_Check(Map_Current, 1))
1184                         return Map_Current;
1185         }
1186         return -1;
1187 }
1188
1189 void Maplist_Init()
1190 {
1191         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1192         if(Map_Count == 0)
1193         {
1194                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1195                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1196                 if(autocvar_g_maplist_shuffle)
1197                         ShuffleMaplist();
1198                 localcmd("\nmenu_cmd sync\n");
1199                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1200         }
1201         if(Map_Count == 0)
1202                 error("empty maplist, cannot select a new map");
1203         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1204
1205         if(Map_Current_Name)
1206                 strunzone(Map_Current_Name);
1207         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1208         // this may or may not be correct, but who cares, in the worst case a map
1209         // isn't chosen in the first pass that should have been
1210 }
1211
1212 string GetNextMap()
1213 {
1214         float nextMap;
1215
1216         Maplist_Init();
1217         nextMap = -1;
1218
1219         if(nextMap == -1)
1220                 if(autocvar_g_maplist_shuffle > 0)
1221                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1222
1223         if(nextMap == -1)
1224                 if(autocvar_g_maplist_selectrandom)
1225                         nextMap = MaplistMethod_Random();
1226
1227         if(nextMap == -1)
1228                 nextMap = MaplistMethod_Iterate();
1229
1230         if(nextMap == -1)
1231                 nextMap = MaplistMethod_Repeat();
1232
1233         if(nextMap >= 0)
1234         {
1235                 Map_Goto_SetFloat(nextMap);
1236                 return getmapname_stored;
1237         }
1238
1239         return "";
1240 };
1241
1242 float DoNextMapOverride()
1243 {
1244         if(autocvar_g_campaign)
1245         {
1246                 CampaignPostIntermission();
1247                 alreadychangedlevel = TRUE;
1248                 return TRUE;
1249         }
1250         if(autocvar_quit_when_empty)
1251         {
1252                 if(player_count <= currentbots)
1253                 {
1254                         localcmd("quit\n");
1255                         alreadychangedlevel = TRUE;
1256                         return TRUE;
1257                 }
1258         }
1259         if(autocvar_quit_and_redirect != "")
1260         {
1261                 redirection_target = strzone(autocvar_quit_and_redirect);
1262                 alreadychangedlevel = TRUE;
1263                 return TRUE;
1264         }
1265         if (autocvar_samelevel) // if samelevel is set, stay on same level
1266         {
1267                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1268                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1269                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1270                 localcmd("restart\n");
1271                 //changelevel (mapname);
1272                 alreadychangedlevel = TRUE;
1273                 return TRUE;
1274         }
1275         if(autocvar_nextmap != "")
1276                 if(MapInfo_CheckMap(autocvar_nextmap))
1277                 {
1278                         Map_Goto_SetStr(autocvar_nextmap);
1279                         Map_Goto();
1280                         alreadychangedlevel = TRUE;
1281                         return TRUE;
1282                 }
1283         if(autocvar_lastlevel)
1284         {
1285                 GameResetCfg();
1286                 localcmd("set lastlevel 0\ntogglemenu\n");
1287                 alreadychangedlevel = TRUE;
1288                 return TRUE;
1289         }
1290         return FALSE;
1291 };
1292
1293 void GotoNextMap()
1294 {
1295         //local string nextmap;
1296         //local float n, nummaps;
1297         //local string s;
1298         if (alreadychangedlevel)
1299                 return;
1300         alreadychangedlevel = TRUE;
1301
1302         {
1303                 string nextMap;
1304                 float allowReset;
1305
1306                 for(allowReset = 1; allowReset >= 0; --allowReset)
1307                 {
1308                         nextMap = GetNextMap();
1309                         if(nextMap != "")
1310                                 break;
1311
1312                         if(allowReset)
1313                         {
1314                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1315                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1316                                 if(autocvar_g_maplist_shuffle)
1317                                         ShuffleMaplist();
1318                                 localcmd("\nmenu_cmd sync\n");
1319                         }
1320                         else
1321                         {
1322                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1323                         }
1324                 }
1325                 Map_Goto();
1326         }
1327 };
1328
1329
1330 /*
1331 ============
1332 IntermissionThink
1333
1334 When the player presses attack or jump, change to the next level
1335 ============
1336 */
1337 .float autoscreenshot;
1338 void() MapVote_Start;
1339 void() MapVote_Think;
1340 float mapvote_initialized;
1341 void IntermissionThink()
1342 {
1343         FixIntermissionClient(self);
1344
1345         if(autocvar_sv_autoscreenshot)
1346         if(self.autoscreenshot > 0)
1347         if(time > self.autoscreenshot)
1348         {
1349                 self.autoscreenshot = -1;
1350                 if(clienttype(self) == CLIENTTYPE_REAL)
1351                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1352                 return;
1353         }
1354
1355         if (time < intermission_exittime)
1356                 return;
1357
1358         if(!mapvote_initialized)
1359                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1360                         return;
1361
1362         MapVote_Start();
1363 };
1364
1365 /*
1366 ============
1367 FindIntermission
1368
1369 Returns the entity to view from
1370 ============
1371 */
1372 /*
1373 entity FindIntermission()
1374 {
1375         local   entity spot;
1376         local   float cyc;
1377
1378 // look for info_intermission first
1379         spot = find (world, classname, "info_intermission");
1380         if (spot)
1381         {       // pick a random one
1382                 cyc = random() * 4;
1383                 while (cyc > 1)
1384                 {
1385                         spot = find (spot, classname, "info_intermission");
1386                         if (!spot)
1387                                 spot = find (spot, classname, "info_intermission");
1388                         cyc = cyc - 1;
1389                 }
1390                 return spot;
1391         }
1392
1393 // then look for the start position
1394         spot = find (world, classname, "info_player_start");
1395         if (spot)
1396                 return spot;
1397
1398 // testinfo_player_start is only found in regioned levels
1399         spot = find (world, classname, "testplayerstart");
1400         if (spot)
1401                 return spot;
1402
1403 // then look for the start position
1404         spot = find (world, classname, "info_player_deathmatch");
1405         if (spot)
1406                 return spot;
1407
1408         //objerror ("FindIntermission: no spot");
1409         return world;
1410 };
1411 */
1412
1413 /*
1414 ===============================================================================
1415
1416 RULES
1417
1418 ===============================================================================
1419 */
1420
1421 void DumpStats(float final)
1422 {
1423         float file;
1424         string s;
1425         float to_console;
1426         float to_eventlog;
1427         float to_file;
1428         float i;
1429
1430         to_console = autocvar_sv_logscores_console;
1431         to_eventlog = autocvar_sv_eventlog;
1432         to_file = autocvar_sv_logscores_file;
1433
1434         if(!final)
1435         {
1436                 to_console = TRUE; // always print printstats replies
1437                 to_eventlog = FALSE; // but never print them to the event log
1438         }
1439
1440         if(to_eventlog)
1441                 if(autocvar_sv_eventlog_console)
1442                         to_console = FALSE; // otherwise we get the output twice
1443
1444         if(final)
1445                 s = ":scores:";
1446         else
1447                 s = ":status:";
1448         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1449
1450         if(to_console)
1451                 print(s, "\n");
1452         if(to_eventlog)
1453                 GameLogEcho(s);
1454         if(to_file)
1455         {
1456                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1457                 if(file == -1)
1458                         to_file = FALSE;
1459                 else
1460                         fputs(file, strcat(s, "\n"));
1461         }
1462
1463         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1464         if(to_console)
1465                 print(s, "\n");
1466         if(to_eventlog)
1467                 GameLogEcho(s);
1468         if(to_file)
1469                 fputs(file, strcat(s, "\n"));
1470
1471         FOR_EACH_CLIENT(other)
1472         {
1473                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1474                 {
1475                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1476                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1477                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1478                                 s = strcat(s, ftos(other.team), ":");
1479                         else
1480                                 s = strcat(s, "spectator:");
1481
1482                         if(to_console)
1483                                 print(s, other.netname, "\n");
1484                         if(to_eventlog)
1485                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1486                         if(to_file)
1487                                 fputs(file, strcat(s, other.netname, "\n"));
1488                 }
1489         }
1490
1491         if(teamplay)
1492         {
1493                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1494                 if(to_console)
1495                         print(s, "\n");
1496                 if(to_eventlog)
1497                         GameLogEcho(s);
1498                 if(to_file)
1499                         fputs(file, strcat(s, "\n"));
1500
1501                 for(i = 1; i < 16; ++i)
1502                 {
1503                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1504                         s = strcat(s, ":", ftos(i));
1505                         if(to_console)
1506                                 print(s, "\n");
1507                         if(to_eventlog)
1508                                 GameLogEcho(s);
1509                         if(to_file)
1510                                 fputs(file, strcat(s, "\n"));
1511                 }
1512         }
1513
1514         if(to_console)
1515                 print(":end\n");
1516         if(to_eventlog)
1517                 GameLogEcho(":end");
1518         if(to_file)
1519         {
1520                 fputs(file, ":end\n");
1521                 fclose(file);
1522         }
1523 }
1524
1525 void FixIntermissionClient(entity e)
1526 {
1527         string s;
1528         if(!e.autoscreenshot) // initial call
1529         {
1530                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1531                 e.health = -2342;
1532                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1533                 e.solid = SOLID_NOT;
1534                 e.movetype = MOVETYPE_NONE;
1535                 e.takedamage = DAMAGE_NO;
1536                 if(e.weaponentity)
1537                 {
1538                         e.weaponentity.effects = EF_NODRAW;
1539                         if (e.weaponentity.weaponentity)
1540                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1541                 }
1542                 if(clienttype(e) == CLIENTTYPE_REAL)
1543                 {
1544                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1545                         s = autocvar_sv_intermission_cdtrack;
1546                         if(s != "")
1547                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1548                         msg_entity = e;
1549                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1550                 }
1551         }
1552 }
1553
1554
1555 /*
1556 go to the next level for deathmatch
1557 only called if a time or frag limit has expired
1558 */
1559 void NextLevel()
1560 {
1561         gameover = TRUE;
1562
1563         intermission_running = 1;
1564
1565 // enforce a wait time before allowing changelevel
1566         if(player_count > 0)
1567                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1568         else
1569                 intermission_exittime = -1;
1570
1571         /*
1572         WriteByte (MSG_ALL, SVC_CDTRACK);
1573         WriteByte (MSG_ALL, 3);
1574         WriteByte (MSG_ALL, 3);
1575         // done in FixIntermission
1576         */
1577
1578         //pos = FindIntermission ();
1579
1580         VoteReset();
1581
1582         DumpStats(TRUE);
1583
1584         // send statistics
1585         entity e;
1586         PlayerStats_EndMatch(1);
1587         FOR_EACH_CLIENT(e)
1588                 PlayerStats_AddGlobalInfo(e);
1589         PlayerStats_Shutdown();
1590         WeaponStats_Shutdown();
1591
1592         if(autocvar_sv_eventlog)
1593                 GameLogEcho(":gameover");
1594
1595         GameLogClose();
1596
1597         FOR_EACH_PLAYER(other) {
1598                 FixIntermissionClient(other);
1599                 if(other.winning)
1600                         bprint(other.netname, " ^7wins.\n");
1601         }
1602
1603         if(autocvar_g_campaign)
1604                 CampaignPreIntermission();
1605
1606         localcmd("\nsv_hook_gameend\n");
1607 }
1608
1609 /*
1610 ============
1611 CheckRules_Player
1612
1613 Exit deathmatch games upon conditions
1614 ============
1615 */
1616 void CheckRules_Player()
1617 {
1618         if (gameover)   // someone else quit the game already
1619                 return;
1620
1621         if(self.deadflag == DEAD_NO)
1622                 self.play_time += frametime;
1623
1624         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1625         //   (div0: and that in CheckRules_World please)
1626 };
1627
1628 float checkrules_equality;
1629 float checkrules_suddendeathwarning;
1630 float checkrules_suddendeathend;
1631 float checkrules_overtimesadded; //how many overtimes have been already added
1632
1633 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1634 float WINNING_YES = 1; // winner found
1635 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1636 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1637
1638 float InitiateSuddenDeath()
1639 {
1640         // Check first whether normal overtimes could be added before initiating suddendeath mode
1641         // - for this timelimit_overtime needs to be >0 of course
1642         // - also check the winning condition calculated in the previous frame and only add normal overtime
1643         //   again, if at the point at which timelimit would be extended again, still no winner was found
1644         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1645         {
1646                 return 1; // need to call InitiateOvertime later
1647         }
1648         else
1649         {
1650                 if(!checkrules_suddendeathend)
1651                 {
1652                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1653                         if(g_race && !g_race_qualifying)
1654                                 race_StartCompleting();
1655                 }
1656                 return 0;
1657         }
1658 }
1659
1660 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1661 {
1662         ++checkrules_overtimesadded;
1663         //add one more overtime by simply extending the timelimit
1664         float tl;
1665         tl = autocvar_timelimit;
1666         tl += autocvar_timelimit_overtime;
1667         cvar_set("timelimit", ftos(tl));
1668         string minutesPlural;
1669         if (autocvar_timelimit_overtime == 1)
1670                 minutesPlural = " ^3minute";
1671         else
1672                 minutesPlural = " ^3minutes";
1673
1674         bcenterprint(
1675                 strcat(
1676                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1677                         ftos(autocvar_timelimit_overtime),
1678                         minutesPlural,
1679                         " to the game!"
1680                 )
1681         );
1682 }
1683
1684 float GetWinningCode(float fraglimitreached, float equality)
1685 {
1686         if(autocvar_g_campaign == 1)
1687                 if(fraglimitreached)
1688                         return WINNING_YES;
1689                 else
1690                         return WINNING_NO;
1691
1692         else
1693                 if(equality)
1694                         if(fraglimitreached)
1695                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1696                         else
1697                                 return WINNING_NEVER;
1698                 else
1699                         if(fraglimitreached)
1700                                 return WINNING_YES;
1701                         else
1702                                 return WINNING_NO;
1703 }
1704
1705 // set the .winning flag for exactly those players with a given field value
1706 void SetWinners(.float field, float value)
1707 {
1708         entity head;
1709         FOR_EACH_PLAYER(head)
1710                 head.winning = (head.field == value);
1711 }
1712
1713 // set the .winning flag for those players with a given field value
1714 void AddWinners(.float field, float value)
1715 {
1716         entity head;
1717         FOR_EACH_PLAYER(head)
1718                 if(head.field == value)
1719                         head.winning = 1;
1720 }
1721
1722 // clear the .winning flags
1723 void ClearWinners(void)
1724 {
1725         entity head;
1726         FOR_EACH_PLAYER(head)
1727                 head.winning = 0;
1728 }
1729
1730 // Onslaught winning condition:
1731 // game terminates if only one team has a working generator (or none)
1732 float WinningCondition_Onslaught()
1733 {
1734         entity head;
1735         local float t1, t2, t3, t4;
1736
1737         WinningConditionHelper(); // set worldstatus
1738
1739         if(inWarmupStage)
1740                 return WINNING_NO;
1741
1742         // first check if the game has ended
1743         t1 = t2 = t3 = t4 = 0;
1744         head = find(world, classname, "onslaught_generator");
1745         while (head)
1746         {
1747                 if (head.health > 0)
1748                 {
1749                         if (head.team == COLOR_TEAM1) t1 = 1;
1750                         if (head.team == COLOR_TEAM2) t2 = 1;
1751                         if (head.team == COLOR_TEAM3) t3 = 1;
1752                         if (head.team == COLOR_TEAM4) t4 = 1;
1753                 }
1754                 head = find(head, classname, "onslaught_generator");
1755         }
1756         if (t1 + t2 + t3 + t4 < 2)
1757         {
1758                 // game over, only one team remains (or none)
1759                 ClearWinners();
1760                 if (t1) SetWinners(team, COLOR_TEAM1);
1761                 if (t2) SetWinners(team, COLOR_TEAM2);
1762                 if (t3) SetWinners(team, COLOR_TEAM3);
1763                 if (t4) SetWinners(team, COLOR_TEAM4);
1764                 dprint("Have a winner, ending game.\n");
1765                 return WINNING_YES;
1766         }
1767
1768         // Two or more teams remain
1769         return WINNING_NO;
1770 }
1771
1772 float LMS_NewPlayerLives()
1773 {
1774         float fl;
1775         fl = autocvar_fraglimit;
1776         if(fl == 0)
1777                 fl = 999;
1778
1779         // first player has left the game for dying too much? Nobody else can get in.
1780         if(lms_lowest_lives < 1)
1781                 return 0;
1782
1783         if(!autocvar_g_lms_join_anytime)
1784                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1785                         return 0;
1786
1787         return bound(1, lms_lowest_lives, fl);
1788 }
1789
1790 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1791 // they win. Otherwise the defending team wins once the timelimit passes.
1792 void assault_new_round();
1793 float WinningCondition_Assault()
1794 {
1795         local float status;
1796
1797         WinningConditionHelper(); // set worldstatus
1798
1799         status = WINNING_NO;
1800         // as the timelimit has not yet passed just assume the defending team will win
1801         if(assault_attacker_team == COLOR_TEAM1)
1802         {
1803                 SetWinners(team, COLOR_TEAM2);
1804         }
1805         else
1806         {
1807                 SetWinners(team, COLOR_TEAM1);
1808         }
1809
1810         local entity ent;
1811         ent = find(world, classname, "target_assault_roundend");
1812         if(ent)
1813         {
1814                 if(ent.winning) // round end has been triggered by attacking team
1815                 {
1816                         bprint("ASSAULT: round completed...\n");
1817                         SetWinners(team, assault_attacker_team);
1818
1819                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1820
1821                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1822                         {
1823                                 status = WINNING_YES;
1824                         }
1825                         else
1826                         {
1827                                 local entity oldself;
1828                                 oldself = self;
1829                                 self = ent;
1830                                 assault_new_round();
1831                                 self = oldself;
1832                         }
1833                 }
1834         }
1835
1836         return status;
1837 }
1838
1839 // LMS winning condition: game terminates if and only if there's at most one
1840 // one player who's living lives. Top two scores being equal cancels the time
1841 // limit.
1842 float WinningCondition_LMS()
1843 {
1844         entity head, head2;
1845         float have_player;
1846         float have_players;
1847         float l;
1848
1849         have_player = FALSE;
1850         have_players = FALSE;
1851         l = LMS_NewPlayerLives();
1852
1853         head = find(world, classname, "player");
1854         if(head)
1855                 have_player = TRUE;
1856         head2 = find(head, classname, "player");
1857         if(head2)
1858                 have_players = TRUE;
1859
1860         if(have_player)
1861         {
1862                 // we have at least one player
1863                 if(have_players)
1864                 {
1865                         // two or more active players - continue with the game
1866                 }
1867                 else
1868                 {
1869                         // exactly one player?
1870
1871                         ClearWinners();
1872                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1873
1874                         if(l)
1875                         {
1876                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1877                                 return WINNING_NO;
1878                         }
1879                         else
1880                         {
1881                                 // a winner!
1882                                 // and assign him his first place
1883                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1884                                 return WINNING_YES;
1885                         }
1886                 }
1887         }
1888         else
1889         {
1890                 // nobody is playing at all...
1891                 if(l)
1892                 {
1893                         // wait for players...
1894                 }
1895                 else
1896                 {
1897                         // SNAFU (maybe a draw game?)
1898                         ClearWinners();
1899                         dprint("No players, ending game.\n");
1900                         return WINNING_YES;
1901                 }
1902         }
1903
1904         // When we get here, we have at least two players who are actually LIVING,
1905         // now check if the top two players have equal score.
1906         WinningConditionHelper();
1907
1908         ClearWinners();
1909         if(WinningConditionHelper_winner)
1910                 WinningConditionHelper_winner.winning = TRUE;
1911         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1912                 return WINNING_NEVER;
1913
1914         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1915         return WINNING_NO;
1916 }
1917
1918 void ShuffleMaplist()
1919 {
1920         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1921 }
1922
1923 float leaderfrags;
1924 float WinningCondition_Scores(float limit, float leadlimit)
1925 {
1926         float limitreached;
1927
1928         // TODO make everything use THIS winning condition (except LMS)
1929         WinningConditionHelper();
1930
1931         if(teamplay)
1932         {
1933                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1934                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1935                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1936                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1937         }
1938
1939         ClearWinners();
1940         if(WinningConditionHelper_winner)
1941                 WinningConditionHelper_winner.winning = 1;
1942         if(WinningConditionHelper_winnerteam >= 0)
1943                 SetWinners(team, WinningConditionHelper_winnerteam);
1944
1945         if(WinningConditionHelper_lowerisbetter)
1946         {
1947                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1948                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1949                 limit = -limit;
1950         }
1951
1952         if(WinningConditionHelper_zeroisworst)
1953                 leadlimit = 0; // not supported in this mode
1954
1955         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1956         // these modes always score in increments of 1, thus this makes sense
1957         {
1958                 if(leaderfrags != WinningConditionHelper_topscore)
1959                 {
1960                         leaderfrags = WinningConditionHelper_topscore;
1961
1962                         if (limit)
1963                         if (leaderfrags == limit - 1)
1964                                 Announce("1fragleft");
1965                         else if (leaderfrags == limit - 2)
1966                                 Announce("2fragsleft");
1967                         else if (leaderfrags == limit - 3)
1968                                 Announce("3fragsleft");
1969                 }
1970         }
1971
1972         limitreached = FALSE;
1973         if(limit)
1974                 if(WinningConditionHelper_topscore >= limit)
1975                         limitreached = TRUE;
1976         if(leadlimit)
1977         {
1978                 float leadlimitreached;
1979                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1980                 if(autocvar_leadlimit_and_fraglimit)
1981                         limitreached = (limitreached && leadlimitreached);
1982                 else
1983                         limitreached = (limitreached || leadlimitreached);
1984         }
1985
1986         return GetWinningCode(
1987                 WinningConditionHelper_topscore && limitreached,
1988                 WinningConditionHelper_equality
1989         );
1990 }
1991
1992 float WinningCondition_Race(float fraglimit)
1993 {
1994         float wc;
1995         entity p;
1996         float n, c;
1997
1998         n = 0;
1999         c = 0;
2000         FOR_EACH_PLAYER(p)
2001         {
2002                 ++n;
2003                 if(p.race_completed)
2004                         ++c;
2005         }
2006         if(n && (n == c))
2007                 return WINNING_YES;
2008         wc = WinningCondition_Scores(fraglimit, 0);
2009
2010         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2011         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2012         // do NOT support equality when the laps are all raced!
2013                 return WINNING_STARTSUDDENDEATHOVERTIME;
2014         else
2015                 return WINNING_NEVER;
2016         return wc;
2017 }
2018
2019 void ReadyRestart();
2020 float WinningCondition_QualifyingThenRace(float limit)
2021 {
2022         float wc;
2023         wc = WinningCondition_Scores(limit, 0);
2024
2025         // NEVER initiate overtime
2026         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2027         {
2028                 return WINNING_YES;
2029         }
2030
2031         return wc;
2032 }
2033
2034 float WinningCondition_RanOutOfSpawns()
2035 {
2036         entity head;
2037
2038         if(have_team_spawns <= 0)
2039                 return WINNING_NO;
2040
2041         if(!some_spawn_has_been_used)
2042                 return WINNING_NO;
2043
2044         team1_score = team2_score = team3_score = team4_score = 0;
2045
2046         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2047         {
2048                 if(head.team == COLOR_TEAM1)
2049                         team1_score = 1;
2050                 else if(head.team == COLOR_TEAM2)
2051                         team2_score = 1;
2052                 else if(head.team == COLOR_TEAM3)
2053                         team3_score = 1;
2054                 else if(head.team == COLOR_TEAM4)
2055                         team4_score = 1;
2056         }
2057
2058         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2059         {
2060                 if(head.team == COLOR_TEAM1)
2061                         team1_score = 1;
2062                 else if(head.team == COLOR_TEAM2)
2063                         team2_score = 1;
2064                 else if(head.team == COLOR_TEAM3)
2065                         team3_score = 1;
2066                 else if(head.team == COLOR_TEAM4)
2067                         team4_score = 1;
2068         }
2069
2070         ClearWinners();
2071         if(team1_score + team2_score + team3_score + team4_score == 0)
2072         {
2073                 checkrules_equality = TRUE;
2074                 return WINNING_YES;
2075         }
2076         else if(team1_score + team2_score + team3_score + team4_score == 1)
2077         {
2078                 float t, i;
2079                 if(team1_score) t = COLOR_TEAM1;
2080                 if(team2_score) t = COLOR_TEAM2;
2081                 if(team3_score) t = COLOR_TEAM3;
2082                 if(team4_score) t = COLOR_TEAM4;
2083                 CheckAllowedTeams(world);
2084                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2085                 {
2086                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2087                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2088                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2089                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2090                 }
2091
2092                 AddWinners(team, t);
2093                 return WINNING_YES;
2094         }
2095         else
2096                 return WINNING_NO;
2097 }
2098
2099 /*
2100 ============
2101 CheckRules_World
2102
2103 Exit deathmatch games upon conditions
2104 ============
2105 */
2106 void CheckRules_World()
2107 {
2108         float timelimit;
2109         float fraglimit;
2110         float leadlimit;
2111
2112         VoteThink();
2113         MapVote_Think();
2114
2115         SetDefaultAlpha();
2116
2117         /*
2118         MapVote_Think should now do that part
2119         if (intermission_running)
2120                 if (time >= intermission_exittime + 60)
2121                 {
2122                         if(!DoNextMapOverride())
2123                                 GotoNextMap();
2124                         return;
2125                 }
2126         */
2127
2128         if (gameover)   // someone else quit the game already
2129         {
2130                 if(player_count == 0) // Nobody there? Then let's go to the next map
2131                         MapVote_Start();
2132                         // this will actually check the player count in the next frame
2133                         // again, but this shouldn't hurt
2134                 return;
2135         }
2136
2137         timelimit = autocvar_timelimit * 60;
2138         fraglimit = autocvar_fraglimit;
2139         leadlimit = autocvar_leadlimit;
2140
2141         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2142         {
2143                 if(timelimit > 0)
2144                         timelimit = 0; // timelimit is not made for warmup
2145                 if(fraglimit > 0)
2146                         fraglimit = 0; // no fraglimit for now
2147                 leadlimit = 0; // no leadlimit for now
2148         }
2149
2150         if(g_onslaught)
2151                 timelimit = 0; // ONS has its own overtime rule
2152
2153         if(timelimit > 0)
2154         {
2155                 timelimit += game_starttime;
2156         }
2157         else if (timelimit < 0)
2158         {
2159                 // endmatch
2160                 NextLevel();
2161                 return;
2162         }
2163
2164         float wantovertime;
2165         wantovertime = 0;
2166
2167         if(checkrules_suddendeathend)
2168         {
2169                 if(!checkrules_suddendeathwarning)
2170                 {
2171                         checkrules_suddendeathwarning = TRUE;
2172                         if(g_race && !g_race_qualifying)
2173                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2174                         else
2175                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2176                 }
2177         }
2178         else
2179         {
2180                 if (timelimit && time >= timelimit)
2181                 {
2182                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2183                         {
2184                                 float totalplayers;
2185                                 float playerswithlaps;
2186                                 float readyplayers;
2187                                 entity head;
2188                                 totalplayers = playerswithlaps = readyplayers = 0;
2189                                 FOR_EACH_PLAYER(head)
2190                                 {
2191                                         ++totalplayers;
2192                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2193                                                 ++playerswithlaps;
2194                                         if(head.ready)
2195                                                 ++readyplayers;
2196                                 }
2197
2198                                 // at least 2 of the players have completed a lap: start the RACE
2199                                 // otherwise, the players should end the qualifying on their own
2200                                 if(readyplayers || playerswithlaps >= 2)
2201                                 {
2202                                         checkrules_suddendeathend = 0;
2203                                         ReadyRestart(); // go to race
2204                                         return;
2205                                 }
2206                                 else
2207                                         wantovertime |= InitiateSuddenDeath();
2208                         }
2209                         else
2210                                 wantovertime |= InitiateSuddenDeath();
2211                 }
2212         }
2213
2214         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2215         {
2216                 NextLevel();
2217                 return;
2218         }
2219
2220         float checkrules_status;
2221         checkrules_status = WinningCondition_RanOutOfSpawns();
2222         if(checkrules_status == WINNING_YES)
2223         {
2224                 bprint("Hey! Someone ran out of spawns!\n");
2225         }
2226         else if(g_race && !g_race_qualifying && timelimit >= 0)
2227         {
2228                 checkrules_status = WinningCondition_Race(fraglimit);
2229                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2230         }
2231         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2232         {
2233                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2234                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2235         }
2236         else if(g_assault)
2237         {
2238                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2239         }
2240         else if(g_lms)
2241         {
2242                 checkrules_status = WinningCondition_LMS();
2243         }
2244         else if (g_onslaught)
2245         {
2246                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2247         }
2248         else
2249         {
2250                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2251                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2252         }
2253
2254         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2255         {
2256                 checkrules_status = WINNING_NEVER;
2257                 checkrules_overtimesadded = -1;
2258                 wantovertime |= InitiateSuddenDeath();
2259         }
2260
2261         if(checkrules_status == WINNING_NEVER)
2262                 // equality cases! Nobody wins if the overtime ends in a draw.
2263                 ClearWinners();
2264
2265         if(wantovertime)
2266         {
2267                 if(checkrules_status == WINNING_NEVER)
2268                         InitiateOvertime();
2269                 else
2270                         checkrules_status = WINNING_YES;
2271         }
2272
2273         if(checkrules_suddendeathend)
2274                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2275                         checkrules_status = WINNING_YES;
2276
2277         if(checkrules_status == WINNING_YES)
2278         {
2279                 //print("WINNING\n");
2280                 NextLevel();
2281         }
2282 };
2283
2284 float mapvote_nextthink;
2285 float mapvote_initialized;
2286 float mapvote_keeptwotime;
2287 float mapvote_timeout;
2288 string mapvote_message;
2289 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2290 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2291 float mapvote_screenshot_dirs_count;
2292
2293 float mapvote_count;
2294 float mapvote_count_real;
2295 string mapvote_maps[MAPVOTE_COUNT];
2296 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2297 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2298 float mapvote_maps_suggested[MAPVOTE_COUNT];
2299 string mapvote_suggestions[MAPVOTE_COUNT];
2300 float mapvote_suggestion_ptr;
2301 float mapvote_voters;
2302 float mapvote_votes[MAPVOTE_COUNT];
2303 float mapvote_run;
2304 float mapvote_detail;
2305 float mapvote_abstain;
2306 .float mapvote;
2307
2308 void MapVote_ClearAllVotes()
2309 {
2310         FOR_EACH_CLIENT(other)
2311                 other.mapvote = 0;
2312 }
2313
2314 string MapVote_Suggest(string m)
2315 {
2316         float i;
2317         if(m == "")
2318                 return "That's not how to use this command.";
2319         if(!autocvar_g_maplist_votable_suggestions)
2320                 return "Suggestions are not accepted on this server.";
2321         if(mapvote_initialized)
2322                 return "Can't suggest - voting is already in progress!";
2323         m = MapInfo_FixName(m);
2324         if(!m)
2325                 return "The map you suggested is not available on this server.";
2326         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2327                 if(Map_IsRecent(m))
2328                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2329
2330         if(!MapInfo_CheckMap(m))
2331                 return "The map you suggested does not support the current game mode.";
2332         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2333                 if(mapvote_suggestions[i] == m)
2334                         return "This map was already suggested.";
2335         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2336         {
2337                 i = floor(random() * mapvote_suggestion_ptr);
2338         }
2339         else
2340         {
2341                 i = mapvote_suggestion_ptr;
2342                 mapvote_suggestion_ptr += 1;
2343         }
2344         if(mapvote_suggestions[i] != "")
2345                 strunzone(mapvote_suggestions[i]);
2346         mapvote_suggestions[i] = strzone(m);
2347         if(autocvar_sv_eventlog)
2348                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2349         return strcat("Suggestion of ", m, " accepted.");
2350 }
2351
2352 void MapVote_AddVotable(string nextMap, float isSuggestion)
2353 {
2354         float j, i, o;
2355         string pakfile, mapfile;
2356
2357         if(nextMap == "")
2358                 return;
2359         for(j = 0; j < mapvote_count; ++j)
2360                 if(mapvote_maps[j] == nextMap)
2361                         return;
2362         // suggestions might be no longer valid/allowed after gametype switch!
2363         if(isSuggestion)
2364                 if(!MapInfo_CheckMap(nextMap))
2365                         return;
2366         mapvote_maps[mapvote_count] = strzone(nextMap);
2367         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2368
2369         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2370         {
2371                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2372                 pakfile = whichpack(strcat(mapfile, ".tga"));
2373                 if(pakfile == "")
2374                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2375                 if(pakfile == "")
2376                         pakfile = whichpack(strcat(mapfile, ".png"));
2377                 if(pakfile != "")
2378                         break;
2379         }
2380         if(i >= mapvote_screenshot_dirs_count)
2381                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2382         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2383                 pakfile = substring(pakfile, o, -1);
2384
2385         mapvote_maps_screenshot_dir[mapvote_count] = i;
2386         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2387
2388         mapvote_count += 1;
2389 }
2390
2391 void MapVote_Spawn();
2392 void MapVote_Init()
2393 {
2394         float i;
2395         float nmax, smax;
2396
2397         MapVote_ClearAllVotes();
2398
2399         mapvote_count = 0;
2400         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2401         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2402
2403         if(mapvote_abstain)
2404                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2405         else
2406                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2407         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2408
2409         // we need this for AddVotable, as that cycles through the screenshot dirs
2410         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2411         if(mapvote_screenshot_dirs_count == 0)
2412                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2413         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2414         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2415                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2416
2417         if(mapvote_suggestion_ptr)
2418                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2419                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2420
2421         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2422                 MapVote_AddVotable(GetNextMap(), FALSE);
2423
2424         if(mapvote_count == 0)
2425         {
2426                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2427                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2428                 if(autocvar_g_maplist_shuffle)
2429                         ShuffleMaplist();
2430                 localcmd("\nmenu_cmd sync\n");
2431                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2432                         MapVote_AddVotable(GetNextMap(), FALSE);
2433         }
2434
2435         mapvote_count_real = mapvote_count;
2436         if(mapvote_abstain)
2437                 MapVote_AddVotable("don't care", 0);
2438
2439         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2440
2441         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2442         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2443         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2444                 mapvote_keeptwotime = 0;
2445         mapvote_message = "Choose a map and press its key!";
2446
2447         MapVote_Spawn();
2448 }
2449
2450 void MapVote_SendPicture(float id)
2451 {
2452         msg_entity = self;
2453         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2454         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2455         WriteByte(MSG_ONE, id);
2456         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2457 }
2458
2459 float GameCommand_MapVote(string cmd)
2460 {
2461         if(!intermission_running)
2462                 return FALSE;
2463
2464         if(cmd == "mv_getpic")
2465         {
2466                 MapVote_SendPicture(stof(argv(1)));
2467                 return TRUE;
2468         }
2469
2470         return FALSE;
2471 }
2472
2473 float MapVote_GetMapMask()
2474 {
2475         float mask, i, power;
2476         mask = 0;
2477         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2478                 if(mapvote_maps[i] != "")
2479                         mask |= power;
2480         return mask;
2481 }
2482
2483 entity mapvote_ent;
2484 float MapVote_SendEntity(entity to, float sf)
2485 {
2486         float i;
2487
2488         if(sf & 1)
2489                 sf &~= 2; // if we send 1, we don't need to also send 2
2490
2491         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2492         WriteByte(MSG_ENTITY, sf);
2493
2494         if(sf & 1)
2495         {
2496                 // flag 1 == initialization
2497                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2498                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2499                 WriteString(MSG_ENTITY, "");
2500                 WriteByte(MSG_ENTITY, mapvote_count);
2501                 WriteByte(MSG_ENTITY, mapvote_abstain);
2502                 WriteByte(MSG_ENTITY, mapvote_detail);
2503                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2504                 if(mapvote_count <= 8)
2505                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2506                 else
2507                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2508                 for(i = 0; i < mapvote_count; ++i)
2509                         if(mapvote_maps[i] != "")
2510                         {
2511                                 if(mapvote_abstain && i == mapvote_count - 1)
2512                                 {
2513                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2514                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2515                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2516                                 }
2517                                 else
2518                                 {
2519                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2520                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2521                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2522                                 }
2523                         }
2524         }
2525
2526         if(sf & 2)
2527         {
2528                 // flag 2 == update of mask
2529                 if(mapvote_count <= 8)
2530                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2531                 else
2532                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2533         }
2534
2535         if(sf & 4)
2536         {
2537                 if(mapvote_detail)
2538                         for(i = 0; i < mapvote_count; ++i)
2539                                 if(mapvote_maps[i] != "")
2540                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2541
2542                 WriteByte(MSG_ENTITY, to.mapvote);
2543         }
2544
2545         return TRUE;
2546 }
2547
2548 void MapVote_Spawn()
2549 {
2550         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2551 }
2552
2553 void MapVote_TouchMask()
2554 {
2555         mapvote_ent.SendFlags |= 2;
2556 }
2557
2558 void MapVote_TouchVotes(entity voter)
2559 {
2560         mapvote_ent.SendFlags |= 4;
2561 }
2562
2563 float MapVote_Finished(float mappos)
2564 {
2565         string result;
2566         float i;
2567         float didntvote;
2568
2569         if(autocvar_sv_eventlog)
2570         {
2571                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2572                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2573                 didntvote = mapvote_voters;
2574                 for(i = 0; i < mapvote_count; ++i)
2575                         if(mapvote_maps[i] != "")
2576                         {
2577                                 didntvote -= mapvote_votes[i];
2578                                 if(i != mappos)
2579                                 {
2580                                         result = strcat(result, ":", mapvote_maps[i]);
2581                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2582                                 }
2583                         }
2584                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2585
2586                 GameLogEcho(result);
2587                 if(mapvote_maps_suggested[mappos])
2588                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2589         }
2590
2591         FOR_EACH_REALCLIENT(other)
2592                 FixClientCvars(other);
2593
2594         Map_Goto_SetStr(mapvote_maps[mappos]);
2595         Map_Goto();
2596         alreadychangedlevel = TRUE;
2597         return TRUE;
2598 }
2599 void MapVote_CheckRules_1()
2600 {
2601         float i;
2602
2603         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2604         {
2605                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2606                 mapvote_votes[i] = 0;
2607         }
2608
2609         mapvote_voters = 0;
2610         FOR_EACH_REALCLIENT(other)
2611         {
2612                 ++mapvote_voters;
2613                 if(other.mapvote)
2614                 {
2615                         i = other.mapvote - 1;
2616                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2617                         mapvote_votes[i] = mapvote_votes[i] + 1;
2618                 }
2619         }
2620 }
2621
2622 float MapVote_CheckRules_2()
2623 {
2624         float i;
2625         float firstPlace, secondPlace;
2626         float firstPlaceVotes, secondPlaceVotes;
2627         float mapvote_voters_real;
2628         string result;
2629
2630         if(mapvote_count_real == 1)
2631                 return MapVote_Finished(0);
2632
2633         mapvote_voters_real = mapvote_voters;
2634         if(mapvote_abstain)
2635                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2636
2637         RandomSelection_Init();
2638         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2639                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2640         firstPlace = RandomSelection_chosen_float;
2641         firstPlaceVotes = RandomSelection_best_priority;
2642         //dprint("First place: ", ftos(firstPlace), "\n");
2643         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2644
2645         RandomSelection_Init();
2646         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2647                 if(i != firstPlace)
2648                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2649         secondPlace = RandomSelection_chosen_float;
2650         secondPlaceVotes = RandomSelection_best_priority;
2651         //dprint("Second place: ", ftos(secondPlace), "\n");
2652         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2653
2654         if(firstPlace == -1)
2655                 error("No first place in map vote... WTF?");
2656
2657         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2658                 return MapVote_Finished(firstPlace);
2659
2660         if(mapvote_keeptwotime)
2661                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2662                 {
2663                         float didntvote;
2664                         MapVote_TouchMask();
2665                         mapvote_message = "Now decide between the TOP TWO!";
2666                         mapvote_keeptwotime = 0;
2667                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2668                         result = strcat(result, ":", ftos(firstPlaceVotes));
2669                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2670                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2671                         didntvote = mapvote_voters;
2672                         for(i = 0; i < mapvote_count; ++i)
2673                                 if(mapvote_maps[i] != "")
2674                                 {
2675                                         didntvote -= mapvote_votes[i];
2676                                         if(i != firstPlace)
2677                                                 if(i != secondPlace)
2678                                                 {
2679                                                         result = strcat(result, ":", mapvote_maps[i]);
2680                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2681                                                         if(i < mapvote_count_real)
2682                                                         {
2683                                                                 strunzone(mapvote_maps[i]);
2684                                                                 mapvote_maps[i] = "";
2685                                                                 strunzone(mapvote_maps_pakfile[i]);
2686                                                                 mapvote_maps_pakfile[i] = "";
2687                                                         }
2688                                                 }
2689                                 }
2690                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2691                         if(autocvar_sv_eventlog)
2692                                 GameLogEcho(result);
2693                 }
2694
2695         return FALSE;
2696 }
2697 void MapVote_Tick()
2698 {
2699         float keeptwo;
2700         float totalvotes;
2701
2702         keeptwo = mapvote_keeptwotime;
2703         MapVote_CheckRules_1(); // count
2704         if(MapVote_CheckRules_2()) // decide
2705                 return;
2706
2707         totalvotes = 0;
2708         FOR_EACH_REALCLIENT(other)
2709         {
2710                 // hide scoreboard again
2711                 if(other.health != 2342)
2712                 {
2713                         other.health = 2342;
2714                         other.impulse = 0;
2715                         if(clienttype(other) == CLIENTTYPE_REAL)
2716                         {
2717                                 msg_entity = other;
2718                                 WriteByte(MSG_ONE, SVC_FINALE);
2719                                 WriteString(MSG_ONE, "");
2720                         }
2721                 }
2722
2723                 // clear possibly invalid votes
2724                 if(mapvote_maps[other.mapvote - 1] == "")
2725                         other.mapvote = 0;
2726                 // use impulses as new vote
2727                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2728                         if(mapvote_maps[other.impulse - 1] != "")
2729                         {
2730                                 other.mapvote = other.impulse;
2731                                 MapVote_TouchVotes(other);
2732                         }
2733                 other.impulse = 0;
2734
2735                 if(other.mapvote)
2736                         ++totalvotes;
2737         }
2738
2739         MapVote_CheckRules_1(); // just count
2740 }
2741 void MapVote_Start()
2742 {
2743         if(mapvote_run)
2744                 return;
2745
2746         // wait for stats to be sent first
2747         if(!playerstats_waitforme)
2748                 return;
2749
2750         MapInfo_Enumerate();
2751         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2752                 mapvote_run = TRUE;
2753 }
2754 void MapVote_Think()
2755 {
2756         if(!mapvote_run)
2757                 return;
2758
2759         if(alreadychangedlevel)
2760                 return;
2761
2762         if(time < mapvote_nextthink)
2763                 return;
2764         //dprint("tick\n");
2765
2766         mapvote_nextthink = time + 0.5;
2767
2768         if(!mapvote_initialized)
2769         {
2770                 if(autocvar_rescan_pending == 1)
2771                 {
2772                         cvar_set("rescan_pending", "2");
2773                         localcmd("fs_rescan\nrescan_pending 3\n");
2774                         return;
2775                 }
2776                 else if(autocvar_rescan_pending == 2)
2777                 {
2778                         return;
2779                 }
2780                 else if(autocvar_rescan_pending == 3)
2781                 {
2782                         // now build missing mapinfo files
2783                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2784                                 return;
2785
2786                         // we're done, start the timer
2787                         cvar_set("rescan_pending", "0");
2788                 }
2789
2790                 mapvote_initialized = TRUE;
2791                 if(DoNextMapOverride())
2792                         return;
2793                 if(!autocvar_g_maplist_votable || player_count <= 0)
2794                 {
2795                         GotoNextMap();
2796                         return;
2797                 }
2798                 MapVote_Init();
2799         }
2800
2801         MapVote_Tick();
2802 };
2803
2804 string GotoMap(string m)
2805 {
2806         if(!MapInfo_CheckMap(m))
2807                 return "The map you chose is not available on this server.";
2808         cvar_set("nextmap", m);
2809         cvar_set("timelimit", "-1");
2810         if(mapvote_initialized || alreadychangedlevel)
2811         {
2812                 if(DoNextMapOverride())
2813                         return "Map switch initiated.";
2814                 else
2815                         return "Hm... no. For some reason I like THIS map more.";
2816         }
2817         else
2818                 return "Map switch will happen after scoreboard.";
2819 }
2820
2821
2822 void EndFrame()
2823 {
2824         float altime;
2825         FOR_EACH_REALCLIENT(self)
2826         {
2827                 if(self.classname == "spectator")
2828                 {
2829                         if(self.enemy.typehitsound)
2830                                 self.typehit_time = time;
2831                         else if(self.enemy.hitsound)
2832                                 self.hit_time = time;
2833                 }
2834                 else
2835                 {
2836                         if(self.typehitsound)
2837                                 self.typehit_time = time;
2838                         else if(self.hitsound)
2839                                 self.hit_time = time;
2840                 }
2841         }
2842         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2843         // add 1 frametime because after this, engine SV_Physics
2844         // increases time by a frametime and then networks the frame
2845         // add another frametime because client shows everything with
2846         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2847         // needed!
2848         FOR_EACH_CLIENT(self)
2849         {
2850                 self.hitsound = FALSE;
2851                 self.typehitsound = FALSE;
2852                 antilag_record(self, altime);
2853         }
2854 }
2855
2856
2857 /*
2858  * RedirectionThink:
2859  * returns TRUE if redirecting
2860  */
2861 float redirection_timeout;
2862 float redirection_nextthink;
2863 float RedirectionThink()
2864 {
2865         float clients_found;
2866
2867         if(redirection_target == "")
2868                 return FALSE;
2869
2870         if(!redirection_timeout)
2871         {
2872                 cvar_set("sv_public", "-2");
2873                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2874                 if(redirection_target == "self")
2875                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2876                 else
2877                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2878         }
2879
2880         if(time < redirection_nextthink)
2881                 return TRUE;
2882
2883         redirection_nextthink = time + 1;
2884
2885         clients_found = 0;
2886         FOR_EACH_REALCLIENT(self)
2887         {
2888                 print("Redirecting: sending connect command to ", self.netname, "\n");
2889                 if(redirection_target == "self")
2890                         stuffcmd(self, "\ndisconnect; reconnect\n");
2891                 else
2892                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2893                 ++clients_found;
2894         }
2895
2896         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2897
2898         if(time > redirection_timeout || clients_found == 0)
2899                 localcmd("\nwait; wait; wait; quit\n");
2900
2901         return TRUE;
2902 }
2903
2904 void TargetMusic_RestoreGame();
2905 void RestoreGame()
2906 {
2907         // Loaded from a save game
2908         // some things then break, so let's work around them...
2909
2910         // Progs DB (capture records)
2911         ServerProgsDB = db_load("server.db");
2912
2913         // Mapinfo
2914         MapInfo_Shutdown();
2915         MapInfo_Enumerate();
2916         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2917         WeaponStats_Init();
2918
2919         TargetMusic_RestoreGame();
2920 }
2921
2922 void SV_Shutdown()
2923 {
2924         entity e;
2925
2926         if(gameover > 1) // shutting down already?
2927                 return;
2928
2929         gameover = 2; // 2 = server shutting down
2930
2931         if(world_initialized > 0)
2932         {
2933                 world_initialized = 0;
2934                 print("Saving persistent data...\n");
2935                 Ban_SaveBans();
2936
2937                 PlayerStats_EndMatch(0);
2938                 FOR_EACH_CLIENT(e)
2939                         PlayerStats_AddGlobalInfo(e);
2940                 PlayerStats_Shutdown();
2941
2942                 if(!cheatcount_total)
2943                 {
2944                         if(autocvar_sv_db_saveasdump)
2945                                 db_dump(ServerProgsDB, "server.db");
2946                         else
2947                                 db_save(ServerProgsDB, "server.db");
2948                 }
2949                 if(autocvar_developer)
2950                 {
2951                         if(autocvar_sv_db_saveasdump)
2952                                 db_dump(TemporaryDB, "server-temp.db");
2953                         else
2954                                 db_save(TemporaryDB, "server-temp.db");
2955                 }
2956                 CheatShutdown(); // must be after cheatcount check
2957                 db_close(ServerProgsDB);
2958                 db_close(TemporaryDB);
2959                 print("done!\n");
2960                 // tell the bot system the game is ending now
2961                 bot_endgame();
2962
2963                 WeaponStats_Shutdown();
2964                 MapInfo_Shutdown();
2965         }
2966         else if(world_initialized == 0)
2967         {
2968                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2969         }
2970 }