qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("serverconfig");
 276                 BADPREFIX("g_ban_");
 277                 BADPREFIX("g_chat_flood_");
 278                 BADPREFIX("g_voice_flood_");
 279                 BADPREFIX("rcon_");
 280                 BADPREFIX("settemp_");
 281                 BADPREFIX("sv_allowdownloads_");
 282                 BADPREFIX("sv_autodemo");
 283                 BADPREFIX("sv_curl_");
 284                 BADPREFIX("sv_eventlog");
 285                 BADPREFIX("sv_logscores_");
 286                 BADPREFIX("sv_master");
 287                 BADCVAR("g_banned_list");
 288                 BADCVAR("log_dest_udp");
 289                 BADCVAR("log_file");
 290                 BADCVAR("net_address");
 291                 BADCVAR("port");
 292                 BADCVAR("savedgamecfg");
 293                 BADCVAR("sv_heartbeatperiod");
 294                 BADCVAR("sv_vote_master_password");
 295                 BADCVAR("sys_colortranslation");
 296                 BADCVAR("sys_specialcharactertranslation");
 297                 BADCVAR("timestamps");
 298                 BADCVAR("net_address");
 299                 BADCVAR("net_address_ipv6");
 300                 BADPREFIX("sv_weaponstats_");
 301                 BADCVAR("developer");
 302                 BADPREFIX("developer_");
 303
 304                 // mapinfo
 305                 BADCVAR("timelimit");
 306                 BADCVAR("fraglimit");
 307                 BADCVAR("g_arena");
 308                 BADCVAR("g_ca");
 309                 BADCVAR("g_assault");
 310                 BADCVAR("g_ctf");
 311                 BADCVAR("g_dm");
 312                 BADCVAR("g_domination");
 313                 BADCVAR("g_keyhunt");
 314                 BADCVAR("g_keyhunt_teams");
 315                 BADCVAR("g_onslaught");
 316                 BADCVAR("g_race");
 317                 BADCVAR("g_cts");
 318                 BADCVAR("g_runematch");
 319                 BADCVAR("g_tdm");
 320                 BADCVAR("g_nexball");
 321                 BADCVAR("teamplay");
 322
 323                 // long
 324                 BADCVAR("hostname");
 325                 BADCVAR("g_maplist");
 326                 BADCVAR("g_maplist_mostrecent");
 327                 BADCVAR("sv_motd");
 328
 329                 v = cvar_string(k);
 330                 d = cvar_defstring(k);
 331                 if(v == d)
 332                         continue;
 333
 334                 if(adding)
 335                 {
 336                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 337                         if(strlen(cvar_changes) > 16384)
 338                         {
 339                                 cvar_changes = "// too many settings have been changed to show them here\n";
 340                                 adding = 0;
 341                         }
 342                 }
 343
 344                 // now check if the changes are actually gameplay relevant
 345
 346                 // does nothing visible
 347                 BADPREFIX("prvm_");
 348                 BADPREFIX("crypto_");
 349                 BADPREFIX("g_chat_");
 350                 BADPREFIX("sv_fragmessage_");
 351                 BADPREFIX("sv_vote_");
 352                 BADPREFIX("timelimit_");
 353
 354                 // allowed changes to server admins (please sync this to server.cfg)
 355                 // vi commands:
 356                 //   :/"impure"/,$d
 357                 //   :g!,^\/\/[^ /],d
 358                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 359                 //   :%!sort
 360                 // yes, this does contain some redundant stuff, don't really care
 361                 BADCVAR("bot_number");
 362                 BADCVAR("bot_prefix");
 363                 BADCVAR("bot_suffix");
 364                 BADCVAR("capturelimit_override");
 365                 BADCVAR("fraglimit_override");
 366                 BADCVAR("gametype");
 367                 BADCVAR("g_antilag");
 368                 BADCVAR("g_balance_teams");
 369                 BADCVAR("g_balance_teams_force");
 370                 BADCVAR("g_ban_sync_trusted_servers");
 371                 BADCVAR("g_ban_sync_uri");
 372                 BADCVAR("g_ctf_capture_limit");
 373                 BADCVAR("g_ctf_ignore_frags");
 374                 BADCVAR("g_ctf_win_mode");
 375                 BADCVAR("g_domination_point_limit");
 376                 BADCVAR("g_fullbrightitems");
 377                 BADCVAR("g_fullbrightplayers");
 378                 BADCVAR("g_keyhunt_point_limit");
 379                 BADCVAR("g_keyhunt_teams_override");
 380                 BADCVAR("g_lms_lives_override");
 381                 BADCVAR("g_maplist");
 382                 BADCVAR("g_maplist_check_waypoints");
 383                 BADCVAR("g_maplist_mostrecent_count");
 384                 BADCVAR("g_maplist_shuffle");
 385                 BADCVAR("g_maplist_votable");
 386                 BADCVAR("g_maplist_votable_abstain");
 387                 BADCVAR("g_maplist_votable_nodetail");
 388                 BADCVAR("g_maplist_votable_suggestions");
 389                 BADCVAR("g_nexball_goallimit");
 390                 BADCVAR("g_runematch_point_limit");
 391                 BADCVAR("g_start_delay");
 392                 BADCVAR("hostname");
 393                 BADCVAR("log_file");
 394                 BADCVAR("maxplayers");
 395                 BADCVAR("minplayers");
 396                 BADCVAR("net_address");
 397                 BADCVAR("port");
 398                 BADCVAR("rcon_password");
 399                 BADCVAR("rcon_restricted_commands");
 400                 BADCVAR("rcon_restricted_password");
 401                 BADCVAR("skill");
 402                 BADCVAR("sv_autoscreenshot");
 403                 BADCVAR("sv_curl_defaulturl");
 404                 BADCVAR("sv_defaultcharacter");
 405                 BADCVAR("sv_defaultplayermodel");
 406                 BADCVAR("sv_defaultplayerskin");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_maxidle");
 409                 BADCVAR("sv_motd");
 410                 BADCVAR("sv_public");
 411                 BADCVAR("sv_ready_restart");
 412                 BADCVAR("sv_status_privacy");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("timelimit_override");
 421 #undef BADPREFIX
 422 #undef BADCVAR
 423
 424                 if(pureadding)
 425                 {
 426                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 427                         if(strlen(cvar_purechanges) > 16384)
 428                         {
 429                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 430                                 pureadding = 0;
 431                         }
 432                 }
 433                 ++cvar_purechanges_count;
 434         }
 435         buf_del(h);
 436         if(cvar_changes == "")
 437                 cvar_changes = "// this server runs at default server settings\n";
 438         else
 439                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 440         cvar_changes = strzone(cvar_changes);
 441         if(cvar_purechanges == "")
 442                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 443         else
 444                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 445         cvar_purechanges = strzone(cvar_purechanges);
 446 }
 447
 448 void detect_maptype()
 449 {
 450 #if 0
 451         vector o, v;
 452         float i;
 453
 454         for(;;)
 455         {
 456                 o = world.mins;
 457                 o_x += random() * (world.maxs_x - world.mins_x);
 458                 o_y += random() * (world.maxs_y - world.mins_y);
 459                 o_z += random() * (world.maxs_z - world.mins_z);
 460
 461                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 462                 if(trace_fraction == 1)
 463                         continue;
 464
 465                 v = trace_endpos;
 466
 467                 for(i = 0; i < 64; i += 4)
 468                 {
 469                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 470         if(trace_fraction == 1)
 471                 continue;
 472                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 473                 }
 474
 475                 break;
 476         }
 477 #endif
 478 }
 479
 480 entity randomseed;
 481 float RandomSeed_Send(entity to, float sf)
 482 {
 483         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 484         WriteShort(MSG_ENTITY, self.cnt);
 485         return TRUE;
 486 }
 487 void RandomSeed_Think()
 488 {
 489         self.cnt = bound(0, floor(random() * 65536), 65535);
 490         self.nextthink = time + 5;
 491
 492         self.SendFlags |= 1;
 493 }
 494 void RandomSeed_Spawn()
 495 {
 496         randomseed = spawn();
 497         randomseed.think = RandomSeed_Think;
 498         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 499
 500         entity oldself;
 501         oldself = self;
 502         self = randomseed;
 503         self.think(); // sets random seed and nextthink
 504         self = oldself;
 505 }
 506
 507 void spawnfunc___init_dedicated_server(void)
 508 {
 509         // handler for _init/_init map (only for dedicated server initialization)
 510
 511         world_initialized = -1; // don't complain
 512         cvar = cvar_normal;
 513         cvar_string = cvar_string_normal;
 514         cvar_set = cvar_set_normal;
 515
 516         remove = remove_unsafely;
 517
 518         entity e;
 519         e = spawn();
 520         e.think = GotoFirstMap;
 521         e.nextthink = time; // this is usually 1 at this point
 522
 523         e = spawn();
 524         e.classname = "info_player_deathmatch"; // safeguard against player joining
 525
 526         self.classname = "worldspawn"; // safeguard against various stuff ;)
 527
 528         MapInfo_Enumerate();
 529         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 530 }
 531
 532 void Map_MarkAsRecent(string m);
 533 float world_already_spawned;
 534 void RegisterWeapons();
 535 void Nagger_Init();
 536 void ClientInit_Spawn();
 537 void WeaponStats_Init();
 538 void WeaponStats_Shutdown();
 539 void spawnfunc_worldspawn (void)
 540 {
 541         float fd, l, i, j, n;
 542         string s, col;
 543
 544         cvar = cvar_normal;
 545         cvar_string = cvar_string_normal;
 546         cvar_set = cvar_set_normal;
 547
 548         if(world_already_spawned)
 549                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 550         world_already_spawned = TRUE;
 551
 552         remove = remove_safely; // during spawning, watch what you remove!
 553
 554         check_unacceptable_compiler_bugs();
 555
 556         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 557
 558         compressShortVector_init();
 559
 560         allowed_to_spawn = TRUE;
 561
 562         local entity head;
 563         head = nextent(world);
 564         maxclients = 0;
 565         while(head)
 566         {
 567                 ++maxclients;
 568                 head = nextent(head);
 569         }
 570
 571         // needs to be done so early as they would still spawn
 572         RegisterWeapons();
 573
 574         ServerProgsDB = db_load("server.db");
 575
 576         TemporaryDB = db_create();
 577
 578         /*
 579         TODO sound pack system
 580         // initialize sound pack system
 581         soundpack = cvar_string("g_soundpack");
 582         if(soundpack != "")
 583                 soundpack = strcat(soundpack, "/");
 584         soundpack = strzone(soundpack);
 585         */
 586
 587         // 0 normal
 588         lightstyle(0, "m");
 589
 590         // 1 FLICKER (first variety)
 591         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 592
 593         // 2 SLOW STRONG PULSE
 594         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 595
 596         // 3 CANDLE (first variety)
 597         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 598
 599         // 4 FAST STROBE
 600         lightstyle(4, "mamamamamama");
 601
 602         // 5 GENTLE PULSE 1
 603         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 604
 605         // 6 FLICKER (second variety)
 606         lightstyle(6, "nmonqnmomnmomomno");
 607
 608         // 7 CANDLE (second variety)
 609         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 610
 611         // 8 CANDLE (third variety)
 612         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 613
 614         // 9 SLOW STROBE (fourth variety)
 615         lightstyle(9, "aaaaaaaazzzzzzzz");
 616
 617         // 10 FLUORESCENT FLICKER
 618         lightstyle(10, "mmamammmmammamamaaamammma");
 619
 620         // 11 SLOW PULSE NOT FADE TO BLACK
 621         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 622
 623         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 624
 625         // 63 testing
 626         lightstyle(63, "a");
 627
 628         if(cvar("g_campaign"))
 629                 CampaignPreInit();
 630
 631         Map_MarkAsRecent(mapname);
 632
 633         precache_model ("null"); // we need this one before InitGameplayMode
 634         InitGameplayMode();
 635         readlevelcvars();
 636         GrappleHookInit();
 637         ElectroInit();
 638         LaserInit();
 639
 640         player_count = 0;
 641         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 642         if(bot_waypoints_for_items == 1)
 643                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 644                         bot_waypoints_for_items = 0;
 645
 646         // for setting by mapinfo
 647         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 648         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 649
 650         precache();
 651
 652         WaypointSprite_Init();
 653
 654         //if (g_domination)
 655         //      dom_init();
 656
 657         GameLogInit(); // prepare everything
 658         if(cvar("sv_eventlog"))
 659         {
 660                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 661                 s = strcat(s, ftos(random()));
 662                 matchid = strzone(s);
 663
 664                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 665                 s = ":gameinfo:mutators:LIST";
 666
 667                 ret_string = s;
 668                 MUTATOR_CALLHOOK(BuildMutatorsString);
 669                 s = ret_string;
 670
 671                 if(cvar("g_grappling_hook"))
 672                         s = strcat(s, ":grappling_hook");
 673                 if(!cvar("g_use_ammunition"))
 674                         s = strcat(s, ":no_use_ammunition");
 675                 if(!cvar("g_pickup_items"))
 676                         s = strcat(s, ":no_pickup_items");
 677                 if(cvar_string("g_weaponarena") != "0")
 678                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 679                 if(cvar("g_vampire"))
 680                         s = strcat(s, ":vampire");
 681                 if(cvar("g_laserguided_missile"))
 682                         s = strcat(s, ":laserguided_missile");
 683                 if(cvar("g_norecoil"))
 684                         s = strcat(s, ":norecoil");
 685                 if(cvar("g_midair"))
 686                         s = strcat(s, ":midair");
 687                 if(cvar("g_minstagib"))
 688                         s = strcat(s, ":minstagib");
 689                 GameLogEcho(s);
 690                 GameLogEcho(":gameinfo:end");
 691         }
 692         else
 693                 matchid = strzone(ftos(random()));
 694
 695         cvar_set("nextmap", "");
 696
 697         SetDefaultAlpha();
 698
 699         if(cvar("g_campaign"))
 700                 CampaignPostInit();
 701
 702         fteqcc_testbugs();
 703
 704         Ban_LoadBans();
 705
 706         MapInfo_Enumerate();
 707         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 708
 709         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 710         {
 711                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 712                 if(fd != -1)
 713                 {
 714                         while((s = fgets(fd)))
 715                         {
 716                                 l = tokenize_console(s);
 717                                 if(l < 2)
 718                                         continue;
 719                                 if(argv(0) == "cd")
 720                                 {
 721                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 722                                         print("  cdtrack ", argv(2), "\n");
 723                                 }
 724                                 else if(argv(0) == "fog")
 725                                 {
 726                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 727                                         print("  \"fog\" \"", s, "\"\n");
 728                                 }
 729                                 else if(argv(0) == "set")
 730                                 {
 731                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 732                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 733                                 }
 734                                 else if(argv(0) != "//")
 735                                 {
 736                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 737                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 738                                 }
 739                         }
 740                         fclose(fd);
 741                 }
 742         }
 743
 744         WeaponStats_Init();
 745
 746         addstat(STAT_WEAPONS, AS_INT, weapons);
 747         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 748         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 749         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 750         Nagger_Init();
 751
 752         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 753         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 754         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 755         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 756         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 757         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 758         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 759         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 760         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 761         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 762
 763         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 764
 765         if(g_ca)
 766         {
 767                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 768                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 769         }
 770         // g_movementspeed hack
 771         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 772         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 773         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 774
 775         next_pingtime = time + 5;
 776
 777         detect_maptype();
 778
 779         lsmaps_reply = "^7Maps available: ";
 780         lsnewmaps_reply = "^7Maps without a record set: ";
 781         for(i = 0, j = 0; i < MapInfo_count; ++i)
 782         {
 783                 if(MapInfo_Get_ByID(i))
 784                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 785                         {
 786                                 if(mod(i, 2))
 787                                         col = "^2";
 788                                 else
 789                                         col = "^3";
 790                                 ++j;
 791                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 792                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 793                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 794                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 795                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 796                         }
 797         }
 798         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 799         if (!g_race && !g_cts)
 800                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 801         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 802
 803         maplist_reply = "^7Maps in list: ";
 804         n = tokenize_console(cvar_string("g_maplist"));
 805         for(i = 0, j = 0; i < n; ++i)
 806         {
 807                 if(MapInfo_CheckMap(argv(i)))
 808                 {
 809                         if(mod(j, 2))
 810                                 col = "^2";
 811                         else
 812                                 col = "^3";
 813                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 814                         ++j;
 815                 }
 816         }
 817         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 818         MapInfo_ClearTemps();
 819
 820         for(i = 0; i < 10; ++i)
 821         {
 822                 records_reply[i] = strzone(getrecords(i));
 823         }
 824
 825         rankings_reply = strzone(getrankings());
 826
 827         ClientInit_Spawn();
 828         RandomSeed_Spawn();
 829         PingPLReport_Spawn();
 830
 831         CheatInit();
 832
 833         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 834
 835         // fill sv_curl_serverpackages from .serverpackage files
 836         if(cvar("sv_curl_serverpackages_auto"))
 837         {
 838                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 839                 s = "";
 840                 if(fd >= 0)
 841                 {
 842                         j = search_getsize(fd);
 843                         for(i = 0; i < j; ++i)
 844                                 s = strcat(s, " ", search_getfilename(fd, i));
 845                         search_end(fd);
 846                 }
 847                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 848         }
 849
 850         world_initialized = 1;
 851 }
 852
 853 void spawnfunc_light (void)
 854 {
 855         //makestatic (self); // Who the f___ did that?
 856         remove(self);
 857 }
 858
 859 float TryFile( string pFilename )
 860 {
 861         local float lHandle;
 862         dprint("TryFile(\"", pFilename, "\")\n");
 863         lHandle = fopen( pFilename, FILE_READ );
 864         if( lHandle != -1 ) {
 865                 fclose( lHandle );
 866                 return TRUE;
 867         } else {
 868                 return FALSE;
 869         }
 870 };
 871
 872 string GetGametype()
 873 {
 874         return GametypeNameFromType(game);
 875 }
 876
 877 string getmapname_stored;
 878 string GetMapname()
 879 {
 880         return mapname;
 881 }
 882
 883 float Map_Count, Map_Current;
 884 string Map_Current_Name;
 885
 886 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 887 float GetMaplistPosition()
 888 {
 889         float pos, idx;
 890         string map;
 891
 892         map = GetMapname();
 893         idx = cvar("g_maplist_index");
 894
 895         if(idx >= 0)
 896                 if(idx < Map_Count)
 897                         if(map == argv(idx))
 898                                 return idx;
 899
 900         for(pos = 0; pos < Map_Count; ++pos)
 901                 if(map == argv(pos))
 902                         return pos;
 903
 904         // resume normal maplist rotation if current map is not in g_maplist
 905         return idx;
 906 }
 907
 908 float MapHasRightSize(string map)
 909 {
 910         float fh;
 911         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 912         if(cvar("g_maplist_check_waypoints"))
 913         {
 914                 dprint("checkwp "); dprint(map);
 915                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 916                 if(fh < 0)
 917                 {
 918                         dprint(": no waypoints\n");
 919                         return FALSE;
 920                 }
 921                 dprint(": has waypoints\n");
 922                 fclose(fh);
 923         }
 924
 925         // open map size restriction file
 926         dprint("opensize "); dprint(map);
 927         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 928         if(fh >= 0)
 929         {
 930                 float mapmin, mapmax;
 931                 dprint(": ok, ");
 932                 mapmin = stof(fgets(fh));
 933                 mapmax = stof(fgets(fh));
 934                 fclose(fh);
 935                 if(player_count < mapmin)
 936                 {
 937                         dprint("not enough\n");
 938                         return FALSE;
 939                 }
 940                 if(player_count > mapmax)
 941                 {
 942                         dprint("too many\n");
 943                         return FALSE;
 944                 }
 945                 dprint("right size\n");
 946                 return TRUE;
 947         }
 948         dprint(": not found\n");
 949         return TRUE;
 950 }
 951
 952 string Map_Filename(float position)
 953 {
 954         return strcat("maps/", argv(position), ".bsp");
 955 }
 956
 957 string strwords(string s, float w)
 958 {
 959         float endpos;
 960         for(endpos = 0; w && endpos >= 0; --w)
 961                 endpos = strstrofs(s, " ", endpos + 1);
 962         if(endpos < 0)
 963                 return s;
 964         else
 965                 return substring(s, 0, endpos);
 966 }
 967
 968 float strhasword(string s, string w)
 969 {
 970         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 971 }
 972
 973 void Map_MarkAsRecent(string m)
 974 {
 975         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 976 }
 977
 978 float Map_IsRecent(string m)
 979 {
 980         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 981 }
 982
 983 float Map_Check(float position, float pass)
 984 {
 985         string filename;
 986         string map_next;
 987         map_next = argv(position);
 988         if(pass <= 1)
 989         {
 990                 if(Map_IsRecent(map_next))
 991                         return 0;
 992         }
 993         filename = Map_Filename(position);
 994         if(MapInfo_CheckMap(map_next))
 995         {
 996                 if(pass == 2)
 997                         return 1;
 998                 if(MapHasRightSize(map_next))
 999                         return 1;
1000                 return 0;
1001         }
1002         else
1003                 dprint( "Couldn't select '", filename, "'..\n" );
1004
1005         return 0;
1006 }
1007
1008 void Map_Goto_SetStr(string nextmapname)
1009 {
1010         if(getmapname_stored != "")
1011                 strunzone(getmapname_stored);
1012         if(nextmapname == "")
1013                 getmapname_stored = "";
1014         else
1015                 getmapname_stored = strzone(nextmapname);
1016 }
1017
1018 void Map_Goto_SetFloat(float position)
1019 {
1020         cvar_set("g_maplist_index", ftos(position));
1021         Map_Goto_SetStr(argv(position));
1022 }
1023
1024 void GameResetCfg()
1025 {
1026         // settings persist, except...
1027         localcmd("\nsettemp_restore\n");
1028 };
1029
1030 void Map_Goto()
1031 {
1032         GameResetCfg();
1033         MapInfo_LoadMap(getmapname_stored);
1034 }
1035
1036 // return codes of map selectors:
1037 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1038 //   -2 = permanent failure
1039 float() MaplistMethod_Iterate = // usual method
1040 {
1041         float pass, i;
1042
1043         for(pass = 1; pass <= 2; ++pass)
1044         {
1045                 for(i = 1; i < Map_Count; ++i)
1046                 {
1047                         float mapindex;
1048                         mapindex = mod(i + Map_Current, Map_Count);
1049                         if(Map_Check(mapindex, pass))
1050                                 return mapindex;
1051                 }
1052         }
1053         return -1;
1054 }
1055
1056 float() MaplistMethod_Repeat = // fallback method
1057 {
1058         if(Map_Check(Map_Current, 2))
1059                 return Map_Current;
1060         return -2;
1061 }
1062
1063 float() MaplistMethod_Random = // random map selection
1064 {
1065         float i, imax;
1066
1067         imax = 42;
1068
1069         for(i = 0; i <= imax; ++i)
1070         {
1071                 float mapindex;
1072                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1073                 if(Map_Check(mapindex, 1))
1074                         return mapindex;
1075         }
1076         return -1;
1077 }
1078
1079 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1080 // the exponent sets a bias on the map selection:
1081 // the higher the exponent, the less likely "shortly repeated" same maps are
1082 {
1083         float i, j, imax, insertpos;
1084
1085         imax = 42;
1086
1087         for(i = 0; i <= imax; ++i)
1088         {
1089                 string newlist;
1090
1091                 // now reinsert this at another position
1092                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1093                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1094                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1095                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1096
1097                 // insert the current map there
1098                 newlist = "";
1099                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1100                         newlist = strcat(newlist, " ", argv(j));
1101                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1102                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1103                         newlist = strcat(newlist, " ", argv(j));
1104                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1105                 cvar_set("g_maplist", newlist);
1106                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1107
1108                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1109                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1110                 if(Map_Check(Map_Current, 1))
1111                         return Map_Current;
1112         }
1113         return -1;
1114 }
1115
1116 void Maplist_Init()
1117 {
1118         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1119         if(Map_Count == 0)
1120         {
1121                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1122                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1123                 if(cvar("g_maplist_shuffle"))
1124                         ShuffleMaplist();
1125                 localcmd("\nmenu_cmd sync\n");
1126                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1127         }
1128         if(Map_Count == 0)
1129                 error("empty maplist, cannot select a new map");
1130         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1131
1132         if(Map_Current_Name)
1133                 strunzone(Map_Current_Name);
1134         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1135         // this may or may not be correct, but who cares, in the worst case a map
1136         // isn't chosen in the first pass that should have been
1137 }
1138
1139 string GetNextMap()
1140 {
1141         float nextMap;
1142
1143         Maplist_Init();
1144         nextMap = -1;
1145
1146         if(nextMap == -1)
1147                 if(cvar("g_maplist_shuffle") > 0)
1148                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1149
1150         if(nextMap == -1)
1151                 if(cvar("g_maplist_selectrandom"))
1152                         nextMap = MaplistMethod_Random();
1153
1154         if(nextMap == -1)
1155                 nextMap = MaplistMethod_Iterate();
1156
1157         if(nextMap == -1)
1158                 nextMap = MaplistMethod_Repeat();
1159
1160         if(nextMap >= 0)
1161         {
1162                 Map_Goto_SetFloat(nextMap);
1163                 return getmapname_stored;
1164         }
1165
1166         return "";
1167 };
1168
1169 float DoNextMapOverride()
1170 {
1171         if(cvar("g_campaign"))
1172         {
1173                 CampaignPostIntermission();
1174                 alreadychangedlevel = TRUE;
1175                 return TRUE;
1176         }
1177         if(cvar("quit_when_empty"))
1178         {
1179                 if(player_count <= currentbots)
1180                 {
1181                         localcmd("quit\n");
1182                         alreadychangedlevel = TRUE;
1183                         return TRUE;
1184                 }
1185         }
1186         if(cvar_string("quit_and_redirect") != "")
1187         {
1188                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1189                 alreadychangedlevel = TRUE;
1190                 return TRUE;
1191         }
1192         if (cvar("samelevel")) // if samelevel is set, stay on same level
1193         {
1194                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1195                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1196                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1197                 localcmd("restart\n");
1198                 //changelevel (mapname);
1199                 alreadychangedlevel = TRUE;
1200                 return TRUE;
1201         }
1202         if(cvar_string("nextmap") != "")
1203                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1204                 {
1205                         Map_Goto_SetStr(cvar_string("nextmap"));
1206                         Map_Goto();
1207                         alreadychangedlevel = TRUE;
1208                         return TRUE;
1209                 }
1210         if(cvar("lastlevel"))
1211         {
1212                 GameResetCfg();
1213                 localcmd("set lastlevel 0\ntogglemenu\n");
1214                 alreadychangedlevel = TRUE;
1215                 return TRUE;
1216         }
1217         return FALSE;
1218 };
1219
1220 void GotoNextMap()
1221 {
1222         //local string nextmap;
1223         //local float n, nummaps;
1224         //local string s;
1225         if (alreadychangedlevel)
1226                 return;
1227         alreadychangedlevel = TRUE;
1228
1229         {
1230                 string nextMap;
1231                 float allowReset;
1232
1233                 for(allowReset = 1; allowReset >= 0; --allowReset)
1234                 {
1235                         nextMap = GetNextMap();
1236                         if(nextMap != "")
1237                                 break;
1238
1239                         if(allowReset)
1240                         {
1241                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1242                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1243                                 if(cvar("g_maplist_shuffle"))
1244                                         ShuffleMaplist();
1245                                 localcmd("\nmenu_cmd sync\n");
1246                         }
1247                         else
1248                         {
1249                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1250                         }
1251                 }
1252                 Map_Goto();
1253         }
1254 };
1255
1256
1257 /*
1258 ============
1259 IntermissionThink
1260
1261 When the player presses attack or jump, change to the next level
1262 ============
1263 */
1264 .float autoscreenshot;
1265 void() MapVote_Start;
1266 void() MapVote_Think;
1267 float mapvote_initialized;
1268 void IntermissionThink()
1269 {
1270         FixIntermissionClient(self);
1271
1272         if(cvar("sv_autoscreenshot"))
1273         if(self.autoscreenshot > 0)
1274         if(time > self.autoscreenshot)
1275         {
1276                 self.autoscreenshot = -1;
1277                 if(clienttype(self) == CLIENTTYPE_REAL)
1278                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1279                 return;
1280         }
1281
1282         if (time < intermission_exittime)
1283                 return;
1284
1285         if(!mapvote_initialized)
1286                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1287                         return;
1288
1289         MapVote_Start();
1290 };
1291
1292 /*
1293 ============
1294 FindIntermission
1295
1296 Returns the entity to view from
1297 ============
1298 */
1299 /*
1300 entity FindIntermission()
1301 {
1302         local   entity spot;
1303         local   float cyc;
1304
1305 // look for info_intermission first
1306         spot = find (world, classname, "info_intermission");
1307         if (spot)
1308         {       // pick a random one
1309                 cyc = random() * 4;
1310                 while (cyc > 1)
1311                 {
1312                         spot = find (spot, classname, "info_intermission");
1313                         if (!spot)
1314                                 spot = find (spot, classname, "info_intermission");
1315                         cyc = cyc - 1;
1316                 }
1317                 return spot;
1318         }
1319
1320 // then look for the start position
1321         spot = find (world, classname, "info_player_start");
1322         if (spot)
1323                 return spot;
1324
1325 // testinfo_player_start is only found in regioned levels
1326         spot = find (world, classname, "testplayerstart");
1327         if (spot)
1328                 return spot;
1329
1330 // then look for the start position
1331         spot = find (world, classname, "info_player_deathmatch");
1332         if (spot)
1333                 return spot;
1334
1335         //objerror ("FindIntermission: no spot");
1336         return world;
1337 };
1338 */
1339
1340 /*
1341 ===============================================================================
1342
1343 RULES
1344
1345 ===============================================================================
1346 */
1347
1348 void DumpStats(float final)
1349 {
1350         local float file;
1351         local string s;
1352         local float to_console;
1353         local float to_eventlog;
1354         local float to_file;
1355         local float i;
1356
1357         to_console = cvar("sv_logscores_console");
1358         to_eventlog = cvar("sv_eventlog");
1359         to_file = cvar("sv_logscores_file");
1360
1361         if(!final)
1362         {
1363                 to_console = TRUE; // always print printstats replies
1364                 to_eventlog = FALSE; // but never print them to the event log
1365         }
1366
1367         if(to_eventlog)
1368                 if(cvar("sv_eventlog_console"))
1369                         to_console = FALSE; // otherwise we get the output twice
1370
1371         if(final)
1372                 s = ":scores:";
1373         else
1374                 s = ":status:";
1375         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1376
1377         if(to_console)
1378                 print(s, "\n");
1379         if(to_eventlog)
1380                 GameLogEcho(s);
1381         if(to_file)
1382         {
1383                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1384                 if(file == -1)
1385                         to_file = FALSE;
1386                 else
1387                         fputs(file, strcat(s, "\n"));
1388         }
1389
1390         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1391         if(to_console)
1392                 print(s, "\n");
1393         if(to_eventlog)
1394                 GameLogEcho(s);
1395         if(to_file)
1396                 fputs(file, strcat(s, "\n"));
1397
1398         FOR_EACH_CLIENT(other)
1399         {
1400                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1401                 {
1402                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1403                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1404                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1405                                 s = strcat(s, ftos(other.team), ":");
1406                         else
1407                                 s = strcat(s, "spectator:");
1408
1409                         if(to_console)
1410                                 print(s, other.netname, "\n");
1411                         if(to_eventlog)
1412                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1413                         if(to_file)
1414                                 fputs(file, strcat(s, other.netname, "\n"));
1415                 }
1416         }
1417
1418         if(teams_matter)
1419         {
1420                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1421                 if(to_console)
1422                         print(s, "\n");
1423                 if(to_eventlog)
1424                         GameLogEcho(s);
1425                 if(to_file)
1426                         fputs(file, strcat(s, "\n"));
1427
1428                 for(i = 1; i < 16; ++i)
1429                 {
1430                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1431                         s = strcat(s, ":", ftos(i));
1432                         if(to_console)
1433                                 print(s, "\n");
1434                         if(to_eventlog)
1435                                 GameLogEcho(s);
1436                         if(to_file)
1437                                 fputs(file, strcat(s, "\n"));
1438                 }
1439         }
1440
1441         if(to_console)
1442                 print(":end\n");
1443         if(to_eventlog)
1444                 GameLogEcho(":end");
1445         if(to_file)
1446         {
1447                 fputs(file, ":end\n");
1448                 fclose(file);
1449         }
1450 }
1451
1452 void FixIntermissionClient(entity e)
1453 {
1454         string s;
1455         if(!e.autoscreenshot) // initial call
1456         {
1457                 e.angles = e.v_angle;
1458                 e.angles_x = -e.angles_x;
1459                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1460                 e.health = -2342;
1461                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1462                 e.solid = SOLID_NOT;
1463                 e.movetype = MOVETYPE_NONE;
1464                 e.takedamage = DAMAGE_NO;
1465                 if(e.weaponentity)
1466                 {
1467                         e.weaponentity.effects = EF_NODRAW;
1468                         if (e.weaponentity.weaponentity)
1469                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1470                 }
1471                 if(clienttype(e) == CLIENTTYPE_REAL)
1472                 {
1473                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1474                         s = cvar_string("sv_intermission_cdtrack");
1475                         if(s != "")
1476                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1477                         msg_entity = e;
1478                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1479                 }
1480         }
1481
1482         //e.velocity = '0 0 0';
1483         //e.fixangle = TRUE;
1484
1485         // TODO halt weapon animation
1486 }
1487
1488
1489 /*
1490 go to the next level for deathmatch
1491 only called if a time or frag limit has expired
1492 */
1493 void NextLevel()
1494 {
1495         float i;
1496
1497         gameover = TRUE;
1498
1499         intermission_running = 1;
1500
1501 // enforce a wait time before allowing changelevel
1502         if(player_count > 0)
1503                 intermission_exittime = time + cvar("sv_mapchange_delay");
1504         else
1505                 intermission_exittime = -1;
1506
1507         /*
1508         WriteByte (MSG_ALL, SVC_CDTRACK);
1509         WriteByte (MSG_ALL, 3);
1510         WriteByte (MSG_ALL, 3);
1511         // done in FixIntermission
1512         */
1513
1514         //pos = FindIntermission ();
1515
1516         VoteReset();
1517
1518         DumpStats(TRUE);
1519
1520         if(cvar("sv_eventlog"))
1521                 GameLogEcho(":gameover");
1522
1523         GameLogClose();
1524
1525 // TO DO
1526
1527 // save the stats to a text file on the client
1528 // stuffcmd(other, log_stats "stats/file_name");
1529 // bprint stats
1530 // stuffcmd(other, log_stats "");
1531 // use a filename similar to the demo name
1532         // string file_name;
1533         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1534
1535 // write a stats parser for the menu
1536
1537         if(cvar("sv_accuracy_data_send")) {
1538                 string stats_to_send;
1539
1540                 FOR_EACH_CLIENT(other) {  // make the string to send
1541                         FixIntermissionClient(other);
1542
1543                         if(other.cvar_cl_accuracy_data_share) {
1544                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1545
1546                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1547                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1548
1549                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1550
1551                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1552                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1553
1554                                 stats_to_send = strcat(stats_to_send, "\n");
1555                         }
1556                 }
1557
1558                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1559                         Score_NicePrint(other);  // print the score
1560
1561                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1562                                 bprint(stats_to_send);
1563                 }
1564         } else { // ye olde message
1565                 FOR_EACH_PLAYER(other) {
1566                         FixIntermissionClient(other);
1567
1568                         if(other.winning)
1569                                 bprint(other.netname, " ^7wins.\n");
1570                 }
1571         }
1572
1573         if(cvar("g_campaign"))
1574                 CampaignPreIntermission();
1575
1576         localcmd("\nsv_hook_gameend\n");
1577 }
1578
1579 /*
1580 ============
1581 CheckRules_Player
1582
1583 Exit deathmatch games upon conditions
1584 ============
1585 */
1586 void CheckRules_Player()
1587 {
1588         if (gameover)   // someone else quit the game already
1589                 return;
1590
1591         if(self.deadflag == DEAD_NO)
1592                 self.play_time += frametime;
1593
1594         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1595         //   (div0: and that in CheckRules_World please)
1596 };
1597
1598 float checkrules_equality;
1599 float checkrules_suddendeathwarning;
1600 float checkrules_suddendeathend;
1601 float checkrules_overtimesadded; //how many overtimes have been already added
1602
1603 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1604 float WINNING_YES = 1; // winner found
1605 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1606 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1607
1608 float InitiateSuddenDeath()
1609 {
1610         // Check first whether normal overtimes could be added before initiating suddendeath mode
1611         // - for this timelimit_overtime needs to be >0 of course
1612         // - also check the winning condition calculated in the previous frame and only add normal overtime
1613         //   again, if at the point at which timelimit would be extended again, still no winner was found
1614         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1615         {
1616                 return 1; // need to call InitiateOvertime later
1617         }
1618         else
1619         {
1620                 if(!checkrules_suddendeathend)
1621                 {
1622                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1623                         if(g_race && !g_race_qualifying)
1624                                 race_StartCompleting();
1625                 }
1626                 return 0;
1627         }
1628 }
1629
1630 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1631 {
1632         ++checkrules_overtimesadded;
1633         //add one more overtime by simply extending the timelimit
1634         float tl;
1635         tl = cvar("timelimit");
1636         tl += cvar("timelimit_overtime");
1637         cvar_set("timelimit", ftos(tl));
1638         string minutesPlural;
1639         if (cvar("timelimit_overtime") == 1)
1640                 minutesPlural = " ^3minute";
1641         else
1642                 minutesPlural = " ^3minutes";
1643
1644         bcenterprint(
1645                 strcat(
1646                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1647                         ftos(cvar("timelimit_overtime")),
1648                         minutesPlural,
1649                         " to the game!"
1650                 )
1651         );
1652 }
1653
1654 float GetWinningCode(float fraglimitreached, float equality)
1655 {
1656         if(cvar("g_campaign") == 1)
1657                 if(fraglimitreached)
1658                         return WINNING_YES;
1659                 else
1660                         return WINNING_NO;
1661
1662         else
1663                 if(equality)
1664                         if(fraglimitreached)
1665                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1666                         else
1667                                 return WINNING_NEVER;
1668                 else
1669                         if(fraglimitreached)
1670                                 return WINNING_YES;
1671                         else
1672                                 return WINNING_NO;
1673 }
1674
1675 // set the .winning flag for exactly those players with a given field value
1676 void SetWinners(.float field, float value)
1677 {
1678         entity head;
1679         FOR_EACH_PLAYER(head)
1680                 head.winning = (head.field == value);
1681 }
1682
1683 // set the .winning flag for those players with a given field value
1684 void AddWinners(.float field, float value)
1685 {
1686         entity head;
1687         FOR_EACH_PLAYER(head)
1688                 if(head.field == value)
1689                         head.winning = 1;
1690 }
1691
1692 // clear the .winning flags
1693 void ClearWinners(void)
1694 {
1695         entity head;
1696         FOR_EACH_PLAYER(head)
1697                 head.winning = 0;
1698 }
1699
1700 // Onslaught winning condition:
1701 // game terminates if only one team has a working generator (or none)
1702 float WinningCondition_Onslaught()
1703 {
1704         entity head;
1705         local float t1, t2, t3, t4;
1706
1707         WinningConditionHelper(); // set worldstatus
1708
1709         if(inWarmupStage)
1710                 return WINNING_NO;
1711
1712         // first check if the game has ended
1713         t1 = t2 = t3 = t4 = 0;
1714         head = find(world, classname, "onslaught_generator");
1715         while (head)
1716         {
1717                 if (head.health > 0)
1718                 {
1719                         if (head.team == COLOR_TEAM1) t1 = 1;
1720                         if (head.team == COLOR_TEAM2) t2 = 1;
1721                         if (head.team == COLOR_TEAM3) t3 = 1;
1722                         if (head.team == COLOR_TEAM4) t4 = 1;
1723                 }
1724                 head = find(head, classname, "onslaught_generator");
1725         }
1726         if (t1 + t2 + t3 + t4 < 2)
1727         {
1728                 // game over, only one team remains (or none)
1729                 ClearWinners();
1730                 if (t1) SetWinners(team, COLOR_TEAM1);
1731                 if (t2) SetWinners(team, COLOR_TEAM2);
1732                 if (t3) SetWinners(team, COLOR_TEAM3);
1733                 if (t4) SetWinners(team, COLOR_TEAM4);
1734                 dprint("Have a winner, ending game.\n");
1735                 return WINNING_YES;
1736         }
1737
1738         // Two or more teams remain
1739         return WINNING_NO;
1740 }
1741
1742 float LMS_NewPlayerLives()
1743 {
1744         float fl;
1745         fl = cvar("fraglimit");
1746         if(fl == 0)
1747                 fl = 999;
1748
1749         // first player has left the game for dying too much? Nobody else can get in.
1750         if(lms_lowest_lives < 1)
1751                 return 0;
1752
1753         if(!cvar("g_lms_join_anytime"))
1754                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1755                         return 0;
1756
1757         return bound(1, lms_lowest_lives, fl);
1758 }
1759
1760 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1761 // they win. Otherwise the defending team wins once the timelimit passes.
1762 void assault_new_round();
1763 float WinningCondition_Assault()
1764 {
1765         local float status;
1766
1767         WinningConditionHelper(); // set worldstatus
1768
1769         status = WINNING_NO;
1770         // as the timelimit has not yet passed just assume the defending team will win
1771         if(assault_attacker_team == COLOR_TEAM1)
1772         {
1773                 SetWinners(team, COLOR_TEAM2);
1774         }
1775         else
1776         {
1777                 SetWinners(team, COLOR_TEAM1);
1778         }
1779
1780         local entity ent;
1781         ent = find(world, classname, "target_assault_roundend");
1782         if(ent)
1783         {
1784                 if(ent.winning) // round end has been triggered by attacking team
1785                 {
1786                         bprint("ASSAULT: round completed...\n");
1787                         SetWinners(team, assault_attacker_team);
1788
1789                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1790
1791                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1792                         {
1793                                 status = WINNING_YES;
1794                         }
1795                         else
1796                         {
1797                                 local entity oldself;
1798                                 oldself = self;
1799                                 self = ent;
1800                                 assault_new_round();
1801                                 self = oldself;
1802                         }
1803                 }
1804         }
1805
1806         return status;
1807 }
1808
1809 // LMS winning condition: game terminates if and only if there's at most one
1810 // one player who's living lives. Top two scores being equal cancels the time
1811 // limit.
1812 float WinningCondition_LMS()
1813 {
1814         entity head, head2;
1815         float have_player;
1816         float have_players;
1817         float l;
1818
1819         have_player = FALSE;
1820         have_players = FALSE;
1821         l = LMS_NewPlayerLives();
1822
1823         head = find(world, classname, "player");
1824         if(head)
1825                 have_player = TRUE;
1826         head2 = find(head, classname, "player");
1827         if(head2)
1828                 have_players = TRUE;
1829
1830         if(have_player)
1831         {
1832                 // we have at least one player
1833                 if(have_players)
1834                 {
1835                         // two or more active players - continue with the game
1836                 }
1837                 else
1838                 {
1839                         // exactly one player?
1840
1841                         ClearWinners();
1842                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1843
1844                         if(l)
1845                         {
1846                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1847                                 return WINNING_NO;
1848                         }
1849                         else
1850                         {
1851                                 // a winner!
1852                                 // and assign him his first place
1853                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1854                                 return WINNING_YES;
1855                         }
1856                 }
1857         }
1858         else
1859         {
1860                 // nobody is playing at all...
1861                 if(l)
1862                 {
1863                         // wait for players...
1864                 }
1865                 else
1866                 {
1867                         // SNAFU (maybe a draw game?)
1868                         ClearWinners();
1869                         dprint("No players, ending game.\n");
1870                         return WINNING_YES;
1871                 }
1872         }
1873
1874         // When we get here, we have at least two players who are actually LIVING,
1875         // now check if the top two players have equal score.
1876         WinningConditionHelper();
1877
1878         ClearWinners();
1879         if(WinningConditionHelper_winner)
1880                 WinningConditionHelper_winner.winning = TRUE;
1881         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1882                 return WINNING_NEVER;
1883
1884         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1885         return WINNING_NO;
1886 }
1887
1888 void ShuffleMaplist()
1889 {
1890         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1891 }
1892
1893 float leaderfrags;
1894 float WinningCondition_Scores(float limit, float leadlimit)
1895 {
1896         float limitreached;
1897
1898         // TODO make everything use THIS winning condition (except LMS)
1899         WinningConditionHelper();
1900
1901         if(teams_matter)
1902         {
1903                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1904                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1905                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1906                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1907         }
1908
1909         ClearWinners();
1910         if(WinningConditionHelper_winner)
1911                 WinningConditionHelper_winner.winning = 1;
1912         if(WinningConditionHelper_winnerteam >= 0)
1913                 SetWinners(team, WinningConditionHelper_winnerteam);
1914
1915         if(WinningConditionHelper_lowerisbetter)
1916         {
1917                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1918                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1919                 limit = -limit;
1920         }
1921
1922         if(WinningConditionHelper_zeroisworst)
1923                 leadlimit = 0; // not supported in this mode
1924
1925         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1926         // these modes always score in increments of 1, thus this makes sense
1927         {
1928                 if(leaderfrags != WinningConditionHelper_topscore)
1929                 {
1930                         leaderfrags = WinningConditionHelper_topscore;
1931
1932                         if (limit)
1933                         if (leaderfrags == limit - 1)
1934                                 Announce("1fragleft");
1935                         else if (leaderfrags == limit - 2)
1936                                 Announce("2fragsleft");
1937                         else if (leaderfrags == limit - 3)
1938                                 Announce("3fragsleft");
1939                 }
1940         }
1941
1942         limitreached = FALSE;
1943         if(limit)
1944                 if(WinningConditionHelper_topscore >= limit)
1945                         limitreached = TRUE;
1946         if(leadlimit)
1947         {
1948                 float leadlimitreached;
1949                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1950                 if(cvar("leadlimit_and_fraglimit"))
1951                         limitreached = (limitreached && leadlimitreached);
1952                 else
1953                         limitreached = (limitreached || leadlimitreached);
1954         }
1955
1956         return GetWinningCode(
1957                 WinningConditionHelper_topscore && limitreached,
1958                 WinningConditionHelper_equality
1959         );
1960 }
1961
1962 float WinningCondition_Race(float fraglimit)
1963 {
1964         float wc;
1965         entity p;
1966         float n, c;
1967
1968         n = 0;
1969         c = 0;
1970         FOR_EACH_PLAYER(p)
1971         {
1972                 ++n;
1973                 if(p.race_completed)
1974                         ++c;
1975         }
1976         if(n && (n == c))
1977                 return WINNING_YES;
1978         wc = WinningCondition_Scores(fraglimit, 0);
1979
1980         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1981         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1982         // do NOT support equality when the laps are all raced!
1983                 return WINNING_STARTSUDDENDEATHOVERTIME;
1984         else
1985                 return WINNING_NEVER;
1986         return wc;
1987 }
1988
1989 void ReadyRestart();
1990 float WinningCondition_QualifyingThenRace(float limit)
1991 {
1992         float wc;
1993         wc = WinningCondition_Scores(limit, 0);
1994
1995         // NEVER initiate overtime
1996         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1997         {
1998                 return WINNING_YES;
1999         }
2000
2001         return wc;
2002 }
2003
2004 float WinningCondition_RanOutOfSpawns()
2005 {
2006         entity head;
2007
2008         if(have_team_spawns <= 0)
2009                 return WINNING_NO;
2010
2011         if(!some_spawn_has_been_used)
2012                 return WINNING_NO;
2013
2014         team1_score = team2_score = team3_score = team4_score = 0;
2015
2016         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2017         {
2018                 if(head.team == COLOR_TEAM1)
2019                         team1_score = 1;
2020                 else if(head.team == COLOR_TEAM2)
2021                         team2_score = 1;
2022                 else if(head.team == COLOR_TEAM3)
2023                         team3_score = 1;
2024                 else if(head.team == COLOR_TEAM4)
2025                         team4_score = 1;
2026         }
2027
2028         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2029         {
2030                 if(head.team == COLOR_TEAM1)
2031                         team1_score = 1;
2032                 else if(head.team == COLOR_TEAM2)
2033                         team2_score = 1;
2034                 else if(head.team == COLOR_TEAM3)
2035                         team3_score = 1;
2036                 else if(head.team == COLOR_TEAM4)
2037                         team4_score = 1;
2038         }
2039
2040         ClearWinners();
2041         if(team1_score + team2_score + team3_score + team4_score == 0)
2042         {
2043                 checkrules_equality = TRUE;
2044                 return WINNING_YES;
2045         }
2046         else if(team1_score + team2_score + team3_score + team4_score == 1)
2047         {
2048                 float t, i;
2049                 if(team1_score) t = COLOR_TEAM1;
2050                 if(team2_score) t = COLOR_TEAM2;
2051                 if(team3_score) t = COLOR_TEAM3;
2052                 if(team4_score) t = COLOR_TEAM4;
2053                 CheckAllowedTeams(world);
2054                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2055                 {
2056                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2057                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2058                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2059                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2060                 }
2061
2062                 AddWinners(team, t);
2063                 return WINNING_YES;
2064         }
2065         else
2066                 return WINNING_NO;
2067 }
2068
2069 /*
2070 ============
2071 CheckRules_World
2072
2073 Exit deathmatch games upon conditions
2074 ============
2075 */
2076 void CheckRules_World()
2077 {
2078         float timelimit;
2079         float fraglimit;
2080         float leadlimit;
2081
2082         VoteThink();
2083         MapVote_Think();
2084
2085         SetDefaultAlpha();
2086
2087         /*
2088         MapVote_Think should now do that part
2089         if (intermission_running)
2090                 if (time >= intermission_exittime + 60)
2091                 {
2092                         if(!DoNextMapOverride())
2093                                 GotoNextMap();
2094                         return;
2095                 }
2096         */
2097
2098         if (gameover)   // someone else quit the game already
2099         {
2100                 if(player_count == 0) // Nobody there? Then let's go to the next map
2101                         MapVote_Start();
2102                         // this will actually check the player count in the next frame
2103                         // again, but this shouldn't hurt
2104                 return;
2105         }
2106
2107         timelimit = cvar("timelimit") * 60;
2108         fraglimit = cvar("fraglimit");
2109         leadlimit = cvar("leadlimit");
2110
2111         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2112         {
2113                 if(timelimit > 0)
2114                         timelimit = 0; // timelimit is not made for warmup
2115                 if(fraglimit > 0)
2116                         fraglimit = 0; // no fraglimit for now
2117                 leadlimit = 0; // no leadlimit for now
2118         }
2119
2120         if(g_onslaught)
2121                 timelimit = 0; // ONS has its own overtime rule
2122
2123         if(timelimit > 0)
2124         {
2125                 timelimit += game_starttime;
2126         }
2127         else if (timelimit < 0)
2128         {
2129                 // endmatch
2130                 NextLevel();
2131                 return;
2132         }
2133
2134         float wantovertime;
2135         wantovertime = 0;
2136
2137         if(checkrules_suddendeathend)
2138         {
2139                 if(!checkrules_suddendeathwarning)
2140                 {
2141                         checkrules_suddendeathwarning = TRUE;
2142                         if(g_race && !g_race_qualifying)
2143                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2144                         else
2145                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2146                 }
2147         }
2148         else
2149         {
2150                 if (timelimit && time >= timelimit)
2151                 {
2152                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2153                         {
2154                                 float totalplayers;
2155                                 float playerswithlaps;
2156                                 float readyplayers;
2157                                 entity head;
2158                                 totalplayers = playerswithlaps = readyplayers = 0;
2159                                 FOR_EACH_PLAYER(head)
2160                                 {
2161                                         ++totalplayers;
2162                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2163                                                 ++playerswithlaps;
2164                                         if(head.ready)
2165                                                 ++readyplayers;
2166                                 }
2167
2168                                 // at least 2 of the players have completed a lap: start the RACE
2169                                 // otherwise, the players should end the qualifying on their own
2170                                 if(readyplayers || playerswithlaps >= 2)
2171                                 {
2172                                         checkrules_suddendeathend = 0;
2173                                         ReadyRestart(); // go to race
2174                                         return;
2175                                 }
2176                                 else
2177                                         wantovertime |= InitiateSuddenDeath();
2178                         }
2179                         else
2180                                 wantovertime |= InitiateSuddenDeath();
2181                 }
2182         }
2183
2184         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2185         {
2186                 NextLevel();
2187                 return;
2188         }
2189
2190         float checkrules_status;
2191         checkrules_status = WinningCondition_RanOutOfSpawns();
2192         if(checkrules_status == WINNING_YES)
2193         {
2194                 bprint("Hey! Someone ran out of spawns!\n");
2195         }
2196         else if(g_race && !g_race_qualifying && timelimit >= 0)
2197         {
2198                 checkrules_status = WinningCondition_Race(fraglimit);
2199                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2200         }
2201         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2202         {
2203                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2204                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2205         }
2206         else if(g_assault)
2207         {
2208                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2209         }
2210         else if(g_lms)
2211         {
2212                 checkrules_status = WinningCondition_LMS();
2213         }
2214         else if (g_onslaught)
2215         {
2216                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2217         }
2218         else
2219         {
2220                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2221                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2222         }
2223
2224         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2225         {
2226                 checkrules_status = WINNING_NEVER;
2227                 checkrules_overtimesadded = -1;
2228                 wantovertime |= InitiateSuddenDeath();
2229         }
2230
2231         if(checkrules_status == WINNING_NEVER)
2232                 // equality cases! Nobody wins if the overtime ends in a draw.
2233                 ClearWinners();
2234
2235         if(wantovertime)
2236         {
2237                 if(checkrules_status == WINNING_NEVER)
2238                         InitiateOvertime();
2239                 else
2240                         checkrules_status = WINNING_YES;
2241         }
2242
2243         if(checkrules_suddendeathend)
2244                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2245                         checkrules_status = WINNING_YES;
2246
2247         if(checkrules_status == WINNING_YES)
2248         {
2249                 //print("WINNING\n");
2250                 NextLevel();
2251         }
2252 };
2253
2254 float mapvote_nextthink;
2255 float mapvote_initialized;
2256 float mapvote_keeptwotime;
2257 float mapvote_timeout;
2258 string mapvote_message;
2259 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2260 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2261 float mapvote_screenshot_dirs_count;
2262
2263 float mapvote_count;
2264 float mapvote_count_real;
2265 string mapvote_maps[MAPVOTE_COUNT];
2266 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2267 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2268 float mapvote_maps_suggested[MAPVOTE_COUNT];
2269 string mapvote_suggestions[MAPVOTE_COUNT];
2270 float mapvote_suggestion_ptr;
2271 float mapvote_maxlen;
2272 float mapvote_voters;
2273 float mapvote_votes[MAPVOTE_COUNT];
2274 float mapvote_run;
2275 float mapvote_detail;
2276 float mapvote_abstain;
2277 .float mapvote;
2278
2279 void MapVote_ClearAllVotes()
2280 {
2281         FOR_EACH_CLIENT(other)
2282                 other.mapvote = 0;
2283 }
2284
2285 string MapVote_Suggest(string m)
2286 {
2287         float i;
2288         if(m == "")
2289                 return "That's not how to use this command.";
2290         if(!cvar("g_maplist_votable_suggestions"))
2291                 return "Suggestions are not accepted on this server.";
2292         if(mapvote_initialized)
2293                 return "Can't suggest - voting is already in progress!";
2294         m = MapInfo_FixName(m);
2295         if(!m)
2296                 return "The map you suggested is not available on this server.";
2297         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2298                 if(Map_IsRecent(m))
2299                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2300
2301         if(!MapInfo_CheckMap(m))
2302                 return "The map you suggested does not support the current game mode.";
2303         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2304                 if(mapvote_suggestions[i] == m)
2305                         return "This map was already suggested.";
2306         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2307         {
2308                 i = floor(random() * mapvote_suggestion_ptr);
2309         }
2310         else
2311         {
2312                 i = mapvote_suggestion_ptr;
2313                 mapvote_suggestion_ptr += 1;
2314         }
2315         if(mapvote_suggestions[i] != "")
2316                 strunzone(mapvote_suggestions[i]);
2317         mapvote_suggestions[i] = strzone(m);
2318         if(cvar("sv_eventlog"))
2319                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2320         return strcat("Suggestion of ", m, " accepted.");
2321 }
2322
2323 void MapVote_AddVotable(string nextMap, float isSuggestion)
2324 {
2325         float j, i, o;
2326         string pakfile, mapfile;
2327
2328         if(nextMap == "")
2329                 return;
2330         for(j = 0; j < mapvote_count; ++j)
2331                 if(mapvote_maps[j] == nextMap)
2332                         return;
2333         if(strlen(nextMap) > mapvote_maxlen)
2334                 mapvote_maxlen = strlen(nextMap);
2335         mapvote_maps[mapvote_count] = strzone(nextMap);
2336         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2337
2338         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2339         {
2340                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2341                 pakfile = whichpack(strcat(mapfile, ".tga"));
2342                 if(pakfile == "")
2343                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2344                 if(pakfile == "")
2345                         pakfile = whichpack(strcat(mapfile, ".png"));
2346                 if(pakfile != "")
2347                         break;
2348         }
2349         if(i >= mapvote_screenshot_dirs_count)
2350                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2351         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2352                 pakfile = substring(pakfile, o, -1);
2353
2354         mapvote_maps_screenshot_dir[mapvote_count] = i;
2355         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2356
2357         mapvote_count += 1;
2358 }
2359
2360 void MapVote_Spawn();
2361 void MapVote_Init()
2362 {
2363         float i;
2364         float nmax, smax;
2365
2366         MapVote_ClearAllVotes();
2367
2368         mapvote_count = 0;
2369         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2370         mapvote_abstain = cvar("g_maplist_votable_abstain");
2371
2372         if(mapvote_abstain)
2373                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2374         else
2375                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2376         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2377
2378         // we need this for AddVotable, as that cycles through the screenshot dirs
2379         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2380         if(mapvote_screenshot_dirs_count == 0)
2381                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2382         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2383         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2384                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2385
2386         if(mapvote_suggestion_ptr)
2387                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2388                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2389
2390         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2391                 MapVote_AddVotable(GetNextMap(), FALSE);
2392
2393         if(mapvote_count == 0)
2394         {
2395                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2396                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2397                 if(cvar("g_maplist_shuffle"))
2398                         ShuffleMaplist();
2399                 localcmd("\nmenu_cmd sync\n");
2400                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2401                         MapVote_AddVotable(GetNextMap(), FALSE);
2402         }
2403
2404         mapvote_count_real = mapvote_count;
2405         if(mapvote_abstain)
2406                 MapVote_AddVotable("don't care", 0);
2407
2408         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2409
2410         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2411         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2412         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2413                 mapvote_keeptwotime = 0;
2414         mapvote_message = "Choose a map and press its key!";
2415
2416         MapVote_Spawn();
2417 }
2418
2419 void MapVote_SendPicture(float id)
2420 {
2421         msg_entity = self;
2422         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2423         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2424         WriteByte(MSG_ONE, id);
2425         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2426 }
2427
2428 float GameCommand_MapVote(string cmd)
2429 {
2430         if(!intermission_running)
2431                 return FALSE;
2432
2433         if(cmd == "mv_getpic")
2434         {
2435                 MapVote_SendPicture(stof(argv(1)));
2436                 return TRUE;
2437         }
2438
2439         return FALSE;
2440 }
2441
2442 float MapVote_GetMapMask()
2443 {
2444         float mask, i, power;
2445         mask = 0;
2446         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2447                 if(mapvote_maps[i] != "")
2448                         mask |= power;
2449         return mask;
2450 }
2451
2452 entity mapvote_ent;
2453 float MapVote_SendEntity(entity to, float sf)
2454 {
2455         float i;
2456
2457         if(sf & 1)
2458                 sf &~= 2; // if we send 1, we don't need to also send 2
2459
2460         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2461         WriteByte(MSG_ENTITY, sf);
2462
2463         if(sf & 1)
2464         {
2465                 // flag 1 == initialization
2466                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2467                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2468                 WriteString(MSG_ENTITY, "");
2469                 WriteByte(MSG_ENTITY, mapvote_count);
2470                 WriteByte(MSG_ENTITY, mapvote_abstain);
2471                 WriteByte(MSG_ENTITY, mapvote_detail);
2472                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2473                 if(mapvote_count <= 8)
2474                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2475                 else
2476                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2477                 for(i = 0; i < mapvote_count; ++i)
2478                         if(mapvote_maps[i] != "")
2479                         {
2480                                 if(mapvote_abstain && i == mapvote_count - 1)
2481                                 {
2482                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2483                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2484                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2485                                 }
2486                                 else
2487                                 {
2488                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2489                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2490                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2491                                 }
2492                         }
2493         }
2494
2495         if(sf & 2)
2496         {
2497                 // flag 2 == update of mask
2498                 if(mapvote_count <= 8)
2499                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2500                 else
2501                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2502         }
2503
2504         if(sf & 4)
2505         {
2506                 if(mapvote_detail)
2507                         for(i = 0; i < mapvote_count; ++i)
2508                                 if(mapvote_maps[i] != "")
2509                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2510
2511                 WriteByte(MSG_ENTITY, to.mapvote);
2512         }
2513
2514         return TRUE;
2515 }
2516
2517 void MapVote_Spawn()
2518 {
2519         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2520 }
2521
2522 void MapVote_TouchMask()
2523 {
2524         mapvote_ent.SendFlags |= 2;
2525 }
2526
2527 void MapVote_TouchVotes(entity voter)
2528 {
2529         mapvote_ent.SendFlags |= 4;
2530 }
2531
2532 float MapVote_Finished(float mappos)
2533 {
2534         string result;
2535         float i;
2536         float didntvote;
2537
2538         if(cvar("sv_eventlog"))
2539         {
2540                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2541                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2542                 didntvote = mapvote_voters;
2543                 for(i = 0; i < mapvote_count; ++i)
2544                         if(mapvote_maps[i] != "")
2545                         {
2546                                 didntvote -= mapvote_votes[i];
2547                                 if(i != mappos)
2548                                 {
2549                                         result = strcat(result, ":", mapvote_maps[i]);
2550                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2551                                 }
2552                         }
2553                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2554
2555                 GameLogEcho(result);
2556                 if(mapvote_maps_suggested[mappos])
2557                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2558         }
2559
2560         FOR_EACH_REALCLIENT(other)
2561                 FixClientCvars(other);
2562
2563         Map_Goto_SetStr(mapvote_maps[mappos]);
2564         Map_Goto();
2565         alreadychangedlevel = TRUE;
2566         return TRUE;
2567 }
2568 void MapVote_CheckRules_1()
2569 {
2570         float i;
2571
2572         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2573         {
2574                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2575                 mapvote_votes[i] = 0;
2576         }
2577
2578         mapvote_voters = 0;
2579         FOR_EACH_REALCLIENT(other)
2580         {
2581                 ++mapvote_voters;
2582                 if(other.mapvote)
2583                 {
2584                         i = other.mapvote - 1;
2585                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2586                         mapvote_votes[i] = mapvote_votes[i] + 1;
2587                 }
2588         }
2589 }
2590
2591 float MapVote_CheckRules_2()
2592 {
2593         float i;
2594         float firstPlace, secondPlace;
2595         float firstPlaceVotes, secondPlaceVotes;
2596         float mapvote_voters_real;
2597         string result;
2598
2599         if(mapvote_count_real == 1)
2600                 return MapVote_Finished(0);
2601
2602         mapvote_voters_real = mapvote_voters;
2603         if(mapvote_abstain)
2604                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2605
2606         RandomSelection_Init();
2607         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2608                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2609         firstPlace = RandomSelection_chosen_float;
2610         firstPlaceVotes = RandomSelection_best_priority;
2611         //dprint("First place: ", ftos(firstPlace), "\n");
2612         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2613
2614         RandomSelection_Init();
2615         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2616                 if(i != firstPlace)
2617                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2618         secondPlace = RandomSelection_chosen_float;
2619         secondPlaceVotes = RandomSelection_best_priority;
2620         //dprint("Second place: ", ftos(secondPlace), "\n");
2621         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2622
2623         if(firstPlace == -1)
2624                 error("No first place in map vote... WTF?");
2625
2626         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2627                 return MapVote_Finished(firstPlace);
2628
2629         if(mapvote_keeptwotime)
2630                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2631                 {
2632                         float didntvote;
2633                         MapVote_TouchMask();
2634                         mapvote_message = "Now decide between the TOP TWO!";
2635                         mapvote_keeptwotime = 0;
2636                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2637                         result = strcat(result, ":", ftos(firstPlaceVotes));
2638                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2639                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2640                         didntvote = mapvote_voters;
2641                         for(i = 0; i < mapvote_count; ++i)
2642                                 if(mapvote_maps[i] != "")
2643                                 {
2644                                         didntvote -= mapvote_votes[i];
2645                                         if(i != firstPlace)
2646                                                 if(i != secondPlace)
2647                                                 {
2648                                                         result = strcat(result, ":", mapvote_maps[i]);
2649                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2650                                                         if(i < mapvote_count_real)
2651                                                         {
2652                                                                 strunzone(mapvote_maps[i]);
2653                                                                 mapvote_maps[i] = "";
2654                                                                 strunzone(mapvote_maps_pakfile[i]);
2655                                                                 mapvote_maps_pakfile[i] = "";
2656                                                         }
2657                                                 }
2658                                 }
2659                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2660                         if(cvar("sv_eventlog"))
2661                                 GameLogEcho(result);
2662                 }
2663
2664         return FALSE;
2665 }
2666 void MapVote_Tick()
2667 {
2668         float keeptwo;
2669         float totalvotes;
2670
2671         keeptwo = mapvote_keeptwotime;
2672         MapVote_CheckRules_1(); // count
2673         if(MapVote_CheckRules_2()) // decide
2674                 return;
2675
2676         totalvotes = 0;
2677         FOR_EACH_REALCLIENT(other)
2678         {
2679                 // hide scoreboard again
2680                 if(other.health != 2342)
2681                 {
2682                         other.health = 2342;
2683                         other.impulse = 0;
2684                         if(clienttype(other) == CLIENTTYPE_REAL)
2685                         {
2686                                 msg_entity = other;
2687                                 WriteByte(MSG_ONE, SVC_FINALE);
2688                                 WriteString(MSG_ONE, "");
2689                         }
2690                 }
2691
2692                 // clear possibly invalid votes
2693                 if(mapvote_maps[other.mapvote - 1] == "")
2694                         other.mapvote = 0;
2695                 // use impulses as new vote
2696                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2697                         if(mapvote_maps[other.impulse - 1] != "")
2698                         {
2699                                 other.mapvote = other.impulse;
2700                                 MapVote_TouchVotes(other);
2701                         }
2702                 other.impulse = 0;
2703
2704                 if(other.mapvote)
2705                         ++totalvotes;
2706         }
2707
2708         MapVote_CheckRules_1(); // just count
2709 }
2710 void MapVote_Start()
2711 {
2712         if(mapvote_run)
2713                 return;
2714
2715         MapInfo_Enumerate();
2716         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2717                 mapvote_run = TRUE;
2718 }
2719 void MapVote_Think()
2720 {
2721         if(!mapvote_run)
2722                 return;
2723
2724         if(alreadychangedlevel)
2725                 return;
2726
2727         if(time < mapvote_nextthink)
2728                 return;
2729         //dprint("tick\n");
2730
2731         mapvote_nextthink = time + 0.5;
2732
2733         if(!mapvote_initialized)
2734         {
2735                 if(cvar("rescan_pending") == 1)
2736                 {
2737                         cvar_set("rescan_pending", "2");
2738                         localcmd("fs_rescan\nrescan_pending 3\n");
2739                         return;
2740                 }
2741                 else if(cvar("rescan_pending") == 2)
2742                 {
2743                         return;
2744                 }
2745                 else if(cvar("rescan_pending") == 3)
2746                 {
2747                         // now build missing mapinfo files
2748                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2749                                 return;
2750
2751                         // we're done, start the timer
2752                         cvar_set("rescan_pending", "0");
2753                 }
2754
2755                 mapvote_initialized = TRUE;
2756                 if(DoNextMapOverride())
2757                         return;
2758                 if(!cvar("g_maplist_votable") || player_count <= 0)
2759                 {
2760                         GotoNextMap();
2761                         return;
2762                 }
2763                 MapVote_Init();
2764         }
2765
2766         MapVote_Tick();
2767 };
2768
2769 string GotoMap(string m)
2770 {
2771         if(!MapInfo_CheckMap(m))
2772                 return "The map you chose is not available on this server.";
2773         cvar_set("nextmap", m);
2774         cvar_set("timelimit", "-1");
2775         if(mapvote_initialized || alreadychangedlevel)
2776         {
2777                 if(DoNextMapOverride())
2778                         return "Map switch initiated.";
2779                 else
2780                         return "Hm... no. For some reason I like THIS map more.";
2781         }
2782         else
2783                 return "Map switch will happen after scoreboard.";
2784 }
2785
2786
2787 void EndFrame()
2788 {
2789         float altime;
2790         FOR_EACH_REALCLIENT(self)
2791         {
2792                 if(self.classname == "spectator")
2793                 {
2794                         if(self.enemy.typehitsound)
2795                                 play2(self, "misc/typehit.wav");
2796                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2797                                 play2(self, "misc/hit.wav");
2798                 }
2799                 else
2800                 {
2801                         if(self.typehitsound)
2802                                 play2(self, "misc/typehit.wav");
2803                         else if(self.hitsound && self.cvar_cl_hitsound)
2804                                 play2(self, "misc/hit.wav");
2805                 }
2806         }
2807         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2808         // add 1 frametime because after this, engine SV_Physics
2809         // increases time by a frametime and then networks the frame
2810         // add another frametime because client shows everything with
2811         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2812         // needed!
2813         FOR_EACH_CLIENT(self)
2814         {
2815                 self.hitsound = FALSE;
2816                 self.typehitsound = FALSE;
2817                 antilag_record(self, altime);
2818         }
2819 }
2820
2821
2822 /*
2823  * RedirectionThink:
2824  * returns TRUE if redirecting
2825  */
2826 float redirection_timeout;
2827 float redirection_nextthink;
2828 float RedirectionThink()
2829 {
2830         float clients_found;
2831
2832         if(redirection_target == "")
2833                 return FALSE;
2834
2835         if(!redirection_timeout)
2836         {
2837                 cvar_set("sv_public", "-2");
2838                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2839                 if(redirection_target == "self")
2840                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2841                 else
2842                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2843         }
2844
2845         if(time < redirection_nextthink)
2846                 return TRUE;
2847
2848         redirection_nextthink = time + 1;
2849
2850         clients_found = 0;
2851         FOR_EACH_REALCLIENT(self)
2852         {
2853                 print("Redirecting: sending connect command to ", self.netname, "\n");
2854                 if(redirection_target == "self")
2855                         stuffcmd(self, "\ndisconnect; reconnect\n");
2856                 else
2857                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2858                 ++clients_found;
2859         }
2860
2861         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2862
2863         if(time > redirection_timeout || clients_found == 0)
2864                 localcmd("\nwait; wait; wait; quit\n");
2865
2866         return TRUE;
2867 }
2868
2869 void TargetMusic_RestoreGame();
2870 void RestoreGame()
2871 {
2872         // Loaded from a save game
2873         // some things then break, so let's work around them...
2874
2875         // Progs DB (capture records)
2876         ServerProgsDB = db_load("server.db");
2877
2878         // Mapinfo
2879         MapInfo_Shutdown();
2880         MapInfo_Enumerate();
2881         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2882         WeaponStats_Init();
2883
2884         TargetMusic_RestoreGame();
2885 }
2886
2887 void SV_Shutdown()
2888 {
2889         if(gameover > 1) // shutting down already?
2890                 return;
2891
2892         gameover = 2; // 2 = server shutting down
2893
2894         if(world_initialized > 0)
2895         {
2896                 world_initialized = 0;
2897                 print("Saving persistent data...\n");
2898                 Ban_SaveBans();
2899                 if(!cheatcount_total)
2900                 {
2901                         if(cvar("sv_db_saveasdump"))
2902                                 db_dump(ServerProgsDB, "server.db");
2903                         else
2904                                 db_save(ServerProgsDB, "server.db");
2905                 }
2906                 if(cvar("developer"))
2907                 {
2908                         if(cvar("sv_db_saveasdump"))
2909                                 db_dump(TemporaryDB, "server-temp.db");
2910                         else
2911                                 db_save(TemporaryDB, "server-temp.db");
2912                 }
2913                 CheatShutdown(); // must be after cheatcount check
2914                 db_close(ServerProgsDB);
2915                 db_close(TemporaryDB);
2916                 print("done!\n");
2917                 // tell the bot system the game is ending now
2918                 bot_endgame();
2919
2920                 WeaponStats_Shutdown();
2921                 MapInfo_Shutdown();
2922         }
2923         else if(world_initialized == 0)
2924         {
2925                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2926         }
2927 }