qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(autocvar_sv_fragmessage_information_ping) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(autocvar_sv_fragmessage_information_handicap)
 104                         if(autocvar_sv_fragmessage_information_handicap == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(autocvar_sv_fragmessage_information_handicap) {
 114                 if(autocvar_sv_fragmessage_information_handicap == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (autocvar_sv_eventlog_files)
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = autocvar_sv_eventlog_files_counter + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (autocvar_sv_eventlog_files_timestamps)
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (autocvar_sv_eventlog_console)
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 193     PL_MIN                                  = stov(autocvar_sv_player_mins);
 194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239
 240     if (autocvar_r_showbboxes)
 241     {
 242         // show where spawnpoints point at too
 243         makevectors(self.angles);
 244         entity e;
 245         e = spawn();
 246         e.classname = "info_player_foo";
 247         setorigin(e, self.origin + v_forward * 24);
 248         setsize(e, '-8 -8 -8', '8 8 8');
 249         e.solid = SOLID_TRIGGER;
 250     }
 251 }
 252
 253 #define strstr strstrofs
 254 /*
 255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 258 // BE CONSTANT OR strzoneD!
 259 float strstr(string haystack, string needle, float offset)
 260 {
 261         float len, endpos;
 262         string found;
 263         len = strlen(needle);
 264         endpos = strlen(haystack) - len;
 265         while(offset <= endpos)
 266         {
 267                 found = substring(haystack, offset, len);
 268                 if(found == needle)
 269                         return offset;
 270                 offset = offset + 1;
 271         }
 272         return -1;
 273 }
 274 */
 275
 276 float NUM_NEAREST_ENTITIES = 4;
 277 entity nearest_entity[NUM_NEAREST_ENTITIES];
 278 float nearest_length[NUM_NEAREST_ENTITIES];
 279 entity findnearest(vector point, .string field, string value, vector axismod)
 280 {
 281     entity localhead;
 282     float i;
 283     float j;
 284     float len;
 285     vector dist;
 286
 287     float num_nearest;
 288     num_nearest = 0;
 289
 290     localhead = find(world, field, value);
 291     while (localhead)
 292     {
 293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 294             dist = localhead.oldorigin;
 295         else
 296             dist = localhead.origin;
 297         dist = dist - point;
 298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 299         len = vlen(dist);
 300
 301         for (i = 0; i < num_nearest; ++i)
 302         {
 303             if (len < nearest_length[i])
 304                 break;
 305         }
 306
 307         // now i tells us where to insert at
 308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 309         if (i < NUM_NEAREST_ENTITIES)
 310         {
 311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 312             {
 313                 nearest_length[j + 1] = nearest_length[j];
 314                 nearest_entity[j + 1] = nearest_entity[j];
 315             }
 316             nearest_length[i] = len;
 317             nearest_entity[i] = localhead;
 318             if (num_nearest < NUM_NEAREST_ENTITIES)
 319                 num_nearest = num_nearest + 1;
 320         }
 321
 322         localhead = find(localhead, field, value);
 323     }
 324
 325     // now use the first one from our list that we can see
 326     for (i = 0; i < num_nearest; ++i)
 327     {
 328         traceline(point, nearest_entity[i].origin, TRUE, world);
 329         if (trace_fraction == 1)
 330         {
 331             if (i != 0)
 332             {
 333                 dprint("Nearest point (");
 334                 dprint(nearest_entity[0].netname);
 335                 dprint(") is not visible, using a visible one.\n");
 336             }
 337             return nearest_entity[i];
 338         }
 339     }
 340
 341     if (num_nearest == 0)
 342         return world;
 343
 344     dprint("Not seeing any location point, using nearest as fallback.\n");
 345     /* DEBUGGING CODE:
 346     dprint("Candidates were: ");
 347     for(j = 0; j < num_nearest; ++j)
 348     {
 349         if(j != 0)
 350                 dprint(", ");
 351         dprint(nearest_entity[j].netname);
 352     }
 353     dprint("\n");
 354     */
 355
 356     return nearest_entity[0];
 357 }
 358
 359 void spawnfunc_target_location()
 360 {
 361     self.classname = "target_location";
 362     // location name in netname
 363     // eventually support: count, teamgame selectors, line of sight?
 364 };
 365
 366 void spawnfunc_info_location()
 367 {
 368     self.classname = "target_location";
 369     self.message = self.netname;
 370 };
 371
 372 string NearestLocation(vector p)
 373 {
 374     entity loc;
 375     string ret;
 376     ret = "somewhere";
 377     loc = findnearest(p, classname, "target_location", '1 1 1');
 378     if (loc)
 379     {
 380         ret = loc.message;
 381     }
 382     else
 383     {
 384         loc = findnearest(p, target, "###item###", '1 1 4');
 385         if (loc)
 386             ret = loc.netname;
 387     }
 388     return ret;
 389 }
 390
 391 string formatmessage(string msg)
 392 {
 393         float p, p1, p2;
 394         float n;
 395         vector cursor;
 396         entity cursor_ent;
 397         string escape;
 398         string replacement;
 399         p = 0;
 400         n = 7;
 401
 402         WarpZone_crosshair_trace(self);
 403         cursor = trace_endpos;
 404         cursor_ent = trace_ent;
 405
 406         while (1) {
 407                 if (n < 1)
 408                         break; // too many replacements
 409
 410                 n = n - 1;
 411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 413
 414                 if (p1 < 0)
 415                         p1 = p2;
 416
 417                 if (p2 < 0)
 418                         p2 = p1;
 419
 420                 p = min(p1, p2);
 421
 422                 if (p < 0)
 423                         break;
 424
 425                 replacement = substring(msg, p, 2);
 426                 escape = substring(msg, p + 1, 1);
 427
 428                 if (escape == "%")
 429                         replacement = "%";
 430                 else if (escape == "\\")
 431                         replacement = "\\";
 432                 else if (escape == "n")
 433                         replacement = "\n";
 434                 else if (escape == "a")
 435                         replacement = ftos(floor(self.armorvalue));
 436                 else if (escape == "h")
 437                         replacement = ftos(floor(self.health));
 438                 else if (escape == "l")
 439                         replacement = NearestLocation(self.origin);
 440                 else if (escape == "y")
 441                         replacement = NearestLocation(cursor);
 442                 else if (escape == "d")
 443                         replacement = NearestLocation(self.death_origin);
 444                 else if (escape == "w") {
 445                         float wep;
 446                         wep = self.weapon;
 447                         if (!wep)
 448                                 wep = self.switchweapon;
 449                         if (!wep)
 450                                 wep = self.cnt;
 451                         replacement = W_Name(wep);
 452                 } else if (escape == "W") {
 453                         if (self.items & IT_SHELLS) replacement = "shells";
 454                         else if (self.items & IT_NAILS) replacement = "bullets";
 455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 456                         else if (self.items & IT_CELLS) replacement = "cells";
 457                         else replacement = "batteries"; // ;)
 458                 } else if (escape == "x") {
 459                         replacement = cursor_ent.netname;
 460                         if (!replacement || !cursor_ent)
 461                                 replacement = "nothing";
 462                 } else if (escape == "p") {
 463                         if (self.last_selected_player)
 464                                 replacement = self.last_selected_player.netname;
 465                         else
 466                                 replacement = "(nobody)";
 467                 } else if (escape == "s")
 468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 469                 else if (escape == "S")
 470                         replacement = ftos(vlen(self.velocity));
 471
 472                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 473                 p = p + strlen(replacement);
 474         }
 475         return msg;
 476 }
 477
 478 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 479         return (value == 0) ? FALSE : TRUE;
 480 }
 481
 482 /*
 483 =============
 484 GetCvars
 485 =============
 486 Called with:
 487   0:  sends the request
 488   >0: receives a cvar from name=argv(f) value=argv(f+1)
 489 */
 490 void GetCvars_handleString(string thisname, float f, .string field, string name)
 491 {
 492         if (f < 0)
 493         {
 494                 if (self.field)
 495                         strunzone(self.field);
 496                 self.field = string_null;
 497         }
 498         else if (f > 0)
 499         {
 500                 if (thisname == name)
 501                 {
 502                         if (self.field)
 503                                 strunzone(self.field);
 504                         self.field = strzone(argv(f + 1));
 505                 }
 506         }
 507         else
 508                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 509 }
 510 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 511 {
 512         GetCvars_handleString(thisname, f, field, name);
 513         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 514                 if (thisname == name)
 515                 {
 516                         string s;
 517                         s = func(strcat1(self.field));
 518                         if (s != self.field)
 519                         {
 520                                 strunzone(self.field);
 521                                 self.field = strzone(s);
 522                         }
 523                 }
 524 }
 525 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 526 {
 527         if (f < 0)
 528         {
 529         }
 530         else if (f > 0)
 531         {
 532                 if (thisname == name)
 533                         self.field = stof(argv(f + 1));
 534         }
 535         else
 536                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 537 }
 538 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 539 {
 540         if (f < 0)
 541         {
 542         }
 543         else if (f > 0)
 544         {
 545                 if (thisname == name)
 546                 {
 547                         if(!self.field)
 548                         {
 549                                 self.field = stof(argv(f + 1));
 550                                 if(!self.field)
 551                                         self.field = -1;
 552                         }
 553                 }
 554         }
 555         else
 556         {
 557                 if(!self.field)
 558                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 559         }
 560 }
 561 float w_getbestweapon(entity e);
 562 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 563 {
 564         string o;
 565         o = W_FixWeaponOrder_ForceComplete(wo);
 566         if(self.weaponorder_byimpulse)
 567         {
 568                 strunzone(self.weaponorder_byimpulse);
 569                 self.weaponorder_byimpulse = string_null;
 570         }
 571         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 572         return o;
 573 }
 574 void GetCvars(float f)
 575 {
 576         string s;
 577
 578         if (f > 0)
 579                 s = strcat1(argv(f));
 580
 581         get_cvars_f = f;
 582         get_cvars_s = s;
 583         MUTATOR_CALLHOOK(GetCvars);
 584         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 585         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 586         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 587         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 588         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 589         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 606         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 608         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 609
 610         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 611         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 612
 613 #ifdef ALLOW_FORCEMODELS
 614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 615         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 616 #endif
 617         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 618         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 619
 620         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 621         if (f > 0)
 622         {
 623                 if (s == "cl_weaponpriority")
 624                         self.switchweapon = w_getbestweapon(self);
 625         }
 626 }
 627
 628 float fexists(string f)
 629 {
 630     float fh;
 631     fh = fopen(f, FILE_READ);
 632     if (fh < 0)
 633         return FALSE;
 634     fclose(fh);
 635     return TRUE;
 636 }
 637
 638 void backtrace(string msg)
 639 {
 640     float dev, war;
 641     dev = autocvar_developer;
 642     war = autocvar_prvm_backtraceforwarnings;
 643     cvar_set("developer", "1");
 644     cvar_set("prvm_backtraceforwarnings", "1");
 645     print("\n");
 646     print("--- CUT HERE ---\nWARNING: ");
 647     print(msg);
 648     print("\n");
 649     remove(world); // isn't there any better way to cause a backtrace?
 650     print("\n--- CUT UNTIL HERE ---\n");
 651     cvar_set("developer", ftos(dev));
 652     cvar_set("prvm_backtraceforwarnings", ftos(war));
 653 }
 654
 655 string Team_ColorCode(float teamid)
 656 {
 657     if (teamid == COLOR_TEAM1)
 658         return "^1";
 659     else if (teamid == COLOR_TEAM2)
 660         return "^4";
 661     else if (teamid == COLOR_TEAM3)
 662         return "^3";
 663     else if (teamid == COLOR_TEAM4)
 664         return "^6";
 665     else
 666         return "^7";
 667 }
 668
 669 string Team_ColorName(float t)
 670 {
 671     // fixme: Search for team entities and get their .netname's!
 672     if (t == COLOR_TEAM1)
 673         return "Red";
 674     if (t == COLOR_TEAM2)
 675         return "Blue";
 676     if (t == COLOR_TEAM3)
 677         return "Yellow";
 678     if (t == COLOR_TEAM4)
 679         return "Pink";
 680     return "Neutral";
 681 }
 682
 683 string Team_ColorNameLowerCase(float t)
 684 {
 685     // fixme: Search for team entities and get their .netname's!
 686     if (t == COLOR_TEAM1)
 687         return "red";
 688     if (t == COLOR_TEAM2)
 689         return "blue";
 690     if (t == COLOR_TEAM3)
 691         return "yellow";
 692     if (t == COLOR_TEAM4)
 693         return "pink";
 694     return "neutral";
 695 }
 696
 697 float ColourToNumber(string team_colour)
 698 {
 699         if (team_colour == "red")
 700                 return COLOR_TEAM1;
 701
 702         if (team_colour == "blue")
 703                 return COLOR_TEAM2;
 704
 705         if (team_colour == "yellow")
 706                 return COLOR_TEAM3;
 707
 708         if (team_colour == "pink")
 709                 return COLOR_TEAM4;
 710
 711         if (team_colour == "auto")
 712                 return 0;
 713
 714         return -1;
 715 }
 716
 717 float NumberToTeamNumber(float number)
 718 {
 719         if (number == 1)
 720                 return COLOR_TEAM1;
 721
 722         if (number == 2)
 723                 return COLOR_TEAM2;
 724
 725         if (number == 3)
 726                 return COLOR_TEAM3;
 727
 728         if (number == 4)
 729                 return COLOR_TEAM4;
 730
 731         return -1;
 732 }
 733
 734 #define CENTERPRIO_POINT 1
 735 #define CENTERPRIO_SPAM 2
 736 #define CENTERPRIO_VOTE 4
 737 #define CENTERPRIO_NORMAL 5
 738 #define CENTERPRIO_SHIELDING 7
 739 #define CENTERPRIO_MAPVOTE 9
 740 #define CENTERPRIO_IDLEKICK 50
 741 #define CENTERPRIO_ADMIN 99
 742 .float centerprint_priority;
 743 .float centerprint_expires;
 744 void centerprint_atprio(entity e, float prio, string s)
 745 {
 746     if (intermission_running)
 747         if (prio < CENTERPRIO_MAPVOTE)
 748             return;
 749     if (time > e.centerprint_expires)
 750         e.centerprint_priority = 0;
 751     if (prio >= e.centerprint_priority)
 752     {
 753         e.centerprint_priority = prio;
 754         if (timeoutStatus == 2)
 755             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 756         else
 757             e.centerprint_expires = time + e.cvar_scr_centertime;
 758         centerprint_builtin(e, s);
 759     }
 760 }
 761 void centerprint_expire(entity e, float prio)
 762 {
 763     if (prio == e.centerprint_priority)
 764     {
 765         e.centerprint_priority = 0;
 766         centerprint_builtin(e, "");
 767     }
 768 }
 769 void centerprint(entity e, string s)
 770 {
 771     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 772 }
 773
 774 // decolorizes and team colors the player name when needed
 775 string playername(entity p)
 776 {
 777     string t;
 778     if (teams_matter && !intermission_running && p.classname == "player")
 779     {
 780         t = Team_ColorCode(p.team);
 781         return strcat(t, strdecolorize(p.netname));
 782     }
 783     else
 784         return p.netname;
 785 }
 786
 787 vector randompos(vector m1, vector m2)
 788 {
 789     local vector v;
 790     m2 = m2 - m1;
 791     v_x = m2_x * random() + m1_x;
 792     v_y = m2_y * random() + m1_y;
 793     v_z = m2_z * random() + m1_z;
 794     return  v;
 795 };
 796
 797 //#NO AUTOCVARS START
 798
 799 float g_pickup_shells;
 800 float g_pickup_shells_max;
 801 float g_pickup_nails;
 802 float g_pickup_nails_max;
 803 float g_pickup_rockets;
 804 float g_pickup_rockets_max;
 805 float g_pickup_cells;
 806 float g_pickup_cells_max;
 807 float g_pickup_fuel;
 808 float g_pickup_fuel_jetpack;
 809 float g_pickup_fuel_max;
 810 float g_pickup_armorsmall;
 811 float g_pickup_armorsmall_max;
 812 float g_pickup_armorsmall_anyway;
 813 float g_pickup_armormedium;
 814 float g_pickup_armormedium_max;
 815 float g_pickup_armormedium_anyway;
 816 float g_pickup_armorbig;
 817 float g_pickup_armorbig_max;
 818 float g_pickup_armorbig_anyway;
 819 float g_pickup_armorlarge;
 820 float g_pickup_armorlarge_max;
 821 float g_pickup_armorlarge_anyway;
 822 float g_pickup_healthsmall;
 823 float g_pickup_healthsmall_max;
 824 float g_pickup_healthsmall_anyway;
 825 float g_pickup_healthmedium;
 826 float g_pickup_healthmedium_max;
 827 float g_pickup_healthmedium_anyway;
 828 float g_pickup_healthlarge;
 829 float g_pickup_healthlarge_max;
 830 float g_pickup_healthlarge_anyway;
 831 float g_pickup_healthmega;
 832 float g_pickup_healthmega_max;
 833 float g_pickup_healthmega_anyway;
 834 float g_pickup_ammo_anyway;
 835 float g_pickup_weapons_anyway;
 836 float g_weaponarena;
 837 float g_weaponarena_random;
 838 float g_weaponarena_random_with_laser;
 839 string g_weaponarena_list;
 840 float g_weaponspeedfactor;
 841 float g_weaponratefactor;
 842 float g_weapondamagefactor;
 843 float g_weaponforcefactor;
 844 float g_weaponspreadfactor;
 845
 846 float start_weapons;
 847 float start_items;
 848 float start_ammo_shells;
 849 float start_ammo_nails;
 850 float start_ammo_rockets;
 851 float start_ammo_cells;
 852 float start_ammo_fuel;
 853 float start_health;
 854 float start_armorvalue;
 855 float warmup_start_weapons;
 856 float warmup_start_ammo_shells;
 857 float warmup_start_ammo_nails;
 858 float warmup_start_ammo_rockets;
 859 float warmup_start_ammo_cells;
 860 float warmup_start_ammo_fuel;
 861 float warmup_start_health;
 862 float warmup_start_armorvalue;
 863 float g_weapon_stay;
 864 float g_ghost_items;
 865
 866 entity get_weaponinfo(float w);
 867
 868 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 869 {
 870         var float i = weaponinfo.weapon;
 871
 872         if (!i)
 873                 return 0;
 874
 875         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 876
 877         if (t < 0) // "default" weapon selection
 878         {
 879                 if (g_lms || g_ca || allguns)
 880                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 881                 else if(t < -1)
 882                         t = 0;
 883                 else if (g_cts)
 884                         t = (i == WEP_SHOTGUN);
 885                 else if (g_nexball)
 886                         t = 0; // weapon is set a few lines later
 887                 else
 888                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 889                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 890                         t |= (i == WEP_HOOK);
 891         }
 892
 893         // we cannot disable porto in Nexball, we must force it
 894         if(g_nexball && i == WEP_PORTO)
 895                 t = 1;
 896
 897         return t;
 898 }
 899
 900 void readplayerstartcvars()
 901 {
 902         entity e;
 903         float i, j, t;
 904         string s;
 905
 906         // initialize starting values for players
 907         start_weapons = 0;
 908         start_items = 0;
 909         start_ammo_shells = 0;
 910         start_ammo_nails = 0;
 911         start_ammo_rockets = 0;
 912         start_ammo_cells = 0;
 913         start_health = cvar("g_balance_health_start");
 914         start_armorvalue = cvar("g_balance_armor_start");
 915
 916         g_weaponarena = 0;
 917         s = cvar_string("g_weaponarena");
 918         if (s == "0" || s == "")
 919         {
 920                 if(g_lms || g_ca)
 921                         s = "most";
 922         }
 923
 924         if (s == "off")
 925         {
 926                 // forcibly turn off weaponarena
 927         }
 928         else if (s == "all")
 929         {
 930                 g_weaponarena_list = "All Weapons";
 931                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 932                 {
 933                         e = get_weaponinfo(j);
 934                         g_weaponarena |= e.weapons;
 935                         weapon_action(e.weapon, WR_PRECACHE);
 936                 }
 937         }
 938         else if (s == "most")
 939         {
 940                 g_weaponarena_list = "Most Weapons";
 941                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 942                 {
 943                         e = get_weaponinfo(j);
 944                         if (e.spawnflags & WEP_FLAG_NORMAL)
 945                         {
 946                                 g_weaponarena |= e.weapons;
 947                                 weapon_action(e.weapon, WR_PRECACHE);
 948                         }
 949                 }
 950         }
 951         else if (s == "none")
 952         {
 953                 g_weaponarena_list = "No Weapons";
 954                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 955         }
 956         else
 957         {
 958                 t = tokenize_console(s);
 959                 g_weaponarena_list = "";
 960                 for (i = 0; i < t; ++i)
 961                 {
 962                         s = argv(i);
 963                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 964                         {
 965                                 e = get_weaponinfo(j);
 966                                 if (e.netname == s)
 967                                 {
 968                                         g_weaponarena |= e.weapons;
 969                                         weapon_action(e.weapon, WR_PRECACHE);
 970                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 971                                         break;
 972                                 }
 973                         }
 974                         if (j > WEP_LAST)
 975                         {
 976                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 977                         }
 978                 }
 979                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 980         }
 981
 982         if(g_weaponarena)
 983                 g_weaponarena_random = cvar("g_weaponarena_random");
 984         else
 985                 g_weaponarena_random = 0;
 986         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 987
 988         if (g_weaponarena)
 989         {
 990                 start_weapons = g_weaponarena;
 991                 if(!(g_lms || g_ca))
 992                         start_items |= IT_UNLIMITED_AMMO;
 993         }
 994         else if (g_minstagib)
 995         {
 996                 start_health = 100;
 997                 start_armorvalue = 0;
 998                 start_weapons = WEPBIT_MINSTANEX;
 999                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1000                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1001                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1002                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1003
1004                 if (g_minstagib_invis_alpha <= 0)
1005                         g_minstagib_invis_alpha = -1;
1006         }
1007         else
1008         {
1009                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1010                 {
1011                         e = get_weaponinfo(i);
1012                         if(want_weapon("g_start_weapon_", e, FALSE))
1013                                 start_weapons |= e.weapons;
1014                 }
1015         }
1016
1017         if(!cvar("g_use_ammunition"))
1018                 start_items |= IT_UNLIMITED_AMMO;
1019
1020         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
1021         {
1022                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1023                 {
1024                         e = get_weaponinfo(j);
1025                         if(start_weapons & e.weapons)
1026                         {
1027                                 if(e.items & IT_ROCKETS)
1028                                         start_ammo_rockets = 999;
1029                                 if(e.items & IT_SHELLS)
1030                                         start_ammo_shells = 999;
1031                                 if(e.items & IT_CELLS)
1032                                         start_ammo_cells = 999;
1033                                 if(e.items & IT_NAILS)
1034                                         start_ammo_nails = 999;
1035                                 if(e.items & IT_FUEL)
1036                                         start_ammo_fuel = 999;
1037                         }
1038                 }
1039         }
1040         else
1041         {
1042                 if(g_lms || g_ca)
1043                 {
1044                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1045                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1046                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1047                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1048                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1049                 }
1050                 else
1051                 {
1052                         start_ammo_shells = cvar("g_start_ammo_shells");
1053                         start_ammo_nails = cvar("g_start_ammo_nails");
1054                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1055                         start_ammo_cells = cvar("g_start_ammo_cells");
1056                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1057                 }
1058         }
1059
1060         if (g_lms || g_ca)
1061         {
1062                 start_health = cvar("g_lms_start_health");
1063                 start_armorvalue = cvar("g_lms_start_armor");
1064         }
1065
1066         if (inWarmupStage)
1067         {
1068                 warmup_start_ammo_shells = start_ammo_shells;
1069                 warmup_start_ammo_nails = start_ammo_nails;
1070                 warmup_start_ammo_rockets = start_ammo_rockets;
1071                 warmup_start_ammo_cells = start_ammo_cells;
1072                 warmup_start_ammo_fuel = start_ammo_fuel;
1073                 warmup_start_health = start_health;
1074                 warmup_start_armorvalue = start_armorvalue;
1075                 warmup_start_weapons = start_weapons;
1076
1077                 if (!g_weaponarena && !g_minstagib && !g_ca)
1078                 {
1079                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1080                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1081                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1082                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1083                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1084                         warmup_start_health = cvar("g_warmup_start_health");
1085                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1086                         warmup_start_weapons = 0;
1087                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1088                         {
1089                                 e = get_weaponinfo(i);
1090                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1091                                         warmup_start_weapons |= e.weapons;
1092                         }
1093                 }
1094         }
1095
1096         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1097         {
1098                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1099                 start_items |= IT_FUEL_REGEN;
1100                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1101                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1102         }
1103
1104         if (g_jetpack)
1105                 start_items |= IT_JETPACK;
1106
1107         if (g_weapon_stay == 2)
1108         {
1109                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1110                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1111                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1112                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1113                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1114                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1115                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1116                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1117                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1118                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1119         }
1120
1121         MUTATOR_CALLHOOK(SetStartItems);
1122
1123         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1124         {
1125                 e = get_weaponinfo(i);
1126                 if(e.weapons & (start_weapons | warmup_start_weapons))
1127                         weapon_action(e.weapon, WR_PRECACHE);
1128         }
1129
1130         start_ammo_shells = max(0, start_ammo_shells);
1131         start_ammo_nails = max(0, start_ammo_nails);
1132         start_ammo_cells = max(0, start_ammo_cells);
1133         start_ammo_rockets = max(0, start_ammo_rockets);
1134         start_ammo_fuel = max(0, start_ammo_fuel);
1135
1136         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1137         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1138         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1139         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1140         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1141 }
1142
1143 float g_bugrigs;
1144 float g_bugrigs_planar_movement;
1145 float g_bugrigs_planar_movement_car_jumping;
1146 float g_bugrigs_reverse_spinning;
1147 float g_bugrigs_reverse_speeding;
1148 float g_bugrigs_reverse_stopping;
1149 float g_bugrigs_air_steering;
1150 float g_bugrigs_angle_smoothing;
1151 float g_bugrigs_friction_floor;
1152 float g_bugrigs_friction_brake;
1153 float g_bugrigs_friction_air;
1154 float g_bugrigs_accel;
1155 float g_bugrigs_speed_ref;
1156 float g_bugrigs_speed_pow;
1157 float g_bugrigs_steer;
1158
1159 float g_touchexplode;
1160 float g_touchexplode_radius;
1161 float g_touchexplode_damage;
1162 float g_touchexplode_edgedamage;
1163 float g_touchexplode_force;
1164
1165 float sv_autotaunt;
1166 float sv_taunt;
1167
1168 float sv_pitch_min;
1169 float sv_pitch_max;
1170 float sv_pitch_fixyaw;
1171
1172 string GetGametype(); // g_world.qc
1173 void readlevelcvars(void)
1174 {
1175         // first load all the mutators
1176         if(cvar("g_nix"))
1177                 MUTATOR_ADD(mutator_nix);
1178         if(cvar("g_dodging"))
1179                 MUTATOR_ADD(mutator_dodging);
1180         if(cvar("g_rocket_flying"))
1181                 MUTATOR_ADD(mutator_rocketflying);
1182         if(cvar("g_vampire"))
1183                 MUTATOR_ADD(mutator_vampire);
1184
1185         if(cvar("sv_allow_fullbright"))
1186                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1187
1188     g_bugrigs = cvar("g_bugrigs");
1189     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1190     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1191     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1192     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1193     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1194     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1195     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1196     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1197     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1198     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1199     g_bugrigs_accel = cvar("g_bugrigs_accel");
1200     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1201     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1202     g_bugrigs_steer = cvar("g_bugrigs_steer");
1203
1204     g_touchexplode = cvar("g_touchexplode");
1205     g_touchexplode_radius = cvar("g_touchexplode_radius");
1206     g_touchexplode_damage = cvar("g_touchexplode_damage");
1207     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1208     g_touchexplode_force = cvar("g_touchexplode_force");
1209
1210 #ifdef ALLOW_FORCEMODELS
1211         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1212 #endif
1213         sv_loddistance1 = cvar("sv_loddistance1");
1214         sv_loddistance2 = cvar("sv_loddistance2");
1215
1216         if(sv_loddistance2 <= sv_loddistance1)
1217                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1218
1219         sv_clones = cvar("sv_clones");
1220         sv_gentle = cvar("sv_gentle");
1221         sv_foginterval = cvar("sv_foginterval");
1222         g_cloaked = cvar("g_cloaked");
1223     if(g_cts)
1224         g_cloaked = 1; // always enable cloak in CTS
1225         g_jump_grunt = cvar("g_jump_grunt");
1226         g_footsteps = cvar("g_footsteps");
1227         g_grappling_hook = cvar("g_grappling_hook");
1228         g_jetpack = cvar("g_jetpack");
1229         g_midair = cvar("g_midair");
1230         g_minstagib = cvar("g_minstagib");
1231         g_norecoil = cvar("g_norecoil");
1232         g_bloodloss = cvar("g_bloodloss");
1233         sv_maxidle = cvar("sv_maxidle");
1234         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1235         sv_pogostick = cvar("sv_pogostick");
1236         g_ctf_reverse = cvar("g_ctf_reverse");
1237         sv_autotaunt = cvar("sv_autotaunt");
1238         sv_taunt = cvar("sv_taunt");
1239
1240         inWarmupStage = cvar("g_warmup");
1241         g_warmup_limit = cvar("g_warmup_limit");
1242         g_warmup_allguns = cvar("g_warmup_allguns");
1243         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1244
1245         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1246                 inWarmupStage = 0; // these modes cannot work together, sorry
1247
1248         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1249         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1250         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1251         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1252         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1253         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1254         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1255         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1256         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1257         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1258         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1259         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1260
1261         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1262         g_weaponratefactor = cvar("g_weaponratefactor");
1263         g_weapondamagefactor = cvar("g_weapondamagefactor");
1264         g_weaponforcefactor = cvar("g_weaponforcefactor");
1265         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1266
1267         g_pickup_shells = cvar("g_pickup_shells");
1268         g_pickup_shells_max = cvar("g_pickup_shells_max");
1269         g_pickup_nails = cvar("g_pickup_nails");
1270         g_pickup_nails_max = cvar("g_pickup_nails_max");
1271         g_pickup_rockets = cvar("g_pickup_rockets");
1272         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1273         g_pickup_cells = cvar("g_pickup_cells");
1274         g_pickup_cells_max = cvar("g_pickup_cells_max");
1275         g_pickup_fuel = cvar("g_pickup_fuel");
1276         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1277         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1278         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1279         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1280         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1281         g_pickup_armormedium = cvar("g_pickup_armormedium");
1282         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1283         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1284         g_pickup_armorbig = cvar("g_pickup_armorbig");
1285         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1286         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1287         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1288         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1289         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1290         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1291         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1292         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1293         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1294         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1295         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1296         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1297         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1298         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1299         g_pickup_healthmega = cvar("g_pickup_healthmega");
1300         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1301         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1302
1303         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1304         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1305
1306         g_pinata = cvar("g_pinata");
1307
1308     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1309     if(!g_weapon_stay)
1310         g_weapon_stay = cvar("g_weapon_stay");
1311
1312         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1313                 g_weapon_stay = 1;
1314
1315         g_ghost_items = cvar("g_ghost_items");
1316
1317         if(g_ghost_items >= 1)
1318                 g_ghost_items = 0.25; // default alpha value
1319
1320         if not(inWarmupStage && !g_ca)
1321                 game_starttime = cvar("g_start_delay");
1322
1323         sv_pitch_min = cvar("sv_pitch_min");
1324         sv_pitch_max = cvar("sv_pitch_max");
1325         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1326
1327         readplayerstartcvars();
1328 }
1329
1330 //#NO AUTOCVARS END
1331
1332 // Sound functions
1333 string precache_sound (string s) = #19;
1334 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1335 float precache_sound_index (string s) = #19;
1336
1337 #define SND_VOLUME      1
1338 #define SND_ATTENUATION 2
1339 #define SND_LARGEENTITY 8
1340 #define SND_LARGESOUND  16
1341
1342 float sound_allowed(float dest, entity e)
1343 {
1344     // sounds from world may always pass
1345     for (;;)
1346     {
1347         if (e.classname == "body")
1348             e = e.enemy;
1349         if (e.owner && e.owner != e)
1350             e = e.owner;
1351         else
1352             break;
1353     }
1354     // sounds to self may always pass
1355     if (dest == MSG_ONE)
1356         if (e == msg_entity)
1357             return TRUE;
1358     // sounds by players can be removed
1359     if (autocvar_bot_sound_monopoly)
1360         if (clienttype(e) == CLIENTTYPE_REAL)
1361             return FALSE;
1362     // anything else may pass
1363     return TRUE;
1364 }
1365
1366 void sound(entity e, float chan, string samp, float vol, float atten)
1367 {
1368     if (!sound_allowed(MSG_BROADCAST, e))
1369         return;
1370     sound_builtin(e, chan, samp, vol, atten);
1371 }
1372 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1373 {
1374     float entno, idx;
1375
1376     if (!sound_allowed(dest, e))
1377         return;
1378
1379     entno = num_for_edict(e);
1380     idx = precache_sound_index(samp);
1381
1382     float sflags;
1383     sflags = 0;
1384
1385     atten = floor(atten * 64);
1386     vol = floor(vol * 255);
1387
1388     if (vol != 255)
1389         sflags |= SND_VOLUME;
1390     if (atten != 64)
1391         sflags |= SND_ATTENUATION;
1392     if (entno >= 8192)
1393         sflags |= SND_LARGEENTITY;
1394     if (idx >= 256)
1395         sflags |= SND_LARGESOUND;
1396
1397     WriteByte(dest, SVC_SOUND);
1398     WriteByte(dest, sflags);
1399     if (sflags & SND_VOLUME)
1400         WriteByte(dest, vol);
1401     if (sflags & SND_ATTENUATION)
1402         WriteByte(dest, atten);
1403     if (sflags & SND_LARGEENTITY)
1404     {
1405         WriteShort(dest, entno);
1406         WriteByte(dest, chan);
1407     }
1408     else
1409     {
1410         WriteShort(dest, entno * 8 + chan);
1411     }
1412     if (sflags & SND_LARGESOUND)
1413         WriteShort(dest, idx);
1414     else
1415         WriteByte(dest, idx);
1416
1417     WriteCoord(dest, o_x);
1418     WriteCoord(dest, o_y);
1419     WriteCoord(dest, o_z);
1420 }
1421 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1422 {
1423     vector o;
1424
1425     if (!sound_allowed(dest, e))
1426         return;
1427
1428     o = e.origin + 0.5 * (e.mins + e.maxs);
1429     soundtoat(dest, e, o, chan, samp, vol, atten);
1430 }
1431 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1432 {
1433     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1434 }
1435 void stopsoundto(float dest, entity e, float chan)
1436 {
1437     float entno;
1438
1439     if (!sound_allowed(dest, e))
1440         return;
1441
1442     entno = num_for_edict(e);
1443
1444     if (entno >= 8192)
1445     {
1446         float idx, sflags;
1447         idx = precache_sound_index("misc/null.wav");
1448         sflags = SND_LARGEENTITY;
1449         if (idx >= 256)
1450             sflags |= SND_LARGESOUND;
1451         WriteByte(dest, SVC_SOUND);
1452         WriteByte(dest, sflags);
1453         WriteShort(dest, entno);
1454         WriteByte(dest, chan);
1455         if (sflags & SND_LARGESOUND)
1456             WriteShort(dest, idx);
1457         else
1458             WriteByte(dest, idx);
1459         WriteCoord(dest, e.origin_x);
1460         WriteCoord(dest, e.origin_y);
1461         WriteCoord(dest, e.origin_z);
1462     }
1463     else
1464     {
1465         WriteByte(dest, SVC_STOPSOUND);
1466         WriteShort(dest, entno * 8 + chan);
1467     }
1468 }
1469 void stopsound(entity e, float chan)
1470 {
1471     if (!sound_allowed(MSG_BROADCAST, e))
1472         return;
1473
1474     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1475     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1476 }
1477
1478 void play2(entity e, string filename)
1479 {
1480     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1481     msg_entity = e;
1482     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1483 }
1484
1485 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1486 .float spamtime;
1487 float spamsound(entity e, float chan, string samp, float vol, float atten)
1488 {
1489     if (!sound_allowed(MSG_BROADCAST, e))
1490         return FALSE;
1491
1492     if (time > e.spamtime)
1493     {
1494         e.spamtime = time;
1495         sound(e, chan, samp, vol, atten);
1496         return TRUE;
1497     }
1498     return FALSE;
1499 }
1500
1501 void play2team(float t, string filename)
1502 {
1503     local entity head;
1504
1505     if (autocvar_bot_sound_monopoly)
1506         return;
1507
1508     FOR_EACH_REALPLAYER(head)
1509     {
1510         if (head.team == t)
1511             play2(head, filename);
1512     }
1513 }
1514
1515 void play2all(string samp)
1516 {
1517     if (autocvar_bot_sound_monopoly)
1518         return;
1519
1520     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1521 }
1522
1523 void PrecachePlayerSounds(string f);
1524 void precache_playermodel(string m)
1525 {
1526         float globhandle, i, n;
1527         string f;
1528
1529         if(substring(m, -9,5) == "_lod1")
1530                 return;
1531         if(substring(m, -9,5) == "_lod2")
1532                 return;
1533         precache_model(m);
1534         if(sv_loddistance1)
1535         {
1536                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1537                 if(fexists(f))
1538                         precache_model(f);
1539                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1540                 if(fexists(f))
1541                         precache_model(f);
1542         }
1543
1544         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1545         if (globhandle < 0)
1546                 return;
1547         n = search_getsize(globhandle);
1548         for (i = 0; i < n; ++i)
1549         {
1550                 //print(search_getfilename(globhandle, i), "\n");
1551                 f = search_getfilename(globhandle, i);
1552                 PrecachePlayerSounds(f);
1553         }
1554         search_end(globhandle);
1555 }
1556 void precache_all_playermodels(string pattern)
1557 {
1558         float globhandle, i, n;
1559         string f;
1560
1561         globhandle = search_begin(pattern, TRUE, FALSE);
1562         if (globhandle < 0)
1563                 return;
1564         n = search_getsize(globhandle);
1565         for (i = 0; i < n; ++i)
1566         {
1567                 //print(search_getfilename(globhandle, i), "\n");
1568                 f = search_getfilename(globhandle, i);
1569                 precache_playermodel(f);
1570         }
1571         search_end(globhandle);
1572 }
1573
1574 void precache()
1575 {
1576     // gamemode related things
1577     precache_model ("models/misc/chatbubble.spr");
1578     precache_model ("models/misc/teambubble.spr");
1579     if (g_runematch)
1580     {
1581         precache_model ("models/runematch/curse.mdl");
1582         precache_model ("models/runematch/rune.mdl");
1583     }
1584
1585 #ifdef TTURRETS_ENABLED
1586     if (autocvar_g_turrets)
1587         turrets_precash();
1588 #endif
1589
1590     // Precache all player models if desired
1591     if (autocvar_sv_precacheplayermodels)
1592     {
1593         PrecachePlayerSounds("sound/player/default.sounds");
1594         precache_all_playermodels("models/player/*.zym");
1595         precache_all_playermodels("models/player/*.dpm");
1596         precache_all_playermodels("models/player/*.md3");
1597         precache_all_playermodels("models/player/*.psk");
1598         precache_all_playermodels("models/player/*.iqm");
1599     }
1600
1601     if (autocvar_sv_defaultcharacter)
1602     {
1603         string s;
1604         s = autocvar_sv_defaultplayermodel_red;
1605         if (s != "")
1606             precache_playermodel(s);
1607         s = autocvar_sv_defaultplayermodel_blue;
1608         if (s != "")
1609             precache_playermodel(s);
1610         s = autocvar_sv_defaultplayermodel_yellow;
1611         if (s != "")
1612             precache_playermodel(s);
1613         s = autocvar_sv_defaultplayermodel_pink;
1614         if (s != "")
1615             precache_playermodel(s);
1616         s = autocvar_sv_defaultplayermodel;
1617         if (s != "")
1618             precache_playermodel(s);
1619     }
1620
1621     if (g_footsteps)
1622     {
1623         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1624         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1625     }
1626
1627     // gore and miscellaneous sounds
1628     //precache_sound ("misc/h2ohit.wav");
1629     precache_model ("models/hook.md3");
1630     precache_sound ("misc/armorimpact.wav");
1631     precache_sound ("misc/bodyimpact1.wav");
1632     precache_sound ("misc/bodyimpact2.wav");
1633     precache_sound ("misc/gib.wav");
1634     precache_sound ("misc/gib_splat01.wav");
1635     precache_sound ("misc/gib_splat02.wav");
1636     precache_sound ("misc/gib_splat03.wav");
1637     precache_sound ("misc/gib_splat04.wav");
1638     precache_sound ("misc/hit.wav");
1639         precache_sound ("misc/typehit.wav");
1640     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1641     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1642     precache_sound ("misc/null.wav");
1643     precache_sound ("misc/spawn.wav");
1644     precache_sound ("misc/talk.wav");
1645     precache_sound ("misc/teleport.wav");
1646     precache_sound ("misc/poweroff.wav");
1647     precache_sound ("player/lava.wav");
1648     precache_sound ("player/slime.wav");
1649
1650     if (g_jetpack)
1651         precache_sound ("misc/jetpack_fly.wav");
1652
1653     precache_model ("models/sprites/0.spr32");
1654     precache_model ("models/sprites/1.spr32");
1655     precache_model ("models/sprites/2.spr32");
1656     precache_model ("models/sprites/3.spr32");
1657     precache_model ("models/sprites/4.spr32");
1658     precache_model ("models/sprites/5.spr32");
1659     precache_model ("models/sprites/6.spr32");
1660     precache_model ("models/sprites/7.spr32");
1661     precache_model ("models/sprites/8.spr32");
1662     precache_model ("models/sprites/9.spr32");
1663     precache_model ("models/sprites/10.spr32");
1664
1665     // common weapon precaches
1666     precache_sound ("weapons/weapon_switch.wav");
1667     precache_sound ("weapons/weaponpickup.wav");
1668     precache_sound ("weapons/unavailable.wav");
1669     precache_sound ("weapons/dryfire.wav");
1670     if (g_grappling_hook)
1671     {
1672         precache_sound ("weapons/hook_fire.wav"); // hook
1673         precache_sound ("weapons/hook_impact.wav"); // hook
1674     }
1675
1676     if(autocvar_sv_precacheweapons)
1677     {
1678         //precache weapon models/sounds
1679         local float wep;
1680         wep = WEP_FIRST;
1681         while (wep <= WEP_LAST)
1682         {
1683             weapon_action(wep, WR_PRECACHE);
1684             wep = wep + 1;
1685         }
1686     }
1687
1688     precache_model("models/elaser.mdl");
1689     precache_model("models/laser.mdl");
1690     precache_model("models/ebomb.mdl");
1691
1692 #if 0
1693     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1694
1695     if (!self.noise && self.music) // quake 3 uses the music field
1696         self.noise = self.music;
1697
1698     // plays music for the level if there is any
1699     if (self.noise)
1700     {
1701         precache_sound (self.noise);
1702         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1703     }
1704 #endif
1705 }
1706
1707 // sorry, but using \ in macros breaks line numbers
1708 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1709 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1710 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1711
1712 // WARNING: this kills the trace globals
1713 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1714 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1715
1716 #define INITPRIO_FIRST              0
1717 #define INITPRIO_GAMETYPE           0
1718 #define INITPRIO_GAMETYPE_FALLBACK  1
1719 #define INITPRIO_FINDTARGET        10
1720 #define INITPRIO_DROPTOFLOOR       20
1721 #define INITPRIO_SETLOCATION       90
1722 #define INITPRIO_LINKDOORS         91
1723 #define INITPRIO_LAST              99
1724
1725 .void(void) initialize_entity;
1726 .float initialize_entity_order;
1727 .entity initialize_entity_next;
1728 entity initialize_entity_first;
1729
1730 void make_safe_for_remove(entity e)
1731 {
1732     if (e.initialize_entity)
1733     {
1734         entity ent, prev;
1735         for (ent = initialize_entity_first; ent; )
1736         {
1737             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1738             {
1739                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1740                 // skip it in linked list
1741                 if (prev)
1742                 {
1743                     prev.initialize_entity_next = ent.initialize_entity_next;
1744                     ent = prev.initialize_entity_next;
1745                 }
1746                 else
1747                 {
1748                     initialize_entity_first = ent.initialize_entity_next;
1749                     ent = initialize_entity_first;
1750                 }
1751             }
1752             else
1753             {
1754                 prev = ent;
1755                 ent = ent.initialize_entity_next;
1756             }
1757         }
1758     }
1759 }
1760
1761 void objerror(string s)
1762 {
1763     make_safe_for_remove(self);
1764     objerror_builtin(s);
1765 }
1766
1767 .float remove_except_protected_forbidden;
1768 void remove_except_protected(entity e)
1769 {
1770         if(e.remove_except_protected_forbidden)
1771                 error("not allowed to remove this at this point");
1772         remove_builtin(e);
1773 }
1774
1775 void remove_unsafely(entity e)
1776 {
1777     remove_builtin(e);
1778 }
1779
1780 void remove_safely(entity e)
1781 {
1782     make_safe_for_remove(e);
1783     remove_builtin(e);
1784 }
1785
1786 void InitializeEntity(entity e, void(void) func, float order)
1787 {
1788     entity prev, cur;
1789
1790     if (!e || e.initialize_entity)
1791     {
1792         // make a proxy initializer entity
1793         entity e_old;
1794         e_old = e;
1795         e = spawn();
1796         e.classname = "initialize_entity";
1797         e.enemy = e_old;
1798     }
1799
1800     e.initialize_entity = func;
1801     e.initialize_entity_order = order;
1802
1803     cur = initialize_entity_first;
1804     for (;;)
1805     {
1806         if (!cur || cur.initialize_entity_order > order)
1807         {
1808             // insert between prev and cur
1809             if (prev)
1810                 prev.initialize_entity_next = e;
1811             else
1812                 initialize_entity_first = e;
1813             e.initialize_entity_next = cur;
1814             return;
1815         }
1816         prev = cur;
1817         cur = cur.initialize_entity_next;
1818     }
1819 }
1820 void InitializeEntitiesRun()
1821 {
1822     entity startoflist;
1823     startoflist = initialize_entity_first;
1824     initialize_entity_first = world;
1825     remove = remove_except_protected;
1826     for (self = startoflist; self; self = self.initialize_entity_next)
1827     {
1828         self.remove_except_protected_forbidden = 1;
1829     }
1830     for (self = startoflist; self; )
1831     {
1832         entity e;
1833         var void(void) func;
1834         e = self.initialize_entity_next;
1835         func = self.initialize_entity;
1836         self.initialize_entity_order = 0;
1837         self.initialize_entity = func_null;
1838         self.initialize_entity_next = world;
1839         self.remove_except_protected_forbidden = 0;
1840         if (self.classname == "initialize_entity")
1841         {
1842             entity e_old;
1843             e_old = self.enemy;
1844             remove_builtin(self);
1845             self = e_old;
1846         }
1847         //dprint("Delayed initialization: ", self.classname, "\n");
1848         if(func != func_null)
1849             func();
1850         else
1851         {
1852             eprint(self);
1853             backtrace(strcat("Null function in: ", self.classname, "\n"));
1854         }
1855         self = e;
1856     }
1857     remove = remove_unsafely;
1858 }
1859
1860 .float uncustomizeentityforclient_set;
1861 .void(void) uncustomizeentityforclient;
1862 void(void) SUB_Nullpointer = #0;
1863 void UncustomizeEntitiesRun()
1864 {
1865     entity oldself;
1866     oldself = self;
1867     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1868         self.uncustomizeentityforclient();
1869     self = oldself;
1870 }
1871 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1872 {
1873     e.customizeentityforclient = customizer;
1874     e.uncustomizeentityforclient = uncustomizer;
1875     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1876 }
1877
1878 .float nottargeted;
1879 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1880
1881 void() SUB_Remove;
1882 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1883 {
1884     vector mi, ma;
1885
1886     if (e.classname == "")
1887         e.classname = "net_linked";
1888
1889     if (e.model == "" || self.modelindex == 0)
1890     {
1891         mi = e.mins;
1892         ma = e.maxs;
1893         setmodel(e, "null");
1894         setsize(e, mi, ma);
1895     }
1896
1897     e.SendEntity = sendfunc;
1898     e.SendFlags = 0xFFFFFF;
1899
1900     if (!docull)
1901         e.effects |= EF_NODEPTHTEST;
1902
1903     if (dt)
1904     {
1905         e.nextthink = time + dt;
1906         e.think = SUB_Remove;
1907     }
1908 }
1909
1910 void adaptor_think2touch()
1911 {
1912     entity o;
1913     o = other;
1914     other = world;
1915     self.touch();
1916     other = o;
1917 }
1918
1919 void adaptor_think2use()
1920 {
1921     entity o, a;
1922     o = other;
1923     a = activator;
1924     activator = world;
1925     other = world;
1926     self.use();
1927     other = o;
1928     activator = a;
1929 }
1930
1931 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1932 {
1933         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1934                 self.projectiledeathtype |= HITTYPE_SPLASH;
1935         adaptor_think2use();
1936 }
1937
1938 // deferred dropping
1939 void DropToFloor_Handler()
1940 {
1941     droptofloor_builtin();
1942     self.dropped_origin = self.origin;
1943 }
1944
1945 void droptofloor()
1946 {
1947     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1948 }
1949
1950
1951
1952 float trace_hits_box_a0, trace_hits_box_a1;
1953
1954 float trace_hits_box_1d(float end, float thmi, float thma)
1955 {
1956     if (end == 0)
1957     {
1958         // just check if x is in range
1959         if (0 < thmi)
1960             return FALSE;
1961         if (0 > thma)
1962             return FALSE;
1963     }
1964     else
1965     {
1966         // do the trace with respect to x
1967         // 0 -> end has to stay in thmi -> thma
1968         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1969         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1970         if (trace_hits_box_a0 > trace_hits_box_a1)
1971             return FALSE;
1972     }
1973     return TRUE;
1974 }
1975
1976 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1977 {
1978     end -= start;
1979     thmi -= start;
1980     thma -= start;
1981     // now it is a trace from 0 to end
1982
1983     trace_hits_box_a0 = 0;
1984     trace_hits_box_a1 = 1;
1985
1986     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1987         return FALSE;
1988     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1989         return FALSE;
1990     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1991         return FALSE;
1992
1993     return TRUE;
1994 }
1995
1996 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1997 {
1998     return trace_hits_box(start, end, thmi - ma, thma - mi);
1999 }
2000
2001 float SUB_NoImpactCheck()
2002 {
2003         // zero hitcontents = this is not the real impact, but either the
2004         // mirror-impact of something hitting the projectile instead of the
2005         // projectile hitting the something, or a touchareagrid one. Neither of
2006         // these stop the projectile from moving, so...
2007         if(trace_dphitcontents == 0)
2008         {
2009                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
2010                 checkclient();
2011         }
2012     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2013         return 1;
2014     if (other == world && self.size != '0 0 0')
2015     {
2016         vector tic;
2017         tic = self.velocity * sys_frametime;
2018         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2019         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2020         if (trace_fraction >= 1)
2021         {
2022             dprint("Odd... did not hit...?\n");
2023         }
2024         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2025         {
2026             dprint("Detected and prevented the sky-grapple bug.\n");
2027             return 1;
2028         }
2029     }
2030
2031     return 0;
2032 }
2033
2034 #define SUB_OwnerCheck() (other && (other == self.owner))
2035
2036 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2037 {
2038         if(SUB_OwnerCheck())
2039                 return TRUE;
2040         if(SUB_NoImpactCheck())
2041         {
2042                 remove(self);
2043                 return TRUE;
2044         }
2045         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2046                 UpdateCSQCProjectileNextFrame(self);
2047         return FALSE;
2048 }
2049 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2050
2051 float MAX_IPBAN_URIS           = 16;
2052
2053 float URI_GET_DISCARD          = 0;
2054 float URI_GET_IPBAN            = 1;
2055 float URI_GET_IPBAN_END        = 16;
2056 float URI_GET_PLAYERSTATS_SENT = 17;
2057
2058 void URI_Get_Callback(float id, float status, string data)
2059 {
2060     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2061     dprint(data);
2062     dprint("\nEnd of data.\n");
2063
2064     if (id == URI_GET_DISCARD)
2065     {
2066         // discard
2067     }
2068     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2069     {
2070         // online ban list
2071         OnlineBanList_URI_Get_Callback(id, status, data);
2072     }
2073     else if (id == URI_GET_PLAYERSTATS_SENT)
2074     {
2075         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2076     }
2077     else
2078     {
2079         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2080     }
2081 }
2082
2083 void print_to(entity e, string s)
2084 {
2085     if (e)
2086         sprint(e, strcat(s, "\n"));
2087     else
2088         print(s, "\n");
2089 }
2090
2091 string uid2name(string myuid) {
2092         string s;
2093         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2094
2095         if(s == "")
2096                 s = "^1Unregistered Player";
2097         return s;
2098 }
2099
2100 float race_readTime(string map, float pos)
2101 {
2102         string rr;
2103         if(g_cts)
2104                 rr = CTS_RECORD;
2105         else
2106                 rr = RACE_RECORD;
2107
2108         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2109 }
2110
2111 string race_readUID(string map, float pos)
2112 {
2113         string rr;
2114         if(g_cts)
2115                 rr = CTS_RECORD;
2116         else
2117                 rr = RACE_RECORD;
2118
2119         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2120 }
2121
2122 float race_readPos(string map, float t) {
2123         float i;
2124         for (i = 1; i <= RANKINGS_CNT; ++i)
2125                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2126                         return i;
2127
2128         return 0; // pos is zero if unranked
2129 }
2130
2131 void race_writeTime(string map, float t, string myuid)
2132 {
2133         string rr;
2134         if(g_cts)
2135                 rr = CTS_RECORD;
2136         else
2137                 rr = RACE_RECORD;
2138
2139         float newpos;
2140         newpos = race_readPos(map, t);
2141
2142         float i, prevpos;
2143         for(i = 1; i <= RANKINGS_CNT; ++i)
2144         {
2145                 if(race_readUID(map, i) == myuid)
2146                         prevpos = i;
2147         }
2148         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2149                 for (i = prevpos; i > newpos; --i) {
2150                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2151                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2152                 }
2153         } else { // player has no ranked record yet
2154                 for (i = RANKINGS_CNT; i > newpos; --i) {
2155                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2156                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2157                 }
2158         }
2159
2160         // store new time itself
2161         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2162         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2163 }
2164
2165 string race_readName(string map, float pos)
2166 {
2167         string rr;
2168         if(g_cts)
2169                 rr = CTS_RECORD;
2170         else
2171                 rr = RACE_RECORD;
2172
2173         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2174 }
2175
2176 string race_placeName(float pos) {
2177         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2178         {
2179                 if(mod(pos, 10) == 1)
2180                         return strcat(ftos(pos), "st");
2181                 else if(mod(pos, 10) == 2)
2182                         return strcat(ftos(pos), "nd");
2183                 else if(mod(pos, 10) == 3)
2184                         return strcat(ftos(pos), "rd");
2185                 else
2186                         return strcat(ftos(pos), "th");
2187         }
2188         else
2189                 return strcat(ftos(pos), "th");
2190 }
2191 string getrecords(float page) // 50 records per page
2192 {
2193     float rec;
2194     string h;
2195     float r;
2196     float i;
2197     string s;
2198
2199     rec = 0;
2200
2201     s = "";
2202
2203     if (g_ctf)
2204     {
2205         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2206         {
2207             if (MapInfo_Get_ByID(i))
2208             {
2209                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2210                 if (r == 0)
2211                     continue;
2212                 // TODO: uid2name
2213                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2214                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2215                 ++rec;
2216             }
2217         }
2218     }
2219
2220     if (g_race)
2221     {
2222         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2223         {
2224             if (MapInfo_Get_ByID(i))
2225             {
2226                 r = race_readTime(MapInfo_Map_bspname, 1);
2227                 if (r == 0)
2228                     continue;
2229                 h = race_readName(MapInfo_Map_bspname, 1);
2230                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2231                 ++rec;
2232             }
2233         }
2234     }
2235
2236     if (g_cts)
2237     {
2238         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2239         {
2240             if (MapInfo_Get_ByID(i))
2241             {
2242                 r = race_readTime(MapInfo_Map_bspname, 1);
2243                 if (r == 0)
2244                     continue;
2245                 h = race_readName(MapInfo_Map_bspname, 1);
2246                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2247                 ++rec;
2248             }
2249         }
2250     }
2251
2252     MapInfo_ClearTemps();
2253
2254     if (s == "" && page == 0)
2255         return "No records are available on this server.\n";
2256     else
2257         return s;
2258 }
2259
2260 string getrankings()
2261 {
2262     string n;
2263     float t;
2264     float i;
2265     string s;
2266     string p;
2267     string map;
2268
2269     s = "";
2270
2271     map = GetMapname();
2272
2273     for (i = 1; i <= RANKINGS_CNT; ++i)
2274     {
2275         t = race_readTime(map, i);
2276         if (t == 0)
2277             continue;
2278         n = race_readName(map, i);
2279         p = race_placeName(i);
2280         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2281     }
2282
2283     MapInfo_ClearTemps();
2284
2285     if (s == "")
2286         return strcat("No records are available for the map: ", map, "\n");
2287     else
2288         return strcat("Records for ", map, ":\n", s);
2289 }
2290
2291 #define LADDER_FIRSTPOINT 100
2292 #define LADDER_CNT 10
2293         // position X still gives LADDER_FIRSTPOINT/X points
2294 #define LADDER_SIZE 30
2295         // ladder shows the top X players
2296 string top_uids[LADDER_SIZE];
2297 float top_scores[LADDER_SIZE];
2298 string getladder()
2299 {
2300     float i, j, k, uidcnt;
2301     string s, temp_s;
2302
2303     s = "";
2304     temp_s = "";
2305
2306     string rr;
2307     if(g_cts)
2308         rr = CTS_RECORD;
2309     else
2310         rr = RACE_RECORD;
2311
2312     string myuid;
2313
2314     for (k = 0; k < MapInfo_count; ++k)
2315     {
2316         if (MapInfo_Get_ByID(k))
2317         {
2318                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2319                         if(i == 0) // speed award
2320                         {
2321                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2322                                         continue;
2323
2324                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2325                         }
2326                         else // normal record, if it exists (else break)
2327                         {
2328                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2329                                         continue;
2330
2331                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2332                         }
2333
2334                         // string s contains:
2335                         // arg 0 = # of speed recs
2336                         // arg 1 = # of 1st place recs
2337                         // arg 2 = # of 2nd place recs
2338                         // ... etc
2339                         // LADDER_CNT+1 = total points
2340
2341                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2342                         if (temp_s == "")
2343                         {
2344                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2345                             ++uidcnt;
2346                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2347                             {
2348                                 if(j != LADDER_CNT + 1)
2349                                     temp_s = strcat(temp_s, "0 ");
2350                                 else
2351                                     temp_s = strcat(temp_s, "0");
2352                             }
2353                         }
2354
2355                         tokenize_console(temp_s);
2356                         s = "";
2357
2358                         if(i == 0) // speed award
2359                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2360                             {
2361                                 if(j == 0) // speed award
2362                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2363                                 else
2364                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2365                             }
2366                         else // record
2367                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2368                             {
2369                                 if(j == 0)
2370                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2371                                 else if(j == i) // wanted rec!
2372                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2373                                 else
2374                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2375                             }
2376
2377                         // total points are (by default) calculated like this:
2378                         // speedrec = floor(100 / 10) = 10 points
2379                         // 1st place = floor(100 / 1) = 100 points
2380                         // 2nd place = floor(100 / 2) = 50 points
2381                         // 3rd place = floor(100 / 3) = 33 points
2382                         // 4th place = floor(100 / 4) = 25 points
2383                         // 5th place = floor(100 / 5) = 20 points
2384                         // ... etc
2385
2386                         if(i == 0)
2387                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2388                         else
2389                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2390
2391                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2392                 }
2393         }
2394     }
2395
2396     float thiscnt;
2397     string thisuid;
2398     for (i = 0; i <= uidcnt; ++i) // for each known uid
2399     {
2400         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2401         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2402         tokenize_console(temp_s);
2403         thiscnt = stof(argv(LADDER_CNT+1));
2404
2405         if(thiscnt > top_scores[LADDER_SIZE-1])
2406         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2407         {
2408             if(thiscnt > top_scores[j])
2409             {
2410                 for (k = LADDER_SIZE-1; k >= j; --k)
2411                 {
2412                     top_uids[k] = top_uids[k-1];
2413                     top_scores[k] = top_scores[k-1];
2414                 }
2415                 top_uids[j] = thisuid;
2416                 top_scores[j] = thiscnt;
2417                 break;
2418             }
2419         }
2420     }
2421
2422     s = "^3-----------------------\n\n";
2423
2424     s = strcat(s, "Pos ^3|");
2425     s = strcat(s, " ^7Total  ^3|");
2426     for (i = 1; i <= LADDER_CNT; ++i)
2427     {
2428         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2429     }
2430     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2431
2432     s = strcat(s, "\n^3----+--------");
2433     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2434     {
2435         s = strcat(s, "+-----");
2436     }
2437 #if LADDER_CNT > 9
2438     for (i = 1; i <= LADDER_CNT - 9; ++i)
2439     {
2440         s = strcat(s, "+------");
2441     }
2442 #endif
2443
2444     s = strcat(s, "+--------------+--------------------\n");
2445
2446     for (i = 0; i < LADDER_SIZE; ++i)
2447     {
2448         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2449         tokenize_console(temp_s);
2450         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2451             continue;
2452         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2453         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2454         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2455         {
2456             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2457         }
2458 #if LADDER_CNT > 9
2459         for (j = 10; j <= LADDER_CNT; ++j)
2460         {
2461             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2462         }
2463 #endif
2464
2465         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2466         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2467     }
2468
2469     MapInfo_ClearTemps();
2470
2471     if (s == "")
2472         return "No ladder on this server!\n";
2473     else
2474         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2475 }
2476
2477
2478 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2479 {
2480     float m, i;
2481     vector start, org, delta, end, enddown, mstart;
2482
2483     m = e.dphitcontentsmask;
2484     e.dphitcontentsmask = goodcontents | badcontents;
2485
2486     org = world.mins;
2487     delta = world.maxs - world.mins;
2488
2489     for (i = 0; i < attempts; ++i)
2490     {
2491         start_x = org_x + random() * delta_x;
2492         start_y = org_y + random() * delta_y;
2493         start_z = org_z + random() * delta_z;
2494
2495         // rule 1: start inside world bounds, and outside
2496         // solid, and don't start from somewhere where you can
2497         // fall down to evil
2498         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2499         if (trace_fraction >= 1)
2500             continue;
2501         if (trace_startsolid)
2502             continue;
2503         if (trace_dphitcontents & badcontents)
2504             continue;
2505         if (trace_dphitq3surfaceflags & badsurfaceflags)
2506             continue;
2507
2508         // rule 2: if we are too high, lower the point
2509         if (trace_fraction * delta_z > maxaboveground)
2510             start = trace_endpos + '0 0 1' * maxaboveground;
2511         enddown = trace_endpos;
2512
2513         // rule 3: make sure we aren't outside the map. This only works
2514         // for somewhat well formed maps. A good rule of thumb is that
2515         // the map should have a convex outside hull.
2516         // these can be traceLINES as we already verified the starting box
2517         mstart = start + 0.5 * (e.mins + e.maxs);
2518         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2519         if (trace_fraction >= 1)
2520             continue;
2521         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2522         if (trace_fraction >= 1)
2523             continue;
2524         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2525         if (trace_fraction >= 1)
2526             continue;
2527         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2528         if (trace_fraction >= 1)
2529             continue;
2530         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2531         if (trace_fraction >= 1)
2532             continue;
2533
2534         // find a random vector to "look at"
2535         end_x = org_x + random() * delta_x;
2536         end_y = org_y + random() * delta_y;
2537         end_z = org_z + random() * delta_z;
2538         end = start + normalize(end - start) * vlen(delta);
2539
2540         // rule 4: start TO end must not be too short
2541         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2542         if (trace_startsolid)
2543             continue;
2544         if (trace_fraction < minviewdistance / vlen(delta))
2545             continue;
2546
2547         // rule 5: don't want to look at sky
2548         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2549             continue;
2550
2551         // rule 6: we must not end up in trigger_hurt
2552         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2553         {
2554             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2555             continue;
2556         }
2557
2558         break;
2559     }
2560
2561     e.dphitcontentsmask = m;
2562
2563     if (i < attempts)
2564     {
2565         setorigin(e, start);
2566         e.angles = vectoangles(end - start);
2567         dprint("Needed ", ftos(i + 1), " attempts\n");
2568         return TRUE;
2569     }
2570     else
2571         return FALSE;
2572 }
2573
2574 float zcurveparticles_effectno;
2575 vector zcurveparticles_start;
2576 float zcurveparticles_spd;
2577
2578 void endzcurveparticles()
2579 {
2580         if(zcurveparticles_effectno)
2581         {
2582                 // terminator
2583                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2584         }
2585         zcurveparticles_effectno = 0;
2586 }
2587
2588 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2589 {
2590         spd = bound(0, floor(spd / 16), 32767);
2591         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2592         {
2593                 endzcurveparticles();
2594                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2595                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2596                 WriteShort(MSG_BROADCAST, effectno);
2597                 WriteCoord(MSG_BROADCAST, start_x);
2598                 WriteCoord(MSG_BROADCAST, start_y);
2599                 WriteCoord(MSG_BROADCAST, start_z);
2600                 zcurveparticles_effectno = effectno;
2601                 zcurveparticles_start = start;
2602         }
2603         else
2604                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2605         WriteCoord(MSG_BROADCAST, end_x);
2606         WriteCoord(MSG_BROADCAST, end_y);
2607         WriteCoord(MSG_BROADCAST, end_z);
2608         WriteCoord(MSG_BROADCAST, end_dz);
2609         zcurveparticles_spd = spd;
2610 }
2611
2612 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2613 {
2614         float end_dz;
2615         vector vecxy, velxy;
2616
2617         vecxy = end - start;
2618         vecxy_z = 0;
2619         velxy = vel;
2620         velxy_z = 0;
2621
2622         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2623         {
2624                 endzcurveparticles();
2625                 trailparticles(world, effectno, start, end);
2626                 return;
2627         }
2628
2629         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2630         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2631 }
2632
2633 void write_recordmarker(entity pl, float tstart, float dt)
2634 {
2635     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2636
2637     // also write a marker into demo files for demotc-race-record-extractor to find
2638     stuffcmd(pl,
2639              strcat(
2640                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2641                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2642 }
2643
2644 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2645 {
2646         switch(algn)
2647         {
2648                 case 1: // right
2649                         break;
2650
2651                 case 2: // left
2652                         vecs_y = -vecs_y;
2653                         break;
2654
2655                 default:
2656                 case 3:
2657                         if(allowcenter) // 2: allow center handedness
2658                         {
2659                                 // center
2660                                 vecs_y = 0;
2661                                 vecs_z -= 2;
2662                         }
2663                         else
2664                         {
2665                                 // right
2666                         }
2667                         break;
2668
2669                 case 4:
2670                         if(allowcenter) // 2: allow center handedness
2671                         {
2672                                 // center
2673                                 vecs_y = 0;
2674                                 vecs_z -= 2;
2675                         }
2676                         else
2677                         {
2678                                 // left
2679                                 vecs_y = -vecs_y;
2680                         }
2681                         break;
2682         }
2683         return vecs;
2684 }
2685
2686 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2687 {
2688         string s;
2689         vector v;
2690
2691         if (autocvar_g_shootfromeye)
2692         {
2693                 if (visual)
2694                 {
2695                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2696                 }
2697                 else
2698                 {
2699                         vecs_y = 0;
2700                         vecs_z = 0;
2701                 }
2702         }
2703         else if (autocvar_g_shootfromcenter)
2704         {
2705                 if (visual)
2706                 {
2707                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2708                 }
2709                 else
2710                 {
2711                         vecs_y = 0;
2712                         vecs_z -= 2;
2713                 }
2714         }
2715         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2716         {
2717                 v = stov(s);
2718                 if (y_is_right)
2719                         v_y = -v_y;
2720                 if (v_x != 0)
2721                         vecs_x = v_x;
2722                 vecs_y = v_y;
2723                 vecs_z = v_z;
2724         }
2725         else if (autocvar_g_shootfromclient)
2726         {
2727                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2728         }
2729         return vecs;
2730 }
2731
2732 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2733 {
2734         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2735 }
2736
2737
2738 void attach_sameorigin(entity e, entity to, string tag)
2739 {
2740     vector org, t_forward, t_left, t_up, e_forward, e_up;
2741     vector org0, ang0;
2742     float tagscale;
2743
2744     ang0 = e.angles;
2745     org0 = e.origin;
2746
2747     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2748     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2749     t_forward = v_forward * tagscale;
2750     t_left = v_right * -tagscale;
2751     t_up = v_up * tagscale;
2752
2753     e.origin_x = org * t_forward;
2754     e.origin_y = org * t_left;
2755     e.origin_z = org * t_up;
2756
2757     // current forward and up directions
2758     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2759                 e.angles = AnglesTransform_FromVAngles(e.angles);
2760         else
2761                 e.angles = AnglesTransform_FromAngles(e.angles);
2762     fixedmakevectors(e.angles);
2763
2764     // untransform forward, up!
2765     e_forward_x = v_forward * t_forward;
2766     e_forward_y = v_forward * t_left;
2767     e_forward_z = v_forward * t_up;
2768     e_up_x = v_up * t_forward;
2769     e_up_y = v_up * t_left;
2770     e_up_z = v_up * t_up;
2771
2772     e.angles = fixedvectoangles2(e_forward, e_up);
2773     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2774                 e.angles = AnglesTransform_ToVAngles(e.angles);
2775         else
2776                 e.angles = AnglesTransform_ToAngles(e.angles);
2777
2778     setattachment(e, to, tag);
2779     setorigin(e, e.origin);
2780 }
2781
2782 void detach_sameorigin(entity e)
2783 {
2784     vector org;
2785     org = gettaginfo(e, 0);
2786     e.angles = fixedvectoangles2(v_forward, v_up);
2787     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2788                 e.angles = AnglesTransform_ToVAngles(e.angles);
2789         else
2790                 e.angles = AnglesTransform_ToAngles(e.angles);
2791     setorigin(e, org);
2792     setattachment(e, world, "");
2793     setorigin(e, e.origin);
2794 }
2795
2796 void follow_sameorigin(entity e, entity to)
2797 {
2798     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2799     e.aiment = to; // make the hole follow bmodel
2800     e.punchangle = to.angles; // the original angles of bmodel
2801     e.view_ofs = e.origin - to.origin; // relative origin
2802     e.v_angle = e.angles - to.angles; // relative angles
2803 }
2804
2805 void unfollow_sameorigin(entity e)
2806 {
2807     e.movetype = MOVETYPE_NONE;
2808 }
2809
2810 entity gettaginfo_relative_ent;
2811 vector gettaginfo_relative(entity e, float tag)
2812 {
2813     if (!gettaginfo_relative_ent)
2814     {
2815         gettaginfo_relative_ent = spawn();
2816         gettaginfo_relative_ent.effects = EF_NODRAW;
2817     }
2818     gettaginfo_relative_ent.model = e.model;
2819     gettaginfo_relative_ent.modelindex = e.modelindex;
2820     gettaginfo_relative_ent.frame = e.frame;
2821     return gettaginfo(gettaginfo_relative_ent, tag);
2822 }
2823
2824 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2825 {
2826     float p;
2827     p = pow(2, chan);
2828     if (pl.soundentity.cnt & p)
2829         return;
2830     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2831     pl.soundentity.cnt |= p;
2832 }
2833
2834 void SoundEntity_StopSound(entity pl, float chan)
2835 {
2836     float p;
2837     p = pow(2, chan);
2838     if (pl.soundentity.cnt & p)
2839     {
2840         stopsoundto(MSG_ALL, pl.soundentity, chan);
2841         pl.soundentity.cnt &~= p;
2842     }
2843 }
2844
2845 void SoundEntity_Attach(entity pl)
2846 {
2847     pl.soundentity = spawn();
2848     pl.soundentity.classname = "soundentity";
2849     pl.soundentity.owner = pl;
2850     setattachment(pl.soundentity, pl, "");
2851     setmodel(pl.soundentity, "null");
2852 }
2853
2854 void SoundEntity_Detach(entity pl)
2855 {
2856     float i;
2857     for (i = 0; i <= 7; ++i)
2858         SoundEntity_StopSound(pl, i);
2859 }
2860
2861
2862 float ParseCommandPlayerSlotTarget_firsttoken;
2863 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2864 {
2865     string s;
2866     entity e, head;
2867     float n;
2868
2869     s = string_null;
2870
2871     ParseCommandPlayerSlotTarget_firsttoken = -1;
2872
2873     if (tokens > idx)
2874     {
2875         if (substring(argv(idx), 0, 1) == "#")
2876         {
2877             s = substring(argv(idx), 1, -1);
2878             ++idx;
2879             if (s == "")
2880                 if (tokens > idx)
2881                 {
2882                     s = argv(idx);
2883                     ++idx;
2884                 }
2885                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2886             if (s == ftos(stof(s)))
2887             {
2888                 e = edict_num(stof(s));
2889                 if (e.flags & FL_CLIENT)
2890                     return e;
2891             }
2892         }
2893         else
2894         {
2895             // it must be a nick name
2896             s = argv(idx);
2897             ++idx;
2898                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2899
2900             n = 0;
2901             FOR_EACH_CLIENT(head)
2902             if (head.netname == s)
2903             {
2904                 e = head;
2905                 ++n;
2906             }
2907             if (n == 1)
2908                 return e;
2909
2910             s = strdecolorize(s);
2911             n = 0;
2912             FOR_EACH_CLIENT(head)
2913             if (strdecolorize(head.netname) == s)
2914             {
2915                 e = head;
2916                 ++n;
2917             }
2918             if (n == 1)
2919                 return e;
2920         }
2921     }
2922
2923     return world;
2924 }
2925
2926 .float scale2;
2927
2928 float modeleffect_SendEntity(entity to, float sf)
2929 {
2930         float f;
2931         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2932
2933         f = 0;
2934         if(self.velocity != '0 0 0')
2935                 f |= 1;
2936         if(self.angles != '0 0 0')
2937                 f |= 2;
2938         if(self.avelocity != '0 0 0')
2939                 f |= 4;
2940
2941         WriteByte(MSG_ENTITY, f);
2942         WriteShort(MSG_ENTITY, self.modelindex);
2943         WriteByte(MSG_ENTITY, self.skin);
2944         WriteByte(MSG_ENTITY, self.frame);
2945         WriteCoord(MSG_ENTITY, self.origin_x);
2946         WriteCoord(MSG_ENTITY, self.origin_y);
2947         WriteCoord(MSG_ENTITY, self.origin_z);
2948         if(f & 1)
2949         {
2950                 WriteCoord(MSG_ENTITY, self.velocity_x);
2951                 WriteCoord(MSG_ENTITY, self.velocity_y);
2952                 WriteCoord(MSG_ENTITY, self.velocity_z);
2953         }
2954         if(f & 2)
2955         {
2956                 WriteCoord(MSG_ENTITY, self.angles_x);
2957                 WriteCoord(MSG_ENTITY, self.angles_y);
2958                 WriteCoord(MSG_ENTITY, self.angles_z);
2959         }
2960         if(f & 4)
2961         {
2962                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2963                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2964                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2965         }
2966         WriteShort(MSG_ENTITY, self.scale * 256.0);
2967         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2968         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2969         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2970         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2971
2972         return TRUE;
2973 }
2974
2975 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2976 {
2977         entity e;
2978         float sz;
2979         e = spawn();
2980         e.classname = "modeleffect";
2981         setmodel(e, m);
2982         e.frame = f;
2983         setorigin(e, o);
2984         e.velocity = v;
2985         e.angles = ang;
2986         e.avelocity = angv;
2987         e.alpha = a;
2988         e.teleport_time = t1;
2989         e.fade_time = t2;
2990         e.skin = s;
2991         if(s0 >= 0)
2992                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2993         else
2994                 e.scale = -s0;
2995         if(s2 >= 0)
2996                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2997         else
2998                 e.scale2 = -s2;
2999         sz = max(e.scale, e.scale2);
3000         setsize(e, e.mins * sz, e.maxs * sz);
3001         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
3002 }
3003
3004 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
3005 {
3006         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
3007 }
3008
3009 float randombit(float bits)
3010 {
3011         if not(bits & (bits-1)) // this ONLY holds for powers of two!
3012                 return bits;
3013
3014         float n, f, b, r;
3015
3016         r = random();
3017         b = 0;
3018         n = 0;
3019
3020         for(f = 1; f <= bits; f *= 2)
3021         {
3022                 if(bits & f)
3023                 {
3024                         ++n;
3025                         r *= n;
3026                         if(r <= 1)
3027                                 b = f;
3028                         else
3029                                 r = (r - 1) / (n - 1);
3030                 }
3031         }
3032
3033         return b;
3034 }
3035
3036 float randombits(float bits, float k, float error_return)
3037 {
3038         float r;
3039         r = 0;
3040         while(k > 0 && bits != r)
3041         {
3042                 r += randombit(bits - r);
3043                 --k;
3044         }
3045         if(error_return)
3046                 if(k > 0)
3047                         return -1; // all
3048         return r;
3049 }
3050
3051 void randombit_test(float bits, float iter)
3052 {
3053         while(iter > 0)
3054         {
3055                 print(ftos(randombit(bits)), "\n");
3056                 --iter;
3057         }
3058 }
3059
3060 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3061 {
3062         if(halflifedist > 0)
3063                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3064         else if(halflifedist < 0)
3065                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3066         else
3067                 return 1;
3068 }
3069
3070
3071
3072
3073 #ifdef RELEASE
3074 #define cvar_string_normal cvar_string_builtin
3075 #define cvar_normal cvar_builtin
3076 #else
3077 string cvar_string_normal(string n)
3078 {
3079         if not(cvar_type(n) & 1)
3080                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3081         return cvar_string_builtin(n);
3082 }
3083
3084 float cvar_normal(string n)
3085 {
3086         return stof(cvar_string_normal(n));
3087 }
3088 #endif
3089 #define cvar_set_normal cvar_set_builtin
3090
3091 void defer_think()
3092 {
3093     entity oself;
3094
3095     oself           = self;
3096     self            = self.owner;
3097     oself.think     = SUB_Remove;
3098     oself.nextthink = time;
3099
3100     oself.use();
3101 }
3102
3103 /*
3104     Execute func() after time + fdelay.
3105     self when func is executed = self when defer is called
3106 */
3107 void defer(float fdelay, void() func)
3108 {
3109     entity e;
3110
3111     e           = spawn();
3112     e.owner     = self;
3113     e.use       = func;
3114     e.think     = defer_think;
3115     e.nextthink = time + fdelay;
3116 }