qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312
 313                 // these can contain player IDs, so better hide
 314                 BADPREFIX("g_forced_team_");
 315
 316                 // mapinfo
 317                 BADCVAR("fraglimit");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_assault");
 320                 BADCVAR("g_ca");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_cts");
 323                 BADCVAR("g_dm");
 324                 BADCVAR("g_domination");
 325                 BADCVAR("g_domination_default_teams");
 326                 BADCVAR("g_freezetag");
 327                 BADCVAR("g_keepaway");
 328                 BADCVAR("g_keyhunt");
 329                 BADCVAR("g_keyhunt_teams");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_lms");
 332                 BADCVAR("g_nexball");
 333                 BADCVAR("g_onslaught");
 334                 BADCVAR("g_race");
 335                 BADCVAR("g_race_qualifying_timelimit");
 336                 BADCVAR("g_runematch");
 337                 BADCVAR("g_tdm");
 338                 BADCVAR("g_tdm_teams");
 339                 BADCVAR("leadlimit");
 340                 BADCVAR("nextmap");
 341                 BADCVAR("teamplay");
 342                 BADCVAR("timelimit");
 343
 344                 // long
 345                 BADCVAR("hostname");
 346                 BADCVAR("g_maplist");
 347                 BADCVAR("g_maplist_mostrecent");
 348                 BADCVAR("sv_motd");
 349
 350                 v = cvar_string(k);
 351                 d = cvar_defstring(k);
 352                 if(v == d)
 353                         continue;
 354
 355                 if(adding)
 356                 {
 357                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 358                         if(strlen(cvar_changes) > 16384)
 359                         {
 360                                 cvar_changes = "// too many settings have been changed to show them here\n";
 361                                 adding = 0;
 362                         }
 363                 }
 364
 365                 // now check if the changes are actually gameplay relevant
 366
 367                 // does nothing visible
 368                 BADCVAR("captureleadlimit_override");
 369                 BADCVAR("g_arena_point_leadlimit");
 370                 BADCVAR("g_balance_kill_delay");
 371                 BADCVAR("g_ca_point_leadlimit");
 372                 BADCVAR("g_ctf_captimerecord_always");
 373                 BADCVAR("g_ctf_capture_leadlimit");
 374                 BADCVAR("g_ctf_flag_capture_effects");
 375                 BADCVAR("g_ctf_flag_glowtrails");
 376                 BADCVAR("g_ctf_flag_pickup_effects");
 377                 BADCVAR("g_domination_point_leadlimit");
 378                 BADCVAR("g_forced_respawn");
 379                 BADCVAR("g_keyhunt_point_leadlimit");
 380                 BADCVAR("g_nexball_goalleadlimit");
 381                 BADCVAR("g_runematch_point_leadlimit");
 382                 BADCVAR("leadlimit_and_fraglimit");
 383                 BADCVAR("leadlimit_override");
 384                 BADCVAR("pausable");
 385                 BADCVAR("sv_allow_fullbright");
 386                 BADCVAR("sv_checkforpacketsduringsleep");
 387                 BADCVAR("sv_timeout");
 388                 BADCVAR("welcome_message_time");
 389                 BADPREFIX("crypto_");
 390                 BADPREFIX("g_chat_");
 391                 BADPREFIX("g_ctf_captimerecord_");
 392                 BADPREFIX("g_maplist_votable_");
 393                 BADPREFIX("net_");
 394                 BADPREFIX("prvm_");
 395                 BADPREFIX("skill_");
 396                 BADPREFIX("sv_cullentities_");
 397                 BADPREFIX("sv_fraginfo_");
 398                 BADPREFIX("sv_maxidle_");
 399                 BADPREFIX("sv_vote_");
 400                 BADPREFIX("timelimit_");
 401                 BADCVAR("gameversion");
 402                 BADPREFIX("gameversion_");
 403
 404                 // allowed changes to server admins (please sync this to server.cfg)
 405                 // vi commands:
 406                 //   :/"impure"/,$d
 407                 //   :g!,^\/\/[^ /],d
 408                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 409                 //   :%!sort
 410                 // yes, this does contain some redundant stuff, don't really care
 411                 BADCVAR("bot_number");
 412                 BADCVAR("bot_prefix");
 413                 BADCVAR("bot_suffix");
 414                 BADCVAR("bot_config_file");
 415                 BADCVAR("capturelimit_override");
 416                 BADCVAR("fraglimit_override");
 417                 BADCVAR("gametype");
 418                 BADCVAR("g_antilag");
 419                 BADCVAR("g_balance_teams");
 420                 BADCVAR("g_balance_teams_force");
 421                 BADCVAR("g_ban_sync_trusted_servers");
 422                 BADCVAR("g_ban_sync_uri");
 423                 BADCVAR("g_ctf_capture_limit");
 424                 BADCVAR("g_ctf_ignore_frags");
 425                 BADCVAR("g_ctf_win_mode");
 426                 BADCVAR("g_domination_point_limit");
 427                 BADCVAR("g_friendlyfire");
 428                 BADCVAR("g_fullbrightitems");
 429                 BADCVAR("g_fullbrightplayers");
 430                 BADCVAR("g_keyhunt_point_limit");
 431                 BADCVAR("g_keyhunt_teams_override");
 432                 BADCVAR("g_lms_lives_override");
 433                 BADCVAR("g_maplist");
 434                 BADCVAR("g_maplist_check_waypoints");
 435                 BADCVAR("g_maplist_mostrecent_count");
 436                 BADCVAR("g_maplist_shuffle");
 437                 BADCVAR("g_maplist_votable");
 438                 BADCVAR("g_maplist_votable_abstain");
 439                 BADCVAR("g_maplist_votable_nodetail");
 440                 BADCVAR("g_maplist_votable_suggestions");
 441                 BADCVAR("g_maxplayers");
 442                 BADCVAR("g_minstagib");
 443                 BADCVAR("g_mirrordamage");
 444                 BADCVAR("g_nexball_goallimit");
 445                 BADCVAR("g_runematch_point_limit");
 446                 BADCVAR("g_start_delay");
 447                 BADCVAR("g_warmup");
 448                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 449                 BADCVAR("hostname");
 450                 BADCVAR("log_file");
 451                 BADCVAR("maxplayers");
 452                 BADCVAR("minplayers");
 453                 BADCVAR("net_address");
 454                 BADCVAR("port");
 455                 BADCVAR("rcon_password");
 456                 BADCVAR("rcon_restricted_commands");
 457                 BADCVAR("rcon_restricted_password");
 458                 BADCVAR("skill");
 459                 BADCVAR("sv_adminnick");
 460                 BADCVAR("sv_autoscreenshot");
 461                 BADCVAR("sv_curl_defaulturl");
 462                 BADCVAR("sv_defaultcharacter");
 463                 BADCVAR("sv_defaultplayercolors");
 464                 BADCVAR("sv_defaultplayermodel");
 465                 BADCVAR("sv_defaultplayerskin");
 466                 BADCVAR("sv_maxidle");
 467                 BADCVAR("sv_maxrate");
 468                 BADCVAR("sv_motd");
 469                 BADCVAR("sv_public");
 470                 BADCVAR("sv_ready_restart");
 471                 BADCVAR("sv_status_privacy");
 472                 BADCVAR("sv_vote_call");
 473                 BADCVAR("sv_vote_commands");
 474                 BADCVAR("sv_vote_majority_factor");
 475                 BADCVAR("sv_vote_master");
 476                 BADCVAR("sv_vote_master_commands");
 477                 BADCVAR("sv_vote_master_password");
 478                 BADCVAR("sv_vote_simple_majority_factor");
 479                 BADCVAR("sys_ticrate");
 480                 BADCVAR("teamplay_mode");
 481                 BADCVAR("timelimit_override");
 482                 BADPREFIX("g_warmup_");
 483
 484                 if(autocvar_g_minstagib)
 485                 {
 486                         BADCVAR("g_grappling_hook");
 487                         BADCVAR("g_jetpack");
 488                 }
 489 #undef BADPREFIX
 490 #undef BADCVAR
 491
 492                 if(pureadding)
 493                 {
 494                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 495                         if(strlen(cvar_purechanges) > 16384)
 496                         {
 497                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 498                                 pureadding = 0;
 499                         }
 500                 }
 501                 ++cvar_purechanges_count;
 502                 // WARNING: this variable is used for the server list
 503                 // NEVER dare to skip this code!
 504                 // Hacks to intentionally appearing as "pure server" even though you DO have
 505                 // modified settings may be punished by removal from the server list.
 506                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 507                 // though.
 508         }
 509         buf_del(h);
 510         if(cvar_changes == "")
 511                 cvar_changes = "// this server runs at default server settings\n";
 512         else
 513                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 514         cvar_changes = strzone(cvar_changes);
 515         if(cvar_purechanges == "")
 516                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 517         else
 518                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 519         cvar_purechanges = strzone(cvar_purechanges);
 520 }
 521
 522 void detect_maptype()
 523 {
 524 #if 0
 525         vector o, v;
 526         float i;
 527
 528         for(;;)
 529         {
 530                 o = world.mins;
 531                 o_x += random() * (world.maxs_x - world.mins_x);
 532                 o_y += random() * (world.maxs_y - world.mins_y);
 533                 o_z += random() * (world.maxs_z - world.mins_z);
 534
 535                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 536                 if(trace_fraction == 1)
 537                         continue;
 538
 539                 v = trace_endpos;
 540
 541                 for(i = 0; i < 64; i += 4)
 542                 {
 543                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 544         if(trace_fraction == 1)
 545                 continue;
 546                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 547                 }
 548
 549                 break;
 550         }
 551 #endif
 552 }
 553
 554 entity randomseed;
 555 float RandomSeed_Send(entity to, float sf)
 556 {
 557         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 558         WriteShort(MSG_ENTITY, self.cnt);
 559         return TRUE;
 560 }
 561 void RandomSeed_Think()
 562 {
 563         self.cnt = bound(0, floor(random() * 65536), 65535);
 564         self.nextthink = time + 5;
 565
 566         self.SendFlags |= 1;
 567 }
 568 void RandomSeed_Spawn()
 569 {
 570         randomseed = spawn();
 571         randomseed.think = RandomSeed_Think;
 572         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 573
 574         entity oldself;
 575         oldself = self;
 576         self = randomseed;
 577         self.think(); // sets random seed and nextthink
 578         self = oldself;
 579 }
 580
 581 void spawnfunc___init_dedicated_server(void)
 582 {
 583         // handler for _init/_init map (only for dedicated server initialization)
 584
 585         world_initialized = -1; // don't complain
 586         cvar = cvar_normal;
 587         cvar_string = cvar_string_normal;
 588         cvar_set = cvar_set_normal;
 589
 590         remove = remove_unsafely;
 591
 592         entity e;
 593         e = spawn();
 594         e.think = GotoFirstMap;
 595         e.nextthink = time; // this is usually 1 at this point
 596
 597         e = spawn();
 598         e.classname = "info_player_deathmatch"; // safeguard against player joining
 599
 600         self.classname = "worldspawn"; // safeguard against various stuff ;)
 601
 602         MapInfo_Enumerate();
 603         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 604 }
 605
 606 void Map_MarkAsRecent(string m);
 607 float world_already_spawned;
 608 void RegisterWeapons();
 609 void Nagger_Init();
 610 void ClientInit_Spawn();
 611 void WeaponStats_Init();
 612 void WeaponStats_Shutdown();
 613 void spawnfunc_worldspawn (void)
 614 {
 615         float fd, l, i, j, n;
 616         string s, col;
 617
 618         cvar = cvar_normal;
 619         cvar_string = cvar_string_normal;
 620         cvar_set = cvar_set_normal;
 621
 622         if(world_already_spawned)
 623                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 624         world_already_spawned = TRUE;
 625
 626         remove = remove_safely; // during spawning, watch what you remove!
 627
 628         check_unacceptable_compiler_bugs();
 629
 630         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 631
 632         compressShortVector_init();
 633
 634         allowed_to_spawn = TRUE;
 635
 636         entity head;
 637         head = nextent(world);
 638         maxclients = 0;
 639         while(head)
 640         {
 641                 ++maxclients;
 642                 head = nextent(head);
 643         }
 644
 645         // needs to be done so early as they would still spawn
 646         RegisterWeapons();
 647
 648         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 649
 650         TemporaryDB = db_create();
 651
 652         // 0 normal
 653         lightstyle(0, "m");
 654
 655         // 1 FLICKER (first variety)
 656         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 657
 658         // 2 SLOW STRONG PULSE
 659         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 660
 661         // 3 CANDLE (first variety)
 662         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 663
 664         // 4 FAST STROBE
 665         lightstyle(4, "mamamamamama");
 666
 667         // 5 GENTLE PULSE 1
 668         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 669
 670         // 6 FLICKER (second variety)
 671         lightstyle(6, "nmonqnmomnmomomno");
 672
 673         // 7 CANDLE (second variety)
 674         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 675
 676         // 8 CANDLE (third variety)
 677         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 678
 679         // 9 SLOW STROBE (fourth variety)
 680         lightstyle(9, "aaaaaaaazzzzzzzz");
 681
 682         // 10 FLUORESCENT FLICKER
 683         lightstyle(10, "mmamammmmammamamaaamammma");
 684
 685         // 11 SLOW PULSE NOT FADE TO BLACK
 686         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 687
 688         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 689
 690         // 63 testing
 691         lightstyle(63, "a");
 692
 693         if(autocvar_g_campaign)
 694                 CampaignPreInit();
 695
 696         Map_MarkAsRecent(mapname);
 697
 698         precache_model ("null"); // we need this one before InitGameplayMode
 699         InitGameplayMode();
 700         readlevelcvars();
 701         GrappleHookInit();
 702         ElectroInit();
 703         LaserInit();
 704
 705         player_count = 0;
 706         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 707         if(bot_waypoints_for_items == 1)
 708                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 709                         bot_waypoints_for_items = 0;
 710
 711         precache();
 712
 713         WaypointSprite_Init();
 714
 715         //if (g_domination)
 716         //      dom_init();
 717
 718         GameLogInit(); // prepare everything
 719         if(autocvar_sv_eventlog)
 720         {
 721                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 722                 matchid = strzone(s);
 723
 724                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 725                 s = ":gameinfo:mutators:LIST";
 726
 727                 ret_string = s;
 728                 MUTATOR_CALLHOOK(BuildMutatorsString);
 729                 s = ret_string;
 730
 731                 // simple, probably not good in the mutator system
 732                 if(autocvar_g_grappling_hook)
 733                         s = strcat(s, ":grappling_hook");
 734
 735                 // initialiation stuff, not good in the mutator system
 736                 if(!autocvar_g_use_ammunition)
 737                         s = strcat(s, ":no_use_ammunition");
 738
 739                 // initialiation stuff, not good in the mutator system
 740                 if(!autocvar_g_pickup_items)
 741                         s = strcat(s, ":no_pickup_items");
 742
 743                 // initialiation stuff, not good in the mutator system
 744                 if(autocvar_g_weaponarena != "0")
 745                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 746
 747                 // TODO to mutator system
 748                 if(autocvar_g_norecoil)
 749                         s = strcat(s, ":norecoil");
 750
 751                 // TODO to mutator system
 752                 if(autocvar_g_midair)
 753                         s = strcat(s, ":midair");
 754
 755                 // TODO to mutator system
 756                 if(autocvar_g_minstagib)
 757                         s = strcat(s, ":minstagib");
 758
 759                 GameLogEcho(s);
 760                 GameLogEcho(":gameinfo:end");
 761         }
 762         else
 763                 matchid = strzone(ftos(random()));
 764
 765         cvar_set("nextmap", "");
 766
 767         SetDefaultAlpha();
 768
 769         if(autocvar_g_campaign)
 770                 CampaignPostInit();
 771
 772         fteqcc_testbugs();
 773
 774         Ban_LoadBans();
 775
 776         MapInfo_Enumerate();
 777         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 778
 779         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 780         {
 781                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 782                 if(fd != -1)
 783                 {
 784                         while((s = fgets(fd)))
 785                         {
 786                                 l = tokenize_console(s);
 787                                 if(l < 2)
 788                                         continue;
 789                                 if(argv(0) == "cd")
 790                                 {
 791                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 792                                         print("  cdtrack ", argv(2), "\n");
 793                                 }
 794                                 else if(argv(0) == "fog")
 795                                 {
 796                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 797                                         print("  \"fog\" \"", s, "\"\n");
 798                                 }
 799                                 else if(argv(0) == "set")
 800                                 {
 801                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 802                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 803                                 }
 804                                 else if(argv(0) != "//")
 805                                 {
 806                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 807                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 808                                 }
 809                         }
 810                         fclose(fd);
 811                 }
 812         }
 813
 814         WeaponStats_Init();
 815
 816         addstat(STAT_WEAPONS, AS_INT, weapons);
 817         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 818         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 819         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 820         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 821         Nagger_Init();
 822
 823         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 824         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 825         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 826         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 827         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 828         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 829         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 830         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 831         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 832         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 833         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 834         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 835
 836         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 837         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 838
 839         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 840
 841         if(g_ca || g_freezetag)
 842         {
 843                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 844                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 845                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 846                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 847         }
 848         if(g_freezetag)
 849         {
 850                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 851                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 852         }
 853
 854         // g_movementspeed hack
 855         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 856         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 857         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 858         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 859
 860         // secrets
 861         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 862         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 863
 864         next_pingtime = time + 5;
 865
 866         detect_maptype();
 867
 868         lsmaps_reply = "^7Maps available: ";
 869         lsnewmaps_reply = "^7Maps without a record set: ";
 870         for(i = 0, j = 0; i < MapInfo_count; ++i)
 871         {
 872                 if(MapInfo_Get_ByID(i))
 873                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 874                         {
 875                                 if(mod(i, 2))
 876                                         col = "^2";
 877                                 else
 878                                         col = "^3";
 879                                 ++j;
 880                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 881                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 882                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 883                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 884                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 885                         }
 886         }
 887         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 888         if (!g_race && !g_cts)
 889                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 890         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 891
 892         maplist_reply = "^7Maps in list: ";
 893         n = tokenize_console(autocvar_g_maplist);
 894         for(i = 0, j = 0; i < n; ++i)
 895         {
 896                 if(MapInfo_CheckMap(argv(i)))
 897                 {
 898                         if(mod(j, 2))
 899                                 col = "^2";
 900                         else
 901                                 col = "^3";
 902                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 903                         ++j;
 904                 }
 905         }
 906         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 907         MapInfo_ClearTemps();
 908
 909         for(i = 0; i < 10; ++i)
 910         {
 911                 records_reply[i] = strzone(getrecords(i));
 912         }
 913         if(g_cts)
 914                 ladder_reply = strzone(getladder());
 915
 916         rankings_reply = strzone(getrankings());
 917
 918         ClientInit_Spawn();
 919         RandomSeed_Spawn();
 920         PingPLReport_Spawn();
 921
 922         CheatInit();
 923
 924         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 925
 926         // fill sv_curl_serverpackages from .serverpackage files
 927         if(autocvar_sv_curl_serverpackages_auto)
 928         {
 929                 s = "";
 930                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 931                 for(i = 0; i < n; ++i)
 932                         if(substring(argv(i), -14, -1) != ".serverpackage")
 933                                 s = strcat(s, " ", argv(i));
 934                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 935                 if(fd >= 0)
 936                 {
 937                         j = search_getsize(fd);
 938                         for(i = 0; i < j; ++i)
 939                                 s = strcat(s, " ", search_getfilename(fd, i));
 940                         search_end(fd);
 941                 }
 942                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 943         }
 944
 945         PlayerStats_Init();
 946
 947         world_initialized = 1;
 948 }
 949
 950 void spawnfunc_light (void)
 951 {
 952         //makestatic (self); // Who the f___ did that?
 953         remove(self);
 954 }
 955
 956 string GetGametype()
 957 {
 958         return GametypeNameFromType(game);
 959 }
 960
 961 string getmapname_stored;
 962 string GetMapname()
 963 {
 964         return mapname;
 965 }
 966
 967 float Map_Count, Map_Current;
 968 string Map_Current_Name;
 969
 970 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 971 float GetMaplistPosition()
 972 {
 973         float pos, idx;
 974         string map;
 975
 976         map = GetMapname();
 977         idx = autocvar_g_maplist_index;
 978
 979         if(idx >= 0)
 980                 if(idx < Map_Count)
 981                         if(map == argv(idx))
 982                                 return idx;
 983
 984         for(pos = 0; pos < Map_Count; ++pos)
 985                 if(map == argv(pos))
 986                         return pos;
 987
 988         // resume normal maplist rotation if current map is not in g_maplist
 989         return idx;
 990 }
 991
 992 float MapHasRightSize(string map)
 993 {
 994         float fh;
 995         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 996         if(autocvar_g_maplist_check_waypoints)
 997         {
 998                 dprint("checkwp "); dprint(map);
 999                 if(!fexists(strcat("maps/", map, ".waypoints")))
1000                 {
1001                         dprint(": no waypoints\n");
1002                         return FALSE;
1003                 }
1004                 dprint(": has waypoints\n");
1005         }
1006
1007         // open map size restriction file
1008         dprint("opensize "); dprint(map);
1009         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1010         if(fh >= 0)
1011         {
1012                 float mapmin, mapmax;
1013                 dprint(": ok, ");
1014                 mapmin = stof(fgets(fh));
1015                 mapmax = stof(fgets(fh));
1016                 fclose(fh);
1017                 if(player_count < mapmin)
1018                 {
1019                         dprint("not enough\n");
1020                         return FALSE;
1021                 }
1022                 if(player_count > mapmax)
1023                 {
1024                         dprint("too many\n");
1025                         return FALSE;
1026                 }
1027                 dprint("right size\n");
1028                 return TRUE;
1029         }
1030         dprint(": not found\n");
1031         return TRUE;
1032 }
1033
1034 string Map_Filename(float position)
1035 {
1036         return strcat("maps/", argv(position), ".bsp");
1037 }
1038
1039 string strwords(string s, float w)
1040 {
1041         float endpos;
1042         for(endpos = 0; w && endpos >= 0; --w)
1043                 endpos = strstrofs(s, " ", endpos + 1);
1044         if(endpos < 0)
1045                 return s;
1046         else
1047                 return substring(s, 0, endpos);
1048 }
1049
1050 float strhasword(string s, string w)
1051 {
1052         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1053 }
1054
1055 void Map_MarkAsRecent(string m)
1056 {
1057         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1058 }
1059
1060 float Map_IsRecent(string m)
1061 {
1062         return strhasword(autocvar_g_maplist_mostrecent, m);
1063 }
1064
1065 float Map_Check(float position, float pass)
1066 {
1067         string filename;
1068         string map_next;
1069         map_next = argv(position);
1070         if(pass <= 1)
1071         {
1072                 if(Map_IsRecent(map_next))
1073                         return 0;
1074         }
1075         filename = Map_Filename(position);
1076         if(MapInfo_CheckMap(map_next))
1077         {
1078                 if(pass == 2)
1079                         return 1;
1080                 if(MapHasRightSize(map_next))
1081                         return 1;
1082                 return 0;
1083         }
1084         else
1085                 dprint( "Couldn't select '", filename, "'..\n" );
1086
1087         return 0;
1088 }
1089
1090 void Map_Goto_SetStr(string nextmapname)
1091 {
1092         if(getmapname_stored != "")
1093                 strunzone(getmapname_stored);
1094         if(nextmapname == "")
1095                 getmapname_stored = "";
1096         else
1097                 getmapname_stored = strzone(nextmapname);
1098 }
1099
1100 void Map_Goto_SetFloat(float position)
1101 {
1102         cvar_set("g_maplist_index", ftos(position));
1103         Map_Goto_SetStr(argv(position));
1104 }
1105
1106 void GameResetCfg()
1107 {
1108         // settings persist, except...
1109         localcmd("\nsettemp_restore\n");
1110 }
1111
1112 void Map_Goto()
1113 {
1114         GameResetCfg();
1115         MapInfo_LoadMap(getmapname_stored);
1116 }
1117
1118 // return codes of map selectors:
1119 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1120 //   -2 = permanent failure
1121 float() MaplistMethod_Iterate = // usual method
1122 {
1123         float pass, i;
1124
1125         for(pass = 1; pass <= 2; ++pass)
1126         {
1127                 for(i = 1; i < Map_Count; ++i)
1128                 {
1129                         float mapindex;
1130                         mapindex = mod(i + Map_Current, Map_Count);
1131                         if(Map_Check(mapindex, pass))
1132                                 return mapindex;
1133                 }
1134         }
1135         return -1;
1136 }
1137
1138 float() MaplistMethod_Repeat = // fallback method
1139 {
1140         if(Map_Check(Map_Current, 2))
1141                 return Map_Current;
1142         return -2;
1143 }
1144
1145 float() MaplistMethod_Random = // random map selection
1146 {
1147         float i, imax;
1148
1149         imax = 42;
1150
1151         for(i = 0; i <= imax; ++i)
1152         {
1153                 float mapindex;
1154                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1155                 if(Map_Check(mapindex, 1))
1156                         return mapindex;
1157         }
1158         return -1;
1159 }
1160
1161 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1162 // the exponent sets a bias on the map selection:
1163 // the higher the exponent, the less likely "shortly repeated" same maps are
1164 {
1165         float i, j, imax, insertpos;
1166
1167         imax = 42;
1168
1169         for(i = 0; i <= imax; ++i)
1170         {
1171                 string newlist;
1172
1173                 // now reinsert this at another position
1174                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1175                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1176                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1177                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1178
1179                 // insert the current map there
1180                 newlist = "";
1181                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1182                         newlist = strcat(newlist, " ", argv(j));
1183                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1184                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1185                         newlist = strcat(newlist, " ", argv(j));
1186                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1187                 cvar_set("g_maplist", newlist);
1188                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1189
1190                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1191                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1192                 if(Map_Check(Map_Current, 1))
1193                         return Map_Current;
1194         }
1195         return -1;
1196 }
1197
1198 void Maplist_Init()
1199 {
1200         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1201         if(Map_Count == 0)
1202         {
1203                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1204                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1205                 if(autocvar_g_maplist_shuffle)
1206                         ShuffleMaplist();
1207                 localcmd("\nmenu_cmd sync\n");
1208                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1209         }
1210         if(Map_Count == 0)
1211                 error("empty maplist, cannot select a new map");
1212         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1213
1214         if(Map_Current_Name)
1215                 strunzone(Map_Current_Name);
1216         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1217         // this may or may not be correct, but who cares, in the worst case a map
1218         // isn't chosen in the first pass that should have been
1219 }
1220
1221 string GetNextMap()
1222 {
1223         float nextMap;
1224
1225         Maplist_Init();
1226         nextMap = -1;
1227
1228         if(nextMap == -1)
1229                 if(autocvar_g_maplist_shuffle > 0)
1230                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1231
1232         if(nextMap == -1)
1233                 if(autocvar_g_maplist_selectrandom)
1234                         nextMap = MaplistMethod_Random();
1235
1236         if(nextMap == -1)
1237                 nextMap = MaplistMethod_Iterate();
1238
1239         if(nextMap == -1)
1240                 nextMap = MaplistMethod_Repeat();
1241
1242         if(nextMap >= 0)
1243         {
1244                 Map_Goto_SetFloat(nextMap);
1245                 return getmapname_stored;
1246         }
1247
1248         return "";
1249 }
1250
1251 float DoNextMapOverride()
1252 {
1253         if(autocvar_g_campaign)
1254         {
1255                 CampaignPostIntermission();
1256                 alreadychangedlevel = TRUE;
1257                 return TRUE;
1258         }
1259         if(autocvar_quit_when_empty)
1260         {
1261                 if(player_count <= currentbots)
1262                 {
1263                         localcmd("quit\n");
1264                         alreadychangedlevel = TRUE;
1265                         return TRUE;
1266                 }
1267         }
1268         if(autocvar_quit_and_redirect != "")
1269         {
1270                 redirection_target = strzone(autocvar_quit_and_redirect);
1271                 alreadychangedlevel = TRUE;
1272                 return TRUE;
1273         }
1274         if (autocvar_samelevel) // if samelevel is set, stay on same level
1275         {
1276                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1277                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1278                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1279                 localcmd("restart\n");
1280                 //changelevel (mapname);
1281                 alreadychangedlevel = TRUE;
1282                 return TRUE;
1283         }
1284         if(autocvar_nextmap != "")
1285                 if(MapInfo_CheckMap(autocvar_nextmap))
1286                 {
1287                         Map_Goto_SetStr(autocvar_nextmap);
1288                         Map_Goto();
1289                         alreadychangedlevel = TRUE;
1290                         return TRUE;
1291                 }
1292         if(autocvar_lastlevel)
1293         {
1294                 GameResetCfg();
1295                 localcmd("set lastlevel 0\ntogglemenu\n");
1296                 alreadychangedlevel = TRUE;
1297                 return TRUE;
1298         }
1299         return FALSE;
1300 }
1301
1302 void GotoNextMap()
1303 {
1304         //string nextmap;
1305         //float n, nummaps;
1306         //string s;
1307         if (alreadychangedlevel)
1308                 return;
1309         alreadychangedlevel = TRUE;
1310
1311         {
1312                 string nextMap;
1313                 float allowReset;
1314
1315                 for(allowReset = 1; allowReset >= 0; --allowReset)
1316                 {
1317                         nextMap = GetNextMap();
1318                         if(nextMap != "")
1319                                 break;
1320
1321                         if(allowReset)
1322                         {
1323                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1324                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1325                                 if(autocvar_g_maplist_shuffle)
1326                                         ShuffleMaplist();
1327                                 localcmd("\nmenu_cmd sync\n");
1328                         }
1329                         else
1330                         {
1331                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1332                         }
1333                 }
1334                 Map_Goto();
1335         }
1336 }
1337
1338
1339 /*
1340 ============
1341 IntermissionThink
1342
1343 When the player presses attack or jump, change to the next level
1344 ============
1345 */
1346 .float autoscreenshot;
1347 void() MapVote_Start;
1348 void() MapVote_Think;
1349 float mapvote_initialized;
1350 void IntermissionThink()
1351 {
1352         FixIntermissionClient(self);
1353
1354         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1355                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1356         {
1357                 self.autoscreenshot = -1;
1358                 if(clienttype(self) == CLIENTTYPE_REAL)
1359                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1360                 return;
1361         }
1362
1363         if (time < intermission_exittime)
1364                 return;
1365
1366         if(!mapvote_initialized)
1367                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1368                         return;
1369
1370         MapVote_Start();
1371 }
1372
1373 /*
1374 ============
1375 FindIntermission
1376
1377 Returns the entity to view from
1378 ============
1379 */
1380 /*
1381 entity FindIntermission()
1382 {
1383         local   entity spot;
1384         local   float cyc;
1385
1386 // look for info_intermission first
1387         spot = find (world, classname, "info_intermission");
1388         if (spot)
1389         {       // pick a random one
1390                 cyc = random() * 4;
1391                 while (cyc > 1)
1392                 {
1393                         spot = find (spot, classname, "info_intermission");
1394                         if (!spot)
1395                                 spot = find (spot, classname, "info_intermission");
1396                         cyc = cyc - 1;
1397                 }
1398                 return spot;
1399         }
1400
1401 // then look for the start position
1402         spot = find (world, classname, "info_player_start");
1403         if (spot)
1404                 return spot;
1405
1406 // testinfo_player_start is only found in regioned levels
1407         spot = find (world, classname, "testplayerstart");
1408         if (spot)
1409                 return spot;
1410
1411 // then look for the start position
1412         spot = find (world, classname, "info_player_deathmatch");
1413         if (spot)
1414                 return spot;
1415
1416         //objerror ("FindIntermission: no spot");
1417         return world;
1418 }
1419 */
1420
1421 /*
1422 ===============================================================================
1423
1424 RULES
1425
1426 ===============================================================================
1427 */
1428
1429 void DumpStats(float final)
1430 {
1431         float file;
1432         string s;
1433         float to_console;
1434         float to_eventlog;
1435         float to_file;
1436         float i;
1437
1438         to_console = autocvar_sv_logscores_console;
1439         to_eventlog = autocvar_sv_eventlog;
1440         to_file = autocvar_sv_logscores_file;
1441
1442         if(!final)
1443         {
1444                 to_console = TRUE; // always print printstats replies
1445                 to_eventlog = FALSE; // but never print them to the event log
1446         }
1447
1448         if(to_eventlog)
1449                 if(autocvar_sv_eventlog_console)
1450                         to_console = FALSE; // otherwise we get the output twice
1451
1452         if(final)
1453                 s = ":scores:";
1454         else
1455                 s = ":status:";
1456         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1457
1458         if(to_console)
1459                 print(s, "\n");
1460         if(to_eventlog)
1461                 GameLogEcho(s);
1462         if(to_file)
1463         {
1464                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1465                 if(file == -1)
1466                         to_file = FALSE;
1467                 else
1468                         fputs(file, strcat(s, "\n"));
1469         }
1470
1471         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1472         if(to_console)
1473                 print(s, "\n");
1474         if(to_eventlog)
1475                 GameLogEcho(s);
1476         if(to_file)
1477                 fputs(file, strcat(s, "\n"));
1478
1479         FOR_EACH_CLIENT(other)
1480         {
1481                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1482                 {
1483                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1484                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1485                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1486                                 s = strcat(s, ftos(other.team), ":");
1487                         else
1488                                 s = strcat(s, "spectator:");
1489
1490                         if(to_console)
1491                                 print(s, other.netname, "\n");
1492                         if(to_eventlog)
1493                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1494                         if(to_file)
1495                                 fputs(file, strcat(s, other.netname, "\n"));
1496                 }
1497         }
1498
1499         if(teamplay)
1500         {
1501                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1502                 if(to_console)
1503                         print(s, "\n");
1504                 if(to_eventlog)
1505                         GameLogEcho(s);
1506                 if(to_file)
1507                         fputs(file, strcat(s, "\n"));
1508
1509                 for(i = 1; i < 16; ++i)
1510                 {
1511                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1512                         s = strcat(s, ":", ftos(i));
1513                         if(to_console)
1514                                 print(s, "\n");
1515                         if(to_eventlog)
1516                                 GameLogEcho(s);
1517                         if(to_file)
1518                                 fputs(file, strcat(s, "\n"));
1519                 }
1520         }
1521
1522         if(to_console)
1523                 print(":end\n");
1524         if(to_eventlog)
1525                 GameLogEcho(":end");
1526         if(to_file)
1527         {
1528                 fputs(file, ":end\n");
1529                 fclose(file);
1530         }
1531 }
1532
1533 void FixIntermissionClient(entity e)
1534 {
1535         string s;
1536         if(!e.autoscreenshot) // initial call
1537         {
1538                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1539                 e.health = -2342;
1540                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1541                 e.solid = SOLID_NOT;
1542                 e.movetype = MOVETYPE_NONE;
1543                 e.takedamage = DAMAGE_NO;
1544                 if(e.weaponentity)
1545                 {
1546                         e.weaponentity.effects = EF_NODRAW;
1547                         if (e.weaponentity.weaponentity)
1548                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1549                 }
1550                 if(clienttype(e) == CLIENTTYPE_REAL)
1551                 {
1552                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1553                         s = autocvar_sv_intermission_cdtrack;
1554                         if(s != "")
1555                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1556                         msg_entity = e;
1557                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1558                 }
1559         }
1560 }
1561
1562
1563 /*
1564 go to the next level for deathmatch
1565 only called if a time or frag limit has expired
1566 */
1567 void NextLevel()
1568 {
1569         gameover = TRUE;
1570
1571         intermission_running = 1;
1572
1573 // enforce a wait time before allowing changelevel
1574         if(player_count > 0)
1575                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1576         else
1577                 intermission_exittime = -1;
1578
1579         /*
1580         WriteByte (MSG_ALL, SVC_CDTRACK);
1581         WriteByte (MSG_ALL, 3);
1582         WriteByte (MSG_ALL, 3);
1583         // done in FixIntermission
1584         */
1585
1586         //pos = FindIntermission ();
1587
1588         VoteReset();
1589
1590         DumpStats(TRUE);
1591
1592         // send statistics
1593         entity e;
1594         PlayerStats_EndMatch(1);
1595         FOR_EACH_CLIENT(e)
1596                 PlayerStats_AddGlobalInfo(e);
1597         PlayerStats_Shutdown();
1598         WeaponStats_Shutdown();
1599
1600         if(autocvar_sv_eventlog)
1601                 GameLogEcho(":gameover");
1602
1603         GameLogClose();
1604
1605         FOR_EACH_PLAYER(other) {
1606                 FixIntermissionClient(other);
1607                 if(other.winning)
1608                         bprint(other.netname, " ^7wins.\n");
1609         }
1610
1611         if(autocvar_g_campaign)
1612                 CampaignPreIntermission();
1613
1614         localcmd("\nsv_hook_gameend\n");
1615 }
1616
1617 /*
1618 ============
1619 CheckRules_Player
1620
1621 Exit deathmatch games upon conditions
1622 ============
1623 */
1624 void CheckRules_Player()
1625 {
1626         if (gameover)   // someone else quit the game already
1627                 return;
1628
1629         if(self.deadflag == DEAD_NO)
1630                 self.play_time += frametime;
1631
1632         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1633         //   (div0: and that in CheckRules_World please)
1634 }
1635
1636 float checkrules_equality;
1637 float checkrules_suddendeathwarning;
1638 float checkrules_suddendeathend;
1639 float checkrules_overtimesadded; //how many overtimes have been already added
1640
1641 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1642 float WINNING_YES = 1; // winner found
1643 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1644 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1645
1646 float InitiateSuddenDeath()
1647 {
1648         // Check first whether normal overtimes could be added before initiating suddendeath mode
1649         // - for this timelimit_overtime needs to be >0 of course
1650         // - also check the winning condition calculated in the previous frame and only add normal overtime
1651         //   again, if at the point at which timelimit would be extended again, still no winner was found
1652         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1653         {
1654                 return 1; // need to call InitiateOvertime later
1655         }
1656         else
1657         {
1658                 if(!checkrules_suddendeathend)
1659                 {
1660                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1661                         if(g_race && !g_race_qualifying)
1662                                 race_StartCompleting();
1663                 }
1664                 return 0;
1665         }
1666 }
1667
1668 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1669 {
1670         ++checkrules_overtimesadded;
1671         //add one more overtime by simply extending the timelimit
1672         float tl;
1673         tl = autocvar_timelimit;
1674         tl += autocvar_timelimit_overtime;
1675         cvar_set("timelimit", ftos(tl));
1676         string minutesPlural;
1677         if (autocvar_timelimit_overtime == 1)
1678                 minutesPlural = " ^3minute";
1679         else
1680                 minutesPlural = " ^3minutes";
1681
1682         bcenterprint(
1683                 strcat(
1684                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1685                         ftos(autocvar_timelimit_overtime),
1686                         minutesPlural,
1687                         " to the game!"
1688                 )
1689         );
1690 }
1691
1692 float GetWinningCode(float fraglimitreached, float equality)
1693 {
1694         if(autocvar_g_campaign == 1)
1695                 if(fraglimitreached)
1696                         return WINNING_YES;
1697                 else
1698                         return WINNING_NO;
1699
1700         else
1701                 if(equality)
1702                         if(fraglimitreached)
1703                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1704                         else
1705                                 return WINNING_NEVER;
1706                 else
1707                         if(fraglimitreached)
1708                                 return WINNING_YES;
1709                         else
1710                                 return WINNING_NO;
1711 }
1712
1713 // set the .winning flag for exactly those players with a given field value
1714 void SetWinners(.float field, float value)
1715 {
1716         entity head;
1717         FOR_EACH_PLAYER(head)
1718                 head.winning = (head.field == value);
1719 }
1720
1721 // set the .winning flag for those players with a given field value
1722 void AddWinners(.float field, float value)
1723 {
1724         entity head;
1725         FOR_EACH_PLAYER(head)
1726                 if(head.field == value)
1727                         head.winning = 1;
1728 }
1729
1730 // clear the .winning flags
1731 void ClearWinners(void)
1732 {
1733         entity head;
1734         FOR_EACH_PLAYER(head)
1735                 head.winning = 0;
1736 }
1737
1738 // Onslaught winning condition:
1739 // game terminates if only one team has a working generator (or none)
1740 float WinningCondition_Onslaught()
1741 {
1742         entity head;
1743         float t1, t2, t3, t4;
1744
1745         WinningConditionHelper(); // set worldstatus
1746
1747         if(inWarmupStage)
1748                 return WINNING_NO;
1749
1750         // first check if the game has ended
1751         t1 = t2 = t3 = t4 = 0;
1752         head = find(world, classname, "onslaught_generator");
1753         while (head)
1754         {
1755                 if (head.health > 0)
1756                 {
1757                         if (head.team == COLOR_TEAM1) t1 = 1;
1758                         if (head.team == COLOR_TEAM2) t2 = 1;
1759                         if (head.team == COLOR_TEAM3) t3 = 1;
1760                         if (head.team == COLOR_TEAM4) t4 = 1;
1761                 }
1762                 head = find(head, classname, "onslaught_generator");
1763         }
1764         if (t1 + t2 + t3 + t4 < 2)
1765         {
1766                 // game over, only one team remains (or none)
1767                 ClearWinners();
1768                 if (t1) SetWinners(team, COLOR_TEAM1);
1769                 if (t2) SetWinners(team, COLOR_TEAM2);
1770                 if (t3) SetWinners(team, COLOR_TEAM3);
1771                 if (t4) SetWinners(team, COLOR_TEAM4);
1772                 dprint("Have a winner, ending game.\n");
1773                 return WINNING_YES;
1774         }
1775
1776         // Two or more teams remain
1777         return WINNING_NO;
1778 }
1779
1780 float LMS_NewPlayerLives()
1781 {
1782         float fl;
1783         fl = autocvar_fraglimit;
1784         if(fl == 0)
1785                 fl = 999;
1786
1787         // first player has left the game for dying too much? Nobody else can get in.
1788         if(lms_lowest_lives < 1)
1789                 return 0;
1790
1791         if(!autocvar_g_lms_join_anytime)
1792                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1793                         return 0;
1794
1795         return bound(1, lms_lowest_lives, fl);
1796 }
1797
1798 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1799 // they win. Otherwise the defending team wins once the timelimit passes.
1800 void assault_new_round();
1801 float WinningCondition_Assault()
1802 {
1803         float status;
1804
1805         WinningConditionHelper(); // set worldstatus
1806
1807         status = WINNING_NO;
1808         // as the timelimit has not yet passed just assume the defending team will win
1809         if(assault_attacker_team == COLOR_TEAM1)
1810         {
1811                 SetWinners(team, COLOR_TEAM2);
1812         }
1813         else
1814         {
1815                 SetWinners(team, COLOR_TEAM1);
1816         }
1817
1818         entity ent;
1819         ent = find(world, classname, "target_assault_roundend");
1820         if(ent)
1821         {
1822                 if(ent.winning) // round end has been triggered by attacking team
1823                 {
1824                         bprint("ASSAULT: round completed...\n");
1825                         SetWinners(team, assault_attacker_team);
1826
1827                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1828
1829                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1830                         {
1831                                 status = WINNING_YES;
1832                         }
1833                         else
1834                         {
1835                                 entity oldself;
1836                                 oldself = self;
1837                                 self = ent;
1838                                 assault_new_round();
1839                                 self = oldself;
1840                         }
1841                 }
1842         }
1843
1844         return status;
1845 }
1846
1847 // LMS winning condition: game terminates if and only if there's at most one
1848 // one player who's living lives. Top two scores being equal cancels the time
1849 // limit.
1850 float WinningCondition_LMS()
1851 {
1852         entity head, head2;
1853         float have_player;
1854         float have_players;
1855         float l;
1856
1857         have_player = FALSE;
1858         have_players = FALSE;
1859         l = LMS_NewPlayerLives();
1860
1861         head = find(world, classname, "player");
1862         if(head)
1863                 have_player = TRUE;
1864         head2 = find(head, classname, "player");
1865         if(head2)
1866                 have_players = TRUE;
1867
1868         if(have_player)
1869         {
1870                 // we have at least one player
1871                 if(have_players)
1872                 {
1873                         // two or more active players - continue with the game
1874                 }
1875                 else
1876                 {
1877                         // exactly one player?
1878
1879                         ClearWinners();
1880                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1881
1882                         if(l)
1883                         {
1884                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1885                                 return WINNING_NO;
1886                         }
1887                         else
1888                         {
1889                                 // a winner!
1890                                 // and assign him his first place
1891                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1892                                 return WINNING_YES;
1893                         }
1894                 }
1895         }
1896         else
1897         {
1898                 // nobody is playing at all...
1899                 if(l)
1900                 {
1901                         // wait for players...
1902                 }
1903                 else
1904                 {
1905                         // SNAFU (maybe a draw game?)
1906                         ClearWinners();
1907                         dprint("No players, ending game.\n");
1908                         return WINNING_YES;
1909                 }
1910         }
1911
1912         // When we get here, we have at least two players who are actually LIVING,
1913         // now check if the top two players have equal score.
1914         WinningConditionHelper();
1915
1916         ClearWinners();
1917         if(WinningConditionHelper_winner)
1918                 WinningConditionHelper_winner.winning = TRUE;
1919         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1920                 return WINNING_NEVER;
1921
1922         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1923         return WINNING_NO;
1924 }
1925
1926 void ShuffleMaplist()
1927 {
1928         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1929 }
1930
1931 float leaderfrags;
1932 float WinningCondition_Scores(float limit, float leadlimit)
1933 {
1934         float limitreached;
1935
1936         // TODO make everything use THIS winning condition (except LMS)
1937         WinningConditionHelper();
1938
1939         if(teamplay)
1940         {
1941                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1942                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1943                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1944                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1945         }
1946
1947         ClearWinners();
1948         if(WinningConditionHelper_winner)
1949                 WinningConditionHelper_winner.winning = 1;
1950         if(WinningConditionHelper_winnerteam >= 0)
1951                 SetWinners(team, WinningConditionHelper_winnerteam);
1952
1953         if(WinningConditionHelper_lowerisbetter)
1954         {
1955                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1956                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1957                 limit = -limit;
1958         }
1959
1960         if(WinningConditionHelper_zeroisworst)
1961                 leadlimit = 0; // not supported in this mode
1962
1963         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1964         // these modes always score in increments of 1, thus this makes sense
1965         {
1966                 if(leaderfrags != WinningConditionHelper_topscore)
1967                 {
1968                         leaderfrags = WinningConditionHelper_topscore;
1969
1970                         if (limit)
1971                         if (leaderfrags == limit - 1)
1972                                 Announce("1fragleft");
1973                         else if (leaderfrags == limit - 2)
1974                                 Announce("2fragsleft");
1975                         else if (leaderfrags == limit - 3)
1976                                 Announce("3fragsleft");
1977                 }
1978         }
1979
1980         limitreached = FALSE;
1981         if(limit)
1982                 if(WinningConditionHelper_topscore >= limit)
1983                         limitreached = TRUE;
1984         if(leadlimit)
1985         {
1986                 float leadlimitreached;
1987                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1988                 if(autocvar_leadlimit_and_fraglimit)
1989                         limitreached = (limitreached && leadlimitreached);
1990                 else
1991                         limitreached = (limitreached || leadlimitreached);
1992         }
1993
1994         return GetWinningCode(
1995                 WinningConditionHelper_topscore && limitreached,
1996                 WinningConditionHelper_equality
1997         );
1998 }
1999
2000 float WinningCondition_Race(float fraglimit)
2001 {
2002         float wc;
2003         entity p;
2004         float n, c;
2005
2006         n = 0;
2007         c = 0;
2008         FOR_EACH_PLAYER(p)
2009         {
2010                 ++n;
2011                 if(p.race_completed)
2012                         ++c;
2013         }
2014         if(n && (n == c))
2015                 return WINNING_YES;
2016         wc = WinningCondition_Scores(fraglimit, 0);
2017
2018         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2019         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2020         // do NOT support equality when the laps are all raced!
2021                 return WINNING_STARTSUDDENDEATHOVERTIME;
2022         else
2023                 return WINNING_NEVER;
2024         return wc;
2025 }
2026
2027 void ReadyRestart();
2028 float WinningCondition_QualifyingThenRace(float limit)
2029 {
2030         float wc;
2031         wc = WinningCondition_Scores(limit, 0);
2032
2033         // NEVER initiate overtime
2034         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2035         {
2036                 return WINNING_YES;
2037         }
2038
2039         return wc;
2040 }
2041
2042 float WinningCondition_RanOutOfSpawns()
2043 {
2044         entity head;
2045
2046         if(have_team_spawns <= 0)
2047                 return WINNING_NO;
2048
2049         if(!some_spawn_has_been_used)
2050                 return WINNING_NO;
2051
2052         team1_score = team2_score = team3_score = team4_score = 0;
2053
2054         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2055         {
2056                 if(head.team == COLOR_TEAM1)
2057                         team1_score = 1;
2058                 else if(head.team == COLOR_TEAM2)
2059                         team2_score = 1;
2060                 else if(head.team == COLOR_TEAM3)
2061                         team3_score = 1;
2062                 else if(head.team == COLOR_TEAM4)
2063                         team4_score = 1;
2064         }
2065
2066         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2067         {
2068                 if(head.team == COLOR_TEAM1)
2069                         team1_score = 1;
2070                 else if(head.team == COLOR_TEAM2)
2071                         team2_score = 1;
2072                 else if(head.team == COLOR_TEAM3)
2073                         team3_score = 1;
2074                 else if(head.team == COLOR_TEAM4)
2075                         team4_score = 1;
2076         }
2077
2078         ClearWinners();
2079         if(team1_score + team2_score + team3_score + team4_score == 0)
2080         {
2081                 checkrules_equality = TRUE;
2082                 return WINNING_YES;
2083         }
2084         else if(team1_score + team2_score + team3_score + team4_score == 1)
2085         {
2086                 float t, i;
2087                 if(team1_score) t = COLOR_TEAM1;
2088                 if(team2_score) t = COLOR_TEAM2;
2089                 if(team3_score) t = COLOR_TEAM3;
2090                 if(team4_score) t = COLOR_TEAM4;
2091                 CheckAllowedTeams(world);
2092                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2093                 {
2094                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2095                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2096                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2097                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2098                 }
2099
2100                 AddWinners(team, t);
2101                 return WINNING_YES;
2102         }
2103         else
2104                 return WINNING_NO;
2105 }
2106
2107 /*
2108 ============
2109 CheckRules_World
2110
2111 Exit deathmatch games upon conditions
2112 ============
2113 */
2114 void CheckRules_World()
2115 {
2116         float timelimit;
2117         float fraglimit;
2118         float leadlimit;
2119
2120         VoteThink();
2121         MapVote_Think();
2122
2123         SetDefaultAlpha();
2124
2125         /*
2126         MapVote_Think should now do that part
2127         if (intermission_running)
2128                 if (time >= intermission_exittime + 60)
2129                 {
2130                         if(!DoNextMapOverride())
2131                                 GotoNextMap();
2132                         return;
2133                 }
2134         */
2135
2136         if (gameover)   // someone else quit the game already
2137         {
2138                 if(player_count == 0) // Nobody there? Then let's go to the next map
2139                         MapVote_Start();
2140                         // this will actually check the player count in the next frame
2141                         // again, but this shouldn't hurt
2142                 return;
2143         }
2144
2145         timelimit = autocvar_timelimit * 60;
2146         fraglimit = autocvar_fraglimit;
2147         leadlimit = autocvar_leadlimit;
2148
2149         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2150         {
2151                 if(timelimit > 0)
2152                         timelimit = 0; // timelimit is not made for warmup
2153                 if(fraglimit > 0)
2154                         fraglimit = 0; // no fraglimit for now
2155                 leadlimit = 0; // no leadlimit for now
2156         }
2157
2158         if(g_onslaught)
2159                 timelimit = 0; // ONS has its own overtime rule
2160
2161         if(timelimit > 0)
2162         {
2163                 timelimit += game_starttime;
2164         }
2165         else if (timelimit < 0)
2166         {
2167                 // endmatch
2168                 NextLevel();
2169                 return;
2170         }
2171
2172         float wantovertime;
2173         wantovertime = 0;
2174
2175         if(checkrules_suddendeathend)
2176         {
2177                 if(!checkrules_suddendeathwarning)
2178                 {
2179                         checkrules_suddendeathwarning = TRUE;
2180                         if(g_race && !g_race_qualifying)
2181                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2182                         else
2183                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2184                 }
2185         }
2186         else
2187         {
2188                 if (timelimit && time >= timelimit)
2189                 {
2190                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2191                         {
2192                                 float totalplayers;
2193                                 float playerswithlaps;
2194                                 float readyplayers;
2195                                 entity head;
2196                                 totalplayers = playerswithlaps = readyplayers = 0;
2197                                 FOR_EACH_PLAYER(head)
2198                                 {
2199                                         ++totalplayers;
2200                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2201                                                 ++playerswithlaps;
2202                                         if(head.ready)
2203                                                 ++readyplayers;
2204                                 }
2205
2206                                 // at least 2 of the players have completed a lap: start the RACE
2207                                 // otherwise, the players should end the qualifying on their own
2208                                 if(readyplayers || playerswithlaps >= 2)
2209                                 {
2210                                         checkrules_suddendeathend = 0;
2211                                         ReadyRestart(); // go to race
2212                                         return;
2213                                 }
2214                                 else
2215                                         wantovertime |= InitiateSuddenDeath();
2216                         }
2217                         else
2218                                 wantovertime |= InitiateSuddenDeath();
2219                 }
2220         }
2221
2222         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2223         {
2224                 NextLevel();
2225                 return;
2226         }
2227
2228         float checkrules_status;
2229         checkrules_status = WinningCondition_RanOutOfSpawns();
2230         if(checkrules_status == WINNING_YES)
2231         {
2232                 bprint("Hey! Someone ran out of spawns!\n");
2233         }
2234         else if(g_race && !g_race_qualifying && timelimit >= 0)
2235         {
2236                 checkrules_status = WinningCondition_Race(fraglimit);
2237                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2238         }
2239         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2240         {
2241                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2242                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2243         }
2244         else if(g_assault)
2245         {
2246                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2247         }
2248         else if(g_lms)
2249         {
2250                 checkrules_status = WinningCondition_LMS();
2251         }
2252         else if (g_onslaught)
2253         {
2254                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2255         }
2256         else
2257         {
2258                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2259                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2260         }
2261
2262         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2263         {
2264                 checkrules_status = WINNING_NEVER;
2265                 checkrules_overtimesadded = -1;
2266                 wantovertime |= InitiateSuddenDeath();
2267         }
2268
2269         if(checkrules_status == WINNING_NEVER)
2270                 // equality cases! Nobody wins if the overtime ends in a draw.
2271                 ClearWinners();
2272
2273         if(wantovertime)
2274         {
2275                 if(checkrules_status == WINNING_NEVER)
2276                         InitiateOvertime();
2277                 else
2278                         checkrules_status = WINNING_YES;
2279         }
2280
2281         if(checkrules_suddendeathend)
2282                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2283                         checkrules_status = WINNING_YES;
2284
2285         if(checkrules_status == WINNING_YES)
2286         {
2287                 //print("WINNING\n");
2288                 NextLevel();
2289         }
2290 }
2291
2292 float mapvote_nextthink;
2293 float mapvote_initialized;
2294 float mapvote_keeptwotime;
2295 float mapvote_timeout;
2296 string mapvote_message;
2297 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2298 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2299 float mapvote_screenshot_dirs_count;
2300
2301 float mapvote_count;
2302 float mapvote_count_real;
2303 string mapvote_maps[MAPVOTE_COUNT];
2304 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2305 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2306 float mapvote_maps_suggested[MAPVOTE_COUNT];
2307 string mapvote_suggestions[MAPVOTE_COUNT];
2308 float mapvote_suggestion_ptr;
2309 float mapvote_voters;
2310 float mapvote_votes[MAPVOTE_COUNT];
2311 float mapvote_run;
2312 float mapvote_detail;
2313 float mapvote_abstain;
2314 .float mapvote;
2315
2316 void MapVote_ClearAllVotes()
2317 {
2318         FOR_EACH_CLIENT(other)
2319                 other.mapvote = 0;
2320 }
2321
2322 string MapVote_Suggest(string m)
2323 {
2324         float i;
2325         if(m == "")
2326                 return "That's not how to use this command.";
2327         if(!autocvar_g_maplist_votable_suggestions)
2328                 return "Suggestions are not accepted on this server.";
2329         if(mapvote_initialized)
2330                 return "Can't suggest - voting is already in progress!";
2331         m = MapInfo_FixName(m);
2332         if(!m)
2333                 return "The map you suggested is not available on this server.";
2334         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2335                 if(Map_IsRecent(m))
2336                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2337
2338         if(!MapInfo_CheckMap(m))
2339                 return "The map you suggested does not support the current game mode.";
2340         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2341                 if(mapvote_suggestions[i] == m)
2342                         return "This map was already suggested.";
2343         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2344         {
2345                 i = floor(random() * mapvote_suggestion_ptr);
2346         }
2347         else
2348         {
2349                 i = mapvote_suggestion_ptr;
2350                 mapvote_suggestion_ptr += 1;
2351         }
2352         if(mapvote_suggestions[i] != "")
2353                 strunzone(mapvote_suggestions[i]);
2354         mapvote_suggestions[i] = strzone(m);
2355         if(autocvar_sv_eventlog)
2356                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2357         return strcat("Suggestion of ", m, " accepted.");
2358 }
2359
2360 void MapVote_AddVotable(string nextMap, float isSuggestion)
2361 {
2362         float j, i, o;
2363         string pakfile, mapfile;
2364
2365         if(nextMap == "")
2366                 return;
2367         for(j = 0; j < mapvote_count; ++j)
2368                 if(mapvote_maps[j] == nextMap)
2369                         return;
2370         // suggestions might be no longer valid/allowed after gametype switch!
2371         if(isSuggestion)
2372                 if(!MapInfo_CheckMap(nextMap))
2373                         return;
2374         mapvote_maps[mapvote_count] = strzone(nextMap);
2375         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2376
2377         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2378         {
2379                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2380                 pakfile = whichpack(strcat(mapfile, ".tga"));
2381                 if(pakfile == "")
2382                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2383                 if(pakfile == "")
2384                         pakfile = whichpack(strcat(mapfile, ".png"));
2385                 if(pakfile != "")
2386                         break;
2387         }
2388         if(i >= mapvote_screenshot_dirs_count)
2389                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2390         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2391                 pakfile = substring(pakfile, o, -1);
2392
2393         mapvote_maps_screenshot_dir[mapvote_count] = i;
2394         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2395
2396         mapvote_count += 1;
2397 }
2398
2399 void MapVote_Spawn();
2400 void MapVote_Init()
2401 {
2402         float i;
2403         float nmax, smax;
2404
2405         MapVote_ClearAllVotes();
2406
2407         mapvote_count = 0;
2408         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2409         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2410
2411         if(mapvote_abstain)
2412                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2413         else
2414                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2415         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2416
2417         // we need this for AddVotable, as that cycles through the screenshot dirs
2418         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2419         if(mapvote_screenshot_dirs_count == 0)
2420                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2421         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2422         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2423                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2424
2425         if(mapvote_suggestion_ptr)
2426                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2427                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2428
2429         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2430                 MapVote_AddVotable(GetNextMap(), FALSE);
2431
2432         if(mapvote_count == 0)
2433         {
2434                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2435                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2436                 if(autocvar_g_maplist_shuffle)
2437                         ShuffleMaplist();
2438                 localcmd("\nmenu_cmd sync\n");
2439                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2440                         MapVote_AddVotable(GetNextMap(), FALSE);
2441         }
2442
2443         mapvote_count_real = mapvote_count;
2444         if(mapvote_abstain)
2445                 MapVote_AddVotable("don't care", 0);
2446
2447         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2448
2449         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2450         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2451         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2452                 mapvote_keeptwotime = 0;
2453         mapvote_message = "Choose a map and press its key!";
2454
2455         MapVote_Spawn();
2456 }
2457
2458 void MapVote_SendPicture(float id)
2459 {
2460         msg_entity = self;
2461         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2462         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2463         WriteByte(MSG_ONE, id);
2464         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2465 }
2466
2467 float GameCommand_MapVote(string cmd)
2468 {
2469         if(!intermission_running)
2470                 return FALSE;
2471
2472         if(cmd == "mv_getpic")
2473         {
2474                 MapVote_SendPicture(stof(argv(1)));
2475                 return TRUE;
2476         }
2477
2478         return FALSE;
2479 }
2480
2481 float MapVote_GetMapMask()
2482 {
2483         float mask, i, power;
2484         mask = 0;
2485         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2486                 if(mapvote_maps[i] != "")
2487                         mask |= power;
2488         return mask;
2489 }
2490
2491 entity mapvote_ent;
2492 float MapVote_SendEntity(entity to, float sf)
2493 {
2494         float i;
2495
2496         if(sf & 1)
2497                 sf &~= 2; // if we send 1, we don't need to also send 2
2498
2499         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2500         WriteByte(MSG_ENTITY, sf);
2501
2502         if(sf & 1)
2503         {
2504                 // flag 1 == initialization
2505                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2506                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2507                 WriteString(MSG_ENTITY, "");
2508                 WriteByte(MSG_ENTITY, mapvote_count);
2509                 WriteByte(MSG_ENTITY, mapvote_abstain);
2510                 WriteByte(MSG_ENTITY, mapvote_detail);
2511                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2512                 if(mapvote_count <= 8)
2513                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2514                 else
2515                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2516                 for(i = 0; i < mapvote_count; ++i)
2517                         if(mapvote_maps[i] != "")
2518                         {
2519                                 if(mapvote_abstain && i == mapvote_count - 1)
2520                                 {
2521                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2522                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2523                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2524                                 }
2525                                 else
2526                                 {
2527                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2528                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2529                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2530                                 }
2531                         }
2532         }
2533
2534         if(sf & 2)
2535         {
2536                 // flag 2 == update of mask
2537                 if(mapvote_count <= 8)
2538                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2539                 else
2540                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2541         }
2542
2543         if(sf & 4)
2544         {
2545                 if(mapvote_detail)
2546                         for(i = 0; i < mapvote_count; ++i)
2547                                 if(mapvote_maps[i] != "")
2548                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2549
2550                 WriteByte(MSG_ENTITY, to.mapvote);
2551         }
2552
2553         return TRUE;
2554 }
2555
2556 void MapVote_Spawn()
2557 {
2558         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2559 }
2560
2561 void MapVote_TouchMask()
2562 {
2563         mapvote_ent.SendFlags |= 2;
2564 }
2565
2566 void MapVote_TouchVotes(entity voter)
2567 {
2568         mapvote_ent.SendFlags |= 4;
2569 }
2570
2571 float MapVote_Finished(float mappos)
2572 {
2573         string result;
2574         float i;
2575         float didntvote;
2576
2577         if(autocvar_sv_eventlog)
2578         {
2579                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2580                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2581                 didntvote = mapvote_voters;
2582                 for(i = 0; i < mapvote_count; ++i)
2583                         if(mapvote_maps[i] != "")
2584                         {
2585                                 didntvote -= mapvote_votes[i];
2586                                 if(i != mappos)
2587                                 {
2588                                         result = strcat(result, ":", mapvote_maps[i]);
2589                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2590                                 }
2591                         }
2592                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2593
2594                 GameLogEcho(result);
2595                 if(mapvote_maps_suggested[mappos])
2596                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2597         }
2598
2599         FOR_EACH_REALCLIENT(other)
2600                 FixClientCvars(other);
2601
2602         Map_Goto_SetStr(mapvote_maps[mappos]);
2603         Map_Goto();
2604         alreadychangedlevel = TRUE;
2605         return TRUE;
2606 }
2607 void MapVote_CheckRules_1()
2608 {
2609         float i;
2610
2611         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2612         {
2613                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2614                 mapvote_votes[i] = 0;
2615         }
2616
2617         mapvote_voters = 0;
2618         FOR_EACH_REALCLIENT(other)
2619         {
2620                 ++mapvote_voters;
2621                 if(other.mapvote)
2622                 {
2623                         i = other.mapvote - 1;
2624                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2625                         mapvote_votes[i] = mapvote_votes[i] + 1;
2626                 }
2627         }
2628 }
2629
2630 float MapVote_CheckRules_2()
2631 {
2632         float i;
2633         float firstPlace, secondPlace;
2634         float firstPlaceVotes, secondPlaceVotes;
2635         float mapvote_voters_real;
2636         string result;
2637
2638         if(mapvote_count_real == 1)
2639                 return MapVote_Finished(0);
2640
2641         mapvote_voters_real = mapvote_voters;
2642         if(mapvote_abstain)
2643                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2644
2645         RandomSelection_Init();
2646         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2647                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2648         firstPlace = RandomSelection_chosen_float;
2649         firstPlaceVotes = RandomSelection_best_priority;
2650         //dprint("First place: ", ftos(firstPlace), "\n");
2651         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2652
2653         RandomSelection_Init();
2654         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2655                 if(i != firstPlace)
2656                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2657         secondPlace = RandomSelection_chosen_float;
2658         secondPlaceVotes = RandomSelection_best_priority;
2659         //dprint("Second place: ", ftos(secondPlace), "\n");
2660         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2661
2662         if(firstPlace == -1)
2663                 error("No first place in map vote... WTF?");
2664
2665         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2666                 return MapVote_Finished(firstPlace);
2667
2668         if(mapvote_keeptwotime)
2669                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2670                 {
2671                         float didntvote;
2672                         MapVote_TouchMask();
2673                         mapvote_message = "Now decide between the TOP TWO!";
2674                         mapvote_keeptwotime = 0;
2675                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2676                         result = strcat(result, ":", ftos(firstPlaceVotes));
2677                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2678                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2679                         didntvote = mapvote_voters;
2680                         for(i = 0; i < mapvote_count; ++i)
2681                                 if(mapvote_maps[i] != "")
2682                                 {
2683                                         didntvote -= mapvote_votes[i];
2684                                         if(i != firstPlace)
2685                                                 if(i != secondPlace)
2686                                                 {
2687                                                         result = strcat(result, ":", mapvote_maps[i]);
2688                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2689                                                         if(i < mapvote_count_real)
2690                                                         {
2691                                                                 strunzone(mapvote_maps[i]);
2692                                                                 mapvote_maps[i] = "";
2693                                                                 strunzone(mapvote_maps_pakfile[i]);
2694                                                                 mapvote_maps_pakfile[i] = "";
2695                                                         }
2696                                                 }
2697                                 }
2698                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2699                         if(autocvar_sv_eventlog)
2700                                 GameLogEcho(result);
2701                 }
2702
2703         return FALSE;
2704 }
2705 void MapVote_Tick()
2706 {
2707         float keeptwo;
2708         float totalvotes;
2709
2710         keeptwo = mapvote_keeptwotime;
2711         MapVote_CheckRules_1(); // count
2712         if(MapVote_CheckRules_2()) // decide
2713                 return;
2714
2715         totalvotes = 0;
2716         FOR_EACH_REALCLIENT(other)
2717         {
2718                 // hide scoreboard again
2719                 if(other.health != 2342)
2720                 {
2721                         other.health = 2342;
2722                         other.impulse = 0;
2723                         if(clienttype(other) == CLIENTTYPE_REAL)
2724                         {
2725                                 msg_entity = other;
2726                                 WriteByte(MSG_ONE, SVC_FINALE);
2727                                 WriteString(MSG_ONE, "");
2728                         }
2729                 }
2730
2731                 // clear possibly invalid votes
2732                 if(mapvote_maps[other.mapvote - 1] == "")
2733                         other.mapvote = 0;
2734                 // use impulses as new vote
2735                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2736                         if(mapvote_maps[other.impulse - 1] != "")
2737                         {
2738                                 other.mapvote = other.impulse;
2739                                 MapVote_TouchVotes(other);
2740                         }
2741                 other.impulse = 0;
2742
2743                 if(other.mapvote)
2744                         ++totalvotes;
2745         }
2746
2747         MapVote_CheckRules_1(); // just count
2748 }
2749 void MapVote_Start()
2750 {
2751         if(mapvote_run)
2752                 return;
2753
2754         // wait for stats to be sent first
2755         if(!playerstats_waitforme)
2756                 return;
2757
2758         MapInfo_Enumerate();
2759         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2760                 mapvote_run = TRUE;
2761 }
2762 void MapVote_Think()
2763 {
2764         if(!mapvote_run)
2765                 return;
2766
2767         if(alreadychangedlevel)
2768                 return;
2769
2770         if(time < mapvote_nextthink)
2771                 return;
2772         //dprint("tick\n");
2773
2774         mapvote_nextthink = time + 0.5;
2775
2776         if(!mapvote_initialized)
2777         {
2778                 if(autocvar_rescan_pending == 1)
2779                 {
2780                         cvar_set("rescan_pending", "2");
2781                         localcmd("fs_rescan\nrescan_pending 3\n");
2782                         return;
2783                 }
2784                 else if(autocvar_rescan_pending == 2)
2785                 {
2786                         return;
2787                 }
2788                 else if(autocvar_rescan_pending == 3)
2789                 {
2790                         // now build missing mapinfo files
2791                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2792                                 return;
2793
2794                         // we're done, start the timer
2795                         cvar_set("rescan_pending", "0");
2796                 }
2797
2798                 mapvote_initialized = TRUE;
2799                 if(DoNextMapOverride())
2800                         return;
2801                 if(!autocvar_g_maplist_votable || player_count <= 0)
2802                 {
2803                         GotoNextMap();
2804                         return;
2805                 }
2806                 MapVote_Init();
2807         }
2808
2809         MapVote_Tick();
2810 }
2811
2812 string GotoMap(string m)
2813 {
2814         if(!MapInfo_CheckMap(m))
2815                 return "The map you chose is not available on this server.";
2816         cvar_set("nextmap", m);
2817         cvar_set("timelimit", "-1");
2818         if(mapvote_initialized || alreadychangedlevel)
2819         {
2820                 if(DoNextMapOverride())
2821                         return "Map switch initiated.";
2822                 else
2823                         return "Hm... no. For some reason I like THIS map more.";
2824         }
2825         else
2826                 return "Map switch will happen after scoreboard.";
2827 }
2828
2829
2830 void EndFrame()
2831 {
2832         float altime;
2833         FOR_EACH_REALCLIENT(self)
2834         {
2835                 if(self.classname == "spectator")
2836                 {
2837                         if(self.enemy.typehitsound)
2838                                 self.typehit_time = time;
2839                         else if(self.enemy.hitsound)
2840                                 self.hit_time = time;
2841                 }
2842                 else
2843                 {
2844                         if(self.typehitsound)
2845                                 self.typehit_time = time;
2846                         else if(self.hitsound)
2847                                 self.hit_time = time;
2848                 }
2849         }
2850         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2851         // add 1 frametime because after this, engine SV_Physics
2852         // increases time by a frametime and then networks the frame
2853         // add another frametime because client shows everything with
2854         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2855         // needed!
2856         FOR_EACH_CLIENT(self)
2857         {
2858                 self.hitsound = FALSE;
2859                 self.typehitsound = FALSE;
2860                 antilag_record(self, altime);
2861         }
2862 }
2863
2864
2865 /*
2866  * RedirectionThink:
2867  * returns TRUE if redirecting
2868  */
2869 float redirection_timeout;
2870 float redirection_nextthink;
2871 float RedirectionThink()
2872 {
2873         float clients_found;
2874
2875         if(redirection_target == "")
2876                 return FALSE;
2877
2878         if(!redirection_timeout)
2879         {
2880                 cvar_set("sv_public", "-2");
2881                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2882                 if(redirection_target == "self")
2883                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2884                 else
2885                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2886         }
2887
2888         if(time < redirection_nextthink)
2889                 return TRUE;
2890
2891         redirection_nextthink = time + 1;
2892
2893         clients_found = 0;
2894         FOR_EACH_REALCLIENT(self)
2895         {
2896                 print("Redirecting: sending connect command to ", self.netname, "\n");
2897                 if(redirection_target == "self")
2898                         stuffcmd(self, "\ndisconnect; reconnect\n");
2899                 else
2900                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2901                 ++clients_found;
2902         }
2903
2904         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2905
2906         if(time > redirection_timeout || clients_found == 0)
2907                 localcmd("\nwait; wait; wait; quit\n");
2908
2909         return TRUE;
2910 }
2911
2912 void TargetMusic_RestoreGame();
2913 void RestoreGame()
2914 {
2915         // Loaded from a save game
2916         // some things then break, so let's work around them...
2917
2918         // Progs DB (capture records)
2919         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2920
2921         // Mapinfo
2922         MapInfo_Shutdown();
2923         MapInfo_Enumerate();
2924         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2925         WeaponStats_Init();
2926
2927         TargetMusic_RestoreGame();
2928 }
2929
2930 void SV_Shutdown()
2931 {
2932         entity e;
2933
2934         if(gameover > 1) // shutting down already?
2935                 return;
2936
2937         gameover = 2; // 2 = server shutting down
2938
2939         if(world_initialized > 0)
2940         {
2941                 world_initialized = 0;
2942                 print("Saving persistent data...\n");
2943                 Ban_SaveBans();
2944
2945                 PlayerStats_EndMatch(0);
2946                 FOR_EACH_CLIENT(e)
2947                         PlayerStats_AddGlobalInfo(e);
2948                 PlayerStats_Shutdown();
2949
2950                 if(!cheatcount_total)
2951                 {
2952                         if(autocvar_sv_db_saveasdump)
2953                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2954                         else
2955                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2956                 }
2957                 if(autocvar_developer)
2958                 {
2959                         if(autocvar_sv_db_saveasdump)
2960                                 db_dump(TemporaryDB, "server-temp.db");
2961                         else
2962                                 db_save(TemporaryDB, "server-temp.db");
2963                 }
2964                 CheatShutdown(); // must be after cheatcount check
2965                 db_close(ServerProgsDB);
2966                 db_close(TemporaryDB);
2967                 print("done!\n");
2968                 // tell the bot system the game is ending now
2969                 bot_endgame();
2970
2971                 WeaponStats_Shutdown();
2972                 MapInfo_Shutdown();
2973         }
2974         else if(world_initialized == 0)
2975         {
2976                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2977         }
2978 }