qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312
 313                 // these can contain player IDs, so better hide
 314                 BADPREFIX("g_forced_team_");
 315
 316                 // mapinfo
 317                 BADCVAR("fraglimit");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_assault");
 320                 BADCVAR("g_ca");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_cts");
 323                 BADCVAR("g_dm");
 324                 BADCVAR("g_domination");
 325                 BADCVAR("g_domination_default_teams");
 326                 BADCVAR("g_freezetag");
 327                 BADCVAR("g_keepaway");
 328                 BADCVAR("g_keyhunt");
 329                 BADCVAR("g_keyhunt_teams");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_lms");
 332                 BADCVAR("g_nexball");
 333                 BADCVAR("g_onslaught");
 334                 BADCVAR("g_race");
 335                 BADCVAR("g_race_qualifying_timelimit");
 336                 BADCVAR("g_runematch");
 337                 BADCVAR("g_tdm");
 338                 BADCVAR("g_tdm_teams");
 339                 BADCVAR("leadlimit");
 340                 BADCVAR("nextmap");
 341                 BADCVAR("teamplay");
 342                 BADCVAR("timelimit");
 343
 344                 // long
 345                 BADCVAR("hostname");
 346                 BADCVAR("g_maplist");
 347                 BADCVAR("g_maplist_mostrecent");
 348                 BADCVAR("sv_motd");
 349
 350                 v = cvar_string(k);
 351                 d = cvar_defstring(k);
 352                 if(v == d)
 353                         continue;
 354
 355                 if(adding)
 356                 {
 357                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 358                         if(strlen(cvar_changes) > 16384)
 359                         {
 360                                 cvar_changes = "// too many settings have been changed to show them here\n";
 361                                 adding = 0;
 362                         }
 363                 }
 364
 365                 // now check if the changes are actually gameplay relevant
 366
 367                 // does nothing visible
 368                 BADCVAR("captureleadlimit_override");
 369                 BADCVAR("g_arena_point_leadlimit");
 370                 BADCVAR("g_balance_kill_delay");
 371                 BADCVAR("g_ca_point_leadlimit");
 372                 BADCVAR("g_ctf_captimerecord_always");
 373                 BADCVAR("g_ctf_capture_leadlimit");
 374                 BADCVAR("g_ctf_flag_capture_effects");
 375                 BADCVAR("g_ctf_flag_glowtrails");
 376                 BADCVAR("g_ctf_flag_pickup_effects");
 377                 BADCVAR("g_domination_point_leadlimit");
 378                 BADCVAR("g_forced_respawn");
 379                 BADCVAR("g_keyhunt_point_leadlimit");
 380                 BADCVAR("g_nexball_goalleadlimit");
 381                 BADCVAR("g_runematch_point_leadlimit");
 382                 BADCVAR("leadlimit_and_fraglimit");
 383                 BADCVAR("leadlimit_override");
 384                 BADCVAR("pausable");
 385                 BADCVAR("sv_checkforpacketsduringsleep");
 386                 BADCVAR("sv_timeout");
 387                 BADCVAR("welcome_message_time");
 388                 BADPREFIX("crypto_");
 389                 BADPREFIX("g_chat_");
 390                 BADPREFIX("g_ctf_captimerecord_");
 391                 BADPREFIX("g_maplist_votable_");
 392                 BADPREFIX("net_");
 393                 BADPREFIX("prvm_");
 394                 BADPREFIX("skill_");
 395                 BADPREFIX("sv_fraginfo_");
 396                 BADPREFIX("sv_maxidle_");
 397                 BADPREFIX("sv_vote_");
 398                 BADPREFIX("timelimit_");
 399                 BADCVAR("gameversion");
 400                 BADPREFIX("gameversion_");
 401
 402                 // allowed changes to server admins (please sync this to server.cfg)
 403                 // vi commands:
 404                 //   :/"impure"/,$d
 405                 //   :g!,^\/\/[^ /],d
 406                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 407                 //   :%!sort
 408                 // yes, this does contain some redundant stuff, don't really care
 409                 BADCVAR("bot_number");
 410                 BADCVAR("bot_prefix");
 411                 BADCVAR("bot_suffix");
 412                 BADCVAR("bot_config_file");
 413                 BADCVAR("capturelimit_override");
 414                 BADCVAR("fraglimit_override");
 415                 BADCVAR("gametype");
 416                 BADCVAR("g_antilag");
 417                 BADCVAR("g_balance_teams");
 418                 BADCVAR("g_balance_teams_force");
 419                 BADCVAR("g_ban_sync_trusted_servers");
 420                 BADCVAR("g_ban_sync_uri");
 421                 BADCVAR("g_ctf_capture_limit");
 422                 BADCVAR("g_ctf_ignore_frags");
 423                 BADCVAR("g_ctf_win_mode");
 424                 BADCVAR("g_domination_point_limit");
 425                 BADCVAR("g_friendlyfire");
 426                 BADCVAR("g_fullbrightitems");
 427                 BADCVAR("g_fullbrightplayers");
 428                 BADCVAR("g_keyhunt_point_limit");
 429                 BADCVAR("g_keyhunt_teams_override");
 430                 BADCVAR("g_lms_lives_override");
 431                 BADCVAR("g_maplist");
 432                 BADCVAR("g_maplist_check_waypoints");
 433                 BADCVAR("g_maplist_mostrecent_count");
 434                 BADCVAR("g_maplist_shuffle");
 435                 BADCVAR("g_maplist_votable");
 436                 BADCVAR("g_maplist_votable_abstain");
 437                 BADCVAR("g_maplist_votable_nodetail");
 438                 BADCVAR("g_maplist_votable_suggestions");
 439                 BADCVAR("g_maxplayers");
 440                 BADCVAR("g_minstagib");
 441                 BADCVAR("g_mirrordamage");
 442                 BADCVAR("g_nexball_goallimit");
 443                 BADCVAR("g_runematch_point_limit");
 444                 BADCVAR("g_start_delay");
 445                 BADCVAR("g_warmup");
 446                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 447                 BADCVAR("hostname");
 448                 BADCVAR("log_file");
 449                 BADCVAR("maxplayers");
 450                 BADCVAR("minplayers");
 451                 BADCVAR("net_address");
 452                 BADCVAR("port");
 453                 BADCVAR("rcon_password");
 454                 BADCVAR("rcon_restricted_commands");
 455                 BADCVAR("rcon_restricted_password");
 456                 BADCVAR("skill");
 457                 BADCVAR("sv_adminnick");
 458                 BADCVAR("sv_autoscreenshot");
 459                 BADCVAR("sv_curl_defaulturl");
 460                 BADCVAR("sv_defaultcharacter");
 461                 BADCVAR("sv_defaultplayercolors");
 462                 BADCVAR("sv_defaultplayermodel");
 463                 BADCVAR("sv_defaultplayerskin");
 464                 BADCVAR("sv_maxidle");
 465                 BADCVAR("sv_maxrate");
 466                 BADCVAR("sv_motd");
 467                 BADCVAR("sv_public");
 468                 BADCVAR("sv_ready_restart");
 469                 BADCVAR("sv_status_privacy");
 470                 BADCVAR("sv_vote_call");
 471                 BADCVAR("sv_vote_commands");
 472                 BADCVAR("sv_vote_majority_factor");
 473                 BADCVAR("sv_vote_master");
 474                 BADCVAR("sv_vote_master_commands");
 475                 BADCVAR("sv_vote_master_password");
 476                 BADCVAR("sv_vote_simple_majority_factor");
 477                 BADCVAR("sys_ticrate");
 478                 BADCVAR("teamplay_mode");
 479                 BADCVAR("timelimit_override");
 480                 BADPREFIX("g_warmup_");
 481
 482                 if(autocvar_g_minstagib)
 483                 {
 484                         BADCVAR("g_grappling_hook");
 485                         BADCVAR("g_jetpack");
 486                 }
 487 #undef BADPREFIX
 488 #undef BADCVAR
 489
 490                 if(pureadding)
 491                 {
 492                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 493                         if(strlen(cvar_purechanges) > 16384)
 494                         {
 495                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 496                                 pureadding = 0;
 497                         }
 498                 }
 499                 ++cvar_purechanges_count;
 500                 // WARNING: this variable is used for the server list
 501                 // NEVER dare to skip this code!
 502                 // Hacks to intentionally appearing as "pure server" even though you DO have
 503                 // modified settings may be punished by removal from the server list.
 504                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 505                 // though.
 506         }
 507         buf_del(h);
 508         if(cvar_changes == "")
 509                 cvar_changes = "// this server runs at default server settings\n";
 510         else
 511                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 512         cvar_changes = strzone(cvar_changes);
 513         if(cvar_purechanges == "")
 514                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 515         else
 516                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 517         cvar_purechanges = strzone(cvar_purechanges);
 518 }
 519
 520 void detect_maptype()
 521 {
 522 #if 0
 523         vector o, v;
 524         float i;
 525
 526         for(;;)
 527         {
 528                 o = world.mins;
 529                 o_x += random() * (world.maxs_x - world.mins_x);
 530                 o_y += random() * (world.maxs_y - world.mins_y);
 531                 o_z += random() * (world.maxs_z - world.mins_z);
 532
 533                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 534                 if(trace_fraction == 1)
 535                         continue;
 536
 537                 v = trace_endpos;
 538
 539                 for(i = 0; i < 64; i += 4)
 540                 {
 541                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 542         if(trace_fraction == 1)
 543                 continue;
 544                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 545                 }
 546
 547                 break;
 548         }
 549 #endif
 550 }
 551
 552 entity randomseed;
 553 float RandomSeed_Send(entity to, float sf)
 554 {
 555         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 556         WriteShort(MSG_ENTITY, self.cnt);
 557         return TRUE;
 558 }
 559 void RandomSeed_Think()
 560 {
 561         self.cnt = bound(0, floor(random() * 65536), 65535);
 562         self.nextthink = time + 5;
 563
 564         self.SendFlags |= 1;
 565 }
 566 void RandomSeed_Spawn()
 567 {
 568         randomseed = spawn();
 569         randomseed.think = RandomSeed_Think;
 570         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 571
 572         entity oldself;
 573         oldself = self;
 574         self = randomseed;
 575         self.think(); // sets random seed and nextthink
 576         self = oldself;
 577 }
 578
 579 void spawnfunc___init_dedicated_server(void)
 580 {
 581         // handler for _init/_init map (only for dedicated server initialization)
 582
 583         world_initialized = -1; // don't complain
 584         cvar = cvar_normal;
 585         cvar_string = cvar_string_normal;
 586         cvar_set = cvar_set_normal;
 587
 588         remove = remove_unsafely;
 589
 590         entity e;
 591         e = spawn();
 592         e.think = GotoFirstMap;
 593         e.nextthink = time; // this is usually 1 at this point
 594
 595         e = spawn();
 596         e.classname = "info_player_deathmatch"; // safeguard against player joining
 597
 598         self.classname = "worldspawn"; // safeguard against various stuff ;)
 599
 600         MapInfo_Enumerate();
 601         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 602 }
 603
 604 void Map_MarkAsRecent(string m);
 605 float world_already_spawned;
 606 void RegisterWeapons();
 607 void Nagger_Init();
 608 void ClientInit_Spawn();
 609 void WeaponStats_Init();
 610 void WeaponStats_Shutdown();
 611 void spawnfunc_worldspawn (void)
 612 {
 613         float fd, l, i, j, n;
 614         string s, col;
 615
 616         cvar = cvar_normal;
 617         cvar_string = cvar_string_normal;
 618         cvar_set = cvar_set_normal;
 619
 620         if(world_already_spawned)
 621                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 622         world_already_spawned = TRUE;
 623
 624         remove = remove_safely; // during spawning, watch what you remove!
 625
 626         check_unacceptable_compiler_bugs();
 627
 628         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 629
 630         compressShortVector_init();
 631
 632         allowed_to_spawn = TRUE;
 633
 634         entity head;
 635         head = nextent(world);
 636         maxclients = 0;
 637         while(head)
 638         {
 639                 ++maxclients;
 640                 head = nextent(head);
 641         }
 642
 643         // needs to be done so early as they would still spawn
 644         RegisterWeapons();
 645
 646         ServerProgsDB = db_load("server.db");
 647
 648         TemporaryDB = db_create();
 649
 650         // 0 normal
 651         lightstyle(0, "m");
 652
 653         // 1 FLICKER (first variety)
 654         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 655
 656         // 2 SLOW STRONG PULSE
 657         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 658
 659         // 3 CANDLE (first variety)
 660         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 661
 662         // 4 FAST STROBE
 663         lightstyle(4, "mamamamamama");
 664
 665         // 5 GENTLE PULSE 1
 666         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 667
 668         // 6 FLICKER (second variety)
 669         lightstyle(6, "nmonqnmomnmomomno");
 670
 671         // 7 CANDLE (second variety)
 672         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 673
 674         // 8 CANDLE (third variety)
 675         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 676
 677         // 9 SLOW STROBE (fourth variety)
 678         lightstyle(9, "aaaaaaaazzzzzzzz");
 679
 680         // 10 FLUORESCENT FLICKER
 681         lightstyle(10, "mmamammmmammamamaaamammma");
 682
 683         // 11 SLOW PULSE NOT FADE TO BLACK
 684         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 685
 686         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 687
 688         // 63 testing
 689         lightstyle(63, "a");
 690
 691         if(autocvar_g_campaign)
 692                 CampaignPreInit();
 693
 694         Map_MarkAsRecent(mapname);
 695
 696         precache_model ("null"); // we need this one before InitGameplayMode
 697         InitGameplayMode();
 698         readlevelcvars();
 699         GrappleHookInit();
 700         ElectroInit();
 701         LaserInit();
 702
 703         player_count = 0;
 704         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 705         if(bot_waypoints_for_items == 1)
 706                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 707                         bot_waypoints_for_items = 0;
 708
 709         precache();
 710
 711         WaypointSprite_Init();
 712
 713         //if (g_domination)
 714         //      dom_init();
 715
 716         GameLogInit(); // prepare everything
 717         if(autocvar_sv_eventlog)
 718         {
 719                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 720                 matchid = strzone(s);
 721
 722                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 723                 s = ":gameinfo:mutators:LIST";
 724
 725                 ret_string = s;
 726                 MUTATOR_CALLHOOK(BuildMutatorsString);
 727                 s = ret_string;
 728
 729                 // simple, probably not good in the mutator system
 730                 if(autocvar_g_grappling_hook)
 731                         s = strcat(s, ":grappling_hook");
 732
 733                 // initialiation stuff, not good in the mutator system
 734                 if(!autocvar_g_use_ammunition)
 735                         s = strcat(s, ":no_use_ammunition");
 736
 737                 // initialiation stuff, not good in the mutator system
 738                 if(!autocvar_g_pickup_items)
 739                         s = strcat(s, ":no_pickup_items");
 740
 741                 // initialiation stuff, not good in the mutator system
 742                 if(autocvar_g_weaponarena != "0")
 743                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 744
 745                 // TODO to mutator system
 746                 if(autocvar_g_norecoil)
 747                         s = strcat(s, ":norecoil");
 748
 749                 // TODO to mutator system
 750                 if(autocvar_g_midair)
 751                         s = strcat(s, ":midair");
 752
 753                 // TODO to mutator system
 754                 if(autocvar_g_minstagib)
 755                         s = strcat(s, ":minstagib");
 756
 757                 GameLogEcho(s);
 758                 GameLogEcho(":gameinfo:end");
 759         }
 760         else
 761                 matchid = strzone(ftos(random()));
 762
 763         cvar_set("nextmap", "");
 764
 765         SetDefaultAlpha();
 766
 767         if(autocvar_g_campaign)
 768                 CampaignPostInit();
 769
 770         fteqcc_testbugs();
 771
 772         Ban_LoadBans();
 773
 774         MapInfo_Enumerate();
 775         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 776
 777         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 778         {
 779                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 780                 if(fd != -1)
 781                 {
 782                         while((s = fgets(fd)))
 783                         {
 784                                 l = tokenize_console(s);
 785                                 if(l < 2)
 786                                         continue;
 787                                 if(argv(0) == "cd")
 788                                 {
 789                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 790                                         print("  cdtrack ", argv(2), "\n");
 791                                 }
 792                                 else if(argv(0) == "fog")
 793                                 {
 794                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 795                                         print("  \"fog\" \"", s, "\"\n");
 796                                 }
 797                                 else if(argv(0) == "set")
 798                                 {
 799                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 800                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 801                                 }
 802                                 else if(argv(0) != "//")
 803                                 {
 804                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 805                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 806                                 }
 807                         }
 808                         fclose(fd);
 809                 }
 810         }
 811
 812         WeaponStats_Init();
 813
 814         addstat(STAT_WEAPONS, AS_INT, weapons);
 815         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 816         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 817         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 818         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 819         Nagger_Init();
 820
 821         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 822         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 823         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 824         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 825         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 826         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 827         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 828         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 829         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 830         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 831         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 832         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 833
 834         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 835         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 836
 837         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 838
 839         if(g_ca || g_freezetag)
 840         {
 841                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 842                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 843                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 844                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 845         }
 846         if(g_freezetag)
 847         {
 848                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 849                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 850         }
 851
 852         // g_movementspeed hack
 853         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 854         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 855         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 856         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 857
 858         // secrets
 859         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 860         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 861
 862         next_pingtime = time + 5;
 863
 864         detect_maptype();
 865
 866         lsmaps_reply = "^7Maps available: ";
 867         lsnewmaps_reply = "^7Maps without a record set: ";
 868         for(i = 0, j = 0; i < MapInfo_count; ++i)
 869         {
 870                 if(MapInfo_Get_ByID(i))
 871                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 872                         {
 873                                 if(mod(i, 2))
 874                                         col = "^2";
 875                                 else
 876                                         col = "^3";
 877                                 ++j;
 878                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 879                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 880                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 881                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 882                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 883                         }
 884         }
 885         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 886         if (!g_race && !g_cts)
 887                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 888         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 889
 890         maplist_reply = "^7Maps in list: ";
 891         n = tokenize_console(autocvar_g_maplist);
 892         for(i = 0, j = 0; i < n; ++i)
 893         {
 894                 if(MapInfo_CheckMap(argv(i)))
 895                 {
 896                         if(mod(j, 2))
 897                                 col = "^2";
 898                         else
 899                                 col = "^3";
 900                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 901                         ++j;
 902                 }
 903         }
 904         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 905         MapInfo_ClearTemps();
 906
 907         for(i = 0; i < 10; ++i)
 908         {
 909                 records_reply[i] = strzone(getrecords(i));
 910         }
 911         if(g_cts)
 912                 ladder_reply = strzone(getladder());
 913
 914         rankings_reply = strzone(getrankings());
 915
 916         ClientInit_Spawn();
 917         RandomSeed_Spawn();
 918         PingPLReport_Spawn();
 919
 920         CheatInit();
 921
 922         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 923
 924         // fill sv_curl_serverpackages from .serverpackage files
 925         if(autocvar_sv_curl_serverpackages_auto)
 926         {
 927                 s = "";
 928                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 929                 for(i = 0; i < n; ++i)
 930                         if(substring(argv(i), -14, -1) != ".serverpackage")
 931                                 s = strcat(s, " ", argv(i));
 932                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 933                 if(fd >= 0)
 934                 {
 935                         j = search_getsize(fd);
 936                         for(i = 0; i < j; ++i)
 937                                 s = strcat(s, " ", search_getfilename(fd, i));
 938                         search_end(fd);
 939                 }
 940                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 941         }
 942
 943         PlayerStats_Init();
 944
 945         world_initialized = 1;
 946 }
 947
 948 void spawnfunc_light (void)
 949 {
 950         //makestatic (self); // Who the f___ did that?
 951         remove(self);
 952 }
 953
 954 string GetGametype()
 955 {
 956         return GametypeNameFromType(game);
 957 }
 958
 959 string getmapname_stored;
 960 string GetMapname()
 961 {
 962         return mapname;
 963 }
 964
 965 float Map_Count, Map_Current;
 966 string Map_Current_Name;
 967
 968 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 969 float GetMaplistPosition()
 970 {
 971         float pos, idx;
 972         string map;
 973
 974         map = GetMapname();
 975         idx = autocvar_g_maplist_index;
 976
 977         if(idx >= 0)
 978                 if(idx < Map_Count)
 979                         if(map == argv(idx))
 980                                 return idx;
 981
 982         for(pos = 0; pos < Map_Count; ++pos)
 983                 if(map == argv(pos))
 984                         return pos;
 985
 986         // resume normal maplist rotation if current map is not in g_maplist
 987         return idx;
 988 }
 989
 990 float MapHasRightSize(string map)
 991 {
 992         float fh;
 993         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 994         if(autocvar_g_maplist_check_waypoints)
 995         {
 996                 dprint("checkwp "); dprint(map);
 997                 if(!fexists(strcat("maps/", map, ".waypoints")))
 998                 {
 999                         dprint(": no waypoints\n");
1000                         return FALSE;
1001                 }
1002                 dprint(": has waypoints\n");
1003         }
1004
1005         // open map size restriction file
1006         dprint("opensize "); dprint(map);
1007         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1008         if(fh >= 0)
1009         {
1010                 float mapmin, mapmax;
1011                 dprint(": ok, ");
1012                 mapmin = stof(fgets(fh));
1013                 mapmax = stof(fgets(fh));
1014                 fclose(fh);
1015                 if(player_count < mapmin)
1016                 {
1017                         dprint("not enough\n");
1018                         return FALSE;
1019                 }
1020                 if(player_count > mapmax)
1021                 {
1022                         dprint("too many\n");
1023                         return FALSE;
1024                 }
1025                 dprint("right size\n");
1026                 return TRUE;
1027         }
1028         dprint(": not found\n");
1029         return TRUE;
1030 }
1031
1032 string Map_Filename(float position)
1033 {
1034         return strcat("maps/", argv(position), ".bsp");
1035 }
1036
1037 string strwords(string s, float w)
1038 {
1039         float endpos;
1040         for(endpos = 0; w && endpos >= 0; --w)
1041                 endpos = strstrofs(s, " ", endpos + 1);
1042         if(endpos < 0)
1043                 return s;
1044         else
1045                 return substring(s, 0, endpos);
1046 }
1047
1048 float strhasword(string s, string w)
1049 {
1050         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1051 }
1052
1053 void Map_MarkAsRecent(string m)
1054 {
1055         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1056 }
1057
1058 float Map_IsRecent(string m)
1059 {
1060         return strhasword(autocvar_g_maplist_mostrecent, m);
1061 }
1062
1063 float Map_Check(float position, float pass)
1064 {
1065         string filename;
1066         string map_next;
1067         map_next = argv(position);
1068         if(pass <= 1)
1069         {
1070                 if(Map_IsRecent(map_next))
1071                         return 0;
1072         }
1073         filename = Map_Filename(position);
1074         if(MapInfo_CheckMap(map_next))
1075         {
1076                 if(pass == 2)
1077                         return 1;
1078                 if(MapHasRightSize(map_next))
1079                         return 1;
1080                 return 0;
1081         }
1082         else
1083                 dprint( "Couldn't select '", filename, "'..\n" );
1084
1085         return 0;
1086 }
1087
1088 void Map_Goto_SetStr(string nextmapname)
1089 {
1090         if(getmapname_stored != "")
1091                 strunzone(getmapname_stored);
1092         if(nextmapname == "")
1093                 getmapname_stored = "";
1094         else
1095                 getmapname_stored = strzone(nextmapname);
1096 }
1097
1098 void Map_Goto_SetFloat(float position)
1099 {
1100         cvar_set("g_maplist_index", ftos(position));
1101         Map_Goto_SetStr(argv(position));
1102 }
1103
1104 void GameResetCfg()
1105 {
1106         // settings persist, except...
1107         localcmd("\nsettemp_restore\n");
1108 }
1109
1110 void Map_Goto()
1111 {
1112         GameResetCfg();
1113         MapInfo_LoadMap(getmapname_stored);
1114 }
1115
1116 // return codes of map selectors:
1117 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1118 //   -2 = permanent failure
1119 float() MaplistMethod_Iterate = // usual method
1120 {
1121         float pass, i;
1122
1123         for(pass = 1; pass <= 2; ++pass)
1124         {
1125                 for(i = 1; i < Map_Count; ++i)
1126                 {
1127                         float mapindex;
1128                         mapindex = mod(i + Map_Current, Map_Count);
1129                         if(Map_Check(mapindex, pass))
1130                                 return mapindex;
1131                 }
1132         }
1133         return -1;
1134 }
1135
1136 float() MaplistMethod_Repeat = // fallback method
1137 {
1138         if(Map_Check(Map_Current, 2))
1139                 return Map_Current;
1140         return -2;
1141 }
1142
1143 float() MaplistMethod_Random = // random map selection
1144 {
1145         float i, imax;
1146
1147         imax = 42;
1148
1149         for(i = 0; i <= imax; ++i)
1150         {
1151                 float mapindex;
1152                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1153                 if(Map_Check(mapindex, 1))
1154                         return mapindex;
1155         }
1156         return -1;
1157 }
1158
1159 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1160 // the exponent sets a bias on the map selection:
1161 // the higher the exponent, the less likely "shortly repeated" same maps are
1162 {
1163         float i, j, imax, insertpos;
1164
1165         imax = 42;
1166
1167         for(i = 0; i <= imax; ++i)
1168         {
1169                 string newlist;
1170
1171                 // now reinsert this at another position
1172                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1173                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1174                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1175                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1176
1177                 // insert the current map there
1178                 newlist = "";
1179                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1180                         newlist = strcat(newlist, " ", argv(j));
1181                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1182                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1183                         newlist = strcat(newlist, " ", argv(j));
1184                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1185                 cvar_set("g_maplist", newlist);
1186                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1187
1188                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1189                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1190                 if(Map_Check(Map_Current, 1))
1191                         return Map_Current;
1192         }
1193         return -1;
1194 }
1195
1196 void Maplist_Init()
1197 {
1198         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1199         if(Map_Count == 0)
1200         {
1201                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1202                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1203                 if(autocvar_g_maplist_shuffle)
1204                         ShuffleMaplist();
1205                 localcmd("\nmenu_cmd sync\n");
1206                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1207         }
1208         if(Map_Count == 0)
1209                 error("empty maplist, cannot select a new map");
1210         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1211
1212         if(Map_Current_Name)
1213                 strunzone(Map_Current_Name);
1214         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1215         // this may or may not be correct, but who cares, in the worst case a map
1216         // isn't chosen in the first pass that should have been
1217 }
1218
1219 string GetNextMap()
1220 {
1221         float nextMap;
1222
1223         Maplist_Init();
1224         nextMap = -1;
1225
1226         if(nextMap == -1)
1227                 if(autocvar_g_maplist_shuffle > 0)
1228                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1229
1230         if(nextMap == -1)
1231                 if(autocvar_g_maplist_selectrandom)
1232                         nextMap = MaplistMethod_Random();
1233
1234         if(nextMap == -1)
1235                 nextMap = MaplistMethod_Iterate();
1236
1237         if(nextMap == -1)
1238                 nextMap = MaplistMethod_Repeat();
1239
1240         if(nextMap >= 0)
1241         {
1242                 Map_Goto_SetFloat(nextMap);
1243                 return getmapname_stored;
1244         }
1245
1246         return "";
1247 }
1248
1249 float DoNextMapOverride()
1250 {
1251         if(autocvar_g_campaign)
1252         {
1253                 CampaignPostIntermission();
1254                 alreadychangedlevel = TRUE;
1255                 return TRUE;
1256         }
1257         if(autocvar_quit_when_empty)
1258         {
1259                 if(player_count <= currentbots)
1260                 {
1261                         localcmd("quit\n");
1262                         alreadychangedlevel = TRUE;
1263                         return TRUE;
1264                 }
1265         }
1266         if(autocvar_quit_and_redirect != "")
1267         {
1268                 redirection_target = strzone(autocvar_quit_and_redirect);
1269                 alreadychangedlevel = TRUE;
1270                 return TRUE;
1271         }
1272         if (autocvar_samelevel) // if samelevel is set, stay on same level
1273         {
1274                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1275                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1276                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1277                 localcmd("restart\n");
1278                 //changelevel (mapname);
1279                 alreadychangedlevel = TRUE;
1280                 return TRUE;
1281         }
1282         if(autocvar_nextmap != "")
1283                 if(MapInfo_CheckMap(autocvar_nextmap))
1284                 {
1285                         Map_Goto_SetStr(autocvar_nextmap);
1286                         Map_Goto();
1287                         alreadychangedlevel = TRUE;
1288                         return TRUE;
1289                 }
1290         if(autocvar_lastlevel)
1291         {
1292                 GameResetCfg();
1293                 localcmd("set lastlevel 0\ntogglemenu\n");
1294                 alreadychangedlevel = TRUE;
1295                 return TRUE;
1296         }
1297         return FALSE;
1298 }
1299
1300 void GotoNextMap()
1301 {
1302         //string nextmap;
1303         //float n, nummaps;
1304         //string s;
1305         if (alreadychangedlevel)
1306                 return;
1307         alreadychangedlevel = TRUE;
1308
1309         {
1310                 string nextMap;
1311                 float allowReset;
1312
1313                 for(allowReset = 1; allowReset >= 0; --allowReset)
1314                 {
1315                         nextMap = GetNextMap();
1316                         if(nextMap != "")
1317                                 break;
1318
1319                         if(allowReset)
1320                         {
1321                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1322                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1323                                 if(autocvar_g_maplist_shuffle)
1324                                         ShuffleMaplist();
1325                                 localcmd("\nmenu_cmd sync\n");
1326                         }
1327                         else
1328                         {
1329                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1330                         }
1331                 }
1332                 Map_Goto();
1333         }
1334 }
1335
1336
1337 /*
1338 ============
1339 IntermissionThink
1340
1341 When the player presses attack or jump, change to the next level
1342 ============
1343 */
1344 .float autoscreenshot;
1345 void() MapVote_Start;
1346 void() MapVote_Think;
1347 float mapvote_initialized;
1348 void IntermissionThink()
1349 {
1350         FixIntermissionClient(self);
1351
1352         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1353                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1354         {
1355                 self.autoscreenshot = -1;
1356                 if(clienttype(self) == CLIENTTYPE_REAL)
1357                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1358                 return;
1359         }
1360
1361         if (time < intermission_exittime)
1362                 return;
1363
1364         if(!mapvote_initialized)
1365                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1366                         return;
1367
1368         MapVote_Start();
1369 }
1370
1371 /*
1372 ============
1373 FindIntermission
1374
1375 Returns the entity to view from
1376 ============
1377 */
1378 /*
1379 entity FindIntermission()
1380 {
1381         local   entity spot;
1382         local   float cyc;
1383
1384 // look for info_intermission first
1385         spot = find (world, classname, "info_intermission");
1386         if (spot)
1387         {       // pick a random one
1388                 cyc = random() * 4;
1389                 while (cyc > 1)
1390                 {
1391                         spot = find (spot, classname, "info_intermission");
1392                         if (!spot)
1393                                 spot = find (spot, classname, "info_intermission");
1394                         cyc = cyc - 1;
1395                 }
1396                 return spot;
1397         }
1398
1399 // then look for the start position
1400         spot = find (world, classname, "info_player_start");
1401         if (spot)
1402                 return spot;
1403
1404 // testinfo_player_start is only found in regioned levels
1405         spot = find (world, classname, "testplayerstart");
1406         if (spot)
1407                 return spot;
1408
1409 // then look for the start position
1410         spot = find (world, classname, "info_player_deathmatch");
1411         if (spot)
1412                 return spot;
1413
1414         //objerror ("FindIntermission: no spot");
1415         return world;
1416 }
1417 */
1418
1419 /*
1420 ===============================================================================
1421
1422 RULES
1423
1424 ===============================================================================
1425 */
1426
1427 void DumpStats(float final)
1428 {
1429         float file;
1430         string s;
1431         float to_console;
1432         float to_eventlog;
1433         float to_file;
1434         float i;
1435
1436         to_console = autocvar_sv_logscores_console;
1437         to_eventlog = autocvar_sv_eventlog;
1438         to_file = autocvar_sv_logscores_file;
1439
1440         if(!final)
1441         {
1442                 to_console = TRUE; // always print printstats replies
1443                 to_eventlog = FALSE; // but never print them to the event log
1444         }
1445
1446         if(to_eventlog)
1447                 if(autocvar_sv_eventlog_console)
1448                         to_console = FALSE; // otherwise we get the output twice
1449
1450         if(final)
1451                 s = ":scores:";
1452         else
1453                 s = ":status:";
1454         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1455
1456         if(to_console)
1457                 print(s, "\n");
1458         if(to_eventlog)
1459                 GameLogEcho(s);
1460         if(to_file)
1461         {
1462                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1463                 if(file == -1)
1464                         to_file = FALSE;
1465                 else
1466                         fputs(file, strcat(s, "\n"));
1467         }
1468
1469         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1470         if(to_console)
1471                 print(s, "\n");
1472         if(to_eventlog)
1473                 GameLogEcho(s);
1474         if(to_file)
1475                 fputs(file, strcat(s, "\n"));
1476
1477         FOR_EACH_CLIENT(other)
1478         {
1479                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1480                 {
1481                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1482                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1483                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1484                                 s = strcat(s, ftos(other.team), ":");
1485                         else
1486                                 s = strcat(s, "spectator:");
1487
1488                         if(to_console)
1489                                 print(s, other.netname, "\n");
1490                         if(to_eventlog)
1491                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1492                         if(to_file)
1493                                 fputs(file, strcat(s, other.netname, "\n"));
1494                 }
1495         }
1496
1497         if(teamplay)
1498         {
1499                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1500                 if(to_console)
1501                         print(s, "\n");
1502                 if(to_eventlog)
1503                         GameLogEcho(s);
1504                 if(to_file)
1505                         fputs(file, strcat(s, "\n"));
1506
1507                 for(i = 1; i < 16; ++i)
1508                 {
1509                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1510                         s = strcat(s, ":", ftos(i));
1511                         if(to_console)
1512                                 print(s, "\n");
1513                         if(to_eventlog)
1514                                 GameLogEcho(s);
1515                         if(to_file)
1516                                 fputs(file, strcat(s, "\n"));
1517                 }
1518         }
1519
1520         if(to_console)
1521                 print(":end\n");
1522         if(to_eventlog)
1523                 GameLogEcho(":end");
1524         if(to_file)
1525         {
1526                 fputs(file, ":end\n");
1527                 fclose(file);
1528         }
1529 }
1530
1531 void FixIntermissionClient(entity e)
1532 {
1533         string s;
1534         if(!e.autoscreenshot) // initial call
1535         {
1536                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1537                 e.health = -2342;
1538                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1539                 e.solid = SOLID_NOT;
1540                 e.movetype = MOVETYPE_NONE;
1541                 e.takedamage = DAMAGE_NO;
1542                 if(e.weaponentity)
1543                 {
1544                         e.weaponentity.effects = EF_NODRAW;
1545                         if (e.weaponentity.weaponentity)
1546                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1547                 }
1548                 if(clienttype(e) == CLIENTTYPE_REAL)
1549                 {
1550                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1551                         s = autocvar_sv_intermission_cdtrack;
1552                         if(s != "")
1553                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1554                         msg_entity = e;
1555                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1556                 }
1557         }
1558 }
1559
1560
1561 /*
1562 go to the next level for deathmatch
1563 only called if a time or frag limit has expired
1564 */
1565 void NextLevel()
1566 {
1567         gameover = TRUE;
1568
1569         intermission_running = 1;
1570
1571 // enforce a wait time before allowing changelevel
1572         if(player_count > 0)
1573                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1574         else
1575                 intermission_exittime = -1;
1576
1577         /*
1578         WriteByte (MSG_ALL, SVC_CDTRACK);
1579         WriteByte (MSG_ALL, 3);
1580         WriteByte (MSG_ALL, 3);
1581         // done in FixIntermission
1582         */
1583
1584         //pos = FindIntermission ();
1585
1586         VoteReset();
1587
1588         DumpStats(TRUE);
1589
1590         // send statistics
1591         entity e;
1592         PlayerStats_EndMatch(1);
1593         FOR_EACH_CLIENT(e)
1594                 PlayerStats_AddGlobalInfo(e);
1595         PlayerStats_Shutdown();
1596         WeaponStats_Shutdown();
1597
1598         if(autocvar_sv_eventlog)
1599                 GameLogEcho(":gameover");
1600
1601         GameLogClose();
1602
1603         FOR_EACH_PLAYER(other) {
1604                 FixIntermissionClient(other);
1605                 if(other.winning)
1606                         bprint(other.netname, " ^7wins.\n");
1607         }
1608
1609         if(autocvar_g_campaign)
1610                 CampaignPreIntermission();
1611
1612         localcmd("\nsv_hook_gameend\n");
1613 }
1614
1615 /*
1616 ============
1617 CheckRules_Player
1618
1619 Exit deathmatch games upon conditions
1620 ============
1621 */
1622 void CheckRules_Player()
1623 {
1624         if (gameover)   // someone else quit the game already
1625                 return;
1626
1627         if(self.deadflag == DEAD_NO)
1628                 self.play_time += frametime;
1629
1630         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1631         //   (div0: and that in CheckRules_World please)
1632 }
1633
1634 float checkrules_equality;
1635 float checkrules_suddendeathwarning;
1636 float checkrules_suddendeathend;
1637 float checkrules_overtimesadded; //how many overtimes have been already added
1638
1639 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1640 float WINNING_YES = 1; // winner found
1641 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1642 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1643
1644 float InitiateSuddenDeath()
1645 {
1646         // Check first whether normal overtimes could be added before initiating suddendeath mode
1647         // - for this timelimit_overtime needs to be >0 of course
1648         // - also check the winning condition calculated in the previous frame and only add normal overtime
1649         //   again, if at the point at which timelimit would be extended again, still no winner was found
1650         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1651         {
1652                 return 1; // need to call InitiateOvertime later
1653         }
1654         else
1655         {
1656                 if(!checkrules_suddendeathend)
1657                 {
1658                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1659                         if(g_race && !g_race_qualifying)
1660                                 race_StartCompleting();
1661                 }
1662                 return 0;
1663         }
1664 }
1665
1666 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1667 {
1668         ++checkrules_overtimesadded;
1669         //add one more overtime by simply extending the timelimit
1670         float tl;
1671         tl = autocvar_timelimit;
1672         tl += autocvar_timelimit_overtime;
1673         cvar_set("timelimit", ftos(tl));
1674         string minutesPlural;
1675         if (autocvar_timelimit_overtime == 1)
1676                 minutesPlural = " ^3minute";
1677         else
1678                 minutesPlural = " ^3minutes";
1679
1680         bcenterprint(
1681                 strcat(
1682                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1683                         ftos(autocvar_timelimit_overtime),
1684                         minutesPlural,
1685                         " to the game!"
1686                 )
1687         );
1688 }
1689
1690 float GetWinningCode(float fraglimitreached, float equality)
1691 {
1692         if(autocvar_g_campaign == 1)
1693                 if(fraglimitreached)
1694                         return WINNING_YES;
1695                 else
1696                         return WINNING_NO;
1697
1698         else
1699                 if(equality)
1700                         if(fraglimitreached)
1701                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1702                         else
1703                                 return WINNING_NEVER;
1704                 else
1705                         if(fraglimitreached)
1706                                 return WINNING_YES;
1707                         else
1708                                 return WINNING_NO;
1709 }
1710
1711 // set the .winning flag for exactly those players with a given field value
1712 void SetWinners(.float field, float value)
1713 {
1714         entity head;
1715         FOR_EACH_PLAYER(head)
1716                 head.winning = (head.field == value);
1717 }
1718
1719 // set the .winning flag for those players with a given field value
1720 void AddWinners(.float field, float value)
1721 {
1722         entity head;
1723         FOR_EACH_PLAYER(head)
1724                 if(head.field == value)
1725                         head.winning = 1;
1726 }
1727
1728 // clear the .winning flags
1729 void ClearWinners(void)
1730 {
1731         entity head;
1732         FOR_EACH_PLAYER(head)
1733                 head.winning = 0;
1734 }
1735
1736 // Onslaught winning condition:
1737 // game terminates if only one team has a working generator (or none)
1738 float WinningCondition_Onslaught()
1739 {
1740         entity head;
1741         float t1, t2, t3, t4;
1742
1743         WinningConditionHelper(); // set worldstatus
1744
1745         if(inWarmupStage)
1746                 return WINNING_NO;
1747
1748         // first check if the game has ended
1749         t1 = t2 = t3 = t4 = 0;
1750         head = find(world, classname, "onslaught_generator");
1751         while (head)
1752         {
1753                 if (head.health > 0)
1754                 {
1755                         if (head.team == COLOR_TEAM1) t1 = 1;
1756                         if (head.team == COLOR_TEAM2) t2 = 1;
1757                         if (head.team == COLOR_TEAM3) t3 = 1;
1758                         if (head.team == COLOR_TEAM4) t4 = 1;
1759                 }
1760                 head = find(head, classname, "onslaught_generator");
1761         }
1762         if (t1 + t2 + t3 + t4 < 2)
1763         {
1764                 // game over, only one team remains (or none)
1765                 ClearWinners();
1766                 if (t1) SetWinners(team, COLOR_TEAM1);
1767                 if (t2) SetWinners(team, COLOR_TEAM2);
1768                 if (t3) SetWinners(team, COLOR_TEAM3);
1769                 if (t4) SetWinners(team, COLOR_TEAM4);
1770                 dprint("Have a winner, ending game.\n");
1771                 return WINNING_YES;
1772         }
1773
1774         // Two or more teams remain
1775         return WINNING_NO;
1776 }
1777
1778 float LMS_NewPlayerLives()
1779 {
1780         float fl;
1781         fl = autocvar_fraglimit;
1782         if(fl == 0)
1783                 fl = 999;
1784
1785         // first player has left the game for dying too much? Nobody else can get in.
1786         if(lms_lowest_lives < 1)
1787                 return 0;
1788
1789         if(!autocvar_g_lms_join_anytime)
1790                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1791                         return 0;
1792
1793         return bound(1, lms_lowest_lives, fl);
1794 }
1795
1796 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1797 // they win. Otherwise the defending team wins once the timelimit passes.
1798 void assault_new_round();
1799 float WinningCondition_Assault()
1800 {
1801         float status;
1802
1803         WinningConditionHelper(); // set worldstatus
1804
1805         status = WINNING_NO;
1806         // as the timelimit has not yet passed just assume the defending team will win
1807         if(assault_attacker_team == COLOR_TEAM1)
1808         {
1809                 SetWinners(team, COLOR_TEAM2);
1810         }
1811         else
1812         {
1813                 SetWinners(team, COLOR_TEAM1);
1814         }
1815
1816         entity ent;
1817         ent = find(world, classname, "target_assault_roundend");
1818         if(ent)
1819         {
1820                 if(ent.winning) // round end has been triggered by attacking team
1821                 {
1822                         bprint("ASSAULT: round completed...\n");
1823                         SetWinners(team, assault_attacker_team);
1824
1825                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1826
1827                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1828                         {
1829                                 status = WINNING_YES;
1830                         }
1831                         else
1832                         {
1833                                 entity oldself;
1834                                 oldself = self;
1835                                 self = ent;
1836                                 assault_new_round();
1837                                 self = oldself;
1838                         }
1839                 }
1840         }
1841
1842         return status;
1843 }
1844
1845 // LMS winning condition: game terminates if and only if there's at most one
1846 // one player who's living lives. Top two scores being equal cancels the time
1847 // limit.
1848 float WinningCondition_LMS()
1849 {
1850         entity head, head2;
1851         float have_player;
1852         float have_players;
1853         float l;
1854
1855         have_player = FALSE;
1856         have_players = FALSE;
1857         l = LMS_NewPlayerLives();
1858
1859         head = find(world, classname, "player");
1860         if(head)
1861                 have_player = TRUE;
1862         head2 = find(head, classname, "player");
1863         if(head2)
1864                 have_players = TRUE;
1865
1866         if(have_player)
1867         {
1868                 // we have at least one player
1869                 if(have_players)
1870                 {
1871                         // two or more active players - continue with the game
1872                 }
1873                 else
1874                 {
1875                         // exactly one player?
1876
1877                         ClearWinners();
1878                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1879
1880                         if(l)
1881                         {
1882                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1883                                 return WINNING_NO;
1884                         }
1885                         else
1886                         {
1887                                 // a winner!
1888                                 // and assign him his first place
1889                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1890                                 return WINNING_YES;
1891                         }
1892                 }
1893         }
1894         else
1895         {
1896                 // nobody is playing at all...
1897                 if(l)
1898                 {
1899                         // wait for players...
1900                 }
1901                 else
1902                 {
1903                         // SNAFU (maybe a draw game?)
1904                         ClearWinners();
1905                         dprint("No players, ending game.\n");
1906                         return WINNING_YES;
1907                 }
1908         }
1909
1910         // When we get here, we have at least two players who are actually LIVING,
1911         // now check if the top two players have equal score.
1912         WinningConditionHelper();
1913
1914         ClearWinners();
1915         if(WinningConditionHelper_winner)
1916                 WinningConditionHelper_winner.winning = TRUE;
1917         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1918                 return WINNING_NEVER;
1919
1920         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1921         return WINNING_NO;
1922 }
1923
1924 void ShuffleMaplist()
1925 {
1926         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1927 }
1928
1929 float leaderfrags;
1930 float WinningCondition_Scores(float limit, float leadlimit)
1931 {
1932         float limitreached;
1933
1934         // TODO make everything use THIS winning condition (except LMS)
1935         WinningConditionHelper();
1936
1937         if(teamplay)
1938         {
1939                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1940                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1941                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1942                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1943         }
1944
1945         ClearWinners();
1946         if(WinningConditionHelper_winner)
1947                 WinningConditionHelper_winner.winning = 1;
1948         if(WinningConditionHelper_winnerteam >= 0)
1949                 SetWinners(team, WinningConditionHelper_winnerteam);
1950
1951         if(WinningConditionHelper_lowerisbetter)
1952         {
1953                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1954                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1955                 limit = -limit;
1956         }
1957
1958         if(WinningConditionHelper_zeroisworst)
1959                 leadlimit = 0; // not supported in this mode
1960
1961         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1962         // these modes always score in increments of 1, thus this makes sense
1963         {
1964                 if(leaderfrags != WinningConditionHelper_topscore)
1965                 {
1966                         leaderfrags = WinningConditionHelper_topscore;
1967
1968                         if (limit)
1969                         if (leaderfrags == limit - 1)
1970                                 Announce("1fragleft");
1971                         else if (leaderfrags == limit - 2)
1972                                 Announce("2fragsleft");
1973                         else if (leaderfrags == limit - 3)
1974                                 Announce("3fragsleft");
1975                 }
1976         }
1977
1978         limitreached = FALSE;
1979         if(limit)
1980                 if(WinningConditionHelper_topscore >= limit)
1981                         limitreached = TRUE;
1982         if(leadlimit)
1983         {
1984                 float leadlimitreached;
1985                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1986                 if(autocvar_leadlimit_and_fraglimit)
1987                         limitreached = (limitreached && leadlimitreached);
1988                 else
1989                         limitreached = (limitreached || leadlimitreached);
1990         }
1991
1992         return GetWinningCode(
1993                 WinningConditionHelper_topscore && limitreached,
1994                 WinningConditionHelper_equality
1995         );
1996 }
1997
1998 float WinningCondition_Race(float fraglimit)
1999 {
2000         float wc;
2001         entity p;
2002         float n, c;
2003
2004         n = 0;
2005         c = 0;
2006         FOR_EACH_PLAYER(p)
2007         {
2008                 ++n;
2009                 if(p.race_completed)
2010                         ++c;
2011         }
2012         if(n && (n == c))
2013                 return WINNING_YES;
2014         wc = WinningCondition_Scores(fraglimit, 0);
2015
2016         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2017         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2018         // do NOT support equality when the laps are all raced!
2019                 return WINNING_STARTSUDDENDEATHOVERTIME;
2020         else
2021                 return WINNING_NEVER;
2022         return wc;
2023 }
2024
2025 void ReadyRestart();
2026 float WinningCondition_QualifyingThenRace(float limit)
2027 {
2028         float wc;
2029         wc = WinningCondition_Scores(limit, 0);
2030
2031         // NEVER initiate overtime
2032         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2033         {
2034                 return WINNING_YES;
2035         }
2036
2037         return wc;
2038 }
2039
2040 float WinningCondition_RanOutOfSpawns()
2041 {
2042         entity head;
2043
2044         if(have_team_spawns <= 0)
2045                 return WINNING_NO;
2046
2047         if(!some_spawn_has_been_used)
2048                 return WINNING_NO;
2049
2050         team1_score = team2_score = team3_score = team4_score = 0;
2051
2052         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2053         {
2054                 if(head.team == COLOR_TEAM1)
2055                         team1_score = 1;
2056                 else if(head.team == COLOR_TEAM2)
2057                         team2_score = 1;
2058                 else if(head.team == COLOR_TEAM3)
2059                         team3_score = 1;
2060                 else if(head.team == COLOR_TEAM4)
2061                         team4_score = 1;
2062         }
2063
2064         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2065         {
2066                 if(head.team == COLOR_TEAM1)
2067                         team1_score = 1;
2068                 else if(head.team == COLOR_TEAM2)
2069                         team2_score = 1;
2070                 else if(head.team == COLOR_TEAM3)
2071                         team3_score = 1;
2072                 else if(head.team == COLOR_TEAM4)
2073                         team4_score = 1;
2074         }
2075
2076         ClearWinners();
2077         if(team1_score + team2_score + team3_score + team4_score == 0)
2078         {
2079                 checkrules_equality = TRUE;
2080                 return WINNING_YES;
2081         }
2082         else if(team1_score + team2_score + team3_score + team4_score == 1)
2083         {
2084                 float t, i;
2085                 if(team1_score) t = COLOR_TEAM1;
2086                 if(team2_score) t = COLOR_TEAM2;
2087                 if(team3_score) t = COLOR_TEAM3;
2088                 if(team4_score) t = COLOR_TEAM4;
2089                 CheckAllowedTeams(world);
2090                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2091                 {
2092                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2093                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2094                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2095                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2096                 }
2097
2098                 AddWinners(team, t);
2099                 return WINNING_YES;
2100         }
2101         else
2102                 return WINNING_NO;
2103 }
2104
2105 /*
2106 ============
2107 CheckRules_World
2108
2109 Exit deathmatch games upon conditions
2110 ============
2111 */
2112 void CheckRules_World()
2113 {
2114         float timelimit;
2115         float fraglimit;
2116         float leadlimit;
2117
2118         VoteThink();
2119         MapVote_Think();
2120
2121         SetDefaultAlpha();
2122
2123         /*
2124         MapVote_Think should now do that part
2125         if (intermission_running)
2126                 if (time >= intermission_exittime + 60)
2127                 {
2128                         if(!DoNextMapOverride())
2129                                 GotoNextMap();
2130                         return;
2131                 }
2132         */
2133
2134         if (gameover)   // someone else quit the game already
2135         {
2136                 if(player_count == 0) // Nobody there? Then let's go to the next map
2137                         MapVote_Start();
2138                         // this will actually check the player count in the next frame
2139                         // again, but this shouldn't hurt
2140                 return;
2141         }
2142
2143         timelimit = autocvar_timelimit * 60;
2144         fraglimit = autocvar_fraglimit;
2145         leadlimit = autocvar_leadlimit;
2146
2147         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2148         {
2149                 if(timelimit > 0)
2150                         timelimit = 0; // timelimit is not made for warmup
2151                 if(fraglimit > 0)
2152                         fraglimit = 0; // no fraglimit for now
2153                 leadlimit = 0; // no leadlimit for now
2154         }
2155
2156         if(g_onslaught)
2157                 timelimit = 0; // ONS has its own overtime rule
2158
2159         if(timelimit > 0)
2160         {
2161                 timelimit += game_starttime;
2162         }
2163         else if (timelimit < 0)
2164         {
2165                 // endmatch
2166                 NextLevel();
2167                 return;
2168         }
2169
2170         float wantovertime;
2171         wantovertime = 0;
2172
2173         if(checkrules_suddendeathend)
2174         {
2175                 if(!checkrules_suddendeathwarning)
2176                 {
2177                         checkrules_suddendeathwarning = TRUE;
2178                         if(g_race && !g_race_qualifying)
2179                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2180                         else
2181                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2182                 }
2183         }
2184         else
2185         {
2186                 if (timelimit && time >= timelimit)
2187                 {
2188                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2189                         {
2190                                 float totalplayers;
2191                                 float playerswithlaps;
2192                                 float readyplayers;
2193                                 entity head;
2194                                 totalplayers = playerswithlaps = readyplayers = 0;
2195                                 FOR_EACH_PLAYER(head)
2196                                 {
2197                                         ++totalplayers;
2198                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2199                                                 ++playerswithlaps;
2200                                         if(head.ready)
2201                                                 ++readyplayers;
2202                                 }
2203
2204                                 // at least 2 of the players have completed a lap: start the RACE
2205                                 // otherwise, the players should end the qualifying on their own
2206                                 if(readyplayers || playerswithlaps >= 2)
2207                                 {
2208                                         checkrules_suddendeathend = 0;
2209                                         ReadyRestart(); // go to race
2210                                         return;
2211                                 }
2212                                 else
2213                                         wantovertime |= InitiateSuddenDeath();
2214                         }
2215                         else
2216                                 wantovertime |= InitiateSuddenDeath();
2217                 }
2218         }
2219
2220         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2221         {
2222                 NextLevel();
2223                 return;
2224         }
2225
2226         float checkrules_status;
2227         checkrules_status = WinningCondition_RanOutOfSpawns();
2228         if(checkrules_status == WINNING_YES)
2229         {
2230                 bprint("Hey! Someone ran out of spawns!\n");
2231         }
2232         else if(g_race && !g_race_qualifying && timelimit >= 0)
2233         {
2234                 checkrules_status = WinningCondition_Race(fraglimit);
2235                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2236         }
2237         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2238         {
2239                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2240                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2241         }
2242         else if(g_assault)
2243         {
2244                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2245         }
2246         else if(g_lms)
2247         {
2248                 checkrules_status = WinningCondition_LMS();
2249         }
2250         else if (g_onslaught)
2251         {
2252                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2253         }
2254         else
2255         {
2256                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2257                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2258         }
2259
2260         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2261         {
2262                 checkrules_status = WINNING_NEVER;
2263                 checkrules_overtimesadded = -1;
2264                 wantovertime |= InitiateSuddenDeath();
2265         }
2266
2267         if(checkrules_status == WINNING_NEVER)
2268                 // equality cases! Nobody wins if the overtime ends in a draw.
2269                 ClearWinners();
2270
2271         if(wantovertime)
2272         {
2273                 if(checkrules_status == WINNING_NEVER)
2274                         InitiateOvertime();
2275                 else
2276                         checkrules_status = WINNING_YES;
2277         }
2278
2279         if(checkrules_suddendeathend)
2280                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2281                         checkrules_status = WINNING_YES;
2282
2283         if(checkrules_status == WINNING_YES)
2284         {
2285                 //print("WINNING\n");
2286                 NextLevel();
2287         }
2288 }
2289
2290 float mapvote_nextthink;
2291 float mapvote_initialized;
2292 float mapvote_keeptwotime;
2293 float mapvote_timeout;
2294 string mapvote_message;
2295 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2296 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2297 float mapvote_screenshot_dirs_count;
2298
2299 float mapvote_count;
2300 float mapvote_count_real;
2301 string mapvote_maps[MAPVOTE_COUNT];
2302 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2303 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2304 float mapvote_maps_suggested[MAPVOTE_COUNT];
2305 string mapvote_suggestions[MAPVOTE_COUNT];
2306 float mapvote_suggestion_ptr;
2307 float mapvote_voters;
2308 float mapvote_votes[MAPVOTE_COUNT];
2309 float mapvote_run;
2310 float mapvote_detail;
2311 float mapvote_abstain;
2312 .float mapvote;
2313
2314 void MapVote_ClearAllVotes()
2315 {
2316         FOR_EACH_CLIENT(other)
2317                 other.mapvote = 0;
2318 }
2319
2320 string MapVote_Suggest(string m)
2321 {
2322         float i;
2323         if(m == "")
2324                 return "That's not how to use this command.";
2325         if(!autocvar_g_maplist_votable_suggestions)
2326                 return "Suggestions are not accepted on this server.";
2327         if(mapvote_initialized)
2328                 return "Can't suggest - voting is already in progress!";
2329         m = MapInfo_FixName(m);
2330         if(!m)
2331                 return "The map you suggested is not available on this server.";
2332         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2333                 if(Map_IsRecent(m))
2334                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2335
2336         if(!MapInfo_CheckMap(m))
2337                 return "The map you suggested does not support the current game mode.";
2338         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2339                 if(mapvote_suggestions[i] == m)
2340                         return "This map was already suggested.";
2341         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2342         {
2343                 i = floor(random() * mapvote_suggestion_ptr);
2344         }
2345         else
2346         {
2347                 i = mapvote_suggestion_ptr;
2348                 mapvote_suggestion_ptr += 1;
2349         }
2350         if(mapvote_suggestions[i] != "")
2351                 strunzone(mapvote_suggestions[i]);
2352         mapvote_suggestions[i] = strzone(m);
2353         if(autocvar_sv_eventlog)
2354                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2355         return strcat("Suggestion of ", m, " accepted.");
2356 }
2357
2358 void MapVote_AddVotable(string nextMap, float isSuggestion)
2359 {
2360         float j, i, o;
2361         string pakfile, mapfile;
2362
2363         if(nextMap == "")
2364                 return;
2365         for(j = 0; j < mapvote_count; ++j)
2366                 if(mapvote_maps[j] == nextMap)
2367                         return;
2368         // suggestions might be no longer valid/allowed after gametype switch!
2369         if(isSuggestion)
2370                 if(!MapInfo_CheckMap(nextMap))
2371                         return;
2372         mapvote_maps[mapvote_count] = strzone(nextMap);
2373         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2374
2375         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2376         {
2377                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2378                 pakfile = whichpack(strcat(mapfile, ".tga"));
2379                 if(pakfile == "")
2380                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2381                 if(pakfile == "")
2382                         pakfile = whichpack(strcat(mapfile, ".png"));
2383                 if(pakfile != "")
2384                         break;
2385         }
2386         if(i >= mapvote_screenshot_dirs_count)
2387                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2388         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2389                 pakfile = substring(pakfile, o, -1);
2390
2391         mapvote_maps_screenshot_dir[mapvote_count] = i;
2392         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2393
2394         mapvote_count += 1;
2395 }
2396
2397 void MapVote_Spawn();
2398 void MapVote_Init()
2399 {
2400         float i;
2401         float nmax, smax;
2402
2403         MapVote_ClearAllVotes();
2404
2405         mapvote_count = 0;
2406         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2407         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2408
2409         if(mapvote_abstain)
2410                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2411         else
2412                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2413         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2414
2415         // we need this for AddVotable, as that cycles through the screenshot dirs
2416         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2417         if(mapvote_screenshot_dirs_count == 0)
2418                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2419         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2420         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2421                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2422
2423         if(mapvote_suggestion_ptr)
2424                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2425                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2426
2427         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2428                 MapVote_AddVotable(GetNextMap(), FALSE);
2429
2430         if(mapvote_count == 0)
2431         {
2432                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2433                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2434                 if(autocvar_g_maplist_shuffle)
2435                         ShuffleMaplist();
2436                 localcmd("\nmenu_cmd sync\n");
2437                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2438                         MapVote_AddVotable(GetNextMap(), FALSE);
2439         }
2440
2441         mapvote_count_real = mapvote_count;
2442         if(mapvote_abstain)
2443                 MapVote_AddVotable("don't care", 0);
2444
2445         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2446
2447         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2448         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2449         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2450                 mapvote_keeptwotime = 0;
2451         mapvote_message = "Choose a map and press its key!";
2452
2453         MapVote_Spawn();
2454 }
2455
2456 void MapVote_SendPicture(float id)
2457 {
2458         msg_entity = self;
2459         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2460         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2461         WriteByte(MSG_ONE, id);
2462         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2463 }
2464
2465 float GameCommand_MapVote(string cmd)
2466 {
2467         if(!intermission_running)
2468                 return FALSE;
2469
2470         if(cmd == "mv_getpic")
2471         {
2472                 MapVote_SendPicture(stof(argv(1)));
2473                 return TRUE;
2474         }
2475
2476         return FALSE;
2477 }
2478
2479 float MapVote_GetMapMask()
2480 {
2481         float mask, i, power;
2482         mask = 0;
2483         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2484                 if(mapvote_maps[i] != "")
2485                         mask |= power;
2486         return mask;
2487 }
2488
2489 entity mapvote_ent;
2490 float MapVote_SendEntity(entity to, float sf)
2491 {
2492         float i;
2493
2494         if(sf & 1)
2495                 sf &~= 2; // if we send 1, we don't need to also send 2
2496
2497         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2498         WriteByte(MSG_ENTITY, sf);
2499
2500         if(sf & 1)
2501         {
2502                 // flag 1 == initialization
2503                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2504                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2505                 WriteString(MSG_ENTITY, "");
2506                 WriteByte(MSG_ENTITY, mapvote_count);
2507                 WriteByte(MSG_ENTITY, mapvote_abstain);
2508                 WriteByte(MSG_ENTITY, mapvote_detail);
2509                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2510                 if(mapvote_count <= 8)
2511                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2512                 else
2513                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2514                 for(i = 0; i < mapvote_count; ++i)
2515                         if(mapvote_maps[i] != "")
2516                         {
2517                                 if(mapvote_abstain && i == mapvote_count - 1)
2518                                 {
2519                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2520                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2521                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2522                                 }
2523                                 else
2524                                 {
2525                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2526                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2527                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2528                                 }
2529                         }
2530         }
2531
2532         if(sf & 2)
2533         {
2534                 // flag 2 == update of mask
2535                 if(mapvote_count <= 8)
2536                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2537                 else
2538                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2539         }
2540
2541         if(sf & 4)
2542         {
2543                 if(mapvote_detail)
2544                         for(i = 0; i < mapvote_count; ++i)
2545                                 if(mapvote_maps[i] != "")
2546                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2547
2548                 WriteByte(MSG_ENTITY, to.mapvote);
2549         }
2550
2551         return TRUE;
2552 }
2553
2554 void MapVote_Spawn()
2555 {
2556         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2557 }
2558
2559 void MapVote_TouchMask()
2560 {
2561         mapvote_ent.SendFlags |= 2;
2562 }
2563
2564 void MapVote_TouchVotes(entity voter)
2565 {
2566         mapvote_ent.SendFlags |= 4;
2567 }
2568
2569 float MapVote_Finished(float mappos)
2570 {
2571         string result;
2572         float i;
2573         float didntvote;
2574
2575         if(autocvar_sv_eventlog)
2576         {
2577                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2578                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2579                 didntvote = mapvote_voters;
2580                 for(i = 0; i < mapvote_count; ++i)
2581                         if(mapvote_maps[i] != "")
2582                         {
2583                                 didntvote -= mapvote_votes[i];
2584                                 if(i != mappos)
2585                                 {
2586                                         result = strcat(result, ":", mapvote_maps[i]);
2587                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2588                                 }
2589                         }
2590                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2591
2592                 GameLogEcho(result);
2593                 if(mapvote_maps_suggested[mappos])
2594                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2595         }
2596
2597         FOR_EACH_REALCLIENT(other)
2598                 FixClientCvars(other);
2599
2600         Map_Goto_SetStr(mapvote_maps[mappos]);
2601         Map_Goto();
2602         alreadychangedlevel = TRUE;
2603         return TRUE;
2604 }
2605 void MapVote_CheckRules_1()
2606 {
2607         float i;
2608
2609         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2610         {
2611                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2612                 mapvote_votes[i] = 0;
2613         }
2614
2615         mapvote_voters = 0;
2616         FOR_EACH_REALCLIENT(other)
2617         {
2618                 ++mapvote_voters;
2619                 if(other.mapvote)
2620                 {
2621                         i = other.mapvote - 1;
2622                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2623                         mapvote_votes[i] = mapvote_votes[i] + 1;
2624                 }
2625         }
2626 }
2627
2628 float MapVote_CheckRules_2()
2629 {
2630         float i;
2631         float firstPlace, secondPlace;
2632         float firstPlaceVotes, secondPlaceVotes;
2633         float mapvote_voters_real;
2634         string result;
2635
2636         if(mapvote_count_real == 1)
2637                 return MapVote_Finished(0);
2638
2639         mapvote_voters_real = mapvote_voters;
2640         if(mapvote_abstain)
2641                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2642
2643         RandomSelection_Init();
2644         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2645                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2646         firstPlace = RandomSelection_chosen_float;
2647         firstPlaceVotes = RandomSelection_best_priority;
2648         //dprint("First place: ", ftos(firstPlace), "\n");
2649         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2650
2651         RandomSelection_Init();
2652         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2653                 if(i != firstPlace)
2654                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2655         secondPlace = RandomSelection_chosen_float;
2656         secondPlaceVotes = RandomSelection_best_priority;
2657         //dprint("Second place: ", ftos(secondPlace), "\n");
2658         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2659
2660         if(firstPlace == -1)
2661                 error("No first place in map vote... WTF?");
2662
2663         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2664                 return MapVote_Finished(firstPlace);
2665
2666         if(mapvote_keeptwotime)
2667                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2668                 {
2669                         float didntvote;
2670                         MapVote_TouchMask();
2671                         mapvote_message = "Now decide between the TOP TWO!";
2672                         mapvote_keeptwotime = 0;
2673                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2674                         result = strcat(result, ":", ftos(firstPlaceVotes));
2675                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2676                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2677                         didntvote = mapvote_voters;
2678                         for(i = 0; i < mapvote_count; ++i)
2679                                 if(mapvote_maps[i] != "")
2680                                 {
2681                                         didntvote -= mapvote_votes[i];
2682                                         if(i != firstPlace)
2683                                                 if(i != secondPlace)
2684                                                 {
2685                                                         result = strcat(result, ":", mapvote_maps[i]);
2686                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2687                                                         if(i < mapvote_count_real)
2688                                                         {
2689                                                                 strunzone(mapvote_maps[i]);
2690                                                                 mapvote_maps[i] = "";
2691                                                                 strunzone(mapvote_maps_pakfile[i]);
2692                                                                 mapvote_maps_pakfile[i] = "";
2693                                                         }
2694                                                 }
2695                                 }
2696                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2697                         if(autocvar_sv_eventlog)
2698                                 GameLogEcho(result);
2699                 }
2700
2701         return FALSE;
2702 }
2703 void MapVote_Tick()
2704 {
2705         float keeptwo;
2706         float totalvotes;
2707
2708         keeptwo = mapvote_keeptwotime;
2709         MapVote_CheckRules_1(); // count
2710         if(MapVote_CheckRules_2()) // decide
2711                 return;
2712
2713         totalvotes = 0;
2714         FOR_EACH_REALCLIENT(other)
2715         {
2716                 // hide scoreboard again
2717                 if(other.health != 2342)
2718                 {
2719                         other.health = 2342;
2720                         other.impulse = 0;
2721                         if(clienttype(other) == CLIENTTYPE_REAL)
2722                         {
2723                                 msg_entity = other;
2724                                 WriteByte(MSG_ONE, SVC_FINALE);
2725                                 WriteString(MSG_ONE, "");
2726                         }
2727                 }
2728
2729                 // clear possibly invalid votes
2730                 if(mapvote_maps[other.mapvote - 1] == "")
2731                         other.mapvote = 0;
2732                 // use impulses as new vote
2733                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2734                         if(mapvote_maps[other.impulse - 1] != "")
2735                         {
2736                                 other.mapvote = other.impulse;
2737                                 MapVote_TouchVotes(other);
2738                         }
2739                 other.impulse = 0;
2740
2741                 if(other.mapvote)
2742                         ++totalvotes;
2743         }
2744
2745         MapVote_CheckRules_1(); // just count
2746 }
2747 void MapVote_Start()
2748 {
2749         if(mapvote_run)
2750                 return;
2751
2752         // wait for stats to be sent first
2753         if(!playerstats_waitforme)
2754                 return;
2755
2756         MapInfo_Enumerate();
2757         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2758                 mapvote_run = TRUE;
2759 }
2760 void MapVote_Think()
2761 {
2762         if(!mapvote_run)
2763                 return;
2764
2765         if(alreadychangedlevel)
2766                 return;
2767
2768         if(time < mapvote_nextthink)
2769                 return;
2770         //dprint("tick\n");
2771
2772         mapvote_nextthink = time + 0.5;
2773
2774         if(!mapvote_initialized)
2775         {
2776                 if(autocvar_rescan_pending == 1)
2777                 {
2778                         cvar_set("rescan_pending", "2");
2779                         localcmd("fs_rescan\nrescan_pending 3\n");
2780                         return;
2781                 }
2782                 else if(autocvar_rescan_pending == 2)
2783                 {
2784                         return;
2785                 }
2786                 else if(autocvar_rescan_pending == 3)
2787                 {
2788                         // now build missing mapinfo files
2789                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2790                                 return;
2791
2792                         // we're done, start the timer
2793                         cvar_set("rescan_pending", "0");
2794                 }
2795
2796                 mapvote_initialized = TRUE;
2797                 if(DoNextMapOverride())
2798                         return;
2799                 if(!autocvar_g_maplist_votable || player_count <= 0)
2800                 {
2801                         GotoNextMap();
2802                         return;
2803                 }
2804                 MapVote_Init();
2805         }
2806
2807         MapVote_Tick();
2808 }
2809
2810 string GotoMap(string m)
2811 {
2812         if(!MapInfo_CheckMap(m))
2813                 return "The map you chose is not available on this server.";
2814         cvar_set("nextmap", m);
2815         cvar_set("timelimit", "-1");
2816         if(mapvote_initialized || alreadychangedlevel)
2817         {
2818                 if(DoNextMapOverride())
2819                         return "Map switch initiated.";
2820                 else
2821                         return "Hm... no. For some reason I like THIS map more.";
2822         }
2823         else
2824                 return "Map switch will happen after scoreboard.";
2825 }
2826
2827
2828 void EndFrame()
2829 {
2830         float altime;
2831         FOR_EACH_REALCLIENT(self)
2832         {
2833                 if(self.classname == "spectator")
2834                 {
2835                         if(self.enemy.typehitsound)
2836                                 self.typehit_time = time;
2837                         else if(self.enemy.hitsound)
2838                                 self.hit_time = time;
2839                 }
2840                 else
2841                 {
2842                         if(self.typehitsound)
2843                                 self.typehit_time = time;
2844                         else if(self.hitsound)
2845                                 self.hit_time = time;
2846                 }
2847         }
2848         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2849         // add 1 frametime because after this, engine SV_Physics
2850         // increases time by a frametime and then networks the frame
2851         // add another frametime because client shows everything with
2852         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2853         // needed!
2854         FOR_EACH_CLIENT(self)
2855         {
2856                 self.hitsound = FALSE;
2857                 self.typehitsound = FALSE;
2858                 antilag_record(self, altime);
2859         }
2860 }
2861
2862
2863 /*
2864  * RedirectionThink:
2865  * returns TRUE if redirecting
2866  */
2867 float redirection_timeout;
2868 float redirection_nextthink;
2869 float RedirectionThink()
2870 {
2871         float clients_found;
2872
2873         if(redirection_target == "")
2874                 return FALSE;
2875
2876         if(!redirection_timeout)
2877         {
2878                 cvar_set("sv_public", "-2");
2879                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2880                 if(redirection_target == "self")
2881                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2882                 else
2883                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2884         }
2885
2886         if(time < redirection_nextthink)
2887                 return TRUE;
2888
2889         redirection_nextthink = time + 1;
2890
2891         clients_found = 0;
2892         FOR_EACH_REALCLIENT(self)
2893         {
2894                 print("Redirecting: sending connect command to ", self.netname, "\n");
2895                 if(redirection_target == "self")
2896                         stuffcmd(self, "\ndisconnect; reconnect\n");
2897                 else
2898                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2899                 ++clients_found;
2900         }
2901
2902         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2903
2904         if(time > redirection_timeout || clients_found == 0)
2905                 localcmd("\nwait; wait; wait; quit\n");
2906
2907         return TRUE;
2908 }
2909
2910 void TargetMusic_RestoreGame();
2911 void RestoreGame()
2912 {
2913         // Loaded from a save game
2914         // some things then break, so let's work around them...
2915
2916         // Progs DB (capture records)
2917         ServerProgsDB = db_load("server.db");
2918
2919         // Mapinfo
2920         MapInfo_Shutdown();
2921         MapInfo_Enumerate();
2922         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2923         WeaponStats_Init();
2924
2925         TargetMusic_RestoreGame();
2926 }
2927
2928 void SV_Shutdown()
2929 {
2930         entity e;
2931
2932         if(gameover > 1) // shutting down already?
2933                 return;
2934
2935         gameover = 2; // 2 = server shutting down
2936
2937         if(world_initialized > 0)
2938         {
2939                 world_initialized = 0;
2940                 print("Saving persistent data...\n");
2941                 Ban_SaveBans();
2942
2943                 PlayerStats_EndMatch(0);
2944                 FOR_EACH_CLIENT(e)
2945                         PlayerStats_AddGlobalInfo(e);
2946                 PlayerStats_Shutdown();
2947
2948                 if(!cheatcount_total)
2949                 {
2950                         if(autocvar_sv_db_saveasdump)
2951                                 db_dump(ServerProgsDB, "server.db");
2952                         else
2953                                 db_save(ServerProgsDB, "server.db");
2954                 }
2955                 if(autocvar_developer)
2956                 {
2957                         if(autocvar_sv_db_saveasdump)
2958                                 db_dump(TemporaryDB, "server-temp.db");
2959                         else
2960                                 db_save(TemporaryDB, "server-temp.db");
2961                 }
2962                 CheatShutdown(); // must be after cheatcount check
2963                 db_close(ServerProgsDB);
2964                 db_close(TemporaryDB);
2965                 print("done!\n");
2966                 // tell the bot system the game is ending now
2967                 bot_endgame();
2968
2969                 WeaponStats_Shutdown();
2970                 MapInfo_Shutdown();
2971         }
2972         else if(world_initialized == 0)
2973         {
2974                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2975         }
2976 }