qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include <common/net_linked.qh>
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/_mod.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications/all.qh"
  29 #include "../common/physics/player.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/_mod.qh"
  37 #include <common/weapons/_all.qh>
  38 #include "../common/state.qh"
  39
  40 const float LATENCY_THINKRATE = 10;
  41 .float latency_sum;
  42 .float latency_cnt;
  43 .float latency_time;
  44 entity pingplreport;
  45 void PingPLReport_Think(entity this)
  46 {
  47         float delta;
  48         entity e;
  49
  50         delta = 3 / maxclients;
  51         if(delta < sys_frametime)
  52                 delta = 0;
  53         this.nextthink = time + delta;
  54
  55         e = edict_num(this.cnt + 1);
  56         if(IS_REAL_CLIENT(e))
  57         {
  58                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  59                 WriteByte(MSG_BROADCAST, this.cnt);
  60                 WriteShort(MSG_BROADCAST, bound(1, e.ping, 65535));
  61                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_packetloss * 255), 255));
  62                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_movementloss * 255), 255));
  63
  64                 // record latency times for clients throughout the match so we can report it to playerstats
  65                 if(time > (e.latency_time + LATENCY_THINKRATE))
  66                 {
  67                         e.latency_sum += e.ping;
  68                         e.latency_cnt += 1;
  69                         e.latency_time = time;
  70                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  71                 }
  72         }
  73         else
  74         {
  75                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, this.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         this.cnt = (this.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = new_pure(pingplreport);
  86         setthink(pingplreport, PingPLReport_Think);
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap(entity this)
 109 {
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 this.nextthink = time;
 134         }
 135         else
 136         {
 137                 this.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("g_maplist_index");
 180                 BADCVAR("halflifebsp");
 181                 BADCVAR("sv_mapformat_is_quake2");
 182                 BADCVAR("sv_mapformat_is_quake3");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADCVAR("g_require_stats");
 231                 BADPREFIX("developer_");
 232                 BADPREFIX("g_ban_");
 233                 BADPREFIX("g_banned_list");
 234                 BADPREFIX("g_require_stats_");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_voice_flood_");
 239                 BADPREFIX("log_file");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_assault");
 257                 BADCVAR("g_ca");
 258                 BADCVAR("g_ca_teams");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_freezetag_teams");
 266                 BADCVAR("g_invasion_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_laps_limit");
 275                 BADCVAR("g_race_qualifying_timelimit");
 276                 BADCVAR("g_race_qualifying_timelimit_override");
 277                 BADCVAR("g_tdm");
 278                 BADCVAR("g_tdm_teams");
 279                 BADCVAR("leadlimit");
 280                 BADCVAR("nextmap");
 281                 BADCVAR("teamplay");
 282                 BADCVAR("timelimit");
 283
 284                 // long
 285                 BADCVAR("hostname");
 286                 BADCVAR("g_maplist");
 287                 BADCVAR("g_maplist_mostrecent");
 288                 BADCVAR("sv_motd");
 289
 290                 v = cvar_string(k);
 291                 d = cvar_defstring(k);
 292                 if(v == d)
 293                         continue;
 294
 295                 if(adding)
 296                 {
 297                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 298                         if(strlen(cvar_changes) > 16384)
 299                         {
 300                                 cvar_changes = "// too many settings have been changed to show them here\n";
 301                                 adding = 0;
 302                         }
 303                 }
 304
 305                 // now check if the changes are actually gameplay relevant
 306
 307                 // does nothing gameplay relevant
 308                 BADCVAR("captureleadlimit_override");
 309                 BADCVAR("gameversion");
 310                 BADCVAR("g_allow_oldvortexbeam");
 311                 BADCVAR("g_balance_kill_delay");
 312                 BADCVAR("g_campcheck_distance");
 313                 BADCVAR("g_ca_point_leadlimit");
 314                 BADCVAR("g_ca_point_limit");
 315                 BADCVAR("g_ctf_captimerecord_always");
 316                 BADCVAR("g_ctf_flag_glowtrails");
 317                 BADCVAR("g_ctf_flag_pickup_verbosename");
 318                 BADCVAR("g_domination_point_leadlimit");
 319                 BADCVAR("g_forced_respawn");
 320                 BADCVAR("g_freezetag_point_leadlimit");
 321                 BADCVAR("g_freezetag_point_limit");
 322                 BADCVAR("g_hats");
 323                 BADCVAR("g_invasion_point_limit");
 324                 BADCVAR("g_keyhunt_point_leadlimit");
 325                 BADCVAR("g_nexball_goalleadlimit");
 326                 BADCVAR("g_new_toys_use_pickupsound");
 327                 BADCVAR("g_physics_predictall");
 328                 BADCVAR("g_piggyback");
 329                 BADCVAR("g_tdm_point_leadlimit");
 330                 BADCVAR("g_tdm_point_limit");
 331                 BADCVAR("leadlimit_and_fraglimit");
 332                 BADCVAR("leadlimit_override");
 333                 BADCVAR("pausable");
 334                 BADCVAR("sv_checkforpacketsduringsleep");
 335                 BADCVAR("sv_intermission_cdtrack");
 336                 BADCVAR("sv_minigames");
 337                 BADCVAR("sv_namechangetimer");
 338                 BADCVAR("sv_precacheplayermodels");
 339                 BADCVAR("sv_stepheight");
 340                 BADCVAR("sv_timeout");
 341                 BADPREFIX("crypto_");
 342                 BADPREFIX("gameversion_");
 343                 BADPREFIX("g_chat_");
 344                 BADPREFIX("g_ctf_captimerecord_");
 345                 BADPREFIX("g_maplist_votable_");
 346                 BADPREFIX("g_mod_");
 347                 BADPREFIX("g_respawn_");
 348                 BADPREFIX("net_");
 349                 BADPREFIX("prvm_");
 350                 BADPREFIX("skill_");
 351                 BADPREFIX("sv_allow_");
 352                 BADPREFIX("sv_cullentities_");
 353                 BADPREFIX("sv_maxidle_");
 354                 BADPREFIX("sv_minigames_");
 355                 BADPREFIX("sv_radio_");
 356                 BADPREFIX("sv_timeout_");
 357                 BADPREFIX("sv_vote_");
 358                 BADPREFIX("timelimit_");
 359
 360                 // allowed changes to server admins (please sync this to server.cfg)
 361                 // vi commands:
 362                 //   :/"impure"/,$d
 363                 //   :g!,^\/\/[^ /],d
 364                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 365                 //   :%!sort
 366                 // yes, this does contain some redundant stuff, don't really care
 367                 BADCVAR("bot_config_file");
 368                 BADCVAR("bot_number");
 369                 BADCVAR("bot_prefix");
 370                 BADCVAR("bot_suffix");
 371                 BADCVAR("capturelimit_override");
 372                 BADCVAR("fraglimit_override");
 373                 BADCVAR("gametype");
 374                 BADCVAR("g_antilag");
 375                 BADCVAR("g_balance_teams");
 376                 BADCVAR("g_balance_teams_prevent_imbalance");
 377                 BADCVAR("g_balance_teams_scorefactor");
 378                 BADCVAR("g_ban_sync_trusted_servers");
 379                 BADCVAR("g_ban_sync_uri");
 380                 BADCVAR("g_buffs");
 381                 BADCVAR("g_ca_teams_override");
 382                 BADCVAR("g_ctf_ignore_frags");
 383                 BADCVAR("g_domination_point_limit");
 384                 BADCVAR("g_domination_teams_override");
 385                 BADCVAR("g_freezetag_teams_override");
 386                 BADCVAR("g_friendlyfire");
 387                 BADCVAR("g_fullbrightitems");
 388                 BADCVAR("g_fullbrightplayers");
 389                 BADCVAR("g_keyhunt_point_limit");
 390                 BADCVAR("g_keyhunt_teams_override");
 391                 BADCVAR("g_lms_lives_override");
 392                 BADCVAR("g_maplist");
 393                 BADCVAR("g_maplist_check_waypoints");
 394                 BADCVAR("g_maplist_mostrecent_count");
 395                 BADCVAR("g_maplist_shuffle");
 396                 BADCVAR("g_maplist_votable");
 397                 BADCVAR("g_maplist_votable_abstain");
 398                 BADCVAR("g_maplist_votable_nodetail");
 399                 BADCVAR("g_maplist_votable_suggestions");
 400                 BADCVAR("g_maxplayers");
 401                 BADCVAR("g_mirrordamage");
 402                 BADCVAR("g_nexball_goallimit");
 403                 BADCVAR("g_norecoil");
 404                 BADCVAR("g_physics_clientselect");
 405                 BADCVAR("g_pinata");
 406                 BADCVAR("g_powerups");
 407                 BADCVAR("g_spawnshieldtime");
 408                 BADCVAR("g_start_delay");
 409                 BADCVAR("g_superspectate");
 410                 BADCVAR("g_tdm_teams_override");
 411                 BADCVAR("g_warmup");
 412                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 413                 BADCVAR("hostname");
 414                 BADCVAR("log_file");
 415                 BADCVAR("maxplayers");
 416                 BADCVAR("minplayers");
 417                 BADCVAR("net_address");
 418                 BADCVAR("port");
 419                 BADCVAR("rcon_password");
 420                 BADCVAR("rcon_restricted_commands");
 421                 BADCVAR("rcon_restricted_password");
 422                 BADCVAR("skill");
 423                 BADCVAR("sv_adminnick");
 424                 BADCVAR("sv_autoscreenshot");
 425                 BADCVAR("sv_autotaunt");
 426                 BADCVAR("sv_curl_defaulturl");
 427                 BADCVAR("sv_defaultcharacter");
 428                 BADCVAR("sv_defaultcharacterskin");
 429                 BADCVAR("sv_defaultplayercolors");
 430                 BADCVAR("sv_defaultplayermodel");
 431                 BADCVAR("sv_defaultplayerskin");
 432                 BADCVAR("sv_maxidle");
 433                 BADCVAR("sv_maxrate");
 434                 BADCVAR("sv_motd");
 435                 BADCVAR("sv_public");
 436                 BADCVAR("sv_ready_restart");
 437                 BADCVAR("sv_status_privacy");
 438                 BADCVAR("sv_taunt");
 439                 BADCVAR("sv_vote_call");
 440                 BADCVAR("sv_vote_commands");
 441                 BADCVAR("sv_vote_majority_factor");
 442                 BADCVAR("sv_vote_master");
 443                 BADCVAR("sv_vote_master_commands");
 444                 BADCVAR("sv_vote_master_password");
 445                 BADCVAR("sv_vote_simple_majority_factor");
 446                 BADCVAR("teamplay_mode");
 447                 BADCVAR("timelimit_override");
 448                 BADPREFIX("g_warmup_");
 449                 BADPREFIX("sv_ready_restart_");
 450
 451                 // mutators that announce themselves properly to the server browser
 452                 BADCVAR("g_instagib");
 453                 BADCVAR("g_new_toys");
 454                 BADCVAR("g_nix");
 455                 BADCVAR("g_grappling_hook");
 456                 BADCVAR("g_jetpack");
 457
 458 #undef BADPRESUFFIX
 459 #undef BADPREFIX
 460 #undef BADCVAR
 461
 462                 if(pureadding)
 463                 {
 464                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 465                         if(strlen(cvar_purechanges) > 16384)
 466                         {
 467                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 468                                 pureadding = 0;
 469                         }
 470                 }
 471                 ++cvar_purechanges_count;
 472                 // WARNING: this variable is used for the server list
 473                 // NEVER dare to skip this code!
 474                 // Hacks to intentionally appearing as "pure server" even though you DO have
 475                 // modified settings may be punished by removal from the server list.
 476                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 477                 // though.
 478         }
 479         buf_del(h);
 480         if(cvar_changes == "")
 481                 cvar_changes = "// this server runs at default server settings\n";
 482         else
 483                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 484         cvar_changes = strzone(cvar_changes);
 485         if(cvar_purechanges == "")
 486                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 487         else
 488                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 489         cvar_purechanges = strzone(cvar_purechanges);
 490 }
 491
 492 void detect_maptype()
 493 {
 494 #if 0
 495         vector o, v;
 496         float i;
 497
 498         for (;;)
 499         {
 500                 o = world.mins;
 501                 o.x += random() * (world.maxs.x - world.mins.x);
 502                 o.y += random() * (world.maxs.y - world.mins.y);
 503                 o.z += random() * (world.maxs.z - world.mins.z);
 504
 505                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, NULL);
 506                 if(trace_fraction == 1)
 507                         continue;
 508
 509                 v = trace_endpos;
 510
 511                 for(i = 0; i < 64; i += 4)
 512                 {
 513                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
 514         if(trace_fraction == 1)
 515                 continue;
 516                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 517                 }
 518
 519                 break;
 520         }
 521 #endif
 522 }
 523
 524 entity randomseed;
 525 bool RandomSeed_Send(entity this, entity to, int sf)
 526 {
 527         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 528         WriteShort(MSG_ENTITY, this.cnt);
 529         return true;
 530 }
 531 void RandomSeed_Think(entity this)
 532 {
 533         this.cnt = bound(0, floor(random() * 65536), 65535);
 534         this.nextthink = time + 5;
 535
 536         this.SendFlags |= 1;
 537 }
 538 void RandomSeed_Spawn()
 539 {
 540         randomseed = new_pure(randomseed);
 541         setthink(randomseed, RandomSeed_Think);
 542         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 543
 544         getthink(randomseed)(randomseed); // sets random seed and nextthink
 545 }
 546
 547 spawnfunc(__init_dedicated_server)
 548 {
 549         // handler for _init/_init map (only for dedicated server initialization)
 550
 551         world_initialized = -1; // don't complain
 552         cvar = cvar_normal;
 553         cvar_string = cvar_string_normal;
 554         cvar_set = cvar_set_normal;
 555
 556         delete_fn = remove_unsafely;
 557
 558         entity e = spawn();
 559         setthink(e, GotoFirstMap);
 560         e.nextthink = time; // this is usually 1 at this point
 561
 562         e = new(info_player_deathmatch);  // safeguard against player joining
 563
 564         this.classname = "worldspawn"; // safeguard against various stuff ;)
 565
 566         // needs to be done so early because of the constants they create
 567         static_init();
 568         static_init_late();
 569         static_init_precache();
 570
 571         IL_PUSH(g_spawnpoints, e); // just incase
 572
 573         MapInfo_Enumerate();
 574         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 575 }
 576
 577 void __init_dedicated_server_shutdown() {
 578         MapInfo_Shutdown();
 579 }
 580
 581 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override)
 582 {
 583         if(!autocvar_g_campaign)
 584         {
 585                 if(fraglimit_override >= 0) cvar_set("fraglimit", ftos(fraglimit_override));
 586                 if(timelimit_override >= 0) cvar_set("timelimit", ftos(timelimit_override));
 587                 if(leadlimit_override >= 0) cvar_set("leadlimit", ftos(leadlimit_override));
 588                 if(qualifying_override >= 0) cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 589         }
 590         limits_are_set = true;
 591 }
 592
 593 void Map_MarkAsRecent(string m);
 594 float world_already_spawned;
 595 void Nagger_Init();
 596 void ClientInit_Spawn();
 597 void WeaponStats_Init();
 598 void WeaponStats_Shutdown();
 599 spawnfunc(worldspawn)
 600 {
 601         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 602
 603     bool wantrestart = false;
 604         {
 605                 if (!server_is_dedicated)
 606                 {
 607                         // force unloading of server pk3 files when starting a listen server
 608                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 609                         // restore csqc_progname too
 610                         string expect = "csprogs.dat";
 611                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 612                         cvar_set_normal("csqc_progname", expect);
 613                 }
 614                 else
 615                 {
 616                         // Try to use versioned csprogs from pk3
 617                         // Only ever use versioned csprogs.dat files on dedicated servers;
 618                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 619                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 620                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 621                         string select = "csprogs.dat";
 622                         if (fexists(pk3csprogs)) select = pk3csprogs;
 623                         if (cvar_string_normal("csqc_progname") != select)
 624                         {
 625                                 cvar_set_normal("csqc_progname", select);
 626                                 wantrestart = true;
 627                         }
 628                         // Check for updates on startup
 629                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 630                         int sentinel = fopen("progs.txt", FILE_READ);
 631                         if (sentinel >= 0)
 632                         {
 633                                 string switchversion = fgets(sentinel);
 634                                 fclose(sentinel);
 635                                 if (switchversion != "" && switchversion != WATERMARK)
 636                                 {
 637                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 638                                         // if it doesn't exist, assume either:
 639                                         //   a) the current program was overwritten
 640                                         //   b) this is a client only update
 641                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 642                                         if (fexists(newprogs))
 643                                         {
 644                                                 cvar_set_normal("sv_progs", newprogs);
 645                                                 wantrestart = true;
 646                                         }
 647                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 648                                         if (fexists(newcsprogs))
 649                                         {
 650                                                 cvar_set_normal("csqc_progname", newcsprogs);
 651                                                 wantrestart = true;
 652                                         }
 653                                 }
 654                         }
 655                 }
 656                 if (wantrestart)
 657                 {
 658                         LOG_INFOF("Restart requested\n");
 659                         changelevel(mapname);
 660                         // let initialization continue, shutdown depends on it
 661                 }
 662         }
 663
 664         cvar = cvar_normal;
 665         cvar_string = cvar_string_normal;
 666         cvar_set = cvar_set_normal;
 667
 668         if(world_already_spawned)
 669                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 670         world_already_spawned = true;
 671
 672         delete_fn = remove_safely; // during spawning, watch what you remove!
 673
 674         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 675
 676         maxclients = 0;
 677         for (entity head = nextent(NULL); head; head = nextent(head))
 678         {
 679                 ++maxclients;
 680         }
 681
 682         // needs to be done so early because of the constants they create
 683         static_init();
 684
 685         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 686
 687         TemporaryDB = db_create();
 688
 689         // 0 normal
 690         lightstyle(0, "m");
 691
 692         // 1 FLICKER (first variety)
 693         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 694
 695         // 2 SLOW STRONG PULSE
 696         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 697
 698         // 3 CANDLE (first variety)
 699         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 700
 701         // 4 FAST STROBE
 702         lightstyle(4, "mamamamamama");
 703
 704         // 5 GENTLE PULSE 1
 705         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 706
 707         // 6 FLICKER (second variety)
 708         lightstyle(6, "nmonqnmomnmomomno");
 709
 710         // 7 CANDLE (second variety)
 711         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 712
 713         // 8 CANDLE (third variety)
 714         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 715
 716         // 9 SLOW STROBE (fourth variety)
 717         lightstyle(9, "aaaaaaaazzzzzzzz");
 718
 719         // 10 FLUORESCENT FLICKER
 720         lightstyle(10, "mmamammmmammamamaaamammma");
 721
 722         // 11 SLOW PULSE NOT FADE TO BLACK
 723         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 724
 725         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 726
 727         // 63 testing
 728         lightstyle(63, "a");
 729
 730         if(autocvar_g_campaign)
 731                 CampaignPreInit();
 732
 733         Map_MarkAsRecent(mapname);
 734
 735         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 736
 737         InitGameplayMode();
 738         static_init_late();
 739         static_init_precache();
 740         readlevelcvars();
 741         GrappleHookInit();
 742
 743         if(!limits_are_set)
 744                 SetLimits(autocvar_fraglimit_override, autocvar_leadlimit_override, autocvar_timelimit_override, -1);
 745
 746         if(warmup_limit == 0)
 747                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 748
 749         player_count = 0;
 750         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 751         if(bot_waypoints_for_items == 1)
 752                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 753                         bot_waypoints_for_items = 0;
 754
 755         precache();
 756
 757         WaypointSprite_Init();
 758
 759         GameLogInit(); // prepare everything
 760         // NOTE for matchid:
 761         // changing the logic generating it is okay. But:
 762         // it HAS to stay <= 64 chars
 763         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 764         if(autocvar_sv_eventlog)
 765         {
 766                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 767                 matchid = strzone(s);
 768
 769                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 770                 s = ":gameinfo:mutators:LIST";
 771
 772                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 773                 s = M_ARGV(0, string);
 774
 775                 // initialiation stuff, not good in the mutator system
 776                 if(!autocvar_g_use_ammunition)
 777                         s = strcat(s, ":no_use_ammunition");
 778
 779                 // initialiation stuff, not good in the mutator system
 780                 if(autocvar_g_pickup_items == 0)
 781                         s = strcat(s, ":no_pickup_items");
 782                 if(autocvar_g_pickup_items > 0)
 783                         s = strcat(s, ":pickup_items");
 784
 785                 // initialiation stuff, not good in the mutator system
 786                 if(autocvar_g_weaponarena != "0")
 787                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 788
 789                 // TODO to mutator system
 790                 if(autocvar_g_norecoil)
 791                         s = strcat(s, ":norecoil");
 792
 793                 // TODO to mutator system
 794                 if(autocvar_g_powerups == 0)
 795                         s = strcat(s, ":no_powerups");
 796                 if(autocvar_g_powerups > 0)
 797                         s = strcat(s, ":powerups");
 798
 799                 GameLogEcho(s);
 800                 GameLogEcho(":gameinfo:end");
 801         }
 802         else
 803                 matchid = strzone(ftos(random()));
 804
 805         cvar_set("nextmap", "");
 806
 807         SetDefaultAlpha();
 808
 809         if(autocvar_g_campaign)
 810                 CampaignPostInit();
 811
 812         Ban_LoadBans();
 813
 814         MapInfo_Enumerate();
 815         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 816
 817         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 818         {
 819                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 820                 if(fd != -1)
 821                 {
 822                         string s;
 823                         while((s = fgets(fd)))
 824                         {
 825                                 int l = tokenize_console(s);
 826                                 if(l < 2)
 827                                         continue;
 828                                 if(argv(0) == "cd")
 829                                 {
 830                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 831                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 832                                 }
 833                                 else if(argv(0) == "fog")
 834                                 {
 835                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 836                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 837                                 }
 838                                 else if(argv(0) == "set")
 839                                 {
 840                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 841                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 842                                 }
 843                                 else if(argv(0) != "//")
 844                                 {
 845                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 846                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 847                                 }
 848                         }
 849                         fclose(fd);
 850                 }
 851         }
 852
 853         WeaponStats_Init();
 854
 855         Nagger_Init();
 856
 857         next_pingtime = time + 5;
 858
 859         detect_maptype();
 860
 861         // set up information replies for clients and server to use
 862         maplist_reply = strzone(getmaplist());
 863         lsmaps_reply = strzone(getlsmaps());
 864         monsterlist_reply = strzone(getmonsterlist());
 865         for(int i = 0; i < 10; ++i)
 866         {
 867                 string s = getrecords(i);
 868                 if (s)
 869                         records_reply[i] = strzone(s);
 870         }
 871         ladder_reply = strzone(getladder());
 872         rankings_reply = strzone(getrankings());
 873
 874         // begin other init
 875         ClientInit_Spawn();
 876         RandomSeed_Spawn();
 877         PingPLReport_Spawn();
 878
 879         CheatInit();
 880
 881         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 882
 883         // fill sv_curl_serverpackages from .serverpackage files
 884         if (autocvar_sv_curl_serverpackages_auto)
 885         {
 886                 string s = "csprogs-" WATERMARK ".txt";
 887                 // remove automatically managed files from the list to prevent duplicates
 888                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 889                 {
 890                         string pkg = argv(i);
 891                         if (startsWith(pkg, "csprogs-")) continue;
 892                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 893                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 894                         s = cons(s, pkg);
 895                 }
 896                 // add automatically managed files to the list
 897                 #define X(match) MACRO_BEGIN { \
 898                         int fd = search_begin(match, true, false); \
 899                         if (fd >= 0) \
 900                         { \
 901                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 902                                 { \
 903                                         s = cons(s, search_getfilename(fd, i)); \
 904                                 } \
 905                                 search_end(fd); \
 906                         } \
 907                 } MACRO_END
 908                 X("*-serverpackage.txt");
 909                 X("*.serverpackage");
 910                 #undef X
 911                 cvar_set("sv_curl_serverpackages", s);
 912         }
 913
 914         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 915         modname = "Xonotic";
 916         // physics/balance/config changes that count as mod
 917         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 918                 modname = cvar_string("g_mod_physics");
 919         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 920                 modname = cvar_string("g_mod_balance");
 921         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 922                 modname = cvar_string("g_mod_config");
 923         // extra mutators that deserve to count as mod
 924         MUTATOR_CALLHOOK(SetModname, modname);
 925         modname = M_ARGV(0, string);
 926
 927         // save it for later
 928         modname = strzone(modname);
 929
 930         WinningConditionHelper(this); // set worldstatus
 931
 932         world_initialized = 1;
 933 }
 934
 935 spawnfunc(light)
 936 {
 937         //makestatic (this); // Who the f___ did that?
 938         delete(this);
 939 }
 940
 941 string GetGametype()
 942 {
 943         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 944 }
 945
 946 string GetMapname()
 947 {
 948         return mapname;
 949 }
 950
 951 float Map_Count, Map_Current;
 952 string Map_Current_Name;
 953
 954 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 955 float GetMaplistPosition()
 956 {
 957         float pos, idx;
 958         string map;
 959
 960         map = GetMapname();
 961         idx = autocvar_g_maplist_index;
 962
 963         if(idx >= 0)
 964                 if(idx < Map_Count)
 965                         if(map == argv(idx))
 966                                 return idx;
 967
 968         for(pos = 0; pos < Map_Count; ++pos)
 969                 if(map == argv(pos))
 970                         return pos;
 971
 972         // resume normal maplist rotation if current map is not in g_maplist
 973         return idx;
 974 }
 975
 976 float MapHasRightSize(string map)
 977 {
 978         float fh;
 979         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 980         if(autocvar_g_maplist_check_waypoints)
 981         {
 982                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 983                 if(!fexists(strcat("maps/", map, ".waypoints")))
 984                 {
 985                         LOG_TRACE(": no waypoints");
 986                         return false;
 987                 }
 988                 LOG_TRACE(": has waypoints");
 989         }
 990
 991         // open map size restriction file
 992         LOG_TRACE("opensize "); LOG_TRACE(map);
 993         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 994         if(fh >= 0)
 995         {
 996                 float mapmin, mapmax;
 997                 LOG_TRACE(": ok, ");
 998                 mapmin = stof(fgets(fh));
 999                 mapmax = stof(fgets(fh));
1000                 fclose(fh);
1001                 if(player_count < mapmin)
1002                 {
1003                         LOG_TRACE("not enough");
1004                         return false;
1005                 }
1006                 if(player_count > mapmax)
1007                 {
1008                         LOG_TRACE("too many");
1009                         return false;
1010                 }
1011                 LOG_TRACE("right size");
1012                 return true;
1013         }
1014         LOG_TRACE(": not found");
1015         return true;
1016 }
1017
1018 string Map_Filename(float position)
1019 {
1020         return strcat("maps/", argv(position), ".bsp");
1021 }
1022
1023 void Map_MarkAsRecent(string m)
1024 {
1025         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1026 }
1027
1028 float Map_IsRecent(string m)
1029 {
1030         return strhasword(autocvar_g_maplist_mostrecent, m);
1031 }
1032
1033 float Map_Check(float position, float pass)
1034 {
1035         string filename;
1036         string map_next;
1037         map_next = argv(position);
1038         if(pass <= 1)
1039         {
1040                 if(Map_IsRecent(map_next))
1041                         return 0;
1042         }
1043         filename = Map_Filename(position);
1044         if(MapInfo_CheckMap(map_next))
1045         {
1046                 if(pass == 2)
1047                         return 1;
1048                 if(MapHasRightSize(map_next))
1049                         return 1;
1050                 return 0;
1051         }
1052         else
1053                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1054
1055         return 0;
1056 }
1057
1058 void Map_Goto_SetStr(string nextmapname)
1059 {
1060         if(getmapname_stored != "")
1061                 strunzone(getmapname_stored);
1062         if(nextmapname == "")
1063                 getmapname_stored = "";
1064         else
1065                 getmapname_stored = strzone(nextmapname);
1066 }
1067
1068 void Map_Goto_SetFloat(float position)
1069 {
1070         cvar_set("g_maplist_index", ftos(position));
1071         Map_Goto_SetStr(argv(position));
1072 }
1073
1074 void Map_Goto(float reinit)
1075 {
1076         MapInfo_LoadMap(getmapname_stored, reinit);
1077 }
1078
1079 // return codes of map selectors:
1080 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1081 //   -2 = permanent failure
1082 float() MaplistMethod_Iterate = // usual method
1083 {
1084         float pass, i;
1085
1086         LOG_TRACE("Trying MaplistMethod_Iterate");
1087
1088         for(pass = 1; pass <= 2; ++pass)
1089         {
1090                 for(i = 1; i < Map_Count; ++i)
1091                 {
1092                         float mapindex;
1093                         mapindex = (i + Map_Current) % Map_Count;
1094                         if(Map_Check(mapindex, pass))
1095                                 return mapindex;
1096                 }
1097         }
1098         return -1;
1099 }
1100
1101 float() MaplistMethod_Repeat = // fallback method
1102 {
1103         LOG_TRACE("Trying MaplistMethod_Repeat");
1104
1105         if(Map_Check(Map_Current, 2))
1106                 return Map_Current;
1107         return -2;
1108 }
1109
1110 float() MaplistMethod_Random = // random map selection
1111 {
1112         float i, imax;
1113
1114         LOG_TRACE("Trying MaplistMethod_Random");
1115
1116         imax = 42;
1117
1118         for(i = 0; i <= imax; ++i)
1119         {
1120                 float mapindex;
1121                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1122                 if(Map_Check(mapindex, 1))
1123                         return mapindex;
1124         }
1125         return -1;
1126 }
1127
1128 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1129 // the exponent sets a bias on the map selection:
1130 // the higher the exponent, the less likely "shortly repeated" same maps are
1131 {
1132         float i, j, imax, insertpos;
1133
1134         LOG_TRACE("Trying MaplistMethod_Shuffle");
1135
1136         imax = 42;
1137
1138         for(i = 0; i <= imax; ++i)
1139         {
1140                 string newlist;
1141
1142                 // now reinsert this at another position
1143                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1144                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1145                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1146                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1147
1148                 // insert the current map there
1149                 newlist = "";
1150                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1151                         newlist = strcat(newlist, " ", argv(j));
1152                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1153                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1154                         newlist = strcat(newlist, " ", argv(j));
1155                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1156                 cvar_set("g_maplist", newlist);
1157                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1158
1159                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1160                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1161                 if(Map_Check(Map_Current, 1))
1162                         return Map_Current;
1163         }
1164         return -1;
1165 }
1166
1167 void Maplist_Init()
1168 {
1169         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1170         float i;
1171         for (i = 0; i < Map_Count; ++i)
1172                 if (Map_Check(i, 2))
1173                         break;
1174         if (i == Map_Count)
1175         {
1176                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1177                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1178                 if(autocvar_g_maplist_shuffle)
1179                         ShuffleMaplist();
1180                 localcmd("\nmenu_cmd sync\n");
1181                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1182         }
1183         if(Map_Count == 0)
1184                 error("empty maplist, cannot select a new map");
1185         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1186
1187         if(Map_Current_Name)
1188                 strunzone(Map_Current_Name);
1189         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1190         // this may or may not be correct, but who cares, in the worst case a map
1191         // isn't chosen in the first pass that should have been
1192 }
1193
1194 string GetNextMap()
1195 {
1196         float nextMap;
1197
1198         Maplist_Init();
1199         nextMap = -1;
1200
1201         if(nextMap == -1)
1202                 if(autocvar_g_maplist_shuffle > 0)
1203                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1204
1205         if(nextMap == -1)
1206                 if(autocvar_g_maplist_selectrandom)
1207                         nextMap = MaplistMethod_Random();
1208
1209         if(nextMap == -1)
1210                 nextMap = MaplistMethod_Iterate();
1211
1212         if(nextMap == -1)
1213                 nextMap = MaplistMethod_Repeat();
1214
1215         if(nextMap >= 0)
1216         {
1217                 Map_Goto_SetFloat(nextMap);
1218                 return getmapname_stored;
1219         }
1220
1221         return "";
1222 }
1223
1224 float DoNextMapOverride(float reinit)
1225 {
1226         if(autocvar_g_campaign)
1227         {
1228                 CampaignPostIntermission();
1229                 alreadychangedlevel = true;
1230                 return true;
1231         }
1232         if(autocvar_quit_when_empty)
1233         {
1234                 if(player_count <= currentbots)
1235                 {
1236                         localcmd("quit\n");
1237                         alreadychangedlevel = true;
1238                         return true;
1239                 }
1240         }
1241         if(autocvar_quit_and_redirect != "")
1242         {
1243                 redirection_target = strzone(autocvar_quit_and_redirect);
1244                 alreadychangedlevel = true;
1245                 return true;
1246         }
1247         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1248         {
1249                 localcmd("restart\n");
1250                 alreadychangedlevel = true;
1251                 return true;
1252         }
1253         if(autocvar_nextmap != "")
1254         {
1255                 string m;
1256                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1257                 cvar_set("nextmap",m);
1258
1259                 if(!m || gametypevote)
1260                         return false;
1261                 if(autocvar_sv_vote_gametype)
1262                 {
1263                         Map_Goto_SetStr(m);
1264                         return false;
1265                 }
1266
1267                 if(MapInfo_CheckMap(m))
1268                 {
1269                         Map_Goto_SetStr(m);
1270                         Map_Goto(reinit);
1271                         alreadychangedlevel = true;
1272                         return true;
1273                 }
1274         }
1275         if(!reinit && autocvar_lastlevel)
1276         {
1277                 cvar_settemp_restore();
1278                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1279                 alreadychangedlevel = true;
1280                 return true;
1281         }
1282         return false;
1283 }
1284
1285 void GotoNextMap(float reinit)
1286 {
1287         //string nextmap;
1288         //float n, nummaps;
1289         //string s;
1290         if (alreadychangedlevel)
1291                 return;
1292         alreadychangedlevel = true;
1293
1294         string nextMap;
1295
1296         nextMap = GetNextMap();
1297         if(nextMap == "")
1298                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1299         Map_Goto(reinit);
1300 }
1301
1302
1303 /*
1304 ============
1305 IntermissionThink
1306
1307 When the player presses attack or jump, change to the next level
1308 ============
1309 */
1310 .float autoscreenshot;
1311 void IntermissionThink(entity this)
1312 {
1313         FixIntermissionClient(this);
1314
1315         float server_screenshot = (autocvar_sv_autoscreenshot && this.cvar_cl_autoscreenshot);
1316         float client_screenshot = (this.cvar_cl_autoscreenshot == 2);
1317
1318         if( (server_screenshot || client_screenshot)
1319                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1320         {
1321                 this.autoscreenshot = -1;
1322                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1323                 return;
1324         }
1325
1326         if (time < intermission_exittime)
1327                 return;
1328
1329         if(!mapvote_initialized)
1330                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1331                         return;
1332
1333         MapVote_Start();
1334 }
1335
1336 /*
1337 ============
1338 FindIntermission
1339
1340 Returns the entity to view from
1341 ============
1342 */
1343 /*
1344 entity FindIntermission()
1345 {
1346         local   entity spot;
1347         local   float cyc;
1348
1349 // look for info_intermission first
1350         spot = find(NULL, classname, "info_intermission");
1351         if (spot)
1352         {       // pick a random one
1353                 cyc = random() * 4;
1354                 while (cyc > 1)
1355                 {
1356                         spot = find(spot, classname, "info_intermission");
1357                         if (!spot)
1358                                 spot = find(spot, classname, "info_intermission");
1359                         cyc = cyc - 1;
1360                 }
1361                 return spot;
1362         }
1363
1364 // then look for the start position
1365         spot = find(NULL, classname, "info_player_start");
1366         if (spot)
1367                 return spot;
1368
1369 // testinfo_player_start is only found in regioned levels
1370         spot = find(NULL, classname, "testplayerstart");
1371         if (spot)
1372                 return spot;
1373
1374 // then look for the start position
1375         spot = find(NULL, classname, "info_player_deathmatch");
1376         if (spot)
1377                 return spot;
1378
1379         //objerror ("FindIntermission: no spot");
1380         return NULL;
1381 }
1382 */
1383
1384 /*
1385 ===============================================================================
1386
1387 RULES
1388
1389 ===============================================================================
1390 */
1391
1392 void DumpStats(float final)
1393 {
1394         float file;
1395         string s;
1396         float to_console;
1397         float to_eventlog;
1398         float to_file;
1399         float i;
1400
1401         to_console = autocvar_sv_logscores_console;
1402         to_eventlog = autocvar_sv_eventlog;
1403         to_file = autocvar_sv_logscores_file;
1404
1405         if(!final)
1406         {
1407                 to_console = true; // always print printstats replies
1408                 to_eventlog = false; // but never print them to the event log
1409         }
1410
1411         if(to_eventlog)
1412                 if(autocvar_sv_eventlog_console)
1413                         to_console = false; // otherwise we get the output twice
1414
1415         if(final)
1416                 s = ":scores:";
1417         else
1418                 s = ":status:";
1419         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1420
1421         if(to_console)
1422                 LOG_INFO(s, "\n");
1423         if(to_eventlog)
1424                 GameLogEcho(s);
1425
1426         file = -1;
1427         if(to_file)
1428         {
1429                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1430                 if(file == -1)
1431                         to_file = false;
1432                 else
1433                         fputs(file, strcat(s, "\n"));
1434         }
1435
1436         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1437         if(to_console)
1438                 LOG_INFO(s, "\n");
1439         if(to_eventlog)
1440                 GameLogEcho(s);
1441         if(to_file)
1442                 fputs(file, strcat(s, "\n"));
1443
1444         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1445                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1446                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1447                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1448                         s = strcat(s, ftos(it.team), ":");
1449                 else
1450                         s = strcat(s, "spectator:");
1451
1452                 if(to_console)
1453                         LOG_INFO(s, playername(it, false), "\n");
1454                 if(to_eventlog)
1455                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1456                 if(to_file)
1457                         fputs(file, strcat(s, playername(it, false), "\n"));
1458         ));
1459
1460         if(teamplay)
1461         {
1462                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1463                 if(to_console)
1464                         LOG_INFO(s, "\n");
1465                 if(to_eventlog)
1466                         GameLogEcho(s);
1467                 if(to_file)
1468                         fputs(file, strcat(s, "\n"));
1469
1470                 for(i = 1; i < 16; ++i)
1471                 {
1472                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1473                         s = strcat(s, ":", ftos(i));
1474                         if(to_console)
1475                                 LOG_INFO(s, "\n");
1476                         if(to_eventlog)
1477                                 GameLogEcho(s);
1478                         if(to_file)
1479                                 fputs(file, strcat(s, "\n"));
1480                 }
1481         }
1482
1483         if(to_console)
1484                 LOG_INFO(":end\n");
1485         if(to_eventlog)
1486                 GameLogEcho(":end");
1487         if(to_file)
1488         {
1489                 fputs(file, ":end\n");
1490                 fclose(file);
1491         }
1492 }
1493
1494 void FixIntermissionClient(entity e)
1495 {
1496         if(!e.autoscreenshot) // initial call
1497         {
1498                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1499                 e.health = -2342;
1500                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1501                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1502                 {
1503                     .entity weaponentity = weaponentities[slot];
1504                         if(e.(weaponentity))
1505                         {
1506                                 e.(weaponentity).effects = EF_NODRAW;
1507                                 if (e.(weaponentity).weaponchild)
1508                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1509                         }
1510                 }
1511                 if(IS_REAL_CLIENT(e))
1512                 {
1513                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1514                         RandomSelection_Init();
1515                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1516                                 RandomSelection_AddString(it, 1, 1);
1517                         ));
1518                         if (RandomSelection_chosen_string != "")
1519                         {
1520                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1521                         }
1522                         msg_entity = e;
1523                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1524                 }
1525         }
1526 }
1527
1528 /*
1529 go to the next level for deathmatch
1530 only called if a time or frag limit has expired
1531 */
1532 void NextLevel()
1533 {
1534         game_stopped = true;
1535         intermission_running = 1; // game over
1536
1537         // enforce a wait time before allowing changelevel
1538         if(player_count > 0)
1539                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1540         else
1541                 intermission_exittime = -1;
1542
1543         /*
1544         WriteByte (MSG_ALL, SVC_CDTRACK);
1545         WriteByte (MSG_ALL, 3);
1546         WriteByte (MSG_ALL, 3);
1547         // done in FixIntermission
1548         */
1549
1550         //pos = FindIntermission ();
1551
1552         VoteReset();
1553
1554         DumpStats(true);
1555
1556         // send statistics
1557         PlayerStats_GameReport(true);
1558         WeaponStats_Shutdown();
1559
1560         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1561
1562         if(autocvar_sv_eventlog)
1563                 GameLogEcho(":gameover");
1564
1565         GameLogClose();
1566
1567         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1568                 FixIntermissionClient(it);
1569                 if(it.winning)
1570                         bprint(playername(it, false), " ^7wins.\n");
1571         ));
1572
1573         target_music_kill();
1574
1575         if(autocvar_g_campaign)
1576                 CampaignPreIntermission();
1577
1578         MUTATOR_CALLHOOK(MatchEnd);
1579
1580         localcmd("\nsv_hook_gameend\n");
1581 }
1582
1583 /*
1584 ============
1585 CheckRules_Player
1586
1587 Exit deathmatch games upon conditions
1588 ============
1589 */
1590 void CheckRules_Player(entity this)
1591 {
1592         if (game_stopped) // someone else quit the game already
1593                 return;
1594
1595         if(!IS_DEAD(this))
1596                 this.play_time += frametime;
1597
1598         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1599         //   (div0: and that in CheckRules_World please)
1600 }
1601
1602
1603 float InitiateSuddenDeath()
1604 {
1605         // Check first whether normal overtimes could be added before initiating suddendeath mode
1606         // - for this timelimit_overtime needs to be >0 of course
1607         // - also check the winning condition calculated in the previous frame and only add normal overtime
1608         //   again, if at the point at which timelimit would be extended again, still no winner was found
1609         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1610         {
1611                 return 1; // need to call InitiateOvertime later
1612         }
1613         else
1614         {
1615                 if(!checkrules_suddendeathend)
1616                 {
1617                         if(autocvar_g_campaign)
1618                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1619                         else
1620                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1621                         if(g_race && !g_race_qualifying)
1622                                 race_StartCompleting();
1623                 }
1624                 return 0;
1625         }
1626 }
1627
1628 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1629 {
1630         ++checkrules_overtimesadded;
1631         //add one more overtime by simply extending the timelimit
1632         float tl;
1633         tl = autocvar_timelimit;
1634         tl += autocvar_timelimit_overtime;
1635         cvar_set("timelimit", ftos(tl));
1636
1637         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1638 }
1639
1640 float GetWinningCode(float fraglimitreached, float equality)
1641 {
1642         if(autocvar_g_campaign == 1)
1643                 if(fraglimitreached)
1644                         return WINNING_YES;
1645                 else
1646                         return WINNING_NO;
1647
1648         else
1649                 if(equality)
1650                         if(fraglimitreached)
1651                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1652                         else
1653                                 return WINNING_NEVER;
1654                 else
1655                         if(fraglimitreached)
1656                                 return WINNING_YES;
1657                         else
1658                                 return WINNING_NO;
1659 }
1660
1661 // set the .winning flag for exactly those players with a given field value
1662 void SetWinners(.float field, float value)
1663 {
1664         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1665 }
1666
1667 // set the .winning flag for those players with a given field value
1668 void AddWinners(.float field, float value)
1669 {
1670         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1671                 if(it.(field) == value)
1672                         it.winning = 1;
1673         ));
1674 }
1675
1676 // clear the .winning flags
1677 void ClearWinners()
1678 {
1679         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1680 }
1681
1682 void ShuffleMaplist()
1683 {
1684         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1685 }
1686
1687 float leaderfrags;
1688 float WinningCondition_Scores(float limit, float leadlimit)
1689 {
1690         float limitreached;
1691
1692         // TODO make everything use THIS winning condition (except LMS)
1693         WinningConditionHelper(NULL);
1694
1695         if(teamplay)
1696         {
1697                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1698                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1699                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1700                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1701         }
1702
1703         ClearWinners();
1704         if(WinningConditionHelper_winner)
1705                 WinningConditionHelper_winner.winning = 1;
1706         if(WinningConditionHelper_winnerteam >= 0)
1707                 SetWinners(team, WinningConditionHelper_winnerteam);
1708
1709         if(WinningConditionHelper_lowerisbetter)
1710         {
1711                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1712                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1713                 limit = -limit;
1714         }
1715
1716         if(WinningConditionHelper_zeroisworst)
1717                 leadlimit = 0; // not supported in this mode
1718
1719         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1720         // these modes always score in increments of 1, thus this makes sense
1721         {
1722                 if(leaderfrags != WinningConditionHelper_topscore)
1723                 {
1724                         leaderfrags = WinningConditionHelper_topscore;
1725
1726                         if (limit)
1727                         if (leaderfrags == limit - 1)
1728                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1729                         else if (leaderfrags == limit - 2)
1730                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1731                         else if (leaderfrags == limit - 3)
1732                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1733                 }
1734         }
1735
1736         limitreached = false;
1737         if(limit)
1738                 if(WinningConditionHelper_topscore >= limit)
1739                         limitreached = true;
1740         if(leadlimit)
1741         {
1742                 float leadlimitreached;
1743                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1744                 if(autocvar_leadlimit_and_fraglimit)
1745                         limitreached = (limitreached && leadlimitreached);
1746                 else
1747                         limitreached = (limitreached || leadlimitreached);
1748         }
1749
1750         if(limit)
1751                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1752
1753         return GetWinningCode(
1754                 WinningConditionHelper_topscore && limitreached,
1755                 WinningConditionHelper_equality
1756         );
1757 }
1758
1759 float WinningCondition_RanOutOfSpawns()
1760 {
1761         if(have_team_spawns <= 0)
1762                 return WINNING_NO;
1763
1764         if(!autocvar_g_spawn_useallspawns)
1765                 return WINNING_NO;
1766
1767         if(!some_spawn_has_been_used)
1768                 return WINNING_NO;
1769
1770         team1_score = team2_score = team3_score = team4_score = 0;
1771
1772         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1773                 switch(it.team)
1774                 {
1775                         case NUM_TEAM_1: team1_score = 1; break;
1776                         case NUM_TEAM_2: team2_score = 1; break;
1777                         case NUM_TEAM_3: team3_score = 1; break;
1778                         case NUM_TEAM_4: team4_score = 1; break;
1779                 }
1780         ));
1781
1782         IL_EACH(g_spawnpoints, true,
1783         {
1784                 switch(it.team)
1785                 {
1786                         case NUM_TEAM_1: team1_score = 1; break;
1787                         case NUM_TEAM_2: team2_score = 1; break;
1788                         case NUM_TEAM_3: team3_score = 1; break;
1789                         case NUM_TEAM_4: team4_score = 1; break;
1790                 }
1791         });
1792
1793         ClearWinners();
1794         if(team1_score + team2_score + team3_score + team4_score == 0)
1795         {
1796                 checkrules_equality = true;
1797                 return WINNING_YES;
1798         }
1799         else if(team1_score + team2_score + team3_score + team4_score == 1)
1800         {
1801                 float t, i;
1802                 if(team1_score)
1803                         t = NUM_TEAM_1;
1804                 else if(team2_score)
1805                         t = NUM_TEAM_2;
1806                 else if(team3_score)
1807                         t = NUM_TEAM_3;
1808                 else // if(team4_score)
1809                         t = NUM_TEAM_4;
1810                 CheckAllowedTeams(NULL);
1811                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1812                 {
1813                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1814                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1815                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1816                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1817                 }
1818
1819                 AddWinners(team, t);
1820                 return WINNING_YES;
1821         }
1822         else
1823                 return WINNING_NO;
1824 }
1825
1826 /*
1827 ============
1828 CheckRules_World
1829
1830 Exit deathmatch games upon conditions
1831 ============
1832 */
1833 void CheckRules_World()
1834 {
1835         float timelimit;
1836         float fraglimit;
1837         float leadlimit;
1838
1839         VoteThink();
1840         MapVote_Think();
1841
1842         SetDefaultAlpha();
1843
1844         if (intermission_running) // someone else quit the game already
1845         {
1846                 if(player_count == 0) // Nobody there? Then let's go to the next map
1847                         MapVote_Start();
1848                         // this will actually check the player count in the next frame
1849                         // again, but this shouldn't hurt
1850                 return;
1851         }
1852
1853         timelimit = autocvar_timelimit * 60;
1854         fraglimit = autocvar_fraglimit;
1855         leadlimit = autocvar_leadlimit;
1856
1857         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1858         {
1859                 if(timelimit > 0)
1860                         timelimit = 0; // timelimit is not made for warmup
1861                 if(fraglimit > 0)
1862                         fraglimit = 0; // no fraglimit for now
1863                 leadlimit = 0; // no leadlimit for now
1864         }
1865
1866         if(timelimit > 0)
1867         {
1868                 timelimit += game_starttime;
1869         }
1870         else if (timelimit < 0)
1871         {
1872                 // endmatch
1873                 NextLevel();
1874                 return;
1875         }
1876
1877         float wantovertime;
1878         wantovertime = 0;
1879
1880         if(timelimit > game_starttime)
1881                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1882         else
1883                 game_completion_ratio = 0;
1884
1885         if(checkrules_suddendeathend)
1886         {
1887                 if(!checkrules_suddendeathwarning)
1888                 {
1889                         checkrules_suddendeathwarning = true;
1890                         if(g_race && !g_race_qualifying)
1891                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1892                         else
1893                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1894                 }
1895         }
1896         else
1897         {
1898                 if (timelimit && time >= timelimit)
1899                 {
1900                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1901                         {
1902                                 float totalplayers;
1903                                 float playerswithlaps;
1904                                 float readyplayers;
1905                                 totalplayers = playerswithlaps = readyplayers = 0;
1906                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1907                                         ++totalplayers;
1908                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1909                                                 ++playerswithlaps;
1910                                         if(it.ready)
1911                                                 ++readyplayers;
1912                                 ));
1913
1914                                 // at least 2 of the players have completed a lap: start the RACE
1915                                 // otherwise, the players should end the qualifying on their own
1916                                 if(readyplayers || playerswithlaps >= 2)
1917                                 {
1918                                         checkrules_suddendeathend = 0;
1919                                         ReadyRestart(); // go to race
1920                                         return;
1921                                 }
1922                                 else
1923                                         wantovertime |= InitiateSuddenDeath();
1924                         }
1925                         else
1926                                 wantovertime |= InitiateSuddenDeath();
1927                 }
1928         }
1929
1930         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1931         {
1932                 NextLevel();
1933                 return;
1934         }
1935
1936         int checkrules_status = WinningCondition_RanOutOfSpawns();
1937         if(checkrules_status == WINNING_YES)
1938                 bprint("Hey! Someone ran out of spawns!\n");
1939         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1940                 checkrules_status = M_ARGV(0, float);
1941         else
1942                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1943
1944         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1945         {
1946                 checkrules_status = WINNING_NEVER;
1947                 checkrules_overtimesadded = -1;
1948                 wantovertime |= InitiateSuddenDeath();
1949         }
1950
1951         if(checkrules_status == WINNING_NEVER)
1952                 // equality cases! Nobody wins if the overtime ends in a draw.
1953                 ClearWinners();
1954
1955         if(wantovertime)
1956         {
1957                 if(checkrules_status == WINNING_NEVER)
1958                         InitiateOvertime();
1959                 else
1960                         checkrules_status = WINNING_YES;
1961         }
1962
1963         if(checkrules_suddendeathend)
1964                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1965                         checkrules_status = WINNING_YES;
1966
1967         if(checkrules_status == WINNING_YES)
1968         {
1969                 //print("WINNING\n");
1970                 NextLevel();
1971         }
1972 }
1973
1974 string GotoMap(string m)
1975 {
1976         m = GameTypeVote_MapInfo_FixName(m);
1977         if (!m)
1978                 return "The map you suggested is not available on this server.";
1979         if (!autocvar_sv_vote_gametype)
1980         if(!MapInfo_CheckMap(m))
1981                 return "The map you suggested does not support the current game mode.";
1982         cvar_set("nextmap", m);
1983         cvar_set("timelimit", "-1");
1984         if(mapvote_initialized || alreadychangedlevel)
1985         {
1986                 if(DoNextMapOverride(0))
1987                         return "Map switch initiated.";
1988                 else
1989                         return "Hm... no. For some reason I like THIS map more.";
1990         }
1991         else
1992                 return "Map switch will happen after scoreboard.";
1993 }
1994
1995 bool autocvar_sv_gameplayfix_multiplethinksperframe;
1996 void RunThink(entity this)
1997 {
1998         // don't let things stay in the past.
1999         // it is possible to start that way by a trigger with a local time.
2000         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2001                 return;
2002
2003         float oldtime = time; // do we need to save this?
2004
2005         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2006         {
2007                 time = max(oldtime, this.nextthink);
2008                 this.nextthink = 0;
2009
2010                 if(getthink(this))
2011                         getthink(this)(this);
2012                 // mods often set nextthink to time to cause a think every frame,
2013                 // we don't want to loop in that case, so exit if the new nextthink is
2014                 // <= the time the qc was told, also exit if it is past the end of the
2015                 // frame
2016                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2017                         break;
2018         }
2019
2020         time = oldtime;
2021 }
2022
2023 bool autocvar_sv_freezenonclients;
2024 bool autocvar_sv_gameplayfix_delayprojectiles;
2025 void Physics_Frame()
2026 {
2027         if(autocvar_sv_freezenonclients)
2028                 return;
2029
2030         FOREACH_ENTITY_FLOAT(pure_data, false,
2031         {
2032                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2033                         continue;
2034
2035                 set_movetype(it, it.move_movetype);
2036
2037                 if(it.move_movetype == MOVETYPE_NONE)
2038                         continue;
2039
2040                 if(it.move_qcphysics)
2041                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2042
2043                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2044                 {
2045                         // handle thinking here
2046                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2047                                 RunThink(it);
2048                 }
2049         });
2050
2051         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2052                 return;
2053
2054         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2055         {
2056                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2057                         continue;
2058                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2059         });
2060 }
2061
2062 void systems_update();
2063 void EndFrame()
2064 {
2065         anticheat_endframe();
2066
2067         Physics_Frame();
2068
2069         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2070                 entity e = IS_SPEC(it) ? it.enemy : it;
2071                 if (e.typehitsound) {
2072                         it.typehit_time = time;
2073                 } else if (e.damage_dealt) {
2074                         it.hit_time = time;
2075                         it.damage_dealt_total += ceil(e.damage_dealt);
2076                 }
2077         });
2078         // add 1 frametime because after this, engine SV_Physics
2079         // increases time by a frametime and then networks the frame
2080         // add another frametime because client shows everything with
2081         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2082         // needed!
2083         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2084         FOREACH_CLIENT(true, {
2085                 it.typehitsound = false;
2086                 it.damage_dealt = 0;
2087                 antilag_record(it, CS(it), altime);
2088         });
2089         IL_EACH(g_monsters, true,
2090         {
2091                 antilag_record(it, it, altime);
2092         });
2093         systems_update();
2094         IL_ENDFRAME();
2095 }
2096
2097
2098 /*
2099  * RedirectionThink:
2100  * returns true if redirecting
2101  */
2102 float redirection_timeout;
2103 float redirection_nextthink;
2104 float RedirectionThink()
2105 {
2106         float clients_found;
2107
2108         if(redirection_target == "")
2109                 return false;
2110
2111         if(!redirection_timeout)
2112         {
2113                 cvar_set("sv_public", "-2");
2114                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2115                 if(redirection_target == "self")
2116                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2117                 else
2118                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2119         }
2120
2121         if(time < redirection_nextthink)
2122                 return true;
2123
2124         redirection_nextthink = time + 1;
2125
2126         clients_found = 0;
2127         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2128                 // TODO add timer
2129                 LOG_INFO("Redirecting: sending connect command to ", it.netname, "\n");
2130                 if(redirection_target == "self")
2131                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2132                 else
2133                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2134                 ++clients_found;
2135         ));
2136
2137         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2138
2139         if(time > redirection_timeout || clients_found == 0)
2140                 localcmd("\nwait; wait; wait; quit\n");
2141
2142         return true;
2143 }
2144
2145 void TargetMusic_RestoreGame();
2146 void RestoreGame()
2147 {
2148         // Loaded from a save game
2149         // some things then break, so let's work around them...
2150
2151         // Progs DB (capture records)
2152         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2153
2154         // Mapinfo
2155         MapInfo_Shutdown();
2156         MapInfo_Enumerate();
2157         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2158         WeaponStats_Init();
2159
2160         TargetMusic_RestoreGame();
2161 }
2162
2163 void Shutdown()
2164 {
2165         game_stopped = 2;
2166
2167         if(world_initialized > 0)
2168         {
2169                 world_initialized = 0;
2170                 LOG_TRACE("Saving persistent data...");
2171                 Ban_SaveBans();
2172
2173                 // playerstats with unfinished match
2174                 PlayerStats_GameReport(false);
2175
2176                 if(!cheatcount_total)
2177                 {
2178                         if(autocvar_sv_db_saveasdump)
2179                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2180                         else
2181                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2182                 }
2183                 if(autocvar_developer)
2184                 {
2185                         if(autocvar_sv_db_saveasdump)
2186                                 db_dump(TemporaryDB, "server-temp.db");
2187                         else
2188                                 db_save(TemporaryDB, "server-temp.db");
2189                 }
2190                 CheatShutdown(); // must be after cheatcount check
2191                 db_close(ServerProgsDB);
2192                 db_close(TemporaryDB);
2193                 LOG_TRACE("Saving persistent data... done!");
2194                 // tell the bot system the game is ending now
2195                 bot_endgame();
2196
2197                 WeaponStats_Shutdown();
2198                 MapInfo_Shutdown();
2199         }
2200         else if(world_initialized == 0)
2201         {
2202                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2203         }
2204         else
2205         {
2206                 __init_dedicated_server_shutdown();
2207         }
2208 }