qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 float race_GetTime(float pos);
  20 string race_GetName(float pos);
  21 string race_PlaceName(float pos);
  22 string GetMapname();
  23 string ColoredTeamName(float t);
  24
  25 string admin_name(void)
  26 {
  27         if(cvar_string("sv_adminnick") != "")
  28                 return cvar_string("sv_adminnick");
  29         else
  30                 return "SERVER ADMIN";
  31 }
  32
  33 float DistributeEvenly_amount;
  34 float DistributeEvenly_totalweight;
  35 void DistributeEvenly_Init(float amount, float totalweight)
  36 {
  37     if (DistributeEvenly_amount)
  38     {
  39         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  40         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  41     }
  42     if (totalweight == 0)
  43         DistributeEvenly_amount = 0;
  44     else
  45         DistributeEvenly_amount = amount;
  46     DistributeEvenly_totalweight = totalweight;
  47 }
  48 float DistributeEvenly_Get(float weight)
  49 {
  50     float f;
  51     if (weight <= 0)
  52         return 0;
  53     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  54     DistributeEvenly_totalweight -= weight;
  55     DistributeEvenly_amount -= f;
  56     return f;
  57 }
  58
  59 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  60
  61
  62 string STR_PLAYER = "player";
  63 string STR_SPECTATOR = "spectator";
  64 string STR_OBSERVER = "observer";
  65
  66 #if 0
  67 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  68 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  69 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  70 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  71 #else
  72 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  73 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  74 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  75 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  76 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  77 #endif
  78
  79 // copies a string to a tempstring (so one can strunzone it)
  80 string strcat1(string s) = #115; // FRIK_FILE
  81
  82 float logfile_open;
  83 float logfile;
  84
  85 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  86 {
  87         local float nPlayerHealth = rint(enPlayer.health);
  88         local float nPlayerArmor = rint(enPlayer.armorvalue);
  89         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  90         local float nPlayerPing = rint(enPlayer.ping);
  91         local string strPlayerPingColor;
  92         local string strMessage;
  93         if(nPlayerPing >= 150)
  94                 strPlayerPingColor = "^1";
  95         else
  96                 strPlayerPingColor = "^2";
  97
  98         if((cvar("sv_fragmessage_information_stats")) && (enPlayer.health >= 1))
  99                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
 100
 101         if(cvar("sv_fragmessage_information_ping")) {
 102                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 103                         strMessage = strcat(strMessage, " ^7(^2Bot");
 104                 else
 105                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 106                 if(cvar("sv_fragmessage_information_handicap"))
 107                         if(cvar("sv_fragmessage_information_handicap") == 2)
 108                                 if(nPlayerHandicap <= 1)
 109                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 110                                 else
 111                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 112                         else if not(nPlayerHandicap <= 1)
 113                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 114                 else
 115                         strMessage = strcat(strMessage, "^7)");
 116         } else if(cvar("sv_fragmessage_information_handicap")) {
 117                 if(cvar("sv_fragmessage_information_handicap") == 2)
 118                         if(nPlayerHandicap <= 1)
 119                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 120                         else
 121                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 122                 else if(nPlayerHandicap > 1)
 123                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 124         }
 125         return strMessage;
 126 }
 127 void bcenterprint(string s)
 128 {
 129     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 130     entity head;
 131     FOR_EACH_PLAYER(head)
 132     if (clienttype(head) == CLIENTTYPE_REAL)
 133         centerprint(head, s);
 134 }
 135
 136 void GameLogEcho(string s)
 137 {
 138     string fn;
 139     float matches;
 140
 141     if (cvar("sv_eventlog_files"))
 142     {
 143         if (!logfile_open)
 144         {
 145             logfile_open = TRUE;
 146             matches = cvar("sv_eventlog_files_counter") + 1;
 147             cvar_set("sv_eventlog_files_counter", ftos(matches));
 148             fn = ftos(matches);
 149             if (strlen(fn) < 8)
 150                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 151             fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 152             logfile = fopen(fn, FILE_APPEND);
 153             fputs(logfile, ":logversion:3\n");
 154         }
 155         if (logfile >= 0)
 156         {
 157             if (cvar("sv_eventlog_files_timestamps"))
 158                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 159             else
 160                 fputs(logfile, strcat(s, "\n"));
 161         }
 162     }
 163     if (cvar("sv_eventlog_console"))
 164     {
 165         print(s, "\n");
 166     }
 167 }
 168
 169 void GameLogInit()
 170 {
 171     logfile_open = 0;
 172     // will be opened later
 173 }
 174
 175 void GameLogClose()
 176 {
 177     if (logfile_open && logfile >= 0)
 178     {
 179         fclose(logfile);
 180         logfile = -1;
 181     }
 182 }
 183
 184 vector PL_VIEW_OFS;
 185 vector PL_MIN;
 186 vector PL_MAX;
 187 vector PL_CROUCH_VIEW_OFS;
 188 vector PL_CROUCH_MIN;
 189 vector PL_CROUCH_MAX;
 190
 191 float spawnpoint_nag;
 192 void relocate_spawnpoint()
 193 {
 194     PL_VIEW_OFS                             = stov(cvar_string("sv_player_viewoffset"));
 195     PL_MIN                                  = stov(cvar_string("sv_player_mins"));
 196     PL_MAX                                  = stov(cvar_string("sv_player_maxs"));
 197     PL_CROUCH_VIEW_OFS                      = stov(cvar_string("sv_player_crouch_viewoffset"));
 198     PL_CROUCH_MIN                           = stov(cvar_string("sv_player_crouch_mins"));
 199     PL_CROUCH_MAX                           = stov(cvar_string("sv_player_crouch_maxs"));
 200
 201     // nudge off the floor
 202     setorigin(self, self.origin + '0 0 1');
 203
 204     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 205     if (trace_startsolid)
 206     {
 207         vector o;
 208         o = self.origin;
 209         self.mins = PL_MIN;
 210         self.maxs = PL_MAX;
 211         if (!move_out_of_solid(self))
 212             objerror("could not get out of solid at all!");
 213         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 214         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 215         print(" ", ftos(self.origin_y - o_y));
 216         print(" ", ftos(self.origin_z - o_z), "'\n");
 217         if (cvar("g_spawnpoints_auto_move_out_of_solid"))
 218         {
 219             if (!spawnpoint_nag)
 220                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 221             spawnpoint_nag = 1;
 222         }
 223         else
 224         {
 225             setorigin(self, o);
 226             self.mins = self.maxs = '0 0 0';
 227             objerror("player spawn point in solid, mapper sucks!\n");
 228             return;
 229         }
 230     }
 231
 232     self.use = spawnpoint_use;
 233     self.team_saved = self.team;
 234     if (!self.cnt)
 235         self.cnt = 1;
 236
 237     if (have_team_spawns != 0)
 238         if (self.team)
 239             have_team_spawns = 1;
 240
 241     if (cvar("r_showbboxes"))
 242     {
 243         // show where spawnpoints point at too
 244         makevectors(self.angles);
 245         entity e;
 246         e = spawn();
 247         e.classname = "info_player_foo";
 248         setorigin(e, self.origin + v_forward * 24);
 249         setsize(e, '-8 -8 -8', '8 8 8');
 250         e.solid = SOLID_TRIGGER;
 251     }
 252 }
 253
 254 #define strstr strstrofs
 255 /*
 256 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 257 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 258 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 259 // BE CONSTANT OR strzoneD!
 260 float strstr(string haystack, string needle, float offset)
 261 {
 262         float len, endpos;
 263         string found;
 264         len = strlen(needle);
 265         endpos = strlen(haystack) - len;
 266         while(offset <= endpos)
 267         {
 268                 found = substring(haystack, offset, len);
 269                 if(found == needle)
 270                         return offset;
 271                 offset = offset + 1;
 272         }
 273         return -1;
 274 }
 275 */
 276
 277 float NUM_NEAREST_ENTITIES = 4;
 278 entity nearest_entity[NUM_NEAREST_ENTITIES];
 279 float nearest_length[NUM_NEAREST_ENTITIES];
 280 entity findnearest(vector point, .string field, string value, vector axismod)
 281 {
 282     entity localhead;
 283     float i;
 284     float j;
 285     float len;
 286     vector dist;
 287
 288     float num_nearest;
 289     num_nearest = 0;
 290
 291     localhead = find(world, field, value);
 292     while (localhead)
 293     {
 294         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 295             dist = localhead.oldorigin;
 296         else
 297             dist = localhead.origin;
 298         dist = dist - point;
 299         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 300         len = vlen(dist);
 301
 302         for (i = 0; i < num_nearest; ++i)
 303         {
 304             if (len < nearest_length[i])
 305                 break;
 306         }
 307
 308         // now i tells us where to insert at
 309         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 310         if (i < NUM_NEAREST_ENTITIES)
 311         {
 312             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 313             {
 314                 nearest_length[j + 1] = nearest_length[j];
 315                 nearest_entity[j + 1] = nearest_entity[j];
 316             }
 317             nearest_length[i] = len;
 318             nearest_entity[i] = localhead;
 319             if (num_nearest < NUM_NEAREST_ENTITIES)
 320                 num_nearest = num_nearest + 1;
 321         }
 322
 323         localhead = find(localhead, field, value);
 324     }
 325
 326     // now use the first one from our list that we can see
 327     for (i = 0; i < num_nearest; ++i)
 328     {
 329         traceline(point, nearest_entity[i].origin, TRUE, world);
 330         if (trace_fraction == 1)
 331         {
 332             if (i != 0)
 333             {
 334                 dprint("Nearest point (");
 335                 dprint(nearest_entity[0].netname);
 336                 dprint(") is not visible, using a visible one.\n");
 337             }
 338             return nearest_entity[i];
 339         }
 340     }
 341
 342     if (num_nearest == 0)
 343         return world;
 344
 345     dprint("Not seeing any location point, using nearest as fallback.\n");
 346     /* DEBUGGING CODE:
 347     dprint("Candidates were: ");
 348     for(j = 0; j < num_nearest; ++j)
 349     {
 350         if(j != 0)
 351                 dprint(", ");
 352         dprint(nearest_entity[j].netname);
 353     }
 354     dprint("\n");
 355     */
 356
 357     return nearest_entity[0];
 358 }
 359
 360 void spawnfunc_target_location()
 361 {
 362     self.classname = "target_location";
 363     // location name in netname
 364     // eventually support: count, teamgame selectors, line of sight?
 365 };
 366
 367 void spawnfunc_info_location()
 368 {
 369     self.classname = "target_location";
 370     self.message = self.netname;
 371 };
 372
 373 string NearestLocation(vector p)
 374 {
 375     entity loc;
 376     string ret;
 377     ret = "somewhere";
 378     loc = findnearest(p, classname, "target_location", '1 1 1');
 379     if (loc)
 380     {
 381         ret = loc.message;
 382     }
 383     else
 384     {
 385         loc = findnearest(p, target, "###item###", '1 1 4');
 386         if (loc)
 387             ret = loc.netname;
 388     }
 389     return ret;
 390 }
 391
 392 string formatmessage(string msg)
 393 {
 394         float p, p1, p2;
 395         float n;
 396         vector cursor;
 397         entity cursor_ent;
 398         string escape;
 399         string replacement;
 400         p = 0;
 401         n = 7;
 402
 403         WarpZone_crosshair_trace(self);
 404         cursor = trace_endpos;
 405         cursor_ent = trace_ent;
 406
 407         while (1) {
 408                 if (n < 1)
 409                         break; // too many replacements
 410
 411                 n = n - 1;
 412                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 413                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 414
 415                 if (p1 < 0)
 416                         p1 = p2;
 417
 418                 if (p2 < 0)
 419                         p2 = p1;
 420
 421                 p = min(p1, p2);
 422
 423                 if (p < 0)
 424                         break;
 425
 426                 replacement = substring(msg, p, 2);
 427                 escape = substring(msg, p + 1, 1);
 428
 429                 if (escape == "%")
 430                         replacement = "%";
 431                 else if (escape == "\\")
 432                         replacement = "\\";
 433                 else if (escape == "n")
 434                         replacement = "\n";
 435                 else if (escape == "a")
 436                         replacement = ftos(floor(self.armorvalue));
 437                 else if (escape == "h")
 438                         replacement = ftos(floor(self.health));
 439                 else if (escape == "l")
 440                         replacement = NearestLocation(self.origin);
 441                 else if (escape == "y")
 442                         replacement = NearestLocation(cursor);
 443                 else if (escape == "d")
 444                         replacement = NearestLocation(self.death_origin);
 445                 else if (escape == "w") {
 446                         float wep;
 447                         wep = self.weapon;
 448                         if (!wep)
 449                                 wep = self.switchweapon;
 450                         if (!wep)
 451                                 wep = self.cnt;
 452                         replacement = W_Name(wep);
 453                 } else if (escape == "W") {
 454                         if (self.items & IT_SHELLS) replacement = "shells";
 455                         else if (self.items & IT_NAILS) replacement = "bullets";
 456                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 457                         else if (self.items & IT_CELLS) replacement = "cells";
 458                         else replacement = "batteries"; // ;)
 459                 } else if (escape == "x") {
 460                         replacement = cursor_ent.netname;
 461                         if (!replacement || !cursor_ent)
 462                                 replacement = "nothing";
 463                 } else if (escape == "p") {
 464                         if (self.last_selected_player)
 465                                 replacement = self.last_selected_player.netname;
 466                         else
 467                                 replacement = "(nobody)";
 468                 } else if (escape == "s")
 469                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 470                 else if (escape == "S")
 471                         replacement = ftos(vlen(self.velocity));
 472                 else if (escape == "v") {
 473                         float weapon_number;
 474                         local entity stats;
 475
 476                         if(self.classname == "spectator")
 477                                 stats = self.enemy;
 478                         else
 479                                 stats = self;
 480
 481                         weapon_number = stats.weapon;
 482
 483                         if (!weapon_number)
 484                                 weapon_number = stats.switchweapon;
 485
 486                         if (!weapon_number)
 487                                 weapon_number = stats.cnt;
 488
 489                         if(stats.cvar_cl_accuracy_data_share && stats.stats_fired[weapon_number - 1])
 490                                 replacement = ftos(bound(0, floor(100 * stats.stats_hit[weapon_number - 1] / stats.stats_fired[weapon_number - 1]), 100));
 491                         else
 492                                 replacement = "~"; // or something to indicate NULL, not available
 493                 }
 494
 495                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 496                 p = p + strlen(replacement);
 497         }
 498         return msg;
 499 }
 500
 501 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 502         return (value == 0) ? FALSE : TRUE;
 503 }
 504
 505 /*
 506 =============
 507 GetCvars
 508 =============
 509 Called with:
 510   0:  sends the request
 511   >0: receives a cvar from name=argv(f) value=argv(f+1)
 512 */
 513 void GetCvars_handleString(string thisname, float f, .string field, string name)
 514 {
 515         if (f < 0)
 516         {
 517                 if (self.field)
 518                         strunzone(self.field);
 519                 self.field = string_null;
 520         }
 521         else if (f > 0)
 522         {
 523                 if (thisname == name)
 524                 {
 525                         if (self.field)
 526                                 strunzone(self.field);
 527                         self.field = strzone(argv(f + 1));
 528                 }
 529         }
 530         else
 531                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 532 }
 533 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 534 {
 535         GetCvars_handleString(thisname, f, field, name);
 536         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 537                 if (thisname == name)
 538                 {
 539                         string s;
 540                         s = func(strcat1(self.field));
 541                         if (s != self.field)
 542                         {
 543                                 strunzone(self.field);
 544                                 self.field = strzone(s);
 545                         }
 546                 }
 547 }
 548 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 549 {
 550         if (f < 0)
 551         {
 552         }
 553         else if (f > 0)
 554         {
 555                 if (thisname == name)
 556                         self.field = stof(argv(f + 1));
 557         }
 558         else
 559                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 560 }
 561 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 562 {
 563         if (f < 0)
 564         {
 565         }
 566         else if (f > 0)
 567         {
 568                 if (thisname == name)
 569                 {
 570                         if(!self.field)
 571                         {
 572                                 self.field = stof(argv(f + 1));
 573                                 if(!self.field)
 574                                         self.field = -1;
 575                         }
 576                 }
 577         }
 578         else
 579         {
 580                 if(!self.field)
 581                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 582         }
 583 }
 584 string W_FixWeaponOrder_ForceComplete(string s);
 585 string W_FixWeaponOrder_AllowIncomplete(string s);
 586 float w_getbestweapon(entity e);
 587 void GetCvars(float f)
 588 {
 589         string s;
 590
 591         if (f > 0)
 592                 s = strcat1(argv(f));
 593
 594         get_cvars_f = f;
 595         get_cvars_s = s;
 596         MUTATOR_CALLHOOK(GetCvars);
 597         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 598         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 599         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 600         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 601         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 602         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 603         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 604         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 605         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 606         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 607         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 608         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 609         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 610         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 611         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 612         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 613         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 614         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 615         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 616         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 617         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 618         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 619         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 620         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 621         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 622
 623         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 624         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 625
 626 #ifdef ALLOW_FORCEMODELS
 627         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 628         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 629 #endif
 630         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 631
 632         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 633         if (f > 0)
 634         {
 635                 if (s == "cl_weaponpriority")
 636                         self.switchweapon = w_getbestweapon(self);
 637         }
 638 }
 639
 640 float fexists(string f)
 641 {
 642     float fh;
 643     fh = fopen(f, FILE_READ);
 644     if (fh < 0)
 645         return FALSE;
 646     fclose(fh);
 647     return TRUE;
 648 }
 649
 650 void backtrace(string msg)
 651 {
 652     float dev, war;
 653     dev = cvar("developer");
 654     war = cvar("prvm_backtraceforwarnings");
 655     cvar_set("developer", "1");
 656     cvar_set("prvm_backtraceforwarnings", "1");
 657     print("\n");
 658     print("--- CUT HERE ---\nWARNING: ");
 659     print(msg);
 660     print("\n");
 661     remove(world); // isn't there any better way to cause a backtrace?
 662     print("\n--- CUT UNTIL HERE ---\n");
 663     cvar_set("developer", ftos(dev));
 664     cvar_set("prvm_backtraceforwarnings", ftos(war));
 665 }
 666
 667 string Team_ColorCode(float teamid)
 668 {
 669     if (teamid == COLOR_TEAM1)
 670         return "^1";
 671     else if (teamid == COLOR_TEAM2)
 672         return "^4";
 673     else if (teamid == COLOR_TEAM3)
 674         return "^3";
 675     else if (teamid == COLOR_TEAM4)
 676         return "^6";
 677     else
 678         return "^7";
 679 }
 680
 681 string Team_ColorName(float t)
 682 {
 683     // fixme: Search for team entities and get their .netname's!
 684     if (t == COLOR_TEAM1)
 685         return "Red";
 686     if (t == COLOR_TEAM2)
 687         return "Blue";
 688     if (t == COLOR_TEAM3)
 689         return "Yellow";
 690     if (t == COLOR_TEAM4)
 691         return "Pink";
 692     return "Neutral";
 693 }
 694
 695 string Team_ColorNameLowerCase(float t)
 696 {
 697     // fixme: Search for team entities and get their .netname's!
 698     if (t == COLOR_TEAM1)
 699         return "red";
 700     if (t == COLOR_TEAM2)
 701         return "blue";
 702     if (t == COLOR_TEAM3)
 703         return "yellow";
 704     if (t == COLOR_TEAM4)
 705         return "pink";
 706     return "neutral";
 707 }
 708
 709 float ColourToNumber(string team_colour)
 710 {
 711         if (team_colour == "red")
 712                 return COLOR_TEAM1;
 713
 714         if (team_colour == "blue")
 715                 return COLOR_TEAM2;
 716
 717         if (team_colour == "yellow")
 718                 return COLOR_TEAM3;
 719
 720         if (team_colour == "pink")
 721                 return COLOR_TEAM4;
 722
 723         if (team_colour == "auto")
 724                 return 0;
 725
 726         return -1;
 727 }
 728
 729 float NumberToTeamNumber(float number)
 730 {
 731         if (number == 1)
 732                 return COLOR_TEAM1;
 733
 734         if (number == 2)
 735                 return COLOR_TEAM2;
 736
 737         if (number == 3)
 738                 return COLOR_TEAM3;
 739
 740         if (number == 4)
 741                 return COLOR_TEAM4;
 742
 743         return -1;
 744 }
 745
 746 #define CENTERPRIO_POINT 1
 747 #define CENTERPRIO_SPAM 2
 748 #define CENTERPRIO_VOTE 4
 749 #define CENTERPRIO_NORMAL 5
 750 #define CENTERPRIO_SHIELDING 7
 751 #define CENTERPRIO_MAPVOTE 9
 752 #define CENTERPRIO_IDLEKICK 50
 753 #define CENTERPRIO_ADMIN 99
 754 .float centerprint_priority;
 755 .float centerprint_expires;
 756 void centerprint_atprio(entity e, float prio, string s)
 757 {
 758     if (intermission_running)
 759         if (prio < CENTERPRIO_MAPVOTE)
 760             return;
 761     if (time > e.centerprint_expires)
 762         e.centerprint_priority = 0;
 763     if (prio >= e.centerprint_priority)
 764     {
 765         e.centerprint_priority = prio;
 766         if (timeoutStatus == 2)
 767             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 768         else
 769             e.centerprint_expires = time + e.cvar_scr_centertime;
 770         centerprint_builtin(e, s);
 771     }
 772 }
 773 void centerprint_expire(entity e, float prio)
 774 {
 775     if (prio == e.centerprint_priority)
 776     {
 777         e.centerprint_priority = 0;
 778         centerprint_builtin(e, "");
 779     }
 780 }
 781 void centerprint(entity e, string s)
 782 {
 783     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 784 }
 785
 786 // decolorizes and team colors the player name when needed
 787 string playername(entity p)
 788 {
 789     string t;
 790     if (teams_matter && !intermission_running && p.classname == "player")
 791     {
 792         t = Team_ColorCode(p.team);
 793         return strcat(t, strdecolorize(p.netname));
 794     }
 795     else
 796         return p.netname;
 797 }
 798
 799 vector randompos(vector m1, vector m2)
 800 {
 801     local vector v;
 802     m2 = m2 - m1;
 803     v_x = m2_x * random() + m1_x;
 804     v_y = m2_y * random() + m1_y;
 805     v_z = m2_z * random() + m1_z;
 806     return  v;
 807 };
 808
 809 float g_pickup_shells;
 810 float g_pickup_shells_max;
 811 float g_pickup_nails;
 812 float g_pickup_nails_max;
 813 float g_pickup_rockets;
 814 float g_pickup_rockets_max;
 815 float g_pickup_cells;
 816 float g_pickup_cells_max;
 817 float g_pickup_fuel;
 818 float g_pickup_fuel_jetpack;
 819 float g_pickup_fuel_max;
 820 float g_pickup_armorsmall;
 821 float g_pickup_armorsmall_max;
 822 float g_pickup_armorsmall_anyway;
 823 float g_pickup_armormedium;
 824 float g_pickup_armormedium_max;
 825 float g_pickup_armormedium_anyway;
 826 float g_pickup_armorbig;
 827 float g_pickup_armorbig_max;
 828 float g_pickup_armorbig_anyway;
 829 float g_pickup_armorlarge;
 830 float g_pickup_armorlarge_max;
 831 float g_pickup_armorlarge_anyway;
 832 float g_pickup_healthsmall;
 833 float g_pickup_healthsmall_max;
 834 float g_pickup_healthsmall_anyway;
 835 float g_pickup_healthmedium;
 836 float g_pickup_healthmedium_max;
 837 float g_pickup_healthmedium_anyway;
 838 float g_pickup_healthlarge;
 839 float g_pickup_healthlarge_max;
 840 float g_pickup_healthlarge_anyway;
 841 float g_pickup_healthmega;
 842 float g_pickup_healthmega_max;
 843 float g_pickup_healthmega_anyway;
 844 float g_pickup_ammo_anyway;
 845 float g_pickup_weapons_anyway;
 846 float g_weaponarena;
 847 float g_weaponarena_random;
 848 string g_weaponarena_list;
 849 float g_weaponspeedfactor;
 850 float g_weaponratefactor;
 851 float g_weapondamagefactor;
 852 float g_weaponforcefactor;
 853 float g_weaponspreadfactor;
 854
 855 float start_weapons;
 856 float start_items;
 857 float start_ammo_shells;
 858 float start_ammo_nails;
 859 float start_ammo_rockets;
 860 float start_ammo_cells;
 861 float start_ammo_fuel;
 862 float start_health;
 863 float start_armorvalue;
 864 float warmup_start_weapons;
 865 float warmup_start_ammo_shells;
 866 float warmup_start_ammo_nails;
 867 float warmup_start_ammo_rockets;
 868 float warmup_start_ammo_cells;
 869 float warmup_start_ammo_fuel;
 870 float warmup_start_health;
 871 float warmup_start_armorvalue;
 872 float g_weapon_stay;
 873 float g_ghost_items;
 874
 875 entity get_weaponinfo(float w);
 876
 877 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 878 {
 879         var float i = weaponinfo.weapon;
 880
 881         if (!i)
 882                 return 0;
 883
 884         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 885
 886         if (t < 0) // "default" weapon selection
 887         {
 888                 if (g_lms || g_ca || allguns)
 889                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 890                 else if(t < -1)
 891                         t = 0;
 892                 else if (g_race || g_cts)
 893                         t = (i == WEP_LASER);
 894                 else if (g_nexball)
 895                         t = 0; // weapon is set a few lines later
 896                 else
 897                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 898                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 899                         t |= (i == WEP_HOOK);
 900         }
 901
 902         // we cannot disable porto in Nexball, we must force it
 903         if(g_nexball && i == WEP_PORTO)
 904                 t = 1;
 905
 906         return t;
 907 }
 908
 909 void readplayerstartcvars()
 910 {
 911         entity e;
 912         float i, j, t;
 913         string s;
 914
 915         // initialize starting values for players
 916         start_weapons = 0;
 917         start_items = 0;
 918         start_ammo_shells = 0;
 919         start_ammo_nails = 0;
 920         start_ammo_rockets = 0;
 921         start_ammo_cells = 0;
 922         start_health = cvar("g_balance_health_start");
 923         start_armorvalue = cvar("g_balance_armor_start");
 924
 925         g_weaponarena = 0;
 926         s = cvar_string("g_weaponarena");
 927         if (s == "0")
 928         {
 929         }
 930         else if (s == "all")
 931         {
 932                 g_weaponarena_list = "All Weapons";
 933                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 934                 {
 935                         e = get_weaponinfo(j);
 936                         g_weaponarena |= e.weapons;
 937                         weapon_action(e.weapon, WR_PRECACHE);
 938                 }
 939         }
 940         else if (s == "most")
 941         {
 942                 g_weaponarena_list = "Most Weapons";
 943                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 944                 {
 945                         e = get_weaponinfo(j);
 946                         if (e.spawnflags & WEP_FLAG_NORMAL)
 947                         {
 948                                 g_weaponarena |= e.weapons;
 949                                 weapon_action(e.weapon, WR_PRECACHE);
 950                         }
 951                 }
 952         }
 953         else if (s == "none")
 954         {
 955                 g_weaponarena_list = "No Weapons";
 956                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 957         }
 958         else
 959         {
 960                 t = tokenize_console(s);
 961                 g_weaponarena_list = "";
 962                 for (i = 0; i < t; ++i)
 963                 {
 964                         s = argv(i);
 965                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 966                         {
 967                                 e = get_weaponinfo(j);
 968                                 if (e.netname == s)
 969                                 {
 970                                         g_weaponarena |= e.weapons;
 971                                         weapon_action(e.weapon, WR_PRECACHE);
 972                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 973                                         break;
 974                                 }
 975                         }
 976                         if (j > WEP_LAST)
 977                         {
 978                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 979                         }
 980                 }
 981                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 982         }
 983
 984         if(g_weaponarena)
 985                 g_weaponarena_random = cvar("g_weaponarena_random");
 986         else
 987                 g_weaponarena_random = 0;
 988
 989         if (g_weaponarena)
 990         {
 991                 start_weapons = g_weaponarena;
 992                 if (g_weaponarena & (WEPBIT_GRENADE_LAUNCHER | WEPBIT_MINE_LAYER | WEPBIT_HAGAR | WEPBIT_ROCKET_LAUNCHER))
 993                         start_ammo_rockets = 999;
 994                 if (g_weaponarena & WEPBIT_SHOTGUN)
 995                         start_ammo_shells = 999;
 996                 if (g_weaponarena & (WEPBIT_ELECTRO | WEPBIT_CRYLINK | WEPBIT_NEX | WEPBIT_MINSTANEX | WEPBIT_HLAC | WEPBIT_HOOK))
 997                         start_ammo_cells = 999;
 998                 if (g_weaponarena & (WEPBIT_UZI | WEPBIT_CAMPINGRIFLE))
 999                         start_ammo_nails = 999;
1000                 if (g_weaponarena & WEPBIT_HOOK)
1001                         start_ammo_fuel = 999;
1002                 start_items |= IT_UNLIMITED_AMMO;
1003         }
1004         else if (g_minstagib)
1005         {
1006                 start_health = 100;
1007                 start_armorvalue = 0;
1008                 start_weapons = WEPBIT_MINSTANEX;
1009                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1010                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1011                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1012                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1013
1014                 if (g_minstagib_invis_alpha <= 0)
1015                         g_minstagib_invis_alpha = -1;
1016         }
1017         else
1018         {
1019                 if (g_lms || g_ca)
1020                 {
1021                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1022                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1023                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1024                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1025                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1026                         start_health = cvar("g_lms_start_health");
1027                         start_armorvalue = cvar("g_lms_start_armor");
1028                 }
1029                 else
1030                 {
1031                         start_ammo_shells = cvar("g_start_ammo_shells");
1032                         start_ammo_nails = cvar("g_start_ammo_nails");
1033                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1034                         start_ammo_cells = cvar("g_start_ammo_cells");
1035                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1036                 }
1037
1038                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1039                 {
1040                         e = get_weaponinfo(i);
1041                         if(want_weapon("g_start_weapon_", e, FALSE))
1042                                 start_weapons |= e.weapons;
1043                 }
1044         }
1045
1046         if (inWarmupStage)
1047         {
1048                 warmup_start_ammo_shells = start_ammo_shells;
1049                 warmup_start_ammo_nails = start_ammo_nails;
1050                 warmup_start_ammo_rockets = start_ammo_rockets;
1051                 warmup_start_ammo_cells = start_ammo_cells;
1052                 warmup_start_ammo_fuel = start_ammo_fuel;
1053                 warmup_start_health = start_health;
1054                 warmup_start_armorvalue = start_armorvalue;
1055                 warmup_start_weapons = start_weapons;
1056
1057                 if (!g_weaponarena && !g_minstagib && !g_ca)
1058                 {
1059                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1060                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1061                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1062                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1063                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1064                         warmup_start_health = cvar("g_warmup_start_health");
1065                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1066                         warmup_start_weapons = 0;
1067                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1068                         {
1069                                 e = get_weaponinfo(i);
1070                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1071                                         warmup_start_weapons |= e.weapons;
1072                         }
1073                 }
1074         }
1075
1076         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1077         {
1078                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1079                 start_items |= IT_FUEL_REGEN;
1080                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1081                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1082         }
1083
1084         if(!cvar("g_use_ammunition"))
1085         {
1086                 start_ammo_shells = cvar("g_pickup_shells_max");
1087                 start_ammo_nails = cvar("g_pickup_nails_max");
1088                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1089                 start_ammo_cells = cvar("g_pickup_cells_max");
1090                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1091                 start_items |= IT_UNLIMITED_AMMO;
1092                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1093                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1094                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1095                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1096                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1097                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1098         }
1099
1100         if (g_jetpack)
1101                 start_items |= IT_JETPACK;
1102
1103         if (g_weapon_stay == 2)
1104         {
1105                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1106                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1107                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1108                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1109                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1110                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1111                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1112                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1113                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1114                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1115         }
1116
1117         MUTATOR_CALLHOOK(SetStartItems);
1118
1119         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1120         {
1121                 e = get_weaponinfo(i);
1122                 if(e.weapons & (start_weapons | warmup_start_weapons))
1123                         weapon_action(e.weapon, WR_PRECACHE);
1124         }
1125
1126         start_ammo_shells = max(0, start_ammo_shells);
1127         start_ammo_nails = max(0, start_ammo_nails);
1128         start_ammo_cells = max(0, start_ammo_cells);
1129         start_ammo_rockets = max(0, start_ammo_rockets);
1130         start_ammo_fuel = max(0, start_ammo_fuel);
1131
1132         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1133         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1134         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1135         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1136         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1137 }
1138
1139 float g_bugrigs;
1140 float g_bugrigs_planar_movement;
1141 float g_bugrigs_planar_movement_car_jumping;
1142 float g_bugrigs_reverse_spinning;
1143 float g_bugrigs_reverse_speeding;
1144 float g_bugrigs_reverse_stopping;
1145 float g_bugrigs_air_steering;
1146 float g_bugrigs_angle_smoothing;
1147 float g_bugrigs_friction_floor;
1148 float g_bugrigs_friction_brake;
1149 float g_bugrigs_friction_air;
1150 float g_bugrigs_accel;
1151 float g_bugrigs_speed_ref;
1152 float g_bugrigs_speed_pow;
1153 float g_bugrigs_steer;
1154
1155 float g_touchexplode;
1156 float g_touchexplode_radius;
1157 float g_touchexplode_damage;
1158 float g_touchexplode_edgedamage;
1159 float g_touchexplode_force;
1160
1161 float sv_autotaunt;
1162 float sv_taunt;
1163
1164 float sv_pitch_min;
1165 float sv_pitch_max;
1166 float sv_pitch_fixyaw;
1167
1168 float sv_accuracy_data_share;
1169
1170 void readlevelcvars(void)
1171 {
1172         // first load all the mutators
1173         if(cvar("g_nix"))
1174                 MUTATOR_ADD(mutator_nix);
1175
1176     g_bugrigs = cvar("g_bugrigs");
1177     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1178     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1179     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1180     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1181     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1182     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1183     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1184     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1185     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1186     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1187     g_bugrigs_accel = cvar("g_bugrigs_accel");
1188     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1189     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1190     g_bugrigs_steer = cvar("g_bugrigs_steer");
1191
1192     g_touchexplode = cvar("g_touchexplode");
1193     g_touchexplode_radius = cvar("g_touchexplode_radius");
1194     g_touchexplode_damage = cvar("g_touchexplode_damage");
1195     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1196     g_touchexplode_force = cvar("g_touchexplode_force");
1197
1198 #ifdef ALLOW_FORCEMODELS
1199         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1200 #endif
1201         sv_loddistance1 = cvar("sv_loddistance1");
1202         sv_loddistance2 = cvar("sv_loddistance2");
1203
1204         if(sv_loddistance2 <= sv_loddistance1)
1205                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1206
1207         sv_clones = cvar("sv_clones");
1208         sv_gentle = cvar("sv_gentle");
1209         sv_foginterval = cvar("sv_foginterval");
1210         g_cloaked = cvar("g_cloaked");
1211         g_jump_grunt = cvar("g_jump_grunt");
1212         g_footsteps = cvar("g_footsteps");
1213         g_grappling_hook = cvar("g_grappling_hook");
1214         g_jetpack = cvar("g_jetpack");
1215         g_laserguided_missile = cvar("g_laserguided_missile");
1216         g_midair = cvar("g_midair");
1217         g_minstagib = cvar("g_minstagib");
1218         g_norecoil = cvar("g_norecoil");
1219         g_vampire = cvar("g_vampire");
1220         g_bloodloss = cvar("g_bloodloss");
1221         sv_maxidle = cvar("sv_maxidle");
1222         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1223         sv_pogostick = cvar("sv_pogostick");
1224         g_ctf_reverse = cvar("g_ctf_reverse");
1225         sv_autotaunt = cvar("sv_autotaunt");
1226         sv_taunt = cvar("sv_taunt");
1227
1228         inWarmupStage = cvar("g_warmup");
1229         g_warmup_limit = cvar("g_warmup_limit");
1230         g_warmup_allguns = cvar("g_warmup_allguns");
1231         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1232
1233         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1234                 inWarmupStage = 0; // these modes cannot work together, sorry
1235
1236         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1237         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1238         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1239         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1240         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1241         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1242         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1243         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1244         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1245         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1246         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1247         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1248
1249         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1250         g_weaponratefactor = cvar("g_weaponratefactor");
1251         g_weapondamagefactor = cvar("g_weapondamagefactor");
1252         g_weaponforcefactor = cvar("g_weaponforcefactor");
1253         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1254
1255         g_pickup_shells = cvar("g_pickup_shells");
1256         g_pickup_shells_max = cvar("g_pickup_shells_max");
1257         g_pickup_nails = cvar("g_pickup_nails");
1258         g_pickup_nails_max = cvar("g_pickup_nails_max");
1259         g_pickup_rockets = cvar("g_pickup_rockets");
1260         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1261         g_pickup_cells = cvar("g_pickup_cells");
1262         g_pickup_cells_max = cvar("g_pickup_cells_max");
1263         g_pickup_fuel = cvar("g_pickup_fuel");
1264         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1265         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1266         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1267         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1268         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1269         g_pickup_armormedium = cvar("g_pickup_armormedium");
1270         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1271         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1272         g_pickup_armorbig = cvar("g_pickup_armorbig");
1273         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1274         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1275         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1276         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1277         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1278         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1279         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1280         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1281         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1282         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1283         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1284         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1285         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1286         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1287         g_pickup_healthmega = cvar("g_pickup_healthmega");
1288         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1289         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1290
1291         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1292         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1293
1294         g_pinata = cvar("g_pinata");
1295
1296         g_weapon_stay = cvar("g_weapon_stay");
1297
1298         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1299                 g_weapon_stay = 1;
1300
1301         g_ghost_items = cvar("g_ghost_items");
1302
1303         if(g_ghost_items >= 1)
1304                 g_ghost_items = 0.25; // default alpha value
1305
1306         if not(inWarmupStage && !g_ca)
1307                 game_starttime = cvar("g_start_delay");
1308
1309         sv_pitch_min = cvar("sv_pitch_min");
1310         sv_pitch_max = cvar("sv_pitch_max");
1311         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1312
1313         sv_accuracy_data_share = boolean(cvar("sv_accuracy_data_share"));
1314
1315         readplayerstartcvars();
1316 }
1317
1318 /*
1319 // TODO sound pack system
1320 string soundpack;
1321
1322 string precache_sound_builtin (string s) = #19;
1323 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1324 string precache_sound(string s)
1325 {
1326         return precache_sound_builtin(strcat(soundpack, s));
1327 }
1328 void play2(entity e, string filename)
1329 {
1330         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1331 }
1332 void sound(entity e, float chan, string samp, float vol, float atten)
1333 {
1334         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1335 }
1336 */
1337
1338 // Sound functions
1339 string precache_sound (string s) = #19;
1340 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1341 float precache_sound_index (string s) = #19;
1342
1343 #define SND_VOLUME      1
1344 #define SND_ATTENUATION 2
1345 #define SND_LARGEENTITY 8
1346 #define SND_LARGESOUND  16
1347
1348 float sound_allowed(float dest, entity e)
1349 {
1350     // sounds from world may always pass
1351     for (;;)
1352     {
1353         if (e.classname == "body")
1354             e = e.enemy;
1355         if (e.owner && e.owner != e)
1356             e = e.owner;
1357         else
1358             break;
1359     }
1360     // sounds to self may always pass
1361     if (dest == MSG_ONE)
1362         if (e == msg_entity)
1363             return TRUE;
1364     // sounds by players can be removed
1365     if (cvar("bot_sound_monopoly"))
1366         if (clienttype(e) == CLIENTTYPE_REAL)
1367             return FALSE;
1368     // anything else may pass
1369     return TRUE;
1370 }
1371
1372 void sound(entity e, float chan, string samp, float vol, float atten)
1373 {
1374     if (!sound_allowed(MSG_BROADCAST, e))
1375         return;
1376     sound_builtin(e, chan, samp, vol, atten);
1377 }
1378 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1379 {
1380     float entno, idx;
1381
1382     if (!sound_allowed(dest, e))
1383         return;
1384
1385     entno = num_for_edict(e);
1386     idx = precache_sound_index(samp);
1387
1388     float sflags;
1389     sflags = 0;
1390
1391     atten = floor(atten * 64);
1392     vol = floor(vol * 255);
1393
1394     if (vol != 255)
1395         sflags |= SND_VOLUME;
1396     if (atten != 64)
1397         sflags |= SND_ATTENUATION;
1398     if (entno >= 8192)
1399         sflags |= SND_LARGEENTITY;
1400     if (idx >= 256)
1401         sflags |= SND_LARGESOUND;
1402
1403     WriteByte(dest, SVC_SOUND);
1404     WriteByte(dest, sflags);
1405     if (sflags & SND_VOLUME)
1406         WriteByte(dest, vol);
1407     if (sflags & SND_ATTENUATION)
1408         WriteByte(dest, atten);
1409     if (sflags & SND_LARGEENTITY)
1410     {
1411         WriteShort(dest, entno);
1412         WriteByte(dest, chan);
1413     }
1414     else
1415     {
1416         WriteShort(dest, entno * 8 + chan);
1417     }
1418     if (sflags & SND_LARGESOUND)
1419         WriteShort(dest, idx);
1420     else
1421         WriteByte(dest, idx);
1422
1423     WriteCoord(dest, o_x);
1424     WriteCoord(dest, o_y);
1425     WriteCoord(dest, o_z);
1426 }
1427 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1428 {
1429     vector o;
1430
1431     if (!sound_allowed(dest, e))
1432         return;
1433
1434     o = e.origin + 0.5 * (e.mins + e.maxs);
1435     soundtoat(dest, e, o, chan, samp, vol, atten);
1436 }
1437 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1438 {
1439     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1440 }
1441 void stopsoundto(float dest, entity e, float chan)
1442 {
1443     float entno;
1444
1445     if (!sound_allowed(dest, e))
1446         return;
1447
1448     entno = num_for_edict(e);
1449
1450     if (entno >= 8192)
1451     {
1452         float idx, sflags;
1453         idx = precache_sound_index("misc/null.wav");
1454         sflags = SND_LARGEENTITY;
1455         if (idx >= 256)
1456             sflags |= SND_LARGESOUND;
1457         WriteByte(dest, SVC_SOUND);
1458         WriteByte(dest, sflags);
1459         WriteShort(dest, entno);
1460         WriteByte(dest, chan);
1461         if (sflags & SND_LARGESOUND)
1462             WriteShort(dest, idx);
1463         else
1464             WriteByte(dest, idx);
1465         WriteCoord(dest, e.origin_x);
1466         WriteCoord(dest, e.origin_y);
1467         WriteCoord(dest, e.origin_z);
1468     }
1469     else
1470     {
1471         WriteByte(dest, SVC_STOPSOUND);
1472         WriteShort(dest, entno * 8 + chan);
1473     }
1474 }
1475 void stopsound(entity e, float chan)
1476 {
1477     if (!sound_allowed(MSG_BROADCAST, e))
1478         return;
1479
1480     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1481     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1482 }
1483
1484 void play2(entity e, string filename)
1485 {
1486     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1487     msg_entity = e;
1488     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1489 }
1490
1491 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1492 .float spamtime;
1493 float spamsound(entity e, float chan, string samp, float vol, float atten)
1494 {
1495     if (!sound_allowed(MSG_BROADCAST, e))
1496         return FALSE;
1497
1498     if (time > e.spamtime)
1499     {
1500         e.spamtime = time;
1501         sound(e, chan, samp, vol, atten);
1502         return TRUE;
1503     }
1504     return FALSE;
1505 }
1506
1507 void play2team(float t, string filename)
1508 {
1509     local entity head;
1510
1511     if (cvar("bot_sound_monopoly"))
1512         return;
1513
1514     FOR_EACH_REALPLAYER(head)
1515     {
1516         if (head.team == t)
1517             play2(head, filename);
1518     }
1519 }
1520
1521 void play2all(string samp)
1522 {
1523     if (cvar("bot_sound_monopoly"))
1524         return;
1525
1526     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1527 }
1528
1529 void PrecachePlayerSounds(string f);
1530 void precache_playermodel(string m)
1531 {
1532         float globhandle, i, n;
1533         string f;
1534
1535         if(substring(m, -9,5) == "_lod1")
1536                 return;
1537         if(substring(m, -9,5) == "_lod2")
1538                 return;
1539         precache_model(m);
1540         if(sv_loddistance1)
1541         {
1542                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1543                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1544         }
1545
1546         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1547         if (globhandle < 0)
1548                 return;
1549         n = search_getsize(globhandle);
1550         for (i = 0; i < n; ++i)
1551         {
1552                 //print(search_getfilename(globhandle, i), "\n");
1553                 f = search_getfilename(globhandle, i);
1554                 PrecachePlayerSounds(f);
1555         }
1556         search_end(globhandle);
1557 }
1558 void precache_all_playermodels(string pattern)
1559 {
1560         float globhandle, i, n;
1561         string f;
1562
1563         globhandle = search_begin(pattern, TRUE, FALSE);
1564         if (globhandle < 0)
1565                 return;
1566         n = search_getsize(globhandle);
1567         for (i = 0; i < n; ++i)
1568         {
1569                 //print(search_getfilename(globhandle, i), "\n");
1570                 f = search_getfilename(globhandle, i);
1571                 precache_playermodel(f);
1572         }
1573         search_end(globhandle);
1574 }
1575
1576 void precache()
1577 {
1578     // gamemode related things
1579     precache_model ("models/misc/chatbubble.spr");
1580     precache_model ("models/misc/teambubble.spr");
1581     if (g_runematch)
1582     {
1583         precache_model ("models/runematch/curse.mdl");
1584         precache_model ("models/runematch/rune.mdl");
1585     }
1586
1587 #ifdef TTURRETS_ENABLED
1588     if (cvar("g_turrets"))
1589         turrets_precash();
1590 #endif
1591
1592     // Precache all player models if desired
1593     if (cvar("sv_precacheplayermodels"))
1594     {
1595         PrecachePlayerSounds("sound/player/default.sounds");
1596         precache_all_playermodels("models/player/*.zym");
1597         precache_all_playermodels("models/player/*.dpm");
1598         precache_all_playermodels("models/player/*.md3");
1599         precache_all_playermodels("models/player/*.psk");
1600         precache_all_playermodels("models/player/*.iqm");
1601     }
1602
1603     if (cvar("sv_defaultcharacter"))
1604     {
1605         string s;
1606         s = cvar_string("sv_defaultplayermodel_red");
1607         if (s != "")
1608             precache_playermodel(s);
1609         s = cvar_string("sv_defaultplayermodel_blue");
1610         if (s != "")
1611             precache_playermodel(s);
1612         s = cvar_string("sv_defaultplayermodel_yellow");
1613         if (s != "")
1614             precache_playermodel(s);
1615         s = cvar_string("sv_defaultplayermodel_pink");
1616         if (s != "")
1617             precache_playermodel(s);
1618         s = cvar_string("sv_defaultplayermodel");
1619         if (s != "")
1620             precache_playermodel(s);
1621     }
1622
1623     if (g_footsteps)
1624     {
1625         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1626         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1627     }
1628
1629     // gore and miscellaneous sounds
1630     //precache_sound ("misc/h2ohit.wav");
1631     precache_model ("models/hook.md3");
1632     precache_sound ("misc/armorimpact.wav");
1633     precache_sound ("misc/bodyimpact1.wav");
1634     precache_sound ("misc/bodyimpact2.wav");
1635     precache_sound ("misc/gib.wav");
1636     precache_sound ("misc/gib_splat01.wav");
1637     precache_sound ("misc/gib_splat02.wav");
1638     precache_sound ("misc/gib_splat03.wav");
1639     precache_sound ("misc/gib_splat04.wav");
1640     precache_sound ("misc/hit.wav");
1641         precache_sound ("misc/typehit.wav");
1642     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1643     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1644     precache_sound ("misc/null.wav");
1645     precache_sound ("misc/spawn.wav");
1646     precache_sound ("misc/talk.wav");
1647     precache_sound ("misc/teleport.wav");
1648     precache_sound ("misc/poweroff.wav");
1649     precache_sound ("player/lava.wav");
1650     precache_sound ("player/slime.wav");
1651
1652     if (g_jetpack)
1653         precache_sound ("misc/jetpack_fly.wav");
1654
1655     precache_model ("models/sprites/0.spr32");
1656     precache_model ("models/sprites/1.spr32");
1657     precache_model ("models/sprites/2.spr32");
1658     precache_model ("models/sprites/3.spr32");
1659     precache_model ("models/sprites/4.spr32");
1660     precache_model ("models/sprites/5.spr32");
1661     precache_model ("models/sprites/6.spr32");
1662     precache_model ("models/sprites/7.spr32");
1663     precache_model ("models/sprites/8.spr32");
1664     precache_model ("models/sprites/9.spr32");
1665     precache_model ("models/sprites/10.spr32");
1666
1667     // common weapon precaches
1668     precache_sound ("weapons/weapon_switch.wav");
1669     precache_sound ("weapons/weaponpickup.wav");
1670     precache_sound ("weapons/unavailable.wav");
1671     precache_sound ("weapons/dryfire.wav");
1672     if (g_grappling_hook)
1673     {
1674         precache_sound ("weapons/hook_fire.wav"); // hook
1675         precache_sound ("weapons/hook_impact.wav"); // hook
1676     }
1677
1678     if(cvar("sv_precacheweapons"))
1679     {
1680         //precache weapon models/sounds
1681         local float wep;
1682         wep = WEP_FIRST;
1683         while (wep <= WEP_LAST)
1684         {
1685             weapon_action(wep, WR_PRECACHE);
1686             wep = wep + 1;
1687         }
1688     }
1689
1690     precache_model("models/elaser.mdl");
1691     precache_model("models/laser.mdl");
1692     precache_model("models/ebomb.mdl");
1693
1694 #if 0
1695     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1696
1697     if (!self.noise && self.music) // quake 3 uses the music field
1698         self.noise = self.music;
1699
1700     // plays music for the level if there is any
1701     if (self.noise)
1702     {
1703         precache_sound (self.noise);
1704         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1705     }
1706 #endif
1707 }
1708
1709 // sorry, but using \ in macros breaks line numbers
1710 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1711 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1712 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1713
1714 // WARNING: this kills the trace globals
1715 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1716 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1717
1718 #define INITPRIO_FIRST              0
1719 #define INITPRIO_GAMETYPE           0
1720 #define INITPRIO_GAMETYPE_FALLBACK  1
1721 #define INITPRIO_CVARS              5
1722 #define INITPRIO_FINDTARGET        10
1723 #define INITPRIO_DROPTOFLOOR       20
1724 #define INITPRIO_SETLOCATION       90
1725 #define INITPRIO_LINKDOORS         91
1726 #define INITPRIO_LAST              99
1727
1728 .void(void) initialize_entity;
1729 .float initialize_entity_order;
1730 .entity initialize_entity_next;
1731 entity initialize_entity_first;
1732
1733 void make_safe_for_remove(entity e)
1734 {
1735     if (e.initialize_entity)
1736     {
1737         entity ent, prev;
1738         for (ent = initialize_entity_first; ent; )
1739         {
1740             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1741             {
1742                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1743                 // skip it in linked list
1744                 if (prev)
1745                 {
1746                     prev.initialize_entity_next = ent.initialize_entity_next;
1747                     ent = prev.initialize_entity_next;
1748                 }
1749                 else
1750                 {
1751                     initialize_entity_first = ent.initialize_entity_next;
1752                     ent = initialize_entity_first;
1753                 }
1754             }
1755             else
1756             {
1757                 prev = ent;
1758                 ent = ent.initialize_entity_next;
1759             }
1760         }
1761     }
1762 }
1763
1764 void objerror(string s)
1765 {
1766     make_safe_for_remove(self);
1767     objerror_builtin(s);
1768 }
1769
1770 void remove_unsafely(entity e)
1771 {
1772     remove_builtin(e);
1773 }
1774
1775 void remove_safely(entity e)
1776 {
1777     make_safe_for_remove(e);
1778     remove_builtin(e);
1779 }
1780
1781 void InitializeEntity(entity e, void(void) func, float order)
1782 {
1783     entity prev, cur;
1784
1785     if (!e || e.initialize_entity)
1786     {
1787         // make a proxy initializer entity
1788         entity e_old;
1789         e_old = e;
1790         e = spawn();
1791         e.classname = "initialize_entity";
1792         e.enemy = e_old;
1793     }
1794
1795     e.initialize_entity = func;
1796     e.initialize_entity_order = order;
1797
1798     cur = initialize_entity_first;
1799     for (;;)
1800     {
1801         if (!cur || cur.initialize_entity_order > order)
1802         {
1803             // insert between prev and cur
1804             if (prev)
1805                 prev.initialize_entity_next = e;
1806             else
1807                 initialize_entity_first = e;
1808             e.initialize_entity_next = cur;
1809             return;
1810         }
1811         prev = cur;
1812         cur = cur.initialize_entity_next;
1813     }
1814 }
1815 void InitializeEntitiesRun()
1816 {
1817     entity startoflist;
1818     startoflist = initialize_entity_first;
1819     initialize_entity_first = world;
1820     for (self = startoflist; self; )
1821     {
1822         entity e;
1823         var void(void) func;
1824         e = self.initialize_entity_next;
1825         func = self.initialize_entity;
1826         self.initialize_entity_order = 0;
1827         self.initialize_entity = func_null;
1828         self.initialize_entity_next = world;
1829         if (self.classname == "initialize_entity")
1830         {
1831             entity e_old;
1832             e_old = self.enemy;
1833             remove_builtin(self);
1834             self = e_old;
1835         }
1836         //dprint("Delayed initialization: ", self.classname, "\n");
1837         func();
1838         self = e;
1839     }
1840 }
1841
1842 .float uncustomizeentityforclient_set;
1843 .void(void) uncustomizeentityforclient;
1844 void(void) SUB_Nullpointer = #0;
1845 void UncustomizeEntitiesRun()
1846 {
1847     entity oldself;
1848     oldself = self;
1849     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1850         self.uncustomizeentityforclient();
1851     self = oldself;
1852 }
1853 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1854 {
1855     e.customizeentityforclient = customizer;
1856     e.uncustomizeentityforclient = uncustomizer;
1857     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1858 }
1859
1860 .float nottargeted;
1861 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1862
1863 void() SUB_Remove;
1864 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1865 {
1866     vector mi, ma;
1867
1868     if (e.classname == "")
1869         e.classname = "net_linked";
1870
1871     if (e.model == "" || self.modelindex == 0)
1872     {
1873         mi = e.mins;
1874         ma = e.maxs;
1875         setmodel(e, "null");
1876         setsize(e, mi, ma);
1877     }
1878
1879     e.SendEntity = sendfunc;
1880     e.SendFlags = 0xFFFFFF;
1881
1882     if (!docull)
1883         e.effects |= EF_NODEPTHTEST;
1884
1885     if (dt)
1886     {
1887         e.nextthink = time + dt;
1888         e.think = SUB_Remove;
1889     }
1890 }
1891
1892 void adaptor_think2touch()
1893 {
1894     entity o;
1895     o = other;
1896     other = world;
1897     self.touch();
1898     other = o;
1899 }
1900
1901 void adaptor_think2use()
1902 {
1903     entity o, a;
1904     o = other;
1905     a = activator;
1906     activator = world;
1907     other = world;
1908     self.use();
1909     other = o;
1910     activator = a;
1911 }
1912
1913 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1914 {
1915         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1916                 self.projectiledeathtype |= HITTYPE_SPLASH;
1917         adaptor_think2use();
1918 }
1919
1920 // deferred dropping
1921 void DropToFloor_Handler()
1922 {
1923     droptofloor_builtin();
1924     self.dropped_origin = self.origin;
1925 }
1926
1927 void droptofloor()
1928 {
1929     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1930 }
1931
1932
1933
1934 float trace_hits_box_a0, trace_hits_box_a1;
1935
1936 float trace_hits_box_1d(float end, float thmi, float thma)
1937 {
1938     if (end == 0)
1939     {
1940         // just check if x is in range
1941         if (0 < thmi)
1942             return FALSE;
1943         if (0 > thma)
1944             return FALSE;
1945     }
1946     else
1947     {
1948         // do the trace with respect to x
1949         // 0 -> end has to stay in thmi -> thma
1950         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1951         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1952         if (trace_hits_box_a0 > trace_hits_box_a1)
1953             return FALSE;
1954     }
1955     return TRUE;
1956 }
1957
1958 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1959 {
1960     end -= start;
1961     thmi -= start;
1962     thma -= start;
1963     // now it is a trace from 0 to end
1964
1965     trace_hits_box_a0 = 0;
1966     trace_hits_box_a1 = 1;
1967
1968     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1969         return FALSE;
1970     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1971         return FALSE;
1972     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1973         return FALSE;
1974
1975     return TRUE;
1976 }
1977
1978 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1979 {
1980     return trace_hits_box(start, end, thmi - ma, thma - mi);
1981 }
1982
1983 float SUB_NoImpactCheck()
1984 {
1985         // zero hitcontents = this is not the real impact, but either the
1986         // mirror-impact of something hitting the projectile instead of the
1987         // projectile hitting the something, or a touchareagrid one. Neither of
1988         // these stop the projectile from moving, so...
1989         if(trace_dphitcontents == 0)
1990         {
1991                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1992                 checkclient();
1993         }
1994     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1995         return 1;
1996     if (other == world && self.size != '0 0 0')
1997     {
1998         vector tic;
1999         tic = self.velocity * sys_frametime;
2000         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2001         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2002         if (trace_fraction >= 1)
2003         {
2004             dprint("Odd... did not hit...?\n");
2005         }
2006         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2007         {
2008             dprint("Detected and prevented the sky-grapple bug.\n");
2009             return 1;
2010         }
2011     }
2012
2013     return 0;
2014 }
2015
2016 #define SUB_OwnerCheck() (other && (other == self.owner))
2017
2018 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2019 {
2020         if(SUB_OwnerCheck())
2021                 return TRUE;
2022         if(SUB_NoImpactCheck())
2023         {
2024                 remove(self);
2025                 return TRUE;
2026         }
2027         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2028                 UpdateCSQCProjectileNextFrame(self);
2029         return FALSE;
2030 }
2031 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2032
2033 float MAX_IPBAN_URIS = 16;
2034
2035 float URI_GET_DISCARD   = 0;
2036 float URI_GET_IPBAN     = 1;
2037 float URI_GET_IPBAN_END = 16;
2038
2039 void URI_Get_Callback(float id, float status, string data)
2040 {
2041     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2042     dprint(data);
2043     dprint("\nEnd of data.\n");
2044
2045     if (id == URI_GET_DISCARD)
2046     {
2047         // discard
2048     }
2049     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2050     {
2051         // online ban list
2052         OnlineBanList_URI_Get_Callback(id, status, data);
2053     }
2054     else
2055     {
2056         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2057     }
2058 }
2059
2060 void print_to(entity e, string s)
2061 {
2062     if (e)
2063         sprint(e, strcat(s, "\n"));
2064     else
2065         print(s, "\n");
2066 }
2067
2068 string getrecords(float page) // 50 records per page
2069 {
2070     float rec;
2071     string h;
2072     float r;
2073     float i;
2074     string s;
2075
2076     rec = 0;
2077
2078     s = "";
2079
2080     if (g_ctf)
2081     {
2082         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2083         {
2084             if (MapInfo_Get_ByID(i))
2085             {
2086                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2087                 if (r == 0)
2088                     continue;
2089                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2090                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2091                 ++rec;
2092             }
2093         }
2094     }
2095
2096     if (g_race)
2097     {
2098         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2099         {
2100             if (MapInfo_Get_ByID(i))
2101             {
2102                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time")));
2103                 if (r == 0)
2104                     continue;
2105                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "netname"));
2106                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2107                 ++rec;
2108             }
2109         }
2110     }
2111
2112     if (g_cts)
2113     {
2114         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2115         {
2116             if (MapInfo_Get_ByID(i))
2117             {
2118                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time")));
2119                 if (r == 0)
2120                     continue;
2121                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "netname"));
2122                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2123                 ++rec;
2124             }
2125         }
2126     }
2127
2128     MapInfo_ClearTemps();
2129
2130     if (s == "" && page == 0)
2131         return "No records are available on this server.\n";
2132     else
2133         return s;
2134 }
2135
2136 string getrankings()
2137 {
2138     string n;
2139     float t;
2140     float i;
2141     string s;
2142     string p;
2143     string map;
2144
2145     s = "";
2146
2147     map = GetMapname();
2148
2149     for (i = 1; i <= RANKINGS_CNT; ++i)
2150     {
2151         t = race_GetTime(i);
2152         if (t == 0)
2153             continue;
2154         n = race_GetName(i);
2155         p = race_PlaceName(i);
2156         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2157     }
2158
2159     MapInfo_ClearTemps();
2160
2161     if (s == "")
2162         return strcat("No records are available for the map: ", map, "\n");
2163     else
2164         return strcat("Records for ", map, ":\n", s);
2165 }
2166
2167 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2168 {
2169     float m, i;
2170     vector start, org, delta, end, enddown, mstart;
2171
2172     m = e.dphitcontentsmask;
2173     e.dphitcontentsmask = goodcontents | badcontents;
2174
2175     org = world.mins;
2176     delta = world.maxs - world.mins;
2177
2178     for (i = 0; i < attempts; ++i)
2179     {
2180         start_x = org_x + random() * delta_x;
2181         start_y = org_y + random() * delta_y;
2182         start_z = org_z + random() * delta_z;
2183
2184         // rule 1: start inside world bounds, and outside
2185         // solid, and don't start from somewhere where you can
2186         // fall down to evil
2187         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2188         if (trace_fraction >= 1)
2189             continue;
2190         if (trace_startsolid)
2191             continue;
2192         if (trace_dphitcontents & badcontents)
2193             continue;
2194         if (trace_dphitq3surfaceflags & badsurfaceflags)
2195             continue;
2196
2197         // rule 2: if we are too high, lower the point
2198         if (trace_fraction * delta_z > maxaboveground)
2199             start = trace_endpos + '0 0 1' * maxaboveground;
2200         enddown = trace_endpos;
2201
2202         // rule 3: make sure we aren't outside the map. This only works
2203         // for somewhat well formed maps. A good rule of thumb is that
2204         // the map should have a convex outside hull.
2205         // these can be traceLINES as we already verified the starting box
2206         mstart = start + 0.5 * (e.mins + e.maxs);
2207         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2208         if (trace_fraction >= 1)
2209             continue;
2210         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2211         if (trace_fraction >= 1)
2212             continue;
2213         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2214         if (trace_fraction >= 1)
2215             continue;
2216         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2217         if (trace_fraction >= 1)
2218             continue;
2219         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2220         if (trace_fraction >= 1)
2221             continue;
2222
2223         // find a random vector to "look at"
2224         end_x = org_x + random() * delta_x;
2225         end_y = org_y + random() * delta_y;
2226         end_z = org_z + random() * delta_z;
2227         end = start + normalize(end - start) * vlen(delta);
2228
2229         // rule 4: start TO end must not be too short
2230         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2231         if (trace_startsolid)
2232             continue;
2233         if (trace_fraction < minviewdistance / vlen(delta))
2234             continue;
2235
2236         // rule 5: don't want to look at sky
2237         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2238             continue;
2239
2240         // rule 6: we must not end up in trigger_hurt
2241         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2242         {
2243             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2244             continue;
2245         }
2246
2247         break;
2248     }
2249
2250     e.dphitcontentsmask = m;
2251
2252     if (i < attempts)
2253     {
2254         setorigin(e, start);
2255         e.angles = vectoangles(end - start);
2256         dprint("Needed ", ftos(i + 1), " attempts\n");
2257         return TRUE;
2258     }
2259     else
2260         return FALSE;
2261 }
2262
2263 float zcurveparticles_effectno;
2264 vector zcurveparticles_start;
2265 float zcurveparticles_spd;
2266
2267 void endzcurveparticles()
2268 {
2269         if(zcurveparticles_effectno)
2270         {
2271                 // terminator
2272                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2273         }
2274         zcurveparticles_effectno = 0;
2275 }
2276
2277 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2278 {
2279         spd = bound(0, floor(spd / 16), 32767);
2280         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2281         {
2282                 endzcurveparticles();
2283                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2284                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2285                 WriteShort(MSG_BROADCAST, effectno);
2286                 WriteCoord(MSG_BROADCAST, start_x);
2287                 WriteCoord(MSG_BROADCAST, start_y);
2288                 WriteCoord(MSG_BROADCAST, start_z);
2289                 zcurveparticles_effectno = effectno;
2290                 zcurveparticles_start = start;
2291         }
2292         else
2293                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2294         WriteCoord(MSG_BROADCAST, end_x);
2295         WriteCoord(MSG_BROADCAST, end_y);
2296         WriteCoord(MSG_BROADCAST, end_z);
2297         WriteCoord(MSG_BROADCAST, end_dz);
2298         zcurveparticles_spd = spd;
2299 }
2300
2301 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2302 {
2303         float end_dz;
2304         vector vecxy, velxy;
2305
2306         vecxy = end - start;
2307         vecxy_z = 0;
2308         velxy = vel;
2309         velxy_z = 0;
2310
2311         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2312         {
2313                 endzcurveparticles();
2314                 trailparticles(world, effectno, start, end);
2315                 return;
2316         }
2317
2318         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2319         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2320 }
2321
2322 string GetGametype(); // g_world.qc
2323 void write_recordmarker(entity pl, float tstart, float dt)
2324 {
2325     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2326
2327     // also write a marker into demo files for demotc-race-record-extractor to find
2328     stuffcmd(pl,
2329              strcat(
2330                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2331                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2332 }
2333
2334 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2335 {
2336         switch(algn)
2337         {
2338                 case 1: // right
2339                         break;
2340
2341                 case 2: // left
2342                         vecs_y = -vecs_y;
2343                         break;
2344
2345                 default:
2346                 case 3:
2347                         if(allowcenter) // 2: allow center handedness
2348                         {
2349                                 // center
2350                                 vecs_y = 0;
2351                                 vecs_z -= 2;
2352                         }
2353                         else
2354                         {
2355                                 // right
2356                         }
2357                         break;
2358
2359                 case 4:
2360                         if(allowcenter) // 2: allow center handedness
2361                         {
2362                                 // center
2363                                 vecs_y = 0;
2364                                 vecs_z -= 2;
2365                         }
2366                         else
2367                         {
2368                                 // left
2369                                 vecs_y = -vecs_y;
2370                         }
2371                         break;
2372         }
2373         return vecs;
2374 }
2375
2376 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2377 {
2378         string s;
2379         vector v;
2380
2381         if (cvar("g_shootfromeye"))
2382         {
2383                 if (visual)
2384                 {
2385                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2386                 }
2387                 else
2388                 {
2389                         vecs_y = 0;
2390                         vecs_z = 0;
2391                 }
2392         }
2393         else if (cvar("g_shootfromcenter"))
2394         {
2395                 if (visual)
2396                 {
2397                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2398                 }
2399                 else
2400                 {
2401                         vecs_y = 0;
2402                         vecs_z -= 2;
2403                 }
2404         }
2405         else if ((s = cvar_string("g_shootfromfixedorigin")) != "")
2406         {
2407                 v = stov(s);
2408                 if (y_is_right)
2409                         v_y = -v_y;
2410                 if (v_x != 0)
2411                         vecs_x = v_x;
2412                 vecs_y = v_y;
2413                 vecs_z = v_z;
2414         }
2415         else if (cvar("g_shootfromclient"))
2416         {
2417                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (cvar("g_shootfromclient") >= 2), algn);
2418         }
2419         return vecs;
2420 }
2421
2422 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2423 {
2424         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2425 }
2426
2427
2428 void attach_sameorigin(entity e, entity to, string tag)
2429 {
2430     vector org, t_forward, t_left, t_up, e_forward, e_up;
2431     vector org0, ang0;
2432     float tagscale;
2433
2434     ang0 = e.angles;
2435     org0 = e.origin;
2436
2437     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2438     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2439     t_forward = v_forward * tagscale;
2440     t_left = v_right * -tagscale;
2441     t_up = v_up * tagscale;
2442
2443     e.origin_x = org * t_forward;
2444     e.origin_y = org * t_left;
2445     e.origin_z = org * t_up;
2446
2447     // current forward and up directions
2448     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2449                 e.angles = AnglesTransform_FromVAngles(e.angles);
2450         else
2451                 e.angles = AnglesTransform_FromAngles(e.angles);
2452     fixedmakevectors(e.angles);
2453
2454     // untransform forward, up!
2455     e_forward_x = v_forward * t_forward;
2456     e_forward_y = v_forward * t_left;
2457     e_forward_z = v_forward * t_up;
2458     e_up_x = v_up * t_forward;
2459     e_up_y = v_up * t_left;
2460     e_up_z = v_up * t_up;
2461
2462     e.angles = fixedvectoangles2(e_forward, e_up);
2463     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2464                 e.angles = AnglesTransform_ToVAngles(e.angles);
2465         else
2466                 e.angles = AnglesTransform_ToAngles(e.angles);
2467
2468     setattachment(e, to, tag);
2469     setorigin(e, e.origin);
2470 }
2471
2472 void detach_sameorigin(entity e)
2473 {
2474     vector org;
2475     org = gettaginfo(e, 0);
2476     e.angles = fixedvectoangles2(v_forward, v_up);
2477     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2478                 e.angles = AnglesTransform_ToVAngles(e.angles);
2479         else
2480                 e.angles = AnglesTransform_ToAngles(e.angles);
2481     setorigin(e, org);
2482     setattachment(e, world, "");
2483     setorigin(e, e.origin);
2484 }
2485
2486 void follow_sameorigin(entity e, entity to)
2487 {
2488     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2489     e.aiment = to; // make the hole follow bmodel
2490     e.punchangle = to.angles; // the original angles of bmodel
2491     e.view_ofs = e.origin - to.origin; // relative origin
2492     e.v_angle = e.angles - to.angles; // relative angles
2493 }
2494
2495 void unfollow_sameorigin(entity e)
2496 {
2497     e.movetype = MOVETYPE_NONE;
2498 }
2499
2500 entity gettaginfo_relative_ent;
2501 vector gettaginfo_relative(entity e, float tag)
2502 {
2503     if (!gettaginfo_relative_ent)
2504     {
2505         gettaginfo_relative_ent = spawn();
2506         gettaginfo_relative_ent.effects = EF_NODRAW;
2507     }
2508     gettaginfo_relative_ent.model = e.model;
2509     gettaginfo_relative_ent.modelindex = e.modelindex;
2510     gettaginfo_relative_ent.frame = e.frame;
2511     return gettaginfo(gettaginfo_relative_ent, tag);
2512 }
2513
2514 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2515 {
2516     float p;
2517     p = pow(2, chan);
2518     if (pl.soundentity.cnt & p)
2519         return;
2520     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2521     pl.soundentity.cnt |= p;
2522 }
2523
2524 void SoundEntity_StopSound(entity pl, float chan)
2525 {
2526     float p;
2527     p = pow(2, chan);
2528     if (pl.soundentity.cnt & p)
2529     {
2530         stopsoundto(MSG_ALL, pl.soundentity, chan);
2531         pl.soundentity.cnt &~= p;
2532     }
2533 }
2534
2535 void SoundEntity_Attach(entity pl)
2536 {
2537     pl.soundentity = spawn();
2538     pl.soundentity.classname = "soundentity";
2539     pl.soundentity.owner = pl;
2540     setattachment(pl.soundentity, pl, "");
2541     setmodel(pl.soundentity, "null");
2542 }
2543
2544 void SoundEntity_Detach(entity pl)
2545 {
2546     float i;
2547     for (i = 0; i <= 7; ++i)
2548         SoundEntity_StopSound(pl, i);
2549 }
2550
2551
2552 float ParseCommandPlayerSlotTarget_firsttoken;
2553 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2554 {
2555     string s;
2556     entity e, head;
2557     float n;
2558
2559     s = string_null;
2560
2561     ParseCommandPlayerSlotTarget_firsttoken = -1;
2562
2563     if (tokens > idx)
2564     {
2565         if (substring(argv(idx), 0, 1) == "#")
2566         {
2567             s = substring(argv(idx), 1, -1);
2568             ++idx;
2569             if (s == "")
2570                 if (tokens > idx)
2571                 {
2572                     s = argv(idx);
2573                     ++idx;
2574                 }
2575                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2576             if (s == ftos(stof(s)))
2577             {
2578                 e = edict_num(stof(s));
2579                 if (e.flags & FL_CLIENT)
2580                     return e;
2581             }
2582         }
2583         else
2584         {
2585             // it must be a nick name
2586             s = argv(idx);
2587             ++idx;
2588                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2589
2590             n = 0;
2591             FOR_EACH_CLIENT(head)
2592             if (head.netname == s)
2593             {
2594                 e = head;
2595                 ++n;
2596             }
2597             if (n == 1)
2598                 return e;
2599
2600             s = strdecolorize(s);
2601             n = 0;
2602             FOR_EACH_CLIENT(head)
2603             if (strdecolorize(head.netname) == s)
2604             {
2605                 e = head;
2606                 ++n;
2607             }
2608             if (n == 1)
2609                 return e;
2610         }
2611     }
2612
2613     return world;
2614 }
2615
2616 .float scale2;
2617
2618 float modeleffect_SendEntity(entity to, float sf)
2619 {
2620         float f;
2621         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2622
2623         f = 0;
2624         if(self.velocity != '0 0 0')
2625                 f |= 1;
2626         if(self.angles != '0 0 0')
2627                 f |= 2;
2628         if(self.avelocity != '0 0 0')
2629                 f |= 4;
2630
2631         WriteByte(MSG_ENTITY, f);
2632         WriteShort(MSG_ENTITY, self.modelindex);
2633         WriteByte(MSG_ENTITY, self.skin);
2634         WriteByte(MSG_ENTITY, self.frame);
2635         WriteCoord(MSG_ENTITY, self.origin_x);
2636         WriteCoord(MSG_ENTITY, self.origin_y);
2637         WriteCoord(MSG_ENTITY, self.origin_z);
2638         if(f & 1)
2639         {
2640                 WriteCoord(MSG_ENTITY, self.velocity_x);
2641                 WriteCoord(MSG_ENTITY, self.velocity_y);
2642                 WriteCoord(MSG_ENTITY, self.velocity_z);
2643         }
2644         if(f & 2)
2645         {
2646                 WriteCoord(MSG_ENTITY, self.angles_x);
2647                 WriteCoord(MSG_ENTITY, self.angles_y);
2648                 WriteCoord(MSG_ENTITY, self.angles_z);
2649         }
2650         if(f & 4)
2651         {
2652                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2653                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2654                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2655         }
2656         WriteShort(MSG_ENTITY, self.scale * 256.0);
2657         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2658         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2659         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2660         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2661
2662         return TRUE;
2663 }
2664
2665 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2666 {
2667         entity e;
2668         float sz;
2669         e = spawn();
2670         e.classname = "modeleffect";
2671         setmodel(e, m);
2672         e.frame = f;
2673         setorigin(e, o);
2674         e.velocity = v;
2675         e.angles = ang;
2676         e.avelocity = angv;
2677         e.alpha = a;
2678         e.teleport_time = t1;
2679         e.fade_time = t2;
2680         e.skin = s;
2681         if(s0 >= 0)
2682                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2683         else
2684                 e.scale = -s0;
2685         if(s2 >= 0)
2686                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2687         else
2688                 e.scale2 = -s2;
2689         sz = max(e.scale, e.scale2);
2690         setsize(e, e.mins * sz, e.maxs * sz);
2691         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2692 }
2693
2694 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2695 {
2696         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2697 }
2698
2699 float randombit(float bits)
2700 {
2701         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2702                 return bits;
2703
2704         float n, f, b, r;
2705
2706         r = random();
2707         b = 0;
2708         n = 0;
2709
2710         for(f = 1; f <= bits; f *= 2)
2711         {
2712                 if(bits & f)
2713                 {
2714                         ++n;
2715                         r *= n;
2716                         if(r <= 1)
2717                                 b = f;
2718                         else
2719                                 r = (r - 1) / (n - 1);
2720                 }
2721         }
2722
2723         return b;
2724 }
2725
2726 float randombits(float bits, float k, float error_return)
2727 {
2728         float r;
2729         r = 0;
2730         while(k > 0 && bits != r)
2731         {
2732                 r += randombit(bits - r);
2733                 --k;
2734         }
2735         if(error_return)
2736                 if(k > 0)
2737                         return -1; // all
2738         return r;
2739 }
2740
2741 void randombit_test(float bits, float iter)
2742 {
2743         while(iter > 0)
2744         {
2745                 print(ftos(randombit(bits)), "\n");
2746                 --iter;
2747         }
2748 }
2749
2750 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2751 {
2752         if(halflifedist > 0)
2753                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2754         else if(halflifedist < 0)
2755                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2756         else
2757                 return 1;
2758 }
2759
2760
2761
2762
2763 #ifdef RELEASE
2764 #define cvar_string_normal cvar_string_builtin
2765 #define cvar_normal cvar_builtin
2766 #else
2767 string cvar_string_normal(string n)
2768 {
2769         if not(cvar_type(n) & 1)
2770                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2771         return cvar_string_builtin(n);
2772 }
2773
2774 float cvar_normal(string n)
2775 {
2776         return stof(cvar_string_normal(n));
2777 }
2778 #endif
2779 #define cvar_set_normal cvar_set_builtin
2780
2781 void defer_think()
2782 {
2783     entity oself;
2784
2785     oself           = self;
2786     self            = self.owner;
2787     oself.think     = SUB_Remove;
2788     oself.nextthink = time;
2789
2790     oself.use();
2791 }
2792
2793 /*
2794     Execute func() after time + fdelay.
2795     self when func is executed = self when defer is called
2796 */
2797 void defer(float fdelay, void() func)
2798 {
2799     entity e;
2800
2801     e           = spawn();
2802     e.owner     = self;
2803     e.use       = func;
2804     e.think     = defer_think;
2805     e.nextthink = time + fdelay;
2806 }