qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312                 BADCVAR("rescan_pending");
 313
 314                 // these can contain player IDs, so better hide
 315                 BADPREFIX("g_forced_team_");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_allow_fullbright");
 387                 BADCVAR("sv_checkforpacketsduringsleep");
 388                 BADCVAR("sv_timeout");
 389                 BADCVAR("welcome_message_time");
 390                 BADPREFIX("crypto_");
 391                 BADPREFIX("g_chat_");
 392                 BADPREFIX("g_ctf_captimerecord_");
 393                 BADPREFIX("g_maplist_votable_");
 394                 BADPREFIX("net_");
 395                 BADPREFIX("prvm_");
 396                 BADPREFIX("skill_");
 397                 BADPREFIX("sv_cullentities_");
 398                 BADPREFIX("sv_fraginfo_");
 399                 BADPREFIX("sv_maxidle_");
 400                 BADPREFIX("sv_vote_");
 401                 BADPREFIX("timelimit_");
 402                 BADCVAR("gameversion");
 403                 BADPREFIX("gameversion_");
 404                 BADCVAR("sv_namechangetimer");
 405
 406                 // allowed changes to server admins (please sync this to server.cfg)
 407                 // vi commands:
 408                 //   :/"impure"/,$d
 409                 //   :g!,^\/\/[^ /],d
 410                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 411                 //   :%!sort
 412                 // yes, this does contain some redundant stuff, don't really care
 413                 BADCVAR("bot_config_file");
 414                 BADCVAR("bot_number");
 415                 BADCVAR("bot_prefix");
 416                 BADCVAR("bot_suffix");
 417                 BADCVAR("capturelimit_override");
 418                 BADCVAR("fraglimit_override");
 419                 BADCVAR("gametype");
 420                 BADCVAR("g_antilag");
 421                 BADCVAR("g_balance_teams");
 422                 BADCVAR("g_balance_teams_force");
 423                 BADCVAR("g_ban_sync_trusted_servers");
 424                 BADCVAR("g_ban_sync_uri");
 425                 BADCVAR("g_ctf_capture_limit");
 426                 BADCVAR("g_ctf_ignore_frags");
 427                 BADCVAR("g_ctf_win_mode");
 428                 BADCVAR("g_domination_point_limit");
 429                 BADCVAR("g_friendlyfire");
 430                 BADCVAR("g_fullbrightitems");
 431                 BADCVAR("g_fullbrightplayers");
 432                 BADCVAR("g_keyhunt_point_limit");
 433                 BADCVAR("g_keyhunt_teams_override");
 434                 BADCVAR("g_lms_lives_override");
 435                 BADCVAR("g_maplist");
 436                 BADCVAR("g_maplist_check_waypoints");
 437                 BADCVAR("g_maplist_mostrecent_count");
 438                 BADCVAR("g_maplist_shuffle");
 439                 BADCVAR("g_maplist_votable");
 440                 BADCVAR("g_maplist_votable_abstain");
 441                 BADCVAR("g_maplist_votable_nodetail");
 442                 BADCVAR("g_maplist_votable_suggestions");
 443                 BADCVAR("g_maxplayers");
 444                 BADCVAR("g_minstagib");
 445                 BADCVAR("g_mirrordamage");
 446                 BADCVAR("g_nexball_goallimit");
 447                 BADCVAR("g_powerups");
 448                 BADCVAR("g_runematch_point_limit");
 449                 BADCVAR("g_start_delay");
 450                 BADCVAR("g_warmup");
 451                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 452                 BADCVAR("hostname");
 453                 BADCVAR("log_file");
 454                 BADCVAR("maxplayers");
 455                 BADCVAR("minplayers");
 456                 BADCVAR("net_address");
 457                 BADCVAR("port");
 458                 BADCVAR("rcon_password");
 459                 BADCVAR("rcon_restricted_commands");
 460                 BADCVAR("rcon_restricted_password");
 461                 BADCVAR("skill");
 462                 BADCVAR("sv_adminnick");
 463                 BADCVAR("sv_autoscreenshot");
 464                 BADCVAR("sv_autotaunt");
 465                 BADCVAR("sv_curl_defaulturl");
 466                 BADCVAR("sv_defaultcharacter");
 467                 BADCVAR("sv_defaultplayercolors");
 468                 BADCVAR("sv_defaultplayermodel");
 469                 BADCVAR("sv_defaultplayerskin");
 470                 BADCVAR("sv_maxidle");
 471                 BADCVAR("sv_maxrate");
 472                 BADCVAR("sv_motd");
 473                 BADCVAR("sv_public");
 474                 BADCVAR("sv_ready_restart");
 475                 BADCVAR("sv_status_privacy");
 476                 BADCVAR("sv_taunt");
 477                 BADCVAR("sv_vote_call");
 478                 BADCVAR("sv_vote_commands");
 479                 BADCVAR("sv_vote_majority_factor");
 480                 BADCVAR("sv_vote_master");
 481                 BADCVAR("sv_vote_master_commands");
 482                 BADCVAR("sv_vote_master_password");
 483                 BADCVAR("sv_vote_simple_majority_factor");
 484                 BADCVAR("sys_ticrate");
 485                 BADCVAR("teamplay_mode");
 486                 BADCVAR("timelimit_override");
 487                 BADPREFIX("g_warmup_");
 488                 BADPREFIX("sv_ready_restart_");
 489
 490                 if(autocvar_g_minstagib)
 491                 {
 492                         BADCVAR("g_grappling_hook");
 493                         BADCVAR("g_jetpack");
 494                 }
 495 #undef BADPREFIX
 496 #undef BADCVAR
 497
 498                 if(pureadding)
 499                 {
 500                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 501                         if(strlen(cvar_purechanges) > 16384)
 502                         {
 503                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 504                                 pureadding = 0;
 505                         }
 506                 }
 507                 ++cvar_purechanges_count;
 508                 // WARNING: this variable is used for the server list
 509                 // NEVER dare to skip this code!
 510                 // Hacks to intentionally appearing as "pure server" even though you DO have
 511                 // modified settings may be punished by removal from the server list.
 512                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 513                 // though.
 514         }
 515         buf_del(h);
 516         if(cvar_changes == "")
 517                 cvar_changes = "// this server runs at default server settings\n";
 518         else
 519                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 520         cvar_changes = strzone(cvar_changes);
 521         if(cvar_purechanges == "")
 522                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 523         else
 524                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 525         cvar_purechanges = strzone(cvar_purechanges);
 526 }
 527
 528 void detect_maptype()
 529 {
 530 #if 0
 531         vector o, v;
 532         float i;
 533
 534         for(;;)
 535         {
 536                 o = world.mins;
 537                 o_x += random() * (world.maxs_x - world.mins_x);
 538                 o_y += random() * (world.maxs_y - world.mins_y);
 539                 o_z += random() * (world.maxs_z - world.mins_z);
 540
 541                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 542                 if(trace_fraction == 1)
 543                         continue;
 544
 545                 v = trace_endpos;
 546
 547                 for(i = 0; i < 64; i += 4)
 548                 {
 549                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 550         if(trace_fraction == 1)
 551                 continue;
 552                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 553                 }
 554
 555                 break;
 556         }
 557 #endif
 558 }
 559
 560 entity randomseed;
 561 float RandomSeed_Send(entity to, float sf)
 562 {
 563         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 564         WriteShort(MSG_ENTITY, self.cnt);
 565         return TRUE;
 566 }
 567 void RandomSeed_Think()
 568 {
 569         self.cnt = bound(0, floor(random() * 65536), 65535);
 570         self.nextthink = time + 5;
 571
 572         self.SendFlags |= 1;
 573 }
 574 void RandomSeed_Spawn()
 575 {
 576         randomseed = spawn();
 577         randomseed.think = RandomSeed_Think;
 578         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 579
 580         entity oldself;
 581         oldself = self;
 582         self = randomseed;
 583         self.think(); // sets random seed and nextthink
 584         self = oldself;
 585 }
 586
 587 void spawnfunc___init_dedicated_server(void)
 588 {
 589         // handler for _init/_init map (only for dedicated server initialization)
 590
 591         world_initialized = -1; // don't complain
 592         cvar = cvar_normal;
 593         cvar_string = cvar_string_normal;
 594         cvar_set = cvar_set_normal;
 595
 596         remove = remove_unsafely;
 597
 598         entity e;
 599         e = spawn();
 600         e.think = GotoFirstMap;
 601         e.nextthink = time; // this is usually 1 at this point
 602
 603         e = spawn();
 604         e.classname = "info_player_deathmatch"; // safeguard against player joining
 605
 606         self.classname = "worldspawn"; // safeguard against various stuff ;)
 607
 608         MapInfo_Enumerate();
 609         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 610 }
 611
 612 void Map_MarkAsRecent(string m);
 613 float world_already_spawned;
 614 void RegisterWeapons();
 615 void Nagger_Init();
 616 void ClientInit_Spawn();
 617 void WeaponStats_Init();
 618 void WeaponStats_Shutdown();
 619 void spawnfunc_worldspawn (void)
 620 {
 621         float fd, l, i, j, n;
 622         string s, col;
 623
 624         cvar = cvar_normal;
 625         cvar_string = cvar_string_normal;
 626         cvar_set = cvar_set_normal;
 627
 628         if(world_already_spawned)
 629                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 630         world_already_spawned = TRUE;
 631
 632         remove = remove_safely; // during spawning, watch what you remove!
 633
 634         check_unacceptable_compiler_bugs();
 635
 636         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 637
 638         compressShortVector_init();
 639
 640         allowed_to_spawn = TRUE;
 641
 642         entity head;
 643         head = nextent(world);
 644         maxclients = 0;
 645         while(head)
 646         {
 647                 ++maxclients;
 648                 head = nextent(head);
 649         }
 650
 651         // needs to be done so early as they would still spawn
 652         RegisterWeapons();
 653
 654         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 655
 656         TemporaryDB = db_create();
 657
 658         // 0 normal
 659         lightstyle(0, "m");
 660
 661         // 1 FLICKER (first variety)
 662         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 663
 664         // 2 SLOW STRONG PULSE
 665         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 666
 667         // 3 CANDLE (first variety)
 668         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 669
 670         // 4 FAST STROBE
 671         lightstyle(4, "mamamamamama");
 672
 673         // 5 GENTLE PULSE 1
 674         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 675
 676         // 6 FLICKER (second variety)
 677         lightstyle(6, "nmonqnmomnmomomno");
 678
 679         // 7 CANDLE (second variety)
 680         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 681
 682         // 8 CANDLE (third variety)
 683         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 684
 685         // 9 SLOW STROBE (fourth variety)
 686         lightstyle(9, "aaaaaaaazzzzzzzz");
 687
 688         // 10 FLUORESCENT FLICKER
 689         lightstyle(10, "mmamammmmammamamaaamammma");
 690
 691         // 11 SLOW PULSE NOT FADE TO BLACK
 692         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 693
 694         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 695
 696         // 63 testing
 697         lightstyle(63, "a");
 698
 699         if(autocvar_g_campaign)
 700                 CampaignPreInit();
 701
 702         Map_MarkAsRecent(mapname);
 703
 704         precache_model ("null"); // we need this one before InitGameplayMode
 705         InitGameplayMode();
 706         readlevelcvars();
 707         GrappleHookInit();
 708         ElectroInit();
 709         LaserInit();
 710
 711         player_count = 0;
 712         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 713         if(bot_waypoints_for_items == 1)
 714                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 715                         bot_waypoints_for_items = 0;
 716
 717         precache();
 718
 719         WaypointSprite_Init();
 720
 721         //if (g_domination)
 722         //      dom_init();
 723
 724         GameLogInit(); // prepare everything
 725         // NOTE for matchid:
 726         // changing the logic generating it is okay. But:
 727         // it HAS to stay <= 64 chars
 728         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 729         if(autocvar_sv_eventlog)
 730         {
 731                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 732                 matchid = strzone(s);
 733
 734                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 735                 s = ":gameinfo:mutators:LIST";
 736
 737                 ret_string = s;
 738                 MUTATOR_CALLHOOK(BuildMutatorsString);
 739                 s = ret_string;
 740
 741                 // simple, probably not good in the mutator system
 742                 if(autocvar_g_grappling_hook)
 743                         s = strcat(s, ":grappling_hook");
 744
 745                 // initialiation stuff, not good in the mutator system
 746                 if(!autocvar_g_use_ammunition)
 747                         s = strcat(s, ":no_use_ammunition");
 748
 749                 // initialiation stuff, not good in the mutator system
 750                 if(!autocvar_g_pickup_items)
 751                         s = strcat(s, ":no_pickup_items");
 752
 753                 // initialiation stuff, not good in the mutator system
 754                 if(autocvar_g_weaponarena != "0")
 755                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 756
 757                 // TODO to mutator system
 758                 if(autocvar_g_norecoil)
 759                         s = strcat(s, ":norecoil");
 760
 761                 // TODO to mutator system
 762                 if(autocvar_g_midair)
 763                         s = strcat(s, ":midair");
 764
 765                 // TODO to mutator system
 766                 if(autocvar_g_minstagib)
 767                         s = strcat(s, ":minstagib");
 768
 769                 // TODO to mutator system
 770                 if(autocvar_g_powerups == 0)
 771                         s = strcat(s, ":no_powerups");
 772                 if(autocvar_g_powerups > 0)
 773                         s = strcat(s, ":powerups");
 774
 775                 GameLogEcho(s);
 776                 GameLogEcho(":gameinfo:end");
 777         }
 778         else
 779                 matchid = strzone(ftos(random()));
 780
 781         cvar_set("nextmap", "");
 782
 783         SetDefaultAlpha();
 784
 785         if(autocvar_g_campaign)
 786                 CampaignPostInit();
 787
 788         fteqcc_testbugs();
 789
 790         Ban_LoadBans();
 791
 792         MapInfo_Enumerate();
 793         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 794
 795         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 796         {
 797                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 798                 if(fd != -1)
 799                 {
 800                         while((s = fgets(fd)))
 801                         {
 802                                 l = tokenize_console(s);
 803                                 if(l < 2)
 804                                         continue;
 805                                 if(argv(0) == "cd")
 806                                 {
 807                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 808                                         print("  cdtrack ", argv(2), "\n");
 809                                 }
 810                                 else if(argv(0) == "fog")
 811                                 {
 812                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 813                                         print("  \"fog\" \"", s, "\"\n");
 814                                 }
 815                                 else if(argv(0) == "set")
 816                                 {
 817                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 818                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 819                                 }
 820                                 else if(argv(0) != "//")
 821                                 {
 822                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 823                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 824                                 }
 825                         }
 826                         fclose(fd);
 827                 }
 828         }
 829
 830         WeaponStats_Init();
 831
 832         addstat(STAT_WEAPONS, AS_INT, weapons);
 833         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 834         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 835         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 836         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 837         Nagger_Init();
 838
 839         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 840         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 841         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 842         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 843         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 844         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 845         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 846         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 847         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 848         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 849         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 850         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 851
 852         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 853         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 854
 855         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 856
 857         if(g_ca || g_freezetag)
 858         {
 859                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 860                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 861                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 862                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 863         }
 864         if(g_freezetag)
 865         {
 866                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 867                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 868         }
 869
 870         // g_movementspeed hack
 871         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 872         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 873         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 874         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 875
 876         // secrets
 877         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 878         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 879
 880         next_pingtime = time + 5;
 881
 882         detect_maptype();
 883
 884         lsmaps_reply = "^7Maps available: ";
 885         lsnewmaps_reply = "^7Maps without a record set: ";
 886         for(i = 0, j = 0; i < MapInfo_count; ++i)
 887         {
 888                 if(MapInfo_Get_ByID(i))
 889                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 890                         {
 891                                 if(mod(i, 2))
 892                                         col = "^2";
 893                                 else
 894                                         col = "^3";
 895                                 ++j;
 896                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 897                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 898                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 899                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 900                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 901                         }
 902         }
 903         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 904         if (!g_race && !g_cts)
 905                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 906         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 907
 908         maplist_reply = "^7Maps in list: ";
 909         n = tokenize_console(autocvar_g_maplist);
 910         for(i = 0, j = 0; i < n; ++i)
 911         {
 912                 if(MapInfo_CheckMap(argv(i)))
 913                 {
 914                         if(mod(j, 2))
 915                                 col = "^2";
 916                         else
 917                                 col = "^3";
 918                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 919                         ++j;
 920                 }
 921         }
 922         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 923         MapInfo_ClearTemps();
 924
 925         for(i = 0; i < 10; ++i)
 926         {
 927                 records_reply[i] = strzone(getrecords(i));
 928         }
 929         if(g_cts)
 930                 ladder_reply = strzone(getladder());
 931
 932         rankings_reply = strzone(getrankings());
 933
 934         ClientInit_Spawn();
 935         RandomSeed_Spawn();
 936         PingPLReport_Spawn();
 937
 938         CheatInit();
 939
 940         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 941
 942         // fill sv_curl_serverpackages from .serverpackage files
 943         if(autocvar_sv_curl_serverpackages_auto)
 944         {
 945                 s = "";
 946                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 947                 for(i = 0; i < n; ++i)
 948                         if(substring(argv(i), -14, -1) != ".serverpackage")
 949                                 s = strcat(s, " ", argv(i));
 950                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 951                 if(fd >= 0)
 952                 {
 953                         j = search_getsize(fd);
 954                         for(i = 0; i < j; ++i)
 955                                 s = strcat(s, " ", search_getfilename(fd, i));
 956                         search_end(fd);
 957                 }
 958                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 959         }
 960
 961         PlayerStats_Init();
 962
 963         world_initialized = 1;
 964 }
 965
 966 void spawnfunc_light (void)
 967 {
 968         //makestatic (self); // Who the f___ did that?
 969         remove(self);
 970 }
 971
 972 string GetGametype()
 973 {
 974         return GametypeNameFromType(game);
 975 }
 976
 977 string getmapname_stored;
 978 string GetMapname()
 979 {
 980         return mapname;
 981 }
 982
 983 float Map_Count, Map_Current;
 984 string Map_Current_Name;
 985
 986 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 987 float GetMaplistPosition()
 988 {
 989         float pos, idx;
 990         string map;
 991
 992         map = GetMapname();
 993         idx = autocvar_g_maplist_index;
 994
 995         if(idx >= 0)
 996                 if(idx < Map_Count)
 997                         if(map == argv(idx))
 998                                 return idx;
 999
1000         for(pos = 0; pos < Map_Count; ++pos)
1001                 if(map == argv(pos))
1002                         return pos;
1003
1004         // resume normal maplist rotation if current map is not in g_maplist
1005         return idx;
1006 }
1007
1008 float MapHasRightSize(string map)
1009 {
1010         float fh;
1011         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1012         if(autocvar_g_maplist_check_waypoints)
1013         {
1014                 dprint("checkwp "); dprint(map);
1015                 if(!fexists(strcat("maps/", map, ".waypoints")))
1016                 {
1017                         dprint(": no waypoints\n");
1018                         return FALSE;
1019                 }
1020                 dprint(": has waypoints\n");
1021         }
1022
1023         // open map size restriction file
1024         dprint("opensize "); dprint(map);
1025         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1026         if(fh >= 0)
1027         {
1028                 float mapmin, mapmax;
1029                 dprint(": ok, ");
1030                 mapmin = stof(fgets(fh));
1031                 mapmax = stof(fgets(fh));
1032                 fclose(fh);
1033                 if(player_count < mapmin)
1034                 {
1035                         dprint("not enough\n");
1036                         return FALSE;
1037                 }
1038                 if(player_count > mapmax)
1039                 {
1040                         dprint("too many\n");
1041                         return FALSE;
1042                 }
1043                 dprint("right size\n");
1044                 return TRUE;
1045         }
1046         dprint(": not found\n");
1047         return TRUE;
1048 }
1049
1050 string Map_Filename(float position)
1051 {
1052         return strcat("maps/", argv(position), ".bsp");
1053 }
1054
1055 string strwords(string s, float w)
1056 {
1057         float endpos;
1058         for(endpos = 0; w && endpos >= 0; --w)
1059                 endpos = strstrofs(s, " ", endpos + 1);
1060         if(endpos < 0)
1061                 return s;
1062         else
1063                 return substring(s, 0, endpos);
1064 }
1065
1066 float strhasword(string s, string w)
1067 {
1068         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1069 }
1070
1071 void Map_MarkAsRecent(string m)
1072 {
1073         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1074 }
1075
1076 float Map_IsRecent(string m)
1077 {
1078         return strhasword(autocvar_g_maplist_mostrecent, m);
1079 }
1080
1081 float Map_Check(float position, float pass)
1082 {
1083         string filename;
1084         string map_next;
1085         map_next = argv(position);
1086         if(pass <= 1)
1087         {
1088                 if(Map_IsRecent(map_next))
1089                         return 0;
1090         }
1091         filename = Map_Filename(position);
1092         if(MapInfo_CheckMap(map_next))
1093         {
1094                 if(pass == 2)
1095                         return 1;
1096                 if(MapHasRightSize(map_next))
1097                         return 1;
1098                 return 0;
1099         }
1100         else
1101                 dprint( "Couldn't select '", filename, "'..\n" );
1102
1103         return 0;
1104 }
1105
1106 void Map_Goto_SetStr(string nextmapname)
1107 {
1108         if(getmapname_stored != "")
1109                 strunzone(getmapname_stored);
1110         if(nextmapname == "")
1111                 getmapname_stored = "";
1112         else
1113                 getmapname_stored = strzone(nextmapname);
1114 }
1115
1116 void Map_Goto_SetFloat(float position)
1117 {
1118         cvar_set("g_maplist_index", ftos(position));
1119         Map_Goto_SetStr(argv(position));
1120 }
1121
1122 void GameResetCfg()
1123 {
1124         // settings persist, except...
1125         localcmd("\nsettemp_restore\n");
1126 }
1127
1128 void Map_Goto()
1129 {
1130         GameResetCfg();
1131         MapInfo_LoadMap(getmapname_stored);
1132 }
1133
1134 // return codes of map selectors:
1135 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1136 //   -2 = permanent failure
1137 float() MaplistMethod_Iterate = // usual method
1138 {
1139         float pass, i;
1140
1141         for(pass = 1; pass <= 2; ++pass)
1142         {
1143                 for(i = 1; i < Map_Count; ++i)
1144                 {
1145                         float mapindex;
1146                         mapindex = mod(i + Map_Current, Map_Count);
1147                         if(Map_Check(mapindex, pass))
1148                                 return mapindex;
1149                 }
1150         }
1151         return -1;
1152 }
1153
1154 float() MaplistMethod_Repeat = // fallback method
1155 {
1156         if(Map_Check(Map_Current, 2))
1157                 return Map_Current;
1158         return -2;
1159 }
1160
1161 float() MaplistMethod_Random = // random map selection
1162 {
1163         float i, imax;
1164
1165         imax = 42;
1166
1167         for(i = 0; i <= imax; ++i)
1168         {
1169                 float mapindex;
1170                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1171                 if(Map_Check(mapindex, 1))
1172                         return mapindex;
1173         }
1174         return -1;
1175 }
1176
1177 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1178 // the exponent sets a bias on the map selection:
1179 // the higher the exponent, the less likely "shortly repeated" same maps are
1180 {
1181         float i, j, imax, insertpos;
1182
1183         imax = 42;
1184
1185         for(i = 0; i <= imax; ++i)
1186         {
1187                 string newlist;
1188
1189                 // now reinsert this at another position
1190                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1191                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1192                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1193                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1194
1195                 // insert the current map there
1196                 newlist = "";
1197                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1198                         newlist = strcat(newlist, " ", argv(j));
1199                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1200                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1201                         newlist = strcat(newlist, " ", argv(j));
1202                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1203                 cvar_set("g_maplist", newlist);
1204                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1205
1206                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1207                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1208                 if(Map_Check(Map_Current, 1))
1209                         return Map_Current;
1210         }
1211         return -1;
1212 }
1213
1214 void Maplist_Init()
1215 {
1216         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1217         if(Map_Count == 0)
1218         {
1219                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1220                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1221                 if(autocvar_g_maplist_shuffle)
1222                         ShuffleMaplist();
1223                 localcmd("\nmenu_cmd sync\n");
1224                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1225         }
1226         if(Map_Count == 0)
1227                 error("empty maplist, cannot select a new map");
1228         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1229
1230         if(Map_Current_Name)
1231                 strunzone(Map_Current_Name);
1232         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1233         // this may or may not be correct, but who cares, in the worst case a map
1234         // isn't chosen in the first pass that should have been
1235 }
1236
1237 string GetNextMap()
1238 {
1239         float nextMap;
1240
1241         Maplist_Init();
1242         nextMap = -1;
1243
1244         if(nextMap == -1)
1245                 if(autocvar_g_maplist_shuffle > 0)
1246                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1247
1248         if(nextMap == -1)
1249                 if(autocvar_g_maplist_selectrandom)
1250                         nextMap = MaplistMethod_Random();
1251
1252         if(nextMap == -1)
1253                 nextMap = MaplistMethod_Iterate();
1254
1255         if(nextMap == -1)
1256                 nextMap = MaplistMethod_Repeat();
1257
1258         if(nextMap >= 0)
1259         {
1260                 Map_Goto_SetFloat(nextMap);
1261                 return getmapname_stored;
1262         }
1263
1264         return "";
1265 }
1266
1267 float DoNextMapOverride()
1268 {
1269         if(autocvar_g_campaign)
1270         {
1271                 CampaignPostIntermission();
1272                 alreadychangedlevel = TRUE;
1273                 return TRUE;
1274         }
1275         if(autocvar_quit_when_empty)
1276         {
1277                 if(player_count <= currentbots)
1278                 {
1279                         localcmd("quit\n");
1280                         alreadychangedlevel = TRUE;
1281                         return TRUE;
1282                 }
1283         }
1284         if(autocvar_quit_and_redirect != "")
1285         {
1286                 redirection_target = strzone(autocvar_quit_and_redirect);
1287                 alreadychangedlevel = TRUE;
1288                 return TRUE;
1289         }
1290         if (autocvar_samelevel) // if samelevel is set, stay on same level
1291         {
1292                 localcmd("restart\n");
1293                 alreadychangedlevel = TRUE;
1294                 return TRUE;
1295         }
1296         if(autocvar_nextmap != "")
1297                 if(MapInfo_CheckMap(autocvar_nextmap))
1298                 {
1299                         Map_Goto_SetStr(autocvar_nextmap);
1300                         Map_Goto();
1301                         alreadychangedlevel = TRUE;
1302                         return TRUE;
1303                 }
1304         if(autocvar_lastlevel)
1305         {
1306                 GameResetCfg();
1307                 localcmd("set lastlevel 0\ntogglemenu\n");
1308                 alreadychangedlevel = TRUE;
1309                 return TRUE;
1310         }
1311         return FALSE;
1312 }
1313
1314 void GotoNextMap()
1315 {
1316         //string nextmap;
1317         //float n, nummaps;
1318         //string s;
1319         if (alreadychangedlevel)
1320                 return;
1321         alreadychangedlevel = TRUE;
1322
1323         {
1324                 string nextMap;
1325                 float allowReset;
1326
1327                 for(allowReset = 1; allowReset >= 0; --allowReset)
1328                 {
1329                         nextMap = GetNextMap();
1330                         if(nextMap != "")
1331                                 break;
1332
1333                         if(allowReset)
1334                         {
1335                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1336                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1337                                 if(autocvar_g_maplist_shuffle)
1338                                         ShuffleMaplist();
1339                                 localcmd("\nmenu_cmd sync\n");
1340                         }
1341                         else
1342                         {
1343                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1344                         }
1345                 }
1346                 Map_Goto();
1347         }
1348 }
1349
1350
1351 /*
1352 ============
1353 IntermissionThink
1354
1355 When the player presses attack or jump, change to the next level
1356 ============
1357 */
1358 .float autoscreenshot;
1359 void() MapVote_Start;
1360 void() MapVote_Think;
1361 float mapvote_initialized;
1362 void IntermissionThink()
1363 {
1364         FixIntermissionClient(self);
1365
1366         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1367                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1368         {
1369                 self.autoscreenshot = -1;
1370                 if(clienttype(self) == CLIENTTYPE_REAL)
1371                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1372                 return;
1373         }
1374
1375         if (time < intermission_exittime)
1376                 return;
1377
1378         if(!mapvote_initialized)
1379                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1380                         return;
1381
1382         MapVote_Start();
1383 }
1384
1385 /*
1386 ============
1387 FindIntermission
1388
1389 Returns the entity to view from
1390 ============
1391 */
1392 /*
1393 entity FindIntermission()
1394 {
1395         local   entity spot;
1396         local   float cyc;
1397
1398 // look for info_intermission first
1399         spot = find (world, classname, "info_intermission");
1400         if (spot)
1401         {       // pick a random one
1402                 cyc = random() * 4;
1403                 while (cyc > 1)
1404                 {
1405                         spot = find (spot, classname, "info_intermission");
1406                         if (!spot)
1407                                 spot = find (spot, classname, "info_intermission");
1408                         cyc = cyc - 1;
1409                 }
1410                 return spot;
1411         }
1412
1413 // then look for the start position
1414         spot = find (world, classname, "info_player_start");
1415         if (spot)
1416                 return spot;
1417
1418 // testinfo_player_start is only found in regioned levels
1419         spot = find (world, classname, "testplayerstart");
1420         if (spot)
1421                 return spot;
1422
1423 // then look for the start position
1424         spot = find (world, classname, "info_player_deathmatch");
1425         if (spot)
1426                 return spot;
1427
1428         //objerror ("FindIntermission: no spot");
1429         return world;
1430 }
1431 */
1432
1433 /*
1434 ===============================================================================
1435
1436 RULES
1437
1438 ===============================================================================
1439 */
1440
1441 void DumpStats(float final)
1442 {
1443         float file;
1444         string s;
1445         float to_console;
1446         float to_eventlog;
1447         float to_file;
1448         float i;
1449
1450         to_console = autocvar_sv_logscores_console;
1451         to_eventlog = autocvar_sv_eventlog;
1452         to_file = autocvar_sv_logscores_file;
1453
1454         if(!final)
1455         {
1456                 to_console = TRUE; // always print printstats replies
1457                 to_eventlog = FALSE; // but never print them to the event log
1458         }
1459
1460         if(to_eventlog)
1461                 if(autocvar_sv_eventlog_console)
1462                         to_console = FALSE; // otherwise we get the output twice
1463
1464         if(final)
1465                 s = ":scores:";
1466         else
1467                 s = ":status:";
1468         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1469
1470         if(to_console)
1471                 print(s, "\n");
1472         if(to_eventlog)
1473                 GameLogEcho(s);
1474         if(to_file)
1475         {
1476                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1477                 if(file == -1)
1478                         to_file = FALSE;
1479                 else
1480                         fputs(file, strcat(s, "\n"));
1481         }
1482
1483         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1484         if(to_console)
1485                 print(s, "\n");
1486         if(to_eventlog)
1487                 GameLogEcho(s);
1488         if(to_file)
1489                 fputs(file, strcat(s, "\n"));
1490
1491         FOR_EACH_CLIENT(other)
1492         {
1493                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1494                 {
1495                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1496                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1497                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1498                                 s = strcat(s, ftos(other.team), ":");
1499                         else
1500                                 s = strcat(s, "spectator:");
1501
1502                         if(to_console)
1503                                 print(s, other.netname, "\n");
1504                         if(to_eventlog)
1505                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1506                         if(to_file)
1507                                 fputs(file, strcat(s, other.netname, "\n"));
1508                 }
1509         }
1510
1511         if(teamplay)
1512         {
1513                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1514                 if(to_console)
1515                         print(s, "\n");
1516                 if(to_eventlog)
1517                         GameLogEcho(s);
1518                 if(to_file)
1519                         fputs(file, strcat(s, "\n"));
1520
1521                 for(i = 1; i < 16; ++i)
1522                 {
1523                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1524                         s = strcat(s, ":", ftos(i));
1525                         if(to_console)
1526                                 print(s, "\n");
1527                         if(to_eventlog)
1528                                 GameLogEcho(s);
1529                         if(to_file)
1530                                 fputs(file, strcat(s, "\n"));
1531                 }
1532         }
1533
1534         if(to_console)
1535                 print(":end\n");
1536         if(to_eventlog)
1537                 GameLogEcho(":end");
1538         if(to_file)
1539         {
1540                 fputs(file, ":end\n");
1541                 fclose(file);
1542         }
1543 }
1544
1545 void FixIntermissionClient(entity e)
1546 {
1547         string s;
1548         if(!e.autoscreenshot) // initial call
1549         {
1550                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1551                 e.health = -2342;
1552                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1553                 e.solid = SOLID_NOT;
1554                 e.movetype = MOVETYPE_NONE;
1555                 e.takedamage = DAMAGE_NO;
1556                 if(e.weaponentity)
1557                 {
1558                         e.weaponentity.effects = EF_NODRAW;
1559                         if (e.weaponentity.weaponentity)
1560                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1561                 }
1562                 if(clienttype(e) == CLIENTTYPE_REAL)
1563                 {
1564                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1565                         s = autocvar_sv_intermission_cdtrack;
1566                         if(s != "")
1567                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1568                         msg_entity = e;
1569                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1570                 }
1571         }
1572 }
1573
1574
1575 /*
1576 go to the next level for deathmatch
1577 only called if a time or frag limit has expired
1578 */
1579 void NextLevel()
1580 {
1581         gameover = TRUE;
1582
1583         intermission_running = 1;
1584
1585 // enforce a wait time before allowing changelevel
1586         if(player_count > 0)
1587                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1588         else
1589                 intermission_exittime = -1;
1590
1591         /*
1592         WriteByte (MSG_ALL, SVC_CDTRACK);
1593         WriteByte (MSG_ALL, 3);
1594         WriteByte (MSG_ALL, 3);
1595         // done in FixIntermission
1596         */
1597
1598         //pos = FindIntermission ();
1599
1600         VoteReset();
1601
1602         DumpStats(TRUE);
1603
1604         // send statistics
1605         entity e;
1606         PlayerStats_EndMatch(1);
1607         FOR_EACH_CLIENT(e)
1608                 PlayerStats_AddGlobalInfo(e);
1609         PlayerStats_Shutdown();
1610         WeaponStats_Shutdown();
1611
1612         if(autocvar_sv_eventlog)
1613                 GameLogEcho(":gameover");
1614
1615         GameLogClose();
1616
1617         FOR_EACH_PLAYER(other) {
1618                 FixIntermissionClient(other);
1619                 if(other.winning)
1620                         bprint(other.netname, " ^7wins.\n");
1621         }
1622
1623         if(autocvar_g_campaign)
1624                 CampaignPreIntermission();
1625
1626         localcmd("\nsv_hook_gameend\n");
1627 }
1628
1629 /*
1630 ============
1631 CheckRules_Player
1632
1633 Exit deathmatch games upon conditions
1634 ============
1635 */
1636 void CheckRules_Player()
1637 {
1638         if (gameover)   // someone else quit the game already
1639                 return;
1640
1641         if(self.deadflag == DEAD_NO)
1642                 self.play_time += frametime;
1643
1644         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1645         //   (div0: and that in CheckRules_World please)
1646 }
1647
1648 float checkrules_equality;
1649 float checkrules_suddendeathwarning;
1650 float checkrules_suddendeathend;
1651 float checkrules_overtimesadded; //how many overtimes have been already added
1652
1653 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1654 float WINNING_YES = 1; // winner found
1655 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1656 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1657
1658 float InitiateSuddenDeath()
1659 {
1660         // Check first whether normal overtimes could be added before initiating suddendeath mode
1661         // - for this timelimit_overtime needs to be >0 of course
1662         // - also check the winning condition calculated in the previous frame and only add normal overtime
1663         //   again, if at the point at which timelimit would be extended again, still no winner was found
1664         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1665         {
1666                 return 1; // need to call InitiateOvertime later
1667         }
1668         else
1669         {
1670                 if(!checkrules_suddendeathend)
1671                 {
1672                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1673                         if(g_race && !g_race_qualifying)
1674                                 race_StartCompleting();
1675                 }
1676                 return 0;
1677         }
1678 }
1679
1680 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1681 {
1682         ++checkrules_overtimesadded;
1683         //add one more overtime by simply extending the timelimit
1684         float tl;
1685         tl = autocvar_timelimit;
1686         tl += autocvar_timelimit_overtime;
1687         cvar_set("timelimit", ftos(tl));
1688         string minutesPlural;
1689         if (autocvar_timelimit_overtime == 1)
1690                 minutesPlural = " ^3minute";
1691         else
1692                 minutesPlural = " ^3minutes";
1693
1694         bcenterprint(
1695                 strcat(
1696                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1697                         ftos(autocvar_timelimit_overtime),
1698                         minutesPlural,
1699                         " to the game!"
1700                 )
1701         );
1702 }
1703
1704 float GetWinningCode(float fraglimitreached, float equality)
1705 {
1706         if(autocvar_g_campaign == 1)
1707                 if(fraglimitreached)
1708                         return WINNING_YES;
1709                 else
1710                         return WINNING_NO;
1711
1712         else
1713                 if(equality)
1714                         if(fraglimitreached)
1715                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1716                         else
1717                                 return WINNING_NEVER;
1718                 else
1719                         if(fraglimitreached)
1720                                 return WINNING_YES;
1721                         else
1722                                 return WINNING_NO;
1723 }
1724
1725 // set the .winning flag for exactly those players with a given field value
1726 void SetWinners(.float field, float value)
1727 {
1728         entity head;
1729         FOR_EACH_PLAYER(head)
1730                 head.winning = (head.field == value);
1731 }
1732
1733 // set the .winning flag for those players with a given field value
1734 void AddWinners(.float field, float value)
1735 {
1736         entity head;
1737         FOR_EACH_PLAYER(head)
1738                 if(head.field == value)
1739                         head.winning = 1;
1740 }
1741
1742 // clear the .winning flags
1743 void ClearWinners(void)
1744 {
1745         entity head;
1746         FOR_EACH_PLAYER(head)
1747                 head.winning = 0;
1748 }
1749
1750 // Onslaught winning condition:
1751 // game terminates if only one team has a working generator (or none)
1752 float WinningCondition_Onslaught()
1753 {
1754         entity head;
1755         float t1, t2, t3, t4;
1756
1757         WinningConditionHelper(); // set worldstatus
1758
1759         if(inWarmupStage)
1760                 return WINNING_NO;
1761
1762         // first check if the game has ended
1763         t1 = t2 = t3 = t4 = 0;
1764         head = find(world, classname, "onslaught_generator");
1765         while (head)
1766         {
1767                 if (head.health > 0)
1768                 {
1769                         if (head.team == COLOR_TEAM1) t1 = 1;
1770                         if (head.team == COLOR_TEAM2) t2 = 1;
1771                         if (head.team == COLOR_TEAM3) t3 = 1;
1772                         if (head.team == COLOR_TEAM4) t4 = 1;
1773                 }
1774                 head = find(head, classname, "onslaught_generator");
1775         }
1776         if (t1 + t2 + t3 + t4 < 2)
1777         {
1778                 // game over, only one team remains (or none)
1779                 ClearWinners();
1780                 if (t1) SetWinners(team, COLOR_TEAM1);
1781                 if (t2) SetWinners(team, COLOR_TEAM2);
1782                 if (t3) SetWinners(team, COLOR_TEAM3);
1783                 if (t4) SetWinners(team, COLOR_TEAM4);
1784                 dprint("Have a winner, ending game.\n");
1785                 return WINNING_YES;
1786         }
1787
1788         // Two or more teams remain
1789         return WINNING_NO;
1790 }
1791
1792 float LMS_NewPlayerLives()
1793 {
1794         float fl;
1795         fl = autocvar_fraglimit;
1796         if(fl == 0)
1797                 fl = 999;
1798
1799         // first player has left the game for dying too much? Nobody else can get in.
1800         if(lms_lowest_lives < 1)
1801                 return 0;
1802
1803         if(!autocvar_g_lms_join_anytime)
1804                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1805                         return 0;
1806
1807         return bound(1, lms_lowest_lives, fl);
1808 }
1809
1810 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1811 // they win. Otherwise the defending team wins once the timelimit passes.
1812 void assault_new_round();
1813 float WinningCondition_Assault()
1814 {
1815         float status;
1816
1817         WinningConditionHelper(); // set worldstatus
1818
1819         status = WINNING_NO;
1820         // as the timelimit has not yet passed just assume the defending team will win
1821         if(assault_attacker_team == COLOR_TEAM1)
1822         {
1823                 SetWinners(team, COLOR_TEAM2);
1824         }
1825         else
1826         {
1827                 SetWinners(team, COLOR_TEAM1);
1828         }
1829
1830         entity ent;
1831         ent = find(world, classname, "target_assault_roundend");
1832         if(ent)
1833         {
1834                 if(ent.winning) // round end has been triggered by attacking team
1835                 {
1836                         bprint("ASSAULT: round completed...\n");
1837                         SetWinners(team, assault_attacker_team);
1838
1839                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1840
1841                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1842                         {
1843                                 status = WINNING_YES;
1844                         }
1845                         else
1846                         {
1847                                 entity oldself;
1848                                 oldself = self;
1849                                 self = ent;
1850                                 assault_new_round();
1851                                 self = oldself;
1852                         }
1853                 }
1854         }
1855
1856         return status;
1857 }
1858
1859 // LMS winning condition: game terminates if and only if there's at most one
1860 // one player who's living lives. Top two scores being equal cancels the time
1861 // limit.
1862 float WinningCondition_LMS()
1863 {
1864         entity head, head2;
1865         float have_player;
1866         float have_players;
1867         float l;
1868
1869         have_player = FALSE;
1870         have_players = FALSE;
1871         l = LMS_NewPlayerLives();
1872
1873         head = find(world, classname, "player");
1874         if(head)
1875                 have_player = TRUE;
1876         head2 = find(head, classname, "player");
1877         if(head2)
1878                 have_players = TRUE;
1879
1880         if(have_player)
1881         {
1882                 // we have at least one player
1883                 if(have_players)
1884                 {
1885                         // two or more active players - continue with the game
1886                 }
1887                 else
1888                 {
1889                         // exactly one player?
1890
1891                         ClearWinners();
1892                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1893
1894                         if(l)
1895                         {
1896                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1897                                 return WINNING_NO;
1898                         }
1899                         else
1900                         {
1901                                 // a winner!
1902                                 // and assign him his first place
1903                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1904                                 return WINNING_YES;
1905                         }
1906                 }
1907         }
1908         else
1909         {
1910                 // nobody is playing at all...
1911                 if(l)
1912                 {
1913                         // wait for players...
1914                 }
1915                 else
1916                 {
1917                         // SNAFU (maybe a draw game?)
1918                         ClearWinners();
1919                         dprint("No players, ending game.\n");
1920                         return WINNING_YES;
1921                 }
1922         }
1923
1924         // When we get here, we have at least two players who are actually LIVING,
1925         // now check if the top two players have equal score.
1926         WinningConditionHelper();
1927
1928         ClearWinners();
1929         if(WinningConditionHelper_winner)
1930                 WinningConditionHelper_winner.winning = TRUE;
1931         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1932                 return WINNING_NEVER;
1933
1934         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1935         return WINNING_NO;
1936 }
1937
1938 void ShuffleMaplist()
1939 {
1940         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1941 }
1942
1943 float leaderfrags;
1944 float WinningCondition_Scores(float limit, float leadlimit)
1945 {
1946         float limitreached;
1947
1948         // TODO make everything use THIS winning condition (except LMS)
1949         WinningConditionHelper();
1950
1951         if(teamplay)
1952         {
1953                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1954                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1955                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1956                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1957         }
1958
1959         ClearWinners();
1960         if(WinningConditionHelper_winner)
1961                 WinningConditionHelper_winner.winning = 1;
1962         if(WinningConditionHelper_winnerteam >= 0)
1963                 SetWinners(team, WinningConditionHelper_winnerteam);
1964
1965         if(WinningConditionHelper_lowerisbetter)
1966         {
1967                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1968                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1969                 limit = -limit;
1970         }
1971
1972         if(WinningConditionHelper_zeroisworst)
1973                 leadlimit = 0; // not supported in this mode
1974
1975         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1976         // these modes always score in increments of 1, thus this makes sense
1977         {
1978                 if(leaderfrags != WinningConditionHelper_topscore)
1979                 {
1980                         leaderfrags = WinningConditionHelper_topscore;
1981
1982                         if (limit)
1983                         if (leaderfrags == limit - 1)
1984                                 Announce("1fragleft");
1985                         else if (leaderfrags == limit - 2)
1986                                 Announce("2fragsleft");
1987                         else if (leaderfrags == limit - 3)
1988                                 Announce("3fragsleft");
1989                 }
1990         }
1991
1992         limitreached = FALSE;
1993         if(limit)
1994                 if(WinningConditionHelper_topscore >= limit)
1995                         limitreached = TRUE;
1996         if(leadlimit)
1997         {
1998                 float leadlimitreached;
1999                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2000                 if(autocvar_leadlimit_and_fraglimit)
2001                         limitreached = (limitreached && leadlimitreached);
2002                 else
2003                         limitreached = (limitreached || leadlimitreached);
2004         }
2005
2006         return GetWinningCode(
2007                 WinningConditionHelper_topscore && limitreached,
2008                 WinningConditionHelper_equality
2009         );
2010 }
2011
2012 float WinningCondition_Race(float fraglimit)
2013 {
2014         float wc;
2015         entity p;
2016         float n, c;
2017
2018         n = 0;
2019         c = 0;
2020         FOR_EACH_PLAYER(p)
2021         {
2022                 ++n;
2023                 if(p.race_completed)
2024                         ++c;
2025         }
2026         if(n && (n == c))
2027                 return WINNING_YES;
2028         wc = WinningCondition_Scores(fraglimit, 0);
2029
2030         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2031         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2032         // do NOT support equality when the laps are all raced!
2033                 return WINNING_STARTSUDDENDEATHOVERTIME;
2034         else
2035                 return WINNING_NEVER;
2036         return wc;
2037 }
2038
2039 void ReadyRestart();
2040 float WinningCondition_QualifyingThenRace(float limit)
2041 {
2042         float wc;
2043         wc = WinningCondition_Scores(limit, 0);
2044
2045         // NEVER initiate overtime
2046         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2047         {
2048                 return WINNING_YES;
2049         }
2050
2051         return wc;
2052 }
2053
2054 float WinningCondition_RanOutOfSpawns()
2055 {
2056         entity head;
2057
2058         if(have_team_spawns <= 0)
2059                 return WINNING_NO;
2060
2061         if(autocvar_g_spawn_useallspawns <= 0)
2062                 return WINNING_NO;
2063
2064         if(!some_spawn_has_been_used)
2065                 return WINNING_NO;
2066
2067         team1_score = team2_score = team3_score = team4_score = 0;
2068
2069         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2070         {
2071                 if(head.team == COLOR_TEAM1)
2072                         team1_score = 1;
2073                 else if(head.team == COLOR_TEAM2)
2074                         team2_score = 1;
2075                 else if(head.team == COLOR_TEAM3)
2076                         team3_score = 1;
2077                 else if(head.team == COLOR_TEAM4)
2078                         team4_score = 1;
2079         }
2080
2081         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2082         {
2083                 if(head.team == COLOR_TEAM1)
2084                         team1_score = 1;
2085                 else if(head.team == COLOR_TEAM2)
2086                         team2_score = 1;
2087                 else if(head.team == COLOR_TEAM3)
2088                         team3_score = 1;
2089                 else if(head.team == COLOR_TEAM4)
2090                         team4_score = 1;
2091         }
2092
2093         ClearWinners();
2094         if(team1_score + team2_score + team3_score + team4_score == 0)
2095         {
2096                 checkrules_equality = TRUE;
2097                 return WINNING_YES;
2098         }
2099         else if(team1_score + team2_score + team3_score + team4_score == 1)
2100         {
2101                 float t, i;
2102                 if(team1_score) t = COLOR_TEAM1;
2103                 if(team2_score) t = COLOR_TEAM2;
2104                 if(team3_score) t = COLOR_TEAM3;
2105                 if(team4_score) t = COLOR_TEAM4;
2106                 CheckAllowedTeams(world);
2107                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2108                 {
2109                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2110                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2111                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2112                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2113                 }
2114
2115                 AddWinners(team, t);
2116                 return WINNING_YES;
2117         }
2118         else
2119                 return WINNING_NO;
2120 }
2121
2122 /*
2123 ============
2124 CheckRules_World
2125
2126 Exit deathmatch games upon conditions
2127 ============
2128 */
2129 void CheckRules_World()
2130 {
2131         float timelimit;
2132         float fraglimit;
2133         float leadlimit;
2134
2135         VoteThink();
2136         MapVote_Think();
2137
2138         SetDefaultAlpha();
2139
2140         /*
2141         MapVote_Think should now do that part
2142         if (intermission_running)
2143                 if (time >= intermission_exittime + 60)
2144                 {
2145                         if(!DoNextMapOverride())
2146                                 GotoNextMap();
2147                         return;
2148                 }
2149         */
2150
2151         if (gameover)   // someone else quit the game already
2152         {
2153                 if(player_count == 0) // Nobody there? Then let's go to the next map
2154                         MapVote_Start();
2155                         // this will actually check the player count in the next frame
2156                         // again, but this shouldn't hurt
2157                 return;
2158         }
2159
2160         timelimit = autocvar_timelimit * 60;
2161         fraglimit = autocvar_fraglimit;
2162         leadlimit = autocvar_leadlimit;
2163
2164         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2165         {
2166                 if(timelimit > 0)
2167                         timelimit = 0; // timelimit is not made for warmup
2168                 if(fraglimit > 0)
2169                         fraglimit = 0; // no fraglimit for now
2170                 leadlimit = 0; // no leadlimit for now
2171         }
2172
2173         if(g_onslaught)
2174                 timelimit = 0; // ONS has its own overtime rule
2175
2176         if(timelimit > 0)
2177         {
2178                 timelimit += game_starttime;
2179         }
2180         else if (timelimit < 0)
2181         {
2182                 // endmatch
2183                 NextLevel();
2184                 return;
2185         }
2186
2187         float wantovertime;
2188         wantovertime = 0;
2189
2190         if(checkrules_suddendeathend)
2191         {
2192                 if(!checkrules_suddendeathwarning)
2193                 {
2194                         checkrules_suddendeathwarning = TRUE;
2195                         if(g_race && !g_race_qualifying)
2196                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2197                         else
2198                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2199                 }
2200         }
2201         else
2202         {
2203                 if (timelimit && time >= timelimit)
2204                 {
2205                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2206                         {
2207                                 float totalplayers;
2208                                 float playerswithlaps;
2209                                 float readyplayers;
2210                                 entity head;
2211                                 totalplayers = playerswithlaps = readyplayers = 0;
2212                                 FOR_EACH_PLAYER(head)
2213                                 {
2214                                         ++totalplayers;
2215                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2216                                                 ++playerswithlaps;
2217                                         if(head.ready)
2218                                                 ++readyplayers;
2219                                 }
2220
2221                                 // at least 2 of the players have completed a lap: start the RACE
2222                                 // otherwise, the players should end the qualifying on their own
2223                                 if(readyplayers || playerswithlaps >= 2)
2224                                 {
2225                                         checkrules_suddendeathend = 0;
2226                                         ReadyRestart(); // go to race
2227                                         return;
2228                                 }
2229                                 else
2230                                         wantovertime |= InitiateSuddenDeath();
2231                         }
2232                         else
2233                                 wantovertime |= InitiateSuddenDeath();
2234                 }
2235         }
2236
2237         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2238         {
2239                 NextLevel();
2240                 return;
2241         }
2242
2243         float checkrules_status;
2244         checkrules_status = WinningCondition_RanOutOfSpawns();
2245         if(checkrules_status == WINNING_YES)
2246         {
2247                 bprint("Hey! Someone ran out of spawns!\n");
2248         }
2249         else if(g_race && !g_race_qualifying && timelimit >= 0)
2250         {
2251                 checkrules_status = WinningCondition_Race(fraglimit);
2252                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2253         }
2254         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2255         {
2256                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2257                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2258         }
2259         else if(g_assault)
2260         {
2261                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2262         }
2263         else if(g_lms)
2264         {
2265                 checkrules_status = WinningCondition_LMS();
2266         }
2267         else if (g_onslaught)
2268         {
2269                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2270         }
2271         else
2272         {
2273                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2274                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2275         }
2276
2277         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2278         {
2279                 checkrules_status = WINNING_NEVER;
2280                 checkrules_overtimesadded = -1;
2281                 wantovertime |= InitiateSuddenDeath();
2282         }
2283
2284         if(checkrules_status == WINNING_NEVER)
2285                 // equality cases! Nobody wins if the overtime ends in a draw.
2286                 ClearWinners();
2287
2288         if(wantovertime)
2289         {
2290                 if(checkrules_status == WINNING_NEVER)
2291                         InitiateOvertime();
2292                 else
2293                         checkrules_status = WINNING_YES;
2294         }
2295
2296         if(checkrules_suddendeathend)
2297                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2298                         checkrules_status = WINNING_YES;
2299
2300         if(checkrules_status == WINNING_YES)
2301         {
2302                 //print("WINNING\n");
2303                 NextLevel();
2304         }
2305 }
2306
2307 float mapvote_nextthink;
2308 float mapvote_initialized;
2309 float mapvote_keeptwotime;
2310 float mapvote_timeout;
2311 string mapvote_message;
2312 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2313 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2314 float mapvote_screenshot_dirs_count;
2315
2316 float mapvote_count;
2317 float mapvote_count_real;
2318 string mapvote_maps[MAPVOTE_COUNT];
2319 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2320 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2321 float mapvote_maps_suggested[MAPVOTE_COUNT];
2322 string mapvote_suggestions[MAPVOTE_COUNT];
2323 float mapvote_suggestion_ptr;
2324 float mapvote_voters;
2325 float mapvote_votes[MAPVOTE_COUNT];
2326 float mapvote_run;
2327 float mapvote_detail;
2328 float mapvote_abstain;
2329 .float mapvote;
2330
2331 void MapVote_ClearAllVotes()
2332 {
2333         FOR_EACH_CLIENT(other)
2334                 other.mapvote = 0;
2335 }
2336
2337 string MapVote_Suggest(string m)
2338 {
2339         float i;
2340         if(m == "")
2341                 return "That's not how to use this command.";
2342         if(!autocvar_g_maplist_votable_suggestions)
2343                 return "Suggestions are not accepted on this server.";
2344         if(mapvote_initialized)
2345                 return "Can't suggest - voting is already in progress!";
2346         m = MapInfo_FixName(m);
2347         if(!m)
2348                 return "The map you suggested is not available on this server.";
2349         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2350                 if(Map_IsRecent(m))
2351                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2352
2353         if(!MapInfo_CheckMap(m))
2354                 return "The map you suggested does not support the current game mode.";
2355         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2356                 if(mapvote_suggestions[i] == m)
2357                         return "This map was already suggested.";
2358         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2359         {
2360                 i = floor(random() * mapvote_suggestion_ptr);
2361         }
2362         else
2363         {
2364                 i = mapvote_suggestion_ptr;
2365                 mapvote_suggestion_ptr += 1;
2366         }
2367         if(mapvote_suggestions[i] != "")
2368                 strunzone(mapvote_suggestions[i]);
2369         mapvote_suggestions[i] = strzone(m);
2370         if(autocvar_sv_eventlog)
2371                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2372         return strcat("Suggestion of ", m, " accepted.");
2373 }
2374
2375 void MapVote_AddVotable(string nextMap, float isSuggestion)
2376 {
2377         float j, i, o;
2378         string pakfile, mapfile;
2379
2380         if(nextMap == "")
2381                 return;
2382         for(j = 0; j < mapvote_count; ++j)
2383                 if(mapvote_maps[j] == nextMap)
2384                         return;
2385         // suggestions might be no longer valid/allowed after gametype switch!
2386         if(isSuggestion)
2387                 if(!MapInfo_CheckMap(nextMap))
2388                         return;
2389         mapvote_maps[mapvote_count] = strzone(nextMap);
2390         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2391
2392         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2393         {
2394                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2395                 pakfile = whichpack(strcat(mapfile, ".tga"));
2396                 if(pakfile == "")
2397                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2398                 if(pakfile == "")
2399                         pakfile = whichpack(strcat(mapfile, ".png"));
2400                 if(pakfile != "")
2401                         break;
2402         }
2403         if(i >= mapvote_screenshot_dirs_count)
2404                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2405         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2406                 pakfile = substring(pakfile, o, -1);
2407
2408         mapvote_maps_screenshot_dir[mapvote_count] = i;
2409         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2410
2411         mapvote_count += 1;
2412 }
2413
2414 void MapVote_Spawn();
2415 void MapVote_Init()
2416 {
2417         float i;
2418         float nmax, smax;
2419
2420         MapVote_ClearAllVotes();
2421
2422         mapvote_count = 0;
2423         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2424         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2425
2426         if(mapvote_abstain)
2427                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2428         else
2429                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2430         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2431
2432         // we need this for AddVotable, as that cycles through the screenshot dirs
2433         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2434         if(mapvote_screenshot_dirs_count == 0)
2435                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2436         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2437         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2438                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2439
2440         if(mapvote_suggestion_ptr)
2441                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2442                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2443
2444         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2445                 MapVote_AddVotable(GetNextMap(), FALSE);
2446
2447         if(mapvote_count == 0)
2448         {
2449                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2450                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2451                 if(autocvar_g_maplist_shuffle)
2452                         ShuffleMaplist();
2453                 localcmd("\nmenu_cmd sync\n");
2454                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2455                         MapVote_AddVotable(GetNextMap(), FALSE);
2456         }
2457
2458         mapvote_count_real = mapvote_count;
2459         if(mapvote_abstain)
2460                 MapVote_AddVotable("don't care", 0);
2461
2462         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2463
2464         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2465         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2466         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2467                 mapvote_keeptwotime = 0;
2468         mapvote_message = "Choose a map and press its key!";
2469
2470         MapVote_Spawn();
2471 }
2472
2473 void MapVote_SendPicture(float id)
2474 {
2475         msg_entity = self;
2476         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2477         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2478         WriteByte(MSG_ONE, id);
2479         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2480 }
2481
2482 float GameCommand_MapVote(string cmd)
2483 {
2484         if(!intermission_running)
2485                 return FALSE;
2486
2487         if(cmd == "mv_getpic")
2488         {
2489                 MapVote_SendPicture(stof(argv(1)));
2490                 return TRUE;
2491         }
2492
2493         return FALSE;
2494 }
2495
2496 float MapVote_GetMapMask()
2497 {
2498         float mask, i, power;
2499         mask = 0;
2500         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2501                 if(mapvote_maps[i] != "")
2502                         mask |= power;
2503         return mask;
2504 }
2505
2506 entity mapvote_ent;
2507 float MapVote_SendEntity(entity to, float sf)
2508 {
2509         float i;
2510
2511         if(sf & 1)
2512                 sf &~= 2; // if we send 1, we don't need to also send 2
2513
2514         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2515         WriteByte(MSG_ENTITY, sf);
2516
2517         if(sf & 1)
2518         {
2519                 // flag 1 == initialization
2520                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2521                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2522                 WriteString(MSG_ENTITY, "");
2523                 WriteByte(MSG_ENTITY, mapvote_count);
2524                 WriteByte(MSG_ENTITY, mapvote_abstain);
2525                 WriteByte(MSG_ENTITY, mapvote_detail);
2526                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2527                 if(mapvote_count <= 8)
2528                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2529                 else
2530                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2531                 for(i = 0; i < mapvote_count; ++i)
2532                         if(mapvote_maps[i] != "")
2533                         {
2534                                 if(mapvote_abstain && i == mapvote_count - 1)
2535                                 {
2536                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2537                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2538                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2539                                 }
2540                                 else
2541                                 {
2542                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2543                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2544                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2545                                 }
2546                         }
2547         }
2548
2549         if(sf & 2)
2550         {
2551                 // flag 2 == update of mask
2552                 if(mapvote_count <= 8)
2553                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2554                 else
2555                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2556         }
2557
2558         if(sf & 4)
2559         {
2560                 if(mapvote_detail)
2561                         for(i = 0; i < mapvote_count; ++i)
2562                                 if(mapvote_maps[i] != "")
2563                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2564
2565                 WriteByte(MSG_ENTITY, to.mapvote);
2566         }
2567
2568         return TRUE;
2569 }
2570
2571 void MapVote_Spawn()
2572 {
2573         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2574 }
2575
2576 void MapVote_TouchMask()
2577 {
2578         mapvote_ent.SendFlags |= 2;
2579 }
2580
2581 void MapVote_TouchVotes(entity voter)
2582 {
2583         mapvote_ent.SendFlags |= 4;
2584 }
2585
2586 float MapVote_Finished(float mappos)
2587 {
2588         string result;
2589         float i;
2590         float didntvote;
2591
2592         if(autocvar_sv_eventlog)
2593         {
2594                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2595                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2596                 didntvote = mapvote_voters;
2597                 for(i = 0; i < mapvote_count; ++i)
2598                         if(mapvote_maps[i] != "")
2599                         {
2600                                 didntvote -= mapvote_votes[i];
2601                                 if(i != mappos)
2602                                 {
2603                                         result = strcat(result, ":", mapvote_maps[i]);
2604                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2605                                 }
2606                         }
2607                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2608
2609                 GameLogEcho(result);
2610                 if(mapvote_maps_suggested[mappos])
2611                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2612         }
2613
2614         FOR_EACH_REALCLIENT(other)
2615                 FixClientCvars(other);
2616
2617         Map_Goto_SetStr(mapvote_maps[mappos]);
2618         Map_Goto();
2619         alreadychangedlevel = TRUE;
2620         return TRUE;
2621 }
2622 void MapVote_CheckRules_1()
2623 {
2624         float i;
2625
2626         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2627         {
2628                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2629                 mapvote_votes[i] = 0;
2630         }
2631
2632         mapvote_voters = 0;
2633         FOR_EACH_REALCLIENT(other)
2634         {
2635                 ++mapvote_voters;
2636                 if(other.mapvote)
2637                 {
2638                         i = other.mapvote - 1;
2639                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2640                         mapvote_votes[i] = mapvote_votes[i] + 1;
2641                 }
2642         }
2643 }
2644
2645 float MapVote_CheckRules_2()
2646 {
2647         float i;
2648         float firstPlace, secondPlace;
2649         float firstPlaceVotes, secondPlaceVotes;
2650         float mapvote_voters_real;
2651         string result;
2652
2653         if(mapvote_count_real == 1)
2654                 return MapVote_Finished(0);
2655
2656         mapvote_voters_real = mapvote_voters;
2657         if(mapvote_abstain)
2658                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2659
2660         RandomSelection_Init();
2661         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2662                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2663         firstPlace = RandomSelection_chosen_float;
2664         firstPlaceVotes = RandomSelection_best_priority;
2665         //dprint("First place: ", ftos(firstPlace), "\n");
2666         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2667
2668         RandomSelection_Init();
2669         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2670                 if(i != firstPlace)
2671                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2672         secondPlace = RandomSelection_chosen_float;
2673         secondPlaceVotes = RandomSelection_best_priority;
2674         //dprint("Second place: ", ftos(secondPlace), "\n");
2675         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2676
2677         if(firstPlace == -1)
2678                 error("No first place in map vote... WTF?");
2679
2680         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2681                 return MapVote_Finished(firstPlace);
2682
2683         if(mapvote_keeptwotime)
2684                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2685                 {
2686                         float didntvote;
2687                         MapVote_TouchMask();
2688                         mapvote_message = "Now decide between the TOP TWO!";
2689                         mapvote_keeptwotime = 0;
2690                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2691                         result = strcat(result, ":", ftos(firstPlaceVotes));
2692                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2693                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2694                         didntvote = mapvote_voters;
2695                         for(i = 0; i < mapvote_count; ++i)
2696                                 if(mapvote_maps[i] != "")
2697                                 {
2698                                         didntvote -= mapvote_votes[i];
2699                                         if(i != firstPlace)
2700                                                 if(i != secondPlace)
2701                                                 {
2702                                                         result = strcat(result, ":", mapvote_maps[i]);
2703                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2704                                                         if(i < mapvote_count_real)
2705                                                         {
2706                                                                 strunzone(mapvote_maps[i]);
2707                                                                 mapvote_maps[i] = "";
2708                                                                 strunzone(mapvote_maps_pakfile[i]);
2709                                                                 mapvote_maps_pakfile[i] = "";
2710                                                         }
2711                                                 }
2712                                 }
2713                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2714                         if(autocvar_sv_eventlog)
2715                                 GameLogEcho(result);
2716                 }
2717
2718         return FALSE;
2719 }
2720 void MapVote_Tick()
2721 {
2722         float keeptwo;
2723         float totalvotes;
2724
2725         keeptwo = mapvote_keeptwotime;
2726         MapVote_CheckRules_1(); // count
2727         if(MapVote_CheckRules_2()) // decide
2728                 return;
2729
2730         totalvotes = 0;
2731         FOR_EACH_REALCLIENT(other)
2732         {
2733                 // hide scoreboard again
2734                 if(other.health != 2342)
2735                 {
2736                         other.health = 2342;
2737                         other.impulse = 0;
2738                         if(clienttype(other) == CLIENTTYPE_REAL)
2739                         {
2740                                 msg_entity = other;
2741                                 WriteByte(MSG_ONE, SVC_FINALE);
2742                                 WriteString(MSG_ONE, "");
2743                         }
2744                 }
2745
2746                 // clear possibly invalid votes
2747                 if(mapvote_maps[other.mapvote - 1] == "")
2748                         other.mapvote = 0;
2749                 // use impulses as new vote
2750                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2751                         if(mapvote_maps[other.impulse - 1] != "")
2752                         {
2753                                 other.mapvote = other.impulse;
2754                                 MapVote_TouchVotes(other);
2755                         }
2756                 other.impulse = 0;
2757
2758                 if(other.mapvote)
2759                         ++totalvotes;
2760         }
2761
2762         MapVote_CheckRules_1(); // just count
2763 }
2764 void MapVote_Start()
2765 {
2766         if(mapvote_run)
2767                 return;
2768
2769         // wait for stats to be sent first
2770         if(!playerstats_waitforme)
2771                 return;
2772
2773         MapInfo_Enumerate();
2774         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2775                 mapvote_run = TRUE;
2776 }
2777 void MapVote_Think()
2778 {
2779         if(!mapvote_run)
2780                 return;
2781
2782         if(alreadychangedlevel)
2783                 return;
2784
2785         if(time < mapvote_nextthink)
2786                 return;
2787         //dprint("tick\n");
2788
2789         mapvote_nextthink = time + 0.5;
2790
2791         if(!mapvote_initialized)
2792         {
2793                 if(autocvar_rescan_pending == 1)
2794                 {
2795                         cvar_set("rescan_pending", "2");
2796                         localcmd("fs_rescan\nrescan_pending 3\n");
2797                         return;
2798                 }
2799                 else if(autocvar_rescan_pending == 2)
2800                 {
2801                         return;
2802                 }
2803                 else if(autocvar_rescan_pending == 3)
2804                 {
2805                         // now build missing mapinfo files
2806                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2807                                 return;
2808
2809                         // we're done, start the timer
2810                         cvar_set("rescan_pending", "0");
2811                 }
2812
2813                 mapvote_initialized = TRUE;
2814                 if(DoNextMapOverride())
2815                         return;
2816                 if(!autocvar_g_maplist_votable || player_count <= 0)
2817                 {
2818                         GotoNextMap();
2819                         return;
2820                 }
2821                 MapVote_Init();
2822         }
2823
2824         MapVote_Tick();
2825 }
2826
2827 string GotoMap(string m)
2828 {
2829         if(!MapInfo_CheckMap(m))
2830                 return "The map you chose is not available on this server.";
2831         cvar_set("nextmap", m);
2832         cvar_set("timelimit", "-1");
2833         if(mapvote_initialized || alreadychangedlevel)
2834         {
2835                 if(DoNextMapOverride())
2836                         return "Map switch initiated.";
2837                 else
2838                         return "Hm... no. For some reason I like THIS map more.";
2839         }
2840         else
2841                 return "Map switch will happen after scoreboard.";
2842 }
2843
2844
2845 void EndFrame()
2846 {
2847         float altime;
2848         FOR_EACH_REALCLIENT(self)
2849         {
2850                 if(self.classname == "spectator")
2851                 {
2852                         if(self.enemy.typehitsound)
2853                                 self.typehit_time = time;
2854                         else if(self.enemy.hitsound)
2855                                 self.hit_time = time;
2856                 }
2857                 else
2858                 {
2859                         if(self.typehitsound)
2860                                 self.typehit_time = time;
2861                         else if(self.hitsound)
2862                                 self.hit_time = time;
2863                 }
2864         }
2865         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2866         // add 1 frametime because after this, engine SV_Physics
2867         // increases time by a frametime and then networks the frame
2868         // add another frametime because client shows everything with
2869         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2870         // needed!
2871         FOR_EACH_CLIENT(self)
2872         {
2873                 self.hitsound = FALSE;
2874                 self.typehitsound = FALSE;
2875                 antilag_record(self, altime);
2876         }
2877 }
2878
2879
2880 /*
2881  * RedirectionThink:
2882  * returns TRUE if redirecting
2883  */
2884 float redirection_timeout;
2885 float redirection_nextthink;
2886 float RedirectionThink()
2887 {
2888         float clients_found;
2889
2890         if(redirection_target == "")
2891                 return FALSE;
2892
2893         if(!redirection_timeout)
2894         {
2895                 cvar_set("sv_public", "-2");
2896                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2897                 if(redirection_target == "self")
2898                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2899                 else
2900                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2901         }
2902
2903         if(time < redirection_nextthink)
2904                 return TRUE;
2905
2906         redirection_nextthink = time + 1;
2907
2908         clients_found = 0;
2909         FOR_EACH_REALCLIENT(self)
2910         {
2911                 print("Redirecting: sending connect command to ", self.netname, "\n");
2912                 if(redirection_target == "self")
2913                         stuffcmd(self, "\ndisconnect; reconnect\n");
2914                 else
2915                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2916                 ++clients_found;
2917         }
2918
2919         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2920
2921         if(time > redirection_timeout || clients_found == 0)
2922                 localcmd("\nwait; wait; wait; quit\n");
2923
2924         return TRUE;
2925 }
2926
2927 void TargetMusic_RestoreGame();
2928 void RestoreGame()
2929 {
2930         // Loaded from a save game
2931         // some things then break, so let's work around them...
2932
2933         // Progs DB (capture records)
2934         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2935
2936         // Mapinfo
2937         MapInfo_Shutdown();
2938         MapInfo_Enumerate();
2939         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2940         WeaponStats_Init();
2941
2942         TargetMusic_RestoreGame();
2943 }
2944
2945 void SV_Shutdown()
2946 {
2947         entity e;
2948
2949         if(gameover > 1) // shutting down already?
2950                 return;
2951
2952         gameover = 2; // 2 = server shutting down
2953
2954         if(world_initialized > 0)
2955         {
2956                 world_initialized = 0;
2957                 print("Saving persistent data...\n");
2958                 Ban_SaveBans();
2959
2960                 PlayerStats_EndMatch(0);
2961                 FOR_EACH_CLIENT(e)
2962                         PlayerStats_AddGlobalInfo(e);
2963                 PlayerStats_Shutdown();
2964
2965                 if(!cheatcount_total)
2966                 {
2967                         if(autocvar_sv_db_saveasdump)
2968                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2969                         else
2970                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2971                 }
2972                 if(autocvar_developer)
2973                 {
2974                         if(autocvar_sv_db_saveasdump)
2975                                 db_dump(TemporaryDB, "server-temp.db");
2976                         else
2977                                 db_save(TemporaryDB, "server-temp.db");
2978                 }
2979                 CheatShutdown(); // must be after cheatcount check
2980                 db_close(ServerProgsDB);
2981                 db_close(TemporaryDB);
2982                 print("done!\n");
2983                 // tell the bot system the game is ending now
2984                 bot_endgame();
2985
2986                 WeaponStats_Shutdown();
2987                 MapInfo_Shutdown();
2988         }
2989         else if(world_initialized == 0)
2990         {
2991                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2992         }
2993 }