qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include "../common/deathtypes/all.qh"
  23 #include "../common/mapinfo.qh"
  24 #include "../common/monsters/_mod.qh"
  25 #include "../common/monsters/sv_monsters.qh"
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/notifications/all.qh"
  28 #include "../common/physics/player.qh"
  29 #include "../common/playerstats.qh"
  30 #include "../common/stats.qh"
  31 #include "../common/teams.qh"
  32 #include "../common/triggers/trigger/secret.qh"
  33 #include "../common/triggers/target/music.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/_mod.qh"
  36 #include <common/weapons/_all.qh>
  37 #include "../common/state.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think(entity this)
  45 {
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         this.nextthink = time + delta;
  53
  54         e = edict_num(this.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, this.cnt);
  59                 WriteShort(MSG_BROADCAST, bound(1, e.ping, 65535));
  60                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_packetloss * 255), 255));
  61                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_movementloss * 255), 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, this.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         this.cnt = (this.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new_pure(pingplreport);
  85         setthink(pingplreport, PingPLReport_Think);
  86         pingplreport.nextthink = time;
  87 }
  88
  89 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  90 string redirection_target;
  91 float world_initialized;
  92
  93 string GetGametype();
  94 void ShuffleMaplist();
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         if(cvar_changes)
 148                 strunzone(cvar_changes);
 149         cvar_changes = string_null;
 150         if(cvar_purechanges)
 151                 strunzone(cvar_purechanges);
 152         cvar_purechanges = string_null;
 153         cvar_purechanges_count = 0;
 154
 155         h = buf_create();
 156         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 157         n = buf_getsize(h);
 158
 159         adding = true;
 160         pureadding = true;
 161
 162         for(i = 0; i < n; ++i)
 163         {
 164                 k = bufstr_get(h, i);
 165
 166 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 167 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 168 #define BADCVAR(p) if(k == p) continue
 169
 170                 // general excludes and namespaces for server admin used cvars
 171                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 172
 173                 // internal
 174                 BADPREFIX("csqc_");
 175                 BADPREFIX("cvar_check_");
 176                 BADCVAR("gamecfg");
 177                 BADCVAR("g_configversion");
 178                 BADCVAR("g_maplist_index");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213
 214                 // private
 215                 BADCVAR("developer");
 216                 BADCVAR("log_dest_udp");
 217                 BADCVAR("net_address");
 218                 BADCVAR("net_address_ipv6");
 219                 BADCVAR("port");
 220                 BADCVAR("savedgamecfg");
 221                 BADCVAR("serverconfig");
 222                 BADCVAR("sv_autoscreenshot");
 223                 BADCVAR("sv_heartbeatperiod");
 224                 BADCVAR("sv_vote_master_password");
 225                 BADCVAR("sys_colortranslation");
 226                 BADCVAR("sys_specialcharactertranslation");
 227                 BADCVAR("timeformat");
 228                 BADCVAR("timestamps");
 229                 BADPREFIX("developer_");
 230                 BADPREFIX("g_ban_");
 231                 BADPREFIX("g_banned_list");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_voice_flood_");
 236                 BADPREFIX("log_file");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250
 251                 // mapinfo
 252                 BADCVAR("fraglimit");
 253                 BADCVAR("g_assault");
 254                 BADCVAR("g_ca");
 255                 BADCVAR("g_ca_teams");
 256                 BADCVAR("g_ctf");
 257                 BADCVAR("g_cts");
 258                 BADCVAR("g_dm");
 259                 BADCVAR("g_domination");
 260                 BADCVAR("g_domination_default_teams");
 261                 BADCVAR("g_freezetag");
 262                 BADCVAR("g_freezetag_teams");
 263                 BADCVAR("g_invasion_teams");
 264                 BADCVAR("g_keepaway");
 265                 BADCVAR("g_keyhunt");
 266                 BADCVAR("g_keyhunt_teams");
 267                 BADCVAR("g_lms");
 268                 BADCVAR("g_nexball");
 269                 BADCVAR("g_onslaught");
 270                 BADCVAR("g_race");
 271                 BADCVAR("g_race_laps_limit");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_race_qualifying_timelimit_override");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing gameplay relevant
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("gameversion");
 307                 BADCVAR("g_allow_oldvortexbeam");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_campcheck_distance");
 310                 BADCVAR("g_ca_point_leadlimit");
 311                 BADCVAR("g_ca_point_limit");
 312                 BADCVAR("g_ctf_captimerecord_always");
 313                 BADCVAR("g_ctf_flag_glowtrails");
 314                 BADCVAR("g_ctf_flag_pickup_verbosename");
 315                 BADCVAR("g_domination_point_leadlimit");
 316                 BADCVAR("g_forced_respawn");
 317                 BADCVAR("g_freezetag_point_leadlimit");
 318                 BADCVAR("g_freezetag_point_limit");
 319                 BADCVAR("g_hats");
 320                 BADCVAR("g_invasion_point_limit");
 321                 BADCVAR("g_keyhunt_point_leadlimit");
 322                 BADCVAR("g_nexball_goalleadlimit");
 323                 BADCVAR("g_new_toys_use_pickupsound");
 324                 BADCVAR("g_physics_predictall");
 325                 BADCVAR("g_piggyback");
 326                 BADCVAR("g_tdm_point_leadlimit");
 327                 BADCVAR("g_tdm_point_limit");
 328                 BADCVAR("leadlimit_and_fraglimit");
 329                 BADCVAR("leadlimit_override");
 330                 BADCVAR("pausable");
 331                 BADCVAR("sv_checkforpacketsduringsleep");
 332                 BADCVAR("sv_intermission_cdtrack");
 333                 BADCVAR("sv_minigames");
 334                 BADCVAR("sv_namechangetimer");
 335                 BADCVAR("sv_precacheplayermodels");
 336                 BADCVAR("sv_stepheight");
 337                 BADCVAR("sv_timeout");
 338                 BADPREFIX("crypto_");
 339                 BADPREFIX("gameversion_");
 340                 BADPREFIX("g_chat_");
 341                 BADPREFIX("g_ctf_captimerecord_");
 342                 BADPREFIX("g_maplist_votable_");
 343                 BADPREFIX("g_mod_");
 344                 BADPREFIX("g_respawn_");
 345                 BADPREFIX("net_");
 346                 BADPREFIX("prvm_");
 347                 BADPREFIX("skill_");
 348                 BADPREFIX("sv_allow_");
 349                 BADPREFIX("sv_cullentities_");
 350                 BADPREFIX("sv_maxidle_");
 351                 BADPREFIX("sv_minigames_");
 352                 BADPREFIX("sv_radio_");
 353                 BADPREFIX("sv_timeout_");
 354                 BADPREFIX("sv_vote_");
 355                 BADPREFIX("timelimit_");
 356
 357                 // allowed changes to server admins (please sync this to server.cfg)
 358                 // vi commands:
 359                 //   :/"impure"/,$d
 360                 //   :g!,^\/\/[^ /],d
 361                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 362                 //   :%!sort
 363                 // yes, this does contain some redundant stuff, don't really care
 364                 BADCVAR("bot_config_file");
 365                 BADCVAR("bot_number");
 366                 BADCVAR("bot_prefix");
 367                 BADCVAR("bot_suffix");
 368                 BADCVAR("capturelimit_override");
 369                 BADCVAR("fraglimit_override");
 370                 BADCVAR("gametype");
 371                 BADCVAR("g_antilag");
 372                 BADCVAR("g_balance_teams");
 373                 BADCVAR("g_balance_teams_prevent_imbalance");
 374                 BADCVAR("g_balance_teams_scorefactor");
 375                 BADCVAR("g_ban_sync_trusted_servers");
 376                 BADCVAR("g_ban_sync_uri");
 377                 BADCVAR("g_buffs");
 378                 BADCVAR("g_ca_teams_override");
 379                 BADCVAR("g_ctf_ignore_frags");
 380                 BADCVAR("g_domination_point_limit");
 381                 BADCVAR("g_domination_teams_override");
 382                 BADCVAR("g_freezetag_teams_override");
 383                 BADCVAR("g_friendlyfire");
 384                 BADCVAR("g_fullbrightitems");
 385                 BADCVAR("g_fullbrightplayers");
 386                 BADCVAR("g_keyhunt_point_limit");
 387                 BADCVAR("g_keyhunt_teams_override");
 388                 BADCVAR("g_lms_lives_override");
 389                 BADCVAR("g_maplist");
 390                 BADCVAR("g_maplist_check_waypoints");
 391                 BADCVAR("g_maplist_mostrecent_count");
 392                 BADCVAR("g_maplist_shuffle");
 393                 BADCVAR("g_maplist_votable");
 394                 BADCVAR("g_maplist_votable_abstain");
 395                 BADCVAR("g_maplist_votable_nodetail");
 396                 BADCVAR("g_maplist_votable_suggestions");
 397                 BADCVAR("g_maxplayers");
 398                 BADCVAR("g_mirrordamage");
 399                 BADCVAR("g_nexball_goallimit");
 400                 BADCVAR("g_norecoil");
 401                 BADCVAR("g_physics_clientselect");
 402                 BADCVAR("g_powerups");
 403                 BADCVAR("g_spawnshieldtime");
 404                 BADCVAR("g_start_delay");
 405                 BADCVAR("g_superspectate");
 406                 BADCVAR("g_tdm_teams_override");
 407                 BADCVAR("g_warmup");
 408                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 409                 BADCVAR("hostname");
 410                 BADCVAR("log_file");
 411                 BADCVAR("maxplayers");
 412                 BADCVAR("minplayers");
 413                 BADCVAR("net_address");
 414                 BADCVAR("port");
 415                 BADCVAR("rcon_password");
 416                 BADCVAR("rcon_restricted_commands");
 417                 BADCVAR("rcon_restricted_password");
 418                 BADCVAR("skill");
 419                 BADCVAR("sv_adminnick");
 420                 BADCVAR("sv_autoscreenshot");
 421                 BADCVAR("sv_autotaunt");
 422                 BADCVAR("sv_curl_defaulturl");
 423                 BADCVAR("sv_defaultcharacter");
 424                 BADCVAR("sv_defaultcharacterskin");
 425                 BADCVAR("sv_defaultplayercolors");
 426                 BADCVAR("sv_defaultplayermodel");
 427                 BADCVAR("sv_defaultplayerskin");
 428                 BADCVAR("sv_maxidle");
 429                 BADCVAR("sv_maxrate");
 430                 BADCVAR("sv_motd");
 431                 BADCVAR("sv_public");
 432                 BADCVAR("sv_ready_restart");
 433                 BADCVAR("sv_status_privacy");
 434                 BADCVAR("sv_taunt");
 435                 BADCVAR("sv_vote_call");
 436                 BADCVAR("sv_vote_commands");
 437                 BADCVAR("sv_vote_majority_factor");
 438                 BADCVAR("sv_vote_master");
 439                 BADCVAR("sv_vote_master_commands");
 440                 BADCVAR("sv_vote_master_password");
 441                 BADCVAR("sv_vote_simple_majority_factor");
 442                 BADCVAR("teamplay_mode");
 443                 BADCVAR("timelimit_override");
 444                 BADPREFIX("g_warmup_");
 445                 BADPREFIX("sv_ready_restart_");
 446
 447                 // mutators that announce themselves properly to the server browser
 448                 BADCVAR("g_instagib");
 449                 BADCVAR("g_new_toys");
 450                 BADCVAR("g_nix");
 451                 BADCVAR("g_grappling_hook");
 452                 BADCVAR("g_jetpack");
 453
 454 #undef BADPRESUFFIX
 455 #undef BADPREFIX
 456 #undef BADCVAR
 457
 458                 if(pureadding)
 459                 {
 460                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 461                         if(strlen(cvar_purechanges) > 16384)
 462                         {
 463                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 464                                 pureadding = 0;
 465                         }
 466                 }
 467                 ++cvar_purechanges_count;
 468                 // WARNING: this variable is used for the server list
 469                 // NEVER dare to skip this code!
 470                 // Hacks to intentionally appearing as "pure server" even though you DO have
 471                 // modified settings may be punished by removal from the server list.
 472                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 473                 // though.
 474         }
 475         buf_del(h);
 476         if(cvar_changes == "")
 477                 cvar_changes = "// this server runs at default server settings\n";
 478         else
 479                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 480         cvar_changes = strzone(cvar_changes);
 481         if(cvar_purechanges == "")
 482                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 483         else
 484                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 485         cvar_purechanges = strzone(cvar_purechanges);
 486 }
 487
 488 void detect_maptype()
 489 {
 490 #if 0
 491         vector o, v;
 492         float i;
 493
 494         for (;;)
 495         {
 496                 o = world.mins;
 497                 o.x += random() * (world.maxs.x - world.mins.x);
 498                 o.y += random() * (world.maxs.y - world.mins.y);
 499                 o.z += random() * (world.maxs.z - world.mins.z);
 500
 501                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, NULL);
 502                 if(trace_fraction == 1)
 503                         continue;
 504
 505                 v = trace_endpos;
 506
 507                 for(i = 0; i < 64; i += 4)
 508                 {
 509                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
 510         if(trace_fraction == 1)
 511                 continue;
 512                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 513                 }
 514
 515                 break;
 516         }
 517 #endif
 518 }
 519
 520 entity randomseed;
 521 bool RandomSeed_Send(entity this, entity to, int sf)
 522 {
 523         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 524         WriteShort(MSG_ENTITY, this.cnt);
 525         return true;
 526 }
 527 void RandomSeed_Think(entity this)
 528 {
 529         this.cnt = bound(0, floor(random() * 65536), 65535);
 530         this.nextthink = time + 5;
 531
 532         this.SendFlags |= 1;
 533 }
 534 void RandomSeed_Spawn()
 535 {
 536         randomseed = new_pure(randomseed);
 537         setthink(randomseed, RandomSeed_Think);
 538         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 539
 540         getthink(randomseed)(randomseed); // sets random seed and nextthink
 541 }
 542
 543 spawnfunc(__init_dedicated_server)
 544 {
 545         // handler for _init/_init map (only for dedicated server initialization)
 546
 547         world_initialized = -1; // don't complain
 548         cvar = cvar_normal;
 549         cvar_string = cvar_string_normal;
 550         cvar_set = cvar_set_normal;
 551
 552         delete_fn = remove_unsafely;
 553
 554         entity e = spawn();
 555         setthink(e, GotoFirstMap);
 556         e.nextthink = time; // this is usually 1 at this point
 557
 558         e = new(info_player_deathmatch);  // safeguard against player joining
 559
 560         this.classname = "worldspawn"; // safeguard against various stuff ;)
 561
 562         // needs to be done so early because of the constants they create
 563         static_init();
 564         static_init_late();
 565         static_init_precache();
 566
 567         IL_PUSH(g_spawnpoints, e); // just incase
 568
 569         MapInfo_Enumerate();
 570         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 571 }
 572
 573 void __init_dedicated_server_shutdown() {
 574         MapInfo_Shutdown();
 575 }
 576
 577 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override)
 578 {
 579         if(!autocvar_g_campaign)
 580         {
 581                 if(fraglimit_override >= 0) cvar_set("fraglimit", ftos(fraglimit_override));
 582                 if(timelimit_override >= 0) cvar_set("timelimit", ftos(timelimit_override));
 583                 if(leadlimit_override >= 0) cvar_set("leadlimit", ftos(leadlimit_override));
 584                 if(qualifying_override >= 0) cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 585         }
 586         limits_are_set = true;
 587 }
 588
 589 void Map_MarkAsRecent(string m);
 590 float world_already_spawned;
 591 void Nagger_Init();
 592 void ClientInit_Spawn();
 593 void WeaponStats_Init();
 594 void WeaponStats_Shutdown();
 595 spawnfunc(worldspawn)
 596 {
 597         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 598
 599     bool wantrestart = false;
 600         {
 601                 if (!server_is_dedicated)
 602                 {
 603                         // force unloading of server pk3 files when starting a listen server
 604                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 605                         // restore csqc_progname too
 606                         string expect = "csprogs.dat";
 607                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 608                         cvar_set_normal("csqc_progname", expect);
 609                 }
 610                 else
 611                 {
 612                         // Try to use versioned csprogs from pk3
 613                         // Only ever use versioned csprogs.dat files on dedicated servers;
 614                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 615                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 616                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 617                         string select = "csprogs.dat";
 618                         if (fexists(pk3csprogs)) select = pk3csprogs;
 619                         if (cvar_string_normal("csqc_progname") != select)
 620                         {
 621                                 cvar_set_normal("csqc_progname", select);
 622                                 wantrestart = true;
 623                         }
 624                         // Check for updates on startup
 625                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 626                         int sentinel = fopen("progs.txt", FILE_READ);
 627                         if (sentinel >= 0)
 628                         {
 629                                 string switchversion = fgets(sentinel);
 630                                 fclose(sentinel);
 631                                 if (switchversion != "" && switchversion != WATERMARK)
 632                                 {
 633                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 634                                         // if it doesn't exist, assume either:
 635                                         //   a) the current program was overwritten
 636                                         //   b) this is a client only update
 637                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 638                                         if (fexists(newprogs))
 639                                         {
 640                                                 cvar_set_normal("sv_progs", newprogs);
 641                                                 wantrestart = true;
 642                                         }
 643                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 644                                         if (fexists(newcsprogs))
 645                                         {
 646                                                 cvar_set_normal("csqc_progname", newcsprogs);
 647                                                 wantrestart = true;
 648                                         }
 649                                 }
 650                         }
 651                 }
 652                 if (wantrestart)
 653                 {
 654                         LOG_INFOF("Restart requested\n");
 655                         changelevel(mapname);
 656                         // let initialization continue, shutdown depends on it
 657                 }
 658         }
 659
 660         cvar = cvar_normal;
 661         cvar_string = cvar_string_normal;
 662         cvar_set = cvar_set_normal;
 663
 664         if(world_already_spawned)
 665                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 666         world_already_spawned = true;
 667
 668         delete_fn = remove_safely; // during spawning, watch what you remove!
 669
 670         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 671
 672         maxclients = 0;
 673         for (entity head = nextent(NULL); head; head = nextent(head))
 674         {
 675                 ++maxclients;
 676         }
 677
 678         // needs to be done so early because of the constants they create
 679         static_init();
 680
 681         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 682
 683         TemporaryDB = db_create();
 684
 685         // 0 normal
 686         lightstyle(0, "m");
 687
 688         // 1 FLICKER (first variety)
 689         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 690
 691         // 2 SLOW STRONG PULSE
 692         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 693
 694         // 3 CANDLE (first variety)
 695         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 696
 697         // 4 FAST STROBE
 698         lightstyle(4, "mamamamamama");
 699
 700         // 5 GENTLE PULSE 1
 701         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 702
 703         // 6 FLICKER (second variety)
 704         lightstyle(6, "nmonqnmomnmomomno");
 705
 706         // 7 CANDLE (second variety)
 707         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 708
 709         // 8 CANDLE (third variety)
 710         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 711
 712         // 9 SLOW STROBE (fourth variety)
 713         lightstyle(9, "aaaaaaaazzzzzzzz");
 714
 715         // 10 FLUORESCENT FLICKER
 716         lightstyle(10, "mmamammmmammamamaaamammma");
 717
 718         // 11 SLOW PULSE NOT FADE TO BLACK
 719         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 720
 721         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 722
 723         // 63 testing
 724         lightstyle(63, "a");
 725
 726         if(autocvar_g_campaign)
 727                 CampaignPreInit();
 728
 729         Map_MarkAsRecent(mapname);
 730
 731         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 732
 733         InitGameplayMode();
 734         static_init_late();
 735         static_init_precache();
 736         readlevelcvars();
 737         GrappleHookInit();
 738
 739         if(!limits_are_set)
 740                 SetLimits(autocvar_fraglimit_override, autocvar_leadlimit_override, autocvar_timelimit_override, -1);
 741
 742         if(warmup_limit == 0)
 743                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 744
 745         player_count = 0;
 746         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 747         if(bot_waypoints_for_items == 1)
 748                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 749                         bot_waypoints_for_items = 0;
 750
 751         precache();
 752
 753         WaypointSprite_Init();
 754
 755         GameLogInit(); // prepare everything
 756         // NOTE for matchid:
 757         // changing the logic generating it is okay. But:
 758         // it HAS to stay <= 64 chars
 759         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 760         if(autocvar_sv_eventlog)
 761         {
 762                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 763                 matchid = strzone(s);
 764
 765                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 766                 s = ":gameinfo:mutators:LIST";
 767
 768                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 769                 s = M_ARGV(0, string);
 770
 771                 // initialiation stuff, not good in the mutator system
 772                 if(!autocvar_g_use_ammunition)
 773                         s = strcat(s, ":no_use_ammunition");
 774
 775                 // initialiation stuff, not good in the mutator system
 776                 if(autocvar_g_pickup_items == 0)
 777                         s = strcat(s, ":no_pickup_items");
 778                 if(autocvar_g_pickup_items > 0)
 779                         s = strcat(s, ":pickup_items");
 780
 781                 // initialiation stuff, not good in the mutator system
 782                 if(autocvar_g_weaponarena != "0")
 783                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 784
 785                 // TODO to mutator system
 786                 if(autocvar_g_norecoil)
 787                         s = strcat(s, ":norecoil");
 788
 789                 // TODO to mutator system
 790                 if(autocvar_g_powerups == 0)
 791                         s = strcat(s, ":no_powerups");
 792                 if(autocvar_g_powerups > 0)
 793                         s = strcat(s, ":powerups");
 794
 795                 GameLogEcho(s);
 796                 GameLogEcho(":gameinfo:end");
 797         }
 798         else
 799                 matchid = strzone(ftos(random()));
 800
 801         cvar_set("nextmap", "");
 802
 803         SetDefaultAlpha();
 804
 805         if(autocvar_g_campaign)
 806                 CampaignPostInit();
 807
 808         Ban_LoadBans();
 809
 810         MapInfo_Enumerate();
 811         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 812
 813         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 814         {
 815                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 816                 if(fd != -1)
 817                 {
 818                         string s;
 819                         while((s = fgets(fd)))
 820                         {
 821                                 int l = tokenize_console(s);
 822                                 if(l < 2)
 823                                         continue;
 824                                 if(argv(0) == "cd")
 825                                 {
 826                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 827                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 828                                 }
 829                                 else if(argv(0) == "fog")
 830                                 {
 831                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 832                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 833                                 }
 834                                 else if(argv(0) == "set")
 835                                 {
 836                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 837                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 838                                 }
 839                                 else if(argv(0) != "//")
 840                                 {
 841                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 842                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 843                                 }
 844                         }
 845                         fclose(fd);
 846                 }
 847         }
 848
 849         WeaponStats_Init();
 850
 851         Nagger_Init();
 852
 853         next_pingtime = time + 5;
 854
 855         detect_maptype();
 856
 857         // set up information replies for clients and server to use
 858         maplist_reply = strzone(getmaplist());
 859         lsmaps_reply = strzone(getlsmaps());
 860         monsterlist_reply = strzone(getmonsterlist());
 861         for(int i = 0; i < 10; ++i)
 862         {
 863                 string s = getrecords(i);
 864                 if (s)
 865                         records_reply[i] = strzone(s);
 866         }
 867         ladder_reply = strzone(getladder());
 868         rankings_reply = strzone(getrankings());
 869
 870         // begin other init
 871         ClientInit_Spawn();
 872         RandomSeed_Spawn();
 873         PingPLReport_Spawn();
 874
 875         CheatInit();
 876
 877         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 878
 879         // fill sv_curl_serverpackages from .serverpackage files
 880         if (autocvar_sv_curl_serverpackages_auto)
 881         {
 882                 string s = "csprogs-" WATERMARK ".txt";
 883                 // remove automatically managed files from the list to prevent duplicates
 884                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 885                 {
 886                         string pkg = argv(i);
 887                         if (startsWith(pkg, "csprogs-")) continue;
 888                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 889                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 890                         s = cons(s, pkg);
 891                 }
 892                 // add automatically managed files to the list
 893                 #define X(match) MACRO_BEGIN { \
 894                         int fd = search_begin(match, true, false); \
 895                         if (fd >= 0) \
 896                         { \
 897                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 898                                 { \
 899                                         s = cons(s, search_getfilename(fd, i)); \
 900                                 } \
 901                                 search_end(fd); \
 902                         } \
 903                 } MACRO_END
 904                 X("*-serverpackage.txt");
 905                 X("*.serverpackage");
 906                 #undef X
 907                 cvar_set("sv_curl_serverpackages", s);
 908         }
 909
 910         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 911         modname = "Xonotic";
 912         // physics/balance/config changes that count as mod
 913         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 914                 modname = cvar_string("g_mod_physics");
 915         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 916                 modname = cvar_string("g_mod_balance");
 917         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 918                 modname = cvar_string("g_mod_config");
 919         // extra mutators that deserve to count as mod
 920         MUTATOR_CALLHOOK(SetModname);
 921
 922         // save it for later
 923         modname = strzone(modname);
 924
 925         WinningConditionHelper(this); // set worldstatus
 926
 927         world_initialized = 1;
 928 }
 929
 930 spawnfunc(light)
 931 {
 932         //makestatic (this); // Who the f___ did that?
 933         delete(this);
 934 }
 935
 936 string GetGametype()
 937 {
 938         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 939 }
 940
 941 string GetMapname()
 942 {
 943         return mapname;
 944 }
 945
 946 float Map_Count, Map_Current;
 947 string Map_Current_Name;
 948
 949 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 950 float GetMaplistPosition()
 951 {
 952         float pos, idx;
 953         string map;
 954
 955         map = GetMapname();
 956         idx = autocvar_g_maplist_index;
 957
 958         if(idx >= 0)
 959                 if(idx < Map_Count)
 960                         if(map == argv(idx))
 961                                 return idx;
 962
 963         for(pos = 0; pos < Map_Count; ++pos)
 964                 if(map == argv(pos))
 965                         return pos;
 966
 967         // resume normal maplist rotation if current map is not in g_maplist
 968         return idx;
 969 }
 970
 971 float MapHasRightSize(string map)
 972 {
 973         float fh;
 974         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 975         if(autocvar_g_maplist_check_waypoints)
 976         {
 977                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 978                 if(!fexists(strcat("maps/", map, ".waypoints")))
 979                 {
 980                         LOG_TRACE(": no waypoints");
 981                         return false;
 982                 }
 983                 LOG_TRACE(": has waypoints");
 984         }
 985
 986         // open map size restriction file
 987         LOG_TRACE("opensize "); LOG_TRACE(map);
 988         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 989         if(fh >= 0)
 990         {
 991                 float mapmin, mapmax;
 992                 LOG_TRACE(": ok, ");
 993                 mapmin = stof(fgets(fh));
 994                 mapmax = stof(fgets(fh));
 995                 fclose(fh);
 996                 if(player_count < mapmin)
 997                 {
 998                         LOG_TRACE("not enough");
 999                         return false;
1000                 }
1001                 if(player_count > mapmax)
1002                 {
1003                         LOG_TRACE("too many");
1004                         return false;
1005                 }
1006                 LOG_TRACE("right size");
1007                 return true;
1008         }
1009         LOG_TRACE(": not found");
1010         return true;
1011 }
1012
1013 string Map_Filename(float position)
1014 {
1015         return strcat("maps/", argv(position), ".bsp");
1016 }
1017
1018 void Map_MarkAsRecent(string m)
1019 {
1020         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1021 }
1022
1023 float Map_IsRecent(string m)
1024 {
1025         return strhasword(autocvar_g_maplist_mostrecent, m);
1026 }
1027
1028 float Map_Check(float position, float pass)
1029 {
1030         string filename;
1031         string map_next;
1032         map_next = argv(position);
1033         if(pass <= 1)
1034         {
1035                 if(Map_IsRecent(map_next))
1036                         return 0;
1037         }
1038         filename = Map_Filename(position);
1039         if(MapInfo_CheckMap(map_next))
1040         {
1041                 if(pass == 2)
1042                         return 1;
1043                 if(MapHasRightSize(map_next))
1044                         return 1;
1045                 return 0;
1046         }
1047         else
1048                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1049
1050         return 0;
1051 }
1052
1053 void Map_Goto_SetStr(string nextmapname)
1054 {
1055         if(getmapname_stored != "")
1056                 strunzone(getmapname_stored);
1057         if(nextmapname == "")
1058                 getmapname_stored = "";
1059         else
1060                 getmapname_stored = strzone(nextmapname);
1061 }
1062
1063 void Map_Goto_SetFloat(float position)
1064 {
1065         cvar_set("g_maplist_index", ftos(position));
1066         Map_Goto_SetStr(argv(position));
1067 }
1068
1069 void Map_Goto(float reinit)
1070 {
1071         MapInfo_LoadMap(getmapname_stored, reinit);
1072 }
1073
1074 // return codes of map selectors:
1075 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1076 //   -2 = permanent failure
1077 float() MaplistMethod_Iterate = // usual method
1078 {
1079         float pass, i;
1080
1081         LOG_TRACE("Trying MaplistMethod_Iterate");
1082
1083         for(pass = 1; pass <= 2; ++pass)
1084         {
1085                 for(i = 1; i < Map_Count; ++i)
1086                 {
1087                         float mapindex;
1088                         mapindex = (i + Map_Current) % Map_Count;
1089                         if(Map_Check(mapindex, pass))
1090                                 return mapindex;
1091                 }
1092         }
1093         return -1;
1094 }
1095
1096 float() MaplistMethod_Repeat = // fallback method
1097 {
1098         LOG_TRACE("Trying MaplistMethod_Repeat");
1099
1100         if(Map_Check(Map_Current, 2))
1101                 return Map_Current;
1102         return -2;
1103 }
1104
1105 float() MaplistMethod_Random = // random map selection
1106 {
1107         float i, imax;
1108
1109         LOG_TRACE("Trying MaplistMethod_Random");
1110
1111         imax = 42;
1112
1113         for(i = 0; i <= imax; ++i)
1114         {
1115                 float mapindex;
1116                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1117                 if(Map_Check(mapindex, 1))
1118                         return mapindex;
1119         }
1120         return -1;
1121 }
1122
1123 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1124 // the exponent sets a bias on the map selection:
1125 // the higher the exponent, the less likely "shortly repeated" same maps are
1126 {
1127         float i, j, imax, insertpos;
1128
1129         LOG_TRACE("Trying MaplistMethod_Shuffle");
1130
1131         imax = 42;
1132
1133         for(i = 0; i <= imax; ++i)
1134         {
1135                 string newlist;
1136
1137                 // now reinsert this at another position
1138                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1139                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1140                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1141                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1142
1143                 // insert the current map there
1144                 newlist = "";
1145                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1146                         newlist = strcat(newlist, " ", argv(j));
1147                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1148                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1149                         newlist = strcat(newlist, " ", argv(j));
1150                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1151                 cvar_set("g_maplist", newlist);
1152                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1153
1154                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1155                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1156                 if(Map_Check(Map_Current, 1))
1157                         return Map_Current;
1158         }
1159         return -1;
1160 }
1161
1162 void Maplist_Init()
1163 {
1164         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1165         float i;
1166         for (i = 0; i < Map_Count; ++i)
1167                 if (Map_Check(i, 2))
1168                         break;
1169         if (i == Map_Count)
1170         {
1171                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1172                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1173                 if(autocvar_g_maplist_shuffle)
1174                         ShuffleMaplist();
1175                 localcmd("\nmenu_cmd sync\n");
1176                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1177         }
1178         if(Map_Count == 0)
1179                 error("empty maplist, cannot select a new map");
1180         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1181
1182         if(Map_Current_Name)
1183                 strunzone(Map_Current_Name);
1184         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1185         // this may or may not be correct, but who cares, in the worst case a map
1186         // isn't chosen in the first pass that should have been
1187 }
1188
1189 string GetNextMap()
1190 {
1191         float nextMap;
1192
1193         Maplist_Init();
1194         nextMap = -1;
1195
1196         if(nextMap == -1)
1197                 if(autocvar_g_maplist_shuffle > 0)
1198                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1199
1200         if(nextMap == -1)
1201                 if(autocvar_g_maplist_selectrandom)
1202                         nextMap = MaplistMethod_Random();
1203
1204         if(nextMap == -1)
1205                 nextMap = MaplistMethod_Iterate();
1206
1207         if(nextMap == -1)
1208                 nextMap = MaplistMethod_Repeat();
1209
1210         if(nextMap >= 0)
1211         {
1212                 Map_Goto_SetFloat(nextMap);
1213                 return getmapname_stored;
1214         }
1215
1216         return "";
1217 }
1218
1219 float DoNextMapOverride(float reinit)
1220 {
1221         if(autocvar_g_campaign)
1222         {
1223                 CampaignPostIntermission();
1224                 alreadychangedlevel = true;
1225                 return true;
1226         }
1227         if(autocvar_quit_when_empty)
1228         {
1229                 if(player_count <= currentbots)
1230                 {
1231                         localcmd("quit\n");
1232                         alreadychangedlevel = true;
1233                         return true;
1234                 }
1235         }
1236         if(autocvar_quit_and_redirect != "")
1237         {
1238                 redirection_target = strzone(autocvar_quit_and_redirect);
1239                 alreadychangedlevel = true;
1240                 return true;
1241         }
1242         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1243         {
1244                 localcmd("restart\n");
1245                 alreadychangedlevel = true;
1246                 return true;
1247         }
1248         if(autocvar_nextmap != "")
1249         {
1250                 string m;
1251                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1252                 cvar_set("nextmap",m);
1253
1254                 if(!m || gametypevote)
1255                         return false;
1256                 if(autocvar_sv_vote_gametype)
1257                 {
1258                         Map_Goto_SetStr(m);
1259                         return false;
1260                 }
1261
1262                 if(MapInfo_CheckMap(m))
1263                 {
1264                         Map_Goto_SetStr(m);
1265                         Map_Goto(reinit);
1266                         alreadychangedlevel = true;
1267                         return true;
1268                 }
1269         }
1270         if(!reinit && autocvar_lastlevel)
1271         {
1272                 cvar_settemp_restore();
1273                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1274                 alreadychangedlevel = true;
1275                 return true;
1276         }
1277         return false;
1278 }
1279
1280 void GotoNextMap(float reinit)
1281 {
1282         //string nextmap;
1283         //float n, nummaps;
1284         //string s;
1285         if (alreadychangedlevel)
1286                 return;
1287         alreadychangedlevel = true;
1288
1289         string nextMap;
1290
1291         nextMap = GetNextMap();
1292         if(nextMap == "")
1293                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1294         Map_Goto(reinit);
1295 }
1296
1297
1298 /*
1299 ============
1300 IntermissionThink
1301
1302 When the player presses attack or jump, change to the next level
1303 ============
1304 */
1305 .float autoscreenshot;
1306 void IntermissionThink(entity this)
1307 {
1308         FixIntermissionClient(this);
1309         CSQCMODEL_AUTOUPDATE(this); // PlayerPostThink returns before calling this during intermission, so run it here
1310
1311         float server_screenshot = (autocvar_sv_autoscreenshot && this.cvar_cl_autoscreenshot);
1312         float client_screenshot = (this.cvar_cl_autoscreenshot == 2);
1313
1314         if( (server_screenshot || client_screenshot)
1315                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1316         {
1317                 this.autoscreenshot = -1;
1318                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1319                 return;
1320         }
1321
1322         if (time < intermission_exittime)
1323                 return;
1324
1325         if(!mapvote_initialized)
1326                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1327                         return;
1328
1329         MapVote_Start();
1330 }
1331
1332 /*
1333 ============
1334 FindIntermission
1335
1336 Returns the entity to view from
1337 ============
1338 */
1339 /*
1340 entity FindIntermission()
1341 {
1342         local   entity spot;
1343         local   float cyc;
1344
1345 // look for info_intermission first
1346         spot = find(NULL, classname, "info_intermission");
1347         if (spot)
1348         {       // pick a random one
1349                 cyc = random() * 4;
1350                 while (cyc > 1)
1351                 {
1352                         spot = find(spot, classname, "info_intermission");
1353                         if (!spot)
1354                                 spot = find(spot, classname, "info_intermission");
1355                         cyc = cyc - 1;
1356                 }
1357                 return spot;
1358         }
1359
1360 // then look for the start position
1361         spot = find(NULL, classname, "info_player_start");
1362         if (spot)
1363                 return spot;
1364
1365 // testinfo_player_start is only found in regioned levels
1366         spot = find(NULL, classname, "testplayerstart");
1367         if (spot)
1368                 return spot;
1369
1370 // then look for the start position
1371         spot = find(NULL, classname, "info_player_deathmatch");
1372         if (spot)
1373                 return spot;
1374
1375         //objerror ("FindIntermission: no spot");
1376         return NULL;
1377 }
1378 */
1379
1380 /*
1381 ===============================================================================
1382
1383 RULES
1384
1385 ===============================================================================
1386 */
1387
1388 void DumpStats(float final)
1389 {
1390         float file;
1391         string s;
1392         float to_console;
1393         float to_eventlog;
1394         float to_file;
1395         float i;
1396
1397         to_console = autocvar_sv_logscores_console;
1398         to_eventlog = autocvar_sv_eventlog;
1399         to_file = autocvar_sv_logscores_file;
1400
1401         if(!final)
1402         {
1403                 to_console = true; // always print printstats replies
1404                 to_eventlog = false; // but never print them to the event log
1405         }
1406
1407         if(to_eventlog)
1408                 if(autocvar_sv_eventlog_console)
1409                         to_console = false; // otherwise we get the output twice
1410
1411         if(final)
1412                 s = ":scores:";
1413         else
1414                 s = ":status:";
1415         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1416
1417         if(to_console)
1418                 LOG_INFO(s, "\n");
1419         if(to_eventlog)
1420                 GameLogEcho(s);
1421
1422         file = -1;
1423         if(to_file)
1424         {
1425                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1426                 if(file == -1)
1427                         to_file = false;
1428                 else
1429                         fputs(file, strcat(s, "\n"));
1430         }
1431
1432         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1433         if(to_console)
1434                 LOG_INFO(s, "\n");
1435         if(to_eventlog)
1436                 GameLogEcho(s);
1437         if(to_file)
1438                 fputs(file, strcat(s, "\n"));
1439
1440         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1441                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1442                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1443                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1444                         s = strcat(s, ftos(it.team), ":");
1445                 else
1446                         s = strcat(s, "spectator:");
1447
1448                 if(to_console)
1449                         LOG_INFO(s, it.netname, "\n");
1450                 if(to_eventlog)
1451                         GameLogEcho(strcat(s, ftos(it.playerid), ":", it.netname));
1452                 if(to_file)
1453                         fputs(file, strcat(s, it.netname, "\n"));
1454         ));
1455
1456         if(teamplay)
1457         {
1458                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1459                 if(to_console)
1460                         LOG_INFO(s, "\n");
1461                 if(to_eventlog)
1462                         GameLogEcho(s);
1463                 if(to_file)
1464                         fputs(file, strcat(s, "\n"));
1465
1466                 for(i = 1; i < 16; ++i)
1467                 {
1468                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1469                         s = strcat(s, ":", ftos(i));
1470                         if(to_console)
1471                                 LOG_INFO(s, "\n");
1472                         if(to_eventlog)
1473                                 GameLogEcho(s);
1474                         if(to_file)
1475                                 fputs(file, strcat(s, "\n"));
1476                 }
1477         }
1478
1479         if(to_console)
1480                 LOG_INFO(":end\n");
1481         if(to_eventlog)
1482                 GameLogEcho(":end");
1483         if(to_file)
1484         {
1485                 fputs(file, ":end\n");
1486                 fclose(file);
1487         }
1488 }
1489
1490 void FixIntermissionClient(entity e)
1491 {
1492         if(!e.autoscreenshot) // initial call
1493         {
1494                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1495                 e.health = -2342;
1496                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1497                 e.solid = SOLID_NOT;
1498                 set_movetype(e, MOVETYPE_NONE);
1499                 e.takedamage = DAMAGE_NO;
1500                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1501                 {
1502                     .entity weaponentity = weaponentities[slot];
1503                         if(e.(weaponentity))
1504                         {
1505                                 e.(weaponentity).effects = EF_NODRAW;
1506                                 if (e.(weaponentity).weaponchild)
1507                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1508                         }
1509                 }
1510                 if(IS_REAL_CLIENT(e))
1511                 {
1512                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1513                         RandomSelection_Init();
1514                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1515                                 RandomSelection_AddString(it, 1, 1);
1516                         ));
1517                         if (RandomSelection_chosen_string != "")
1518                         {
1519                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1520                         }
1521                         msg_entity = e;
1522                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1523                 }
1524         }
1525 }
1526
1527 /*
1528 go to the next level for deathmatch
1529 only called if a time or frag limit has expired
1530 */
1531 void NextLevel()
1532 {
1533         gameover = true;
1534
1535         intermission_running = 1;
1536
1537 // enforce a wait time before allowing changelevel
1538         if(player_count > 0)
1539                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1540         else
1541                 intermission_exittime = -1;
1542
1543         /*
1544         WriteByte (MSG_ALL, SVC_CDTRACK);
1545         WriteByte (MSG_ALL, 3);
1546         WriteByte (MSG_ALL, 3);
1547         // done in FixIntermission
1548         */
1549
1550         //pos = FindIntermission ();
1551
1552         VoteReset();
1553
1554         DumpStats(true);
1555
1556         // send statistics
1557         PlayerStats_GameReport(true);
1558         WeaponStats_Shutdown();
1559
1560         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1561
1562         if(autocvar_sv_eventlog)
1563                 GameLogEcho(":gameover");
1564
1565         GameLogClose();
1566
1567         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1568                 FixIntermissionClient(it);
1569                 if(it.winning)
1570                         bprint(it.netname, " ^7wins.\n");
1571         ));
1572
1573         target_music_kill();
1574
1575         if(autocvar_g_campaign)
1576                 CampaignPreIntermission();
1577
1578         MUTATOR_CALLHOOK(MatchEnd);
1579
1580         localcmd("\nsv_hook_gameend\n");
1581 }
1582
1583 /*
1584 ============
1585 CheckRules_Player
1586
1587 Exit deathmatch games upon conditions
1588 ============
1589 */
1590 void CheckRules_Player(entity this)
1591 {
1592         if (gameover)   // someone else quit the game already
1593                 return;
1594
1595         if(!IS_DEAD(this))
1596                 this.play_time += frametime;
1597
1598         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1599         //   (div0: and that in CheckRules_World please)
1600 }
1601
1602
1603 float InitiateSuddenDeath()
1604 {
1605         // Check first whether normal overtimes could be added before initiating suddendeath mode
1606         // - for this timelimit_overtime needs to be >0 of course
1607         // - also check the winning condition calculated in the previous frame and only add normal overtime
1608         //   again, if at the point at which timelimit would be extended again, still no winner was found
1609         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1610         {
1611                 return 1; // need to call InitiateOvertime later
1612         }
1613         else
1614         {
1615                 if(!checkrules_suddendeathend)
1616                 {
1617                         if(autocvar_g_campaign)
1618                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1619                         else
1620                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1621                         if(g_race && !g_race_qualifying)
1622                                 race_StartCompleting();
1623                 }
1624                 return 0;
1625         }
1626 }
1627
1628 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1629 {
1630         ++checkrules_overtimesadded;
1631         //add one more overtime by simply extending the timelimit
1632         float tl;
1633         tl = autocvar_timelimit;
1634         tl += autocvar_timelimit_overtime;
1635         cvar_set("timelimit", ftos(tl));
1636
1637         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1638 }
1639
1640 float GetWinningCode(float fraglimitreached, float equality)
1641 {
1642         if(autocvar_g_campaign == 1)
1643                 if(fraglimitreached)
1644                         return WINNING_YES;
1645                 else
1646                         return WINNING_NO;
1647
1648         else
1649                 if(equality)
1650                         if(fraglimitreached)
1651                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1652                         else
1653                                 return WINNING_NEVER;
1654                 else
1655                         if(fraglimitreached)
1656                                 return WINNING_YES;
1657                         else
1658                                 return WINNING_NO;
1659 }
1660
1661 // set the .winning flag for exactly those players with a given field value
1662 void SetWinners(.float field, float value)
1663 {
1664         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1665 }
1666
1667 // set the .winning flag for those players with a given field value
1668 void AddWinners(.float field, float value)
1669 {
1670         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1671                 if(it.(field) == value)
1672                         it.winning = 1;
1673         ));
1674 }
1675
1676 // clear the .winning flags
1677 void ClearWinners()
1678 {
1679         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1680 }
1681
1682 void ShuffleMaplist()
1683 {
1684         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1685 }
1686
1687 float leaderfrags;
1688 float WinningCondition_Scores(float limit, float leadlimit)
1689 {
1690         float limitreached;
1691
1692         // TODO make everything use THIS winning condition (except LMS)
1693         WinningConditionHelper(NULL);
1694
1695         if(teamplay)
1696         {
1697                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1698                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1699                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1700                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1701         }
1702
1703         ClearWinners();
1704         if(WinningConditionHelper_winner)
1705                 WinningConditionHelper_winner.winning = 1;
1706         if(WinningConditionHelper_winnerteam >= 0)
1707                 SetWinners(team, WinningConditionHelper_winnerteam);
1708
1709         if(WinningConditionHelper_lowerisbetter)
1710         {
1711                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1712                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1713                 limit = -limit;
1714         }
1715
1716         if(WinningConditionHelper_zeroisworst)
1717                 leadlimit = 0; // not supported in this mode
1718
1719         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1720         // these modes always score in increments of 1, thus this makes sense
1721         {
1722                 if(leaderfrags != WinningConditionHelper_topscore)
1723                 {
1724                         leaderfrags = WinningConditionHelper_topscore;
1725
1726                         if (limit)
1727                         if (leaderfrags == limit - 1)
1728                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1729                         else if (leaderfrags == limit - 2)
1730                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1731                         else if (leaderfrags == limit - 3)
1732                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1733                 }
1734         }
1735
1736         limitreached = false;
1737         if(limit)
1738                 if(WinningConditionHelper_topscore >= limit)
1739                         limitreached = true;
1740         if(leadlimit)
1741         {
1742                 float leadlimitreached;
1743                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1744                 if(autocvar_leadlimit_and_fraglimit)
1745                         limitreached = (limitreached && leadlimitreached);
1746                 else
1747                         limitreached = (limitreached || leadlimitreached);
1748         }
1749
1750         if(limit)
1751                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1752
1753         return GetWinningCode(
1754                 WinningConditionHelper_topscore && limitreached,
1755                 WinningConditionHelper_equality
1756         );
1757 }
1758
1759 float WinningCondition_RanOutOfSpawns()
1760 {
1761         if(have_team_spawns <= 0)
1762                 return WINNING_NO;
1763
1764         if(!autocvar_g_spawn_useallspawns)
1765                 return WINNING_NO;
1766
1767         if(!some_spawn_has_been_used)
1768                 return WINNING_NO;
1769
1770         team1_score = team2_score = team3_score = team4_score = 0;
1771
1772         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1773                 switch(it.team)
1774                 {
1775                         case NUM_TEAM_1: team1_score = 1; break;
1776                         case NUM_TEAM_2: team2_score = 1; break;
1777                         case NUM_TEAM_3: team3_score = 1; break;
1778                         case NUM_TEAM_4: team4_score = 1; break;
1779                 }
1780         ));
1781
1782         IL_EACH(g_spawnpoints, true,
1783         {
1784                 switch(it.team)
1785                 {
1786                         case NUM_TEAM_1: team1_score = 1; break;
1787                         case NUM_TEAM_2: team2_score = 1; break;
1788                         case NUM_TEAM_3: team3_score = 1; break;
1789                         case NUM_TEAM_4: team4_score = 1; break;
1790                 }
1791         });
1792
1793         ClearWinners();
1794         if(team1_score + team2_score + team3_score + team4_score == 0)
1795         {
1796                 checkrules_equality = true;
1797                 return WINNING_YES;
1798         }
1799         else if(team1_score + team2_score + team3_score + team4_score == 1)
1800         {
1801                 float t, i;
1802                 if(team1_score)
1803                         t = NUM_TEAM_1;
1804                 else if(team2_score)
1805                         t = NUM_TEAM_2;
1806                 else if(team3_score)
1807                         t = NUM_TEAM_3;
1808                 else // if(team4_score)
1809                         t = NUM_TEAM_4;
1810                 CheckAllowedTeams(NULL);
1811                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1812                 {
1813                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1814                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1815                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1816                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1817                 }
1818
1819                 AddWinners(team, t);
1820                 return WINNING_YES;
1821         }
1822         else
1823                 return WINNING_NO;
1824 }
1825
1826 /*
1827 ============
1828 CheckRules_World
1829
1830 Exit deathmatch games upon conditions
1831 ============
1832 */
1833 void CheckRules_World()
1834 {
1835         float timelimit;
1836         float fraglimit;
1837         float leadlimit;
1838
1839         VoteThink();
1840         MapVote_Think();
1841
1842         SetDefaultAlpha();
1843
1844         if (gameover)   // someone else quit the game already
1845         {
1846                 if(player_count == 0) // Nobody there? Then let's go to the next map
1847                         MapVote_Start();
1848                         // this will actually check the player count in the next frame
1849                         // again, but this shouldn't hurt
1850                 return;
1851         }
1852
1853         timelimit = autocvar_timelimit * 60;
1854         fraglimit = autocvar_fraglimit;
1855         leadlimit = autocvar_leadlimit;
1856
1857         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1858         {
1859                 if(timelimit > 0)
1860                         timelimit = 0; // timelimit is not made for warmup
1861                 if(fraglimit > 0)
1862                         fraglimit = 0; // no fraglimit for now
1863                 leadlimit = 0; // no leadlimit for now
1864         }
1865
1866         if(timelimit > 0)
1867         {
1868                 timelimit += game_starttime;
1869         }
1870         else if (timelimit < 0)
1871         {
1872                 // endmatch
1873                 NextLevel();
1874                 return;
1875         }
1876
1877         float wantovertime;
1878         wantovertime = 0;
1879
1880         if(timelimit > game_starttime)
1881                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1882         else
1883                 game_completion_ratio = 0;
1884
1885         if(checkrules_suddendeathend)
1886         {
1887                 if(!checkrules_suddendeathwarning)
1888                 {
1889                         checkrules_suddendeathwarning = true;
1890                         if(g_race && !g_race_qualifying)
1891                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1892                         else
1893                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1894                 }
1895         }
1896         else
1897         {
1898                 if (timelimit && time >= timelimit)
1899                 {
1900                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1901                         {
1902                                 float totalplayers;
1903                                 float playerswithlaps;
1904                                 float readyplayers;
1905                                 totalplayers = playerswithlaps = readyplayers = 0;
1906                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1907                                         ++totalplayers;
1908                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1909                                                 ++playerswithlaps;
1910                                         if(it.ready)
1911                                                 ++readyplayers;
1912                                 ));
1913
1914                                 // at least 2 of the players have completed a lap: start the RACE
1915                                 // otherwise, the players should end the qualifying on their own
1916                                 if(readyplayers || playerswithlaps >= 2)
1917                                 {
1918                                         checkrules_suddendeathend = 0;
1919                                         ReadyRestart(); // go to race
1920                                         return;
1921                                 }
1922                                 else
1923                                         wantovertime |= InitiateSuddenDeath();
1924                         }
1925                         else
1926                                 wantovertime |= InitiateSuddenDeath();
1927                 }
1928         }
1929
1930         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1931         {
1932                 NextLevel();
1933                 return;
1934         }
1935
1936         int checkrules_status = WinningCondition_RanOutOfSpawns();
1937         if(checkrules_status == WINNING_YES)
1938                 bprint("Hey! Someone ran out of spawns!\n");
1939         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1940                 checkrules_status = M_ARGV(0, float);
1941         else
1942                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1943
1944         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1945         {
1946                 checkrules_status = WINNING_NEVER;
1947                 checkrules_overtimesadded = -1;
1948                 wantovertime |= InitiateSuddenDeath();
1949         }
1950
1951         if(checkrules_status == WINNING_NEVER)
1952                 // equality cases! Nobody wins if the overtime ends in a draw.
1953                 ClearWinners();
1954
1955         if(wantovertime)
1956         {
1957                 if(checkrules_status == WINNING_NEVER)
1958                         InitiateOvertime();
1959                 else
1960                         checkrules_status = WINNING_YES;
1961         }
1962
1963         if(checkrules_suddendeathend)
1964                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1965                         checkrules_status = WINNING_YES;
1966
1967         if(checkrules_status == WINNING_YES)
1968         {
1969                 //print("WINNING\n");
1970                 NextLevel();
1971         }
1972 }
1973
1974 string GotoMap(string m)
1975 {
1976         m = GameTypeVote_MapInfo_FixName(m);
1977         if (!m)
1978                 return "The map you suggested is not available on this server.";
1979         if (!autocvar_sv_vote_gametype)
1980         if(!MapInfo_CheckMap(m))
1981                 return "The map you suggested does not support the current game mode.";
1982         cvar_set("nextmap", m);
1983         cvar_set("timelimit", "-1");
1984         if(mapvote_initialized || alreadychangedlevel)
1985         {
1986                 if(DoNextMapOverride(0))
1987                         return "Map switch initiated.";
1988                 else
1989                         return "Hm... no. For some reason I like THIS map more.";
1990         }
1991         else
1992                 return "Map switch will happen after scoreboard.";
1993 }
1994
1995 bool autocvar_sv_gameplayfix_multiplethinksperframe;
1996 void RunThink(entity this)
1997 {
1998         // don't let things stay in the past.
1999         // it is possible to start that way by a trigger with a local time.
2000         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2001                 return;
2002
2003         float oldtime = time; // do we need to save this?
2004
2005         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2006         {
2007                 time = max(oldtime, this.nextthink);
2008                 this.nextthink = 0;
2009
2010                 if(getthink(this))
2011                         getthink(this)(this);
2012                 // mods often set nextthink to time to cause a think every frame,
2013                 // we don't want to loop in that case, so exit if the new nextthink is
2014                 // <= the time the qc was told, also exit if it is past the end of the
2015                 // frame
2016                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2017                         break;
2018         }
2019
2020         time = oldtime;
2021 }
2022
2023 bool autocvar_sv_freezenonclients;
2024 bool autocvar_sv_gameplayfix_delayprojectiles;
2025 void Physics_Frame()
2026 {
2027         if(autocvar_sv_freezenonclients)
2028                 return;
2029
2030         FOREACH_ENTITY_FLOAT(pure_data, false,
2031         {
2032                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2033                         continue;
2034
2035                 set_movetype(it, it.move_movetype);
2036
2037                 if(it.move_movetype == MOVETYPE_NONE)
2038                         continue;
2039
2040                 if(it.move_qcphysics)
2041                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2042
2043                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2044                 {
2045                         // handle thinking here
2046                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2047                                 RunThink(it);
2048                 }
2049         });
2050
2051         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2052                 return;
2053
2054         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2055         {
2056                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2057                         continue;
2058                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2059         });
2060 }
2061
2062 void systems_update();
2063 void EndFrame()
2064 {
2065         anticheat_endframe();
2066
2067         Physics_Frame();
2068
2069         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2070                 entity e = IS_SPEC(it) ? it.enemy : it;
2071                 if (e.typehitsound) {
2072                         it.typehit_time = time;
2073                 } else if (e.damage_dealt) {
2074                         it.hit_time = time;
2075                         it.damage_dealt_total += ceil(e.damage_dealt);
2076                 }
2077         });
2078         // add 1 frametime because after this, engine SV_Physics
2079         // increases time by a frametime and then networks the frame
2080         // add another frametime because client shows everything with
2081         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2082         // needed!
2083         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2084         FOREACH_CLIENT(true, {
2085                 it.typehitsound = false;
2086                 it.damage_dealt = 0;
2087                 antilag_record(it, CS(it), altime);
2088         });
2089         IL_EACH(g_monsters, true,
2090         {
2091                 antilag_record(it, it, altime);
2092         });
2093         systems_update();
2094         IL_ENDFRAME();
2095 }
2096
2097
2098 /*
2099  * RedirectionThink:
2100  * returns true if redirecting
2101  */
2102 float redirection_timeout;
2103 float redirection_nextthink;
2104 float RedirectionThink()
2105 {
2106         float clients_found;
2107
2108         if(redirection_target == "")
2109                 return false;
2110
2111         if(!redirection_timeout)
2112         {
2113                 cvar_set("sv_public", "-2");
2114                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2115                 if(redirection_target == "self")
2116                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2117                 else
2118                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2119         }
2120
2121         if(time < redirection_nextthink)
2122                 return true;
2123
2124         redirection_nextthink = time + 1;
2125
2126         clients_found = 0;
2127         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2128                 // TODO add timer
2129                 LOG_INFO("Redirecting: sending connect command to ", it.netname, "\n");
2130                 if(redirection_target == "self")
2131                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2132                 else
2133                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2134                 ++clients_found;
2135         ));
2136
2137         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2138
2139         if(time > redirection_timeout || clients_found == 0)
2140                 localcmd("\nwait; wait; wait; quit\n");
2141
2142         return true;
2143 }
2144
2145 void TargetMusic_RestoreGame();
2146 void RestoreGame()
2147 {
2148         // Loaded from a save game
2149         // some things then break, so let's work around them...
2150
2151         // Progs DB (capture records)
2152         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2153
2154         // Mapinfo
2155         MapInfo_Shutdown();
2156         MapInfo_Enumerate();
2157         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2158         WeaponStats_Init();
2159
2160         TargetMusic_RestoreGame();
2161 }
2162
2163 void Shutdown()
2164 {
2165         gameover = 2;
2166
2167         if(world_initialized > 0)
2168         {
2169                 world_initialized = 0;
2170                 LOG_TRACE("Saving persistent data...");
2171                 Ban_SaveBans();
2172
2173                 // playerstats with unfinished match
2174                 PlayerStats_GameReport(false);
2175
2176                 if(!cheatcount_total)
2177                 {
2178                         if(autocvar_sv_db_saveasdump)
2179                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2180                         else
2181                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2182                 }
2183                 if(autocvar_developer)
2184                 {
2185                         if(autocvar_sv_db_saveasdump)
2186                                 db_dump(TemporaryDB, "server-temp.db");
2187                         else
2188                                 db_save(TemporaryDB, "server-temp.db");
2189                 }
2190                 CheatShutdown(); // must be after cheatcount check
2191                 db_close(ServerProgsDB);
2192                 db_close(TemporaryDB);
2193                 LOG_TRACE("Saving persistent data... done!");
2194                 // tell the bot system the game is ending now
2195                 bot_endgame();
2196
2197                 WeaponStats_Shutdown();
2198                 MapInfo_Shutdown();
2199         }
2200         else if(world_initialized == 0)
2201         {
2202                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2203         }
2204         else
2205         {
2206                 __init_dedicated_server_shutdown();
2207         }
2208 }