qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/mutators_include.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/all.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications.qh"
  29 #include "../common/physics.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/all.qh"
  36 #include "../common/weapons/all.qh"
  37
  38 const float LATENCY_THINKRATE = 10;
  39 .float latency_sum;
  40 .float latency_cnt;
  41 .float latency_time;
  42 entity pingplreport;
  43 void PingPLReport_Think()
  44 {SELFPARAM();
  45         float delta;
  46         entity e;
  47
  48         delta = 3 / maxclients;
  49         if(delta < sys_frametime)
  50                 delta = 0;
  51         self.nextthink = time + delta;
  52
  53         e = edict_num(self.cnt + 1);
  54         if(IS_REAL_CLIENT(e))
  55         {
  56                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  57                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  75                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, self.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         self.cnt = (self.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = spawn();
  86         pingplreport.classname = "pingplreport";
  87         pingplreport.think = PingPLReport_Think;
  88         pingplreport.nextthink = time;
  89 }
  90
  91 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  92 string redirection_target;
  93 float world_initialized;
  94
  95 string GetGametype();
  96 void ShuffleMaplist();
  97
  98 void SetDefaultAlpha()
  99 {
 100         if(autocvar_g_running_guns)
 101         {
 102                 default_player_alpha = -1;
 103                 default_weapon_alpha = +1;
 104         }
 105         else if(g_cloaked)
 106         {
 107                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 108                 default_weapon_alpha = default_player_alpha;
 109         }
 110         else
 111         {
 112                 default_player_alpha = autocvar_g_player_alpha;
 113                 if(default_player_alpha == 0)
 114                         default_player_alpha = 1;
 115                 default_weapon_alpha = default_player_alpha;
 116         }
 117 }
 118
 119 void GotoFirstMap()
 120 {SELFPARAM();
 121         float n;
 122         if(autocvar__sv_init)
 123         {
 124                 // cvar_set("_sv_init", "0");
 125                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 126                 // to this "init" map on a dedicated server will cause no permanent
 127                 // harm
 128                 if(autocvar_g_maplist_shuffle)
 129                         ShuffleMaplist();
 130                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 131                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 132
 133                 MapInfo_Enumerate();
 134                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 135
 136                 if(!DoNextMapOverride(1))
 137                         GotoNextMap(1);
 138
 139                 return;
 140         }
 141
 142         if(time < 5)
 143         {
 144                 self.nextthink = time;
 145         }
 146         else
 147         {
 148                 self.nextthink = time + 1;
 149                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 150         }
 151 }
 152
 153 void cvar_changes_init()
 154 {
 155         float h;
 156         string k, v, d;
 157         float n, i, adding, pureadding;
 158
 159         if(cvar_changes)
 160                 strunzone(cvar_changes);
 161         cvar_changes = string_null;
 162         if(cvar_purechanges)
 163                 strunzone(cvar_purechanges);
 164         cvar_purechanges = string_null;
 165         cvar_purechanges_count = 0;
 166
 167         h = buf_create();
 168         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 169         n = buf_getsize(h);
 170
 171         adding = true;
 172         pureadding = true;
 173
 174         for(i = 0; i < n; ++i)
 175         {
 176                 k = bufstr_get(h, i);
 177
 178 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 179 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 180 #define BADCVAR(p) if(k == p) continue
 181
 182                 // general excludes and namespaces for server admin used cvars
 183                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 184
 185                 // internal
 186                 BADPREFIX("csqc_");
 187                 BADPREFIX("cvar_check_");
 188                 BADCVAR("gamecfg");
 189                 BADCVAR("g_configversion");
 190                 BADCVAR("g_maplist_index");
 191                 BADCVAR("halflifebsp");
 192                 BADCVAR("sv_mapformat_is_quake2");
 193                 BADCVAR("sv_mapformat_is_quake3");
 194                 BADPREFIX("sv_world");
 195
 196                 // client
 197                 BADPREFIX("chase_");
 198                 BADPREFIX("cl_");
 199                 BADPREFIX("con_");
 200                 BADPREFIX("scoreboard_");
 201                 BADPREFIX("g_campaign");
 202                 BADPREFIX("g_waypointsprite_");
 203                 BADPREFIX("gl_");
 204                 BADPREFIX("joy");
 205                 BADPREFIX("hud_");
 206                 BADPREFIX("m_");
 207                 BADPREFIX("menu_");
 208                 BADPREFIX("net_slist_");
 209                 BADPREFIX("r_");
 210                 BADPREFIX("sbar_");
 211                 BADPREFIX("scr_");
 212                 BADPREFIX("snd_");
 213                 BADPREFIX("show");
 214                 BADPREFIX("sensitivity");
 215                 BADPREFIX("userbind");
 216                 BADPREFIX("v_");
 217                 BADPREFIX("vid_");
 218                 BADPREFIX("crosshair");
 219                 BADCVAR("mod_q3bsp_lightmapmergepower");
 220                 BADCVAR("mod_q3bsp_nolightmaps");
 221                 BADCVAR("fov");
 222                 BADCVAR("mastervolume");
 223                 BADCVAR("volume");
 224                 BADCVAR("bgmvolume");
 225
 226                 // private
 227                 BADCVAR("developer");
 228                 BADCVAR("log_dest_udp");
 229                 BADCVAR("net_address");
 230                 BADCVAR("net_address_ipv6");
 231                 BADCVAR("port");
 232                 BADCVAR("savedgamecfg");
 233                 BADCVAR("serverconfig");
 234                 BADCVAR("sv_autoscreenshot");
 235                 BADCVAR("sv_heartbeatperiod");
 236                 BADCVAR("sv_vote_master_password");
 237                 BADCVAR("sys_colortranslation");
 238                 BADCVAR("sys_specialcharactertranslation");
 239                 BADCVAR("timeformat");
 240                 BADCVAR("timestamps");
 241                 BADPREFIX("developer_");
 242                 BADPREFIX("g_ban_");
 243                 BADPREFIX("g_banned_list");
 244                 BADPREFIX("g_chat_flood_");
 245                 BADPREFIX("g_ghost_items");
 246                 BADPREFIX("g_playerstats_");
 247                 BADPREFIX("g_respawn_ghosts");
 248                 BADPREFIX("g_voice_flood_");
 249                 BADPREFIX("log_file");
 250                 BADPREFIX("rcon_");
 251                 BADPREFIX("sv_allowdownloads");
 252                 BADPREFIX("sv_autodemo");
 253                 BADPREFIX("sv_curl_");
 254                 BADPREFIX("sv_eventlog");
 255                 BADPREFIX("sv_logscores_");
 256                 BADPREFIX("sv_master");
 257                 BADPREFIX("sv_weaponstats_");
 258                 BADPREFIX("sv_waypointsprite_");
 259                 BADCVAR("rescan_pending");
 260
 261                 // these can contain player IDs, so better hide
 262                 BADPREFIX("g_forced_team_");
 263
 264                 // mapinfo
 265                 BADCVAR("fraglimit");
 266                 BADCVAR("g_assault");
 267                 BADCVAR("g_ca");
 268                 BADCVAR("g_ca_teams");
 269                 BADCVAR("g_ctf");
 270                 BADCVAR("g_cts");
 271                 BADCVAR("g_dm");
 272                 BADCVAR("g_domination");
 273                 BADCVAR("g_domination_default_teams");
 274                 BADCVAR("g_freezetag");
 275                 BADCVAR("g_freezetag_teams");
 276                 BADCVAR("g_invasion_teams");
 277                 BADCVAR("g_keepaway");
 278                 BADCVAR("g_keyhunt");
 279                 BADCVAR("g_keyhunt_teams");
 280                 BADCVAR("g_lms");
 281                 BADCVAR("g_nexball");
 282                 BADCVAR("g_onslaught");
 283                 BADCVAR("g_race");
 284                 BADCVAR("g_race_qualifying_timelimit");
 285                 BADCVAR("g_tdm");
 286                 BADCVAR("g_tdm_teams");
 287                 BADCVAR("leadlimit");
 288                 BADCVAR("nextmap");
 289                 BADCVAR("teamplay");
 290                 BADCVAR("timelimit");
 291
 292                 // long
 293                 BADCVAR("hostname");
 294                 BADCVAR("g_maplist");
 295                 BADCVAR("g_maplist_mostrecent");
 296                 BADCVAR("sv_motd");
 297
 298                 v = cvar_string(k);
 299                 d = cvar_defstring(k);
 300                 if(v == d)
 301                         continue;
 302
 303                 if(adding)
 304                 {
 305                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 306                         if(strlen(cvar_changes) > 16384)
 307                         {
 308                                 cvar_changes = "// too many settings have been changed to show them here\n";
 309                                 adding = 0;
 310                         }
 311                 }
 312
 313                 // now check if the changes are actually gameplay relevant
 314
 315                 // does nothing visible
 316                 BADCVAR("captureleadlimit_override");
 317                 BADCVAR("g_balance_kill_delay");
 318                 BADCVAR("g_ca_point_limit");
 319                 BADCVAR("g_ca_point_leadlimit");
 320                 BADCVAR("g_ctf_captimerecord_always");
 321                 BADCVAR("g_ctf_flag_glowtrails");
 322                 BADCVAR("g_ctf_flag_pickup_verbosename");
 323                 BADCVAR("g_domination_point_leadlimit");
 324                 BADCVAR("g_forced_respawn");
 325                 BADCVAR("g_freezetag_point_limit");
 326                 BADCVAR("g_freezetag_point_leadlimit");
 327                 BADCVAR("g_keyhunt_point_leadlimit");
 328                 BADPREFIX("g_mod_");
 329                 BADCVAR("g_invasion_point_limit");
 330                 BADCVAR("g_nexball_goalleadlimit");
 331                 BADCVAR("g_tdm_point_limit");
 332                 BADCVAR("g_tdm_point_leadlimit");
 333                 BADCVAR("leadlimit_and_fraglimit");
 334                 BADCVAR("leadlimit_override");
 335                 BADCVAR("pausable");
 336                 BADCVAR("sv_allow_fullbright");
 337                 BADCVAR("sv_checkforpacketsduringsleep");
 338                 BADCVAR("sv_timeout");
 339                 BADPREFIX("sv_timeout_");
 340                 BADPREFIX("crypto_");
 341                 BADPREFIX("g_chat_");
 342                 BADPREFIX("g_ctf_captimerecord_");
 343                 BADPREFIX("g_maplist_votable_");
 344                 BADPREFIX("net_");
 345                 BADPREFIX("prvm_");
 346                 BADPREFIX("skill_");
 347                 BADPREFIX("sv_cullentities_");
 348                 BADPREFIX("sv_maxidle_");
 349                 BADPREFIX("sv_vote_");
 350                 BADPREFIX("timelimit_");
 351                 BADCVAR("gameversion");
 352                 BADPREFIX("gameversion_");
 353                 BADCVAR("sv_minigames");
 354                 BADPREFIX("sv_minigames_");
 355                 BADCVAR("sv_namechangetimer");
 356
 357                 // allowed changes to server admins (please sync this to server.cfg)
 358                 // vi commands:
 359                 //   :/"impure"/,$d
 360                 //   :g!,^\/\/[^ /],d
 361                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 362                 //   :%!sort
 363                 // yes, this does contain some redundant stuff, don't really care
 364                 BADCVAR("bot_config_file");
 365                 BADCVAR("bot_number");
 366                 BADCVAR("bot_prefix");
 367                 BADCVAR("bot_suffix");
 368                 BADCVAR("capturelimit_override");
 369                 BADCVAR("fraglimit_override");
 370                 BADCVAR("gametype");
 371                 BADCVAR("g_antilag");
 372                 BADCVAR("g_balance_teams");
 373                 BADCVAR("g_balance_teams_prevent_imbalance");
 374                 BADCVAR("g_balance_teams_scorefactor");
 375                 BADCVAR("g_ban_sync_trusted_servers");
 376                 BADCVAR("g_ban_sync_uri");
 377                 BADCVAR("g_ca_teams_override");
 378                 BADCVAR("g_ctf_ignore_frags");
 379                 BADCVAR("g_domination_point_limit");
 380                 BADCVAR("g_domination_teams_override");
 381                 BADCVAR("g_freezetag_teams_override");
 382                 BADCVAR("g_friendlyfire");
 383                 BADCVAR("g_fullbrightitems");
 384                 BADCVAR("g_fullbrightplayers");
 385                 BADCVAR("g_keyhunt_point_limit");
 386                 BADCVAR("g_keyhunt_teams_override");
 387                 BADCVAR("g_lms_lives_override");
 388                 BADCVAR("g_maplist");
 389                 BADCVAR("g_maplist_check_waypoints");
 390                 BADCVAR("g_maplist_mostrecent_count");
 391                 BADCVAR("g_maplist_shuffle");
 392                 BADCVAR("g_maplist_votable");
 393                 BADCVAR("g_maplist_votable_abstain");
 394                 BADCVAR("g_maplist_votable_nodetail");
 395                 BADCVAR("g_maplist_votable_suggestions");
 396                 BADCVAR("g_maxplayers");
 397                 BADCVAR("g_mirrordamage");
 398                 BADCVAR("g_nexball_goallimit");
 399                 BADCVAR("g_powerups");
 400                 BADCVAR("g_start_delay");
 401                 BADCVAR("g_tdm_teams_override");
 402                 BADCVAR("g_warmup");
 403                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 404                 BADCVAR("hostname");
 405                 BADCVAR("log_file");
 406                 BADCVAR("maxplayers");
 407                 BADCVAR("minplayers");
 408                 BADCVAR("net_address");
 409                 BADCVAR("port");
 410                 BADCVAR("rcon_password");
 411                 BADCVAR("rcon_restricted_commands");
 412                 BADCVAR("rcon_restricted_password");
 413                 BADCVAR("skill");
 414                 BADCVAR("sv_adminnick");
 415                 BADCVAR("sv_autoscreenshot");
 416                 BADCVAR("sv_autotaunt");
 417                 BADCVAR("sv_curl_defaulturl");
 418                 BADCVAR("sv_defaultcharacter");
 419                 BADCVAR("sv_defaultplayercolors");
 420                 BADCVAR("sv_defaultplayermodel");
 421                 BADCVAR("sv_defaultplayerskin");
 422                 BADCVAR("sv_maxidle");
 423                 BADCVAR("sv_maxrate");
 424                 BADCVAR("sv_motd");
 425                 BADCVAR("sv_public");
 426                 BADCVAR("sv_ready_restart");
 427                 BADCVAR("sv_status_privacy");
 428                 BADCVAR("sv_taunt");
 429                 BADCVAR("sv_vote_call");
 430                 BADCVAR("sv_vote_commands");
 431                 BADCVAR("sv_vote_majority_factor");
 432                 BADCVAR("sv_vote_master");
 433                 BADCVAR("sv_vote_master_commands");
 434                 BADCVAR("sv_vote_master_password");
 435                 BADCVAR("sv_vote_simple_majority_factor");
 436                 BADCVAR("teamplay_mode");
 437                 BADCVAR("timelimit_override");
 438                 BADCVAR("g_spawnshieldtime");
 439                 BADPREFIX("g_warmup_");
 440                 BADPREFIX("sv_ready_restart_");
 441
 442                 // mutators that announce themselves properly to the server browser
 443                 BADCVAR("g_instagib");
 444                 BADCVAR("g_new_toys");
 445                 BADCVAR("g_nix");
 446                 BADCVAR("g_grappling_hook");
 447                 BADCVAR("g_jetpack");
 448
 449 #undef BADPREFIX
 450 #undef BADCVAR
 451
 452                 if(pureadding)
 453                 {
 454                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 455                         if(strlen(cvar_purechanges) > 16384)
 456                         {
 457                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 458                                 pureadding = 0;
 459                         }
 460                 }
 461                 ++cvar_purechanges_count;
 462                 // WARNING: this variable is used for the server list
 463                 // NEVER dare to skip this code!
 464                 // Hacks to intentionally appearing as "pure server" even though you DO have
 465                 // modified settings may be punished by removal from the server list.
 466                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 467                 // though.
 468         }
 469         buf_del(h);
 470         if(cvar_changes == "")
 471                 cvar_changes = "// this server runs at default server settings\n";
 472         else
 473                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 474         cvar_changes = strzone(cvar_changes);
 475         if(cvar_purechanges == "")
 476                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 477         else
 478                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 479         cvar_purechanges = strzone(cvar_purechanges);
 480 }
 481
 482 void detect_maptype()
 483 {
 484 #if 0
 485         vector o, v;
 486         float i;
 487
 488         for (;;)
 489         {
 490                 o = world.mins;
 491                 o.x += random() * (world.maxs.x - world.mins.x);
 492                 o.y += random() * (world.maxs.y - world.mins.y);
 493                 o.z += random() * (world.maxs.z - world.mins.z);
 494
 495                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 496                 if(trace_fraction == 1)
 497                         continue;
 498
 499                 v = trace_endpos;
 500
 501                 for(i = 0; i < 64; i += 4)
 502                 {
 503                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 504         if(trace_fraction == 1)
 505                 continue;
 506                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 507                 }
 508
 509                 break;
 510         }
 511 #endif
 512 }
 513
 514 entity randomseed;
 515 bool RandomSeed_Send(entity this, entity to, int sf)
 516 {
 517         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 518         WriteShort(MSG_ENTITY, self.cnt);
 519         return true;
 520 }
 521 void RandomSeed_Think()
 522 {SELFPARAM();
 523         self.cnt = bound(0, floor(random() * 65536), 65535);
 524         self.nextthink = time + 5;
 525
 526         self.SendFlags |= 1;
 527 }
 528 void RandomSeed_Spawn()
 529 {SELFPARAM();
 530         randomseed = spawn();
 531         randomseed.think = RandomSeed_Think;
 532         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 533
 534         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 535 }
 536
 537 spawnfunc(__init_dedicated_server)
 538 {
 539         // handler for _init/_init map (only for dedicated server initialization)
 540
 541         world_initialized = -1; // don't complain
 542         cvar = cvar_normal;
 543         cvar_string = cvar_string_normal;
 544         cvar_set = cvar_set_normal;
 545
 546         remove = remove_unsafely;
 547
 548         entity e;
 549         e = spawn();
 550         e.think = GotoFirstMap;
 551         e.nextthink = time; // this is usually 1 at this point
 552
 553         e = spawn();
 554         e.classname = "info_player_deathmatch"; // safeguard against player joining
 555
 556         self.classname = "worldspawn"; // safeguard against various stuff ;)
 557
 558         // needs to be done so early because of the constants they create
 559         static_init();
 560
 561         MapInfo_Enumerate();
 562         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 563 }
 564
 565 void Map_MarkAsRecent(string m);
 566 float world_already_spawned;
 567 void Nagger_Init();
 568 void ClientInit_Spawn();
 569 void WeaponStats_Init();
 570 void WeaponStats_Shutdown();
 571 void Physics_AddStats();
 572 spawnfunc(worldspawn)
 573 {
 574         float fd, l, j, n;
 575         string s;
 576
 577         cvar = cvar_normal;
 578         cvar_string = cvar_string_normal;
 579         cvar_set = cvar_set_normal;
 580
 581         if(world_already_spawned)
 582                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 583         world_already_spawned = true;
 584
 585         remove = remove_safely; // during spawning, watch what you remove!
 586
 587         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 588
 589         compressShortVector_init();
 590
 591         entity head;
 592         head = nextent(world);
 593         maxclients = 0;
 594         while(head)
 595         {
 596                 ++maxclients;
 597                 head = nextent(head);
 598         }
 599
 600         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 601
 602         // needs to be done so early because of the constants they create
 603         static_init();
 604
 605         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 606
 607         TemporaryDB = db_create();
 608
 609         // 0 normal
 610         lightstyle(0, "m");
 611
 612         // 1 FLICKER (first variety)
 613         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 614
 615         // 2 SLOW STRONG PULSE
 616         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 617
 618         // 3 CANDLE (first variety)
 619         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 620
 621         // 4 FAST STROBE
 622         lightstyle(4, "mamamamamama");
 623
 624         // 5 GENTLE PULSE 1
 625         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 626
 627         // 6 FLICKER (second variety)
 628         lightstyle(6, "nmonqnmomnmomomno");
 629
 630         // 7 CANDLE (second variety)
 631         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 632
 633         // 8 CANDLE (third variety)
 634         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 635
 636         // 9 SLOW STROBE (fourth variety)
 637         lightstyle(9, "aaaaaaaazzzzzzzz");
 638
 639         // 10 FLUORESCENT FLICKER
 640         lightstyle(10, "mmamammmmammamamaaamammma");
 641
 642         // 11 SLOW PULSE NOT FADE TO BLACK
 643         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 644
 645         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 646
 647         // 63 testing
 648         lightstyle(63, "a");
 649
 650         if(autocvar_g_campaign)
 651                 CampaignPreInit();
 652
 653         Map_MarkAsRecent(mapname);
 654
 655         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 656
 657         InitGameplayMode();
 658         readlevelcvars();
 659         GrappleHookInit();
 660
 661         player_count = 0;
 662         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 663         if(bot_waypoints_for_items == 1)
 664                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 665                         bot_waypoints_for_items = 0;
 666
 667         precache();
 668
 669         WaypointSprite_Init();
 670
 671         GameLogInit(); // prepare everything
 672         // NOTE for matchid:
 673         // changing the logic generating it is okay. But:
 674         // it HAS to stay <= 64 chars
 675         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 676         if(autocvar_sv_eventlog)
 677         {
 678                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 679                 matchid = strzone(s);
 680
 681                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 682                 s = ":gameinfo:mutators:LIST";
 683
 684                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 685                 s = ret_string;
 686
 687                 // initialiation stuff, not good in the mutator system
 688                 if(!autocvar_g_use_ammunition)
 689                         s = strcat(s, ":no_use_ammunition");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(autocvar_g_pickup_items == 0)
 693                         s = strcat(s, ":no_pickup_items");
 694                 if(autocvar_g_pickup_items > 0)
 695                         s = strcat(s, ":pickup_items");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(autocvar_g_weaponarena != "0")
 699                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 700
 701                 // TODO to mutator system
 702                 if(autocvar_g_norecoil)
 703                         s = strcat(s, ":norecoil");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_powerups == 0)
 707                         s = strcat(s, ":no_powerups");
 708                 if(autocvar_g_powerups > 0)
 709                         s = strcat(s, ":powerups");
 710
 711                 GameLogEcho(s);
 712                 GameLogEcho(":gameinfo:end");
 713         }
 714         else
 715                 matchid = strzone(ftos(random()));
 716
 717         cvar_set("nextmap", "");
 718
 719         SetDefaultAlpha();
 720
 721         if(autocvar_g_campaign)
 722                 CampaignPostInit();
 723
 724         Ban_LoadBans();
 725
 726         MapInfo_Enumerate();
 727         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 728
 729         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 730         {
 731                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 732                 if(fd != -1)
 733                 {
 734                         while((s = fgets(fd)))
 735                         {
 736                                 l = tokenize_console(s);
 737                                 if(l < 2)
 738                                         continue;
 739                                 if(argv(0) == "cd")
 740                                 {
 741                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 742                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 743                                 }
 744                                 else if(argv(0) == "fog")
 745                                 {
 746                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 747                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 748                                 }
 749                                 else if(argv(0) == "set")
 750                                 {
 751                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 752                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 753                                 }
 754                                 else if(argv(0) != "//")
 755                                 {
 756                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 757                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 758                                 }
 759                         }
 760                         fclose(fd);
 761                 }
 762         }
 763
 764         WeaponStats_Init();
 765
 766         WepSet_AddStat();
 767         WepSet_AddStat_InMap();
 768         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 769         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 770         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 771         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 772         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 773         Nagger_Init();
 774
 775         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 776         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 777         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 778         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 779         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 780         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 781         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 782         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 783         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 784         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 785         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 786         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 787         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 788         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 789         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 790
 791         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 792         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 793
 794         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 795
 796         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 797
 798         // freeze attacks
 799         addstat(STAT_FROZEN, AS_INT, frozen);
 800         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 801
 802         // physics
 803         Physics_AddStats();
 804
 805         // new properties
 806         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 807         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 808         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 809         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 810         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 811         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 812         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 813         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 814         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 815         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 816         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 817         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 818         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 819         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 820         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 821         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 822         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 823         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 824         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 825
 826         // secrets
 827         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 828         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 829
 830         // monsters
 831         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 832         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 833
 834         // misc
 835         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 836
 837         next_pingtime = time + 5;
 838
 839         detect_maptype();
 840
 841         // set up information replies for clients and server to use
 842         maplist_reply = strzone(getmaplist());
 843         lsmaps_reply = strzone(getlsmaps());
 844         monsterlist_reply = strzone(getmonsterlist());
 845         for(int i = 0; i < 10; ++i)
 846         {
 847                 s = getrecords(i);
 848                 if (s)
 849                         records_reply[i] = strzone(s);
 850         }
 851         ladder_reply = strzone(getladder());
 852         rankings_reply = strzone(getrankings());
 853
 854         // begin other init
 855         ClientInit_Spawn();
 856         RandomSeed_Spawn();
 857         PingPLReport_Spawn();
 858
 859         CheatInit();
 860
 861         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 862
 863         // fill sv_curl_serverpackages from .serverpackage files
 864         if(autocvar_sv_curl_serverpackages_auto)
 865         {
 866                 s = "";
 867                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 868                 for(int i = 0; i < n; ++i)
 869                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 870                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 871                                 s = strcat(s, " ", argv(i));
 872                 fd = search_begin("*-serverpackage.txt", true, false);
 873                 if(fd >= 0)
 874                 {
 875                         j = search_getsize(fd);
 876                         for(int i = 0; i < j; ++i)
 877                                 s = strcat(s, " ", search_getfilename(fd, i));
 878                         search_end(fd);
 879                 }
 880                 fd = search_begin("*.serverpackage", true, false);
 881                 if(fd >= 0)
 882                 {
 883                         j = search_getsize(fd);
 884                         for(int i = 0; i < j; ++i)
 885                                 s = strcat(s, " ", search_getfilename(fd, i));
 886                         search_end(fd);
 887                 }
 888                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 889         }
 890
 891         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 892         modname = "Xonotic";
 893         // physics/balance/config changes that count as mod
 894         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 895                 modname = cvar_string("g_mod_physics");
 896         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 897                 modname = cvar_string("g_mod_balance");
 898         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 899                 modname = cvar_string("g_mod_config");
 900         // extra mutators that deserve to count as mod
 901         MUTATOR_CALLHOOK(SetModname);
 902
 903         // save it for later
 904         modname = strzone(modname);
 905
 906         WinningConditionHelper(); // set worldstatus
 907
 908         world_initialized = 1;
 909 }
 910
 911 spawnfunc(light)
 912 {
 913         //makestatic (self); // Who the f___ did that?
 914         remove(self);
 915 }
 916
 917 string GetGametype()
 918 {
 919         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 920 }
 921
 922 string GetMapname()
 923 {
 924         return mapname;
 925 }
 926
 927 float Map_Count, Map_Current;
 928 string Map_Current_Name;
 929
 930 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 931 float GetMaplistPosition()
 932 {
 933         float pos, idx;
 934         string map;
 935
 936         map = GetMapname();
 937         idx = autocvar_g_maplist_index;
 938
 939         if(idx >= 0)
 940                 if(idx < Map_Count)
 941                         if(map == argv(idx))
 942                                 return idx;
 943
 944         for(pos = 0; pos < Map_Count; ++pos)
 945                 if(map == argv(pos))
 946                         return pos;
 947
 948         // resume normal maplist rotation if current map is not in g_maplist
 949         return idx;
 950 }
 951
 952 float MapHasRightSize(string map)
 953 {
 954         float fh;
 955         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 956         if(autocvar_g_maplist_check_waypoints)
 957         {
 958                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 959                 if(!fexists(strcat("maps/", map, ".waypoints")))
 960                 {
 961                         LOG_TRACE(": no waypoints\n");
 962                         return false;
 963                 }
 964                 LOG_TRACE(": has waypoints\n");
 965         }
 966
 967         // open map size restriction file
 968         LOG_TRACE("opensize "); LOG_TRACE(map);
 969         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 970         if(fh >= 0)
 971         {
 972                 float mapmin, mapmax;
 973                 LOG_TRACE(": ok, ");
 974                 mapmin = stof(fgets(fh));
 975                 mapmax = stof(fgets(fh));
 976                 fclose(fh);
 977                 if(player_count < mapmin)
 978                 {
 979                         LOG_TRACE("not enough\n");
 980                         return false;
 981                 }
 982                 if(player_count > mapmax)
 983                 {
 984                         LOG_TRACE("too many\n");
 985                         return false;
 986                 }
 987                 LOG_TRACE("right size\n");
 988                 return true;
 989         }
 990         LOG_TRACE(": not found\n");
 991         return true;
 992 }
 993
 994 string Map_Filename(float position)
 995 {
 996         return strcat("maps/", argv(position), ".bsp");
 997 }
 998
 999 void Map_MarkAsRecent(string m)
1000 {
1001         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1002 }
1003
1004 float Map_IsRecent(string m)
1005 {
1006         return strhasword(autocvar_g_maplist_mostrecent, m);
1007 }
1008
1009 float Map_Check(float position, float pass)
1010 {
1011         string filename;
1012         string map_next;
1013         map_next = argv(position);
1014         if(pass <= 1)
1015         {
1016                 if(Map_IsRecent(map_next))
1017                         return 0;
1018         }
1019         filename = Map_Filename(position);
1020         if(MapInfo_CheckMap(map_next))
1021         {
1022                 if(pass == 2)
1023                         return 1;
1024                 if(MapHasRightSize(map_next))
1025                         return 1;
1026                 return 0;
1027         }
1028         else
1029                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1030
1031         return 0;
1032 }
1033
1034 void Map_Goto_SetStr(string nextmapname)
1035 {
1036         if(getmapname_stored != "")
1037                 strunzone(getmapname_stored);
1038         if(nextmapname == "")
1039                 getmapname_stored = "";
1040         else
1041                 getmapname_stored = strzone(nextmapname);
1042 }
1043
1044 void Map_Goto_SetFloat(float position)
1045 {
1046         cvar_set("g_maplist_index", ftos(position));
1047         Map_Goto_SetStr(argv(position));
1048 }
1049
1050 void Map_Goto(float reinit)
1051 {
1052         MapInfo_LoadMap(getmapname_stored, reinit);
1053 }
1054
1055 // return codes of map selectors:
1056 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1057 //   -2 = permanent failure
1058 float() MaplistMethod_Iterate = // usual method
1059 {
1060         float pass, i;
1061
1062         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1063
1064         for(pass = 1; pass <= 2; ++pass)
1065         {
1066                 for(i = 1; i < Map_Count; ++i)
1067                 {
1068                         float mapindex;
1069                         mapindex = (i + Map_Current) % Map_Count;
1070                         if(Map_Check(mapindex, pass))
1071                                 return mapindex;
1072                 }
1073         }
1074         return -1;
1075 }
1076
1077 float() MaplistMethod_Repeat = // fallback method
1078 {
1079         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1080
1081         if(Map_Check(Map_Current, 2))
1082                 return Map_Current;
1083         return -2;
1084 }
1085
1086 float() MaplistMethod_Random = // random map selection
1087 {
1088         float i, imax;
1089
1090         LOG_TRACE("Trying MaplistMethod_Random\n");
1091
1092         imax = 42;
1093
1094         for(i = 0; i <= imax; ++i)
1095         {
1096                 float mapindex;
1097                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1098                 if(Map_Check(mapindex, 1))
1099                         return mapindex;
1100         }
1101         return -1;
1102 }
1103
1104 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1105 // the exponent sets a bias on the map selection:
1106 // the higher the exponent, the less likely "shortly repeated" same maps are
1107 {
1108         float i, j, imax, insertpos;
1109
1110         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1111
1112         imax = 42;
1113
1114         for(i = 0; i <= imax; ++i)
1115         {
1116                 string newlist;
1117
1118                 // now reinsert this at another position
1119                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1120                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1121                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1122                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1123
1124                 // insert the current map there
1125                 newlist = "";
1126                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1127                         newlist = strcat(newlist, " ", argv(j));
1128                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1129                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1130                         newlist = strcat(newlist, " ", argv(j));
1131                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1132                 cvar_set("g_maplist", newlist);
1133                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1134
1135                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1136                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1137                 if(Map_Check(Map_Current, 1))
1138                         return Map_Current;
1139         }
1140         return -1;
1141 }
1142
1143 void Maplist_Init()
1144 {
1145         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1146         float i;
1147         for (i = 0; i < Map_Count; ++i)
1148                 if (Map_Check(i, 2))
1149                         break;
1150         if (i == Map_Count)
1151         {
1152                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1153                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1154                 if(autocvar_g_maplist_shuffle)
1155                         ShuffleMaplist();
1156                 localcmd("\nmenu_cmd sync\n");
1157                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1158         }
1159         if(Map_Count == 0)
1160                 error("empty maplist, cannot select a new map");
1161         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1162
1163         if(Map_Current_Name)
1164                 strunzone(Map_Current_Name);
1165         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1166         // this may or may not be correct, but who cares, in the worst case a map
1167         // isn't chosen in the first pass that should have been
1168 }
1169
1170 string GetNextMap()
1171 {
1172         float nextMap;
1173
1174         Maplist_Init();
1175         nextMap = -1;
1176
1177         if(nextMap == -1)
1178                 if(autocvar_g_maplist_shuffle > 0)
1179                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1180
1181         if(nextMap == -1)
1182                 if(autocvar_g_maplist_selectrandom)
1183                         nextMap = MaplistMethod_Random();
1184
1185         if(nextMap == -1)
1186                 nextMap = MaplistMethod_Iterate();
1187
1188         if(nextMap == -1)
1189                 nextMap = MaplistMethod_Repeat();
1190
1191         if(nextMap >= 0)
1192         {
1193                 Map_Goto_SetFloat(nextMap);
1194                 return getmapname_stored;
1195         }
1196
1197         return "";
1198 }
1199
1200 float DoNextMapOverride(float reinit)
1201 {
1202         if(autocvar_g_campaign)
1203         {
1204                 CampaignPostIntermission();
1205                 alreadychangedlevel = true;
1206                 return true;
1207         }
1208         if(autocvar_quit_when_empty)
1209         {
1210                 if(player_count <= currentbots)
1211                 {
1212                         localcmd("quit\n");
1213                         alreadychangedlevel = true;
1214                         return true;
1215                 }
1216         }
1217         if(autocvar_quit_and_redirect != "")
1218         {
1219                 redirection_target = strzone(autocvar_quit_and_redirect);
1220                 alreadychangedlevel = true;
1221                 return true;
1222         }
1223         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1224         {
1225                 localcmd("restart\n");
1226                 alreadychangedlevel = true;
1227                 return true;
1228         }
1229         if(autocvar_nextmap != "")
1230         {
1231                 string m;
1232                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1233                 cvar_set("nextmap",m);
1234
1235                 if(!m || gametypevote)
1236                         return false;
1237                 if(autocvar_sv_vote_gametype)
1238                 {
1239                         Map_Goto_SetStr(m);
1240                         return false;
1241                 }
1242
1243                 if(MapInfo_CheckMap(m))
1244                 {
1245                         Map_Goto_SetStr(m);
1246                         Map_Goto(reinit);
1247                         alreadychangedlevel = true;
1248                         return true;
1249                 }
1250         }
1251         if(!reinit && autocvar_lastlevel)
1252         {
1253                 cvar_settemp_restore();
1254                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1255                 alreadychangedlevel = true;
1256                 return true;
1257         }
1258         return false;
1259 }
1260
1261 void GotoNextMap(float reinit)
1262 {
1263         //string nextmap;
1264         //float n, nummaps;
1265         //string s;
1266         if (alreadychangedlevel)
1267                 return;
1268         alreadychangedlevel = true;
1269
1270         string nextMap;
1271
1272         nextMap = GetNextMap();
1273         if(nextMap == "")
1274                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1275         Map_Goto(reinit);
1276 }
1277
1278
1279 /*
1280 ============
1281 IntermissionThink
1282
1283 When the player presses attack or jump, change to the next level
1284 ============
1285 */
1286 .float autoscreenshot;
1287 void IntermissionThink()
1288 {SELFPARAM();
1289         FixIntermissionClient(self);
1290
1291         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1292         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1293
1294         if( (server_screenshot || client_screenshot)
1295                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1296         {
1297                 self.autoscreenshot = -1;
1298                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1299                 return;
1300         }
1301
1302         if (time < intermission_exittime)
1303                 return;
1304
1305         if(!mapvote_initialized)
1306                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1307                         return;
1308
1309         MapVote_Start();
1310 }
1311
1312 /*
1313 ============
1314 FindIntermission
1315
1316 Returns the entity to view from
1317 ============
1318 */
1319 /*
1320 entity FindIntermission()
1321 {
1322         local   entity spot;
1323         local   float cyc;
1324
1325 // look for info_intermission first
1326         spot = find (world, classname, "info_intermission");
1327         if (spot)
1328         {       // pick a random one
1329                 cyc = random() * 4;
1330                 while (cyc > 1)
1331                 {
1332                         spot = find (spot, classname, "info_intermission");
1333                         if (!spot)
1334                                 spot = find (spot, classname, "info_intermission");
1335                         cyc = cyc - 1;
1336                 }
1337                 return spot;
1338         }
1339
1340 // then look for the start position
1341         spot = find (world, classname, "info_player_start");
1342         if (spot)
1343                 return spot;
1344
1345 // testinfo_player_start is only found in regioned levels
1346         spot = find (world, classname, "testplayerstart");
1347         if (spot)
1348                 return spot;
1349
1350 // then look for the start position
1351         spot = find (world, classname, "info_player_deathmatch");
1352         if (spot)
1353                 return spot;
1354
1355         //objerror ("FindIntermission: no spot");
1356         return world;
1357 }
1358 */
1359
1360 /*
1361 ===============================================================================
1362
1363 RULES
1364
1365 ===============================================================================
1366 */
1367
1368 void DumpStats(float final)
1369 {
1370         float file;
1371         string s;
1372         float to_console;
1373         float to_eventlog;
1374         float to_file;
1375         float i;
1376
1377         to_console = autocvar_sv_logscores_console;
1378         to_eventlog = autocvar_sv_eventlog;
1379         to_file = autocvar_sv_logscores_file;
1380
1381         if(!final)
1382         {
1383                 to_console = true; // always print printstats replies
1384                 to_eventlog = false; // but never print them to the event log
1385         }
1386
1387         if(to_eventlog)
1388                 if(autocvar_sv_eventlog_console)
1389                         to_console = false; // otherwise we get the output twice
1390
1391         if(final)
1392                 s = ":scores:";
1393         else
1394                 s = ":status:";
1395         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1396
1397         if(to_console)
1398                 LOG_INFO(s, "\n");
1399         if(to_eventlog)
1400                 GameLogEcho(s);
1401
1402         file = -1;
1403         if(to_file)
1404         {
1405                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1406                 if(file == -1)
1407                         to_file = false;
1408                 else
1409                         fputs(file, strcat(s, "\n"));
1410         }
1411
1412         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1413         if(to_console)
1414                 LOG_INFO(s, "\n");
1415         if(to_eventlog)
1416                 GameLogEcho(s);
1417         if(to_file)
1418                 fputs(file, strcat(s, "\n"));
1419
1420         FOR_EACH_CLIENT(other)
1421         {
1422                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1423                 {
1424                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1425                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1426                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1427                                 s = strcat(s, ftos(other.team), ":");
1428                         else
1429                                 s = strcat(s, "spectator:");
1430
1431                         if(to_console)
1432                                 LOG_INFO(s, other.netname, "\n");
1433                         if(to_eventlog)
1434                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1435                         if(to_file)
1436                                 fputs(file, strcat(s, other.netname, "\n"));
1437                 }
1438         }
1439
1440         if(teamplay)
1441         {
1442                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1443                 if(to_console)
1444                         LOG_INFO(s, "\n");
1445                 if(to_eventlog)
1446                         GameLogEcho(s);
1447                 if(to_file)
1448                         fputs(file, strcat(s, "\n"));
1449
1450                 for(i = 1; i < 16; ++i)
1451                 {
1452                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1453                         s = strcat(s, ":", ftos(i));
1454                         if(to_console)
1455                                 LOG_INFO(s, "\n");
1456                         if(to_eventlog)
1457                                 GameLogEcho(s);
1458                         if(to_file)
1459                                 fputs(file, strcat(s, "\n"));
1460                 }
1461         }
1462
1463         if(to_console)
1464                 LOG_INFO(":end\n");
1465         if(to_eventlog)
1466                 GameLogEcho(":end");
1467         if(to_file)
1468         {
1469                 fputs(file, ":end\n");
1470                 fclose(file);
1471         }
1472 }
1473
1474 void FixIntermissionClient(entity e)
1475 {
1476         string s;
1477         if(!e.autoscreenshot) // initial call
1478         {
1479                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1480                 e.health = -2342;
1481                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1482                 e.solid = SOLID_NOT;
1483                 e.movetype = MOVETYPE_NONE;
1484                 e.takedamage = DAMAGE_NO;
1485                 if(e.weaponentity)
1486                 {
1487                         e.weaponentity.effects = EF_NODRAW;
1488                         if (e.weaponentity.weaponentity)
1489                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1490                 }
1491                 if(IS_REAL_CLIENT(e))
1492                 {
1493                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1494                         s = autocvar_sv_intermission_cdtrack;
1495                         if(s != "")
1496                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1497                         msg_entity = e;
1498                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1499                 }
1500         }
1501 }
1502
1503 /*
1504 go to the next level for deathmatch
1505 only called if a time or frag limit has expired
1506 */
1507 void NextLevel()
1508 {
1509         gameover = true;
1510
1511         intermission_running = 1;
1512
1513 // enforce a wait time before allowing changelevel
1514         if(player_count > 0)
1515                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1516         else
1517                 intermission_exittime = -1;
1518
1519         /*
1520         WriteByte (MSG_ALL, SVC_CDTRACK);
1521         WriteByte (MSG_ALL, 3);
1522         WriteByte (MSG_ALL, 3);
1523         // done in FixIntermission
1524         */
1525
1526         //pos = FindIntermission ();
1527
1528         VoteReset();
1529
1530         DumpStats(true);
1531
1532         // send statistics
1533         PlayerStats_GameReport(true);
1534         WeaponStats_Shutdown();
1535
1536         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1537
1538         if(autocvar_sv_eventlog)
1539                 GameLogEcho(":gameover");
1540
1541         GameLogClose();
1542
1543         FOR_EACH_PLAYER(other) {
1544                 FixIntermissionClient(other);
1545                 if(other.winning)
1546                         bprint(other.netname, " ^7wins.\n");
1547         }
1548
1549         if(autocvar_g_campaign)
1550                 CampaignPreIntermission();
1551
1552         MUTATOR_CALLHOOK(MatchEnd);
1553
1554         localcmd("\nsv_hook_gameend\n");
1555 }
1556
1557 /*
1558 ============
1559 CheckRules_Player
1560
1561 Exit deathmatch games upon conditions
1562 ============
1563 */
1564 void CheckRules_Player()
1565 {SELFPARAM();
1566         if (gameover)   // someone else quit the game already
1567                 return;
1568
1569         if(self.deadflag == DEAD_NO)
1570                 self.play_time += frametime;
1571
1572         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1573         //   (div0: and that in CheckRules_World please)
1574 }
1575
1576
1577 float InitiateSuddenDeath()
1578 {
1579         // Check first whether normal overtimes could be added before initiating suddendeath mode
1580         // - for this timelimit_overtime needs to be >0 of course
1581         // - also check the winning condition calculated in the previous frame and only add normal overtime
1582         //   again, if at the point at which timelimit would be extended again, still no winner was found
1583         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1584         {
1585                 return 1; // need to call InitiateOvertime later
1586         }
1587         else
1588         {
1589                 if(!checkrules_suddendeathend)
1590                 {
1591                         if(autocvar_g_campaign)
1592                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1593                         else
1594                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1595                         if(g_race && !g_race_qualifying)
1596                                 race_StartCompleting();
1597                 }
1598                 return 0;
1599         }
1600 }
1601
1602 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1603 {
1604         ++checkrules_overtimesadded;
1605         //add one more overtime by simply extending the timelimit
1606         float tl;
1607         tl = autocvar_timelimit;
1608         tl += autocvar_timelimit_overtime;
1609         cvar_set("timelimit", ftos(tl));
1610
1611         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1612 }
1613
1614 float GetWinningCode(float fraglimitreached, float equality)
1615 {
1616         if(autocvar_g_campaign == 1)
1617                 if(fraglimitreached)
1618                         return WINNING_YES;
1619                 else
1620                         return WINNING_NO;
1621
1622         else
1623                 if(equality)
1624                         if(fraglimitreached)
1625                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1626                         else
1627                                 return WINNING_NEVER;
1628                 else
1629                         if(fraglimitreached)
1630                                 return WINNING_YES;
1631                         else
1632                                 return WINNING_NO;
1633 }
1634
1635 // set the .winning flag for exactly those players with a given field value
1636 void SetWinners(.float field, float value)
1637 {
1638         entity head;
1639         FOR_EACH_PLAYER(head)
1640                 head.winning = (head.(field) == value);
1641 }
1642
1643 // set the .winning flag for those players with a given field value
1644 void AddWinners(.float field, float value)
1645 {
1646         entity head;
1647         FOR_EACH_PLAYER(head)
1648                 if (head.(field) == value)
1649                         head.winning = 1;
1650 }
1651
1652 // clear the .winning flags
1653 void ClearWinners(void)
1654 {
1655         entity head;
1656         FOR_EACH_PLAYER(head)
1657                 head.winning = 0;
1658 }
1659
1660 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1661 // they win. Otherwise the defending team wins once the timelimit passes.
1662 void assault_new_round();
1663 float WinningCondition_Assault()
1664 {SELFPARAM();
1665         float status;
1666
1667         WinningConditionHelper(); // set worldstatus
1668
1669         status = WINNING_NO;
1670         // as the timelimit has not yet passed just assume the defending team will win
1671         if(assault_attacker_team == NUM_TEAM_1)
1672         {
1673                 SetWinners(team, NUM_TEAM_2);
1674         }
1675         else
1676         {
1677                 SetWinners(team, NUM_TEAM_1);
1678         }
1679
1680         entity ent;
1681         ent = find(world, classname, "target_assault_roundend");
1682         if(ent)
1683         {
1684                 if(ent.winning) // round end has been triggered by attacking team
1685                 {
1686                         bprint("ASSAULT: round completed...\n");
1687                         SetWinners(team, assault_attacker_team);
1688
1689                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1690
1691                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1692                         {
1693                                 status = WINNING_YES;
1694                         }
1695                         else
1696                         {
1697                                 WITH(entity, self, ent, assault_new_round());
1698                         }
1699                 }
1700         }
1701
1702         return status;
1703 }
1704
1705 // LMS winning condition: game terminates if and only if there's at most one
1706 // one player who's living lives. Top two scores being equal cancels the time
1707 // limit.
1708 float WinningCondition_LMS()
1709 {
1710         entity head, head2;
1711         float have_player;
1712         float have_players;
1713         float l;
1714
1715         have_player = false;
1716         have_players = false;
1717         l = LMS_NewPlayerLives();
1718
1719         head = find(world, classname, "player");
1720         if(head)
1721                 have_player = true;
1722         head2 = find(head, classname, "player");
1723         if(head2)
1724                 have_players = true;
1725
1726         if(have_player)
1727         {
1728                 // we have at least one player
1729                 if(have_players)
1730                 {
1731                         // two or more active players - continue with the game
1732                 }
1733                 else
1734                 {
1735                         // exactly one player?
1736
1737                         ClearWinners();
1738                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1739
1740                         if(l)
1741                         {
1742                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1743                                 return WINNING_NO;
1744                         }
1745                         else
1746                         {
1747                                 // a winner!
1748                                 // and assign him his first place
1749                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1750                                 return WINNING_YES;
1751                         }
1752                 }
1753         }
1754         else
1755         {
1756                 // nobody is playing at all...
1757                 if(l)
1758                 {
1759                         // wait for players...
1760                 }
1761                 else
1762                 {
1763                         // SNAFU (maybe a draw game?)
1764                         ClearWinners();
1765                         LOG_TRACE("No players, ending game.\n");
1766                         return WINNING_YES;
1767                 }
1768         }
1769
1770         // When we get here, we have at least two players who are actually LIVING,
1771         // now check if the top two players have equal score.
1772         WinningConditionHelper();
1773
1774         ClearWinners();
1775         if(WinningConditionHelper_winner)
1776                 WinningConditionHelper_winner.winning = true;
1777         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1778                 return WINNING_NEVER;
1779
1780         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1781         return WINNING_NO;
1782 }
1783
1784 void ShuffleMaplist()
1785 {
1786         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1787 }
1788
1789 float leaderfrags;
1790 float WinningCondition_Scores(float limit, float leadlimit)
1791 {
1792         float limitreached;
1793
1794         // TODO make everything use THIS winning condition (except LMS)
1795         WinningConditionHelper();
1796
1797         if(teamplay)
1798         {
1799                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1800                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1801                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1802                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1803         }
1804
1805         ClearWinners();
1806         if(WinningConditionHelper_winner)
1807                 WinningConditionHelper_winner.winning = 1;
1808         if(WinningConditionHelper_winnerteam >= 0)
1809                 SetWinners(team, WinningConditionHelper_winnerteam);
1810
1811         if(WinningConditionHelper_lowerisbetter)
1812         {
1813                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1814                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1815                 limit = -limit;
1816         }
1817
1818         if(WinningConditionHelper_zeroisworst)
1819                 leadlimit = 0; // not supported in this mode
1820
1821         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1822         // these modes always score in increments of 1, thus this makes sense
1823         {
1824                 if(leaderfrags != WinningConditionHelper_topscore)
1825                 {
1826                         leaderfrags = WinningConditionHelper_topscore;
1827
1828                         if (limit)
1829                         if (leaderfrags == limit - 1)
1830                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1831                         else if (leaderfrags == limit - 2)
1832                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1833                         else if (leaderfrags == limit - 3)
1834                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1835                 }
1836         }
1837
1838         limitreached = false;
1839         if(limit)
1840                 if(WinningConditionHelper_topscore >= limit)
1841                         limitreached = true;
1842         if(leadlimit)
1843         {
1844                 float leadlimitreached;
1845                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1846                 if(autocvar_leadlimit_and_fraglimit)
1847                         limitreached = (limitreached && leadlimitreached);
1848                 else
1849                         limitreached = (limitreached || leadlimitreached);
1850         }
1851
1852         if(limit)
1853                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1854
1855         return GetWinningCode(
1856                 WinningConditionHelper_topscore && limitreached,
1857                 WinningConditionHelper_equality
1858         );
1859 }
1860
1861 float WinningCondition_Race(float fraglimit)
1862 {
1863         float wc;
1864         entity p;
1865         float n, c;
1866
1867         n = 0;
1868         c = 0;
1869         FOR_EACH_PLAYER(p)
1870         {
1871                 ++n;
1872                 if(p.race_completed)
1873                         ++c;
1874         }
1875         if(n && (n == c))
1876                 return WINNING_YES;
1877         wc = WinningCondition_Scores(fraglimit, 0);
1878
1879         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1880         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1881         // do NOT support equality when the laps are all raced!
1882                 return WINNING_STARTSUDDENDEATHOVERTIME;
1883         else
1884                 return WINNING_NEVER;
1885 }
1886
1887 float WinningCondition_QualifyingThenRace(float limit)
1888 {
1889         float wc;
1890         wc = WinningCondition_Scores(limit, 0);
1891
1892         // NEVER initiate overtime
1893         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1894         {
1895                 return WINNING_YES;
1896         }
1897
1898         return wc;
1899 }
1900
1901 float WinningCondition_RanOutOfSpawns()
1902 {
1903         entity head;
1904
1905         if(have_team_spawns <= 0)
1906                 return WINNING_NO;
1907
1908         if(!autocvar_g_spawn_useallspawns)
1909                 return WINNING_NO;
1910
1911         if(!some_spawn_has_been_used)
1912                 return WINNING_NO;
1913
1914         team1_score = team2_score = team3_score = team4_score = 0;
1915
1916         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1917         {
1918                 if(head.team == NUM_TEAM_1)
1919                         team1_score = 1;
1920                 else if(head.team == NUM_TEAM_2)
1921                         team2_score = 1;
1922                 else if(head.team == NUM_TEAM_3)
1923                         team3_score = 1;
1924                 else if(head.team == NUM_TEAM_4)
1925                         team4_score = 1;
1926         }
1927
1928         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1929         {
1930                 if(head.team == NUM_TEAM_1)
1931                         team1_score = 1;
1932                 else if(head.team == NUM_TEAM_2)
1933                         team2_score = 1;
1934                 else if(head.team == NUM_TEAM_3)
1935                         team3_score = 1;
1936                 else if(head.team == NUM_TEAM_4)
1937                         team4_score = 1;
1938         }
1939
1940         ClearWinners();
1941         if(team1_score + team2_score + team3_score + team4_score == 0)
1942         {
1943                 checkrules_equality = true;
1944                 return WINNING_YES;
1945         }
1946         else if(team1_score + team2_score + team3_score + team4_score == 1)
1947         {
1948                 float t, i;
1949                 if(team1_score)
1950                         t = NUM_TEAM_1;
1951                 else if(team2_score)
1952                         t = NUM_TEAM_2;
1953                 else if(team3_score)
1954                         t = NUM_TEAM_3;
1955                 else // if(team4_score)
1956                         t = NUM_TEAM_4;
1957                 CheckAllowedTeams(world);
1958                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1959                 {
1960                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1961                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1962                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1963                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1964                 }
1965
1966                 AddWinners(team, t);
1967                 return WINNING_YES;
1968         }
1969         else
1970                 return WINNING_NO;
1971 }
1972
1973 /*
1974 ============
1975 CheckRules_World
1976
1977 Exit deathmatch games upon conditions
1978 ============
1979 */
1980 void CheckRules_World()
1981 {
1982         float timelimit;
1983         float fraglimit;
1984         float leadlimit;
1985
1986         VoteThink();
1987         MapVote_Think();
1988
1989         SetDefaultAlpha();
1990
1991         if (gameover)   // someone else quit the game already
1992         {
1993                 if(player_count == 0) // Nobody there? Then let's go to the next map
1994                         MapVote_Start();
1995                         // this will actually check the player count in the next frame
1996                         // again, but this shouldn't hurt
1997                 return;
1998         }
1999
2000         timelimit = autocvar_timelimit * 60;
2001         fraglimit = autocvar_fraglimit;
2002         leadlimit = autocvar_leadlimit;
2003
2004         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2005         {
2006                 if(timelimit > 0)
2007                         timelimit = 0; // timelimit is not made for warmup
2008                 if(fraglimit > 0)
2009                         fraglimit = 0; // no fraglimit for now
2010                 leadlimit = 0; // no leadlimit for now
2011         }
2012
2013         if(timelimit > 0)
2014         {
2015                 timelimit += game_starttime;
2016         }
2017         else if (timelimit < 0)
2018         {
2019                 // endmatch
2020                 NextLevel();
2021                 return;
2022         }
2023
2024         float wantovertime;
2025         wantovertime = 0;
2026
2027         if(timelimit > game_starttime)
2028                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2029         else
2030                 game_completion_ratio = 0;
2031
2032         if(checkrules_suddendeathend)
2033         {
2034                 if(!checkrules_suddendeathwarning)
2035                 {
2036                         checkrules_suddendeathwarning = true;
2037                         if(g_race && !g_race_qualifying)
2038                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2039                         else
2040                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2041                 }
2042         }
2043         else
2044         {
2045                 if (timelimit && time >= timelimit)
2046                 {
2047                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2048                         {
2049                                 float totalplayers;
2050                                 float playerswithlaps;
2051                                 float readyplayers;
2052                                 entity head;
2053                                 totalplayers = playerswithlaps = readyplayers = 0;
2054                                 FOR_EACH_PLAYER(head)
2055                                 {
2056                                         ++totalplayers;
2057                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2058                                                 ++playerswithlaps;
2059                                         if(head.ready)
2060                                                 ++readyplayers;
2061                                 }
2062
2063                                 // at least 2 of the players have completed a lap: start the RACE
2064                                 // otherwise, the players should end the qualifying on their own
2065                                 if(readyplayers || playerswithlaps >= 2)
2066                                 {
2067                                         checkrules_suddendeathend = 0;
2068                                         ReadyRestart(); // go to race
2069                                         return;
2070                                 }
2071                                 else
2072                                         wantovertime |= InitiateSuddenDeath();
2073                         }
2074                         else
2075                                 wantovertime |= InitiateSuddenDeath();
2076                 }
2077         }
2078
2079         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2080         {
2081                 NextLevel();
2082                 return;
2083         }
2084
2085         float checkrules_status;
2086         checkrules_status = WinningCondition_RanOutOfSpawns();
2087         if(checkrules_status == WINNING_YES)
2088         {
2089                 bprint("Hey! Someone ran out of spawns!\n");
2090         }
2091         else if(g_race && !g_race_qualifying && timelimit >= 0)
2092         {
2093                 checkrules_status = WinningCondition_Race(fraglimit);
2094                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2095         }
2096         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2097         {
2098                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2099                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2100         }
2101         else if(g_assault)
2102         {
2103                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2104         }
2105         else if(g_lms)
2106         {
2107                 checkrules_status = WinningCondition_LMS();
2108         }
2109         else
2110         {
2111                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2112                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2113         }
2114
2115         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2116         {
2117                 checkrules_status = WINNING_NEVER;
2118                 checkrules_overtimesadded = -1;
2119                 wantovertime |= InitiateSuddenDeath();
2120         }
2121
2122         if(checkrules_status == WINNING_NEVER)
2123                 // equality cases! Nobody wins if the overtime ends in a draw.
2124                 ClearWinners();
2125
2126         if(wantovertime)
2127         {
2128                 if(checkrules_status == WINNING_NEVER)
2129                         InitiateOvertime();
2130                 else
2131                         checkrules_status = WINNING_YES;
2132         }
2133
2134         if(checkrules_suddendeathend)
2135                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2136                         checkrules_status = WINNING_YES;
2137
2138         if(checkrules_status == WINNING_YES)
2139         {
2140                 //print("WINNING\n");
2141                 NextLevel();
2142         }
2143 }
2144
2145 string GotoMap(string m)
2146 {
2147         m = GameTypeVote_MapInfo_FixName(m);
2148         if (!m)
2149                 return "The map you suggested is not available on this server.";
2150         if (!autocvar_sv_vote_gametype)
2151         if(!MapInfo_CheckMap(m))
2152                 return "The map you suggested does not support the current game mode.";
2153         cvar_set("nextmap", m);
2154         cvar_set("timelimit", "-1");
2155         if(mapvote_initialized || alreadychangedlevel)
2156         {
2157                 if(DoNextMapOverride(0))
2158                         return "Map switch initiated.";
2159                 else
2160                         return "Hm... no. For some reason I like THIS map more.";
2161         }
2162         else
2163                 return "Map switch will happen after scoreboard.";
2164 }
2165
2166
2167 void EndFrame()
2168 {SELFPARAM();
2169         anticheat_endframe();
2170
2171         float altime;
2172         entity e_;
2173         FOR_EACH_REALCLIENT(e_)
2174         {
2175                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2176                 if(e.typehitsound)
2177                         e_.typehit_time = time;
2178                 else if(e.damage_dealt)
2179                 {
2180                         e_.hit_time = time;
2181                         e_.damage_dealt_total += ceil(e.damage_dealt);
2182                 }
2183         }
2184         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2185         // add 1 frametime because after this, engine SV_Physics
2186         // increases time by a frametime and then networks the frame
2187         // add another frametime because client shows everything with
2188         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2189         // needed!
2190         FOR_EACH_CLIENT(e_)
2191         {
2192                 e_.typehitsound = false;
2193                 e_.damage_dealt = 0;
2194                 setself(e_);
2195                 antilag_record(e_, altime);
2196         }
2197         FOR_EACH_MONSTER(e_)
2198         {
2199                 setself(e_);
2200                 antilag_record(e_, altime);
2201         }
2202 }
2203
2204
2205 /*
2206  * RedirectionThink:
2207  * returns true if redirecting
2208  */
2209 float redirection_timeout;
2210 float redirection_nextthink;
2211 float RedirectionThink()
2212 {SELFPARAM();
2213         float clients_found;
2214
2215         if(redirection_target == "")
2216                 return false;
2217
2218         if(!redirection_timeout)
2219         {
2220                 cvar_set("sv_public", "-2");
2221                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2222                 if(redirection_target == "self")
2223                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2224                 else
2225                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2226         }
2227
2228         if(time < redirection_nextthink)
2229                 return true;
2230
2231         redirection_nextthink = time + 1;
2232
2233         clients_found = 0;
2234         entity e;
2235         FOR_EACH_REALCLIENT(e)
2236         {
2237                 setself(e);
2238                 // TODO add timer
2239                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2240                 if(redirection_target == "self")
2241                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2242                 else
2243                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2244                 ++clients_found;
2245         }
2246
2247         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2248
2249         if(time > redirection_timeout || clients_found == 0)
2250                 localcmd("\nwait; wait; wait; quit\n");
2251
2252         return true;
2253 }
2254
2255 void TargetMusic_RestoreGame();
2256 void RestoreGame()
2257 {
2258         // Loaded from a save game
2259         // some things then break, so let's work around them...
2260
2261         // Progs DB (capture records)
2262         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2263
2264         // Mapinfo
2265         MapInfo_Shutdown();
2266         MapInfo_Enumerate();
2267         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2268         WeaponStats_Init();
2269
2270         TargetMusic_RestoreGame();
2271 }
2272
2273 void Shutdown()
2274 {
2275         gameover = 2;
2276
2277         if(world_initialized > 0)
2278         {
2279                 world_initialized = 0;
2280                 LOG_INFO("Saving persistent data...\n");
2281                 Ban_SaveBans();
2282
2283                 // playerstats with unfinished match
2284                 PlayerStats_GameReport(false);
2285
2286                 if(!cheatcount_total)
2287                 {
2288                         if(autocvar_sv_db_saveasdump)
2289                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2290                         else
2291                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2292                 }
2293                 if(autocvar_developer)
2294                 {
2295                         if(autocvar_sv_db_saveasdump)
2296                                 db_dump(TemporaryDB, "server-temp.db");
2297                         else
2298                                 db_save(TemporaryDB, "server-temp.db");
2299                 }
2300                 CheatShutdown(); // must be after cheatcount check
2301                 db_close(ServerProgsDB);
2302                 db_close(TemporaryDB);
2303                 LOG_INFO("done!\n");
2304                 // tell the bot system the game is ending now
2305                 bot_endgame();
2306
2307                 WeaponStats_Shutdown();
2308                 MapInfo_Shutdown();
2309         }
2310         else if(world_initialized == 0)
2311         {
2312                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2313         }
2314 }