qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 float race_GetTime(float pos);
  20 string race_GetName(float pos);
  21 string race_PlaceName(float pos);
  22 string GetMapname();
  23 string ColoredTeamName(float t);
  24
  25 string admin_name(void)
  26 {
  27         if(cvar_string("sv_adminnick") != "")
  28                 return cvar_string("sv_adminnick");
  29         else
  30                 return "SERVER ADMIN";
  31 }
  32
  33 float DistributeEvenly_amount;
  34 float DistributeEvenly_totalweight;
  35 void DistributeEvenly_Init(float amount, float totalweight)
  36 {
  37     if (DistributeEvenly_amount)
  38     {
  39         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  40         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  41     }
  42     if (totalweight == 0)
  43         DistributeEvenly_amount = 0;
  44     else
  45         DistributeEvenly_amount = amount;
  46     DistributeEvenly_totalweight = totalweight;
  47 }
  48 float DistributeEvenly_Get(float weight)
  49 {
  50     float f;
  51     if (weight <= 0)
  52         return 0;
  53     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  54     DistributeEvenly_totalweight -= weight;
  55     DistributeEvenly_amount -= f;
  56     return f;
  57 }
  58
  59 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  60
  61
  62 string STR_PLAYER = "player";
  63 string STR_SPECTATOR = "spectator";
  64 string STR_OBSERVER = "observer";
  65
  66 #if 0
  67 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  68 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  69 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  70 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  71 #else
  72 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  73 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  74 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  75 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  76 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  77 #endif
  78
  79 // copies a string to a tempstring (so one can strunzone it)
  80 string strcat1(string s) = #115; // FRIK_FILE
  81
  82 float logfile_open;
  83 float logfile;
  84
  85 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  86 {
  87         local float nPlayerHealth = rint(enPlayer.health);
  88         local float nPlayerArmor = rint(enPlayer.armorvalue);
  89         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  90         local float nPlayerPing = rint(enPlayer.ping);
  91         local string strPlayerPingColor;
  92         local string strMessage;
  93         if(nPlayerPing >= 150)
  94                 strPlayerPingColor = "^1";
  95         else
  96                 strPlayerPingColor = "^2";
  97
  98         if((cvar("sv_fragmessage_information_stats")) && (enPlayer.health >= 1))
  99                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
 100
 101         if(cvar("sv_fragmessage_information_ping")) {
 102                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 103                         strMessage = strcat(strMessage, "\n^7(^2Bot");
 104                 else
 105                         strMessage = strcat(strMessage, "\n^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 106                 if(cvar("sv_fragmessage_information_handicap"))
 107                         if(cvar("sv_fragmessage_information_handicap") == 2)
 108                                 if(nPlayerHandicap <= 1)
 109                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 110                                 else
 111                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 112                         else if not(nPlayerHandicap <= 1)
 113                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 114                 else
 115                         strMessage = strcat(strMessage, "^7)");
 116         } else if(cvar("sv_fragmessage_information_handicap")) {
 117                 if(cvar("sv_fragmessage_information_handicap") == 2)
 118                         if(nPlayerHandicap <= 1)
 119                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 120                         else
 121                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 122                 else if(nPlayerHandicap > 1)
 123                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 124         }
 125         return strMessage;
 126 }
 127 void bcenterprint(string s)
 128 {
 129     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 130     entity head;
 131     FOR_EACH_PLAYER(head)
 132     if (clienttype(head) == CLIENTTYPE_REAL)
 133         centerprint(head, s);
 134 }
 135
 136 void GameLogEcho(string s)
 137 {
 138     string fn;
 139     float matches;
 140
 141     if (cvar("sv_eventlog_files"))
 142     {
 143         if (!logfile_open)
 144         {
 145             logfile_open = TRUE;
 146             matches = cvar("sv_eventlog_files_counter") + 1;
 147             cvar_set("sv_eventlog_files_counter", ftos(matches));
 148             fn = ftos(matches);
 149             if (strlen(fn) < 8)
 150                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 151             fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 152             logfile = fopen(fn, FILE_APPEND);
 153             fputs(logfile, ":logversion:3\n");
 154         }
 155         if (logfile >= 0)
 156         {
 157             if (cvar("sv_eventlog_files_timestamps"))
 158                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 159             else
 160                 fputs(logfile, strcat(s, "\n"));
 161         }
 162     }
 163     if (cvar("sv_eventlog_console"))
 164     {
 165         print(s, "\n");
 166     }
 167 }
 168
 169 void GameLogInit()
 170 {
 171     logfile_open = 0;
 172     // will be opened later
 173 }
 174
 175 void GameLogClose()
 176 {
 177     if (logfile_open && logfile >= 0)
 178     {
 179         fclose(logfile);
 180         logfile = -1;
 181     }
 182 }
 183
 184 vector PL_VIEW_OFS;
 185 vector PL_MIN;
 186 vector PL_MAX;
 187 vector PL_CROUCH_VIEW_OFS;
 188 vector PL_CROUCH_MIN;
 189 vector PL_CROUCH_MAX;
 190
 191 float spawnpoint_nag;
 192 void relocate_spawnpoint()
 193 {
 194     PL_VIEW_OFS                             = stov(cvar_string("sv_player_viewoffset"));
 195     PL_MIN                                  = stov(cvar_string("sv_player_mins"));
 196     PL_MAX                                  = stov(cvar_string("sv_player_maxs"));
 197     PL_CROUCH_VIEW_OFS                      = stov(cvar_string("sv_player_crouch_viewoffset"));
 198     PL_CROUCH_MIN                           = stov(cvar_string("sv_player_crouch_mins"));
 199     PL_CROUCH_MAX                           = stov(cvar_string("sv_player_crouch_maxs"));
 200
 201     // nudge off the floor
 202     setorigin(self, self.origin + '0 0 1');
 203
 204     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 205     if (trace_startsolid)
 206     {
 207         vector o;
 208         o = self.origin;
 209         self.mins = PL_MIN;
 210         self.maxs = PL_MAX;
 211         if (!move_out_of_solid(self))
 212             objerror("could not get out of solid at all!");
 213         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 214         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 215         print(" ", ftos(self.origin_y - o_y));
 216         print(" ", ftos(self.origin_z - o_z), "'\n");
 217         if (cvar("g_spawnpoints_auto_move_out_of_solid"))
 218         {
 219             if (!spawnpoint_nag)
 220                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 221             spawnpoint_nag = 1;
 222         }
 223         else
 224         {
 225             setorigin(self, o);
 226             self.mins = self.maxs = '0 0 0';
 227             objerror("player spawn point in solid, mapper sucks!\n");
 228             return;
 229         }
 230     }
 231
 232     if (cvar("g_spawnpoints_autodrop"))
 233     {
 234         setsize(self, PL_MIN, PL_MAX);
 235         droptofloor();
 236     }
 237
 238     self.use = spawnpoint_use;
 239     self.team_saved = self.team;
 240     if (!self.cnt)
 241         self.cnt = 1;
 242
 243     if (have_team_spawns != 0)
 244         if (self.team)
 245             have_team_spawns = 1;
 246
 247     if (cvar("r_showbboxes"))
 248     {
 249         // show where spawnpoints point at too
 250         makevectors(self.angles);
 251         entity e;
 252         e = spawn();
 253         e.classname = "info_player_foo";
 254         setorigin(e, self.origin + v_forward * 24);
 255         setsize(e, '-8 -8 -8', '8 8 8');
 256         e.solid = SOLID_TRIGGER;
 257     }
 258 }
 259
 260 #define strstr strstrofs
 261 /*
 262 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 263 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 264 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 265 // BE CONSTANT OR strzoneD!
 266 float strstr(string haystack, string needle, float offset)
 267 {
 268         float len, endpos;
 269         string found;
 270         len = strlen(needle);
 271         endpos = strlen(haystack) - len;
 272         while(offset <= endpos)
 273         {
 274                 found = substring(haystack, offset, len);
 275                 if(found == needle)
 276                         return offset;
 277                 offset = offset + 1;
 278         }
 279         return -1;
 280 }
 281 */
 282
 283 float NUM_NEAREST_ENTITIES = 4;
 284 entity nearest_entity[NUM_NEAREST_ENTITIES];
 285 float nearest_length[NUM_NEAREST_ENTITIES];
 286 entity findnearest(vector point, .string field, string value, vector axismod)
 287 {
 288     entity localhead;
 289     float i;
 290     float j;
 291     float len;
 292     vector dist;
 293
 294     float num_nearest;
 295     num_nearest = 0;
 296
 297     localhead = find(world, field, value);
 298     while (localhead)
 299     {
 300         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 301             dist = localhead.oldorigin;
 302         else
 303             dist = localhead.origin;
 304         dist = dist - point;
 305         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 306         len = vlen(dist);
 307
 308         for (i = 0; i < num_nearest; ++i)
 309         {
 310             if (len < nearest_length[i])
 311                 break;
 312         }
 313
 314         // now i tells us where to insert at
 315         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 316         if (i < NUM_NEAREST_ENTITIES)
 317         {
 318             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 319             {
 320                 nearest_length[j + 1] = nearest_length[j];
 321                 nearest_entity[j + 1] = nearest_entity[j];
 322             }
 323             nearest_length[i] = len;
 324             nearest_entity[i] = localhead;
 325             if (num_nearest < NUM_NEAREST_ENTITIES)
 326                 num_nearest = num_nearest + 1;
 327         }
 328
 329         localhead = find(localhead, field, value);
 330     }
 331
 332     // now use the first one from our list that we can see
 333     for (i = 0; i < num_nearest; ++i)
 334     {
 335         traceline(point, nearest_entity[i].origin, TRUE, world);
 336         if (trace_fraction == 1)
 337         {
 338             if (i != 0)
 339             {
 340                 dprint("Nearest point (");
 341                 dprint(nearest_entity[0].netname);
 342                 dprint(") is not visible, using a visible one.\n");
 343             }
 344             return nearest_entity[i];
 345         }
 346     }
 347
 348     if (num_nearest == 0)
 349         return world;
 350
 351     dprint("Not seeing any location point, using nearest as fallback.\n");
 352     /* DEBUGGING CODE:
 353     dprint("Candidates were: ");
 354     for(j = 0; j < num_nearest; ++j)
 355     {
 356         if(j != 0)
 357                 dprint(", ");
 358         dprint(nearest_entity[j].netname);
 359     }
 360     dprint("\n");
 361     */
 362
 363     return nearest_entity[0];
 364 }
 365
 366 void spawnfunc_target_location()
 367 {
 368     self.classname = "target_location";
 369     // location name in netname
 370     // eventually support: count, teamgame selectors, line of sight?
 371 };
 372
 373 void spawnfunc_info_location()
 374 {
 375     self.classname = "target_location";
 376     self.message = self.netname;
 377 };
 378
 379 string NearestLocation(vector p)
 380 {
 381     entity loc;
 382     string ret;
 383     ret = "somewhere";
 384     loc = findnearest(p, classname, "target_location", '1 1 1');
 385     if (loc)
 386     {
 387         ret = loc.message;
 388     }
 389     else
 390     {
 391         loc = findnearest(p, target, "###item###", '1 1 4');
 392         if (loc)
 393             ret = loc.netname;
 394     }
 395     return ret;
 396 }
 397
 398 string formatmessage(string msg)
 399 {
 400         float p, p1, p2;
 401         float n;
 402         vector cursor;
 403         entity cursor_ent;
 404         string escape;
 405         string replacement;
 406         p = 0;
 407         n = 7;
 408
 409         WarpZone_crosshair_trace(self);
 410         cursor = trace_endpos;
 411         cursor_ent = trace_ent;
 412
 413         while (1) {
 414                 if (n < 1)
 415                         break; // too many replacements
 416
 417                 n = n - 1;
 418                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 419                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 420
 421                 if (p1 < 0)
 422                         p1 = p2;
 423
 424                 if (p2 < 0)
 425                         p2 = p1;
 426
 427                 p = min(p1, p2);
 428
 429                 if (p < 0)
 430                         break;
 431
 432                 replacement = substring(msg, p, 2);
 433                 escape = substring(msg, p + 1, 1);
 434
 435                 if (escape == "%")
 436                         replacement = "%";
 437                 else if (escape == "\\")
 438                         replacement = "\\";
 439                 else if (escape == "n")
 440                         replacement = "\n";
 441                 else if (escape == "a")
 442                         replacement = ftos(floor(self.armorvalue));
 443                 else if (escape == "h")
 444                         replacement = ftos(floor(self.health));
 445                 else if (escape == "l")
 446                         replacement = NearestLocation(self.origin);
 447                 else if (escape == "y")
 448                         replacement = NearestLocation(cursor);
 449                 else if (escape == "d")
 450                         replacement = NearestLocation(self.death_origin);
 451                 else if (escape == "w") {
 452                         float wep;
 453                         wep = self.weapon;
 454                         if (!wep)
 455                                 wep = self.switchweapon;
 456                         if (!wep)
 457                                 wep = self.cnt;
 458                         replacement = W_Name(wep);
 459                 } else if (escape == "W") {
 460                         if (self.items & IT_SHELLS) replacement = "shells";
 461                         else if (self.items & IT_NAILS) replacement = "bullets";
 462                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 463                         else if (self.items & IT_CELLS) replacement = "cells";
 464                         else replacement = "batteries"; // ;)
 465                 } else if (escape == "x") {
 466                         replacement = cursor_ent.netname;
 467                         if (!replacement || !cursor_ent)
 468                                 replacement = "nothing";
 469                 } else if (escape == "p") {
 470                         if (self.last_selected_player)
 471                                 replacement = self.last_selected_player.netname;
 472                         else
 473                                 replacement = "(nobody)";
 474                 } else if (escape == "s")
 475                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 476                 else if (escape == "S")
 477                         replacement = ftos(vlen(self.velocity));
 478                 else if (escape == "v") {
 479                         float weapon_number;
 480                         local entity stats;
 481
 482                         if(self.classname == "spectator")
 483                                 stats = self.enemy;
 484                         else
 485                                 stats = self;
 486
 487                         weapon_number = stats.weapon;
 488
 489                         if (!weapon_number)
 490                                 weapon_number = stats.switchweapon;
 491
 492                         if (!weapon_number)
 493                                 weapon_number = stats.cnt;
 494
 495                         if(stats.cvar_cl_accuracy_data_share && stats.stats_fired[weapon_number - 1])
 496                                 replacement = ftos(bound(0, floor(100 * stats.stats_hit[weapon_number - 1] / stats.stats_fired[weapon_number - 1]), 100));
 497                         else
 498                                 replacement = "~"; // or something to indicate NULL, not available
 499                 }
 500
 501                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 502                 p = p + strlen(replacement);
 503         }
 504         return msg;
 505 }
 506
 507 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 508         return (value == 0) ? FALSE : TRUE;
 509 }
 510
 511 /*
 512 =============
 513 GetCvars
 514 =============
 515 Called with:
 516   0:  sends the request
 517   >0: receives a cvar from name=argv(f) value=argv(f+1)
 518 */
 519 void GetCvars_handleString(string thisname, float f, .string field, string name)
 520 {
 521         if (f < 0)
 522         {
 523                 if (self.field)
 524                         strunzone(self.field);
 525                 self.field = string_null;
 526         }
 527         else if (f > 0)
 528         {
 529                 if (thisname == name)
 530                 {
 531                         if (self.field)
 532                                 strunzone(self.field);
 533                         self.field = strzone(argv(f + 1));
 534                 }
 535         }
 536         else
 537                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 538 }
 539 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 540 {
 541         GetCvars_handleString(thisname, f, field, name);
 542         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 543                 if (thisname == name)
 544                 {
 545                         string s;
 546                         s = func(strcat1(self.field));
 547                         if (s != self.field)
 548                         {
 549                                 strunzone(self.field);
 550                                 self.field = strzone(s);
 551                         }
 552                 }
 553 }
 554 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 555 {
 556         if (f < 0)
 557         {
 558         }
 559         else if (f > 0)
 560         {
 561                 if (thisname == name)
 562                         self.field = stof(argv(f + 1));
 563         }
 564         else
 565                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 566 }
 567 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 568 {
 569         if (f < 0)
 570         {
 571         }
 572         else if (f > 0)
 573         {
 574                 if (thisname == name)
 575                 {
 576                         if(!self.field)
 577                         {
 578                                 self.field = stof(argv(f + 1));
 579                                 if(!self.field)
 580                                         self.field = -1;
 581                         }
 582                 }
 583         }
 584         else
 585         {
 586                 if(!self.field)
 587                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 588         }
 589 }
 590 string W_FixWeaponOrder_ForceComplete(string s);
 591 string W_FixWeaponOrder_AllowIncomplete(string s);
 592 float w_getbestweapon(entity e);
 593 void GetCvars(float f)
 594 {
 595         string s;
 596
 597         if (f > 0)
 598                 s = strcat1(argv(f));
 599
 600         get_cvars_f = f;
 601         get_cvars_s = s;
 602         MUTATOR_CALLHOOK(GetCvars);
 603         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 604         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 605         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 606         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 607         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 608         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 609         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 610         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 611         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 612         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 613         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 614         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 615         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 616         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 617         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 618         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 619         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 620         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 621         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 622         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 623         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 624         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 625         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 626         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 627         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 628
 629         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 630         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 631
 632 #ifdef ALLOW_FORCEMODELS
 633         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 634         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 635 #endif
 636         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 637
 638         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 639         if (f > 0)
 640         {
 641                 if (s == "cl_weaponpriority")
 642                         self.switchweapon = w_getbestweapon(self);
 643         }
 644 }
 645
 646 float fexists(string f)
 647 {
 648     float fh;
 649     fh = fopen(f, FILE_READ);
 650     if (fh < 0)
 651         return FALSE;
 652     fclose(fh);
 653     return TRUE;
 654 }
 655
 656 void backtrace(string msg)
 657 {
 658     float dev, war;
 659     dev = cvar("developer");
 660     war = cvar("prvm_backtraceforwarnings");
 661     cvar_set("developer", "1");
 662     cvar_set("prvm_backtraceforwarnings", "1");
 663     print("\n");
 664     print("--- CUT HERE ---\nWARNING: ");
 665     print(msg);
 666     print("\n");
 667     remove(world); // isn't there any better way to cause a backtrace?
 668     print("\n--- CUT UNTIL HERE ---\n");
 669     cvar_set("developer", ftos(dev));
 670     cvar_set("prvm_backtraceforwarnings", ftos(war));
 671 }
 672
 673 string Team_ColorCode(float teamid)
 674 {
 675     if (teamid == COLOR_TEAM1)
 676         return "^1";
 677     else if (teamid == COLOR_TEAM2)
 678         return "^4";
 679     else if (teamid == COLOR_TEAM3)
 680         return "^3";
 681     else if (teamid == COLOR_TEAM4)
 682         return "^6";
 683     else
 684         return "^7";
 685 }
 686
 687 string Team_ColorName(float t)
 688 {
 689     // fixme: Search for team entities and get their .netname's!
 690     if (t == COLOR_TEAM1)
 691         return "Red";
 692     if (t == COLOR_TEAM2)
 693         return "Blue";
 694     if (t == COLOR_TEAM3)
 695         return "Yellow";
 696     if (t == COLOR_TEAM4)
 697         return "Pink";
 698     return "Neutral";
 699 }
 700
 701 string Team_ColorNameLowerCase(float t)
 702 {
 703     // fixme: Search for team entities and get their .netname's!
 704     if (t == COLOR_TEAM1)
 705         return "red";
 706     if (t == COLOR_TEAM2)
 707         return "blue";
 708     if (t == COLOR_TEAM3)
 709         return "yellow";
 710     if (t == COLOR_TEAM4)
 711         return "pink";
 712     return "neutral";
 713 }
 714
 715 float ColourToNumber(string team_colour)
 716 {
 717         if (team_colour == "red")
 718                 return COLOR_TEAM1;
 719
 720         if (team_colour == "blue")
 721                 return COLOR_TEAM2;
 722
 723         if (team_colour == "yellow")
 724                 return COLOR_TEAM3;
 725
 726         if (team_colour == "pink")
 727                 return COLOR_TEAM4;
 728
 729         if (team_colour == "auto")
 730                 return 0;
 731
 732         return -1;
 733 }
 734
 735 float NumberToTeamNumber(float number)
 736 {
 737         if (number == 1)
 738                 return COLOR_TEAM1;
 739
 740         if (number == 2)
 741                 return COLOR_TEAM2;
 742
 743         if (number == 3)
 744                 return COLOR_TEAM3;
 745
 746         if (number == 4)
 747                 return COLOR_TEAM4;
 748
 749         return -1;
 750 }
 751
 752 #define CENTERPRIO_POINT 1
 753 #define CENTERPRIO_SPAM 2
 754 #define CENTERPRIO_VOTE 4
 755 #define CENTERPRIO_NORMAL 5
 756 #define CENTERPRIO_SHIELDING 7
 757 #define CENTERPRIO_MAPVOTE 9
 758 #define CENTERPRIO_IDLEKICK 50
 759 #define CENTERPRIO_ADMIN 99
 760 .float centerprint_priority;
 761 .float centerprint_expires;
 762 void centerprint_atprio(entity e, float prio, string s)
 763 {
 764     if (intermission_running)
 765         if (prio < CENTERPRIO_MAPVOTE)
 766             return;
 767     if (time > e.centerprint_expires)
 768         e.centerprint_priority = 0;
 769     if (prio >= e.centerprint_priority)
 770     {
 771         e.centerprint_priority = prio;
 772         if (timeoutStatus == 2)
 773             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 774         else
 775             e.centerprint_expires = time + e.cvar_scr_centertime;
 776         centerprint_builtin(e, s);
 777     }
 778 }
 779 void centerprint_expire(entity e, float prio)
 780 {
 781     if (prio == e.centerprint_priority)
 782     {
 783         e.centerprint_priority = 0;
 784         centerprint_builtin(e, "");
 785     }
 786 }
 787 void centerprint(entity e, string s)
 788 {
 789     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 790 }
 791
 792 // decolorizes and team colors the player name when needed
 793 string playername(entity p)
 794 {
 795     string t;
 796     if (teams_matter && !intermission_running && p.classname == "player")
 797     {
 798         t = Team_ColorCode(p.team);
 799         return strcat(t, strdecolorize(p.netname));
 800     }
 801     else
 802         return p.netname;
 803 }
 804
 805 vector randompos(vector m1, vector m2)
 806 {
 807     local vector v;
 808     m2 = m2 - m1;
 809     v_x = m2_x * random() + m1_x;
 810     v_y = m2_y * random() + m1_y;
 811     v_z = m2_z * random() + m1_z;
 812     return  v;
 813 };
 814
 815 float g_pickup_shells;
 816 float g_pickup_shells_max;
 817 float g_pickup_nails;
 818 float g_pickup_nails_max;
 819 float g_pickup_rockets;
 820 float g_pickup_rockets_max;
 821 float g_pickup_cells;
 822 float g_pickup_cells_max;
 823 float g_pickup_fuel;
 824 float g_pickup_fuel_jetpack;
 825 float g_pickup_fuel_max;
 826 float g_pickup_armorsmall;
 827 float g_pickup_armorsmall_max;
 828 float g_pickup_armormedium;
 829 float g_pickup_armormedium_max;
 830 float g_pickup_armorbig;
 831 float g_pickup_armorbig_max;
 832 float g_pickup_armorlarge;
 833 float g_pickup_armorlarge_max;
 834 float g_pickup_healthsmall;
 835 float g_pickup_healthsmall_max;
 836 float g_pickup_healthmedium;
 837 float g_pickup_healthmedium_max;
 838 float g_pickup_healthlarge;
 839 float g_pickup_healthlarge_max;
 840 float g_pickup_healthmega;
 841 float g_pickup_healthmega_max;
 842 float g_weaponarena;
 843 float g_weaponarena_random;
 844 string g_weaponarena_list;
 845 float g_weaponspeedfactor;
 846 float g_weaponratefactor;
 847 float g_weapondamagefactor;
 848 float g_weaponforcefactor;
 849 float g_weaponspreadfactor;
 850
 851 float start_weapons;
 852 float start_items;
 853 float start_ammo_shells;
 854 float start_ammo_nails;
 855 float start_ammo_rockets;
 856 float start_ammo_cells;
 857 float start_ammo_fuel;
 858 float start_health;
 859 float start_armorvalue;
 860 float warmup_start_weapons;
 861 float warmup_start_ammo_shells;
 862 float warmup_start_ammo_nails;
 863 float warmup_start_ammo_rockets;
 864 float warmup_start_ammo_cells;
 865 float warmup_start_ammo_fuel;
 866 float warmup_start_health;
 867 float warmup_start_armorvalue;
 868 float g_weapon_stay;
 869 float g_ghost_items;
 870
 871 entity get_weaponinfo(float w);
 872
 873 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 874 {
 875         var float i = weaponinfo.weapon;
 876
 877         if (!i)
 878                 return 0;
 879
 880         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 881
 882         if (t < 0) // "default" weapon selection
 883         {
 884                 if (g_lms || g_ca || allguns)
 885                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 886                 else if(t < -1)
 887                         t = 0;
 888                 else if (g_race || g_cts)
 889                         t = (i == WEP_LASER);
 890                 else if (g_nexball)
 891                         t = 0; // weapon is set a few lines later
 892                 else
 893                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 894                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 895                         t |= (i == WEP_HOOK);
 896         }
 897
 898         // we cannot disable porto in Nexball, we must force it
 899         if(g_nexball && i == WEP_PORTO)
 900                 t = 1;
 901
 902         return t;
 903 }
 904
 905 void readplayerstartcvars()
 906 {
 907         entity e;
 908         float i, j, t;
 909         string s;
 910
 911         // initialize starting values for players
 912         start_weapons = 0;
 913         start_items = 0;
 914         start_ammo_shells = 0;
 915         start_ammo_nails = 0;
 916         start_ammo_rockets = 0;
 917         start_ammo_cells = 0;
 918         start_health = cvar("g_balance_health_start");
 919         start_armorvalue = cvar("g_balance_armor_start");
 920
 921         g_weaponarena = 0;
 922         s = cvar_string("g_weaponarena");
 923         if (s == "0")
 924         {
 925         }
 926         else if (s == "all")
 927         {
 928                 g_weaponarena_list = "All Weapons";
 929                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 930                 {
 931                         e = get_weaponinfo(j);
 932                         g_weaponarena |= e.weapons;
 933                         weapon_action(e.weapon, WR_PRECACHE);
 934                 }
 935         }
 936         else if (s == "most")
 937         {
 938                 g_weaponarena_list = "Most Weapons";
 939                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 940                 {
 941                         e = get_weaponinfo(j);
 942                         if (e.spawnflags & WEP_FLAG_NORMAL)
 943                         {
 944                                 g_weaponarena |= e.weapons;
 945                                 weapon_action(e.weapon, WR_PRECACHE);
 946                         }
 947                 }
 948         }
 949         else if (s == "none")
 950         {
 951                 g_weaponarena_list = "No Weapons";
 952                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 953         }
 954         else
 955         {
 956                 t = tokenize_console(s);
 957                 g_weaponarena_list = "";
 958                 for (i = 0; i < t; ++i)
 959                 {
 960                         s = argv(i);
 961                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 962                         {
 963                                 e = get_weaponinfo(j);
 964                                 if (e.netname == s)
 965                                 {
 966                                         g_weaponarena |= e.weapons;
 967                                         weapon_action(e.weapon, WR_PRECACHE);
 968                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 969                                         break;
 970                                 }
 971                         }
 972                         if (j > WEP_LAST)
 973                         {
 974                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 975                         }
 976                 }
 977                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 978         }
 979
 980         if(g_weaponarena)
 981                 g_weaponarena_random = cvar("g_weaponarena_random");
 982         else
 983                 g_weaponarena_random = 0;
 984
 985         if (g_weaponarena)
 986         {
 987                 start_weapons = g_weaponarena;
 988                 if (g_weaponarena & (WEPBIT_GRENADE_LAUNCHER | WEPBIT_HAGAR | WEPBIT_ROCKET_LAUNCHER))
 989                         start_ammo_rockets = 999;
 990                 if (g_weaponarena & WEPBIT_SHOTGUN)
 991                         start_ammo_shells = 999;
 992                 if (g_weaponarena & (WEPBIT_ELECTRO | WEPBIT_CRYLINK | WEPBIT_NEX | WEPBIT_MINSTANEX | WEPBIT_HLAC | WEPBIT_HOOK))
 993                         start_ammo_cells = 999;
 994                 if (g_weaponarena & (WEPBIT_UZI | WEPBIT_CAMPINGRIFLE))
 995                         start_ammo_nails = 999;
 996                 if (g_weaponarena & WEPBIT_HOOK)
 997                         start_ammo_fuel = 999;
 998                 start_items |= IT_UNLIMITED_AMMO;
 999         }
1000         else if (g_minstagib)
1001         {
1002                 start_health = 100;
1003                 start_armorvalue = 0;
1004                 start_weapons = WEPBIT_MINSTANEX;
1005                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1006                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1007                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1008                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1009
1010                 if (g_minstagib_invis_alpha <= 0)
1011                         g_minstagib_invis_alpha = -1;
1012         }
1013         else
1014         {
1015                 if (g_lms || g_ca)
1016                 {
1017                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1018                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1019                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1020                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1021                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1022                         start_health = cvar("g_lms_start_health");
1023                         start_armorvalue = cvar("g_lms_start_armor");
1024                 }
1025                 else
1026                 {
1027                         start_ammo_shells = cvar("g_start_ammo_shells");
1028                         start_ammo_nails = cvar("g_start_ammo_nails");
1029                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1030                         start_ammo_cells = cvar("g_start_ammo_cells");
1031                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1032                 }
1033
1034                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1035                 {
1036                         e = get_weaponinfo(i);
1037                         if(want_weapon("g_start_weapon_", e, FALSE))
1038                                 start_weapons |= e.weapons;
1039                 }
1040         }
1041
1042         if (inWarmupStage)
1043         {
1044                 warmup_start_ammo_shells = start_ammo_shells;
1045                 warmup_start_ammo_nails = start_ammo_nails;
1046                 warmup_start_ammo_rockets = start_ammo_rockets;
1047                 warmup_start_ammo_cells = start_ammo_cells;
1048                 warmup_start_ammo_fuel = start_ammo_fuel;
1049                 warmup_start_health = start_health;
1050                 warmup_start_armorvalue = start_armorvalue;
1051                 warmup_start_weapons = start_weapons;
1052
1053                 if (!g_weaponarena && !g_minstagib && !g_ca)
1054                 {
1055                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1056                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1057                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1058                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1059                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1060                         warmup_start_health = cvar("g_warmup_start_health");
1061                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1062                         warmup_start_weapons = 0;
1063                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1064                         {
1065                                 e = get_weaponinfo(i);
1066                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1067                                         warmup_start_weapons |= e.weapons;
1068                         }
1069                 }
1070         }
1071
1072         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1073         {
1074                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1075                 start_items |= IT_FUEL_REGEN;
1076                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1077                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1078         }
1079
1080         if(!cvar("g_use_ammunition"))
1081         {
1082                 start_ammo_shells = cvar("g_pickup_shells_max");
1083                 start_ammo_nails = cvar("g_pickup_nails_max");
1084                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1085                 start_ammo_cells = cvar("g_pickup_cells_max");
1086                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1087                 start_items |= IT_UNLIMITED_AMMO;
1088                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1089                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1090                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1091                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1092                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1093                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1094         }
1095
1096         if (g_jetpack)
1097                 start_items |= IT_JETPACK;
1098
1099         if (g_weapon_stay == 2)
1100         {
1101                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1102                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1103                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1104                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1105                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1106                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1107                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1108                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1109                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1110                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1111         }
1112
1113         MUTATOR_CALLHOOK(SetStartItems);
1114
1115         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1116         {
1117                 e = get_weaponinfo(i);
1118                 if(e.weapons & (start_weapons | warmup_start_weapons))
1119                         weapon_action(e.weapon, WR_PRECACHE);
1120         }
1121
1122         start_ammo_shells = max(0, start_ammo_shells);
1123         start_ammo_nails = max(0, start_ammo_nails);
1124         start_ammo_cells = max(0, start_ammo_cells);
1125         start_ammo_rockets = max(0, start_ammo_rockets);
1126         start_ammo_fuel = max(0, start_ammo_fuel);
1127
1128         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1129         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1130         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1131         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1132         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1133 }
1134
1135 float g_bugrigs;
1136 float g_bugrigs_planar_movement;
1137 float g_bugrigs_planar_movement_car_jumping;
1138 float g_bugrigs_reverse_spinning;
1139 float g_bugrigs_reverse_speeding;
1140 float g_bugrigs_reverse_stopping;
1141 float g_bugrigs_air_steering;
1142 float g_bugrigs_angle_smoothing;
1143 float g_bugrigs_friction_floor;
1144 float g_bugrigs_friction_brake;
1145 float g_bugrigs_friction_air;
1146 float g_bugrigs_accel;
1147 float g_bugrigs_speed_ref;
1148 float g_bugrigs_speed_pow;
1149 float g_bugrigs_steer;
1150
1151 float g_touchexplode;
1152 float g_touchexplode_radius;
1153 float g_touchexplode_damage;
1154 float g_touchexplode_edgedamage;
1155 float g_touchexplode_force;
1156
1157 float sv_autotaunt;
1158 float sv_taunt;
1159
1160 float sv_pitch_min;
1161 float sv_pitch_max;
1162 float sv_pitch_fixyaw;
1163
1164 float sv_accuracy_data_share;
1165
1166 void readlevelcvars(void)
1167 {
1168         // first load all the mutators
1169         if(cvar("g_nix"))
1170                 MUTATOR_ADD(mutator_nix);
1171
1172     g_bugrigs = cvar("g_bugrigs");
1173     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1174     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1175     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1176     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1177     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1178     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1179     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1180     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1181     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1182     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1183     g_bugrigs_accel = cvar("g_bugrigs_accel");
1184     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1185     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1186     g_bugrigs_steer = cvar("g_bugrigs_steer");
1187
1188     g_touchexplode = cvar("g_touchexplode");
1189     g_touchexplode_radius = cvar("g_touchexplode_radius");
1190     g_touchexplode_damage = cvar("g_touchexplode_damage");
1191     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1192     g_touchexplode_force = cvar("g_touchexplode_force");
1193
1194 #ifdef ALLOW_FORCEMODELS
1195         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1196 #endif
1197         sv_loddistance1 = cvar("sv_loddistance1");
1198         sv_loddistance2 = cvar("sv_loddistance2");
1199
1200         if(sv_loddistance2 <= sv_loddistance1)
1201                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1202
1203         sv_clones = cvar("sv_clones");
1204         sv_gentle = cvar("sv_gentle");
1205         sv_foginterval = cvar("sv_foginterval");
1206         g_cloaked = cvar("g_cloaked");
1207         g_jump_grunt = cvar("g_jump_grunt");
1208         g_footsteps = cvar("g_footsteps");
1209         g_grappling_hook = cvar("g_grappling_hook");
1210         g_jetpack = cvar("g_jetpack");
1211         g_laserguided_missile = cvar("g_laserguided_missile");
1212         g_midair = cvar("g_midair");
1213         g_minstagib = cvar("g_minstagib");
1214         g_norecoil = cvar("g_norecoil");
1215         g_vampire = cvar("g_vampire");
1216         g_bloodloss = cvar("g_bloodloss");
1217         sv_maxidle = cvar("sv_maxidle");
1218         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1219         sv_pogostick = cvar("sv_pogostick");
1220         sv_doublejump = cvar("sv_doublejump");
1221         g_ctf_reverse = cvar("g_ctf_reverse");
1222         sv_autotaunt = cvar("sv_autotaunt");
1223         sv_taunt = cvar("sv_taunt");
1224
1225         inWarmupStage = cvar("g_warmup");
1226         g_warmup_limit = cvar("g_warmup_limit");
1227         g_warmup_allguns = cvar("g_warmup_allguns");
1228         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1229
1230         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1231                 inWarmupStage = 0; // these modes cannot work together, sorry
1232
1233         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1234         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1235         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1236         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1237         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1238         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1239         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1240         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1241         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1242         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1243         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1244         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1245
1246         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1247         g_weaponratefactor = cvar("g_weaponratefactor");
1248         g_weapondamagefactor = cvar("g_weapondamagefactor");
1249         g_weaponforcefactor = cvar("g_weaponforcefactor");
1250         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1251
1252         g_pickup_shells = cvar("g_pickup_shells");
1253         g_pickup_shells_max = cvar("g_pickup_shells_max");
1254         g_pickup_nails = cvar("g_pickup_nails");
1255         g_pickup_nails_max = cvar("g_pickup_nails_max");
1256         g_pickup_rockets = cvar("g_pickup_rockets");
1257         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1258         g_pickup_cells = cvar("g_pickup_cells");
1259         g_pickup_cells_max = cvar("g_pickup_cells_max");
1260         g_pickup_fuel = cvar("g_pickup_fuel");
1261         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1262         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1263         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1264         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1265         g_pickup_armormedium = cvar("g_pickup_armormedium");
1266         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1267         g_pickup_armorbig = cvar("g_pickup_armorbig");
1268         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1269         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1270         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1271         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1272         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1273         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1274         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1275         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1276         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1277         g_pickup_healthmega = cvar("g_pickup_healthmega");
1278         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1279
1280         g_pinata = cvar("g_pinata");
1281
1282         g_weapon_stay = cvar("g_weapon_stay");
1283
1284         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1285                 g_weapon_stay = 1;
1286
1287         g_ghost_items = cvar("g_ghost_items");
1288
1289         if(g_ghost_items >= 1)
1290                 g_ghost_items = 0.25; // default alpha value
1291
1292         if not(inWarmupStage && !g_ca)
1293                 game_starttime = cvar("g_start_delay");
1294
1295         sv_pitch_min = cvar("sv_pitch_min");
1296         sv_pitch_max = cvar("sv_pitch_max");
1297         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1298
1299         sv_accuracy_data_share = boolean(cvar("sv_accuracy_data_share"));
1300
1301         readplayerstartcvars();
1302 }
1303
1304 /*
1305 // TODO sound pack system
1306 string soundpack;
1307
1308 string precache_sound_builtin (string s) = #19;
1309 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1310 string precache_sound(string s)
1311 {
1312         return precache_sound_builtin(strcat(soundpack, s));
1313 }
1314 void play2(entity e, string filename)
1315 {
1316         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1317 }
1318 void sound(entity e, float chan, string samp, float vol, float atten)
1319 {
1320         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1321 }
1322 */
1323
1324 // Sound functions
1325 string precache_sound (string s) = #19;
1326 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1327 float precache_sound_index (string s) = #19;
1328
1329 #define SND_VOLUME      1
1330 #define SND_ATTENUATION 2
1331 #define SND_LARGEENTITY 8
1332 #define SND_LARGESOUND  16
1333
1334 float sound_allowed(float dest, entity e)
1335 {
1336     // sounds from world may always pass
1337     for (;;)
1338     {
1339         if (e.classname == "body")
1340             e = e.enemy;
1341         if (e.owner && e.owner != e)
1342             e = e.owner;
1343         else
1344             break;
1345     }
1346     // sounds to self may always pass
1347     if (dest == MSG_ONE)
1348         if (e == msg_entity)
1349             return TRUE;
1350     // sounds by players can be removed
1351     if (cvar("bot_sound_monopoly"))
1352         if (clienttype(e) == CLIENTTYPE_REAL)
1353             return FALSE;
1354     // anything else may pass
1355     return TRUE;
1356 }
1357
1358 void sound(entity e, float chan, string samp, float vol, float atten)
1359 {
1360     if (!sound_allowed(MSG_BROADCAST, e))
1361         return;
1362     sound_builtin(e, chan, samp, vol, atten);
1363 }
1364 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1365 {
1366     float entno, idx;
1367
1368     if (!sound_allowed(dest, e))
1369         return;
1370
1371     entno = num_for_edict(e);
1372     idx = precache_sound_index(samp);
1373
1374     float sflags;
1375     sflags = 0;
1376
1377     atten = floor(atten * 64);
1378     vol = floor(vol * 255);
1379
1380     if (vol != 255)
1381         sflags |= SND_VOLUME;
1382     if (atten != 64)
1383         sflags |= SND_ATTENUATION;
1384     if (entno >= 8192)
1385         sflags |= SND_LARGEENTITY;
1386     if (idx >= 256)
1387         sflags |= SND_LARGESOUND;
1388
1389     WriteByte(dest, SVC_SOUND);
1390     WriteByte(dest, sflags);
1391     if (sflags & SND_VOLUME)
1392         WriteByte(dest, vol);
1393     if (sflags & SND_ATTENUATION)
1394         WriteByte(dest, atten);
1395     if (sflags & SND_LARGEENTITY)
1396     {
1397         WriteShort(dest, entno);
1398         WriteByte(dest, chan);
1399     }
1400     else
1401     {
1402         WriteShort(dest, entno * 8 + chan);
1403     }
1404     if (sflags & SND_LARGESOUND)
1405         WriteShort(dest, idx);
1406     else
1407         WriteByte(dest, idx);
1408
1409     WriteCoord(dest, o_x);
1410     WriteCoord(dest, o_y);
1411     WriteCoord(dest, o_z);
1412 }
1413 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1414 {
1415     vector o;
1416
1417     if (!sound_allowed(dest, e))
1418         return;
1419
1420     o = e.origin + 0.5 * (e.mins + e.maxs);
1421     soundtoat(dest, e, o, chan, samp, vol, atten);
1422 }
1423 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1424 {
1425     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1426 }
1427 void stopsoundto(float dest, entity e, float chan)
1428 {
1429     float entno;
1430
1431     if (!sound_allowed(dest, e))
1432         return;
1433
1434     entno = num_for_edict(e);
1435
1436     if (entno >= 8192)
1437     {
1438         float idx, sflags;
1439         idx = precache_sound_index("misc/null.wav");
1440         sflags = SND_LARGEENTITY;
1441         if (idx >= 256)
1442             sflags |= SND_LARGESOUND;
1443         WriteByte(dest, SVC_SOUND);
1444         WriteByte(dest, sflags);
1445         WriteShort(dest, entno);
1446         WriteByte(dest, chan);
1447         if (sflags & SND_LARGESOUND)
1448             WriteShort(dest, idx);
1449         else
1450             WriteByte(dest, idx);
1451         WriteCoord(dest, e.origin_x);
1452         WriteCoord(dest, e.origin_y);
1453         WriteCoord(dest, e.origin_z);
1454     }
1455     else
1456     {
1457         WriteByte(dest, SVC_STOPSOUND);
1458         WriteShort(dest, entno * 8 + chan);
1459     }
1460 }
1461 void stopsound(entity e, float chan)
1462 {
1463     if (!sound_allowed(MSG_BROADCAST, e))
1464         return;
1465
1466     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1467     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1468 }
1469
1470 void play2(entity e, string filename)
1471 {
1472     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1473     msg_entity = e;
1474     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1475 }
1476
1477 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1478 .float spamtime;
1479 float spamsound(entity e, float chan, string samp, float vol, float atten)
1480 {
1481     if (!sound_allowed(MSG_BROADCAST, e))
1482         return FALSE;
1483
1484     if (time > e.spamtime)
1485     {
1486         e.spamtime = time;
1487         sound(e, chan, samp, vol, atten);
1488         return TRUE;
1489     }
1490     return FALSE;
1491 }
1492
1493 void play2team(float t, string filename)
1494 {
1495     local entity head;
1496
1497     if (cvar("bot_sound_monopoly"))
1498         return;
1499
1500     FOR_EACH_REALPLAYER(head)
1501     {
1502         if (head.team == t)
1503             play2(head, filename);
1504     }
1505 }
1506
1507 void play2all(string samp)
1508 {
1509     if (cvar("bot_sound_monopoly"))
1510         return;
1511
1512     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1513 }
1514
1515 void PrecachePlayerSounds(string f);
1516 void precache_playermodel(string m)
1517 {
1518         float globhandle, i, n;
1519         string f;
1520
1521         if(substring(m, -9,5) == "_lod1")
1522                 return;
1523         if(substring(m, -9,5) == "_lod2")
1524                 return;
1525         precache_model(m);
1526         if(sv_loddistance1)
1527         {
1528                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1529                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1530         }
1531
1532         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1533         if (globhandle < 0)
1534                 return;
1535         n = search_getsize(globhandle);
1536         for (i = 0; i < n; ++i)
1537         {
1538                 //print(search_getfilename(globhandle, i), "\n");
1539                 f = search_getfilename(globhandle, i);
1540                 PrecachePlayerSounds(f);
1541         }
1542         search_end(globhandle);
1543 }
1544 void precache_all_playermodels(string pattern)
1545 {
1546         float globhandle, i, n;
1547         string f;
1548
1549         globhandle = search_begin(pattern, TRUE, FALSE);
1550         if (globhandle < 0)
1551                 return;
1552         n = search_getsize(globhandle);
1553         for (i = 0; i < n; ++i)
1554         {
1555                 //print(search_getfilename(globhandle, i), "\n");
1556                 f = search_getfilename(globhandle, i);
1557                 precache_playermodel(f);
1558         }
1559         search_end(globhandle);
1560 }
1561
1562 void precache()
1563 {
1564     // gamemode related things
1565     precache_model ("models/misc/chatbubble.spr");
1566     precache_model ("models/misc/teambubble.spr");
1567     if (g_runematch)
1568     {
1569         precache_model ("models/runematch/curse.mdl");
1570         precache_model ("models/runematch/rune.mdl");
1571     }
1572
1573 #ifdef TTURRETS_ENABLED
1574     if (cvar("g_turrets"))
1575         turrets_precash();
1576 #endif
1577
1578     // Precache all player models if desired
1579     if (cvar("sv_precacheplayermodels"))
1580     {
1581         PrecachePlayerSounds("sound/player/default.sounds");
1582         precache_all_playermodels("models/player/*.zym");
1583         precache_all_playermodels("models/player/*.dpm");
1584         precache_all_playermodels("models/player/*.md3");
1585         precache_all_playermodels("models/player/*.psk");
1586     }
1587
1588     if (cvar("sv_defaultcharacter"))
1589     {
1590         string s;
1591         s = cvar_string("sv_defaultplayermodel_red");
1592         if (s != "")
1593             precache_playermodel(s);
1594         s = cvar_string("sv_defaultplayermodel_blue");
1595         if (s != "")
1596             precache_playermodel(s);
1597         s = cvar_string("sv_defaultplayermodel_yellow");
1598         if (s != "")
1599             precache_playermodel(s);
1600         s = cvar_string("sv_defaultplayermodel_pink");
1601         if (s != "")
1602             precache_playermodel(s);
1603         s = cvar_string("sv_defaultplayermodel");
1604         if (s != "")
1605             precache_playermodel(s);
1606     }
1607
1608     if (g_footsteps)
1609     {
1610         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1611         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1612     }
1613
1614     // gore and miscellaneous sounds
1615     //precache_sound ("misc/h2ohit.wav");
1616     precache_model ("models/hook.md3");
1617     precache_sound ("misc/armorimpact.wav");
1618     precache_sound ("misc/bodyimpact1.wav");
1619     precache_sound ("misc/bodyimpact2.wav");
1620     precache_sound ("misc/gib.wav");
1621     precache_sound ("misc/gib_splat01.wav");
1622     precache_sound ("misc/gib_splat02.wav");
1623     precache_sound ("misc/gib_splat03.wav");
1624     precache_sound ("misc/gib_splat04.wav");
1625     precache_sound ("misc/hit.wav");
1626         precache_sound ("misc/typehit.wav");
1627     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1628     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1629     precache_sound ("misc/null.wav");
1630     precache_sound ("misc/spawn.wav");
1631     precache_sound ("misc/talk.wav");
1632     precache_sound ("misc/teleport.wav");
1633     precache_sound ("misc/poweroff.wav");
1634     precache_sound ("player/lava.wav");
1635     precache_sound ("player/slime.wav");
1636
1637     if (g_jetpack)
1638         precache_sound ("misc/jetpack_fly.wav");
1639
1640     precache_model ("models/sprites/0.spr32");
1641     precache_model ("models/sprites/1.spr32");
1642     precache_model ("models/sprites/2.spr32");
1643     precache_model ("models/sprites/3.spr32");
1644     precache_model ("models/sprites/4.spr32");
1645     precache_model ("models/sprites/5.spr32");
1646     precache_model ("models/sprites/6.spr32");
1647     precache_model ("models/sprites/7.spr32");
1648     precache_model ("models/sprites/8.spr32");
1649     precache_model ("models/sprites/9.spr32");
1650     precache_model ("models/sprites/10.spr32");
1651
1652     // common weapon precaches
1653     precache_sound ("weapons/weapon_switch.wav");
1654     precache_sound ("weapons/weaponpickup.wav");
1655     precache_sound ("weapons/unavailable.wav");
1656     if (g_grappling_hook)
1657     {
1658         precache_sound ("weapons/hook_fire.wav"); // hook
1659         precache_sound ("weapons/hook_impact.wav"); // hook
1660     }
1661
1662     if(cvar("sv_precacheweapons"))
1663     {
1664         //precache weapon models/sounds
1665         local float wep;
1666         wep = WEP_FIRST;
1667         while (wep <= WEP_LAST)
1668         {
1669             weapon_action(wep, WR_PRECACHE);
1670             wep = wep + 1;
1671         }
1672     }
1673
1674     precache_model("models/elaser.mdl");
1675     precache_model("models/laser.mdl");
1676     precache_model("models/ebomb.mdl");
1677
1678 #if 0
1679     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1680
1681     if (!self.noise && self.music) // quake 3 uses the music field
1682         self.noise = self.music;
1683
1684     // plays music for the level if there is any
1685     if (self.noise)
1686     {
1687         precache_sound (self.noise);
1688         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1689     }
1690 #endif
1691 }
1692
1693 // sorry, but using \ in macros breaks line numbers
1694 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1695 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1696 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1697
1698 // WARNING: this kills the trace globals
1699 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1700 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1701
1702 #define INITPRIO_FIRST              0
1703 #define INITPRIO_GAMETYPE           0
1704 #define INITPRIO_GAMETYPE_FALLBACK  1
1705 #define INITPRIO_CVARS              5
1706 #define INITPRIO_FINDTARGET        10
1707 #define INITPRIO_DROPTOFLOOR       20
1708 #define INITPRIO_SETLOCATION       90
1709 #define INITPRIO_LINKDOORS         91
1710 #define INITPRIO_LAST              99
1711
1712 .void(void) initialize_entity;
1713 .float initialize_entity_order;
1714 .entity initialize_entity_next;
1715 entity initialize_entity_first;
1716
1717 void make_safe_for_remove(entity e)
1718 {
1719     if (e.initialize_entity)
1720     {
1721         entity ent, prev;
1722         for (ent = initialize_entity_first; ent; )
1723         {
1724             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1725             {
1726                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1727                 // skip it in linked list
1728                 if (prev)
1729                 {
1730                     prev.initialize_entity_next = ent.initialize_entity_next;
1731                     ent = prev.initialize_entity_next;
1732                 }
1733                 else
1734                 {
1735                     initialize_entity_first = ent.initialize_entity_next;
1736                     ent = initialize_entity_first;
1737                 }
1738             }
1739             else
1740             {
1741                 prev = ent;
1742                 ent = ent.initialize_entity_next;
1743             }
1744         }
1745     }
1746 }
1747
1748 void objerror(string s)
1749 {
1750     make_safe_for_remove(self);
1751     objerror_builtin(s);
1752 }
1753
1754 void remove_unsafely(entity e)
1755 {
1756     remove_builtin(e);
1757 }
1758
1759 void remove_safely(entity e)
1760 {
1761     make_safe_for_remove(e);
1762     remove_builtin(e);
1763 }
1764
1765 void InitializeEntity(entity e, void(void) func, float order)
1766 {
1767     entity prev, cur;
1768
1769     if (!e || e.initialize_entity)
1770     {
1771         // make a proxy initializer entity
1772         entity e_old;
1773         e_old = e;
1774         e = spawn();
1775         e.classname = "initialize_entity";
1776         e.enemy = e_old;
1777     }
1778
1779     e.initialize_entity = func;
1780     e.initialize_entity_order = order;
1781
1782     cur = initialize_entity_first;
1783     for (;;)
1784     {
1785         if (!cur || cur.initialize_entity_order > order)
1786         {
1787             // insert between prev and cur
1788             if (prev)
1789                 prev.initialize_entity_next = e;
1790             else
1791                 initialize_entity_first = e;
1792             e.initialize_entity_next = cur;
1793             return;
1794         }
1795         prev = cur;
1796         cur = cur.initialize_entity_next;
1797     }
1798 }
1799 void InitializeEntitiesRun()
1800 {
1801     entity startoflist;
1802     startoflist = initialize_entity_first;
1803     initialize_entity_first = world;
1804     for (self = startoflist; self; )
1805     {
1806         entity e;
1807         var void(void) func;
1808         e = self.initialize_entity_next;
1809         func = self.initialize_entity;
1810         self.initialize_entity_order = 0;
1811         self.initialize_entity = func_null;
1812         self.initialize_entity_next = world;
1813         if (self.classname == "initialize_entity")
1814         {
1815             entity e_old;
1816             e_old = self.enemy;
1817             remove_builtin(self);
1818             self = e_old;
1819         }
1820         //dprint("Delayed initialization: ", self.classname, "\n");
1821         func();
1822         self = e;
1823     }
1824 }
1825
1826 .float uncustomizeentityforclient_set;
1827 .void(void) uncustomizeentityforclient;
1828 void(void) SUB_Nullpointer = #0;
1829 void UncustomizeEntitiesRun()
1830 {
1831     entity oldself;
1832     oldself = self;
1833     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1834         self.uncustomizeentityforclient();
1835     self = oldself;
1836 }
1837 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1838 {
1839     e.customizeentityforclient = customizer;
1840     e.uncustomizeentityforclient = uncustomizer;
1841     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1842 }
1843
1844 .float nottargeted;
1845 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1846
1847 void() SUB_Remove;
1848 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1849 {
1850     vector mi, ma;
1851
1852     if (e.classname == "")
1853         e.classname = "net_linked";
1854
1855     if (e.model == "" || self.modelindex == 0)
1856     {
1857         mi = e.mins;
1858         ma = e.maxs;
1859         setmodel(e, "null");
1860         setsize(e, mi, ma);
1861     }
1862
1863     e.SendEntity = sendfunc;
1864     e.SendFlags = 0xFFFFFF;
1865
1866     if (!docull)
1867         e.effects |= EF_NODEPTHTEST;
1868
1869     if (dt)
1870     {
1871         e.nextthink = time + dt;
1872         e.think = SUB_Remove;
1873     }
1874 }
1875
1876 void adaptor_think2touch()
1877 {
1878     entity o;
1879     o = other;
1880     other = world;
1881     self.touch();
1882     other = o;
1883 }
1884
1885 void adaptor_think2use()
1886 {
1887     entity o, a;
1888     o = other;
1889     a = activator;
1890     activator = world;
1891     other = world;
1892     self.use();
1893     other = o;
1894     activator = a;
1895 }
1896
1897 // deferred dropping
1898 void DropToFloor_Handler()
1899 {
1900     droptofloor_builtin();
1901     self.dropped_origin = self.origin;
1902 }
1903
1904 void droptofloor()
1905 {
1906     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1907 }
1908
1909
1910
1911 float trace_hits_box_a0, trace_hits_box_a1;
1912
1913 float trace_hits_box_1d(float end, float thmi, float thma)
1914 {
1915     if (end == 0)
1916     {
1917         // just check if x is in range
1918         if (0 < thmi)
1919             return FALSE;
1920         if (0 > thma)
1921             return FALSE;
1922     }
1923     else
1924     {
1925         // do the trace with respect to x
1926         // 0 -> end has to stay in thmi -> thma
1927         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1928         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1929         if (trace_hits_box_a0 > trace_hits_box_a1)
1930             return FALSE;
1931     }
1932     return TRUE;
1933 }
1934
1935 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1936 {
1937     end -= start;
1938     thmi -= start;
1939     thma -= start;
1940     // now it is a trace from 0 to end
1941
1942     trace_hits_box_a0 = 0;
1943     trace_hits_box_a1 = 1;
1944
1945     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1946         return FALSE;
1947     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1948         return FALSE;
1949     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1950         return FALSE;
1951
1952     return TRUE;
1953 }
1954
1955 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1956 {
1957     return trace_hits_box(start, end, thmi - ma, thma - mi);
1958 }
1959
1960 float SUB_NoImpactCheck()
1961 {
1962         // zero hitcontents = this is not the real impact, but either the
1963         // mirror-impact of something hitting the projectile instead of the
1964         // projectile hitting the something, or a touchareagrid one. Neither of
1965         // these stop the projectile from moving, so...
1966         if(trace_dphitcontents == 0)
1967         {
1968                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1969                 checkclient();
1970         }
1971     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1972         return 1;
1973     if (other == world && self.size != '0 0 0')
1974     {
1975         vector tic;
1976         tic = self.velocity * sys_frametime;
1977         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1978         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1979         if (trace_fraction >= 1)
1980         {
1981             dprint("Odd... did not hit...?\n");
1982         }
1983         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1984         {
1985             dprint("Detected and prevented the sky-grapple bug.\n");
1986             return 1;
1987         }
1988     }
1989
1990     return 0;
1991 }
1992
1993 #define SUB_OwnerCheck() (other && (other == self.owner))
1994
1995 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1996 {
1997         if(SUB_OwnerCheck())
1998                 return TRUE;
1999         if(SUB_NoImpactCheck())
2000         {
2001                 remove(self);
2002                 return TRUE;
2003         }
2004         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2005                 UpdateCSQCProjectileNextFrame(self);
2006         return FALSE;
2007 }
2008 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2009
2010 float MAX_IPBAN_URIS = 16;
2011
2012 float URI_GET_DISCARD   = 0;
2013 float URI_GET_IPBAN     = 1;
2014 float URI_GET_IPBAN_END = 16;
2015
2016 void URI_Get_Callback(float id, float status, string data)
2017 {
2018     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2019     dprint(data);
2020     dprint("\nEnd of data.\n");
2021
2022     if (id == URI_GET_DISCARD)
2023     {
2024         // discard
2025     }
2026     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2027     {
2028         // online ban list
2029         OnlineBanList_URI_Get_Callback(id, status, data);
2030     }
2031     else
2032     {
2033         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2034     }
2035 }
2036
2037 void print_to(entity e, string s)
2038 {
2039     if (e)
2040         sprint(e, strcat(s, "\n"));
2041     else
2042         print(s, "\n");
2043 }
2044
2045 string getrecords(float page) // 50 records per page
2046 {
2047     float rec;
2048     string h;
2049     float r;
2050     float i;
2051     string s;
2052
2053     rec = 0;
2054
2055     s = "";
2056
2057     if (g_ctf)
2058     {
2059         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2060         {
2061             if (MapInfo_Get_ByID(i))
2062             {
2063                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2064                 if (r == 0)
2065                     continue;
2066                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2067                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2068                 ++rec;
2069             }
2070         }
2071     }
2072
2073     if (g_race)
2074     {
2075         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2076         {
2077             if (MapInfo_Get_ByID(i))
2078             {
2079                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time")));
2080                 if (r == 0)
2081                     continue;
2082                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "netname"));
2083                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2084                 ++rec;
2085             }
2086         }
2087     }
2088
2089     if (g_cts)
2090     {
2091         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2092         {
2093             if (MapInfo_Get_ByID(i))
2094             {
2095                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time")));
2096                 if (r == 0)
2097                     continue;
2098                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "netname"));
2099                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2100                 ++rec;
2101             }
2102         }
2103     }
2104
2105     MapInfo_ClearTemps();
2106
2107     if (s == "" && page == 0)
2108         return "No records are available on this server.\n";
2109     else
2110         return s;
2111 }
2112
2113 string getrankings()
2114 {
2115     string n;
2116     float t;
2117     float i;
2118     string s;
2119     string p;
2120     string map;
2121
2122     s = "";
2123
2124     map = GetMapname();
2125
2126     for (i = 1; i <= RANKINGS_CNT; ++i)
2127     {
2128         t = race_GetTime(i);
2129         if (t == 0)
2130             continue;
2131         n = race_GetName(i);
2132         p = race_PlaceName(i);
2133         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2134     }
2135
2136     MapInfo_ClearTemps();
2137
2138     if (s == "")
2139         return strcat("No records are available for the map: ", map, "\n");
2140     else
2141         return strcat("Records for ", map, ":\n", s);
2142 }
2143
2144 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2145 {
2146     float m, i;
2147     vector start, org, delta, end, enddown, mstart;
2148
2149     m = e.dphitcontentsmask;
2150     e.dphitcontentsmask = goodcontents | badcontents;
2151
2152     org = world.mins;
2153     delta = world.maxs - world.mins;
2154
2155     for (i = 0; i < attempts; ++i)
2156     {
2157         start_x = org_x + random() * delta_x;
2158         start_y = org_y + random() * delta_y;
2159         start_z = org_z + random() * delta_z;
2160
2161         // rule 1: start inside world bounds, and outside
2162         // solid, and don't start from somewhere where you can
2163         // fall down to evil
2164         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2165         if (trace_fraction >= 1)
2166             continue;
2167         if (trace_startsolid)
2168             continue;
2169         if (trace_dphitcontents & badcontents)
2170             continue;
2171         if (trace_dphitq3surfaceflags & badsurfaceflags)
2172             continue;
2173
2174         // rule 2: if we are too high, lower the point
2175         if (trace_fraction * delta_z > maxaboveground)
2176             start = trace_endpos + '0 0 1' * maxaboveground;
2177         enddown = trace_endpos;
2178
2179         // rule 3: make sure we aren't outside the map. This only works
2180         // for somewhat well formed maps. A good rule of thumb is that
2181         // the map should have a convex outside hull.
2182         // these can be traceLINES as we already verified the starting box
2183         mstart = start + 0.5 * (e.mins + e.maxs);
2184         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2185         if (trace_fraction >= 1)
2186             continue;
2187         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2188         if (trace_fraction >= 1)
2189             continue;
2190         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2191         if (trace_fraction >= 1)
2192             continue;
2193         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2194         if (trace_fraction >= 1)
2195             continue;
2196         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2197         if (trace_fraction >= 1)
2198             continue;
2199
2200         // find a random vector to "look at"
2201         end_x = org_x + random() * delta_x;
2202         end_y = org_y + random() * delta_y;
2203         end_z = org_z + random() * delta_z;
2204         end = start + normalize(end - start) * vlen(delta);
2205
2206         // rule 4: start TO end must not be too short
2207         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2208         if (trace_startsolid)
2209             continue;
2210         if (trace_fraction < minviewdistance / vlen(delta))
2211             continue;
2212
2213         // rule 5: don't want to look at sky
2214         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2215             continue;
2216
2217         // rule 6: we must not end up in trigger_hurt
2218         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2219         {
2220             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2221             continue;
2222         }
2223
2224         break;
2225     }
2226
2227     e.dphitcontentsmask = m;
2228
2229     if (i < attempts)
2230     {
2231         setorigin(e, start);
2232         e.angles = vectoangles(end - start);
2233         dprint("Needed ", ftos(i + 1), " attempts\n");
2234         return TRUE;
2235     }
2236     else
2237         return FALSE;
2238 }
2239
2240 float zcurveparticles_effectno;
2241 vector zcurveparticles_start;
2242 float zcurveparticles_spd;
2243
2244 void endzcurveparticles()
2245 {
2246         if(zcurveparticles_effectno)
2247         {
2248                 // terminator
2249                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2250         }
2251         zcurveparticles_effectno = 0;
2252 }
2253
2254 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2255 {
2256         spd = bound(0, floor(spd / 16), 32767);
2257         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2258         {
2259                 endzcurveparticles();
2260                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2261                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2262                 WriteShort(MSG_BROADCAST, effectno);
2263                 WriteCoord(MSG_BROADCAST, start_x);
2264                 WriteCoord(MSG_BROADCAST, start_y);
2265                 WriteCoord(MSG_BROADCAST, start_z);
2266                 zcurveparticles_effectno = effectno;
2267                 zcurveparticles_start = start;
2268         }
2269         else
2270                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2271         WriteCoord(MSG_BROADCAST, end_x);
2272         WriteCoord(MSG_BROADCAST, end_y);
2273         WriteCoord(MSG_BROADCAST, end_z);
2274         WriteCoord(MSG_BROADCAST, end_dz);
2275         zcurveparticles_spd = spd;
2276 }
2277
2278 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2279 {
2280         float end_dz;
2281         vector vecxy, velxy;
2282
2283         vecxy = end - start;
2284         vecxy_z = 0;
2285         velxy = vel;
2286         velxy_z = 0;
2287
2288         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2289         {
2290                 endzcurveparticles();
2291                 trailparticles(world, effectno, start, end);
2292                 return;
2293         }
2294
2295         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2296         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2297 }
2298
2299 string GetGametype(); // g_world.qc
2300 void write_recordmarker(entity pl, float tstart, float dt)
2301 {
2302     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2303
2304     // also write a marker into demo files for demotc-race-record-extractor to find
2305     stuffcmd(pl,
2306              strcat(
2307                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2308                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2309 }
2310
2311 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter)
2312 {
2313         switch(self.owner.cvar_cl_gunalign)
2314         {
2315                 case 1: // right
2316                         break;
2317
2318                 case 2: // left
2319                         vecs_y = -vecs_y;
2320                         break;
2321
2322                 default:
2323                 case 3:
2324                         if(allowcenter) // 2: allow center handedness
2325                         {
2326                                 // center
2327                                 vecs_y = 0;
2328                                 vecs_z -= 4;
2329                         }
2330                         else
2331                         {
2332                                 // right
2333                         }
2334                         break;
2335
2336                 case 4:
2337                         if(allowcenter) // 2: allow center handedness
2338                         {
2339                                 // center
2340                                 vecs_y = 0;
2341                                 vecs_z -= 4;
2342                         }
2343                         else
2344                         {
2345                                 // left
2346                                 vecs_y = -vecs_y;
2347                         }
2348                         break;
2349         }
2350         return vecs;
2351 }
2352
2353 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2354 {
2355         string s;
2356         vector v;
2357
2358         if (cvar("g_shootfromeye"))
2359         {
2360                 if (visual)
2361                 {
2362                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE);
2363                 }
2364                 else
2365                 {
2366                         vecs_y = 0;
2367                         vecs_z = 0;
2368                 }
2369         }
2370         else if (cvar("g_shootfromcenter"))
2371         {
2372                 if (visual)
2373                 {
2374                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE);
2375                 }
2376                 else
2377                 {
2378                         vecs_y = 0;
2379                         vecs_z -= 4;
2380                 }
2381         }
2382         else if ((s = cvar_string("g_shootfromfixedorigin")) != "")
2383         {
2384                 v = stov(s);
2385                 if (y_is_right)
2386                         v_y = -v_y;
2387                 if (v_x != 0)
2388                         vecs_x = v_x;
2389                 vecs_y = v_y;
2390                 vecs_z = v_z;
2391         }
2392         else if (cvar("g_shootfromclient"))
2393         {
2394                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (cvar("g_shootfromclient") >= 2));
2395         }
2396         return vecs;
2397 }
2398
2399
2400
2401 void attach_sameorigin(entity e, entity to, string tag)
2402 {
2403     vector org, t_forward, t_left, t_up, e_forward, e_up;
2404     vector org0, ang0;
2405     float tagscale;
2406
2407     ang0 = e.angles;
2408     org0 = e.origin;
2409
2410     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2411     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2412     t_forward = v_forward * tagscale;
2413     t_left = v_right * -tagscale;
2414     t_up = v_up * tagscale;
2415
2416     e.origin_x = org * t_forward;
2417     e.origin_y = org * t_left;
2418     e.origin_z = org * t_up;
2419
2420     // current forward and up directions
2421     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2422                 e.angles = AnglesTransform_FromVAngles(e.angles);
2423         else
2424                 e.angles = AnglesTransform_FromAngles(e.angles);
2425     fixedmakevectors(e.angles);
2426
2427     // untransform forward, up!
2428     e_forward_x = v_forward * t_forward;
2429     e_forward_y = v_forward * t_left;
2430     e_forward_z = v_forward * t_up;
2431     e_up_x = v_up * t_forward;
2432     e_up_y = v_up * t_left;
2433     e_up_z = v_up * t_up;
2434
2435     e.angles = fixedvectoangles2(e_forward, e_up);
2436     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2437                 e.angles = AnglesTransform_ToVAngles(e.angles);
2438         else
2439                 e.angles = AnglesTransform_ToAngles(e.angles);
2440
2441     setattachment(e, to, tag);
2442     setorigin(e, e.origin);
2443 }
2444
2445 void detach_sameorigin(entity e)
2446 {
2447     vector org;
2448     org = gettaginfo(e, 0);
2449     e.angles = fixedvectoangles2(v_forward, v_up);
2450     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2451                 e.angles = AnglesTransform_ToVAngles(e.angles);
2452         else
2453                 e.angles = AnglesTransform_ToAngles(e.angles);
2454     setorigin(e, org);
2455     setattachment(e, world, "");
2456     setorigin(e, e.origin);
2457 }
2458
2459 void follow_sameorigin(entity e, entity to)
2460 {
2461     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2462     e.aiment = to; // make the hole follow bmodel
2463     e.punchangle = to.angles; // the original angles of bmodel
2464     e.view_ofs = e.origin - to.origin; // relative origin
2465     e.v_angle = e.angles - to.angles; // relative angles
2466 }
2467
2468 void unfollow_sameorigin(entity e)
2469 {
2470     e.movetype = MOVETYPE_NONE;
2471 }
2472
2473 entity gettaginfo_relative_ent;
2474 vector gettaginfo_relative(entity e, float tag)
2475 {
2476     if (!gettaginfo_relative_ent)
2477     {
2478         gettaginfo_relative_ent = spawn();
2479         gettaginfo_relative_ent.effects = EF_NODRAW;
2480     }
2481     gettaginfo_relative_ent.model = e.model;
2482     gettaginfo_relative_ent.modelindex = e.modelindex;
2483     gettaginfo_relative_ent.frame = e.frame;
2484     return gettaginfo(gettaginfo_relative_ent, tag);
2485 }
2486
2487 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2488 {
2489     float p;
2490     p = pow(2, chan);
2491     if (pl.soundentity.cnt & p)
2492         return;
2493     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2494     pl.soundentity.cnt |= p;
2495 }
2496
2497 void SoundEntity_StopSound(entity pl, float chan)
2498 {
2499     float p;
2500     p = pow(2, chan);
2501     if (pl.soundentity.cnt & p)
2502     {
2503         stopsoundto(MSG_ALL, pl.soundentity, chan);
2504         pl.soundentity.cnt &~= p;
2505     }
2506 }
2507
2508 void SoundEntity_Attach(entity pl)
2509 {
2510     pl.soundentity = spawn();
2511     pl.soundentity.classname = "soundentity";
2512     pl.soundentity.owner = pl;
2513     setattachment(pl.soundentity, pl, "");
2514     setmodel(pl.soundentity, "null");
2515 }
2516
2517 void SoundEntity_Detach(entity pl)
2518 {
2519     float i;
2520     for (i = 0; i <= 7; ++i)
2521         SoundEntity_StopSound(pl, i);
2522 }
2523
2524
2525 float ParseCommandPlayerSlotTarget_firsttoken;
2526 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2527 {
2528     string s;
2529     entity e, head;
2530     float n;
2531
2532     s = string_null;
2533
2534     ParseCommandPlayerSlotTarget_firsttoken = -1;
2535
2536     if (tokens > idx)
2537     {
2538         if (substring(argv(idx), 0, 1) == "#")
2539         {
2540             s = substring(argv(idx), 1, -1);
2541             ++idx;
2542             if (s == "")
2543                 if (tokens > idx)
2544                 {
2545                     s = argv(idx);
2546                     ++idx;
2547                 }
2548                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2549             if (s == ftos(stof(s)))
2550             {
2551                 e = edict_num(stof(s));
2552                 if (e.flags & FL_CLIENT)
2553                     return e;
2554             }
2555         }
2556         else
2557         {
2558             // it must be a nick name
2559             s = argv(idx);
2560             ++idx;
2561                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2562
2563             n = 0;
2564             FOR_EACH_CLIENT(head)
2565             if (head.netname == s)
2566             {
2567                 e = head;
2568                 ++n;
2569             }
2570             if (n == 1)
2571                 return e;
2572
2573             s = strdecolorize(s);
2574             n = 0;
2575             FOR_EACH_CLIENT(head)
2576             if (strdecolorize(head.netname) == s)
2577             {
2578                 e = head;
2579                 ++n;
2580             }
2581             if (n == 1)
2582                 return e;
2583         }
2584     }
2585
2586     return world;
2587 }
2588
2589 .float scale2;
2590
2591 float modeleffect_SendEntity(entity to, float sf)
2592 {
2593         float f;
2594         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2595
2596         f = 0;
2597         if(self.velocity != '0 0 0')
2598                 f |= 1;
2599         if(self.angles != '0 0 0')
2600                 f |= 2;
2601         if(self.avelocity != '0 0 0')
2602                 f |= 4;
2603
2604         WriteByte(MSG_ENTITY, f);
2605         WriteShort(MSG_ENTITY, self.modelindex);
2606         WriteByte(MSG_ENTITY, self.skin);
2607         WriteByte(MSG_ENTITY, self.frame);
2608         WriteCoord(MSG_ENTITY, self.origin_x);
2609         WriteCoord(MSG_ENTITY, self.origin_y);
2610         WriteCoord(MSG_ENTITY, self.origin_z);
2611         if(f & 1)
2612         {
2613                 WriteCoord(MSG_ENTITY, self.velocity_x);
2614                 WriteCoord(MSG_ENTITY, self.velocity_y);
2615                 WriteCoord(MSG_ENTITY, self.velocity_z);
2616         }
2617         if(f & 2)
2618         {
2619                 WriteCoord(MSG_ENTITY, self.angles_x);
2620                 WriteCoord(MSG_ENTITY, self.angles_y);
2621                 WriteCoord(MSG_ENTITY, self.angles_z);
2622         }
2623         if(f & 4)
2624         {
2625                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2626                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2627                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2628         }
2629         WriteShort(MSG_ENTITY, self.scale * 256.0);
2630         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2631         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2632         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2633         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2634
2635         return TRUE;
2636 }
2637
2638 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2639 {
2640         entity e;
2641         float sz;
2642         e = spawn();
2643         e.classname = "modeleffect";
2644         setmodel(e, m);
2645         e.frame = f;
2646         setorigin(e, o);
2647         e.velocity = v;
2648         e.angles = ang;
2649         e.avelocity = angv;
2650         e.alpha = a;
2651         e.teleport_time = t1;
2652         e.fade_time = t2;
2653         e.skin = s;
2654         if(s0 >= 0)
2655                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2656         else
2657                 e.scale = -s0;
2658         if(s2 >= 0)
2659                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2660         else
2661                 e.scale2 = -s2;
2662         sz = max(e.scale, e.scale2);
2663         setsize(e, e.mins * sz, e.maxs * sz);
2664         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2665 }
2666
2667 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2668 {
2669         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2670 }
2671
2672 float randombit(float bits)
2673 {
2674         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2675                 return bits;
2676
2677         float n, f, b, r;
2678
2679         r = random();
2680         b = 0;
2681         n = 0;
2682
2683         for(f = 1; f <= bits; f *= 2)
2684         {
2685                 if(bits & f)
2686                 {
2687                         ++n;
2688                         r *= n;
2689                         if(r <= 1)
2690                                 b = f;
2691                         else
2692                                 r = (r - 1) / (n - 1);
2693                 }
2694         }
2695
2696         return b;
2697 }
2698
2699 float randombits(float bits, float k, float error_return)
2700 {
2701         float r;
2702         r = 0;
2703         while(k > 0 && bits != r)
2704         {
2705                 r += randombit(bits - r);
2706                 --k;
2707         }
2708         if(error_return)
2709                 if(k > 0)
2710                         return -1; // all
2711         return r;
2712 }
2713
2714 void randombit_test(float bits, float iter)
2715 {
2716         while(iter > 0)
2717         {
2718                 print(ftos(randombit(bits)), "\n");
2719                 --iter;
2720         }
2721 }
2722
2723 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2724 {
2725         if(halflifedist > 0)
2726                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2727         else if(halflifedist < 0)
2728                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2729         else
2730                 return 1;
2731 }
2732
2733
2734
2735
2736 #ifdef RELEASE
2737 #define cvar_string_normal cvar_string_builtin
2738 #define cvar_normal cvar_builtin
2739 #else
2740 string cvar_string_normal(string n)
2741 {
2742         if not(cvar_type(n) & 1)
2743                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2744         return cvar_string_builtin(n);
2745 }
2746
2747 float cvar_normal(string n)
2748 {
2749         return stof(cvar_string_normal(n));
2750 }
2751 #endif
2752 #define cvar_set_normal cvar_set_builtin
2753
2754 void defer_think()
2755 {
2756     entity oself;
2757
2758     oself           = self;
2759     self            = self.owner;
2760     oself.think     = SUB_Remove;
2761     oself.nextthink = time;
2762
2763     oself.use();
2764 }
2765
2766 /*
2767     Execute func() after time + fdelay.
2768     self when func is executed = self when defer is called
2769 */
2770 void defer(float fdelay, void() func)
2771 {
2772     entity e;
2773
2774     e           = spawn();
2775     e.owner     = self;
2776     e.use       = func;
2777     e.think     = defer_think;
2778     e.nextthink = time + fdelay;
2779 }