qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2 #include "_all.qh"
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include "mutators/mutators_include.qh"
   9 #include "t_items.qh"
  10 #include "weapons/accuracy.qh"
  11 #include "weapons/csqcprojectile.qh"
  12 #include "weapons/selection.qh"
  13 #include "../common/command/generic.qh"
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes.qh"
  16 #include "../common/mapinfo.qh"
  17 #include "../common/notifications.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../common/teams.qh"
  20 #include "../common/triggers/subs.qh"
  21 #include "../common/urllib.qh"
  22 #include "../common/util.qh"
  23 #include "../common/turrets/sv_turrets.qh"
  24 #include "../common/weapons/all.qh"
  25 #include "../csqcmodellib/sv_model.qh"
  26 #include "../warpzonelib/anglestransform.qh"
  27 #include "../warpzonelib/server.qh"
  28
  29 void crosshair_trace(entity pl)
  30 {
  31         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  32 }
  33 void crosshair_trace_plusvisibletriggers(entity pl)
  34 {
  35         entity first;
  36         entity e;
  37         first = findchainfloat(solid, SOLID_TRIGGER);
  38
  39         for (e = first; e; e = e.chain)
  40                 if (e.model != "")
  41                         e.solid = SOLID_BSP;
  42
  43         crosshair_trace(pl);
  44
  45         for (e = first; e; e = e.chain)
  46                 e.solid = SOLID_TRIGGER;
  47 }
  48 void WarpZone_crosshair_trace(entity pl)
  49 {
  50         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  51 }
  52
  53
  54 string admin_name(void)
  55 {
  56         if(autocvar_sv_adminnick != "")
  57                 return autocvar_sv_adminnick;
  58         else
  59                 return "SERVER ADMIN";
  60 }
  61
  62 void DistributeEvenly_Init(float amount, float totalweight)
  63 {
  64     if (DistributeEvenly_amount)
  65     {
  66         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  67         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  68     }
  69     if (totalweight == 0)
  70         DistributeEvenly_amount = 0;
  71     else
  72         DistributeEvenly_amount = amount;
  73     DistributeEvenly_totalweight = totalweight;
  74 }
  75 float DistributeEvenly_Get(float weight)
  76 {
  77     float f;
  78     if (weight <= 0)
  79         return 0;
  80     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  81     DistributeEvenly_totalweight -= weight;
  82     DistributeEvenly_amount -= f;
  83     return f;
  84 }
  85 float DistributeEvenly_GetRandomized(float weight)
  86 {
  87     float f;
  88     if (weight <= 0)
  89         return 0;
  90     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  91     DistributeEvenly_totalweight -= weight;
  92     DistributeEvenly_amount -= f;
  93     return f;
  94 }
  95
  96
  97 void GameLogEcho(string s)
  98 {
  99     string fn;
 100     int matches;
 101
 102     if (autocvar_sv_eventlog_files)
 103     {
 104         if (!logfile_open)
 105         {
 106             logfile_open = true;
 107             matches = autocvar_sv_eventlog_files_counter + 1;
 108             cvar_set("sv_eventlog_files_counter", itos(matches));
 109             fn = ftos(matches);
 110             if (strlen(fn) < 8)
 111                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 112             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 113             logfile = fopen(fn, FILE_APPEND);
 114             fputs(logfile, ":logversion:3\n");
 115         }
 116         if (logfile >= 0)
 117         {
 118             if (autocvar_sv_eventlog_files_timestamps)
 119                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 120             else
 121                 fputs(logfile, strcat(s, "\n"));
 122         }
 123     }
 124     if (autocvar_sv_eventlog_console)
 125     {
 126         print(s, "\n");
 127     }
 128 }
 129
 130 void GameLogInit()
 131 {
 132     logfile_open = 0;
 133     // will be opened later
 134 }
 135
 136 void GameLogClose()
 137 {
 138     if (logfile_open && logfile >= 0)
 139     {
 140         fclose(logfile);
 141         logfile = -1;
 142     }
 143 }
 144
 145 entity findnearest(vector point, .string field, string value, vector axismod)
 146 {
 147     entity localhead;
 148     float i;
 149     float j;
 150     float len;
 151     vector dist;
 152
 153     float num_nearest;
 154     num_nearest = 0;
 155
 156     localhead = find(world, field, value);
 157     while (localhead)
 158     {
 159         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 160             dist = localhead.oldorigin;
 161         else
 162             dist = localhead.origin;
 163         dist = dist - point;
 164         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 165         len = vlen(dist);
 166
 167         for (i = 0; i < num_nearest; ++i)
 168         {
 169             if (len < nearest_length[i])
 170                 break;
 171         }
 172
 173         // now i tells us where to insert at
 174         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 175         if (i < NUM_NEAREST_ENTITIES)
 176         {
 177             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 178             {
 179                 nearest_length[j + 1] = nearest_length[j];
 180                 nearest_entity[j + 1] = nearest_entity[j];
 181             }
 182             nearest_length[i] = len;
 183             nearest_entity[i] = localhead;
 184             if (num_nearest < NUM_NEAREST_ENTITIES)
 185                 num_nearest = num_nearest + 1;
 186         }
 187
 188         localhead = find(localhead, field, value);
 189     }
 190
 191     // now use the first one from our list that we can see
 192     for (i = 0; i < num_nearest; ++i)
 193     {
 194         traceline(point, nearest_entity[i].origin, true, world);
 195         if (trace_fraction == 1)
 196         {
 197             if (i != 0)
 198             {
 199                 dprint("Nearest point (");
 200                 dprint(nearest_entity[0].netname);
 201                 dprint(") is not visible, using a visible one.\n");
 202             }
 203             return nearest_entity[i];
 204         }
 205     }
 206
 207     if (num_nearest == 0)
 208         return world;
 209
 210     dprint("Not seeing any location point, using nearest as fallback.\n");
 211     /* DEBUGGING CODE:
 212     dprint("Candidates were: ");
 213     for(j = 0; j < num_nearest; ++j)
 214     {
 215         if(j != 0)
 216                 dprint(", ");
 217         dprint(nearest_entity[j].netname);
 218     }
 219     dprint("\n");
 220     */
 221
 222     return nearest_entity[0];
 223 }
 224
 225 string NearestLocation(vector p)
 226 {
 227     entity loc;
 228     string ret;
 229     ret = "somewhere";
 230     loc = findnearest(p, classname, "target_location", '1 1 1');
 231     if (loc)
 232     {
 233         ret = loc.message;
 234     }
 235     else
 236     {
 237         loc = findnearest(p, target, "###item###", '1 1 4');
 238         if (loc)
 239             ret = loc.netname;
 240     }
 241     return ret;
 242 }
 243
 244 string formatmessage(string msg)
 245 {
 246         float p, p1, p2;
 247         float n;
 248         vector cursor;
 249         entity cursor_ent;
 250         string escape;
 251         string replacement;
 252         p = 0;
 253         n = 7;
 254
 255         WarpZone_crosshair_trace(self);
 256         cursor = trace_endpos;
 257         cursor_ent = trace_ent;
 258
 259         while (1) {
 260                 if (n < 1)
 261                         break; // too many replacements
 262
 263                 n = n - 1;
 264                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 265                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 266
 267                 if (p1 < 0)
 268                         p1 = p2;
 269
 270                 if (p2 < 0)
 271                         p2 = p1;
 272
 273                 p = min(p1, p2);
 274
 275                 if (p < 0)
 276                         break;
 277
 278                 replacement = substring(msg, p, 2);
 279                 escape = substring(msg, p + 1, 1);
 280
 281                 if (escape == "%")
 282                         replacement = "%";
 283                 else if (escape == "\\")
 284                         replacement = "\\";
 285                 else if (escape == "n")
 286                         replacement = "\n";
 287                 else if (escape == "a")
 288                         replacement = ftos(floor(self.armorvalue));
 289                 else if (escape == "h")
 290                         replacement = ftos(floor(self.health));
 291                 else if (escape == "l")
 292                         replacement = NearestLocation(self.origin);
 293                 else if (escape == "y")
 294                         replacement = NearestLocation(cursor);
 295                 else if (escape == "d")
 296                         replacement = NearestLocation(self.death_origin);
 297                 else if (escape == "w") {
 298                         float wep;
 299                         wep = self.weapon;
 300                         if (!wep)
 301                                 wep = self.switchweapon;
 302                         if (!wep)
 303                                 wep = self.cnt;
 304                         replacement = WEP_NAME(wep);
 305                 } else if (escape == "W") {
 306                         if (self.items & ITEM_Shells.m_itemid) replacement = "shells";
 307                         else if (self.items & ITEM_Bullets.m_itemid) replacement = "bullets";
 308                         else if (self.items & ITEM_Rockets.m_itemid) replacement = "rockets";
 309                         else if (self.items & ITEM_Cells.m_itemid) replacement = "cells";
 310                         else if (self.items & ITEM_Plasma.m_itemid) replacement = "plasma";
 311                         else replacement = "batteries"; // ;)
 312                 } else if (escape == "x") {
 313                         replacement = cursor_ent.netname;
 314                         if (replacement == "" || !cursor_ent)
 315                                 replacement = "nothing";
 316                 } else if (escape == "s")
 317                         replacement = ftos(vlen(self.velocity - self.velocity.z * '0 0 1'));
 318                 else if (escape == "S")
 319                         replacement = ftos(vlen(self.velocity));
 320
 321                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 322                 p = p + strlen(replacement);
 323         }
 324         return msg;
 325 }
 326
 327 float boolean(float value) { // if value is 0 return false (0), otherwise return true (1)
 328         return (value == 0) ? false : true;
 329 }
 330
 331 /*
 332 =============
 333 GetCvars
 334 =============
 335 Called with:
 336   0:  sends the request
 337   >0: receives a cvar from name=argv(f) value=argv(f+1)
 338 */
 339 void GetCvars_handleString(string thisname, float f, .string field, string name)
 340 {
 341         if (f < 0)
 342         {
 343                 if (self.(field))
 344                         strunzone(self.(field));
 345                 self.(field) = string_null;
 346         }
 347         else if (f > 0)
 348         {
 349                 if (thisname == name)
 350                 {
 351                         if (self.(field))
 352                                 strunzone(self.(field));
 353                         self.(field) = strzone(argv(f + 1));
 354                 }
 355         }
 356         else
 357                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 358 }
 359 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 360 {
 361         GetCvars_handleString(thisname, f, field, name);
 362         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 363                 if (thisname == name)
 364                 {
 365                         string s = func(strcat1(self.(field)));
 366                         if (s != self.(field))
 367                         {
 368                                 strunzone(self.(field));
 369                                 self.(field) = strzone(s);
 370                         }
 371                 }
 372 }
 373 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 374 {
 375         if (f < 0)
 376         {
 377         }
 378         else if (f > 0)
 379         {
 380                 if (thisname == name)
 381                         self.(field) = stof(argv(f + 1));
 382         }
 383         else
 384                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 385 }
 386 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 387 {
 388         if (f < 0)
 389         {
 390         }
 391         else if (f > 0)
 392         {
 393                 if (thisname == name)
 394                 {
 395                         if (!self.(field))
 396                         {
 397                                 self.(field) = stof(argv(f + 1));
 398                                 if (!self.(field))
 399                                         self.(field) = -1;
 400                         }
 401                 }
 402         }
 403         else
 404         {
 405                 if (!self.(field))
 406                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 407         }
 408 }
 409 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 410 {
 411         string o;
 412         o = W_FixWeaponOrder_ForceComplete(wo);
 413         if(self.weaponorder_byimpulse)
 414         {
 415                 strunzone(self.weaponorder_byimpulse);
 416                 self.weaponorder_byimpulse = string_null;
 417         }
 418         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 419         return o;
 420 }
 421 void GetCvars(float f)
 422 {
 423         string s = string_null;
 424
 425         if (f > 0)
 426                 s = strcat1(argv(f));
 427
 428         get_cvars_f = f;
 429         get_cvars_s = s;
 430         MUTATOR_CALLHOOK(GetCvars);
 431
 432         Notification_GetCvars();
 433
 434         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 435         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 436         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 437         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 438         GetCvars_handleString(s, f, cvar_cl_physics, "cl_physics");
 439         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 440         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 441         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 442         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 443         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 444         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 445         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 446         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 447         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 448         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 449         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 450         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 451         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 452         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 453         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 454         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 455         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 456         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 457         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 458         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 459
 460         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 461         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 462
 463         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 464         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 465         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 466         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 467         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 468
 469         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 470         if (f > 0)
 471         {
 472                 if (s == "cl_weaponpriority")
 473                         self.switchweapon = w_getbestweapon(self);
 474                 if (s == "cl_allow_uidtracking")
 475                         PlayerStats_GameReport_AddPlayer(self);
 476         }
 477 }
 478
 479 // decolorizes and team colors the player name when needed
 480 string playername(entity p)
 481 {
 482     string t;
 483     if (teamplay && !intermission_running && IS_PLAYER(p))
 484     {
 485         t = Team_ColorCode(p.team);
 486         return strcat(t, strdecolorize(p.netname));
 487     }
 488     else
 489         return p.netname;
 490 }
 491
 492 vector randompos(vector m1, vector m2)
 493 {
 494     vector v;
 495     m2 = m2 - m1;
 496     v.x = m2_x * random() + m1_x;
 497     v.y = m2_y * random() + m1_y;
 498     v.z = m2_z * random() + m1_z;
 499     return  v;
 500 }
 501
 502 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 503 {
 504         int i = weaponinfo.weapon;
 505         int d = 0;
 506
 507         if (!i)
 508                 return 0;
 509
 510         if (g_lms || g_ca || allguns)
 511         {
 512                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 513                         d = true;
 514                 else
 515                         d = false;
 516         }
 517         else if (g_cts)
 518                 d = (i == WEP_SHOTGUN.m_id);
 519         else if (g_nexball)
 520                 d = 0; // weapon is set a few lines later
 521         else
 522                 d = !(!weaponinfo.weaponstart);
 523
 524         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 525                 d |= (i == WEP_HOOK.m_id);
 526         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 527                 d = 0;
 528
 529         float t = weaponinfo.weaponstartoverride;
 530
 531         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 532
 533         // bit order in t:
 534         // 1: want or not
 535         // 2: is default?
 536         // 4: is set by default?
 537         if(t < 0)
 538                 t = 4 | (3 * d);
 539         else
 540                 t |= (2 * d);
 541
 542         return t;
 543 }
 544
 545 void readplayerstartcvars()
 546 {
 547         entity e;
 548         float i, j, t;
 549         string s;
 550
 551         // initialize starting values for players
 552         start_weapons = '0 0 0';
 553         start_weapons_default = '0 0 0';
 554         start_weapons_defaultmask = '0 0 0';
 555         start_items = 0;
 556         start_ammo_shells = 0;
 557         start_ammo_nails = 0;
 558         start_ammo_rockets = 0;
 559         start_ammo_cells = 0;
 560         start_ammo_plasma = 0;
 561         start_health = cvar("g_balance_health_start");
 562         start_armorvalue = cvar("g_balance_armor_start");
 563
 564         g_weaponarena = 0;
 565         g_weaponarena_weapons = '0 0 0';
 566
 567         s = cvar_string("g_weaponarena");
 568         if (s == "0" || s == "")
 569         {
 570                 if(g_ca || g_freezetag)
 571                         s = "most";
 572         }
 573
 574         if (s == "0" || s == "")
 575         {
 576                 // no arena
 577         }
 578         else if (s == "off")
 579         {
 580                 // forcibly turn off weaponarena
 581         }
 582         else if (s == "all" || s == "1")
 583         {
 584                 g_weaponarena = 1;
 585                 g_weaponarena_list = "All Weapons";
 586                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 587                 {
 588                         e = get_weaponinfo(j);
 589                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 590                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 591                 }
 592         }
 593         else if (s == "most")
 594         {
 595                 g_weaponarena = 1;
 596                 g_weaponarena_list = "Most Weapons";
 597                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 598                 {
 599                         e = get_weaponinfo(j);
 600                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 601                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 602                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 603                 }
 604         }
 605         else if (s == "none")
 606         {
 607                 g_weaponarena = 1;
 608                 g_weaponarena_list = "No Weapons";
 609         }
 610         else
 611         {
 612                 g_weaponarena = 1;
 613                 t = tokenize_console(s);
 614                 g_weaponarena_list = "";
 615                 for (i = 0; i < t; ++i)
 616                 {
 617                         s = argv(i);
 618                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 619                         {
 620                                 e = get_weaponinfo(j);
 621                                 if (e.netname == s)
 622                                 {
 623                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 624                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 625                                         break;
 626                                 }
 627                         }
 628                         if (j > WEP_LAST)
 629                         {
 630                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 631                         }
 632                 }
 633                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 634         }
 635
 636         if(g_weaponarena)
 637                 g_weaponarena_random = cvar("g_weaponarena_random");
 638         else
 639                 g_weaponarena_random = 0;
 640         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 641
 642         if (g_weaponarena)
 643         {
 644                 g_weapon_stay = 0; // incompatible
 645                 start_weapons = g_weaponarena_weapons;
 646                 start_items |= IT_UNLIMITED_AMMO;
 647         }
 648         else
 649         {
 650                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 651                 {
 652                         e = get_weaponinfo(i);
 653                         int w = want_weapon(e, false);
 654                         if(w & 1)
 655                                 start_weapons |= WepSet_FromWeapon(i);
 656                         if(w & 2)
 657                                 start_weapons_default |= WepSet_FromWeapon(i);
 658                         if(w & 4)
 659                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 660                 }
 661         }
 662
 663         if(!cvar("g_use_ammunition"))
 664                 start_items |= IT_UNLIMITED_AMMO;
 665
 666         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 667         {
 668                 start_ammo_shells = 999;
 669                 start_ammo_nails = 999;
 670                 start_ammo_rockets = 999;
 671                 start_ammo_cells = 999;
 672                 start_ammo_plasma = 999;
 673                 start_ammo_fuel = 999;
 674         }
 675         else
 676         {
 677                 start_ammo_shells = cvar("g_start_ammo_shells");
 678                 start_ammo_nails = cvar("g_start_ammo_nails");
 679                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 680                 start_ammo_cells = cvar("g_start_ammo_cells");
 681                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 682                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 683         }
 684
 685         if (warmup_stage)
 686         {
 687                 warmup_start_ammo_shells = start_ammo_shells;
 688                 warmup_start_ammo_nails = start_ammo_nails;
 689                 warmup_start_ammo_rockets = start_ammo_rockets;
 690                 warmup_start_ammo_cells = start_ammo_cells;
 691                 warmup_start_ammo_plasma = start_ammo_plasma;
 692                 warmup_start_ammo_fuel = start_ammo_fuel;
 693                 warmup_start_health = start_health;
 694                 warmup_start_armorvalue = start_armorvalue;
 695                 warmup_start_weapons = start_weapons;
 696                 warmup_start_weapons_default = start_weapons_default;
 697                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 698
 699                 if (!g_weaponarena && !g_ca && !g_freezetag)
 700                 {
 701                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 702                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 703                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 704                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 705                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 706                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 707                         warmup_start_health = cvar("g_warmup_start_health");
 708                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 709                         warmup_start_weapons = '0 0 0';
 710                         warmup_start_weapons_default = '0 0 0';
 711                         warmup_start_weapons_defaultmask = '0 0 0';
 712                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 713                         {
 714                                 e = get_weaponinfo(i);
 715                                 int w = want_weapon(e, g_warmup_allguns);
 716                                 if(w & 1)
 717                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 718                                 if(w & 2)
 719                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 720                                 if(w & 4)
 721                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 722                         }
 723                 }
 724         }
 725
 726         if (g_jetpack)
 727                 start_items |= ITEM_Jetpack.m_itemid;
 728
 729         MUTATOR_CALLHOOK(SetStartItems);
 730
 731         if ((start_items & ITEM_Jetpack.m_itemid) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 732         {
 733                 start_items |= ITEM_JetpackRegen.m_itemid;
 734                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 735                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 736         }
 737
 738         WepSet precache_weapons = start_weapons;
 739         if (g_warmup_allguns != 1)
 740                 precache_weapons |= warmup_start_weapons;
 741         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 742         {
 743                 e = get_weaponinfo(i);
 744                 if(precache_weapons & WepSet_FromWeapon(i))
 745                         WEP_ACTION(i, WR_INIT);
 746         }
 747
 748         start_ammo_shells = max(0, start_ammo_shells);
 749         start_ammo_nails = max(0, start_ammo_nails);
 750         start_ammo_rockets = max(0, start_ammo_rockets);
 751         start_ammo_cells = max(0, start_ammo_cells);
 752         start_ammo_plasma = max(0, start_ammo_plasma);
 753         start_ammo_fuel = max(0, start_ammo_fuel);
 754
 755         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 756         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 757         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 758         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 759         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 760         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 761 }
 762
 763 float sound_allowed(float destin, entity e)
 764 {
 765     // sounds from world may always pass
 766     for (;;)
 767     {
 768         if (e.classname == "body")
 769             e = e.enemy;
 770         else if (e.realowner && e.realowner != e)
 771             e = e.realowner;
 772         else if (e.owner && e.owner != e)
 773             e = e.owner;
 774         else
 775             break;
 776     }
 777     // sounds to self may always pass
 778     if (destin == MSG_ONE)
 779         if (e == msg_entity)
 780             return true;
 781     // sounds by players can be removed
 782     if (autocvar_bot_sound_monopoly)
 783         if (IS_REAL_CLIENT(e))
 784             return false;
 785     // anything else may pass
 786     return true;
 787 }
 788
 789 #undef sound
 790 void sound(entity e, float chan, string samp, float vol, float attenu)
 791 {
 792     if (!sound_allowed(MSG_BROADCAST, e))
 793         return;
 794     sound7(e, chan, samp, vol, attenu, 0, 0);
 795 }
 796
 797 void soundtoat(float _dest, entity e, vector o, float chan, string samp, float vol, float attenu)
 798 {
 799     float entno, idx;
 800
 801     if (!sound_allowed(_dest, e))
 802         return;
 803
 804     entno = num_for_edict(e);
 805     idx = precache_sound_index(samp);
 806
 807     int sflags;
 808     sflags = 0;
 809
 810     attenu = floor(attenu * 64);
 811     vol = floor(vol * 255);
 812
 813     if (vol != 255)
 814         sflags |= SND_VOLUME;
 815     if (attenu != 64)
 816         sflags |= SND_ATTENUATION;
 817     if (entno >= 8192 || chan < 0 || chan > 7)
 818         sflags |= SND_LARGEENTITY;
 819     if (idx >= 256)
 820         sflags |= SND_LARGESOUND;
 821
 822     WriteByte(_dest, SVC_SOUND);
 823     WriteByte(_dest, sflags);
 824     if (sflags & SND_VOLUME)
 825         WriteByte(_dest, vol);
 826     if (sflags & SND_ATTENUATION)
 827         WriteByte(_dest, attenu);
 828     if (sflags & SND_LARGEENTITY)
 829     {
 830         WriteShort(_dest, entno);
 831         WriteByte(_dest, chan);
 832     }
 833     else
 834     {
 835         WriteShort(_dest, entno * 8 + chan);
 836     }
 837     if (sflags & SND_LARGESOUND)
 838         WriteShort(_dest, idx);
 839     else
 840         WriteByte(_dest, idx);
 841
 842     WriteCoord(_dest, o.x);
 843     WriteCoord(_dest, o.y);
 844     WriteCoord(_dest, o.z);
 845 }
 846 void soundto(float _dest, entity e, float chan, string samp, float vol, float _atten)
 847 {
 848     vector o;
 849
 850     if (!sound_allowed(_dest, e))
 851         return;
 852
 853     o = e.origin + 0.5 * (e.mins + e.maxs);
 854     soundtoat(_dest, e, o, chan, samp, vol, _atten);
 855 }
 856 void soundat(entity e, vector o, float chan, string samp, float vol, float _atten)
 857 {
 858     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, _atten);
 859 }
 860 void stopsoundto(float _dest, entity e, float chan)
 861 {
 862     float entno;
 863
 864     if (!sound_allowed(_dest, e))
 865         return;
 866
 867     entno = num_for_edict(e);
 868
 869     if (entno >= 8192 || chan < 0 || chan > 7)
 870     {
 871         float idx, sflags;
 872         idx = precache_sound_index("misc/null.wav");
 873         sflags = SND_LARGEENTITY;
 874         if (idx >= 256)
 875             sflags |= SND_LARGESOUND;
 876         WriteByte(_dest, SVC_SOUND);
 877         WriteByte(_dest, sflags);
 878         WriteShort(_dest, entno);
 879         WriteByte(_dest, chan);
 880         if (sflags & SND_LARGESOUND)
 881             WriteShort(_dest, idx);
 882         else
 883             WriteByte(_dest, idx);
 884         WriteCoord(_dest, e.origin.x);
 885         WriteCoord(_dest, e.origin.y);
 886         WriteCoord(_dest, e.origin.z);
 887     }
 888     else
 889     {
 890         WriteByte(_dest, SVC_STOPSOUND);
 891         WriteShort(_dest, entno * 8 + chan);
 892     }
 893 }
 894 void stopsound(entity e, float chan)
 895 {
 896     if (!sound_allowed(MSG_BROADCAST, e))
 897         return;
 898
 899     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
 900     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
 901 }
 902
 903 void play2(entity e, string filename)
 904 {
 905     //stuffcmd(e, strcat("play2 ", filename, "\n"));
 906     msg_entity = e;
 907     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
 908 }
 909
 910 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
 911 .float spamtime;
 912 float spamsound(entity e, float chan, string samp, float vol, float _atten)
 913 {
 914     if (!sound_allowed(MSG_BROADCAST, e))
 915         return false;
 916
 917     if (time > e.spamtime)
 918     {
 919         e.spamtime = time;
 920         sound(e, chan, samp, vol, _atten);
 921         return true;
 922     }
 923     return false;
 924 }
 925
 926 void play2team(float t, string filename)
 927 {
 928     entity head;
 929
 930     if (autocvar_bot_sound_monopoly)
 931         return;
 932
 933     FOR_EACH_REALPLAYER(head)
 934     {
 935         if (head.team == t)
 936             play2(head, filename);
 937     }
 938 }
 939
 940 void play2all(string samp)
 941 {
 942     if (autocvar_bot_sound_monopoly)
 943         return;
 944
 945     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
 946 }
 947
 948 void PrecachePlayerSounds(string f);
 949 void precache_playermodel(string m)
 950 {
 951         float globhandle, i, n;
 952         string f;
 953
 954         if(substring(m, -9,5) == "_lod1")
 955                 return;
 956         if(substring(m, -9,5) == "_lod2")
 957                 return;
 958         precache_model(m);
 959         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 960         if(fexists(f))
 961                 precache_model(f);
 962         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 963         if(fexists(f))
 964                 precache_model(f);
 965
 966         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 967         if (globhandle < 0)
 968                 return;
 969         n = search_getsize(globhandle);
 970         for (i = 0; i < n; ++i)
 971         {
 972                 //print(search_getfilename(globhandle, i), "\n");
 973                 f = search_getfilename(globhandle, i);
 974                 PrecachePlayerSounds(f);
 975         }
 976         search_end(globhandle);
 977 }
 978 void precache_all_playermodels(string pattern)
 979 {
 980         float globhandle, i, n;
 981         string f;
 982
 983         globhandle = search_begin(pattern, true, false);
 984         if (globhandle < 0)
 985                 return;
 986         n = search_getsize(globhandle);
 987         for (i = 0; i < n; ++i)
 988         {
 989                 //print(search_getfilename(globhandle, i), "\n");
 990                 f = search_getfilename(globhandle, i);
 991                 precache_playermodel(f);
 992         }
 993         search_end(globhandle);
 994 }
 995
 996 void precache()
 997 {
 998     // gamemode related things
 999     precache_model ("models/misc/chatbubble.spr");
1000         precache_model("models/ice/ice.md3");
1001
1002     // Precache all player models if desired
1003     if (autocvar_sv_precacheplayermodels)
1004     {
1005         PrecachePlayerSounds("sound/player/default.sounds");
1006         precache_all_playermodels("models/player/*.zym");
1007         precache_all_playermodels("models/player/*.dpm");
1008         precache_all_playermodels("models/player/*.md3");
1009         precache_all_playermodels("models/player/*.psk");
1010         precache_all_playermodels("models/player/*.iqm");
1011     }
1012
1013     if (autocvar_sv_defaultcharacter)
1014     {
1015         string s;
1016         s = autocvar_sv_defaultplayermodel_red;
1017         if (s != "")
1018             precache_playermodel(s);
1019         s = autocvar_sv_defaultplayermodel_blue;
1020         if (s != "")
1021             precache_playermodel(s);
1022         s = autocvar_sv_defaultplayermodel_yellow;
1023         if (s != "")
1024             precache_playermodel(s);
1025         s = autocvar_sv_defaultplayermodel_pink;
1026         if (s != "")
1027             precache_playermodel(s);
1028         s = autocvar_sv_defaultplayermodel;
1029         if (s != "")
1030             precache_playermodel(s);
1031     }
1032
1033     if (g_footsteps)
1034     {
1035         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1036         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1037     }
1038
1039     // gore and miscellaneous sounds
1040     //precache_sound ("misc/h2ohit.wav");
1041     precache_model ("models/hook.md3");
1042     precache_sound ("misc/armorimpact.wav");
1043     precache_sound ("misc/bodyimpact1.wav");
1044     precache_sound ("misc/bodyimpact2.wav");
1045     precache_sound ("misc/gib.wav");
1046     precache_sound ("misc/gib_splat01.wav");
1047     precache_sound ("misc/gib_splat02.wav");
1048     precache_sound ("misc/gib_splat03.wav");
1049     precache_sound ("misc/gib_splat04.wav");
1050     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1051     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1052     precache_sound ("misc/null.wav");
1053     precache_sound ("misc/spawn.wav");
1054     precache_sound ("misc/talk.wav");
1055     precache_sound ("misc/teleport.wav");
1056     precache_sound ("misc/poweroff.wav");
1057     precache_sound ("player/lava.wav");
1058     precache_sound ("player/slime.wav");
1059
1060     precache_model ("models/sprites/0.spr32");
1061     precache_model ("models/sprites/1.spr32");
1062     precache_model ("models/sprites/2.spr32");
1063     precache_model ("models/sprites/3.spr32");
1064     precache_model ("models/sprites/4.spr32");
1065     precache_model ("models/sprites/5.spr32");
1066     precache_model ("models/sprites/6.spr32");
1067     precache_model ("models/sprites/7.spr32");
1068     precache_model ("models/sprites/8.spr32");
1069     precache_model ("models/sprites/9.spr32");
1070     precache_model ("models/sprites/10.spr32");
1071
1072     // common weapon precaches
1073         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1074     precache_sound ("weapons/weapon_switch.wav");
1075     precache_sound ("weapons/weaponpickup.wav");
1076     precache_sound ("weapons/unavailable.wav");
1077     precache_sound ("weapons/dryfire.wav");
1078     if (g_grappling_hook)
1079     {
1080         precache_sound ("weapons/hook_fire.wav"); // hook
1081         precache_sound ("weapons/hook_impact.wav"); // hook
1082     }
1083
1084     precache_model("models/elaser.mdl");
1085     precache_model("models/laser.mdl");
1086     precache_model("models/ebomb.mdl");
1087
1088 #if 0
1089     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1090
1091     if (!self.noise && self.music) // quake 3 uses the music field
1092         self.noise = self.music;
1093
1094     // plays music for the level if there is any
1095     if (self.noise)
1096     {
1097         precache_sound (self.noise);
1098         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1099     }
1100 #endif
1101
1102 #include "precache-for-csqc.inc"
1103 }
1104
1105
1106 void make_safe_for_remove(entity e)
1107 {
1108     if (e.initialize_entity)
1109     {
1110         entity ent, prev = world;
1111         for (ent = initialize_entity_first; ent; )
1112         {
1113             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1114             {
1115                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1116                 // skip it in linked list
1117                 if (prev)
1118                 {
1119                     prev.initialize_entity_next = ent.initialize_entity_next;
1120                     ent = prev.initialize_entity_next;
1121                 }
1122                 else
1123                 {
1124                     initialize_entity_first = ent.initialize_entity_next;
1125                     ent = initialize_entity_first;
1126                 }
1127             }
1128             else
1129             {
1130                 prev = ent;
1131                 ent = ent.initialize_entity_next;
1132             }
1133         }
1134     }
1135 }
1136
1137 void objerror(string s)
1138 {
1139     make_safe_for_remove(self);
1140     builtin_objerror(s);
1141 }
1142
1143 .float remove_except_protected_forbidden;
1144 void remove_except_protected(entity e)
1145 {
1146         if(e.remove_except_protected_forbidden)
1147                 error("not allowed to remove this at this point");
1148         builtin_remove(e);
1149 }
1150
1151 void remove_unsafely(entity e)
1152 {
1153     if(e.classname == "spike")
1154         error("Removing spikes is forbidden (crylink bug), please report");
1155     builtin_remove(e);
1156 }
1157
1158 void remove_safely(entity e)
1159 {
1160     make_safe_for_remove(e);
1161     builtin_remove(e);
1162 }
1163
1164 void InitializeEntity(entity e, void(void) func, float order)
1165 {
1166     entity prev, cur;
1167
1168     if (!e || e.initialize_entity)
1169     {
1170         // make a proxy initializer entity
1171         entity e_old;
1172         e_old = e;
1173         e = spawn();
1174         e.classname = "initialize_entity";
1175         e.enemy = e_old;
1176     }
1177
1178     e.initialize_entity = func;
1179     e.initialize_entity_order = order;
1180
1181     cur = initialize_entity_first;
1182     prev = world;
1183     for (;;)
1184     {
1185         if (!cur || cur.initialize_entity_order > order)
1186         {
1187             // insert between prev and cur
1188             if (prev)
1189                 prev.initialize_entity_next = e;
1190             else
1191                 initialize_entity_first = e;
1192             e.initialize_entity_next = cur;
1193             return;
1194         }
1195         prev = cur;
1196         cur = cur.initialize_entity_next;
1197     }
1198 }
1199 void InitializeEntitiesRun()
1200 {
1201     entity startoflist;
1202     startoflist = initialize_entity_first;
1203     initialize_entity_first = world;
1204     remove = remove_except_protected;
1205     for (self = startoflist; self; self = self.initialize_entity_next)
1206     {
1207         self.remove_except_protected_forbidden = 1;
1208     }
1209     for (self = startoflist; self; )
1210     {
1211         entity e;
1212         var void(void) func;
1213         e = self.initialize_entity_next;
1214         func = self.initialize_entity;
1215         self.initialize_entity_order = 0;
1216         self.initialize_entity = func_null;
1217         self.initialize_entity_next = world;
1218         self.remove_except_protected_forbidden = 0;
1219         if (self.classname == "initialize_entity")
1220         {
1221             entity e_old;
1222             e_old = self.enemy;
1223             builtin_remove(self);
1224             self = e_old;
1225         }
1226         //dprint("Delayed initialization: ", self.classname, "\n");
1227         if(func)
1228             func();
1229         else
1230         {
1231             eprint(self);
1232             backtrace(strcat("Null function in: ", self.classname, "\n"));
1233         }
1234         self = e;
1235     }
1236     remove = remove_unsafely;
1237 }
1238
1239 void UncustomizeEntitiesRun()
1240 {
1241     entity oldself;
1242     oldself = self;
1243     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1244         self.uncustomizeentityforclient();
1245     self = oldself;
1246 }
1247 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1248 {
1249     e.customizeentityforclient = customizer;
1250     e.uncustomizeentityforclient = uncustomizer;
1251     e.uncustomizeentityforclient_set = !!uncustomizer;
1252 }
1253
1254 void Net_LinkEntity(entity e, bool docull, float dt, bool(entity, int) sendfunc)
1255 {
1256     vector mi, ma;
1257
1258     if (e.classname == "")
1259         e.classname = "net_linked";
1260
1261     if (e.model == "" || self.modelindex == 0)
1262     {
1263         mi = e.mins;
1264         ma = e.maxs;
1265         setmodel(e, "null");
1266         setsize(e, mi, ma);
1267     }
1268
1269     e.SendEntity = sendfunc;
1270     e.SendFlags = 0xFFFFFF;
1271
1272     if (!docull)
1273         e.effects |= EF_NODEPTHTEST;
1274
1275     if (dt)
1276     {
1277         e.nextthink = time + dt;
1278         e.think = SUB_Remove;
1279     }
1280 }
1281
1282
1283 .float(entity) isEliminated;
1284 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1285 {
1286         float i, f, b;
1287         entity e;
1288         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1289         WriteByte(MSG_ENTITY, sendflags);
1290
1291         if(sendflags & 1)
1292         {
1293                 for(i = 1; i <= maxclients; i += 8)
1294                 {
1295                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1296                         {
1297                                 if(eliminatedPlayers.isEliminated(e))
1298                                         f |= b;
1299                         }
1300                         WriteByte(MSG_ENTITY, f);
1301                 }
1302         }
1303
1304         return true;
1305 }
1306
1307 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1308 {
1309         if(eliminatedPlayers)
1310         {
1311                 backtrace("Can't spawn eliminatedPlayers again!");
1312                 return;
1313         }
1314         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1315         eliminatedPlayers.isEliminated = isEliminated_func;
1316 }
1317
1318
1319 void adaptor_think2touch()
1320 {
1321     entity o;
1322     o = other;
1323     other = world;
1324     self.touch();
1325     other = o;
1326 }
1327
1328 void adaptor_think2use()
1329 {
1330     entity o, a;
1331     o = other;
1332     a = activator;
1333     activator = world;
1334     other = world;
1335     self.use();
1336     other = o;
1337     activator = a;
1338 }
1339
1340 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1341 {
1342         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1343                 self.projectiledeathtype |= HITTYPE_SPLASH;
1344         adaptor_think2use();
1345 }
1346
1347 // deferred dropping
1348 void DropToFloor_Handler()
1349 {
1350     builtin_droptofloor();
1351     self.dropped_origin = self.origin;
1352 }
1353
1354 void droptofloor()
1355 {
1356     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1357 }
1358
1359
1360
1361 float trace_hits_box_a0, trace_hits_box_a1;
1362
1363 float trace_hits_box_1d(float end, float thmi, float thma)
1364 {
1365     if (end == 0)
1366     {
1367         // just check if x is in range
1368         if (0 < thmi)
1369             return false;
1370         if (0 > thma)
1371             return false;
1372     }
1373     else
1374     {
1375         // do the trace with respect to x
1376         // 0 -> end has to stay in thmi -> thma
1377         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1378         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1379         if (trace_hits_box_a0 > trace_hits_box_a1)
1380             return false;
1381     }
1382     return true;
1383 }
1384
1385 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1386 {
1387     end -= start;
1388     thmi -= start;
1389     thma -= start;
1390     // now it is a trace from 0 to end
1391
1392     trace_hits_box_a0 = 0;
1393     trace_hits_box_a1 = 1;
1394
1395     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1396         return false;
1397     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1398         return false;
1399     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1400         return false;
1401
1402     return true;
1403 }
1404
1405 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1406 {
1407     return trace_hits_box(start, end, thmi - ma, thma - mi);
1408 }
1409
1410 float SUB_NoImpactCheck()
1411 {
1412         // zero hitcontents = this is not the real impact, but either the
1413         // mirror-impact of something hitting the projectile instead of the
1414         // projectile hitting the something, or a touchareagrid one. Neither of
1415         // these stop the projectile from moving, so...
1416         if(trace_dphitcontents == 0)
1417         {
1418                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1419                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1420                 checkclient();
1421         }
1422     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1423         return 1;
1424     if (other == world && self.size != '0 0 0')
1425     {
1426         vector tic;
1427         tic = self.velocity * sys_frametime;
1428         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1429         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1430         if (trace_fraction >= 1)
1431         {
1432             dprint("Odd... did not hit...?\n");
1433         }
1434         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1435         {
1436             dprint("Detected and prevented the sky-grapple bug.\n");
1437             return 1;
1438         }
1439     }
1440
1441     return 0;
1442 }
1443
1444 #define SUB_OwnerCheck() (other && (other == self.owner))
1445
1446 void W_Crylink_Dequeue(entity e);
1447 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1448 {
1449         if(SUB_OwnerCheck())
1450                 return true;
1451         if(SUB_NoImpactCheck())
1452         {
1453                 if(self.classname == "nade")
1454                         return false; // no checks here
1455                 else if(self.classname == "grapplinghook")
1456                         RemoveGrapplingHook(self.realowner);
1457                 else if(self.classname == "spike")
1458                 {
1459                         W_Crylink_Dequeue(self);
1460                         remove(self);
1461                 }
1462                 else
1463                         remove(self);
1464                 return true;
1465         }
1466         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1467                 UpdateCSQCProjectile(self);
1468         return false;
1469 }
1470
1471
1472 void URI_Get_Callback(float id, float status, string data)
1473 {
1474         if(url_URI_Get_Callback(id, status, data))
1475         {
1476                 // handled
1477         }
1478         else if (id == URI_GET_DISCARD)
1479         {
1480                 // discard
1481         }
1482         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1483         {
1484                 // sv_cmd curl
1485                 Curl_URI_Get_Callback(id, status, data);
1486         }
1487         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1488         {
1489                 // online ban list
1490                 OnlineBanList_URI_Get_Callback(id, status, data);
1491         }
1492         else
1493         {
1494                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1495         }
1496 }
1497
1498 string uid2name(string myuid) {
1499         string s;
1500         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1501
1502         // FIXME remove this later after 0.6 release
1503         // convert old style broken records to correct style
1504         if(s == "")
1505         {
1506                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1507                 if(s != "")
1508                 {
1509                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1510                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1511                 }
1512         }
1513
1514         if(s == "")
1515                 s = "^1Unregistered Player";
1516         return s;
1517 }
1518
1519 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1520 {
1521     float m, i;
1522     vector start, org, delta, end, enddown, mstart;
1523     entity sp;
1524
1525     m = e.dphitcontentsmask;
1526     e.dphitcontentsmask = goodcontents | badcontents;
1527
1528     org = world.mins;
1529     delta = world.maxs - world.mins;
1530
1531     start = end = org;
1532
1533     for (i = 0; i < attempts; ++i)
1534     {
1535         start.x = org.x + random() * delta.x;
1536         start.y = org.y + random() * delta.y;
1537         start.z = org.z + random() * delta.z;
1538
1539         // rule 1: start inside world bounds, and outside
1540         // solid, and don't start from somewhere where you can
1541         // fall down to evil
1542         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1543         if (trace_fraction >= 1)
1544             continue;
1545         if (trace_startsolid)
1546             continue;
1547         if (trace_dphitcontents & badcontents)
1548             continue;
1549         if (trace_dphitq3surfaceflags & badsurfaceflags)
1550             continue;
1551
1552         // rule 2: if we are too high, lower the point
1553         if (trace_fraction * delta.z > maxaboveground)
1554             start = trace_endpos + '0 0 1' * maxaboveground;
1555         enddown = trace_endpos;
1556
1557         // rule 3: make sure we aren't outside the map. This only works
1558         // for somewhat well formed maps. A good rule of thumb is that
1559         // the map should have a convex outside hull.
1560         // these can be traceLINES as we already verified the starting box
1561         mstart = start + 0.5 * (e.mins + e.maxs);
1562         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1563         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1564             continue;
1565         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1566         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1567             continue;
1568         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1569         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1570             continue;
1571         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1572         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1573             continue;
1574         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1575         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1576             continue;
1577
1578         // rule 4: we must "see" some spawnpoint or item
1579         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1580                 if(checkpvs(mstart, sp))
1581                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1582                                 break;
1583         if(!sp)
1584         {
1585                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1586                         if(checkpvs(mstart, sp))
1587                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1588                                         break;
1589                 if(!sp)
1590                         continue;
1591         }
1592
1593         // find a random vector to "look at"
1594         end.x = org.x + random() * delta.x;
1595         end.y = org.y + random() * delta.y;
1596         end.z = org.z + random() * delta.z;
1597         end = start + normalize(end - start) * vlen(delta);
1598
1599         // rule 4: start TO end must not be too short
1600         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1601         if (trace_startsolid)
1602             continue;
1603         if (trace_fraction < minviewdistance / vlen(delta))
1604             continue;
1605
1606         // rule 5: don't want to look at sky
1607         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1608             continue;
1609
1610         // rule 6: we must not end up in trigger_hurt
1611         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1612             continue;
1613
1614         break;
1615     }
1616
1617     e.dphitcontentsmask = m;
1618
1619     if (i < attempts)
1620     {
1621         setorigin(e, start);
1622         e.angles = vectoangles(end - start);
1623         dprint("Needed ", ftos(i + 1), " attempts\n");
1624         return true;
1625     }
1626     else
1627         return false;
1628 }
1629
1630 void write_recordmarker(entity pl, float tstart, float dt)
1631 {
1632     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1633
1634     // also write a marker into demo files for demotc-race-record-extractor to find
1635     stuffcmd(pl,
1636              strcat(
1637                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1638                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1639 }
1640
1641 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1642 {
1643         switch(algn)
1644         {
1645                 default:
1646                 case 3: // right
1647                         break;
1648
1649                 case 4: // left
1650                         vecs.y = -vecs.y;
1651                         break;
1652
1653                 case 1:
1654                         if(allowcenter) // 2: allow center handedness
1655                         {
1656                                 // center
1657                                 vecs.y = 0;
1658                                 vecs.z -= 2;
1659                         }
1660                         else
1661                         {
1662                                 // right
1663                         }
1664                         break;
1665
1666                 case 2:
1667                         if(allowcenter) // 2: allow center handedness
1668                         {
1669                                 // center
1670                                 vecs.y = 0;
1671                                 vecs.z -= 2;
1672                         }
1673                         else
1674                         {
1675                                 // left
1676                                 vecs.y = -vecs.y;
1677                         }
1678                         break;
1679         }
1680         return vecs;
1681 }
1682
1683 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1684 {
1685         string s;
1686         vector v;
1687
1688         if (autocvar_g_shootfromeye)
1689         {
1690                 if (visual)
1691                 {
1692                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
1693                         else { vecs.y = 0; vecs.z -= 2; }
1694                 }
1695                 else
1696                 {
1697                         vecs.y = 0;
1698                         vecs.z = 0;
1699                 }
1700         }
1701         else if (autocvar_g_shootfromcenter)
1702         {
1703                 vecs.y = 0;
1704                 vecs.z -= 2;
1705         }
1706         else if ((s = autocvar_g_shootfromfixedorigin) != "")
1707         {
1708                 v = stov(s);
1709                 if (y_is_right)
1710                         v.y = -v.y;
1711                 if (v.x != 0)
1712                         vecs.x = v.x;
1713                 vecs.y = v.y;
1714                 vecs.z = v.z;
1715         }
1716         else if (autocvar_g_shootfromclient)
1717         {
1718                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
1719         }
1720         return vecs;
1721 }
1722
1723 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
1724 {
1725         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
1726 }
1727
1728
1729 void attach_sameorigin(entity e, entity to, string tag)
1730 {
1731     vector org, t_forward, t_left, t_up, e_forward, e_up;
1732     float tagscale;
1733
1734     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1735     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
1736     t_forward = v_forward * tagscale;
1737     t_left = v_right * -tagscale;
1738     t_up = v_up * tagscale;
1739
1740     e.origin_x = org * t_forward;
1741     e.origin_y = org * t_left;
1742     e.origin_z = org * t_up;
1743
1744     // current forward and up directions
1745     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1746                 e.angles = AnglesTransform_FromVAngles(e.angles);
1747         else
1748                 e.angles = AnglesTransform_FromAngles(e.angles);
1749     fixedmakevectors(e.angles);
1750
1751     // untransform forward, up!
1752     e_forward.x = v_forward * t_forward;
1753     e_forward.y = v_forward * t_left;
1754     e_forward.z = v_forward * t_up;
1755     e_up.x = v_up * t_forward;
1756     e_up.y = v_up * t_left;
1757     e_up.z = v_up * t_up;
1758
1759     e.angles = fixedvectoangles2(e_forward, e_up);
1760     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1761                 e.angles = AnglesTransform_ToVAngles(e.angles);
1762         else
1763                 e.angles = AnglesTransform_ToAngles(e.angles);
1764
1765     setattachment(e, to, tag);
1766     setorigin(e, e.origin);
1767 }
1768
1769 void detach_sameorigin(entity e)
1770 {
1771     vector org;
1772     org = gettaginfo(e, 0);
1773     e.angles = fixedvectoangles2(v_forward, v_up);
1774     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1775                 e.angles = AnglesTransform_ToVAngles(e.angles);
1776         else
1777                 e.angles = AnglesTransform_ToAngles(e.angles);
1778     setorigin(e, org);
1779     setattachment(e, world, "");
1780     setorigin(e, e.origin);
1781 }
1782
1783 void follow_sameorigin(entity e, entity to)
1784 {
1785     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
1786     e.aiment = to; // make the hole follow bmodel
1787     e.punchangle = to.angles; // the original angles of bmodel
1788     e.view_ofs = e.origin - to.origin; // relative origin
1789     e.v_angle = e.angles - to.angles; // relative angles
1790 }
1791
1792 void unfollow_sameorigin(entity e)
1793 {
1794     e.movetype = MOVETYPE_NONE;
1795 }
1796
1797 entity gettaginfo_relative_ent;
1798 vector gettaginfo_relative(entity e, float tag)
1799 {
1800     if (!gettaginfo_relative_ent)
1801     {
1802         gettaginfo_relative_ent = spawn();
1803         gettaginfo_relative_ent.effects = EF_NODRAW;
1804     }
1805     gettaginfo_relative_ent.model = e.model;
1806     gettaginfo_relative_ent.modelindex = e.modelindex;
1807     gettaginfo_relative_ent.frame = e.frame;
1808     return gettaginfo(gettaginfo_relative_ent, tag);
1809 }
1810
1811 .float scale2;
1812
1813 float modeleffect_SendEntity(entity to, int sf)
1814 {
1815         float f;
1816         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
1817
1818         f = 0;
1819         if(self.velocity != '0 0 0')
1820                 f |= 1;
1821         if(self.angles != '0 0 0')
1822                 f |= 2;
1823         if(self.avelocity != '0 0 0')
1824                 f |= 4;
1825
1826         WriteByte(MSG_ENTITY, f);
1827         WriteShort(MSG_ENTITY, self.modelindex);
1828         WriteByte(MSG_ENTITY, self.skin);
1829         WriteByte(MSG_ENTITY, self.frame);
1830         WriteCoord(MSG_ENTITY, self.origin.x);
1831         WriteCoord(MSG_ENTITY, self.origin.y);
1832         WriteCoord(MSG_ENTITY, self.origin.z);
1833         if(f & 1)
1834         {
1835                 WriteCoord(MSG_ENTITY, self.velocity.x);
1836                 WriteCoord(MSG_ENTITY, self.velocity.y);
1837                 WriteCoord(MSG_ENTITY, self.velocity.z);
1838         }
1839         if(f & 2)
1840         {
1841                 WriteCoord(MSG_ENTITY, self.angles.x);
1842                 WriteCoord(MSG_ENTITY, self.angles.y);
1843                 WriteCoord(MSG_ENTITY, self.angles.z);
1844         }
1845         if(f & 4)
1846         {
1847                 WriteCoord(MSG_ENTITY, self.avelocity.x);
1848                 WriteCoord(MSG_ENTITY, self.avelocity.y);
1849                 WriteCoord(MSG_ENTITY, self.avelocity.z);
1850         }
1851         WriteShort(MSG_ENTITY, self.scale * 256.0);
1852         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
1853         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
1854         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
1855         WriteByte(MSG_ENTITY, self.alpha * 255.0);
1856
1857         return true;
1858 }
1859
1860 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
1861 {
1862         entity e;
1863         float sz;
1864         e = spawn();
1865         e.classname = "modeleffect";
1866         setmodel(e, m);
1867         e.frame = f;
1868         setorigin(e, o);
1869         e.velocity = v;
1870         e.angles = ang;
1871         e.avelocity = angv;
1872         e.alpha = a;
1873         e.teleport_time = t1;
1874         e.fade_time = t2;
1875         e.skin = s;
1876         if(s0 >= 0)
1877                 e.scale = s0 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1878         else
1879                 e.scale = -s0;
1880         if(s2 >= 0)
1881                 e.scale2 = s2 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1882         else
1883                 e.scale2 = -s2;
1884         sz = max(e.scale, e.scale2);
1885         setsize(e, e.mins * sz, e.maxs * sz);
1886         Net_LinkEntity(e, false, 0.1, modeleffect_SendEntity);
1887 }
1888
1889 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
1890 {
1891         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
1892 }
1893
1894 float randombit(float bits)
1895 {
1896         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
1897                 return bits;
1898
1899         float n, f, b, r;
1900
1901         r = random();
1902         b = 0;
1903         n = 0;
1904
1905         for(f = 1; f <= bits; f *= 2)
1906         {
1907                 if(bits & f)
1908                 {
1909                         ++n;
1910                         r *= n;
1911                         if(r <= 1)
1912                                 b = f;
1913                         else
1914                                 r = (r - 1) / (n - 1);
1915                 }
1916         }
1917
1918         return b;
1919 }
1920
1921 float randombits(float bits, float k, float error_return)
1922 {
1923         float r;
1924         r = 0;
1925         while(k > 0 && bits != r)
1926         {
1927                 r += randombit(bits - r);
1928                 --k;
1929         }
1930         if(error_return)
1931                 if(k > 0)
1932                         return -1; // all
1933         return r;
1934 }
1935
1936 void randombit_test(float bits, float iter)
1937 {
1938         while(iter > 0)
1939         {
1940                 print(ftos(randombit(bits)), "\n");
1941                 --iter;
1942         }
1943 }
1944
1945 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
1946 {
1947         if(halflifedist > 0)
1948                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
1949         else if(halflifedist < 0)
1950                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
1951         else
1952                 return 1;
1953 }
1954
1955
1956 void defer_think()
1957 {
1958     entity oself;
1959
1960     oself           = self;
1961     self            = self.owner;
1962     oself.think     = SUB_Remove;
1963     oself.nextthink = time;
1964
1965     oself.use();
1966 }
1967
1968 /*
1969     Execute func() after time + fdelay.
1970     self when func is executed = self when defer is called
1971 */
1972 void defer(float fdelay, void() func)
1973 {
1974     entity e;
1975
1976     e           = spawn();
1977     e.owner     = self;
1978     e.use       = func;
1979     e.think     = defer_think;
1980     e.nextthink = time + fdelay;
1981 }
1982
1983 .string aiment_classname;
1984 .float aiment_deadflag;
1985 void SetMovetypeFollow(entity ent, entity e)
1986 {
1987         // FIXME this may not be warpzone aware
1988         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
1989         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1990         ent.aiment = e; // make the hole follow bmodel
1991         ent.punchangle = e.angles; // the original angles of bmodel
1992         ent.view_ofs = ent.origin - e.origin; // relative origin
1993         ent.v_angle = ent.angles - e.angles; // relative angles
1994         ent.aiment_classname = strzone(e.classname);
1995         ent.aiment_deadflag = e.deadflag;
1996 }
1997 void UnsetMovetypeFollow(entity ent)
1998 {
1999         ent.movetype = MOVETYPE_FLY;
2000         PROJECTILE_MAKETRIGGER(ent);
2001         ent.aiment = world;
2002 }
2003 float LostMovetypeFollow(entity ent)
2004 {
2005 /*
2006         if(ent.movetype != MOVETYPE_FOLLOW)
2007                 if(ent.aiment)
2008                         error("???");
2009 */
2010         if(ent.aiment)
2011         {
2012                 if(ent.aiment.classname != ent.aiment_classname)
2013                         return 1;
2014                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2015                         return 1;
2016         }
2017         return 0;
2018 }
2019
2020 float isPushable(entity e)
2021 {
2022         if(e.iscreature)
2023                 return true;
2024         if(e.pushable)
2025                 return true;
2026         switch(e.classname)
2027         {
2028                 case "body":
2029                 case "droppedweapon":
2030                 case "keepawayball":
2031                 case "nexball_basketball":
2032                 case "nexball_football":
2033                         return true;
2034                 case "bullet": // antilagged bullets can't hit this either
2035                         return false;
2036         }
2037         if (e.projectiledeathtype)
2038                 return true;
2039         return false;
2040 }