qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include <common/weapons/weapon/crylink.qh>
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/notifications/all.qh"
  23 #include "../common/playerstats.qh"
  24 #include "../common/teams.qh"
  25 #include "../common/mapobjects/subs.qh"
  26 #include "../common/util.qh"
  27 #include "../common/turrets/sv_turrets.qh"
  28 #include <common/weapons/_all.qh>
  29 #include "../common/vehicles/sv_vehicles.qh"
  30 #include "../common/vehicles/vehicle.qh"
  31 #include "../common/items/_mod.qh"
  32 #include "../common/state.qh"
  33 #include "../common/effects/qc/globalsound.qh"
  34 #include "../common/wepent.qh"
  35 #include "../lib/csqcmodel/sv_model.qh"
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/server.qh"
  38
  39 void crosshair_trace(entity pl)
  40 {
  41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  42 }
  43
  44 void crosshair_trace_plusvisibletriggers(entity pl)
  45 {
  46         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
  47 }
  48
  49 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
  50 {
  51         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
  52 }
  53
  54 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
  55 {
  56         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  57         {
  58                 if(it.model != "")
  59                 {
  60                         it.solid = SOLID_BSP;
  61                         IL_PUSH(g_ctrace_changed, it);
  62                 }
  63         });
  64
  65         if (is_wz)
  66                 WarpZone_crosshair_trace(pl);
  67         else
  68                 crosshair_trace(pl);
  69
  70         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
  71
  72         IL_CLEAR(g_ctrace_changed);
  73 }
  74
  75 void WarpZone_crosshair_trace(entity pl)
  76 {
  77         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  78 }
  79
  80 void dedicated_print(string input)
  81 {
  82         if (server_is_dedicated) print(input);
  83 }
  84
  85 void GameLogEcho(string s)
  86 {
  87     string fn;
  88     int matches;
  89
  90     if (autocvar_sv_eventlog_files)
  91     {
  92         if (!logfile_open)
  93         {
  94             logfile_open = true;
  95             matches = autocvar_sv_eventlog_files_counter + 1;
  96             cvar_set("sv_eventlog_files_counter", itos(matches));
  97             fn = ftos(matches);
  98             if (strlen(fn) < 8)
  99                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 100             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 101             logfile = fopen(fn, FILE_APPEND);
 102             fputs(logfile, ":logversion:3\n");
 103         }
 104         if (logfile >= 0)
 105         {
 106             if (autocvar_sv_eventlog_files_timestamps)
 107                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 108             else
 109                 fputs(logfile, strcat(s, "\n"));
 110         }
 111     }
 112     if (autocvar_sv_eventlog_console)
 113     {
 114         dedicated_print(strcat(s, "\n"));
 115     }
 116 }
 117
 118 void GameLogInit()
 119 {
 120     logfile_open = 0;
 121     // will be opened later
 122 }
 123
 124 void GameLogClose()
 125 {
 126     if (logfile_open && logfile >= 0)
 127     {
 128         fclose(logfile);
 129         logfile = -1;
 130     }
 131 }
 132
 133 entity findnearest(vector point, bool checkitems, vector axismod)
 134 {
 135     vector dist;
 136     int num_nearest = 0;
 137
 138     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 139     {
 140         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 141             dist = it.oldorigin;
 142         else
 143             dist = it.origin;
 144         dist = dist - point;
 145         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 146         float len = vlen2(dist);
 147
 148         int l;
 149         for (l = 0; l < num_nearest; ++l)
 150         {
 151             if (len < nearest_length[l])
 152                 break;
 153         }
 154
 155         // now i tells us where to insert at
 156         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 157         if (l < NUM_NEAREST_ENTITIES)
 158         {
 159             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 160             {
 161                 nearest_length[j + 1] = nearest_length[j];
 162                 nearest_entity[j + 1] = nearest_entity[j];
 163             }
 164             nearest_length[l] = len;
 165             nearest_entity[l] = it;
 166             if (num_nearest < NUM_NEAREST_ENTITIES)
 167                 num_nearest = num_nearest + 1;
 168         }
 169     });
 170
 171     // now use the first one from our list that we can see
 172     for (int j = 0; j < num_nearest; ++j)
 173     {
 174         traceline(point, nearest_entity[j].origin, true, NULL);
 175         if (trace_fraction == 1)
 176         {
 177             if (j != 0)
 178                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 179             return nearest_entity[j];
 180         }
 181     }
 182
 183     if (num_nearest == 0)
 184         return NULL;
 185
 186     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 187     /* DEBUGGING CODE:
 188     dprint("Candidates were: ");
 189     for(j = 0; j < num_nearest; ++j)
 190     {
 191         if(j != 0)
 192                 dprint(", ");
 193         dprint(nearest_entity[j].netname);
 194     }
 195     dprint("\n");
 196     */
 197
 198     return nearest_entity[0];
 199 }
 200
 201 string NearestLocation(vector p)
 202 {
 203     string ret = "somewhere";
 204     entity loc = findnearest(p, false, '1 1 1');
 205     if (loc)
 206         ret = loc.message;
 207     else
 208     {
 209         loc = findnearest(p, true, '1 1 4');
 210         if (loc)
 211             ret = loc.netname;
 212     }
 213     return ret;
 214 }
 215
 216 string AmmoNameFromWeaponentity(Weapon wep)
 217 {
 218         string ammoitems = "batteries";
 219         switch (wep.ammo_type)
 220         {
 221                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 222                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 223                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 224                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 225                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 226                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 227         }
 228         return ammoitems;
 229 }
 230
 231 string formatmessage(entity this, string msg)
 232 {
 233         float p, p1, p2;
 234         float n;
 235         vector cursor = '0 0 0';
 236         entity cursor_ent = NULL;
 237         string escape;
 238         string replacement;
 239         p = 0;
 240         n = 7;
 241         bool traced = false;
 242
 243         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 244         msg = M_ARGV(1, string);
 245
 246         while (1) {
 247                 if (n < 1)
 248                         break; // too many replacements
 249
 250                 n = n - 1;
 251                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 252                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 253
 254                 if (p1 < 0)
 255                         p1 = p2;
 256
 257                 if (p2 < 0)
 258                         p2 = p1;
 259
 260                 p = min(p1, p2);
 261
 262                 if (p < 0)
 263                         break;
 264
 265                 if(!traced)
 266                 {
 267                         WarpZone_crosshair_trace_plusvisibletriggers(this);
 268                         cursor = trace_endpos;
 269                         cursor_ent = trace_ent;
 270                         traced = true;
 271                 }
 272
 273                 replacement = substring(msg, p, 2);
 274                 escape = substring(msg, p + 1, 1);
 275
 276                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 277
 278                 switch(escape)
 279                 {
 280                         case "%": replacement = "%"; break;
 281                         case "\\":replacement = "\\"; break;
 282                         case "n": replacement = "\n"; break;
 283                         case "a": replacement = ftos(floor(GetResourceAmount(this, RESOURCE_ARMOR))); break;
 284                         case "h": replacement = ftos(floor(GetResourceAmount(this, RESOURCE_HEALTH))); break;
 285                         case "l": replacement = NearestLocation(this.origin); break;
 286                         case "y": replacement = NearestLocation(cursor); break;
 287                         case "d": replacement = NearestLocation(this.death_origin); break;
 288                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 289                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 290                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 291                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 292                         case "S": replacement = ftos(vlen(this.velocity)); break;
 293                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 294                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 295                         default:
 296                         {
 297                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 298                                 replacement = M_ARGV(2, string);
 299                                 break;
 300                         }
 301                 }
 302
 303                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 304                 p = p + strlen(replacement);
 305         }
 306         return msg;
 307 }
 308
 309 /*
 310 =============
 311 GetCvars
 312 =============
 313 Called with:
 314   0:  sends the request
 315   >0: receives a cvar from name=argv(f) value=argv(f+1)
 316 */
 317 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 318 {
 319         if (f < 0)
 320         {
 321                 strfree(store.(field));
 322         }
 323         else if (f > 0)
 324         {
 325                 if (thisname == name)
 326                 {
 327                         strcpy(store.(field), argv(f + 1));
 328                 }
 329         }
 330         else
 331                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 332 }
 333 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 334 {
 335         GetCvars_handleString(this, store, thisname, f, field, name);
 336         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 337                 if (thisname == name)
 338                 {
 339                         string s = func(this, strcat1(store.(field)));
 340                         if (s != store.(field))
 341                         {
 342                                 strcpy(store.(field), s);
 343                         }
 344                 }
 345 }
 346 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 347 {
 348         if (f < 0)
 349         {
 350         }
 351         else if (f > 0)
 352         {
 353                 if (thisname == name)
 354                         store.(field) = stof(argv(f + 1));
 355         }
 356         else
 357                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 358 }
 359 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 360 {
 361         if (f < 0)
 362         {
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                 {
 368                         if (!store.(field))
 369                         {
 370                                 store.(field) = stof(argv(f + 1));
 371                                 if (!store.(field))
 372                                         store.(field) = -1;
 373                         }
 374                 }
 375         }
 376         else
 377         {
 378                 if (!store.(field))
 379                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 380         }
 381 }
 382 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 383 {
 384         string o = W_FixWeaponOrder_ForceComplete(wo);
 385         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 386         return o;
 387 }
 388
 389 REPLICATE(autoswitch, bool, "cl_autoswitch");
 390
 391 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 392
 393 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 394
 395 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 396
 397 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 398
 399 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 400
 401 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 402
 403 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 404
 405 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 406
 407 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 408
 409 REPLICATE(cvar_cl_physics, string, "cl_physics");
 410
 411 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 412
 413 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 414
 415 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 416
 417 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 418
 419 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
 420
 421 /**
 422  * @param f -1: cleanup, 0: request, 1: receive
 423  */
 424 void GetCvars(entity this, entity store, int f)
 425 {
 426         string s = string_null;
 427
 428         if (f > 0)
 429                 s = strcat1(argv(f));
 430
 431         get_cvars_f = f;
 432         get_cvars_s = s;
 433         MUTATOR_CALLHOOK(GetCvars);
 434
 435         Notification_GetCvars(this);
 436
 437         ReplicateVars(this, store, s, f);
 438
 439         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 440         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 441         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 442         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 443         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 444         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 445         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 446         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 447         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 448         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 449         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 450
 451         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 452
 453         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 454         if (f > 0)
 455         {
 456                 if (s == "cl_weaponpriority")
 457                 {
 458                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 459                         {
 460                                 .entity weaponentity = weaponentities[slot];
 461                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 462                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 463                         }
 464                 }
 465                 if (s == "cl_allow_uidtracking")
 466                         PlayerStats_GameReport_AddPlayer(this);
 467         }
 468 }
 469
 470 // decolorizes and team colors the player name when needed
 471 string playername(entity p, bool team_colorize)
 472 {
 473     string t;
 474     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 475     {
 476         t = Team_ColorCode(p.team);
 477         return strcat(t, strdecolorize(p.netname));
 478     }
 479     else
 480         return p.netname;
 481 }
 482
 483 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 484 {
 485         int i = weaponinfo.m_id;
 486         int d = 0;
 487         bool allow_mutatorblocked = false;
 488
 489         if(!i)
 490                 return 0;
 491
 492         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 493         d = M_ARGV(1, float);
 494         allguns = M_ARGV(2, bool);
 495         allow_mutatorblocked = M_ARGV(3, bool);
 496
 497         if(allguns)
 498         {
 499                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 500                         d = true;
 501                 else
 502                         d = false;
 503         }
 504         else if(!mutator_returnvalue)
 505                 d = !(!weaponinfo.weaponstart);
 506
 507         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 508                 d = 0;
 509
 510         float t = weaponinfo.weaponstartoverride;
 511
 512         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 513
 514         // bit order in t:
 515         // 1: want or not
 516         // 2: is default?
 517         // 4: is set by default?
 518         if(t < 0)
 519                 t = 4 | (3 * d);
 520         else
 521                 t |= (2 * d);
 522
 523         return t;
 524 }
 525
 526 void readplayerstartcvars()
 527 {
 528         float i, t;
 529         string s;
 530
 531         // initialize starting values for players
 532         start_weapons = '0 0 0';
 533         start_weapons_default = '0 0 0';
 534         start_weapons_defaultmask = '0 0 0';
 535         start_items = 0;
 536         start_ammo_shells = 0;
 537         start_ammo_nails = 0;
 538         start_ammo_rockets = 0;
 539         start_ammo_cells = 0;
 540         start_ammo_plasma = 0;
 541         if (random_start_ammo == NULL)
 542         {
 543                 random_start_ammo = spawn();
 544         }
 545         start_health = cvar("g_balance_health_start");
 546         start_armorvalue = cvar("g_balance_armor_start");
 547
 548         g_weaponarena = 0;
 549         g_weaponarena_weapons = '0 0 0';
 550
 551         s = cvar_string("g_weaponarena");
 552
 553         MUTATOR_CALLHOOK(SetWeaponArena, s);
 554         s = M_ARGV(0, string);
 555
 556         if (s == "0" || s == "")
 557         {
 558                 // no arena
 559         }
 560         else if (s == "off")
 561         {
 562                 // forcibly turn off weaponarena
 563         }
 564         else if (s == "all" || s == "1")
 565         {
 566                 g_weaponarena = 1;
 567                 g_weaponarena_list = "All Weapons";
 568                 FOREACH(Weapons, it != WEP_Null, {
 569                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 570                                 g_weaponarena_weapons |= (it.m_wepset);
 571                 });
 572         }
 573         else if (s == "devall")
 574         {
 575                 g_weaponarena = 1;
 576                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 577                 FOREACH(Weapons, it != WEP_Null,
 578                 {
 579                         g_weaponarena_weapons |= (it.m_wepset);
 580                 });
 581         }
 582         else if (s == "most")
 583         {
 584                 g_weaponarena = 1;
 585                 g_weaponarena_list = "Most Weapons";
 586                 FOREACH(Weapons, it != WEP_Null, {
 587                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 588                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 589                                         g_weaponarena_weapons |= (it.m_wepset);
 590                 });
 591         }
 592         else if (s == "none")
 593         {
 594                 g_weaponarena = 1;
 595                 g_weaponarena_list = "No Weapons";
 596         }
 597         else
 598         {
 599                 g_weaponarena = 1;
 600                 t = tokenize_console(s);
 601                 g_weaponarena_list = "";
 602                 for (i = 0; i < t; ++i)
 603                 {
 604                         s = argv(i);
 605                         Weapon wep = Weapons_fromstr(s);
 606                         if(wep != WEP_Null)
 607                         {
 608                                 g_weaponarena_weapons |= (wep.m_wepset);
 609                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
 610                         }
 611                 }
 612                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 613         }
 614
 615         if (g_weaponarena)
 616         {
 617                 g_weapon_stay = 0; // incompatible
 618                 start_weapons = g_weaponarena_weapons;
 619                 start_items |= IT_UNLIMITED_AMMO;
 620         }
 621         else
 622         {
 623                 FOREACH(Weapons, it != WEP_Null, {
 624                         int w = want_weapon(it, false);
 625                         WepSet s = it.m_wepset;
 626                         if(w & 1)
 627                                 start_weapons |= s;
 628                         if(w & 2)
 629                                 start_weapons_default |= s;
 630                         if(w & 4)
 631                                 start_weapons_defaultmask |= s;
 632                 });
 633         }
 634
 635         if(cvar("g_balance_superweapons_time") < 0)
 636                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 637
 638         if(!cvar("g_use_ammunition"))
 639                 start_items |= IT_UNLIMITED_AMMO;
 640
 641         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 642         {
 643                 start_ammo_shells = 999;
 644                 start_ammo_nails = 999;
 645                 start_ammo_rockets = 999;
 646                 start_ammo_cells = 999;
 647                 start_ammo_plasma = 999;
 648                 start_ammo_fuel = 999;
 649         }
 650         else
 651         {
 652                 start_ammo_shells = cvar("g_start_ammo_shells");
 653                 start_ammo_nails = cvar("g_start_ammo_nails");
 654                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 655                 start_ammo_cells = cvar("g_start_ammo_cells");
 656                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 657                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 658                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 659                 SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, cvar(
 660                         "g_random_start_shells"));
 661                 SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, cvar(
 662                         "g_random_start_bullets"));
 663                 SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS,
 664                         cvar("g_random_start_rockets"));
 665                 SetResourceAmount(random_start_ammo, RESOURCE_CELLS, cvar(
 666                         "g_random_start_cells"));
 667                 SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, cvar(
 668                         "g_random_start_plasma"));
 669         }
 670
 671         if (warmup_stage)
 672         {
 673                 warmup_start_ammo_shells = start_ammo_shells;
 674                 warmup_start_ammo_nails = start_ammo_nails;
 675                 warmup_start_ammo_rockets = start_ammo_rockets;
 676                 warmup_start_ammo_cells = start_ammo_cells;
 677                 warmup_start_ammo_plasma = start_ammo_plasma;
 678                 warmup_start_ammo_fuel = start_ammo_fuel;
 679                 warmup_start_health = start_health;
 680                 warmup_start_armorvalue = start_armorvalue;
 681                 warmup_start_weapons = start_weapons;
 682                 warmup_start_weapons_default = start_weapons_default;
 683                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 684
 685                 if (!g_weaponarena && !g_ca && !g_freezetag)
 686                 {
 687                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 688                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 689                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 690                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 691                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 692                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 693                         warmup_start_health = cvar("g_warmup_start_health");
 694                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 695                         warmup_start_weapons = '0 0 0';
 696                         warmup_start_weapons_default = '0 0 0';
 697                         warmup_start_weapons_defaultmask = '0 0 0';
 698                         FOREACH(Weapons, it != WEP_Null, {
 699                                 int w = want_weapon(it, g_warmup_allguns);
 700                                 WepSet s = (it.m_wepset);
 701                                 if(w & 1)
 702                                         warmup_start_weapons |= s;
 703                                 if(w & 2)
 704                                         warmup_start_weapons_default |= s;
 705                                 if(w & 4)
 706                                         warmup_start_weapons_defaultmask |= s;
 707                         });
 708                 }
 709         }
 710
 711         if (g_jetpack)
 712                 start_items |= ITEM_Jetpack.m_itemid;
 713
 714         MUTATOR_CALLHOOK(SetStartItems);
 715
 716         if (start_items & ITEM_Jetpack.m_itemid)
 717         {
 718                 start_items |= ITEM_JetpackRegen.m_itemid;
 719                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 720                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 721         }
 722
 723         WepSet precache_weapons = start_weapons;
 724         if (g_warmup_allguns != 1)
 725                 precache_weapons |= warmup_start_weapons;
 726         FOREACH(Weapons, it != WEP_Null, {
 727                 if(precache_weapons & (it.m_wepset))
 728                         it.wr_init(it);
 729         });
 730
 731         start_ammo_shells = max(0, start_ammo_shells);
 732         start_ammo_nails = max(0, start_ammo_nails);
 733         start_ammo_rockets = max(0, start_ammo_rockets);
 734         start_ammo_cells = max(0, start_ammo_cells);
 735         start_ammo_plasma = max(0, start_ammo_plasma);
 736         start_ammo_fuel = max(0, start_ammo_fuel);
 737         SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, max(0,
 738                 GetResourceAmount(random_start_ammo, RESOURCE_SHELLS)));
 739         SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, max(0,
 740                 GetResourceAmount(random_start_ammo, RESOURCE_BULLETS)));
 741         SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS, max(0,
 742                 GetResourceAmount(random_start_ammo, RESOURCE_ROCKETS)));
 743         SetResourceAmount(random_start_ammo, RESOURCE_CELLS, max(0,
 744                 GetResourceAmount(random_start_ammo, RESOURCE_CELLS)));
 745         SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, max(0,
 746                 GetResourceAmount(random_start_ammo, RESOURCE_PLASMA)));
 747
 748         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 749         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 750         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 751         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 752         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 753         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 754 }
 755
 756 void precache_playermodel(string m)
 757 {
 758         float globhandle, i, n;
 759         string f;
 760
 761         if(substring(m, -9,5) == "_lod1")
 762                 return;
 763         if(substring(m, -9,5) == "_lod2")
 764                 return;
 765         precache_model(m);
 766         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 767         if(fexists(f))
 768                 precache_model(f);
 769         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 770         if(fexists(f))
 771                 precache_model(f);
 772
 773         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 774         if (globhandle < 0)
 775                 return;
 776         n = search_getsize(globhandle);
 777         for (i = 0; i < n; ++i)
 778         {
 779                 //print(search_getfilename(globhandle, i), "\n");
 780                 f = search_getfilename(globhandle, i);
 781                 PrecachePlayerSounds(f);
 782         }
 783         search_end(globhandle);
 784 }
 785 void precache_all_playermodels(string pattern)
 786 {
 787         int globhandle = search_begin(pattern, true, false);
 788         if (globhandle < 0) return;
 789         int n = search_getsize(globhandle);
 790         for (int i = 0; i < n; ++i)
 791         {
 792                 string s = search_getfilename(globhandle, i);
 793                 precache_playermodel(s);
 794         }
 795         search_end(globhandle);
 796 }
 797
 798 void precache_playermodels(string s)
 799 {
 800         FOREACH_WORD(s, true, { precache_playermodel(it); });
 801 }
 802
 803 void precache()
 804 {
 805     // gamemode related things
 806
 807     // Precache all player models if desired
 808     if (autocvar_sv_precacheplayermodels)
 809     {
 810         PrecachePlayerSounds("sound/player/default.sounds");
 811         precache_all_playermodels("models/player/*.zym");
 812         precache_all_playermodels("models/player/*.dpm");
 813         precache_all_playermodels("models/player/*.md3");
 814         precache_all_playermodels("models/player/*.psk");
 815         precache_all_playermodels("models/player/*.iqm");
 816     }
 817
 818     if (autocvar_sv_defaultcharacter)
 819     {
 820                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 821                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 822                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 823                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 824                 precache_playermodels(autocvar_sv_defaultplayermodel);
 825     }
 826
 827 #if 0
 828     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 829
 830     if (!this.noise && this.music) // quake 3 uses the music field
 831         this.noise = this.music;
 832
 833     // plays music for the level if there is any
 834     if (this.noise)
 835     {
 836         precache_sound (this.noise);
 837         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 838     }
 839 #endif
 840 }
 841
 842
 843 void make_safe_for_remove(entity e)
 844 {
 845     if (e.initialize_entity)
 846     {
 847         entity ent, prev = NULL;
 848         for (ent = initialize_entity_first; ent; )
 849         {
 850             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 851             {
 852                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 853                 // skip it in linked list
 854                 if (prev)
 855                 {
 856                     prev.initialize_entity_next = ent.initialize_entity_next;
 857                     ent = prev.initialize_entity_next;
 858                 }
 859                 else
 860                 {
 861                     initialize_entity_first = ent.initialize_entity_next;
 862                     ent = initialize_entity_first;
 863                 }
 864             }
 865             else
 866             {
 867                 prev = ent;
 868                 ent = ent.initialize_entity_next;
 869             }
 870         }
 871     }
 872 }
 873
 874 .float remove_except_protected_forbidden;
 875 void remove_except_protected(entity e)
 876 {
 877         if(e.remove_except_protected_forbidden)
 878                 error("not allowed to remove this at this point");
 879         builtin_remove(e);
 880 }
 881
 882 void remove_unsafely(entity e)
 883 {
 884     if(e.classname == "spike")
 885         error("Removing spikes is forbidden (crylink bug), please report");
 886     builtin_remove(e);
 887 }
 888
 889 void remove_safely(entity e)
 890 {
 891     make_safe_for_remove(e);
 892     builtin_remove(e);
 893 }
 894
 895 void InitializeEntity(entity e, void(entity this) func, int order)
 896 {
 897     entity prev, cur;
 898
 899     if (!e || e.initialize_entity)
 900     {
 901         // make a proxy initializer entity
 902         entity e_old = e;
 903         e = new(initialize_entity);
 904         e.enemy = e_old;
 905     }
 906
 907     e.initialize_entity = func;
 908     e.initialize_entity_order = order;
 909
 910     cur = initialize_entity_first;
 911     prev = NULL;
 912     for (;;)
 913     {
 914         if (!cur || cur.initialize_entity_order > order)
 915         {
 916             // insert between prev and cur
 917             if (prev)
 918                 prev.initialize_entity_next = e;
 919             else
 920                 initialize_entity_first = e;
 921             e.initialize_entity_next = cur;
 922             return;
 923         }
 924         prev = cur;
 925         cur = cur.initialize_entity_next;
 926     }
 927 }
 928 void InitializeEntitiesRun()
 929 {
 930     entity startoflist = initialize_entity_first;
 931     initialize_entity_first = NULL;
 932     delete_fn = remove_except_protected;
 933     for (entity e = startoflist; e; e = e.initialize_entity_next)
 934     {
 935                 e.remove_except_protected_forbidden = 1;
 936     }
 937     for (entity e = startoflist; e; )
 938     {
 939                 e.remove_except_protected_forbidden = 0;
 940         e.initialize_entity_order = 0;
 941         entity next = e.initialize_entity_next;
 942         e.initialize_entity_next = NULL;
 943         var void(entity this) func = e.initialize_entity;
 944         e.initialize_entity = func_null;
 945         if (e.classname == "initialize_entity")
 946         {
 947             entity wrappee = e.enemy;
 948             builtin_remove(e);
 949             e = wrappee;
 950         }
 951         //dprint("Delayed initialization: ", e.classname, "\n");
 952         if (func)
 953         {
 954                 func(e);
 955         }
 956         else
 957         {
 958             eprint(e);
 959             backtrace(strcat("Null function in: ", e.classname, "\n"));
 960         }
 961         e = next;
 962     }
 963     delete_fn = remove_unsafely;
 964 }
 965
 966 .float(entity) isEliminated;
 967 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 968 {
 969         Stream out = MSG_ENTITY;
 970         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 971         serialize(byte, out, sendflags);
 972         if (sendflags & 1) {
 973                 for (int i = 1; i <= maxclients; i += 8) {
 974                         int f = 0;
 975                         entity e = edict_num(i);
 976                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 977                                 if (eliminatedPlayers.isEliminated(e)) {
 978                                         f |= BIT(b);
 979                                 }
 980                         }
 981                         serialize(byte, out, f);
 982                 }
 983         }
 984         return true;
 985 }
 986
 987 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 988 {
 989         if(eliminatedPlayers)
 990         {
 991                 backtrace("Can't spawn eliminatedPlayers again!");
 992                 return;
 993         }
 994         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 995         eliminatedPlayers.isEliminated = isEliminated_func;
 996 }
 997
 998
 999
