qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/all.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications.qh"
  29 #include "../common/physics.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/all.qh"
  37 #include "../common/weapons/all.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {SELFPARAM();
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         self.nextthink = time + delta;
  53
  54         e = edict_num(self.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new(pingplreport);
  85         make_pure(pingplreport);
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap()
 109 {SELFPARAM();
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 self.nextthink = time;
 134         }
 135         else
 136         {
 137                 self.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("g_maplist_index");
 180                 BADCVAR("halflifebsp");
 181                 BADCVAR("sv_mapformat_is_quake2");
 182                 BADCVAR("sv_mapformat_is_quake3");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_invasion_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_limit");
 308                 BADCVAR("g_ca_point_leadlimit");
 309                 BADCVAR("g_ctf_captimerecord_always");
 310                 BADCVAR("g_ctf_flag_glowtrails");
 311                 BADCVAR("g_ctf_flag_pickup_verbosename");
 312                 BADCVAR("g_domination_point_leadlimit");
 313                 BADCVAR("g_forced_respawn");
 314                 BADCVAR("g_freezetag_point_limit");
 315                 BADCVAR("g_freezetag_point_leadlimit");
 316                 BADCVAR("g_keyhunt_point_leadlimit");
 317                 BADPREFIX("g_mod_");
 318                 BADCVAR("g_invasion_point_limit");
 319                 BADCVAR("g_nexball_goalleadlimit");
 320                 BADCVAR("g_tdm_point_limit");
 321                 BADCVAR("g_tdm_point_leadlimit");
 322                 BADCVAR("leadlimit_and_fraglimit");
 323                 BADCVAR("leadlimit_override");
 324                 BADCVAR("pausable");
 325                 BADCVAR("sv_allow_fullbright");
 326                 BADCVAR("sv_checkforpacketsduringsleep");
 327                 BADCVAR("sv_timeout");
 328                 BADPREFIX("sv_timeout_");
 329                 BADPREFIX("crypto_");
 330                 BADPREFIX("g_chat_");
 331                 BADPREFIX("g_ctf_captimerecord_");
 332                 BADPREFIX("g_maplist_votable_");
 333                 BADPREFIX("net_");
 334                 BADPREFIX("prvm_");
 335                 BADPREFIX("skill_");
 336                 BADPREFIX("sv_cullentities_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_minigames");
 343                 BADPREFIX("sv_minigames_");
 344                 BADCVAR("sv_namechangetimer");
 345
 346                 // allowed changes to server admins (please sync this to server.cfg)
 347                 // vi commands:
 348                 //   :/"impure"/,$d
 349                 //   :g!,^\/\/[^ /],d
 350                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 351                 //   :%!sort
 352                 // yes, this does contain some redundant stuff, don't really care
 353                 BADCVAR("bot_config_file");
 354                 BADCVAR("bot_number");
 355                 BADCVAR("bot_prefix");
 356                 BADCVAR("bot_suffix");
 357                 BADCVAR("capturelimit_override");
 358                 BADCVAR("fraglimit_override");
 359                 BADCVAR("gametype");
 360                 BADCVAR("g_antilag");
 361                 BADCVAR("g_balance_teams");
 362                 BADCVAR("g_balance_teams_prevent_imbalance");
 363                 BADCVAR("g_balance_teams_scorefactor");
 364                 BADCVAR("g_ban_sync_trusted_servers");
 365                 BADCVAR("g_ban_sync_uri");
 366                 BADCVAR("g_ca_teams_override");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_domination_teams_override");
 370                 BADCVAR("g_freezetag_teams_override");
 371                 BADCVAR("g_friendlyfire");
 372                 BADCVAR("g_fullbrightitems");
 373                 BADCVAR("g_fullbrightplayers");
 374                 BADCVAR("g_keyhunt_point_limit");
 375                 BADCVAR("g_keyhunt_teams_override");
 376                 BADCVAR("g_lms_lives_override");
 377                 BADCVAR("g_maplist");
 378                 BADCVAR("g_maplist_check_waypoints");
 379                 BADCVAR("g_maplist_mostrecent_count");
 380                 BADCVAR("g_maplist_shuffle");
 381                 BADCVAR("g_maplist_votable");
 382                 BADCVAR("g_maplist_votable_abstain");
 383                 BADCVAR("g_maplist_votable_nodetail");
 384                 BADCVAR("g_maplist_votable_suggestions");
 385                 BADCVAR("g_maxplayers");
 386                 BADCVAR("g_mirrordamage");
 387                 BADCVAR("g_nexball_goallimit");
 388                 BADCVAR("g_powerups");
 389                 BADCVAR("g_start_delay");
 390                 BADCVAR("g_tdm_teams_override");
 391                 BADCVAR("g_warmup");
 392                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 393                 BADCVAR("hostname");
 394                 BADCVAR("log_file");
 395                 BADCVAR("maxplayers");
 396                 BADCVAR("minplayers");
 397                 BADCVAR("net_address");
 398                 BADCVAR("port");
 399                 BADCVAR("rcon_password");
 400                 BADCVAR("rcon_restricted_commands");
 401                 BADCVAR("rcon_restricted_password");
 402                 BADCVAR("skill");
 403                 BADCVAR("sv_adminnick");
 404                 BADCVAR("sv_autoscreenshot");
 405                 BADCVAR("sv_autotaunt");
 406                 BADCVAR("sv_curl_defaulturl");
 407                 BADCVAR("sv_defaultcharacter");
 408                 BADCVAR("sv_defaultplayercolors");
 409                 BADCVAR("sv_defaultplayermodel");
 410                 BADCVAR("sv_defaultplayerskin");
 411                 BADCVAR("sv_maxidle");
 412                 BADCVAR("sv_maxrate");
 413                 BADCVAR("sv_motd");
 414                 BADCVAR("sv_public");
 415                 BADCVAR("sv_ready_restart");
 416                 BADCVAR("sv_status_privacy");
 417                 BADCVAR("sv_taunt");
 418                 BADCVAR("sv_vote_call");
 419                 BADCVAR("sv_vote_commands");
 420                 BADCVAR("sv_vote_majority_factor");
 421                 BADCVAR("sv_vote_master");
 422                 BADCVAR("sv_vote_master_commands");
 423                 BADCVAR("sv_vote_master_password");
 424                 BADCVAR("sv_vote_simple_majority_factor");
 425                 BADCVAR("teamplay_mode");
 426                 BADCVAR("timelimit_override");
 427                 BADCVAR("g_spawnshieldtime");
 428                 BADPREFIX("g_warmup_");
 429                 BADPREFIX("sv_ready_restart_");
 430
 431                 // mutators that announce themselves properly to the server browser
 432                 BADCVAR("g_instagib");
 433                 BADCVAR("g_new_toys");
 434                 BADCVAR("g_nix");
 435                 BADCVAR("g_grappling_hook");
 436                 BADCVAR("g_jetpack");
 437
 438 #undef BADPREFIX
 439 #undef BADCVAR
 440
 441                 if(pureadding)
 442                 {
 443                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 444                         if(strlen(cvar_purechanges) > 16384)
 445                         {
 446                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 447                                 pureadding = 0;
 448                         }
 449                 }
 450                 ++cvar_purechanges_count;
 451                 // WARNING: this variable is used for the server list
 452                 // NEVER dare to skip this code!
 453                 // Hacks to intentionally appearing as "pure server" even though you DO have
 454                 // modified settings may be punished by removal from the server list.
 455                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 456                 // though.
 457         }
 458         buf_del(h);
 459         if(cvar_changes == "")
 460                 cvar_changes = "// this server runs at default server settings\n";
 461         else
 462                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 463         cvar_changes = strzone(cvar_changes);
 464         if(cvar_purechanges == "")
 465                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 466         else
 467                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 468         cvar_purechanges = strzone(cvar_purechanges);
 469 }
 470
 471 void detect_maptype()
 472 {
 473 #if 0
 474         vector o, v;
 475         float i;
 476
 477         for (;;)
 478         {
 479                 o = world.mins;
 480                 o.x += random() * (world.maxs.x - world.mins.x);
 481                 o.y += random() * (world.maxs.y - world.mins.y);
 482                 o.z += random() * (world.maxs.z - world.mins.z);
 483
 484                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 485                 if(trace_fraction == 1)
 486                         continue;
 487
 488                 v = trace_endpos;
 489
 490                 for(i = 0; i < 64; i += 4)
 491                 {
 492                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 493         if(trace_fraction == 1)
 494                 continue;
 495                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 496                 }
 497
 498                 break;
 499         }
 500 #endif
 501 }
 502
 503 entity randomseed;
 504 bool RandomSeed_Send(entity this, entity to, int sf)
 505 {
 506         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 507         WriteShort(MSG_ENTITY, self.cnt);
 508         return true;
 509 }
 510 void RandomSeed_Think()
 511 {SELFPARAM();
 512         self.cnt = bound(0, floor(random() * 65536), 65535);
 513         self.nextthink = time + 5;
 514
 515         self.SendFlags |= 1;
 516 }
 517 void RandomSeed_Spawn()
 518 {SELFPARAM();
 519         randomseed = new(randomseed);
 520         make_pure(randomseed);
 521         randomseed.think = RandomSeed_Think;
 522         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 523
 524         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 525 }
 526
 527 spawnfunc(__init_dedicated_server)
 528 {
 529         // handler for _init/_init map (only for dedicated server initialization)
 530
 531         world_initialized = -1; // don't complain
 532         cvar = cvar_normal;
 533         cvar_string = cvar_string_normal;
 534         cvar_set = cvar_set_normal;
 535
 536         remove = remove_unsafely;
 537
 538         entity e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = new(info_player_deathmatch);  // safeguard against player joining
 543
 544         self.classname = "worldspawn"; // safeguard against various stuff ;)
 545
 546         // needs to be done so early because of the constants they create
 547         static_init();
 548         static_init_late();
 549         static_init_precache();
 550
 551         MapInfo_Enumerate();
 552         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 553 }
 554
 555 void Map_MarkAsRecent(string m);
 556 float world_already_spawned;
 557 void Nagger_Init();
 558 void ClientInit_Spawn();
 559 void WeaponStats_Init();
 560 void WeaponStats_Shutdown();
 561 void Physics_AddStats();
 562 spawnfunc(worldspawn)
 563 {
 564         float fd, l, j, n;
 565         string s;
 566
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         if(world_already_spawned)
 572                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 573         world_already_spawned = true;
 574
 575         remove = remove_safely; // during spawning, watch what you remove!
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 591
 592         // needs to be done so early because of the constants they create
 593         static_init();
 594
 595         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 596
 597         TemporaryDB = db_create();
 598
 599         // 0 normal
 600         lightstyle(0, "m");
 601
 602         // 1 FLICKER (first variety)
 603         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 604
 605         // 2 SLOW STRONG PULSE
 606         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 607
 608         // 3 CANDLE (first variety)
 609         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 610
 611         // 4 FAST STROBE
 612         lightstyle(4, "mamamamamama");
 613
 614         // 5 GENTLE PULSE 1
 615         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 616
 617         // 6 FLICKER (second variety)
 618         lightstyle(6, "nmonqnmomnmomomno");
 619
 620         // 7 CANDLE (second variety)
 621         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 622
 623         // 8 CANDLE (third variety)
 624         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 625
 626         // 9 SLOW STROBE (fourth variety)
 627         lightstyle(9, "aaaaaaaazzzzzzzz");
 628
 629         // 10 FLUORESCENT FLICKER
 630         lightstyle(10, "mmamammmmammamamaaamammma");
 631
 632         // 11 SLOW PULSE NOT FADE TO BLACK
 633         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 634
 635         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 636
 637         // 63 testing
 638         lightstyle(63, "a");
 639
 640         if(autocvar_g_campaign)
 641                 CampaignPreInit();
 642
 643         Map_MarkAsRecent(mapname);
 644
 645         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 646
 647         InitGameplayMode();
 648         static_init_late();
 649         static_init_precache();
 650         readlevelcvars();
 651         GrappleHookInit();
 652
 653         player_count = 0;
 654         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 655         if(bot_waypoints_for_items == 1)
 656                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 657                         bot_waypoints_for_items = 0;
 658
 659         precache();
 660
 661         WaypointSprite_Init();
 662
 663         GameLogInit(); // prepare everything
 664         // NOTE for matchid:
 665         // changing the logic generating it is okay. But:
 666         // it HAS to stay <= 64 chars
 667         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 668         if(autocvar_sv_eventlog)
 669         {
 670                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 671                 matchid = strzone(s);
 672
 673                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 674                 s = ":gameinfo:mutators:LIST";
 675
 676                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 677                 s = ret_string;
 678
 679                 // initialiation stuff, not good in the mutator system
 680                 if(!autocvar_g_use_ammunition)
 681                         s = strcat(s, ":no_use_ammunition");
 682
 683                 // initialiation stuff, not good in the mutator system
 684                 if(autocvar_g_pickup_items == 0)
 685                         s = strcat(s, ":no_pickup_items");
 686                 if(autocvar_g_pickup_items > 0)
 687                         s = strcat(s, ":pickup_items");
 688
 689                 // initialiation stuff, not good in the mutator system
 690                 if(autocvar_g_weaponarena != "0")
 691                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 692
 693                 // TODO to mutator system
 694                 if(autocvar_g_norecoil)
 695                         s = strcat(s, ":norecoil");
 696
 697                 // TODO to mutator system
 698                 if(autocvar_g_powerups == 0)
 699                         s = strcat(s, ":no_powerups");
 700                 if(autocvar_g_powerups > 0)
 701                         s = strcat(s, ":powerups");
 702
 703                 GameLogEcho(s);
 704                 GameLogEcho(":gameinfo:end");
 705         }
 706         else
 707                 matchid = strzone(ftos(random()));
 708
 709         cvar_set("nextmap", "");
 710
 711         SetDefaultAlpha();
 712
 713         if(autocvar_g_campaign)
 714                 CampaignPostInit();
 715
 716         Ban_LoadBans();
 717
 718         MapInfo_Enumerate();
 719         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 720
 721         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 722         {
 723                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 724                 if(fd != -1)
 725                 {
 726                         while((s = fgets(fd)))
 727                         {
 728                                 l = tokenize_console(s);
 729                                 if(l < 2)
 730                                         continue;
 731                                 if(argv(0) == "cd")
 732                                 {
 733                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 734                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 735                                 }
 736                                 else if(argv(0) == "fog")
 737                                 {
 738                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 739                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 740                                 }
 741                                 else if(argv(0) == "set")
 742                                 {
 743                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 744                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) != "//")
 747                                 {
 748                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 749                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 750                                 }
 751                         }
 752                         fclose(fd);
 753                 }
 754         }
 755
 756         WeaponStats_Init();
 757
 758         WepSet_AddStat();
 759         WepSet_AddStat_InMap();
 760         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 761         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 762         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 763         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 764         Nagger_Init();
 765
 766         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 767         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 768         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 769         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 770         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 771         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 772         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 773         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 774         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 775         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 776         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 777         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 778         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 779         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 780         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 781
 782         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 783         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 784
 785         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 786
 787         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 788
 789         // freeze attacks
 790         addstat(STAT_FROZEN, AS_INT, frozen);
 791         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 792
 793         // physics
 794         Physics_AddStats();
 795
 796         // new properties
 797         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 798         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 799         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 800         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 801         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 802         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 803         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 804         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 805         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 806         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 807         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 808         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 809         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 810         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 811         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 812         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 813         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 814         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 815         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 816
 817         // secrets
 818         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 819         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 820
 821         // monsters
 822         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 823         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 824
 825         // misc
 826         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 827
 828         next_pingtime = time + 5;
 829
 830         detect_maptype();
 831
 832         // set up information replies for clients and server to use
 833         maplist_reply = strzone(getmaplist());
 834         lsmaps_reply = strzone(getlsmaps());
 835         monsterlist_reply = strzone(getmonsterlist());
 836         for(int i = 0; i < 10; ++i)
 837         {
 838                 s = getrecords(i);
 839                 if (s)
 840                         records_reply[i] = strzone(s);
 841         }
 842         ladder_reply = strzone(getladder());
 843         rankings_reply = strzone(getrankings());
 844
 845         // begin other init
 846         ClientInit_Spawn();
 847         RandomSeed_Spawn();
 848         PingPLReport_Spawn();
 849
 850         CheatInit();
 851
 852         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 853
 854         // fill sv_curl_serverpackages from .serverpackage files
 855         if(autocvar_sv_curl_serverpackages_auto)
 856         {
 857                 s = "";
 858                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 859                 for(int i = 0; i < n; ++i)
 860                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 861                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 862                                 s = strcat(s, " ", argv(i));
 863                 fd = search_begin("*-serverpackage.txt", true, false);
 864                 if(fd >= 0)
 865                 {
 866                         j = search_getsize(fd);
 867                         for(int i = 0; i < j; ++i)
 868                                 s = strcat(s, " ", search_getfilename(fd, i));
 869                         search_end(fd);
 870                 }
 871                 fd = search_begin("*.serverpackage", true, false);
 872                 if(fd >= 0)
 873                 {
 874                         j = search_getsize(fd);
 875                         for(int i = 0; i < j; ++i)
 876                                 s = strcat(s, " ", search_getfilename(fd, i));
 877                         search_end(fd);
 878                 }
 879                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 880         }
 881
 882         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 883         modname = "Xonotic";
 884         // physics/balance/config changes that count as mod
 885         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 886                 modname = cvar_string("g_mod_physics");
 887         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 888                 modname = cvar_string("g_mod_balance");
 889         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 890                 modname = cvar_string("g_mod_config");
 891         // extra mutators that deserve to count as mod
 892         MUTATOR_CALLHOOK(SetModname);
 893
 894         // save it for later
 895         modname = strzone(modname);
 896
 897         WinningConditionHelper(); // set worldstatus
 898
 899         world_initialized = 1;
 900 }
 901
 902 spawnfunc(light)
 903 {
 904         //makestatic (self); // Who the f___ did that?
 905         remove(self);
 906 }
 907
 908 string GetGametype()
 909 {
 910         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 911 }
 912
 913 string GetMapname()
 914 {
 915         return mapname;
 916 }
 917
 918 float Map_Count, Map_Current;
 919 string Map_Current_Name;
 920
 921 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 922 float GetMaplistPosition()
 923 {
 924         float pos, idx;
 925         string map;
 926
 927         map = GetMapname();
 928         idx = autocvar_g_maplist_index;
 929
 930         if(idx >= 0)
 931                 if(idx < Map_Count)
 932                         if(map == argv(idx))
 933                                 return idx;
 934
 935         for(pos = 0; pos < Map_Count; ++pos)
 936                 if(map == argv(pos))
 937                         return pos;
 938
 939         // resume normal maplist rotation if current map is not in g_maplist
 940         return idx;
 941 }
 942
 943 float MapHasRightSize(string map)
 944 {
 945         float fh;
 946         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 947         if(autocvar_g_maplist_check_waypoints)
 948         {
 949                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 950                 if(!fexists(strcat("maps/", map, ".waypoints")))
 951                 {
 952                         LOG_TRACE(": no waypoints\n");
 953                         return false;
 954                 }
 955                 LOG_TRACE(": has waypoints\n");
 956         }
 957
 958         // open map size restriction file
 959         LOG_TRACE("opensize "); LOG_TRACE(map);
 960         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 961         if(fh >= 0)
 962         {
 963                 float mapmin, mapmax;
 964                 LOG_TRACE(": ok, ");
 965                 mapmin = stof(fgets(fh));
 966                 mapmax = stof(fgets(fh));
 967                 fclose(fh);
 968                 if(player_count < mapmin)
 969                 {
 970                         LOG_TRACE("not enough\n");
 971                         return false;
 972                 }
 973                 if(player_count > mapmax)
 974                 {
 975                         LOG_TRACE("too many\n");
 976                         return false;
 977                 }
 978                 LOG_TRACE("right size\n");
 979                 return true;
 980         }
 981         LOG_TRACE(": not found\n");
 982         return true;
 983 }
 984
 985 string Map_Filename(float position)
 986 {
 987         return strcat("maps/", argv(position), ".bsp");
 988 }
 989
 990 void Map_MarkAsRecent(string m)
 991 {
 992         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 993 }
 994
 995 float Map_IsRecent(string m)
 996 {
 997         return strhasword(autocvar_g_maplist_mostrecent, m);
 998 }
 999
