qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include <server/mutators/_mod.qh>
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "scores_rules.qh"
  20 #include "teamplay.qh"
  21 #include "weapons/weaponstats.qh"
  22 #include "../common/constants.qh"
  23 #include <common/net_linked.qh>
  24 #include "../common/deathtypes/all.qh"
  25 #include "../common/gamemodes/sv_rules.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/_mod.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/vehicles/all.qh"
  30 #include "../common/notifications/all.qh"
  31 #include "../common/physics/player.qh"
  32 #include "../common/playerstats.qh"
  33 #include "../common/stats.qh"
  34 #include "../common/teams.qh"
  35 #include "../common/mapobjects/trigger/secret.qh"
  36 #include "../common/mapobjects/target/music.qh"
  37 #include "../common/util.qh"
  38 #include "../common/items/_mod.qh"
  39 #include <common/weapons/_all.qh>
  40 #include "../common/state.qh"
  41
  42 const float LATENCY_THINKRATE = 10;
  43 .float latency_sum;
  44 .float latency_cnt;
  45 .float latency_time;
  46 entity pingplreport;
  47 void PingPLReport_Think(entity this)
  48 {
  49         float delta;
  50         entity e;
  51
  52         delta = 3 / maxclients;
  53         if(delta < sys_frametime)
  54                 delta = 0;
  55         this.nextthink = time + delta;
  56
  57         e = edict_num(this.cnt + 1);
  58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  59         {
  60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  61                 WriteByte(MSG_BROADCAST, this.cnt);
  62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  65
  66                 // record latency times for clients throughout the match so we can report it to playerstats
  67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  68                 {
  69                         CS(e).latency_sum += CS(e).ping;
  70                         CS(e).latency_cnt += 1;
  71                         CS(e).latency_time = time;
  72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  73                 }
  74         }
  75         else
  76         {
  77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  78                 WriteByte(MSG_BROADCAST, this.cnt);
  79                 WriteShort(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81                 WriteByte(MSG_BROADCAST, 0);
  82         }
  83         this.cnt = (this.cnt + 1) % maxclients;
  84 }
  85 void PingPLReport_Spawn()
  86 {
  87         pingplreport = new_pure(pingplreport);
  88         setthink(pingplreport, PingPLReport_Think);
  89         pingplreport.nextthink = time;
  90 }
  91
  92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  93 string redirection_target;
  94 float world_initialized;
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         strfree(cvar_changes);
 148         strfree(cvar_purechanges);
 149         cvar_purechanges_count = 0;
 150
 151         h = buf_create();
 152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 153         n = buf_getsize(h);
 154
 155         adding = true;
 156         pureadding = true;
 157
 158         for(i = 0; i < n; ++i)
 159         {
 160                 k = bufstr_get(h, i);
 161
 162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 164 #define BADCVAR(p) if(k == p) continue
 165
 166                 // general excludes and namespaces for server admin used cvars
 167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 168
 169                 // internal
 170                 BADPREFIX("csqc_");
 171                 BADPREFIX("cvar_check_");
 172                 BADCVAR("gamecfg");
 173                 BADCVAR("g_configversion");
 174                 BADCVAR("halflifebsp");
 175                 BADCVAR("sv_mapformat_is_quake2");
 176                 BADCVAR("sv_mapformat_is_quake3");
 177                 BADPREFIX("sv_world");
 178
 179                 // client
 180                 BADPREFIX("chase_");
 181                 BADPREFIX("cl_");
 182                 BADPREFIX("con_");
 183                 BADPREFIX("scoreboard_");
 184                 BADPREFIX("g_campaign");
 185                 BADPREFIX("g_waypointsprite_");
 186                 BADPREFIX("gl_");
 187                 BADPREFIX("joy");
 188                 BADPREFIX("hud_");
 189                 BADPREFIX("m_");
 190                 BADPREFIX("menu_");
 191                 BADPREFIX("net_slist_");
 192                 BADPREFIX("r_");
 193                 BADPREFIX("sbar_");
 194                 BADPREFIX("scr_");
 195                 BADPREFIX("snd_");
 196                 BADPREFIX("show");
 197                 BADPREFIX("sensitivity");
 198                 BADPREFIX("userbind");
 199                 BADPREFIX("v_");
 200                 BADPREFIX("vid_");
 201                 BADPREFIX("crosshair");
 202                 BADCVAR("mod_q3bsp_lightmapmergepower");
 203                 BADCVAR("mod_q3bsp_nolightmaps");
 204                 BADCVAR("fov");
 205                 BADCVAR("mastervolume");
 206                 BADCVAR("volume");
 207                 BADCVAR("bgmvolume");
 208                 BADCVAR("in_pitch_min");
 209                 BADCVAR("in_pitch_max");
 210
 211                 // private
 212                 BADCVAR("developer");
 213                 BADCVAR("log_dest_udp");
 214                 BADCVAR("net_address");
 215                 BADCVAR("net_address_ipv6");
 216                 BADCVAR("port");
 217                 BADCVAR("savedgamecfg");
 218                 BADCVAR("serverconfig");
 219                 BADCVAR("sv_autoscreenshot");
 220                 BADCVAR("sv_heartbeatperiod");
 221                 BADCVAR("sv_vote_master_password");
 222                 BADCVAR("sys_colortranslation");
 223                 BADCVAR("sys_specialcharactertranslation");
 224                 BADCVAR("timeformat");
 225                 BADCVAR("timestamps");
 226                 BADCVAR("g_require_stats");
 227                 BADPREFIX("developer_");
 228                 BADPREFIX("g_ban_");
 229                 BADPREFIX("g_banned_list");
 230                 BADPREFIX("g_require_stats_");
 231                 BADPREFIX("g_chat_flood_");
 232                 BADPREFIX("g_ghost_items");
 233                 BADPREFIX("g_playerstats_");
 234                 BADPREFIX("g_voice_flood_");
 235                 BADPREFIX("log_file");
 236                 BADPREFIX("quit_");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250                 BADCVAR("sv_muteban_list");
 251                 BADCVAR("sv_voteban_list");
 252                 BADCVAR("sv_allow_customplayermodels_idlist");
 253                 BADCVAR("sv_allow_customplayermodels_speciallist");
 254
 255                 // mapinfo
 256                 BADCVAR("fraglimit");
 257                 BADCVAR("g_arena");
 258                 BADCVAR("g_assault");
 259                 BADCVAR("g_ca");
 260                 BADCVAR("g_ca_teams");
 261                 BADCVAR("g_conquest");
 262                 BADCVAR("g_ctf");
 263                 BADCVAR("g_cts");
 264                 BADCVAR("g_dotc");
 265                 BADCVAR("g_dm");
 266                 BADCVAR("g_domination");
 267                 BADCVAR("g_domination_default_teams");
 268                 BADCVAR("g_duel");
 269                 BADCVAR("g_freezetag");
 270                 BADCVAR("g_freezetag_teams");
 271                 BADCVAR("g_invasion_teams");
 272                 BADCVAR("g_invasion_type");
 273                 BADCVAR("g_jailbreak");
 274                 BADCVAR("g_jailbreak_teams");
 275                 BADCVAR("g_keepaway");
 276                 BADCVAR("g_keyhunt");
 277                 BADCVAR("g_keyhunt_teams");
 278                 BADCVAR("g_lms");
 279                 BADCVAR("g_nexball");
 280                 BADCVAR("g_onslaught");
 281                 BADCVAR("g_race");
 282                 BADCVAR("g_race_laps_limit");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_race_qualifying_timelimit_override");
 285                 BADCVAR("g_runematch");
 286                 BADCVAR("g_snafu");
 287                 BADCVAR("g_tdm");
 288                 BADCVAR("g_tdm_teams");
 289                 BADCVAR("g_vip");
 290                 BADCVAR("leadlimit");
 291                 BADCVAR("nextmap");
 292                 BADCVAR("teamplay");
 293                 BADCVAR("timelimit");
 294                 BADCVAR("g_mapinfo_ignore_warnings");
 295
 296                 // long
 297                 BADCVAR("hostname");
 298                 BADCVAR("g_maplist");
 299                 BADCVAR("g_maplist_mostrecent");
 300                 BADCVAR("sv_motd");
 301
 302                 v = cvar_string(k);
 303                 d = cvar_defstring(k);
 304                 if(v == d)
 305                         continue;
 306
 307                 if(adding)
 308                 {
 309                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 310                         if(strlen(cvar_changes) > 16384)
 311                         {
 312                                 cvar_changes = "// too many settings have been changed to show them here\n";
 313                                 adding = 0;
 314                         }
 315                 }
 316
 317                 // now check if the changes are actually gameplay relevant
 318
 319                 // does nothing gameplay relevant
 320                 BADCVAR("captureleadlimit_override");
 321                 BADCVAR("condump_stripcolors");
 322                 BADCVAR("gameversion");
 323                 BADCVAR("g_allow_oldvortexbeam");
 324                 BADCVAR("g_balance_kill_delay");
 325                 BADCVAR("g_buffs_pickup_anyway");
 326                 BADCVAR("g_buffs_randomize");
 327                 BADCVAR("g_campcheck_distance");
 328                 BADCVAR("g_ca_point_leadlimit");
 329                 BADCVAR("g_ca_point_limit");
 330                 BADCVAR("g_ctf_captimerecord_always");
 331                 BADCVAR("g_ctf_flag_glowtrails");
 332                 BADCVAR("g_ctf_flag_pickup_verbosename");
 333                 BADCVAR("g_domination_point_leadlimit");
 334                 BADCVAR("g_forced_respawn");
 335                 BADCVAR("g_freezetag_point_leadlimit");
 336                 BADCVAR("g_freezetag_point_limit");
 337                 BADCVAR("g_hats");
 338                 BADCVAR("g_invasion_point_limit");
 339                 BADCVAR("g_jump_grunt");
 340                 BADCVAR("g_keyhunt_point_leadlimit");
 341                 BADCVAR("g_nexball_goalleadlimit");
 342                 BADCVAR("g_new_toys_use_pickupsound");
 343                 BADCVAR("g_physics_predictall");
 344                 BADCVAR("g_piggyback");
 345                 BADCVAR("g_playerclip_collisions");
 346                 BADCVAR("g_tdm_point_leadlimit");
 347                 BADCVAR("g_tdm_point_limit");
 348                 BADCVAR("leadlimit_and_fraglimit");
 349                 BADCVAR("leadlimit_override");
 350                 BADCVAR("pausable");
 351                 BADCVAR("sv_checkforpacketsduringsleep");
 352                 BADCVAR("sv_damagetext");
 353                 BADCVAR("sv_db_saveasdump");
 354                 BADCVAR("sv_intermission_cdtrack");
 355                 BADCVAR("sv_minigames");
 356                 BADCVAR("sv_namechangetimer");
 357                 BADCVAR("sv_precacheplayermodels");
 358                 BADCVAR("sv_stepheight");
 359                 BADCVAR("sv_timeout");
 360                 BADCVAR("sv_weapons_modeloverride");
 361                 BADCVAR("w_prop_interval");
 362                 BADPREFIX("crypto_");
 363                 BADPREFIX("gameversion_");
 364                 BADPREFIX("g_chat_");
 365                 BADPREFIX("g_ctf_captimerecord_");
 366                 BADPREFIX("g_hats_");
 367                 BADPREFIX("g_maplist_");
 368                 BADPREFIX("g_mod_");
 369                 BADPREFIX("g_respawn_");
 370                 BADPREFIX("net_");
 371                 BADPREFIX("notification_");
 372                 BADPREFIX("prvm_");
 373                 BADPREFIX("skill_");
 374                 BADPREFIX("sv_allow_");
 375                 BADPREFIX("sv_cullentities_");
 376                 BADPREFIX("sv_maxidle_");
 377                 BADPREFIX("sv_minigames_");
 378                 BADPREFIX("sv_radio_");
 379                 BADPREFIX("sv_timeout_");
 380                 BADPREFIX("sv_vote_");
 381                 BADPREFIX("timelimit_");
 382
 383                 // allowed changes to server admins (please sync this to server.cfg)
 384                 // vi commands:
 385                 //   :/"impure"/,$d
 386                 //   :g!,^\/\/[^ /],d
 387                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 388                 //   :%!sort
 389                 // yes, this does contain some redundant stuff, don't really care
 390                 BADCVAR("bot_config_file");
 391                 BADCVAR("bot_number");
 392                 BADCVAR("bot_prefix");
 393                 BADCVAR("bot_suffix");
 394                 BADCVAR("capturelimit_override");
 395                 BADCVAR("fraglimit_override");
 396                 BADCVAR("gametype");
 397                 BADCVAR("g_antilag");
 398                 BADCVAR("g_balance_teams");
 399                 BADCVAR("g_balance_teams_prevent_imbalance");
 400                 BADCVAR("g_balance_teams_scorefactor");
 401                 BADCVAR("g_ban_sync_trusted_servers");
 402                 BADCVAR("g_ban_sync_uri");
 403                 BADCVAR("g_buffs");
 404                 BADCVAR("g_ca_teams_override");
 405                 BADCVAR("g_ctf_ignore_frags");
 406                 BADCVAR("g_ctf_leaderboard");
 407                 BADCVAR("g_domination_point_limit");
 408                 BADCVAR("g_domination_teams_override");
 409                 BADCVAR("g_freezetag_teams_override");
 410                 BADCVAR("g_friendlyfire");
 411                 BADCVAR("g_fullbrightitems");
 412                 BADCVAR("g_fullbrightplayers");
 413                 BADCVAR("g_keyhunt_point_limit");
 414                 BADCVAR("g_keyhunt_teams_override");
 415                 BADCVAR("g_lms_lives_override");
 416                 BADCVAR("g_maplist");
 417                 BADCVAR("g_maxplayers");
 418                 BADCVAR("g_mirrordamage");
 419                 BADCVAR("g_nexball_goallimit");
 420                 BADCVAR("g_norecoil");
 421                 BADCVAR("g_physics_clientselect");
 422                 BADCVAR("g_pinata");
 423                 BADCVAR("g_powerups");
 424                 BADCVAR("g_spawnshieldtime");
 425                 BADCVAR("g_start_delay");
 426                 BADCVAR("g_superspectate");
 427                 BADCVAR("g_tdm_teams_override");
 428                 BADCVAR("g_warmup");
 429                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 430                 BADCVAR("hostname");
 431                 BADCVAR("log_file");
 432                 BADCVAR("maxplayers");
 433                 BADCVAR("minplayers");
 434                 BADCVAR("net_address");
 435                 BADCVAR("port");
 436                 BADCVAR("rcon_password");
 437                 BADCVAR("rcon_restricted_commands");
 438                 BADCVAR("rcon_restricted_password");
 439                 BADCVAR("skill");
 440                 BADCVAR("sv_adminnick");
 441                 BADCVAR("sv_autoscreenshot");
 442                 BADCVAR("sv_autotaunt");
 443                 BADCVAR("sv_curl_defaulturl");
 444                 BADCVAR("sv_defaultcharacter");
 445                 BADCVAR("sv_defaultcharacterskin");
 446                 BADCVAR("sv_defaultplayercolors");
 447                 BADCVAR("sv_defaultplayermodel");
 448                 BADCVAR("sv_defaultplayerskin");
 449                 BADCVAR("sv_maxidle");
 450                 BADCVAR("sv_maxrate");
 451                 BADCVAR("sv_motd");
 452                 BADCVAR("sv_public");
 453                 BADCVAR("sv_ready_restart");
 454                 BADCVAR("sv_status_privacy");
 455                 BADCVAR("sv_taunt");
 456                 BADCVAR("sv_vote_call");
 457                 BADCVAR("sv_vote_commands");
 458                 BADCVAR("sv_vote_majority_factor");
 459                 BADCVAR("sv_vote_master");
 460                 BADCVAR("sv_vote_master_commands");
 461                 BADCVAR("sv_vote_master_password");
 462                 BADCVAR("sv_vote_simple_majority_factor");
 463                 BADCVAR("teamplay_mode");
 464                 BADCVAR("timelimit_override");
 465                 BADPREFIX("g_warmup_");
 466                 BADPREFIX("sv_info_");
 467                 BADPREFIX("sv_ready_restart_");
 468
 469                 // mutators that announce themselves properly to the server browser
 470                 BADCVAR("g_instagib");
 471                 BADCVAR("g_new_toys");
 472                 BADCVAR("g_nix");
 473                 BADCVAR("g_grappling_hook");
 474                 BADCVAR("g_jetpack");
 475
 476 #undef BADPRESUFFIX
 477 #undef BADPREFIX
 478 #undef BADCVAR
 479
 480                 if(pureadding)
 481                 {
 482                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 483                         if(strlen(cvar_purechanges) > 16384)
 484                         {
 485                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 486                                 pureadding = 0;
 487                         }
 488                 }
 489                 ++cvar_purechanges_count;
 490                 // WARNING: this variable is used for the server list
 491                 // NEVER dare to skip this code!
 492                 // Hacks to intentionally appearing as "pure server" even though you DO have
 493                 // modified settings may be punished by removal from the server list.
 494                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 495                 // though.
 496         }
 497         buf_del(h);
 498         if(cvar_changes == "")
 499                 cvar_changes = "// this server runs at default server settings\n";
 500         else
 501                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 502         cvar_changes = strzone(cvar_changes);
 503         if(cvar_purechanges == "")
 504                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 505         else
 506                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 507         cvar_purechanges = strzone(cvar_purechanges);
 508 }
 509
 510 entity randomseed;
 511 bool RandomSeed_Send(entity this, entity to, int sf)
 512 {
 513         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 514         WriteShort(MSG_ENTITY, this.cnt);
 515         return true;
 516 }
 517 void RandomSeed_Think(entity this)
 518 {
 519         this.cnt = bound(0, floor(random() * 65536), 65535);
 520         this.nextthink = time + 5;
 521
 522         this.SendFlags |= 1;
 523 }
 524 void RandomSeed_Spawn()
 525 {
 526         randomseed = new_pure(randomseed);
 527         setthink(randomseed, RandomSeed_Think);
 528         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 529
 530         getthink(randomseed)(randomseed); // sets random seed and nextthink
 531 }
 532
 533 spawnfunc(__init_dedicated_server)
 534 {
 535         // handler for _init/_init map (only for dedicated server initialization)
 536
 537         world_initialized = -1; // don't complain
 538         cvar = cvar_normal;
 539         cvar_string = cvar_string_normal;
 540         cvar_set = cvar_set_normal;
 541
 542         delete_fn = remove_unsafely;
 543
 544         entity e = spawn();
 545         setthink(e, GotoFirstMap);
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = new(info_player_deathmatch);  // safeguard against player joining
 549
 550     // assign reflectively to avoid "assignment to world" warning
 551     for (int i = 0, n = numentityfields(); i < n; ++i) {
 552         string k = entityfieldname(i);
 553         if (k == "classname") {
 554             // safeguard against various stuff ;)
 555             putentityfieldstring(i, this, "worldspawn");
 556             break;
 557         }
 558     }
 559
 560         // needs to be done so early because of the constants they create
 561         static_init();
 562         static_init_late();
 563         static_init_precache();
 564
 565         IL_PUSH(g_spawnpoints, e); // just incase
 566
 567         MapInfo_Enumerate();
 568         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 569 }
 570
 571 void __init_dedicated_server_shutdown() {
 572         MapInfo_Shutdown();
 573 }
 574
 575 STATIC_INIT_EARLY(maxclients)
 576 {
 577         maxclients = 0;
 578         for (entity head = nextent(NULL); head; head = nextent(head)) {
 579                 ++maxclients;
 580         }
 581 }
 582
 583 void default_delayedinit(entity this)
 584 {
 585         if(!scores_initialized)
 586                 ScoreRules_generic();
 587 }
 588
 589 void InitGameplayMode()
 590 {
 591         VoteReset();
 592
 593         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 594         get_mi_min_max(1);
 595         // assign reflectively to avoid "assignment to world" warning
 596         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 597             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 598             if (v) {
 599             putentityfieldstring(i, world, sprintf("%v", v));
 600             if (++done == 2) break;
 601         }
 602         }
 603         // currently, NetRadiant's limit is 131072 qu for each side
 604         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 605         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 606         // in case somebody makes extremely large maps
 607         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 608
 609         MapInfo_LoadMapSettings(mapname);
 610         GameRules_teams(false);
 611
 612         if (!cvar_value_issafe(world.fog))
 613         {
 614                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 615                 world.fog = string_null;
 616         }
 617         if(MapInfo_Map_fog != "")
 618         {
 619                 if(MapInfo_Map_fog == "none")
 620                         world.fog = string_null;
 621                 else
 622                         world.fog = strzone(MapInfo_Map_fog);
 623         }
 624         clientstuff = strzone(MapInfo_Map_clientstuff);
 625
 626         MapInfo_ClearTemps();
 627
 628         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 629
 630         cache_mutatormsg = strzone("");
 631         cache_lastmutatormsg = strzone("");
 632
 633         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 634 }
 635
 636 void Map_MarkAsRecent(string m);
 637 float world_already_spawned;
 638 spawnfunc(worldspawn)
 639 {
 640         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 641
 642     bool wantrestart = false;
 643         {
 644                 if (!server_is_dedicated)
 645                 {
 646                         // force unloading of server pk3 files when starting a listen server
 647                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 648                         // restore csqc_progname too
 649                         string expect = "csprogs.dat";
 650                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 651                         cvar_set_normal("csqc_progname", expect);
 652                 }
 653                 else
 654                 {
 655                         // Try to use versioned csprogs from pk3
 656                         // Only ever use versioned csprogs.dat files on dedicated servers;
 657                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 658                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 659                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 660                         string select = "csprogs.dat";
 661                         if (fexists(pk3csprogs)) select = pk3csprogs;
 662                         if (cvar_string_normal("csqc_progname") != select)
 663                         {
 664                                 cvar_set_normal("csqc_progname", select);
 665                                 wantrestart = true;
 666                         }
 667                         // Check for updates on startup
 668                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 669                         int sentinel = fopen("progs.txt", FILE_READ);
 670                         if (sentinel >= 0)
 671                         {
 672                                 string switchversion = fgets(sentinel);
 673                                 fclose(sentinel);
 674                                 if (switchversion != "" && switchversion != WATERMARK)
 675                                 {
 676                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 677                                         // if it doesn't exist, assume either:
 678                                         //   a) the current program was overwritten
 679                                         //   b) this is a client only update
 680                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 681                                         if (fexists(newprogs))
 682                                         {
 683                                                 cvar_set_normal("sv_progs", newprogs);
 684                                                 wantrestart = true;
 685                                         }
 686                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 687                                         if (fexists(newcsprogs))
 688                                         {
 689                                                 cvar_set_normal("csqc_progname", newcsprogs);
 690                                                 wantrestart = true;
 691                                         }
 692                                 }
 693                         }
 694                 }
 695                 if (wantrestart)
 696                 {
 697                         LOG_INFOF("Restart requested");
 698                         changelevel(mapname);
 699                         // let initialization continue, shutdown depends on it
 700                 }
 701         }
 702
 703         cvar = cvar_normal;
 704         cvar_string = cvar_string_normal;
 705         cvar_set = cvar_set_normal;
 706
 707         if(world_already_spawned)
 708                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 709         world_already_spawned = true;
 710
 711         delete_fn = remove_safely; // during spawning, watch what you remove!
 712
 713         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 714
 715         // needs to be done so early because of the constants they create
 716         static_init();
 717
 718         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 719
 720         TemporaryDB = db_create();
 721
 722         // 0 normal
 723         lightstyle(0, "m");
 724
 725         // 1 FLICKER (first variety)
 726         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 727
 728         // 2 SLOW STRONG PULSE
 729         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 730
 731         // 3 CANDLE (first variety)
 732         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 733
 734         // 4 FAST STROBE
 735         lightstyle(4, "mamamamamama");
 736
 737         // 5 GENTLE PULSE 1
 738         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 739
 740         // 6 FLICKER (second variety)
 741         lightstyle(6, "nmonqnmomnmomomno");
 742
 743         // 7 CANDLE (second variety)
 744         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 745
 746         // 8 CANDLE (third variety)
 747         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 748
 749         // 9 SLOW STROBE (fourth variety)
 750         lightstyle(9, "aaaaaaaazzzzzzzz");
 751
 752         // 10 FLUORESCENT FLICKER
 753         lightstyle(10, "mmamammmmammamamaaamammma");
 754
 755         // 11 SLOW PULSE NOT FADE TO BLACK
 756         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 757
 758         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 759
 760         // 63 testing
 761         lightstyle(63, "a");
 762
 763         if(autocvar_g_campaign)
 764                 CampaignPreInit();
 765
 766         Map_MarkAsRecent(mapname);
 767
 768         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 769
 770         InitGameplayMode();
 771         static_init_late();
 772         static_init_precache();
 773         readlevelcvars();
 774         GrappleHookInit();
 775
 776     GameRules_limit_fallbacks();
 777
 778         if(warmup_limit == 0)
 779                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 780
 781         player_count = 0;
 782         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 783         if(bot_waypoints_for_items == 1)
 784                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 785                         bot_waypoints_for_items = 0;
 786
 787         precache();
 788
 789         WaypointSprite_Init();
 790
 791         GameLogInit(); // prepare everything
 792         // NOTE for matchid:
 793         // changing the logic generating it is okay. But:
 794         // it HAS to stay <= 64 chars
 795         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 796         if(autocvar_sv_eventlog)
 797         {
 798                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 799                 matchid = strzone(s);
 800
 801                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 802                 s = ":gameinfo:mutators:LIST";
 803
 804                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 805                 s = M_ARGV(0, string);
 806
 807                 // initialiation stuff, not good in the mutator system
 808                 if(!autocvar_g_use_ammunition)
 809                         s = strcat(s, ":no_use_ammunition");
 810
 811                 // initialiation stuff, not good in the mutator system
 812                 if(autocvar_g_pickup_items == 0)
 813                         s = strcat(s, ":no_pickup_items");
 814                 if(autocvar_g_pickup_items > 0)
 815                         s = strcat(s, ":pickup_items");
 816
 817                 // initialiation stuff, not good in the mutator system
 818                 if(autocvar_g_weaponarena != "0")
 819                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 820
 821                 // TODO to mutator system
 822                 if(autocvar_g_norecoil)
 823                         s = strcat(s, ":norecoil");
 824
 825                 // TODO to mutator system
 826                 if(autocvar_g_powerups == 0)
 827                         s = strcat(s, ":no_powerups");
 828                 if(autocvar_g_powerups > 0)
 829                         s = strcat(s, ":powerups");
 830
 831                 GameLogEcho(s);
 832                 GameLogEcho(":gameinfo:end");
 833         }
 834         else
 835                 matchid = strzone(ftos(random()));
 836
 837         cvar_set("nextmap", "");
 838
 839         SetDefaultAlpha();
 840
 841         if(autocvar_g_campaign)
 842                 CampaignPostInit();
 843
 844         Ban_LoadBans();
 845
 846         MapInfo_Enumerate();
 847         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 848
 849         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 850         {
 851                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 852                 if(fd != -1)
 853                 {
 854                         string s;
 855                         while((s = fgets(fd)))
 856                         {
 857                                 int l = tokenize_console(s);
 858                                 if(l < 2)
 859                                         continue;
 860                                 if(argv(0) == "cd")
 861                                 {
 862                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 863                                         LOG_INFO("  cdtrack ", argv(2));
 864                                 }
 865                                 else if(argv(0) == "fog")
 866                                 {
 867                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 868                                         LOG_INFO("  \"fog\" \"", s, "\"");
 869                                 }
 870                                 else if(argv(0) == "set")
 871                                 {
 872                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 873                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 874                                 }
 875                                 else if(argv(0) != "//")
 876                                 {
 877                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 878                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 879                                 }
 880                         }
 881                         fclose(fd);
 882                 }
 883         }
 884
 885         WeaponStats_Init();
 886
 887         Nagger_Init();
 888
 889         next_pingtime = time + 5;
 890
 891         // set up information replies for clients and server to use
 892         maplist_reply = strzone(getmaplist());
 893         lsmaps_reply = strzone(getlsmaps());
 894         monsterlist_reply = strzone(getmonsterlist());
 895         for(int i = 0; i < 10; ++i)
 896         {
 897                 string s = getrecords(i);
 898                 if (s)
 899                         records_reply[i] = strzone(s);
 900         }
 901         ladder_reply = strzone(getladder());
 902         rankings_reply = strzone(getrankings());
 903
 904         // begin other init
 905         ClientInit_Spawn();
 906         RandomSeed_Spawn();
 907         PingPLReport_Spawn();
 908
 909         CheatInit();
 910
 911         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 912
 913         // fill sv_curl_serverpackages from .serverpackage files
 914         if (autocvar_sv_curl_serverpackages_auto)
 915         {
 916                 string s = "csprogs-" WATERMARK ".txt";
 917                 // remove automatically managed files from the list to prevent duplicates
 918                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 919                 {
 920                         string pkg = argv(i);
 921                         if (startsWith(pkg, "csprogs-")) continue;
 922                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 923                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 924                         s = cons(s, pkg);
 925                 }
 926                 // add automatically managed files to the list
 927                 #define X(match) MACRO_BEGIN \
 928                         int fd = search_begin(match, true, false); \
 929                         if (fd >= 0) \
 930                         { \
 931                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 932                                 { \
 933                                         s = cons(s, search_getfilename(fd, i)); \
 934                                 } \
 935                                 search_end(fd); \
 936                         } \
 937                 MACRO_END
 938                 X("*-serverpackage.txt");
 939                 X("*.serverpackage");
 940                 #undef X
 941                 cvar_set("sv_curl_serverpackages", s);
 942         }
 943
 944         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 945         modname = "Xonotic";
 946         // physics/balance/config changes that count as mod
 947         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 948                 modname = cvar_string("g_mod_physics");
 949         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 950                 modname = cvar_string("g_mod_balance");
 951         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 952                 modname = cvar_string("g_mod_config");
 953         // extra mutators that deserve to count as mod
 954         MUTATOR_CALLHOOK(SetModname, modname);
 955         modname = M_ARGV(0, string);
 956
 957         // save it for later
 958         modname = strzone(modname);
 959
 960         WinningConditionHelper(this); // set worldstatus
 961
 962         world_initialized = 1;
 963         __spawnfunc_spawn_all();
 964 }
 965
 966 spawnfunc(light)
 967 {
 968         //makestatic (this); // Who the f___ did that?
 969         delete(this);
 970 }
 971
 972 string GetGametype()
 973 {
 974         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 975 }
 976
 977 string GetMapname()
 978 {
 979         return mapname;
 980 }
 981
 982 float Map_Count, Map_Current;
 983 string Map_Current_Name;
 984
 985 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 986 float GetMaplistPosition()
 987 {
 988         float pos, idx;
 989         string map;
 990
 991         map = GetMapname();
 992         idx = autocvar_g_maplist_index;
 993
 994         if(idx >= 0)
 995                 if(idx < Map_Count)
 996                         if(map == argv(idx))
 997                                 return idx;
 998
 999         for(pos = 0; pos < Map_Count; ++pos)
1000                 if(map == argv(pos))
1001                         return pos;
1002
1003         // resume normal maplist rotation if current map is not in g_maplist
1004         return idx;
1005 }
1006
1007 bool MapHasRightSize(string map)
1008 {
1009         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1010         if(autocvar_g_maplist_check_waypoints)
1011         {
1012                 string checkwp_msg = strcat("checkwp ", map);
1013                 if(!fexists(strcat("maps/", map, ".waypoints")))
1014                 {
1015                         LOG_TRACE(checkwp_msg, ": no waypoints");
1016                         return false;
1017                 }
1018                 LOG_TRACE(checkwp_msg, ": has waypoints");
1019         }
1020
1021         // open map size restriction file
1022         string opensize_msg = strcat("opensize ", map);
1023         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1024         if(fh >= 0)
1025         {
1026                 opensize_msg = strcat(opensize_msg, ": ok, ");
1027                 int mapmin = stoi(fgets(fh));
1028                 int mapmax = stoi(fgets(fh));
1029                 fclose(fh);
1030                 if(player_count < mapmin)
1031                 {
1032                         LOG_TRACE(opensize_msg, "not enough");
1033                         return false;
1034                 }
1035                 if(mapmax && player_count > mapmax)
1036                 {
1037                         LOG_TRACE(opensize_msg, "too many");
1038                         return false;
1039                 }
1040                 LOG_TRACE(opensize_msg, "right size");
1041                 return true;
1042         }
1043         LOG_TRACE(opensize_msg, ": not found");
1044         return true;
1045 }
1046
1047 string Map_Filename(float position)
1048 {
1049         return strcat("maps/", argv(position), ".bsp");
1050 }
1051
1052 void Map_MarkAsRecent(string m)
1053 {
1054         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1055 }
1056
1057 float Map_IsRecent(string m)
1058 {
1059         return strhasword(autocvar_g_maplist_mostrecent, m);
1060 }
1061
1062 float Map_Check(float position, float pass)
1063 {
1064         string filename;
1065         string map_next;
1066         map_next = argv(position);
1067         if(pass <= 1)
1068         {
1069                 if(Map_IsRecent(map_next))
1070                         return 0;
1071         }
1072         filename = Map_Filename(position);
1073         if(MapInfo_CheckMap(map_next))
1074         {
1075                 if(pass == 2)
1076                         return 1;
1077                 if(MapHasRightSize(map_next))
1078                         return 1;
1079                 return 0;
1080         }
1081         else
1082                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1083
1084         return 0;
1085 }
1086
1087 void Map_Goto_SetStr(string nextmapname)
1088 {
1089         if(getmapname_stored != "")
1090                 strunzone(getmapname_stored);
1091         if(nextmapname == "")
1092                 getmapname_stored = "";
1093         else
1094                 getmapname_stored = strzone(nextmapname);
1095 }
1096
1097 void Map_Goto_SetFloat(float position)
1098 {
1099         cvar_set("g_maplist_index", ftos(position));
1100         Map_Goto_SetStr(argv(position));
1101 }
1102
1103 void Map_Goto(float reinit)
1104 {
1105         MapInfo_LoadMap(getmapname_stored, reinit);
1106 }
1107
1108 // return codes of map selectors:
1109 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1110 //   -2 = permanent failure
1111 float MaplistMethod_Iterate() // usual method
1112 {
1113         float pass, i;
1114
1115         LOG_TRACE("Trying MaplistMethod_Iterate");
1116
1117         for(pass = 1; pass <= 2; ++pass)
1118         {
1119                 for(i = 1; i < Map_Count; ++i)
1120                 {
1121                         float mapindex;
1122                         mapindex = (i + Map_Current) % Map_Count;
1123                         if(Map_Check(mapindex, pass))
1124                                 return mapindex;
1125                 }
1126         }
1127         return -1;
1128 }
1129
1130 float MaplistMethod_Repeat() // fallback method
1131 {
1132         LOG_TRACE("Trying MaplistMethod_Repeat");
1133
1134         if(Map_Check(Map_Current, 2))
1135                 return Map_Current;
1136         return -2;
1137 }
1138
1139 float MaplistMethod_Random() // random map selection
1140 {
1141         float i, imax;
1142
1143         LOG_TRACE("Trying MaplistMethod_Random");
1144
1145         imax = 42;
1146
1147         for(i = 0; i <= imax; ++i)
1148         {
1149                 float mapindex;
1150                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1151                 if(Map_Check(mapindex, 1))
1152                         return mapindex;
1153         }
1154         return -1;
1155 }
1156
1157 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1158 // the exponent sets a bias on the map selection:
1159 // the higher the exponent, the less likely "shortly repeated" same maps are
1160 {
1161         float i, j, imax, insertpos;
1162
1163         LOG_TRACE("Trying MaplistMethod_Shuffle");
1164
1165         imax = 42;
1166
1167         for(i = 0; i <= imax; ++i)
1168         {
1169                 string newlist;
1170
1171                 // now reinsert this at another position
1172                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1173                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1174                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1175                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1176
1177                 // insert the current map there
1178                 newlist = "";
1179                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1180                         newlist = strcat(newlist, " ", argv(j));
1181                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1182                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1183                         newlist = strcat(newlist, " ", argv(j));
1184                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1185                 cvar_set("g_maplist", newlist);
1186                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1187
1188                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1189                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1190                 if(Map_Check(Map_Current, 1))
1191                         return Map_Current;
1192         }
1193         return -1;
1194 }
1195
1196 void Maplist_Init()
1197 {
1198         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1199         float i;
1200         for (i = 0; i < Map_Count; ++i)
1201                 if (Map_Check(i, 2))
1202                         break;
1203         if (i == Map_Count)
1204         {
1205                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1206                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1207                 if(autocvar_g_maplist_shuffle)
1208                         ShuffleMaplist();
1209                 localcmd("\nmenu_cmd sync\n");
1210                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1211         }
1212         if(Map_Count == 0)
1213                 error("empty maplist, cannot select a new map");
1214         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1215
1216         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1217         // this may or may not be correct, but who cares, in the worst case a map
1218         // isn't chosen in the first pass that should have been
1219 }
1220
1221 string GetNextMap()
1222 {
1223         float nextMap;
1224
1225         Maplist_Init();
1226         nextMap = -1;
1227
1228         if(nextMap == -1)
1229                 if(autocvar_g_maplist_shuffle > 0)
1230                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1231
1232         if(nextMap == -1)
1233                 if(autocvar_g_maplist_selectrandom)
1234                         nextMap = MaplistMethod_Random();
1235
1236         if(nextMap == -1)
1237                 nextMap = MaplistMethod_Iterate();
1238
1239         if(nextMap == -1)
1240                 nextMap = MaplistMethod_Repeat();
1241
1242         if(nextMap >= 0)
1243         {
1244                 Map_Goto_SetFloat(nextMap);
1245                 return getmapname_stored;
1246         }
1247
1248         return "";
1249 }
1250
1251 float DoNextMapOverride(float reinit)
1252 {
1253         if(autocvar_g_campaign)
1254         {
1255                 CampaignPostIntermission();
1256                 alreadychangedlevel = true;
1257                 return true;
1258         }
1259         if(autocvar_quit_when_empty)
1260         {
1261                 if(player_count <= currentbots)
1262                 {
1263                         localcmd("quit\n");
1264                         alreadychangedlevel = true;
1265                         return true;
1266                 }
1267         }
1268         if(autocvar_quit_and_redirect != "")
1269         {
1270                 redirection_target = strzone(autocvar_quit_and_redirect);
1271                 alreadychangedlevel = true;
1272                 return true;
1273         }
1274         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1275         {
1276                 localcmd("restart\n");
1277                 alreadychangedlevel = true;
1278                 return true;
1279         }
1280         if(autocvar_nextmap != "")
1281         {
1282                 string m;
1283                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1284                 cvar_set("nextmap",m);
1285
1286                 if(!m || gametypevote)
1287                         return false;
1288                 if(autocvar_sv_vote_gametype)
1289                 {
1290                         Map_Goto_SetStr(m);
1291                         return false;
1292                 }
1293
1294                 if(MapInfo_CheckMap(m))
1295                 {
1296                         Map_Goto_SetStr(m);
1297                         Map_Goto(reinit);
1298                         alreadychangedlevel = true;
1299                         return true;
1300                 }
1301         }
1302         if(!reinit && autocvar_lastlevel)
1303         {
1304                 cvar_settemp_restore();
1305                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1306                 alreadychangedlevel = true;
1307                 return true;
1308         }
1309         return false;
1310 }
1311
1312 void GotoNextMap(float reinit)
1313 {
1314         //string nextmap;
1315         //float n, nummaps;
1316         //string s;
1317         if (alreadychangedlevel)
1318                 return;
1319         alreadychangedlevel = true;
1320
1321         string nextMap;
1322
1323         nextMap = GetNextMap();
1324         if(nextMap == "")
1325                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1326         Map_Goto(reinit);
1327 }
1328
1329
1330 /*
1331 ============
1332 IntermissionThink
1333
1334 When the player presses attack or jump, change to the next level
1335 ============
1336 */
1337 .float autoscreenshot;
1338 void IntermissionThink(entity this)
1339 {
1340         FixIntermissionClient(this);
1341
1342         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1343         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1344
1345         if( (server_screenshot || client_screenshot)
1346                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1347         {
1348                 this.autoscreenshot = -1;
1349                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1350                 return;
1351         }
1352
1353         if (time < intermission_exittime)
1354                 return;
1355
1356         if(!mapvote_initialized)
1357                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1358                         return;
1359
1360         MapVote_Start();
1361 }
1362
1363 /*
1364 ============
1365 FindIntermission
1366
1367 Returns the entity to view from
1368 ============
1369 */
1370 /*
1371 entity FindIntermission()
1372 {
1373         local   entity spot;
1374         local   float cyc;
1375
1376 // look for info_intermission first
1377         spot = find(NULL, classname, "info_intermission");
1378         if (spot)
1379         {       // pick a random one
1380                 cyc = random() * 4;
1381                 while (cyc > 1)
1382                 {
1383                         spot = find(spot, classname, "info_intermission");
1384                         if (!spot)
1385                                 spot = find(spot, classname, "info_intermission");
1386                         cyc = cyc - 1;
1387                 }
1388                 return spot;
1389         }
1390
1391 // then look for the start position
1392         spot = find(NULL, classname, "info_player_start");
1393         if (spot)
1394                 return spot;
1395
1396 // testinfo_player_start is only found in regioned levels
1397         spot = find(NULL, classname, "testplayerstart");
1398         if (spot)
1399                 return spot;
1400
1401 // then look for the start position
1402         spot = find(NULL, classname, "info_player_deathmatch");
1403         if (spot)
1404                 return spot;
1405
1406         //objerror ("FindIntermission: no spot");
1407         return NULL;
1408 }
1409 */
1410
1411 /*
1412 ===============================================================================
1413
1414 RULES
1415
1416 ===============================================================================
1417 */
1418
1419 void DumpStats(float final)
1420 {
1421         float file;
1422         string s;
1423         float to_console;
1424         float to_eventlog;
1425         float to_file;
1426         float i;
1427
1428         to_console = autocvar_sv_logscores_console;
1429         to_eventlog = autocvar_sv_eventlog;
1430         to_file = autocvar_sv_logscores_file;
1431
1432         if(!final)
1433         {
1434                 to_console = true; // always print printstats replies
1435                 to_eventlog = false; // but never print them to the event log
1436         }
1437
1438         if(to_eventlog)
1439                 if(autocvar_sv_eventlog_console)
1440                         to_console = false; // otherwise we get the output twice
1441
1442         if(final)
1443                 s = ":scores:";
1444         else
1445                 s = ":status:";
1446         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1447
1448         if(to_console)
1449                 LOG_INFO(s);
1450         if(to_eventlog)
1451                 GameLogEcho(s);
1452
1453         file = -1;
1454         if(to_file)
1455         {
1456                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1457                 if(file == -1)
1458                         to_file = false;
1459                 else
1460                         fputs(file, strcat(s, "\n"));
1461         }
1462
1463         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1464         if(to_console)
1465                 LOG_INFO(s);
1466         if(to_eventlog)
1467                 GameLogEcho(s);
1468         if(to_file)
1469                 fputs(file, strcat(s, "\n"));
1470
1471         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1472                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1473                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1474                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1475                         s = strcat(s, ftos(it.team), ":");
1476                 else
1477                         s = strcat(s, "spectator:");
1478
1479                 if(to_console)
1480                         LOG_INFO(s, playername(it, false));
1481                 if(to_eventlog)
1482                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1483                 if(to_file)
1484                         fputs(file, strcat(s, playername(it, false), "\n"));
1485         });
1486
1487         if(teamplay)
1488         {
1489                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1490                 if(to_console)
1491                         LOG_INFO(s);
1492                 if(to_eventlog)
1493                         GameLogEcho(s);
1494                 if(to_file)
1495                         fputs(file, strcat(s, "\n"));
1496
1497                 for(i = 1; i < 16; ++i)
1498                 {
1499                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1500                         s = strcat(s, ":", ftos(i));
1501                         if(to_console)
1502                                 LOG_INFO(s);
1503                         if(to_eventlog)
1504                                 GameLogEcho(s);
1505                         if(to_file)
1506                                 fputs(file, strcat(s, "\n"));
1507                 }
1508         }
1509
1510         if(to_console)
1511                 LOG_INFO(":end");
1512         if(to_eventlog)
1513                 GameLogEcho(":end");
1514         if(to_file)
1515         {
1516                 fputs(file, ":end\n");
1517                 fclose(file);
1518         }
1519 }
1520
1521 void FixIntermissionClient(entity e)
1522 {
1523         if(!e.autoscreenshot) // initial call
1524         {
1525                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1526                 SetResource(e, RES_HEALTH, -2342);
1527                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1528                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1529                 {
1530                     .entity weaponentity = weaponentities[slot];
1531                         if(e.(weaponentity))
1532                         {
1533                                 e.(weaponentity).effects = EF_NODRAW;
1534                                 if (e.(weaponentity).weaponchild)
1535                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1536                         }
1537                 }
1538                 if(IS_REAL_CLIENT(e))
1539                 {
1540                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1541                         RandomSelection_Init();
1542                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1543                                 RandomSelection_AddString(it, 1, 1);
1544                         });
1545                         if (RandomSelection_chosen_string != "")
1546                         {
1547                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1548                         }
1549                         msg_entity = e;
1550                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1551                 }
1552         }
1553 }
1554
1555 /*
1556 go to the next level for deathmatch
1557 only called if a time or frag limit has expired
1558 */
1559 void NextLevel()
1560 {
1561         game_stopped = true;
1562         intermission_running = 1; // game over
1563
1564         // enforce a wait time before allowing changelevel
1565         if(player_count > 0)
1566                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1567         else
1568                 intermission_exittime = -1;
1569
1570         /*
1571         WriteByte (MSG_ALL, SVC_CDTRACK);
1572         WriteByte (MSG_ALL, 3);
1573         WriteByte (MSG_ALL, 3);
1574         // done in FixIntermission
1575         */
1576
1577         //pos = FindIntermission ();
1578
1579         VoteReset();
1580
1581         DumpStats(true);
1582
1583         // send statistics
1584         PlayerStats_GameReport(true);
1585         WeaponStats_Shutdown();
1586
1587         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1588
1589         if(autocvar_sv_eventlog)
1590                 GameLogEcho(":gameover");
1591
1592         GameLogClose();
1593
1594         FOREACH_CLIENT(IS_PLAYER(it), {
1595                 FixIntermissionClient(it);
1596                 if(it.winning)
1597                         bprint(playername(it, false), " ^7wins.\n");
1598         });
1599
1600         target_music_kill();
1601
1602         if(autocvar_g_campaign)
1603                 CampaignPreIntermission();
1604
1605         MUTATOR_CALLHOOK(MatchEnd);
1606
1607         localcmd("\nsv_hook_gameend\n");
1608 }
1609
1610
1611 float InitiateSuddenDeath()
1612 {
1613         // Check first whether normal overtimes could be added before initiating suddendeath mode
1614         // - for this timelimit_overtime needs to be >0 of course
1615         // - also check the winning condition calculated in the previous frame and only add normal overtime
1616         //   again, if at the point at which timelimit would be extended again, still no winner was found
1617         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1618                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1619                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1620         {
1621                 return 1; // need to call InitiateOvertime later
1622         }
1623         else
1624         {
1625                 if(!checkrules_suddendeathend)
1626                 {
1627                         if(autocvar_g_campaign)
1628                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1629                         else
1630                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1631                         if(g_race && !g_race_qualifying)
1632                                 race_StartCompleting();
1633                 }
1634                 return 0;
1635         }
1636 }
1637
1638 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1639 {
1640         ++checkrules_overtimesadded;
1641         //add one more overtime by simply extending the timelimit
1642         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1643         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1644 }
1645
1646 float GetWinningCode(float fraglimitreached, float equality)
1647 {
1648         if(autocvar_g_campaign == 1)
1649         {
1650                 if(fraglimitreached)
1651                         return WINNING_YES;
1652                 else
1653                         return WINNING_NO;
1654         }
1655         else
1656         {
1657                 if(equality)
1658                 {
1659                         if(fraglimitreached)
1660                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1661                         else
1662                                 return WINNING_NEVER;
1663                 }
1664                 else
1665                 {
1666                         if(fraglimitreached)
1667                                 return WINNING_YES;
1668                         else
1669                                 return WINNING_NO;
1670                 }
1671         }
1672 }
1673
1674 // set the .winning flag for exactly those players with a given field value
1675 void SetWinners(.float field, float value)
1676 {
1677         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1678 }
1679
1680 // set the .winning flag for those players with a given field value
1681 void AddWinners(.float field, float value)
1682 {
1683         FOREACH_CLIENT(IS_PLAYER(it), {
1684                 if(it.(field) == value)
1685                         it.winning = 1;
1686         });
1687 }
1688
1689 // clear the .winning flags
1690 void ClearWinners()
1691 {
1692         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1693 }
1694
1695 void ShuffleMaplist()
1696 {
1697         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1698 }
1699
1700 float leaderfrags;
1701 float WinningCondition_Scores(float limit, float leadlimit)
1702 {
1703         float limitreached;
1704
1705         // TODO make everything use THIS winning condition (except LMS)
1706         WinningConditionHelper(NULL);
1707
1708         if(teamplay)
1709         {
1710                 for (int i = 1; i < 5; ++i)
1711                 {
1712                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1713                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1714                 }
1715         }
1716
1717         ClearWinners();
1718         if(WinningConditionHelper_winner)
1719                 WinningConditionHelper_winner.winning = 1;
1720         if(WinningConditionHelper_winnerteam >= 0)
1721                 SetWinners(team, WinningConditionHelper_winnerteam);
1722
1723         if(WinningConditionHelper_lowerisbetter)
1724         {
1725                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1726                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1727                 limit = -limit;
1728         }
1729
1730         if(WinningConditionHelper_zeroisworst)
1731                 leadlimit = 0; // not supported in this mode
1732
1733         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1734         // these modes always score in increments of 1, thus this makes sense
1735         {
1736                 if(leaderfrags != WinningConditionHelper_topscore)
1737                 {
1738                         leaderfrags = WinningConditionHelper_topscore;
1739
1740                         if (limit)
1741                         {
1742                                 if (leaderfrags == limit - 1)
1743                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1744                                 else if (leaderfrags == limit - 2)
1745                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1746                                 else if (leaderfrags == limit - 3)
1747                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1748                         }
1749                 }
1750         }
1751
1752         limitreached = false;
1753         if (limit && WinningConditionHelper_topscore >= limit)
1754                 limitreached = true;
1755         if(leadlimit)
1756         {
1757                 float leadlimitreached;
1758                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1759                 if(autocvar_leadlimit_and_fraglimit)
1760                         limitreached = (limitreached && leadlimitreached);
1761                 else
1762                         limitreached = (limitreached || leadlimitreached);
1763         }
1764
1765         if(limit)
1766                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1767
1768         return GetWinningCode(
1769                 WinningConditionHelper_topscore && limitreached,
1770                 WinningConditionHelper_equality
1771         );
1772 }
1773
1774 float WinningCondition_RanOutOfSpawns()
1775 {
1776         if(have_team_spawns <= 0)
1777                 return WINNING_NO;
1778
1779         if(!autocvar_g_spawn_useallspawns)
1780                 return WINNING_NO;
1781
1782         if(!some_spawn_has_been_used)
1783                 return WINNING_NO;
1784
1785         for (int i = 1; i < 5; ++i)
1786         {
1787                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1788         }
1789
1790         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1791         {
1792                 if (Team_IsValidTeam(it.team))
1793                 {
1794                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1795                 }
1796         });
1797
1798         IL_EACH(g_spawnpoints, true,
1799         {
1800                 if (Team_IsValidTeam(it.team))
1801                 {
1802                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1803                 }
1804         });
1805
1806         ClearWinners();
1807         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1808         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1809         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1810         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1811         if(team1_score + team2_score + team3_score + team4_score == 0)
1812         {
1813                 checkrules_equality = true;
1814                 return WINNING_YES;
1815         }
1816         else if(team1_score + team2_score + team3_score + team4_score == 1)
1817         {
1818                 float t, i;
1819                 if(team1_score)
1820                         t = 1;
1821                 else if(team2_score)
1822                         t = 2;
1823                 else if(team3_score)
1824                         t = 3;
1825                 else // if(team4_score)
1826                         t = 4;
1827                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1828                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1829                 {
1830                         for (int j = 1; j <= NUM_TEAMS; ++j)
1831                         {
1832                                 if (t == j)
1833                                 {
1834                                         continue;
1835                                 }
1836                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1837                                 {
1838                                         continue;
1839                                 }
1840                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1841                         }
1842                 }
1843
1844                 AddWinners(team, t);
1845                 return WINNING_YES;
1846         }
1847         else
1848                 return WINNING_NO;
1849 }
1850
1851 /*
1852 ============
1853 CheckRules_World
1854
1855 Exit deathmatch games upon conditions
1856 ============
1857 */
1858 void CheckRules_World()
1859 {
1860         float timelimit;
1861         float fraglimit;
1862         float leadlimit;
1863
1864         VoteThink();
1865         MapVote_Think();
1866
1867         SetDefaultAlpha();
1868
1869         if (intermission_running) // someone else quit the game already
1870         {
1871                 if(player_count == 0) // Nobody there? Then let's go to the next map
1872                         MapVote_Start();
1873                         // this will actually check the player count in the next frame
1874                         // again, but this shouldn't hurt
1875                 return;
1876         }
1877
1878         timelimit = autocvar_timelimit * 60;
1879         fraglimit = autocvar_fraglimit;
1880         leadlimit = autocvar_leadlimit;
1881
1882         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1883         {
1884                 if(timelimit > 0)
1885                         timelimit = 0; // timelimit is not made for warmup
1886                 if(fraglimit > 0)
1887                         fraglimit = 0; // no fraglimit for now
1888                 leadlimit = 0; // no leadlimit for now
1889         }
1890
1891         if(timelimit > 0)
1892         {
1893                 timelimit += game_starttime;
1894         }
1895         else if (timelimit < 0)
1896         {
1897                 // endmatch
1898                 NextLevel();
1899                 return;
1900         }
1901
1902         float wantovertime;
1903         wantovertime = 0;
1904
1905         if(timelimit > game_starttime)
1906                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1907         else
1908                 game_completion_ratio = 0;
1909
1910         if(checkrules_suddendeathend)
1911         {
1912                 if(!checkrules_suddendeathwarning)
1913                 {
1914                         checkrules_suddendeathwarning = true;
1915                         if(g_race && !g_race_qualifying)
1916                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1917                         else
1918                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1919                 }
1920         }
1921         else
1922         {
1923                 if (timelimit && time >= timelimit)
1924                 {
1925                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1926                         {
1927                                 float totalplayers;
1928                                 float playerswithlaps;
1929                                 float readyplayers;
1930                                 totalplayers = playerswithlaps = readyplayers = 0;
1931                                 FOREACH_CLIENT(IS_PLAYER(it), {
1932                                         ++totalplayers;
1933                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1934                                                 ++playerswithlaps;
1935                                         if(it.ready)
1936                                                 ++readyplayers;
1937                                 });
1938
1939                                 // at least 2 of the players have completed a lap: start the RACE
1940                                 // otherwise, the players should end the qualifying on their own
1941                                 if(readyplayers || playerswithlaps >= 2)
1942                                 {
1943                                         checkrules_suddendeathend = 0;
1944                                         ReadyRestart(); // go to race
1945                                         return;
1946                                 }
1947                                 else
1948                                         wantovertime |= InitiateSuddenDeath();
1949                         }
1950                         else
1951                                 wantovertime |= InitiateSuddenDeath();
1952                 }
1953         }
1954
1955         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1956         {
1957                 NextLevel();
1958                 return;
1959         }
1960
1961         int checkrules_status = WinningCondition_RanOutOfSpawns();
1962         if(checkrules_status == WINNING_YES)
1963                 bprint("Hey! Someone ran out of spawns!\n");
1964         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1965                 checkrules_status = M_ARGV(0, float);
1966         else
1967                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1968
1969         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1970         {
1971                 checkrules_status = WINNING_NEVER;
1972                 checkrules_overtimesadded = -1;
1973                 wantovertime |= InitiateSuddenDeath();
1974         }
1975
1976         if(checkrules_status == WINNING_NEVER)
1977                 // equality cases! Nobody wins if the overtime ends in a draw.
1978                 ClearWinners();
1979
1980         if(wantovertime)
1981         {
1982                 if(checkrules_status == WINNING_NEVER)
1983                         InitiateOvertime();
1984                 else
1985                         checkrules_status = WINNING_YES;
1986         }
1987
1988         if(checkrules_suddendeathend)
1989                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1990                         checkrules_status = WINNING_YES;
1991
1992         if(checkrules_status == WINNING_YES)
1993         {
1994                 //print("WINNING\n");
1995                 NextLevel();
1996         }
1997 }
1998
1999 string GotoMap(string m)
2000 {
2001         m = GameTypeVote_MapInfo_FixName(m);
2002         if (!m)
2003                 return "The map you suggested is not available on this server.";
2004         if (!autocvar_sv_vote_gametype)
2005         if(!MapInfo_CheckMap(m))
2006                 return "The map you suggested does not support the current game mode.";
2007         cvar_set("nextmap", m);
2008         cvar_set("timelimit", "-1");
2009         if(mapvote_initialized || alreadychangedlevel)
2010         {
2011                 if(DoNextMapOverride(0))
2012                         return "Map switch initiated.";
2013                 else
2014                         return "Hm... no. For some reason I like THIS map more.";
2015         }
2016         else
2017                 return "Map switch will happen after scoreboard.";
2018 }
2019
2020 bool autocvar_sv_gameplayfix_multiplethinksperframe;
2021 void RunThink(entity this)
2022 {
2023         // don't let things stay in the past.
2024         // it is possible to start that way by a trigger with a local time.
2025         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2026                 return;
2027
2028         float oldtime = time; // do we need to save this?
2029
2030         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2031         {
2032                 time = max(oldtime, this.nextthink);
2033                 this.nextthink = 0;
2034
2035                 if(getthink(this))
2036                         getthink(this)(this);
2037                 // mods often set nextthink to time to cause a think every frame,
2038                 // we don't want to loop in that case, so exit if the new nextthink is
2039                 // <= the time the qc was told, also exit if it is past the end of the
2040                 // frame
2041                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2042                         break;
2043         }
2044
2045         time = oldtime;
2046 }
2047
2048 bool autocvar_sv_freezenonclients;
2049 bool autocvar_sv_gameplayfix_delayprojectiles;
2050 void Physics_Frame()
2051 {
2052         if(autocvar_sv_freezenonclients)
2053                 return;
2054
2055         FOREACH_ENTITY_FLOAT(pure_data, false,
2056         {
2057                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2058                         continue;
2059
2060                 //set_movetype(it, it.move_movetype);
2061                 // inline the set_movetype function, since this is called a lot
2062                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2063
2064                 if(it.move_movetype == MOVETYPE_NONE)
2065                         continue;
2066
2067                 if(it.move_qcphysics)
2068                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2069
2070                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2071                 {
2072                         // handle thinking here
2073                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2074                                 RunThink(it);
2075                 }
2076         });
2077
2078         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2079                 return;
2080
2081         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2082         {
2083                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2084                         continue;
2085                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2086         });
2087 }
2088
2089 void systems_update();
2090 void EndFrame()
2091 {
2092         anticheat_endframe();
2093
2094         Physics_Frame();
2095
2096         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2097                 entity e = IS_SPEC(it) ? it.enemy : it;
2098                 if (e.typehitsound) {
2099                         STAT(TYPEHIT_TIME, it) = time;
2100                 } else if (e.killsound) {
2101                         STAT(KILL_TIME, it) = time;
2102                 } else if (e.damage_dealt) {
2103                         STAT(HIT_TIME, it) = time;
2104                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2105                 }
2106         });
2107         // add 1 frametime because after this, engine SV_Physics
2108         // increases time by a frametime and then networks the frame
2109         // add another frametime because client shows everything with
2110         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2111         // needed!
2112         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2113         FOREACH_CLIENT(true, {
2114                 it.typehitsound = false;
2115                 it.damage_dealt = 0;
2116                 it.killsound = false;
2117                 antilag_record(it, CS(it), altime);
2118         });
2119         IL_EACH(g_monsters, true,
2120         {
2121                 antilag_record(it, it, altime);
2122         });
2123         IL_EACH(g_projectiles, it.classname == "nade",
2124         {
2125                 antilag_record(it, it, altime);
2126         });
2127         systems_update();
2128         IL_ENDFRAME();
2129 }
2130
2131
2132 /*
2133  * RedirectionThink:
2134  * returns true if redirecting
2135  */
2136 float redirection_timeout;
2137 float redirection_nextthink;
2138 float RedirectionThink()
2139 {
2140         float clients_found;
2141
2142         if(redirection_target == "")
2143                 return false;
2144
2145         if(!redirection_timeout)
2146         {
2147                 cvar_set("sv_public", "-2");
2148                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2149                 if(redirection_target == "self")
2150                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2151                 else
2152                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2153         }
2154
2155         if(time < redirection_nextthink)
2156                 return true;
2157
2158         redirection_nextthink = time + 1;
2159
2160         clients_found = 0;
2161         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2162                 // TODO add timer
2163                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2164                 if(redirection_target == "self")
2165                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2166                 else
2167                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2168                 ++clients_found;
2169         });
2170
2171         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2172
2173         if(time > redirection_timeout || clients_found == 0)
2174                 localcmd("\nwait; wait; wait; quit\n");
2175
2176         return true;
2177 }
2178
2179 void RestoreGame()
2180 {
2181         // Loaded from a save game
2182         // some things then break, so let's work around them...
2183
2184         // Progs DB (capture records)
2185         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2186
2187         // Mapinfo
2188         MapInfo_Shutdown();
2189         MapInfo_Enumerate();
2190         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2191         WeaponStats_Init();
2192
2193         TargetMusic_RestoreGame();
2194 }
2195
2196 void Shutdown()
2197 {
2198         game_stopped = 2;
2199
2200         if(world_initialized > 0)
2201         {
2202                 world_initialized = 0;
2203                 LOG_TRACE("Saving persistent data...");
2204                 Ban_SaveBans();
2205
2206                 // playerstats with unfinished match
2207                 PlayerStats_GameReport(false);
2208
2209                 if(!cheatcount_total)
2210                 {
2211                         if(autocvar_sv_db_saveasdump)
2212                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2213                         else
2214                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2215                 }
2216                 if(autocvar_developer)
2217                 {
2218                         if(autocvar_sv_db_saveasdump)
2219                                 db_dump(TemporaryDB, "server-temp.db");
2220                         else
2221                                 db_save(TemporaryDB, "server-temp.db");
2222                 }
2223                 CheatShutdown(); // must be after cheatcount check
2224                 db_close(ServerProgsDB);
2225                 db_close(TemporaryDB);
2226                 LOG_TRACE("Saving persistent data... done!");
2227                 // tell the bot system the game is ending now
2228                 bot_endgame();
2229
2230                 WeaponStats_Shutdown();
2231                 MapInfo_Shutdown();
2232         }
2233         else if(world_initialized == 0)
2234         {
2235                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2236         }
2237         else
2238         {
2239                 __init_dedicated_server_shutdown();
2240         }
2241 }