qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("cl_");
 250                 BADPREFIX("con_");
 251                 BADPREFIX("g_campaign");
 252                 BADPREFIX("gl_");
 253                 BADPREFIX("joy");
 254                 BADPREFIX("hud_");
 255                 BADPREFIX("menu_");
 256                 BADPREFIX("net_slist_");
 257                 BADPREFIX("r_");
 258                 BADPREFIX("sbar_");
 259                 BADPREFIX("scr_");
 260                 BADPREFIX("userbind");
 261                 BADPREFIX("v_");
 262                 BADPREFIX("vid_");
 263                 BADPREFIX("crosshair");
 264                 BADCVAR("mod_q3bsp_lightmapmergepower");
 265                 BADCVAR("mod_q3bsp_nolightmaps");
 266
 267                 // private
 268                 BADCVAR("serverconfig");
 269                 BADPREFIX("g_ban_");
 270                 BADPREFIX("g_chat_flood_");
 271                 BADPREFIX("g_voice_flood_");
 272                 BADPREFIX("rcon_");
 273                 BADPREFIX("settemp_");
 274                 BADPREFIX("sv_allowdownloads_");
 275                 BADPREFIX("sv_autodemo");
 276                 BADPREFIX("sv_curl_");
 277                 BADPREFIX("sv_eventlog");
 278                 BADPREFIX("sv_logscores_");
 279                 BADPREFIX("sv_master");
 280                 BADCVAR("g_banned_list");
 281                 BADCVAR("log_dest_udp");
 282                 BADCVAR("log_file");
 283                 BADCVAR("net_address");
 284                 BADCVAR("port");
 285                 BADCVAR("savedgamecfg");
 286                 BADCVAR("sv_heartbeatperiod");
 287                 BADCVAR("sv_vote_master_password");
 288                 BADCVAR("sys_colortranslation");
 289                 BADCVAR("sys_specialcharactertranslation");
 290                 BADCVAR("timestamps");
 291                 BADCVAR("net_address");
 292                 BADCVAR("net_address_ipv6");
 293                 BADPREFIX("sv_weaponstats_");
 294
 295                 // mapinfo
 296                 BADCVAR("timelimit");
 297                 BADCVAR("fraglimit");
 298                 BADCVAR("g_arena");
 299                 BADCVAR("g_ca");
 300                 BADCVAR("g_assault");
 301                 BADCVAR("g_ctf");
 302                 BADCVAR("g_dm");
 303                 BADCVAR("g_domination");
 304                 BADCVAR("g_keyhunt");
 305                 BADCVAR("g_keyhunt_teams");
 306                 BADCVAR("g_onslaught");
 307                 BADCVAR("g_race");
 308                 BADCVAR("g_cts");
 309                 BADCVAR("g_runematch");
 310                 BADCVAR("g_tdm");
 311                 BADCVAR("g_nexball");
 312                 BADCVAR("teamplay");
 313
 314                 // long
 315                 BADCVAR("hostname");
 316                 BADCVAR("g_maplist");
 317                 BADCVAR("g_maplist_mostrecent");
 318                 BADCVAR("sv_motd");
 319
 320                 v = cvar_string(k);
 321                 d = cvar_defstring(k);
 322                 if(v == d)
 323                         continue;
 324
 325                 if(adding)
 326                 {
 327                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 328                         if(strlen(cvar_changes) > 16384)
 329                         {
 330                                 cvar_changes = "// too many settings have been changed to show them here\n";
 331                                 adding = 0;
 332                         }
 333                 }
 334
 335                 // now check if the changes are actually gameplay relevant
 336
 337                 // does nothing visible
 338                 BADPREFIX("prvm_");
 339                 BADCVAR("bot_prefix");
 340                 BADCVAR("bot_suffix");
 341
 342                 // allowed changes to server admins (please sync this to server.cfg)
 343                 // vi commands:
 344                 //   :/"impure"/,$d
 345                 //   :g!,^\/\/[^ /],d
 346                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 347                 //   :%!sort
 348                 // yes, this does contain some redundant stuff, don't really care
 349                 BADCVAR("bot_number");
 350                 BADCVAR("bot_prefix");
 351                 BADCVAR("bot_suffix");
 352                 BADCVAR("capturelimit_override");
 353                 BADCVAR("fraglimit_override");
 354                 BADCVAR("gametype");
 355                 BADCVAR("g_antilag");
 356                 BADCVAR("g_balance_teams");
 357                 BADCVAR("g_balance_teams_force");
 358                 BADCVAR("g_ban_sync_trusted_servers");
 359                 BADCVAR("g_ban_sync_uri");
 360                 BADCVAR("g_ctf_capture_limit");
 361                 BADCVAR("g_ctf_ignore_frags");
 362                 BADCVAR("g_ctf_win_mode");
 363                 BADCVAR("g_domination_point_limit");
 364                 BADCVAR("g_fullbrightitems");
 365                 BADCVAR("g_fullbrightplayers");
 366                 BADCVAR("g_keyhunt_point_limit");
 367                 BADCVAR("g_keyhunt_teams_override");
 368                 BADCVAR("g_lms_lives_override");
 369                 BADCVAR("g_maplist");
 370                 BADCVAR("g_maplist_check_waypoints");
 371                 BADCVAR("g_maplist_mostrecent_count");
 372                 BADCVAR("g_maplist_shuffle");
 373                 BADCVAR("g_maplist_votable");
 374                 BADCVAR("g_maplist_votable_abstain");
 375                 BADCVAR("g_maplist_votable_nodetail");
 376                 BADCVAR("g_maplist_votable_suggestions");
 377                 BADCVAR("g_nexball_goallimit");
 378                 BADCVAR("g_runematch_point_limit");
 379                 BADCVAR("hostname");
 380                 BADCVAR("log_file");
 381                 BADCVAR("maxplayers");
 382                 BADCVAR("minplayers");
 383                 BADCVAR("net_address");
 384                 BADCVAR("port");
 385                 BADCVAR("rcon_password");
 386                 BADCVAR("rcon_restricted_commands");
 387                 BADCVAR("rcon_restricted_password");
 388                 BADCVAR("skill");
 389                 BADCVAR("sv_autoscreenshot");
 390                 BADCVAR("sv_curl_defaulturl");
 391                 BADCVAR("sv_defaultcharacter");
 392                 BADCVAR("sv_defaultplayermodel");
 393                 BADCVAR("sv_defaultplayerskin");
 394                 BADCVAR("sv_maxrate");
 395                 BADCVAR("sv_motd");
 396                 BADCVAR("sv_public");
 397                 BADCVAR("sv_ready_restart");
 398                 BADCVAR("sv_status_privacy");
 399                 BADCVAR("sv_vote_call");
 400                 BADCVAR("sv_vote_commands");
 401                 BADCVAR("sv_vote_majority_factor");
 402                 BADCVAR("sv_vote_master");
 403                 BADCVAR("sv_vote_master_commands");
 404                 BADCVAR("sv_vote_master_password");
 405                 BADCVAR("sv_vote_simple_majority_factor");
 406                 BADCVAR("timelimit_override");
 407 #undef BADPREFIX
 408 #undef BADCVAR
 409
 410                 if(pureadding)
 411                 {
 412                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 413                         if(strlen(cvar_purechanges) > 16384)
 414                         {
 415                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 416                                 pureadding = 0;
 417                         }
 418                 }
 419                 ++cvar_purechanges_count;
 420         }
 421         buf_del(h);
 422         if(cvar_changes == "")
 423                 cvar_changes = "// this server runs at default server settings\n";
 424         else
 425                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 426         cvar_changes = strzone(cvar_changes);
 427         if(cvar_purechanges == "")
 428                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 429         else
 430                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 431         cvar_purechanges = strzone(cvar_purechanges);
 432 }
 433
 434 void detect_maptype()
 435 {
 436 #if 0
 437         vector o, v;
 438         float i;
 439
 440         for(;;)
 441         {
 442                 o = world.mins;
 443                 o_x += random() * (world.maxs_x - world.mins_x);
 444                 o_y += random() * (world.maxs_y - world.mins_y);
 445                 o_z += random() * (world.maxs_z - world.mins_z);
 446
 447                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 448                 if(trace_fraction == 1)
 449                         continue;
 450
 451                 v = trace_endpos;
 452
 453                 for(i = 0; i < 64; i += 4)
 454                 {
 455                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 456         if(trace_fraction == 1)
 457                 continue;
 458                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 459                 }
 460
 461                 break;
 462         }
 463 #endif
 464 }
 465
 466 entity randomseed;
 467 float RandomSeed_Send(entity to, float sf)
 468 {
 469         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 470         WriteShort(MSG_ENTITY, self.cnt);
 471         return TRUE;
 472 }
 473 void RandomSeed_Think()
 474 {
 475         self.cnt = bound(0, floor(random() * 65536), 65535);
 476         self.nextthink = time + 5;
 477
 478         self.SendFlags |= 1;
 479 }
 480 void RandomSeed_Spawn()
 481 {
 482         randomseed = spawn();
 483         randomseed.think = RandomSeed_Think;
 484         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 485
 486         entity oldself;
 487         oldself = self;
 488         self = randomseed;
 489         self.think(); // sets random seed and nextthink
 490         self = oldself;
 491 }
 492
 493 void spawnfunc___init_dedicated_server(void)
 494 {
 495         // handler for _init/_init map (only for dedicated server initialization)
 496
 497         world_initialized = -1; // don't complain
 498         cvar = cvar_normal;
 499         cvar_string = cvar_string_normal;
 500         cvar_set = cvar_set_normal;
 501
 502         remove = remove_unsafely;
 503
 504         entity e;
 505         e = spawn();
 506         e.think = GotoFirstMap;
 507         e.nextthink = time; // this is usually 1 at this point
 508
 509         e = spawn();
 510         e.classname = "info_player_deathmatch"; // safeguard against player joining
 511
 512         self.classname = "worldspawn"; // safeguard against various stuff ;)
 513
 514         MapInfo_Enumerate();
 515         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 516 }
 517
 518 void Map_MarkAsRecent(string m);
 519 float world_already_spawned;
 520 void RegisterWeapons();
 521 void Nagger_Init();
 522 void ClientInit_Spawn();
 523 void WeaponStats_Init();
 524 void WeaponStats_Shutdown();
 525 void spawnfunc_worldspawn (void)
 526 {
 527         float fd, l, i, j, n;
 528         string s, col;
 529
 530         cvar = cvar_normal;
 531         cvar_string = cvar_string_normal;
 532         cvar_set = cvar_set_normal;
 533
 534         if(world_already_spawned)
 535                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 536         world_already_spawned = TRUE;
 537
 538         remove = remove_safely; // during spawning, watch what you remove!
 539
 540         check_unacceptable_compiler_bugs();
 541
 542         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 543
 544         compressShortVector_init();
 545
 546         allowed_to_spawn = TRUE;
 547
 548         local entity head;
 549         head = nextent(world);
 550         maxclients = 0;
 551         while(head)
 552         {
 553                 ++maxclients;
 554                 head = nextent(head);
 555         }
 556
 557         // needs to be done so early as they would still spawn
 558         RegisterWeapons();
 559
 560         ServerProgsDB = db_load("server.db");
 561
 562         TemporaryDB = db_create();
 563
 564         /*
 565         TODO sound pack system
 566         // initialize sound pack system
 567         soundpack = cvar_string("g_soundpack");
 568         if(soundpack != "")
 569                 soundpack = strcat(soundpack, "/");
 570         soundpack = strzone(soundpack);
 571         */
 572
 573         // 0 normal
 574         lightstyle(0, "m");
 575
 576         // 1 FLICKER (first variety)
 577         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 578
 579         // 2 SLOW STRONG PULSE
 580         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 581
 582         // 3 CANDLE (first variety)
 583         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 584
 585         // 4 FAST STROBE
 586         lightstyle(4, "mamamamamama");
 587
 588         // 5 GENTLE PULSE 1
 589         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 590
 591         // 6 FLICKER (second variety)
 592         lightstyle(6, "nmonqnmomnmomomno");
 593
 594         // 7 CANDLE (second variety)
 595         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 596
 597         // 8 CANDLE (third variety)
 598         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 599
 600         // 9 SLOW STROBE (fourth variety)
 601         lightstyle(9, "aaaaaaaazzzzzzzz");
 602
 603         // 10 FLUORESCENT FLICKER
 604         lightstyle(10, "mmamammmmammamamaaamammma");
 605
 606         // 11 SLOW PULSE NOT FADE TO BLACK
 607         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 608
 609         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 610
 611         // 63 testing
 612         lightstyle(63, "a");
 613
 614         if(cvar("g_campaign"))
 615                 CampaignPreInit();
 616
 617         Map_MarkAsRecent(mapname);
 618
 619         precache_model ("null"); // we need this one before InitGameplayMode
 620         InitGameplayMode();
 621         readlevelcvars();
 622         GrappleHookInit();
 623         ElectroInit();
 624         LaserInit();
 625
 626         player_count = 0;
 627         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 628         if(bot_waypoints_for_items == 1)
 629                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 630                         bot_waypoints_for_items = 0;
 631
 632         // for setting by mapinfo
 633         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 634         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 635
 636         precache();
 637
 638         WaypointSprite_Init();
 639
 640         //if (g_domination)
 641         //      dom_init();
 642
 643         GameLogInit(); // prepare everything
 644         if(cvar("sv_eventlog"))
 645         {
 646                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 647                 s = strcat(s, ftos(random()));
 648                 matchid = strzone(s);
 649
 650                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 651                 s = ":gameinfo:mutators:LIST";
 652
 653                 ret_string = s;
 654                 MUTATOR_CALLHOOK(BuildMutatorsString);
 655                 s = ret_string;
 656
 657                 if(cvar("g_grappling_hook"))
 658                         s = strcat(s, ":grappling_hook");
 659                 if(!cvar("g_use_ammunition"))
 660                         s = strcat(s, ":no_use_ammunition");
 661                 if(!cvar("g_pickup_items"))
 662                         s = strcat(s, ":no_pickup_items");
 663                 if(cvar_string("g_weaponarena") != "0")
 664                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 665                 if(cvar("g_vampire"))
 666                         s = strcat(s, ":vampire");
 667                 if(cvar("g_laserguided_missile"))
 668                         s = strcat(s, ":laserguided_missile");
 669                 if(cvar("g_norecoil"))
 670                         s = strcat(s, ":norecoil");
 671                 if(cvar("g_midair"))
 672                         s = strcat(s, ":midair");
 673                 if(cvar("g_minstagib"))
 674                         s = strcat(s, ":minstagib");
 675                 GameLogEcho(s);
 676                 GameLogEcho(":gameinfo:end");
 677         }
 678         else
 679                 matchid = strzone(ftos(random()));
 680
 681         cvar_set("nextmap", "");
 682
 683         SetDefaultAlpha();
 684
 685         if(cvar("g_campaign"))
 686                 CampaignPostInit();
 687
 688         fteqcc_testbugs();
 689
 690         Ban_LoadBans();
 691
 692         MapInfo_Enumerate();
 693         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 694
 695         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 696         {
 697                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 698                 if(fd != -1)
 699                 {
 700                         while((s = fgets(fd)))
 701                         {
 702                                 l = tokenize_console(s);
 703                                 if(l < 2)
 704                                         continue;
 705                                 if(argv(0) == "cd")
 706                                 {
 707                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 708                                         print("  cdtrack ", argv(2), "\n");
 709                                 }
 710                                 else if(argv(0) == "fog")
 711                                 {
 712                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 713                                         print("  \"fog\" \"", s, "\"\n");
 714                                 }
 715                                 else if(argv(0) == "set")
 716                                 {
 717                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 718                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 719                                 }
 720                                 else if(argv(0) != "//")
 721                                 {
 722                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 723                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 724                                 }
 725                         }
 726                         fclose(fd);
 727                 }
 728         }
 729
 730         WeaponStats_Init();
 731
 732         addstat(STAT_WEAPONS, AS_INT, weapons);
 733         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 734         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 735         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 736         Nagger_Init();
 737
 738         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 739         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 740         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 741         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 742         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 743         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 744         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 745         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 746         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 747         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 748
 749         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 750
 751         if(g_ca)
 752         {
 753                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 754                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 755         }
 756         // g_movementspeed hack
 757         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 758         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 759         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 760
 761         next_pingtime = time + 5;
 762
 763         detect_maptype();
 764
 765         lsmaps_reply = "^7Maps available: ";
 766         lsnewmaps_reply = "^7Maps without a record set: ";
 767         for(i = 0, j = 0; i < MapInfo_count; ++i)
 768         {
 769                 if(MapInfo_Get_ByID(i))
 770                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 771                         {
 772                                 if(mod(i, 2))
 773                                         col = "^2";
 774                                 else
 775                                         col = "^3";
 776                                 ++j;
 777                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 778                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 779                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 780                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 781                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 782                         }
 783         }
 784         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 785         if (!g_race && !g_cts)
 786                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 787         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 788
 789         maplist_reply = "^7Maps in list: ";
 790         n = tokenize_console(cvar_string("g_maplist"));
 791         for(i = 0, j = 0; i < n; ++i)
 792         {
 793                 if(MapInfo_CheckMap(argv(i)))
 794                 {
 795                         if(mod(j, 2))
 796                                 col = "^2";
 797                         else
 798                                 col = "^3";
 799                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 800                         ++j;
 801                 }
 802         }
 803         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 804         MapInfo_ClearTemps();
 805
 806         for(i = 0; i < 10; ++i)
 807         {
 808                 records_reply[i] = strzone(getrecords(i));
 809         }
 810
 811         rankings_reply = strzone(getrankings());
 812
 813         ClientInit_Spawn();
 814         RandomSeed_Spawn();
 815         PingPLReport_Spawn();
 816
 817         CheatInit();
 818
 819         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 820
 821         // fill sv_curl_serverpackages from .serverpackage files
 822         if(cvar("sv_curl_serverpackages_auto"))
 823         {
 824                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 825                 s = "";
 826                 if(fd >= 0)
 827                 {
 828                         j = search_getsize(fd);
 829                         for(i = 0; i < j; ++i)
 830                                 s = strcat(s, " ", search_getfilename(fd, i));
 831                         search_end(fd);
 832                 }
 833                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 834         }
 835
 836         world_initialized = 1;
 837 }
 838
 839 void spawnfunc_light (void)
 840 {
 841         //makestatic (self); // Who the f___ did that?
 842         remove(self);
 843 }
 844
 845 float TryFile( string pFilename )
 846 {
 847         local float lHandle;
 848         dprint("TryFile(\"", pFilename, "\")\n");
 849         lHandle = fopen( pFilename, FILE_READ );
 850         if( lHandle != -1 ) {
 851                 fclose( lHandle );
 852                 return TRUE;
 853         } else {
 854                 return FALSE;
 855         }
 856 };
 857
 858 string GetGametype()
 859 {
 860         return GametypeNameFromType(game);
 861 }
 862
 863 string getmapname_stored;
 864 string GetMapname()
 865 {
 866         return mapname;
 867 }
 868
 869 float Map_Count, Map_Current;
 870 string Map_Current_Name;
 871
 872 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 873 float GetMaplistPosition()
 874 {
 875         float pos, idx;
 876         string map;
 877
 878         map = GetMapname();
 879         idx = cvar("g_maplist_index");
 880
 881         if(idx >= 0)
 882                 if(idx < Map_Count)
 883                         if(map == argv(idx))
 884                                 return idx;
 885
 886         for(pos = 0; pos < Map_Count; ++pos)
 887                 if(map == argv(pos))
 888                         return pos;
 889
 890         // resume normal maplist rotation if current map is not in g_maplist
 891         return idx;
 892 }
 893
 894 float MapHasRightSize(string map)
 895 {
 896         float fh;
 897         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 898         if(cvar("g_maplist_check_waypoints"))
 899         {
 900                 dprint("checkwp "); dprint(map);
 901                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 902                 if(fh < 0)
 903                 {
 904                         dprint(": no waypoints\n");
 905                         return FALSE;
 906                 }
 907                 dprint(": has waypoints\n");
 908                 fclose(fh);
 909         }
 910
 911         // open map size restriction file
 912         dprint("opensize "); dprint(map);
 913         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 914         if(fh >= 0)
 915         {
 916                 float mapmin, mapmax;
 917                 dprint(": ok, ");
 918                 mapmin = stof(fgets(fh));
 919                 mapmax = stof(fgets(fh));
 920                 fclose(fh);
 921                 if(player_count < mapmin)
 922                 {
 923                         dprint("not enough\n");
 924                         return FALSE;
 925                 }
 926                 if(player_count > mapmax)
 927                 {
 928                         dprint("too many\n");
 929                         return FALSE;
 930                 }
 931                 dprint("right size\n");
 932                 return TRUE;
 933         }
 934         dprint(": not found\n");
 935         return TRUE;
 936 }
 937
 938 string Map_Filename(float position)
 939 {
 940         return strcat("maps/", argv(position), ".bsp");
 941 }
 942
 943 string strwords(string s, float w)
 944 {
 945         float endpos;
 946         for(endpos = 0; w && endpos >= 0; --w)
 947                 endpos = strstrofs(s, " ", endpos + 1);
 948         if(endpos < 0)
 949                 return s;
 950         else
 951                 return substring(s, 0, endpos);
 952 }
 953
 954 float strhasword(string s, string w)
 955 {
 956         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 957 }
 958
 959 void Map_MarkAsRecent(string m)
 960 {
 961         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 962 }
 963
 964 float Map_IsRecent(string m)
 965 {
 966         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 967 }
 968
 969 float Map_Check(float position, float pass)
 970 {
 971         string filename;
 972         string map_next;
 973         map_next = argv(position);
 974         if(pass <= 1)
 975         {
 976                 if(Map_IsRecent(map_next))
 977                         return 0;
 978         }
 979         filename = Map_Filename(position);
 980         if(MapInfo_CheckMap(map_next))
 981         {
 982                 if(pass == 2)
 983                         return 1;
 984                 if(MapHasRightSize(map_next))
 985                         return 1;
 986                 return 0;
 987         }
 988         else
 989                 dprint( "Couldn't select '", filename, "'..\n" );
 990
 991         return 0;
 992 }
 993
 994 void Map_Goto_SetStr(string nextmapname)
 995 {
 996         if(getmapname_stored != "")
 997                 strunzone(getmapname_stored);
 998         if(nextmapname == "")
 999                 getmapname_stored = "";
1000         else
1001                 getmapname_stored = strzone(nextmapname);
1002 }
1003
1004 void Map_Goto_SetFloat(float position)
1005 {
1006         cvar_set("g_maplist_index", ftos(position));
1007         Map_Goto_SetStr(argv(position));
1008 }
1009
1010 void GameResetCfg()
1011 {
1012         // settings persist, except...
1013         localcmd("\nsettemp_restore\n");
1014 };
1015
1016 void Map_Goto()
1017 {
1018         GameResetCfg();
1019         MapInfo_LoadMap(getmapname_stored);
1020 }
1021
1022 // return codes of map selectors:
1023 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1024 //   -2 = permanent failure
1025 float() MaplistMethod_Iterate = // usual method
1026 {
1027         float pass, i;
1028
1029         for(pass = 1; pass <= 2; ++pass)
1030         {
1031                 for(i = 1; i < Map_Count; ++i)
1032                 {
1033                         float mapindex;
1034                         mapindex = mod(i + Map_Current, Map_Count);
1035                         if(Map_Check(mapindex, pass))
1036                                 return mapindex;
1037                 }
1038         }
1039         return -1;
1040 }
1041
1042 float() MaplistMethod_Repeat = // fallback method
1043 {
1044         if(Map_Check(Map_Current, 2))
1045                 return Map_Current;
1046         return -2;
1047 }
1048
1049 float() MaplistMethod_Random = // random map selection
1050 {
1051         float i, imax;
1052
1053         imax = 42;
1054
1055         for(i = 0; i <= imax; ++i)
1056         {
1057                 float mapindex;
1058                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1059                 if(Map_Check(mapindex, 1))
1060                         return mapindex;
1061         }
1062         return -1;
1063 }
1064
1065 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1066 // the exponent sets a bias on the map selection:
1067 // the higher the exponent, the less likely "shortly repeated" same maps are
1068 {
1069         float i, j, imax, insertpos;
1070
1071         imax = 42;
1072
1073         for(i = 0; i <= imax; ++i)
1074         {
1075                 string newlist;
1076
1077                 // now reinsert this at another position
1078                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1079                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1080                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1081                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1082
1083                 // insert the current map there
1084                 newlist = "";
1085                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1086                         newlist = strcat(newlist, " ", argv(j));
1087                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1088                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1089                         newlist = strcat(newlist, " ", argv(j));
1090                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1091                 cvar_set("g_maplist", newlist);
1092                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1093
1094                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1095                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1096                 if(Map_Check(Map_Current, 1))
1097                         return Map_Current;
1098         }
1099         return -1;
1100 }
1101
1102 void Maplist_Init()
1103 {
1104         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1105         if(Map_Count == 0)
1106         {
1107                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1108                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1109                 if(cvar("g_maplist_shuffle"))
1110                         ShuffleMaplist();
1111                 localcmd("\nmenu_cmd sync\n");
1112                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1113         }
1114         if(Map_Count == 0)
1115                 error("empty maplist, cannot select a new map");
1116         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1117
1118         if(Map_Current_Name)
1119                 strunzone(Map_Current_Name);
1120         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1121         // this may or may not be correct, but who cares, in the worst case a map
1122         // isn't chosen in the first pass that should have been
1123 }
1124
1125 string GetNextMap()
1126 {
1127         float nextMap;
1128
1129         Maplist_Init();
1130         nextMap = -1;
1131
1132         if(nextMap == -1)
1133                 if(cvar("g_maplist_shuffle") > 0)
1134                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1135
1136         if(nextMap == -1)
1137                 if(cvar("g_maplist_selectrandom"))
1138                         nextMap = MaplistMethod_Random();
1139
1140         if(nextMap == -1)
1141                 nextMap = MaplistMethod_Iterate();
1142
1143         if(nextMap == -1)
1144                 nextMap = MaplistMethod_Repeat();
1145
1146         if(nextMap >= 0)
1147         {
1148                 Map_Goto_SetFloat(nextMap);
1149                 return getmapname_stored;
1150         }
1151
1152         return "";
1153 };
1154
1155 float DoNextMapOverride()
1156 {
1157         if(cvar("g_campaign"))
1158         {
1159                 CampaignPostIntermission();
1160                 alreadychangedlevel = TRUE;
1161                 return TRUE;
1162         }
1163         if(cvar("quit_when_empty"))
1164         {
1165                 if(player_count <= currentbots)
1166                 {
1167                         localcmd("quit\n");
1168                         alreadychangedlevel = TRUE;
1169                         return TRUE;
1170                 }
1171         }
1172         if(cvar_string("quit_and_redirect") != "")
1173         {
1174                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1175                 alreadychangedlevel = TRUE;
1176                 return TRUE;
1177         }
1178         if (cvar("samelevel")) // if samelevel is set, stay on same level
1179         {
1180                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1181                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1182                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1183                 localcmd("restart\n");
1184                 //changelevel (mapname);
1185                 alreadychangedlevel = TRUE;
1186                 return TRUE;
1187         }
1188         if(cvar_string("nextmap") != "")
1189                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1190                 {
1191                         Map_Goto_SetStr(cvar_string("nextmap"));
1192                         Map_Goto();
1193                         alreadychangedlevel = TRUE;
1194                         return TRUE;
1195                 }
1196         if(cvar("lastlevel"))
1197         {
1198                 GameResetCfg();
1199                 localcmd("set lastlevel 0\ntogglemenu\n");
1200                 alreadychangedlevel = TRUE;
1201                 return TRUE;
1202         }
1203         return FALSE;
1204 };
1205
1206 void GotoNextMap()
1207 {
1208         //local string nextmap;
1209         //local float n, nummaps;
1210         //local string s;
1211         if (alreadychangedlevel)
1212                 return;
1213         alreadychangedlevel = TRUE;
1214
1215         {
1216                 string nextMap;
1217                 float allowReset;
1218
1219                 for(allowReset = 1; allowReset >= 0; --allowReset)
1220                 {
1221                         nextMap = GetNextMap();
1222                         if(nextMap != "")
1223                                 break;
1224
1225                         if(allowReset)
1226                         {
1227                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1228                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1229                                 if(cvar("g_maplist_shuffle"))
1230                                         ShuffleMaplist();
1231                                 localcmd("\nmenu_cmd sync\n");
1232                         }
1233                         else
1234                         {
1235                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1236                         }
1237                 }
1238                 Map_Goto();
1239         }
1240 };
1241
1242
1243 /*
1244 ============
1245 IntermissionThink
1246
1247 When the player presses attack or jump, change to the next level
1248 ============
1249 */
1250 .float autoscreenshot;
1251 void() MapVote_Start;
1252 void() MapVote_Think;
1253 float mapvote_initialized;
1254 void IntermissionThink()
1255 {
1256         FixIntermissionClient(self);
1257
1258         if(cvar("sv_autoscreenshot"))
1259         if(self.autoscreenshot > 0)
1260         if(time > self.autoscreenshot)
1261         {
1262                 self.autoscreenshot = -1;
1263                 if(clienttype(self) == CLIENTTYPE_REAL)
1264                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1265                 return;
1266         }
1267
1268         if (time < intermission_exittime)
1269                 return;
1270
1271         if(!mapvote_initialized)
1272                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1273                         return;
1274
1275         MapVote_Start();
1276 };
1277
1278 /*
1279 ============
1280 FindIntermission
1281
1282 Returns the entity to view from
1283 ============
1284 */
1285 /*
1286 entity FindIntermission()
1287 {
1288         local   entity spot;
1289         local   float cyc;
1290
1291 // look for info_intermission first
1292         spot = find (world, classname, "info_intermission");
1293         if (spot)
1294         {       // pick a random one
1295                 cyc = random() * 4;
1296                 while (cyc > 1)
1297                 {
1298                         spot = find (spot, classname, "info_intermission");
1299                         if (!spot)
1300                                 spot = find (spot, classname, "info_intermission");
1301                         cyc = cyc - 1;
1302                 }
1303                 return spot;
1304         }
1305
1306 // then look for the start position
1307         spot = find (world, classname, "info_player_start");
1308         if (spot)
1309                 return spot;
1310
1311 // testinfo_player_start is only found in regioned levels
1312         spot = find (world, classname, "testplayerstart");
1313         if (spot)
1314                 return spot;
1315
1316 // then look for the start position
1317         spot = find (world, classname, "info_player_deathmatch");
1318         if (spot)
1319                 return spot;
1320
1321         //objerror ("FindIntermission: no spot");
1322         return world;
1323 };
1324 */
1325
1326 /*
1327 ===============================================================================
1328
1329 RULES
1330
1331 ===============================================================================
1332 */
1333
1334 void DumpStats(float final)
1335 {
1336         local float file;
1337         local string s;
1338         local float to_console;
1339         local float to_eventlog;
1340         local float to_file;
1341         local float i;
1342
1343         to_console = cvar("sv_logscores_console");
1344         to_eventlog = cvar("sv_eventlog");
1345         to_file = cvar("sv_logscores_file");
1346
1347         if(!final)
1348         {
1349                 to_console = TRUE; // always print printstats replies
1350                 to_eventlog = FALSE; // but never print them to the event log
1351         }
1352
1353         if(to_eventlog)
1354                 if(cvar("sv_eventlog_console"))
1355                         to_console = FALSE; // otherwise we get the output twice
1356
1357         if(final)
1358                 s = ":scores:";
1359         else
1360                 s = ":status:";
1361         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1362
1363         if(to_console)
1364                 print(s, "\n");
1365         if(to_eventlog)
1366                 GameLogEcho(s);
1367         if(to_file)
1368         {
1369                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1370                 if(file == -1)
1371                         to_file = FALSE;
1372                 else
1373                         fputs(file, strcat(s, "\n"));
1374         }
1375
1376         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1377         if(to_console)
1378                 print(s, "\n");
1379         if(to_eventlog)
1380                 GameLogEcho(s);
1381         if(to_file)
1382                 fputs(file, strcat(s, "\n"));
1383
1384         FOR_EACH_CLIENT(other)
1385         {
1386                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1387                 {
1388                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1389                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1390                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1391                                 s = strcat(s, ftos(other.team), ":");
1392                         else
1393                                 s = strcat(s, "spectator:");
1394
1395                         if(to_console)
1396                                 print(s, other.netname, "\n");
1397                         if(to_eventlog)
1398                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1399                         if(to_file)
1400                                 fputs(file, strcat(s, other.netname, "\n"));
1401                 }
1402         }
1403
1404         if(teams_matter)
1405         {
1406                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1407                 if(to_console)
1408                         print(s, "\n");
1409                 if(to_eventlog)
1410                         GameLogEcho(s);
1411                 if(to_file)
1412                         fputs(file, strcat(s, "\n"));
1413
1414                 for(i = 1; i < 16; ++i)
1415                 {
1416                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1417                         s = strcat(s, ":", ftos(i));
1418                         if(to_console)
1419                                 print(s, "\n");
1420                         if(to_eventlog)
1421                                 GameLogEcho(s);
1422                         if(to_file)
1423                                 fputs(file, strcat(s, "\n"));
1424                 }
1425         }
1426
1427         if(to_console)
1428                 print(":end\n");
1429         if(to_eventlog)
1430                 GameLogEcho(":end");
1431         if(to_file)
1432         {
1433                 fputs(file, ":end\n");
1434                 fclose(file);
1435         }
1436 }
1437
1438 void FixIntermissionClient(entity e)
1439 {
1440         string s;
1441         if(!e.autoscreenshot) // initial call
1442         {
1443                 e.angles = e.v_angle;
1444                 e.angles_x = -e.angles_x;
1445                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1446                 e.health = -2342;
1447                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1448                 e.solid = SOLID_NOT;
1449                 e.movetype = MOVETYPE_NONE;
1450                 e.takedamage = DAMAGE_NO;
1451                 if(e.weaponentity)
1452                 {
1453                         e.weaponentity.effects = EF_NODRAW;
1454                         if (e.weaponentity.weaponentity)
1455                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1456                 }
1457                 if(clienttype(e) == CLIENTTYPE_REAL)
1458                 {
1459                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1460                         s = cvar_string("sv_intermission_cdtrack");
1461                         if(s != "")
1462                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1463                         msg_entity = e;
1464                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1465                 }
1466         }
1467
1468         //e.velocity = '0 0 0';
1469         //e.fixangle = TRUE;
1470
1471         // TODO halt weapon animation
1472 }
1473
1474
1475 /*
1476 go to the next level for deathmatch
1477 only called if a time or frag limit has expired
1478 */
1479 void NextLevel()
1480 {
1481         float i;
1482
1483         gameover = TRUE;
1484
1485         intermission_running = 1;
1486
1487 // enforce a wait time before allowing changelevel
1488         if(player_count > 0)
1489                 intermission_exittime = time + cvar("sv_mapchange_delay");
1490         else
1491                 intermission_exittime = -1;
1492
1493         /*
1494         WriteByte (MSG_ALL, SVC_CDTRACK);
1495         WriteByte (MSG_ALL, 3);
1496         WriteByte (MSG_ALL, 3);
1497         // done in FixIntermission
1498         */
1499
1500         //pos = FindIntermission ();
1501
1502         VoteReset();
1503
1504         DumpStats(TRUE);
1505
1506         if(cvar("sv_eventlog"))
1507                 GameLogEcho(":gameover");
1508
1509         GameLogClose();
1510
1511 // TO DO
1512
1513 // save the stats to a text file on the client
1514 // stuffcmd(other, log_stats "stats/file_name");
1515 // bprint stats
1516 // stuffcmd(other, log_stats "");
1517 // use a filename similar to the demo name
1518         // string file_name;
1519         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1520
1521 // write a stats parser for the menu
1522
1523         if(cvar("sv_accuracy_data_send")) {
1524                 string stats_to_send;
1525
1526                 FOR_EACH_CLIENT(other) {  // make the string to send
1527                         FixIntermissionClient(other);
1528
1529                         if(other.cvar_cl_accuracy_data_share) {
1530                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1531
1532                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1533                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1534
1535                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1536
1537                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1538                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1539
1540                                 stats_to_send = strcat(stats_to_send, "\n");
1541                         }
1542                 }
1543
1544                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1545                         Score_NicePrint(other);  // print the score
1546
1547                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1548                                 bprint(stats_to_send);
1549                 }
1550         } else { // ye olde message
1551                 FOR_EACH_PLAYER(other) {
1552                         FixIntermissionClient(other);
1553
1554                         if(other.winning)
1555                                 bprint(other.netname, " ^7wins.\n");
1556                 }
1557         }
1558
1559         if(cvar("g_campaign"))
1560                 CampaignPreIntermission();
1561
1562         localcmd("\nsv_hook_gameend\n");
1563 }
1564
1565 /*
1566 ============
1567 CheckRules_Player
1568
1569 Exit deathmatch games upon conditions
1570 ============
1571 */
1572 void CheckRules_Player()
1573 {
1574         if (gameover)   // someone else quit the game already
1575                 return;
1576
1577         if(self.deadflag == DEAD_NO)
1578                 self.play_time += frametime;
1579
1580         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1581         //   (div0: and that in CheckRules_World please)
1582 };
1583
1584 float checkrules_equality;
1585 float checkrules_suddendeathwarning;
1586 float checkrules_suddendeathend;
1587 float checkrules_overtimesadded; //how many overtimes have been already added
1588
1589 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1590 float WINNING_YES = 1; // winner found
1591 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1592 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1593
1594 float InitiateSuddenDeath()
1595 {
1596         // Check first whether normal overtimes could be added before initiating suddendeath mode
1597         // - for this timelimit_overtime needs to be >0 of course
1598         // - also check the winning condition calculated in the previous frame and only add normal overtime
1599         //   again, if at the point at which timelimit would be extended again, still no winner was found
1600         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1601         {
1602                 return 1; // need to call InitiateOvertime later
1603         }
1604         else
1605         {
1606                 if(!checkrules_suddendeathend)
1607                 {
1608                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1609                         if(g_race && !g_race_qualifying)
1610                                 race_StartCompleting();
1611                 }
1612                 return 0;
1613         }
1614 }
1615
1616 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1617 {
1618         ++checkrules_overtimesadded;
1619         //add one more overtime by simply extending the timelimit
1620         float tl;
1621         tl = cvar("timelimit");
1622         tl += cvar("timelimit_overtime");
1623         cvar_set("timelimit", ftos(tl));
1624         string minutesPlural;
1625         if (cvar("timelimit_overtime") == 1)
1626                 minutesPlural = " ^3minute";
1627         else
1628                 minutesPlural = " ^3minutes";
1629
1630         bcenterprint(
1631                 strcat(
1632                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1633                         ftos(cvar("timelimit_overtime")),
1634                         minutesPlural,
1635                         " to the game!"
1636                 )
1637         );
1638 }
1639
1640 float GetWinningCode(float fraglimitreached, float equality)
1641 {
1642         if(cvar("g_campaign") == 1)
1643                 if(fraglimitreached)
1644                         return WINNING_YES;
1645                 else
1646                         return WINNING_NO;
1647
1648         else
1649                 if(equality)
1650                         if(fraglimitreached)
1651                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1652                         else
1653                                 return WINNING_NEVER;
1654                 else
1655                         if(fraglimitreached)
1656                                 return WINNING_YES;
1657                         else
1658                                 return WINNING_NO;
1659 }
1660
1661 // set the .winning flag for exactly those players with a given field value
1662 void SetWinners(.float field, float value)
1663 {
1664         entity head;
1665         FOR_EACH_PLAYER(head)
1666                 head.winning = (head.field == value);
1667 }
1668
1669 // set the .winning flag for those players with a given field value
1670 void AddWinners(.float field, float value)
1671 {
1672         entity head;
1673         FOR_EACH_PLAYER(head)
1674                 if(head.field == value)
1675                         head.winning = 1;
1676 }
1677
1678 // clear the .winning flags
1679 void ClearWinners(void)
1680 {
1681         entity head;
1682         FOR_EACH_PLAYER(head)
1683                 head.winning = 0;
1684 }
1685
1686 // Onslaught winning condition:
1687 // game terminates if only one team has a working generator (or none)
1688 float WinningCondition_Onslaught()
1689 {
1690         entity head;
1691         local float t1, t2, t3, t4;
1692
1693         WinningConditionHelper(); // set worldstatus
1694
1695         if(inWarmupStage)
1696                 return WINNING_NO;
1697
1698         // first check if the game has ended
1699         t1 = t2 = t3 = t4 = 0;
1700         head = find(world, classname, "onslaught_generator");
1701         while (head)
1702         {
1703                 if (head.health > 0)
1704                 {
1705                         if (head.team == COLOR_TEAM1) t1 = 1;
1706                         if (head.team == COLOR_TEAM2) t2 = 1;
1707                         if (head.team == COLOR_TEAM3) t3 = 1;
1708                         if (head.team == COLOR_TEAM4) t4 = 1;
1709                 }
1710                 head = find(head, classname, "onslaught_generator");
1711         }
1712         if (t1 + t2 + t3 + t4 < 2)
1713         {
1714                 // game over, only one team remains (or none)
1715                 ClearWinners();
1716                 if (t1) SetWinners(team, COLOR_TEAM1);
1717                 if (t2) SetWinners(team, COLOR_TEAM2);
1718                 if (t3) SetWinners(team, COLOR_TEAM3);
1719                 if (t4) SetWinners(team, COLOR_TEAM4);
1720                 dprint("Have a winner, ending game.\n");
1721                 return WINNING_YES;
1722         }
1723
1724         // Two or more teams remain
1725         return WINNING_NO;
1726 }
1727
1728 float LMS_NewPlayerLives()
1729 {
1730         float fl;
1731         fl = cvar("fraglimit");
1732         if(fl == 0)
1733                 fl = 999;
1734
1735         // first player has left the game for dying too much? Nobody else can get in.
1736         if(lms_lowest_lives < 1)
1737                 return 0;
1738
1739         if(!cvar("g_lms_join_anytime"))
1740                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1741                         return 0;
1742
1743         return bound(1, lms_lowest_lives, fl);
1744 }
1745
1746 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1747 // they win. Otherwise the defending team wins once the timelimit passes.
1748 void assault_new_round();
1749 float WinningCondition_Assault()
1750 {
1751         local float status;
1752
1753         WinningConditionHelper(); // set worldstatus
1754
1755         status = WINNING_NO;
1756         // as the timelimit has not yet passed just assume the defending team will win
1757         if(assault_attacker_team == COLOR_TEAM1)
1758         {
1759                 SetWinners(team, COLOR_TEAM2);
1760         }
1761         else
1762         {
1763                 SetWinners(team, COLOR_TEAM1);
1764         }
1765
1766         local entity ent;
1767         ent = find(world, classname, "target_assault_roundend");
1768         if(ent)
1769         {
1770                 if(ent.winning) // round end has been triggered by attacking team
1771                 {
1772                         bprint("ASSAULT: round completed...\n");
1773                         SetWinners(team, assault_attacker_team);
1774
1775                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1776
1777                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1778                         {
1779                                 status = WINNING_YES;
1780                         }
1781                         else
1782                         {
1783                                 local entity oldself;
1784                                 oldself = self;
1785                                 self = ent;
1786                                 assault_new_round();
1787                                 self = oldself;
1788                         }
1789                 }
1790         }
1791
1792         return status;
1793 }
1794
1795 // LMS winning condition: game terminates if and only if there's at most one
1796 // one player who's living lives. Top two scores being equal cancels the time
1797 // limit.
1798 float WinningCondition_LMS()
1799 {
1800         entity head, head2;
1801         float have_player;
1802         float have_players;
1803         float l;
1804
1805         have_player = FALSE;
1806         have_players = FALSE;
1807         l = LMS_NewPlayerLives();
1808
1809         head = find(world, classname, "player");
1810         if(head)
1811                 have_player = TRUE;
1812         head2 = find(head, classname, "player");
1813         if(head2)
1814                 have_players = TRUE;
1815
1816         if(have_player)
1817         {
1818                 // we have at least one player
1819                 if(have_players)
1820                 {
1821                         // two or more active players - continue with the game
1822                 }
1823                 else
1824                 {
1825                         // exactly one player?
1826
1827                         ClearWinners();
1828                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1829
1830                         if(l)
1831                         {
1832                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1833                                 return WINNING_NO;
1834                         }
1835                         else
1836                         {
1837                                 // a winner!
1838                                 // and assign him his first place
1839                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1840                                 return WINNING_YES;
1841                         }
1842                 }
1843         }
1844         else
1845         {
1846                 // nobody is playing at all...
1847                 if(l)
1848                 {
1849                         // wait for players...
1850                 }
1851                 else
1852                 {
1853                         // SNAFU (maybe a draw game?)
1854                         ClearWinners();
1855                         dprint("No players, ending game.\n");
1856                         return WINNING_YES;
1857                 }
1858         }
1859
1860         // When we get here, we have at least two players who are actually LIVING,
1861         // now check if the top two players have equal score.
1862         WinningConditionHelper();
1863
1864         ClearWinners();
1865         if(WinningConditionHelper_winner)
1866                 WinningConditionHelper_winner.winning = TRUE;
1867         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1868                 return WINNING_NEVER;
1869
1870         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1871         return WINNING_NO;
1872 }
1873
1874 void ShuffleMaplist()
1875 {
1876         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1877 }
1878
1879 float leaderfrags;
1880 float WinningCondition_Scores(float limit, float leadlimit)
1881 {
1882         float limitreached;
1883
1884         // TODO make everything use THIS winning condition (except LMS)
1885         WinningConditionHelper();
1886
1887         if(teams_matter)
1888         {
1889                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1890                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1891                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1892                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1893         }
1894
1895         ClearWinners();
1896         if(WinningConditionHelper_winner)
1897                 WinningConditionHelper_winner.winning = 1;
1898         if(WinningConditionHelper_winnerteam >= 0)
1899                 SetWinners(team, WinningConditionHelper_winnerteam);
1900
1901         if(WinningConditionHelper_lowerisbetter)
1902         {
1903                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1904                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1905                 limit = -limit;
1906         }
1907
1908         if(WinningConditionHelper_zeroisworst)
1909                 leadlimit = 0; // not supported in this mode
1910
1911         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1912         // these modes always score in increments of 1, thus this makes sense
1913         {
1914                 if(leaderfrags != WinningConditionHelper_topscore)
1915                 {
1916                         leaderfrags = WinningConditionHelper_topscore;
1917
1918                         if (limit)
1919                         if (leaderfrags == limit - 1)
1920                                 Announce("1fragleft");
1921                         else if (leaderfrags == limit - 2)
1922                                 Announce("2fragsleft");
1923                         else if (leaderfrags == limit - 3)
1924                                 Announce("3fragsleft");
1925                 }
1926         }
1927
1928         limitreached = FALSE;
1929         if(limit)
1930                 if(WinningConditionHelper_topscore >= limit)
1931                         limitreached = TRUE;
1932         if(leadlimit)
1933         {
1934                 float leadlimitreached;
1935                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1936                 if(cvar("leadlimit_and_fraglimit"))
1937                         limitreached = (limitreached && leadlimitreached);
1938                 else
1939                         limitreached = (limitreached || leadlimitreached);
1940         }
1941
1942         return GetWinningCode(
1943                 WinningConditionHelper_topscore && limitreached,
1944                 WinningConditionHelper_equality
1945         );
1946 }
1947
1948 float WinningCondition_Race(float fraglimit)
1949 {
1950         float wc;
1951         entity p;
1952         float n, c;
1953
1954         n = 0;
1955         c = 0;
1956         FOR_EACH_PLAYER(p)
1957         {
1958                 ++n;
1959                 if(p.race_completed)
1960                         ++c;
1961         }
1962         if(n && (n == c))
1963                 return WINNING_YES;
1964         wc = WinningCondition_Scores(fraglimit, 0);
1965
1966         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1967         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1968         // do NOT support equality when the laps are all raced!
1969                 return WINNING_STARTSUDDENDEATHOVERTIME;
1970         else
1971                 return WINNING_NEVER;
1972         return wc;
1973 }
1974
1975 void ReadyRestart();
1976 float WinningCondition_QualifyingThenRace(float limit)
1977 {
1978         float wc;
1979         wc = WinningCondition_Scores(limit, 0);
1980
1981         // NEVER initiate overtime
1982         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1983         {
1984                 return WINNING_YES;
1985         }
1986
1987         return wc;
1988 }
1989
1990 float WinningCondition_RanOutOfSpawns()
1991 {
1992         entity head;
1993
1994         if(have_team_spawns <= 0)
1995                 return WINNING_NO;
1996
1997         if(!some_spawn_has_been_used)
1998                 return WINNING_NO;
1999
2000         team1_score = team2_score = team3_score = team4_score = 0;
2001
2002         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2003         {
2004                 if(head.team == COLOR_TEAM1)
2005                         team1_score = 1;
2006                 else if(head.team == COLOR_TEAM2)
2007                         team2_score = 1;
2008                 else if(head.team == COLOR_TEAM3)
2009                         team3_score = 1;
2010                 else if(head.team == COLOR_TEAM4)
2011                         team4_score = 1;
2012         }
2013
2014         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2015         {
2016                 if(head.team == COLOR_TEAM1)
2017                         team1_score = 1;
2018                 else if(head.team == COLOR_TEAM2)
2019                         team2_score = 1;
2020                 else if(head.team == COLOR_TEAM3)
2021                         team3_score = 1;
2022                 else if(head.team == COLOR_TEAM4)
2023                         team4_score = 1;
2024         }
2025
2026         ClearWinners();
2027         if(team1_score + team2_score + team3_score + team4_score == 0)
2028         {
2029                 checkrules_equality = TRUE;
2030                 return WINNING_YES;
2031         }
2032         else if(team1_score + team2_score + team3_score + team4_score == 1)
2033         {
2034                 float t, i;
2035                 if(team1_score) t = COLOR_TEAM1;
2036                 if(team2_score) t = COLOR_TEAM2;
2037                 if(team3_score) t = COLOR_TEAM3;
2038                 if(team4_score) t = COLOR_TEAM4;
2039                 CheckAllowedTeams(world);
2040                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2041                 {
2042                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2043                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2044                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2045                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2046                 }
2047
2048                 AddWinners(team, t);
2049                 return WINNING_YES;
2050         }
2051         else
2052                 return WINNING_NO;
2053 }
2054
2055 /*
2056 ============
2057 CheckRules_World
2058
2059 Exit deathmatch games upon conditions
2060 ============
2061 */
2062 void CheckRules_World()
2063 {
2064         float timelimit;
2065         float fraglimit;
2066         float leadlimit;
2067
2068         VoteThink();
2069         MapVote_Think();
2070
2071         SetDefaultAlpha();
2072
2073         /*
2074         MapVote_Think should now do that part
2075         if (intermission_running)
2076                 if (time >= intermission_exittime + 60)
2077                 {
2078                         if(!DoNextMapOverride())
2079                                 GotoNextMap();
2080                         return;
2081                 }
2082         */
2083
2084         if (gameover)   // someone else quit the game already
2085         {
2086                 if(player_count == 0) // Nobody there? Then let's go to the next map
2087                         MapVote_Start();
2088                         // this will actually check the player count in the next frame
2089                         // again, but this shouldn't hurt
2090                 return;
2091         }
2092
2093         timelimit = cvar("timelimit") * 60;
2094         fraglimit = cvar("fraglimit");
2095         leadlimit = cvar("leadlimit");
2096
2097         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2098         {
2099                 if(timelimit > 0)
2100                         timelimit = 0; // timelimit is not made for warmup
2101                 if(fraglimit > 0)
2102                         fraglimit = 0; // no fraglimit for now
2103                 leadlimit = 0; // no leadlimit for now
2104         }
2105
2106         if(g_onslaught)
2107                 timelimit = 0; // ONS has its own overtime rule
2108
2109         if(timelimit > 0)
2110         {
2111                 timelimit += game_starttime;
2112         }
2113         else if (timelimit < 0)
2114         {
2115                 // endmatch
2116                 NextLevel();
2117                 return;
2118         }
2119
2120         float wantovertime;
2121         wantovertime = 0;
2122
2123         if(checkrules_suddendeathend)
2124         {
2125                 if(!checkrules_suddendeathwarning)
2126                 {
2127                         checkrules_suddendeathwarning = TRUE;
2128                         if(g_race && !g_race_qualifying)
2129                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2130                         else
2131                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2132                 }
2133         }
2134         else
2135         {
2136                 if (timelimit && time >= timelimit)
2137                 {
2138                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2139                         {
2140                                 float totalplayers;
2141                                 float playerswithlaps;
2142                                 float readyplayers;
2143                                 entity head;
2144                                 totalplayers = playerswithlaps = readyplayers = 0;
2145                                 FOR_EACH_PLAYER(head)
2146                                 {
2147                                         ++totalplayers;
2148                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2149                                                 ++playerswithlaps;
2150                                         if(head.ready)
2151                                                 ++readyplayers;
2152                                 }
2153
2154                                 // at least 2 of the players have completed a lap: start the RACE
2155                                 // otherwise, the players should end the qualifying on their own
2156                                 if(readyplayers || playerswithlaps >= 2)
2157                                 {
2158                                         checkrules_suddendeathend = 0;
2159                                         ReadyRestart(); // go to race
2160                                         return;
2161                                 }
2162                                 else
2163                                         wantovertime |= InitiateSuddenDeath();
2164                         }
2165                         else
2166                                 wantovertime |= InitiateSuddenDeath();
2167                 }
2168         }
2169
2170         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2171         {
2172                 NextLevel();
2173                 return;
2174         }
2175
2176         float checkrules_status;
2177         checkrules_status = WinningCondition_RanOutOfSpawns();
2178         if(checkrules_status == WINNING_YES)
2179         {
2180                 bprint("Hey! Someone ran out of spawns!\n");
2181         }
2182         else if(g_race && !g_race_qualifying && timelimit >= 0)
2183         {
2184                 checkrules_status = WinningCondition_Race(fraglimit);
2185                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2186         }
2187         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2188         {
2189                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2190                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2191         }
2192         else if(g_assault)
2193         {
2194                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2195         }
2196         else if(g_lms)
2197         {
2198                 checkrules_status = WinningCondition_LMS();
2199         }
2200         else if (g_onslaught)
2201         {
2202                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2203         }
2204         else
2205         {
2206                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2207                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2208         }
2209
2210         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2211         {
2212                 checkrules_status = WINNING_NEVER;
2213                 checkrules_overtimesadded = -1;
2214                 wantovertime |= InitiateSuddenDeath();
2215         }
2216
2217         if(checkrules_status == WINNING_NEVER)
2218                 // equality cases! Nobody wins if the overtime ends in a draw.
2219                 ClearWinners();
2220
2221         if(wantovertime)
2222         {
2223                 if(checkrules_status == WINNING_NEVER)
2224                         InitiateOvertime();
2225                 else
2226                         checkrules_status = WINNING_YES;
2227         }
2228
2229         if(checkrules_suddendeathend)
2230                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2231                         checkrules_status = WINNING_YES;
2232
2233         if(checkrules_status == WINNING_YES)
2234         {
2235                 //print("WINNING\n");
2236                 NextLevel();
2237         }
2238 };
2239
2240 float mapvote_nextthink;
2241 float mapvote_initialized;
2242 float mapvote_keeptwotime;
2243 float mapvote_timeout;
2244 string mapvote_message;
2245 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2246 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2247 float mapvote_screenshot_dirs_count;
2248
2249 float mapvote_count;
2250 float mapvote_count_real;
2251 string mapvote_maps[MAPVOTE_COUNT];
2252 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2253 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2254 float mapvote_maps_suggested[MAPVOTE_COUNT];
2255 string mapvote_suggestions[MAPVOTE_COUNT];
2256 float mapvote_suggestion_ptr;
2257 float mapvote_maxlen;
2258 float mapvote_voters;
2259 float mapvote_votes[MAPVOTE_COUNT];
2260 float mapvote_run;
2261 float mapvote_detail;
2262 float mapvote_abstain;
2263 .float mapvote;
2264
2265 void MapVote_ClearAllVotes()
2266 {
2267         FOR_EACH_CLIENT(other)
2268                 other.mapvote = 0;
2269 }
2270
2271 string MapVote_Suggest(string m)
2272 {
2273         float i;
2274         if(m == "")
2275                 return "That's not how to use this command.";
2276         if(!cvar("g_maplist_votable_suggestions"))
2277                 return "Suggestions are not accepted on this server.";
2278         if(mapvote_initialized)
2279                 return "Can't suggest - voting is already in progress!";
2280         m = MapInfo_FixName(m);
2281         if(!m)
2282                 return "The map you suggested is not available on this server.";
2283         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2284                 if(Map_IsRecent(m))
2285                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2286
2287         if(!MapInfo_CheckMap(m))
2288                 return "The map you suggested does not support the current game mode.";
2289         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2290                 if(mapvote_suggestions[i] == m)
2291                         return "This map was already suggested.";
2292         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2293         {
2294                 i = floor(random() * mapvote_suggestion_ptr);
2295         }
2296         else
2297         {
2298                 i = mapvote_suggestion_ptr;
2299                 mapvote_suggestion_ptr += 1;
2300         }
2301         if(mapvote_suggestions[i] != "")
2302                 strunzone(mapvote_suggestions[i]);
2303         mapvote_suggestions[i] = strzone(m);
2304         if(cvar("sv_eventlog"))
2305                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2306         return strcat("Suggestion of ", m, " accepted.");
2307 }
2308
2309 void MapVote_AddVotable(string nextMap, float isSuggestion)
2310 {
2311         float j, i, o;
2312         string pakfile, mapfile;
2313
2314         if(nextMap == "")
2315                 return;
2316         for(j = 0; j < mapvote_count; ++j)
2317                 if(mapvote_maps[j] == nextMap)
2318                         return;
2319         if(strlen(nextMap) > mapvote_maxlen)
2320                 mapvote_maxlen = strlen(nextMap);
2321         mapvote_maps[mapvote_count] = strzone(nextMap);
2322         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2323
2324         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2325         {
2326                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2327                 pakfile = whichpack(strcat(mapfile, ".tga"));
2328                 if(pakfile == "")
2329                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2330                 if(pakfile == "")
2331                         pakfile = whichpack(strcat(mapfile, ".png"));
2332                 if(pakfile != "")
2333                         break;
2334         }
2335         if(i >= mapvote_screenshot_dirs_count)
2336                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2337         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2338                 pakfile = substring(pakfile, o, -1);
2339
2340         mapvote_maps_screenshot_dir[mapvote_count] = i;
2341         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2342
2343         mapvote_count += 1;
2344 }
2345
2346 void MapVote_Spawn();
2347 void MapVote_Init()
2348 {
2349         float i;
2350         float nmax, smax;
2351
2352         MapVote_ClearAllVotes();
2353
2354         mapvote_count = 0;
2355         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2356         mapvote_abstain = cvar("g_maplist_votable_abstain");
2357
2358         if(mapvote_abstain)
2359                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2360         else
2361                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2362         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2363
2364         // we need this for AddVotable, as that cycles through the screenshot dirs
2365         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2366         if(mapvote_screenshot_dirs_count == 0)
2367                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2368         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2369         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2370                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2371
2372         if(mapvote_suggestion_ptr)
2373                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2374                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2375
2376         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2377                 MapVote_AddVotable(GetNextMap(), FALSE);
2378
2379         if(mapvote_count == 0)
2380         {
2381                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2382                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2383                 if(cvar("g_maplist_shuffle"))
2384                         ShuffleMaplist();
2385                 localcmd("\nmenu_cmd sync\n");
2386                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2387                         MapVote_AddVotable(GetNextMap(), FALSE);
2388         }
2389
2390         mapvote_count_real = mapvote_count;
2391         if(mapvote_abstain)
2392                 MapVote_AddVotable("don't care", 0);
2393
2394         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2395
2396         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2397         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2398         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2399                 mapvote_keeptwotime = 0;
2400         mapvote_message = "Choose a map and press its key!";
2401
2402         MapVote_Spawn();
2403 }
2404
2405 void MapVote_SendPicture(float id)
2406 {
2407         msg_entity = self;
2408         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2409         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2410         WriteByte(MSG_ONE, id);
2411         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2412 }
2413
2414 float GameCommand_MapVote(string cmd)
2415 {
2416         if(!intermission_running)
2417                 return FALSE;
2418
2419         if(cmd == "mv_getpic")
2420         {
2421                 MapVote_SendPicture(stof(argv(1)));
2422                 return TRUE;
2423         }
2424
2425         return FALSE;
2426 }
2427
2428 float MapVote_GetMapMask()
2429 {
2430         float mask, i, power;
2431         mask = 0;
2432         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2433                 if(mapvote_maps[i] != "")
2434                         mask |= power;
2435         return mask;
2436 }
2437
2438 entity mapvote_ent;
2439 float MapVote_SendEntity(entity to, float sf)
2440 {
2441         float i;
2442
2443         if(sf & 1)
2444                 sf &~= 2; // if we send 1, we don't need to also send 2
2445
2446         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2447         WriteByte(MSG_ENTITY, sf);
2448
2449         if(sf & 1)
2450         {
2451                 // flag 1 == initialization
2452                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2453                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2454                 WriteString(MSG_ENTITY, "");
2455                 WriteByte(MSG_ENTITY, mapvote_count);
2456                 WriteByte(MSG_ENTITY, mapvote_abstain);
2457                 WriteByte(MSG_ENTITY, mapvote_detail);
2458                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2459                 if(mapvote_count <= 8)
2460                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2461                 else
2462                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2463                 for(i = 0; i < mapvote_count; ++i)
2464                         if(mapvote_maps[i] != "")
2465                         {
2466                                 if(mapvote_abstain && i == mapvote_count - 1)
2467                                 {
2468                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2469                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2470                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2471                                 }
2472                                 else
2473                                 {
2474                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2475                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2476                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2477                                 }
2478                         }
2479         }
2480
2481         if(sf & 2)
2482         {
2483                 // flag 2 == update of mask
2484                 if(mapvote_count <= 8)
2485                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2486                 else
2487                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2488         }
2489
2490         if(sf & 4)
2491         {
2492                 if(mapvote_detail)
2493                         for(i = 0; i < mapvote_count; ++i)
2494                                 if(mapvote_maps[i] != "")
2495                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2496
2497                 WriteByte(MSG_ENTITY, to.mapvote);
2498         }
2499
2500         return TRUE;
2501 }
2502
2503 void MapVote_Spawn()
2504 {
2505         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2506 }
2507
2508 void MapVote_TouchMask()
2509 {
2510         mapvote_ent.SendFlags |= 2;
2511 }
2512
2513 void MapVote_TouchVotes(entity voter)
2514 {
2515         mapvote_ent.SendFlags |= 4;
2516 }
2517
2518 float MapVote_Finished(float mappos)
2519 {
2520         string result;
2521         float i;
2522         float didntvote;
2523
2524         if(cvar("sv_eventlog"))
2525         {
2526                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2527                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2528                 didntvote = mapvote_voters;
2529                 for(i = 0; i < mapvote_count; ++i)
2530                         if(mapvote_maps[i] != "")
2531                         {
2532                                 didntvote -= mapvote_votes[i];
2533                                 if(i != mappos)
2534                                 {
2535                                         result = strcat(result, ":", mapvote_maps[i]);
2536                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2537                                 }
2538                         }
2539                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2540
2541                 GameLogEcho(result);
2542                 if(mapvote_maps_suggested[mappos])
2543                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2544         }
2545
2546         FOR_EACH_REALCLIENT(other)
2547                 FixClientCvars(other);
2548
2549         Map_Goto_SetStr(mapvote_maps[mappos]);
2550         Map_Goto();
2551         alreadychangedlevel = TRUE;
2552         return TRUE;
2553 }
2554 void MapVote_CheckRules_1()
2555 {
2556         float i;
2557
2558         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2559         {
2560                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2561                 mapvote_votes[i] = 0;
2562         }
2563
2564         mapvote_voters = 0;
2565         FOR_EACH_REALCLIENT(other)
2566         {
2567                 ++mapvote_voters;
2568                 if(other.mapvote)
2569                 {
2570                         i = other.mapvote - 1;
2571                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2572                         mapvote_votes[i] = mapvote_votes[i] + 1;
2573                 }
2574         }
2575 }
2576
2577 float MapVote_CheckRules_2()
2578 {
2579         float i;
2580         float firstPlace, secondPlace;
2581         float firstPlaceVotes, secondPlaceVotes;
2582         float mapvote_voters_real;
2583         string result;
2584
2585         if(mapvote_count_real == 1)
2586                 return MapVote_Finished(0);
2587
2588         mapvote_voters_real = mapvote_voters;
2589         if(mapvote_abstain)
2590                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2591
2592         RandomSelection_Init();
2593         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2594                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2595         firstPlace = RandomSelection_chosen_float;
2596         firstPlaceVotes = RandomSelection_best_priority;
2597         //dprint("First place: ", ftos(firstPlace), "\n");
2598         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2599
2600         RandomSelection_Init();
2601         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2602                 if(i != firstPlace)
2603                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2604         secondPlace = RandomSelection_chosen_float;
2605         secondPlaceVotes = RandomSelection_best_priority;
2606         //dprint("Second place: ", ftos(secondPlace), "\n");
2607         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2608
2609         if(firstPlace == -1)
2610                 error("No first place in map vote... WTF?");
2611
2612         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2613                 return MapVote_Finished(firstPlace);
2614
2615         if(mapvote_keeptwotime)
2616                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2617                 {
2618                         float didntvote;
2619                         MapVote_TouchMask();
2620                         mapvote_message = "Now decide between the TOP TWO!";
2621                         mapvote_keeptwotime = 0;
2622                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2623                         result = strcat(result, ":", ftos(firstPlaceVotes));
2624                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2625                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2626                         didntvote = mapvote_voters;
2627                         for(i = 0; i < mapvote_count; ++i)
2628                                 if(mapvote_maps[i] != "")
2629                                 {
2630                                         didntvote -= mapvote_votes[i];
2631                                         if(i != firstPlace)
2632                                                 if(i != secondPlace)
2633                                                 {
2634                                                         result = strcat(result, ":", mapvote_maps[i]);
2635                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2636                                                         if(i < mapvote_count_real)
2637                                                         {
2638                                                                 strunzone(mapvote_maps[i]);
2639                                                                 mapvote_maps[i] = "";
2640                                                                 strunzone(mapvote_maps_pakfile[i]);
2641                                                                 mapvote_maps_pakfile[i] = "";
2642                                                         }
2643                                                 }
2644                                 }
2645                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2646                         if(cvar("sv_eventlog"))
2647                                 GameLogEcho(result);
2648                 }
2649
2650         return FALSE;
2651 }
2652 void MapVote_Tick()
2653 {
2654         float keeptwo;
2655         float totalvotes;
2656
2657         keeptwo = mapvote_keeptwotime;
2658         MapVote_CheckRules_1(); // count
2659         if(MapVote_CheckRules_2()) // decide
2660                 return;
2661
2662         totalvotes = 0;
2663         FOR_EACH_REALCLIENT(other)
2664         {
2665                 // hide scoreboard again
2666                 if(other.health != 2342)
2667                 {
2668                         other.health = 2342;
2669                         other.impulse = 0;
2670                         if(clienttype(other) == CLIENTTYPE_REAL)
2671                         {
2672                                 msg_entity = other;
2673                                 WriteByte(MSG_ONE, SVC_FINALE);
2674                                 WriteString(MSG_ONE, "");
2675                         }
2676                 }
2677
2678                 // clear possibly invalid votes
2679                 if(mapvote_maps[other.mapvote - 1] == "")
2680                         other.mapvote = 0;
2681                 // use impulses as new vote
2682                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2683                         if(mapvote_maps[other.impulse - 1] != "")
2684                         {
2685                                 other.mapvote = other.impulse;
2686                                 MapVote_TouchVotes(other);
2687                         }
2688                 other.impulse = 0;
2689
2690                 if(other.mapvote)
2691                         ++totalvotes;
2692         }
2693
2694         MapVote_CheckRules_1(); // just count
2695 }
2696 void MapVote_Start()
2697 {
2698         if(mapvote_run)
2699                 return;
2700
2701         MapInfo_Enumerate();
2702         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2703                 mapvote_run = TRUE;
2704 }
2705 void MapVote_Think()
2706 {
2707         if(!mapvote_run)
2708                 return;
2709
2710         if(alreadychangedlevel)
2711                 return;
2712
2713         if(time < mapvote_nextthink)
2714                 return;
2715         //dprint("tick\n");
2716
2717         mapvote_nextthink = time + 0.5;
2718
2719         if(!mapvote_initialized)
2720         {
2721                 if(cvar("rescan_pending") == 1)
2722                 {
2723                         cvar_set("rescan_pending", "2");
2724                         localcmd("fs_rescan\nrescan_pending 3\n");
2725                         return;
2726                 }
2727                 else if(cvar("rescan_pending") == 2)
2728                 {
2729                         return;
2730                 }
2731                 else if(cvar("rescan_pending") == 3)
2732                 {
2733                         // now build missing mapinfo files
2734                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2735                                 return;
2736
2737                         // we're done, start the timer
2738                         cvar_set("rescan_pending", "0");
2739                 }
2740
2741                 mapvote_initialized = TRUE;
2742                 if(DoNextMapOverride())
2743                         return;
2744                 if(!cvar("g_maplist_votable") || player_count <= 0)
2745                 {
2746                         GotoNextMap();
2747                         return;
2748                 }
2749                 MapVote_Init();
2750         }
2751
2752         MapVote_Tick();
2753 };
2754
2755 string GotoMap(string m)
2756 {
2757         if(!MapInfo_CheckMap(m))
2758                 return "The map you chose is not available on this server.";
2759         cvar_set("nextmap", m);
2760         cvar_set("timelimit", "-1");
2761         if(mapvote_initialized || alreadychangedlevel)
2762         {
2763                 if(DoNextMapOverride())
2764                         return "Map switch initiated.";
2765                 else
2766                         return "Hm... no. For some reason I like THIS map more.";
2767         }
2768         else
2769                 return "Map switch will happen after scoreboard.";
2770 }
2771
2772
2773 void EndFrame()
2774 {
2775         float altime;
2776         FOR_EACH_REALCLIENT(self)
2777         {
2778                 if(self.classname == "spectator")
2779                 {
2780                         if(self.enemy.typehitsound)
2781                                 play2(self, "misc/typehit.wav");
2782                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2783                                 play2(self, "misc/hit.wav");
2784                 }
2785                 else
2786                 {
2787                         if(self.typehitsound)
2788                                 play2(self, "misc/typehit.wav");
2789                         else if(self.hitsound && self.cvar_cl_hitsound)
2790                                 play2(self, "misc/hit.wav");
2791                 }
2792         }
2793         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2794         // add 1 frametime because after this, engine SV_Physics
2795         // increases time by a frametime and then networks the frame
2796         // add another frametime because client shows everything with
2797         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2798         // needed!
2799         FOR_EACH_CLIENT(self)
2800         {
2801                 self.hitsound = FALSE;
2802                 self.typehitsound = FALSE;
2803                 antilag_record(self, altime);
2804         }
2805 }
2806
2807
2808 /*
2809  * RedirectionThink:
2810  * returns TRUE if redirecting
2811  */
2812 float redirection_timeout;
2813 float redirection_nextthink;
2814 float RedirectionThink()
2815 {
2816         float clients_found;
2817
2818         if(redirection_target == "")
2819                 return FALSE;
2820
2821         if(!redirection_timeout)
2822         {
2823                 cvar_set("sv_public", "-2");
2824                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2825                 if(redirection_target == "self")
2826                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2827                 else
2828                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2829         }
2830
2831         if(time < redirection_nextthink)
2832                 return TRUE;
2833
2834         redirection_nextthink = time + 1;
2835
2836         clients_found = 0;
2837         FOR_EACH_REALCLIENT(self)
2838         {
2839                 print("Redirecting: sending connect command to ", self.netname, "\n");
2840                 if(redirection_target == "self")
2841                         stuffcmd(self, "\ndisconnect; reconnect\n");
2842                 else
2843                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2844                 ++clients_found;
2845         }
2846
2847         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2848
2849         if(time > redirection_timeout || clients_found == 0)
2850                 localcmd("\nwait; wait; wait; quit\n");
2851
2852         return TRUE;
2853 }
2854
2855 void TargetMusic_RestoreGame();
2856 void RestoreGame()
2857 {
2858         // Loaded from a save game
2859         // some things then break, so let's work around them...
2860
2861         // Progs DB (capture records)
2862         ServerProgsDB = db_load("server.db");
2863
2864         // Mapinfo
2865         MapInfo_Shutdown();
2866         MapInfo_Enumerate();
2867         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2868         WeaponStats_Init();
2869
2870         TargetMusic_RestoreGame();
2871 }
2872
2873 void SV_Shutdown()
2874 {
2875         if(gameover > 1) // shutting down already?
2876                 return;
2877
2878         gameover = 2; // 2 = server shutting down
2879
2880         if(world_initialized > 0)
2881         {
2882                 world_initialized = 0;
2883                 print("Saving persistent data...\n");
2884                 Ban_SaveBans();
2885                 if(!cheatcount_total)
2886                 {
2887                         if(cvar("sv_db_saveasdump"))
2888                                 db_dump(ServerProgsDB, "server.db");
2889                         else
2890                                 db_save(ServerProgsDB, "server.db");
2891                 }
2892                 if(cvar("developer"))
2893                 {
2894                         if(cvar("sv_db_saveasdump"))
2895                                 db_dump(TemporaryDB, "server-temp.db");
2896                         else
2897                                 db_save(TemporaryDB, "server-temp.db");
2898                 }
2899                 CheatShutdown(); // must be after cheatcount check
2900                 db_close(ServerProgsDB);
2901                 db_close(TemporaryDB);
2902                 print("done!\n");
2903                 // tell the bot system the game is ending now
2904                 bot_endgame();
2905
2906                 WeaponStats_Shutdown();
2907                 MapInfo_Shutdown();
2908         }
2909         else if(world_initialized == 0)
2910         {
2911                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2912         }
2913 }