qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312
 313                 // these can contain player IDs, so better hide
 314                 BADPREFIX("g_forced_team_");
 315
 316                 // mapinfo
 317                 BADCVAR("fraglimit");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_assault");
 320                 BADCVAR("g_ca");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_cts");
 323                 BADCVAR("g_dm");
 324                 BADCVAR("g_domination");
 325                 BADCVAR("g_domination_default_teams");
 326                 BADCVAR("g_freezetag");
 327                 BADCVAR("g_keepaway");
 328                 BADCVAR("g_keyhunt");
 329                 BADCVAR("g_keyhunt_teams");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_lms");
 332                 BADCVAR("g_nexball");
 333                 BADCVAR("g_onslaught");
 334                 BADCVAR("g_race");
 335                 BADCVAR("g_race_qualifying_timelimit");
 336                 BADCVAR("g_runematch");
 337                 BADCVAR("g_tdm");
 338                 BADCVAR("g_tdm_teams");
 339                 BADCVAR("leadlimit");
 340                 BADCVAR("nextmap");
 341                 BADCVAR("teamplay");
 342                 BADCVAR("timelimit");
 343
 344                 // long
 345                 BADCVAR("hostname");
 346                 BADCVAR("g_maplist");
 347                 BADCVAR("g_maplist_mostrecent");
 348                 BADCVAR("sv_motd");
 349
 350                 v = cvar_string(k);
 351                 d = cvar_defstring(k);
 352                 if(v == d)
 353                         continue;
 354
 355                 if(adding)
 356                 {
 357                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 358                         if(strlen(cvar_changes) > 16384)
 359                         {
 360                                 cvar_changes = "// too many settings have been changed to show them here\n";
 361                                 adding = 0;
 362                         }
 363                 }
 364
 365                 // now check if the changes are actually gameplay relevant
 366
 367                 // does nothing visible
 368                 BADCVAR("captureleadlimit_override");
 369                 BADCVAR("g_arena_point_leadlimit");
 370                 BADCVAR("g_balance_kill_delay");
 371                 BADCVAR("g_ca_point_leadlimit");
 372                 BADCVAR("g_ctf_captimerecord_always");
 373                 BADCVAR("g_ctf_capture_leadlimit");
 374                 BADCVAR("g_ctf_flag_capture_effects");
 375                 BADCVAR("g_ctf_flag_glowtrails");
 376                 BADCVAR("g_ctf_flag_pickup_effects");
 377                 BADCVAR("g_domination_point_leadlimit");
 378                 BADCVAR("g_forced_respawn");
 379                 BADCVAR("g_keyhunt_point_leadlimit");
 380                 BADCVAR("g_nexball_goalleadlimit");
 381                 BADCVAR("g_runematch_point_leadlimit");
 382                 BADCVAR("leadlimit_and_fraglimit");
 383                 BADCVAR("leadlimit_override");
 384                 BADCVAR("pausable");
 385                 BADCVAR("sv_checkforpacketsduringsleep");
 386                 BADCVAR("sv_timeout");
 387                 BADCVAR("welcome_message_time");
 388                 BADPREFIX("crypto_");
 389                 BADPREFIX("g_chat_");
 390                 BADPREFIX("g_ctf_captimerecord_");
 391                 BADPREFIX("g_maplist_votable_");
 392                 BADPREFIX("net_");
 393                 BADPREFIX("prvm_");
 394                 BADPREFIX("skill_");
 395                 BADPREFIX("sv_fragmessage_");
 396                 BADPREFIX("sv_maxidle_");
 397                 BADPREFIX("sv_vote_");
 398                 BADPREFIX("timelimit_");
 399                 BADCVAR("gameversion");
 400                 BADPREFIX("gameversion_");
 401
 402                 // allowed changes to server admins (please sync this to server.cfg)
 403                 // vi commands:
 404                 //   :/"impure"/,$d
 405                 //   :g!,^\/\/[^ /],d
 406                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 407                 //   :%!sort
 408                 // yes, this does contain some redundant stuff, don't really care
 409                 BADCVAR("bot_number");
 410                 BADCVAR("bot_prefix");
 411                 BADCVAR("bot_suffix");
 412                 BADCVAR("bot_config_file");
 413                 BADCVAR("capturelimit_override");
 414                 BADCVAR("fraglimit_override");
 415                 BADCVAR("gametype");
 416                 BADCVAR("g_antilag");
 417                 BADCVAR("g_balance_teams");
 418                 BADCVAR("g_balance_teams_force");
 419                 BADCVAR("g_ban_sync_trusted_servers");
 420                 BADCVAR("g_ban_sync_uri");
 421                 BADCVAR("g_ctf_capture_limit");
 422                 BADCVAR("g_ctf_ignore_frags");
 423                 BADCVAR("g_ctf_win_mode");
 424                 BADCVAR("g_domination_point_limit");
 425                 BADCVAR("g_friendlyfire");
 426                 BADCVAR("g_fullbrightitems");
 427                 BADCVAR("g_fullbrightplayers");
 428                 BADCVAR("g_keyhunt_point_limit");
 429                 BADCVAR("g_keyhunt_teams_override");
 430                 BADCVAR("g_lms_lives_override");
 431                 BADCVAR("g_maplist");
 432                 BADCVAR("g_maplist_check_waypoints");
 433                 BADCVAR("g_maplist_mostrecent_count");
 434                 BADCVAR("g_maplist_shuffle");
 435                 BADCVAR("g_maplist_votable");
 436                 BADCVAR("g_maplist_votable_abstain");
 437                 BADCVAR("g_maplist_votable_nodetail");
 438                 BADCVAR("g_maplist_votable_suggestions");
 439                 BADCVAR("g_maxplayers");
 440                 BADCVAR("g_minstagib");
 441                 BADCVAR("g_mirrordamage");
 442                 BADCVAR("g_nexball_goallimit");
 443                 BADCVAR("g_runematch_point_limit");
 444                 BADCVAR("g_start_delay");
 445                 BADCVAR("g_warmup");
 446                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 447                 BADCVAR("hostname");
 448                 BADCVAR("log_file");
 449                 BADCVAR("maxplayers");
 450                 BADCVAR("minplayers");
 451                 BADCVAR("net_address");
 452                 BADCVAR("port");
 453                 BADCVAR("rcon_password");
 454                 BADCVAR("rcon_restricted_commands");
 455                 BADCVAR("rcon_restricted_password");
 456                 BADCVAR("skill");
 457                 BADCVAR("sv_adminnick");
 458                 BADCVAR("sv_autoscreenshot");
 459                 BADCVAR("sv_curl_defaulturl");
 460                 BADCVAR("sv_defaultcharacter");
 461                 BADCVAR("sv_defaultplayercolors");
 462                 BADCVAR("sv_defaultplayermodel");
 463                 BADCVAR("sv_defaultplayerskin");
 464                 BADCVAR("sv_maxidle");
 465                 BADCVAR("sv_maxrate");
 466                 BADCVAR("sv_motd");
 467                 BADCVAR("sv_public");
 468                 BADCVAR("sv_ready_restart");
 469                 BADCVAR("sv_status_privacy");
 470                 BADCVAR("sv_vote_call");
 471                 BADCVAR("sv_vote_commands");
 472                 BADCVAR("sv_vote_majority_factor");
 473                 BADCVAR("sv_vote_master");
 474                 BADCVAR("sv_vote_master_commands");
 475                 BADCVAR("sv_vote_master_password");
 476                 BADCVAR("sv_vote_simple_majority_factor");
 477                 BADCVAR("sys_ticrate");
 478                 BADCVAR("teamplay_mode");
 479                 BADCVAR("timelimit_override");
 480                 BADPREFIX("g_warmup_");
 481
 482                 if(autocvar_g_minstagib)
 483                 {
 484                         BADCVAR("g_grappling_hook");
 485                         BADCVAR("g_jetpack");
 486                 }
 487 #undef BADPREFIX
 488 #undef BADCVAR
 489
 490                 if(pureadding)
 491                 {
 492                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 493                         if(strlen(cvar_purechanges) > 16384)
 494                         {
 495                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 496                                 pureadding = 0;
 497                         }
 498                 }
 499                 ++cvar_purechanges_count;
 500                 // WARNING: this variable is used for the server list
 501                 // NEVER dare to skip this code!
 502                 // Hacks to intentionally appearing as "pure server" even though you DO have
 503                 // modified settings may be punished by removal from the server list.
 504                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 505                 // though.
 506         }
 507         buf_del(h);
 508         if(cvar_changes == "")
 509                 cvar_changes = "// this server runs at default server settings\n";
 510         else
 511                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 512         cvar_changes = strzone(cvar_changes);
 513         if(cvar_purechanges == "")
 514                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 515         else
 516                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 517         cvar_purechanges = strzone(cvar_purechanges);
 518 }
 519
 520 void detect_maptype()
 521 {
 522 #if 0
 523         vector o, v;
 524         float i;
 525
 526         for(;;)
 527         {
 528                 o = world.mins;
 529                 o_x += random() * (world.maxs_x - world.mins_x);
 530                 o_y += random() * (world.maxs_y - world.mins_y);
 531                 o_z += random() * (world.maxs_z - world.mins_z);
 532
 533                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 534                 if(trace_fraction == 1)
 535                         continue;
 536
 537                 v = trace_endpos;
 538
 539                 for(i = 0; i < 64; i += 4)
 540                 {
 541                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 542         if(trace_fraction == 1)
 543                 continue;
 544                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 545                 }
 546
 547                 break;
 548         }
 549 #endif
 550 }
 551
 552 entity randomseed;
 553 float RandomSeed_Send(entity to, float sf)
 554 {
 555         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 556         WriteShort(MSG_ENTITY, self.cnt);
 557         return TRUE;
 558 }
 559 void RandomSeed_Think()
 560 {
 561         self.cnt = bound(0, floor(random() * 65536), 65535);
 562         self.nextthink = time + 5;
 563
 564         self.SendFlags |= 1;
 565 }
 566 void RandomSeed_Spawn()
 567 {
 568         randomseed = spawn();
 569         randomseed.think = RandomSeed_Think;
 570         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 571
 572         entity oldself;
 573         oldself = self;
 574         self = randomseed;
 575         self.think(); // sets random seed and nextthink
 576         self = oldself;
 577 }
 578
 579 void spawnfunc___init_dedicated_server(void)
 580 {
 581         // handler for _init/_init map (only for dedicated server initialization)
 582
 583         world_initialized = -1; // don't complain
 584         cvar = cvar_normal;
 585         cvar_string = cvar_string_normal;
 586         cvar_set = cvar_set_normal;
 587
 588         remove = remove_unsafely;
 589
 590         entity e;
 591         e = spawn();
 592         e.think = GotoFirstMap;
 593         e.nextthink = time; // this is usually 1 at this point
 594
 595         e = spawn();
 596         e.classname = "info_player_deathmatch"; // safeguard against player joining
 597
 598         self.classname = "worldspawn"; // safeguard against various stuff ;)
 599
 600         MapInfo_Enumerate();
 601         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 602 }
 603
 604 void Map_MarkAsRecent(string m);
 605 float world_already_spawned;
 606 void RegisterWeapons();
 607 void Nagger_Init();
 608 void ClientInit_Spawn();
 609 void WeaponStats_Init();
 610 void WeaponStats_Shutdown();
 611 void spawnfunc_worldspawn (void)
 612 {
 613         float fd, l, i, j, n;
 614         string s, col;
 615
 616         cvar = cvar_normal;
 617         cvar_string = cvar_string_normal;
 618         cvar_set = cvar_set_normal;
 619
 620         if(world_already_spawned)
 621                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 622         world_already_spawned = TRUE;
 623
 624         remove = remove_safely; // during spawning, watch what you remove!
 625
 626         check_unacceptable_compiler_bugs();
 627
 628         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 629
 630         compressShortVector_init();
 631
 632         allowed_to_spawn = TRUE;
 633
 634         entity head;
 635         head = nextent(world);
 636         maxclients = 0;
 637         while(head)
 638         {
 639                 ++maxclients;
 640                 head = nextent(head);
 641         }
 642
 643         // needs to be done so early as they would still spawn
 644         RegisterWeapons();
 645
 646         ServerProgsDB = db_load("server.db");
 647
 648         TemporaryDB = db_create();
 649
 650         // 0 normal
 651         lightstyle(0, "m");
 652
 653         // 1 FLICKER (first variety)
 654         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 655
 656         // 2 SLOW STRONG PULSE
 657         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 658
 659         // 3 CANDLE (first variety)
 660         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 661
 662         // 4 FAST STROBE
 663         lightstyle(4, "mamamamamama");
 664
 665         // 5 GENTLE PULSE 1
 666         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 667
 668         // 6 FLICKER (second variety)
 669         lightstyle(6, "nmonqnmomnmomomno");
 670
 671         // 7 CANDLE (second variety)
 672         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 673
 674         // 8 CANDLE (third variety)
 675         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 676
 677         // 9 SLOW STROBE (fourth variety)
 678         lightstyle(9, "aaaaaaaazzzzzzzz");
 679
 680         // 10 FLUORESCENT FLICKER
 681         lightstyle(10, "mmamammmmammamamaaamammma");
 682
 683         // 11 SLOW PULSE NOT FADE TO BLACK
 684         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 685
 686         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 687
 688         // 63 testing
 689         lightstyle(63, "a");
 690
 691         if(autocvar_g_campaign)
 692                 CampaignPreInit();
 693
 694         Map_MarkAsRecent(mapname);
 695
 696         precache_model ("null"); // we need this one before InitGameplayMode
 697         InitGameplayMode();
 698         readlevelcvars();
 699         GrappleHookInit();
 700         ElectroInit();
 701         LaserInit();
 702
 703         player_count = 0;
 704         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 705         if(bot_waypoints_for_items == 1)
 706                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 707                         bot_waypoints_for_items = 0;
 708
 709         precache();
 710
 711         WaypointSprite_Init();
 712
 713         //if (g_domination)
 714         //      dom_init();
 715
 716         GameLogInit(); // prepare everything
 717         if(autocvar_sv_eventlog)
 718         {
 719                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 720                 matchid = strzone(s);
 721
 722                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 723                 s = ":gameinfo:mutators:LIST";
 724
 725                 ret_string = s;
 726                 MUTATOR_CALLHOOK(BuildMutatorsString);
 727                 s = ret_string;
 728
 729                 // simple, probably not good in the mutator system
 730                 if(autocvar_g_grappling_hook)
 731                         s = strcat(s, ":grappling_hook");
 732
 733                 // initialiation stuff, not good in the mutator system
 734                 if(!autocvar_g_use_ammunition)
 735                         s = strcat(s, ":no_use_ammunition");
 736
 737                 // initialiation stuff, not good in the mutator system
 738                 if(!autocvar_g_pickup_items)
 739                         s = strcat(s, ":no_pickup_items");
 740
 741                 // initialiation stuff, not good in the mutator system
 742                 if(autocvar_g_weaponarena != "0")
 743                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 744
 745                 // TODO to mutator system
 746                 if(autocvar_g_norecoil)
 747                         s = strcat(s, ":norecoil");
 748
 749                 // TODO to mutator system
 750                 if(autocvar_g_midair)
 751                         s = strcat(s, ":midair");
 752
 753                 // TODO to mutator system
 754                 if(autocvar_g_minstagib)
 755                         s = strcat(s, ":minstagib");
 756
 757                 GameLogEcho(s);
 758                 GameLogEcho(":gameinfo:end");
 759         }
 760         else
 761                 matchid = strzone(ftos(random()));
 762
 763         cvar_set("nextmap", "");
 764
 765         SetDefaultAlpha();
 766
 767         if(autocvar_g_campaign)
 768                 CampaignPostInit();
 769
 770         fteqcc_testbugs();
 771
 772         Ban_LoadBans();
 773
 774         MapInfo_Enumerate();
 775         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 776
 777         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 778         {
 779                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 780                 if(fd != -1)
 781                 {
 782                         while((s = fgets(fd)))
 783                         {
 784                                 l = tokenize_console(s);
 785                                 if(l < 2)
 786                                         continue;
 787                                 if(argv(0) == "cd")
 788                                 {
 789                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 790                                         print("  cdtrack ", argv(2), "\n");
 791                                 }
 792                                 else if(argv(0) == "fog")
 793                                 {
 794                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 795                                         print("  \"fog\" \"", s, "\"\n");
 796                                 }
 797                                 else if(argv(0) == "set")
 798                                 {
 799                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 800                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 801                                 }
 802                                 else if(argv(0) != "//")
 803                                 {
 804                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 805                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 806                                 }
 807                         }
 808                         fclose(fd);
 809                 }
 810         }
 811
 812         WeaponStats_Init();
 813
 814         addstat(STAT_WEAPONS, AS_INT, weapons);
 815         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 816         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 817         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 818         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 819         Nagger_Init();
 820
 821         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 822         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 823         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 824         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 825         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 826         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 827         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 828         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 829         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 830         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 831         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 832         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 833
 834         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 835         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 836
 837         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 838
 839         if(g_ca || g_freezetag)
 840         {
 841                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 842                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 843                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 844                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 845         }
 846         if(g_freezetag)
 847         {
 848                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 849                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 850         }
 851
 852         // g_movementspeed hack
 853         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 854         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 855         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 856         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 857
 858         next_pingtime = time + 5;
 859
 860         detect_maptype();
 861
 862         lsmaps_reply = "^7Maps available: ";
 863         lsnewmaps_reply = "^7Maps without a record set: ";
 864         for(i = 0, j = 0; i < MapInfo_count; ++i)
 865         {
 866                 if(MapInfo_Get_ByID(i))
 867                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 868                         {
 869                                 if(mod(i, 2))
 870                                         col = "^2";
 871                                 else
 872                                         col = "^3";
 873                                 ++j;
 874                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 875                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 876                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 877                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 878                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 879                         }
 880         }
 881         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 882         if (!g_race && !g_cts)
 883                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 884         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 885
 886         maplist_reply = "^7Maps in list: ";
 887         n = tokenize_console(autocvar_g_maplist);
 888         for(i = 0, j = 0; i < n; ++i)
 889         {
 890                 if(MapInfo_CheckMap(argv(i)))
 891                 {
 892                         if(mod(j, 2))
 893                                 col = "^2";
 894                         else
 895                                 col = "^3";
 896                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 897                         ++j;
 898                 }
 899         }
 900         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 901         MapInfo_ClearTemps();
 902
 903         for(i = 0; i < 10; ++i)
 904         {
 905                 records_reply[i] = strzone(getrecords(i));
 906         }
 907         if(g_cts)
 908                 ladder_reply = strzone(getladder());
 909
 910         rankings_reply = strzone(getrankings());
 911
 912         ClientInit_Spawn();
 913         RandomSeed_Spawn();
 914         PingPLReport_Spawn();
 915
 916         CheatInit();
 917
 918         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 919
 920         // fill sv_curl_serverpackages from .serverpackage files
 921         if(autocvar_sv_curl_serverpackages_auto)
 922         {
 923                 s = "";
 924                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 925                 for(i = 0; i < n; ++i)
 926                         if(substring(argv(i), -14, -1) != ".serverpackage")
 927                                 s = strcat(s, " ", argv(i));
 928                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 929                 if(fd >= 0)
 930                 {
 931                         j = search_getsize(fd);
 932                         for(i = 0; i < j; ++i)
 933                                 s = strcat(s, " ", search_getfilename(fd, i));
 934                         search_end(fd);
 935                 }
 936                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 937         }
 938
 939         PlayerStats_Init();
 940
 941         world_initialized = 1;
 942 }
 943
 944 void spawnfunc_light (void)
 945 {
 946         //makestatic (self); // Who the f___ did that?
 947         remove(self);
 948 }
 949
 950 string GetGametype()
 951 {
 952         return GametypeNameFromType(game);
 953 }
 954
 955 string getmapname_stored;
 956 string GetMapname()
 957 {
 958         return mapname;
 959 }
 960
 961 float Map_Count, Map_Current;
 962 string Map_Current_Name;
 963
 964 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 965 float GetMaplistPosition()
 966 {
 967         float pos, idx;
 968         string map;
 969
 970         map = GetMapname();
 971         idx = autocvar_g_maplist_index;
 972
 973         if(idx >= 0)
 974                 if(idx < Map_Count)
 975                         if(map == argv(idx))
 976                                 return idx;
 977
 978         for(pos = 0; pos < Map_Count; ++pos)
 979                 if(map == argv(pos))
 980                         return pos;
 981
 982         // resume normal maplist rotation if current map is not in g_maplist
 983         return idx;
 984 }
 985
 986 float MapHasRightSize(string map)
 987 {
 988         float fh;
 989         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 990         if(autocvar_g_maplist_check_waypoints)
 991         {
 992                 dprint("checkwp "); dprint(map);
 993                 if(!fexists(strcat("maps/", map, ".waypoints")))
 994                 {
 995                         dprint(": no waypoints\n");
 996                         return FALSE;
 997                 }
 998                 dprint(": has waypoints\n");
 999         }
1000
1001         // open map size restriction file
1002         dprint("opensize "); dprint(map);
1003         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1004         if(fh >= 0)
1005         {
1006                 float mapmin, mapmax;
1007                 dprint(": ok, ");
1008                 mapmin = stof(fgets(fh));
1009                 mapmax = stof(fgets(fh));
1010                 fclose(fh);
1011                 if(player_count < mapmin)
1012                 {
1013                         dprint("not enough\n");
1014                         return FALSE;
1015                 }
1016                 if(player_count > mapmax)
1017                 {
1018                         dprint("too many\n");
1019                         return FALSE;
1020                 }
1021                 dprint("right size\n");
1022                 return TRUE;
1023         }
1024         dprint(": not found\n");
1025         return TRUE;
1026 }
1027
1028 string Map_Filename(float position)
1029 {
1030         return strcat("maps/", argv(position), ".bsp");
1031 }
1032
1033 string strwords(string s, float w)
1034 {
1035         float endpos;
1036         for(endpos = 0; w && endpos >= 0; --w)
1037                 endpos = strstrofs(s, " ", endpos + 1);
1038         if(endpos < 0)
1039                 return s;
1040         else
1041                 return substring(s, 0, endpos);
1042 }
1043
1044 float strhasword(string s, string w)
1045 {
1046         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1047 }
1048
1049 void Map_MarkAsRecent(string m)
1050 {
1051         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1052 }
1053
1054 float Map_IsRecent(string m)
1055 {
1056         return strhasword(autocvar_g_maplist_mostrecent, m);
1057 }
1058
1059 float Map_Check(float position, float pass)
1060 {
1061         string filename;
1062         string map_next;
1063         map_next = argv(position);
1064         if(pass <= 1)
1065         {
1066                 if(Map_IsRecent(map_next))
1067                         return 0;
1068         }
1069         filename = Map_Filename(position);
1070         if(MapInfo_CheckMap(map_next))
1071         {
1072                 if(pass == 2)
1073                         return 1;
1074                 if(MapHasRightSize(map_next))
1075                         return 1;
1076                 return 0;
1077         }
1078         else
1079                 dprint( "Couldn't select '", filename, "'..\n" );
1080
1081         return 0;
1082 }
1083
1084 void Map_Goto_SetStr(string nextmapname)
1085 {
1086         if(getmapname_stored != "")
1087                 strunzone(getmapname_stored);
1088         if(nextmapname == "")
1089                 getmapname_stored = "";
1090         else
1091                 getmapname_stored = strzone(nextmapname);
1092 }
1093
1094 void Map_Goto_SetFloat(float position)
1095 {
1096         cvar_set("g_maplist_index", ftos(position));
1097         Map_Goto_SetStr(argv(position));
1098 }
1099
1100 void GameResetCfg()
1101 {
1102         // settings persist, except...
1103         localcmd("\nsettemp_restore\n");
1104 }
1105
1106 void Map_Goto()
1107 {
1108         GameResetCfg();
1109         MapInfo_LoadMap(getmapname_stored);
1110 }
1111
1112 // return codes of map selectors:
1113 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1114 //   -2 = permanent failure
1115 float() MaplistMethod_Iterate = // usual method
1116 {
1117         float pass, i;
1118
1119         for(pass = 1; pass <= 2; ++pass)
1120         {
1121                 for(i = 1; i < Map_Count; ++i)
1122                 {
1123                         float mapindex;
1124                         mapindex = mod(i + Map_Current, Map_Count);
1125                         if(Map_Check(mapindex, pass))
1126                                 return mapindex;
1127                 }
1128         }
1129         return -1;
1130 }
1131
1132 float() MaplistMethod_Repeat = // fallback method
1133 {
1134         if(Map_Check(Map_Current, 2))
1135                 return Map_Current;
1136         return -2;
1137 }
1138
1139 float() MaplistMethod_Random = // random map selection
1140 {
1141         float i, imax;
1142
1143         imax = 42;
1144
1145         for(i = 0; i <= imax; ++i)
1146         {
1147                 float mapindex;
1148                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1149                 if(Map_Check(mapindex, 1))
1150                         return mapindex;
1151         }
1152         return -1;
1153 }
1154
1155 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1156 // the exponent sets a bias on the map selection:
1157 // the higher the exponent, the less likely "shortly repeated" same maps are
1158 {
1159         float i, j, imax, insertpos;
1160
1161         imax = 42;
1162
1163         for(i = 0; i <= imax; ++i)
1164         {
1165                 string newlist;
1166
1167                 // now reinsert this at another position
1168                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1169                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1170                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1171                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1172
1173                 // insert the current map there
1174                 newlist = "";
1175                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1176                         newlist = strcat(newlist, " ", argv(j));
1177                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1178                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1179                         newlist = strcat(newlist, " ", argv(j));
1180                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1181                 cvar_set("g_maplist", newlist);
1182                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1183
1184                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1185                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1186                 if(Map_Check(Map_Current, 1))
1187                         return Map_Current;
1188         }
1189         return -1;
1190 }
1191
1192 void Maplist_Init()
1193 {
1194         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1195         if(Map_Count == 0)
1196         {
1197                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1198                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1199                 if(autocvar_g_maplist_shuffle)
1200                         ShuffleMaplist();
1201                 localcmd("\nmenu_cmd sync\n");
1202                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1203         }
1204         if(Map_Count == 0)
1205                 error("empty maplist, cannot select a new map");
1206         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1207
1208         if(Map_Current_Name)
1209                 strunzone(Map_Current_Name);
1210         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1211         // this may or may not be correct, but who cares, in the worst case a map
1212         // isn't chosen in the first pass that should have been
1213 }
1214
1215 string GetNextMap()
1216 {
1217         float nextMap;
1218
1219         Maplist_Init();
1220         nextMap = -1;
1221
1222         if(nextMap == -1)
1223                 if(autocvar_g_maplist_shuffle > 0)
1224                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1225
1226         if(nextMap == -1)
1227                 if(autocvar_g_maplist_selectrandom)
1228                         nextMap = MaplistMethod_Random();
1229
1230         if(nextMap == -1)
1231                 nextMap = MaplistMethod_Iterate();
1232
1233         if(nextMap == -1)
1234                 nextMap = MaplistMethod_Repeat();
1235
1236         if(nextMap >= 0)
1237         {
1238                 Map_Goto_SetFloat(nextMap);
1239                 return getmapname_stored;
1240         }
1241
1242         return "";
1243 }
1244
1245 float DoNextMapOverride()
1246 {
1247         if(autocvar_g_campaign)
1248         {
1249                 CampaignPostIntermission();
1250                 alreadychangedlevel = TRUE;
1251                 return TRUE;
1252         }
1253         if(autocvar_quit_when_empty)
1254         {
1255                 if(player_count <= currentbots)
1256                 {
1257                         localcmd("quit\n");
1258                         alreadychangedlevel = TRUE;
1259                         return TRUE;
1260                 }
1261         }
1262         if(autocvar_quit_and_redirect != "")
1263         {
1264                 redirection_target = strzone(autocvar_quit_and_redirect);
1265                 alreadychangedlevel = TRUE;
1266                 return TRUE;
1267         }
1268         if (autocvar_samelevel) // if samelevel is set, stay on same level
1269         {
1270                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1271                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1272                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1273                 localcmd("restart\n");
1274                 //changelevel (mapname);
1275                 alreadychangedlevel = TRUE;
1276                 return TRUE;
1277         }
1278         if(autocvar_nextmap != "")
1279                 if(MapInfo_CheckMap(autocvar_nextmap))
1280                 {
1281                         Map_Goto_SetStr(autocvar_nextmap);
1282                         Map_Goto();
1283                         alreadychangedlevel = TRUE;
1284                         return TRUE;
1285                 }
1286         if(autocvar_lastlevel)
1287         {
1288                 GameResetCfg();
1289                 localcmd("set lastlevel 0\ntogglemenu\n");
1290                 alreadychangedlevel = TRUE;
1291                 return TRUE;
1292         }
1293         return FALSE;
1294 }
1295
1296 void GotoNextMap()
1297 {
1298         //string nextmap;
1299         //float n, nummaps;
1300         //string s;
1301         if (alreadychangedlevel)
1302                 return;
1303         alreadychangedlevel = TRUE;
1304
1305         {
1306                 string nextMap;
1307                 float allowReset;
1308
1309                 for(allowReset = 1; allowReset >= 0; --allowReset)
1310                 {
1311                         nextMap = GetNextMap();
1312                         if(nextMap != "")
1313                                 break;
1314
1315                         if(allowReset)
1316                         {
1317                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1318                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1319                                 if(autocvar_g_maplist_shuffle)
1320                                         ShuffleMaplist();
1321                                 localcmd("\nmenu_cmd sync\n");
1322                         }
1323                         else
1324                         {
1325                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1326                         }
1327                 }
1328                 Map_Goto();
1329         }
1330 }
1331
1332
1333 /*
1334 ============
1335 IntermissionThink
1336
1337 When the player presses attack or jump, change to the next level
1338 ============
1339 */
1340 .float autoscreenshot;
1341 void() MapVote_Start;
1342 void() MapVote_Think;
1343 float mapvote_initialized;
1344 void IntermissionThink()
1345 {
1346         FixIntermissionClient(self);
1347
1348         if(autocvar_sv_autoscreenshot)
1349         if(self.autoscreenshot > 0)
1350         if(time > self.autoscreenshot)
1351         {
1352                 self.autoscreenshot = -1;
1353                 if(clienttype(self) == CLIENTTYPE_REAL)
1354                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1355                 return;
1356         }
1357
1358         if (time < intermission_exittime)
1359                 return;
1360
1361         if(!mapvote_initialized)
1362                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1363                         return;
1364
1365         MapVote_Start();
1366 }
1367
1368 /*
1369 ============
1370 FindIntermission
1371
1372 Returns the entity to view from
1373 ============
1374 */
1375 /*
1376 entity FindIntermission()
1377 {
1378         local   entity spot;
1379         local   float cyc;
1380
1381 // look for info_intermission first
1382         spot = find (world, classname, "info_intermission");
1383         if (spot)
1384         {       // pick a random one
1385                 cyc = random() * 4;
1386                 while (cyc > 1)
1387                 {
1388                         spot = find (spot, classname, "info_intermission");
1389                         if (!spot)
1390                                 spot = find (spot, classname, "info_intermission");
1391                         cyc = cyc - 1;
1392                 }
1393                 return spot;
1394         }
1395
1396 // then look for the start position
1397         spot = find (world, classname, "info_player_start");
1398         if (spot)
1399                 return spot;
1400
1401 // testinfo_player_start is only found in regioned levels
1402         spot = find (world, classname, "testplayerstart");
1403         if (spot)
1404                 return spot;
1405
1406 // then look for the start position
1407         spot = find (world, classname, "info_player_deathmatch");
1408         if (spot)
1409                 return spot;
1410
1411         //objerror ("FindIntermission: no spot");
1412         return world;
1413 }
1414 */
1415
1416 /*
1417 ===============================================================================
1418
1419 RULES
1420
1421 ===============================================================================
1422 */
1423
1424 void DumpStats(float final)
1425 {
1426         float file;
1427         string s;
1428         float to_console;
1429         float to_eventlog;
1430         float to_file;
1431         float i;
1432
1433         to_console = autocvar_sv_logscores_console;
1434         to_eventlog = autocvar_sv_eventlog;
1435         to_file = autocvar_sv_logscores_file;
1436
1437         if(!final)
1438         {
1439                 to_console = TRUE; // always print printstats replies
1440                 to_eventlog = FALSE; // but never print them to the event log
1441         }
1442
1443         if(to_eventlog)
1444                 if(autocvar_sv_eventlog_console)
1445                         to_console = FALSE; // otherwise we get the output twice
1446
1447         if(final)
1448                 s = ":scores:";
1449         else
1450                 s = ":status:";
1451         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1452
1453         if(to_console)
1454                 print(s, "\n");
1455         if(to_eventlog)
1456                 GameLogEcho(s);
1457         if(to_file)
1458         {
1459                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1460                 if(file == -1)
1461                         to_file = FALSE;
1462                 else
1463                         fputs(file, strcat(s, "\n"));
1464         }
1465
1466         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1467         if(to_console)
1468                 print(s, "\n");
1469         if(to_eventlog)
1470                 GameLogEcho(s);
1471         if(to_file)
1472                 fputs(file, strcat(s, "\n"));
1473
1474         FOR_EACH_CLIENT(other)
1475         {
1476                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1477                 {
1478                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1479                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1480                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1481                                 s = strcat(s, ftos(other.team), ":");
1482                         else
1483                                 s = strcat(s, "spectator:");
1484
1485                         if(to_console)
1486                                 print(s, other.netname, "\n");
1487                         if(to_eventlog)
1488                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1489                         if(to_file)
1490                                 fputs(file, strcat(s, other.netname, "\n"));
1491                 }
1492         }
1493
1494         if(teamplay)
1495         {
1496                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1497                 if(to_console)
1498                         print(s, "\n");
1499                 if(to_eventlog)
1500                         GameLogEcho(s);
1501                 if(to_file)
1502                         fputs(file, strcat(s, "\n"));
1503
1504                 for(i = 1; i < 16; ++i)
1505                 {
1506                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1507                         s = strcat(s, ":", ftos(i));
1508                         if(to_console)
1509                                 print(s, "\n");
1510                         if(to_eventlog)
1511                                 GameLogEcho(s);
1512                         if(to_file)
1513                                 fputs(file, strcat(s, "\n"));
1514                 }
1515         }
1516
1517         if(to_console)
1518                 print(":end\n");
1519         if(to_eventlog)
1520                 GameLogEcho(":end");
1521         if(to_file)
1522         {
1523                 fputs(file, ":end\n");
1524                 fclose(file);
1525         }
1526 }
1527
1528 void FixIntermissionClient(entity e)
1529 {
1530         string s;
1531         if(!e.autoscreenshot) // initial call
1532         {
1533                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1534                 e.health = -2342;
1535                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1536                 e.solid = SOLID_NOT;
1537                 e.movetype = MOVETYPE_NONE;
1538                 e.takedamage = DAMAGE_NO;
1539                 if(e.weaponentity)
1540                 {
1541                         e.weaponentity.effects = EF_NODRAW;
1542                         if (e.weaponentity.weaponentity)
1543                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1544                 }
1545                 if(clienttype(e) == CLIENTTYPE_REAL)
1546                 {
1547                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1548                         s = autocvar_sv_intermission_cdtrack;
1549                         if(s != "")
1550                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1551                         msg_entity = e;
1552                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1553                 }
1554         }
1555 }
1556
1557
1558 /*
1559 go to the next level for deathmatch
1560 only called if a time or frag limit has expired
1561 */
1562 void NextLevel()
1563 {
1564         gameover = TRUE;
1565
1566         intermission_running = 1;
1567
1568 // enforce a wait time before allowing changelevel
1569         if(player_count > 0)
1570                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1571         else
1572                 intermission_exittime = -1;
1573
1574         /*
1575         WriteByte (MSG_ALL, SVC_CDTRACK);
1576         WriteByte (MSG_ALL, 3);
1577         WriteByte (MSG_ALL, 3);
1578         // done in FixIntermission
1579         */
1580
1581         //pos = FindIntermission ();
1582
1583         VoteReset();
1584
1585         DumpStats(TRUE);
1586
1587         // send statistics
1588         entity e;
1589         PlayerStats_EndMatch(1);
1590         FOR_EACH_CLIENT(e)
1591                 PlayerStats_AddGlobalInfo(e);
1592         PlayerStats_Shutdown();
1593         WeaponStats_Shutdown();
1594
1595         if(autocvar_sv_eventlog)
1596                 GameLogEcho(":gameover");
1597
1598         GameLogClose();
1599
1600         FOR_EACH_PLAYER(other) {
1601                 FixIntermissionClient(other);
1602                 if(other.winning)
1603                         bprint(other.netname, " ^7wins.\n");
1604         }
1605
1606         if(autocvar_g_campaign)
1607                 CampaignPreIntermission();
1608
1609         localcmd("\nsv_hook_gameend\n");
1610 }
1611
1612 /*
1613 ============
1614 CheckRules_Player
1615
1616 Exit deathmatch games upon conditions
1617 ============
1618 */
1619 void CheckRules_Player()
1620 {
1621         if (gameover)   // someone else quit the game already
1622                 return;
1623
1624         if(self.deadflag == DEAD_NO)
1625                 self.play_time += frametime;
1626
1627         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1628         //   (div0: and that in CheckRules_World please)
1629 }
1630
1631 float checkrules_equality;
1632 float checkrules_suddendeathwarning;
1633 float checkrules_suddendeathend;
1634 float checkrules_overtimesadded; //how many overtimes have been already added
1635
1636 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1637 float WINNING_YES = 1; // winner found
1638 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1639 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1640
1641 float InitiateSuddenDeath()
1642 {
1643         // Check first whether normal overtimes could be added before initiating suddendeath mode
1644         // - for this timelimit_overtime needs to be >0 of course
1645         // - also check the winning condition calculated in the previous frame and only add normal overtime
1646         //   again, if at the point at which timelimit would be extended again, still no winner was found
1647         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1648         {
1649                 return 1; // need to call InitiateOvertime later
1650         }
1651         else
1652         {
1653                 if(!checkrules_suddendeathend)
1654                 {
1655                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1656                         if(g_race && !g_race_qualifying)
1657                                 race_StartCompleting();
1658                 }
1659                 return 0;
1660         }
1661 }
1662
1663 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1664 {
1665         ++checkrules_overtimesadded;
1666         //add one more overtime by simply extending the timelimit
1667         float tl;
1668         tl = autocvar_timelimit;
1669         tl += autocvar_timelimit_overtime;
1670         cvar_set("timelimit", ftos(tl));
1671         string minutesPlural;
1672         if (autocvar_timelimit_overtime == 1)
1673                 minutesPlural = " ^3minute";
1674         else
1675                 minutesPlural = " ^3minutes";
1676
1677         bcenterprint(
1678                 strcat(
1679                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1680                         ftos(autocvar_timelimit_overtime),
1681                         minutesPlural,
1682                         " to the game!"
1683                 )
1684         );
1685 }
1686
1687 float GetWinningCode(float fraglimitreached, float equality)
1688 {
1689         if(autocvar_g_campaign == 1)
1690                 if(fraglimitreached)
1691                         return WINNING_YES;
1692                 else
1693                         return WINNING_NO;
1694
1695         else
1696                 if(equality)
1697                         if(fraglimitreached)
1698                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1699                         else
1700                                 return WINNING_NEVER;
1701                 else
1702                         if(fraglimitreached)
1703                                 return WINNING_YES;
1704                         else
1705                                 return WINNING_NO;
1706 }
1707
1708 // set the .winning flag for exactly those players with a given field value
1709 void SetWinners(.float field, float value)
1710 {
1711         entity head;
1712         FOR_EACH_PLAYER(head)
1713                 head.winning = (head.field == value);
1714 }
1715
1716 // set the .winning flag for those players with a given field value
1717 void AddWinners(.float field, float value)
1718 {
1719         entity head;
1720         FOR_EACH_PLAYER(head)
1721                 if(head.field == value)
1722                         head.winning = 1;
1723 }
1724
1725 // clear the .winning flags
1726 void ClearWinners(void)
1727 {
1728         entity head;
1729         FOR_EACH_PLAYER(head)
1730                 head.winning = 0;
1731 }
1732
1733 // Onslaught winning condition:
1734 // game terminates if only one team has a working generator (or none)
1735 float WinningCondition_Onslaught()
1736 {
1737         entity head;
1738         float t1, t2, t3, t4;
1739
1740         WinningConditionHelper(); // set worldstatus
1741
1742         if(inWarmupStage)
1743                 return WINNING_NO;
1744
1745         // first check if the game has ended
1746         t1 = t2 = t3 = t4 = 0;
1747         head = find(world, classname, "onslaught_generator");
1748         while (head)
1749         {
1750                 if (head.health > 0)
1751                 {
1752                         if (head.team == COLOR_TEAM1) t1 = 1;
1753                         if (head.team == COLOR_TEAM2) t2 = 1;
1754                         if (head.team == COLOR_TEAM3) t3 = 1;
1755                         if (head.team == COLOR_TEAM4) t4 = 1;
1756                 }
1757                 head = find(head, classname, "onslaught_generator");
1758         }
1759         if (t1 + t2 + t3 + t4 < 2)
1760         {
1761                 // game over, only one team remains (or none)
1762                 ClearWinners();
1763                 if (t1) SetWinners(team, COLOR_TEAM1);
1764                 if (t2) SetWinners(team, COLOR_TEAM2);
1765                 if (t3) SetWinners(team, COLOR_TEAM3);
1766                 if (t4) SetWinners(team, COLOR_TEAM4);
1767                 dprint("Have a winner, ending game.\n");
1768                 return WINNING_YES;
1769         }
1770
1771         // Two or more teams remain
1772         return WINNING_NO;
1773 }
1774
1775 float LMS_NewPlayerLives()
1776 {
1777         float fl;
1778         fl = autocvar_fraglimit;
1779         if(fl == 0)
1780                 fl = 999;
1781
1782         // first player has left the game for dying too much? Nobody else can get in.
1783         if(lms_lowest_lives < 1)
1784                 return 0;
1785
1786         if(!autocvar_g_lms_join_anytime)
1787                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1788                         return 0;
1789
1790         return bound(1, lms_lowest_lives, fl);
1791 }
1792
1793 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1794 // they win. Otherwise the defending team wins once the timelimit passes.
1795 void assault_new_round();
1796 float WinningCondition_Assault()
1797 {
1798         float status;
1799
1800         WinningConditionHelper(); // set worldstatus
1801
1802         status = WINNING_NO;
1803         // as the timelimit has not yet passed just assume the defending team will win
1804         if(assault_attacker_team == COLOR_TEAM1)
1805         {
1806                 SetWinners(team, COLOR_TEAM2);
1807         }
1808         else
1809         {
1810                 SetWinners(team, COLOR_TEAM1);
1811         }
1812
1813         entity ent;
1814         ent = find(world, classname, "target_assault_roundend");
1815         if(ent)
1816         {
1817                 if(ent.winning) // round end has been triggered by attacking team
1818                 {
1819                         bprint("ASSAULT: round completed...\n");
1820                         SetWinners(team, assault_attacker_team);
1821
1822                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1823
1824                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1825                         {
1826                                 status = WINNING_YES;
1827                         }
1828                         else
1829                         {
1830                                 entity oldself;
1831                                 oldself = self;
1832                                 self = ent;
1833                                 assault_new_round();
1834                                 self = oldself;
1835                         }
1836                 }
1837         }
1838
1839         return status;
1840 }
1841
1842 // LMS winning condition: game terminates if and only if there's at most one
1843 // one player who's living lives. Top two scores being equal cancels the time
1844 // limit.
1845 float WinningCondition_LMS()
1846 {
1847         entity head, head2;
1848         float have_player;
1849         float have_players;
1850         float l;
1851
1852         have_player = FALSE;
1853         have_players = FALSE;
1854         l = LMS_NewPlayerLives();
1855
1856         head = find(world, classname, "player");
1857         if(head)
1858                 have_player = TRUE;
1859         head2 = find(head, classname, "player");
1860         if(head2)
1861                 have_players = TRUE;
1862
1863         if(have_player)
1864         {
1865                 // we have at least one player
1866                 if(have_players)
1867                 {
1868                         // two or more active players - continue with the game
1869                 }
1870                 else
1871                 {
1872                         // exactly one player?
1873
1874                         ClearWinners();
1875                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1876
1877                         if(l)
1878                         {
1879                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1880                                 return WINNING_NO;
1881                         }
1882                         else
1883                         {
1884                                 // a winner!
1885                                 // and assign him his first place
1886                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1887                                 return WINNING_YES;
1888                         }
1889                 }
1890         }
1891         else
1892         {
1893                 // nobody is playing at all...
1894                 if(l)
1895                 {
1896                         // wait for players...
1897                 }
1898                 else
1899                 {
1900                         // SNAFU (maybe a draw game?)
1901                         ClearWinners();
1902                         dprint("No players, ending game.\n");
1903                         return WINNING_YES;
1904                 }
1905         }
1906
1907         // When we get here, we have at least two players who are actually LIVING,
1908         // now check if the top two players have equal score.
1909         WinningConditionHelper();
1910
1911         ClearWinners();
1912         if(WinningConditionHelper_winner)
1913                 WinningConditionHelper_winner.winning = TRUE;
1914         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1915                 return WINNING_NEVER;
1916
1917         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1918         return WINNING_NO;
1919 }
1920
1921 void ShuffleMaplist()
1922 {
1923         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1924 }
1925
1926 float leaderfrags;
1927 float WinningCondition_Scores(float limit, float leadlimit)
1928 {
1929         float limitreached;
1930
1931         // TODO make everything use THIS winning condition (except LMS)
1932         WinningConditionHelper();
1933
1934         if(teamplay)
1935         {
1936                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1937                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1938                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1939                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1940         }
1941
1942         ClearWinners();
1943         if(WinningConditionHelper_winner)
1944                 WinningConditionHelper_winner.winning = 1;
1945         if(WinningConditionHelper_winnerteam >= 0)
1946                 SetWinners(team, WinningConditionHelper_winnerteam);
1947
1948         if(WinningConditionHelper_lowerisbetter)
1949         {
1950                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1951                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1952                 limit = -limit;
1953         }
1954
1955         if(WinningConditionHelper_zeroisworst)
1956                 leadlimit = 0; // not supported in this mode
1957
1958         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1959         // these modes always score in increments of 1, thus this makes sense
1960         {
1961                 if(leaderfrags != WinningConditionHelper_topscore)
1962                 {
1963                         leaderfrags = WinningConditionHelper_topscore;
1964
1965                         if (limit)
1966                         if (leaderfrags == limit - 1)
1967                                 Announce("1fragleft");
1968                         else if (leaderfrags == limit - 2)
1969                                 Announce("2fragsleft");
1970                         else if (leaderfrags == limit - 3)
1971                                 Announce("3fragsleft");
1972                 }
1973         }
1974
1975         limitreached = FALSE;
1976         if(limit)
1977                 if(WinningConditionHelper_topscore >= limit)
1978                         limitreached = TRUE;
1979         if(leadlimit)
1980         {
1981                 float leadlimitreached;
1982                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1983                 if(autocvar_leadlimit_and_fraglimit)
1984                         limitreached = (limitreached && leadlimitreached);
1985                 else
1986                         limitreached = (limitreached || leadlimitreached);
1987         }
1988
1989         return GetWinningCode(
1990                 WinningConditionHelper_topscore && limitreached,
1991                 WinningConditionHelper_equality
1992         );
1993 }
1994
1995 float WinningCondition_Race(float fraglimit)
1996 {
1997         float wc;
1998         entity p;
1999         float n, c;
2000
2001         n = 0;
2002         c = 0;
2003         FOR_EACH_PLAYER(p)
2004         {
2005                 ++n;
2006                 if(p.race_completed)
2007                         ++c;
2008         }
2009         if(n && (n == c))
2010                 return WINNING_YES;
2011         wc = WinningCondition_Scores(fraglimit, 0);
2012
2013         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2014         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2015         // do NOT support equality when the laps are all raced!
2016                 return WINNING_STARTSUDDENDEATHOVERTIME;
2017         else
2018                 return WINNING_NEVER;
2019         return wc;
2020 }
2021
2022 void ReadyRestart();
2023 float WinningCondition_QualifyingThenRace(float limit)
2024 {
2025         float wc;
2026         wc = WinningCondition_Scores(limit, 0);
2027
2028         // NEVER initiate overtime
2029         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2030         {
2031                 return WINNING_YES;
2032         }
2033
2034         return wc;
2035 }
2036
2037 float WinningCondition_RanOutOfSpawns()
2038 {
2039         entity head;
2040
2041         if(have_team_spawns <= 0)
2042                 return WINNING_NO;
2043
2044         if(!some_spawn_has_been_used)
2045                 return WINNING_NO;
2046
2047         team1_score = team2_score = team3_score = team4_score = 0;
2048
2049         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2050         {
2051                 if(head.team == COLOR_TEAM1)
2052                         team1_score = 1;
2053                 else if(head.team == COLOR_TEAM2)
2054                         team2_score = 1;
2055                 else if(head.team == COLOR_TEAM3)
2056                         team3_score = 1;
2057                 else if(head.team == COLOR_TEAM4)
2058                         team4_score = 1;
2059         }
2060
2061         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2062         {
2063                 if(head.team == COLOR_TEAM1)
2064                         team1_score = 1;
2065                 else if(head.team == COLOR_TEAM2)
2066                         team2_score = 1;
2067                 else if(head.team == COLOR_TEAM3)
2068                         team3_score = 1;
2069                 else if(head.team == COLOR_TEAM4)
2070                         team4_score = 1;
2071         }
2072
2073         ClearWinners();
2074         if(team1_score + team2_score + team3_score + team4_score == 0)
2075         {
2076                 checkrules_equality = TRUE;
2077                 return WINNING_YES;
2078         }
2079         else if(team1_score + team2_score + team3_score + team4_score == 1)
2080         {
2081                 float t, i;
2082                 if(team1_score) t = COLOR_TEAM1;
2083                 if(team2_score) t = COLOR_TEAM2;
2084                 if(team3_score) t = COLOR_TEAM3;
2085                 if(team4_score) t = COLOR_TEAM4;
2086                 CheckAllowedTeams(world);
2087                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2088                 {
2089                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2090                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2091                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2092                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2093                 }
2094
2095                 AddWinners(team, t);
2096                 return WINNING_YES;
2097         }
2098         else
2099                 return WINNING_NO;
2100 }
2101
2102 /*
2103 ============
2104 CheckRules_World
2105
2106 Exit deathmatch games upon conditions
2107 ============
2108 */
2109 void CheckRules_World()
2110 {
2111         float timelimit;
2112         float fraglimit;
2113         float leadlimit;
2114
2115         VoteThink();
2116         MapVote_Think();
2117
2118         SetDefaultAlpha();
2119
2120         /*
2121         MapVote_Think should now do that part
2122         if (intermission_running)
2123                 if (time >= intermission_exittime + 60)
2124                 {
2125                         if(!DoNextMapOverride())
2126                                 GotoNextMap();
2127                         return;
2128                 }
2129         */
2130
2131         if (gameover)   // someone else quit the game already
2132         {
2133                 if(player_count == 0) // Nobody there? Then let's go to the next map
2134                         MapVote_Start();
2135                         // this will actually check the player count in the next frame
2136                         // again, but this shouldn't hurt
2137                 return;
2138         }
2139
2140         timelimit = autocvar_timelimit * 60;
2141         fraglimit = autocvar_fraglimit;
2142         leadlimit = autocvar_leadlimit;
2143
2144         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2145         {
2146                 if(timelimit > 0)
2147                         timelimit = 0; // timelimit is not made for warmup
2148                 if(fraglimit > 0)
2149                         fraglimit = 0; // no fraglimit for now
2150                 leadlimit = 0; // no leadlimit for now
2151         }
2152
2153         if(g_onslaught)
2154                 timelimit = 0; // ONS has its own overtime rule
2155
2156         if(timelimit > 0)
2157         {
2158                 timelimit += game_starttime;
2159         }
2160         else if (timelimit < 0)
2161         {
2162                 // endmatch
2163                 NextLevel();
2164                 return;
2165         }
2166
2167         float wantovertime;
2168         wantovertime = 0;
2169
2170         if(checkrules_suddendeathend)
2171         {
2172                 if(!checkrules_suddendeathwarning)
2173                 {
2174                         checkrules_suddendeathwarning = TRUE;
2175                         if(g_race && !g_race_qualifying)
2176                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2177                         else
2178                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2179                 }
2180         }
2181         else
2182         {
2183                 if (timelimit && time >= timelimit)
2184                 {
2185                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2186                         {
2187                                 float totalplayers;
2188                                 float playerswithlaps;
2189                                 float readyplayers;
2190                                 entity head;
2191                                 totalplayers = playerswithlaps = readyplayers = 0;
2192                                 FOR_EACH_PLAYER(head)
2193                                 {
2194                                         ++totalplayers;
2195                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2196                                                 ++playerswithlaps;
2197                                         if(head.ready)
2198                                                 ++readyplayers;
2199                                 }
2200
2201                                 // at least 2 of the players have completed a lap: start the RACE
2202                                 // otherwise, the players should end the qualifying on their own
2203                                 if(readyplayers || playerswithlaps >= 2)
2204                                 {
2205                                         checkrules_suddendeathend = 0;
2206                                         ReadyRestart(); // go to race
2207                                         return;
2208                                 }
2209                                 else
2210                                         wantovertime |= InitiateSuddenDeath();
2211                         }
2212                         else
2213                                 wantovertime |= InitiateSuddenDeath();
2214                 }
2215         }
2216
2217         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2218         {
2219                 NextLevel();
2220                 return;
2221         }
2222
2223         float checkrules_status;
2224         checkrules_status = WinningCondition_RanOutOfSpawns();
2225         if(checkrules_status == WINNING_YES)
2226         {
2227                 bprint("Hey! Someone ran out of spawns!\n");
2228         }
2229         else if(g_race && !g_race_qualifying && timelimit >= 0)
2230         {
2231                 checkrules_status = WinningCondition_Race(fraglimit);
2232                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2233         }
2234         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2235         {
2236                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2237                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2238         }
2239         else if(g_assault)
2240         {
2241                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2242         }
2243         else if(g_lms)
2244         {
2245                 checkrules_status = WinningCondition_LMS();
2246         }
2247         else if (g_onslaught)
2248         {
2249                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2250         }
2251         else
2252         {
2253                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2254                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2255         }
2256
2257         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2258         {
2259                 checkrules_status = WINNING_NEVER;
2260                 checkrules_overtimesadded = -1;
2261                 wantovertime |= InitiateSuddenDeath();
2262         }
2263
2264         if(checkrules_status == WINNING_NEVER)
2265                 // equality cases! Nobody wins if the overtime ends in a draw.
2266                 ClearWinners();
2267
2268         if(wantovertime)
2269         {
2270                 if(checkrules_status == WINNING_NEVER)
2271                         InitiateOvertime();
2272                 else
2273                         checkrules_status = WINNING_YES;
2274         }
2275
2276         if(checkrules_suddendeathend)
2277                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2278                         checkrules_status = WINNING_YES;
2279
2280         if(checkrules_status == WINNING_YES)
2281         {
2282                 //print("WINNING\n");
2283                 NextLevel();
2284         }
2285 }
2286
2287 float mapvote_nextthink;
2288 float mapvote_initialized;
2289 float mapvote_keeptwotime;
2290 float mapvote_timeout;
2291 string mapvote_message;
2292 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2293 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2294 float mapvote_screenshot_dirs_count;
2295
2296 float mapvote_count;
2297 float mapvote_count_real;
2298 string mapvote_maps[MAPVOTE_COUNT];
2299 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2300 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2301 float mapvote_maps_suggested[MAPVOTE_COUNT];
2302 string mapvote_suggestions[MAPVOTE_COUNT];
2303 float mapvote_suggestion_ptr;
2304 float mapvote_voters;
2305 float mapvote_votes[MAPVOTE_COUNT];
2306 float mapvote_run;
2307 float mapvote_detail;
2308 float mapvote_abstain;
2309 .float mapvote;
2310
2311 void MapVote_ClearAllVotes()
2312 {
2313         FOR_EACH_CLIENT(other)
2314                 other.mapvote = 0;
2315 }
2316
2317 string MapVote_Suggest(string m)
2318 {
2319         float i;
2320         if(m == "")
2321                 return "That's not how to use this command.";
2322         if(!autocvar_g_maplist_votable_suggestions)
2323                 return "Suggestions are not accepted on this server.";
2324         if(mapvote_initialized)
2325                 return "Can't suggest - voting is already in progress!";
2326         m = MapInfo_FixName(m);
2327         if(!m)
2328                 return "The map you suggested is not available on this server.";
2329         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2330                 if(Map_IsRecent(m))
2331                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2332
2333         if(!MapInfo_CheckMap(m))
2334                 return "The map you suggested does not support the current game mode.";
2335         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2336                 if(mapvote_suggestions[i] == m)
2337                         return "This map was already suggested.";
2338         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2339         {
2340                 i = floor(random() * mapvote_suggestion_ptr);
2341         }
2342         else
2343         {
2344                 i = mapvote_suggestion_ptr;
2345                 mapvote_suggestion_ptr += 1;
2346         }
2347         if(mapvote_suggestions[i] != "")
2348                 strunzone(mapvote_suggestions[i]);
2349         mapvote_suggestions[i] = strzone(m);
2350         if(autocvar_sv_eventlog)
2351                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2352         return strcat("Suggestion of ", m, " accepted.");
2353 }
2354
2355 void MapVote_AddVotable(string nextMap, float isSuggestion)
2356 {
2357         float j, i, o;
2358         string pakfile, mapfile;
2359
2360         if(nextMap == "")
2361                 return;
2362         for(j = 0; j < mapvote_count; ++j)
2363                 if(mapvote_maps[j] == nextMap)
2364                         return;
2365         // suggestions might be no longer valid/allowed after gametype switch!
2366         if(isSuggestion)
2367                 if(!MapInfo_CheckMap(nextMap))
2368                         return;
2369         mapvote_maps[mapvote_count] = strzone(nextMap);
2370         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2371
2372         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2373         {
2374                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2375                 pakfile = whichpack(strcat(mapfile, ".tga"));
2376                 if(pakfile == "")
2377                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2378                 if(pakfile == "")
2379                         pakfile = whichpack(strcat(mapfile, ".png"));
2380                 if(pakfile != "")
2381                         break;
2382         }
2383         if(i >= mapvote_screenshot_dirs_count)
2384                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2385         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2386                 pakfile = substring(pakfile, o, -1);
2387
2388         mapvote_maps_screenshot_dir[mapvote_count] = i;
2389         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2390
2391         mapvote_count += 1;
2392 }
2393
2394 void MapVote_Spawn();
2395 void MapVote_Init()
2396 {
2397         float i;
2398         float nmax, smax;
2399
2400         MapVote_ClearAllVotes();
2401
2402         mapvote_count = 0;
2403         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2404         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2405
2406         if(mapvote_abstain)
2407                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2408         else
2409                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2410         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2411
2412         // we need this for AddVotable, as that cycles through the screenshot dirs
2413         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2414         if(mapvote_screenshot_dirs_count == 0)
2415                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2416         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2417         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2418                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2419
2420         if(mapvote_suggestion_ptr)
2421                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2422                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2423
2424         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2425                 MapVote_AddVotable(GetNextMap(), FALSE);
2426
2427         if(mapvote_count == 0)
2428         {
2429                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2430                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2431                 if(autocvar_g_maplist_shuffle)
2432                         ShuffleMaplist();
2433                 localcmd("\nmenu_cmd sync\n");
2434                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2435                         MapVote_AddVotable(GetNextMap(), FALSE);
2436         }
2437
2438         mapvote_count_real = mapvote_count;
2439         if(mapvote_abstain)
2440                 MapVote_AddVotable("don't care", 0);
2441
2442         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2443
2444         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2445         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2446         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2447                 mapvote_keeptwotime = 0;
2448         mapvote_message = "Choose a map and press its key!";
2449
2450         MapVote_Spawn();
2451 }
2452
2453 void MapVote_SendPicture(float id)
2454 {
2455         msg_entity = self;
2456         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2457         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2458         WriteByte(MSG_ONE, id);
2459         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2460 }
2461
2462 float GameCommand_MapVote(string cmd)
2463 {
2464         if(!intermission_running)
2465                 return FALSE;
2466
2467         if(cmd == "mv_getpic")
2468         {
2469                 MapVote_SendPicture(stof(argv(1)));
2470                 return TRUE;
2471         }
2472
2473         return FALSE;
2474 }
2475
2476 float MapVote_GetMapMask()
2477 {
2478         float mask, i, power;
2479         mask = 0;
2480         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2481                 if(mapvote_maps[i] != "")
2482                         mask |= power;
2483         return mask;
2484 }
2485
2486 entity mapvote_ent;
2487 float MapVote_SendEntity(entity to, float sf)
2488 {
2489         float i;
2490
2491         if(sf & 1)
2492                 sf &~= 2; // if we send 1, we don't need to also send 2
2493
2494         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2495         WriteByte(MSG_ENTITY, sf);
2496
2497         if(sf & 1)
2498         {
2499                 // flag 1 == initialization
2500                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2501                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2502                 WriteString(MSG_ENTITY, "");
2503                 WriteByte(MSG_ENTITY, mapvote_count);
2504                 WriteByte(MSG_ENTITY, mapvote_abstain);
2505                 WriteByte(MSG_ENTITY, mapvote_detail);
2506                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2507                 if(mapvote_count <= 8)
2508                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2509                 else
2510                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2511                 for(i = 0; i < mapvote_count; ++i)
2512                         if(mapvote_maps[i] != "")
2513                         {
2514                                 if(mapvote_abstain && i == mapvote_count - 1)
2515                                 {
2516                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2517                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2518                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2519                                 }
2520                                 else
2521                                 {
2522                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2523                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2524                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2525                                 }
2526                         }
2527         }
2528
2529         if(sf & 2)
2530         {
2531                 // flag 2 == update of mask
2532                 if(mapvote_count <= 8)
2533                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2534                 else
2535                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2536         }
2537
2538         if(sf & 4)
2539         {
2540                 if(mapvote_detail)
2541                         for(i = 0; i < mapvote_count; ++i)
2542                                 if(mapvote_maps[i] != "")
2543                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2544
2545                 WriteByte(MSG_ENTITY, to.mapvote);
2546         }
2547
2548         return TRUE;
2549 }
2550
2551 void MapVote_Spawn()
2552 {
2553         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2554 }
2555
2556 void MapVote_TouchMask()
2557 {
2558         mapvote_ent.SendFlags |= 2;
2559 }
2560
2561 void MapVote_TouchVotes(entity voter)
2562 {
2563         mapvote_ent.SendFlags |= 4;
2564 }
2565
2566 float MapVote_Finished(float mappos)
2567 {
2568         string result;
2569         float i;
2570         float didntvote;
2571
2572         if(autocvar_sv_eventlog)
2573         {
2574                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2575                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2576                 didntvote = mapvote_voters;
2577                 for(i = 0; i < mapvote_count; ++i)
2578                         if(mapvote_maps[i] != "")
2579                         {
2580                                 didntvote -= mapvote_votes[i];
2581                                 if(i != mappos)
2582                                 {
2583                                         result = strcat(result, ":", mapvote_maps[i]);
2584                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2585                                 }
2586                         }
2587                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2588
2589                 GameLogEcho(result);
2590                 if(mapvote_maps_suggested[mappos])
2591                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2592         }
2593
2594         FOR_EACH_REALCLIENT(other)
2595                 FixClientCvars(other);
2596
2597         Map_Goto_SetStr(mapvote_maps[mappos]);
2598         Map_Goto();
2599         alreadychangedlevel = TRUE;
2600         return TRUE;
2601 }
2602 void MapVote_CheckRules_1()
2603 {
2604         float i;
2605
2606         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2607         {
2608                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2609                 mapvote_votes[i] = 0;
2610         }
2611
2612         mapvote_voters = 0;
2613         FOR_EACH_REALCLIENT(other)
2614         {
2615                 ++mapvote_voters;
2616                 if(other.mapvote)
2617                 {
2618                         i = other.mapvote - 1;
2619                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2620                         mapvote_votes[i] = mapvote_votes[i] + 1;
2621                 }
2622         }
2623 }
2624
2625 float MapVote_CheckRules_2()
2626 {
2627         float i;
2628         float firstPlace, secondPlace;
2629         float firstPlaceVotes, secondPlaceVotes;
2630         float mapvote_voters_real;
2631         string result;
2632
2633         if(mapvote_count_real == 1)
2634                 return MapVote_Finished(0);
2635
2636         mapvote_voters_real = mapvote_voters;
2637         if(mapvote_abstain)
2638                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2639
2640         RandomSelection_Init();
2641         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2642                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2643         firstPlace = RandomSelection_chosen_float;
2644         firstPlaceVotes = RandomSelection_best_priority;
2645         //dprint("First place: ", ftos(firstPlace), "\n");
2646         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2647
2648         RandomSelection_Init();
2649         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2650                 if(i != firstPlace)
2651                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2652         secondPlace = RandomSelection_chosen_float;
2653         secondPlaceVotes = RandomSelection_best_priority;
2654         //dprint("Second place: ", ftos(secondPlace), "\n");
2655         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2656
2657         if(firstPlace == -1)
2658                 error("No first place in map vote... WTF?");
2659
2660         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2661                 return MapVote_Finished(firstPlace);
2662
2663         if(mapvote_keeptwotime)
2664                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2665                 {
2666                         float didntvote;
2667                         MapVote_TouchMask();
2668                         mapvote_message = "Now decide between the TOP TWO!";
2669                         mapvote_keeptwotime = 0;
2670                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2671                         result = strcat(result, ":", ftos(firstPlaceVotes));
2672                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2673                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2674                         didntvote = mapvote_voters;
2675                         for(i = 0; i < mapvote_count; ++i)
2676                                 if(mapvote_maps[i] != "")
2677                                 {
2678                                         didntvote -= mapvote_votes[i];
2679                                         if(i != firstPlace)
2680                                                 if(i != secondPlace)
2681                                                 {
2682                                                         result = strcat(result, ":", mapvote_maps[i]);
2683                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2684                                                         if(i < mapvote_count_real)
2685                                                         {
2686                                                                 strunzone(mapvote_maps[i]);
2687                                                                 mapvote_maps[i] = "";
2688                                                                 strunzone(mapvote_maps_pakfile[i]);
2689                                                                 mapvote_maps_pakfile[i] = "";
2690                                                         }
2691                                                 }
2692                                 }
2693                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2694                         if(autocvar_sv_eventlog)
2695                                 GameLogEcho(result);
2696                 }
2697
2698         return FALSE;
2699 }
2700 void MapVote_Tick()
2701 {
2702         float keeptwo;
2703         float totalvotes;
2704
2705         keeptwo = mapvote_keeptwotime;
2706         MapVote_CheckRules_1(); // count
2707         if(MapVote_CheckRules_2()) // decide
2708                 return;
2709
2710         totalvotes = 0;
2711         FOR_EACH_REALCLIENT(other)
2712         {
2713                 // hide scoreboard again
2714                 if(other.health != 2342)
2715                 {
2716                         other.health = 2342;
2717                         other.impulse = 0;
2718                         if(clienttype(other) == CLIENTTYPE_REAL)
2719                         {
2720                                 msg_entity = other;
2721                                 WriteByte(MSG_ONE, SVC_FINALE);
2722                                 WriteString(MSG_ONE, "");
2723                         }
2724                 }
2725
2726                 // clear possibly invalid votes
2727                 if(mapvote_maps[other.mapvote - 1] == "")
2728                         other.mapvote = 0;
2729                 // use impulses as new vote
2730                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2731                         if(mapvote_maps[other.impulse - 1] != "")
2732                         {
2733                                 other.mapvote = other.impulse;
2734                                 MapVote_TouchVotes(other);
2735                         }
2736                 other.impulse = 0;
2737
2738                 if(other.mapvote)
2739                         ++totalvotes;
2740         }
2741
2742         MapVote_CheckRules_1(); // just count
2743 }
2744 void MapVote_Start()
2745 {
2746         if(mapvote_run)
2747                 return;
2748
2749         // wait for stats to be sent first
2750         if(!playerstats_waitforme)
2751                 return;
2752
2753         MapInfo_Enumerate();
2754         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2755                 mapvote_run = TRUE;
2756 }
2757 void MapVote_Think()
2758 {
2759         if(!mapvote_run)
2760                 return;
2761
2762         if(alreadychangedlevel)
2763                 return;
2764
2765         if(time < mapvote_nextthink)
2766                 return;
2767         //dprint("tick\n");
2768
2769         mapvote_nextthink = time + 0.5;
2770
2771         if(!mapvote_initialized)
2772         {
2773                 if(autocvar_rescan_pending == 1)
2774                 {
2775                         cvar_set("rescan_pending", "2");
2776                         localcmd("fs_rescan\nrescan_pending 3\n");
2777                         return;
2778                 }
2779                 else if(autocvar_rescan_pending == 2)
2780                 {
2781                         return;
2782                 }
2783                 else if(autocvar_rescan_pending == 3)
2784                 {
2785                         // now build missing mapinfo files
2786                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2787                                 return;
2788
2789                         // we're done, start the timer
2790                         cvar_set("rescan_pending", "0");
2791                 }
2792
2793                 mapvote_initialized = TRUE;
2794                 if(DoNextMapOverride())
2795                         return;
2796                 if(!autocvar_g_maplist_votable || player_count <= 0)
2797                 {
2798                         GotoNextMap();
2799                         return;
2800                 }
2801                 MapVote_Init();
2802         }
2803
2804         MapVote_Tick();
2805 }
2806
2807 string GotoMap(string m)
2808 {
2809         if(!MapInfo_CheckMap(m))
2810                 return "The map you chose is not available on this server.";
2811         cvar_set("nextmap", m);
2812         cvar_set("timelimit", "-1");
2813         if(mapvote_initialized || alreadychangedlevel)
2814         {
2815                 if(DoNextMapOverride())
2816                         return "Map switch initiated.";
2817                 else
2818                         return "Hm... no. For some reason I like THIS map more.";
2819         }
2820         else
2821                 return "Map switch will happen after scoreboard.";
2822 }
2823
2824
2825 void EndFrame()
2826 {
2827         float altime;
2828         FOR_EACH_REALCLIENT(self)
2829         {
2830                 if(self.classname == "spectator")
2831                 {
2832                         if(self.enemy.typehitsound)
2833                                 self.typehit_time = time;
2834                         else if(self.enemy.hitsound)
2835                                 self.hit_time = time;
2836                 }
2837                 else
2838                 {
2839                         if(self.typehitsound)
2840                                 self.typehit_time = time;
2841                         else if(self.hitsound)
2842                                 self.hit_time = time;
2843                 }
2844         }
2845         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2846         // add 1 frametime because after this, engine SV_Physics
2847         // increases time by a frametime and then networks the frame
2848         // add another frametime because client shows everything with
2849         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2850         // needed!
2851         FOR_EACH_CLIENT(self)
2852         {
2853                 self.hitsound = FALSE;
2854                 self.typehitsound = FALSE;
2855                 antilag_record(self, altime);
2856         }
2857 }
2858
2859
2860 /*
2861  * RedirectionThink:
2862  * returns TRUE if redirecting
2863  */
2864 float redirection_timeout;
2865 float redirection_nextthink;
2866 float RedirectionThink()
2867 {
2868         float clients_found;
2869
2870         if(redirection_target == "")
2871                 return FALSE;
2872
2873         if(!redirection_timeout)
2874         {
2875                 cvar_set("sv_public", "-2");
2876                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2877                 if(redirection_target == "self")
2878                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2879                 else
2880                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2881         }
2882
2883         if(time < redirection_nextthink)
2884                 return TRUE;
2885
2886         redirection_nextthink = time + 1;
2887
2888         clients_found = 0;
2889         FOR_EACH_REALCLIENT(self)
2890         {
2891                 print("Redirecting: sending connect command to ", self.netname, "\n");
2892                 if(redirection_target == "self")
2893                         stuffcmd(self, "\ndisconnect; reconnect\n");
2894                 else
2895                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2896                 ++clients_found;
2897         }
2898
2899         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2900
2901         if(time > redirection_timeout || clients_found == 0)
2902                 localcmd("\nwait; wait; wait; quit\n");
2903
2904         return TRUE;
2905 }
2906
2907 void TargetMusic_RestoreGame();
2908 void RestoreGame()
2909 {
2910         // Loaded from a save game
2911         // some things then break, so let's work around them...
2912
2913         // Progs DB (capture records)
2914         ServerProgsDB = db_load("server.db");
2915
2916         // Mapinfo
2917         MapInfo_Shutdown();
2918         MapInfo_Enumerate();
2919         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2920         WeaponStats_Init();
2921
2922         TargetMusic_RestoreGame();
2923 }
2924
2925 void SV_Shutdown()
2926 {
2927         entity e;
2928
2929         if(gameover > 1) // shutting down already?
2930                 return;
2931
2932         gameover = 2; // 2 = server shutting down
2933
2934         if(world_initialized > 0)
2935         {
2936                 world_initialized = 0;
2937                 print("Saving persistent data...\n");
2938                 Ban_SaveBans();
2939
2940                 PlayerStats_EndMatch(0);
2941                 FOR_EACH_CLIENT(e)
2942                         PlayerStats_AddGlobalInfo(e);
2943                 PlayerStats_Shutdown();
2944
2945                 if(!cheatcount_total)
2946                 {
2947                         if(autocvar_sv_db_saveasdump)
2948                                 db_dump(ServerProgsDB, "server.db");
2949                         else
2950                                 db_save(ServerProgsDB, "server.db");
2951                 }
2952                 if(autocvar_developer)
2953                 {
2954                         if(autocvar_sv_db_saveasdump)
2955                                 db_dump(TemporaryDB, "server-temp.db");
2956                         else
2957                                 db_save(TemporaryDB, "server-temp.db");
2958                 }
2959                 CheatShutdown(); // must be after cheatcount check
2960                 db_close(ServerProgsDB);
2961                 db_close(TemporaryDB);
2962                 print("done!\n");
2963                 // tell the bot system the game is ending now
2964                 bot_endgame();
2965
2966                 WeaponStats_Shutdown();
2967                 MapInfo_Shutdown();
2968         }
2969         else if(world_initialized == 0)
2970         {
2971                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2972         }
2973 }