1000
1001 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
1002 {
1003         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1004                 this.projectiledeathtype |= HITTYPE_SPLASH;
1005         adaptor_think2use(this);
1006 }
1007
1008 // deferred dropping
1009 void DropToFloor_Handler(entity this)
1010 {
1011     WITHSELF(this, builtin_droptofloor());
1012     this.dropped_origin = this.origin;
1013 }
1014
1015 void droptofloor(entity this)
1016 {
1017     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1018 }
1019
1020
1021
1022 float trace_hits_box_a0, trace_hits_box_a1;
1023
1024 float trace_hits_box_1d(float end, float thmi, float thma)
1025 {
1026     if (end == 0)
1027     {
1028         // just check if x is in range
1029         if (0 < thmi)
1030             return false;
1031         if (0 > thma)
1032             return false;
1033     }
1034     else
1035     {
1036         // do the trace with respect to x
1037         // 0 -> end has to stay in thmi -> thma
1038         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1039         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1040         if (trace_hits_box_a0 > trace_hits_box_a1)
1041             return false;
1042     }
1043     return true;
1044 }
1045
1046 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1047 {
1048     end -= start;
1049     thmi -= start;
1050     thma -= start;
1051     // now it is a trace from 0 to end
1052
1053     trace_hits_box_a0 = 0;
1054     trace_hits_box_a1 = 1;
1055
1056     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1057         return false;
1058     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1059         return false;
1060     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1061         return false;
1062
1063     return true;
1064 }
1065
1066 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1067 {
1068     return trace_hits_box(start, end, thmi - ma, thma - mi);
1069 }
1070
1071 bool SUB_NoImpactCheck(entity this, entity toucher)
1072 {
1073         // zero hitcontents = this is not the real impact, but either the
1074         // mirror-impact of something hitting the projectile instead of the
1075         // projectile hitting the something, or a touchareagrid one. Neither of
1076         // these stop the projectile from moving, so...
1077         if(trace_dphitcontents == 0)
1078         {
1079                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1080                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1081         }
1082     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1083         return true;
1084     if (toucher == NULL && this.size != '0 0 0')
1085     {
1086         vector tic;
1087         tic = this.velocity * sys_frametime;
1088         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1089         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1090         if (trace_fraction >= 1)
1091         {
1092             LOG_TRACE("Odd... did not hit...?");
1093         }
1094         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1095         {
1096             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1097             return true;
1098         }
1099     }
1100
1101     return false;
1102 }
1103
1104 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1105
1106 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1107 {
1108         if(SUB_OwnerCheck(this, toucher))
1109                 return true;
1110         if(SUB_NoImpactCheck(this, toucher))
1111         {
1112                 if(this.classname == "nade")
1113                         return false; // no checks here
1114                 else if(this.classname == "grapplinghook")
1115                         RemoveHook(this);
1116                 else if(this.classname == "spike")
1117                 {
1118                         W_Crylink_Dequeue(this);
1119                         delete(this);
1120                 }
1121                 else
1122                         delete(this);
1123                 return true;
1124         }
1125         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1126                 UpdateCSQCProjectile(this);
1127         return false;
1128 }
1129
1130 /** engine callback */
1131 void URI_Get_Callback(float id, float status, string data)
1132 {
1133         if(url_URI_Get_Callback(id, status, data))
1134         {
1135                 // handled
1136         }
1137         else if (id == URI_GET_DISCARD)
1138         {
1139                 // discard
1140         }
1141         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1142         {
1143                 // sv_cmd curl
1144                 Curl_URI_Get_Callback(id, status, data);
1145         }
1146         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1147         {
1148                 // online ban list
1149                 OnlineBanList_URI_Get_Callback(id, status, data);
1150         }
1151         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1152         {
1153                 // handled by a mutator
1154         }
1155         else
1156         {
1157                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1158         }
1159 }
1160
1161 string uid2name(string myuid) {
1162         string s;
1163         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1164
1165         // FIXME remove this later after 0.6 release
1166         // convert old style broken records to correct style
1167         if(s == "")
1168         {
1169                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1170                 if(s != "")
1171                 {
1172                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1173                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1174                 }
1175         }
1176
1177         if(s == "")
1178                 s = "^1Unregistered Player";
1179         return s;
1180 }
1181
1182 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1183 {
1184     float m, i;
1185     vector start, org, delta, end, enddown, mstart;
1186
1187     m = e.dphitcontentsmask;
1188     e.dphitcontentsmask = goodcontents | badcontents;
1189
1190     org = boundmin;
1191     delta = boundmax - boundmin;
1192
1193     start = end = org;
1194
1195     for (i = 0; i < attempts; ++i)
1196     {
1197         start.x = org.x + random() * delta.x;
1198         start.y = org.y + random() * delta.y;
1199         start.z = org.z + random() * delta.z;
1200
1201         // rule 1: start inside world bounds, and outside
1202         // solid, and don't start from somewhere where you can
1203         // fall down to evil
1204         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1205         if (trace_fraction >= 1)
1206             continue;
1207         if (trace_startsolid)
1208             continue;
1209         if (trace_dphitcontents & badcontents)
1210             continue;
1211         if (trace_dphitq3surfaceflags & badsurfaceflags)
1212             continue;
1213
1214         // rule 2: if we are too high, lower the point
1215         if (trace_fraction * delta.z > maxaboveground)
1216             start = trace_endpos + '0 0 1' * maxaboveground;
1217         enddown = trace_endpos;
1218
1219         // rule 3: make sure we aren't outside the map. This only works
1220         // for somewhat well formed maps. A good rule of thumb is that
1221         // the map should have a convex outside hull.
1222         // these can be traceLINES as we already verified the starting box
1223         mstart = start + 0.5 * (e.mins + e.maxs);
1224         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1225         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1226             continue;
1227         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1228         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1229             continue;
1230         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1231         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1232             continue;
1233         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1234         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1235             continue;
1236         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1237         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1238             continue;
1239
1240         // rule 4: we must "see" some spawnpoint or item
1241     entity sp = NULL;
1242     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1243     {
1244         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1245         {
1246                 sp = it;
1247                 break;
1248         }
1249     });
1250         if(!sp)
1251         {
1252                 int items_checked = 0;
1253                 IL_EACH(g_items, checkpvs(mstart, it),
1254                 {
1255                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1256                         {
1257                                 sp = it;
1258                                 break;
1259                         }
1260
1261                         ++items_checked;
1262                         if(items_checked >= attempts)
1263                                 break; // sanity
1264                 });
1265
1266                 if(!sp)
1267                         continue;
1268         }
1269
1270         // find a random vector to "look at"
1271         end.x = org.x + random() * delta.x;
1272         end.y = org.y + random() * delta.y;
1273         end.z = org.z + random() * delta.z;
1274         end = start + normalize(end - start) * vlen(delta);
1275
1276         // rule 4: start TO end must not be too short
1277         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1278         if (trace_startsolid)
1279             continue;
1280         if (trace_fraction < minviewdistance / vlen(delta))
1281             continue;
1282
1283         // rule 5: don't want to look at sky
1284         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1285             continue;
1286
1287         // rule 6: we must not end up in trigger_hurt
1288         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1289             continue;
1290
1291         break;
1292     }
1293
1294     e.dphitcontentsmask = m;
1295
1296     if (i < attempts)
1297     {
1298         setorigin(e, start);
1299         e.angles = vectoangles(end - start);
1300         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1301         return true;
1302     }
1303     else
1304         return false;
1305 }
1306
1307 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1308 {
1309         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1310 }
1311
1312 void write_recordmarker(entity pl, float tstart, float dt)
1313 {
1314     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1315
1316     // also write a marker into demo files for demotc-race-record-extractor to find
1317     stuffcmd(pl,
1318              strcat(
1319                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1320                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1321 }
1322
1323 void attach_sameorigin(entity e, entity to, string tag)
1324 {
1325     vector org, t_forward, t_left, t_up, e_forward, e_up;
1326     float tagscale;
1327
1328     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1329     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1330     t_forward = v_forward * tagscale;
1331     t_left = v_right * -tagscale;
1332     t_up = v_up * tagscale;
1333
1334     e.origin_x = org * t_forward;
1335     e.origin_y = org * t_left;
1336     e.origin_z = org * t_up;
1337
1338     // current forward and up directions
1339     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1340                 e.angles = AnglesTransform_FromVAngles(e.angles);
1341         else
1342                 e.angles = AnglesTransform_FromAngles(e.angles);
1343     fixedmakevectors(e.angles);
1344
1345     // untransform forward, up!
1346     e_forward.x = v_forward * t_forward;
1347     e_forward.y = v_forward * t_left;
1348     e_forward.z = v_forward * t_up;
1349     e_up.x = v_up * t_forward;
1350     e_up.y = v_up * t_left;
1351     e_up.z = v_up * t_up;
1352
1353     e.angles = fixedvectoangles2(e_forward, e_up);
1354     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1355                 e.angles = AnglesTransform_ToVAngles(e.angles);
1356         else
1357                 e.angles = AnglesTransform_ToAngles(e.angles);
1358
1359     setattachment(e, to, tag);
1360     setorigin(e, e.origin);
1361 }
1362
1363 void detach_sameorigin(entity e)
1364 {
1365     vector org;
1366     org = gettaginfo(e, 0);
1367     e.angles = fixedvectoangles2(v_forward, v_up);
1368     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1369                 e.angles = AnglesTransform_ToVAngles(e.angles);
1370         else
1371                 e.angles = AnglesTransform_ToAngles(e.angles);
1372     setorigin(e, org);
1373     setattachment(e, NULL, "");
1374     setorigin(e, e.origin);
1375 }
1376
1377 void follow_sameorigin(entity e, entity to)
1378 {
1379     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1380     e.aiment = to; // make the hole follow bmodel
1381     e.punchangle = to.angles; // the original angles of bmodel
1382     e.view_ofs = e.origin - to.origin; // relative origin
1383     e.v_angle = e.angles - to.angles; // relative angles
1384 }
1385
1386 void unfollow_sameorigin(entity e)
1387 {
1388     set_movetype(e, MOVETYPE_NONE);
1389 }
1390
1391 entity gettaginfo_relative_ent;
1392 vector gettaginfo_relative(entity e, float tag)
1393 {
1394     if (!gettaginfo_relative_ent)
1395     {
1396         gettaginfo_relative_ent = spawn();
1397         gettaginfo_relative_ent.effects = EF_NODRAW;
1398     }
1399     gettaginfo_relative_ent.model = e.model;
1400     gettaginfo_relative_ent.modelindex = e.modelindex;
1401     gettaginfo_relative_ent.frame = e.frame;
1402     return gettaginfo(gettaginfo_relative_ent, tag);
1403 }
1404
1405 .string aiment_classname;
1406 .float aiment_deadflag;
1407 void SetMovetypeFollow(entity ent, entity e)
1408 {
1409         // FIXME this may not be warpzone aware
1410         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1411         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1412         ent.aiment = e; // make the hole follow bmodel
1413         ent.punchangle = e.angles; // the original angles of bmodel
1414         ent.view_ofs = ent.origin - e.origin; // relative origin
1415         ent.v_angle = ent.angles - e.angles; // relative angles
1416         ent.aiment_classname = strzone(e.classname);
1417         ent.aiment_deadflag = e.deadflag;
1418 }
1419 void UnsetMovetypeFollow(entity ent)
1420 {
1421         set_movetype(ent, MOVETYPE_FLY);
1422         PROJECTILE_MAKETRIGGER(ent);
1423         ent.aiment = NULL;
1424 }
1425 float LostMovetypeFollow(entity ent)
1426 {
1427 /*
1428         if(ent.move_movetype != MOVETYPE_FOLLOW)
1429                 if(ent.aiment)
1430                         error("???");
1431 */
1432         if(ent.aiment)
1433         {
1434                 if(ent.aiment.classname != ent.aiment_classname)
1435                         return 1;
1436                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1437                         return 1;
1438         }
1439         return 0;
1440 }
1441
1442 .bool pushable;
1443 bool isPushable(entity e)
1444 {
1445         if(e.pushable)
1446                 return true;
1447         if(IS_VEHICLE(e))
1448                 return false;
1449         if(e.iscreature)
1450                 return true;
1451         if (Item_IsLoot(e))
1452         {
1453                 return true;
1454         }
1455         switch(e.classname)
1456         {
1457                 case "body":
1458                         return true;
1459                 case "bullet": // antilagged bullets can't hit this either
1460                         return false;
1461         }
1462         if (e.projectiledeathtype)
1463                 return true;
1464         return false;
1465 }