qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include <common/net_linked.qh>
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/_mod.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications/all.qh"
  29 #include "../common/physics/player.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/_mod.qh"
  37 #include <common/weapons/_all.qh>
  38 #include "../common/state.qh"
  39
  40 const float LATENCY_THINKRATE = 10;
  41 .float latency_sum;
  42 .float latency_cnt;
  43 .float latency_time;
  44 entity pingplreport;
  45 void PingPLReport_Think(entity this)
  46 {
  47         float delta;
  48         entity e;
  49
  50         delta = 3 / maxclients;
  51         if(delta < sys_frametime)
  52                 delta = 0;
  53         this.nextthink = time + delta;
  54
  55         e = edict_num(this.cnt + 1);
  56         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  57         {
  58                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  59                 WriteByte(MSG_BROADCAST, this.cnt);
  60                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  61                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  62                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  63
  64                 // record latency times for clients throughout the match so we can report it to playerstats
  65                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  66                 {
  67                         CS(e).latency_sum += CS(e).ping;
  68                         CS(e).latency_cnt += 1;
  69                         CS(e).latency_time = time;
  70                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  71                 }
  72         }
  73         else
  74         {
  75                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, this.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         this.cnt = (this.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = new_pure(pingplreport);
  86         setthink(pingplreport, PingPLReport_Think);
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap(entity this)
 109 {
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 this.nextthink = time;
 134         }
 135         else
 136         {
 137                 this.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         strfree(cvar_changes);
 149         strfree(cvar_purechanges);
 150         cvar_purechanges_count = 0;
 151
 152         h = buf_create();
 153         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 154         n = buf_getsize(h);
 155
 156         adding = true;
 157         pureadding = true;
 158
 159         for(i = 0; i < n; ++i)
 160         {
 161                 k = bufstr_get(h, i);
 162
 163 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 164 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 165 #define BADCVAR(p) if(k == p) continue
 166
 167                 // general excludes and namespaces for server admin used cvars
 168                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 169
 170                 // internal
 171                 BADPREFIX("csqc_");
 172                 BADPREFIX("cvar_check_");
 173                 BADCVAR("gamecfg");
 174                 BADCVAR("g_configversion");
 175                 BADCVAR("halflifebsp");
 176                 BADCVAR("sv_mapformat_is_quake2");
 177                 BADCVAR("sv_mapformat_is_quake3");
 178                 BADPREFIX("sv_world");
 179
 180                 // client
 181                 BADPREFIX("chase_");
 182                 BADPREFIX("cl_");
 183                 BADPREFIX("con_");
 184                 BADPREFIX("scoreboard_");
 185                 BADPREFIX("g_campaign");
 186                 BADPREFIX("g_waypointsprite_");
 187                 BADPREFIX("gl_");
 188                 BADPREFIX("joy");
 189                 BADPREFIX("hud_");
 190                 BADPREFIX("m_");
 191                 BADPREFIX("menu_");
 192                 BADPREFIX("net_slist_");
 193                 BADPREFIX("r_");
 194                 BADPREFIX("sbar_");
 195                 BADPREFIX("scr_");
 196                 BADPREFIX("snd_");
 197                 BADPREFIX("show");
 198                 BADPREFIX("sensitivity");
 199                 BADPREFIX("userbind");
 200                 BADPREFIX("v_");
 201                 BADPREFIX("vid_");
 202                 BADPREFIX("crosshair");
 203                 BADCVAR("mod_q3bsp_lightmapmergepower");
 204                 BADCVAR("mod_q3bsp_nolightmaps");
 205                 BADCVAR("fov");
 206                 BADCVAR("mastervolume");
 207                 BADCVAR("volume");
 208                 BADCVAR("bgmvolume");
 209                 BADCVAR("in_pitch_min");
 210                 BADCVAR("in_pitch_max");
 211
 212                 // private
 213                 BADCVAR("developer");
 214                 BADCVAR("log_dest_udp");
 215                 BADCVAR("net_address");
 216                 BADCVAR("net_address_ipv6");
 217                 BADCVAR("port");
 218                 BADCVAR("savedgamecfg");
 219                 BADCVAR("serverconfig");
 220                 BADCVAR("sv_autoscreenshot");
 221                 BADCVAR("sv_heartbeatperiod");
 222                 BADCVAR("sv_vote_master_password");
 223                 BADCVAR("sys_colortranslation");
 224                 BADCVAR("sys_specialcharactertranslation");
 225                 BADCVAR("timeformat");
 226                 BADCVAR("timestamps");
 227                 BADCVAR("g_require_stats");
 228                 BADPREFIX("developer_");
 229                 BADPREFIX("g_ban_");
 230                 BADPREFIX("g_banned_list");
 231                 BADPREFIX("g_require_stats_");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_voice_flood_");
 236                 BADPREFIX("log_file");
 237                 BADPREFIX("quit_");
 238                 BADPREFIX("rcon_");
 239                 BADPREFIX("sv_allowdownloads");
 240                 BADPREFIX("sv_autodemo");
 241                 BADPREFIX("sv_curl_");
 242                 BADPREFIX("sv_eventlog");
 243                 BADPREFIX("sv_logscores_");
 244                 BADPREFIX("sv_master");
 245                 BADPREFIX("sv_weaponstats_");
 246                 BADPREFIX("sv_waypointsprite_");
 247                 BADCVAR("rescan_pending");
 248
 249                 // these can contain player IDs, so better hide
 250                 BADPREFIX("g_forced_team_");
 251                 BADCVAR("sv_muteban_list");
 252                 BADCVAR("sv_voteban_list");
 253                 BADCVAR("sv_allow_customplayermodels_idlist");
 254                 BADCVAR("sv_allow_customplayermodels_speciallist");
 255
 256                 // mapinfo
 257                 BADCVAR("fraglimit");
 258                 BADCVAR("g_arena");
 259                 BADCVAR("g_assault");
 260                 BADCVAR("g_ca");
 261                 BADCVAR("g_ca_teams");
 262                 BADCVAR("g_conquest");
 263                 BADCVAR("g_ctf");
 264                 BADCVAR("g_cts");
 265                 BADCVAR("g_dotc");
 266                 BADCVAR("g_dm");
 267                 BADCVAR("g_domination");
 268                 BADCVAR("g_domination_default_teams");
 269                 BADCVAR("g_freezetag");
 270                 BADCVAR("g_freezetag_teams");
 271                 BADCVAR("g_invasion_teams");
 272                 BADCVAR("g_invasion_type");
 273                 BADCVAR("g_jailbreak");
 274                 BADCVAR("g_jailbreak_teams");
 275                 BADCVAR("g_keepaway");
 276                 BADCVAR("g_keyhunt");
 277                 BADCVAR("g_keyhunt_teams");
 278                 BADCVAR("g_lms");
 279                 BADCVAR("g_nexball");
 280                 BADCVAR("g_onslaught");
 281                 BADCVAR("g_race");
 282                 BADCVAR("g_race_laps_limit");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_race_qualifying_timelimit_override");
 285                 BADCVAR("g_runematch");
 286                 BADCVAR("g_snafu");
 287                 BADCVAR("g_tdm");
 288                 BADCVAR("g_tdm_teams");
 289                 BADCVAR("g_vip");
 290                 BADCVAR("leadlimit");
 291                 BADCVAR("nextmap");
 292                 BADCVAR("teamplay");
 293                 BADCVAR("timelimit");
 294                 BADCVAR("g_mapinfo_ignore_warnings");
 295
 296                 // long
 297                 BADCVAR("hostname");
 298                 BADCVAR("g_maplist");
 299                 BADCVAR("g_maplist_mostrecent");
 300                 BADCVAR("sv_motd");
 301
 302                 v = cvar_string(k);
 303                 d = cvar_defstring(k);
 304                 if(v == d)
 305                         continue;
 306
 307                 if(adding)
 308                 {
 309                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 310                         if(strlen(cvar_changes) > 16384)
 311                         {
 312                                 cvar_changes = "// too many settings have been changed to show them here\n";
 313                                 adding = 0;
 314                         }
 315                 }
 316
 317                 // now check if the changes are actually gameplay relevant
 318
 319                 // does nothing gameplay relevant
 320                 BADCVAR("captureleadlimit_override");
 321                 BADCVAR("condump_stripcolors");
 322                 BADCVAR("gameversion");
 323                 BADCVAR("g_allow_oldvortexbeam");
 324                 BADCVAR("g_balance_kill_delay");
 325                 BADCVAR("g_buffs_pickup_anyway");
 326                 BADCVAR("g_buffs_randomize");
 327                 BADCVAR("g_campcheck_distance");
 328                 BADCVAR("g_ca_point_leadlimit");
 329                 BADCVAR("g_ca_point_limit");
 330                 BADCVAR("g_ctf_captimerecord_always");
 331                 BADCVAR("g_ctf_flag_glowtrails");
 332                 BADCVAR("g_ctf_flag_pickup_verbosename");
 333                 BADCVAR("g_domination_point_leadlimit");
 334                 BADCVAR("g_forced_respawn");
 335                 BADCVAR("g_freezetag_point_leadlimit");
 336                 BADCVAR("g_freezetag_point_limit");
 337                 BADCVAR("g_hats");
 338                 BADCVAR("g_invasion_point_limit");
 339                 BADCVAR("g_jump_grunt");
 340                 BADCVAR("g_keyhunt_point_leadlimit");
 341                 BADCVAR("g_nexball_goalleadlimit");
 342                 BADCVAR("g_new_toys_use_pickupsound");
 343                 BADCVAR("g_physics_predictall");
 344                 BADCVAR("g_piggyback");
 345                 BADCVAR("g_playerclip_collisions");
 346                 BADCVAR("g_tdm_point_leadlimit");
 347                 BADCVAR("g_tdm_point_limit");
 348                 BADCVAR("leadlimit_and_fraglimit");
 349                 BADCVAR("leadlimit_override");
 350                 BADCVAR("pausable");
 351                 BADCVAR("sv_checkforpacketsduringsleep");
 352                 BADCVAR("sv_damagetext");
 353                 BADCVAR("sv_db_saveasdump");
 354                 BADCVAR("sv_intermission_cdtrack");
 355                 BADCVAR("sv_minigames");
 356                 BADCVAR("sv_namechangetimer");
 357                 BADCVAR("sv_precacheplayermodels");
 358                 BADCVAR("sv_stepheight");
 359                 BADCVAR("sv_timeout");
 360                 BADCVAR("sv_weapons_modeloverride");
 361                 BADPREFIX("crypto_");
 362                 BADPREFIX("gameversion_");
 363                 BADPREFIX("g_chat_");
 364                 BADPREFIX("g_ctf_captimerecord_");
 365                 BADPREFIX("g_maplist_");
 366                 BADPREFIX("g_mod_");
 367                 BADPREFIX("g_respawn_");
 368                 BADPREFIX("net_");
 369                 BADPREFIX("notification_");
 370                 BADPREFIX("prvm_");
 371                 BADPREFIX("skill_");
 372                 BADPREFIX("sv_allow_");
 373                 BADPREFIX("sv_cullentities_");
 374                 BADPREFIX("sv_maxidle_");
 375                 BADPREFIX("sv_minigames_");
 376                 BADPREFIX("sv_radio_");
 377                 BADPREFIX("sv_timeout_");
 378                 BADPREFIX("sv_vote_");
 379                 BADPREFIX("timelimit_");
 380
 381                 // allowed changes to server admins (please sync this to server.cfg)
 382                 // vi commands:
 383                 //   :/"impure"/,$d
 384                 //   :g!,^\/\/[^ /],d
 385                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 386                 //   :%!sort
 387                 // yes, this does contain some redundant stuff, don't really care
 388                 BADCVAR("bot_config_file");
 389                 BADCVAR("bot_number");
 390                 BADCVAR("bot_prefix");
 391                 BADCVAR("bot_suffix");
 392                 BADCVAR("capturelimit_override");
 393                 BADCVAR("fraglimit_override");
 394                 BADCVAR("gametype");
 395                 BADCVAR("g_antilag");
 396                 BADCVAR("g_balance_teams");
 397                 BADCVAR("g_balance_teams_prevent_imbalance");
 398                 BADCVAR("g_balance_teams_scorefactor");
 399                 BADCVAR("g_ban_sync_trusted_servers");
 400                 BADCVAR("g_ban_sync_uri");
 401                 BADCVAR("g_buffs");
 402                 BADCVAR("g_ca_teams_override");
 403                 BADCVAR("g_ctf_ignore_frags");
 404                 BADCVAR("g_ctf_leaderboard");
 405                 BADCVAR("g_domination_point_limit");
 406                 BADCVAR("g_domination_teams_override");
 407                 BADCVAR("g_freezetag_teams_override");
 408                 BADCVAR("g_friendlyfire");
 409                 BADCVAR("g_fullbrightitems");
 410                 BADCVAR("g_fullbrightplayers");
 411                 BADCVAR("g_keyhunt_point_limit");
 412                 BADCVAR("g_keyhunt_teams_override");
 413                 BADCVAR("g_lms_lives_override");
 414                 BADCVAR("g_maplist");
 415                 BADCVAR("g_maxplayers");
 416                 BADCVAR("g_mirrordamage");
 417                 BADCVAR("g_nexball_goallimit");
 418                 BADCVAR("g_norecoil");
 419                 BADCVAR("g_physics_clientselect");
 420                 BADCVAR("g_pinata");
 421                 BADCVAR("g_powerups");
 422                 BADCVAR("g_spawnshieldtime");
 423                 BADCVAR("g_start_delay");
 424                 BADCVAR("g_superspectate");
 425                 BADCVAR("g_tdm_teams_override");
 426                 BADCVAR("g_warmup");
 427                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 428                 BADCVAR("hostname");
 429                 BADCVAR("log_file");
 430                 BADCVAR("maxplayers");
 431                 BADCVAR("minplayers");
 432                 BADCVAR("net_address");
 433                 BADCVAR("port");
 434                 BADCVAR("rcon_password");
 435                 BADCVAR("rcon_restricted_commands");
 436                 BADCVAR("rcon_restricted_password");
 437                 BADCVAR("skill");
 438                 BADCVAR("sv_adminnick");
 439                 BADCVAR("sv_autoscreenshot");
 440                 BADCVAR("sv_autotaunt");
 441                 BADCVAR("sv_curl_defaulturl");
 442                 BADCVAR("sv_defaultcharacter");
 443                 BADCVAR("sv_defaultcharacterskin");
 444                 BADCVAR("sv_defaultplayercolors");
 445                 BADCVAR("sv_defaultplayermodel");
 446                 BADCVAR("sv_defaultplayerskin");
 447                 BADCVAR("sv_maxidle");
 448                 BADCVAR("sv_maxrate");
 449                 BADCVAR("sv_motd");
 450                 BADCVAR("sv_public");
 451                 BADCVAR("sv_ready_restart");
 452                 BADCVAR("sv_status_privacy");
 453                 BADCVAR("sv_taunt");
 454                 BADCVAR("sv_vote_call");
 455                 BADCVAR("sv_vote_commands");
 456                 BADCVAR("sv_vote_majority_factor");
 457                 BADCVAR("sv_vote_master");
 458                 BADCVAR("sv_vote_master_commands");
 459                 BADCVAR("sv_vote_master_password");
 460                 BADCVAR("sv_vote_simple_majority_factor");
 461                 BADCVAR("teamplay_mode");
 462                 BADCVAR("timelimit_override");
 463                 BADPREFIX("g_warmup_");
 464                 BADPREFIX("sv_info_");
 465                 BADPREFIX("sv_ready_restart_");
 466
 467                 // mutators that announce themselves properly to the server browser
 468                 BADCVAR("g_instagib");
 469                 BADCVAR("g_new_toys");
 470                 BADCVAR("g_nix");
 471                 BADCVAR("g_grappling_hook");
 472                 BADCVAR("g_jetpack");
 473
 474 #undef BADPRESUFFIX
 475 #undef BADPREFIX
 476 #undef BADCVAR
 477
 478                 if(pureadding)
 479                 {
 480                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 481                         if(strlen(cvar_purechanges) > 16384)
 482                         {
 483                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 484                                 pureadding = 0;
 485                         }
 486                 }
 487                 ++cvar_purechanges_count;
 488                 // WARNING: this variable is used for the server list
 489                 // NEVER dare to skip this code!
 490                 // Hacks to intentionally appearing as "pure server" even though you DO have
 491                 // modified settings may be punished by removal from the server list.
 492                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 493                 // though.
 494         }
 495         buf_del(h);
 496         if(cvar_changes == "")
 497                 cvar_changes = "// this server runs at default server settings\n";
 498         else
 499                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 500         cvar_changes = strzone(cvar_changes);
 501         if(cvar_purechanges == "")
 502                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 503         else
 504                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 505         cvar_purechanges = strzone(cvar_purechanges);
 506 }
 507
 508 void detect_maptype()
 509 {
 510 #if 0
 511         vector o, v;
 512         float i;
 513
 514         for (;;)
 515         {
 516                 o = world.mins;
 517                 o.x += random() * (world.maxs.x - world.mins.x);
 518                 o.y += random() * (world.maxs.y - world.mins.y);
 519                 o.z += random() * (world.maxs.z - world.mins.z);
 520
 521                 tracebox(o, STAT(PL_MIN), STAT(PL_MAX), o - '0 0 32768', MOVE_WORLDONLY, NULL);
 522                 if(trace_fraction == 1)
 523                         continue;
 524
 525                 v = trace_endpos;
 526
 527                 for(i = 0; i < 64; i += 4)
 528                 {
 529                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
 530         if(trace_fraction == 1)
 531                 continue;
 532                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos));
 533                 }
 534
 535                 break;
 536         }
 537 #endif
 538 }
 539
 540 entity randomseed;
 541 bool RandomSeed_Send(entity this, entity to, int sf)
 542 {
 543         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 544         WriteShort(MSG_ENTITY, this.cnt);
 545         return true;
 546 }
 547 void RandomSeed_Think(entity this)
 548 {
 549         this.cnt = bound(0, floor(random() * 65536), 65535);
 550         this.nextthink = time + 5;
 551
 552         this.SendFlags |= 1;
 553 }
 554 void RandomSeed_Spawn()
 555 {
 556         randomseed = new_pure(randomseed);
 557         setthink(randomseed, RandomSeed_Think);
 558         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 559
 560         getthink(randomseed)(randomseed); // sets random seed and nextthink
 561 }
 562
 563 spawnfunc(__init_dedicated_server)
 564 {
 565         // handler for _init/_init map (only for dedicated server initialization)
 566
 567         world_initialized = -1; // don't complain
 568         cvar = cvar_normal;
 569         cvar_string = cvar_string_normal;
 570         cvar_set = cvar_set_normal;
 571
 572         delete_fn = remove_unsafely;
 573
 574         entity e = spawn();
 575         setthink(e, GotoFirstMap);
 576         e.nextthink = time; // this is usually 1 at this point
 577
 578         e = new(info_player_deathmatch);  // safeguard against player joining
 579
 580     // assign reflectively to avoid "assignment to world" warning
 581     for (int i = 0, n = numentityfields(); i < n; ++i) {
 582         string k = entityfieldname(i);
 583         if (k == "classname") {
 584             // safeguard against various stuff ;)
 585             putentityfieldstring(i, this, "worldspawn");
 586             break;
 587         }
 588     }
 589
 590         // needs to be done so early because of the constants they create
 591         static_init();
 592         static_init_late();
 593         static_init_precache();
 594
 595         IL_PUSH(g_spawnpoints, e); // just incase
 596
 597         MapInfo_Enumerate();
 598         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 599 }
 600
 601 void __init_dedicated_server_shutdown() {
 602         MapInfo_Shutdown();
 603 }
 604
 605 STATIC_INIT_EARLY(maxclients)
 606 {
 607         maxclients = 0;
 608         for (entity head = nextent(NULL); head; head = nextent(head)) {
 609                 ++maxclients;
 610         }
 611 }
 612
 613 void Map_MarkAsRecent(string m);
 614 float world_already_spawned;
 615 void Nagger_Init();
 616 void ClientInit_Spawn();
 617 void WeaponStats_Init();
 618 void WeaponStats_Shutdown();
 619 spawnfunc(worldspawn)
 620 {
 621         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 622
 623     bool wantrestart = false;
 624         {
 625                 if (!server_is_dedicated)
 626                 {
 627                         // force unloading of server pk3 files when starting a listen server
 628                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 629                         // restore csqc_progname too
 630                         string expect = "csprogs.dat";
 631                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 632                         cvar_set_normal("csqc_progname", expect);
 633                 }
 634                 else
 635                 {
 636                         // Try to use versioned csprogs from pk3
 637                         // Only ever use versioned csprogs.dat files on dedicated servers;
 638                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 639                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 640                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 641                         string select = "csprogs.dat";
 642                         if (fexists(pk3csprogs)) select = pk3csprogs;
 643                         if (cvar_string_normal("csqc_progname") != select)
 644                         {
 645                                 cvar_set_normal("csqc_progname", select);
 646                                 wantrestart = true;
 647                         }
 648                         // Check for updates on startup
 649                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 650                         int sentinel = fopen("progs.txt", FILE_READ);
 651                         if (sentinel >= 0)
 652                         {
 653                                 string switchversion = fgets(sentinel);
 654                                 fclose(sentinel);
 655                                 if (switchversion != "" && switchversion != WATERMARK)
 656                                 {
 657                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 658                                         // if it doesn't exist, assume either:
 659                                         //   a) the current program was overwritten
 660                                         //   b) this is a client only update
 661                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 662                                         if (fexists(newprogs))
 663                                         {
 664                                                 cvar_set_normal("sv_progs", newprogs);
 665                                                 wantrestart = true;
 666                                         }
 667                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 668                                         if (fexists(newcsprogs))
 669                                         {
 670                                                 cvar_set_normal("csqc_progname", newcsprogs);
 671                                                 wantrestart = true;
 672                                         }
 673                                 }
 674                         }
 675                 }
 676                 if (wantrestart)
 677                 {
 678                         LOG_INFOF("Restart requested");
 679                         changelevel(mapname);
 680                         // let initialization continue, shutdown depends on it
 681                 }
 682         }
 683
 684         cvar = cvar_normal;
 685         cvar_string = cvar_string_normal;
 686         cvar_set = cvar_set_normal;
 687
 688         if(world_already_spawned)
 689                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 690         world_already_spawned = true;
 691
 692         delete_fn = remove_safely; // during spawning, watch what you remove!
 693
 694         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 695
 696         // needs to be done so early because of the constants they create
 697         static_init();
 698
 699         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 700
 701         TemporaryDB = db_create();
 702
 703         // 0 normal
 704         lightstyle(0, "m");
 705
 706         // 1 FLICKER (first variety)
 707         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 708
 709         // 2 SLOW STRONG PULSE
 710         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 711
 712         // 3 CANDLE (first variety)
 713         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 714
 715         // 4 FAST STROBE
 716         lightstyle(4, "mamamamamama");
 717
 718         // 5 GENTLE PULSE 1
 719         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 720
 721         // 6 FLICKER (second variety)
 722         lightstyle(6, "nmonqnmomnmomomno");
 723
 724         // 7 CANDLE (second variety)
 725         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 726
 727         // 8 CANDLE (third variety)
 728         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 729
 730         // 9 SLOW STROBE (fourth variety)
 731         lightstyle(9, "aaaaaaaazzzzzzzz");
 732
 733         // 10 FLUORESCENT FLICKER
 734         lightstyle(10, "mmamammmmammamamaaamammma");
 735
 736         // 11 SLOW PULSE NOT FADE TO BLACK
 737         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 738
 739         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 740
 741         // 63 testing
 742         lightstyle(63, "a");
 743
 744         if(autocvar_g_campaign)
 745                 CampaignPreInit();
 746
 747         Map_MarkAsRecent(mapname);
 748
 749         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 750
 751         InitGameplayMode();
 752         static_init_late();
 753         static_init_precache();
 754         readlevelcvars();
 755         GrappleHookInit();
 756
 757     GameRules_limit_fallbacks();
 758
 759         if(warmup_limit == 0)
 760                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 761
 762         player_count = 0;
 763         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 764         if(bot_waypoints_for_items == 1)
 765                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 766                         bot_waypoints_for_items = 0;
 767
 768         precache();
 769
 770         WaypointSprite_Init();
 771
 772         GameLogInit(); // prepare everything
 773         // NOTE for matchid:
 774         // changing the logic generating it is okay. But:
 775         // it HAS to stay <= 64 chars
 776         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 777         if(autocvar_sv_eventlog)
 778         {
 779                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 780                 matchid = strzone(s);
 781
 782                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 783                 s = ":gameinfo:mutators:LIST";
 784
 785                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 786                 s = M_ARGV(0, string);
 787
 788                 // initialiation stuff, not good in the mutator system
 789                 if(!autocvar_g_use_ammunition)
 790                         s = strcat(s, ":no_use_ammunition");
 791
 792                 // initialiation stuff, not good in the mutator system
 793                 if(autocvar_g_pickup_items == 0)
 794                         s = strcat(s, ":no_pickup_items");
 795                 if(autocvar_g_pickup_items > 0)
 796                         s = strcat(s, ":pickup_items");
 797
 798                 // initialiation stuff, not good in the mutator system
 799                 if(autocvar_g_weaponarena != "0")
 800                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 801
 802                 // TODO to mutator system
 803                 if(autocvar_g_norecoil)
 804                         s = strcat(s, ":norecoil");
 805
 806                 // TODO to mutator system
 807                 if(autocvar_g_powerups == 0)
 808                         s = strcat(s, ":no_powerups");
 809                 if(autocvar_g_powerups > 0)
 810                         s = strcat(s, ":powerups");
 811
 812                 GameLogEcho(s);
 813                 GameLogEcho(":gameinfo:end");
 814         }
 815         else
 816                 matchid = strzone(ftos(random()));
 817
 818         cvar_set("nextmap", "");
 819
 820         SetDefaultAlpha();
 821
 822         if(autocvar_g_campaign)
 823                 CampaignPostInit();
 824
 825         Ban_LoadBans();
 826
 827         MapInfo_Enumerate();
 828         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 829
 830         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 831         {
 832                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 833                 if(fd != -1)
 834                 {
 835                         string s;
 836                         while((s = fgets(fd)))
 837                         {
 838                                 int l = tokenize_console(s);
 839                                 if(l < 2)
 840                                         continue;
 841                                 if(argv(0) == "cd")
 842                                 {
 843                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 844                                         LOG_INFO("  cdtrack ", argv(2));
 845                                 }
 846                                 else if(argv(0) == "fog")
 847                                 {
 848                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 849                                         LOG_INFO("  \"fog\" \"", s, "\"");
 850                                 }
 851                                 else if(argv(0) == "set")
 852                                 {
 853                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 854                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 855                                 }
 856                                 else if(argv(0) != "//")
 857                                 {
 858                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 859                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 860                                 }
 861                         }
 862                         fclose(fd);
 863                 }
 864         }
 865
 866         WeaponStats_Init();
 867
 868         Nagger_Init();
 869
 870         next_pingtime = time + 5;
 871
 872         detect_maptype();
 873
 874         // set up information replies for clients and server to use
 875         maplist_reply = strzone(getmaplist());
 876         lsmaps_reply = strzone(getlsmaps());
 877         monsterlist_reply = strzone(getmonsterlist());
 878         for(int i = 0; i < 10; ++i)
 879         {
 880                 string s = getrecords(i);
 881                 if (s)
 882                         records_reply[i] = strzone(s);
 883         }
 884         ladder_reply = strzone(getladder());
 885         rankings_reply = strzone(getrankings());
 886
 887         // begin other init
 888         ClientInit_Spawn();
 889         RandomSeed_Spawn();
 890         PingPLReport_Spawn();
 891
 892         CheatInit();
 893
 894         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 895
 896         // fill sv_curl_serverpackages from .serverpackage files
 897         if (autocvar_sv_curl_serverpackages_auto)
 898         {
 899                 string s = "csprogs-" WATERMARK ".txt";
 900                 // remove automatically managed files from the list to prevent duplicates
 901                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 902                 {
 903                         string pkg = argv(i);
 904                         if (startsWith(pkg, "csprogs-")) continue;
 905                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 906                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 907                         s = cons(s, pkg);
 908                 }
 909                 // add automatically managed files to the list
 910                 #define X(match) MACRO_BEGIN { \
 911                         int fd = search_begin(match, true, false); \
 912                         if (fd >= 0) \
 913                         { \
 914                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 915                                 { \
 916                                         s = cons(s, search_getfilename(fd, i)); \
 917                                 } \
 918                                 search_end(fd); \
 919                         } \
 920                 } MACRO_END
 921                 X("*-serverpackage.txt");
 922                 X("*.serverpackage");
 923                 #undef X
 924                 cvar_set("sv_curl_serverpackages", s);
 925         }
 926
 927         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 928         modname = "Xonotic";
 929         // physics/balance/config changes that count as mod
 930         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 931                 modname = cvar_string("g_mod_physics");
 932         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 933                 modname = cvar_string("g_mod_balance");
 934         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 935                 modname = cvar_string("g_mod_config");
 936         // extra mutators that deserve to count as mod
 937         MUTATOR_CALLHOOK(SetModname, modname);
 938         modname = M_ARGV(0, string);
 939
 940         // save it for later
 941         modname = strzone(modname);
 942
 943         WinningConditionHelper(this); // set worldstatus
 944
 945         world_initialized = 1;
 946         __spawnfunc_spawn_all();
 947 }
 948
 949 spawnfunc(light)
 950 {
 951         //makestatic (this); // Who the f___ did that?
 952         delete(this);
 953 }
 954
 955 string GetGametype()
 956 {
 957         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 958 }
 959
 960 string GetMapname()
 961 {
 962         return mapname;
 963 }
 964
 965 float Map_Count, Map_Current;
 966 string Map_Current_Name;
 967
 968 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 969 float GetMaplistPosition()
 970 {
 971         float pos, idx;
 972         string map;
 973
 974         map = GetMapname();
 975         idx = autocvar_g_maplist_index;
 976
 977         if(idx >= 0)
 978                 if(idx < Map_Count)
 979                         if(map == argv(idx))
 980                                 return idx;
 981
 982         for(pos = 0; pos < Map_Count; ++pos)
 983                 if(map == argv(pos))
 984                         return pos;
 985
 986         // resume normal maplist rotation if current map is not in g_maplist
 987         return idx;
 988 }
 989
 990 bool MapHasRightSize(string map)
 991 {
 992         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 993         if(autocvar_g_maplist_check_waypoints)
 994         {
 995                 string checkwp_msg = strcat("checkwp ", map);
 996                 if(!fexists(strcat("maps/", map, ".waypoints")))
 997                 {
 998                         LOG_TRACE(checkwp_msg, ": no waypoints");
 999                         return false;
1000                 }
1001                 LOG_TRACE(checkwp_msg, ": has waypoints");
1002         }
1003
1004         // open map size restriction file
1005         string opensize_msg = strcat("opensize ", map);
1006         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1007         if(fh >= 0)
1008         {
1009                 opensize_msg = strcat(opensize_msg, ": ok, ");
1010                 int mapmin = stoi(fgets(fh));
1011                 int mapmax = stoi(fgets(fh));
1012                 fclose(fh);
1013                 if(player_count < mapmin)
1014                 {
1015                         LOG_TRACE(opensize_msg, "not enough");
1016                         return false;
1017                 }
1018                 if(mapmax && player_count > mapmax)
1019                 {
1020                         LOG_TRACE(opensize_msg, "too many");
1021                         return false;
1022                 }
1023                 LOG_TRACE(opensize_msg, "right size");
1024                 return true;
1025         }
1026         LOG_TRACE(opensize_msg, ": not found");
1027         return true;
1028 }
1029
1030 string Map_Filename(float position)
1031 {
1032         return strcat("maps/", argv(position), ".bsp");
1033 }
1034
1035 void Map_MarkAsRecent(string m)
1036 {
1037         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1038 }
1039
1040 float Map_IsRecent(string m)
1041 {
1042         return strhasword(autocvar_g_maplist_mostrecent, m);
1043 }
1044
1045 float Map_Check(float position, float pass)
1046 {
1047         string filename;
1048         string map_next;
1049         map_next = argv(position);
1050         if(pass <= 1)
1051         {
1052                 if(Map_IsRecent(map_next))
1053                         return 0;
1054         }
1055         filename = Map_Filename(position);
1056         if(MapInfo_CheckMap(map_next))
1057         {
1058                 if(pass == 2)
1059                         return 1;
1060                 if(MapHasRightSize(map_next))
1061                         return 1;
1062                 return 0;
1063         }
1064         else
1065                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1066
1067         return 0;
1068 }
1069
1070 void Map_Goto_SetStr(string nextmapname)
1071 {
1072         if(getmapname_stored != "")
1073                 strunzone(getmapname_stored);
1074         if(nextmapname == "")
1075                 getmapname_stored = "";
1076         else
1077                 getmapname_stored = strzone(nextmapname);
1078 }
1079
1080 void Map_Goto_SetFloat(float position)
1081 {
1082         cvar_set("g_maplist_index", ftos(position));
1083         Map_Goto_SetStr(argv(position));
1084 }
1085
1086 void Map_Goto(float reinit)
1087 {
1088         MapInfo_LoadMap(getmapname_stored, reinit);
1089 }
1090
1091 // return codes of map selectors:
1092 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1093 //   -2 = permanent failure
1094 float() MaplistMethod_Iterate = // usual method
1095 {
1096         float pass, i;
1097
1098         LOG_TRACE("Trying MaplistMethod_Iterate");
1099
1100         for(pass = 1; pass <= 2; ++pass)
1101         {
1102                 for(i = 1; i < Map_Count; ++i)
1103                 {
1104                         float mapindex;
1105                         mapindex = (i + Map_Current) % Map_Count;
1106                         if(Map_Check(mapindex, pass))
1107                                 return mapindex;
1108                 }
1109         }
1110         return -1;
1111 }
1112
1113 float() MaplistMethod_Repeat = // fallback method
1114 {
1115         LOG_TRACE("Trying MaplistMethod_Repeat");
1116
1117         if(Map_Check(Map_Current, 2))
1118                 return Map_Current;
1119         return -2;
1120 }
1121
1122 float() MaplistMethod_Random = // random map selection
1123 {
1124         float i, imax;
1125
1126         LOG_TRACE("Trying MaplistMethod_Random");
1127
1128         imax = 42;
1129
1130         for(i = 0; i <= imax; ++i)
1131         {
1132                 float mapindex;
1133                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1134                 if(Map_Check(mapindex, 1))
1135                         return mapindex;
1136         }
1137         return -1;
1138 }
1139
1140 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1141 // the exponent sets a bias on the map selection:
1142 // the higher the exponent, the less likely "shortly repeated" same maps are
1143 {
1144         float i, j, imax, insertpos;
1145
1146         LOG_TRACE("Trying MaplistMethod_Shuffle");
1147
1148         imax = 42;
1149
1150         for(i = 0; i <= imax; ++i)
1151         {
1152                 string newlist;
1153
1154                 // now reinsert this at another position
1155                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1156                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1157                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1158                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1159
1160                 // insert the current map there
1161                 newlist = "";
1162                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1163                         newlist = strcat(newlist, " ", argv(j));
1164                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1165                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1166                         newlist = strcat(newlist, " ", argv(j));
1167                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1168                 cvar_set("g_maplist", newlist);
1169                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1170
1171                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1172                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1173                 if(Map_Check(Map_Current, 1))
1174                         return Map_Current;
1175         }
1176         return -1;
1177 }
1178
1179 void Maplist_Init()
1180 {
1181         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1182         float i;
1183         for (i = 0; i < Map_Count; ++i)
1184                 if (Map_Check(i, 2))
1185                         break;
1186         if (i == Map_Count)
1187         {
1188                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1189                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1190                 if(autocvar_g_maplist_shuffle)
1191                         ShuffleMaplist();
1192                 localcmd("\nmenu_cmd sync\n");
1193                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1194         }
1195         if(Map_Count == 0)
1196                 error("empty maplist, cannot select a new map");
1197         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1198
1199         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1200         // this may or may not be correct, but who cares, in the worst case a map
1201         // isn't chosen in the first pass that should have been
1202 }
1203
1204 string GetNextMap()
1205 {
1206         float nextMap;
1207
1208         Maplist_Init();
1209         nextMap = -1;
1210
1211         if(nextMap == -1)
1212                 if(autocvar_g_maplist_shuffle > 0)
1213                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1214
1215         if(nextMap == -1)
1216                 if(autocvar_g_maplist_selectrandom)
1217                         nextMap = MaplistMethod_Random();
1218
1219         if(nextMap == -1)
1220                 nextMap = MaplistMethod_Iterate();
1221
1222         if(nextMap == -1)
1223                 nextMap = MaplistMethod_Repeat();
1224
1225         if(nextMap >= 0)
1226         {
1227                 Map_Goto_SetFloat(nextMap);
1228                 return getmapname_stored;
1229         }
1230
1231         return "";
1232 }
1233
1234 float DoNextMapOverride(float reinit)
1235 {
1236         if(autocvar_g_campaign)
1237         {
1238                 CampaignPostIntermission();
1239                 alreadychangedlevel = true;
1240                 return true;
1241         }
1242         if(autocvar_quit_when_empty)
1243         {
1244                 if(player_count <= currentbots)
1245                 {
1246                         localcmd("quit\n");
1247                         alreadychangedlevel = true;
1248                         return true;
1249                 }
1250         }
1251         if(autocvar_quit_and_redirect != "")
1252         {
1253                 redirection_target = strzone(autocvar_quit_and_redirect);
1254                 alreadychangedlevel = true;
1255                 return true;
1256         }
1257         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1258         {
1259                 localcmd("restart\n");
1260                 alreadychangedlevel = true;
1261                 return true;
1262         }
1263         if(autocvar_nextmap != "")
1264         {
1265                 string m;
1266                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1267                 cvar_set("nextmap",m);
1268
1269                 if(!m || gametypevote)
1270                         return false;
1271                 if(autocvar_sv_vote_gametype)
1272                 {
1273                         Map_Goto_SetStr(m);
1274                         return false;
1275                 }
1276
1277                 if(MapInfo_CheckMap(m))
1278                 {
1279                         Map_Goto_SetStr(m);
1280                         Map_Goto(reinit);
1281                         alreadychangedlevel = true;
1282                         return true;
1283                 }
1284         }
1285         if(!reinit && autocvar_lastlevel)
1286         {
1287                 cvar_settemp_restore();
1288                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1289                 alreadychangedlevel = true;
1290                 return true;
1291         }
1292         return false;
1293 }
1294
1295 void GotoNextMap(float reinit)
1296 {
1297         //string nextmap;
1298         //float n, nummaps;
1299         //string s;
1300         if (alreadychangedlevel)
1301                 return;
1302         alreadychangedlevel = true;
1303
1304         string nextMap;
1305
1306         nextMap = GetNextMap();
1307         if(nextMap == "")
1308                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1309         Map_Goto(reinit);
1310 }
1311
1312
1313 /*
1314 ============
1315 IntermissionThink
1316
1317 When the player presses attack or jump, change to the next level
1318 ============
1319 */
1320 .float autoscreenshot;
1321 void IntermissionThink(entity this)
1322 {
1323         FixIntermissionClient(this);
1324
1325         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1326         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1327
1328         if( (server_screenshot || client_screenshot)
1329                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1330         {
1331                 this.autoscreenshot = -1;
1332                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1333                 return;
1334         }
1335
1336         if (time < intermission_exittime)
1337                 return;
1338
1339         if(!mapvote_initialized)
1340                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1341                         return;
1342
1343         MapVote_Start();
1344 }
1345
1346 /*
1347 ============
1348 FindIntermission
1349
1350 Returns the entity to view from
1351 ============
1352 */
1353 /*
1354 entity FindIntermission()
1355 {
1356         local   entity spot;
1357         local   float cyc;
1358
1359 // look for info_intermission first
1360         spot = find(NULL, classname, "info_intermission");
1361         if (spot)
1362         {       // pick a random one
1363                 cyc = random() * 4;
1364                 while (cyc > 1)
1365                 {
1366                         spot = find(spot, classname, "info_intermission");
1367                         if (!spot)
1368                                 spot = find(spot, classname, "info_intermission");
1369                         cyc = cyc - 1;
1370                 }
1371                 return spot;
1372         }
1373
1374 // then look for the start position
1375         spot = find(NULL, classname, "info_player_start");
1376         if (spot)
1377                 return spot;
1378
1379 // testinfo_player_start is only found in regioned levels
1380         spot = find(NULL, classname, "testplayerstart");
1381         if (spot)
1382                 return spot;
1383
1384 // then look for the start position
1385         spot = find(NULL, classname, "info_player_deathmatch");
1386         if (spot)
1387                 return spot;
1388
1389         //objerror ("FindIntermission: no spot");
1390         return NULL;
1391 }
1392 */
1393
1394 /*
1395 ===============================================================================
1396
1397 RULES
1398
1399 ===============================================================================
1400 */
1401
1402 void DumpStats(float final)
1403 {
1404         float file;
1405         string s;
1406         float to_console;
1407         float to_eventlog;
1408         float to_file;
1409         float i;
1410
1411         to_console = autocvar_sv_logscores_console;
1412         to_eventlog = autocvar_sv_eventlog;
1413         to_file = autocvar_sv_logscores_file;
1414
1415         if(!final)
1416         {
1417                 to_console = true; // always print printstats replies
1418                 to_eventlog = false; // but never print them to the event log
1419         }
1420
1421         if(to_eventlog)
1422                 if(autocvar_sv_eventlog_console)
1423                         to_console = false; // otherwise we get the output twice
1424
1425         if(final)
1426                 s = ":scores:";
1427         else
1428                 s = ":status:";
1429         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1430
1431         if(to_console)
1432                 LOG_INFO(s);
1433         if(to_eventlog)
1434                 GameLogEcho(s);
1435
1436         file = -1;
1437         if(to_file)
1438         {
1439                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1440                 if(file == -1)
1441                         to_file = false;
1442                 else
1443                         fputs(file, strcat(s, "\n"));
1444         }
1445
1446         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1447         if(to_console)
1448                 LOG_INFO(s);
1449         if(to_eventlog)
1450                 GameLogEcho(s);
1451         if(to_file)
1452                 fputs(file, strcat(s, "\n"));
1453
1454         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1455                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1456                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1457                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1458                         s = strcat(s, ftos(it.team), ":");
1459                 else
1460                         s = strcat(s, "spectator:");
1461
1462                 if(to_console)
1463                         LOG_INFO(s, playername(it, false));
1464                 if(to_eventlog)
1465                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1466                 if(to_file)
1467                         fputs(file, strcat(s, playername(it, false), "\n"));
1468         });
1469
1470         if(teamplay)
1471         {
1472                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1473                 if(to_console)
1474                         LOG_INFO(s);
1475                 if(to_eventlog)
1476                         GameLogEcho(s);
1477                 if(to_file)
1478                         fputs(file, strcat(s, "\n"));
1479
1480                 for(i = 1; i < 16; ++i)
1481                 {
1482                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1483                         s = strcat(s, ":", ftos(i));
1484                         if(to_console)
1485                                 LOG_INFO(s);
1486                         if(to_eventlog)
1487                                 GameLogEcho(s);
1488                         if(to_file)
1489                                 fputs(file, strcat(s, "\n"));
1490                 }
1491         }
1492
1493         if(to_console)
1494                 LOG_INFO(":end");
1495         if(to_eventlog)
1496                 GameLogEcho(":end");
1497         if(to_file)
1498         {
1499                 fputs(file, ":end\n");
1500                 fclose(file);
1501         }
1502 }
1503
1504 void FixIntermissionClient(entity e)
1505 {
1506         if(!e.autoscreenshot) // initial call
1507         {
1508                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1509                 e.health = -2342;
1510                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1511                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1512                 {
1513                     .entity weaponentity = weaponentities[slot];
1514                         if(e.(weaponentity))
1515                         {
1516                                 e.(weaponentity).effects = EF_NODRAW;
1517                                 if (e.(weaponentity).weaponchild)
1518                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1519                         }
1520                 }
1521                 if(IS_REAL_CLIENT(e))
1522                 {
1523                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1524                         RandomSelection_Init();
1525                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1526                                 RandomSelection_AddString(it, 1, 1);
1527                         });
1528                         if (RandomSelection_chosen_string != "")
1529                         {
1530                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1531                         }
1532                         msg_entity = e;
1533                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1534                 }
1535         }
1536 }
1537
1538 /*
1539 go to the next level for deathmatch
1540 only called if a time or frag limit has expired
1541 */
1542 void NextLevel()
1543 {
1544         game_stopped = true;
1545         intermission_running = 1; // game over
1546
1547         // enforce a wait time before allowing changelevel
1548         if(player_count > 0)
1549                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1550         else
1551                 intermission_exittime = -1;
1552
1553         /*
1554         WriteByte (MSG_ALL, SVC_CDTRACK);
1555         WriteByte (MSG_ALL, 3);
1556         WriteByte (MSG_ALL, 3);
1557         // done in FixIntermission
1558         */
1559
1560         //pos = FindIntermission ();
1561
1562         VoteReset();
1563
1564         DumpStats(true);
1565
1566         // send statistics
1567         PlayerStats_GameReport(true);
1568         WeaponStats_Shutdown();
1569
1570         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1571
1572         if(autocvar_sv_eventlog)
1573                 GameLogEcho(":gameover");
1574
1575         GameLogClose();
1576
1577         FOREACH_CLIENT(IS_PLAYER(it), {
1578                 FixIntermissionClient(it);
1579                 if(it.winning)
1580                         bprint(playername(it, false), " ^7wins.\n");
1581         });
1582
1583         target_music_kill();
1584
1585         if(autocvar_g_campaign)
1586                 CampaignPreIntermission();
1587
1588         MUTATOR_CALLHOOK(MatchEnd);
1589
1590         localcmd("\nsv_hook_gameend\n");
1591 }
1592
1593
1594 float InitiateSuddenDeath()
1595 {
1596         // Check first whether normal overtimes could be added before initiating suddendeath mode
1597         // - for this timelimit_overtime needs to be >0 of course
1598         // - also check the winning condition calculated in the previous frame and only add normal overtime
1599         //   again, if at the point at which timelimit would be extended again, still no winner was found
1600         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1601         {
1602                 return 1; // need to call InitiateOvertime later
1603         }
1604         else
1605         {
1606                 if(!checkrules_suddendeathend)
1607                 {
1608                         if(autocvar_g_campaign)
1609                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1610                         else
1611                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1612                         if(g_race && !g_race_qualifying)
1613                                 race_StartCompleting();
1614                 }
1615                 return 0;
1616         }
1617 }
1618
1619 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1620 {
1621         ++checkrules_overtimesadded;
1622         //add one more overtime by simply extending the timelimit
1623         float tl;
1624         tl = autocvar_timelimit;
1625         tl += autocvar_timelimit_overtime;
1626         cvar_set("timelimit", ftos(tl));
1627
1628         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1629 }
1630
1631 float GetWinningCode(float fraglimitreached, float equality)
1632 {
1633         if(autocvar_g_campaign == 1)
1634                 if(fraglimitreached)
1635                         return WINNING_YES;
1636                 else
1637                         return WINNING_NO;
1638
1639         else
1640                 if(equality)
1641                         if(fraglimitreached)
1642                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1643                         else
1644                                 return WINNING_NEVER;
1645                 else
1646                         if(fraglimitreached)
1647                                 return WINNING_YES;
1648                         else
1649                                 return WINNING_NO;
1650 }
1651
1652 // set the .winning flag for exactly those players with a given field value
1653 void SetWinners(.float field, float value)
1654 {
1655         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1656 }
1657
1658 // set the .winning flag for those players with a given field value
1659 void AddWinners(.float field, float value)
1660 {
1661         FOREACH_CLIENT(IS_PLAYER(it), {
1662                 if(it.(field) == value)
1663                         it.winning = 1;
1664         });
1665 }
1666
1667 // clear the .winning flags
1668 void ClearWinners()
1669 {
1670         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1671 }
1672
1673 void ShuffleMaplist()
1674 {
1675         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1676 }
1677
1678 float leaderfrags;
1679 float WinningCondition_Scores(float limit, float leadlimit)
1680 {
1681         float limitreached;
1682
1683         // TODO make everything use THIS winning condition (except LMS)
1684         WinningConditionHelper(NULL);
1685
1686         if(teamplay)
1687         {
1688                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1689                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1690                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1691                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1692         }
1693
1694         ClearWinners();
1695         if(WinningConditionHelper_winner)
1696                 WinningConditionHelper_winner.winning = 1;
1697         if(WinningConditionHelper_winnerteam >= 0)
1698                 SetWinners(team, WinningConditionHelper_winnerteam);
1699
1700         if(WinningConditionHelper_lowerisbetter)
1701         {
1702                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1703                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1704                 limit = -limit;
1705         }
1706
1707         if(WinningConditionHelper_zeroisworst)
1708                 leadlimit = 0; // not supported in this mode
1709
1710         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1711         // these modes always score in increments of 1, thus this makes sense
1712         {
1713                 if(leaderfrags != WinningConditionHelper_topscore)
1714                 {
1715                         leaderfrags = WinningConditionHelper_topscore;
1716
1717                         if (limit)
1718                         if (leaderfrags == limit - 1)
1719                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1720                         else if (leaderfrags == limit - 2)
1721                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1722                         else if (leaderfrags == limit - 3)
1723                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1724                 }
1725         }
1726
1727         limitreached = false;
1728         if(limit)
1729                 if(WinningConditionHelper_topscore >= limit)
1730                         limitreached = true;
1731         if(leadlimit)
1732         {
1733                 float leadlimitreached;
1734                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1735                 if(autocvar_leadlimit_and_fraglimit)
1736                         limitreached = (limitreached && leadlimitreached);
1737                 else
1738                         limitreached = (limitreached || leadlimitreached);
1739         }
1740
1741         if(limit)
1742                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1743
1744         return GetWinningCode(
1745                 WinningConditionHelper_topscore && limitreached,
1746                 WinningConditionHelper_equality
1747         );
1748 }
1749
1750 float WinningCondition_RanOutOfSpawns()
1751 {
1752         if(have_team_spawns <= 0)
1753                 return WINNING_NO;
1754
1755         if(!autocvar_g_spawn_useallspawns)
1756                 return WINNING_NO;
1757
1758         if(!some_spawn_has_been_used)
1759                 return WINNING_NO;
1760
1761         team1_score = team2_score = team3_score = team4_score = 0;
1762
1763         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
1764                 switch(it.team)
1765                 {
1766                         case NUM_TEAM_1: team1_score = 1; break;
1767                         case NUM_TEAM_2: team2_score = 1; break;
1768                         case NUM_TEAM_3: team3_score = 1; break;
1769                         case NUM_TEAM_4: team4_score = 1; break;
1770                 }
1771         });
1772
1773         IL_EACH(g_spawnpoints, true,
1774         {
1775                 switch(it.team)
1776                 {
1777                         case NUM_TEAM_1: team1_score = 1; break;
1778                         case NUM_TEAM_2: team2_score = 1; break;
1779                         case NUM_TEAM_3: team3_score = 1; break;
1780                         case NUM_TEAM_4: team4_score = 1; break;
1781                 }
1782         });
1783
1784         ClearWinners();
1785         if(team1_score + team2_score + team3_score + team4_score == 0)
1786         {
1787                 checkrules_equality = true;
1788                 return WINNING_YES;
1789         }
1790         else if(team1_score + team2_score + team3_score + team4_score == 1)
1791         {
1792                 float t, i;
1793                 if(team1_score)
1794                         t = NUM_TEAM_1;
1795                 else if(team2_score)
1796                         t = NUM_TEAM_2;
1797                 else if(team3_score)
1798                         t = NUM_TEAM_3;
1799                 else // if(team4_score)
1800                         t = NUM_TEAM_4;
1801                 CheckAllowedTeams(NULL);
1802                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1803                 {
1804                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1805                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1806                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1807                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1808                 }
1809
1810                 AddWinners(team, t);
1811                 return WINNING_YES;
1812         }
1813         else
1814                 return WINNING_NO;
1815 }
1816
1817 /*
1818 ============
1819 CheckRules_World
1820
1821 Exit deathmatch games upon conditions
1822 ============
1823 */
1824 void CheckRules_World()
1825 {
1826         float timelimit;
1827         float fraglimit;
1828         float leadlimit;
1829
1830         VoteThink();
1831         MapVote_Think();
1832
1833         SetDefaultAlpha();
1834
1835         if (intermission_running) // someone else quit the game already
1836         {
1837                 if(player_count == 0) // Nobody there? Then let's go to the next map
1838                         MapVote_Start();
1839                         // this will actually check the player count in the next frame
1840                         // again, but this shouldn't hurt
1841                 return;
1842         }
1843
1844         timelimit = autocvar_timelimit * 60;
1845         fraglimit = autocvar_fraglimit;
1846         leadlimit = autocvar_leadlimit;
1847
1848         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1849         {
1850                 if(timelimit > 0)
1851                         timelimit = 0; // timelimit is not made for warmup
1852                 if(fraglimit > 0)
1853                         fraglimit = 0; // no fraglimit for now
1854                 leadlimit = 0; // no leadlimit for now
1855         }
1856
1857         if(timelimit > 0)
1858         {
1859                 timelimit += game_starttime;
1860         }
1861         else if (timelimit < 0)
1862         {
1863                 // endmatch
1864                 NextLevel();
1865                 return;
1866         }
1867
1868         float wantovertime;
1869         wantovertime = 0;
1870
1871         if(timelimit > game_starttime)
1872                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1873         else
1874                 game_completion_ratio = 0;
1875
1876         if(checkrules_suddendeathend)
1877         {
1878                 if(!checkrules_suddendeathwarning)
1879                 {
1880                         checkrules_suddendeathwarning = true;
1881                         if(g_race && !g_race_qualifying)
1882                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1883                         else
1884                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1885                 }
1886         }
1887         else
1888         {
1889                 if (timelimit && time >= timelimit)
1890                 {
1891                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1892                         {
1893                                 float totalplayers;
1894                                 float playerswithlaps;
1895                                 float readyplayers;
1896                                 totalplayers = playerswithlaps = readyplayers = 0;
1897                                 FOREACH_CLIENT(IS_PLAYER(it), {
1898                                         ++totalplayers;
1899                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1900                                                 ++playerswithlaps;
1901                                         if(it.ready)
1902                                                 ++readyplayers;
1903                                 });
1904
1905                                 // at least 2 of the players have completed a lap: start the RACE
1906                                 // otherwise, the players should end the qualifying on their own
1907                                 if(readyplayers || playerswithlaps >= 2)
1908                                 {
1909                                         checkrules_suddendeathend = 0;
1910                                         ReadyRestart(); // go to race
1911                                         return;
1912                                 }
1913                                 else
1914                                         wantovertime |= InitiateSuddenDeath();
1915                         }
1916                         else
1917                                 wantovertime |= InitiateSuddenDeath();
1918                 }
1919         }
1920
1921         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1922         {
1923                 NextLevel();
1924                 return;
1925         }
1926
1927         int checkrules_status = WinningCondition_RanOutOfSpawns();
1928         if(checkrules_status == WINNING_YES)
1929                 bprint("Hey! Someone ran out of spawns!\n");
1930         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1931                 checkrules_status = M_ARGV(0, float);
1932         else
1933                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1934
1935         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1936         {
1937                 checkrules_status = WINNING_NEVER;
1938                 checkrules_overtimesadded = -1;
1939                 wantovertime |= InitiateSuddenDeath();
1940         }
1941
1942         if(checkrules_status == WINNING_NEVER)
1943                 // equality cases! Nobody wins if the overtime ends in a draw.
1944                 ClearWinners();
1945
1946         if(wantovertime)
1947         {
1948                 if(checkrules_status == WINNING_NEVER)
1949                         InitiateOvertime();
1950                 else
1951                         checkrules_status = WINNING_YES;
1952         }
1953
1954         if(checkrules_suddendeathend)
1955                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1956                         checkrules_status = WINNING_YES;
1957
1958         if(checkrules_status == WINNING_YES)
1959         {
1960                 //print("WINNING\n");
1961                 NextLevel();
1962         }
1963 }
1964
1965 string GotoMap(string m)
1966 {
1967         m = GameTypeVote_MapInfo_FixName(m);
1968         if (!m)
1969                 return "The map you suggested is not available on this server.";
1970         if (!autocvar_sv_vote_gametype)
1971         if(!MapInfo_CheckMap(m))
1972                 return "The map you suggested does not support the current game mode.";
1973         cvar_set("nextmap", m);
1974         cvar_set("timelimit", "-1");
1975         if(mapvote_initialized || alreadychangedlevel)
1976         {
1977                 if(DoNextMapOverride(0))
1978                         return "Map switch initiated.";
1979                 else
1980                         return "Hm... no. For some reason I like THIS map more.";
1981         }
1982         else
1983                 return "Map switch will happen after scoreboard.";
1984 }
1985
1986 bool autocvar_sv_gameplayfix_multiplethinksperframe;
1987 void RunThink(entity this)
1988 {
1989         // don't let things stay in the past.
1990         // it is possible to start that way by a trigger with a local time.
1991         if(this.nextthink <= 0 || this.nextthink > time + frametime)
1992                 return;
1993
1994         float oldtime = time; // do we need to save this?
1995
1996         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
1997         {
1998                 time = max(oldtime, this.nextthink);
1999                 this.nextthink = 0;
2000
2001                 if(getthink(this))
2002                         getthink(this)(this);
2003                 // mods often set nextthink to time to cause a think every frame,
2004                 // we don't want to loop in that case, so exit if the new nextthink is
2005                 // <= the time the qc was told, also exit if it is past the end of the
2006                 // frame
2007                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2008                         break;
2009         }
2010
2011         time = oldtime;
2012 }
2013
2014 bool autocvar_sv_freezenonclients;
2015 bool autocvar_sv_gameplayfix_delayprojectiles;
2016 void Physics_Frame()
2017 {
2018         if(autocvar_sv_freezenonclients)
2019                 return;
2020
2021         FOREACH_ENTITY_FLOAT(pure_data, false,
2022         {
2023                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2024                         continue;
2025
2026                 //set_movetype(it, it.move_movetype);
2027                 // inline the set_movetype function, since this is called a lot
2028                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2029
2030                 if(it.move_movetype == MOVETYPE_NONE)
2031                         continue;
2032
2033                 if(it.move_qcphysics)
2034                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2035
2036                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2037                 {
2038                         // handle thinking here
2039                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2040                                 RunThink(it);
2041                 }
2042         });
2043
2044         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2045                 return;
2046
2047         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2048         {
2049                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2050                         continue;
2051                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2052         });
2053 }
2054
2055 void systems_update();
2056 void EndFrame()
2057 {
2058         anticheat_endframe();
2059
2060         Physics_Frame();
2061
2062         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2063                 entity e = IS_SPEC(it) ? it.enemy : it;
2064                 if (e.typehitsound) {
2065                         STAT(TYPEHIT_TIME, it) = time;
2066                 } else if (e.killsound) {
2067                         STAT(KILL_TIME, it) = time;
2068                 } else if (e.damage_dealt) {
2069                         STAT(HIT_TIME, it) = time;
2070                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2071                 }
2072         });
2073         // add 1 frametime because after this, engine SV_Physics
2074         // increases time by a frametime and then networks the frame
2075         // add another frametime because client shows everything with
2076         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2077         // needed!
2078         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2079         FOREACH_CLIENT(true, {
2080                 it.typehitsound = false;
2081                 it.damage_dealt = 0;
2082                 it.killsound = false;
2083                 antilag_record(it, CS(it), altime);
2084         });
2085         IL_EACH(g_monsters, true,
2086         {
2087                 antilag_record(it, it, altime);
2088         });
2089         IL_EACH(g_projectiles, it.classname == "nade",
2090         {
2091                 antilag_record(it, it, altime);
2092         });
2093         systems_update();
2094         IL_ENDFRAME();
2095 }
2096
2097
2098 /*
2099  * RedirectionThink:
2100  * returns true if redirecting
2101  */
2102 float redirection_timeout;
2103 float redirection_nextthink;
2104 float RedirectionThink()
2105 {
2106         float clients_found;
2107
2108         if(redirection_target == "")
2109                 return false;
2110
2111         if(!redirection_timeout)
2112         {
2113                 cvar_set("sv_public", "-2");
2114                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2115                 if(redirection_target == "self")
2116                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2117                 else
2118                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2119         }
2120
2121         if(time < redirection_nextthink)
2122                 return true;
2123
2124         redirection_nextthink = time + 1;
2125
2126         clients_found = 0;
2127         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2128                 // TODO add timer
2129                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2130                 if(redirection_target == "self")
2131                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2132                 else
2133                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2134                 ++clients_found;
2135         });
2136
2137         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2138
2139         if(time > redirection_timeout || clients_found == 0)
2140                 localcmd("\nwait; wait; wait; quit\n");
2141
2142         return true;
2143 }
2144
2145 void TargetMusic_RestoreGame();
2146 void RestoreGame()
2147 {
2148         // Loaded from a save game
2149         // some things then break, so let's work around them...
2150
2151         // Progs DB (capture records)
2152         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2153
2154         // Mapinfo
2155         MapInfo_Shutdown();
2156         MapInfo_Enumerate();
2157         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2158         WeaponStats_Init();
2159
2160         TargetMusic_RestoreGame();
2161 }
2162
2163 void Shutdown()
2164 {
2165         game_stopped = 2;
2166
2167         if(world_initialized > 0)
2168         {
2169                 world_initialized = 0;
2170                 LOG_TRACE("Saving persistent data...");
2171                 Ban_SaveBans();
2172
2173                 // playerstats with unfinished match
2174                 PlayerStats_GameReport(false);
2175
2176                 if(!cheatcount_total)
2177                 {
2178                         if(autocvar_sv_db_saveasdump)
2179                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2180                         else
2181                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2182                 }
2183                 if(autocvar_developer)
2184                 {
2185                         if(autocvar_sv_db_saveasdump)
2186                                 db_dump(TemporaryDB, "server-temp.db");
2187                         else
2188                                 db_save(TemporaryDB, "server-temp.db");
2189                 }
2190                 CheatShutdown(); // must be after cheatcount check
2191                 db_close(ServerProgsDB);
2192                 db_close(TemporaryDB);
2193                 LOG_TRACE("Saving persistent data... done!");
2194                 // tell the bot system the game is ending now
2195                 bot_endgame();
2196
2197                 WeaponStats_Shutdown();
2198                 MapInfo_Shutdown();
2199         }
2200         else if(world_initialized == 0)
2201         {
2202                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2203         }
2204         else
2205         {
2206                 __init_dedicated_server_shutdown();
2207         }
2208 }