qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/mutators_include.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/all.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications.qh"
  29 #include "../common/physics.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/all.qh"
  37 #include "../common/weapons/all.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {SELFPARAM();
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         self.nextthink = time + delta;
  53
  54         e = edict_num(self.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  58                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  59                 WriteByte(MSG_BROADCAST, self.cnt);
  60                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  62                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  63
  64                 // record latency times for clients throughout the match so we can report it to playerstats
  65                 if(time > (e.latency_time + LATENCY_THINKRATE))
  66                 {
  67                         e.latency_sum += e.ping;
  68                         e.latency_cnt += 1;
  69                         e.latency_time = time;
  70                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  71                 }
  72         }
  73         else
  74         {
  75                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  76                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  77                 WriteByte(MSG_BROADCAST, self.cnt);
  78                 WriteShort(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81         }
  82         self.cnt = (self.cnt + 1) % maxclients;
  83 }
  84 void PingPLReport_Spawn()
  85 {
  86         pingplreport = spawn();
  87         pingplreport.classname = "pingplreport";
  88         pingplreport.think = PingPLReport_Think;
  89         pingplreport.nextthink = time;
  90 }
  91
  92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  93 string redirection_target;
  94 float world_initialized;
  95
  96 string GetGametype();
  97 void ShuffleMaplist();
  98
  99 void SetDefaultAlpha()
 100 {
 101         if(autocvar_g_running_guns)
 102         {
 103                 default_player_alpha = -1;
 104                 default_weapon_alpha = +1;
 105         }
 106         else if(g_cloaked)
 107         {
 108                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 109                 default_weapon_alpha = default_player_alpha;
 110         }
 111         else
 112         {
 113                 default_player_alpha = autocvar_g_player_alpha;
 114                 if(default_player_alpha == 0)
 115                         default_player_alpha = 1;
 116                 default_weapon_alpha = default_player_alpha;
 117         }
 118 }
 119
 120 void GotoFirstMap()
 121 {SELFPARAM();
 122         float n;
 123         if(autocvar__sv_init)
 124         {
 125                 // cvar_set("_sv_init", "0");
 126                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 127                 // to this "init" map on a dedicated server will cause no permanent
 128                 // harm
 129                 if(autocvar_g_maplist_shuffle)
 130                         ShuffleMaplist();
 131                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 132                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 133
 134                 MapInfo_Enumerate();
 135                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 136
 137                 if(!DoNextMapOverride(1))
 138                         GotoNextMap(1);
 139
 140                 return;
 141         }
 142
 143         if(time < 5)
 144         {
 145                 self.nextthink = time;
 146         }
 147         else
 148         {
 149                 self.nextthink = time + 1;
 150                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 151         }
 152 }
 153
 154 void cvar_changes_init()
 155 {
 156         float h;
 157         string k, v, d;
 158         float n, i, adding, pureadding;
 159
 160         if(cvar_changes)
 161                 strunzone(cvar_changes);
 162         cvar_changes = string_null;
 163         if(cvar_purechanges)
 164                 strunzone(cvar_purechanges);
 165         cvar_purechanges = string_null;
 166         cvar_purechanges_count = 0;
 167
 168         h = buf_create();
 169         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 170         n = buf_getsize(h);
 171
 172         adding = true;
 173         pureadding = true;
 174
 175         for(i = 0; i < n; ++i)
 176         {
 177                 k = bufstr_get(h, i);
 178
 179 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 180 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 181 #define BADCVAR(p) if(k == p) continue
 182
 183                 // general excludes and namespaces for server admin used cvars
 184                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 185
 186                 // internal
 187                 BADPREFIX("csqc_");
 188                 BADPREFIX("cvar_check_");
 189                 BADCVAR("gamecfg");
 190                 BADCVAR("g_configversion");
 191                 BADCVAR("g_maplist_index");
 192                 BADCVAR("halflifebsp");
 193                 BADCVAR("sv_mapformat_is_quake2");
 194                 BADCVAR("sv_mapformat_is_quake3");
 195                 BADPREFIX("sv_world");
 196
 197                 // client
 198                 BADPREFIX("chase_");
 199                 BADPREFIX("cl_");
 200                 BADPREFIX("con_");
 201                 BADPREFIX("scoreboard_");
 202                 BADPREFIX("g_campaign");
 203                 BADPREFIX("g_waypointsprite_");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("hud_");
 207                 BADPREFIX("m_");
 208                 BADPREFIX("menu_");
 209                 BADPREFIX("net_slist_");
 210                 BADPREFIX("r_");
 211                 BADPREFIX("sbar_");
 212                 BADPREFIX("scr_");
 213                 BADPREFIX("snd_");
 214                 BADPREFIX("show");
 215                 BADPREFIX("sensitivity");
 216                 BADPREFIX("userbind");
 217                 BADPREFIX("v_");
 218                 BADPREFIX("vid_");
 219                 BADPREFIX("crosshair");
 220                 BADCVAR("mod_q3bsp_lightmapmergepower");
 221                 BADCVAR("mod_q3bsp_nolightmaps");
 222                 BADCVAR("fov");
 223                 BADCVAR("mastervolume");
 224                 BADCVAR("volume");
 225                 BADCVAR("bgmvolume");
 226
 227                 // private
 228                 BADCVAR("developer");
 229                 BADCVAR("log_dest_udp");
 230                 BADCVAR("net_address");
 231                 BADCVAR("net_address_ipv6");
 232                 BADCVAR("port");
 233                 BADCVAR("savedgamecfg");
 234                 BADCVAR("serverconfig");
 235                 BADCVAR("sv_autoscreenshot");
 236                 BADCVAR("sv_heartbeatperiod");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timeformat");
 241                 BADCVAR("timestamps");
 242                 BADPREFIX("developer_");
 243                 BADPREFIX("g_ban_");
 244                 BADPREFIX("g_banned_list");
 245                 BADPREFIX("g_chat_flood_");
 246                 BADPREFIX("g_ghost_items");
 247                 BADPREFIX("g_playerstats_");
 248                 BADPREFIX("g_respawn_ghosts");
 249                 BADPREFIX("g_voice_flood_");
 250                 BADPREFIX("log_file");
 251                 BADPREFIX("rcon_");
 252                 BADPREFIX("sv_allowdownloads");
 253                 BADPREFIX("sv_autodemo");
 254                 BADPREFIX("sv_curl_");
 255                 BADPREFIX("sv_eventlog");
 256                 BADPREFIX("sv_logscores_");
 257                 BADPREFIX("sv_master");
 258                 BADPREFIX("sv_weaponstats_");
 259                 BADPREFIX("sv_waypointsprite_");
 260                 BADCVAR("rescan_pending");
 261
 262                 // these can contain player IDs, so better hide
 263                 BADPREFIX("g_forced_team_");
 264
 265                 // mapinfo
 266                 BADCVAR("fraglimit");
 267                 BADCVAR("g_assault");
 268                 BADCVAR("g_ca");
 269                 BADCVAR("g_ca_teams");
 270                 BADCVAR("g_ctf");
 271                 BADCVAR("g_cts");
 272                 BADCVAR("g_dm");
 273                 BADCVAR("g_domination");
 274                 BADCVAR("g_domination_default_teams");
 275                 BADCVAR("g_freezetag");
 276                 BADCVAR("g_freezetag_teams");
 277                 BADCVAR("g_invasion_teams");
 278                 BADCVAR("g_keepaway");
 279                 BADCVAR("g_keyhunt");
 280                 BADCVAR("g_keyhunt_teams");
 281                 BADCVAR("g_lms");
 282                 BADCVAR("g_nexball");
 283                 BADCVAR("g_onslaught");
 284                 BADCVAR("g_race");
 285                 BADCVAR("g_race_qualifying_timelimit");
 286                 BADCVAR("g_tdm");
 287                 BADCVAR("g_tdm_teams");
 288                 BADCVAR("leadlimit");
 289                 BADCVAR("nextmap");
 290                 BADCVAR("teamplay");
 291                 BADCVAR("timelimit");
 292
 293                 // long
 294                 BADCVAR("hostname");
 295                 BADCVAR("g_maplist");
 296                 BADCVAR("g_maplist_mostrecent");
 297                 BADCVAR("sv_motd");
 298
 299                 v = cvar_string(k);
 300                 d = cvar_defstring(k);
 301                 if(v == d)
 302                         continue;
 303
 304                 if(adding)
 305                 {
 306                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 307                         if(strlen(cvar_changes) > 16384)
 308                         {
 309                                 cvar_changes = "// too many settings have been changed to show them here\n";
 310                                 adding = 0;
 311                         }
 312                 }
 313
 314                 // now check if the changes are actually gameplay relevant
 315
 316                 // does nothing visible
 317                 BADCVAR("captureleadlimit_override");
 318                 BADCVAR("g_balance_kill_delay");
 319                 BADCVAR("g_ca_point_limit");
 320                 BADCVAR("g_ca_point_leadlimit");
 321                 BADCVAR("g_ctf_captimerecord_always");
 322                 BADCVAR("g_ctf_flag_glowtrails");
 323                 BADCVAR("g_ctf_flag_pickup_verbosename");
 324                 BADCVAR("g_domination_point_leadlimit");
 325                 BADCVAR("g_forced_respawn");
 326                 BADCVAR("g_freezetag_point_limit");
 327                 BADCVAR("g_freezetag_point_leadlimit");
 328                 BADCVAR("g_keyhunt_point_leadlimit");
 329                 BADPREFIX("g_mod_");
 330                 BADCVAR("g_invasion_point_limit");
 331                 BADCVAR("g_nexball_goalleadlimit");
 332                 BADCVAR("g_tdm_point_limit");
 333                 BADCVAR("g_tdm_point_leadlimit");
 334                 BADCVAR("leadlimit_and_fraglimit");
 335                 BADCVAR("leadlimit_override");
 336                 BADCVAR("pausable");
 337                 BADCVAR("sv_allow_fullbright");
 338                 BADCVAR("sv_checkforpacketsduringsleep");
 339                 BADCVAR("sv_timeout");
 340                 BADPREFIX("sv_timeout_");
 341                 BADPREFIX("crypto_");
 342                 BADPREFIX("g_chat_");
 343                 BADPREFIX("g_ctf_captimerecord_");
 344                 BADPREFIX("g_maplist_votable_");
 345                 BADPREFIX("net_");
 346                 BADPREFIX("prvm_");
 347                 BADPREFIX("skill_");
 348                 BADPREFIX("sv_cullentities_");
 349                 BADPREFIX("sv_maxidle_");
 350                 BADPREFIX("sv_vote_");
 351                 BADPREFIX("timelimit_");
 352                 BADCVAR("gameversion");
 353                 BADPREFIX("gameversion_");
 354                 BADCVAR("sv_minigames");
 355                 BADPREFIX("sv_minigames_");
 356                 BADCVAR("sv_namechangetimer");
 357
 358                 // allowed changes to server admins (please sync this to server.cfg)
 359                 // vi commands:
 360                 //   :/"impure"/,$d
 361                 //   :g!,^\/\/[^ /],d
 362                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 363                 //   :%!sort
 364                 // yes, this does contain some redundant stuff, don't really care
 365                 BADCVAR("bot_config_file");
 366                 BADCVAR("bot_number");
 367                 BADCVAR("bot_prefix");
 368                 BADCVAR("bot_suffix");
 369                 BADCVAR("capturelimit_override");
 370                 BADCVAR("fraglimit_override");
 371                 BADCVAR("gametype");
 372                 BADCVAR("g_antilag");
 373                 BADCVAR("g_balance_teams");
 374                 BADCVAR("g_balance_teams_prevent_imbalance");
 375                 BADCVAR("g_balance_teams_scorefactor");
 376                 BADCVAR("g_ban_sync_trusted_servers");
 377                 BADCVAR("g_ban_sync_uri");
 378                 BADCVAR("g_ca_teams_override");
 379                 BADCVAR("g_ctf_ignore_frags");
 380                 BADCVAR("g_domination_point_limit");
 381                 BADCVAR("g_domination_teams_override");
 382                 BADCVAR("g_freezetag_teams_override");
 383                 BADCVAR("g_friendlyfire");
 384                 BADCVAR("g_fullbrightitems");
 385                 BADCVAR("g_fullbrightplayers");
 386                 BADCVAR("g_keyhunt_point_limit");
 387                 BADCVAR("g_keyhunt_teams_override");
 388                 BADCVAR("g_lms_lives_override");
 389                 BADCVAR("g_maplist");
 390                 BADCVAR("g_maplist_check_waypoints");
 391                 BADCVAR("g_maplist_mostrecent_count");
 392                 BADCVAR("g_maplist_shuffle");
 393                 BADCVAR("g_maplist_votable");
 394                 BADCVAR("g_maplist_votable_abstain");
 395                 BADCVAR("g_maplist_votable_nodetail");
 396                 BADCVAR("g_maplist_votable_suggestions");
 397                 BADCVAR("g_maxplayers");
 398                 BADCVAR("g_mirrordamage");
 399                 BADCVAR("g_nexball_goallimit");
 400                 BADCVAR("g_powerups");
 401                 BADCVAR("g_start_delay");
 402                 BADCVAR("g_tdm_teams_override");
 403                 BADCVAR("g_warmup");
 404                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 405                 BADCVAR("hostname");
 406                 BADCVAR("log_file");
 407                 BADCVAR("maxplayers");
 408                 BADCVAR("minplayers");
 409                 BADCVAR("net_address");
 410                 BADCVAR("port");
 411                 BADCVAR("rcon_password");
 412                 BADCVAR("rcon_restricted_commands");
 413                 BADCVAR("rcon_restricted_password");
 414                 BADCVAR("skill");
 415                 BADCVAR("sv_adminnick");
 416                 BADCVAR("sv_autoscreenshot");
 417                 BADCVAR("sv_autotaunt");
 418                 BADCVAR("sv_curl_defaulturl");
 419                 BADCVAR("sv_defaultcharacter");
 420                 BADCVAR("sv_defaultplayercolors");
 421                 BADCVAR("sv_defaultplayermodel");
 422                 BADCVAR("sv_defaultplayerskin");
 423                 BADCVAR("sv_maxidle");
 424                 BADCVAR("sv_maxrate");
 425                 BADCVAR("sv_motd");
 426                 BADCVAR("sv_public");
 427                 BADCVAR("sv_ready_restart");
 428                 BADCVAR("sv_status_privacy");
 429                 BADCVAR("sv_taunt");
 430                 BADCVAR("sv_vote_call");
 431                 BADCVAR("sv_vote_commands");
 432                 BADCVAR("sv_vote_majority_factor");
 433                 BADCVAR("sv_vote_master");
 434                 BADCVAR("sv_vote_master_commands");
 435                 BADCVAR("sv_vote_master_password");
 436                 BADCVAR("sv_vote_simple_majority_factor");
 437                 BADCVAR("teamplay_mode");
 438                 BADCVAR("timelimit_override");
 439                 BADCVAR("g_spawnshieldtime");
 440                 BADPREFIX("g_warmup_");
 441                 BADPREFIX("sv_ready_restart_");
 442
 443                 // mutators that announce themselves properly to the server browser
 444                 BADCVAR("g_instagib");
 445                 BADCVAR("g_new_toys");
 446                 BADCVAR("g_nix");
 447                 BADCVAR("g_grappling_hook");
 448                 BADCVAR("g_jetpack");
 449
 450 #undef BADPREFIX
 451 #undef BADCVAR
 452
 453                 if(pureadding)
 454                 {
 455                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 456                         if(strlen(cvar_purechanges) > 16384)
 457                         {
 458                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 459                                 pureadding = 0;
 460                         }
 461                 }
 462                 ++cvar_purechanges_count;
 463                 // WARNING: this variable is used for the server list
 464                 // NEVER dare to skip this code!
 465                 // Hacks to intentionally appearing as "pure server" even though you DO have
 466                 // modified settings may be punished by removal from the server list.
 467                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 468                 // though.
 469         }
 470         buf_del(h);
 471         if(cvar_changes == "")
 472                 cvar_changes = "// this server runs at default server settings\n";
 473         else
 474                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 475         cvar_changes = strzone(cvar_changes);
 476         if(cvar_purechanges == "")
 477                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 478         else
 479                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 480         cvar_purechanges = strzone(cvar_purechanges);
 481 }
 482
 483 void detect_maptype()
 484 {
 485 #if 0
 486         vector o, v;
 487         float i;
 488
 489         for (;;)
 490         {
 491                 o = world.mins;
 492                 o.x += random() * (world.maxs.x - world.mins.x);
 493                 o.y += random() * (world.maxs.y - world.mins.y);
 494                 o.z += random() * (world.maxs.z - world.mins.z);
 495
 496                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 497                 if(trace_fraction == 1)
 498                         continue;
 499
 500                 v = trace_endpos;
 501
 502                 for(i = 0; i < 64; i += 4)
 503                 {
 504                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 505         if(trace_fraction == 1)
 506                 continue;
 507                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 508                 }
 509
 510                 break;
 511         }
 512 #endif
 513 }
 514
 515 entity randomseed;
 516 bool RandomSeed_Send(entity this, entity to, int sf)
 517 {
 518         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 519         WriteShort(MSG_ENTITY, self.cnt);
 520         return true;
 521 }
 522 void RandomSeed_Think()
 523 {SELFPARAM();
 524         self.cnt = bound(0, floor(random() * 65536), 65535);
 525         self.nextthink = time + 5;
 526
 527         self.SendFlags |= 1;
 528 }
 529 void RandomSeed_Spawn()
 530 {SELFPARAM();
 531         randomseed = spawn();
 532         randomseed.think = RandomSeed_Think;
 533         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 534
 535         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 536 }
 537
 538 spawnfunc(__init_dedicated_server)
 539 {
 540         // handler for _init/_init map (only for dedicated server initialization)
 541
 542         world_initialized = -1; // don't complain
 543         cvar = cvar_normal;
 544         cvar_string = cvar_string_normal;
 545         cvar_set = cvar_set_normal;
 546
 547         remove = remove_unsafely;
 548
 549         entity e;
 550         e = spawn();
 551         e.think = GotoFirstMap;
 552         e.nextthink = time; // this is usually 1 at this point
 553
 554         e = spawn();
 555         e.classname = "info_player_deathmatch"; // safeguard against player joining
 556
 557         self.classname = "worldspawn"; // safeguard against various stuff ;)
 558
 559         // needs to be done so early because of the constants they create
 560         static_init();
 561
 562         MapInfo_Enumerate();
 563         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 564 }
 565
 566 void Map_MarkAsRecent(string m);
 567 float world_already_spawned;
 568 void Nagger_Init();
 569 void ClientInit_Spawn();
 570 void WeaponStats_Init();
 571 void WeaponStats_Shutdown();
 572 void Physics_AddStats();
 573 spawnfunc(worldspawn)
 574 {
 575         float fd, l, j, n;
 576         string s;
 577
 578         cvar = cvar_normal;
 579         cvar_string = cvar_string_normal;
 580         cvar_set = cvar_set_normal;
 581
 582         if(world_already_spawned)
 583                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 584         world_already_spawned = true;
 585
 586         remove = remove_safely; // during spawning, watch what you remove!
 587
 588         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 589
 590         compressShortVector_init();
 591
 592         entity head;
 593         head = nextent(world);
 594         maxclients = 0;
 595         while(head)
 596         {
 597                 ++maxclients;
 598                 head = nextent(head);
 599         }
 600
 601         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 602
 603         // needs to be done so early because of the constants they create
 604         static_init();
 605
 606         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 607
 608         TemporaryDB = db_create();
 609
 610         // 0 normal
 611         lightstyle(0, "m");
 612
 613         // 1 FLICKER (first variety)
 614         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 615
 616         // 2 SLOW STRONG PULSE
 617         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 618
 619         // 3 CANDLE (first variety)
 620         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 621
 622         // 4 FAST STROBE
 623         lightstyle(4, "mamamamamama");
 624
 625         // 5 GENTLE PULSE 1
 626         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 627
 628         // 6 FLICKER (second variety)
 629         lightstyle(6, "nmonqnmomnmomomno");
 630
 631         // 7 CANDLE (second variety)
 632         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 633
 634         // 8 CANDLE (third variety)
 635         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 636
 637         // 9 SLOW STROBE (fourth variety)
 638         lightstyle(9, "aaaaaaaazzzzzzzz");
 639
 640         // 10 FLUORESCENT FLICKER
 641         lightstyle(10, "mmamammmmammamamaaamammma");
 642
 643         // 11 SLOW PULSE NOT FADE TO BLACK
 644         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 645
 646         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 647
 648         // 63 testing
 649         lightstyle(63, "a");
 650
 651         if(autocvar_g_campaign)
 652                 CampaignPreInit();
 653
 654         Map_MarkAsRecent(mapname);
 655
 656         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 657
 658         InitGameplayMode();
 659         readlevelcvars();
 660         GrappleHookInit();
 661
 662         player_count = 0;
 663         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 664         if(bot_waypoints_for_items == 1)
 665                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 666                         bot_waypoints_for_items = 0;
 667
 668         precache();
 669
 670         WaypointSprite_Init();
 671
 672         GameLogInit(); // prepare everything
 673         // NOTE for matchid:
 674         // changing the logic generating it is okay. But:
 675         // it HAS to stay <= 64 chars
 676         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 677         if(autocvar_sv_eventlog)
 678         {
 679                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 680                 matchid = strzone(s);
 681
 682                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 683                 s = ":gameinfo:mutators:LIST";
 684
 685                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 686                 s = ret_string;
 687
 688                 // initialiation stuff, not good in the mutator system
 689                 if(!autocvar_g_use_ammunition)
 690                         s = strcat(s, ":no_use_ammunition");
 691
 692                 // initialiation stuff, not good in the mutator system
 693                 if(autocvar_g_pickup_items == 0)
 694                         s = strcat(s, ":no_pickup_items");
 695                 if(autocvar_g_pickup_items > 0)
 696                         s = strcat(s, ":pickup_items");
 697
 698                 // initialiation stuff, not good in the mutator system
 699                 if(autocvar_g_weaponarena != "0")
 700                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 701
 702                 // TODO to mutator system
 703                 if(autocvar_g_norecoil)
 704                         s = strcat(s, ":norecoil");
 705
 706                 // TODO to mutator system
 707                 if(autocvar_g_powerups == 0)
 708                         s = strcat(s, ":no_powerups");
 709                 if(autocvar_g_powerups > 0)
 710                         s = strcat(s, ":powerups");
 711
 712                 GameLogEcho(s);
 713                 GameLogEcho(":gameinfo:end");
 714         }
 715         else
 716                 matchid = strzone(ftos(random()));
 717
 718         cvar_set("nextmap", "");
 719
 720         SetDefaultAlpha();
 721
 722         if(autocvar_g_campaign)
 723                 CampaignPostInit();
 724
 725         Ban_LoadBans();
 726
 727         MapInfo_Enumerate();
 728         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 729
 730         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 731         {
 732                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 733                 if(fd != -1)
 734                 {
 735                         while((s = fgets(fd)))
 736                         {
 737                                 l = tokenize_console(s);
 738                                 if(l < 2)
 739                                         continue;
 740                                 if(argv(0) == "cd")
 741                                 {
 742                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 743                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 744                                 }
 745                                 else if(argv(0) == "fog")
 746                                 {
 747                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 748                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 749                                 }
 750                                 else if(argv(0) == "set")
 751                                 {
 752                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 753                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 754                                 }
 755                                 else if(argv(0) != "//")
 756                                 {
 757                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 758                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 759                                 }
 760                         }
 761                         fclose(fd);
 762                 }
 763         }
 764
 765         WeaponStats_Init();
 766
 767         WepSet_AddStat();
 768         WepSet_AddStat_InMap();
 769         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 770         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 771         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 772         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 773         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 774         Nagger_Init();
 775
 776         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 777         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 778         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 779         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 780         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 781         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 782         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 783         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 784         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 785         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 786         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 787         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 788         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 789         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 790         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 791
 792         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 793         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 794
 795         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 796
 797         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 798
 799         // freeze attacks
 800         addstat(STAT_FROZEN, AS_INT, frozen);
 801         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 802
 803         // physics
 804         Physics_AddStats();
 805
 806         // new properties
 807         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 808         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 809         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 810         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 811         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 812         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 813         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 814         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 815         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 816         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 817         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 818         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 819         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 820         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 821         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 822         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 823         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 824         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 825         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 826
 827         // secrets
 828         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 829         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 830
 831         // monsters
 832         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 833         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 834
 835         // misc
 836         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 837
 838         next_pingtime = time + 5;
 839
 840         detect_maptype();
 841
 842         // set up information replies for clients and server to use
 843         maplist_reply = strzone(getmaplist());
 844         lsmaps_reply = strzone(getlsmaps());
 845         monsterlist_reply = strzone(getmonsterlist());
 846         for(int i = 0; i < 10; ++i)
 847         {
 848                 s = getrecords(i);
 849                 if (s)
 850                         records_reply[i] = strzone(s);
 851         }
 852         ladder_reply = strzone(getladder());
 853         rankings_reply = strzone(getrankings());
 854
 855         // begin other init
 856         ClientInit_Spawn();
 857         RandomSeed_Spawn();
 858         PingPLReport_Spawn();
 859
 860         CheatInit();
 861
 862         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 863
 864         // fill sv_curl_serverpackages from .serverpackage files
 865         if(autocvar_sv_curl_serverpackages_auto)
 866         {
 867                 s = "";
 868                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 869                 for(int i = 0; i < n; ++i)
 870                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 871                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 872                                 s = strcat(s, " ", argv(i));
 873                 fd = search_begin("*-serverpackage.txt", true, false);
 874                 if(fd >= 0)
 875                 {
 876                         j = search_getsize(fd);
 877                         for(int i = 0; i < j; ++i)
 878                                 s = strcat(s, " ", search_getfilename(fd, i));
 879                         search_end(fd);
 880                 }
 881                 fd = search_begin("*.serverpackage", true, false);
 882                 if(fd >= 0)
 883                 {
 884                         j = search_getsize(fd);
 885                         for(int i = 0; i < j; ++i)
 886                                 s = strcat(s, " ", search_getfilename(fd, i));
 887                         search_end(fd);
 888                 }
 889                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 890         }
 891
 892         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 893         modname = "Xonotic";
 894         // physics/balance/config changes that count as mod
 895         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 896                 modname = cvar_string("g_mod_physics");
 897         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 898                 modname = cvar_string("g_mod_balance");
 899         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 900                 modname = cvar_string("g_mod_config");
 901         // extra mutators that deserve to count as mod
 902         MUTATOR_CALLHOOK(SetModname);
 903
 904         // save it for later
 905         modname = strzone(modname);
 906
 907         WinningConditionHelper(); // set worldstatus
 908
 909         world_initialized = 1;
 910 }
 911
 912 spawnfunc(light)
 913 {
 914         //makestatic (self); // Who the f___ did that?
 915         remove(self);
 916 }
 917
 918 string GetGametype()
 919 {
 920         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 921 }
 922
 923 string GetMapname()
 924 {
 925         return mapname;
 926 }
 927
 928 float Map_Count, Map_Current;
 929 string Map_Current_Name;
 930
 931 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 932 float GetMaplistPosition()
 933 {
 934         float pos, idx;
 935         string map;
 936
 937         map = GetMapname();
 938         idx = autocvar_g_maplist_index;
 939
 940         if(idx >= 0)
 941                 if(idx < Map_Count)
 942                         if(map == argv(idx))
 943                                 return idx;
 944
 945         for(pos = 0; pos < Map_Count; ++pos)
 946                 if(map == argv(pos))
 947                         return pos;
 948
 949         // resume normal maplist rotation if current map is not in g_maplist
 950         return idx;
 951 }
 952
 953 float MapHasRightSize(string map)
 954 {
 955         float fh;
 956         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 957         if(autocvar_g_maplist_check_waypoints)
 958         {
 959                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 960                 if(!fexists(strcat("maps/", map, ".waypoints")))
 961                 {
 962                         LOG_TRACE(": no waypoints\n");
 963                         return false;
 964                 }
 965                 LOG_TRACE(": has waypoints\n");
 966         }
 967
 968         // open map size restriction file
 969         LOG_TRACE("opensize "); LOG_TRACE(map);
 970         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 971         if(fh >= 0)
 972         {
 973                 float mapmin, mapmax;
 974                 LOG_TRACE(": ok, ");
 975                 mapmin = stof(fgets(fh));
 976                 mapmax = stof(fgets(fh));
 977                 fclose(fh);
 978                 if(player_count < mapmin)
 979                 {
 980                         LOG_TRACE("not enough\n");
 981                         return false;
 982                 }
 983                 if(player_count > mapmax)
 984                 {
 985                         LOG_TRACE("too many\n");
 986                         return false;
 987                 }
 988                 LOG_TRACE("right size\n");
 989                 return true;
 990         }
 991         LOG_TRACE(": not found\n");
 992         return true;
 993 }
 994
 995 string Map_Filename(float position)
 996 {
 997         return strcat("maps/", argv(position), ".bsp");
 998 }
 999
