qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312
 313                 // these can contain player IDs, so better hide
 314                 BADPREFIX("g_forced_team_");
 315
 316                 // mapinfo
 317                 BADCVAR("fraglimit");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_assault");
 320                 BADCVAR("g_ca");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_cts");
 323                 BADCVAR("g_dm");
 324                 BADCVAR("g_domination");
 325                 BADCVAR("g_domination_default_teams");
 326                 BADCVAR("g_freezetag");
 327                 BADCVAR("g_keepaway");
 328                 BADCVAR("g_keyhunt");
 329                 BADCVAR("g_keyhunt_teams");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_lms");
 332                 BADCVAR("g_nexball");
 333                 BADCVAR("g_onslaught");
 334                 BADCVAR("g_race");
 335                 BADCVAR("g_race_qualifying_timelimit");
 336                 BADCVAR("g_runematch");
 337                 BADCVAR("g_tdm");
 338                 BADCVAR("g_tdm_teams");
 339                 BADCVAR("leadlimit");
 340                 BADCVAR("nextmap");
 341                 BADCVAR("teamplay");
 342                 BADCVAR("timelimit");
 343
 344                 // long
 345                 BADCVAR("hostname");
 346                 BADCVAR("g_maplist");
 347                 BADCVAR("g_maplist_mostrecent");
 348                 BADCVAR("sv_motd");
 349
 350                 v = cvar_string(k);
 351                 d = cvar_defstring(k);
 352                 if(v == d)
 353                         continue;
 354
 355                 if(adding)
 356                 {
 357                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 358                         if(strlen(cvar_changes) > 16384)
 359                         {
 360                                 cvar_changes = "// too many settings have been changed to show them here\n";
 361                                 adding = 0;
 362                         }
 363                 }
 364
 365                 // now check if the changes are actually gameplay relevant
 366
 367                 // does nothing visible
 368                 BADCVAR("captureleadlimit_override");
 369                 BADCVAR("g_arena_point_leadlimit");
 370                 BADCVAR("g_balance_kill_delay");
 371                 BADCVAR("g_ca_point_leadlimit");
 372                 BADCVAR("g_ctf_captimerecord_always");
 373                 BADCVAR("g_ctf_capture_leadlimit");
 374                 BADCVAR("g_ctf_flag_capture_effects");
 375                 BADCVAR("g_ctf_flag_glowtrails");
 376                 BADCVAR("g_ctf_flag_pickup_effects");
 377                 BADCVAR("g_domination_point_leadlimit");
 378                 BADCVAR("g_forced_respawn");
 379                 BADCVAR("g_keyhunt_point_leadlimit");
 380                 BADCVAR("g_nexball_goalleadlimit");
 381                 BADCVAR("g_runematch_point_leadlimit");
 382                 BADCVAR("leadlimit_and_fraglimit");
 383                 BADCVAR("leadlimit_override");
 384                 BADCVAR("pausable");
 385                 BADCVAR("sv_checkforpacketsduringsleep");
 386                 BADCVAR("sv_timeout");
 387                 BADCVAR("welcome_message_time");
 388                 BADPREFIX("crypto_");
 389                 BADPREFIX("g_chat_");
 390                 BADPREFIX("g_ctf_captimerecord_");
 391                 BADPREFIX("g_maplist_votable_");
 392                 BADPREFIX("net_");
 393                 BADPREFIX("prvm_");
 394                 BADPREFIX("skill_");
 395                 BADPREFIX("sv_fraginfo_");
 396                 BADPREFIX("sv_maxidle_");
 397                 BADPREFIX("sv_vote_");
 398                 BADPREFIX("timelimit_");
 399                 BADCVAR("gameversion");
 400                 BADPREFIX("gameversion_");
 401
 402                 // allowed changes to server admins (please sync this to server.cfg)
 403                 // vi commands:
 404                 //   :/"impure"/,$d
 405                 //   :g!,^\/\/[^ /],d
 406                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 407                 //   :%!sort
 408                 // yes, this does contain some redundant stuff, don't really care
 409                 BADCVAR("bot_number");
 410                 BADCVAR("bot_prefix");
 411                 BADCVAR("bot_suffix");
 412                 BADCVAR("bot_config_file");
 413                 BADCVAR("capturelimit_override");
 414                 BADCVAR("fraglimit_override");
 415                 BADCVAR("gametype");
 416                 BADCVAR("g_antilag");
 417                 BADCVAR("g_balance_teams");
 418                 BADCVAR("g_balance_teams_force");
 419                 BADCVAR("g_ban_sync_trusted_servers");
 420                 BADCVAR("g_ban_sync_uri");
 421                 BADCVAR("g_ctf_capture_limit");
 422                 BADCVAR("g_ctf_ignore_frags");
 423                 BADCVAR("g_ctf_win_mode");
 424                 BADCVAR("g_domination_point_limit");
 425                 BADCVAR("g_friendlyfire");
 426                 BADCVAR("g_fullbrightitems");
 427                 BADCVAR("g_fullbrightplayers");
 428                 BADCVAR("g_keyhunt_point_limit");
 429                 BADCVAR("g_keyhunt_teams_override");
 430                 BADCVAR("g_lms_lives_override");
 431                 BADCVAR("g_maplist");
 432                 BADCVAR("g_maplist_check_waypoints");
 433                 BADCVAR("g_maplist_mostrecent_count");
 434                 BADCVAR("g_maplist_shuffle");
 435                 BADCVAR("g_maplist_votable");
 436                 BADCVAR("g_maplist_votable_abstain");
 437                 BADCVAR("g_maplist_votable_nodetail");
 438                 BADCVAR("g_maplist_votable_suggestions");
 439                 BADCVAR("g_maxplayers");
 440                 BADCVAR("g_minstagib");
 441                 BADCVAR("g_mirrordamage");
 442                 BADCVAR("g_nexball_goallimit");
 443                 BADCVAR("g_runematch_point_limit");
 444                 BADCVAR("g_start_delay");
 445                 BADCVAR("g_warmup");
 446                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 447                 BADCVAR("hostname");
 448                 BADCVAR("log_file");
 449                 BADCVAR("maxplayers");
 450                 BADCVAR("minplayers");
 451                 BADCVAR("net_address");
 452                 BADCVAR("port");
 453                 BADCVAR("rcon_password");
 454                 BADCVAR("rcon_restricted_commands");
 455                 BADCVAR("rcon_restricted_password");
 456                 BADCVAR("skill");
 457                 BADCVAR("sv_adminnick");
 458                 BADCVAR("sv_autoscreenshot");
 459                 BADCVAR("sv_curl_defaulturl");
 460                 BADCVAR("sv_defaultcharacter");
 461                 BADCVAR("sv_defaultplayercolors");
 462                 BADCVAR("sv_defaultplayermodel");
 463                 BADCVAR("sv_defaultplayerskin");
 464                 BADCVAR("sv_maxidle");
 465                 BADCVAR("sv_maxrate");
 466                 BADCVAR("sv_motd");
 467                 BADCVAR("sv_public");
 468                 BADCVAR("sv_ready_restart");
 469                 BADCVAR("sv_status_privacy");
 470                 BADCVAR("sv_vote_call");
 471                 BADCVAR("sv_vote_commands");
 472                 BADCVAR("sv_vote_majority_factor");
 473                 BADCVAR("sv_vote_master");
 474                 BADCVAR("sv_vote_master_commands");
 475                 BADCVAR("sv_vote_master_password");
 476                 BADCVAR("sv_vote_simple_majority_factor");
 477                 BADCVAR("sys_ticrate");
 478                 BADCVAR("teamplay_mode");
 479                 BADCVAR("timelimit_override");
 480                 BADPREFIX("g_warmup_");
 481
 482                 if(autocvar_g_minstagib)
 483                 {
 484                         BADCVAR("g_grappling_hook");
 485                         BADCVAR("g_jetpack");
 486                 }
 487 #undef BADPREFIX
 488 #undef BADCVAR
 489
 490                 if(pureadding)
 491                 {
 492                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 493                         if(strlen(cvar_purechanges) > 16384)
 494                         {
 495                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 496                                 pureadding = 0;
 497                         }
 498                 }
 499                 ++cvar_purechanges_count;
 500                 // WARNING: this variable is used for the server list
 501                 // NEVER dare to skip this code!
 502                 // Hacks to intentionally appearing as "pure server" even though you DO have
 503                 // modified settings may be punished by removal from the server list.
 504                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 505                 // though.
 506         }
 507         buf_del(h);
 508         if(cvar_changes == "")
 509                 cvar_changes = "// this server runs at default server settings\n";
 510         else
 511                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 512         cvar_changes = strzone(cvar_changes);
 513         if(cvar_purechanges == "")
 514                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 515         else
 516                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 517         cvar_purechanges = strzone(cvar_purechanges);
 518 }
 519
 520 void detect_maptype()
 521 {
 522 #if 0
 523         vector o, v;
 524         float i;
 525
 526         for(;;)
 527         {
 528                 o = world.mins;
 529                 o_x += random() * (world.maxs_x - world.mins_x);
 530                 o_y += random() * (world.maxs_y - world.mins_y);
 531                 o_z += random() * (world.maxs_z - world.mins_z);
 532
 533                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 534                 if(trace_fraction == 1)
 535                         continue;
 536
 537                 v = trace_endpos;
 538
 539                 for(i = 0; i < 64; i += 4)
 540                 {
 541                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 542         if(trace_fraction == 1)
 543                 continue;
 544                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 545                 }
 546
 547                 break;
 548         }
 549 #endif
 550 }
 551
 552 entity randomseed;
 553 float RandomSeed_Send(entity to, float sf)
 554 {
 555         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 556         WriteShort(MSG_ENTITY, self.cnt);
 557         return TRUE;
 558 }
 559 void RandomSeed_Think()
 560 {
 561         self.cnt = bound(0, floor(random() * 65536), 65535);
 562         self.nextthink = time + 5;
 563
 564         self.SendFlags |= 1;
 565 }
 566 void RandomSeed_Spawn()
 567 {
 568         randomseed = spawn();
 569         randomseed.think = RandomSeed_Think;
 570         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 571
 572         entity oldself;
 573         oldself = self;
 574         self = randomseed;
 575         self.think(); // sets random seed and nextthink
 576         self = oldself;
 577 }
 578
 579 void spawnfunc___init_dedicated_server(void)
 580 {
 581         // handler for _init/_init map (only for dedicated server initialization)
 582
 583         world_initialized = -1; // don't complain
 584         cvar = cvar_normal;
 585         cvar_string = cvar_string_normal;
 586         cvar_set = cvar_set_normal;
 587
 588         remove = remove_unsafely;
 589
 590         entity e;
 591         e = spawn();
 592         e.think = GotoFirstMap;
 593         e.nextthink = time; // this is usually 1 at this point
 594
 595         e = spawn();
 596         e.classname = "info_player_deathmatch"; // safeguard against player joining
 597
 598         self.classname = "worldspawn"; // safeguard against various stuff ;)
 599
 600         MapInfo_Enumerate();
 601         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 602 }
 603
 604 void Map_MarkAsRecent(string m);
 605 float world_already_spawned;
 606 void RegisterWeapons();
 607 void Nagger_Init();
 608 void ClientInit_Spawn();
 609 void WeaponStats_Init();
 610 void WeaponStats_Shutdown();
 611 void spawnfunc_worldspawn (void)
 612 {
 613         float fd, l, i, j, n;
 614         string s, col;
 615
 616         cvar = cvar_normal;
 617         cvar_string = cvar_string_normal;
 618         cvar_set = cvar_set_normal;
 619
 620         if(world_already_spawned)
 621                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 622         world_already_spawned = TRUE;
 623
 624         remove = remove_safely; // during spawning, watch what you remove!
 625
 626         check_unacceptable_compiler_bugs();
 627
 628         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 629
 630         compressShortVector_init();
 631
 632         allowed_to_spawn = TRUE;
 633
 634         entity head;
 635         head = nextent(world);
 636         maxclients = 0;
 637         while(head)
 638         {
 639                 ++maxclients;
 640                 head = nextent(head);
 641         }
 642
 643         // needs to be done so early as they would still spawn
 644         RegisterWeapons();
 645
 646         ServerProgsDB = db_load("server.db");
 647
 648         TemporaryDB = db_create();
 649
 650         // 0 normal
 651         lightstyle(0, "m");
 652
 653         // 1 FLICKER (first variety)
 654         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 655
 656         // 2 SLOW STRONG PULSE
 657         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 658
 659         // 3 CANDLE (first variety)
 660         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 661
 662         // 4 FAST STROBE
 663         lightstyle(4, "mamamamamama");
 664
 665         // 5 GENTLE PULSE 1
 666         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 667
 668         // 6 FLICKER (second variety)
 669         lightstyle(6, "nmonqnmomnmomomno");
 670
 671         // 7 CANDLE (second variety)
 672         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 673
 674         // 8 CANDLE (third variety)
 675         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 676
 677         // 9 SLOW STROBE (fourth variety)
 678         lightstyle(9, "aaaaaaaazzzzzzzz");
 679
 680         // 10 FLUORESCENT FLICKER
 681         lightstyle(10, "mmamammmmammamamaaamammma");
 682
 683         // 11 SLOW PULSE NOT FADE TO BLACK
 684         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 685
 686         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 687
 688         // 63 testing
 689         lightstyle(63, "a");
 690
 691         if(autocvar_g_campaign)
 692                 CampaignPreInit();
 693
 694         Map_MarkAsRecent(mapname);
 695
 696         precache_model ("null"); // we need this one before InitGameplayMode
 697         InitGameplayMode();
 698         readlevelcvars();
 699         GrappleHookInit();
 700         ElectroInit();
 701         LaserInit();
 702
 703         player_count = 0;
 704         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 705         if(bot_waypoints_for_items == 1)
 706                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 707                         bot_waypoints_for_items = 0;
 708
 709         precache();
 710
 711         WaypointSprite_Init();
 712
 713         //if (g_domination)
 714         //      dom_init();
 715
 716         GameLogInit(); // prepare everything
 717         if(autocvar_sv_eventlog)
 718         {
 719                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 720                 matchid = strzone(s);
 721
 722                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 723                 s = ":gameinfo:mutators:LIST";
 724
 725                 ret_string = s;
 726                 MUTATOR_CALLHOOK(BuildMutatorsString);
 727                 s = ret_string;
 728
 729                 // simple, probably not good in the mutator system
 730                 if(autocvar_g_grappling_hook)
 731                         s = strcat(s, ":grappling_hook");
 732
 733                 // initialiation stuff, not good in the mutator system
 734                 if(!autocvar_g_use_ammunition)
 735                         s = strcat(s, ":no_use_ammunition");
 736
 737                 // initialiation stuff, not good in the mutator system
 738                 if(!autocvar_g_pickup_items)
 739                         s = strcat(s, ":no_pickup_items");
 740
 741                 // initialiation stuff, not good in the mutator system
 742                 if(autocvar_g_weaponarena != "0")
 743                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 744
 745                 // TODO to mutator system
 746                 if(autocvar_g_norecoil)
 747                         s = strcat(s, ":norecoil");
 748
 749                 // TODO to mutator system
 750                 if(autocvar_g_midair)
 751                         s = strcat(s, ":midair");
 752
 753                 // TODO to mutator system
 754                 if(autocvar_g_minstagib)
 755                         s = strcat(s, ":minstagib");
 756
 757                 GameLogEcho(s);
 758                 GameLogEcho(":gameinfo:end");
 759         }
 760         else
 761                 matchid = strzone(ftos(random()));
 762
 763         cvar_set("nextmap", "");
 764
 765         SetDefaultAlpha();
 766
 767         if(autocvar_g_campaign)
 768                 CampaignPostInit();
 769
 770         fteqcc_testbugs();
 771
 772         Ban_LoadBans();
 773
 774         MapInfo_Enumerate();
 775         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 776
 777         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 778         {
 779                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 780                 if(fd != -1)
 781                 {
 782                         while((s = fgets(fd)))
 783                         {
 784                                 l = tokenize_console(s);
 785                                 if(l < 2)
 786                                         continue;
 787                                 if(argv(0) == "cd")
 788                                 {
 789                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 790                                         print("  cdtrack ", argv(2), "\n");
 791                                 }
 792                                 else if(argv(0) == "fog")
 793                                 {
 794                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 795                                         print("  \"fog\" \"", s, "\"\n");
 796                                 }
 797                                 else if(argv(0) == "set")
 798                                 {
 799                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 800                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 801                                 }
 802                                 else if(argv(0) != "//")
 803                                 {
 804                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 805                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 806                                 }
 807                         }
 808                         fclose(fd);
 809                 }
 810         }
 811
 812         WeaponStats_Init();
 813
 814         addstat(STAT_WEAPONS, AS_INT, weapons);
 815         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 816         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 817         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 818         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 819         Nagger_Init();
 820
 821         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 822         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 823         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 824         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 825         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 826         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 827         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 828         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 829         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 830         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 831         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 832         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 833
 834         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 835         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 836
 837         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 838
 839         if(g_ca || g_freezetag)
 840         {
 841                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 842                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 843                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 844                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 845         }
 846         if(g_freezetag)
 847         {
 848                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 849                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 850         }
 851
 852         // g_movementspeed hack
 853         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 854         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 855         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 856         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 857
 858         next_pingtime = time + 5;
 859
 860         detect_maptype();
 861
 862         lsmaps_reply = "^7Maps available: ";
 863         lsnewmaps_reply = "^7Maps without a record set: ";
 864         for(i = 0, j = 0; i < MapInfo_count; ++i)
 865         {
 866                 if(MapInfo_Get_ByID(i))
 867                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 868                         {
 869                                 if(mod(i, 2))
 870                                         col = "^2";
 871                                 else
 872                                         col = "^3";
 873                                 ++j;
 874                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 875                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 876                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 877                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 878                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 879                         }
 880         }
 881         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 882         if (!g_race && !g_cts)
 883                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 884         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 885
 886         maplist_reply = "^7Maps in list: ";
 887         n = tokenize_console(autocvar_g_maplist);
 888         for(i = 0, j = 0; i < n; ++i)
 889         {
 890                 if(MapInfo_CheckMap(argv(i)))
 891                 {
 892                         if(mod(j, 2))
 893                                 col = "^2";
 894                         else
 895                                 col = "^3";
 896                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 897                         ++j;
 898                 }
 899         }
 900         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 901         MapInfo_ClearTemps();
 902
 903         for(i = 0; i < 10; ++i)
 904         {
 905                 records_reply[i] = strzone(getrecords(i));
 906         }
 907         if(g_cts)
 908                 ladder_reply = strzone(getladder());
 909
 910         rankings_reply = strzone(getrankings());
 911
 912         ClientInit_Spawn();
 913         RandomSeed_Spawn();
 914         PingPLReport_Spawn();
 915
 916         CheatInit();
 917
 918         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 919
 920         // fill sv_curl_serverpackages from .serverpackage files
 921         if(autocvar_sv_curl_serverpackages_auto)
 922         {
 923                 s = "";
 924                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 925                 for(i = 0; i < n; ++i)
 926                         if(substring(argv(i), -14, -1) != ".serverpackage")
 927                                 s = strcat(s, " ", argv(i));
 928                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 929                 if(fd >= 0)
 930                 {
 931                         j = search_getsize(fd);
 932                         for(i = 0; i < j; ++i)
 933                                 s = strcat(s, " ", search_getfilename(fd, i));
 934                         search_end(fd);
 935                 }
 936                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 937         }
 938
 939         PlayerStats_Init();
 940
 941         world_initialized = 1;
 942 }
 943
 944 void spawnfunc_light (void)
 945 {
 946         //makestatic (self); // Who the f___ did that?
 947         remove(self);
 948 }
 949
 950 string GetGametype()
 951 {
 952         return GametypeNameFromType(game);
 953 }
 954
 955 string getmapname_stored;
 956 string GetMapname()
 957 {
 958         return mapname;
 959 }
 960
 961 float Map_Count, Map_Current;
 962 string Map_Current_Name;
 963
 964 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 965 float GetMaplistPosition()
 966 {
 967         float pos, idx;
 968         string map;
 969
 970         map = GetMapname();
 971         idx = autocvar_g_maplist_index;
 972
 973         if(idx >= 0)
 974                 if(idx < Map_Count)
 975                         if(map == argv(idx))
 976                                 return idx;
 977
 978         for(pos = 0; pos < Map_Count; ++pos)
 979                 if(map == argv(pos))
 980                         return pos;
 981
 982         // resume normal maplist rotation if current map is not in g_maplist
 983         return idx;
 984 }
 985
 986 float MapHasRightSize(string map)
 987 {
 988         float fh;
 989         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 990         if(autocvar_g_maplist_check_waypoints)
 991         {
 992                 dprint("checkwp "); dprint(map);
 993                 if(!fexists(strcat("maps/", map, ".waypoints")))
 994                 {
 995                         dprint(": no waypoints\n");
 996                         return FALSE;
 997                 }
 998                 dprint(": has waypoints\n");
 999         }
1000
1001         // open map size restriction file
1002         dprint("opensize "); dprint(map);
1003         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1004         if(fh >= 0)
1005         {
1006                 float mapmin, mapmax;
1007                 dprint(": ok, ");
1008                 mapmin = stof(fgets(fh));
1009                 mapmax = stof(fgets(fh));
1010                 fclose(fh);
1011                 if(player_count < mapmin)
1012                 {
1013                         dprint("not enough\n");
1014                         return FALSE;
1015                 }
1016                 if(player_count > mapmax)
1017                 {
1018                         dprint("too many\n");
1019                         return FALSE;
1020                 }
1021                 dprint("right size\n");
1022                 return TRUE;
1023         }
1024         dprint(": not found\n");
1025         return TRUE;
1026 }
1027
1028 string Map_Filename(float position)
1029 {
1030         return strcat("maps/", argv(position), ".bsp");
1031 }
1032
1033 string strwords(string s, float w)
1034 {
1035         float endpos;
1036         for(endpos = 0; w && endpos >= 0; --w)
1037                 endpos = strstrofs(s, " ", endpos + 1);
1038         if(endpos < 0)
1039                 return s;
1040         else
1041                 return substring(s, 0, endpos);
1042 }
1043
1044 float strhasword(string s, string w)
1045 {
1046         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1047 }
1048
1049 void Map_MarkAsRecent(string m)
1050 {
1051         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1052 }
1053
1054 float Map_IsRecent(string m)
1055 {
1056         return strhasword(autocvar_g_maplist_mostrecent, m);
1057 }
1058
1059 float Map_Check(float position, float pass)
1060 {
1061         string filename;
1062         string map_next;
1063         map_next = argv(position);
1064         if(pass <= 1)
1065         {
1066                 if(Map_IsRecent(map_next))
1067                         return 0;
1068         }
1069         filename = Map_Filename(position);
1070         if(MapInfo_CheckMap(map_next))
1071         {
1072                 if(pass == 2)
1073                         return 1;
1074                 if(MapHasRightSize(map_next))
1075                         return 1;
1076                 return 0;
1077         }
1078         else
1079                 dprint( "Couldn't select '", filename, "'..\n" );
1080
1081         return 0;
1082 }
1083
1084 void Map_Goto_SetStr(string nextmapname)
1085 {
1086         if(getmapname_stored != "")
1087                 strunzone(getmapname_stored);
1088         if(nextmapname == "")
1089                 getmapname_stored = "";
1090         else
1091                 getmapname_stored = strzone(nextmapname);
1092 }
1093
1094 void Map_Goto_SetFloat(float position)
1095 {
1096         cvar_set("g_maplist_index", ftos(position));
1097         Map_Goto_SetStr(argv(position));
1098 }
1099
1100 void GameResetCfg()
1101 {
1102         // settings persist, except...
1103         localcmd("\nsettemp_restore\n");
1104 }
1105
1106 void Map_Goto()
1107 {
1108         GameResetCfg();
1109         MapInfo_LoadMap(getmapname_stored);
1110 }
1111
1112 // return codes of map selectors:
1113 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1114 //   -2 = permanent failure
1115 float() MaplistMethod_Iterate = // usual method
1116 {
1117         float pass, i;
1118
1119         for(pass = 1; pass <= 2; ++pass)
1120         {
1121                 for(i = 1; i < Map_Count; ++i)
1122                 {
1123                         float mapindex;
1124                         mapindex = mod(i + Map_Current, Map_Count);
1125                         if(Map_Check(mapindex, pass))
1126                                 return mapindex;
1127                 }
1128         }
1129         return -1;
1130 }
1131
1132 float() MaplistMethod_Repeat = // fallback method
1133 {
1134         if(Map_Check(Map_Current, 2))
1135                 return Map_Current;
1136         return -2;
1137 }
1138
1139 float() MaplistMethod_Random = // random map selection
1140 {
1141         float i, imax;
1142
1143         imax = 42;
1144
1145         for(i = 0; i <= imax; ++i)
1146         {
1147                 float mapindex;
1148                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1149                 if(Map_Check(mapindex, 1))
1150                         return mapindex;
1151         }
1152         return -1;
1153 }
1154
1155 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1156 // the exponent sets a bias on the map selection:
1157 // the higher the exponent, the less likely "shortly repeated" same maps are
1158 {
1159         float i, j, imax, insertpos;
1160
1161         imax = 42;
1162
1163         for(i = 0; i <= imax; ++i)
1164         {
1165                 string newlist;
1166
1167                 // now reinsert this at another position
1168                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1169                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1170                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1171                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1172
1173                 // insert the current map there
1174                 newlist = "";
1175                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1176                         newlist = strcat(newlist, " ", argv(j));
1177                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1178                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1179                         newlist = strcat(newlist, " ", argv(j));
1180                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1181                 cvar_set("g_maplist", newlist);
1182                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1183
1184                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1185                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1186                 if(Map_Check(Map_Current, 1))
1187                         return Map_Current;
1188         }
1189         return -1;
1190 }
1191
1192 void Maplist_Init()
1193 {
1194         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1195         if(Map_Count == 0)
1196         {
1197                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1198                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1199                 if(autocvar_g_maplist_shuffle)
1200                         ShuffleMaplist();
1201                 localcmd("\nmenu_cmd sync\n");
1202                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1203         }
1204         if(Map_Count == 0)
1205                 error("empty maplist, cannot select a new map");
1206         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1207
1208         if(Map_Current_Name)
1209                 strunzone(Map_Current_Name);
1210         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1211         // this may or may not be correct, but who cares, in the worst case a map
1212         // isn't chosen in the first pass that should have been
1213 }
1214
1215 string GetNextMap()
1216 {
1217         float nextMap;
1218
1219         Maplist_Init();
1220         nextMap = -1;
1221
1222         if(nextMap == -1)
1223                 if(autocvar_g_maplist_shuffle > 0)
1224                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1225
1226         if(nextMap == -1)
1227                 if(autocvar_g_maplist_selectrandom)
1228                         nextMap = MaplistMethod_Random();
1229
1230         if(nextMap == -1)
1231                 nextMap = MaplistMethod_Iterate();
1232
1233         if(nextMap == -1)
1234                 nextMap = MaplistMethod_Repeat();
1235
1236         if(nextMap >= 0)
1237         {
1238                 Map_Goto_SetFloat(nextMap);
1239                 return getmapname_stored;
1240         }
1241
1242         return "";
1243 }
1244
1245 float DoNextMapOverride()
1246 {
1247         if(autocvar_g_campaign)
1248         {
1249                 CampaignPostIntermission();
1250                 alreadychangedlevel = TRUE;
1251                 return TRUE;
1252         }
1253         if(autocvar_quit_when_empty)
1254         {
1255                 if(player_count <= currentbots)
1256                 {
1257                         localcmd("quit\n");
1258                         alreadychangedlevel = TRUE;
1259                         return TRUE;
1260                 }
1261         }
1262         if(autocvar_quit_and_redirect != "")
1263         {
1264                 redirection_target = strzone(autocvar_quit_and_redirect);
1265                 alreadychangedlevel = TRUE;
1266                 return TRUE;
1267         }
1268         if (autocvar_samelevel) // if samelevel is set, stay on same level
1269         {
1270                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1271                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1272                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1273                 localcmd("restart\n");
1274                 //changelevel (mapname);
1275                 alreadychangedlevel = TRUE;
1276                 return TRUE;
1277         }
1278         if(autocvar_nextmap != "")
1279                 if(MapInfo_CheckMap(autocvar_nextmap))
1280                 {
1281                         Map_Goto_SetStr(autocvar_nextmap);
1282                         Map_Goto();
1283                         alreadychangedlevel = TRUE;
1284                         return TRUE;
1285                 }
1286         if(autocvar_lastlevel)
1287         {
1288                 GameResetCfg();
1289                 localcmd("set lastlevel 0\ntogglemenu\n");
1290                 alreadychangedlevel = TRUE;
1291                 return TRUE;
1292         }
1293         return FALSE;
1294 }
1295
1296 void GotoNextMap()
1297 {
1298         //string nextmap;
1299         //float n, nummaps;
1300         //string s;
1301         if (alreadychangedlevel)
1302                 return;
1303         alreadychangedlevel = TRUE;
1304
1305         {
1306                 string nextMap;
1307                 float allowReset;
1308
1309                 for(allowReset = 1; allowReset >= 0; --allowReset)
1310                 {
1311                         nextMap = GetNextMap();
1312                         if(nextMap != "")
1313                                 break;
1314
1315                         if(allowReset)
1316                         {
1317                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1318                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1319                                 if(autocvar_g_maplist_shuffle)
1320                                         ShuffleMaplist();
1321                                 localcmd("\nmenu_cmd sync\n");
1322                         }
1323                         else
1324                         {
1325                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1326                         }
1327                 }
1328                 Map_Goto();
1329         }
1330 }
1331
1332
1333 /*
1334 ============
1335 IntermissionThink
1336
1337 When the player presses attack or jump, change to the next level
1338 ============
1339 */
1340 .float autoscreenshot;
1341 void() MapVote_Start;
1342 void() MapVote_Think;
1343 float mapvote_initialized;
1344 void IntermissionThink()
1345 {
1346         FixIntermissionClient(self);
1347
1348         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1349                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1350         {
1351                 self.autoscreenshot = -1;
1352                 if(clienttype(self) == CLIENTTYPE_REAL)
1353                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1354                 return;
1355         }
1356
1357         if (time < intermission_exittime)
1358                 return;
1359
1360         if(!mapvote_initialized)
1361                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1362                         return;
1363
1364         MapVote_Start();
1365 }
1366
1367 /*
1368 ============
1369 FindIntermission
1370
1371 Returns the entity to view from
1372 ============
1373 */
1374 /*
1375 entity FindIntermission()
1376 {
1377         local   entity spot;
1378         local   float cyc;
1379
1380 // look for info_intermission first
1381         spot = find (world, classname, "info_intermission");
1382         if (spot)
1383         {       // pick a random one
1384                 cyc = random() * 4;
1385                 while (cyc > 1)
1386                 {
1387                         spot = find (spot, classname, "info_intermission");
1388                         if (!spot)
1389                                 spot = find (spot, classname, "info_intermission");
1390                         cyc = cyc - 1;
1391                 }
1392                 return spot;
1393         }
1394
1395 // then look for the start position
1396         spot = find (world, classname, "info_player_start");
1397         if (spot)
1398                 return spot;
1399
1400 // testinfo_player_start is only found in regioned levels
1401         spot = find (world, classname, "testplayerstart");
1402         if (spot)
1403                 return spot;
1404
1405 // then look for the start position
1406         spot = find (world, classname, "info_player_deathmatch");
1407         if (spot)
1408                 return spot;
1409
1410         //objerror ("FindIntermission: no spot");
1411         return world;
1412 }
1413 */
1414
1415 /*
1416 ===============================================================================
1417
1418 RULES
1419
1420 ===============================================================================
1421 */
1422
1423 void DumpStats(float final)
1424 {
1425         float file;
1426         string s;
1427         float to_console;
1428         float to_eventlog;
1429         float to_file;
1430         float i;
1431
1432         to_console = autocvar_sv_logscores_console;
1433         to_eventlog = autocvar_sv_eventlog;
1434         to_file = autocvar_sv_logscores_file;
1435
1436         if(!final)
1437         {
1438                 to_console = TRUE; // always print printstats replies
1439                 to_eventlog = FALSE; // but never print them to the event log
1440         }
1441
1442         if(to_eventlog)
1443                 if(autocvar_sv_eventlog_console)
1444                         to_console = FALSE; // otherwise we get the output twice
1445
1446         if(final)
1447                 s = ":scores:";
1448         else
1449                 s = ":status:";
1450         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1451
1452         if(to_console)
1453                 print(s, "\n");
1454         if(to_eventlog)
1455                 GameLogEcho(s);
1456         if(to_file)
1457         {
1458                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1459                 if(file == -1)
1460                         to_file = FALSE;
1461                 else
1462                         fputs(file, strcat(s, "\n"));
1463         }
1464
1465         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1466         if(to_console)
1467                 print(s, "\n");
1468         if(to_eventlog)
1469                 GameLogEcho(s);
1470         if(to_file)
1471                 fputs(file, strcat(s, "\n"));
1472
1473         FOR_EACH_CLIENT(other)
1474         {
1475                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1476                 {
1477                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1478                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1479                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1480                                 s = strcat(s, ftos(other.team), ":");
1481                         else
1482                                 s = strcat(s, "spectator:");
1483
1484                         if(to_console)
1485                                 print(s, other.netname, "\n");
1486                         if(to_eventlog)
1487                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1488                         if(to_file)
1489                                 fputs(file, strcat(s, other.netname, "\n"));
1490                 }
1491         }
1492
1493         if(teamplay)
1494         {
1495                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1496                 if(to_console)
1497                         print(s, "\n");
1498                 if(to_eventlog)
1499                         GameLogEcho(s);
1500                 if(to_file)
1501                         fputs(file, strcat(s, "\n"));
1502
1503                 for(i = 1; i < 16; ++i)
1504                 {
1505                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1506                         s = strcat(s, ":", ftos(i));
1507                         if(to_console)
1508                                 print(s, "\n");
1509                         if(to_eventlog)
1510                                 GameLogEcho(s);
1511                         if(to_file)
1512                                 fputs(file, strcat(s, "\n"));
1513                 }
1514         }
1515
1516         if(to_console)
1517                 print(":end\n");
1518         if(to_eventlog)
1519                 GameLogEcho(":end");
1520         if(to_file)
1521         {
1522                 fputs(file, ":end\n");
1523                 fclose(file);
1524         }
1525 }
1526
1527 void FixIntermissionClient(entity e)
1528 {
1529         string s;
1530         if(!e.autoscreenshot) // initial call
1531         {
1532                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1533                 e.health = -2342;
1534                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1535                 e.solid = SOLID_NOT;
1536                 e.movetype = MOVETYPE_NONE;
1537                 e.takedamage = DAMAGE_NO;
1538                 if(e.weaponentity)
1539                 {
1540                         e.weaponentity.effects = EF_NODRAW;
1541                         if (e.weaponentity.weaponentity)
1542                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1543                 }
1544                 if(clienttype(e) == CLIENTTYPE_REAL)
1545                 {
1546                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1547                         s = autocvar_sv_intermission_cdtrack;
1548                         if(s != "")
1549                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1550                         msg_entity = e;
1551                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1552                 }
1553         }
1554 }
1555
1556
1557 /*
1558 go to the next level for deathmatch
1559 only called if a time or frag limit has expired
1560 */
1561 void NextLevel()
1562 {
1563         gameover = TRUE;
1564
1565         intermission_running = 1;
1566
1567 // enforce a wait time before allowing changelevel
1568         if(player_count > 0)
1569                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1570         else
1571                 intermission_exittime = -1;
1572
1573         /*
1574         WriteByte (MSG_ALL, SVC_CDTRACK);
1575         WriteByte (MSG_ALL, 3);
1576         WriteByte (MSG_ALL, 3);
1577         // done in FixIntermission
1578         */
1579
1580         //pos = FindIntermission ();
1581
1582         VoteReset();
1583
1584         DumpStats(TRUE);
1585
1586         // send statistics
1587         entity e;
1588         PlayerStats_EndMatch(1);
1589         FOR_EACH_CLIENT(e)
1590                 PlayerStats_AddGlobalInfo(e);
1591         PlayerStats_Shutdown();
1592         WeaponStats_Shutdown();
1593
1594         if(autocvar_sv_eventlog)
1595                 GameLogEcho(":gameover");
1596
1597         GameLogClose();
1598
1599         FOR_EACH_PLAYER(other) {
1600                 FixIntermissionClient(other);
1601                 if(other.winning)
1602                         bprint(other.netname, " ^7wins.\n");
1603         }
1604
1605         if(autocvar_g_campaign)
1606                 CampaignPreIntermission();
1607
1608         localcmd("\nsv_hook_gameend\n");
1609 }
1610
1611 /*
1612 ============
1613 CheckRules_Player
1614
1615 Exit deathmatch games upon conditions
1616 ============
1617 */
1618 void CheckRules_Player()
1619 {
1620         if (gameover)   // someone else quit the game already
1621                 return;
1622
1623         if(self.deadflag == DEAD_NO)
1624                 self.play_time += frametime;
1625
1626         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1627         //   (div0: and that in CheckRules_World please)
1628 }
1629
1630 float checkrules_equality;
1631 float checkrules_suddendeathwarning;
1632 float checkrules_suddendeathend;
1633 float checkrules_overtimesadded; //how many overtimes have been already added
1634
1635 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1636 float WINNING_YES = 1; // winner found
1637 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1638 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1639
1640 float InitiateSuddenDeath()
1641 {
1642         // Check first whether normal overtimes could be added before initiating suddendeath mode
1643         // - for this timelimit_overtime needs to be >0 of course
1644         // - also check the winning condition calculated in the previous frame and only add normal overtime
1645         //   again, if at the point at which timelimit would be extended again, still no winner was found
1646         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1647         {
1648                 return 1; // need to call InitiateOvertime later
1649         }
1650         else
1651         {
1652                 if(!checkrules_suddendeathend)
1653                 {
1654                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1655                         if(g_race && !g_race_qualifying)
1656                                 race_StartCompleting();
1657                 }
1658                 return 0;
1659         }
1660 }
1661
1662 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1663 {
1664         ++checkrules_overtimesadded;
1665         //add one more overtime by simply extending the timelimit
1666         float tl;
1667         tl = autocvar_timelimit;
1668         tl += autocvar_timelimit_overtime;
1669         cvar_set("timelimit", ftos(tl));
1670         string minutesPlural;
1671         if (autocvar_timelimit_overtime == 1)
1672                 minutesPlural = " ^3minute";
1673         else
1674                 minutesPlural = " ^3minutes";
1675
1676         bcenterprint(
1677                 strcat(
1678                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1679                         ftos(autocvar_timelimit_overtime),
1680                         minutesPlural,
1681                         " to the game!"
1682                 )
1683         );
1684 }
1685
1686 float GetWinningCode(float fraglimitreached, float equality)
1687 {
1688         if(autocvar_g_campaign == 1)
1689                 if(fraglimitreached)
1690                         return WINNING_YES;
1691                 else
1692                         return WINNING_NO;
1693
1694         else
1695                 if(equality)
1696                         if(fraglimitreached)
1697                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1698                         else
1699                                 return WINNING_NEVER;
1700                 else
1701                         if(fraglimitreached)
1702                                 return WINNING_YES;
1703                         else
1704                                 return WINNING_NO;
1705 }
1706
1707 // set the .winning flag for exactly those players with a given field value
1708 void SetWinners(.float field, float value)
1709 {
1710         entity head;
1711         FOR_EACH_PLAYER(head)
1712                 head.winning = (head.field == value);
1713 }
1714
1715 // set the .winning flag for those players with a given field value
1716 void AddWinners(.float field, float value)
1717 {
1718         entity head;
1719         FOR_EACH_PLAYER(head)
1720                 if(head.field == value)
1721                         head.winning = 1;
1722 }
1723
1724 // clear the .winning flags
1725 void ClearWinners(void)
1726 {
1727         entity head;
1728         FOR_EACH_PLAYER(head)
1729                 head.winning = 0;
1730 }
1731
1732 // Onslaught winning condition:
1733 // game terminates if only one team has a working generator (or none)
1734 float WinningCondition_Onslaught()
1735 {
1736         entity head;
1737         float t1, t2, t3, t4;
1738
1739         WinningConditionHelper(); // set worldstatus
1740
1741         if(inWarmupStage)
1742                 return WINNING_NO;
1743
1744         // first check if the game has ended
1745         t1 = t2 = t3 = t4 = 0;
1746         head = find(world, classname, "onslaught_generator");
1747         while (head)
1748         {
1749                 if (head.health > 0)
1750                 {
1751                         if (head.team == COLOR_TEAM1) t1 = 1;
1752                         if (head.team == COLOR_TEAM2) t2 = 1;
1753                         if (head.team == COLOR_TEAM3) t3 = 1;
1754                         if (head.team == COLOR_TEAM4) t4 = 1;
1755                 }
1756                 head = find(head, classname, "onslaught_generator");
1757         }
1758         if (t1 + t2 + t3 + t4 < 2)
1759         {
1760                 // game over, only one team remains (or none)
1761                 ClearWinners();
1762                 if (t1) SetWinners(team, COLOR_TEAM1);
1763                 if (t2) SetWinners(team, COLOR_TEAM2);
1764                 if (t3) SetWinners(team, COLOR_TEAM3);
1765                 if (t4) SetWinners(team, COLOR_TEAM4);
1766                 dprint("Have a winner, ending game.\n");
1767                 return WINNING_YES;
1768         }
1769
1770         // Two or more teams remain
1771         return WINNING_NO;
1772 }
1773
1774 float LMS_NewPlayerLives()
1775 {
1776         float fl;
1777         fl = autocvar_fraglimit;
1778         if(fl == 0)
1779                 fl = 999;
1780
1781         // first player has left the game for dying too much? Nobody else can get in.
1782         if(lms_lowest_lives < 1)
1783                 return 0;
1784
1785         if(!autocvar_g_lms_join_anytime)
1786                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1787                         return 0;
1788
1789         return bound(1, lms_lowest_lives, fl);
1790 }
1791
1792 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1793 // they win. Otherwise the defending team wins once the timelimit passes.
1794 void assault_new_round();
1795 float WinningCondition_Assault()
1796 {
1797         float status;
1798
1799         WinningConditionHelper(); // set worldstatus
1800
1801         status = WINNING_NO;
1802         // as the timelimit has not yet passed just assume the defending team will win
1803         if(assault_attacker_team == COLOR_TEAM1)
1804         {
1805                 SetWinners(team, COLOR_TEAM2);
1806         }
1807         else
1808         {
1809                 SetWinners(team, COLOR_TEAM1);
1810         }
1811
1812         entity ent;
1813         ent = find(world, classname, "target_assault_roundend");
1814         if(ent)
1815         {
1816                 if(ent.winning) // round end has been triggered by attacking team
1817                 {
1818                         bprint("ASSAULT: round completed...\n");
1819                         SetWinners(team, assault_attacker_team);
1820
1821                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1822
1823                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1824                         {
1825                                 status = WINNING_YES;
1826                         }
1827                         else
1828                         {
1829                                 entity oldself;
1830                                 oldself = self;
1831                                 self = ent;
1832                                 assault_new_round();
1833                                 self = oldself;
1834                         }
1835                 }
1836         }
1837
1838         return status;
1839 }
1840
1841 // LMS winning condition: game terminates if and only if there's at most one
1842 // one player who's living lives. Top two scores being equal cancels the time
1843 // limit.
1844 float WinningCondition_LMS()
1845 {
1846         entity head, head2;
1847         float have_player;
1848         float have_players;
1849         float l;
1850
1851         have_player = FALSE;
1852         have_players = FALSE;
1853         l = LMS_NewPlayerLives();
1854
1855         head = find(world, classname, "player");
1856         if(head)
1857                 have_player = TRUE;
1858         head2 = find(head, classname, "player");
1859         if(head2)
1860                 have_players = TRUE;
1861
1862         if(have_player)
1863         {
1864                 // we have at least one player
1865                 if(have_players)
1866                 {
1867                         // two or more active players - continue with the game
1868                 }
1869                 else
1870                 {
1871                         // exactly one player?
1872
1873                         ClearWinners();
1874                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1875
1876                         if(l)
1877                         {
1878                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1879                                 return WINNING_NO;
1880                         }
1881                         else
1882                         {
1883                                 // a winner!
1884                                 // and assign him his first place
1885                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1886                                 return WINNING_YES;
1887                         }
1888                 }
1889         }
1890         else
1891         {
1892                 // nobody is playing at all...
1893                 if(l)
1894                 {
1895                         // wait for players...
1896                 }
1897                 else
1898                 {
1899                         // SNAFU (maybe a draw game?)
1900                         ClearWinners();
1901                         dprint("No players, ending game.\n");
1902                         return WINNING_YES;
1903                 }
1904         }
1905
1906         // When we get here, we have at least two players who are actually LIVING,
1907         // now check if the top two players have equal score.
1908         WinningConditionHelper();
1909
1910         ClearWinners();
1911         if(WinningConditionHelper_winner)
1912                 WinningConditionHelper_winner.winning = TRUE;
1913         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1914                 return WINNING_NEVER;
1915
1916         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1917         return WINNING_NO;
1918 }
1919
1920 void ShuffleMaplist()
1921 {
1922         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1923 }
1924
1925 float leaderfrags;
1926 float WinningCondition_Scores(float limit, float leadlimit)
1927 {
1928         float limitreached;
1929
1930         // TODO make everything use THIS winning condition (except LMS)
1931         WinningConditionHelper();
1932
1933         if(teamplay)
1934         {
1935                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1936                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1937                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1938                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1939         }
1940
1941         ClearWinners();
1942         if(WinningConditionHelper_winner)
1943                 WinningConditionHelper_winner.winning = 1;
1944         if(WinningConditionHelper_winnerteam >= 0)
1945                 SetWinners(team, WinningConditionHelper_winnerteam);
1946
1947         if(WinningConditionHelper_lowerisbetter)
1948         {
1949                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1950                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1951                 limit = -limit;
1952         }
1953
1954         if(WinningConditionHelper_zeroisworst)
1955                 leadlimit = 0; // not supported in this mode
1956
1957         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1958         // these modes always score in increments of 1, thus this makes sense
1959         {
1960                 if(leaderfrags != WinningConditionHelper_topscore)
1961                 {
1962                         leaderfrags = WinningConditionHelper_topscore;
1963
1964                         if (limit)
1965                         if (leaderfrags == limit - 1)
1966                                 Announce("1fragleft");
1967                         else if (leaderfrags == limit - 2)
1968                                 Announce("2fragsleft");
1969                         else if (leaderfrags == limit - 3)
1970                                 Announce("3fragsleft");
1971                 }
1972         }
1973
1974         limitreached = FALSE;
1975         if(limit)
1976                 if(WinningConditionHelper_topscore >= limit)
1977                         limitreached = TRUE;
1978         if(leadlimit)
1979         {
1980                 float leadlimitreached;
1981                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1982                 if(autocvar_leadlimit_and_fraglimit)
1983                         limitreached = (limitreached && leadlimitreached);
1984                 else
1985                         limitreached = (limitreached || leadlimitreached);
1986         }
1987
1988         return GetWinningCode(
1989                 WinningConditionHelper_topscore && limitreached,
1990                 WinningConditionHelper_equality
1991         );
1992 }
1993
1994 float WinningCondition_Race(float fraglimit)
1995 {
1996         float wc;
1997         entity p;
1998         float n, c;
1999
2000         n = 0;
2001         c = 0;
2002         FOR_EACH_PLAYER(p)
2003         {
2004                 ++n;
2005                 if(p.race_completed)
2006                         ++c;
2007         }
2008         if(n && (n == c))
2009                 return WINNING_YES;
2010         wc = WinningCondition_Scores(fraglimit, 0);
2011
2012         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2013         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2014         // do NOT support equality when the laps are all raced!
2015                 return WINNING_STARTSUDDENDEATHOVERTIME;
2016         else
2017                 return WINNING_NEVER;
2018         return wc;
2019 }
2020
2021 void ReadyRestart();
2022 float WinningCondition_QualifyingThenRace(float limit)
2023 {
2024         float wc;
2025         wc = WinningCondition_Scores(limit, 0);
2026
2027         // NEVER initiate overtime
2028         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2029         {
2030                 return WINNING_YES;
2031         }
2032
2033         return wc;
2034 }
2035
2036 float WinningCondition_RanOutOfSpawns()
2037 {
2038         entity head;
2039
2040         if(have_team_spawns <= 0)
2041                 return WINNING_NO;
2042
2043         if(!some_spawn_has_been_used)
2044                 return WINNING_NO;
2045
2046         team1_score = team2_score = team3_score = team4_score = 0;
2047
2048         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2049         {
2050                 if(head.team == COLOR_TEAM1)
2051                         team1_score = 1;
2052                 else if(head.team == COLOR_TEAM2)
2053                         team2_score = 1;
2054                 else if(head.team == COLOR_TEAM3)
2055                         team3_score = 1;
2056                 else if(head.team == COLOR_TEAM4)
2057                         team4_score = 1;
2058         }
2059
2060         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2061         {
2062                 if(head.team == COLOR_TEAM1)
2063                         team1_score = 1;
2064                 else if(head.team == COLOR_TEAM2)
2065                         team2_score = 1;
2066                 else if(head.team == COLOR_TEAM3)
2067                         team3_score = 1;
2068                 else if(head.team == COLOR_TEAM4)
2069                         team4_score = 1;
2070         }
2071
2072         ClearWinners();
2073         if(team1_score + team2_score + team3_score + team4_score == 0)
2074         {
2075                 checkrules_equality = TRUE;
2076                 return WINNING_YES;
2077         }
2078         else if(team1_score + team2_score + team3_score + team4_score == 1)
2079         {
2080                 float t, i;
2081                 if(team1_score) t = COLOR_TEAM1;
2082                 if(team2_score) t = COLOR_TEAM2;
2083                 if(team3_score) t = COLOR_TEAM3;
2084                 if(team4_score) t = COLOR_TEAM4;
2085                 CheckAllowedTeams(world);
2086                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2087                 {
2088                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2089                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2090                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2091                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2092                 }
2093
2094                 AddWinners(team, t);
2095                 return WINNING_YES;
2096         }
2097         else
2098                 return WINNING_NO;
2099 }
2100
2101 /*
2102 ============
2103 CheckRules_World
2104
2105 Exit deathmatch games upon conditions
2106 ============
2107 */
2108 void CheckRules_World()
2109 {
2110         float timelimit;
2111         float fraglimit;
2112         float leadlimit;
2113
2114         VoteThink();
2115         MapVote_Think();
2116
2117         SetDefaultAlpha();
2118
2119         /*
2120         MapVote_Think should now do that part
2121         if (intermission_running)
2122                 if (time >= intermission_exittime + 60)
2123                 {
2124                         if(!DoNextMapOverride())
2125                                 GotoNextMap();
2126                         return;
2127                 }
2128         */
2129
2130         if (gameover)   // someone else quit the game already
2131         {
2132                 if(player_count == 0) // Nobody there? Then let's go to the next map
2133                         MapVote_Start();
2134                         // this will actually check the player count in the next frame
2135                         // again, but this shouldn't hurt
2136                 return;
2137         }
2138
2139         timelimit = autocvar_timelimit * 60;
2140         fraglimit = autocvar_fraglimit;
2141         leadlimit = autocvar_leadlimit;
2142
2143         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2144         {
2145                 if(timelimit > 0)
2146                         timelimit = 0; // timelimit is not made for warmup
2147                 if(fraglimit > 0)
2148                         fraglimit = 0; // no fraglimit for now
2149                 leadlimit = 0; // no leadlimit for now
2150         }
2151
2152         if(g_onslaught)
2153                 timelimit = 0; // ONS has its own overtime rule
2154
2155         if(timelimit > 0)
2156         {
2157                 timelimit += game_starttime;
2158         }
2159         else if (timelimit < 0)
2160         {
2161                 // endmatch
2162                 NextLevel();
2163                 return;
2164         }
2165
2166         float wantovertime;
2167         wantovertime = 0;
2168
2169         if(checkrules_suddendeathend)
2170         {
2171                 if(!checkrules_suddendeathwarning)
2172                 {
2173                         checkrules_suddendeathwarning = TRUE;
2174                         if(g_race && !g_race_qualifying)
2175                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2176                         else
2177                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2178                 }
2179         }
2180         else
2181         {
2182                 if (timelimit && time >= timelimit)
2183                 {
2184                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2185                         {
2186                                 float totalplayers;
2187                                 float playerswithlaps;
2188                                 float readyplayers;
2189                                 entity head;
2190                                 totalplayers = playerswithlaps = readyplayers = 0;
2191                                 FOR_EACH_PLAYER(head)
2192                                 {
2193                                         ++totalplayers;
2194                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2195                                                 ++playerswithlaps;
2196                                         if(head.ready)
2197                                                 ++readyplayers;
2198                                 }
2199
2200                                 // at least 2 of the players have completed a lap: start the RACE
2201                                 // otherwise, the players should end the qualifying on their own
2202                                 if(readyplayers || playerswithlaps >= 2)
2203                                 {
2204                                         checkrules_suddendeathend = 0;
2205                                         ReadyRestart(); // go to race
2206                                         return;
2207                                 }
2208                                 else
2209                                         wantovertime |= InitiateSuddenDeath();
2210                         }
2211                         else
2212                                 wantovertime |= InitiateSuddenDeath();
2213                 }
2214         }
2215
2216         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2217         {
2218                 NextLevel();
2219                 return;
2220         }
2221
2222         float checkrules_status;
2223         checkrules_status = WinningCondition_RanOutOfSpawns();
2224         if(checkrules_status == WINNING_YES)
2225         {
2226                 bprint("Hey! Someone ran out of spawns!\n");
2227         }
2228         else if(g_race && !g_race_qualifying && timelimit >= 0)
2229         {
2230                 checkrules_status = WinningCondition_Race(fraglimit);
2231                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2232         }
2233         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2234         {
2235                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2236                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2237         }
2238         else if(g_assault)
2239         {
2240                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2241         }
2242         else if(g_lms)
2243         {
2244                 checkrules_status = WinningCondition_LMS();
2245         }
2246         else if (g_onslaught)
2247         {
2248                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2249         }
2250         else
2251         {
2252                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2253                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2254         }
2255
2256         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2257         {
2258                 checkrules_status = WINNING_NEVER;
2259                 checkrules_overtimesadded = -1;
2260                 wantovertime |= InitiateSuddenDeath();
2261         }
2262
2263         if(checkrules_status == WINNING_NEVER)
2264                 // equality cases! Nobody wins if the overtime ends in a draw.
2265                 ClearWinners();
2266
2267         if(wantovertime)
2268         {
2269                 if(checkrules_status == WINNING_NEVER)
2270                         InitiateOvertime();
2271                 else
2272                         checkrules_status = WINNING_YES;
2273         }
2274
2275         if(checkrules_suddendeathend)
2276                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2277                         checkrules_status = WINNING_YES;
2278
2279         if(checkrules_status == WINNING_YES)
2280         {
2281                 //print("WINNING\n");
2282                 NextLevel();
2283         }
2284 }
2285
2286 float mapvote_nextthink;
2287 float mapvote_initialized;
2288 float mapvote_keeptwotime;
2289 float mapvote_timeout;
2290 string mapvote_message;
2291 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2292 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2293 float mapvote_screenshot_dirs_count;
2294
2295 float mapvote_count;
2296 float mapvote_count_real;
2297 string mapvote_maps[MAPVOTE_COUNT];
2298 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2299 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2300 float mapvote_maps_suggested[MAPVOTE_COUNT];
2301 string mapvote_suggestions[MAPVOTE_COUNT];
2302 float mapvote_suggestion_ptr;
2303 float mapvote_voters;
2304 float mapvote_votes[MAPVOTE_COUNT];
2305 float mapvote_run;
2306 float mapvote_detail;
2307 float mapvote_abstain;
2308 .float mapvote;
2309
2310 void MapVote_ClearAllVotes()
2311 {
2312         FOR_EACH_CLIENT(other)
2313                 other.mapvote = 0;
2314 }
2315
2316 string MapVote_Suggest(string m)
2317 {
2318         float i;
2319         if(m == "")
2320                 return "That's not how to use this command.";
2321         if(!autocvar_g_maplist_votable_suggestions)
2322                 return "Suggestions are not accepted on this server.";
2323         if(mapvote_initialized)
2324                 return "Can't suggest - voting is already in progress!";
2325         m = MapInfo_FixName(m);
2326         if(!m)
2327                 return "The map you suggested is not available on this server.";
2328         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2329                 if(Map_IsRecent(m))
2330                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2331
2332         if(!MapInfo_CheckMap(m))
2333                 return "The map you suggested does not support the current game mode.";
2334         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2335                 if(mapvote_suggestions[i] == m)
2336                         return "This map was already suggested.";
2337         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2338         {
2339                 i = floor(random() * mapvote_suggestion_ptr);
2340         }
2341         else
2342         {
2343                 i = mapvote_suggestion_ptr;
2344                 mapvote_suggestion_ptr += 1;
2345         }
2346         if(mapvote_suggestions[i] != "")
2347                 strunzone(mapvote_suggestions[i]);
2348         mapvote_suggestions[i] = strzone(m);
2349         if(autocvar_sv_eventlog)
2350                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2351         return strcat("Suggestion of ", m, " accepted.");
2352 }
2353
2354 void MapVote_AddVotable(string nextMap, float isSuggestion)
2355 {
2356         float j, i, o;
2357         string pakfile, mapfile;
2358
2359         if(nextMap == "")
2360                 return;
2361         for(j = 0; j < mapvote_count; ++j)
2362                 if(mapvote_maps[j] == nextMap)
2363                         return;
2364         // suggestions might be no longer valid/allowed after gametype switch!
2365         if(isSuggestion)
2366                 if(!MapInfo_CheckMap(nextMap))
2367                         return;
2368         mapvote_maps[mapvote_count] = strzone(nextMap);
2369         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2370
2371         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2372         {
2373                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2374                 pakfile = whichpack(strcat(mapfile, ".tga"));
2375                 if(pakfile == "")
2376                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2377                 if(pakfile == "")
2378                         pakfile = whichpack(strcat(mapfile, ".png"));
2379                 if(pakfile != "")
2380                         break;
2381         }
2382         if(i >= mapvote_screenshot_dirs_count)
2383                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2384         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2385                 pakfile = substring(pakfile, o, -1);
2386
2387         mapvote_maps_screenshot_dir[mapvote_count] = i;
2388         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2389
2390         mapvote_count += 1;
2391 }
2392
2393 void MapVote_Spawn();
2394 void MapVote_Init()
2395 {
2396         float i;
2397         float nmax, smax;
2398
2399         MapVote_ClearAllVotes();
2400
2401         mapvote_count = 0;
2402         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2403         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2404
2405         if(mapvote_abstain)
2406                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2407         else
2408                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2409         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2410
2411         // we need this for AddVotable, as that cycles through the screenshot dirs
2412         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2413         if(mapvote_screenshot_dirs_count == 0)
2414                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2415         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2416         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2417                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2418
2419         if(mapvote_suggestion_ptr)
2420                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2421                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2422
2423         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2424                 MapVote_AddVotable(GetNextMap(), FALSE);
2425
2426         if(mapvote_count == 0)
2427         {
2428                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2429                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2430                 if(autocvar_g_maplist_shuffle)
2431                         ShuffleMaplist();
2432                 localcmd("\nmenu_cmd sync\n");
2433                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2434                         MapVote_AddVotable(GetNextMap(), FALSE);
2435         }
2436
2437         mapvote_count_real = mapvote_count;
2438         if(mapvote_abstain)
2439                 MapVote_AddVotable("don't care", 0);
2440
2441         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2442
2443         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2444         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2445         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2446                 mapvote_keeptwotime = 0;
2447         mapvote_message = "Choose a map and press its key!";
2448
2449         MapVote_Spawn();
2450 }
2451
2452 void MapVote_SendPicture(float id)
2453 {
2454         msg_entity = self;
2455         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2456         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2457         WriteByte(MSG_ONE, id);
2458         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2459 }
2460
2461 float GameCommand_MapVote(string cmd)
2462 {
2463         if(!intermission_running)
2464                 return FALSE;
2465
2466         if(cmd == "mv_getpic")
2467         {
2468                 MapVote_SendPicture(stof(argv(1)));
2469                 return TRUE;
2470         }
2471
2472         return FALSE;
2473 }
2474
2475 float MapVote_GetMapMask()
2476 {
2477         float mask, i, power;
2478         mask = 0;
2479         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2480                 if(mapvote_maps[i] != "")
2481                         mask |= power;
2482         return mask;
2483 }
2484
2485 entity mapvote_ent;
2486 float MapVote_SendEntity(entity to, float sf)
2487 {
2488         float i;
2489
2490         if(sf & 1)
2491                 sf &~= 2; // if we send 1, we don't need to also send 2
2492
2493         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2494         WriteByte(MSG_ENTITY, sf);
2495
2496         if(sf & 1)
2497         {
2498                 // flag 1 == initialization
2499                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2500                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2501                 WriteString(MSG_ENTITY, "");
2502                 WriteByte(MSG_ENTITY, mapvote_count);
2503                 WriteByte(MSG_ENTITY, mapvote_abstain);
2504                 WriteByte(MSG_ENTITY, mapvote_detail);
2505                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2506                 if(mapvote_count <= 8)
2507                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2508                 else
2509                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2510                 for(i = 0; i < mapvote_count; ++i)
2511                         if(mapvote_maps[i] != "")
2512                         {
2513                                 if(mapvote_abstain && i == mapvote_count - 1)
2514                                 {
2515                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2516                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2517                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2518                                 }
2519                                 else
2520                                 {
2521                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2522                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2523                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2524                                 }
2525                         }
2526         }
2527
2528         if(sf & 2)
2529         {
2530                 // flag 2 == update of mask
2531                 if(mapvote_count <= 8)
2532                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2533                 else
2534                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2535         }
2536
2537         if(sf & 4)
2538         {
2539                 if(mapvote_detail)
2540                         for(i = 0; i < mapvote_count; ++i)
2541                                 if(mapvote_maps[i] != "")
2542                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2543
2544                 WriteByte(MSG_ENTITY, to.mapvote);
2545         }
2546
2547         return TRUE;
2548 }
2549
2550 void MapVote_Spawn()
2551 {
2552         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2553 }
2554
2555 void MapVote_TouchMask()
2556 {
2557         mapvote_ent.SendFlags |= 2;
2558 }
2559
2560 void MapVote_TouchVotes(entity voter)
2561 {
2562         mapvote_ent.SendFlags |= 4;
2563 }
2564
2565 float MapVote_Finished(float mappos)
2566 {
2567         string result;
2568         float i;
2569         float didntvote;
2570
2571         if(autocvar_sv_eventlog)
2572         {
2573                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2574                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2575                 didntvote = mapvote_voters;
2576                 for(i = 0; i < mapvote_count; ++i)
2577                         if(mapvote_maps[i] != "")
2578                         {
2579                                 didntvote -= mapvote_votes[i];
2580                                 if(i != mappos)
2581                                 {
2582                                         result = strcat(result, ":", mapvote_maps[i]);
2583                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2584                                 }
2585                         }
2586                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2587
2588                 GameLogEcho(result);
2589                 if(mapvote_maps_suggested[mappos])
2590                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2591         }
2592
2593         FOR_EACH_REALCLIENT(other)
2594                 FixClientCvars(other);
2595
2596         Map_Goto_SetStr(mapvote_maps[mappos]);
2597         Map_Goto();
2598         alreadychangedlevel = TRUE;
2599         return TRUE;
2600 }
2601 void MapVote_CheckRules_1()
2602 {
2603         float i;
2604
2605         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2606         {
2607                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2608                 mapvote_votes[i] = 0;
2609         }
2610
2611         mapvote_voters = 0;
2612         FOR_EACH_REALCLIENT(other)
2613         {
2614                 ++mapvote_voters;
2615                 if(other.mapvote)
2616                 {
2617                         i = other.mapvote - 1;
2618                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2619                         mapvote_votes[i] = mapvote_votes[i] + 1;
2620                 }
2621         }
2622 }
2623
2624 float MapVote_CheckRules_2()
2625 {
2626         float i;
2627         float firstPlace, secondPlace;
2628         float firstPlaceVotes, secondPlaceVotes;
2629         float mapvote_voters_real;
2630         string result;
2631
2632         if(mapvote_count_real == 1)
2633                 return MapVote_Finished(0);
2634
2635         mapvote_voters_real = mapvote_voters;
2636         if(mapvote_abstain)
2637                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2638
2639         RandomSelection_Init();
2640         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2641                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2642         firstPlace = RandomSelection_chosen_float;
2643         firstPlaceVotes = RandomSelection_best_priority;
2644         //dprint("First place: ", ftos(firstPlace), "\n");
2645         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2646
2647         RandomSelection_Init();
2648         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2649                 if(i != firstPlace)
2650                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2651         secondPlace = RandomSelection_chosen_float;
2652         secondPlaceVotes = RandomSelection_best_priority;
2653         //dprint("Second place: ", ftos(secondPlace), "\n");
2654         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2655
2656         if(firstPlace == -1)
2657                 error("No first place in map vote... WTF?");
2658
2659         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2660                 return MapVote_Finished(firstPlace);
2661
2662         if(mapvote_keeptwotime)
2663                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2664                 {
2665                         float didntvote;
2666                         MapVote_TouchMask();
2667                         mapvote_message = "Now decide between the TOP TWO!";
2668                         mapvote_keeptwotime = 0;
2669                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2670                         result = strcat(result, ":", ftos(firstPlaceVotes));
2671                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2672                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2673                         didntvote = mapvote_voters;
2674                         for(i = 0; i < mapvote_count; ++i)
2675                                 if(mapvote_maps[i] != "")
2676                                 {
2677                                         didntvote -= mapvote_votes[i];
2678                                         if(i != firstPlace)
2679                                                 if(i != secondPlace)
2680                                                 {
2681                                                         result = strcat(result, ":", mapvote_maps[i]);
2682                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2683                                                         if(i < mapvote_count_real)
2684                                                         {
2685                                                                 strunzone(mapvote_maps[i]);
2686                                                                 mapvote_maps[i] = "";
2687                                                                 strunzone(mapvote_maps_pakfile[i]);
2688                                                                 mapvote_maps_pakfile[i] = "";
2689                                                         }
2690                                                 }
2691                                 }
2692                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2693                         if(autocvar_sv_eventlog)
2694                                 GameLogEcho(result);
2695                 }
2696
2697         return FALSE;
2698 }
2699 void MapVote_Tick()
2700 {
2701         float keeptwo;
2702         float totalvotes;
2703
2704         keeptwo = mapvote_keeptwotime;
2705         MapVote_CheckRules_1(); // count
2706         if(MapVote_CheckRules_2()) // decide
2707                 return;
2708
2709         totalvotes = 0;
2710         FOR_EACH_REALCLIENT(other)
2711         {
2712                 // hide scoreboard again
2713                 if(other.health != 2342)
2714                 {
2715                         other.health = 2342;
2716                         other.impulse = 0;
2717                         if(clienttype(other) == CLIENTTYPE_REAL)
2718                         {
2719                                 msg_entity = other;
2720                                 WriteByte(MSG_ONE, SVC_FINALE);
2721                                 WriteString(MSG_ONE, "");
2722                         }
2723                 }
2724
2725                 // clear possibly invalid votes
2726                 if(mapvote_maps[other.mapvote - 1] == "")
2727                         other.mapvote = 0;
2728                 // use impulses as new vote
2729                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2730                         if(mapvote_maps[other.impulse - 1] != "")
2731                         {
2732                                 other.mapvote = other.impulse;
2733                                 MapVote_TouchVotes(other);
2734                         }
2735                 other.impulse = 0;
2736
2737                 if(other.mapvote)
2738                         ++totalvotes;
2739         }
2740
2741         MapVote_CheckRules_1(); // just count
2742 }
2743 void MapVote_Start()
2744 {
2745         if(mapvote_run)
2746                 return;
2747
2748         // wait for stats to be sent first
2749         if(!playerstats_waitforme)
2750                 return;
2751
2752         MapInfo_Enumerate();
2753         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2754                 mapvote_run = TRUE;
2755 }
2756 void MapVote_Think()
2757 {
2758         if(!mapvote_run)
2759                 return;
2760
2761         if(alreadychangedlevel)
2762                 return;
2763
2764         if(time < mapvote_nextthink)
2765                 return;
2766         //dprint("tick\n");
2767
2768         mapvote_nextthink = time + 0.5;
2769
2770         if(!mapvote_initialized)
2771         {
2772                 if(autocvar_rescan_pending == 1)
2773                 {
2774                         cvar_set("rescan_pending", "2");
2775                         localcmd("fs_rescan\nrescan_pending 3\n");
2776                         return;
2777                 }
2778                 else if(autocvar_rescan_pending == 2)
2779                 {
2780                         return;
2781                 }
2782                 else if(autocvar_rescan_pending == 3)
2783                 {
2784                         // now build missing mapinfo files
2785                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2786                                 return;
2787
2788                         // we're done, start the timer
2789                         cvar_set("rescan_pending", "0");
2790                 }
2791
2792                 mapvote_initialized = TRUE;
2793                 if(DoNextMapOverride())
2794                         return;
2795                 if(!autocvar_g_maplist_votable || player_count <= 0)
2796                 {
2797                         GotoNextMap();
2798                         return;
2799                 }
2800                 MapVote_Init();
2801         }
2802
2803         MapVote_Tick();
2804 }
2805
2806 string GotoMap(string m)
2807 {
2808         if(!MapInfo_CheckMap(m))
2809                 return "The map you chose is not available on this server.";
2810         cvar_set("nextmap", m);
2811         cvar_set("timelimit", "-1");
2812         if(mapvote_initialized || alreadychangedlevel)
2813         {
2814                 if(DoNextMapOverride())
2815                         return "Map switch initiated.";
2816                 else
2817                         return "Hm... no. For some reason I like THIS map more.";
2818         }
2819         else
2820                 return "Map switch will happen after scoreboard.";
2821 }
2822
2823
2824 void EndFrame()
2825 {
2826         float altime;
2827         FOR_EACH_REALCLIENT(self)
2828         {
2829                 if(self.classname == "spectator")
2830                 {
2831                         if(self.enemy.typehitsound)
2832                                 self.typehit_time = time;
2833                         else if(self.enemy.hitsound)
2834                                 self.hit_time = time;
2835                 }
2836                 else
2837                 {
2838                         if(self.typehitsound)
2839                                 self.typehit_time = time;
2840                         else if(self.hitsound)
2841                                 self.hit_time = time;
2842                 }
2843         }
2844         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2845         // add 1 frametime because after this, engine SV_Physics
2846         // increases time by a frametime and then networks the frame
2847         // add another frametime because client shows everything with
2848         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2849         // needed!
2850         FOR_EACH_CLIENT(self)
2851         {
2852                 self.hitsound = FALSE;
2853                 self.typehitsound = FALSE;
2854                 antilag_record(self, altime);
2855         }
2856 }
2857
2858
2859 /*
2860  * RedirectionThink:
2861  * returns TRUE if redirecting
2862  */
2863 float redirection_timeout;
2864 float redirection_nextthink;
2865 float RedirectionThink()
2866 {
2867         float clients_found;
2868
2869         if(redirection_target == "")
2870                 return FALSE;
2871
2872         if(!redirection_timeout)
2873         {
2874                 cvar_set("sv_public", "-2");
2875                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2876                 if(redirection_target == "self")
2877                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2878                 else
2879                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2880         }
2881
2882         if(time < redirection_nextthink)
2883                 return TRUE;
2884
2885         redirection_nextthink = time + 1;
2886
2887         clients_found = 0;
2888         FOR_EACH_REALCLIENT(self)
2889         {
2890                 print("Redirecting: sending connect command to ", self.netname, "\n");
2891                 if(redirection_target == "self")
2892                         stuffcmd(self, "\ndisconnect; reconnect\n");
2893                 else
2894                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2895                 ++clients_found;
2896         }
2897
2898         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2899
2900         if(time > redirection_timeout || clients_found == 0)
2901                 localcmd("\nwait; wait; wait; quit\n");
2902
2903         return TRUE;
2904 }
2905
2906 void TargetMusic_RestoreGame();
2907 void RestoreGame()
2908 {
2909         // Loaded from a save game
2910         // some things then break, so let's work around them...
2911
2912         // Progs DB (capture records)
2913         ServerProgsDB = db_load("server.db");
2914
2915         // Mapinfo
2916         MapInfo_Shutdown();
2917         MapInfo_Enumerate();
2918         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2919         WeaponStats_Init();
2920
2921         TargetMusic_RestoreGame();
2922 }
2923
2924 void SV_Shutdown()
2925 {
2926         entity e;
2927
2928         if(gameover > 1) // shutting down already?
2929                 return;
2930
2931         gameover = 2; // 2 = server shutting down
2932
2933         if(world_initialized > 0)
2934         {
2935                 world_initialized = 0;
2936                 print("Saving persistent data...\n");
2937                 Ban_SaveBans();
2938
2939                 PlayerStats_EndMatch(0);
2940                 FOR_EACH_CLIENT(e)
2941                         PlayerStats_AddGlobalInfo(e);
2942                 PlayerStats_Shutdown();
2943
2944                 if(!cheatcount_total)
2945                 {
2946                         if(autocvar_sv_db_saveasdump)
2947                                 db_dump(ServerProgsDB, "server.db");
2948                         else
2949                                 db_save(ServerProgsDB, "server.db");
2950                 }
2951                 if(autocvar_developer)
2952                 {
2953                         if(autocvar_sv_db_saveasdump)
2954                                 db_dump(TemporaryDB, "server-temp.db");
2955                         else
2956                                 db_save(TemporaryDB, "server-temp.db");
2957                 }
2958                 CheatShutdown(); // must be after cheatcount check
2959                 db_close(ServerProgsDB);
2960                 db_close(TemporaryDB);
2961                 print("done!\n");
2962                 // tell the bot system the game is ending now
2963                 bot_endgame();
2964
2965                 WeaponStats_Shutdown();
2966                 MapInfo_Shutdown();
2967         }
2968         else if(world_initialized == 0)
2969         {
2970                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2971         }
2972 }