1000 float Map_Check(float position, float pass)
1001 {
1002         string filename;
1003         string map_next;
1004         map_next = argv(position);
1005         if(pass <= 1)
1006         {
1007                 if(Map_IsRecent(map_next))
1008                         return 0;
1009         }
1010         filename = Map_Filename(position);
1011         if(MapInfo_CheckMap(map_next))
1012         {
1013                 if(pass == 2)
1014                         return 1;
1015                 if(MapHasRightSize(map_next))
1016                         return 1;
1017                 return 0;
1018         }
1019         else
1020                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1021
1022         return 0;
1023 }
1024
1025 void Map_Goto_SetStr(string nextmapname)
1026 {
1027         if(getmapname_stored != "")
1028                 strunzone(getmapname_stored);
1029         if(nextmapname == "")
1030                 getmapname_stored = "";
1031         else
1032                 getmapname_stored = strzone(nextmapname);
1033 }
1034
1035 void Map_Goto_SetFloat(float position)
1036 {
1037         cvar_set("g_maplist_index", ftos(position));
1038         Map_Goto_SetStr(argv(position));
1039 }
1040
1041 void Map_Goto(float reinit)
1042 {
1043         MapInfo_LoadMap(getmapname_stored, reinit);
1044 }
1045
1046 // return codes of map selectors:
1047 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1048 //   -2 = permanent failure
1049 float() MaplistMethod_Iterate = // usual method
1050 {
1051         float pass, i;
1052
1053         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1054
1055         for(pass = 1; pass <= 2; ++pass)
1056         {
1057                 for(i = 1; i < Map_Count; ++i)
1058                 {
1059                         float mapindex;
1060                         mapindex = (i + Map_Current) % Map_Count;
1061                         if(Map_Check(mapindex, pass))
1062                                 return mapindex;
1063                 }
1064         }
1065         return -1;
1066 }
1067
1068 float() MaplistMethod_Repeat = // fallback method
1069 {
1070         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1071
1072         if(Map_Check(Map_Current, 2))
1073                 return Map_Current;
1074         return -2;
1075 }
1076
1077 float() MaplistMethod_Random = // random map selection
1078 {
1079         float i, imax;
1080
1081         LOG_TRACE("Trying MaplistMethod_Random\n");
1082
1083         imax = 42;
1084
1085         for(i = 0; i <= imax; ++i)
1086         {
1087                 float mapindex;
1088                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1089                 if(Map_Check(mapindex, 1))
1090                         return mapindex;
1091         }
1092         return -1;
1093 }
1094
1095 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1096 // the exponent sets a bias on the map selection:
1097 // the higher the exponent, the less likely "shortly repeated" same maps are
1098 {
1099         float i, j, imax, insertpos;
1100
1101         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1102
1103         imax = 42;
1104
1105         for(i = 0; i <= imax; ++i)
1106         {
1107                 string newlist;
1108
1109                 // now reinsert this at another position
1110                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1111                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1112                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1113                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1114
1115                 // insert the current map there
1116                 newlist = "";
1117                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1118                         newlist = strcat(newlist, " ", argv(j));
1119                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1120                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1121                         newlist = strcat(newlist, " ", argv(j));
1122                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1123                 cvar_set("g_maplist", newlist);
1124                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1125
1126                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1127                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1128                 if(Map_Check(Map_Current, 1))
1129                         return Map_Current;
1130         }
1131         return -1;
1132 }
1133
1134 void Maplist_Init()
1135 {
1136         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1137         float i;
1138         for (i = 0; i < Map_Count; ++i)
1139                 if (Map_Check(i, 2))
1140                         break;
1141         if (i == Map_Count)
1142         {
1143                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1144                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1145                 if(autocvar_g_maplist_shuffle)
1146                         ShuffleMaplist();
1147                 localcmd("\nmenu_cmd sync\n");
1148                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1149         }
1150         if(Map_Count == 0)
1151                 error("empty maplist, cannot select a new map");
1152         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1153
1154         if(Map_Current_Name)
1155                 strunzone(Map_Current_Name);
1156         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1157         // this may or may not be correct, but who cares, in the worst case a map
1158         // isn't chosen in the first pass that should have been
1159 }
1160
1161 string GetNextMap()
1162 {
1163         float nextMap;
1164
1165         Maplist_Init();
1166         nextMap = -1;
1167
1168         if(nextMap == -1)
1169                 if(autocvar_g_maplist_shuffle > 0)
1170                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1171
1172         if(nextMap == -1)
1173                 if(autocvar_g_maplist_selectrandom)
1174                         nextMap = MaplistMethod_Random();
1175
1176         if(nextMap == -1)
1177                 nextMap = MaplistMethod_Iterate();
1178
1179         if(nextMap == -1)
1180                 nextMap = MaplistMethod_Repeat();
1181
1182         if(nextMap >= 0)
1183         {
1184                 Map_Goto_SetFloat(nextMap);
1185                 return getmapname_stored;
1186         }
1187
1188         return "";
1189 }
1190
1191 float DoNextMapOverride(float reinit)
1192 {
1193         if(autocvar_g_campaign)
1194         {
1195                 CampaignPostIntermission();
1196                 alreadychangedlevel = true;
1197                 return true;
1198         }
1199         if(autocvar_quit_when_empty)
1200         {
1201                 if(player_count <= currentbots)
1202                 {
1203                         localcmd("quit\n");
1204                         alreadychangedlevel = true;
1205                         return true;
1206                 }
1207         }
1208         if(autocvar_quit_and_redirect != "")
1209         {
1210                 redirection_target = strzone(autocvar_quit_and_redirect);
1211                 alreadychangedlevel = true;
1212                 return true;
1213         }
1214         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1215         {
1216                 localcmd("restart\n");
1217                 alreadychangedlevel = true;
1218                 return true;
1219         }
1220         if(autocvar_nextmap != "")
1221         {
1222                 string m;
1223                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1224                 cvar_set("nextmap",m);
1225
1226                 if(!m || gametypevote)
1227                         return false;
1228                 if(autocvar_sv_vote_gametype)
1229                 {
1230                         Map_Goto_SetStr(m);
1231                         return false;
1232                 }
1233
1234                 if(MapInfo_CheckMap(m))
1235                 {
1236                         Map_Goto_SetStr(m);
1237                         Map_Goto(reinit);
1238                         alreadychangedlevel = true;
1239                         return true;
1240                 }
1241         }
1242         if(!reinit && autocvar_lastlevel)
1243         {
1244                 cvar_settemp_restore();
1245                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1246                 alreadychangedlevel = true;
1247                 return true;
1248         }
1249         return false;
1250 }
1251
1252 void GotoNextMap(float reinit)
1253 {
1254         //string nextmap;
1255         //float n, nummaps;
1256         //string s;
1257         if (alreadychangedlevel)
1258                 return;
1259         alreadychangedlevel = true;
1260
1261         string nextMap;
1262
1263         nextMap = GetNextMap();
1264         if(nextMap == "")
1265                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1266         Map_Goto(reinit);
1267 }
1268
1269
1270 /*
1271 ============
1272 IntermissionThink
1273
1274 When the player presses attack or jump, change to the next level
1275 ============
1276 */
1277 .float autoscreenshot;
1278 void IntermissionThink()
1279 {SELFPARAM();
1280         FixIntermissionClient(self);
1281
1282         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1283         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1284
1285         if( (server_screenshot || client_screenshot)
1286                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1287         {
1288                 self.autoscreenshot = -1;
1289                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1290                 return;
1291         }
1292
1293         if (time < intermission_exittime)
1294                 return;
1295
1296         if(!mapvote_initialized)
1297                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1298                         return;
1299
1300         MapVote_Start();
1301 }
1302
1303 /*
1304 ============
1305 FindIntermission
1306
1307 Returns the entity to view from
1308 ============
1309 */
1310 /*
1311 entity FindIntermission()
1312 {
1313         local   entity spot;
1314         local   float cyc;
1315
1316 // look for info_intermission first
1317         spot = find (world, classname, "info_intermission");
1318         if (spot)
1319         {       // pick a random one
1320                 cyc = random() * 4;
1321                 while (cyc > 1)
1322                 {
1323                         spot = find (spot, classname, "info_intermission");
1324                         if (!spot)
1325                                 spot = find (spot, classname, "info_intermission");
1326                         cyc = cyc - 1;
1327                 }
1328                 return spot;
1329         }
1330
1331 // then look for the start position
1332         spot = find (world, classname, "info_player_start");
1333         if (spot)
1334                 return spot;
1335
1336 // testinfo_player_start is only found in regioned levels
1337         spot = find (world, classname, "testplayerstart");
1338         if (spot)
1339                 return spot;
1340
1341 // then look for the start position
1342         spot = find (world, classname, "info_player_deathmatch");
1343         if (spot)
1344                 return spot;
1345
1346         //objerror ("FindIntermission: no spot");
1347         return world;
1348 }
1349 */
1350
1351 /*
1352 ===============================================================================
1353
1354 RULES
1355
1356 ===============================================================================
1357 */
1358
1359 void DumpStats(float final)
1360 {
1361         float file;
1362         string s;
1363         float to_console;
1364         float to_eventlog;
1365         float to_file;
1366         float i;
1367
1368         to_console = autocvar_sv_logscores_console;
1369         to_eventlog = autocvar_sv_eventlog;
1370         to_file = autocvar_sv_logscores_file;
1371
1372         if(!final)
1373         {
1374                 to_console = true; // always print printstats replies
1375                 to_eventlog = false; // but never print them to the event log
1376         }
1377
1378         if(to_eventlog)
1379                 if(autocvar_sv_eventlog_console)
1380                         to_console = false; // otherwise we get the output twice
1381
1382         if(final)
1383                 s = ":scores:";
1384         else
1385                 s = ":status:";
1386         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1387
1388         if(to_console)
1389                 LOG_INFO(s, "\n");
1390         if(to_eventlog)
1391                 GameLogEcho(s);
1392
1393         file = -1;
1394         if(to_file)
1395         {
1396                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1397                 if(file == -1)
1398                         to_file = false;
1399                 else
1400                         fputs(file, strcat(s, "\n"));
1401         }
1402
1403         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1404         if(to_console)
1405                 LOG_INFO(s, "\n");
1406         if(to_eventlog)
1407                 GameLogEcho(s);
1408         if(to_file)
1409                 fputs(file, strcat(s, "\n"));
1410
1411         FOR_EACH_CLIENT(other)
1412         {
1413                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1414                 {
1415                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1416                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1417                         if(IS_PLAYER(other) || MUTATOR_CALLHOOK(GetPlayerStatus, other, s))
1418                                 s = strcat(s, ftos(other.team), ":");
1419                         else
1420                                 s = strcat(s, "spectator:");
1421
1422                         if(to_console)
1423                                 LOG_INFO(s, other.netname, "\n");
1424                         if(to_eventlog)
1425                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1426                         if(to_file)
1427                                 fputs(file, strcat(s, other.netname, "\n"));
1428                 }
1429         }
1430
1431         if(teamplay)
1432         {
1433                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1434                 if(to_console)
1435                         LOG_INFO(s, "\n");
1436                 if(to_eventlog)
1437                         GameLogEcho(s);
1438                 if(to_file)
1439                         fputs(file, strcat(s, "\n"));
1440
1441                 for(i = 1; i < 16; ++i)
1442                 {
1443                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1444                         s = strcat(s, ":", ftos(i));
1445                         if(to_console)
1446                                 LOG_INFO(s, "\n");
1447                         if(to_eventlog)
1448                                 GameLogEcho(s);
1449                         if(to_file)
1450                                 fputs(file, strcat(s, "\n"));
1451                 }
1452         }
1453
1454         if(to_console)
1455                 LOG_INFO(":end\n");
1456         if(to_eventlog)
1457                 GameLogEcho(":end");
1458         if(to_file)
1459         {
1460                 fputs(file, ":end\n");
1461                 fclose(file);
1462         }
1463 }
1464
1465 void FixIntermissionClient(entity e)
1466 {
1467         string s;
1468         if(!e.autoscreenshot) // initial call
1469         {
1470                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1471                 e.health = -2342;
1472                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1473                 e.solid = SOLID_NOT;
1474                 e.movetype = MOVETYPE_NONE;
1475                 e.takedamage = DAMAGE_NO;
1476                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1477                 {
1478                     .entity weaponentity = weaponentities[slot];
1479                         if(e.(weaponentity))
1480                         {
1481                                 e.(weaponentity).effects = EF_NODRAW;
1482                                 if (e.(weaponentity).(weaponentity))
1483                                         e.(weaponentity).(weaponentity).effects = EF_NODRAW;
1484                         }
1485                 }
1486                 if(IS_REAL_CLIENT(e))
1487                 {
1488                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1489                         s = autocvar_sv_intermission_cdtrack;
1490                         if(s != "")
1491                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1492                         msg_entity = e;
1493                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1494                 }
1495         }
1496 }
1497
1498 /*
1499 go to the next level for deathmatch
1500 only called if a time or frag limit has expired
1501 */
1502 void NextLevel()
1503 {
1504         gameover = true;
1505
1506         intermission_running = 1;
1507
1508 // enforce a wait time before allowing changelevel
1509         if(player_count > 0)
1510                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1511         else
1512                 intermission_exittime = -1;
1513
1514         /*
1515         WriteByte (MSG_ALL, SVC_CDTRACK);
1516         WriteByte (MSG_ALL, 3);
1517         WriteByte (MSG_ALL, 3);
1518         // done in FixIntermission
1519         */
1520
1521         //pos = FindIntermission ();
1522
1523         VoteReset();
1524
1525         DumpStats(true);
1526
1527         // send statistics
1528         PlayerStats_GameReport(true);
1529         WeaponStats_Shutdown();
1530
1531         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1532
1533         if(autocvar_sv_eventlog)
1534                 GameLogEcho(":gameover");
1535
1536         GameLogClose();
1537
1538         FOR_EACH_PLAYER(other) {
1539                 FixIntermissionClient(other);
1540                 if(other.winning)
1541                         bprint(other.netname, " ^7wins.\n");
1542         }
1543
1544         entity oldself = self;
1545         target_music_kill();
1546         self = oldself;
1547
1548         if(autocvar_g_campaign)
1549                 CampaignPreIntermission();
1550
1551         MUTATOR_CALLHOOK(MatchEnd);
1552
1553         localcmd("\nsv_hook_gameend\n");
1554 }
1555
1556 /*
1557 ============
1558 CheckRules_Player
1559
1560 Exit deathmatch games upon conditions
1561 ============
1562 */
1563 void CheckRules_Player()
1564 {SELFPARAM();
1565         if (gameover)   // someone else quit the game already
1566                 return;
1567
1568         if(self.deadflag == DEAD_NO)
1569                 self.play_time += frametime;
1570
1571         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1572         //   (div0: and that in CheckRules_World please)
1573 }
1574
1575
1576 float InitiateSuddenDeath()
1577 {
1578         // Check first whether normal overtimes could be added before initiating suddendeath mode
1579         // - for this timelimit_overtime needs to be >0 of course
1580         // - also check the winning condition calculated in the previous frame and only add normal overtime
1581         //   again, if at the point at which timelimit would be extended again, still no winner was found
1582         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1583         {
1584                 return 1; // need to call InitiateOvertime later
1585         }
1586         else
1587         {
1588                 if(!checkrules_suddendeathend)
1589                 {
1590                         if(autocvar_g_campaign)
1591                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1592                         else
1593                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1594                         if(g_race && !g_race_qualifying)
1595                                 race_StartCompleting();
1596                 }
1597                 return 0;
1598         }
1599 }
1600
1601 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1602 {
1603         ++checkrules_overtimesadded;
1604         //add one more overtime by simply extending the timelimit
1605         float tl;
1606         tl = autocvar_timelimit;
1607         tl += autocvar_timelimit_overtime;
1608         cvar_set("timelimit", ftos(tl));
1609
1610         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1611 }
1612
1613 float GetWinningCode(float fraglimitreached, float equality)
1614 {
1615         if(autocvar_g_campaign == 1)
1616                 if(fraglimitreached)
1617                         return WINNING_YES;
1618                 else
1619                         return WINNING_NO;
1620
1621         else
1622                 if(equality)
1623                         if(fraglimitreached)
1624                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1625                         else
1626                                 return WINNING_NEVER;
1627                 else
1628                         if(fraglimitreached)
1629                                 return WINNING_YES;
1630                         else
1631                                 return WINNING_NO;
1632 }
1633
1634 // set the .winning flag for exactly those players with a given field value
1635 void SetWinners(.float field, float value)
1636 {
1637         entity head;
1638         FOR_EACH_PLAYER(head)
1639                 head.winning = (head.(field) == value);
1640 }
1641
1642 // set the .winning flag for those players with a given field value
1643 void AddWinners(.float field, float value)
1644 {
1645         entity head;
1646         FOR_EACH_PLAYER(head)
1647                 if (head.(field) == value)
1648                         head.winning = 1;
1649 }
1650
1651 // clear the .winning flags
1652 void ClearWinners()
1653 {
1654         entity head;
1655         FOR_EACH_PLAYER(head)
1656                 head.winning = 0;
1657 }
1658
1659 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1660 // they win. Otherwise the defending team wins once the timelimit passes.
1661 void assault_new_round();
1662 float WinningCondition_Assault()
1663 {SELFPARAM();
1664         float status;
1665
1666         WinningConditionHelper(); // set worldstatus
1667
1668         status = WINNING_NO;
1669         // as the timelimit has not yet passed just assume the defending team will win
1670         if(assault_attacker_team == NUM_TEAM_1)
1671         {
1672                 SetWinners(team, NUM_TEAM_2);
1673         }
1674         else
1675         {
1676                 SetWinners(team, NUM_TEAM_1);
1677         }
1678
1679         entity ent;
1680         ent = find(world, classname, "target_assault_roundend");
1681         if(ent)
1682         {
1683                 if(ent.winning) // round end has been triggered by attacking team
1684                 {
1685                         bprint("ASSAULT: round completed...\n");
1686                         SetWinners(team, assault_attacker_team);
1687
1688                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1689
1690                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1691                         {
1692                                 status = WINNING_YES;
1693                         }
1694                         else
1695                         {
1696                                 WITH(entity, self, ent, assault_new_round());
1697                         }
1698                 }
1699         }
1700
1701         return status;
1702 }
1703
1704 void ShuffleMaplist()
1705 {
1706         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1707 }
1708
1709 float leaderfrags;
1710 float WinningCondition_Scores(float limit, float leadlimit)
1711 {
1712         float limitreached;
1713
1714         // TODO make everything use THIS winning condition (except LMS)
1715         WinningConditionHelper();
1716
1717         if(teamplay)
1718         {
1719                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1720                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1721                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1722                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1723         }
1724
1725         ClearWinners();
1726         if(WinningConditionHelper_winner)
1727                 WinningConditionHelper_winner.winning = 1;
1728         if(WinningConditionHelper_winnerteam >= 0)
1729                 SetWinners(team, WinningConditionHelper_winnerteam);
1730
1731         if(WinningConditionHelper_lowerisbetter)
1732         {
1733                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1734                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1735                 limit = -limit;
1736         }
1737
1738         if(WinningConditionHelper_zeroisworst)
1739                 leadlimit = 0; // not supported in this mode
1740
1741         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1742         // these modes always score in increments of 1, thus this makes sense
1743         {
1744                 if(leaderfrags != WinningConditionHelper_topscore)
1745                 {
1746                         leaderfrags = WinningConditionHelper_topscore;
1747
1748                         if (limit)
1749                         if (leaderfrags == limit - 1)
1750                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1751                         else if (leaderfrags == limit - 2)
1752                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1753                         else if (leaderfrags == limit - 3)
1754                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1755                 }
1756         }
1757
1758         limitreached = false;
1759         if(limit)
1760                 if(WinningConditionHelper_topscore >= limit)
1761                         limitreached = true;
1762         if(leadlimit)
1763         {
1764                 float leadlimitreached;
1765                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1766                 if(autocvar_leadlimit_and_fraglimit)
1767                         limitreached = (limitreached && leadlimitreached);
1768                 else
1769                         limitreached = (limitreached || leadlimitreached);
1770         }
1771
1772         if(limit)
1773                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1774
1775         return GetWinningCode(
1776                 WinningConditionHelper_topscore && limitreached,
1777                 WinningConditionHelper_equality
1778         );
1779 }
1780
1781 float WinningCondition_Race(float fraglimit)
1782 {
1783         float wc;
1784         entity p;
1785         float n, c;
1786
1787         n = 0;
1788         c = 0;
1789         FOR_EACH_PLAYER(p)
1790         {
1791                 ++n;
1792                 if(p.race_completed)
1793                         ++c;
1794         }
1795         if(n && (n == c))
1796                 return WINNING_YES;
1797         wc = WinningCondition_Scores(fraglimit, 0);
1798
1799         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1800         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1801         // do NOT support equality when the laps are all raced!
1802                 return WINNING_STARTSUDDENDEATHOVERTIME;
1803         else
1804                 return WINNING_NEVER;
1805 }
1806
1807 float WinningCondition_QualifyingThenRace(float limit)
1808 {
1809         float wc;
1810         wc = WinningCondition_Scores(limit, 0);
1811
1812         // NEVER initiate overtime
1813         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1814         {
1815                 return WINNING_YES;
1816         }
1817
1818         return wc;
1819 }
1820
1821 float WinningCondition_RanOutOfSpawns()
1822 {
1823         entity head;
1824
1825         if(have_team_spawns <= 0)
1826                 return WINNING_NO;
1827
1828         if(!autocvar_g_spawn_useallspawns)
1829                 return WINNING_NO;
1830
1831         if(!some_spawn_has_been_used)
1832                 return WINNING_NO;
1833
1834         team1_score = team2_score = team3_score = team4_score = 0;
1835
1836         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1837         {
1838                 if(head.team == NUM_TEAM_1)
1839                         team1_score = 1;
1840                 else if(head.team == NUM_TEAM_2)
1841                         team2_score = 1;
1842                 else if(head.team == NUM_TEAM_3)
1843                         team3_score = 1;
1844                 else if(head.team == NUM_TEAM_4)
1845                         team4_score = 1;
1846         }
1847
1848         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1849         {
1850                 if(head.team == NUM_TEAM_1)
1851                         team1_score = 1;
1852                 else if(head.team == NUM_TEAM_2)
1853                         team2_score = 1;
1854                 else if(head.team == NUM_TEAM_3)
1855                         team3_score = 1;
1856                 else if(head.team == NUM_TEAM_4)
1857                         team4_score = 1;
1858         }
1859
1860         ClearWinners();
1861         if(team1_score + team2_score + team3_score + team4_score == 0)
1862         {
1863                 checkrules_equality = true;
1864                 return WINNING_YES;
1865         }
1866         else if(team1_score + team2_score + team3_score + team4_score == 1)
1867         {
1868                 float t, i;
1869                 if(team1_score)
1870                         t = NUM_TEAM_1;
1871                 else if(team2_score)
1872                         t = NUM_TEAM_2;
1873                 else if(team3_score)
1874                         t = NUM_TEAM_3;
1875                 else // if(team4_score)
1876                         t = NUM_TEAM_4;
1877                 CheckAllowedTeams(world);
1878                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1879                 {
1880                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1881                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1882                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1883                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1884                 }
1885
1886                 AddWinners(team, t);
1887                 return WINNING_YES;
1888         }
1889         else
1890                 return WINNING_NO;
1891 }
1892
1893 /*
1894 ============
1895 CheckRules_World
1896
1897 Exit deathmatch games upon conditions
1898 ============
1899 */
1900 void CheckRules_World()
1901 {
1902         float timelimit;
1903         float fraglimit;
1904         float leadlimit;
1905
1906         VoteThink();
1907         MapVote_Think();
1908
1909         SetDefaultAlpha();
1910
1911         if (gameover)   // someone else quit the game already
1912         {
1913                 if(player_count == 0) // Nobody there? Then let's go to the next map
1914                         MapVote_Start();
1915                         // this will actually check the player count in the next frame
1916                         // again, but this shouldn't hurt
1917                 return;
1918         }
1919
1920         timelimit = autocvar_timelimit * 60;
1921         fraglimit = autocvar_fraglimit;
1922         leadlimit = autocvar_leadlimit;
1923
1924         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1925         {
1926                 if(timelimit > 0)
1927                         timelimit = 0; // timelimit is not made for warmup
1928                 if(fraglimit > 0)
1929                         fraglimit = 0; // no fraglimit for now
1930                 leadlimit = 0; // no leadlimit for now
1931         }
1932
1933         if(timelimit > 0)
1934         {
1935                 timelimit += game_starttime;
1936         }
1937         else if (timelimit < 0)
1938         {
1939                 // endmatch
1940                 NextLevel();
1941                 return;
1942         }
1943
1944         float wantovertime;
1945         wantovertime = 0;
1946
1947         if(timelimit > game_starttime)
1948                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1949         else
1950                 game_completion_ratio = 0;
1951
1952         if(checkrules_suddendeathend)
1953         {
1954                 if(!checkrules_suddendeathwarning)
1955                 {
1956                         checkrules_suddendeathwarning = true;
1957                         if(g_race && !g_race_qualifying)
1958                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1959                         else
1960                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1961                 }
1962         }
1963         else
1964         {
1965                 if (timelimit && time >= timelimit)
1966                 {
1967                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1968                         {
1969                                 float totalplayers;
1970                                 float playerswithlaps;
1971                                 float readyplayers;
1972                                 entity head;
1973                                 totalplayers = playerswithlaps = readyplayers = 0;
1974                                 FOR_EACH_PLAYER(head)
1975                                 {
1976                                         ++totalplayers;
1977                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1978                                                 ++playerswithlaps;
1979                                         if(head.ready)
1980                                                 ++readyplayers;
1981                                 }
1982
1983                                 // at least 2 of the players have completed a lap: start the RACE
1984                                 // otherwise, the players should end the qualifying on their own
1985                                 if(readyplayers || playerswithlaps >= 2)
1986                                 {
1987                                         checkrules_suddendeathend = 0;
1988                                         ReadyRestart(); // go to race
1989                                         return;
1990                                 }
1991                                 else
1992                                         wantovertime |= InitiateSuddenDeath();
1993                         }
1994                         else
1995                                 wantovertime |= InitiateSuddenDeath();
1996                 }
1997         }
1998
1999         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2000         {
2001                 NextLevel();
2002                 return;
2003         }
2004
2005         int checkrules_status = WinningCondition_RanOutOfSpawns();
2006         if(checkrules_status == WINNING_YES)
2007                 bprint("Hey! Someone ran out of spawns!\n");
2008         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
2009                 checkrules_status = ret_float;
2010         else
2011                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2012
2013         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2014         {
2015                 checkrules_status = WINNING_NEVER;
2016                 checkrules_overtimesadded = -1;
2017                 wantovertime |= InitiateSuddenDeath();
2018         }
2019
2020         if(checkrules_status == WINNING_NEVER)
2021                 // equality cases! Nobody wins if the overtime ends in a draw.
2022                 ClearWinners();
2023
2024         if(wantovertime)
2025         {
2026                 if(checkrules_status == WINNING_NEVER)
2027                         InitiateOvertime();
2028                 else
2029                         checkrules_status = WINNING_YES;
2030         }
2031
2032         if(checkrules_suddendeathend)
2033                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2034                         checkrules_status = WINNING_YES;
2035
2036         if(checkrules_status == WINNING_YES)
2037         {
2038                 //print("WINNING\n");
2039                 NextLevel();
2040         }
2041 }
2042
2043 string GotoMap(string m)
2044 {
2045         m = GameTypeVote_MapInfo_FixName(m);
2046         if (!m)
2047                 return "The map you suggested is not available on this server.";
2048         if (!autocvar_sv_vote_gametype)
2049         if(!MapInfo_CheckMap(m))
2050                 return "The map you suggested does not support the current game mode.";
2051         cvar_set("nextmap", m);
2052         cvar_set("timelimit", "-1");
2053         if(mapvote_initialized || alreadychangedlevel)
2054         {
2055                 if(DoNextMapOverride(0))
2056                         return "Map switch initiated.";
2057                 else
2058                         return "Hm... no. For some reason I like THIS map more.";
2059         }
2060         else
2061                 return "Map switch will happen after scoreboard.";
2062 }
2063
2064
2065 void EndFrame()
2066 {SELFPARAM();
2067         anticheat_endframe();
2068
2069         float altime;
2070         entity e_;
2071         FOR_EACH_REALCLIENT(e_)
2072         {
2073                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2074                 if(e.typehitsound)
2075                         e_.typehit_time = time;
2076                 else if(e.damage_dealt)
2077                 {
2078                         e_.hit_time = time;
2079                         e_.damage_dealt_total += ceil(e.damage_dealt);
2080                 }
2081         }
2082         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2083         // add 1 frametime because after this, engine SV_Physics
2084         // increases time by a frametime and then networks the frame
2085         // add another frametime because client shows everything with
2086         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2087         // needed!
2088         FOR_EACH_CLIENT(e_)
2089         {
2090                 e_.typehitsound = false;
2091                 e_.damage_dealt = 0;
2092                 setself(e_);
2093                 antilag_record(e_, altime);
2094         }
2095         FOR_EACH_MONSTER(e_)
2096         {
2097                 setself(e_);
2098                 antilag_record(e_, altime);
2099         }
2100 }
2101
2102
2103 /*
2104  * RedirectionThink:
2105  * returns true if redirecting
2106  */
2107 float redirection_timeout;
2108 float redirection_nextthink;
2109 float RedirectionThink()
2110 {SELFPARAM();
2111         float clients_found;
2112
2113         if(redirection_target == "")
2114                 return false;
2115
2116         if(!redirection_timeout)
2117         {
2118                 cvar_set("sv_public", "-2");
2119                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2120                 if(redirection_target == "self")
2121                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2122                 else
2123                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2124         }
2125
2126         if(time < redirection_nextthink)
2127                 return true;
2128
2129         redirection_nextthink = time + 1;
2130
2131         clients_found = 0;
2132         entity e;
2133         FOR_EACH_REALCLIENT(e)
2134         {
2135                 setself(e);
2136                 // TODO add timer
2137                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2138                 if(redirection_target == "self")
2139                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2140                 else
2141                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2142                 ++clients_found;
2143         }
2144
2145         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2146
2147         if(time > redirection_timeout || clients_found == 0)
2148                 localcmd("\nwait; wait; wait; quit\n");
2149
2150         return true;
2151 }
2152
2153 void TargetMusic_RestoreGame();
2154 void RestoreGame()
2155 {
2156         // Loaded from a save game
2157         // some things then break, so let's work around them...
2158
2159         // Progs DB (capture records)
2160         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2161
2162         // Mapinfo
2163         MapInfo_Shutdown();
2164         MapInfo_Enumerate();
2165         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2166         WeaponStats_Init();
2167
2168         TargetMusic_RestoreGame();
2169 }
2170
2171 void Shutdown()
2172 {
2173         gameover = 2;
2174
2175         if(world_initialized > 0)
2176         {
2177                 world_initialized = 0;
2178                 LOG_INFO("Saving persistent data...\n");
2179                 Ban_SaveBans();
2180
2181                 // playerstats with unfinished match
2182                 PlayerStats_GameReport(false);
2183
2184                 if(!cheatcount_total)
2185                 {
2186                         if(autocvar_sv_db_saveasdump)
2187                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2188                         else
2189                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2190                 }
2191                 if(autocvar_developer)
2192                 {
2193                         if(autocvar_sv_db_saveasdump)
2194                                 db_dump(TemporaryDB, "server-temp.db");
2195                         else
2196                                 db_save(TemporaryDB, "server-temp.db");
2197                 }
2198                 CheatShutdown(); // must be after cheatcount check
2199                 db_close(ServerProgsDB);
2200                 db_close(TemporaryDB);
2201                 LOG_INFO("done!\n");
2202                 // tell the bot system the game is ending now
2203                 bot_endgame();
2204
2205                 WeaponStats_Shutdown();
2206                 MapInfo_Shutdown();
2207         }
2208         else if(world_initialized == 0)
2209         {
2210                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2211         }
2212 }