1000 void Map_MarkAsRecent(string m)
1001 {
1002         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1003 }
1004
1005 float Map_IsRecent(string m)
1006 {
1007         return strhasword(autocvar_g_maplist_mostrecent, m);
1008 }
1009
1010 float Map_Check(float position, float pass)
1011 {
1012         string filename;
1013         string map_next;
1014         map_next = argv(position);
1015         if(pass <= 1)
1016         {
1017                 if(Map_IsRecent(map_next))
1018                         return 0;
1019         }
1020         filename = Map_Filename(position);
1021         if(MapInfo_CheckMap(map_next))
1022         {
1023                 if(pass == 2)
1024                         return 1;
1025                 if(MapHasRightSize(map_next))
1026                         return 1;
1027                 return 0;
1028         }
1029         else
1030                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1031
1032         return 0;
1033 }
1034
1035 void Map_Goto_SetStr(string nextmapname)
1036 {
1037         if(getmapname_stored != "")
1038                 strunzone(getmapname_stored);
1039         if(nextmapname == "")
1040                 getmapname_stored = "";
1041         else
1042                 getmapname_stored = strzone(nextmapname);
1043 }
1044
1045 void Map_Goto_SetFloat(float position)
1046 {
1047         cvar_set("g_maplist_index", ftos(position));
1048         Map_Goto_SetStr(argv(position));
1049 }
1050
1051 void Map_Goto(float reinit)
1052 {
1053         MapInfo_LoadMap(getmapname_stored, reinit);
1054 }
1055
1056 // return codes of map selectors:
1057 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1058 //   -2 = permanent failure
1059 float() MaplistMethod_Iterate = // usual method
1060 {
1061         float pass, i;
1062
1063         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1064
1065         for(pass = 1; pass <= 2; ++pass)
1066         {
1067                 for(i = 1; i < Map_Count; ++i)
1068                 {
1069                         float mapindex;
1070                         mapindex = (i + Map_Current) % Map_Count;
1071                         if(Map_Check(mapindex, pass))
1072                                 return mapindex;
1073                 }
1074         }
1075         return -1;
1076 }
1077
1078 float() MaplistMethod_Repeat = // fallback method
1079 {
1080         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1081
1082         if(Map_Check(Map_Current, 2))
1083                 return Map_Current;
1084         return -2;
1085 }
1086
1087 float() MaplistMethod_Random = // random map selection
1088 {
1089         float i, imax;
1090
1091         LOG_TRACE("Trying MaplistMethod_Random\n");
1092
1093         imax = 42;
1094
1095         for(i = 0; i <= imax; ++i)
1096         {
1097                 float mapindex;
1098                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1099                 if(Map_Check(mapindex, 1))
1100                         return mapindex;
1101         }
1102         return -1;
1103 }
1104
1105 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1106 // the exponent sets a bias on the map selection:
1107 // the higher the exponent, the less likely "shortly repeated" same maps are
1108 {
1109         float i, j, imax, insertpos;
1110
1111         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1112
1113         imax = 42;
1114
1115         for(i = 0; i <= imax; ++i)
1116         {
1117                 string newlist;
1118
1119                 // now reinsert this at another position
1120                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1121                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1122                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1123                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1124
1125                 // insert the current map there
1126                 newlist = "";
1127                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1128                         newlist = strcat(newlist, " ", argv(j));
1129                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1130                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1131                         newlist = strcat(newlist, " ", argv(j));
1132                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1133                 cvar_set("g_maplist", newlist);
1134                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1135
1136                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1137                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1138                 if(Map_Check(Map_Current, 1))
1139                         return Map_Current;
1140         }
1141         return -1;
1142 }
1143
1144 void Maplist_Init()
1145 {
1146         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1147         float i;
1148         for (i = 0; i < Map_Count; ++i)
1149                 if (Map_Check(i, 2))
1150                         break;
1151         if (i == Map_Count)
1152         {
1153                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1154                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1155                 if(autocvar_g_maplist_shuffle)
1156                         ShuffleMaplist();
1157                 localcmd("\nmenu_cmd sync\n");
1158                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1159         }
1160         if(Map_Count == 0)
1161                 error("empty maplist, cannot select a new map");
1162         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1163
1164         if(Map_Current_Name)
1165                 strunzone(Map_Current_Name);
1166         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1167         // this may or may not be correct, but who cares, in the worst case a map
1168         // isn't chosen in the first pass that should have been
1169 }
1170
1171 string GetNextMap()
1172 {
1173         float nextMap;
1174
1175         Maplist_Init();
1176         nextMap = -1;
1177
1178         if(nextMap == -1)
1179                 if(autocvar_g_maplist_shuffle > 0)
1180                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1181
1182         if(nextMap == -1)
1183                 if(autocvar_g_maplist_selectrandom)
1184                         nextMap = MaplistMethod_Random();
1185
1186         if(nextMap == -1)
1187                 nextMap = MaplistMethod_Iterate();
1188
1189         if(nextMap == -1)
1190                 nextMap = MaplistMethod_Repeat();
1191
1192         if(nextMap >= 0)
1193         {
1194                 Map_Goto_SetFloat(nextMap);
1195                 return getmapname_stored;
1196         }
1197
1198         return "";
1199 }
1200
1201 float DoNextMapOverride(float reinit)
1202 {
1203         if(autocvar_g_campaign)
1204         {
1205                 CampaignPostIntermission();
1206                 alreadychangedlevel = true;
1207                 return true;
1208         }
1209         if(autocvar_quit_when_empty)
1210         {
1211                 if(player_count <= currentbots)
1212                 {
1213                         localcmd("quit\n");
1214                         alreadychangedlevel = true;
1215                         return true;
1216                 }
1217         }
1218         if(autocvar_quit_and_redirect != "")
1219         {
1220                 redirection_target = strzone(autocvar_quit_and_redirect);
1221                 alreadychangedlevel = true;
1222                 return true;
1223         }
1224         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1225         {
1226                 localcmd("restart\n");
1227                 alreadychangedlevel = true;
1228                 return true;
1229         }
1230         if(autocvar_nextmap != "")
1231         {
1232                 string m;
1233                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1234                 cvar_set("nextmap",m);
1235
1236                 if(!m || gametypevote)
1237                         return false;
1238                 if(autocvar_sv_vote_gametype)
1239                 {
1240                         Map_Goto_SetStr(m);
1241                         return false;
1242                 }
1243
1244                 if(MapInfo_CheckMap(m))
1245                 {
1246                         Map_Goto_SetStr(m);
1247                         Map_Goto(reinit);
1248                         alreadychangedlevel = true;
1249                         return true;
1250                 }
1251         }
1252         if(!reinit && autocvar_lastlevel)
1253         {
1254                 cvar_settemp_restore();
1255                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1256                 alreadychangedlevel = true;
1257                 return true;
1258         }
1259         return false;
1260 }
1261
1262 void GotoNextMap(float reinit)
1263 {
1264         //string nextmap;
1265         //float n, nummaps;
1266         //string s;
1267         if (alreadychangedlevel)
1268                 return;
1269         alreadychangedlevel = true;
1270
1271         string nextMap;
1272
1273         nextMap = GetNextMap();
1274         if(nextMap == "")
1275                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1276         Map_Goto(reinit);
1277 }
1278
1279
1280 /*
1281 ============
1282 IntermissionThink
1283
1284 When the player presses attack or jump, change to the next level
1285 ============
1286 */
1287 .float autoscreenshot;
1288 void IntermissionThink()
1289 {SELFPARAM();
1290         FixIntermissionClient(self);
1291
1292         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1293         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1294
1295         if( (server_screenshot || client_screenshot)
1296                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1297         {
1298                 self.autoscreenshot = -1;
1299                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1300                 return;
1301         }
1302
1303         if (time < intermission_exittime)
1304                 return;
1305
1306         if(!mapvote_initialized)
1307                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1308                         return;
1309
1310         MapVote_Start();
1311 }
1312
1313 /*
1314 ============
1315 FindIntermission
1316
1317 Returns the entity to view from
1318 ============
1319 */
1320 /*
1321 entity FindIntermission()
1322 {
1323         local   entity spot;
1324         local   float cyc;
1325
1326 // look for info_intermission first
1327         spot = find (world, classname, "info_intermission");
1328         if (spot)
1329         {       // pick a random one
1330                 cyc = random() * 4;
1331                 while (cyc > 1)
1332                 {
1333                         spot = find (spot, classname, "info_intermission");
1334                         if (!spot)
1335                                 spot = find (spot, classname, "info_intermission");
1336                         cyc = cyc - 1;
1337                 }
1338                 return spot;
1339         }
1340
1341 // then look for the start position
1342         spot = find (world, classname, "info_player_start");
1343         if (spot)
1344                 return spot;
1345
1346 // testinfo_player_start is only found in regioned levels
1347         spot = find (world, classname, "testplayerstart");
1348         if (spot)
1349                 return spot;
1350
1351 // then look for the start position
1352         spot = find (world, classname, "info_player_deathmatch");
1353         if (spot)
1354                 return spot;
1355
1356         //objerror ("FindIntermission: no spot");
1357         return world;
1358 }
1359 */
1360
1361 /*
1362 ===============================================================================
1363
1364 RULES
1365
1366 ===============================================================================
1367 */
1368
1369 void DumpStats(float final)
1370 {
1371         float file;
1372         string s;
1373         float to_console;
1374         float to_eventlog;
1375         float to_file;
1376         float i;
1377
1378         to_console = autocvar_sv_logscores_console;
1379         to_eventlog = autocvar_sv_eventlog;
1380         to_file = autocvar_sv_logscores_file;
1381
1382         if(!final)
1383         {
1384                 to_console = true; // always print printstats replies
1385                 to_eventlog = false; // but never print them to the event log
1386         }
1387
1388         if(to_eventlog)
1389                 if(autocvar_sv_eventlog_console)
1390                         to_console = false; // otherwise we get the output twice
1391
1392         if(final)
1393                 s = ":scores:";
1394         else
1395                 s = ":status:";
1396         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1397
1398         if(to_console)
1399                 LOG_INFO(s, "\n");
1400         if(to_eventlog)
1401                 GameLogEcho(s);
1402
1403         file = -1;
1404         if(to_file)
1405         {
1406                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1407                 if(file == -1)
1408                         to_file = false;
1409                 else
1410                         fputs(file, strcat(s, "\n"));
1411         }
1412
1413         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1414         if(to_console)
1415                 LOG_INFO(s, "\n");
1416         if(to_eventlog)
1417                 GameLogEcho(s);
1418         if(to_file)
1419                 fputs(file, strcat(s, "\n"));
1420
1421         FOR_EACH_CLIENT(other)
1422         {
1423                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1424                 {
1425                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1426                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1427                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1428                                 s = strcat(s, ftos(other.team), ":");
1429                         else
1430                                 s = strcat(s, "spectator:");
1431
1432                         if(to_console)
1433                                 LOG_INFO(s, other.netname, "\n");
1434                         if(to_eventlog)
1435                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1436                         if(to_file)
1437                                 fputs(file, strcat(s, other.netname, "\n"));
1438                 }
1439         }
1440
1441         if(teamplay)
1442         {
1443                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1444                 if(to_console)
1445                         LOG_INFO(s, "\n");
1446                 if(to_eventlog)
1447                         GameLogEcho(s);
1448                 if(to_file)
1449                         fputs(file, strcat(s, "\n"));
1450
1451                 for(i = 1; i < 16; ++i)
1452                 {
1453                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1454                         s = strcat(s, ":", ftos(i));
1455                         if(to_console)
1456                                 LOG_INFO(s, "\n");
1457                         if(to_eventlog)
1458                                 GameLogEcho(s);
1459                         if(to_file)
1460                                 fputs(file, strcat(s, "\n"));
1461                 }
1462         }
1463
1464         if(to_console)
1465                 LOG_INFO(":end\n");
1466         if(to_eventlog)
1467                 GameLogEcho(":end");
1468         if(to_file)
1469         {
1470                 fputs(file, ":end\n");
1471                 fclose(file);
1472         }
1473 }
1474
1475 void FixIntermissionClient(entity e)
1476 {
1477         string s;
1478         if(!e.autoscreenshot) // initial call
1479         {
1480                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1481                 e.health = -2342;
1482                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1483                 e.solid = SOLID_NOT;
1484                 e.movetype = MOVETYPE_NONE;
1485                 e.takedamage = DAMAGE_NO;
1486                 if(e.weaponentity)
1487                 {
1488                         e.weaponentity.effects = EF_NODRAW;
1489                         if (e.weaponentity.weaponentity)
1490                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1491                 }
1492                 if(IS_REAL_CLIENT(e))
1493                 {
1494                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1495                         s = autocvar_sv_intermission_cdtrack;
1496                         if(s != "")
1497                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1498                         msg_entity = e;
1499                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1500                 }
1501         }
1502 }
1503
1504 /*
1505 go to the next level for deathmatch
1506 only called if a time or frag limit has expired
1507 */
1508 void NextLevel()
1509 {
1510         gameover = true;
1511
1512         intermission_running = 1;
1513
1514 // enforce a wait time before allowing changelevel
1515         if(player_count > 0)
1516                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1517         else
1518                 intermission_exittime = -1;
1519
1520         /*
1521         WriteByte (MSG_ALL, SVC_CDTRACK);
1522         WriteByte (MSG_ALL, 3);
1523         WriteByte (MSG_ALL, 3);
1524         // done in FixIntermission
1525         */
1526
1527         //pos = FindIntermission ();
1528
1529         VoteReset();
1530
1531         DumpStats(true);
1532
1533         // send statistics
1534         PlayerStats_GameReport(true);
1535         WeaponStats_Shutdown();
1536
1537         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1538
1539         if(autocvar_sv_eventlog)
1540                 GameLogEcho(":gameover");
1541
1542         GameLogClose();
1543
1544         FOR_EACH_PLAYER(other) {
1545                 FixIntermissionClient(other);
1546                 if(other.winning)
1547                         bprint(other.netname, " ^7wins.\n");
1548         }
1549
1550         entity oldself = self;
1551         target_music_kill();
1552         self = oldself;
1553
1554         if(autocvar_g_campaign)
1555                 CampaignPreIntermission();
1556
1557         MUTATOR_CALLHOOK(MatchEnd);
1558
1559         localcmd("\nsv_hook_gameend\n");
1560 }
1561
1562 /*
1563 ============
1564 CheckRules_Player
1565
1566 Exit deathmatch games upon conditions
1567 ============
1568 */
1569 void CheckRules_Player()
1570 {SELFPARAM();
1571         if (gameover)   // someone else quit the game already
1572                 return;
1573
1574         if(self.deadflag == DEAD_NO)
1575                 self.play_time += frametime;
1576
1577         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1578         //   (div0: and that in CheckRules_World please)
1579 }
1580
1581
1582 float InitiateSuddenDeath()
1583 {
1584         // Check first whether normal overtimes could be added before initiating suddendeath mode
1585         // - for this timelimit_overtime needs to be >0 of course
1586         // - also check the winning condition calculated in the previous frame and only add normal overtime
1587         //   again, if at the point at which timelimit would be extended again, still no winner was found
1588         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1589         {
1590                 return 1; // need to call InitiateOvertime later
1591         }
1592         else
1593         {
1594                 if(!checkrules_suddendeathend)
1595                 {
1596                         if(autocvar_g_campaign)
1597                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1598                         else
1599                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1600                         if(g_race && !g_race_qualifying)
1601                                 race_StartCompleting();
1602                 }
1603                 return 0;
1604         }
1605 }
1606
1607 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1608 {
1609         ++checkrules_overtimesadded;
1610         //add one more overtime by simply extending the timelimit
1611         float tl;
1612         tl = autocvar_timelimit;
1613         tl += autocvar_timelimit_overtime;
1614         cvar_set("timelimit", ftos(tl));
1615
1616         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1617 }
1618
1619 float GetWinningCode(float fraglimitreached, float equality)
1620 {
1621         if(autocvar_g_campaign == 1)
1622                 if(fraglimitreached)
1623                         return WINNING_YES;
1624                 else
1625                         return WINNING_NO;
1626
1627         else
1628                 if(equality)
1629                         if(fraglimitreached)
1630                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1631                         else
1632                                 return WINNING_NEVER;
1633                 else
1634                         if(fraglimitreached)
1635                                 return WINNING_YES;
1636                         else
1637                                 return WINNING_NO;
1638 }
1639
1640 // set the .winning flag for exactly those players with a given field value
1641 void SetWinners(.float field, float value)
1642 {
1643         entity head;
1644         FOR_EACH_PLAYER(head)
1645                 head.winning = (head.(field) == value);
1646 }
1647
1648 // set the .winning flag for those players with a given field value
1649 void AddWinners(.float field, float value)
1650 {
1651         entity head;
1652         FOR_EACH_PLAYER(head)
1653                 if (head.(field) == value)
1654                         head.winning = 1;
1655 }
1656
1657 // clear the .winning flags
1658 void ClearWinners(void)
1659 {
1660         entity head;
1661         FOR_EACH_PLAYER(head)
1662                 head.winning = 0;
1663 }
1664
1665 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1666 // they win. Otherwise the defending team wins once the timelimit passes.
1667 void assault_new_round();
1668 float WinningCondition_Assault()
1669 {SELFPARAM();
1670         float status;
1671
1672         WinningConditionHelper(); // set worldstatus
1673
1674         status = WINNING_NO;
1675         // as the timelimit has not yet passed just assume the defending team will win
1676         if(assault_attacker_team == NUM_TEAM_1)
1677         {
1678                 SetWinners(team, NUM_TEAM_2);
1679         }
1680         else
1681         {
1682                 SetWinners(team, NUM_TEAM_1);
1683         }
1684
1685         entity ent;
1686         ent = find(world, classname, "target_assault_roundend");
1687         if(ent)
1688         {
1689                 if(ent.winning) // round end has been triggered by attacking team
1690                 {
1691                         bprint("ASSAULT: round completed...\n");
1692                         SetWinners(team, assault_attacker_team);
1693
1694                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1695
1696                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1697                         {
1698                                 status = WINNING_YES;
1699                         }
1700                         else
1701                         {
1702                                 WITH(entity, self, ent, assault_new_round());
1703                         }
1704                 }
1705         }
1706
1707         return status;
1708 }
1709
1710 // LMS winning condition: game terminates if and only if there's at most one
1711 // one player who's living lives. Top two scores being equal cancels the time
1712 // limit.
1713 float WinningCondition_LMS()
1714 {
1715         entity head, head2;
1716         float have_player;
1717         float have_players;
1718         float l;
1719
1720         have_player = false;
1721         have_players = false;
1722         l = LMS_NewPlayerLives();
1723
1724         head = find(world, classname, "player");
1725         if(head)
1726                 have_player = true;
1727         head2 = find(head, classname, "player");
1728         if(head2)
1729                 have_players = true;
1730
1731         if(have_player)
1732         {
1733                 // we have at least one player
1734                 if(have_players)
1735                 {
1736                         // two or more active players - continue with the game
1737                 }
1738                 else
1739                 {
1740                         // exactly one player?
1741
1742                         ClearWinners();
1743                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1744
1745                         if(l)
1746                         {
1747                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1748                                 return WINNING_NO;
1749                         }
1750                         else
1751                         {
1752                                 // a winner!
1753                                 // and assign him his first place
1754                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1755                                 return WINNING_YES;
1756                         }
1757                 }
1758         }
1759         else
1760         {
1761                 // nobody is playing at all...
1762                 if(l)
1763                 {
1764                         // wait for players...
1765                 }
1766                 else
1767                 {
1768                         // SNAFU (maybe a draw game?)
1769                         ClearWinners();
1770                         LOG_TRACE("No players, ending game.\n");
1771                         return WINNING_YES;
1772                 }
1773         }
1774
1775         // When we get here, we have at least two players who are actually LIVING,
1776         // now check if the top two players have equal score.
1777         WinningConditionHelper();
1778
1779         ClearWinners();
1780         if(WinningConditionHelper_winner)
1781                 WinningConditionHelper_winner.winning = true;
1782         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1783                 return WINNING_NEVER;
1784
1785         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1786         return WINNING_NO;
1787 }
1788
1789 void ShuffleMaplist()
1790 {
1791         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1792 }
1793
1794 float leaderfrags;
1795 float WinningCondition_Scores(float limit, float leadlimit)
1796 {
1797         float limitreached;
1798
1799         // TODO make everything use THIS winning condition (except LMS)
1800         WinningConditionHelper();
1801
1802         if(teamplay)
1803         {
1804                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1805                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1806                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1807                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1808         }
1809
1810         ClearWinners();
1811         if(WinningConditionHelper_winner)
1812                 WinningConditionHelper_winner.winning = 1;
1813         if(WinningConditionHelper_winnerteam >= 0)
1814                 SetWinners(team, WinningConditionHelper_winnerteam);
1815
1816         if(WinningConditionHelper_lowerisbetter)
1817         {
1818                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1819                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1820                 limit = -limit;
1821         }
1822
1823         if(WinningConditionHelper_zeroisworst)
1824                 leadlimit = 0; // not supported in this mode
1825
1826         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1827         // these modes always score in increments of 1, thus this makes sense
1828         {
1829                 if(leaderfrags != WinningConditionHelper_topscore)
1830                 {
1831                         leaderfrags = WinningConditionHelper_topscore;
1832
1833                         if (limit)
1834                         if (leaderfrags == limit - 1)
1835                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1836                         else if (leaderfrags == limit - 2)
1837                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1838                         else if (leaderfrags == limit - 3)
1839                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1840                 }
1841         }
1842
1843         limitreached = false;
1844         if(limit)
1845                 if(WinningConditionHelper_topscore >= limit)
1846                         limitreached = true;
1847         if(leadlimit)
1848         {
1849                 float leadlimitreached;
1850                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1851                 if(autocvar_leadlimit_and_fraglimit)
1852                         limitreached = (limitreached && leadlimitreached);
1853                 else
1854                         limitreached = (limitreached || leadlimitreached);
1855         }
1856
1857         if(limit)
1858                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1859
1860         return GetWinningCode(
1861                 WinningConditionHelper_topscore && limitreached,
1862                 WinningConditionHelper_equality
1863         );
1864 }
1865
1866 float WinningCondition_Race(float fraglimit)
1867 {
1868         float wc;
1869         entity p;
1870         float n, c;
1871
1872         n = 0;
1873         c = 0;
1874         FOR_EACH_PLAYER(p)
1875         {
1876                 ++n;
1877                 if(p.race_completed)
1878                         ++c;
1879         }
1880         if(n && (n == c))
1881                 return WINNING_YES;
1882         wc = WinningCondition_Scores(fraglimit, 0);
1883
1884         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1885         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1886         // do NOT support equality when the laps are all raced!
1887                 return WINNING_STARTSUDDENDEATHOVERTIME;
1888         else
1889                 return WINNING_NEVER;
1890 }
1891
1892 float WinningCondition_QualifyingThenRace(float limit)
1893 {
1894         float wc;
1895         wc = WinningCondition_Scores(limit, 0);
1896
1897         // NEVER initiate overtime
1898         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1899         {
1900                 return WINNING_YES;
1901         }
1902
1903         return wc;
1904 }
1905
1906 float WinningCondition_RanOutOfSpawns()
1907 {
1908         entity head;
1909
1910         if(have_team_spawns <= 0)
1911                 return WINNING_NO;
1912
1913         if(!autocvar_g_spawn_useallspawns)
1914                 return WINNING_NO;
1915
1916         if(!some_spawn_has_been_used)
1917                 return WINNING_NO;
1918
1919         team1_score = team2_score = team3_score = team4_score = 0;
1920
1921         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1922         {
1923                 if(head.team == NUM_TEAM_1)
1924                         team1_score = 1;
1925                 else if(head.team == NUM_TEAM_2)
1926                         team2_score = 1;
1927                 else if(head.team == NUM_TEAM_3)
1928                         team3_score = 1;
1929                 else if(head.team == NUM_TEAM_4)
1930                         team4_score = 1;
1931         }
1932
1933         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1934         {
1935                 if(head.team == NUM_TEAM_1)
1936                         team1_score = 1;
1937                 else if(head.team == NUM_TEAM_2)
1938                         team2_score = 1;
1939                 else if(head.team == NUM_TEAM_3)
1940                         team3_score = 1;
1941                 else if(head.team == NUM_TEAM_4)
1942                         team4_score = 1;
1943         }
1944
1945         ClearWinners();
1946         if(team1_score + team2_score + team3_score + team4_score == 0)
1947         {
1948                 checkrules_equality = true;
1949                 return WINNING_YES;
1950         }
1951         else if(team1_score + team2_score + team3_score + team4_score == 1)
1952         {
1953                 float t, i;
1954                 if(team1_score)
1955                         t = NUM_TEAM_1;
1956                 else if(team2_score)
1957                         t = NUM_TEAM_2;
1958                 else if(team3_score)
1959                         t = NUM_TEAM_3;
1960                 else // if(team4_score)
1961                         t = NUM_TEAM_4;
1962                 CheckAllowedTeams(world);
1963                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1964                 {
1965                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1966                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1967                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1968                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1969                 }
1970
1971                 AddWinners(team, t);
1972                 return WINNING_YES;
1973         }
1974         else
1975                 return WINNING_NO;
1976 }
1977
1978 /*
1979 ============
1980 CheckRules_World
1981
1982 Exit deathmatch games upon conditions
1983 ============
1984 */
1985 void CheckRules_World()
1986 {
1987         float timelimit;
1988         float fraglimit;
1989         float leadlimit;
1990
1991         VoteThink();
1992         MapVote_Think();
1993
1994         SetDefaultAlpha();
1995
1996         if (gameover)   // someone else quit the game already
1997         {
1998                 if(player_count == 0) // Nobody there? Then let's go to the next map
1999                         MapVote_Start();
2000                         // this will actually check the player count in the next frame
2001                         // again, but this shouldn't hurt
2002                 return;
2003         }
2004
2005         timelimit = autocvar_timelimit * 60;
2006         fraglimit = autocvar_fraglimit;
2007         leadlimit = autocvar_leadlimit;
2008
2009         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2010         {
2011                 if(timelimit > 0)
2012                         timelimit = 0; // timelimit is not made for warmup
2013                 if(fraglimit > 0)
2014                         fraglimit = 0; // no fraglimit for now
2015                 leadlimit = 0; // no leadlimit for now
2016         }
2017
2018         if(timelimit > 0)
2019         {
2020                 timelimit += game_starttime;
2021         }
2022         else if (timelimit < 0)
2023         {
2024                 // endmatch
2025                 NextLevel();
2026                 return;
2027         }
2028
2029         float wantovertime;
2030         wantovertime = 0;
2031
2032         if(timelimit > game_starttime)
2033                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2034         else
2035                 game_completion_ratio = 0;
2036
2037         if(checkrules_suddendeathend)
2038         {
2039                 if(!checkrules_suddendeathwarning)
2040                 {
2041                         checkrules_suddendeathwarning = true;
2042                         if(g_race && !g_race_qualifying)
2043                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2044                         else
2045                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2046                 }
2047         }
2048         else
2049         {
2050                 if (timelimit && time >= timelimit)
2051                 {
2052                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2053                         {
2054                                 float totalplayers;
2055                                 float playerswithlaps;
2056                                 float readyplayers;
2057                                 entity head;
2058                                 totalplayers = playerswithlaps = readyplayers = 0;
2059                                 FOR_EACH_PLAYER(head)
2060                                 {
2061                                         ++totalplayers;
2062                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2063                                                 ++playerswithlaps;
2064                                         if(head.ready)
2065                                                 ++readyplayers;
2066                                 }
2067
2068                                 // at least 2 of the players have completed a lap: start the RACE
2069                                 // otherwise, the players should end the qualifying on their own
2070                                 if(readyplayers || playerswithlaps >= 2)
2071                                 {
2072                                         checkrules_suddendeathend = 0;
2073                                         ReadyRestart(); // go to race
2074                                         return;
2075                                 }
2076                                 else
2077                                         wantovertime |= InitiateSuddenDeath();
2078                         }
2079                         else
2080                                 wantovertime |= InitiateSuddenDeath();
2081                 }
2082         }
2083
2084         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2085         {
2086                 NextLevel();
2087                 return;
2088         }
2089
2090         float checkrules_status;
2091         checkrules_status = WinningCondition_RanOutOfSpawns();
2092         if(checkrules_status == WINNING_YES)
2093         {
2094                 bprint("Hey! Someone ran out of spawns!\n");
2095         }
2096         else if(g_race && !g_race_qualifying && timelimit >= 0)
2097         {
2098                 checkrules_status = WinningCondition_Race(fraglimit);
2099                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2100         }
2101         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2102         {
2103                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2104                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2105         }
2106         else if(g_assault)
2107         {
2108                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2109         }
2110         else if(g_lms)
2111         {
2112                 checkrules_status = WinningCondition_LMS();
2113         }
2114         else
2115         {
2116                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2117                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2118         }
2119
2120         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2121         {
2122                 checkrules_status = WINNING_NEVER;
2123                 checkrules_overtimesadded = -1;
2124                 wantovertime |= InitiateSuddenDeath();
2125         }
2126
2127         if(checkrules_status == WINNING_NEVER)
2128                 // equality cases! Nobody wins if the overtime ends in a draw.
2129                 ClearWinners();
2130
2131         if(wantovertime)
2132         {
2133                 if(checkrules_status == WINNING_NEVER)
2134                         InitiateOvertime();
2135                 else
2136                         checkrules_status = WINNING_YES;
2137         }
2138
2139         if(checkrules_suddendeathend)
2140                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2141                         checkrules_status = WINNING_YES;
2142
2143         if(checkrules_status == WINNING_YES)
2144         {
2145                 //print("WINNING\n");
2146                 NextLevel();
2147         }
2148 }
2149
2150 string GotoMap(string m)
2151 {
2152         m = GameTypeVote_MapInfo_FixName(m);
2153         if (!m)
2154                 return "The map you suggested is not available on this server.";
2155         if (!autocvar_sv_vote_gametype)
2156         if(!MapInfo_CheckMap(m))
2157                 return "The map you suggested does not support the current game mode.";
2158         cvar_set("nextmap", m);
2159         cvar_set("timelimit", "-1");
2160         if(mapvote_initialized || alreadychangedlevel)
2161         {
2162                 if(DoNextMapOverride(0))
2163                         return "Map switch initiated.";
2164                 else
2165                         return "Hm... no. For some reason I like THIS map more.";
2166         }
2167         else
2168                 return "Map switch will happen after scoreboard.";
2169 }
2170
2171
2172 void EndFrame()
2173 {SELFPARAM();
2174         anticheat_endframe();
2175
2176         float altime;
2177         entity e_;
2178         FOR_EACH_REALCLIENT(e_)
2179         {
2180                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2181                 if(e.typehitsound)
2182                         e_.typehit_time = time;
2183                 else if(e.damage_dealt)
2184                 {
2185                         e_.hit_time = time;
2186                         e_.damage_dealt_total += ceil(e.damage_dealt);
2187                 }
2188         }
2189         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2190         // add 1 frametime because after this, engine SV_Physics
2191         // increases time by a frametime and then networks the frame
2192         // add another frametime because client shows everything with
2193         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2194         // needed!
2195         FOR_EACH_CLIENT(e_)
2196         {
2197                 e_.typehitsound = false;
2198                 e_.damage_dealt = 0;
2199                 setself(e_);
2200                 antilag_record(e_, altime);
2201         }
2202         FOR_EACH_MONSTER(e_)
2203         {
2204                 setself(e_);
2205                 antilag_record(e_, altime);
2206         }
2207 }
2208
2209
2210 /*
2211  * RedirectionThink:
2212  * returns true if redirecting
2213  */
2214 float redirection_timeout;
2215 float redirection_nextthink;
2216 float RedirectionThink()
2217 {SELFPARAM();
2218         float clients_found;
2219
2220         if(redirection_target == "")
2221                 return false;
2222
2223         if(!redirection_timeout)
2224         {
2225                 cvar_set("sv_public", "-2");
2226                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2227                 if(redirection_target == "self")
2228                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2229                 else
2230                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2231         }
2232
2233         if(time < redirection_nextthink)
2234                 return true;
2235
2236         redirection_nextthink = time + 1;
2237
2238         clients_found = 0;
2239         entity e;
2240         FOR_EACH_REALCLIENT(e)
2241         {
2242                 setself(e);
2243                 // TODO add timer
2244                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2245                 if(redirection_target == "self")
2246                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2247                 else
2248                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2249                 ++clients_found;
2250         }
2251
2252         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2253
2254         if(time > redirection_timeout || clients_found == 0)
2255                 localcmd("\nwait; wait; wait; quit\n");
2256
2257         return true;
2258 }
2259
2260 void TargetMusic_RestoreGame();
2261 void RestoreGame()
2262 {
2263         // Loaded from a save game
2264         // some things then break, so let's work around them...
2265
2266         // Progs DB (capture records)
2267         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2268
2269         // Mapinfo
2270         MapInfo_Shutdown();
2271         MapInfo_Enumerate();
2272         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2273         WeaponStats_Init();
2274
2275         TargetMusic_RestoreGame();
2276 }
2277
2278 void Shutdown()
2279 {
2280         gameover = 2;
2281
2282         if(world_initialized > 0)
2283         {
2284                 world_initialized = 0;
2285                 LOG_INFO("Saving persistent data...\n");
2286                 Ban_SaveBans();
2287
2288                 // playerstats with unfinished match
2289                 PlayerStats_GameReport(false);
2290
2291                 if(!cheatcount_total)
2292                 {
2293                         if(autocvar_sv_db_saveasdump)
2294                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2295                         else
2296                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2297                 }
2298                 if(autocvar_developer)
2299                 {
2300                         if(autocvar_sv_db_saveasdump)
2301                                 db_dump(TemporaryDB, "server-temp.db");
2302                         else
2303                                 db_save(TemporaryDB, "server-temp.db");
2304                 }
2305                 CheatShutdown(); // must be after cheatcount check
2306                 db_close(ServerProgsDB);
2307                 db_close(TemporaryDB);
2308                 LOG_INFO("done!\n");
2309                 // tell the bot system the game is ending now
2310                 bot_endgame();
2311
2312                 WeaponStats_Shutdown();
2313                 MapInfo_Shutdown();
2314         }
2315         else if(world_initialized == 0)
2316         {
2317                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2318         }
2319 }