qcsrc/server/gamecommand.qc

   1 string GotoMap(string m);
   2 void race_deleteTime(string map, float pos);
   3
   4 float FullTraceFraction(vector a, vector mi, vector ma, vector b)
   5 {
   6         vector c;
   7         float white, black;
   8
   9         white = 0.001;
  10         black = 0.001;
  11
  12         c = a;
  13
  14         float n, m;
  15         n = m = 0;
  16
  17         while(vlen(c - b) > 1)
  18         {
  19                 ++m;
  20
  21                 tracebox(c, mi, ma, b, MOVE_WORLDONLY, world);
  22                 ++n;
  23
  24                 if(!trace_startsolid)
  25                 {
  26                         black += vlen(trace_endpos - c);
  27                         c = trace_endpos;
  28                 }
  29
  30                 n += tracebox_inverted(c, mi, ma, b, MOVE_WORLDONLY, world);
  31
  32                 white += vlen(trace_endpos - c);
  33                 c = trace_endpos;
  34         }
  35
  36         if(n > 200)
  37                 dprint("HOLY SHIT! FullTraceFraction: ", ftos(n), " total traces, ", ftos(m), " iterations\n");
  38
  39         return white / (black + white);
  40 }
  41
  42 float RadarMapAtPoint_Trace(float x, float y, float w, float h, float zmin, float zsize, float q)
  43 {
  44         vector a, b, mi, ma;
  45
  46         mi = '0 0 0';
  47         ma = '1 0 0' * w + '0 1 0' * h;
  48         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  49         b = '1 0 0' * x + '0 1 0' * y + '0 0 1' * (zsize + zmin);
  50
  51         return FullTraceFraction(a, mi, ma, b);
  52 }
  53 float RadarMapAtPoint_LineBlock(float x, float y, float w, float h, float zmin, float zsize, float q)
  54 {
  55         vector o, mi, ma;
  56         float i, r;
  57         vector dz;
  58
  59         q = 256 * q - 1;
  60         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
  61
  62         mi = '0 0 0';
  63         dz = (zsize / q) * '0 0 1';
  64         ma = '1 0 0' * w + '0 1 0' * h + dz;
  65         o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  66
  67         if(x < world.absmin_x - w)
  68                 return 0;
  69         if(y < world.absmin_y - h)
  70                 return 0;
  71         if(x > world.absmax_x)
  72                 return 0;
  73         if(y > world.absmax_y)
  74                 return 0;
  75
  76         r = 0;
  77         for(i = 0; i < q; ++i)
  78         {
  79                 vector v1, v2;
  80                 v1 = v2 = o + dz * i + mi;
  81                 v1_x += random() * (ma_x - mi_x);
  82                 v1_y += random() * (ma_y - mi_y);
  83                 v1_z += random() * (ma_z - mi_z);
  84                 v2_x += random() * (ma_x - mi_x);
  85                 v2_y += random() * (ma_y - mi_y);
  86                 v2_z += random() * (ma_z - mi_z);
  87                 traceline(v1, v2, MOVE_WORLDONLY, world);
  88                 if(trace_startsolid || trace_fraction < 1)
  89                         ++r;
  90         }
  91         return r / q;
  92 }
  93 float RadarMapAtPoint_Block(float x, float y, float w, float h, float zmin, float zsize, float q)
  94 {
  95         vector o, mi, ma;
  96         float i, r;
  97         vector dz;
  98
  99         q = 256 * q - 1;
 100         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
 101
 102         mi = '0 0 0';
 103         dz = (zsize / q) * '0 0 1';
 104         ma = '1 0 0' * w + '0 1 0' * h + dz;
 105         o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
 106
 107         if(x < world.absmin_x - w)
 108                 return 0;
 109         if(y < world.absmin_y - h)
 110                 return 0;
 111         if(x > world.absmax_x)
 112                 return 0;
 113         if(y > world.absmax_y)
 114                 return 0;
 115
 116         r = 0;
 117         for(i = 0; i < q; ++i)
 118         {
 119                 tracebox(o + dz * i, mi, ma, o + dz * i, MOVE_WORLDONLY, world);
 120                 if(trace_startsolid)
 121                         ++r;
 122         }
 123         return r / q;
 124 }
 125 float RadarMapAtPoint_Sample(float x, float y, float w, float h, float zmin, float zsize, float q)
 126 {
 127         vector a, b, mi, ma;
 128
 129         q *= 4; // choose q so it matches the regular algorithm in speed
 130
 131         q = 256 * q - 1;
 132         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
 133
 134         mi = '0 0 0';
 135         ma = '1 0 0' * w + '0 1 0' * h;
 136         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
 137         b = '1 0 0' * w + '0 1 0' * h + '0 0 1' * zsize;
 138
 139         float c, i;
 140         c = 0;
 141
 142         for(i = 0; i < q; ++i)
 143         {
 144                 vector v;
 145                 v_x = a_x + random() * b_x;
 146                 v_y = a_y + random() * b_y;
 147                 v_z = a_z + random() * b_z;
 148                 traceline(v, v, MOVE_WORLDONLY, world);
 149                 if(trace_startsolid)
 150                         ++c;
 151         }
 152
 153         return c / q;
 154 }
 155
 156 // FF is contained twice, to map 256 to FF too
 157 // removes the need to bound()
 158 string doublehex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F303132333435363738393A3B3C3D3E3F404142434445464748494A4B4C4D4E4F505152535455565758595A5B5C5D5E5F606162636465666768696A6B6C6D6E6F707172737475767778797A7B7C7D7E7F808182838485868788898A8B8C8D8E8F909192939495969798999A9B9C9D9E9FA0A1A2A3A4A5A6A7A8A9AAABACADAEAFB0B1B2B3B4B5B6B7B8B9BABBBCBDBEBFC0C1C2C3C4C5C6C7C8C9CACBCCCDCECFD0D1D2D3D4D5D6D7D8D9DADBDCDDDEDFE0E1E2E3E4E5E6E7E8E9EAEBECEDEEEFF0F1F2F3F4F5F6F7F8F9FAFBFCFDFEFFFF";
 159
 160 float RADAR_WIDTH_MAX = 512;
 161 float RADAR_HEIGHT_MAX = 512;
 162 float sharpen_buffer[RADAR_WIDTH_MAX * 3];
 163
 164 void sharpen_set(float x, float v)
 165 {
 166         sharpen_buffer[x + 2 * RADAR_WIDTH_MAX] = v;
 167 }
 168
 169 float sharpen_getpixel(float x, float y)
 170 {
 171         if(x < 0)
 172                 return 0;
 173         if(x >= RADAR_WIDTH_MAX)
 174                 return 0;
 175         if(y < 0)
 176                 return 0;
 177         if(y > 2)
 178                 return 0;
 179         return sharpen_buffer[x + y * RADAR_WIDTH_MAX];
 180 }
 181
 182 float sharpen_get(float x, float a)
 183 {
 184         float sum;
 185         sum = sharpen_getpixel(x, 1);
 186         if(a == 0)
 187                 return sum;
 188         sum *= (8 + 1/a);
 189         sum -= sharpen_getpixel(x - 1, 0);
 190         sum -= sharpen_getpixel(x - 1, 1);
 191         sum -= sharpen_getpixel(x - 1, 2);
 192         sum -= sharpen_getpixel(x + 1, 0);
 193         sum -= sharpen_getpixel(x + 1, 1);
 194         sum -= sharpen_getpixel(x + 1, 2);
 195         sum -= sharpen_getpixel(x, 0);
 196         sum -= sharpen_getpixel(x, 2);
 197         return bound(0, sum * a, 1);
 198 }
 199
 200 void sharpen_shift(float w)
 201 {
 202         float i;
 203         for(i = 0; i < w; ++i)
 204         {
 205                 sharpen_buffer[i] = sharpen_buffer[i + RADAR_WIDTH_MAX];
 206                 sharpen_buffer[i + RADAR_WIDTH_MAX] = sharpen_buffer[i + 2 * RADAR_WIDTH_MAX];
 207                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
 208         }
 209 }
 210
 211 void sharpen_init(float w)
 212 {
 213         float i;
 214         for(i = 0; i < w; ++i)
 215         {
 216                 sharpen_buffer[i] = 0;
 217                 sharpen_buffer[i + RADAR_WIDTH_MAX] = 0;
 218                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
 219         }
 220 }
 221
 222 entity radarmapper;
 223 void RadarMap_Next()
 224 {
 225         if(radarmapper.count & 4)
 226         {
 227                 localcmd("quit\n");
 228         }
 229         else if(radarmapper.count & 2)
 230         {
 231                 localcmd(strcat("defer 1 \"sv_cmd radarmap --flags ", ftos(radarmapper.count), strcat(" --res ", ftos(radarmapper.size_x), " ", ftos(radarmapper.size_y), " --sharpen ", ftos(radarmapper.ltime), " --qual ", ftos(radarmapper.size_z)), "\"\n"));
 232                 GotoNextMap();
 233         }
 234         remove(radarmapper);
 235         radarmapper = world;
 236 }
 237
 238 // rough map entity
 239 //   cnt: current line
 240 //   size: pixel width/height
 241 //   maxs: cell width/height
 242 //   frame: counter
 243 void RadarMap_Think()
 244 {
 245         float i, x, l;
 246         string si;
 247
 248         if(self.frame == 0)
 249         {
 250                 // initialize
 251                 get_mi_min_max_texcoords(1);
 252                 self.mins = mi_picmin;
 253                 self.maxs_x = (mi_picmax_x - mi_picmin_x) / self.size_x;
 254                 self.maxs_y = (mi_picmax_y - mi_picmin_y) / self.size_y;
 255                 self.maxs_z = mi_max_z - mi_min_z;
 256                 print("Picture mins/maxs: ", ftos(self.maxs_x), " and ", ftos(self.maxs_y), " should match\n");
 257                 self.netname = strzone(strcat("gfx/", mi_shortname, "_radar.xpm"));
 258                 if(!(self.count & 1))
 259                 {
 260                         self.cnt = fopen(self.netname, FILE_READ);
 261                         if(self.cnt < 0)
 262                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.tga"), FILE_READ);
 263                         if(self.cnt < 0)
 264                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.png"), FILE_READ);
 265                         if(self.cnt < 0)
 266                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.jpg"), FILE_READ);
 267                         if(self.cnt < 0)
 268                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.tga"), FILE_READ);
 269                         if(self.cnt < 0)
 270                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.png"), FILE_READ);
 271                         if(self.cnt < 0)
 272                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.jpg"), FILE_READ);
 273                         if(self.cnt >= 0)
 274                         {
 275                                 fclose(self.cnt);
 276
 277                                 print(self.netname, " already exists, aborting (you may want to specify --force)\n");
 278                                 RadarMap_Next();
 279                                 return;
 280                         }
 281                 }
 282                 self.cnt = fopen(self.netname, FILE_WRITE);
 283                 if(self.cnt < 0)
 284                 {
 285                         print("Error writing ", self.netname, "\n");
 286                         remove(self);
 287                         radarmapper = world;
 288                         return;
 289                 }
 290                 print("Writing to ", self.netname, "...\n");
 291                 fputs(self.cnt, "/* XPM */\n");
 292                 fputs(self.cnt, "static char *RadarMap[] = {\n");
 293                 fputs(self.cnt, "/* columns rows colors chars-per-pixel */\n");
 294                 fputs(self.cnt, strcat("\"", ftos(self.size_x), " ", ftos(self.size_y), " 256 2\",\n"));
 295                 for(i = 0; i < 256; ++i)
 296                 {
 297                         si = substring(doublehex, i*2, 2);
 298                         fputs(self.cnt, strcat("\"", si, " c #", si, si, si, "\",\n"));
 299                 }
 300                 self.frame += 1;
 301                 self.nextthink = time;
 302                 sharpen_init(self.size_x);
 303         }
 304         else if(self.frame <= self.size_y)
 305         {
 306                 // fill the sharpen buffer with this line
 307                 sharpen_shift(self.size_x);
 308                 i = self.count & 24;
 309
 310                 switch(i)
 311                 {
 312                         case 0:
 313                         default:
 314                                 for(x = 0; x < self.size_x; ++x)
 315                                 {
 316                                         l = RadarMapAtPoint_Block(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 317                                         sharpen_set(x, l);
 318                                 }
 319                                 break;
 320                         case 8:
 321                                 for(x = 0; x < self.size_x; ++x)
 322                                 {
 323                                         l = RadarMapAtPoint_Trace(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 324                                         sharpen_set(x, l);
 325                                 }
 326                                 break;
 327                         case 16:
 328                                 for(x = 0; x < self.size_x; ++x)
 329                                 {
 330                                         l = RadarMapAtPoint_Sample(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 331                                         sharpen_set(x, l);
 332                                 }
 333                                 break;
 334                         case 24:
 335                                 for(x = 0; x < self.size_x; ++x)
 336                                 {
 337                                         l = RadarMapAtPoint_LineBlock(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 338                                         sharpen_set(x, l);
 339                                 }
 340                                 break;
 341                 }
 342
 343                 // do we have enough lines?
 344                 if(self.frame >= 2)
 345                 {
 346                         // write a pixel line
 347                         fputs(self.cnt, "\"");
 348                         for(x = 0; x < self.size_x; ++x)
 349                         {
 350                                 l = sharpen_get(x, self.ltime);
 351                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
 352                         }
 353                         if(self.frame == self.size_y)
 354                                 fputs(self.cnt, "\"\n");
 355                         else
 356                         {
 357                                 fputs(self.cnt, "\",\n");
 358                                 print(ftos(self.size_y - self.frame), " lines left\n");
 359                         }
 360                 }
 361
 362                 // is this the last line? then write back the missing line
 363                 if(self.frame == self.size_y)
 364                 {
 365                         sharpen_shift(self.size_x);
 366                         // write a pixel line
 367                         fputs(self.cnt, "\"");
 368                         for(x = 0; x < self.size_x; ++x)
 369                         {
 370                                 l = sharpen_get(x, self.ltime);
 371                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
 372                         }
 373                         if(self.frame == self.size_y)
 374                                 fputs(self.cnt, "\"\n");
 375                         else
 376                         {
 377                                 fputs(self.cnt, "\",\n");
 378                                 print(ftos(self.size_y - self.frame), " lines left\n");
 379                         }
 380                 }
 381
 382                 self.frame += 1;
 383                 self.nextthink = time;
 384         }
 385         else
 386         {
 387                 // close the file
 388                 fputs(self.cnt, "};\n");
 389                 fclose(self.cnt);
 390                 print("Finished. Please edit data/", self.netname, " with an image editing application and place it in the TGA format in the gfx folder.\n");
 391                 RadarMap_Next();
 392         }
 393 }
 394
 395 void RadarMap(float argc)
 396 {
 397         if(radarmapper)
 398                 return;
 399         float i;
 400         radarmapper = spawn();
 401         radarmapper.classname = "radarmapper";
 402         radarmapper.think = RadarMap_Think;
 403         radarmapper.nextthink = time;
 404         radarmapper.count = 8; // default to the --trace method, as it is faster now
 405         radarmapper.ltime = 1;
 406         radarmapper.size_x = 512;
 407         radarmapper.size_y = 512;
 408         radarmapper.size_z = 1;
 409
 410         for(i = 1; i < argc; ++i)
 411         {
 412                 if(argv(i) == "--force")
 413                         radarmapper.count |= 1;
 414                 else if(argv(i) == "--loop")
 415                         radarmapper.count |= 2;
 416                 else if(argv(i) == "--quit")
 417                         radarmapper.count |= 4;
 418                 else if(argv(i) == "--block")
 419                 {
 420                         radarmapper.count &~= 24;
 421                 }
 422                 else if(argv(i) == "--trace")
 423                 {
 424                         radarmapper.count &~= 24;
 425                         radarmapper.count |= 8;
 426                 }
 427                 else if(argv(i) == "--sample")
 428                 {
 429                         radarmapper.count &~= 24;
 430                         radarmapper.count |= 16;
 431                 }
 432                 else if(argv(i) == "--lineblock")
 433                 {
 434                         radarmapper.count |= 24;
 435                 }
 436                 else if(argv(i) == "--flags") // for the recursive call
 437                 {
 438                         ++i;
 439                         radarmapper.count = stof(argv(i));
 440                 }
 441                 else if(argv(i) == "--sharpen") // for the recursive call
 442                 {
 443                         ++i;
 444                         radarmapper.ltime = stof(argv(i));
 445                 }
 446                 else if(argv(i) == "--res") // resolution
 447                 {
 448                         ++i;
 449                         radarmapper.size_x = stof(argv(i));
 450                         ++i;
 451                         radarmapper.size_y = stof(argv(i));
 452                 }
 453                 else if(argv(i) == "--qual") // quality multiplier
 454                 {
 455                         ++i;
 456                         radarmapper.size_z = stof(argv(i));
 457                 }
 458                 else
 459                 {
 460                         remove(radarmapper);
 461                         radarmapper = world;
 462                         print("Usage: sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
 463                         print("The quality factor Q is roughly proportional to the time taken.\n");
 464                         print("--trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
 465                         print("--block \n");
 466                         return;
 467                 }
 468         }
 469
 470         print("Radarmap entity spawned.\n");
 471 }
 472
 473 void BBox()
 474 {
 475         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 476         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 477         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 478         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 479         print("Solid bounding box size:");
 480
 481         tracebox('1 0 0' * world.absmin_x,
 482                  '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 483                  '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 484                  '1 0 0' * world.absmax_x,
 485                          MOVE_WORLDONLY,
 486                          world);
 487         if(trace_startsolid)
 488                 print(" ", ftos(world.absmin_x));
 489         else
 490                 print(" ", ftos(trace_endpos_x));
 491
 492         tracebox('0 1 0' * world.absmin_y,
 493                  '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 494                  '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 495                  '0 1 0' * world.absmax_y,
 496                          MOVE_WORLDONLY,
 497                          world);
 498         if(trace_startsolid)
 499                 print(" ", ftos(world.absmin_y));
 500         else
 501                 print(" ", ftos(trace_endpos_y));
 502
 503         tracebox('0 0 1' * world.absmin_z,
 504                  '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 505                  '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 506                  '0 0 1' * world.absmax_z,
 507                          MOVE_WORLDONLY,
 508                          world);
 509         if(trace_startsolid)
 510                 print(" ", ftos(world.absmin_z));
 511         else
 512                 print(" ", ftos(trace_endpos_z));
 513
 514         tracebox('1 0 0' * world.absmax_x,
 515                  '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 516                  '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 517                  '1 0 0' * world.absmin_x,
 518                          MOVE_WORLDONLY,
 519                          world);
 520         if(trace_startsolid)
 521                 print(" ", ftos(world.absmax_x));
 522         else
 523                 print(" ", ftos(trace_endpos_x));
 524
 525         tracebox('0 1 0' * world.absmax_y,
 526                  '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 527                  '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 528                  '0 1 0' * world.absmin_y,
 529                          MOVE_WORLDONLY,
 530                          world);
 531         if(trace_startsolid)
 532                 print(" ", ftos(world.absmax_y));
 533         else
 534                 print(" ", ftos(trace_endpos_y));
 535
 536         tracebox('0 0 1' * world.absmax_z,
 537                  '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 538                  '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 539                  '0 0 1' * world.absmin_z,
 540                          MOVE_WORLDONLY,
 541                          world);
 542         if(trace_startsolid)
 543                 print(" ", ftos(world.absmax_z));
 544         else
 545                 print(" ", ftos(trace_endpos_z));
 546
 547         print("\n");
 548 }
 549
 550 void EffectIndexDump()
 551 {
 552         float d;
 553         float fh;
 554         string s;
 555
 556         d = db_create();
 557
 558         print("begin of effects list\n");
 559         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 560         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 561         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 562         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 563         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 564         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 565         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 566         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 567         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 568         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 569         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 570         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 571         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 572         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 573         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 574         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 575         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 576         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 577         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 578         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 579         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 580         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 581         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 582         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 583         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 584         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 585         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 586         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 587         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 588         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 589         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 590         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 591         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 592         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 593         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 594         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 595
 596         fh = fopen("effectinfo.txt", FILE_READ);
 597         while((s = fgets(fh)))
 598         {
 599                 tokenize(s); // tokenize_console would hit the loop counter :(
 600                 if(argv(0) == "effect")
 601                 {
 602                         if(db_get(d, argv(1)) != "1")
 603                         {
 604                                 if(particleeffectnum(argv(1)) >= 0)
 605                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 606                                 db_put(d, argv(1), "1");
 607                         }
 608                 }
 609         }
 610         print("end of effects list\n");
 611
 612         db_close(d);
 613 }
 614
 615 void make_mapinfo_Think()
 616 {
 617         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 618         {
 619                 print("Done rebuiling mapinfos.\n");
 620                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 621                 remove(self);
 622         }
 623         else
 624         {
 625                 self.think = make_mapinfo_Think;
 626                 self.nextthink = time;
 627         }
 628 }
 629
 630 void changematchtime(float delta, float mi, float ma)
 631 {
 632         float cur;
 633         float new;
 634         float lim;
 635
 636         if(delta == 0)
 637                 return;
 638         if(autocvar_timelimit < 0)
 639                 return;
 640
 641         if(mi <= 10)
 642                 mi = 10; // at least ten sec in the future
 643         cur = time - game_starttime;
 644         if(cur > 0)
 645                 mi += cur; // from current time!
 646
 647         lim = autocvar_timelimit * 60;
 648
 649         if(delta > 0)
 650         {
 651                 if(lim == 0)
 652                         return; // cannot increase any further
 653                 else if(lim < ma)
 654                         new = min(ma, lim + delta);
 655                 else // already above maximum: FAIL
 656                         return;
 657         }
 658         else
 659         {
 660                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
 661                         new = max(mi, ma);
 662                 else if(lim > mi) // above minimum: decrease
 663                         new = max(mi, lim + delta);
 664                 else // already below minimum: FAIL
 665                         return;
 666         }
 667
 668         cvar_set("timelimit", ftos(new / 60));
 669 }
 670
 671 float g_clientmodel_genericsendentity (entity to, float sf);
 672 void modelbug_make_svqc();
 673 void modelbug_make_csqc()
 674 {
 675         Net_LinkEntity(self, TRUE, 0, g_clientmodel_genericsendentity);
 676         self.think = modelbug_make_svqc;
 677         self.nextthink = time + 1;
 678         setorigin(self, self.origin - '0 0 8');
 679 }
 680 void modelbug_make_svqc()
 681 {
 682         self.SendEntity = func_null;
 683         self.think = modelbug_make_csqc;
 684         self.nextthink = time + 1;
 685         setorigin(self, self.origin + '0 0 8');
 686 }
 687
 688 void modelbug()
 689 {
 690         entity e;
 691         e = spawn();
 692         setorigin(e, nextent(world).origin);
 693         precache_model("models_portal.md3");
 694         setmodel(e, "models/portal.md3");
 695         e.think = modelbug_make_svqc;
 696         e.nextthink = time + 1;
 697 }
 698
 699 void GameCommand(string command)
 700 {
 701         // ===== TODO list =====
 702         // Update the help/command list to actually show all the commands
 703
 704         // Re-order all the commands in alphabetical order -- or in some other easily recognizable order ;3 (if possible)
 705
 706         // Add extra help to each command when used improperly
 707
 708         // Add ifdef to stuffto so that is can only be used when the game code is compiled for it
 709         //(this way it's more obscure and harder to abuse on normal servers)
 710
 711         float argc;
 712         entity client, e;
 713         vector v;
 714         float entno, i, n;
 715         string s;
 716         argc = tokenize_console(command);
 717
 718         if(argv(0) == "help" || argc == 0)
 719         {
 720                 print("Usage: sv_cmd COMMAND..., where possible commands are:\n");
 721                 print("  adminmsg clientnumber \"message\" [infobartime]\n");
 722                 print("  teamstatus\n");
 723                 print("  printstats\n");
 724                 print("  make_mapinfo\n");
 725                 print("  gametype dm|ctf|...\n");
 726                 print("  savedb filename\n");
 727                 print("  dumpdb filename\n");
 728                 print("  loaddb filename\n");
 729                 print("  allready\n");
 730                 print("  effectindexdump\n");
 731                 print("  radarmap [--force] [--quit | --loop] [sharpness]\n");
 732                 print("  bbox\n");
 733                 print("  cvar_changes\n");
 734                 print("  cvar_purechanges\n");
 735                 print("  find classname\n");
 736                 print("  extendmatchtime\n");
 737                 print("  reducematchtime\n");
 738                 GameCommand_Vote("help", world);
 739                 GameCommand_Ban("help");
 740                 GameCommand_Generic("help");
 741                 return;
 742         }
 743
 744         if(GameCommand_Vote(command, world))
 745                 return;
 746
 747         if(GameCommand_Ban(command))
 748                 return;
 749
 750         if(GameCommand_Generic(command))
 751                 return;
 752
 753         if(argv(0) == "stuffto") if(argc == 3)
 754         {
 755                 entity rbi_client;
 756                 float rbi_entno;
 757                 rbi_entno = stof(argv(1));
 758                 rbi_client = world;
 759                 if(rbi_entno <= maxclients)
 760                         rbi_client = edict_num(rbi_entno);
 761                 if(rbi_client.flags & FL_CLIENT)
 762                 {
 763                         stuffcmd(rbi_client, strcat("\n", argv(2), "\n"));
 764                         print("Command sent to ", rbi_client.netname, "\n");
 765                 }
 766                 else
 767                         print("Client not found\n");
 768                 return;
 769         }
 770
 771         if(argv(0) == "printstats")
 772         {
 773                 DumpStats(FALSE);
 774                 return;
 775         }
 776
 777         if(argv(0) == "make_mapinfo")
 778         {
 779                 e = spawn();
 780                 e.classname = "make_mapinfo";
 781                 e.think = make_mapinfo_Think;
 782                 e.nextthink = time;
 783                 MapInfo_Enumerate();
 784                 return;
 785         }
 786
 787         if(argv(0) == "gotomap") if(argc == 2)
 788         {
 789                 print(GotoMap(argv(1)), "\n");
 790                 return;
 791         }
 792
 793         if(argv(0) == "gametype") if(argc == 2)
 794         {
 795                 float t, tsave;
 796                 s = argv(1);
 797                 t = MapInfo_Type_FromString(s);
 798                 tsave = MapInfo_CurrentGametype();
 799                 if(t)
 800                 {
 801                         MapInfo_SwitchGameType(t);
 802                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 803                         if(MapInfo_count > 0)
 804                         {
 805                                 bprint("Game type successfully switched to ", s, "\n");
 806                         }
 807                         else
 808                         {
 809                                 bprint("Cannot use this game type: no map for it found\n");
 810                                 MapInfo_SwitchGameType(tsave);
 811                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 812                         }
 813                 }
 814                 else
 815                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 816                 return;
 817         }
 818
 819         if(argv(0) == "adminmsg")
 820         if(argc >= 3 && argc <= 4)
 821         {
 822                 entno = stof(argv(1));
 823
 824                 if((entno < 0) | (entno > maxclients)) {
 825                         print("Player ", argv(1), " doesn't exist\n");
 826                         return;
 827                 }
 828
 829                 n = 0;
 830                 for(i = (entno ? entno : 1); i <= (entno ? entno : maxclients); ++i)
 831                 {
 832                         client = edict_num(i);
 833                         if(client.flags & FL_CLIENT)
 834                         {
 835                                 if(argc == 4)
 836                                 {
 837                                         s = argv(2);
 838                                         s = strreplace("\n", "", s);
 839                                         s = strreplace("\\", "\\\\", s);
 840                                         s = strreplace("$", "$$", s);
 841                                         s = strreplace("\"", "\\\"", s);
 842                                         stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", stof(argv(3)), s));
 843                                 }
 844                                 else
 845                                 {
 846                                         centerprint_atprio(client, CENTERPRIO_ADMIN, strcat("^3", admin_name(), ":\n\n^7", argv(2)));
 847                                         sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", argv(2), "\n"));
 848                                 }
 849                                 print("Message sent to ", client.netname, "\n");
 850                                 ++n;
 851                         }
 852                 }
 853                 if(!n)
 854                         print("Client not found\n");
 855
 856                 return;
 857         }
 858
 859         if(argv(0) == "savedb") if(argc == 2)
 860         {
 861                 db_save(ServerProgsDB, argv(1));
 862                 print("DB saved.\n");
 863                 return;
 864         }
 865
 866         if(argv(0) == "dumpdb") if(argc == 2)
 867         {
 868                 db_dump(ServerProgsDB, argv(1));
 869                 print("DB dumped.\n");
 870                 return;
 871         }
 872
 873         if(argv(0) == "loaddb") if(argc == 2)
 874         {
 875                 db_close(ServerProgsDB);
 876                 ServerProgsDB = db_load(argv(1));
 877                 print("DB loaded.\n");
 878                 return;
 879         }
 880
 881         if (argv(0) == "nospectators")
 882         {
 883                 blockSpectators = 1;
 884                 local entity plr;
 885                 FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
 886                 {
 887                         if(plr.classname == "spectator" || plr.classname == "observer")
 888                         {
 889                                 plr.spectatortime = time;
 890                                 sprint(plr, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 891                         }
 892                 }
 893                 bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
 894                 return;
 895         }
 896
 897         if (argv(0) == "lockteams")
 898         {
 899                 if(teamplay)
 900                 {
 901                         lockteams = 1;
 902                         bprint("^1The teams are now locked.\n");
 903                 }
 904                 else
 905                         bprint("That command can only be used in a team-based gamemode.\n");
 906                 return;
 907         }
 908
 909         if (argv(0) == "unlockteams")
 910         {
 911                 if(teamplay)
 912                 {
 913                         lockteams = 0;
 914                         bprint("^1The teams are now unlocked.\n");
 915                 }
 916                 else
 917                         bprint("That command can only be used in a team-based gamemode.\n");
 918                 return;
 919         }
 920         if(argv(0) == "movetoteam") if(argc == 3 || argc == 4) {
 921                 //      sv_cmd movetoteam  player_id  team_colour
 922                 //      sv_cmd movetoteam  player_id  team_colour  type_of_move
 923
 924                 //      type of move
 925                 //      0 (00) automove centerprint, admin message
 926                 //      1 (01) automove centerprint, no admin message
 927                 //      2 (10) no centerprint, admin message
 928                 //      3 (11) no centerprint, no admin message
 929
 930                 if(!teamplay) {  // death match
 931                         print("Currently not playing a team game\n");
 932                         return;
 933                 }
 934
 935                 entno = stof(argv(1));
 936
 937                 // player_id is out of range
 938                 if((entno < 1) | (entno > maxclients)) {
 939                         print("Player ", argv(1), " doesn't exist\n");
 940                         return;
 941                 }
 942
 943                 client = edict_num(entno);
 944
 945                 // player entity is not a client
 946                 if not(client.flags & FL_CLIENT) {
 947                         print("Player ", argv(1), " doesn't exist\n");
 948                         return;
 949                 }
 950
 951                 // find the team to move the player to
 952                 float team_colour;
 953                 float save;
 954
 955                 save = client.team_forced;
 956                 client.team_forced = 0;
 957
 958                 team_colour = ColourToNumber(argv(2));
 959
 960                 if(team_colour == client.team) {  // player already on the team
 961                         print("Player ", argv(1), " (", client.netname, ") is already on the ", ColoredTeamName(client.team), "\n");
 962                         // keep the forcing undone
 963                         return;
 964                 } else if(team_colour == 0)  // auto team
 965                         team_colour = NumberToTeamNumber(FindSmallestTeam(client, FALSE));
 966                 else
 967                         CheckAllowedTeams(client);
 968
 969                 client.team_forced = save;
 970
 971                 switch(team_colour) {
 972                         case COLOR_TEAM1:
 973                                 if(c1 == -1) {
 974                                         print("Sorry, there isn't a red team\n");
 975                                         return;
 976                                 }
 977                                 break;
 978
 979                         case COLOR_TEAM2:
 980                                 if(c2 == -1) {
 981                                         print("Sorry, there isn't a blue team\n");
 982                                         return;
 983                                 }
 984                                 break;
 985
 986                         case COLOR_TEAM3:
 987                                 if(c3 == -1) {
 988                                         print("Sorry, there isn't a yellow team\n");
 989                                         return;
 990                                 }
 991                                 break;
 992
 993                         case COLOR_TEAM4:
 994                                 if(c4 == -1) {
 995                                         print("Sorry, there isn't a pink team\n");
 996                                         return;
 997                                 }
 998                                 break;
 999
1000                         default:
1001                                 print("Sorry, team ", argv(2), " doesn't exist\n");
1002                                 return;
1003                 }
1004                 print("Player ", argv(1), " (", client.netname, ") has been moved to the ", ColoredTeamName(team_colour), "\n");
1005
1006                 client.team_forced = 0;
1007                 MoveToTeam(client, team_colour, 6, stof(argv(3)));
1008
1009                 return;
1010         }
1011         if (argv(0) == "teamstatus")
1012         {
1013                 Score_NicePrint(world);
1014                 return;
1015         }
1016         if (argv(0) == "allready")
1017         {
1018                 ReadyRestart();
1019                 return;
1020         }
1021         if (argv(0) == "effectindexdump")
1022         {
1023                 EffectIndexDump();
1024                 return;
1025         }
1026         if (argv(0) == "radarmap")
1027         {
1028                 RadarMap(argc);
1029                 return;
1030         }
1031         if (argv(0) == "bbox")
1032         {
1033                 BBox();
1034                 return;
1035         }
1036         if (argv(0) == "cvar_changes")
1037         {
1038                 print(cvar_changes);
1039                 return;
1040         }
1041         if (argv(0) == "cvar_purechanges")
1042         {
1043                 print(cvar_purechanges);
1044                 return;
1045         }
1046         if (argv(0) == "find") if(argc == 2)
1047         {
1048                 for(client = world; (client = find(client, classname, argv(1))); )
1049                         print(etos(client), "\n");
1050                 return;
1051         }
1052         if (argv(0) == "records")
1053         {
1054                 for (i = 0; i < 10; ++i)
1055                         print(records_reply[i]);
1056                 return;
1057         }
1058         if (argv(0) == "ladder")
1059         {
1060                 print(ladder_reply);
1061                 return;
1062         }
1063         if (argv(0) == "rankings")
1064         {
1065                 strunzone(rankings_reply);
1066                 rankings_reply = strzone(getrankings());
1067                 print(rankings_reply);
1068                 return;
1069         }
1070
1071         if(argv(0) == "cointoss")
1072         {
1073                 bprint("^3Throwing coin... Result: ");
1074                 if (random() > 0.5)
1075                         bprint("^1heads ^3!\n");
1076                 else
1077                         bprint("^1tails ^3!\n");
1078                 return;
1079         }
1080
1081         if(argv(0) == "__FORCE_READY_RESTART")
1082         {
1083                 reset_map(FALSE);
1084                 return;
1085         }
1086
1087         if(argv(0) == "debug_shotorg")
1088         {
1089                 debug_shotorg = stov(argv(1));
1090                 debug_shotorg_y = -debug_shotorg_y;
1091                 return;
1092         }
1093
1094         if(argv(0) == "gettaginfo") if(argc >= 4)
1095         {
1096                 e = spawn();
1097                 if(argv(1) == "w")
1098                         setmodel(e, (nextent(world)).weaponentity.model);
1099                 else
1100                 {
1101                         precache_model(argv(1));
1102                         setmodel(e, argv(1));
1103                 }
1104                 e.frame = stof(argv(2));
1105                 if(substring(argv(3), 0, 1) == "#")
1106                         i = stof(substring(argv(3), 1, -1));
1107                 else
1108                         i = gettagindex(e, argv(3));
1109                 if(i)
1110                 {
1111                         v = gettaginfo(e, i);
1112                         print("model ", e.model, " frame ", ftos(e.frame), " tag ", gettaginfo_name);
1113                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
1114                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
1115                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
1116                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
1117                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
1118                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
1119                         if(argc >= 6)
1120                         {
1121                                 v_y = -v_y;
1122                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
1123                         }
1124                 }
1125                 else
1126                         print("bone not found\n");
1127                 remove(e);
1128                 return;
1129         }
1130
1131         if(argv(0) == "time")
1132         {
1133                 print("time = ", ftos(time), "\n");
1134                 print("frame start = ", ftos(gettime(GETTIME_FRAMESTART)), "\n");
1135                 print("realtime = ", ftos(gettime(GETTIME_REALTIME)), "\n");
1136                 print("hires = ", ftos(gettime(GETTIME_HIRES)), "\n");
1137                 print("uptime = ", ftos(gettime(GETTIME_UPTIME)), "\n");
1138                 print("localtime = ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n");
1139                 print("gmtime = ", strftime(FALSE, "%a %b %e %H:%M:%S %Z %Y"), "\n");
1140                 return;
1141         }
1142
1143         if(argv(0) == "tracebug")
1144         {
1145                 print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1146                 for(;;)
1147                 {
1148                         vector org, delta, start, end, p, q, q0, pos;
1149                         float safe, unsafe, dq, dqf;
1150
1151                         org = world.mins;
1152                         delta = world.maxs - world.mins;
1153
1154                         start_x = org_x + random() * delta_x;
1155                         start_y = org_y + random() * delta_y;
1156                         start_z = org_z + random() * delta_z;
1157
1158                         end_x = org_x + random() * delta_x;
1159                         end_y = org_y + random() * delta_y;
1160                         end_z = org_z + random() * delta_z;
1161
1162                         start = stov(vtos(start));
1163                         end = stov(vtos(end));
1164
1165                         tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1166                         if(!trace_startsolid)
1167                         {
1168                                 p = trace_endpos;
1169                                 tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1170                                 if(trace_startsolid || trace_fraction == 1)
1171                                 {
1172                                         rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1173                                         tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1174                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1175
1176                                         if(trace_startsolid)
1177                                         {
1178                                                 // how much do we need to back off?
1179                                                 safe = 1;
1180                                                 unsafe = 0;
1181                                                 for(;;)
1182                                                 {
1183                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1184                                                         tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1185                                                         if(trace_startsolid)
1186                                                         {
1187                                                                 if((safe + unsafe) * 0.5 == unsafe)
1188                                                                         break;
1189                                                                 unsafe = (safe + unsafe) * 0.5;
1190                                                         }
1191                                                         else
1192                                                         {
1193                                                                 if((safe + unsafe) * 0.5 == safe)
1194                                                                         break;
1195                                                                 safe = (safe + unsafe) * 0.5;
1196                                                         }
1197                                                 }
1198
1199                                                 print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1200                                                 print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1201
1202                                                 tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1203                                                 if(trace_startsolid)
1204                                                         print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1205                                                 else
1206                                                         print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1207                                                 break;
1208                                         }
1209
1210                                         q0 = p;
1211                                         dq = 0;
1212                                         dqf = 1;
1213                                         for(;;)
1214                                         {
1215                                                 q = p + normalize(end - p) * (dq + dqf);
1216                                                 if(q == q0)
1217                                                         break;
1218                                                 tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1219                                                 if(trace_startsolid)
1220                                                         error("THIS ONE cannot happen");
1221                                                 if(trace_fraction > 0)
1222                                                         dq += dqf * trace_fraction;
1223                                                 dqf *= 0.5;
1224                                                 q0 = q;
1225                                         }
1226                                         if(dq > 0)
1227                                         {
1228                                                 print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1229                                                 print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1230                                                 break;
1231                                         }
1232                                 }
1233                         }
1234                 }
1235         }
1236
1237         if(argv(0) == "tracebug2")
1238         {
1239                 e = nextent(world);
1240                 float f;
1241                 vector vv, dv;
1242                 tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1243                 vv = trace_endpos;
1244                 if(trace_fraction == 1)
1245                 {
1246                         print("not above ground, aborting\n");
1247                         return;
1248                 }
1249                 f = 0;
1250                 for(i = 0; i < 100000; ++i)
1251                 {
1252                         dv = randomvec();
1253                         if(dv_z > 0)
1254                                 dv = -1 * dv;
1255                         tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1256                         if(trace_startsolid)
1257                                 print("bug 1\n");
1258                         if(trace_fraction == 1)
1259                         if(dv_z < f)
1260                         {
1261                                 print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1262                                 print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1263                                 f = dv_z;
1264                         }
1265                 }
1266                 print("highest possible dist: ", ftos(f), "\n");
1267                 return;
1268         }
1269
1270         if(argv(0) == "tracewalk")
1271         {
1272                 e = nextent(world);
1273                 if(tracewalk(e, stov(argv(1)), e.mins, e.maxs, stov(argv(2)), MOVE_NORMAL))
1274                         print("can walk\n");
1275                 else
1276                         print("cannot walk\n");
1277                 return;
1278         }
1279
1280         if(argv(0) == "onslaught_updatelinks")
1281         {
1282                 onslaught_updatelinks();
1283                 print("ONS links updated\n");
1284                 return;
1285         }
1286
1287         if(argv(0) == "bot_cmd")
1288         {
1289                 local entity bot;
1290
1291                 if(argv(1) == "help")
1292                 {
1293                         if(argc==2)
1294                         {
1295                                 bot_list_commands();
1296                                 print("\nsv_cmd bot_cmd reset          #Clear the cmd queues of all bots\n");
1297                                 print("sv_cmd bot_cmd load <file>    #Load script file\n");
1298                                 print("\nUse sv_cmd bot_cmd help <command> for more\n\n");
1299                                 return;
1300                         }
1301
1302                         bot_cmdhelp(argv(2));
1303                         return;
1304                 }
1305
1306                 // Clear all bot queues
1307                 if(argv(1) == "reset")
1308                 {
1309                         bot_resetqueues();
1310                         return;
1311                 }
1312
1313                 // Load cmds from file
1314                 if(argv(1) == "load" && argc == 3)
1315                 {
1316                         float fh;
1317                         fh = fopen(argv(2), FILE_READ);
1318                         if(fh < 0)
1319                         {
1320                                 print("cannot open the file\n");
1321                                 return;
1322                         }
1323
1324                         i = 0;
1325                         while((s = fgets(fh)))
1326                         {
1327                                 argc = tokenize_console(s);
1328
1329                                 if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
1330                                 {
1331                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
1332                                         bot = find_bot_by_number(stof(argv(2)));
1333                                         if(bot == world)
1334                                                 bot = find_bot_by_name(argv(2));
1335                                         if(bot)
1336                                                 bot_queuecommand(bot, strcat(argv(3), " ", argv(4)));
1337                                 }
1338                                 else
1339                                         localcmd(strcat(s, "\n"));
1340
1341                                 ++i;
1342                         }
1343
1344                         print(ftos(i), " commands read\n");
1345
1346                         fclose(fh);
1347
1348                         return;
1349                 }
1350
1351                 if(argc < 3)
1352                 {
1353                         print("Usage: sv_cmd bot_cmd <bot name or number> <command> [argument]\n");
1354                         print("Examples: bot_cmd <id> cc \"say something\"\n");
1355                         print("          bot_cmd <id> presskey jump\n");
1356                         print("          .. or sv_cmd bot_cmd help <command> for more\n");
1357                         return;
1358                 }
1359
1360                 bot = find_bot_by_number(stof(argv(1)));
1361                 if(bot == world)
1362                         bot = find_bot_by_name(argv(1));
1363
1364                 if(bot)
1365                         bot_queuecommand(bot, strcat(argv(2), " ", argv(3)));
1366                 else
1367                         print(strcat("Error: Unable to find a bot with the name or number '",argv(1),"'\n"));
1368
1369                 return;
1370         }
1371
1372         if(argv(0) == "playerdemo")
1373         {
1374                 if(argv(1) == "read")
1375                 {
1376                         entno = stof(argv(2));
1377                         if((entno < 1) | (entno > maxclients)) {
1378                                 print("Player ", argv(2), " doesn't exist\n");
1379                                 return;
1380                         }
1381                         client = edict_num(entno);
1382                         if(clienttype(client) != CLIENTTYPE_BOT) {
1383                                 print("Player ", client.netname, " is not a bot\n");
1384                                 return;
1385                         }
1386                         self = client;
1387                         playerdemo_open_read(argv(3));
1388                         return;
1389                 }
1390                 else if(argv(1) == "write")
1391                 {
1392                         entno = stof(argv(2));
1393                         if((entno < 1) | (entno > maxclients)) {
1394                                 print("Player ", argv(2), " doesn't exist\n");
1395                                 return;
1396                         }
1397                         client = edict_num(entno);
1398                         self = client;
1399                         playerdemo_open_write(argv(3));
1400                         return;
1401                 }
1402                 else if(argv(1) == "auto_read_and_write")
1403                 {
1404                         s = argv(2);
1405                         n = stof(argv(3));
1406                         cvar_set("bot_number", ftos(n));
1407                         localcmd("wait; wait; wait\n");
1408                         for(i = 0; i < n; ++i)
1409                                 localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", s, ftos(i+1), "\n");
1410                         localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1411                         return;
1412                 }
1413                 else if(argv(1) == "auto_read")
1414                 {
1415                         s = argv(2);
1416                         n = stof(argv(3));
1417                         cvar_set("bot_number", ftos(n));
1418                         localcmd("wait; wait; wait\n");
1419                         for(i = 0; i < n; ++i)
1420                                 localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", s, ftos(i+1), "\n");
1421                         return;
1422                 }
1423         }
1424
1425         if(argv(0) == "anticheat")
1426         {
1427                 entno = stof(argv(1));
1428                 if((entno < 1) | (entno > maxclients)) {
1429                         print("Player ", argv(1), " doesn't exist\n");
1430                         return;
1431                 }
1432                 client = edict_num(entno);
1433                 if(clienttype(client) != CLIENTTYPE_REAL && clienttype(client) != CLIENTTYPE_BOT) {
1434                         print("Player ", client.netname, " is not active\n");
1435                         return;
1436                 }
1437                 self = client;
1438                 anticheat_report();
1439                 return;
1440         }
1441
1442         if(argv(0) == "defer_clear")
1443         if(argc == 2)
1444         {
1445                 entno = stof(argv(1));
1446
1447                 // player_id is out of range
1448                 if((entno < 1) | (entno > maxclients)) {
1449                         print("Player ", argv(1), " doesn't exist\n");
1450                         return;
1451                 }
1452
1453                 client = edict_num(entno);
1454
1455                 if not(client.flags & FL_CLIENT) {
1456                         print("Player ", argv(1), " doesn't exist\n");
1457                         return;
1458                 }
1459
1460                 if(clienttype(client) == CLIENTTYPE_BOT) {
1461                         print("Player ", argv(1), " (", client.netname, ") is a bot\n");
1462                         return;
1463                 }
1464
1465                 stuffcmd(client, "defer clear\n");
1466                 print("defer clear stuffed to ", argv(1), " (", client.netname, ")\n");
1467                 return;
1468         }
1469
1470         if(argv(0) == "defer_clear_all")
1471         {
1472                 FOR_EACH_CLIENTSLOT(client)
1473                         GameCommand(strcat("defer_clear ", ftos(num_for_edict(client))));
1474
1475                 return;
1476         }
1477         if(argv(0) == "delrec")
1478         {
1479                 if(argv(2) != "")
1480                         race_deleteTime(argv(2), stof(argv(1)));
1481                 else
1482                         race_deleteTime(GetMapname(), stof(argv(1)));
1483
1484                 return;
1485         }
1486
1487         if(argv(0) == "showtraceline")
1488         {
1489                 vector src, dst;
1490                 src = stov(argv(1));
1491                 dst = stov(argv(2));
1492                 traceline(src, dst, MOVE_NORMAL, world);
1493                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), src, trace_endpos);
1494                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dst);
1495                 return;
1496         }
1497
1498         if(argv(0) == "extendmatchtime")
1499         {
1500                 changematchtime(autocvar_timelimit_increment* 60, autocvar_timelimit_min*60, autocvar_timelimit_max*60);
1501                 return;
1502         }
1503
1504         if(argv(0) == "reducematchtime")
1505         {
1506                 changematchtime(autocvar_timelimit_decrement*-60, autocvar_timelimit_min*60, autocvar_timelimit_max*60);
1507                 return;
1508         }
1509
1510         if(argv(0) == "modelbug")
1511         {
1512                 modelbug();
1513                 return;
1514         }
1515
1516         print("Invalid command. For a list of supported commands, try sv_cmd help.\n");
1517 }
1518