qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include "mutators/_mod.qh"
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "weapons/accuracy.qh"
  13 #include "weapons/csqcprojectile.qh"
  14 #include "weapons/selection.qh"
  15 #include "../common/command/_mod.qh"
  16 #include "../common/constants.qh"
  17 #include <common/net_linked.qh>
  18 #include "../common/deathtypes/all.qh"
  19 #include "../common/mapinfo.qh"
  20 #include "../common/notifications/all.qh"
  21 #include "../common/playerstats.qh"
  22 #include "../common/teams.qh"
  23 #include "../common/triggers/subs.qh"
  24 #include "../common/util.qh"
  25 #include "../common/turrets/sv_turrets.qh"
  26 #include <common/weapons/_all.qh>
  27 #include "../common/vehicles/sv_vehicles.qh"
  28 #include "../common/vehicles/vehicle.qh"
  29 #include "../common/items/_mod.qh"
  30 #include "../common/state.qh"
  31 #include "../common/effects/qc/globalsound.qh"
  32 #include "../common/wepent.qh"
  33 #include "../lib/csqcmodel/sv_model.qh"
  34 #include "../lib/warpzone/anglestransform.qh"
  35 #include "../lib/warpzone/server.qh"
  36
  37 void crosshair_trace(entity pl)
  38 {
  39         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  40 }
  41 .bool ctrace_solidchanged;
  42 void crosshair_trace_plusvisibletriggers(entity pl)
  43 {
  44         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  45         {
  46                 if(it.model != "")
  47                 {
  48                         it.solid = SOLID_BSP;
  49                         it.ctrace_solidchanged = true;
  50                         IL_PUSH(g_ctrace_changed, it);
  51                 }
  52         });
  53
  54         crosshair_trace(pl);
  55
  56         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
  57         {
  58                 it.solid = SOLID_TRIGGER;
  59                 it.ctrace_solidchanged = false;
  60         });
  61
  62         IL_CLEAR(g_ctrace_changed);
  63 }
  64 void WarpZone_crosshair_trace(entity pl)
  65 {
  66         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  67 }
  68
  69
  70 void GameLogEcho(string s)
  71 {
  72     string fn;
  73     int matches;
  74
  75     if (autocvar_sv_eventlog_files)
  76     {
  77         if (!logfile_open)
  78         {
  79             logfile_open = true;
  80             matches = autocvar_sv_eventlog_files_counter + 1;
  81             cvar_set("sv_eventlog_files_counter", itos(matches));
  82             fn = ftos(matches);
  83             if (strlen(fn) < 8)
  84                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  85             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  86             logfile = fopen(fn, FILE_APPEND);
  87             fputs(logfile, ":logversion:3\n");
  88         }
  89         if (logfile >= 0)
  90         {
  91             if (autocvar_sv_eventlog_files_timestamps)
  92                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  93             else
  94                 fputs(logfile, strcat(s, "\n"));
  95         }
  96     }
  97     if (autocvar_sv_eventlog_console)
  98     {
  99         dedicated_print(strcat(s, "\n"));
 100     }
 101 }
 102
 103 void GameLogInit()
 104 {
 105     logfile_open = 0;
 106     // will be opened later
 107 }
 108
 109 void GameLogClose()
 110 {
 111     if (logfile_open && logfile >= 0)
 112     {
 113         fclose(logfile);
 114         logfile = -1;
 115     }
 116 }
 117
 118 entity findnearest(vector point, bool checkitems, vector axismod)
 119 {
 120     vector dist;
 121     int num_nearest = 0;
 122
 123     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 124     {
 125         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 126             dist = it.oldorigin;
 127         else
 128             dist = it.origin;
 129         dist = dist - point;
 130         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 131         float len = vlen2(dist);
 132
 133         int l;
 134         for (l = 0; l < num_nearest; ++l)
 135         {
 136             if (len < nearest_length[l])
 137                 break;
 138         }
 139
 140         // now i tells us where to insert at
 141         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 142         if (l < NUM_NEAREST_ENTITIES)
 143         {
 144             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 145             {
 146                 nearest_length[j + 1] = nearest_length[j];
 147                 nearest_entity[j + 1] = nearest_entity[j];
 148             }
 149             nearest_length[l] = len;
 150             nearest_entity[l] = it;
 151             if (num_nearest < NUM_NEAREST_ENTITIES)
 152                 num_nearest = num_nearest + 1;
 153         }
 154     });
 155
 156     // now use the first one from our list that we can see
 157     for (int j = 0; j < num_nearest; ++j)
 158     {
 159         traceline(point, nearest_entity[j].origin, true, NULL);
 160         if (trace_fraction == 1)
 161         {
 162             if (j != 0)
 163                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 164             return nearest_entity[j];
 165         }
 166     }
 167
 168     if (num_nearest == 0)
 169         return NULL;
 170
 171     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 172     /* DEBUGGING CODE:
 173     dprint("Candidates were: ");
 174     for(j = 0; j < num_nearest; ++j)
 175     {
 176         if(j != 0)
 177                 dprint(", ");
 178         dprint(nearest_entity[j].netname);
 179     }
 180     dprint("\n");
 181     */
 182
 183     return nearest_entity[0];
 184 }
 185
 186 string NearestLocation(vector p)
 187 {
 188     string ret = "somewhere";
 189     entity loc = findnearest(p, false, '1 1 1');
 190     if (loc)
 191         ret = loc.message;
 192     else
 193     {
 194         loc = findnearest(p, true, '1 1 4');
 195         if (loc)
 196             ret = loc.netname;
 197     }
 198     return ret;
 199 }
 200
 201 string AmmoNameFromWeaponentity(entity wpn)
 202 {
 203         string ammoitems = "batteries";
 204         switch ((wpn.m_weapon).ammo_type)
 205         {
 206                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 207                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 208                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 209                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 210                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 211                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 212         }
 213         return ammoitems;
 214 }
 215
 216 string formatmessage(entity this, string msg)
 217 {
 218         float p, p1, p2;
 219         float n;
 220         vector cursor;
 221         entity cursor_ent;
 222         string escape;
 223         string replacement;
 224         p = 0;
 225         n = 7;
 226
 227         WarpZone_crosshair_trace(this);
 228         cursor = trace_endpos;
 229         cursor_ent = trace_ent;
 230
 231         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 232         msg = M_ARGV(1, string);
 233
 234         while (1) {
 235                 if (n < 1)
 236                         break; // too many replacements
 237
 238                 n = n - 1;
 239                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 240                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 241
 242                 if (p1 < 0)
 243                         p1 = p2;
 244
 245                 if (p2 < 0)
 246                         p2 = p1;
 247
 248                 p = min(p1, p2);
 249
 250                 if (p < 0)
 251                         break;
 252
 253                 replacement = substring(msg, p, 2);
 254                 escape = substring(msg, p + 1, 1);
 255
 256                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 257
 258                 switch(escape)
 259                 {
 260                         case "%": replacement = "%"; break;
 261                         case "\\":replacement = "\\"; break;
 262                         case "n": replacement = "\n"; break;
 263                         case "a": replacement = ftos(floor(this.armorvalue)); break;
 264                         case "h": replacement = ftos(floor(this.health)); break;
 265                         case "l": replacement = NearestLocation(this.origin); break;
 266                         case "y": replacement = NearestLocation(cursor); break;
 267                         case "d": replacement = NearestLocation(this.death_origin); break;
 268                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 269                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity)); break;
 270                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 271                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 272                         case "S": replacement = ftos(vlen(this.velocity)); break;
 273                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 274                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 275                         default:
 276                         {
 277                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 278                                 replacement = M_ARGV(2, string);
 279                                 break;
 280                         }
 281                 }
 282
 283                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 284                 p = p + strlen(replacement);
 285         }
 286         return msg;
 287 }
 288
 289 /*
 290 =============
 291 GetCvars
 292 =============
 293 Called with:
 294   0:  sends the request
 295   >0: receives a cvar from name=argv(f) value=argv(f+1)
 296 */
 297 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 298 {
 299         if (f < 0)
 300         {
 301                 strfree(store.(field));
 302         }
 303         else if (f > 0)
 304         {
 305                 if (thisname == name)
 306                 {
 307                         strcpy(store.(field), argv(f + 1));
 308                 }
 309         }
 310         else
 311                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 312 }
 313 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 314 {
 315         GetCvars_handleString(this, store, thisname, f, field, name);
 316         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 317                 if (thisname == name)
 318                 {
 319                         string s = func(this, strcat1(store.(field)));
 320                         if (s != store.(field))
 321                         {
 322                                 strcpy(store.(field), s);
 323                         }
 324                 }
 325 }
 326 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 327 {
 328         if (f < 0)
 329         {
 330         }
 331         else if (f > 0)
 332         {
 333                 if (thisname == name)
 334                         store.(field) = stof(argv(f + 1));
 335         }
 336         else
 337                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 338 }
 339 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 340 {
 341         if (f < 0)
 342         {
 343         }
 344         else if (f > 0)
 345         {
 346                 if (thisname == name)
 347                 {
 348                         if (!store.(field))
 349                         {
 350                                 store.(field) = stof(argv(f + 1));
 351                                 if (!store.(field))
 352                                         store.(field) = -1;
 353                         }
 354                 }
 355         }
 356         else
 357         {
 358                 if (!store.(field))
 359                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 360         }
 361 }
 362 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 363 {
 364         string o = W_FixWeaponOrder_ForceComplete(wo);
 365         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 366         return o;
 367 }
 368
 369 REPLICATE(autoswitch, bool, "cl_autoswitch");
 370
 371 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 372
 373 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 374
 375 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 376
 377 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 378
 379 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 380
 381 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 382
 383 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 384
 385 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 386
 387 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 388
 389 REPLICATE(cvar_cl_physics, string, "cl_physics");
 390
 391 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 392
 393 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 394
 395 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 396
 397 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 398
 399 /**
 400  * @param f -1: cleanup, 0: request, 1: receive
 401  */
 402 void GetCvars(entity this, entity store, int f)
 403 {
 404         string s = string_null;
 405
 406         if (f > 0)
 407                 s = strcat1(argv(f));
 408
 409         get_cvars_f = f;
 410         get_cvars_s = s;
 411         MUTATOR_CALLHOOK(GetCvars);
 412
 413         Notification_GetCvars(this);
 414
 415         ReplicateVars(this, store, s, f);
 416
 417         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 418         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 419         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 420         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 421         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 422         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 423         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 424         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 425         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 426         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 427         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 428
 429         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 430
 431         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 432         if (f > 0)
 433         {
 434                 if (s == "cl_weaponpriority")
 435                 {
 436                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 437                         {
 438                                 .entity weaponentity = weaponentities[slot];
 439                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 440                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 441                         }
 442                 }
 443                 if (s == "cl_allow_uidtracking")
 444                         PlayerStats_GameReport_AddPlayer(this);
 445         }
 446 }
 447
 448 // decolorizes and team colors the player name when needed
 449 string playername(entity p, bool team_colorize)
 450 {
 451     string t;
 452     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 453     {
 454         t = Team_ColorCode(p.team);
 455         return strcat(t, strdecolorize(p.netname));
 456     }
 457     else
 458         return p.netname;
 459 }
 460
 461 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 462 {
 463         int i = weaponinfo.m_id;
 464         int d = 0;
 465         bool allow_mutatorblocked = false;
 466
 467         if(!i)
 468                 return 0;
 469
 470         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 471         d = M_ARGV(1, float);
 472         allguns = M_ARGV(2, bool);
 473         allow_mutatorblocked = M_ARGV(3, bool);
 474
 475         if(allguns)
 476         {
 477                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 478                         d = true;
 479                 else
 480                         d = false;
 481         }
 482         else if(!mutator_returnvalue)
 483                 d = !(!weaponinfo.weaponstart);
 484
 485         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 486                 d = 0;
 487
 488         float t = weaponinfo.weaponstartoverride;
 489
 490         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 491
 492         // bit order in t:
 493         // 1: want or not
 494         // 2: is default?
 495         // 4: is set by default?
 496         if(t < 0)
 497                 t = 4 | (3 * d);
 498         else
 499                 t |= (2 * d);
 500
 501         return t;
 502 }
 503
 504 void readplayerstartcvars()
 505 {
 506         float i, t;
 507         string s;
 508
 509         // initialize starting values for players
 510         start_weapons = '0 0 0';
 511         start_weapons_default = '0 0 0';
 512         start_weapons_defaultmask = '0 0 0';
 513         start_items = 0;
 514         start_ammo_shells = 0;
 515         start_ammo_nails = 0;
 516         start_ammo_rockets = 0;
 517         start_ammo_cells = 0;
 518         start_ammo_plasma = 0;
 519         if (random_start_ammo == NULL)
 520         {
 521                 random_start_ammo = spawn();
 522         }
 523         start_health = cvar("g_balance_health_start");
 524         start_armorvalue = cvar("g_balance_armor_start");
 525
 526         g_weaponarena = 0;
 527         g_weaponarena_weapons = '0 0 0';
 528
 529         s = cvar_string("g_weaponarena");
 530
 531         MUTATOR_CALLHOOK(SetWeaponArena, s);
 532         s = M_ARGV(0, string);
 533
 534         if (s == "0" || s == "")
 535         {
 536                 // no arena
 537         }
 538         else if (s == "off")
 539         {
 540                 // forcibly turn off weaponarena
 541         }
 542         else if (s == "all" || s == "1")
 543         {
 544                 g_weaponarena = 1;
 545                 g_weaponarena_list = "All Weapons";
 546                 FOREACH(Weapons, it != WEP_Null, {
 547                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 548                                 g_weaponarena_weapons |= (it.m_wepset);
 549                 });
 550         }
 551         else if (s == "devall")
 552         {
 553                 g_weaponarena = 1;
 554                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 555                 FOREACH(Weapons, it != WEP_Null,
 556                 {
 557                         g_weaponarena_weapons |= (it.m_wepset);
 558                 });
 559         }
 560         else if (s == "most")
 561         {
 562                 g_weaponarena = 1;
 563                 g_weaponarena_list = "Most Weapons";
 564                 FOREACH(Weapons, it != WEP_Null, {
 565                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 566                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 567                                         g_weaponarena_weapons |= (it.m_wepset);
 568                 });
 569         }
 570         else if (s == "none")
 571         {
 572                 g_weaponarena = 1;
 573                 g_weaponarena_list = "No Weapons";
 574         }
 575         else
 576         {
 577                 g_weaponarena = 1;
 578                 t = tokenize_console(s);
 579                 g_weaponarena_list = "";
 580                 for (i = 0; i < t; ++i)
 581                 {
 582                         s = argv(i);
 583                         FOREACH(Weapons, it != WEP_Null, {
 584                                 if(it.netname == s)
 585                                 {
 586                                         g_weaponarena_weapons |= (it.m_wepset);
 587                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 588                                         break;
 589                                 }
 590                         });
 591                 }
 592                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 593         }
 594
 595         if(g_weaponarena)
 596                 g_weaponarena_random = cvar("g_weaponarena_random");
 597         else
 598                 g_weaponarena_random = 0;
 599         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 600
 601         if (g_weaponarena)
 602         {
 603                 g_weapon_stay = 0; // incompatible
 604                 start_weapons = g_weaponarena_weapons;
 605                 start_items |= IT_UNLIMITED_AMMO;
 606         }
 607         else
 608         {
 609                 FOREACH(Weapons, it != WEP_Null, {
 610                         int w = want_weapon(it, false);
 611                         WepSet s = it.m_wepset;
 612                         if(w & 1)
 613                                 start_weapons |= s;
 614                         if(w & 2)
 615                                 start_weapons_default |= s;
 616                         if(w & 4)
 617                                 start_weapons_defaultmask |= s;
 618                 });
 619         }
 620
 621         if(!cvar("g_use_ammunition"))
 622                 start_items |= IT_UNLIMITED_AMMO;
 623
 624         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 625         {
 626                 start_ammo_shells = 999;
 627                 start_ammo_nails = 999;
 628                 start_ammo_rockets = 999;
 629                 start_ammo_cells = 999;
 630                 start_ammo_plasma = 999;
 631                 start_ammo_fuel = 999;
 632         }
 633         else
 634         {
 635                 start_ammo_shells = cvar("g_start_ammo_shells");
 636                 start_ammo_nails = cvar("g_start_ammo_nails");
 637                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 638                 start_ammo_cells = cvar("g_start_ammo_cells");
 639                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 640                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 641                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 642                 SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, cvar(
 643                         "g_random_start_shells"));
 644                 SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, cvar(
 645                         "g_random_start_bullets"));
 646                 SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS,
 647                         cvar("g_random_start_rockets"));
 648                 SetResourceAmount(random_start_ammo, RESOURCE_CELLS, cvar(
 649                         "g_random_start_cells"));
 650                 SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, cvar(
 651                         "g_random_start_plasma"));
 652         }
 653
 654         if (warmup_stage)
 655         {
 656                 warmup_start_ammo_shells = start_ammo_shells;
 657                 warmup_start_ammo_nails = start_ammo_nails;
 658                 warmup_start_ammo_rockets = start_ammo_rockets;
 659                 warmup_start_ammo_cells = start_ammo_cells;
 660                 warmup_start_ammo_plasma = start_ammo_plasma;
 661                 warmup_start_ammo_fuel = start_ammo_fuel;
 662                 warmup_start_health = start_health;
 663                 warmup_start_armorvalue = start_armorvalue;
 664                 warmup_start_weapons = start_weapons;
 665                 warmup_start_weapons_default = start_weapons_default;
 666                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 667
 668                 if (!g_weaponarena && !g_ca && !g_freezetag)
 669                 {
 670                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 671                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 672                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 673                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 674                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 675                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 676                         warmup_start_health = cvar("g_warmup_start_health");
 677                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 678                         warmup_start_weapons = '0 0 0';
 679                         warmup_start_weapons_default = '0 0 0';
 680                         warmup_start_weapons_defaultmask = '0 0 0';
 681                         FOREACH(Weapons, it != WEP_Null, {
 682                                 int w = want_weapon(it, g_warmup_allguns);
 683                                 WepSet s = (it.m_wepset);
 684                                 if(w & 1)
 685                                         warmup_start_weapons |= s;
 686                                 if(w & 2)
 687                                         warmup_start_weapons_default |= s;
 688                                 if(w & 4)
 689                                         warmup_start_weapons_defaultmask |= s;
 690                         });
 691                 }
 692         }
 693
 694         if (g_jetpack)
 695                 start_items |= ITEM_Jetpack.m_itemid;
 696
 697         MUTATOR_CALLHOOK(SetStartItems);
 698
 699         if (start_items & ITEM_Jetpack.m_itemid)
 700         {
 701                 start_items |= ITEM_JetpackRegen.m_itemid;
 702                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 703                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 704         }
 705
 706         WepSet precache_weapons = start_weapons;
 707         if (g_warmup_allguns != 1)
 708                 precache_weapons |= warmup_start_weapons;
 709         FOREACH(Weapons, it != WEP_Null, {
 710                 if(precache_weapons & (it.m_wepset))
 711                         it.wr_init(it);
 712         });
 713
 714         start_ammo_shells = max(0, start_ammo_shells);
 715         start_ammo_nails = max(0, start_ammo_nails);
 716         start_ammo_rockets = max(0, start_ammo_rockets);
 717         start_ammo_cells = max(0, start_ammo_cells);
 718         start_ammo_plasma = max(0, start_ammo_plasma);
 719         start_ammo_fuel = max(0, start_ammo_fuel);
 720         SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, max(0,
 721                 GetResourceAmount(random_start_ammo, RESOURCE_SHELLS)));
 722         SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, max(0,
 723                 GetResourceAmount(random_start_ammo, RESOURCE_BULLETS)));
 724         SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS, max(0,
 725                 GetResourceAmount(random_start_ammo, RESOURCE_ROCKETS)));
 726         SetResourceAmount(random_start_ammo, RESOURCE_CELLS, max(0,
 727                 GetResourceAmount(random_start_ammo, RESOURCE_CELLS)));
 728         SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, max(0,
 729                 GetResourceAmount(random_start_ammo, RESOURCE_PLASMA)));
 730
 731         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 732         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 733         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 734         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 735         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 736         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 737 }
 738
 739 void precache_playermodel(string m)
 740 {
 741         float globhandle, i, n;
 742         string f;
 743
 744         if(substring(m, -9,5) == "_lod1")
 745                 return;
 746         if(substring(m, -9,5) == "_lod2")
 747                 return;
 748         precache_model(m);
 749         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 750         if(fexists(f))
 751                 precache_model(f);
 752         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 753         if(fexists(f))
 754                 precache_model(f);
 755
 756         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 757         if (globhandle < 0)
 758                 return;
 759         n = search_getsize(globhandle);
 760         for (i = 0; i < n; ++i)
 761         {
 762                 //print(search_getfilename(globhandle, i), "\n");
 763                 f = search_getfilename(globhandle, i);
 764                 PrecachePlayerSounds(f);
 765         }
 766         search_end(globhandle);
 767 }
 768 void precache_all_playermodels(string pattern)
 769 {
 770         int globhandle = search_begin(pattern, true, false);
 771         if (globhandle < 0) return;
 772         int n = search_getsize(globhandle);
 773         for (int i = 0; i < n; ++i)
 774         {
 775                 string s = search_getfilename(globhandle, i);
 776                 precache_playermodel(s);
 777         }
 778         search_end(globhandle);
 779 }
 780
 781 void precache_playermodels(string s)
 782 {
 783         FOREACH_WORD(s, true, { precache_playermodel(it); });
 784 }
 785
 786 void precache()
 787 {
 788     // gamemode related things
 789
 790     // Precache all player models if desired
 791     if (autocvar_sv_precacheplayermodels)
 792     {
 793         PrecachePlayerSounds("sound/player/default.sounds");
 794         precache_all_playermodels("models/player/*.zym");
 795         precache_all_playermodels("models/player/*.dpm");
 796         precache_all_playermodels("models/player/*.md3");
 797         precache_all_playermodels("models/player/*.psk");
 798         precache_all_playermodels("models/player/*.iqm");
 799     }
 800
 801     if (autocvar_sv_defaultcharacter)
 802     {
 803                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 804                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 805                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 806                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 807                 precache_playermodels(autocvar_sv_defaultplayermodel);
 808     }
 809
 810 #if 0
 811     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 812
 813     if (!this.noise && this.music) // quake 3 uses the music field
 814         this.noise = this.music;
 815
 816     // plays music for the level if there is any
 817     if (this.noise)
 818     {
 819         precache_sound (this.noise);
 820         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 821     }
 822 #endif
 823 }
 824
 825
 826 void make_safe_for_remove(entity e)
 827 {
 828     if (e.initialize_entity)
 829     {
 830         entity ent, prev = NULL;
 831         for (ent = initialize_entity_first; ent; )
 832         {
 833             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 834             {
 835                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 836                 // skip it in linked list
 837                 if (prev)
 838                 {
 839                     prev.initialize_entity_next = ent.initialize_entity_next;
 840                     ent = prev.initialize_entity_next;
 841                 }
 842                 else
 843                 {
 844                     initialize_entity_first = ent.initialize_entity_next;
 845                     ent = initialize_entity_first;
 846                 }
 847             }
 848             else
 849             {
 850                 prev = ent;
 851                 ent = ent.initialize_entity_next;
 852             }
 853         }
 854     }
 855 }
 856
 857 .float remove_except_protected_forbidden;
 858 void remove_except_protected(entity e)
 859 {
 860         if(e.remove_except_protected_forbidden)
 861                 error("not allowed to remove this at this point");
 862         builtin_remove(e);
 863 }
 864
 865 void remove_unsafely(entity e)
 866 {
 867     if(e.classname == "spike")
 868         error("Removing spikes is forbidden (crylink bug), please report");
 869     builtin_remove(e);
 870 }
 871
 872 void remove_safely(entity e)
 873 {
 874     make_safe_for_remove(e);
 875     builtin_remove(e);
 876 }
 877
 878 void InitializeEntity(entity e, void(entity this) func, float order)
 879 {
 880     entity prev, cur;
 881
 882     if (!e || e.initialize_entity)
 883     {
 884         // make a proxy initializer entity
 885         entity e_old = e;
 886         e = new(initialize_entity);
 887         e.enemy = e_old;
 888     }
 889
 890     e.initialize_entity = func;
 891     e.initialize_entity_order = order;
 892
 893     cur = initialize_entity_first;
 894     prev = NULL;
 895     for (;;)
 896     {
 897         if (!cur || cur.initialize_entity_order > order)
 898         {
 899             // insert between prev and cur
 900             if (prev)
 901                 prev.initialize_entity_next = e;
 902             else
 903                 initialize_entity_first = e;
 904             e.initialize_entity_next = cur;
 905             return;
 906         }
 907         prev = cur;
 908         cur = cur.initialize_entity_next;
 909     }
 910 }
 911 void InitializeEntitiesRun()
 912 {
 913     entity startoflist = initialize_entity_first;
 914     initialize_entity_first = NULL;
 915     delete_fn = remove_except_protected;
 916     for (entity e = startoflist; e; e = e.initialize_entity_next)
 917     {
 918                 e.remove_except_protected_forbidden = 1;
 919     }
 920     for (entity e = startoflist; e; )
 921     {
 922                 e.remove_except_protected_forbidden = 0;
 923         e.initialize_entity_order = 0;
 924         entity next = e.initialize_entity_next;
 925         e.initialize_entity_next = NULL;
 926         var void(entity this) func = e.initialize_entity;
 927         e.initialize_entity = func_null;
 928         if (e.classname == "initialize_entity")
 929         {
 930             entity wrappee = e.enemy;
 931             builtin_remove(e);
 932             e = wrappee;
 933         }
 934         //dprint("Delayed initialization: ", e.classname, "\n");
 935         if (func)
 936         {
 937                 func(e);
 938         }
 939         else
 940         {
 941             eprint(e);
 942             backtrace(strcat("Null function in: ", e.classname, "\n"));
 943         }
 944         e = next;
 945     }
 946     delete_fn = remove_unsafely;
 947 }
 948
 949 .float(entity) isEliminated;
 950 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 951 {
 952         Stream out = MSG_ENTITY;
 953         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 954         serialize(byte, out, sendflags);
 955         if (sendflags & 1) {
 956                 for (int i = 1; i <= maxclients; i += 8) {
 957                         int f = 0;
 958                         entity e = edict_num(i);
 959                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 960                                 if (eliminatedPlayers.isEliminated(e)) {
 961                                         f |= BIT(b);
 962                                 }
 963                         }
 964                         serialize(byte, out, f);
 965                 }
 966         }
 967         return true;
 968 }
 969
 970 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 971 {
 972         if(eliminatedPlayers)
 973         {
 974                 backtrace("Can't spawn eliminatedPlayers again!");
 975                 return;
 976         }
 977         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 978         eliminatedPlayers.isEliminated = isEliminated_func;
 979 }
 980
 981
 982
 983
 984 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 985 {
 986         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 987                 this.projectiledeathtype |= HITTYPE_SPLASH;
 988         adaptor_think2use(this);
 989 }
 990
 991 // deferred dropping
 992 void DropToFloor_Handler(entity this)
 993 {
 994     WITHSELF(this, builtin_droptofloor());
 995     this.dropped_origin = this.origin;
 996 }
 997
 998 void droptofloor(entity this)
 999 {
1000     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1001 }
1002
1003
1004
1005 float trace_hits_box_a0, trace_hits_box_a1;
1006
1007 float trace_hits_box_1d(float end, float thmi, float thma)
1008 {
1009     if (end == 0)
1010     {
1011         // just check if x is in range
1012         if (0 < thmi)
1013             return false;
1014         if (0 > thma)
1015             return false;
1016     }
1017     else
1018     {
1019         // do the trace with respect to x
1020         // 0 -> end has to stay in thmi -> thma
1021         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1022         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1023         if (trace_hits_box_a0 > trace_hits_box_a1)
1024             return false;
1025     }
1026     return true;
1027 }
1028
1029 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1030 {
1031     end -= start;
1032     thmi -= start;
1033     thma -= start;
1034     // now it is a trace from 0 to end
1035
1036     trace_hits_box_a0 = 0;
1037     trace_hits_box_a1 = 1;
1038
1039     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1040         return false;
1041     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1042         return false;
1043     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1044         return false;
1045
1046     return true;
1047 }
1048
1049 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1050 {
1051     return trace_hits_box(start, end, thmi - ma, thma - mi);
1052 }
1053
1054 bool SUB_NoImpactCheck(entity this, entity toucher)
1055 {
1056         // zero hitcontents = this is not the real impact, but either the
1057         // mirror-impact of something hitting the projectile instead of the
1058         // projectile hitting the something, or a touchareagrid one. Neither of
1059         // these stop the projectile from moving, so...
1060         if(trace_dphitcontents == 0)
1061         {
1062                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1063                 checkclient(this);
1064         }
1065     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1066         return true;
1067     if (toucher == NULL && this.size != '0 0 0')
1068     {
1069         vector tic;
1070         tic = this.velocity * sys_frametime;
1071         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1072         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1073         if (trace_fraction >= 1)
1074         {
1075             LOG_TRACE("Odd... did not hit...?");
1076         }
1077         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1078         {
1079             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1080             return true;
1081         }
1082     }
1083
1084     return false;
1085 }
1086
1087 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1088
1089 void W_Crylink_Dequeue(entity e);
1090 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1091 {
1092         if(SUB_OwnerCheck(this, toucher))
1093                 return true;
1094         if(SUB_NoImpactCheck(this, toucher))
1095         {
1096                 if(this.classname == "nade")
1097                         return false; // no checks here
1098                 else if(this.classname == "grapplinghook")
1099                         RemoveHook(this);
1100                 else if(this.classname == "spike")
1101                 {
1102                         W_Crylink_Dequeue(this);
1103                         delete(this);
1104                 }
1105                 else
1106                         delete(this);
1107                 return true;
1108         }
1109         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1110                 UpdateCSQCProjectile(this);
1111         return false;
1112 }
1113
1114 /** engine callback */
1115 void URI_Get_Callback(float id, float status, string data)
1116 {
1117         if(url_URI_Get_Callback(id, status, data))
1118         {
1119                 // handled
1120         }
1121         else if (id == URI_GET_DISCARD)
1122         {
1123                 // discard
1124         }
1125         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1126         {
1127                 // sv_cmd curl
1128                 Curl_URI_Get_Callback(id, status, data);
1129         }
1130         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1131         {
1132                 // online ban list
1133                 OnlineBanList_URI_Get_Callback(id, status, data);
1134         }
1135         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1136         {
1137                 // handled by a mutator
1138         }
1139         else
1140         {
1141                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1142         }
1143 }
1144
1145 string uid2name(string myuid) {
1146         string s;
1147         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1148
1149         // FIXME remove this later after 0.6 release
1150         // convert old style broken records to correct style
1151         if(s == "")
1152         {
1153                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1154                 if(s != "")
1155                 {
1156                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1157                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1158                 }
1159         }
1160
1161         if(s == "")
1162                 s = "^1Unregistered Player";
1163         return s;
1164 }
1165
1166 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1167 {
1168     float m, i;
1169     vector start, org, delta, end, enddown, mstart;
1170
1171     m = e.dphitcontentsmask;
1172     e.dphitcontentsmask = goodcontents | badcontents;
1173
1174     org = boundmin;
1175     delta = boundmax - boundmin;
1176
1177     start = end = org;
1178
1179     for (i = 0; i < attempts; ++i)
1180     {
1181         start.x = org.x + random() * delta.x;
1182         start.y = org.y + random() * delta.y;
1183         start.z = org.z + random() * delta.z;
1184
1185         // rule 1: start inside world bounds, and outside
1186         // solid, and don't start from somewhere where you can
1187         // fall down to evil
1188         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1189         if (trace_fraction >= 1)
1190             continue;
1191         if (trace_startsolid)
1192             continue;
1193         if (trace_dphitcontents & badcontents)
1194             continue;
1195         if (trace_dphitq3surfaceflags & badsurfaceflags)
1196             continue;
1197
1198         // rule 2: if we are too high, lower the point
1199         if (trace_fraction * delta.z > maxaboveground)
1200             start = trace_endpos + '0 0 1' * maxaboveground;
1201         enddown = trace_endpos;
1202
1203         // rule 3: make sure we aren't outside the map. This only works
1204         // for somewhat well formed maps. A good rule of thumb is that
1205         // the map should have a convex outside hull.
1206         // these can be traceLINES as we already verified the starting box
1207         mstart = start + 0.5 * (e.mins + e.maxs);
1208         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1209         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1210             continue;
1211         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1212         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1213             continue;
1214         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1215         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1216             continue;
1217         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1218         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1219             continue;
1220         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1221         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1222             continue;
1223
1224         // rule 4: we must "see" some spawnpoint or item
1225     entity sp = NULL;
1226     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1227     {
1228         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1229         {
1230                 sp = it;
1231                 break;
1232         }
1233     });
1234         if(!sp)
1235         {
1236                 int items_checked = 0;
1237                 IL_EACH(g_items, checkpvs(mstart, it),
1238                 {
1239                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1240                         {
1241                                 sp = it;
1242                                 break;
1243                         }
1244
1245                         ++items_checked;
1246                         if(items_checked >= attempts)
1247                                 break; // sanity
1248                 });
1249
1250                 if(!sp)
1251                         continue;
1252         }
1253
1254         // find a random vector to "look at"
1255         end.x = org.x + random() * delta.x;
1256         end.y = org.y + random() * delta.y;
1257         end.z = org.z + random() * delta.z;
1258         end = start + normalize(end - start) * vlen(delta);
1259
1260         // rule 4: start TO end must not be too short
1261         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1262         if (trace_startsolid)
1263             continue;
1264         if (trace_fraction < minviewdistance / vlen(delta))
1265             continue;
1266
1267         // rule 5: don't want to look at sky
1268         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1269             continue;
1270
1271         // rule 6: we must not end up in trigger_hurt
1272         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1273             continue;
1274
1275         break;
1276     }
1277
1278     e.dphitcontentsmask = m;
1279
1280     if (i < attempts)
1281     {
1282         setorigin(e, start);
1283         e.angles = vectoangles(end - start);
1284         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1285         return true;
1286     }
1287     else
1288         return false;
1289 }
1290
1291 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1292 {
1293         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1294 }
1295
1296 void write_recordmarker(entity pl, float tstart, float dt)
1297 {
1298     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1299
1300     // also write a marker into demo files for demotc-race-record-extractor to find
1301     stuffcmd(pl,
1302              strcat(
1303                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1304                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1305 }
1306
1307 void attach_sameorigin(entity e, entity to, string tag)
1308 {
1309     vector org, t_forward, t_left, t_up, e_forward, e_up;
1310     float tagscale;
1311
1312     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1313     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1314     t_forward = v_forward * tagscale;
1315     t_left = v_right * -tagscale;
1316     t_up = v_up * tagscale;
1317
1318     e.origin_x = org * t_forward;
1319     e.origin_y = org * t_left;
1320     e.origin_z = org * t_up;
1321
1322     // current forward and up directions
1323     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1324                 e.angles = AnglesTransform_FromVAngles(e.angles);
1325         else
1326                 e.angles = AnglesTransform_FromAngles(e.angles);
1327     fixedmakevectors(e.angles);
1328
1329     // untransform forward, up!
1330     e_forward.x = v_forward * t_forward;
1331     e_forward.y = v_forward * t_left;
1332     e_forward.z = v_forward * t_up;
1333     e_up.x = v_up * t_forward;
1334     e_up.y = v_up * t_left;
1335     e_up.z = v_up * t_up;
1336
1337     e.angles = fixedvectoangles2(e_forward, e_up);
1338     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1339                 e.angles = AnglesTransform_ToVAngles(e.angles);
1340         else
1341                 e.angles = AnglesTransform_ToAngles(e.angles);
1342
1343     setattachment(e, to, tag);
1344     setorigin(e, e.origin);
1345 }
1346
1347 void detach_sameorigin(entity e)
1348 {
1349     vector org;
1350     org = gettaginfo(e, 0);
1351     e.angles = fixedvectoangles2(v_forward, v_up);
1352     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1353                 e.angles = AnglesTransform_ToVAngles(e.angles);
1354         else
1355                 e.angles = AnglesTransform_ToAngles(e.angles);
1356     setorigin(e, org);
1357     setattachment(e, NULL, "");
1358     setorigin(e, e.origin);
1359 }
1360
1361 void follow_sameorigin(entity e, entity to)
1362 {
1363     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1364     e.aiment = to; // make the hole follow bmodel
1365     e.punchangle = to.angles; // the original angles of bmodel
1366     e.view_ofs = e.origin - to.origin; // relative origin
1367     e.v_angle = e.angles - to.angles; // relative angles
1368 }
1369
1370 void unfollow_sameorigin(entity e)
1371 {
1372     set_movetype(e, MOVETYPE_NONE);
1373 }
1374
1375 entity gettaginfo_relative_ent;
1376 vector gettaginfo_relative(entity e, float tag)
1377 {
1378     if (!gettaginfo_relative_ent)
1379     {
1380         gettaginfo_relative_ent = spawn();
1381         gettaginfo_relative_ent.effects = EF_NODRAW;
1382     }
1383     gettaginfo_relative_ent.model = e.model;
1384     gettaginfo_relative_ent.modelindex = e.modelindex;
1385     gettaginfo_relative_ent.frame = e.frame;
1386     return gettaginfo(gettaginfo_relative_ent, tag);
1387 }
1388
1389 .string aiment_classname;
1390 .float aiment_deadflag;
1391 void SetMovetypeFollow(entity ent, entity e)
1392 {
1393         // FIXME this may not be warpzone aware
1394         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1395         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1396         ent.aiment = e; // make the hole follow bmodel
1397         ent.punchangle = e.angles; // the original angles of bmodel
1398         ent.view_ofs = ent.origin - e.origin; // relative origin
1399         ent.v_angle = ent.angles - e.angles; // relative angles
1400         ent.aiment_classname = strzone(e.classname);
1401         ent.aiment_deadflag = e.deadflag;
1402 }
1403 void UnsetMovetypeFollow(entity ent)
1404 {
1405         set_movetype(ent, MOVETYPE_FLY);
1406         PROJECTILE_MAKETRIGGER(ent);
1407         ent.aiment = NULL;
1408 }
1409 float LostMovetypeFollow(entity ent)
1410 {
1411 /*
1412         if(ent.move_movetype != MOVETYPE_FOLLOW)
1413                 if(ent.aiment)
1414                         error("???");
1415 */
1416         if(ent.aiment)
1417         {
1418                 if(ent.aiment.classname != ent.aiment_classname)
1419                         return 1;
1420                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1421                         return 1;
1422         }
1423         return 0;
1424 }
1425
1426 .bool pushable;
1427 bool isPushable(entity e)
1428 {
1429         if(e.pushable)
1430                 return true;
1431         if(IS_VEHICLE(e))
1432                 return false;
1433         if(e.iscreature)
1434                 return true;
1435         if (Item_IsLoot(e))
1436         {
1437                 return true;
1438         }
1439         switch(e.classname)
1440         {
1441                 case "body":
1442                         return true;
1443                 case "bullet": // antilagged bullets can't hit this either
1444                         return false;
1445         }
1446         if (e.projectiledeathtype)
1447                 return true;
1448         return false;
1449 }