qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("serverconfig");
 276                 BADPREFIX("g_ban_");
 277                 BADPREFIX("g_chat_flood_");
 278                 BADPREFIX("g_voice_flood_");
 279                 BADPREFIX("rcon_");
 280                 BADPREFIX("settemp_");
 281                 BADPREFIX("sv_allowdownloads_");
 282                 BADPREFIX("sv_autodemo");
 283                 BADPREFIX("sv_curl_");
 284                 BADPREFIX("sv_eventlog");
 285                 BADPREFIX("sv_logscores_");
 286                 BADPREFIX("sv_master");
 287                 BADCVAR("g_banned_list");
 288                 BADCVAR("log_dest_udp");
 289                 BADCVAR("log_file");
 290                 BADCVAR("net_address");
 291                 BADCVAR("port");
 292                 BADCVAR("savedgamecfg");
 293                 BADCVAR("sv_heartbeatperiod");
 294                 BADCVAR("sv_vote_master_password");
 295                 BADCVAR("sys_colortranslation");
 296                 BADCVAR("sys_specialcharactertranslation");
 297                 BADCVAR("timestamps");
 298                 BADCVAR("net_address");
 299                 BADCVAR("net_address_ipv6");
 300                 BADPREFIX("sv_weaponstats_");
 301                 BADCVAR("developer");
 302                 BADPREFIX("developer_");
 303
 304                 // mapinfo
 305                 BADCVAR("timelimit");
 306                 BADCVAR("fraglimit");
 307                 BADCVAR("leadlimit");
 308                 BADCVAR("g_tdm_teams");
 309                 BADCVAR("g_keyhunt_teams");
 310                 BADCVAR("g_domination_default_teams");
 311                 BADCVAR("g_race_qualifying_timelimit");
 312                 BADCVAR("g_lms");
 313                 BADCVAR("g_arena");
 314                 BADCVAR("g_ca");
 315                 BADCVAR("g_assault");
 316                 BADCVAR("g_ctf");
 317                 BADCVAR("g_dm");
 318                 BADCVAR("g_domination");
 319                 BADCVAR("g_keyhunt");
 320                 BADCVAR("g_keyhunt_teams");
 321                 BADCVAR("g_onslaught");
 322                 BADCVAR("g_race");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_runematch");
 325                 BADCVAR("g_tdm");
 326                 BADCVAR("g_nexball");
 327                 BADCVAR("teamplay");
 328
 329                 // long
 330                 BADCVAR("hostname");
 331                 BADCVAR("g_maplist");
 332                 BADCVAR("g_maplist_mostrecent");
 333                 BADCVAR("sv_motd");
 334
 335                 v = cvar_string(k);
 336                 d = cvar_defstring(k);
 337                 if(v == d)
 338                         continue;
 339
 340                 if(adding)
 341                 {
 342                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 343                         if(strlen(cvar_changes) > 16384)
 344                         {
 345                                 cvar_changes = "// too many settings have been changed to show them here\n";
 346                                 adding = 0;
 347                         }
 348                 }
 349
 350                 // now check if the changes are actually gameplay relevant
 351
 352                 // does nothing visible
 353                 BADCVAR("captureleadlimit_override");
 354                 BADCVAR("g_arena_point_leadlimit");
 355                 BADCVAR("g_ca_point_leadlimit");
 356                 BADCVAR("g_ctf_capture_leadlimit");
 357                 BADCVAR("g_domination_point_leadlimit");
 358                 BADCVAR("g_keyhunt_point_leadlimit");
 359                 BADCVAR("g_nexball_goalleadlimit");
 360                 BADCVAR("g_runematch_point_leadlimit");
 361                 BADCVAR("leadlimit_and_fraglimit");
 362                 BADCVAR("leadlimit_override");
 363                 BADCVAR("sv_checkforpacketsduringsleep");
 364                 BADPREFIX("crypto_");
 365                 BADPREFIX("g_chat_");
 366                 BADPREFIX("prvm_");
 367                 BADPREFIX("sv_fragmessage_");
 368                 BADPREFIX("sv_vote_");
 369                 BADPREFIX("timelimit_");
 370
 371                 // allowed changes to server admins (please sync this to server.cfg)
 372                 // vi commands:
 373                 //   :/"impure"/,$d
 374                 //   :g!,^\/\/[^ /],d
 375                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 376                 //   :%!sort
 377                 // yes, this does contain some redundant stuff, don't really care
 378                 BADCVAR("bot_number");
 379                 BADCVAR("bot_prefix");
 380                 BADCVAR("bot_suffix");
 381                 BADCVAR("capturelimit_override");
 382                 BADCVAR("fraglimit_override");
 383                 BADCVAR("gametype");
 384                 BADCVAR("g_antilag");
 385                 BADCVAR("g_balance_teams");
 386                 BADCVAR("g_balance_teams_force");
 387                 BADCVAR("g_ban_sync_trusted_servers");
 388                 BADCVAR("g_ban_sync_uri");
 389                 BADCVAR("g_ctf_capture_limit");
 390                 BADCVAR("g_ctf_ignore_frags");
 391                 BADCVAR("g_ctf_win_mode");
 392                 BADCVAR("g_domination_point_limit");
 393                 BADCVAR("g_fullbrightitems");
 394                 BADCVAR("g_fullbrightplayers");
 395                 BADCVAR("g_keyhunt_point_limit");
 396                 BADCVAR("g_keyhunt_teams_override");
 397                 BADCVAR("g_lms_lives_override");
 398                 BADCVAR("g_maplist");
 399                 BADCVAR("g_maplist_check_waypoints");
 400                 BADCVAR("g_maplist_mostrecent_count");
 401                 BADCVAR("g_maplist_shuffle");
 402                 BADCVAR("g_maplist_votable");
 403                 BADCVAR("g_maplist_votable_abstain");
 404                 BADCVAR("g_maplist_votable_nodetail");
 405                 BADCVAR("g_maplist_votable_suggestions");
 406                 BADCVAR("g_minstagib");
 407                 BADCVAR("g_nexball_goallimit");
 408                 BADCVAR("g_runematch_point_limit");
 409                 BADCVAR("g_start_delay");
 410                 BADCVAR("hostname");
 411                 BADCVAR("log_file");
 412                 BADCVAR("maxplayers");
 413                 BADCVAR("minplayers");
 414                 BADCVAR("net_address");
 415                 BADCVAR("port");
 416                 BADCVAR("rcon_password");
 417                 BADCVAR("rcon_restricted_commands");
 418                 BADCVAR("rcon_restricted_password");
 419                 BADCVAR("skill");
 420                 BADCVAR("sv_adminnick");
 421                 BADCVAR("sv_autoscreenshot");
 422                 BADCVAR("sv_curl_defaulturl");
 423                 BADCVAR("sv_defaultcharacter");
 424                 BADCVAR("sv_defaultplayermodel");
 425                 BADCVAR("sv_defaultplayerskin");
 426                 BADCVAR("sv_maxidle");
 427                 BADCVAR("sv_maxrate");
 428                 BADCVAR("sv_motd");
 429                 BADCVAR("sv_public");
 430                 BADCVAR("sv_ready_restart");
 431                 BADCVAR("sv_status_privacy");
 432                 BADCVAR("sv_vote_call");
 433                 BADCVAR("sv_vote_commands");
 434                 BADCVAR("sv_vote_majority_factor");
 435                 BADCVAR("sv_vote_master");
 436                 BADCVAR("sv_vote_master_commands");
 437                 BADCVAR("sv_vote_master_password");
 438                 BADCVAR("sv_vote_simple_majority_factor");
 439                 BADCVAR("timelimit_override");
 440 #undef BADPREFIX
 441 #undef BADCVAR
 442
 443                 if(pureadding)
 444                 {
 445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 446                         if(strlen(cvar_purechanges) > 16384)
 447                         {
 448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 449                                 pureadding = 0;
 450                         }
 451                 }
 452                 ++cvar_purechanges_count;
 453                 // WARNING: this variable is used for the server list
 454                 // NEVER dare to skip this code!
 455                 // Hacks to intentionally appearing as "pure server" even though you DO have
 456                 // modified settings may be punished by removal from the server list.
 457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 458                 // though.
 459         }
 460         buf_del(h);
 461         if(cvar_changes == "")
 462                 cvar_changes = "// this server runs at default server settings\n";
 463         else
 464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 465         cvar_changes = strzone(cvar_changes);
 466         if(cvar_purechanges == "")
 467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 468         else
 469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 470         cvar_purechanges = strzone(cvar_purechanges);
 471 }
 472
 473 void detect_maptype()
 474 {
 475 #if 0
 476         vector o, v;
 477         float i;
 478
 479         for(;;)
 480         {
 481                 o = world.mins;
 482                 o_x += random() * (world.maxs_x - world.mins_x);
 483                 o_y += random() * (world.maxs_y - world.mins_y);
 484                 o_z += random() * (world.maxs_z - world.mins_z);
 485
 486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 487                 if(trace_fraction == 1)
 488                         continue;
 489
 490                 v = trace_endpos;
 491
 492                 for(i = 0; i < 64; i += 4)
 493                 {
 494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 495         if(trace_fraction == 1)
 496                 continue;
 497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 498                 }
 499
 500                 break;
 501         }
 502 #endif
 503 }
 504
 505 entity randomseed;
 506 float RandomSeed_Send(entity to, float sf)
 507 {
 508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 509         WriteShort(MSG_ENTITY, self.cnt);
 510         return TRUE;
 511 }
 512 void RandomSeed_Think()
 513 {
 514         self.cnt = bound(0, floor(random() * 65536), 65535);
 515         self.nextthink = time + 5;
 516
 517         self.SendFlags |= 1;
 518 }
 519 void RandomSeed_Spawn()
 520 {
 521         randomseed = spawn();
 522         randomseed.think = RandomSeed_Think;
 523         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 524
 525         entity oldself;
 526         oldself = self;
 527         self = randomseed;
 528         self.think(); // sets random seed and nextthink
 529         self = oldself;
 530 }
 531
 532 void spawnfunc___init_dedicated_server(void)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e;
 544         e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = spawn();
 549         e.classname = "info_player_deathmatch"; // safeguard against player joining
 550
 551         self.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         MapInfo_Enumerate();
 554         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 555 }
 556
 557 void Map_MarkAsRecent(string m);
 558 float world_already_spawned;
 559 void RegisterWeapons();
 560 void Nagger_Init();
 561 void ClientInit_Spawn();
 562 void WeaponStats_Init();
 563 void WeaponStats_Shutdown();
 564 void spawnfunc_worldspawn (void)
 565 {
 566         float fd, l, i, j, n;
 567         string s, col;
 568
 569         cvar = cvar_normal;
 570         cvar_string = cvar_string_normal;
 571         cvar_set = cvar_set_normal;
 572
 573         if(world_already_spawned)
 574                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 575         world_already_spawned = TRUE;
 576
 577         remove = remove_safely; // during spawning, watch what you remove!
 578
 579         check_unacceptable_compiler_bugs();
 580
 581         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 582
 583         compressShortVector_init();
 584
 585         allowed_to_spawn = TRUE;
 586
 587         local entity head;
 588         head = nextent(world);
 589         maxclients = 0;
 590         while(head)
 591         {
 592                 ++maxclients;
 593                 head = nextent(head);
 594         }
 595
 596         // needs to be done so early as they would still spawn
 597         RegisterWeapons();
 598
 599         ServerProgsDB = db_load("server.db");
 600
 601         TemporaryDB = db_create();
 602
 603         /*
 604         TODO sound pack system
 605         // initialize sound pack system
 606         soundpack = cvar_string("g_soundpack");
 607         if(soundpack != "")
 608                 soundpack = strcat(soundpack, "/");
 609         soundpack = strzone(soundpack);
 610         */
 611
 612         // 0 normal
 613         lightstyle(0, "m");
 614
 615         // 1 FLICKER (first variety)
 616         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 617
 618         // 2 SLOW STRONG PULSE
 619         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 620
 621         // 3 CANDLE (first variety)
 622         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 623
 624         // 4 FAST STROBE
 625         lightstyle(4, "mamamamamama");
 626
 627         // 5 GENTLE PULSE 1
 628         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 629
 630         // 6 FLICKER (second variety)
 631         lightstyle(6, "nmonqnmomnmomomno");
 632
 633         // 7 CANDLE (second variety)
 634         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 635
 636         // 8 CANDLE (third variety)
 637         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 638
 639         // 9 SLOW STROBE (fourth variety)
 640         lightstyle(9, "aaaaaaaazzzzzzzz");
 641
 642         // 10 FLUORESCENT FLICKER
 643         lightstyle(10, "mmamammmmammamamaaamammma");
 644
 645         // 11 SLOW PULSE NOT FADE TO BLACK
 646         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 647
 648         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 649
 650         // 63 testing
 651         lightstyle(63, "a");
 652
 653         if(cvar("g_campaign"))
 654                 CampaignPreInit();
 655
 656         Map_MarkAsRecent(mapname);
 657
 658         precache_model ("null"); // we need this one before InitGameplayMode
 659         InitGameplayMode();
 660         readlevelcvars();
 661         GrappleHookInit();
 662         ElectroInit();
 663         LaserInit();
 664
 665         player_count = 0;
 666         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 667         if(bot_waypoints_for_items == 1)
 668                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 669                         bot_waypoints_for_items = 0;
 670
 671         // for setting by mapinfo
 672         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 673         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 674
 675         precache();
 676
 677         WaypointSprite_Init();
 678
 679         //if (g_domination)
 680         //      dom_init();
 681
 682         GameLogInit(); // prepare everything
 683         if(cvar("sv_eventlog"))
 684         {
 685                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 686                 s = strcat(s, ftos(random()));
 687                 matchid = strzone(s);
 688
 689                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 690                 s = ":gameinfo:mutators:LIST";
 691
 692                 ret_string = s;
 693                 MUTATOR_CALLHOOK(BuildMutatorsString);
 694                 s = ret_string;
 695
 696                 // simple, probably not good in the mutator system
 697                 if(cvar("g_grappling_hook"))
 698                         s = strcat(s, ":grappling_hook");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(!cvar("g_use_ammunition"))
 702                         s = strcat(s, ":no_use_ammunition");
 703
 704                 // initialiation stuff, not good in the mutator system
 705                 if(!cvar("g_pickup_items"))
 706                         s = strcat(s, ":no_pickup_items");
 707
 708                 // initialiation stuff, not good in the mutator system
 709                 if(cvar_string("g_weaponarena") != "0")
 710                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 711
 712                 // TODO to mutator system
 713                 if(cvar("g_norecoil"))
 714                         s = strcat(s, ":norecoil");
 715
 716                 // TODO to mutator system
 717                 if(cvar("g_midair"))
 718                         s = strcat(s, ":midair");
 719
 720                 // TODO to mutator system
 721                 if(cvar("g_minstagib"))
 722                         s = strcat(s, ":minstagib");
 723
 724                 GameLogEcho(s);
 725                 GameLogEcho(":gameinfo:end");
 726         }
 727         else
 728                 matchid = strzone(ftos(random()));
 729
 730         cvar_set("nextmap", "");
 731
 732         SetDefaultAlpha();
 733
 734         if(cvar("g_campaign"))
 735                 CampaignPostInit();
 736
 737         fteqcc_testbugs();
 738
 739         Ban_LoadBans();
 740
 741         MapInfo_Enumerate();
 742         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 743
 744         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 745         {
 746                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 747                 if(fd != -1)
 748                 {
 749                         while((s = fgets(fd)))
 750                         {
 751                                 l = tokenize_console(s);
 752                                 if(l < 2)
 753                                         continue;
 754                                 if(argv(0) == "cd")
 755                                 {
 756                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 757                                         print("  cdtrack ", argv(2), "\n");
 758                                 }
 759                                 else if(argv(0) == "fog")
 760                                 {
 761                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 762                                         print("  \"fog\" \"", s, "\"\n");
 763                                 }
 764                                 else if(argv(0) == "set")
 765                                 {
 766                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 767                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 768                                 }
 769                                 else if(argv(0) != "//")
 770                                 {
 771                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 772                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 773                                 }
 774                         }
 775                         fclose(fd);
 776                 }
 777         }
 778
 779         WeaponStats_Init();
 780
 781         addstat(STAT_WEAPONS, AS_INT, weapons);
 782         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 783         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 784         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 785         Nagger_Init();
 786
 787         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 788         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 789         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 790         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 791         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 792         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 793         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 794         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 795         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 796         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 797
 798         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 799
 800         if(g_ca)
 801         {
 802                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 803                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 804         }
 805         // g_movementspeed hack
 806         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 807         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 808         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 809
 810         next_pingtime = time + 5;
 811
 812         detect_maptype();
 813
 814         lsmaps_reply = "^7Maps available: ";
 815         lsnewmaps_reply = "^7Maps without a record set: ";
 816         for(i = 0, j = 0; i < MapInfo_count; ++i)
 817         {
 818                 if(MapInfo_Get_ByID(i))
 819                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 820                         {
 821                                 if(mod(i, 2))
 822                                         col = "^2";
 823                                 else
 824                                         col = "^3";
 825                                 ++j;
 826                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 827                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 828                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 829                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 830                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 831                         }
 832         }
 833         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 834         if (!g_race && !g_cts)
 835                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 836         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 837
 838         maplist_reply = "^7Maps in list: ";
 839         n = tokenize_console(cvar_string("g_maplist"));
 840         for(i = 0, j = 0; i < n; ++i)
 841         {
 842                 if(MapInfo_CheckMap(argv(i)))
 843                 {
 844                         if(mod(j, 2))
 845                                 col = "^2";
 846                         else
 847                                 col = "^3";
 848                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 849                         ++j;
 850                 }
 851         }
 852         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 853         MapInfo_ClearTemps();
 854
 855         for(i = 0; i < 10; ++i)
 856         {
 857                 records_reply[i] = strzone(getrecords(i));
 858         }
 859         if(g_cts)
 860                 ladder_reply = strzone(getladder());
 861
 862         rankings_reply = strzone(getrankings());
 863
 864         ClientInit_Spawn();
 865         RandomSeed_Spawn();
 866         PingPLReport_Spawn();
 867
 868         CheatInit();
 869
 870         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 871
 872         // fill sv_curl_serverpackages from .serverpackage files
 873         if(cvar("sv_curl_serverpackages_auto"))
 874         {
 875                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 876                 s = "";
 877                 if(fd >= 0)
 878                 {
 879                         j = search_getsize(fd);
 880                         for(i = 0; i < j; ++i)
 881                                 s = strcat(s, " ", search_getfilename(fd, i));
 882                         search_end(fd);
 883                 }
 884                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 885         }
 886
 887         world_initialized = 1;
 888 }
 889
 890 void spawnfunc_light (void)
 891 {
 892         //makestatic (self); // Who the f___ did that?
 893         remove(self);
 894 }
 895
 896 float TryFile( string pFilename )
 897 {
 898         local float lHandle;
 899         dprint("TryFile(\"", pFilename, "\")\n");
 900         lHandle = fopen( pFilename, FILE_READ );
 901         if( lHandle != -1 ) {
 902                 fclose( lHandle );
 903                 return TRUE;
 904         } else {
 905                 return FALSE;
 906         }
 907 };
 908
 909 string GetGametype()
 910 {
 911         return GametypeNameFromType(game);
 912 }
 913
 914 string getmapname_stored;
 915 string GetMapname()
 916 {
 917         return mapname;
 918 }
 919
 920 float Map_Count, Map_Current;
 921 string Map_Current_Name;
 922
 923 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 924 float GetMaplistPosition()
 925 {
 926         float pos, idx;
 927         string map;
 928
 929         map = GetMapname();
 930         idx = cvar("g_maplist_index");
 931
 932         if(idx >= 0)
 933                 if(idx < Map_Count)
 934                         if(map == argv(idx))
 935                                 return idx;
 936
 937         for(pos = 0; pos < Map_Count; ++pos)
 938                 if(map == argv(pos))
 939                         return pos;
 940
 941         // resume normal maplist rotation if current map is not in g_maplist
 942         return idx;
 943 }
 944
 945 float MapHasRightSize(string map)
 946 {
 947         float fh;
 948         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 949         if(cvar("g_maplist_check_waypoints"))
 950         {
 951                 dprint("checkwp "); dprint(map);
 952                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 953                 if(fh < 0)
 954                 {
 955                         dprint(": no waypoints\n");
 956                         return FALSE;
 957                 }
 958                 dprint(": has waypoints\n");
 959                 fclose(fh);
 960         }
 961
 962         // open map size restriction file
 963         dprint("opensize "); dprint(map);
 964         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 965         if(fh >= 0)
 966         {
 967                 float mapmin, mapmax;
 968                 dprint(": ok, ");
 969                 mapmin = stof(fgets(fh));
 970                 mapmax = stof(fgets(fh));
 971                 fclose(fh);
 972                 if(player_count < mapmin)
 973                 {
 974                         dprint("not enough\n");
 975                         return FALSE;
 976                 }
 977                 if(player_count > mapmax)
 978                 {
 979                         dprint("too many\n");
 980                         return FALSE;
 981                 }
 982                 dprint("right size\n");
 983                 return TRUE;
 984         }
 985         dprint(": not found\n");
 986         return TRUE;
 987 }
 988
 989 string Map_Filename(float position)
 990 {
 991         return strcat("maps/", argv(position), ".bsp");
 992 }
 993
 994 string strwords(string s, float w)
 995 {
 996         float endpos;
 997         for(endpos = 0; w && endpos >= 0; --w)
 998                 endpos = strstrofs(s, " ", endpos + 1);
 999         if(endpos < 0)
1000                 return s;
1001         else
1002                 return substring(s, 0, endpos);
1003 }
1004
1005 float strhasword(string s, string w)
1006 {
1007         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1008 }
1009
1010 void Map_MarkAsRecent(string m)
1011 {
1012         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
1013 }
1014
1015 float Map_IsRecent(string m)
1016 {
1017         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1018 }
1019
1020 float Map_Check(float position, float pass)
1021 {
1022         string filename;
1023         string map_next;
1024         map_next = argv(position);
1025         if(pass <= 1)
1026         {
1027                 if(Map_IsRecent(map_next))
1028                         return 0;
1029         }
1030         filename = Map_Filename(position);
1031         if(MapInfo_CheckMap(map_next))
1032         {
1033                 if(pass == 2)
1034                         return 1;
1035                 if(MapHasRightSize(map_next))
1036                         return 1;
1037                 return 0;
1038         }
1039         else
1040                 dprint( "Couldn't select '", filename, "'..\n" );
1041
1042         return 0;
1043 }
1044
1045 void Map_Goto_SetStr(string nextmapname)
1046 {
1047         if(getmapname_stored != "")
1048                 strunzone(getmapname_stored);
1049         if(nextmapname == "")
1050                 getmapname_stored = "";
1051         else
1052                 getmapname_stored = strzone(nextmapname);
1053 }
1054
1055 void Map_Goto_SetFloat(float position)
1056 {
1057         cvar_set("g_maplist_index", ftos(position));
1058         Map_Goto_SetStr(argv(position));
1059 }
1060
1061 void GameResetCfg()
1062 {
1063         // settings persist, except...
1064         localcmd("\nsettemp_restore\n");
1065 };
1066
1067 void Map_Goto()
1068 {
1069         GameResetCfg();
1070         MapInfo_LoadMap(getmapname_stored);
1071 }
1072
1073 // return codes of map selectors:
1074 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1075 //   -2 = permanent failure
1076 float() MaplistMethod_Iterate = // usual method
1077 {
1078         float pass, i;
1079
1080         for(pass = 1; pass <= 2; ++pass)
1081         {
1082                 for(i = 1; i < Map_Count; ++i)
1083                 {
1084                         float mapindex;
1085                         mapindex = mod(i + Map_Current, Map_Count);
1086                         if(Map_Check(mapindex, pass))
1087                                 return mapindex;
1088                 }
1089         }
1090         return -1;
1091 }
1092
1093 float() MaplistMethod_Repeat = // fallback method
1094 {
1095         if(Map_Check(Map_Current, 2))
1096                 return Map_Current;
1097         return -2;
1098 }
1099
1100 float() MaplistMethod_Random = // random map selection
1101 {
1102         float i, imax;
1103
1104         imax = 42;
1105
1106         for(i = 0; i <= imax; ++i)
1107         {
1108                 float mapindex;
1109                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1110                 if(Map_Check(mapindex, 1))
1111                         return mapindex;
1112         }
1113         return -1;
1114 }
1115
1116 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1117 // the exponent sets a bias on the map selection:
1118 // the higher the exponent, the less likely "shortly repeated" same maps are
1119 {
1120         float i, j, imax, insertpos;
1121
1122         imax = 42;
1123
1124         for(i = 0; i <= imax; ++i)
1125         {
1126                 string newlist;
1127
1128                 // now reinsert this at another position
1129                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1130                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1131                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1132                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1133
1134                 // insert the current map there
1135                 newlist = "";
1136                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1137                         newlist = strcat(newlist, " ", argv(j));
1138                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1139                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1140                         newlist = strcat(newlist, " ", argv(j));
1141                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1142                 cvar_set("g_maplist", newlist);
1143                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1144
1145                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1146                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1147                 if(Map_Check(Map_Current, 1))
1148                         return Map_Current;
1149         }
1150         return -1;
1151 }
1152
1153 void Maplist_Init()
1154 {
1155         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1156         if(Map_Count == 0)
1157         {
1158                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1159                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1160                 if(cvar("g_maplist_shuffle"))
1161                         ShuffleMaplist();
1162                 localcmd("\nmenu_cmd sync\n");
1163                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1164         }
1165         if(Map_Count == 0)
1166                 error("empty maplist, cannot select a new map");
1167         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1168
1169         if(Map_Current_Name)
1170                 strunzone(Map_Current_Name);
1171         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1172         // this may or may not be correct, but who cares, in the worst case a map
1173         // isn't chosen in the first pass that should have been
1174 }
1175
1176 string GetNextMap()
1177 {
1178         float nextMap;
1179
1180         Maplist_Init();
1181         nextMap = -1;
1182
1183         if(nextMap == -1)
1184                 if(cvar("g_maplist_shuffle") > 0)
1185                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1186
1187         if(nextMap == -1)
1188                 if(cvar("g_maplist_selectrandom"))
1189                         nextMap = MaplistMethod_Random();
1190
1191         if(nextMap == -1)
1192                 nextMap = MaplistMethod_Iterate();
1193
1194         if(nextMap == -1)
1195                 nextMap = MaplistMethod_Repeat();
1196
1197         if(nextMap >= 0)
1198         {
1199                 Map_Goto_SetFloat(nextMap);
1200                 return getmapname_stored;
1201         }
1202
1203         return "";
1204 };
1205
1206 float DoNextMapOverride()
1207 {
1208         if(cvar("g_campaign"))
1209         {
1210                 CampaignPostIntermission();
1211                 alreadychangedlevel = TRUE;
1212                 return TRUE;
1213         }
1214         if(cvar("quit_when_empty"))
1215         {
1216                 if(player_count <= currentbots)
1217                 {
1218                         localcmd("quit\n");
1219                         alreadychangedlevel = TRUE;
1220                         return TRUE;
1221                 }
1222         }
1223         if(cvar_string("quit_and_redirect") != "")
1224         {
1225                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1226                 alreadychangedlevel = TRUE;
1227                 return TRUE;
1228         }
1229         if (cvar("samelevel")) // if samelevel is set, stay on same level
1230         {
1231                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1232                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1233                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1234                 localcmd("restart\n");
1235                 //changelevel (mapname);
1236                 alreadychangedlevel = TRUE;
1237                 return TRUE;
1238         }
1239         if(cvar_string("nextmap") != "")
1240                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1241                 {
1242                         Map_Goto_SetStr(cvar_string("nextmap"));
1243                         Map_Goto();
1244                         alreadychangedlevel = TRUE;
1245                         return TRUE;
1246                 }
1247         if(cvar("lastlevel"))
1248         {
1249                 GameResetCfg();
1250                 localcmd("set lastlevel 0\ntogglemenu\n");
1251                 alreadychangedlevel = TRUE;
1252                 return TRUE;
1253         }
1254         return FALSE;
1255 };
1256
1257 void GotoNextMap()
1258 {
1259         //local string nextmap;
1260         //local float n, nummaps;
1261         //local string s;
1262         if (alreadychangedlevel)
1263                 return;
1264         alreadychangedlevel = TRUE;
1265
1266         {
1267                 string nextMap;
1268                 float allowReset;
1269
1270                 for(allowReset = 1; allowReset >= 0; --allowReset)
1271                 {
1272                         nextMap = GetNextMap();
1273                         if(nextMap != "")
1274                                 break;
1275
1276                         if(allowReset)
1277                         {
1278                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1279                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1280                                 if(cvar("g_maplist_shuffle"))
1281                                         ShuffleMaplist();
1282                                 localcmd("\nmenu_cmd sync\n");
1283                         }
1284                         else
1285                         {
1286                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1287                         }
1288                 }
1289                 Map_Goto();
1290         }
1291 };
1292
1293
1294 /*
1295 ============
1296 IntermissionThink
1297
1298 When the player presses attack or jump, change to the next level
1299 ============
1300 */
1301 .float autoscreenshot;
1302 void() MapVote_Start;
1303 void() MapVote_Think;
1304 float mapvote_initialized;
1305 void IntermissionThink()
1306 {
1307         FixIntermissionClient(self);
1308
1309         if(cvar("sv_autoscreenshot"))
1310         if(self.autoscreenshot > 0)
1311         if(time > self.autoscreenshot)
1312         {
1313                 self.autoscreenshot = -1;
1314                 if(clienttype(self) == CLIENTTYPE_REAL)
1315                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1316                 return;
1317         }
1318
1319         if (time < intermission_exittime)
1320                 return;
1321
1322         if(!mapvote_initialized)
1323                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1324                         return;
1325
1326         MapVote_Start();
1327 };
1328
1329 /*
1330 ============
1331 FindIntermission
1332
1333 Returns the entity to view from
1334 ============
1335 */
1336 /*
1337 entity FindIntermission()
1338 {
1339         local   entity spot;
1340         local   float cyc;
1341
1342 // look for info_intermission first
1343         spot = find (world, classname, "info_intermission");
1344         if (spot)
1345         {       // pick a random one
1346                 cyc = random() * 4;
1347                 while (cyc > 1)
1348                 {
1349                         spot = find (spot, classname, "info_intermission");
1350                         if (!spot)
1351                                 spot = find (spot, classname, "info_intermission");
1352                         cyc = cyc - 1;
1353                 }
1354                 return spot;
1355         }
1356
1357 // then look for the start position
1358         spot = find (world, classname, "info_player_start");
1359         if (spot)
1360                 return spot;
1361
1362 // testinfo_player_start is only found in regioned levels
1363         spot = find (world, classname, "testplayerstart");
1364         if (spot)
1365                 return spot;
1366
1367 // then look for the start position
1368         spot = find (world, classname, "info_player_deathmatch");
1369         if (spot)
1370                 return spot;
1371
1372         //objerror ("FindIntermission: no spot");
1373         return world;
1374 };
1375 */
1376
1377 /*
1378 ===============================================================================
1379
1380 RULES
1381
1382 ===============================================================================
1383 */
1384
1385 void DumpStats(float final)
1386 {
1387         local float file;
1388         local string s;
1389         local float to_console;
1390         local float to_eventlog;
1391         local float to_file;
1392         local float i;
1393
1394         to_console = cvar("sv_logscores_console");
1395         to_eventlog = cvar("sv_eventlog");
1396         to_file = cvar("sv_logscores_file");
1397
1398         if(!final)
1399         {
1400                 to_console = TRUE; // always print printstats replies
1401                 to_eventlog = FALSE; // but never print them to the event log
1402         }
1403
1404         if(to_eventlog)
1405                 if(cvar("sv_eventlog_console"))
1406                         to_console = FALSE; // otherwise we get the output twice
1407
1408         if(final)
1409                 s = ":scores:";
1410         else
1411                 s = ":status:";
1412         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1413
1414         if(to_console)
1415                 print(s, "\n");
1416         if(to_eventlog)
1417                 GameLogEcho(s);
1418         if(to_file)
1419         {
1420                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1421                 if(file == -1)
1422                         to_file = FALSE;
1423                 else
1424                         fputs(file, strcat(s, "\n"));
1425         }
1426
1427         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1428         if(to_console)
1429                 print(s, "\n");
1430         if(to_eventlog)
1431                 GameLogEcho(s);
1432         if(to_file)
1433                 fputs(file, strcat(s, "\n"));
1434
1435         FOR_EACH_CLIENT(other)
1436         {
1437                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1438                 {
1439                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1440                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1441                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1442                                 s = strcat(s, ftos(other.team), ":");
1443                         else
1444                                 s = strcat(s, "spectator:");
1445
1446                         if(to_console)
1447                                 print(s, other.netname, "\n");
1448                         if(to_eventlog)
1449                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1450                         if(to_file)
1451                                 fputs(file, strcat(s, other.netname, "\n"));
1452                 }
1453         }
1454
1455         if(teams_matter)
1456         {
1457                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1458                 if(to_console)
1459                         print(s, "\n");
1460                 if(to_eventlog)
1461                         GameLogEcho(s);
1462                 if(to_file)
1463                         fputs(file, strcat(s, "\n"));
1464
1465                 for(i = 1; i < 16; ++i)
1466                 {
1467                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1468                         s = strcat(s, ":", ftos(i));
1469                         if(to_console)
1470                                 print(s, "\n");
1471                         if(to_eventlog)
1472                                 GameLogEcho(s);
1473                         if(to_file)
1474                                 fputs(file, strcat(s, "\n"));
1475                 }
1476         }
1477
1478         if(to_console)
1479                 print(":end\n");
1480         if(to_eventlog)
1481                 GameLogEcho(":end");
1482         if(to_file)
1483         {
1484                 fputs(file, ":end\n");
1485                 fclose(file);
1486         }
1487 }
1488
1489 void FixIntermissionClient(entity e)
1490 {
1491         string s;
1492         if(!e.autoscreenshot) // initial call
1493         {
1494                 e.angles = e.v_angle;
1495                 e.angles_x = -e.angles_x;
1496                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1497                 e.health = -2342;
1498                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1499                 e.solid = SOLID_NOT;
1500                 e.movetype = MOVETYPE_NONE;
1501                 e.takedamage = DAMAGE_NO;
1502                 if(e.weaponentity)
1503                 {
1504                         e.weaponentity.effects = EF_NODRAW;
1505                         if (e.weaponentity.weaponentity)
1506                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1507                 }
1508                 if(clienttype(e) == CLIENTTYPE_REAL)
1509                 {
1510                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1511                         s = cvar_string("sv_intermission_cdtrack");
1512                         if(s != "")
1513                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1514                         msg_entity = e;
1515                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1516                 }
1517         }
1518
1519         //e.velocity = '0 0 0';
1520         //e.fixangle = TRUE;
1521
1522         // TODO halt weapon animation
1523 }
1524
1525
1526 /*
1527 go to the next level for deathmatch
1528 only called if a time or frag limit has expired
1529 */
1530 void NextLevel()
1531 {
1532         float i;
1533
1534         gameover = TRUE;
1535
1536         intermission_running = 1;
1537
1538 // enforce a wait time before allowing changelevel
1539         if(player_count > 0)
1540                 intermission_exittime = time + cvar("sv_mapchange_delay");
1541         else
1542                 intermission_exittime = -1;
1543
1544         /*
1545         WriteByte (MSG_ALL, SVC_CDTRACK);
1546         WriteByte (MSG_ALL, 3);
1547         WriteByte (MSG_ALL, 3);
1548         // done in FixIntermission
1549         */
1550
1551         //pos = FindIntermission ();
1552
1553         VoteReset();
1554
1555         DumpStats(TRUE);
1556
1557         if(cvar("sv_eventlog"))
1558                 GameLogEcho(":gameover");
1559
1560         GameLogClose();
1561
1562 // TO DO
1563
1564 // save the stats to a text file on the client
1565 // stuffcmd(other, log_stats "stats/file_name");
1566 // bprint stats
1567 // stuffcmd(other, log_stats "");
1568 // use a filename similar to the demo name
1569         // string file_name;
1570         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1571
1572 // write a stats parser for the menu
1573
1574         if(cvar("sv_accuracy_data_send")) {
1575                 string stats_to_send;
1576
1577                 FOR_EACH_CLIENT(other) {  // make the string to send
1578                         FixIntermissionClient(other);
1579
1580                         if(other.cvar_cl_accuracy_data_share) {
1581                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1582
1583                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1584                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1585
1586                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1587
1588                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1589                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1590
1591                                 stats_to_send = strcat(stats_to_send, "\n");
1592                         }
1593                 }
1594
1595                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1596                         Score_NicePrint(other);  // print the score
1597
1598                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1599                                 bprint(stats_to_send);
1600                 }
1601         } else { // ye olde message
1602                 FOR_EACH_PLAYER(other) {
1603                         FixIntermissionClient(other);
1604
1605                         if(other.winning)
1606                                 bprint(other.netname, " ^7wins.\n");
1607                 }
1608         }
1609
1610         if(cvar("g_campaign"))
1611                 CampaignPreIntermission();
1612
1613         localcmd("\nsv_hook_gameend\n");
1614 }
1615
1616 /*
1617 ============
1618 CheckRules_Player
1619
1620 Exit deathmatch games upon conditions
1621 ============
1622 */
1623 void CheckRules_Player()
1624 {
1625         if (gameover)   // someone else quit the game already
1626                 return;
1627
1628         if(self.deadflag == DEAD_NO)
1629                 self.play_time += frametime;
1630
1631         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1632         //   (div0: and that in CheckRules_World please)
1633 };
1634
1635 float checkrules_equality;
1636 float checkrules_suddendeathwarning;
1637 float checkrules_suddendeathend;
1638 float checkrules_overtimesadded; //how many overtimes have been already added
1639
1640 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1641 float WINNING_YES = 1; // winner found
1642 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1643 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1644
1645 float InitiateSuddenDeath()
1646 {
1647         // Check first whether normal overtimes could be added before initiating suddendeath mode
1648         // - for this timelimit_overtime needs to be >0 of course
1649         // - also check the winning condition calculated in the previous frame and only add normal overtime
1650         //   again, if at the point at which timelimit would be extended again, still no winner was found
1651         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1652         {
1653                 return 1; // need to call InitiateOvertime later
1654         }
1655         else
1656         {
1657                 if(!checkrules_suddendeathend)
1658                 {
1659                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1660                         if(g_race && !g_race_qualifying)
1661                                 race_StartCompleting();
1662                 }
1663                 return 0;
1664         }
1665 }
1666
1667 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1668 {
1669         ++checkrules_overtimesadded;
1670         //add one more overtime by simply extending the timelimit
1671         float tl;
1672         tl = cvar("timelimit");
1673         tl += cvar("timelimit_overtime");
1674         cvar_set("timelimit", ftos(tl));
1675         string minutesPlural;
1676         if (cvar("timelimit_overtime") == 1)
1677                 minutesPlural = " ^3minute";
1678         else
1679                 minutesPlural = " ^3minutes";
1680
1681         bcenterprint(
1682                 strcat(
1683                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1684                         ftos(cvar("timelimit_overtime")),
1685                         minutesPlural,
1686                         " to the game!"
1687                 )
1688         );
1689 }
1690
1691 float GetWinningCode(float fraglimitreached, float equality)
1692 {
1693         if(cvar("g_campaign") == 1)
1694                 if(fraglimitreached)
1695                         return WINNING_YES;
1696                 else
1697                         return WINNING_NO;
1698
1699         else
1700                 if(equality)
1701                         if(fraglimitreached)
1702                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1703                         else
1704                                 return WINNING_NEVER;
1705                 else
1706                         if(fraglimitreached)
1707                                 return WINNING_YES;
1708                         else
1709                                 return WINNING_NO;
1710 }
1711
1712 // set the .winning flag for exactly those players with a given field value
1713 void SetWinners(.float field, float value)
1714 {
1715         entity head;
1716         FOR_EACH_PLAYER(head)
1717                 head.winning = (head.field == value);
1718 }
1719
1720 // set the .winning flag for those players with a given field value
1721 void AddWinners(.float field, float value)
1722 {
1723         entity head;
1724         FOR_EACH_PLAYER(head)
1725                 if(head.field == value)
1726                         head.winning = 1;
1727 }
1728
1729 // clear the .winning flags
1730 void ClearWinners(void)
1731 {
1732         entity head;
1733         FOR_EACH_PLAYER(head)
1734                 head.winning = 0;
1735 }
1736
1737 // Onslaught winning condition:
1738 // game terminates if only one team has a working generator (or none)
1739 float WinningCondition_Onslaught()
1740 {
1741         entity head;
1742         local float t1, t2, t3, t4;
1743
1744         WinningConditionHelper(); // set worldstatus
1745
1746         if(inWarmupStage)
1747                 return WINNING_NO;
1748
1749         // first check if the game has ended
1750         t1 = t2 = t3 = t4 = 0;
1751         head = find(world, classname, "onslaught_generator");
1752         while (head)
1753         {
1754                 if (head.health > 0)
1755                 {
1756                         if (head.team == COLOR_TEAM1) t1 = 1;
1757                         if (head.team == COLOR_TEAM2) t2 = 1;
1758                         if (head.team == COLOR_TEAM3) t3 = 1;
1759                         if (head.team == COLOR_TEAM4) t4 = 1;
1760                 }
1761                 head = find(head, classname, "onslaught_generator");
1762         }
1763         if (t1 + t2 + t3 + t4 < 2)
1764         {
1765                 // game over, only one team remains (or none)
1766                 ClearWinners();
1767                 if (t1) SetWinners(team, COLOR_TEAM1);
1768                 if (t2) SetWinners(team, COLOR_TEAM2);
1769                 if (t3) SetWinners(team, COLOR_TEAM3);
1770                 if (t4) SetWinners(team, COLOR_TEAM4);
1771                 dprint("Have a winner, ending game.\n");
1772                 return WINNING_YES;
1773         }
1774
1775         // Two or more teams remain
1776         return WINNING_NO;
1777 }
1778
1779 float LMS_NewPlayerLives()
1780 {
1781         float fl;
1782         fl = cvar("fraglimit");
1783         if(fl == 0)
1784                 fl = 999;
1785
1786         // first player has left the game for dying too much? Nobody else can get in.
1787         if(lms_lowest_lives < 1)
1788                 return 0;
1789
1790         if(!cvar("g_lms_join_anytime"))
1791                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1792                         return 0;
1793
1794         return bound(1, lms_lowest_lives, fl);
1795 }
1796
1797 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1798 // they win. Otherwise the defending team wins once the timelimit passes.
1799 void assault_new_round();
1800 float WinningCondition_Assault()
1801 {
1802         local float status;
1803
1804         WinningConditionHelper(); // set worldstatus
1805
1806         status = WINNING_NO;
1807         // as the timelimit has not yet passed just assume the defending team will win
1808         if(assault_attacker_team == COLOR_TEAM1)
1809         {
1810                 SetWinners(team, COLOR_TEAM2);
1811         }
1812         else
1813         {
1814                 SetWinners(team, COLOR_TEAM1);
1815         }
1816
1817         local entity ent;
1818         ent = find(world, classname, "target_assault_roundend");
1819         if(ent)
1820         {
1821                 if(ent.winning) // round end has been triggered by attacking team
1822                 {
1823                         bprint("ASSAULT: round completed...\n");
1824                         SetWinners(team, assault_attacker_team);
1825
1826                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1827
1828                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1829                         {
1830                                 status = WINNING_YES;
1831                         }
1832                         else
1833                         {
1834                                 local entity oldself;
1835                                 oldself = self;
1836                                 self = ent;
1837                                 assault_new_round();
1838                                 self = oldself;
1839                         }
1840                 }
1841         }
1842
1843         return status;
1844 }
1845
1846 // LMS winning condition: game terminates if and only if there's at most one
1847 // one player who's living lives. Top two scores being equal cancels the time
1848 // limit.
1849 float WinningCondition_LMS()
1850 {
1851         entity head, head2;
1852         float have_player;
1853         float have_players;
1854         float l;
1855
1856         have_player = FALSE;
1857         have_players = FALSE;
1858         l = LMS_NewPlayerLives();
1859
1860         head = find(world, classname, "player");
1861         if(head)
1862                 have_player = TRUE;
1863         head2 = find(head, classname, "player");
1864         if(head2)
1865                 have_players = TRUE;
1866
1867         if(have_player)
1868         {
1869                 // we have at least one player
1870                 if(have_players)
1871                 {
1872                         // two or more active players - continue with the game
1873                 }
1874                 else
1875                 {
1876                         // exactly one player?
1877
1878                         ClearWinners();
1879                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1880
1881                         if(l)
1882                         {
1883                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1884                                 return WINNING_NO;
1885                         }
1886                         else
1887                         {
1888                                 // a winner!
1889                                 // and assign him his first place
1890                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1891                                 return WINNING_YES;
1892                         }
1893                 }
1894         }
1895         else
1896         {
1897                 // nobody is playing at all...
1898                 if(l)
1899                 {
1900                         // wait for players...
1901                 }
1902                 else
1903                 {
1904                         // SNAFU (maybe a draw game?)
1905                         ClearWinners();
1906                         dprint("No players, ending game.\n");
1907                         return WINNING_YES;
1908                 }
1909         }
1910
1911         // When we get here, we have at least two players who are actually LIVING,
1912         // now check if the top two players have equal score.
1913         WinningConditionHelper();
1914
1915         ClearWinners();
1916         if(WinningConditionHelper_winner)
1917                 WinningConditionHelper_winner.winning = TRUE;
1918         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1919                 return WINNING_NEVER;
1920
1921         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1922         return WINNING_NO;
1923 }
1924
1925 void ShuffleMaplist()
1926 {
1927         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1928 }
1929
1930 float leaderfrags;
1931 float WinningCondition_Scores(float limit, float leadlimit)
1932 {
1933         float limitreached;
1934
1935         // TODO make everything use THIS winning condition (except LMS)
1936         WinningConditionHelper();
1937
1938         if(teams_matter)
1939         {
1940                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1941                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1942                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1943                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1944         }
1945
1946         ClearWinners();
1947         if(WinningConditionHelper_winner)
1948                 WinningConditionHelper_winner.winning = 1;
1949         if(WinningConditionHelper_winnerteam >= 0)
1950                 SetWinners(team, WinningConditionHelper_winnerteam);
1951
1952         if(WinningConditionHelper_lowerisbetter)
1953         {
1954                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1955                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1956                 limit = -limit;
1957         }
1958
1959         if(WinningConditionHelper_zeroisworst)
1960                 leadlimit = 0; // not supported in this mode
1961
1962         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1963         // these modes always score in increments of 1, thus this makes sense
1964         {
1965                 if(leaderfrags != WinningConditionHelper_topscore)
1966                 {
1967                         leaderfrags = WinningConditionHelper_topscore;
1968
1969                         if (limit)
1970                         if (leaderfrags == limit - 1)
1971                                 Announce("1fragleft");
1972                         else if (leaderfrags == limit - 2)
1973                                 Announce("2fragsleft");
1974                         else if (leaderfrags == limit - 3)
1975                                 Announce("3fragsleft");
1976                 }
1977         }
1978
1979         limitreached = FALSE;
1980         if(limit)
1981                 if(WinningConditionHelper_topscore >= limit)
1982                         limitreached = TRUE;
1983         if(leadlimit)
1984         {
1985                 float leadlimitreached;
1986                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1987                 if(cvar("leadlimit_and_fraglimit"))
1988                         limitreached = (limitreached && leadlimitreached);
1989                 else
1990                         limitreached = (limitreached || leadlimitreached);
1991         }
1992
1993         return GetWinningCode(
1994                 WinningConditionHelper_topscore && limitreached,
1995                 WinningConditionHelper_equality
1996         );
1997 }
1998
1999 float WinningCondition_Race(float fraglimit)
2000 {
2001         float wc;
2002         entity p;
2003         float n, c;
2004
2005         n = 0;
2006         c = 0;
2007         FOR_EACH_PLAYER(p)
2008         {
2009                 ++n;
2010                 if(p.race_completed)
2011                         ++c;
2012         }
2013         if(n && (n == c))
2014                 return WINNING_YES;
2015         wc = WinningCondition_Scores(fraglimit, 0);
2016
2017         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2018         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2019         // do NOT support equality when the laps are all raced!
2020                 return WINNING_STARTSUDDENDEATHOVERTIME;
2021         else
2022                 return WINNING_NEVER;
2023         return wc;
2024 }
2025
2026 void ReadyRestart();
2027 float WinningCondition_QualifyingThenRace(float limit)
2028 {
2029         float wc;
2030         wc = WinningCondition_Scores(limit, 0);
2031
2032         // NEVER initiate overtime
2033         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2034         {
2035                 return WINNING_YES;
2036         }
2037
2038         return wc;
2039 }
2040
2041 float WinningCondition_RanOutOfSpawns()
2042 {
2043         entity head;
2044
2045         if(have_team_spawns <= 0)
2046                 return WINNING_NO;
2047
2048         if(!some_spawn_has_been_used)
2049                 return WINNING_NO;
2050
2051         team1_score = team2_score = team3_score = team4_score = 0;
2052
2053         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2054         {
2055                 if(head.team == COLOR_TEAM1)
2056                         team1_score = 1;
2057                 else if(head.team == COLOR_TEAM2)
2058                         team2_score = 1;
2059                 else if(head.team == COLOR_TEAM3)
2060                         team3_score = 1;
2061                 else if(head.team == COLOR_TEAM4)
2062                         team4_score = 1;
2063         }
2064
2065         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2066         {
2067                 if(head.team == COLOR_TEAM1)
2068                         team1_score = 1;
2069                 else if(head.team == COLOR_TEAM2)
2070                         team2_score = 1;
2071                 else if(head.team == COLOR_TEAM3)
2072                         team3_score = 1;
2073                 else if(head.team == COLOR_TEAM4)
2074                         team4_score = 1;
2075         }
2076
2077         ClearWinners();
2078         if(team1_score + team2_score + team3_score + team4_score == 0)
2079         {
2080                 checkrules_equality = TRUE;
2081                 return WINNING_YES;
2082         }
2083         else if(team1_score + team2_score + team3_score + team4_score == 1)
2084         {
2085                 float t, i;
2086                 if(team1_score) t = COLOR_TEAM1;
2087                 if(team2_score) t = COLOR_TEAM2;
2088                 if(team3_score) t = COLOR_TEAM3;
2089                 if(team4_score) t = COLOR_TEAM4;
2090                 CheckAllowedTeams(world);
2091                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2092                 {
2093                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2094                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2095                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2096                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2097                 }
2098
2099                 AddWinners(team, t);
2100                 return WINNING_YES;
2101         }
2102         else
2103                 return WINNING_NO;
2104 }
2105
2106 /*
2107 ============
2108 CheckRules_World
2109
2110 Exit deathmatch games upon conditions
2111 ============
2112 */
2113 void CheckRules_World()
2114 {
2115         float timelimit;
2116         float fraglimit;
2117         float leadlimit;
2118
2119         VoteThink();
2120         MapVote_Think();
2121
2122         SetDefaultAlpha();
2123
2124         /*
2125         MapVote_Think should now do that part
2126         if (intermission_running)
2127                 if (time >= intermission_exittime + 60)
2128                 {
2129                         if(!DoNextMapOverride())
2130                                 GotoNextMap();
2131                         return;
2132                 }
2133         */
2134
2135         if (gameover)   // someone else quit the game already
2136         {
2137                 if(player_count == 0) // Nobody there? Then let's go to the next map
2138                         MapVote_Start();
2139                         // this will actually check the player count in the next frame
2140                         // again, but this shouldn't hurt
2141                 return;
2142         }
2143
2144         timelimit = cvar("timelimit") * 60;
2145         fraglimit = cvar("fraglimit");
2146         leadlimit = cvar("leadlimit");
2147
2148         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2149         {
2150                 if(timelimit > 0)
2151                         timelimit = 0; // timelimit is not made for warmup
2152                 if(fraglimit > 0)
2153                         fraglimit = 0; // no fraglimit for now
2154                 leadlimit = 0; // no leadlimit for now
2155         }
2156
2157         if(g_onslaught)
2158                 timelimit = 0; // ONS has its own overtime rule
2159
2160         if(timelimit > 0)
2161         {
2162                 timelimit += game_starttime;
2163         }
2164         else if (timelimit < 0)
2165         {
2166                 // endmatch
2167                 NextLevel();
2168                 return;
2169         }
2170
2171         float wantovertime;
2172         wantovertime = 0;
2173
2174         if(checkrules_suddendeathend)
2175         {
2176                 if(!checkrules_suddendeathwarning)
2177                 {
2178                         checkrules_suddendeathwarning = TRUE;
2179                         if(g_race && !g_race_qualifying)
2180                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2181                         else
2182                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2183                 }
2184         }
2185         else
2186         {
2187                 if (timelimit && time >= timelimit)
2188                 {
2189                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2190                         {
2191                                 float totalplayers;
2192                                 float playerswithlaps;
2193                                 float readyplayers;
2194                                 entity head;
2195                                 totalplayers = playerswithlaps = readyplayers = 0;
2196                                 FOR_EACH_PLAYER(head)
2197                                 {
2198                                         ++totalplayers;
2199                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2200                                                 ++playerswithlaps;
2201                                         if(head.ready)
2202                                                 ++readyplayers;
2203                                 }
2204
2205                                 // at least 2 of the players have completed a lap: start the RACE
2206                                 // otherwise, the players should end the qualifying on their own
2207                                 if(readyplayers || playerswithlaps >= 2)
2208                                 {
2209                                         checkrules_suddendeathend = 0;
2210                                         ReadyRestart(); // go to race
2211                                         return;
2212                                 }
2213                                 else
2214                                         wantovertime |= InitiateSuddenDeath();
2215                         }
2216                         else
2217                                 wantovertime |= InitiateSuddenDeath();
2218                 }
2219         }
2220
2221         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2222         {
2223                 NextLevel();
2224                 return;
2225         }
2226
2227         float checkrules_status;
2228         checkrules_status = WinningCondition_RanOutOfSpawns();
2229         if(checkrules_status == WINNING_YES)
2230         {
2231                 bprint("Hey! Someone ran out of spawns!\n");
2232         }
2233         else if(g_race && !g_race_qualifying && timelimit >= 0)
2234         {
2235                 checkrules_status = WinningCondition_Race(fraglimit);
2236                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2237         }
2238         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2239         {
2240                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2241                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2242         }
2243         else if(g_assault)
2244         {
2245                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2246         }
2247         else if(g_lms)
2248         {
2249                 checkrules_status = WinningCondition_LMS();
2250         }
2251         else if (g_onslaught)
2252         {
2253                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2254         }
2255         else
2256         {
2257                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2258                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2259         }
2260
2261         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2262         {
2263                 checkrules_status = WINNING_NEVER;
2264                 checkrules_overtimesadded = -1;
2265                 wantovertime |= InitiateSuddenDeath();
2266         }
2267
2268         if(checkrules_status == WINNING_NEVER)
2269                 // equality cases! Nobody wins if the overtime ends in a draw.
2270                 ClearWinners();
2271
2272         if(wantovertime)
2273         {
2274                 if(checkrules_status == WINNING_NEVER)
2275                         InitiateOvertime();
2276                 else
2277                         checkrules_status = WINNING_YES;
2278         }
2279
2280         if(checkrules_suddendeathend)
2281                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2282                         checkrules_status = WINNING_YES;
2283
2284         if(checkrules_status == WINNING_YES)
2285         {
2286                 //print("WINNING\n");
2287                 NextLevel();
2288         }
2289 };
2290
2291 float mapvote_nextthink;
2292 float mapvote_initialized;
2293 float mapvote_keeptwotime;
2294 float mapvote_timeout;
2295 string mapvote_message;
2296 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2297 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2298 float mapvote_screenshot_dirs_count;
2299
2300 float mapvote_count;
2301 float mapvote_count_real;
2302 string mapvote_maps[MAPVOTE_COUNT];
2303 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2304 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2305 float mapvote_maps_suggested[MAPVOTE_COUNT];
2306 string mapvote_suggestions[MAPVOTE_COUNT];
2307 float mapvote_suggestion_ptr;
2308 float mapvote_maxlen;
2309 float mapvote_voters;
2310 float mapvote_votes[MAPVOTE_COUNT];
2311 float mapvote_run;
2312 float mapvote_detail;
2313 float mapvote_abstain;
2314 .float mapvote;
2315
2316 void MapVote_ClearAllVotes()
2317 {
2318         FOR_EACH_CLIENT(other)
2319                 other.mapvote = 0;
2320 }
2321
2322 string MapVote_Suggest(string m)
2323 {
2324         float i;
2325         if(m == "")
2326                 return "That's not how to use this command.";
2327         if(!cvar("g_maplist_votable_suggestions"))
2328                 return "Suggestions are not accepted on this server.";
2329         if(mapvote_initialized)
2330                 return "Can't suggest - voting is already in progress!";
2331         m = MapInfo_FixName(m);
2332         if(!m)
2333                 return "The map you suggested is not available on this server.";
2334         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2335                 if(Map_IsRecent(m))
2336                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2337
2338         if(!MapInfo_CheckMap(m))
2339                 return "The map you suggested does not support the current game mode.";
2340         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2341                 if(mapvote_suggestions[i] == m)
2342                         return "This map was already suggested.";
2343         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2344         {
2345                 i = floor(random() * mapvote_suggestion_ptr);
2346         }
2347         else
2348         {
2349                 i = mapvote_suggestion_ptr;
2350                 mapvote_suggestion_ptr += 1;
2351         }
2352         if(mapvote_suggestions[i] != "")
2353                 strunzone(mapvote_suggestions[i]);
2354         mapvote_suggestions[i] = strzone(m);
2355         if(cvar("sv_eventlog"))
2356                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2357         return strcat("Suggestion of ", m, " accepted.");
2358 }
2359
2360 void MapVote_AddVotable(string nextMap, float isSuggestion)
2361 {
2362         float j, i, o;
2363         string pakfile, mapfile;
2364
2365         if(nextMap == "")
2366                 return;
2367         for(j = 0; j < mapvote_count; ++j)
2368                 if(mapvote_maps[j] == nextMap)
2369                         return;
2370         if(strlen(nextMap) > mapvote_maxlen)
2371                 mapvote_maxlen = strlen(nextMap);
2372         mapvote_maps[mapvote_count] = strzone(nextMap);
2373         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2374
2375         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2376         {
2377                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2378                 pakfile = whichpack(strcat(mapfile, ".tga"));
2379                 if(pakfile == "")
2380                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2381                 if(pakfile == "")
2382                         pakfile = whichpack(strcat(mapfile, ".png"));
2383                 if(pakfile != "")
2384                         break;
2385         }
2386         if(i >= mapvote_screenshot_dirs_count)
2387                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2388         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2389                 pakfile = substring(pakfile, o, -1);
2390
2391         mapvote_maps_screenshot_dir[mapvote_count] = i;
2392         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2393
2394         mapvote_count += 1;
2395 }
2396
2397 void MapVote_Spawn();
2398 void MapVote_Init()
2399 {
2400         float i;
2401         float nmax, smax;
2402
2403         MapVote_ClearAllVotes();
2404
2405         mapvote_count = 0;
2406         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2407         mapvote_abstain = cvar("g_maplist_votable_abstain");
2408
2409         if(mapvote_abstain)
2410                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2411         else
2412                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2413         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2414
2415         // we need this for AddVotable, as that cycles through the screenshot dirs
2416         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2417         if(mapvote_screenshot_dirs_count == 0)
2418                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2419         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2420         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2421                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2422
2423         if(mapvote_suggestion_ptr)
2424                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2425                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2426
2427         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2428                 MapVote_AddVotable(GetNextMap(), FALSE);
2429
2430         if(mapvote_count == 0)
2431         {
2432                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2433                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2434                 if(cvar("g_maplist_shuffle"))
2435                         ShuffleMaplist();
2436                 localcmd("\nmenu_cmd sync\n");
2437                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2438                         MapVote_AddVotable(GetNextMap(), FALSE);
2439         }
2440
2441         mapvote_count_real = mapvote_count;
2442         if(mapvote_abstain)
2443                 MapVote_AddVotable("don't care", 0);
2444
2445         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2446
2447         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2448         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2449         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2450                 mapvote_keeptwotime = 0;
2451         mapvote_message = "Choose a map and press its key!";
2452
2453         MapVote_Spawn();
2454 }
2455
2456 void MapVote_SendPicture(float id)
2457 {
2458         msg_entity = self;
2459         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2460         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2461         WriteByte(MSG_ONE, id);
2462         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2463 }
2464
2465 float GameCommand_MapVote(string cmd)
2466 {
2467         if(!intermission_running)
2468                 return FALSE;
2469
2470         if(cmd == "mv_getpic")
2471         {
2472                 MapVote_SendPicture(stof(argv(1)));
2473                 return TRUE;
2474         }
2475
2476         return FALSE;
2477 }
2478
2479 float MapVote_GetMapMask()
2480 {
2481         float mask, i, power;
2482         mask = 0;
2483         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2484                 if(mapvote_maps[i] != "")
2485                         mask |= power;
2486         return mask;
2487 }
2488
2489 entity mapvote_ent;
2490 float MapVote_SendEntity(entity to, float sf)
2491 {
2492         float i;
2493
2494         if(sf & 1)
2495                 sf &~= 2; // if we send 1, we don't need to also send 2
2496
2497         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2498         WriteByte(MSG_ENTITY, sf);
2499
2500         if(sf & 1)
2501         {
2502                 // flag 1 == initialization
2503                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2504                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2505                 WriteString(MSG_ENTITY, "");
2506                 WriteByte(MSG_ENTITY, mapvote_count);
2507                 WriteByte(MSG_ENTITY, mapvote_abstain);
2508                 WriteByte(MSG_ENTITY, mapvote_detail);
2509                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2510                 if(mapvote_count <= 8)
2511                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2512                 else
2513                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2514                 for(i = 0; i < mapvote_count; ++i)
2515                         if(mapvote_maps[i] != "")
2516                         {
2517                                 if(mapvote_abstain && i == mapvote_count - 1)
2518                                 {
2519                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2520                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2521                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2522                                 }
2523                                 else
2524                                 {
2525                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2526                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2527                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2528                                 }
2529                         }
2530         }
2531
2532         if(sf & 2)
2533         {
2534                 // flag 2 == update of mask
2535                 if(mapvote_count <= 8)
2536                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2537                 else
2538                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2539         }
2540
2541         if(sf & 4)
2542         {
2543                 if(mapvote_detail)
2544                         for(i = 0; i < mapvote_count; ++i)
2545                                 if(mapvote_maps[i] != "")
2546                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2547
2548                 WriteByte(MSG_ENTITY, to.mapvote);
2549         }
2550
2551         return TRUE;
2552 }
2553
2554 void MapVote_Spawn()
2555 {
2556         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2557 }
2558
2559 void MapVote_TouchMask()
2560 {
2561         mapvote_ent.SendFlags |= 2;
2562 }
2563
2564 void MapVote_TouchVotes(entity voter)
2565 {
2566         mapvote_ent.SendFlags |= 4;
2567 }
2568
2569 float MapVote_Finished(float mappos)
2570 {
2571         string result;
2572         float i;
2573         float didntvote;
2574
2575         if(cvar("sv_eventlog"))
2576         {
2577                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2578                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2579                 didntvote = mapvote_voters;
2580                 for(i = 0; i < mapvote_count; ++i)
2581                         if(mapvote_maps[i] != "")
2582                         {
2583                                 didntvote -= mapvote_votes[i];
2584                                 if(i != mappos)
2585                                 {
2586                                         result = strcat(result, ":", mapvote_maps[i]);
2587                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2588                                 }
2589                         }
2590                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2591
2592                 GameLogEcho(result);
2593                 if(mapvote_maps_suggested[mappos])
2594                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2595         }
2596
2597         FOR_EACH_REALCLIENT(other)
2598                 FixClientCvars(other);
2599
2600         Map_Goto_SetStr(mapvote_maps[mappos]);
2601         Map_Goto();
2602         alreadychangedlevel = TRUE;
2603         return TRUE;
2604 }
2605 void MapVote_CheckRules_1()
2606 {
2607         float i;
2608
2609         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2610         {
2611                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2612                 mapvote_votes[i] = 0;
2613         }
2614
2615         mapvote_voters = 0;
2616         FOR_EACH_REALCLIENT(other)
2617         {
2618                 ++mapvote_voters;
2619                 if(other.mapvote)
2620                 {
2621                         i = other.mapvote - 1;
2622                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2623                         mapvote_votes[i] = mapvote_votes[i] + 1;
2624                 }
2625         }
2626 }
2627
2628 float MapVote_CheckRules_2()
2629 {
2630         float i;
2631         float firstPlace, secondPlace;
2632         float firstPlaceVotes, secondPlaceVotes;
2633         float mapvote_voters_real;
2634         string result;
2635
2636         if(mapvote_count_real == 1)
2637                 return MapVote_Finished(0);
2638
2639         mapvote_voters_real = mapvote_voters;
2640         if(mapvote_abstain)
2641                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2642
2643         RandomSelection_Init();
2644         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2645                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2646         firstPlace = RandomSelection_chosen_float;
2647         firstPlaceVotes = RandomSelection_best_priority;
2648         //dprint("First place: ", ftos(firstPlace), "\n");
2649         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2650
2651         RandomSelection_Init();
2652         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2653                 if(i != firstPlace)
2654                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2655         secondPlace = RandomSelection_chosen_float;
2656         secondPlaceVotes = RandomSelection_best_priority;
2657         //dprint("Second place: ", ftos(secondPlace), "\n");
2658         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2659
2660         if(firstPlace == -1)
2661                 error("No first place in map vote... WTF?");
2662
2663         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2664                 return MapVote_Finished(firstPlace);
2665
2666         if(mapvote_keeptwotime)
2667                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2668                 {
2669                         float didntvote;
2670                         MapVote_TouchMask();
2671                         mapvote_message = "Now decide between the TOP TWO!";
2672                         mapvote_keeptwotime = 0;
2673                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2674                         result = strcat(result, ":", ftos(firstPlaceVotes));
2675                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2676                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2677                         didntvote = mapvote_voters;
2678                         for(i = 0; i < mapvote_count; ++i)
2679                                 if(mapvote_maps[i] != "")
2680                                 {
2681                                         didntvote -= mapvote_votes[i];
2682                                         if(i != firstPlace)
2683                                                 if(i != secondPlace)
2684                                                 {
2685                                                         result = strcat(result, ":", mapvote_maps[i]);
2686                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2687                                                         if(i < mapvote_count_real)
2688                                                         {
2689                                                                 strunzone(mapvote_maps[i]);
2690                                                                 mapvote_maps[i] = "";
2691                                                                 strunzone(mapvote_maps_pakfile[i]);
2692                                                                 mapvote_maps_pakfile[i] = "";
2693                                                         }
2694                                                 }
2695                                 }
2696                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2697                         if(cvar("sv_eventlog"))
2698                                 GameLogEcho(result);
2699                 }
2700
2701         return FALSE;
2702 }
2703 void MapVote_Tick()
2704 {
2705         float keeptwo;
2706         float totalvotes;
2707
2708         keeptwo = mapvote_keeptwotime;
2709         MapVote_CheckRules_1(); // count
2710         if(MapVote_CheckRules_2()) // decide
2711                 return;
2712
2713         totalvotes = 0;
2714         FOR_EACH_REALCLIENT(other)
2715         {
2716                 // hide scoreboard again
2717                 if(other.health != 2342)
2718                 {
2719                         other.health = 2342;
2720                         other.impulse = 0;
2721                         if(clienttype(other) == CLIENTTYPE_REAL)
2722                         {
2723                                 msg_entity = other;
2724                                 WriteByte(MSG_ONE, SVC_FINALE);
2725                                 WriteString(MSG_ONE, "");
2726                         }
2727                 }
2728
2729                 // clear possibly invalid votes
2730                 if(mapvote_maps[other.mapvote - 1] == "")
2731                         other.mapvote = 0;
2732                 // use impulses as new vote
2733                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2734                         if(mapvote_maps[other.impulse - 1] != "")
2735                         {
2736                                 other.mapvote = other.impulse;
2737                                 MapVote_TouchVotes(other);
2738                         }
2739                 other.impulse = 0;
2740
2741                 if(other.mapvote)
2742                         ++totalvotes;
2743         }
2744
2745         MapVote_CheckRules_1(); // just count
2746 }
2747 void MapVote_Start()
2748 {
2749         if(mapvote_run)
2750                 return;
2751
2752         MapInfo_Enumerate();
2753         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2754                 mapvote_run = TRUE;
2755 }
2756 void MapVote_Think()
2757 {
2758         if(!mapvote_run)
2759                 return;
2760
2761         if(alreadychangedlevel)
2762                 return;
2763
2764         if(time < mapvote_nextthink)
2765                 return;
2766         //dprint("tick\n");
2767
2768         mapvote_nextthink = time + 0.5;
2769
2770         if(!mapvote_initialized)
2771         {
2772                 if(cvar("rescan_pending") == 1)
2773                 {
2774                         cvar_set("rescan_pending", "2");
2775                         localcmd("fs_rescan\nrescan_pending 3\n");
2776                         return;
2777                 }
2778                 else if(cvar("rescan_pending") == 2)
2779                 {
2780                         return;
2781                 }
2782                 else if(cvar("rescan_pending") == 3)
2783                 {
2784                         // now build missing mapinfo files
2785                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2786                                 return;
2787
2788                         // we're done, start the timer
2789                         cvar_set("rescan_pending", "0");
2790                 }
2791
2792                 mapvote_initialized = TRUE;
2793                 if(DoNextMapOverride())
2794                         return;
2795                 if(!cvar("g_maplist_votable") || player_count <= 0)
2796                 {
2797                         GotoNextMap();
2798                         return;
2799                 }
2800                 MapVote_Init();
2801         }
2802
2803         MapVote_Tick();
2804 };
2805
2806 string GotoMap(string m)
2807 {
2808         if(!MapInfo_CheckMap(m))
2809                 return "The map you chose is not available on this server.";
2810         cvar_set("nextmap", m);
2811         cvar_set("timelimit", "-1");
2812         if(mapvote_initialized || alreadychangedlevel)
2813         {
2814                 if(DoNextMapOverride())
2815                         return "Map switch initiated.";
2816                 else
2817                         return "Hm... no. For some reason I like THIS map more.";
2818         }
2819         else
2820                 return "Map switch will happen after scoreboard.";
2821 }
2822
2823
2824 void EndFrame()
2825 {
2826         float altime;
2827         FOR_EACH_REALCLIENT(self)
2828         {
2829                 if(self.classname == "spectator")
2830                 {
2831                         if(self.enemy.typehitsound)
2832                                 play2(self, "misc/typehit.wav");
2833                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2834                                 play2(self, "misc/hit.wav");
2835                 }
2836                 else
2837                 {
2838                         if(self.typehitsound)
2839                                 play2(self, "misc/typehit.wav");
2840                         else if(self.hitsound && self.cvar_cl_hitsound)
2841                                 play2(self, "misc/hit.wav");
2842                 }
2843         }
2844         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2845         // add 1 frametime because after this, engine SV_Physics
2846         // increases time by a frametime and then networks the frame
2847         // add another frametime because client shows everything with
2848         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2849         // needed!
2850         FOR_EACH_CLIENT(self)
2851         {
2852                 self.hitsound = FALSE;
2853                 self.typehitsound = FALSE;
2854                 antilag_record(self, altime);
2855         }
2856 }
2857
2858
2859 /*
2860  * RedirectionThink:
2861  * returns TRUE if redirecting
2862  */
2863 float redirection_timeout;
2864 float redirection_nextthink;
2865 float RedirectionThink()
2866 {
2867         float clients_found;
2868
2869         if(redirection_target == "")
2870                 return FALSE;
2871
2872         if(!redirection_timeout)
2873         {
2874                 cvar_set("sv_public", "-2");
2875                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2876                 if(redirection_target == "self")
2877                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2878                 else
2879                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2880         }
2881
2882         if(time < redirection_nextthink)
2883                 return TRUE;
2884
2885         redirection_nextthink = time + 1;
2886
2887         clients_found = 0;
2888         FOR_EACH_REALCLIENT(self)
2889         {
2890                 print("Redirecting: sending connect command to ", self.netname, "\n");
2891                 if(redirection_target == "self")
2892                         stuffcmd(self, "\ndisconnect; reconnect\n");
2893                 else
2894                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2895                 ++clients_found;
2896         }
2897
2898         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2899
2900         if(time > redirection_timeout || clients_found == 0)
2901                 localcmd("\nwait; wait; wait; quit\n");
2902
2903         return TRUE;
2904 }
2905
2906 void TargetMusic_RestoreGame();
2907 void RestoreGame()
2908 {
2909         // Loaded from a save game
2910         // some things then break, so let's work around them...
2911
2912         // Progs DB (capture records)
2913         ServerProgsDB = db_load("server.db");
2914
2915         // Mapinfo
2916         MapInfo_Shutdown();
2917         MapInfo_Enumerate();
2918         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2919         WeaponStats_Init();
2920
2921         TargetMusic_RestoreGame();
2922 }
2923
2924 void SV_Shutdown()
2925 {
2926         if(gameover > 1) // shutting down already?
2927                 return;
2928
2929         gameover = 2; // 2 = server shutting down
2930
2931         if(world_initialized > 0)
2932         {
2933                 world_initialized = 0;
2934                 print("Saving persistent data...\n");
2935                 Ban_SaveBans();
2936                 if(!cheatcount_total)
2937                 {
2938                         if(cvar("sv_db_saveasdump"))
2939                                 db_dump(ServerProgsDB, "server.db");
2940                         else
2941                                 db_save(ServerProgsDB, "server.db");
2942                 }
2943                 if(cvar("developer"))
2944                 {
2945                         if(cvar("sv_db_saveasdump"))
2946                                 db_dump(TemporaryDB, "server-temp.db");
2947                         else
2948                                 db_save(TemporaryDB, "server-temp.db");
2949                 }
2950                 CheatShutdown(); // must be after cheatcount check
2951                 db_close(ServerProgsDB);
2952                 db_close(TemporaryDB);
2953                 print("done!\n");
2954                 // tell the bot system the game is ending now
2955                 bot_endgame();
2956
2957                 WeaponStats_Shutdown();
2958                 MapInfo_Shutdown();
2959         }
2960         else if(world_initialized == 0)
2961         {
2962                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2963         }
2964 }