qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include <server/mutators/_mod.qh>
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "scores_rules.qh"
  20 #include "teamplay.qh"
  21 #include "weapons/weaponstats.qh"
  22 #include "../common/constants.qh"
  23 #include <common/net_linked.qh>
  24 #include "../common/deathtypes/all.qh"
  25 #include "../common/gamemodes/sv_rules.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/_mod.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/vehicles/all.qh"
  30 #include "../common/notifications/all.qh"
  31 #include "../common/physics/player.qh"
  32 #include "../common/playerstats.qh"
  33 #include "../common/stats.qh"
  34 #include "../common/teams.qh"
  35 #include "../common/mapobjects/trigger/secret.qh"
  36 #include "../common/mapobjects/target/music.qh"
  37 #include "../common/util.qh"
  38 #include "../common/items/_mod.qh"
  39 #include <common/weapons/_all.qh>
  40 #include "../common/state.qh"
  41
  42 const float LATENCY_THINKRATE = 10;
  43 .float latency_sum;
  44 .float latency_cnt;
  45 .float latency_time;
  46 entity pingplreport;
  47 void PingPLReport_Think(entity this)
  48 {
  49         float delta;
  50         entity e;
  51
  52         delta = 3 / maxclients;
  53         if(delta < sys_frametime)
  54                 delta = 0;
  55         this.nextthink = time + delta;
  56
  57         e = edict_num(this.cnt + 1);
  58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  59         {
  60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  61                 WriteByte(MSG_BROADCAST, this.cnt);
  62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  65
  66                 // record latency times for clients throughout the match so we can report it to playerstats
  67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  68                 {
  69                         CS(e).latency_sum += CS(e).ping;
  70                         CS(e).latency_cnt += 1;
  71                         CS(e).latency_time = time;
  72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  73                 }
  74         }
  75         else
  76         {
  77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  78                 WriteByte(MSG_BROADCAST, this.cnt);
  79                 WriteShort(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81                 WriteByte(MSG_BROADCAST, 0);
  82         }
  83         this.cnt = (this.cnt + 1) % maxclients;
  84 }
  85 void PingPLReport_Spawn()
  86 {
  87         pingplreport = new_pure(pingplreport);
  88         setthink(pingplreport, PingPLReport_Think);
  89         pingplreport.nextthink = time;
  90 }
  91
  92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  93 string redirection_target;
  94 float world_initialized;
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         strfree(cvar_changes);
 148         strfree(cvar_purechanges);
 149         cvar_purechanges_count = 0;
 150
 151         h = buf_create();
 152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 153         n = buf_getsize(h);
 154
 155         adding = true;
 156         pureadding = true;
 157
 158         for(i = 0; i < n; ++i)
 159         {
 160                 k = bufstr_get(h, i);
 161
 162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 164 #define BADCVAR(p) if(k == p) continue
 165
 166                 // general excludes and namespaces for server admin used cvars
 167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 168
 169                 // internal
 170                 BADPREFIX("csqc_");
 171                 BADPREFIX("cvar_check_");
 172                 BADCVAR("gamecfg");
 173                 BADCVAR("g_configversion");
 174                 BADCVAR("halflifebsp");
 175                 BADCVAR("sv_mapformat_is_quake2");
 176                 BADCVAR("sv_mapformat_is_quake3");
 177                 BADPREFIX("sv_world");
 178
 179                 // client
 180                 BADPREFIX("chase_");
 181                 BADPREFIX("cl_");
 182                 BADPREFIX("con_");
 183                 BADPREFIX("scoreboard_");
 184                 BADPREFIX("g_campaign");
 185                 BADPREFIX("g_waypointsprite_");
 186                 BADPREFIX("gl_");
 187                 BADPREFIX("joy");
 188                 BADPREFIX("hud_");
 189                 BADPREFIX("m_");
 190                 BADPREFIX("menu_");
 191                 BADPREFIX("net_slist_");
 192                 BADPREFIX("r_");
 193                 BADPREFIX("sbar_");
 194                 BADPREFIX("scr_");
 195                 BADPREFIX("snd_");
 196                 BADPREFIX("show");
 197                 BADPREFIX("sensitivity");
 198                 BADPREFIX("userbind");
 199                 BADPREFIX("v_");
 200                 BADPREFIX("vid_");
 201                 BADPREFIX("crosshair");
 202                 BADCVAR("mod_q3bsp_lightmapmergepower");
 203                 BADCVAR("mod_q3bsp_nolightmaps");
 204                 BADCVAR("fov");
 205                 BADCVAR("mastervolume");
 206                 BADCVAR("volume");
 207                 BADCVAR("bgmvolume");
 208                 BADCVAR("in_pitch_min");
 209                 BADCVAR("in_pitch_max");
 210
 211                 // private
 212                 BADCVAR("developer");
 213                 BADCVAR("log_dest_udp");
 214                 BADCVAR("net_address");
 215                 BADCVAR("net_address_ipv6");
 216                 BADCVAR("port");
 217                 BADCVAR("savedgamecfg");
 218                 BADCVAR("serverconfig");
 219                 BADCVAR("sv_autoscreenshot");
 220                 BADCVAR("sv_heartbeatperiod");
 221                 BADCVAR("sv_vote_master_password");
 222                 BADCVAR("sys_colortranslation");
 223                 BADCVAR("sys_specialcharactertranslation");
 224                 BADCVAR("timeformat");
 225                 BADCVAR("timestamps");
 226                 BADCVAR("g_require_stats");
 227                 BADPREFIX("developer_");
 228                 BADPREFIX("g_ban_");
 229                 BADPREFIX("g_banned_list");
 230                 BADPREFIX("g_require_stats_");
 231                 BADPREFIX("g_chat_flood_");
 232                 BADPREFIX("g_ghost_items");
 233                 BADPREFIX("g_playerstats_");
 234                 BADPREFIX("g_voice_flood_");
 235                 BADPREFIX("log_file");
 236                 BADPREFIX("quit_");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250                 BADCVAR("sv_muteban_list");
 251                 BADCVAR("sv_voteban_list");
 252                 BADCVAR("sv_allow_customplayermodels_idlist");
 253                 BADCVAR("sv_allow_customplayermodels_speciallist");
 254
 255                 // mapinfo
 256                 BADCVAR("fraglimit");
 257                 BADCVAR("g_arena");
 258                 BADCVAR("g_assault");
 259                 BADCVAR("g_ca");
 260                 BADCVAR("g_ca_teams");
 261                 BADCVAR("g_conquest");
 262                 BADCVAR("g_ctf");
 263                 BADCVAR("g_cts");
 264                 BADCVAR("g_dotc");
 265                 BADCVAR("g_dm");
 266                 BADCVAR("g_domination");
 267                 BADCVAR("g_domination_default_teams");
 268                 BADCVAR("g_duel");
 269                 BADCVAR("g_freezetag");
 270                 BADCVAR("g_freezetag_teams");
 271                 BADCVAR("g_invasion_teams");
 272                 BADCVAR("g_invasion_type");
 273                 BADCVAR("g_jailbreak");
 274                 BADCVAR("g_jailbreak_teams");
 275                 BADCVAR("g_keepaway");
 276                 BADCVAR("g_keyhunt");
 277                 BADCVAR("g_keyhunt_teams");
 278                 BADCVAR("g_lms");
 279                 BADCVAR("g_nexball");
 280                 BADCVAR("g_onslaught");
 281                 BADCVAR("g_race");
 282                 BADCVAR("g_race_laps_limit");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_race_qualifying_timelimit_override");
 285                 BADCVAR("g_runematch");
 286                 BADCVAR("g_snafu");
 287                 BADCVAR("g_tdm");
 288                 BADCVAR("g_tdm_teams");
 289                 BADCVAR("g_vip");
 290                 BADCVAR("leadlimit");
 291                 BADCVAR("nextmap");
 292                 BADCVAR("teamplay");
 293                 BADCVAR("timelimit");
 294                 BADCVAR("g_mapinfo_ignore_warnings");
 295
 296                 // long
 297                 BADCVAR("hostname");
 298                 BADCVAR("g_maplist");
 299                 BADCVAR("g_maplist_mostrecent");
 300                 BADCVAR("sv_motd");
 301
 302                 v = cvar_string(k);
 303                 d = cvar_defstring(k);
 304                 if(v == d)
 305                         continue;
 306
 307                 if(adding)
 308                 {
 309                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 310                         if(strlen(cvar_changes) > 16384)
 311                         {
 312                                 cvar_changes = "// too many settings have been changed to show them here\n";
 313                                 adding = 0;
 314                         }
 315                 }
 316
 317                 // now check if the changes are actually gameplay relevant
 318
 319                 // does nothing gameplay relevant
 320                 BADCVAR("captureleadlimit_override");
 321                 BADCVAR("condump_stripcolors");
 322                 BADCVAR("gameversion");
 323                 BADCVAR("g_allow_oldvortexbeam");
 324                 BADCVAR("g_balance_kill_delay");
 325                 BADCVAR("g_buffs_pickup_anyway");
 326                 BADCVAR("g_buffs_randomize");
 327                 BADCVAR("g_campcheck_distance");
 328                 BADCVAR("g_ca_point_leadlimit");
 329                 BADCVAR("g_ca_point_limit");
 330                 BADCVAR("g_ctf_captimerecord_always");
 331                 BADCVAR("g_ctf_flag_glowtrails");
 332                 BADCVAR("g_ctf_flag_pickup_verbosename");
 333                 BADCVAR("g_domination_point_leadlimit");
 334                 BADCVAR("g_forced_respawn");
 335                 BADCVAR("g_freezetag_point_leadlimit");
 336                 BADCVAR("g_freezetag_point_limit");
 337                 BADCVAR("g_hats");
 338                 BADCVAR("g_invasion_point_limit");
 339                 BADCVAR("g_jump_grunt");
 340                 BADCVAR("g_keyhunt_point_leadlimit");
 341                 BADCVAR("g_nexball_goalleadlimit");
 342                 BADCVAR("g_new_toys_use_pickupsound");
 343                 BADCVAR("g_physics_predictall");
 344                 BADCVAR("g_piggyback");
 345                 BADCVAR("g_playerclip_collisions");
 346                 BADCVAR("g_tdm_point_leadlimit");
 347                 BADCVAR("g_tdm_point_limit");
 348                 BADCVAR("leadlimit_and_fraglimit");
 349                 BADCVAR("leadlimit_override");
 350                 BADCVAR("pausable");
 351                 BADCVAR("sv_checkforpacketsduringsleep");
 352                 BADCVAR("sv_damagetext");
 353                 BADCVAR("sv_db_saveasdump");
 354                 BADCVAR("sv_intermission_cdtrack");
 355                 BADCVAR("sv_minigames");
 356                 BADCVAR("sv_namechangetimer");
 357                 BADCVAR("sv_precacheplayermodels");
 358                 BADCVAR("sv_stepheight");
 359                 BADCVAR("sv_timeout");
 360                 BADCVAR("sv_weapons_modeloverride");
 361                 BADCVAR("w_prop_interval");
 362                 BADPREFIX("crypto_");
 363                 BADPREFIX("gameversion_");
 364                 BADPREFIX("g_chat_");
 365                 BADPREFIX("g_ctf_captimerecord_");
 366                 BADPREFIX("g_hats_");
 367                 BADPREFIX("g_maplist_");
 368                 BADPREFIX("g_mod_");
 369                 BADPREFIX("g_respawn_");
 370                 BADPREFIX("net_");
 371                 BADPREFIX("notification_");
 372                 BADPREFIX("prvm_");
 373                 BADPREFIX("skill_");
 374                 BADPREFIX("sv_allow_");
 375                 BADPREFIX("sv_cullentities_");
 376                 BADPREFIX("sv_maxidle_");
 377                 BADPREFIX("sv_minigames_");
 378                 BADPREFIX("sv_radio_");
 379                 BADPREFIX("sv_timeout_");
 380                 BADPREFIX("sv_vote_");
 381                 BADPREFIX("timelimit_");
 382
 383                 // allowed changes to server admins (please sync this to server.cfg)
 384                 // vi commands:
 385                 //   :/"impure"/,$d
 386                 //   :g!,^\/\/[^ /],d
 387                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 388                 //   :%!sort
 389                 // yes, this does contain some redundant stuff, don't really care
 390                 BADCVAR("bot_config_file");
 391                 BADCVAR("bot_number");
 392                 BADCVAR("bot_prefix");
 393                 BADCVAR("bot_suffix");
 394                 BADCVAR("capturelimit_override");
 395                 BADCVAR("fraglimit_override");
 396                 BADCVAR("gametype");
 397                 BADCVAR("g_antilag");
 398                 BADCVAR("g_balance_teams");
 399                 BADCVAR("g_balance_teams_prevent_imbalance");
 400                 BADCVAR("g_balance_teams_scorefactor");
 401                 BADCVAR("g_ban_sync_trusted_servers");
 402                 BADCVAR("g_ban_sync_uri");
 403                 BADCVAR("g_buffs");
 404                 BADCVAR("g_ca_teams_override");
 405                 BADCVAR("g_ctf_ignore_frags");
 406                 BADCVAR("g_ctf_leaderboard");
 407                 BADCVAR("g_domination_point_limit");
 408                 BADCVAR("g_domination_teams_override");
 409                 BADCVAR("g_freezetag_teams_override");
 410                 BADCVAR("g_friendlyfire");
 411                 BADCVAR("g_fullbrightitems");
 412                 BADCVAR("g_fullbrightplayers");
 413                 BADCVAR("g_keyhunt_point_limit");
 414                 BADCVAR("g_keyhunt_teams_override");
 415                 BADCVAR("g_lms_lives_override");
 416                 BADCVAR("g_maplist");
 417                 BADCVAR("g_maxplayers");
 418                 BADCVAR("g_mirrordamage");
 419                 BADCVAR("g_nexball_goallimit");
 420                 BADCVAR("g_norecoil");
 421                 BADCVAR("g_physics_clientselect");
 422                 BADCVAR("g_pinata");
 423                 BADCVAR("g_powerups");
 424                 BADCVAR("g_spawnshieldtime");
 425                 BADCVAR("g_start_delay");
 426                 BADCVAR("g_superspectate");
 427                 BADCVAR("g_tdm_teams_override");
 428                 BADCVAR("g_warmup");
 429                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 430                 BADCVAR("hostname");
 431                 BADCVAR("log_file");
 432                 BADCVAR("maxplayers");
 433                 BADCVAR("minplayers");
 434                 BADCVAR("minplayers_per_team");
 435                 BADCVAR("net_address");
 436                 BADCVAR("port");
 437                 BADCVAR("rcon_password");
 438                 BADCVAR("rcon_restricted_commands");
 439                 BADCVAR("rcon_restricted_password");
 440                 BADCVAR("skill");
 441                 BADCVAR("sv_adminnick");
 442                 BADCVAR("sv_autoscreenshot");
 443                 BADCVAR("sv_autotaunt");
 444                 BADCVAR("sv_curl_defaulturl");
 445                 BADCVAR("sv_defaultcharacter");
 446                 BADCVAR("sv_defaultcharacterskin");
 447                 BADCVAR("sv_defaultplayercolors");
 448                 BADCVAR("sv_defaultplayermodel");
 449                 BADCVAR("sv_defaultplayerskin");
 450                 BADCVAR("sv_maxidle");
 451                 BADCVAR("sv_maxrate");
 452                 BADCVAR("sv_motd");
 453                 BADCVAR("sv_public");
 454                 BADCVAR("sv_ready_restart");
 455                 BADCVAR("sv_status_privacy");
 456                 BADCVAR("sv_taunt");
 457                 BADCVAR("sv_vote_call");
 458                 BADCVAR("sv_vote_commands");
 459                 BADCVAR("sv_vote_majority_factor");
 460                 BADCVAR("sv_vote_master");
 461                 BADCVAR("sv_vote_master_commands");
 462                 BADCVAR("sv_vote_master_password");
 463                 BADCVAR("sv_vote_simple_majority_factor");
 464                 BADCVAR("teamplay_mode");
 465                 BADCVAR("timelimit_override");
 466                 BADPREFIX("g_warmup_");
 467                 BADPREFIX("sv_info_");
 468                 BADPREFIX("sv_ready_restart_");
 469
 470                 // mutators that announce themselves properly to the server browser
 471                 BADCVAR("g_instagib");
 472                 BADCVAR("g_new_toys");
 473                 BADCVAR("g_nix");
 474                 BADCVAR("g_grappling_hook");
 475                 BADCVAR("g_jetpack");
 476
 477 #undef BADPRESUFFIX
 478 #undef BADPREFIX
 479 #undef BADCVAR
 480
 481                 if(pureadding)
 482                 {
 483                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 484                         if(strlen(cvar_purechanges) > 16384)
 485                         {
 486                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 487                                 pureadding = 0;
 488                         }
 489                 }
 490                 ++cvar_purechanges_count;
 491                 // WARNING: this variable is used for the server list
 492                 // NEVER dare to skip this code!
 493                 // Hacks to intentionally appearing as "pure server" even though you DO have
 494                 // modified settings may be punished by removal from the server list.
 495                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 496                 // though.
 497         }
 498         buf_del(h);
 499         if(cvar_changes == "")
 500                 cvar_changes = "// this server runs at default server settings\n";
 501         else
 502                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 503         cvar_changes = strzone(cvar_changes);
 504         if(cvar_purechanges == "")
 505                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 506         else
 507                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 508         cvar_purechanges = strzone(cvar_purechanges);
 509 }
 510
 511 entity randomseed;
 512 bool RandomSeed_Send(entity this, entity to, int sf)
 513 {
 514         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 515         WriteShort(MSG_ENTITY, this.cnt);
 516         return true;
 517 }
 518 void RandomSeed_Think(entity this)
 519 {
 520         this.cnt = bound(0, floor(random() * 65536), 65535);
 521         this.nextthink = time + 5;
 522
 523         this.SendFlags |= 1;
 524 }
 525 void RandomSeed_Spawn()
 526 {
 527         randomseed = new_pure(randomseed);
 528         setthink(randomseed, RandomSeed_Think);
 529         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 530
 531         getthink(randomseed)(randomseed); // sets random seed and nextthink
 532 }
 533
 534 spawnfunc(__init_dedicated_server)
 535 {
 536         // handler for _init/_init map (only for dedicated server initialization)
 537
 538         world_initialized = -1; // don't complain
 539         cvar = cvar_normal;
 540         cvar_string = cvar_string_normal;
 541         cvar_set = cvar_set_normal;
 542
 543         delete_fn = remove_unsafely;
 544
 545         entity e = spawn();
 546         setthink(e, GotoFirstMap);
 547         e.nextthink = time; // this is usually 1 at this point
 548
 549         e = new(info_player_deathmatch);  // safeguard against player joining
 550
 551     // assign reflectively to avoid "assignment to world" warning
 552     for (int i = 0, n = numentityfields(); i < n; ++i) {
 553         string k = entityfieldname(i);
 554         if (k == "classname") {
 555             // safeguard against various stuff ;)
 556             putentityfieldstring(i, this, "worldspawn");
 557             break;
 558         }
 559     }
 560
 561         // needs to be done so early because of the constants they create
 562         static_init();
 563         static_init_late();
 564         static_init_precache();
 565
 566         IL_PUSH(g_spawnpoints, e); // just incase
 567
 568         MapInfo_Enumerate();
 569         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 570 }
 571
 572 void __init_dedicated_server_shutdown() {
 573         MapInfo_Shutdown();
 574 }
 575
 576 STATIC_INIT_EARLY(maxclients)
 577 {
 578         maxclients = 0;
 579         for (entity head = nextent(NULL); head; head = nextent(head)) {
 580                 ++maxclients;
 581         }
 582 }
 583
 584 void default_delayedinit(entity this)
 585 {
 586         if(!scores_initialized)
 587                 ScoreRules_generic();
 588 }
 589
 590 void InitGameplayMode()
 591 {
 592         VoteReset();
 593
 594         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 595         get_mi_min_max(1);
 596         // assign reflectively to avoid "assignment to world" warning
 597         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 598             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 599             if (v) {
 600             putentityfieldstring(i, world, sprintf("%v", v));
 601             if (++done == 2) break;
 602         }
 603         }
 604         // currently, NetRadiant's limit is 131072 qu for each side
 605         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 606         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 607         // in case somebody makes extremely large maps
 608         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 609
 610         MapInfo_LoadMapSettings(mapname);
 611         GameRules_teams(false);
 612
 613         if (!cvar_value_issafe(world.fog))
 614         {
 615                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 616                 world.fog = string_null;
 617         }
 618         if(MapInfo_Map_fog != "")
 619         {
 620                 if(MapInfo_Map_fog == "none")
 621                         world.fog = string_null;
 622                 else
 623                         world.fog = strzone(MapInfo_Map_fog);
 624         }
 625         clientstuff = strzone(MapInfo_Map_clientstuff);
 626
 627         MapInfo_ClearTemps();
 628
 629         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 630
 631         cache_mutatormsg = strzone("");
 632         cache_lastmutatormsg = strzone("");
 633
 634         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 635 }
 636
 637 void Map_MarkAsRecent(string m);
 638 float world_already_spawned;
 639 spawnfunc(worldspawn)
 640 {
 641         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 642
 643         bool wantrestart = false;
 644         {
 645                 if (!server_is_dedicated)
 646                 {
 647                         // force unloading of server pk3 files when starting a listen server
 648                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 649                         // restore csqc_progname too
 650                         string expect = "csprogs.dat";
 651                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 652                         cvar_set_normal("csqc_progname", expect);
 653                 }
 654                 else
 655                 {
 656                         // Try to use versioned csprogs from pk3
 657                         // Only ever use versioned csprogs.dat files on dedicated servers;
 658                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 659                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 660                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 661                         string select = "csprogs.dat";
 662                         if (fexists(pk3csprogs)) select = pk3csprogs;
 663                         if (cvar_string_normal("csqc_progname") != select)
 664                         {
 665                                 cvar_set_normal("csqc_progname", select);
 666                                 wantrestart = true;
 667                         }
 668                         // Check for updates on startup
 669                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 670                         int sentinel = fopen("progs.txt", FILE_READ);
 671                         if (sentinel >= 0)
 672                         {
 673                                 string switchversion = fgets(sentinel);
 674                                 fclose(sentinel);
 675                                 if (switchversion != "" && switchversion != WATERMARK)
 676                                 {
 677                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 678                                         // if it doesn't exist, assume either:
 679                                         //   a) the current program was overwritten
 680                                         //   b) this is a client only update
 681                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 682                                         if (fexists(newprogs))
 683                                         {
 684                                                 cvar_set_normal("sv_progs", newprogs);
 685                                                 wantrestart = true;
 686                                         }
 687                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 688                                         if (fexists(newcsprogs))
 689                                         {
 690                                                 cvar_set_normal("csqc_progname", newcsprogs);
 691                                                 wantrestart = true;
 692                                         }
 693                                 }
 694                         }
 695                 }
 696                 if (wantrestart)
 697                 {
 698                         LOG_INFO("Restart requested");
 699                         changelevel(mapname);
 700                         // let initialization continue, shutdown depends on it
 701                 }
 702         }
 703
 704         cvar = cvar_normal;
 705         cvar_string = cvar_string_normal;
 706         cvar_set = cvar_set_normal;
 707
 708         if(world_already_spawned)
 709                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 710         world_already_spawned = true;
 711
 712         delete_fn = remove_safely; // during spawning, watch what you remove!
 713
 714         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 715
 716         // needs to be done so early because of the constants they create
 717         static_init();
 718
 719         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 720
 721         TemporaryDB = db_create();
 722
 723         // 0 normal
 724         lightstyle(0, "m");
 725
 726         // 1 FLICKER (first variety)
 727         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 728
 729         // 2 SLOW STRONG PULSE
 730         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 731
 732         // 3 CANDLE (first variety)
 733         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 734
 735         // 4 FAST STROBE
 736         lightstyle(4, "mamamamamama");
 737
 738         // 5 GENTLE PULSE 1
 739         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 740
 741         // 6 FLICKER (second variety)
 742         lightstyle(6, "nmonqnmomnmomomno");
 743
 744         // 7 CANDLE (second variety)
 745         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 746
 747         // 8 CANDLE (third variety)
 748         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 749
 750         // 9 SLOW STROBE (fourth variety)
 751         lightstyle(9, "aaaaaaaazzzzzzzz");
 752
 753         // 10 FLUORESCENT FLICKER
 754         lightstyle(10, "mmamammmmammamamaaamammma");
 755
 756         // 11 SLOW PULSE NOT FADE TO BLACK
 757         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 758
 759         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 760
 761         // 63 testing
 762         lightstyle(63, "a");
 763
 764         if(autocvar_g_campaign)
 765                 CampaignPreInit();
 766
 767         Map_MarkAsRecent(mapname);
 768
 769         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 770
 771         InitGameplayMode();
 772         static_init_late();
 773         static_init_precache();
 774         readlevelcvars();
 775         GrappleHookInit();
 776
 777         GameRules_limit_fallbacks();
 778
 779         if(warmup_limit == 0)
 780                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 781
 782         player_count = 0;
 783         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 784         if(bot_waypoints_for_items == 1)
 785                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 786                         bot_waypoints_for_items = 0;
 787
 788         precache();
 789
 790         WaypointSprite_Init();
 791
 792         GameLogInit(); // prepare everything
 793         // NOTE for matchid:
 794         // changing the logic generating it is okay. But:
 795         // it HAS to stay <= 64 chars
 796         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 797         if(autocvar_sv_eventlog)
 798         {
 799                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 800                 matchid = strzone(s);
 801
 802                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 803                 s = ":gameinfo:mutators:LIST";
 804
 805                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 806                 s = M_ARGV(0, string);
 807
 808                 // initialiation stuff, not good in the mutator system
 809                 if(!autocvar_g_use_ammunition)
 810                         s = strcat(s, ":no_use_ammunition");
 811
 812                 // initialiation stuff, not good in the mutator system
 813                 if(autocvar_g_pickup_items == 0)
 814                         s = strcat(s, ":no_pickup_items");
 815                 if(autocvar_g_pickup_items > 0)
 816                         s = strcat(s, ":pickup_items");
 817
 818                 // initialiation stuff, not good in the mutator system
 819                 if(autocvar_g_weaponarena != "0")
 820                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 821
 822                 // TODO to mutator system
 823                 if(autocvar_g_norecoil)
 824                         s = strcat(s, ":norecoil");
 825
 826                 // TODO to mutator system
 827                 if(autocvar_g_powerups == 0)
 828                         s = strcat(s, ":no_powerups");
 829                 if(autocvar_g_powerups > 0)
 830                         s = strcat(s, ":powerups");
 831
 832                 GameLogEcho(s);
 833                 GameLogEcho(":gameinfo:end");
 834         }
 835         else
 836                 matchid = strzone(ftos(random()));
 837
 838         cvar_set("nextmap", "");
 839
 840         SetDefaultAlpha();
 841
 842         if(autocvar_g_campaign)
 843                 CampaignPostInit();
 844
 845         Ban_LoadBans();
 846
 847         MapInfo_Enumerate();
 848         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 849
 850         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 851         {
 852                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 853                 if(fd != -1)
 854                 {
 855                         string s;
 856                         while((s = fgets(fd)))
 857                         {
 858                                 int l = tokenize_console(s);
 859                                 if(l < 2)
 860                                         continue;
 861                                 if(argv(0) == "cd")
 862                                 {
 863                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 864                                         LOG_INFO("  cdtrack ", argv(2));
 865                                 }
 866                                 else if(argv(0) == "fog")
 867                                 {
 868                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 869                                         LOG_INFO("  \"fog\" \"", s, "\"");
 870                                 }
 871                                 else if(argv(0) == "set")
 872                                 {
 873                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 874                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 875                                 }
 876                                 else if(argv(0) != "//")
 877                                 {
 878                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 879                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 880                                 }
 881                         }
 882                         fclose(fd);
 883                 }
 884         }
 885
 886         WeaponStats_Init();
 887
 888         Nagger_Init();
 889
 890         next_pingtime = time + 5;
 891
 892         // set up information replies for clients and server to use
 893         maplist_reply = strzone(getmaplist());
 894         lsmaps_reply = strzone(getlsmaps());
 895         monsterlist_reply = strzone(getmonsterlist());
 896         for(int i = 0; i < 10; ++i)
 897         {
 898                 string s = getrecords(i);
 899                 if (s)
 900                         records_reply[i] = strzone(s);
 901         }
 902         ladder_reply = strzone(getladder());
 903         rankings_reply = strzone(getrankings());
 904
 905         // begin other init
 906         ClientInit_Spawn();
 907         RandomSeed_Spawn();
 908         PingPLReport_Spawn();
 909
 910         CheatInit();
 911
 912         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 913
 914         // fill sv_curl_serverpackages from .serverpackage files
 915         if (autocvar_sv_curl_serverpackages_auto)
 916         {
 917                 string s = "csprogs-" WATERMARK ".txt";
 918                 // remove automatically managed files from the list to prevent duplicates
 919                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 920                 {
 921                         string pkg = argv(i);
 922                         if (startsWith(pkg, "csprogs-")) continue;
 923                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 924                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 925                         s = cons(s, pkg);
 926                 }
 927                 // add automatically managed files to the list
 928                 #define X(match) MACRO_BEGIN \
 929                         int fd = search_begin(match, true, false); \
 930                         if (fd >= 0) \
 931                         { \
 932                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 933                                 { \
 934                                         s = cons(s, search_getfilename(fd, i)); \
 935                                 } \
 936                                 search_end(fd); \
 937                         } \
 938                 MACRO_END
 939                 X("*-serverpackage.txt");
 940                 X("*.serverpackage");
 941                 #undef X
 942                 cvar_set("sv_curl_serverpackages", s);
 943         }
 944
 945         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 946         modname = "Xonotic";
 947         // physics/balance/config changes that count as mod
 948         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 949                 modname = cvar_string("g_mod_physics");
 950         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 951                 modname = cvar_string("g_mod_balance");
 952         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 953                 modname = cvar_string("g_mod_config");
 954         // extra mutators that deserve to count as mod
 955         MUTATOR_CALLHOOK(SetModname, modname);
 956         modname = M_ARGV(0, string);
 957
 958         // save it for later
 959         modname = strzone(modname);
 960
 961         WinningConditionHelper(this); // set worldstatus
 962
 963         world_initialized = 1;
 964         __spawnfunc_spawn_all();
 965 }
 966
 967 spawnfunc(light)
 968 {
 969         //makestatic (this); // Who the f___ did that?
 970         delete(this);
 971 }
 972
 973 string GetGametype()
 974 {
 975         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 976 }
 977
 978 string GetMapname()
 979 {
 980         return mapname;
 981 }
 982
 983 float Map_Count, Map_Current;
 984 string Map_Current_Name;
 985
 986 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 987 float GetMaplistPosition()
 988 {
 989         float pos, idx;
 990         string map;
 991
 992         map = GetMapname();
 993         idx = autocvar_g_maplist_index;
 994
 995         if(idx >= 0)
 996                 if(idx < Map_Count)
 997                         if(map == argv(idx))
 998                                 return idx;
 999
1000         for(pos = 0; pos < Map_Count; ++pos)
1001                 if(map == argv(pos))
1002                         return pos;
1003
1004         // resume normal maplist rotation if current map is not in g_maplist
1005         return idx;
1006 }
1007
1008 bool MapHasRightSize(string map)
1009 {
1010         int minplayers = max(0, floor(autocvar_minplayers));
1011         if (teamplay)
1012                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1013         if (autocvar_g_maplist_check_waypoints
1014                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1015         {
1016                 string checkwp_msg = strcat("checkwp ", map);
1017                 if(!fexists(strcat("maps/", map, ".waypoints")))
1018                 {
1019                         LOG_TRACE(checkwp_msg, ": no waypoints");
1020                         return false;
1021                 }
1022                 LOG_TRACE(checkwp_msg, ": has waypoints");
1023         }
1024
1025         if(autocvar_g_maplist_ignore_sizes)
1026                 return true;
1027
1028         // open map size restriction file
1029         string opensize_msg = strcat("opensize ", map);
1030         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1031         if(fh >= 0)
1032         {
1033                 opensize_msg = strcat(opensize_msg, ": ok, ");
1034                 int mapmin = stoi(fgets(fh));
1035                 int mapmax = stoi(fgets(fh));
1036                 fclose(fh);
1037                 if(player_count < mapmin)
1038                 {
1039                         LOG_TRACE(opensize_msg, "not enough");
1040                         return false;
1041                 }
1042                 if(mapmax && player_count > mapmax)
1043                 {
1044                         LOG_TRACE(opensize_msg, "too many");
1045                         return false;
1046                 }
1047                 LOG_TRACE(opensize_msg, "right size");
1048                 return true;
1049         }
1050         LOG_TRACE(opensize_msg, ": not found");
1051         return true;
1052 }
1053
1054 string Map_Filename(float position)
1055 {
1056         return strcat("maps/", argv(position), ".bsp");
1057 }
1058
1059 void Map_MarkAsRecent(string m)
1060 {
1061         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1062 }
1063
1064 float Map_IsRecent(string m)
1065 {
1066         return strhasword(autocvar_g_maplist_mostrecent, m);
1067 }
1068
1069 float Map_Check(float position, float pass)
1070 {
1071         string filename;
1072         string map_next;
1073         map_next = argv(position);
1074         if(pass <= 1)
1075         {
1076                 if(Map_IsRecent(map_next))
1077                         return 0;
1078         }
1079         filename = Map_Filename(position);
1080         if(MapInfo_CheckMap(map_next))
1081         {
1082                 if(pass == 2)
1083                         return 1;
1084                 if(MapHasRightSize(map_next))
1085                         return 1;
1086                 return 0;
1087         }
1088         else
1089                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1090
1091         return 0;
1092 }
1093
1094 void Map_Goto_SetStr(string nextmapname)
1095 {
1096         if(getmapname_stored != "")
1097                 strunzone(getmapname_stored);
1098         if(nextmapname == "")
1099                 getmapname_stored = "";
1100         else
1101                 getmapname_stored = strzone(nextmapname);
1102 }
1103
1104 void Map_Goto_SetFloat(float position)
1105 {
1106         cvar_set("g_maplist_index", ftos(position));
1107         Map_Goto_SetStr(argv(position));
1108 }
1109
1110 void Map_Goto(float reinit)
1111 {
1112         MapInfo_LoadMap(getmapname_stored, reinit);
1113 }
1114
1115 // return codes of map selectors:
1116 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1117 //   -2 = permanent failure
1118 float MaplistMethod_Iterate() // usual method
1119 {
1120         float pass, i;
1121
1122         LOG_TRACE("Trying MaplistMethod_Iterate");
1123
1124         for(pass = 1; pass <= 2; ++pass)
1125         {
1126                 for(i = 1; i < Map_Count; ++i)
1127                 {
1128                         float mapindex;
1129                         mapindex = (i + Map_Current) % Map_Count;
1130                         if(Map_Check(mapindex, pass))
1131                                 return mapindex;
1132                 }
1133         }
1134         return -1;
1135 }
1136
1137 float MaplistMethod_Repeat() // fallback method
1138 {
1139         LOG_TRACE("Trying MaplistMethod_Repeat");
1140
1141         if(Map_Check(Map_Current, 2))
1142                 return Map_Current;
1143         return -2;
1144 }
1145
1146 float MaplistMethod_Random() // random map selection
1147 {
1148         float i, imax;
1149
1150         LOG_TRACE("Trying MaplistMethod_Random");
1151
1152         imax = 42;
1153
1154         for(i = 0; i <= imax; ++i)
1155         {
1156                 float mapindex;
1157                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1158                 if(Map_Check(mapindex, 1))
1159                         return mapindex;
1160         }
1161         return -1;
1162 }
1163
1164 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1165 // the exponent sets a bias on the map selection:
1166 // the higher the exponent, the less likely "shortly repeated" same maps are
1167 {
1168         float i, j, imax, insertpos;
1169
1170         LOG_TRACE("Trying MaplistMethod_Shuffle");
1171
1172         imax = 42;
1173
1174         for(i = 0; i <= imax; ++i)
1175         {
1176                 string newlist;
1177
1178                 // now reinsert this at another position
1179                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1180                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1181                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1182                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1183
1184                 // insert the current map there
1185                 newlist = "";
1186                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1187                         newlist = strcat(newlist, " ", argv(j));
1188                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1189                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1190                         newlist = strcat(newlist, " ", argv(j));
1191                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1192                 cvar_set("g_maplist", newlist);
1193                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1194
1195                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1196                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1197                 if(Map_Check(Map_Current, 1))
1198                         return Map_Current;
1199         }
1200         return -1;
1201 }
1202
1203 void Maplist_Init()
1204 {
1205         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1206         float i;
1207         for (i = 0; i < Map_Count; ++i)
1208                 if (Map_Check(i, 2))
1209                         break;
1210         if (i == Map_Count)
1211         {
1212                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1213                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1214                 if(autocvar_g_maplist_shuffle)
1215                         ShuffleMaplist();
1216                 localcmd("\nmenu_cmd sync\n");
1217                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1218         }
1219         if(Map_Count == 0)
1220                 error("empty maplist, cannot select a new map");
1221         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1222
1223         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1224         // this may or may not be correct, but who cares, in the worst case a map
1225         // isn't chosen in the first pass that should have been
1226 }
1227
1228 string GetNextMap()
1229 {
1230         float nextMap;
1231
1232         Maplist_Init();
1233         nextMap = -1;
1234
1235         if(nextMap == -1)
1236                 if(autocvar_g_maplist_shuffle > 0)
1237                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1238
1239         if(nextMap == -1)
1240                 if(autocvar_g_maplist_selectrandom)
1241                         nextMap = MaplistMethod_Random();
1242
1243         if(nextMap == -1)
1244                 nextMap = MaplistMethod_Iterate();
1245
1246         if(nextMap == -1)
1247                 nextMap = MaplistMethod_Repeat();
1248
1249         if(nextMap >= 0)
1250         {
1251                 Map_Goto_SetFloat(nextMap);
1252                 return getmapname_stored;
1253         }
1254
1255         return "";
1256 }
1257
1258 float DoNextMapOverride(float reinit)
1259 {
1260         if(autocvar_g_campaign)
1261         {
1262                 CampaignPostIntermission();
1263                 alreadychangedlevel = true;
1264                 return true;
1265         }
1266         if(autocvar_quit_when_empty)
1267         {
1268                 if(player_count <= currentbots)
1269                 {
1270                         localcmd("quit\n");
1271                         alreadychangedlevel = true;
1272                         return true;
1273                 }
1274         }
1275         if(autocvar_quit_and_redirect != "")
1276         {
1277                 redirection_target = strzone(autocvar_quit_and_redirect);
1278                 alreadychangedlevel = true;
1279                 return true;
1280         }
1281         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1282         {
1283                 localcmd("restart\n");
1284                 alreadychangedlevel = true;
1285                 return true;
1286         }
1287         if(autocvar_nextmap != "")
1288         {
1289                 string m;
1290                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1291                 cvar_set("nextmap",m);
1292
1293                 if(!m || gametypevote)
1294                         return false;
1295                 if(autocvar_sv_vote_gametype)
1296                 {
1297                         Map_Goto_SetStr(m);
1298                         return false;
1299                 }
1300
1301                 if(MapInfo_CheckMap(m))
1302                 {
1303                         Map_Goto_SetStr(m);
1304                         Map_Goto(reinit);
1305                         alreadychangedlevel = true;
1306                         return true;
1307                 }
1308         }
1309         if(!reinit && autocvar_lastlevel)
1310         {
1311                 cvar_settemp_restore();
1312                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1313                 alreadychangedlevel = true;
1314                 return true;
1315         }
1316         return false;
1317 }
1318
1319 void GotoNextMap(float reinit)
1320 {
1321         //string nextmap;
1322         //float n, nummaps;
1323         //string s;
1324         if (alreadychangedlevel)
1325                 return;
1326         alreadychangedlevel = true;
1327
1328         string nextMap;
1329
1330         nextMap = GetNextMap();
1331         if(nextMap == "")
1332                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1333         Map_Goto(reinit);
1334 }
1335
1336
1337 /*
1338 ============
1339 IntermissionThink
1340
1341 When the player presses attack or jump, change to the next level
1342 ============
1343 */
1344 .float autoscreenshot;
1345 void IntermissionThink(entity this)
1346 {
1347         FixIntermissionClient(this);
1348
1349         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1350         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1351
1352         if( (server_screenshot || client_screenshot)
1353                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1354         {
1355                 this.autoscreenshot = -1;
1356                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1357                 return;
1358         }
1359
1360         if (time < intermission_exittime)
1361                 return;
1362
1363         if(!mapvote_initialized)
1364                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1365                         return;
1366
1367         MapVote_Start();
1368 }
1369
1370 /*
1371 ============
1372 FindIntermission
1373
1374 Returns the entity to view from
1375 ============
1376 */
1377 /*
1378 entity FindIntermission()
1379 {
1380         local   entity spot;
1381         local   float cyc;
1382
1383 // look for info_intermission first
1384         spot = find(NULL, classname, "info_intermission");
1385         if (spot)
1386         {       // pick a random one
1387                 cyc = random() * 4;
1388                 while (cyc > 1)
1389                 {
1390                         spot = find(spot, classname, "info_intermission");
1391                         if (!spot)
1392                                 spot = find(spot, classname, "info_intermission");
1393                         cyc = cyc - 1;
1394                 }
1395                 return spot;
1396         }
1397
1398 // then look for the start position
1399         spot = find(NULL, classname, "info_player_start");
1400         if (spot)
1401                 return spot;
1402
1403 // testinfo_player_start is only found in regioned levels
1404         spot = find(NULL, classname, "testplayerstart");
1405         if (spot)
1406                 return spot;
1407
1408 // then look for the start position
1409         spot = find(NULL, classname, "info_player_deathmatch");
1410         if (spot)
1411                 return spot;
1412
1413         //objerror ("FindIntermission: no spot");
1414         return NULL;
1415 }
1416 */
1417
1418 /*
1419 ===============================================================================
1420
1421 RULES
1422
1423 ===============================================================================
1424 */
1425
1426 void DumpStats(float final)
1427 {
1428         float file;
1429         string s;
1430         float to_console;
1431         float to_eventlog;
1432         float to_file;
1433         float i;
1434
1435         to_console = autocvar_sv_logscores_console;
1436         to_eventlog = autocvar_sv_eventlog;
1437         to_file = autocvar_sv_logscores_file;
1438
1439         if(!final)
1440         {
1441                 to_console = true; // always print printstats replies
1442                 to_eventlog = false; // but never print them to the event log
1443         }
1444
1445         if(to_eventlog)
1446                 if(autocvar_sv_eventlog_console)
1447                         to_console = false; // otherwise we get the output twice
1448
1449         if(final)
1450                 s = ":scores:";
1451         else
1452                 s = ":status:";
1453         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1454
1455         if(to_console)
1456                 LOG_INFO(s);
1457         if(to_eventlog)
1458                 GameLogEcho(s);
1459
1460         file = -1;
1461         if(to_file)
1462         {
1463                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1464                 if(file == -1)
1465                         to_file = false;
1466                 else
1467                         fputs(file, strcat(s, "\n"));
1468         }
1469
1470         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1471         if(to_console)
1472                 LOG_INFO(s);
1473         if(to_eventlog)
1474                 GameLogEcho(s);
1475         if(to_file)
1476                 fputs(file, strcat(s, "\n"));
1477
1478         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1479                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1480                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1481                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1482                         s = strcat(s, ftos(it.team), ":");
1483                 else
1484                         s = strcat(s, "spectator:");
1485
1486                 if(to_console)
1487                         LOG_INFO(s, playername(it, false));
1488                 if(to_eventlog)
1489                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1490                 if(to_file)
1491                         fputs(file, strcat(s, playername(it, false), "\n"));
1492         });
1493
1494         if(teamplay)
1495         {
1496                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1497                 if(to_console)
1498                         LOG_INFO(s);
1499                 if(to_eventlog)
1500                         GameLogEcho(s);
1501                 if(to_file)
1502                         fputs(file, strcat(s, "\n"));
1503
1504                 for(i = 1; i < 16; ++i)
1505                 {
1506                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1507                         s = strcat(s, ":", ftos(i));
1508                         if(to_console)
1509                                 LOG_INFO(s);
1510                         if(to_eventlog)
1511                                 GameLogEcho(s);
1512                         if(to_file)
1513                                 fputs(file, strcat(s, "\n"));
1514                 }
1515         }
1516
1517         if(to_console)
1518                 LOG_INFO(":end");
1519         if(to_eventlog)
1520                 GameLogEcho(":end");
1521         if(to_file)
1522         {
1523                 fputs(file, ":end\n");
1524                 fclose(file);
1525         }
1526 }
1527
1528 void FixIntermissionClient(entity e)
1529 {
1530         if(!e.autoscreenshot) // initial call
1531         {
1532                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1533                 SetResourceExplicit(e, RES_HEALTH, -2342);
1534                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1535                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1536                 {
1537                     .entity weaponentity = weaponentities[slot];
1538                         if(e.(weaponentity))
1539                         {
1540                                 e.(weaponentity).effects = EF_NODRAW;
1541                                 if (e.(weaponentity).weaponchild)
1542                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1543                         }
1544                 }
1545                 if(IS_REAL_CLIENT(e))
1546                 {
1547                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1548                         RandomSelection_Init();
1549                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1550                                 RandomSelection_AddString(it, 1, 1);
1551                         });
1552                         if (RandomSelection_chosen_string != "")
1553                         {
1554                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1555                         }
1556                         msg_entity = e;
1557                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1558                 }
1559         }
1560 }
1561
1562 /*
1563 go to the next level for deathmatch
1564 only called if a time or frag limit has expired
1565 */
1566 void NextLevel()
1567 {
1568         game_stopped = true;
1569         intermission_running = 1; // game over
1570
1571         // enforce a wait time before allowing changelevel
1572         if(player_count > 0)
1573                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1574         else
1575                 intermission_exittime = -1;
1576
1577         /*
1578         WriteByte (MSG_ALL, SVC_CDTRACK);
1579         WriteByte (MSG_ALL, 3);
1580         WriteByte (MSG_ALL, 3);
1581         // done in FixIntermission
1582         */
1583
1584         //pos = FindIntermission ();
1585
1586         VoteReset();
1587
1588         DumpStats(true);
1589
1590         // send statistics
1591         PlayerStats_GameReport(true);
1592         WeaponStats_Shutdown();
1593
1594         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1595
1596         if(autocvar_sv_eventlog)
1597                 GameLogEcho(":gameover");
1598
1599         GameLogClose();
1600
1601         FOREACH_CLIENT(IS_PLAYER(it), {
1602                 FixIntermissionClient(it);
1603                 if(it.winning)
1604                         bprint(playername(it, false), " ^7wins.\n");
1605         });
1606
1607         target_music_kill();
1608
1609         if(autocvar_g_campaign)
1610                 CampaignPreIntermission();
1611
1612         MUTATOR_CALLHOOK(MatchEnd);
1613
1614         localcmd("\nsv_hook_gameend\n");
1615 }
1616
1617
1618 float InitiateSuddenDeath()
1619 {
1620         // Check first whether normal overtimes could be added before initiating suddendeath mode
1621         // - for this timelimit_overtime needs to be >0 of course
1622         // - also check the winning condition calculated in the previous frame and only add normal overtime
1623         //   again, if at the point at which timelimit would be extended again, still no winner was found
1624         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1625                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1626                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1627         {
1628                 return 1; // need to call InitiateOvertime later
1629         }
1630         else
1631         {
1632                 if(!checkrules_suddendeathend)
1633                 {
1634                         if(autocvar_g_campaign)
1635                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1636                         else
1637                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1638                         if(g_race && !g_race_qualifying)
1639                                 race_StartCompleting();
1640                 }
1641                 return 0;
1642         }
1643 }
1644
1645 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1646 {
1647         ++checkrules_overtimesadded;
1648         //add one more overtime by simply extending the timelimit
1649         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1650         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1651 }
1652
1653 float GetWinningCode(float fraglimitreached, float equality)
1654 {
1655         if(autocvar_g_campaign == 1)
1656         {
1657                 if(fraglimitreached)
1658                         return WINNING_YES;
1659                 else
1660                         return WINNING_NO;
1661         }
1662         else
1663         {
1664                 if(equality)
1665                 {
1666                         if(fraglimitreached)
1667                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1668                         else
1669                                 return WINNING_NEVER;
1670                 }
1671                 else
1672                 {
1673                         if(fraglimitreached)
1674                                 return WINNING_YES;
1675                         else
1676                                 return WINNING_NO;
1677                 }
1678         }
1679 }
1680
1681 // set the .winning flag for exactly those players with a given field value
1682 void SetWinners(.float field, float value)
1683 {
1684         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1685 }
1686
1687 // set the .winning flag for those players with a given field value
1688 void AddWinners(.float field, float value)
1689 {
1690         FOREACH_CLIENT(IS_PLAYER(it), {
1691                 if(it.(field) == value)
1692                         it.winning = 1;
1693         });
1694 }
1695
1696 // clear the .winning flags
1697 void ClearWinners()
1698 {
1699         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1700 }
1701
1702 void ShuffleMaplist()
1703 {
1704         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1705 }
1706
1707 float leaderfrags;
1708 float WinningCondition_Scores(float limit, float leadlimit)
1709 {
1710         float limitreached;
1711
1712         // TODO make everything use THIS winning condition (except LMS)
1713         WinningConditionHelper(NULL);
1714
1715         if(teamplay)
1716         {
1717                 for (int i = 1; i < 5; ++i)
1718                 {
1719                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1720                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1721                 }
1722         }
1723
1724         ClearWinners();
1725         if(WinningConditionHelper_winner)
1726                 WinningConditionHelper_winner.winning = 1;
1727         if(WinningConditionHelper_winnerteam >= 0)
1728                 SetWinners(team, WinningConditionHelper_winnerteam);
1729
1730         if(WinningConditionHelper_lowerisbetter)
1731         {
1732                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1733                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1734                 limit = -limit;
1735         }
1736
1737         if(WinningConditionHelper_zeroisworst)
1738                 leadlimit = 0; // not supported in this mode
1739
1740         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1741         // these modes always score in increments of 1, thus this makes sense
1742         {
1743                 if(leaderfrags != WinningConditionHelper_topscore)
1744                 {
1745                         leaderfrags = WinningConditionHelper_topscore;
1746
1747                         if (limit)
1748                         {
1749                                 if (leaderfrags == limit - 1)
1750                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1751                                 else if (leaderfrags == limit - 2)
1752                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1753                                 else if (leaderfrags == limit - 3)
1754                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1755                         }
1756                 }
1757         }
1758
1759         limitreached = false;
1760         if (limit && WinningConditionHelper_topscore >= limit)
1761                 limitreached = true;
1762         if(leadlimit)
1763         {
1764                 float leadlimitreached;
1765                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1766                 if(autocvar_leadlimit_and_fraglimit)
1767                         limitreached = (limitreached && leadlimitreached);
1768                 else
1769                         limitreached = (limitreached || leadlimitreached);
1770         }
1771
1772         if(limit)
1773                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1774
1775         return GetWinningCode(
1776                 WinningConditionHelper_topscore && limitreached,
1777                 WinningConditionHelper_equality
1778         );
1779 }
1780
1781 float WinningCondition_RanOutOfSpawns()
1782 {
1783         if(have_team_spawns <= 0)
1784                 return WINNING_NO;
1785
1786         if(!autocvar_g_spawn_useallspawns)
1787                 return WINNING_NO;
1788
1789         if(!some_spawn_has_been_used)
1790                 return WINNING_NO;
1791
1792         for (int i = 1; i < 5; ++i)
1793         {
1794                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1795         }
1796
1797         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1798         {
1799                 if (Team_IsValidTeam(it.team))
1800                 {
1801                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1802                 }
1803         });
1804
1805         IL_EACH(g_spawnpoints, true,
1806         {
1807                 if (Team_IsValidTeam(it.team))
1808                 {
1809                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1810                 }
1811         });
1812
1813         ClearWinners();
1814         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1815         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1816         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1817         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1818         if(team1_score + team2_score + team3_score + team4_score == 0)
1819         {
1820                 checkrules_equality = true;
1821                 return WINNING_YES;
1822         }
1823         else if(team1_score + team2_score + team3_score + team4_score == 1)
1824         {
1825                 float t, i;
1826                 if(team1_score)
1827                         t = 1;
1828                 else if(team2_score)
1829                         t = 2;
1830                 else if(team3_score)
1831                         t = 3;
1832                 else // if(team4_score)
1833                         t = 4;
1834                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1835                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1836                 {
1837                         for (int j = 1; j <= NUM_TEAMS; ++j)
1838                         {
1839                                 if (t == j)
1840                                 {
1841                                         continue;
1842                                 }
1843                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1844                                 {
1845                                         continue;
1846                                 }
1847                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1848                         }
1849                 }
1850
1851                 AddWinners(team, t);
1852                 return WINNING_YES;
1853         }
1854         else
1855                 return WINNING_NO;
1856 }
1857
1858 /*
1859 ============
1860 CheckRules_World
1861
1862 Exit deathmatch games upon conditions
1863 ============
1864 */
1865 void CheckRules_World()
1866 {
1867         float timelimit;
1868         float fraglimit;
1869         float leadlimit;
1870
1871         VoteThink();
1872         MapVote_Think();
1873
1874         SetDefaultAlpha();
1875
1876         if (intermission_running) // someone else quit the game already
1877         {
1878                 if(player_count == 0) // Nobody there? Then let's go to the next map
1879                         MapVote_Start();
1880                         // this will actually check the player count in the next frame
1881                         // again, but this shouldn't hurt
1882                 return;
1883         }
1884
1885         timelimit = autocvar_timelimit * 60;
1886         fraglimit = autocvar_fraglimit;
1887         leadlimit = autocvar_leadlimit;
1888
1889         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1890         {
1891                 if(timelimit > 0)
1892                         timelimit = 0; // timelimit is not made for warmup
1893                 if(fraglimit > 0)
1894                         fraglimit = 0; // no fraglimit for now
1895                 leadlimit = 0; // no leadlimit for now
1896         }
1897
1898         if(timelimit > 0)
1899         {
1900                 timelimit += game_starttime;
1901         }
1902         else if (timelimit < 0)
1903         {
1904                 // endmatch
1905                 NextLevel();
1906                 return;
1907         }
1908
1909         float wantovertime;
1910         wantovertime = 0;
1911
1912         if(timelimit > game_starttime)
1913                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1914         else
1915                 game_completion_ratio = 0;
1916
1917         if(checkrules_suddendeathend)
1918         {
1919                 if(!checkrules_suddendeathwarning)
1920                 {
1921                         checkrules_suddendeathwarning = true;
1922                         if(g_race && !g_race_qualifying)
1923                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1924                         else
1925                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1926                 }
1927         }
1928         else
1929         {
1930                 if (timelimit && time >= timelimit)
1931                 {
1932                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1933                         {
1934                                 float totalplayers;
1935                                 float playerswithlaps;
1936                                 float readyplayers;
1937                                 totalplayers = playerswithlaps = readyplayers = 0;
1938                                 FOREACH_CLIENT(IS_PLAYER(it), {
1939                                         ++totalplayers;
1940                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1941                                                 ++playerswithlaps;
1942                                         if(it.ready)
1943                                                 ++readyplayers;
1944                                 });
1945
1946                                 // at least 2 of the players have completed a lap: start the RACE
1947                                 // otherwise, the players should end the qualifying on their own
1948                                 if(readyplayers || playerswithlaps >= 2)
1949                                 {
1950                                         checkrules_suddendeathend = 0;
1951                                         ReadyRestart(); // go to race
1952                                         return;
1953                                 }
1954                                 else
1955                                         wantovertime |= InitiateSuddenDeath();
1956                         }
1957                         else
1958                                 wantovertime |= InitiateSuddenDeath();
1959                 }
1960         }
1961
1962         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1963         {
1964                 NextLevel();
1965                 return;
1966         }
1967
1968         int checkrules_status = WinningCondition_RanOutOfSpawns();
1969         if(checkrules_status == WINNING_YES)
1970                 bprint("Hey! Someone ran out of spawns!\n");
1971         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1972                 checkrules_status = M_ARGV(0, float);
1973         else
1974                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1975
1976         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1977         {
1978                 checkrules_status = WINNING_NEVER;
1979                 checkrules_overtimesadded = -1;
1980                 wantovertime |= InitiateSuddenDeath();
1981         }
1982
1983         if(checkrules_status == WINNING_NEVER)
1984                 // equality cases! Nobody wins if the overtime ends in a draw.
1985                 ClearWinners();
1986
1987         if(wantovertime)
1988         {
1989                 if(checkrules_status == WINNING_NEVER)
1990                         InitiateOvertime();
1991                 else
1992                         checkrules_status = WINNING_YES;
1993         }
1994
1995         if(checkrules_suddendeathend)
1996                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1997                         checkrules_status = WINNING_YES;
1998
1999         if(checkrules_status == WINNING_YES)
2000         {
2001                 //print("WINNING\n");
2002                 NextLevel();
2003         }
2004 }
2005
2006 string GotoMap(string m)
2007 {
2008         m = GameTypeVote_MapInfo_FixName(m);
2009         if (!m)
2010                 return "The map you suggested is not available on this server.";
2011         if (!autocvar_sv_vote_gametype)
2012         if(!MapInfo_CheckMap(m))
2013                 return "The map you suggested does not support the current game mode.";
2014         cvar_set("nextmap", m);
2015         cvar_set("timelimit", "-1");
2016         if(mapvote_initialized || alreadychangedlevel)
2017         {
2018                 if(DoNextMapOverride(0))
2019                         return "Map switch initiated.";
2020                 else
2021                         return "Hm... no. For some reason I like THIS map more.";
2022         }
2023         else
2024                 return "Map switch will happen after scoreboard.";
2025 }
2026
2027 bool autocvar_sv_gameplayfix_multiplethinksperframe;
2028 void RunThink(entity this)
2029 {
2030         // don't let things stay in the past.
2031         // it is possible to start that way by a trigger with a local time.
2032         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2033                 return;
2034
2035         float oldtime = time; // do we need to save this?
2036
2037         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2038         {
2039                 time = max(oldtime, this.nextthink);
2040                 this.nextthink = 0;
2041
2042                 if(getthink(this))
2043                         getthink(this)(this);
2044                 // mods often set nextthink to time to cause a think every frame,
2045                 // we don't want to loop in that case, so exit if the new nextthink is
2046                 // <= the time the qc was told, also exit if it is past the end of the
2047                 // frame
2048                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2049                         break;
2050         }
2051
2052         time = oldtime;
2053 }
2054
2055 bool autocvar_sv_freezenonclients;
2056 bool autocvar_sv_gameplayfix_delayprojectiles;
2057 void Physics_Frame()
2058 {
2059         if(autocvar_sv_freezenonclients)
2060                 return;
2061
2062         FOREACH_ENTITY_FLOAT(pure_data, false,
2063         {
2064                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2065                         continue;
2066
2067                 //set_movetype(it, it.move_movetype);
2068                 // inline the set_movetype function, since this is called a lot
2069                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2070
2071                 if(it.move_movetype == MOVETYPE_NONE)
2072                         continue;
2073
2074                 if(it.move_qcphysics)
2075                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2076
2077                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2078                 {
2079                         // handle thinking here
2080                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2081                                 RunThink(it);
2082                 }
2083         });
2084
2085         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2086                 return;
2087
2088         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2089         {
2090                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2091                         continue;
2092                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2093         });
2094 }
2095
2096 void systems_update();
2097 void EndFrame()
2098 {
2099         anticheat_endframe();
2100
2101         Physics_Frame();
2102
2103         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2104                 entity e = IS_SPEC(it) ? it.enemy : it;
2105                 if (e.typehitsound) {
2106                         STAT(TYPEHIT_TIME, it) = time;
2107                 } else if (e.killsound) {
2108                         STAT(KILL_TIME, it) = time;
2109                 } else if (e.damage_dealt) {
2110                         STAT(HIT_TIME, it) = time;
2111                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2112                 }
2113         });
2114         // add 1 frametime because after this, engine SV_Physics
2115         // increases time by a frametime and then networks the frame
2116         // add another frametime because client shows everything with
2117         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2118         // needed!
2119         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2120         FOREACH_CLIENT(true, {
2121                 it.typehitsound = false;
2122                 it.damage_dealt = 0;
2123                 it.killsound = false;
2124                 antilag_record(it, CS(it), altime);
2125         });
2126         IL_EACH(g_monsters, true,
2127         {
2128                 antilag_record(it, it, altime);
2129         });
2130         IL_EACH(g_projectiles, it.classname == "nade",
2131         {
2132                 antilag_record(it, it, altime);
2133         });
2134         systems_update();
2135         IL_ENDFRAME();
2136 }
2137
2138
2139 /*
2140  * RedirectionThink:
2141  * returns true if redirecting
2142  */
2143 float redirection_timeout;
2144 float redirection_nextthink;
2145 float RedirectionThink()
2146 {
2147         float clients_found;
2148
2149         if(redirection_target == "")
2150                 return false;
2151
2152         if(!redirection_timeout)
2153         {
2154                 cvar_set("sv_public", "-2");
2155                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2156                 if(redirection_target == "self")
2157                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2158                 else
2159                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2160         }
2161
2162         if(time < redirection_nextthink)
2163                 return true;
2164
2165         redirection_nextthink = time + 1;
2166
2167         clients_found = 0;
2168         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2169                 // TODO add timer
2170                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2171                 if(redirection_target == "self")
2172                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2173                 else
2174                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2175                 ++clients_found;
2176         });
2177
2178         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2179
2180         if(time > redirection_timeout || clients_found == 0)
2181                 localcmd("\nwait; wait; wait; quit\n");
2182
2183         return true;
2184 }
2185
2186 void RestoreGame()
2187 {
2188         // Loaded from a save game
2189         // some things then break, so let's work around them...
2190
2191         // Progs DB (capture records)
2192         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2193
2194         // Mapinfo
2195         MapInfo_Shutdown();
2196         MapInfo_Enumerate();
2197         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2198         WeaponStats_Init();
2199
2200         TargetMusic_RestoreGame();
2201 }
2202
2203 void Shutdown()
2204 {
2205         game_stopped = 2;
2206
2207         if(world_initialized > 0)
2208         {
2209                 world_initialized = 0;
2210                 LOG_TRACE("Saving persistent data...");
2211                 Ban_SaveBans();
2212
2213                 // playerstats with unfinished match
2214                 PlayerStats_GameReport(false);
2215
2216                 if(!cheatcount_total)
2217                 {
2218                         if(autocvar_sv_db_saveasdump)
2219                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2220                         else
2221                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2222                 }
2223                 if(autocvar_developer)
2224                 {
2225                         if(autocvar_sv_db_saveasdump)
2226                                 db_dump(TemporaryDB, "server-temp.db");
2227                         else
2228                                 db_save(TemporaryDB, "server-temp.db");
2229                 }
2230                 CheatShutdown(); // must be after cheatcount check
2231                 db_close(ServerProgsDB);
2232                 db_close(TemporaryDB);
2233                 LOG_TRACE("Saving persistent data... done!");
2234                 // tell the bot system the game is ending now
2235                 bot_endgame();
2236
2237                 WeaponStats_Shutdown();
2238                 MapInfo_Shutdown();
2239         }
2240         else if(world_initialized == 0)
2241         {
2242                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2243         }
2244         else
2245         {
2246                 __init_dedicated_server_shutdown();
2247         }
2248 }