qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("developer");
 276                 BADCVAR("g_banned_list");
 277                 BADCVAR("log_dest_udp");
 278                 BADCVAR("log_file");
 279                 BADCVAR("net_address");
 280                 BADCVAR("net_address_ipv6");
 281                 BADCVAR("port");
 282                 BADCVAR("savedgamecfg");
 283                 BADCVAR("serverconfig");
 284                 BADCVAR("sv_heartbeatperiod");
 285                 BADCVAR("sv_vote_master_password");
 286                 BADCVAR("sys_colortranslation");
 287                 BADCVAR("sys_specialcharactertranslation");
 288                 BADCVAR("timestamps");
 289                 BADPREFIX("developer_");
 290                 BADPREFIX("g_ban_");
 291                 BADPREFIX("g_chat_flood_");
 292                 BADPREFIX("g_voice_flood_");
 293                 BADPREFIX("rcon_");
 294                 BADPREFIX("settemp_");
 295                 BADPREFIX("sv_allowdownloads_");
 296                 BADPREFIX("sv_autodemo");
 297                 BADPREFIX("sv_curl_");
 298                 BADPREFIX("sv_eventlog");
 299                 BADPREFIX("sv_logscores_");
 300                 BADPREFIX("sv_master");
 301                 BADPREFIX("sv_weaponstats_");
 302
 303                 // these can contain player IDs, so better hide
 304                 BADCVAR("g_forced_team_red");
 305                 BADCVAR("g_forced_team_blue");
 306                 BADCVAR("g_forced_team_yellow");
 307                 BADCVAR("g_forced_team_pink");
 308
 309                 // mapinfo
 310                 BADCVAR("timelimit");
 311                 BADCVAR("fraglimit");
 312                 BADCVAR("leadlimit");
 313                 BADCVAR("g_tdm_teams");
 314                 BADCVAR("g_keyhunt_teams");
 315                 BADCVAR("g_domination_default_teams");
 316                 BADCVAR("g_race_qualifying_timelimit");
 317                 BADCVAR("g_lms");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_ca");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_dm");
 323                 BADCVAR("g_domination");
 324                 BADCVAR("g_keyhunt");
 325                 BADCVAR("g_keyhunt_teams");
 326                 BADCVAR("g_onslaught");
 327                 BADCVAR("g_race");
 328                 BADCVAR("g_cts");
 329                 BADCVAR("g_runematch");
 330                 BADCVAR("g_tdm");
 331                 BADCVAR("g_nexball");
 332                 BADCVAR("g_keepaway");
 333                 BADCVAR("teamplay");
 334
 335                 // long
 336                 BADCVAR("hostname");
 337                 BADCVAR("g_maplist");
 338                 BADCVAR("g_maplist_mostrecent");
 339                 BADCVAR("sv_motd");
 340
 341                 v = cvar_string(k);
 342                 d = cvar_defstring(k);
 343                 if(v == d)
 344                         continue;
 345
 346                 if(adding)
 347                 {
 348                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 349                         if(strlen(cvar_changes) > 16384)
 350                         {
 351                                 cvar_changes = "// too many settings have been changed to show them here\n";
 352                                 adding = 0;
 353                         }
 354                 }
 355
 356                 // now check if the changes are actually gameplay relevant
 357
 358                 // does nothing visible
 359                 BADCVAR("captureleadlimit_override");
 360                 BADCVAR("g_arena_point_leadlimit");
 361                 BADCVAR("g_ca_point_leadlimit");
 362                 BADCVAR("g_ctf_capture_leadlimit");
 363                 BADCVAR("g_domination_point_leadlimit");
 364                 BADCVAR("g_keyhunt_point_leadlimit");
 365                 BADCVAR("g_nexball_goalleadlimit");
 366                 BADCVAR("g_runematch_point_leadlimit");
 367                 BADCVAR("leadlimit_and_fraglimit");
 368                 BADCVAR("leadlimit_override");
 369                 BADCVAR("sv_checkforpacketsduringsleep");
 370                 BADPREFIX("crypto_");
 371                 BADPREFIX("g_chat_");
 372                 BADPREFIX("net_");
 373                 BADPREFIX("prvm_");
 374                 BADPREFIX("sv_fragmessage_");
 375                 BADPREFIX("sv_vote_");
 376                 BADPREFIX("timelimit_");
 377
 378                 // allowed changes to server admins (please sync this to server.cfg)
 379                 // vi commands:
 380                 //   :/"impure"/,$d
 381                 //   :g!,^\/\/[^ /],d
 382                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 383                 //   :%!sort
 384                 // yes, this does contain some redundant stuff, don't really care
 385                 BADCVAR("bot_number");
 386                 BADCVAR("bot_prefix");
 387                 BADCVAR("bot_suffix");
 388                 BADCVAR("capturelimit_override");
 389                 BADCVAR("fraglimit_override");
 390                 BADCVAR("gametype");
 391                 BADCVAR("g_antilag");
 392                 BADCVAR("g_balance_teams");
 393                 BADCVAR("g_balance_teams_force");
 394                 BADCVAR("g_ban_sync_trusted_servers");
 395                 BADCVAR("g_ban_sync_uri");
 396                 BADCVAR("g_ctf_capture_limit");
 397                 BADCVAR("g_ctf_ignore_frags");
 398                 BADCVAR("g_ctf_win_mode");
 399                 BADCVAR("g_domination_point_limit");
 400                 BADCVAR("g_fullbrightitems");
 401                 BADCVAR("g_fullbrightplayers");
 402                 BADCVAR("g_keyhunt_point_limit");
 403                 BADCVAR("g_keyhunt_teams_override");
 404                 BADCVAR("g_lms_lives_override");
 405                 BADCVAR("g_maplist");
 406                 BADCVAR("g_maplist_check_waypoints");
 407                 BADCVAR("g_maplist_mostrecent_count");
 408                 BADCVAR("g_maplist_shuffle");
 409                 BADCVAR("g_maplist_votable");
 410                 BADCVAR("g_maplist_votable_abstain");
 411                 BADCVAR("g_maplist_votable_nodetail");
 412                 BADCVAR("g_maplist_votable_suggestions");
 413                 BADCVAR("g_minstagib");
 414                 BADCVAR("g_nexball_goallimit");
 415                 BADCVAR("g_runematch_point_limit");
 416                 BADCVAR("g_start_delay");
 417                 BADCVAR("hostname");
 418                 BADCVAR("log_file");
 419                 BADCVAR("maxplayers");
 420                 BADCVAR("minplayers");
 421                 BADCVAR("net_address");
 422                 BADCVAR("port");
 423                 BADCVAR("rcon_password");
 424                 BADCVAR("rcon_restricted_commands");
 425                 BADCVAR("rcon_restricted_password");
 426                 BADCVAR("skill");
 427                 BADCVAR("sv_adminnick");
 428                 BADCVAR("sv_autoscreenshot");
 429                 BADCVAR("sv_curl_defaulturl");
 430                 BADCVAR("sv_defaultcharacter");
 431                 BADCVAR("sv_defaultplayercolors");
 432                 BADCVAR("sv_defaultplayermodel");
 433                 BADCVAR("sv_defaultplayerskin");
 434                 BADCVAR("sv_maxidle");
 435                 BADCVAR("sv_maxrate");
 436                 BADCVAR("sv_motd");
 437                 BADCVAR("sv_public");
 438                 BADCVAR("sv_ready_restart");
 439                 BADCVAR("sv_status_privacy");
 440                 BADCVAR("sv_vote_call");
 441                 BADCVAR("sv_vote_commands");
 442                 BADCVAR("sv_vote_majority_factor");
 443                 BADCVAR("sv_vote_master");
 444                 BADCVAR("sv_vote_master_commands");
 445                 BADCVAR("sv_vote_master_password");
 446                 BADCVAR("sv_vote_simple_majority_factor");
 447                 BADCVAR("timelimit_override");
 448
 449                 if(cvar("g_minstagib"))
 450                 {
 451                         BADCVAR("g_grappling_hook");
 452                         BADCVAR("g_jetpack");
 453                 }
 454 #undef BADPREFIX
 455 #undef BADCVAR
 456
 457                 if(pureadding)
 458                 {
 459                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 460                         if(strlen(cvar_purechanges) > 16384)
 461                         {
 462                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 463                                 pureadding = 0;
 464                         }
 465                 }
 466                 ++cvar_purechanges_count;
 467                 // WARNING: this variable is used for the server list
 468                 // NEVER dare to skip this code!
 469                 // Hacks to intentionally appearing as "pure server" even though you DO have
 470                 // modified settings may be punished by removal from the server list.
 471                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 472                 // though.
 473         }
 474         buf_del(h);
 475         if(cvar_changes == "")
 476                 cvar_changes = "// this server runs at default server settings\n";
 477         else
 478                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 479         cvar_changes = strzone(cvar_changes);
 480         if(cvar_purechanges == "")
 481                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 482         else
 483                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 484         cvar_purechanges = strzone(cvar_purechanges);
 485 }
 486
 487 void detect_maptype()
 488 {
 489 #if 0
 490         vector o, v;
 491         float i;
 492
 493         for(;;)
 494         {
 495                 o = world.mins;
 496                 o_x += random() * (world.maxs_x - world.mins_x);
 497                 o_y += random() * (world.maxs_y - world.mins_y);
 498                 o_z += random() * (world.maxs_z - world.mins_z);
 499
 500                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 501                 if(trace_fraction == 1)
 502                         continue;
 503
 504                 v = trace_endpos;
 505
 506                 for(i = 0; i < 64; i += 4)
 507                 {
 508                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 509         if(trace_fraction == 1)
 510                 continue;
 511                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 512                 }
 513
 514                 break;
 515         }
 516 #endif
 517 }
 518
 519 entity randomseed;
 520 float RandomSeed_Send(entity to, float sf)
 521 {
 522         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 523         WriteShort(MSG_ENTITY, self.cnt);
 524         return TRUE;
 525 }
 526 void RandomSeed_Think()
 527 {
 528         self.cnt = bound(0, floor(random() * 65536), 65535);
 529         self.nextthink = time + 5;
 530
 531         self.SendFlags |= 1;
 532 }
 533 void RandomSeed_Spawn()
 534 {
 535         randomseed = spawn();
 536         randomseed.think = RandomSeed_Think;
 537         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 538
 539         entity oldself;
 540         oldself = self;
 541         self = randomseed;
 542         self.think(); // sets random seed and nextthink
 543         self = oldself;
 544 }
 545
 546 void spawnfunc___init_dedicated_server(void)
 547 {
 548         // handler for _init/_init map (only for dedicated server initialization)
 549
 550         world_initialized = -1; // don't complain
 551         cvar = cvar_normal;
 552         cvar_string = cvar_string_normal;
 553         cvar_set = cvar_set_normal;
 554
 555         remove = remove_unsafely;
 556
 557         entity e;
 558         e = spawn();
 559         e.think = GotoFirstMap;
 560         e.nextthink = time; // this is usually 1 at this point
 561
 562         e = spawn();
 563         e.classname = "info_player_deathmatch"; // safeguard against player joining
 564
 565         self.classname = "worldspawn"; // safeguard against various stuff ;)
 566
 567         MapInfo_Enumerate();
 568         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 569 }
 570
 571 void Map_MarkAsRecent(string m);
 572 float world_already_spawned;
 573 void RegisterWeapons();
 574 void Nagger_Init();
 575 void ClientInit_Spawn();
 576 void WeaponStats_Init();
 577 void WeaponStats_Shutdown();
 578 void spawnfunc_worldspawn (void)
 579 {
 580         float fd, l, i, j, n;
 581         string s, col;
 582
 583         cvar = cvar_normal;
 584         cvar_string = cvar_string_normal;
 585         cvar_set = cvar_set_normal;
 586
 587         if(world_already_spawned)
 588                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 589         world_already_spawned = TRUE;
 590
 591         remove = remove_safely; // during spawning, watch what you remove!
 592
 593         check_unacceptable_compiler_bugs();
 594
 595         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 596
 597         compressShortVector_init();
 598
 599         allowed_to_spawn = TRUE;
 600
 601         local entity head;
 602         head = nextent(world);
 603         maxclients = 0;
 604         while(head)
 605         {
 606                 ++maxclients;
 607                 head = nextent(head);
 608         }
 609
 610         // needs to be done so early as they would still spawn
 611         RegisterWeapons();
 612
 613         ServerProgsDB = db_load("server.db");
 614
 615         TemporaryDB = db_create();
 616
 617         /*
 618         TODO sound pack system
 619         // initialize sound pack system
 620         soundpack = cvar_string("g_soundpack");
 621         if(soundpack != "")
 622                 soundpack = strcat(soundpack, "/");
 623         soundpack = strzone(soundpack);
 624         */
 625
 626         // 0 normal
 627         lightstyle(0, "m");
 628
 629         // 1 FLICKER (first variety)
 630         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 631
 632         // 2 SLOW STRONG PULSE
 633         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 634
 635         // 3 CANDLE (first variety)
 636         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 637
 638         // 4 FAST STROBE
 639         lightstyle(4, "mamamamamama");
 640
 641         // 5 GENTLE PULSE 1
 642         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 643
 644         // 6 FLICKER (second variety)
 645         lightstyle(6, "nmonqnmomnmomomno");
 646
 647         // 7 CANDLE (second variety)
 648         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 649
 650         // 8 CANDLE (third variety)
 651         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 652
 653         // 9 SLOW STROBE (fourth variety)
 654         lightstyle(9, "aaaaaaaazzzzzzzz");
 655
 656         // 10 FLUORESCENT FLICKER
 657         lightstyle(10, "mmamammmmammamamaaamammma");
 658
 659         // 11 SLOW PULSE NOT FADE TO BLACK
 660         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 661
 662         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 663
 664         // 63 testing
 665         lightstyle(63, "a");
 666
 667         if(cvar("g_campaign"))
 668                 CampaignPreInit();
 669
 670         Map_MarkAsRecent(mapname);
 671
 672         precache_model ("null"); // we need this one before InitGameplayMode
 673         InitGameplayMode();
 674         readlevelcvars();
 675         GrappleHookInit();
 676         ElectroInit();
 677         LaserInit();
 678
 679         player_count = 0;
 680         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 681         if(bot_waypoints_for_items == 1)
 682                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 683                         bot_waypoints_for_items = 0;
 684
 685         // for setting by mapinfo
 686         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 687         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 688
 689         precache();
 690
 691         WaypointSprite_Init();
 692
 693         //if (g_domination)
 694         //      dom_init();
 695
 696         GameLogInit(); // prepare everything
 697         if(cvar("sv_eventlog"))
 698         {
 699                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 700                 s = strcat(s, ftos(random()));
 701                 matchid = strzone(s);
 702
 703                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 704                 s = ":gameinfo:mutators:LIST";
 705
 706                 ret_string = s;
 707                 MUTATOR_CALLHOOK(BuildMutatorsString);
 708                 s = ret_string;
 709
 710                 // simple, probably not good in the mutator system
 711                 if(cvar("g_grappling_hook"))
 712                         s = strcat(s, ":grappling_hook");
 713
 714                 // initialiation stuff, not good in the mutator system
 715                 if(!cvar("g_use_ammunition"))
 716                         s = strcat(s, ":no_use_ammunition");
 717
 718                 // initialiation stuff, not good in the mutator system
 719                 if(!cvar("g_pickup_items"))
 720                         s = strcat(s, ":no_pickup_items");
 721
 722                 // initialiation stuff, not good in the mutator system
 723                 if(cvar_string("g_weaponarena") != "0")
 724                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 725
 726                 // TODO to mutator system
 727                 if(cvar("g_norecoil"))
 728                         s = strcat(s, ":norecoil");
 729
 730                 // TODO to mutator system
 731                 if(cvar("g_midair"))
 732                         s = strcat(s, ":midair");
 733
 734                 // TODO to mutator system
 735                 if(cvar("g_minstagib"))
 736                         s = strcat(s, ":minstagib");
 737
 738                 GameLogEcho(s);
 739                 GameLogEcho(":gameinfo:end");
 740         }
 741         else
 742                 matchid = strzone(ftos(random()));
 743
 744         cvar_set("nextmap", "");
 745
 746         SetDefaultAlpha();
 747
 748         if(cvar("g_campaign"))
 749                 CampaignPostInit();
 750
 751         fteqcc_testbugs();
 752
 753         Ban_LoadBans();
 754
 755         MapInfo_Enumerate();
 756         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 757
 758         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 759         {
 760                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 761                 if(fd != -1)
 762                 {
 763                         while((s = fgets(fd)))
 764                         {
 765                                 l = tokenize_console(s);
 766                                 if(l < 2)
 767                                         continue;
 768                                 if(argv(0) == "cd")
 769                                 {
 770                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 771                                         print("  cdtrack ", argv(2), "\n");
 772                                 }
 773                                 else if(argv(0) == "fog")
 774                                 {
 775                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 776                                         print("  \"fog\" \"", s, "\"\n");
 777                                 }
 778                                 else if(argv(0) == "set")
 779                                 {
 780                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 781                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 782                                 }
 783                                 else if(argv(0) != "//")
 784                                 {
 785                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 786                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 787                                 }
 788                         }
 789                         fclose(fd);
 790                 }
 791         }
 792
 793         WeaponStats_Init();
 794
 795         addstat(STAT_WEAPONS, AS_INT, weapons);
 796         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 797         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 798         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 799         Nagger_Init();
 800
 801         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 802         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 803         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 804         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 805         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 806         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 807         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 808         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 809
 810         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 811         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_charge_pool_ammo);
 812
 813         if(g_ca)
 814         {
 815                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 816                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 817         }
 818         // g_movementspeed hack
 819         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 820         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 821         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 822         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 823
 824         next_pingtime = time + 5;
 825
 826         detect_maptype();
 827
 828         lsmaps_reply = "^7Maps available: ";
 829         lsnewmaps_reply = "^7Maps without a record set: ";
 830         for(i = 0, j = 0; i < MapInfo_count; ++i)
 831         {
 832                 if(MapInfo_Get_ByID(i))
 833                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 834                         {
 835                                 if(mod(i, 2))
 836                                         col = "^2";
 837                                 else
 838                                         col = "^3";
 839                                 ++j;
 840                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 841                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 842                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 843                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 844                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 845                         }
 846         }
 847         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 848         if (!g_race && !g_cts)
 849                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 850         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 851
 852         maplist_reply = "^7Maps in list: ";
 853         n = tokenize_console(cvar_string("g_maplist"));
 854         for(i = 0, j = 0; i < n; ++i)
 855         {
 856                 if(MapInfo_CheckMap(argv(i)))
 857                 {
 858                         if(mod(j, 2))
 859                                 col = "^2";
 860                         else
 861                                 col = "^3";
 862                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 863                         ++j;
 864                 }
 865         }
 866         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 867         MapInfo_ClearTemps();
 868
 869         for(i = 0; i < 10; ++i)
 870         {
 871                 records_reply[i] = strzone(getrecords(i));
 872         }
 873         if(g_cts)
 874                 ladder_reply = strzone(getladder());
 875
 876         rankings_reply = strzone(getrankings());
 877
 878         ClientInit_Spawn();
 879         RandomSeed_Spawn();
 880         PingPLReport_Spawn();
 881
 882         CheatInit();
 883
 884         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 885
 886         // fill sv_curl_serverpackages from .serverpackage files
 887         if(cvar("sv_curl_serverpackages_auto"))
 888         {
 889                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 890                 s = "";
 891                 if(fd >= 0)
 892                 {
 893                         j = search_getsize(fd);
 894                         for(i = 0; i < j; ++i)
 895                                 s = strcat(s, " ", search_getfilename(fd, i));
 896                         search_end(fd);
 897                 }
 898                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 899         }
 900
 901         world_initialized = 1;
 902 }
 903
 904 void spawnfunc_light (void)
 905 {
 906         //makestatic (self); // Who the f___ did that?
 907         remove(self);
 908 }
 909
 910 float TryFile( string pFilename )
 911 {
 912         local float lHandle;
 913         dprint("TryFile(\"", pFilename, "\")\n");
 914         lHandle = fopen( pFilename, FILE_READ );
 915         if( lHandle != -1 ) {
 916                 fclose( lHandle );
 917                 return TRUE;
 918         } else {
 919                 return FALSE;
 920         }
 921 };
 922
 923 string GetGametype()
 924 {
 925         return GametypeNameFromType(game);
 926 }
 927
 928 string getmapname_stored;
 929 string GetMapname()
 930 {
 931         return mapname;
 932 }
 933
 934 float Map_Count, Map_Current;
 935 string Map_Current_Name;
 936
 937 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 938 float GetMaplistPosition()
 939 {
 940         float pos, idx;
 941         string map;
 942
 943         map = GetMapname();
 944         idx = cvar("g_maplist_index");
 945
 946         if(idx >= 0)
 947                 if(idx < Map_Count)
 948                         if(map == argv(idx))
 949                                 return idx;
 950
 951         for(pos = 0; pos < Map_Count; ++pos)
 952                 if(map == argv(pos))
 953                         return pos;
 954
 955         // resume normal maplist rotation if current map is not in g_maplist
 956         return idx;
 957 }
 958
 959 float MapHasRightSize(string map)
 960 {
 961         float fh;
 962         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 963         if(cvar("g_maplist_check_waypoints"))
 964         {
 965                 dprint("checkwp "); dprint(map);
 966                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 967                 if(fh < 0)
 968                 {
 969                         dprint(": no waypoints\n");
 970                         return FALSE;
 971                 }
 972                 dprint(": has waypoints\n");
 973                 fclose(fh);
 974         }
 975
 976         // open map size restriction file
 977         dprint("opensize "); dprint(map);
 978         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 979         if(fh >= 0)
 980         {
 981                 float mapmin, mapmax;
 982                 dprint(": ok, ");
 983                 mapmin = stof(fgets(fh));
 984                 mapmax = stof(fgets(fh));
 985                 fclose(fh);
 986                 if(player_count < mapmin)
 987                 {
 988                         dprint("not enough\n");
 989                         return FALSE;
 990                 }
 991                 if(player_count > mapmax)
 992                 {
 993                         dprint("too many\n");
 994                         return FALSE;
 995                 }
 996                 dprint("right size\n");
 997                 return TRUE;
 998         }
 999         dprint(": not found\n");
1000         return TRUE;
1001 }
1002
1003 string Map_Filename(float position)
1004 {
1005         return strcat("maps/", argv(position), ".bsp");
1006 }
1007
1008 string strwords(string s, float w)
1009 {
1010         float endpos;
1011         for(endpos = 0; w && endpos >= 0; --w)
1012                 endpos = strstrofs(s, " ", endpos + 1);
1013         if(endpos < 0)
1014                 return s;
1015         else
1016                 return substring(s, 0, endpos);
1017 }
1018
1019 float strhasword(string s, string w)
1020 {
1021         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1022 }
1023
1024 void Map_MarkAsRecent(string m)
1025 {
1026         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
1027 }
1028
1029 float Map_IsRecent(string m)
1030 {
1031         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1032 }
1033
1034 float Map_Check(float position, float pass)
1035 {
1036         string filename;
1037         string map_next;
1038         map_next = argv(position);
1039         if(pass <= 1)
1040         {
1041                 if(Map_IsRecent(map_next))
1042                         return 0;
1043         }
1044         filename = Map_Filename(position);
1045         if(MapInfo_CheckMap(map_next))
1046         {
1047                 if(pass == 2)
1048                         return 1;
1049                 if(MapHasRightSize(map_next))
1050                         return 1;
1051                 return 0;
1052         }
1053         else
1054                 dprint( "Couldn't select '", filename, "'..\n" );
1055
1056         return 0;
1057 }
1058
1059 void Map_Goto_SetStr(string nextmapname)
1060 {
1061         if(getmapname_stored != "")
1062                 strunzone(getmapname_stored);
1063         if(nextmapname == "")
1064                 getmapname_stored = "";
1065         else
1066                 getmapname_stored = strzone(nextmapname);
1067 }
1068
1069 void Map_Goto_SetFloat(float position)
1070 {
1071         cvar_set("g_maplist_index", ftos(position));
1072         Map_Goto_SetStr(argv(position));
1073 }
1074
1075 void GameResetCfg()
1076 {
1077         // settings persist, except...
1078         localcmd("\nsettemp_restore\n");
1079 };
1080
1081 void Map_Goto()
1082 {
1083         GameResetCfg();
1084         MapInfo_LoadMap(getmapname_stored);
1085 }
1086
1087 // return codes of map selectors:
1088 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1089 //   -2 = permanent failure
1090 float() MaplistMethod_Iterate = // usual method
1091 {
1092         float pass, i;
1093
1094         for(pass = 1; pass <= 2; ++pass)
1095         {
1096                 for(i = 1; i < Map_Count; ++i)
1097                 {
1098                         float mapindex;
1099                         mapindex = mod(i + Map_Current, Map_Count);
1100                         if(Map_Check(mapindex, pass))
1101                                 return mapindex;
1102                 }
1103         }
1104         return -1;
1105 }
1106
1107 float() MaplistMethod_Repeat = // fallback method
1108 {
1109         if(Map_Check(Map_Current, 2))
1110                 return Map_Current;
1111         return -2;
1112 }
1113
1114 float() MaplistMethod_Random = // random map selection
1115 {
1116         float i, imax;
1117
1118         imax = 42;
1119
1120         for(i = 0; i <= imax; ++i)
1121         {
1122                 float mapindex;
1123                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1124                 if(Map_Check(mapindex, 1))
1125                         return mapindex;
1126         }
1127         return -1;
1128 }
1129
1130 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1131 // the exponent sets a bias on the map selection:
1132 // the higher the exponent, the less likely "shortly repeated" same maps are
1133 {
1134         float i, j, imax, insertpos;
1135
1136         imax = 42;
1137
1138         for(i = 0; i <= imax; ++i)
1139         {
1140                 string newlist;
1141
1142                 // now reinsert this at another position
1143                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1144                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1145                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1146                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1147
1148                 // insert the current map there
1149                 newlist = "";
1150                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1151                         newlist = strcat(newlist, " ", argv(j));
1152                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1153                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1154                         newlist = strcat(newlist, " ", argv(j));
1155                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1156                 cvar_set("g_maplist", newlist);
1157                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1158
1159                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1160                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1161                 if(Map_Check(Map_Current, 1))
1162                         return Map_Current;
1163         }
1164         return -1;
1165 }
1166
1167 void Maplist_Init()
1168 {
1169         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1170         if(Map_Count == 0)
1171         {
1172                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1173                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1174                 if(cvar("g_maplist_shuffle"))
1175                         ShuffleMaplist();
1176                 localcmd("\nmenu_cmd sync\n");
1177                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1178         }
1179         if(Map_Count == 0)
1180                 error("empty maplist, cannot select a new map");
1181         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1182
1183         if(Map_Current_Name)
1184                 strunzone(Map_Current_Name);
1185         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1186         // this may or may not be correct, but who cares, in the worst case a map
1187         // isn't chosen in the first pass that should have been
1188 }
1189
1190 string GetNextMap()
1191 {
1192         float nextMap;
1193
1194         Maplist_Init();
1195         nextMap = -1;
1196
1197         if(nextMap == -1)
1198                 if(cvar("g_maplist_shuffle") > 0)
1199                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1200
1201         if(nextMap == -1)
1202                 if(cvar("g_maplist_selectrandom"))
1203                         nextMap = MaplistMethod_Random();
1204
1205         if(nextMap == -1)
1206                 nextMap = MaplistMethod_Iterate();
1207
1208         if(nextMap == -1)
1209                 nextMap = MaplistMethod_Repeat();
1210
1211         if(nextMap >= 0)
1212         {
1213                 Map_Goto_SetFloat(nextMap);
1214                 return getmapname_stored;
1215         }
1216
1217         return "";
1218 };
1219
1220 float DoNextMapOverride()
1221 {
1222         if(cvar("g_campaign"))
1223         {
1224                 CampaignPostIntermission();
1225                 alreadychangedlevel = TRUE;
1226                 return TRUE;
1227         }
1228         if(cvar("quit_when_empty"))
1229         {
1230                 if(player_count <= currentbots)
1231                 {
1232                         localcmd("quit\n");
1233                         alreadychangedlevel = TRUE;
1234                         return TRUE;
1235                 }
1236         }
1237         if(cvar_string("quit_and_redirect") != "")
1238         {
1239                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1240                 alreadychangedlevel = TRUE;
1241                 return TRUE;
1242         }
1243         if (cvar("samelevel")) // if samelevel is set, stay on same level
1244         {
1245                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1246                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1247                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1248                 localcmd("restart\n");
1249                 //changelevel (mapname);
1250                 alreadychangedlevel = TRUE;
1251                 return TRUE;
1252         }
1253         if(cvar_string("nextmap") != "")
1254                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1255                 {
1256                         Map_Goto_SetStr(cvar_string("nextmap"));
1257                         Map_Goto();
1258                         alreadychangedlevel = TRUE;
1259                         return TRUE;
1260                 }
1261         if(cvar("lastlevel"))
1262         {
1263                 GameResetCfg();
1264                 localcmd("set lastlevel 0\ntogglemenu\n");
1265                 alreadychangedlevel = TRUE;
1266                 return TRUE;
1267         }
1268         return FALSE;
1269 };
1270
1271 void GotoNextMap()
1272 {
1273         //local string nextmap;
1274         //local float n, nummaps;
1275         //local string s;
1276         if (alreadychangedlevel)
1277                 return;
1278         alreadychangedlevel = TRUE;
1279
1280         {
1281                 string nextMap;
1282                 float allowReset;
1283
1284                 for(allowReset = 1; allowReset >= 0; --allowReset)
1285                 {
1286                         nextMap = GetNextMap();
1287                         if(nextMap != "")
1288                                 break;
1289
1290                         if(allowReset)
1291                         {
1292                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1293                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1294                                 if(cvar("g_maplist_shuffle"))
1295                                         ShuffleMaplist();
1296                                 localcmd("\nmenu_cmd sync\n");
1297                         }
1298                         else
1299                         {
1300                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1301                         }
1302                 }
1303                 Map_Goto();
1304         }
1305 };
1306
1307
1308 /*
1309 ============
1310 IntermissionThink
1311
1312 When the player presses attack or jump, change to the next level
1313 ============
1314 */
1315 .float autoscreenshot;
1316 void() MapVote_Start;
1317 void() MapVote_Think;
1318 float mapvote_initialized;
1319 void IntermissionThink()
1320 {
1321         FixIntermissionClient(self);
1322
1323         if(cvar("sv_autoscreenshot"))
1324         if(self.autoscreenshot > 0)
1325         if(time > self.autoscreenshot)
1326         {
1327                 self.autoscreenshot = -1;
1328                 if(clienttype(self) == CLIENTTYPE_REAL)
1329                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1330                 return;
1331         }
1332
1333         if (time < intermission_exittime)
1334                 return;
1335
1336         if(!mapvote_initialized)
1337                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1338                         return;
1339
1340         MapVote_Start();
1341 };
1342
1343 /*
1344 ============
1345 FindIntermission
1346
1347 Returns the entity to view from
1348 ============
1349 */
1350 /*
1351 entity FindIntermission()
1352 {
1353         local   entity spot;
1354         local   float cyc;
1355
1356 // look for info_intermission first
1357         spot = find (world, classname, "info_intermission");
1358         if (spot)
1359         {       // pick a random one
1360                 cyc = random() * 4;
1361                 while (cyc > 1)
1362                 {
1363                         spot = find (spot, classname, "info_intermission");
1364                         if (!spot)
1365                                 spot = find (spot, classname, "info_intermission");
1366                         cyc = cyc - 1;
1367                 }
1368                 return spot;
1369         }
1370
1371 // then look for the start position
1372         spot = find (world, classname, "info_player_start");
1373         if (spot)
1374                 return spot;
1375
1376 // testinfo_player_start is only found in regioned levels
1377         spot = find (world, classname, "testplayerstart");
1378         if (spot)
1379                 return spot;
1380
1381 // then look for the start position
1382         spot = find (world, classname, "info_player_deathmatch");
1383         if (spot)
1384                 return spot;
1385
1386         //objerror ("FindIntermission: no spot");
1387         return world;
1388 };
1389 */
1390
1391 /*
1392 ===============================================================================
1393
1394 RULES
1395
1396 ===============================================================================
1397 */
1398
1399 void DumpStats(float final)
1400 {
1401         local float file;
1402         local string s;
1403         local float to_console;
1404         local float to_eventlog;
1405         local float to_file;
1406         local float i;
1407
1408         to_console = cvar("sv_logscores_console");
1409         to_eventlog = cvar("sv_eventlog");
1410         to_file = cvar("sv_logscores_file");
1411
1412         if(!final)
1413         {
1414                 to_console = TRUE; // always print printstats replies
1415                 to_eventlog = FALSE; // but never print them to the event log
1416         }
1417
1418         if(to_eventlog)
1419                 if(cvar("sv_eventlog_console"))
1420                         to_console = FALSE; // otherwise we get the output twice
1421
1422         if(final)
1423                 s = ":scores:";
1424         else
1425                 s = ":status:";
1426         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1427
1428         if(to_console)
1429                 print(s, "\n");
1430         if(to_eventlog)
1431                 GameLogEcho(s);
1432         if(to_file)
1433         {
1434                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1435                 if(file == -1)
1436                         to_file = FALSE;
1437                 else
1438                         fputs(file, strcat(s, "\n"));
1439         }
1440
1441         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1442         if(to_console)
1443                 print(s, "\n");
1444         if(to_eventlog)
1445                 GameLogEcho(s);
1446         if(to_file)
1447                 fputs(file, strcat(s, "\n"));
1448
1449         FOR_EACH_CLIENT(other)
1450         {
1451                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1452                 {
1453                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1454                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1455                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1456                                 s = strcat(s, ftos(other.team), ":");
1457                         else
1458                                 s = strcat(s, "spectator:");
1459
1460                         if(to_console)
1461                                 print(s, other.netname, "\n");
1462                         if(to_eventlog)
1463                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1464                         if(to_file)
1465                                 fputs(file, strcat(s, other.netname, "\n"));
1466                 }
1467         }
1468
1469         if(teams_matter)
1470         {
1471                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1472                 if(to_console)
1473                         print(s, "\n");
1474                 if(to_eventlog)
1475                         GameLogEcho(s);
1476                 if(to_file)
1477                         fputs(file, strcat(s, "\n"));
1478
1479                 for(i = 1; i < 16; ++i)
1480                 {
1481                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1482                         s = strcat(s, ":", ftos(i));
1483                         if(to_console)
1484                                 print(s, "\n");
1485                         if(to_eventlog)
1486                                 GameLogEcho(s);
1487                         if(to_file)
1488                                 fputs(file, strcat(s, "\n"));
1489                 }
1490         }
1491
1492         if(to_console)
1493                 print(":end\n");
1494         if(to_eventlog)
1495                 GameLogEcho(":end");
1496         if(to_file)
1497         {
1498                 fputs(file, ":end\n");
1499                 fclose(file);
1500         }
1501 }
1502
1503 void FixIntermissionClient(entity e)
1504 {
1505         string s;
1506         if(!e.autoscreenshot) // initial call
1507         {
1508                 e.angles = e.v_angle;
1509                 e.angles_x = -e.angles_x;
1510                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1511                 e.health = -2342;
1512                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1513                 e.solid = SOLID_NOT;
1514                 e.movetype = MOVETYPE_NONE;
1515                 e.takedamage = DAMAGE_NO;
1516                 if(e.weaponentity)
1517                 {
1518                         e.weaponentity.effects = EF_NODRAW;
1519                         if (e.weaponentity.weaponentity)
1520                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1521                 }
1522                 if(clienttype(e) == CLIENTTYPE_REAL)
1523                 {
1524                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1525                         s = cvar_string("sv_intermission_cdtrack");
1526                         if(s != "")
1527                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1528                         msg_entity = e;
1529                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1530                 }
1531         }
1532
1533         //e.velocity = '0 0 0';
1534         //e.fixangle = TRUE;
1535
1536         // TODO halt weapon animation
1537 }
1538
1539
1540 /*
1541 go to the next level for deathmatch
1542 only called if a time or frag limit has expired
1543 */
1544 void NextLevel()
1545 {
1546         gameover = TRUE;
1547
1548         intermission_running = 1;
1549
1550 // enforce a wait time before allowing changelevel
1551         if(player_count > 0)
1552                 intermission_exittime = time + cvar("sv_mapchange_delay");
1553         else
1554                 intermission_exittime = -1;
1555
1556         /*
1557         WriteByte (MSG_ALL, SVC_CDTRACK);
1558         WriteByte (MSG_ALL, 3);
1559         WriteByte (MSG_ALL, 3);
1560         // done in FixIntermission
1561         */
1562
1563         //pos = FindIntermission ();
1564
1565         VoteReset();
1566
1567         DumpStats(TRUE);
1568
1569         if(cvar("sv_eventlog"))
1570                 GameLogEcho(":gameover");
1571
1572         GameLogClose();
1573
1574         FOR_EACH_PLAYER(other) {
1575                 FixIntermissionClient(other);
1576                 if(other.winning)
1577                         bprint(other.netname, " ^7wins.\n");
1578         }
1579
1580         if(cvar("g_campaign"))
1581                 CampaignPreIntermission();
1582
1583         localcmd("\nsv_hook_gameend\n");
1584 }
1585
1586 /*
1587 ============
1588 CheckRules_Player
1589
1590 Exit deathmatch games upon conditions
1591 ============
1592 */
1593 void CheckRules_Player()
1594 {
1595         if (gameover)   // someone else quit the game already
1596                 return;
1597
1598         if(self.deadflag == DEAD_NO)
1599                 self.play_time += frametime;
1600
1601         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1602         //   (div0: and that in CheckRules_World please)
1603 };
1604
1605 float checkrules_equality;
1606 float checkrules_suddendeathwarning;
1607 float checkrules_suddendeathend;
1608 float checkrules_overtimesadded; //how many overtimes have been already added
1609
1610 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1611 float WINNING_YES = 1; // winner found
1612 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1613 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1614
1615 float InitiateSuddenDeath()
1616 {
1617         // Check first whether normal overtimes could be added before initiating suddendeath mode
1618         // - for this timelimit_overtime needs to be >0 of course
1619         // - also check the winning condition calculated in the previous frame and only add normal overtime
1620         //   again, if at the point at which timelimit would be extended again, still no winner was found
1621         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1622         {
1623                 return 1; // need to call InitiateOvertime later
1624         }
1625         else
1626         {
1627                 if(!checkrules_suddendeathend)
1628                 {
1629                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1630                         if(g_race && !g_race_qualifying)
1631                                 race_StartCompleting();
1632                 }
1633                 return 0;
1634         }
1635 }
1636
1637 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1638 {
1639         ++checkrules_overtimesadded;
1640         //add one more overtime by simply extending the timelimit
1641         float tl;
1642         tl = cvar("timelimit");
1643         tl += cvar("timelimit_overtime");
1644         cvar_set("timelimit", ftos(tl));
1645         string minutesPlural;
1646         if (cvar("timelimit_overtime") == 1)
1647                 minutesPlural = " ^3minute";
1648         else
1649                 minutesPlural = " ^3minutes";
1650
1651         bcenterprint(
1652                 strcat(
1653                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1654                         ftos(cvar("timelimit_overtime")),
1655                         minutesPlural,
1656                         " to the game!"
1657                 )
1658         );
1659 }
1660
1661 float GetWinningCode(float fraglimitreached, float equality)
1662 {
1663         if(cvar("g_campaign") == 1)
1664                 if(fraglimitreached)
1665                         return WINNING_YES;
1666                 else
1667                         return WINNING_NO;
1668
1669         else
1670                 if(equality)
1671                         if(fraglimitreached)
1672                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1673                         else
1674                                 return WINNING_NEVER;
1675                 else
1676                         if(fraglimitreached)
1677                                 return WINNING_YES;
1678                         else
1679                                 return WINNING_NO;
1680 }
1681
1682 // set the .winning flag for exactly those players with a given field value
1683 void SetWinners(.float field, float value)
1684 {
1685         entity head;
1686         FOR_EACH_PLAYER(head)
1687                 head.winning = (head.field == value);
1688 }
1689
1690 // set the .winning flag for those players with a given field value
1691 void AddWinners(.float field, float value)
1692 {
1693         entity head;
1694         FOR_EACH_PLAYER(head)
1695                 if(head.field == value)
1696                         head.winning = 1;
1697 }
1698
1699 // clear the .winning flags
1700 void ClearWinners(void)
1701 {
1702         entity head;
1703         FOR_EACH_PLAYER(head)
1704                 head.winning = 0;
1705 }
1706
1707 // Onslaught winning condition:
1708 // game terminates if only one team has a working generator (or none)
1709 float WinningCondition_Onslaught()
1710 {
1711         entity head;
1712         local float t1, t2, t3, t4;
1713
1714         WinningConditionHelper(); // set worldstatus
1715
1716         if(inWarmupStage)
1717                 return WINNING_NO;
1718
1719         // first check if the game has ended
1720         t1 = t2 = t3 = t4 = 0;
1721         head = find(world, classname, "onslaught_generator");
1722         while (head)
1723         {
1724                 if (head.health > 0)
1725                 {
1726                         if (head.team == COLOR_TEAM1) t1 = 1;
1727                         if (head.team == COLOR_TEAM2) t2 = 1;
1728                         if (head.team == COLOR_TEAM3) t3 = 1;
1729                         if (head.team == COLOR_TEAM4) t4 = 1;
1730                 }
1731                 head = find(head, classname, "onslaught_generator");
1732         }
1733         if (t1 + t2 + t3 + t4 < 2)
1734         {
1735                 // game over, only one team remains (or none)
1736                 ClearWinners();
1737                 if (t1) SetWinners(team, COLOR_TEAM1);
1738                 if (t2) SetWinners(team, COLOR_TEAM2);
1739                 if (t3) SetWinners(team, COLOR_TEAM3);
1740                 if (t4) SetWinners(team, COLOR_TEAM4);
1741                 dprint("Have a winner, ending game.\n");
1742                 return WINNING_YES;
1743         }
1744
1745         // Two or more teams remain
1746         return WINNING_NO;
1747 }
1748
1749 float LMS_NewPlayerLives()
1750 {
1751         float fl;
1752         fl = cvar("fraglimit");
1753         if(fl == 0)
1754                 fl = 999;
1755
1756         // first player has left the game for dying too much? Nobody else can get in.
1757         if(lms_lowest_lives < 1)
1758                 return 0;
1759
1760         if(!cvar("g_lms_join_anytime"))
1761                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1762                         return 0;
1763
1764         return bound(1, lms_lowest_lives, fl);
1765 }
1766
1767 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1768 // they win. Otherwise the defending team wins once the timelimit passes.
1769 void assault_new_round();
1770 float WinningCondition_Assault()
1771 {
1772         local float status;
1773
1774         WinningConditionHelper(); // set worldstatus
1775
1776         status = WINNING_NO;
1777         // as the timelimit has not yet passed just assume the defending team will win
1778         if(assault_attacker_team == COLOR_TEAM1)
1779         {
1780                 SetWinners(team, COLOR_TEAM2);
1781         }
1782         else
1783         {
1784                 SetWinners(team, COLOR_TEAM1);
1785         }
1786
1787         local entity ent;
1788         ent = find(world, classname, "target_assault_roundend");
1789         if(ent)
1790         {
1791                 if(ent.winning) // round end has been triggered by attacking team
1792                 {
1793                         bprint("ASSAULT: round completed...\n");
1794                         SetWinners(team, assault_attacker_team);
1795
1796                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1797
1798                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1799                         {
1800                                 status = WINNING_YES;
1801                         }
1802                         else
1803                         {
1804                                 local entity oldself;
1805                                 oldself = self;
1806                                 self = ent;
1807                                 assault_new_round();
1808                                 self = oldself;
1809                         }
1810                 }
1811         }
1812
1813         return status;
1814 }
1815
1816 // LMS winning condition: game terminates if and only if there's at most one
1817 // one player who's living lives. Top two scores being equal cancels the time
1818 // limit.
1819 float WinningCondition_LMS()
1820 {
1821         entity head, head2;
1822         float have_player;
1823         float have_players;
1824         float l;
1825
1826         have_player = FALSE;
1827         have_players = FALSE;
1828         l = LMS_NewPlayerLives();
1829
1830         head = find(world, classname, "player");
1831         if(head)
1832                 have_player = TRUE;
1833         head2 = find(head, classname, "player");
1834         if(head2)
1835                 have_players = TRUE;
1836
1837         if(have_player)
1838         {
1839                 // we have at least one player
1840                 if(have_players)
1841                 {
1842                         // two or more active players - continue with the game
1843                 }
1844                 else
1845                 {
1846                         // exactly one player?
1847
1848                         ClearWinners();
1849                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1850
1851                         if(l)
1852                         {
1853                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1854                                 return WINNING_NO;
1855                         }
1856                         else
1857                         {
1858                                 // a winner!
1859                                 // and assign him his first place
1860                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1861                                 return WINNING_YES;
1862                         }
1863                 }
1864         }
1865         else
1866         {
1867                 // nobody is playing at all...
1868                 if(l)
1869                 {
1870                         // wait for players...
1871                 }
1872                 else
1873                 {
1874                         // SNAFU (maybe a draw game?)
1875                         ClearWinners();
1876                         dprint("No players, ending game.\n");
1877                         return WINNING_YES;
1878                 }
1879         }
1880
1881         // When we get here, we have at least two players who are actually LIVING,
1882         // now check if the top two players have equal score.
1883         WinningConditionHelper();
1884
1885         ClearWinners();
1886         if(WinningConditionHelper_winner)
1887                 WinningConditionHelper_winner.winning = TRUE;
1888         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1889                 return WINNING_NEVER;
1890
1891         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1892         return WINNING_NO;
1893 }
1894
1895 void ShuffleMaplist()
1896 {
1897         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1898 }
1899
1900 float leaderfrags;
1901 float WinningCondition_Scores(float limit, float leadlimit)
1902 {
1903         float limitreached;
1904
1905         // TODO make everything use THIS winning condition (except LMS)
1906         WinningConditionHelper();
1907
1908         if(teams_matter)
1909         {
1910                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1911                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1912                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1913                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1914         }
1915
1916         ClearWinners();
1917         if(WinningConditionHelper_winner)
1918                 WinningConditionHelper_winner.winning = 1;
1919         if(WinningConditionHelper_winnerteam >= 0)
1920                 SetWinners(team, WinningConditionHelper_winnerteam);
1921
1922         if(WinningConditionHelper_lowerisbetter)
1923         {
1924                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1925                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1926                 limit = -limit;
1927         }
1928
1929         if(WinningConditionHelper_zeroisworst)
1930                 leadlimit = 0; // not supported in this mode
1931
1932         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1933         // these modes always score in increments of 1, thus this makes sense
1934         {
1935                 if(leaderfrags != WinningConditionHelper_topscore)
1936                 {
1937                         leaderfrags = WinningConditionHelper_topscore;
1938
1939                         if (limit)
1940                         if (leaderfrags == limit - 1)
1941                                 Announce("1fragleft");
1942                         else if (leaderfrags == limit - 2)
1943                                 Announce("2fragsleft");
1944                         else if (leaderfrags == limit - 3)
1945                                 Announce("3fragsleft");
1946                 }
1947         }
1948
1949         limitreached = FALSE;
1950         if(limit)
1951                 if(WinningConditionHelper_topscore >= limit)
1952                         limitreached = TRUE;
1953         if(leadlimit)
1954         {
1955                 float leadlimitreached;
1956                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1957                 if(cvar("leadlimit_and_fraglimit"))
1958                         limitreached = (limitreached && leadlimitreached);
1959                 else
1960                         limitreached = (limitreached || leadlimitreached);
1961         }
1962
1963         return GetWinningCode(
1964                 WinningConditionHelper_topscore && limitreached,
1965                 WinningConditionHelper_equality
1966         );
1967 }
1968
1969 float WinningCondition_Race(float fraglimit)
1970 {
1971         float wc;
1972         entity p;
1973         float n, c;
1974
1975         n = 0;
1976         c = 0;
1977         FOR_EACH_PLAYER(p)
1978         {
1979                 ++n;
1980                 if(p.race_completed)
1981                         ++c;
1982         }
1983         if(n && (n == c))
1984                 return WINNING_YES;
1985         wc = WinningCondition_Scores(fraglimit, 0);
1986
1987         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1988         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1989         // do NOT support equality when the laps are all raced!
1990                 return WINNING_STARTSUDDENDEATHOVERTIME;
1991         else
1992                 return WINNING_NEVER;
1993         return wc;
1994 }
1995
1996 void ReadyRestart();
1997 float WinningCondition_QualifyingThenRace(float limit)
1998 {
1999         float wc;
2000         wc = WinningCondition_Scores(limit, 0);
2001
2002         // NEVER initiate overtime
2003         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2004         {
2005                 return WINNING_YES;
2006         }
2007
2008         return wc;
2009 }
2010
2011 float WinningCondition_RanOutOfSpawns()
2012 {
2013         entity head;
2014
2015         if(have_team_spawns <= 0)
2016                 return WINNING_NO;
2017
2018         if(!some_spawn_has_been_used)
2019                 return WINNING_NO;
2020
2021         team1_score = team2_score = team3_score = team4_score = 0;
2022
2023         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2024         {
2025                 if(head.team == COLOR_TEAM1)
2026                         team1_score = 1;
2027                 else if(head.team == COLOR_TEAM2)
2028                         team2_score = 1;
2029                 else if(head.team == COLOR_TEAM3)
2030                         team3_score = 1;
2031                 else if(head.team == COLOR_TEAM4)
2032                         team4_score = 1;
2033         }
2034
2035         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2036         {
2037                 if(head.team == COLOR_TEAM1)
2038                         team1_score = 1;
2039                 else if(head.team == COLOR_TEAM2)
2040                         team2_score = 1;
2041                 else if(head.team == COLOR_TEAM3)
2042                         team3_score = 1;
2043                 else if(head.team == COLOR_TEAM4)
2044                         team4_score = 1;
2045         }
2046
2047         ClearWinners();
2048         if(team1_score + team2_score + team3_score + team4_score == 0)
2049         {
2050                 checkrules_equality = TRUE;
2051                 return WINNING_YES;
2052         }
2053         else if(team1_score + team2_score + team3_score + team4_score == 1)
2054         {
2055                 float t, i;
2056                 if(team1_score) t = COLOR_TEAM1;
2057                 if(team2_score) t = COLOR_TEAM2;
2058                 if(team3_score) t = COLOR_TEAM3;
2059                 if(team4_score) t = COLOR_TEAM4;
2060                 CheckAllowedTeams(world);
2061                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2062                 {
2063                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2064                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2065                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2066                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2067                 }
2068
2069                 AddWinners(team, t);
2070                 return WINNING_YES;
2071         }
2072         else
2073                 return WINNING_NO;
2074 }
2075
2076 /*
2077 ============
2078 CheckRules_World
2079
2080 Exit deathmatch games upon conditions
2081 ============
2082 */
2083 void CheckRules_World()
2084 {
2085         float timelimit;
2086         float fraglimit;
2087         float leadlimit;
2088
2089         VoteThink();
2090         MapVote_Think();
2091
2092         SetDefaultAlpha();
2093
2094         /*
2095         MapVote_Think should now do that part
2096         if (intermission_running)
2097                 if (time >= intermission_exittime + 60)
2098                 {
2099                         if(!DoNextMapOverride())
2100                                 GotoNextMap();
2101                         return;
2102                 }
2103         */
2104
2105         if (gameover)   // someone else quit the game already
2106         {
2107                 if(player_count == 0) // Nobody there? Then let's go to the next map
2108                         MapVote_Start();
2109                         // this will actually check the player count in the next frame
2110                         // again, but this shouldn't hurt
2111                 return;
2112         }
2113
2114         timelimit = cvar("timelimit") * 60;
2115         fraglimit = cvar("fraglimit");
2116         leadlimit = cvar("leadlimit");
2117
2118         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2119         {
2120                 if(timelimit > 0)
2121                         timelimit = 0; // timelimit is not made for warmup
2122                 if(fraglimit > 0)
2123                         fraglimit = 0; // no fraglimit for now
2124                 leadlimit = 0; // no leadlimit for now
2125         }
2126
2127         if(g_onslaught)
2128                 timelimit = 0; // ONS has its own overtime rule
2129
2130         if(timelimit > 0)
2131         {
2132                 timelimit += game_starttime;
2133         }
2134         else if (timelimit < 0)
2135         {
2136                 // endmatch
2137                 NextLevel();
2138                 return;
2139         }
2140
2141         float wantovertime;
2142         wantovertime = 0;
2143
2144         if(checkrules_suddendeathend)
2145         {
2146                 if(!checkrules_suddendeathwarning)
2147                 {
2148                         checkrules_suddendeathwarning = TRUE;
2149                         if(g_race && !g_race_qualifying)
2150                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2151                         else
2152                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2153                 }
2154         }
2155         else
2156         {
2157                 if (timelimit && time >= timelimit)
2158                 {
2159                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2160                         {
2161                                 float totalplayers;
2162                                 float playerswithlaps;
2163                                 float readyplayers;
2164                                 entity head;
2165                                 totalplayers = playerswithlaps = readyplayers = 0;
2166                                 FOR_EACH_PLAYER(head)
2167                                 {
2168                                         ++totalplayers;
2169                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2170                                                 ++playerswithlaps;
2171                                         if(head.ready)
2172                                                 ++readyplayers;
2173                                 }
2174
2175                                 // at least 2 of the players have completed a lap: start the RACE
2176                                 // otherwise, the players should end the qualifying on their own
2177                                 if(readyplayers || playerswithlaps >= 2)
2178                                 {
2179                                         checkrules_suddendeathend = 0;
2180                                         ReadyRestart(); // go to race
2181                                         return;
2182                                 }
2183                                 else
2184                                         wantovertime |= InitiateSuddenDeath();
2185                         }
2186                         else
2187                                 wantovertime |= InitiateSuddenDeath();
2188                 }
2189         }
2190
2191         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2192         {
2193                 NextLevel();
2194                 return;
2195         }
2196
2197         float checkrules_status;
2198         checkrules_status = WinningCondition_RanOutOfSpawns();
2199         if(checkrules_status == WINNING_YES)
2200         {
2201                 bprint("Hey! Someone ran out of spawns!\n");
2202         }
2203         else if(g_race && !g_race_qualifying && timelimit >= 0)
2204         {
2205                 checkrules_status = WinningCondition_Race(fraglimit);
2206                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2207         }
2208         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2209         {
2210                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2211                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2212         }
2213         else if(g_assault)
2214         {
2215                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2216         }
2217         else if(g_lms)
2218         {
2219                 checkrules_status = WinningCondition_LMS();
2220         }
2221         else if (g_onslaught)
2222         {
2223                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2224         }
2225         else
2226         {
2227                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2228                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2229         }
2230
2231         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2232         {
2233                 checkrules_status = WINNING_NEVER;
2234                 checkrules_overtimesadded = -1;
2235                 wantovertime |= InitiateSuddenDeath();
2236         }
2237
2238         if(checkrules_status == WINNING_NEVER)
2239                 // equality cases! Nobody wins if the overtime ends in a draw.
2240                 ClearWinners();
2241
2242         if(wantovertime)
2243         {
2244                 if(checkrules_status == WINNING_NEVER)
2245                         InitiateOvertime();
2246                 else
2247                         checkrules_status = WINNING_YES;
2248         }
2249
2250         if(checkrules_suddendeathend)
2251                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2252                         checkrules_status = WINNING_YES;
2253
2254         if(checkrules_status == WINNING_YES)
2255         {
2256                 //print("WINNING\n");
2257                 NextLevel();
2258         }
2259 };
2260
2261 float mapvote_nextthink;
2262 float mapvote_initialized;
2263 float mapvote_keeptwotime;
2264 float mapvote_timeout;
2265 string mapvote_message;
2266 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2267 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2268 float mapvote_screenshot_dirs_count;
2269
2270 float mapvote_count;
2271 float mapvote_count_real;
2272 string mapvote_maps[MAPVOTE_COUNT];
2273 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2274 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2275 float mapvote_maps_suggested[MAPVOTE_COUNT];
2276 string mapvote_suggestions[MAPVOTE_COUNT];
2277 float mapvote_suggestion_ptr;
2278 float mapvote_maxlen;
2279 float mapvote_voters;
2280 float mapvote_votes[MAPVOTE_COUNT];
2281 float mapvote_run;
2282 float mapvote_detail;
2283 float mapvote_abstain;
2284 .float mapvote;
2285
2286 void MapVote_ClearAllVotes()
2287 {
2288         FOR_EACH_CLIENT(other)
2289                 other.mapvote = 0;
2290 }
2291
2292 string MapVote_Suggest(string m)
2293 {
2294         float i;
2295         if(m == "")
2296                 return "That's not how to use this command.";
2297         if(!cvar("g_maplist_votable_suggestions"))
2298                 return "Suggestions are not accepted on this server.";
2299         if(mapvote_initialized)
2300                 return "Can't suggest - voting is already in progress!";
2301         m = MapInfo_FixName(m);
2302         if(!m)
2303                 return "The map you suggested is not available on this server.";
2304         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2305                 if(Map_IsRecent(m))
2306                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2307
2308         if(!MapInfo_CheckMap(m))
2309                 return "The map you suggested does not support the current game mode.";
2310         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2311                 if(mapvote_suggestions[i] == m)
2312                         return "This map was already suggested.";
2313         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2314         {
2315                 i = floor(random() * mapvote_suggestion_ptr);
2316         }
2317         else
2318         {
2319                 i = mapvote_suggestion_ptr;
2320                 mapvote_suggestion_ptr += 1;
2321         }
2322         if(mapvote_suggestions[i] != "")
2323                 strunzone(mapvote_suggestions[i]);
2324         mapvote_suggestions[i] = strzone(m);
2325         if(cvar("sv_eventlog"))
2326                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2327         return strcat("Suggestion of ", m, " accepted.");
2328 }
2329
2330 void MapVote_AddVotable(string nextMap, float isSuggestion)
2331 {
2332         float j, i, o;
2333         string pakfile, mapfile;
2334
2335         if(nextMap == "")
2336                 return;
2337         for(j = 0; j < mapvote_count; ++j)
2338                 if(mapvote_maps[j] == nextMap)
2339                         return;
2340         if(strlen(nextMap) > mapvote_maxlen)
2341                 mapvote_maxlen = strlen(nextMap);
2342         mapvote_maps[mapvote_count] = strzone(nextMap);
2343         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2344
2345         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2346         {
2347                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2348                 pakfile = whichpack(strcat(mapfile, ".tga"));
2349                 if(pakfile == "")
2350                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2351                 if(pakfile == "")
2352                         pakfile = whichpack(strcat(mapfile, ".png"));
2353                 if(pakfile != "")
2354                         break;
2355         }
2356         if(i >= mapvote_screenshot_dirs_count)
2357                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2358         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2359                 pakfile = substring(pakfile, o, -1);
2360
2361         mapvote_maps_screenshot_dir[mapvote_count] = i;
2362         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2363
2364         mapvote_count += 1;
2365 }
2366
2367 void MapVote_Spawn();
2368 void MapVote_Init()
2369 {
2370         float i;
2371         float nmax, smax;
2372
2373         MapVote_ClearAllVotes();
2374
2375         mapvote_count = 0;
2376         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2377         mapvote_abstain = cvar("g_maplist_votable_abstain");
2378
2379         if(mapvote_abstain)
2380                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2381         else
2382                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2383         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2384
2385         // we need this for AddVotable, as that cycles through the screenshot dirs
2386         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2387         if(mapvote_screenshot_dirs_count == 0)
2388                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2389         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2390         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2391                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2392
2393         if(mapvote_suggestion_ptr)
2394                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2395                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2396
2397         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2398                 MapVote_AddVotable(GetNextMap(), FALSE);
2399
2400         if(mapvote_count == 0)
2401         {
2402                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2403                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2404                 if(cvar("g_maplist_shuffle"))
2405                         ShuffleMaplist();
2406                 localcmd("\nmenu_cmd sync\n");
2407                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2408                         MapVote_AddVotable(GetNextMap(), FALSE);
2409         }
2410
2411         mapvote_count_real = mapvote_count;
2412         if(mapvote_abstain)
2413                 MapVote_AddVotable("don't care", 0);
2414
2415         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2416
2417         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2418         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2419         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2420                 mapvote_keeptwotime = 0;
2421         mapvote_message = "Choose a map and press its key!";
2422
2423         MapVote_Spawn();
2424 }
2425
2426 void MapVote_SendPicture(float id)
2427 {
2428         msg_entity = self;
2429         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2430         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2431         WriteByte(MSG_ONE, id);
2432         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2433 }
2434
2435 float GameCommand_MapVote(string cmd)
2436 {
2437         if(!intermission_running)
2438                 return FALSE;
2439
2440         if(cmd == "mv_getpic")
2441         {
2442                 MapVote_SendPicture(stof(argv(1)));
2443                 return TRUE;
2444         }
2445
2446         return FALSE;
2447 }
2448
2449 float MapVote_GetMapMask()
2450 {
2451         float mask, i, power;
2452         mask = 0;
2453         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2454                 if(mapvote_maps[i] != "")
2455                         mask |= power;
2456         return mask;
2457 }
2458
2459 entity mapvote_ent;
2460 float MapVote_SendEntity(entity to, float sf)
2461 {
2462         float i;
2463
2464         if(sf & 1)
2465                 sf &~= 2; // if we send 1, we don't need to also send 2
2466
2467         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2468         WriteByte(MSG_ENTITY, sf);
2469
2470         if(sf & 1)
2471         {
2472                 // flag 1 == initialization
2473                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2474                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2475                 WriteString(MSG_ENTITY, "");
2476                 WriteByte(MSG_ENTITY, mapvote_count);
2477                 WriteByte(MSG_ENTITY, mapvote_abstain);
2478                 WriteByte(MSG_ENTITY, mapvote_detail);
2479                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2480                 if(mapvote_count <= 8)
2481                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2482                 else
2483                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2484                 for(i = 0; i < mapvote_count; ++i)
2485                         if(mapvote_maps[i] != "")
2486                         {
2487                                 if(mapvote_abstain && i == mapvote_count - 1)
2488                                 {
2489                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2490                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2491                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2492                                 }
2493                                 else
2494                                 {
2495                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2496                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2497                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2498                                 }
2499                         }
2500         }
2501
2502         if(sf & 2)
2503         {
2504                 // flag 2 == update of mask
2505                 if(mapvote_count <= 8)
2506                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2507                 else
2508                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2509         }
2510
2511         if(sf & 4)
2512         {
2513                 if(mapvote_detail)
2514                         for(i = 0; i < mapvote_count; ++i)
2515                                 if(mapvote_maps[i] != "")
2516                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2517
2518                 WriteByte(MSG_ENTITY, to.mapvote);
2519         }
2520
2521         return TRUE;
2522 }
2523
2524 void MapVote_Spawn()
2525 {
2526         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2527 }
2528
2529 void MapVote_TouchMask()
2530 {
2531         mapvote_ent.SendFlags |= 2;
2532 }
2533
2534 void MapVote_TouchVotes(entity voter)
2535 {
2536         mapvote_ent.SendFlags |= 4;
2537 }
2538
2539 float MapVote_Finished(float mappos)
2540 {
2541         string result;
2542         float i;
2543         float didntvote;
2544
2545         if(cvar("sv_eventlog"))
2546         {
2547                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2548                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2549                 didntvote = mapvote_voters;
2550                 for(i = 0; i < mapvote_count; ++i)
2551                         if(mapvote_maps[i] != "")
2552                         {
2553                                 didntvote -= mapvote_votes[i];
2554                                 if(i != mappos)
2555                                 {
2556                                         result = strcat(result, ":", mapvote_maps[i]);
2557                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2558                                 }
2559                         }
2560                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2561
2562                 GameLogEcho(result);
2563                 if(mapvote_maps_suggested[mappos])
2564                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2565         }
2566
2567         FOR_EACH_REALCLIENT(other)
2568                 FixClientCvars(other);
2569
2570         Map_Goto_SetStr(mapvote_maps[mappos]);
2571         Map_Goto();
2572         alreadychangedlevel = TRUE;
2573         return TRUE;
2574 }
2575 void MapVote_CheckRules_1()
2576 {
2577         float i;
2578
2579         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2580         {
2581                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2582                 mapvote_votes[i] = 0;
2583         }
2584
2585         mapvote_voters = 0;
2586         FOR_EACH_REALCLIENT(other)
2587         {
2588                 ++mapvote_voters;
2589                 if(other.mapvote)
2590                 {
2591                         i = other.mapvote - 1;
2592                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2593                         mapvote_votes[i] = mapvote_votes[i] + 1;
2594                 }
2595         }
2596 }
2597
2598 float MapVote_CheckRules_2()
2599 {
2600         float i;
2601         float firstPlace, secondPlace;
2602         float firstPlaceVotes, secondPlaceVotes;
2603         float mapvote_voters_real;
2604         string result;
2605
2606         if(mapvote_count_real == 1)
2607                 return MapVote_Finished(0);
2608
2609         mapvote_voters_real = mapvote_voters;
2610         if(mapvote_abstain)
2611                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2612
2613         RandomSelection_Init();
2614         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2615                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2616         firstPlace = RandomSelection_chosen_float;
2617         firstPlaceVotes = RandomSelection_best_priority;
2618         //dprint("First place: ", ftos(firstPlace), "\n");
2619         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2620
2621         RandomSelection_Init();
2622         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2623                 if(i != firstPlace)
2624                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2625         secondPlace = RandomSelection_chosen_float;
2626         secondPlaceVotes = RandomSelection_best_priority;
2627         //dprint("Second place: ", ftos(secondPlace), "\n");
2628         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2629
2630         if(firstPlace == -1)
2631                 error("No first place in map vote... WTF?");
2632
2633         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2634                 return MapVote_Finished(firstPlace);
2635
2636         if(mapvote_keeptwotime)
2637                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2638                 {
2639                         float didntvote;
2640                         MapVote_TouchMask();
2641                         mapvote_message = "Now decide between the TOP TWO!";
2642                         mapvote_keeptwotime = 0;
2643                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2644                         result = strcat(result, ":", ftos(firstPlaceVotes));
2645                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2646                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2647                         didntvote = mapvote_voters;
2648                         for(i = 0; i < mapvote_count; ++i)
2649                                 if(mapvote_maps[i] != "")
2650                                 {
2651                                         didntvote -= mapvote_votes[i];
2652                                         if(i != firstPlace)
2653                                                 if(i != secondPlace)
2654                                                 {
2655                                                         result = strcat(result, ":", mapvote_maps[i]);
2656                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2657                                                         if(i < mapvote_count_real)
2658                                                         {
2659                                                                 strunzone(mapvote_maps[i]);
2660                                                                 mapvote_maps[i] = "";
2661                                                                 strunzone(mapvote_maps_pakfile[i]);
2662                                                                 mapvote_maps_pakfile[i] = "";
2663                                                         }
2664                                                 }
2665                                 }
2666                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2667                         if(cvar("sv_eventlog"))
2668                                 GameLogEcho(result);
2669                 }
2670
2671         return FALSE;
2672 }
2673 void MapVote_Tick()
2674 {
2675         float keeptwo;
2676         float totalvotes;
2677
2678         keeptwo = mapvote_keeptwotime;
2679         MapVote_CheckRules_1(); // count
2680         if(MapVote_CheckRules_2()) // decide
2681                 return;
2682
2683         totalvotes = 0;
2684         FOR_EACH_REALCLIENT(other)
2685         {
2686                 // hide scoreboard again
2687                 if(other.health != 2342)
2688                 {
2689                         other.health = 2342;
2690                         other.impulse = 0;
2691                         if(clienttype(other) == CLIENTTYPE_REAL)
2692                         {
2693                                 msg_entity = other;
2694                                 WriteByte(MSG_ONE, SVC_FINALE);
2695                                 WriteString(MSG_ONE, "");
2696                         }
2697                 }
2698
2699                 // clear possibly invalid votes
2700                 if(mapvote_maps[other.mapvote - 1] == "")
2701                         other.mapvote = 0;
2702                 // use impulses as new vote
2703                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2704                         if(mapvote_maps[other.impulse - 1] != "")
2705                         {
2706                                 other.mapvote = other.impulse;
2707                                 MapVote_TouchVotes(other);
2708                         }
2709                 other.impulse = 0;
2710
2711                 if(other.mapvote)
2712                         ++totalvotes;
2713         }
2714
2715         MapVote_CheckRules_1(); // just count
2716 }
2717 void MapVote_Start()
2718 {
2719         if(mapvote_run)
2720                 return;
2721
2722         MapInfo_Enumerate();
2723         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2724                 mapvote_run = TRUE;
2725 }
2726 void MapVote_Think()
2727 {
2728         if(!mapvote_run)
2729                 return;
2730
2731         if(alreadychangedlevel)
2732                 return;
2733
2734         if(time < mapvote_nextthink)
2735                 return;
2736         //dprint("tick\n");
2737
2738         mapvote_nextthink = time + 0.5;
2739
2740         if(!mapvote_initialized)
2741         {
2742                 if(cvar("rescan_pending") == 1)
2743                 {
2744                         cvar_set("rescan_pending", "2");
2745                         localcmd("fs_rescan\nrescan_pending 3\n");
2746                         return;
2747                 }
2748                 else if(cvar("rescan_pending") == 2)
2749                 {
2750                         return;
2751                 }
2752                 else if(cvar("rescan_pending") == 3)
2753                 {
2754                         // now build missing mapinfo files
2755                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2756                                 return;
2757
2758                         // we're done, start the timer
2759                         cvar_set("rescan_pending", "0");
2760                 }
2761
2762                 mapvote_initialized = TRUE;
2763                 if(DoNextMapOverride())
2764                         return;
2765                 if(!cvar("g_maplist_votable") || player_count <= 0)
2766                 {
2767                         GotoNextMap();
2768                         return;
2769                 }
2770                 MapVote_Init();
2771         }
2772
2773         MapVote_Tick();
2774 };
2775
2776 string GotoMap(string m)
2777 {
2778         if(!MapInfo_CheckMap(m))
2779                 return "The map you chose is not available on this server.";
2780         cvar_set("nextmap", m);
2781         cvar_set("timelimit", "-1");
2782         if(mapvote_initialized || alreadychangedlevel)
2783         {
2784                 if(DoNextMapOverride())
2785                         return "Map switch initiated.";
2786                 else
2787                         return "Hm... no. For some reason I like THIS map more.";
2788         }
2789         else
2790                 return "Map switch will happen after scoreboard.";
2791 }
2792
2793
2794 void EndFrame()
2795 {
2796         float altime;
2797         FOR_EACH_REALCLIENT(self)
2798         {
2799                 if(self.classname == "spectator")
2800                 {
2801                         if(self.enemy.typehitsound)
2802                                 play2(self, "misc/typehit.wav");
2803                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2804                                 play2(self, "misc/hit.wav");
2805                 }
2806                 else
2807                 {
2808                         if(self.typehitsound)
2809                                 play2(self, "misc/typehit.wav");
2810                         else if(self.hitsound && self.cvar_cl_hitsound)
2811                                 play2(self, "misc/hit.wav");
2812                 }
2813         }
2814         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2815         // add 1 frametime because after this, engine SV_Physics
2816         // increases time by a frametime and then networks the frame
2817         // add another frametime because client shows everything with
2818         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2819         // needed!
2820         FOR_EACH_CLIENT(self)
2821         {
2822                 self.hitsound = FALSE;
2823                 self.typehitsound = FALSE;
2824                 antilag_record(self, altime);
2825         }
2826 }
2827
2828
2829 /*
2830  * RedirectionThink:
2831  * returns TRUE if redirecting
2832  */
2833 float redirection_timeout;
2834 float redirection_nextthink;
2835 float RedirectionThink()
2836 {
2837         float clients_found;
2838
2839         if(redirection_target == "")
2840                 return FALSE;
2841
2842         if(!redirection_timeout)
2843         {
2844                 cvar_set("sv_public", "-2");
2845                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2846                 if(redirection_target == "self")
2847                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2848                 else
2849                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2850         }
2851
2852         if(time < redirection_nextthink)
2853                 return TRUE;
2854
2855         redirection_nextthink = time + 1;
2856
2857         clients_found = 0;
2858         FOR_EACH_REALCLIENT(self)
2859         {
2860                 print("Redirecting: sending connect command to ", self.netname, "\n");
2861                 if(redirection_target == "self")
2862                         stuffcmd(self, "\ndisconnect; reconnect\n");
2863                 else
2864                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2865                 ++clients_found;
2866         }
2867
2868         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2869
2870         if(time > redirection_timeout || clients_found == 0)
2871                 localcmd("\nwait; wait; wait; quit\n");
2872
2873         return TRUE;
2874 }
2875
2876 void TargetMusic_RestoreGame();
2877 void RestoreGame()
2878 {
2879         // Loaded from a save game
2880         // some things then break, so let's work around them...
2881
2882         // Progs DB (capture records)
2883         ServerProgsDB = db_load("server.db");
2884
2885         // Mapinfo
2886         MapInfo_Shutdown();
2887         MapInfo_Enumerate();
2888         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2889         WeaponStats_Init();
2890
2891         TargetMusic_RestoreGame();
2892 }
2893
2894 void SV_Shutdown()
2895 {
2896         if(gameover > 1) // shutting down already?
2897                 return;
2898
2899         gameover = 2; // 2 = server shutting down
2900
2901         if(world_initialized > 0)
2902         {
2903                 world_initialized = 0;
2904                 print("Saving persistent data...\n");
2905                 Ban_SaveBans();
2906                 if(!cheatcount_total)
2907                 {
2908                         if(cvar("sv_db_saveasdump"))
2909                                 db_dump(ServerProgsDB, "server.db");
2910                         else
2911                                 db_save(ServerProgsDB, "server.db");
2912                 }
2913                 if(cvar("developer"))
2914                 {
2915                         if(cvar("sv_db_saveasdump"))
2916                                 db_dump(TemporaryDB, "server-temp.db");
2917                         else
2918                                 db_save(TemporaryDB, "server-temp.db");
2919                 }
2920                 CheatShutdown(); // must be after cheatcount check
2921                 db_close(ServerProgsDB);
2922                 db_close(TemporaryDB);
2923                 print("done!\n");
2924                 // tell the bot system the game is ending now
2925                 bot_endgame();
2926
2927                 WeaponStats_Shutdown();
2928                 MapInfo_Shutdown();
2929         }
2930         else if(world_initialized == 0)
2931         {
2932                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2933         }
2934 }