cb74c8d3a8a926148704766a302c6ab9004284b1
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / miscfunctions.qc
1 var void remove(entity e);
2 void objerror(string s);
3 void droptofloor();
4 .vector dropped_origin;
5
6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
7 void crosshair_trace(entity pl)
8 {
9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
10 }
11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
12 void WarpZone_crosshair_trace(entity pl)
13 {
14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
15 }
16
17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
18 void() spawnpoint_use;
19 string GetMapname();
20 string ColoredTeamName(float t);
21
22 string admin_name(void)
23 {
24         if(cvar_string("sv_adminnick") != "")
25                 return cvar_string("sv_adminnick");
26         else
27                 return "SERVER ADMIN";
28 }
29
30 float DistributeEvenly_amount;
31 float DistributeEvenly_totalweight;
32 void DistributeEvenly_Init(float amount, float totalweight)
33 {
34     if (DistributeEvenly_amount)
35     {
36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
38     }
39     if (totalweight == 0)
40         DistributeEvenly_amount = 0;
41     else
42         DistributeEvenly_amount = amount;
43     DistributeEvenly_totalweight = totalweight;
44 }
45 float DistributeEvenly_Get(float weight)
46 {
47     float f;
48     if (weight <= 0)
49         return 0;
50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
51     DistributeEvenly_totalweight -= weight;
52     DistributeEvenly_amount -= f;
53     return f;
54 }
55
56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
57
58
59 string STR_PLAYER = "player";
60 string STR_SPECTATOR = "spectator";
61 string STR_OBSERVER = "observer";
62
63 #if 0
64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
68 #else
69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
74 #endif
75
76 // copies a string to a tempstring (so one can strunzone it)
77 string strcat1(string s) = #115; // FRIK_FILE
78
79 float logfile_open;
80 float logfile;
81
82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
83 {
84         local float nPlayerHealth = rint(enPlayer.health);
85         local float nPlayerArmor = rint(enPlayer.armorvalue);
86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
87         local float nPlayerPing = rint(enPlayer.ping);
88         local string strPlayerPingColor;
89         local string strMessage;
90         if(nPlayerPing >= 150)
91                 strPlayerPingColor = "^1";
92         else
93                 strPlayerPingColor = "^2";
94
95         if((cvar("sv_fragmessage_information_stats")) && (enPlayer.health >= 1))
96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
97
98         if(cvar("sv_fragmessage_information_ping")) {
99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
100                         strMessage = strcat(strMessage, " ^7(^2Bot");
101                 else
102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
103                 if(cvar("sv_fragmessage_information_handicap"))
104                         if(cvar("sv_fragmessage_information_handicap") == 2)
105                                 if(nPlayerHandicap <= 1)
106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
107                                 else
108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
109                         else if not(nPlayerHandicap <= 1)
110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
111                 else
112                         strMessage = strcat(strMessage, "^7)");
113         } else if(cvar("sv_fragmessage_information_handicap")) {
114                 if(cvar("sv_fragmessage_information_handicap") == 2)
115                         if(nPlayerHandicap <= 1)
116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
117                         else
118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
119                 else if(nPlayerHandicap > 1)
120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
121         }
122         return strMessage;
123 }
124 void bcenterprint(string s)
125 {
126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
127     entity head;
128     FOR_EACH_PLAYER(head)
129     if (clienttype(head) == CLIENTTYPE_REAL)
130         centerprint(head, s);
131 }
132
133 void GameLogEcho(string s)
134 {
135     string fn;
136     float matches;
137
138     if (cvar("sv_eventlog_files"))
139     {
140         if (!logfile_open)
141         {
142             logfile_open = TRUE;
143             matches = cvar("sv_eventlog_files_counter") + 1;
144             cvar_set("sv_eventlog_files_counter", ftos(matches));
145             fn = ftos(matches);
146             if (strlen(fn) < 8)
147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
148             fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
149             logfile = fopen(fn, FILE_APPEND);
150             fputs(logfile, ":logversion:3\n");
151         }
152         if (logfile >= 0)
153         {
154             if (cvar("sv_eventlog_files_timestamps"))
155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
156             else
157                 fputs(logfile, strcat(s, "\n"));
158         }
159     }
160     if (cvar("sv_eventlog_console"))
161     {
162         print(s, "\n");
163     }
164 }
165
166 void GameLogInit()
167 {
168     logfile_open = 0;
169     // will be opened later
170 }
171
172 void GameLogClose()
173 {
174     if (logfile_open && logfile >= 0)
175     {
176         fclose(logfile);
177         logfile = -1;
178     }
179 }
180
181 vector PL_VIEW_OFS;
182 vector PL_MIN;
183 vector PL_MAX;
184 vector PL_HEAD;
185 vector PL_CROUCH_VIEW_OFS;
186 vector PL_CROUCH_MIN;
187 vector PL_CROUCH_MAX;
188
189 float spawnpoint_nag;
190 void relocate_spawnpoint()
191 {
192     PL_VIEW_OFS                             = stov(cvar_string("sv_player_viewoffset"));
193     PL_MIN                                  = stov(cvar_string("sv_player_mins"));
194     PL_MAX                                  = stov(cvar_string("sv_player_maxs"));
195     PL_HEAD                                 = stov(cvar_string("sv_player_headsize"));
196     PL_CROUCH_VIEW_OFS                      = stov(cvar_string("sv_player_crouch_viewoffset"));
197     PL_CROUCH_MIN                           = stov(cvar_string("sv_player_crouch_mins"));
198     PL_CROUCH_MAX                           = stov(cvar_string("sv_player_crouch_maxs"));
199
200     // nudge off the floor
201     setorigin(self, self.origin + '0 0 1');
202
203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
204     if (trace_startsolid)
205     {
206         vector o;
207         o = self.origin;
208         self.mins = PL_MIN;
209         self.maxs = PL_MAX;
210         if (!move_out_of_solid(self))
211             objerror("could not get out of solid at all!");
212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
214         print(" ", ftos(self.origin_y - o_y));
215         print(" ", ftos(self.origin_z - o_z), "'\n");
216         if (cvar("g_spawnpoints_auto_move_out_of_solid"))
217         {
218             if (!spawnpoint_nag)
219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
220             spawnpoint_nag = 1;
221         }
222         else
223         {
224             setorigin(self, o);
225             self.mins = self.maxs = '0 0 0';
226             objerror("player spawn point in solid, mapper sucks!\n");
227             return;
228         }
229     }
230
231     self.use = spawnpoint_use;
232     self.team_saved = self.team;
233     if (!self.cnt)
234         self.cnt = 1;
235
236     if (have_team_spawns != 0)
237         if (self.team)
238             have_team_spawns = 1;
239
240     if (cvar("r_showbboxes"))
241     {
242         // show where spawnpoints point at too
243         makevectors(self.angles);
244         entity e;
245         e = spawn();
246         e.classname = "info_player_foo";
247         setorigin(e, self.origin + v_forward * 24);
248         setsize(e, '-8 -8 -8', '8 8 8');
249         e.solid = SOLID_TRIGGER;
250     }
251 }
252
253 #define strstr strstrofs
254 /*
255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
258 // BE CONSTANT OR strzoneD!
259 float strstr(string haystack, string needle, float offset)
260 {
261         float len, endpos;
262         string found;
263         len = strlen(needle);
264         endpos = strlen(haystack) - len;
265         while(offset <= endpos)
266         {
267                 found = substring(haystack, offset, len);
268                 if(found == needle)
269                         return offset;
270                 offset = offset + 1;
271         }
272         return -1;
273 }
274 */
275
276 float NUM_NEAREST_ENTITIES = 4;
277 entity nearest_entity[NUM_NEAREST_ENTITIES];
278 float nearest_length[NUM_NEAREST_ENTITIES];
279 entity findnearest(vector point, .string field, string value, vector axismod)
280 {
281     entity localhead;
282     float i;
283     float j;
284     float len;
285     vector dist;
286
287     float num_nearest;
288     num_nearest = 0;
289
290     localhead = find(world, field, value);
291     while (localhead)
292     {
293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
294             dist = localhead.oldorigin;
295         else
296             dist = localhead.origin;
297         dist = dist - point;
298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
299         len = vlen(dist);
300
301         for (i = 0; i < num_nearest; ++i)
302         {
303             if (len < nearest_length[i])
304                 break;
305         }
306
307         // now i tells us where to insert at
308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
309         if (i < NUM_NEAREST_ENTITIES)
310         {
311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
312             {
313                 nearest_length[j + 1] = nearest_length[j];
314                 nearest_entity[j + 1] = nearest_entity[j];
315             }
316             nearest_length[i] = len;
317             nearest_entity[i] = localhead;
318             if (num_nearest < NUM_NEAREST_ENTITIES)
319                 num_nearest = num_nearest + 1;
320         }
321
322         localhead = find(localhead, field, value);
323     }
324
325     // now use the first one from our list that we can see
326     for (i = 0; i < num_nearest; ++i)
327     {
328         traceline(point, nearest_entity[i].origin, TRUE, world);
329         if (trace_fraction == 1)
330         {
331             if (i != 0)
332             {
333                 dprint("Nearest point (");
334                 dprint(nearest_entity[0].netname);
335                 dprint(") is not visible, using a visible one.\n");
336             }
337             return nearest_entity[i];
338         }
339     }
340
341     if (num_nearest == 0)
342         return world;
343
344     dprint("Not seeing any location point, using nearest as fallback.\n");
345     /* DEBUGGING CODE:
346     dprint("Candidates were: ");
347     for(j = 0; j < num_nearest; ++j)
348     {
349         if(j != 0)
350                 dprint(", ");
351         dprint(nearest_entity[j].netname);
352     }
353     dprint("\n");
354     */
355
356     return nearest_entity[0];
357 }
358
359 void spawnfunc_target_location()
360 {
361     self.classname = "target_location";
362     // location name in netname
363     // eventually support: count, teamgame selectors, line of sight?
364 };
365
366 void spawnfunc_info_location()
367 {
368     self.classname = "target_location";
369     self.message = self.netname;
370 };
371
372 string NearestLocation(vector p)
373 {
374     entity loc;
375     string ret;
376     ret = "somewhere";
377     loc = findnearest(p, classname, "target_location", '1 1 1');
378     if (loc)
379     {
380         ret = loc.message;
381     }
382     else
383     {
384         loc = findnearest(p, target, "###item###", '1 1 4');
385         if (loc)
386             ret = loc.netname;
387     }
388     return ret;
389 }
390
391 string formatmessage(string msg)
392 {
393         float p, p1, p2;
394         float n;
395         vector cursor;
396         entity cursor_ent;
397         string escape;
398         string replacement;
399         p = 0;
400         n = 7;
401
402         WarpZone_crosshair_trace(self);
403         cursor = trace_endpos;
404         cursor_ent = trace_ent;
405
406         while (1) {
407                 if (n < 1)
408                         break; // too many replacements
409
410                 n = n - 1;
411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
413
414                 if (p1 < 0)
415                         p1 = p2;
416
417                 if (p2 < 0)
418                         p2 = p1;
419
420                 p = min(p1, p2);
421
422                 if (p < 0)
423                         break;
424
425                 replacement = substring(msg, p, 2);
426                 escape = substring(msg, p + 1, 1);
427
428                 if (escape == "%")
429                         replacement = "%";
430                 else if (escape == "\\")
431                         replacement = "\\";
432                 else if (escape == "n")
433                         replacement = "\n";
434                 else if (escape == "a")
435                         replacement = ftos(floor(self.armorvalue));
436                 else if (escape == "h")
437                         replacement = ftos(floor(self.health));
438                 else if (escape == "l")
439                         replacement = NearestLocation(self.origin);
440                 else if (escape == "y")
441                         replacement = NearestLocation(cursor);
442                 else if (escape == "d")
443                         replacement = NearestLocation(self.death_origin);
444                 else if (escape == "w") {
445                         float wep;
446                         wep = self.weapon;
447                         if (!wep)
448                                 wep = self.switchweapon;
449                         if (!wep)
450                                 wep = self.cnt;
451                         replacement = W_Name(wep);
452                 } else if (escape == "W") {
453                         if (self.items & IT_SHELLS) replacement = "shells";
454                         else if (self.items & IT_NAILS) replacement = "bullets";
455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
456                         else if (self.items & IT_CELLS) replacement = "cells";
457                         else replacement = "batteries"; // ;)
458                 } else if (escape == "x") {
459                         replacement = cursor_ent.netname;
460                         if (!replacement || !cursor_ent)
461                                 replacement = "nothing";
462                 } else if (escape == "p") {
463                         if (self.last_selected_player)
464                                 replacement = self.last_selected_player.netname;
465                         else
466                                 replacement = "(nobody)";
467                 } else if (escape == "s")
468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
469                 else if (escape == "S")
470                         replacement = ftos(vlen(self.velocity));
471
472                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
473                 p = p + strlen(replacement);
474         }
475         return msg;
476 }
477
478 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
479         return (value == 0) ? FALSE : TRUE;
480 }
481
482 /*
483 =============
484 GetCvars
485 =============
486 Called with:
487   0:  sends the request
488   >0: receives a cvar from name=argv(f) value=argv(f+1)
489 */
490 void GetCvars_handleString(string thisname, float f, .string field, string name)
491 {
492         if (f < 0)
493         {
494                 if (self.field)
495                         strunzone(self.field);
496                 self.field = string_null;
497         }
498         else if (f > 0)
499         {
500                 if (thisname == name)
501                 {
502                         if (self.field)
503                                 strunzone(self.field);
504                         self.field = strzone(argv(f + 1));
505                 }
506         }
507         else
508                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
509 }
510 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
511 {
512         GetCvars_handleString(thisname, f, field, name);
513         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
514                 if (thisname == name)
515                 {
516                         string s;
517                         s = func(strcat1(self.field));
518                         if (s != self.field)
519                         {
520                                 strunzone(self.field);
521                                 self.field = strzone(s);
522                         }
523                 }
524 }
525 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
526 {
527         if (f < 0)
528         {
529         }
530         else if (f > 0)
531         {
532                 if (thisname == name)
533                         self.field = stof(argv(f + 1));
534         }
535         else
536                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
537 }
538 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
539 {
540         if (f < 0)
541         {
542         }
543         else if (f > 0)
544         {
545                 if (thisname == name)
546                 {
547                         if(!self.field)
548                         {
549                                 self.field = stof(argv(f + 1));
550                                 if(!self.field)
551                                         self.field = -1;
552                         }
553                 }
554         }
555         else
556         {
557                 if(!self.field)
558                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
559         }
560 }
561 float w_getbestweapon(entity e);
562 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
563 {
564         string o;
565         o = W_FixWeaponOrder_ForceComplete(wo);
566         if(self.weaponorder_byimpulse)
567         {
568                 strunzone(self.weaponorder_byimpulse);
569                 self.weaponorder_byimpulse = string_null;
570         }
571         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
572         return o;
573 }
574 void GetCvars(float f)
575 {
576         string s;
577
578         if (f > 0)
579                 s = strcat1(argv(f));
580
581         get_cvars_f = f;
582         get_cvars_s = s;
583         MUTATOR_CALLHOOK(GetCvars);
584         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
585         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
586         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
587         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
588         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
589         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
606         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
608         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
609
610         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
611         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
612
613 #ifdef ALLOW_FORCEMODELS
614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
615         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
616 #endif
617         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
618         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
619
620         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
621         if (f > 0)
622         {
623                 if (s == "cl_weaponpriority")
624                         self.switchweapon = w_getbestweapon(self);
625         }
626 }
627
628 float fexists(string f)
629 {
630     float fh;
631     fh = fopen(f, FILE_READ);
632     if (fh < 0)
633         return FALSE;
634     fclose(fh);
635     return TRUE;
636 }
637
638 void backtrace(string msg)
639 {
640     float dev, war;
641     dev = cvar("developer");
642     war = cvar("prvm_backtraceforwarnings");
643     cvar_set("developer", "1");
644     cvar_set("prvm_backtraceforwarnings", "1");
645     print("\n");
646     print("--- CUT HERE ---\nWARNING: ");
647     print(msg);
648     print("\n");
649     remove(world); // isn't there any better way to cause a backtrace?
650     print("\n--- CUT UNTIL HERE ---\n");
651     cvar_set("developer", ftos(dev));
652     cvar_set("prvm_backtraceforwarnings", ftos(war));
653 }
654
655 string Team_ColorCode(float teamid)
656 {
657     if (teamid == COLOR_TEAM1)
658         return "^1";
659     else if (teamid == COLOR_TEAM2)
660         return "^4";
661     else if (teamid == COLOR_TEAM3)
662         return "^3";
663     else if (teamid == COLOR_TEAM4)
664         return "^6";
665     else
666         return "^7";
667 }
668
669 string Team_ColorName(float t)
670 {
671     // fixme: Search for team entities and get their .netname's!
672     if (t == COLOR_TEAM1)
673         return "Red";
674     if (t == COLOR_TEAM2)
675         return "Blue";
676     if (t == COLOR_TEAM3)
677         return "Yellow";
678     if (t == COLOR_TEAM4)
679         return "Pink";
680     return "Neutral";
681 }
682
683 string Team_ColorNameLowerCase(float t)
684 {
685     // fixme: Search for team entities and get their .netname's!
686     if (t == COLOR_TEAM1)
687         return "red";
688     if (t == COLOR_TEAM2)
689         return "blue";
690     if (t == COLOR_TEAM3)
691         return "yellow";
692     if (t == COLOR_TEAM4)
693         return "pink";
694     return "neutral";
695 }
696
697 float ColourToNumber(string team_colour)
698 {
699         if (team_colour == "red")
700                 return COLOR_TEAM1;
701
702         if (team_colour == "blue")
703                 return COLOR_TEAM2;
704
705         if (team_colour == "yellow")
706                 return COLOR_TEAM3;
707
708         if (team_colour == "pink")
709                 return COLOR_TEAM4;
710
711         if (team_colour == "auto")
712                 return 0;
713
714         return -1;
715 }
716
717 float NumberToTeamNumber(float number)
718 {
719         if (number == 1)
720                 return COLOR_TEAM1;
721
722         if (number == 2)
723                 return COLOR_TEAM2;
724
725         if (number == 3)
726                 return COLOR_TEAM3;
727
728         if (number == 4)
729                 return COLOR_TEAM4;
730
731         return -1;
732 }
733
734 #define CENTERPRIO_POINT 1
735 #define CENTERPRIO_SPAM 2
736 #define CENTERPRIO_VOTE 4
737 #define CENTERPRIO_NORMAL 5
738 #define CENTERPRIO_SHIELDING 7
739 #define CENTERPRIO_MAPVOTE 9
740 #define CENTERPRIO_IDLEKICK 50
741 #define CENTERPRIO_ADMIN 99
742 .float centerprint_priority;
743 .float centerprint_expires;
744 void centerprint_atprio(entity e, float prio, string s)
745 {
746     if (intermission_running)
747         if (prio < CENTERPRIO_MAPVOTE)
748             return;
749     if (time > e.centerprint_expires)
750         e.centerprint_priority = 0;
751     if (prio >= e.centerprint_priority)
752     {
753         e.centerprint_priority = prio;
754         if (timeoutStatus == 2)
755             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
756         else
757             e.centerprint_expires = time + e.cvar_scr_centertime;
758         centerprint_builtin(e, s);
759     }
760 }
761 void centerprint_expire(entity e, float prio)
762 {
763     if (prio == e.centerprint_priority)
764     {
765         e.centerprint_priority = 0;
766         centerprint_builtin(e, "");
767     }
768 }
769 void centerprint(entity e, string s)
770 {
771     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
772 }
773
774 // decolorizes and team colors the player name when needed
775 string playername(entity p)
776 {
777     string t;
778     if (teams_matter && !intermission_running && p.classname == "player")
779     {
780         t = Team_ColorCode(p.team);
781         return strcat(t, strdecolorize(p.netname));
782     }
783     else
784         return p.netname;
785 }
786
787 vector randompos(vector m1, vector m2)
788 {
789     local vector v;
790     m2 = m2 - m1;
791     v_x = m2_x * random() + m1_x;
792     v_y = m2_y * random() + m1_y;
793     v_z = m2_z * random() + m1_z;
794     return  v;
795 };
796
797 float g_pickup_shells;
798 float g_pickup_shells_max;
799 float g_pickup_nails;
800 float g_pickup_nails_max;
801 float g_pickup_rockets;
802 float g_pickup_rockets_max;
803 float g_pickup_cells;
804 float g_pickup_cells_max;
805 float g_pickup_fuel;
806 float g_pickup_fuel_jetpack;
807 float g_pickup_fuel_max;
808 float g_pickup_armorsmall;
809 float g_pickup_armorsmall_max;
810 float g_pickup_armorsmall_anyway;
811 float g_pickup_armormedium;
812 float g_pickup_armormedium_max;
813 float g_pickup_armormedium_anyway;
814 float g_pickup_armorbig;
815 float g_pickup_armorbig_max;
816 float g_pickup_armorbig_anyway;
817 float g_pickup_armorlarge;
818 float g_pickup_armorlarge_max;
819 float g_pickup_armorlarge_anyway;
820 float g_pickup_healthsmall;
821 float g_pickup_healthsmall_max;
822 float g_pickup_healthsmall_anyway;
823 float g_pickup_healthmedium;
824 float g_pickup_healthmedium_max;
825 float g_pickup_healthmedium_anyway;
826 float g_pickup_healthlarge;
827 float g_pickup_healthlarge_max;
828 float g_pickup_healthlarge_anyway;
829 float g_pickup_healthmega;
830 float g_pickup_healthmega_max;
831 float g_pickup_healthmega_anyway;
832 float g_pickup_ammo_anyway;
833 float g_pickup_weapons_anyway;
834 float g_weaponarena;
835 float g_weaponarena_random;
836 float g_weaponarena_random_with_laser;
837 string g_weaponarena_list;
838 float g_weaponspeedfactor;
839 float g_weaponratefactor;
840 float g_weapondamagefactor;
841 float g_weaponforcefactor;
842 float g_weaponspreadfactor;
843
844 float start_weapons;
845 float start_items;
846 float start_ammo_shells;
847 float start_ammo_nails;
848 float start_ammo_rockets;
849 float start_ammo_cells;
850 float start_ammo_fuel;
851 float start_health;
852 float start_armorvalue;
853 float warmup_start_weapons;
854 float warmup_start_ammo_shells;
855 float warmup_start_ammo_nails;
856 float warmup_start_ammo_rockets;
857 float warmup_start_ammo_cells;
858 float warmup_start_ammo_fuel;
859 float warmup_start_health;
860 float warmup_start_armorvalue;
861 float g_weapon_stay;
862 float g_ghost_items;
863
864 entity get_weaponinfo(float w);
865
866 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
867 {
868         var float i = weaponinfo.weapon;
869
870         if (!i)
871                 return 0;
872
873         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
874
875         if (t < 0) // "default" weapon selection
876         {
877                 if (g_lms || g_ca || allguns)
878                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
879                 else if(t < -1)
880                         t = 0;
881                 else if (g_race || g_cts)
882                         t = (i == WEP_LASER);
883                 else if (g_nexball)
884                         t = 0; // weapon is set a few lines later
885                 else
886                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
887                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
888                         t |= (i == WEP_HOOK);
889         }
890
891         // we cannot disable porto in Nexball, we must force it
892         if(g_nexball && i == WEP_PORTO)
893                 t = 1;
894
895         return t;
896 }
897
898 void readplayerstartcvars()
899 {
900         entity e;
901         float i, j, t;
902         string s;
903
904         // initialize starting values for players
905         start_weapons = 0;
906         start_items = 0;
907         start_ammo_shells = 0;
908         start_ammo_nails = 0;
909         start_ammo_rockets = 0;
910         start_ammo_cells = 0;
911         start_health = cvar("g_balance_health_start");
912         start_armorvalue = cvar("g_balance_armor_start");
913
914         g_weaponarena = 0;
915         s = cvar_string("g_weaponarena");
916         if (s == "0")
917         {
918         }
919         else if (s == "all")
920         {
921                 g_weaponarena_list = "All Weapons";
922                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
923                 {
924                         e = get_weaponinfo(j);
925                         g_weaponarena |= e.weapons;
926                         weapon_action(e.weapon, WR_PRECACHE);
927                 }
928         }
929         else if (s == "most")
930         {
931                 g_weaponarena_list = "Most Weapons";
932                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
933                 {
934                         e = get_weaponinfo(j);
935                         if (e.spawnflags & WEP_FLAG_NORMAL)
936                         {
937                                 g_weaponarena |= e.weapons;
938                                 weapon_action(e.weapon, WR_PRECACHE);
939                         }
940                 }
941         }
942         else if (s == "none")
943         {
944                 g_weaponarena_list = "No Weapons";
945                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
946         }
947         else
948         {
949                 t = tokenize_console(s);
950                 g_weaponarena_list = "";
951                 for (i = 0; i < t; ++i)
952                 {
953                         s = argv(i);
954                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
955                         {
956                                 e = get_weaponinfo(j);
957                                 if (e.netname == s)
958                                 {
959                                         g_weaponarena |= e.weapons;
960                                         weapon_action(e.weapon, WR_PRECACHE);
961                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
962                                         break;
963                                 }
964                         }
965                         if (j > WEP_LAST)
966                         {
967                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
968                         }
969                 }
970                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
971         }
972
973         if(g_weaponarena)
974                 g_weaponarena_random = cvar("g_weaponarena_random");
975         else
976                 g_weaponarena_random = 0;
977         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
978
979         if (g_weaponarena)
980         {
981                 start_weapons = g_weaponarena;
982                 if (g_weaponarena & (WEPBIT_GRENADE_LAUNCHER | WEPBIT_MINE_LAYER | WEPBIT_HAGAR | WEPBIT_ROCKET_LAUNCHER))
983                         start_ammo_rockets = 999;
984                 if (g_weaponarena & WEPBIT_SHOTGUN)
985                         start_ammo_shells = 999;
986                 if (g_weaponarena & (WEPBIT_ELECTRO | WEPBIT_CRYLINK | WEPBIT_NEX | WEPBIT_MINSTANEX | WEPBIT_HLAC | WEPBIT_HOOK))
987                         start_ammo_cells = 999;
988                 if (g_weaponarena & (WEPBIT_UZI | WEPBIT_CAMPINGRIFLE))
989                         start_ammo_nails = 999;
990                 if (g_weaponarena & WEPBIT_HOOK)
991                         start_ammo_fuel = 999;
992                 start_items |= IT_UNLIMITED_AMMO;
993         }
994         else if (g_minstagib)
995         {
996                 start_health = 100;
997                 start_armorvalue = 0;
998                 start_weapons = WEPBIT_MINSTANEX;
999                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1000                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1001                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1002                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1003
1004                 if (g_minstagib_invis_alpha <= 0)
1005                         g_minstagib_invis_alpha = -1;
1006         }
1007         else
1008         {
1009                 if (g_lms || g_ca)
1010                 {
1011                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1012                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1013                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1014                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1015                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1016                         start_health = cvar("g_lms_start_health");
1017                         start_armorvalue = cvar("g_lms_start_armor");
1018                 }
1019                 else
1020                 {
1021                         start_ammo_shells = cvar("g_start_ammo_shells");
1022                         start_ammo_nails = cvar("g_start_ammo_nails");
1023                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1024                         start_ammo_cells = cvar("g_start_ammo_cells");
1025                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1026                 }
1027
1028                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1029                 {
1030                         e = get_weaponinfo(i);
1031                         if(want_weapon("g_start_weapon_", e, FALSE))
1032                                 start_weapons |= e.weapons;
1033                 }
1034         }
1035
1036         if (inWarmupStage)
1037         {
1038                 warmup_start_ammo_shells = start_ammo_shells;
1039                 warmup_start_ammo_nails = start_ammo_nails;
1040                 warmup_start_ammo_rockets = start_ammo_rockets;
1041                 warmup_start_ammo_cells = start_ammo_cells;
1042                 warmup_start_ammo_fuel = start_ammo_fuel;
1043                 warmup_start_health = start_health;
1044                 warmup_start_armorvalue = start_armorvalue;
1045                 warmup_start_weapons = start_weapons;
1046
1047                 if (!g_weaponarena && !g_minstagib && !g_ca)
1048                 {
1049                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1050                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1051                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1052                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1053                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1054                         warmup_start_health = cvar("g_warmup_start_health");
1055                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1056                         warmup_start_weapons = 0;
1057                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1058                         {
1059                                 e = get_weaponinfo(i);
1060                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1061                                         warmup_start_weapons |= e.weapons;
1062                         }
1063                 }
1064         }
1065
1066         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1067         {
1068                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1069                 start_items |= IT_FUEL_REGEN;
1070                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1071                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1072         }
1073
1074         if(!cvar("g_use_ammunition"))
1075         {
1076                 start_ammo_shells = cvar("g_pickup_shells_max");
1077                 start_ammo_nails = cvar("g_pickup_nails_max");
1078                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1079                 start_ammo_cells = cvar("g_pickup_cells_max");
1080                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1081                 start_items |= IT_UNLIMITED_AMMO;
1082                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1083                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1084                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1085                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1086                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1087                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1088         }
1089
1090         if (g_jetpack)
1091                 start_items |= IT_JETPACK;
1092
1093         if (g_weapon_stay == 2)
1094         {
1095                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1096                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1097                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1098                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1099                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1100                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1101                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1102                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1103                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1104                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1105         }
1106
1107         MUTATOR_CALLHOOK(SetStartItems);
1108
1109         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1110         {
1111                 e = get_weaponinfo(i);
1112                 if(e.weapons & (start_weapons | warmup_start_weapons))
1113                         weapon_action(e.weapon, WR_PRECACHE);
1114         }
1115
1116         start_ammo_shells = max(0, start_ammo_shells);
1117         start_ammo_nails = max(0, start_ammo_nails);
1118         start_ammo_cells = max(0, start_ammo_cells);
1119         start_ammo_rockets = max(0, start_ammo_rockets);
1120         start_ammo_fuel = max(0, start_ammo_fuel);
1121
1122         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1123         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1124         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1125         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1126         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1127 }
1128
1129 float g_bugrigs;
1130 float g_bugrigs_planar_movement;
1131 float g_bugrigs_planar_movement_car_jumping;
1132 float g_bugrigs_reverse_spinning;
1133 float g_bugrigs_reverse_speeding;
1134 float g_bugrigs_reverse_stopping;
1135 float g_bugrigs_air_steering;
1136 float g_bugrigs_angle_smoothing;
1137 float g_bugrigs_friction_floor;
1138 float g_bugrigs_friction_brake;
1139 float g_bugrigs_friction_air;
1140 float g_bugrigs_accel;
1141 float g_bugrigs_speed_ref;
1142 float g_bugrigs_speed_pow;
1143 float g_bugrigs_steer;
1144
1145 float g_touchexplode;
1146 float g_touchexplode_radius;
1147 float g_touchexplode_damage;
1148 float g_touchexplode_edgedamage;
1149 float g_touchexplode_force;
1150
1151 float sv_autotaunt;
1152 float sv_taunt;
1153
1154 float sv_pitch_min;
1155 float sv_pitch_max;
1156 float sv_pitch_fixyaw;
1157
1158 float sv_accuracy_data_share;
1159
1160 void readlevelcvars(void)
1161 {
1162         // first load all the mutators
1163         if(cvar("g_nix"))
1164                 MUTATOR_ADD(mutator_nix);
1165         if(cvar("g_dodging"))
1166                 MUTATOR_ADD(mutator_dodging);
1167         if(cvar("g_rocket_flying"))
1168                 MUTATOR_ADD(mutator_rocketflying);
1169         if(cvar("g_vampire"))
1170                 MUTATOR_ADD(mutator_vampire);
1171
1172         serverflags = 0;
1173         if(cvar("sv_allow_fullbright"))
1174                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1175
1176     g_bugrigs = cvar("g_bugrigs");
1177     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1178     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1179     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1180     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1181     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1182     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1183     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1184     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1185     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1186     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1187     g_bugrigs_accel = cvar("g_bugrigs_accel");
1188     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1189     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1190     g_bugrigs_steer = cvar("g_bugrigs_steer");
1191
1192     g_touchexplode = cvar("g_touchexplode");
1193     g_touchexplode_radius = cvar("g_touchexplode_radius");
1194     g_touchexplode_damage = cvar("g_touchexplode_damage");
1195     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1196     g_touchexplode_force = cvar("g_touchexplode_force");
1197
1198 #ifdef ALLOW_FORCEMODELS
1199         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1200 #endif
1201         sv_loddistance1 = cvar("sv_loddistance1");
1202         sv_loddistance2 = cvar("sv_loddistance2");
1203
1204         if(sv_loddistance2 <= sv_loddistance1)
1205                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1206
1207         sv_clones = cvar("sv_clones");
1208         sv_gentle = cvar("sv_gentle");
1209         sv_foginterval = cvar("sv_foginterval");
1210         g_cloaked = cvar("g_cloaked");
1211         g_jump_grunt = cvar("g_jump_grunt");
1212         g_footsteps = cvar("g_footsteps");
1213         g_grappling_hook = cvar("g_grappling_hook");
1214         g_jetpack = cvar("g_jetpack");
1215         g_midair = cvar("g_midair");
1216         g_minstagib = cvar("g_minstagib");
1217         g_norecoil = cvar("g_norecoil");
1218         g_bloodloss = cvar("g_bloodloss");
1219         sv_maxidle = cvar("sv_maxidle");
1220         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1221         sv_pogostick = cvar("sv_pogostick");
1222         g_ctf_reverse = cvar("g_ctf_reverse");
1223         sv_autotaunt = cvar("sv_autotaunt");
1224         sv_taunt = cvar("sv_taunt");
1225
1226         inWarmupStage = cvar("g_warmup");
1227         g_warmup_limit = cvar("g_warmup_limit");
1228         g_warmup_allguns = cvar("g_warmup_allguns");
1229         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1230
1231         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1232                 inWarmupStage = 0; // these modes cannot work together, sorry
1233
1234         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1235         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1236         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1237         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1238         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1239         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1240         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1241         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1242         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1243         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1244         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1245         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1246
1247         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1248         g_weaponratefactor = cvar("g_weaponratefactor");
1249         g_weapondamagefactor = cvar("g_weapondamagefactor");
1250         g_weaponforcefactor = cvar("g_weaponforcefactor");
1251         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1252
1253         g_pickup_shells = cvar("g_pickup_shells");
1254         g_pickup_shells_max = cvar("g_pickup_shells_max");
1255         g_pickup_nails = cvar("g_pickup_nails");
1256         g_pickup_nails_max = cvar("g_pickup_nails_max");
1257         g_pickup_rockets = cvar("g_pickup_rockets");
1258         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1259         g_pickup_cells = cvar("g_pickup_cells");
1260         g_pickup_cells_max = cvar("g_pickup_cells_max");
1261         g_pickup_fuel = cvar("g_pickup_fuel");
1262         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1263         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1264         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1265         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1266         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1267         g_pickup_armormedium = cvar("g_pickup_armormedium");
1268         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1269         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1270         g_pickup_armorbig = cvar("g_pickup_armorbig");
1271         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1272         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1273         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1274         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1275         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1276         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1277         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1278         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1279         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1280         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1281         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1282         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1283         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1284         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1285         g_pickup_healthmega = cvar("g_pickup_healthmega");
1286         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1287         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1288
1289         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1290         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1291
1292         g_pinata = cvar("g_pinata");
1293
1294         g_weapon_stay = cvar("g_weapon_stay");
1295
1296         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1297                 g_weapon_stay = 1;
1298
1299         g_ghost_items = cvar("g_ghost_items");
1300
1301         if(g_ghost_items >= 1)
1302                 g_ghost_items = 0.25; // default alpha value
1303
1304         if not(inWarmupStage && !g_ca)
1305                 game_starttime = cvar("g_start_delay");
1306
1307         sv_pitch_min = cvar("sv_pitch_min");
1308         sv_pitch_max = cvar("sv_pitch_max");
1309         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1310
1311         sv_accuracy_data_share = boolean(cvar("sv_accuracy_data_share"));
1312
1313         readplayerstartcvars();
1314 }
1315
1316 /*
1317 // TODO sound pack system
1318 string soundpack;
1319
1320 string precache_sound_builtin (string s) = #19;
1321 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1322 string precache_sound(string s)
1323 {
1324         return precache_sound_builtin(strcat(soundpack, s));
1325 }
1326 void play2(entity e, string filename)
1327 {
1328         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1329 }
1330 void sound(entity e, float chan, string samp, float vol, float atten)
1331 {
1332         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1333 }
1334 */
1335
1336 // Sound functions
1337 string precache_sound (string s) = #19;
1338 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1339 float precache_sound_index (string s) = #19;
1340
1341 #define SND_VOLUME      1
1342 #define SND_ATTENUATION 2
1343 #define SND_LARGEENTITY 8
1344 #define SND_LARGESOUND  16
1345
1346 float sound_allowed(float dest, entity e)
1347 {
1348     // sounds from world may always pass
1349     for (;;)
1350     {
1351         if (e.classname == "body")
1352             e = e.enemy;
1353         if (e.owner && e.owner != e)
1354             e = e.owner;
1355         else
1356             break;
1357     }
1358     // sounds to self may always pass
1359     if (dest == MSG_ONE)
1360         if (e == msg_entity)
1361             return TRUE;
1362     // sounds by players can be removed
1363     if (cvar("bot_sound_monopoly"))
1364         if (clienttype(e) == CLIENTTYPE_REAL)
1365             return FALSE;
1366     // anything else may pass
1367     return TRUE;
1368 }
1369
1370 void sound(entity e, float chan, string samp, float vol, float atten)
1371 {
1372     if (!sound_allowed(MSG_BROADCAST, e))
1373         return;
1374     sound_builtin(e, chan, samp, vol, atten);
1375 }
1376 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1377 {
1378     float entno, idx;
1379
1380     if (!sound_allowed(dest, e))
1381         return;
1382
1383     entno = num_for_edict(e);
1384     idx = precache_sound_index(samp);
1385
1386     float sflags;
1387     sflags = 0;
1388
1389     atten = floor(atten * 64);
1390     vol = floor(vol * 255);
1391
1392     if (vol != 255)
1393         sflags |= SND_VOLUME;
1394     if (atten != 64)
1395         sflags |= SND_ATTENUATION;
1396     if (entno >= 8192)
1397         sflags |= SND_LARGEENTITY;
1398     if (idx >= 256)
1399         sflags |= SND_LARGESOUND;
1400
1401     WriteByte(dest, SVC_SOUND);
1402     WriteByte(dest, sflags);
1403     if (sflags & SND_VOLUME)
1404         WriteByte(dest, vol);
1405     if (sflags & SND_ATTENUATION)
1406         WriteByte(dest, atten);
1407     if (sflags & SND_LARGEENTITY)
1408     {
1409         WriteShort(dest, entno);
1410         WriteByte(dest, chan);
1411     }
1412     else
1413     {
1414         WriteShort(dest, entno * 8 + chan);
1415     }
1416     if (sflags & SND_LARGESOUND)
1417         WriteShort(dest, idx);
1418     else
1419         WriteByte(dest, idx);
1420
1421     WriteCoord(dest, o_x);
1422     WriteCoord(dest, o_y);
1423     WriteCoord(dest, o_z);
1424 }
1425 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1426 {
1427     vector o;
1428
1429     if (!sound_allowed(dest, e))
1430         return;
1431
1432     o = e.origin + 0.5 * (e.mins + e.maxs);
1433     soundtoat(dest, e, o, chan, samp, vol, atten);
1434 }
1435 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1436 {
1437     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1438 }
1439 void stopsoundto(float dest, entity e, float chan)
1440 {
1441     float entno;
1442
1443     if (!sound_allowed(dest, e))
1444         return;
1445
1446     entno = num_for_edict(e);
1447
1448     if (entno >= 8192)
1449     {
1450         float idx, sflags;
1451         idx = precache_sound_index("misc/null.wav");
1452         sflags = SND_LARGEENTITY;
1453         if (idx >= 256)
1454             sflags |= SND_LARGESOUND;
1455         WriteByte(dest, SVC_SOUND);
1456         WriteByte(dest, sflags);
1457         WriteShort(dest, entno);
1458         WriteByte(dest, chan);
1459         if (sflags & SND_LARGESOUND)
1460             WriteShort(dest, idx);
1461         else
1462             WriteByte(dest, idx);
1463         WriteCoord(dest, e.origin_x);
1464         WriteCoord(dest, e.origin_y);
1465         WriteCoord(dest, e.origin_z);
1466     }
1467     else
1468     {
1469         WriteByte(dest, SVC_STOPSOUND);
1470         WriteShort(dest, entno * 8 + chan);
1471     }
1472 }
1473 void stopsound(entity e, float chan)
1474 {
1475     if (!sound_allowed(MSG_BROADCAST, e))
1476         return;
1477
1478     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1479     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1480 }
1481
1482 void play2(entity e, string filename)
1483 {
1484     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1485     msg_entity = e;
1486     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1487 }
1488
1489 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1490 .float spamtime;
1491 float spamsound(entity e, float chan, string samp, float vol, float atten)
1492 {
1493     if (!sound_allowed(MSG_BROADCAST, e))
1494         return FALSE;
1495
1496     if (time > e.spamtime)
1497     {
1498         e.spamtime = time;
1499         sound(e, chan, samp, vol, atten);
1500         return TRUE;
1501     }
1502     return FALSE;
1503 }
1504
1505 void play2team(float t, string filename)
1506 {
1507     local entity head;
1508
1509     if (cvar("bot_sound_monopoly"))
1510         return;
1511
1512     FOR_EACH_REALPLAYER(head)
1513     {
1514         if (head.team == t)
1515             play2(head, filename);
1516     }
1517 }
1518
1519 void play2all(string samp)
1520 {
1521     if (cvar("bot_sound_monopoly"))
1522         return;
1523
1524     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1525 }
1526
1527 void PrecachePlayerSounds(string f);
1528 void precache_playermodel(string m)
1529 {
1530         float globhandle, i, n;
1531         string f;
1532
1533         if(substring(m, -9,5) == "_lod1")
1534                 return;
1535         if(substring(m, -9,5) == "_lod2")
1536                 return;
1537         precache_model(m);
1538         if(sv_loddistance1)
1539         {
1540                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1541                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1542         }
1543
1544         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1545         if (globhandle < 0)
1546                 return;
1547         n = search_getsize(globhandle);
1548         for (i = 0; i < n; ++i)
1549         {
1550                 //print(search_getfilename(globhandle, i), "\n");
1551                 f = search_getfilename(globhandle, i);
1552                 PrecachePlayerSounds(f);
1553         }
1554         search_end(globhandle);
1555 }
1556 void precache_all_playermodels(string pattern)
1557 {
1558         float globhandle, i, n;
1559         string f;
1560
1561         globhandle = search_begin(pattern, TRUE, FALSE);
1562         if (globhandle < 0)
1563                 return;
1564         n = search_getsize(globhandle);
1565         for (i = 0; i < n; ++i)
1566         {
1567                 //print(search_getfilename(globhandle, i), "\n");
1568                 f = search_getfilename(globhandle, i);
1569                 precache_playermodel(f);
1570         }
1571         search_end(globhandle);
1572 }
1573
1574 void precache()
1575 {
1576     // gamemode related things
1577     precache_model ("models/misc/chatbubble.spr");
1578     precache_model ("models/misc/teambubble.spr");
1579     if (g_runematch)
1580     {
1581         precache_model ("models/runematch/curse.mdl");
1582         precache_model ("models/runematch/rune.mdl");
1583     }
1584
1585 #ifdef TTURRETS_ENABLED
1586     if (cvar("g_turrets"))
1587         turrets_precash();
1588 #endif
1589
1590     // Precache all player models if desired
1591     if (cvar("sv_precacheplayermodels"))
1592     {
1593         PrecachePlayerSounds("sound/player/default.sounds");
1594         precache_all_playermodels("models/player/*.zym");
1595         precache_all_playermodels("models/player/*.dpm");
1596         precache_all_playermodels("models/player/*.md3");
1597         precache_all_playermodels("models/player/*.psk");
1598         precache_all_playermodels("models/player/*.iqm");
1599     }
1600
1601     if (cvar("sv_defaultcharacter"))
1602     {
1603         string s;
1604         s = cvar_string("sv_defaultplayermodel_red");
1605         if (s != "")
1606             precache_playermodel(s);
1607         s = cvar_string("sv_defaultplayermodel_blue");
1608         if (s != "")
1609             precache_playermodel(s);
1610         s = cvar_string("sv_defaultplayermodel_yellow");
1611         if (s != "")
1612             precache_playermodel(s);
1613         s = cvar_string("sv_defaultplayermodel_pink");
1614         if (s != "")
1615             precache_playermodel(s);
1616         s = cvar_string("sv_defaultplayermodel");
1617         if (s != "")
1618             precache_playermodel(s);
1619     }
1620
1621     if (g_footsteps)
1622     {
1623         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1624         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1625     }
1626
1627     // gore and miscellaneous sounds
1628     //precache_sound ("misc/h2ohit.wav");
1629     precache_model ("models/hook.md3");
1630     precache_sound ("misc/armorimpact.wav");
1631     precache_sound ("misc/bodyimpact1.wav");
1632     precache_sound ("misc/bodyimpact2.wav");
1633     precache_sound ("misc/gib.wav");
1634     precache_sound ("misc/gib_splat01.wav");
1635     precache_sound ("misc/gib_splat02.wav");
1636     precache_sound ("misc/gib_splat03.wav");
1637     precache_sound ("misc/gib_splat04.wav");
1638     precache_sound ("misc/hit.wav");
1639         precache_sound ("misc/typehit.wav");
1640     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1641     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1642     precache_sound ("misc/null.wav");
1643     precache_sound ("misc/spawn.wav");
1644     precache_sound ("misc/talk.wav");
1645     precache_sound ("misc/teleport.wav");
1646     precache_sound ("misc/poweroff.wav");
1647     precache_sound ("player/lava.wav");
1648     precache_sound ("player/slime.wav");
1649
1650     if (g_jetpack)
1651         precache_sound ("misc/jetpack_fly.wav");
1652
1653     precache_model ("models/sprites/0.spr32");
1654     precache_model ("models/sprites/1.spr32");
1655     precache_model ("models/sprites/2.spr32");
1656     precache_model ("models/sprites/3.spr32");
1657     precache_model ("models/sprites/4.spr32");
1658     precache_model ("models/sprites/5.spr32");
1659     precache_model ("models/sprites/6.spr32");
1660     precache_model ("models/sprites/7.spr32");
1661     precache_model ("models/sprites/8.spr32");
1662     precache_model ("models/sprites/9.spr32");
1663     precache_model ("models/sprites/10.spr32");
1664
1665     // common weapon precaches
1666     precache_sound ("weapons/weapon_switch.wav");
1667     precache_sound ("weapons/weaponpickup.wav");
1668     precache_sound ("weapons/unavailable.wav");
1669     precache_sound ("weapons/dryfire.wav");
1670     if (g_grappling_hook)
1671     {
1672         precache_sound ("weapons/hook_fire.wav"); // hook
1673         precache_sound ("weapons/hook_impact.wav"); // hook
1674     }
1675
1676     if(cvar("sv_precacheweapons"))
1677     {
1678         //precache weapon models/sounds
1679         local float wep;
1680         wep = WEP_FIRST;
1681         while (wep <= WEP_LAST)
1682         {
1683             weapon_action(wep, WR_PRECACHE);
1684             wep = wep + 1;
1685         }
1686     }
1687
1688     precache_model("models/elaser.mdl");
1689     precache_model("models/laser.mdl");
1690     precache_model("models/ebomb.mdl");
1691
1692 #if 0
1693     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1694
1695     if (!self.noise && self.music) // quake 3 uses the music field
1696         self.noise = self.music;
1697
1698     // plays music for the level if there is any
1699     if (self.noise)
1700     {
1701         precache_sound (self.noise);
1702         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1703     }
1704 #endif
1705 }
1706
1707 // sorry, but using \ in macros breaks line numbers
1708 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1709 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1710 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1711
1712 // WARNING: this kills the trace globals
1713 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1714 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1715
1716 #define INITPRIO_FIRST              0
1717 #define INITPRIO_GAMETYPE           0
1718 #define INITPRIO_GAMETYPE_FALLBACK  1
1719 #define INITPRIO_FINDTARGET        10
1720 #define INITPRIO_DROPTOFLOOR       20
1721 #define INITPRIO_SETLOCATION       90
1722 #define INITPRIO_LINKDOORS         91
1723 #define INITPRIO_LAST              99
1724
1725 .void(void) initialize_entity;
1726 .float initialize_entity_order;
1727 .entity initialize_entity_next;
1728 entity initialize_entity_first;
1729
1730 void make_safe_for_remove(entity e)
1731 {
1732     if (e.initialize_entity)
1733     {
1734         entity ent, prev;
1735         for (ent = initialize_entity_first; ent; )
1736         {
1737             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1738             {
1739                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1740                 // skip it in linked list
1741                 if (prev)
1742                 {
1743                     prev.initialize_entity_next = ent.initialize_entity_next;
1744                     ent = prev.initialize_entity_next;
1745                 }
1746                 else
1747                 {
1748                     initialize_entity_first = ent.initialize_entity_next;
1749                     ent = initialize_entity_first;
1750                 }
1751             }
1752             else
1753             {
1754                 prev = ent;
1755                 ent = ent.initialize_entity_next;
1756             }
1757         }
1758     }
1759 }
1760
1761 void objerror(string s)
1762 {
1763     make_safe_for_remove(self);
1764     objerror_builtin(s);
1765 }
1766
1767 void remove_unsafely(entity e)
1768 {
1769     remove_builtin(e);
1770 }
1771
1772 void remove_safely(entity e)
1773 {
1774     make_safe_for_remove(e);
1775     remove_builtin(e);
1776 }
1777
1778 void InitializeEntity(entity e, void(void) func, float order)
1779 {
1780     entity prev, cur;
1781
1782     if (!e || e.initialize_entity)
1783     {
1784         // make a proxy initializer entity
1785         entity e_old;
1786         e_old = e;
1787         e = spawn();
1788         e.classname = "initialize_entity";
1789         e.enemy = e_old;
1790     }
1791
1792     e.initialize_entity = func;
1793     e.initialize_entity_order = order;
1794
1795     cur = initialize_entity_first;
1796     for (;;)
1797     {
1798         if (!cur || cur.initialize_entity_order > order)
1799         {
1800             // insert between prev and cur
1801             if (prev)
1802                 prev.initialize_entity_next = e;
1803             else
1804                 initialize_entity_first = e;
1805             e.initialize_entity_next = cur;
1806             return;
1807         }
1808         prev = cur;
1809         cur = cur.initialize_entity_next;
1810     }
1811 }
1812 void InitializeEntitiesRun()
1813 {
1814     entity startoflist;
1815     startoflist = initialize_entity_first;
1816     initialize_entity_first = world;
1817     for (self = startoflist; self; )
1818     {
1819         entity e;
1820         var void(void) func;
1821         e = self.initialize_entity_next;
1822         func = self.initialize_entity;
1823         self.initialize_entity_order = 0;
1824         self.initialize_entity = func_null;
1825         self.initialize_entity_next = world;
1826         if (self.classname == "initialize_entity")
1827         {
1828             entity e_old;
1829             e_old = self.enemy;
1830             remove_builtin(self);
1831             self = e_old;
1832         }
1833         //dprint("Delayed initialization: ", self.classname, "\n");
1834         func();
1835         self = e;
1836     }
1837 }
1838
1839 .float uncustomizeentityforclient_set;
1840 .void(void) uncustomizeentityforclient;
1841 void(void) SUB_Nullpointer = #0;
1842 void UncustomizeEntitiesRun()
1843 {
1844     entity oldself;
1845     oldself = self;
1846     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1847         self.uncustomizeentityforclient();
1848     self = oldself;
1849 }
1850 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1851 {
1852     e.customizeentityforclient = customizer;
1853     e.uncustomizeentityforclient = uncustomizer;
1854     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1855 }
1856
1857 .float nottargeted;
1858 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1859
1860 void() SUB_Remove;
1861 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1862 {
1863     vector mi, ma;
1864
1865     if (e.classname == "")
1866         e.classname = "net_linked";
1867
1868     if (e.model == "" || self.modelindex == 0)
1869     {
1870         mi = e.mins;
1871         ma = e.maxs;
1872         setmodel(e, "null");
1873         setsize(e, mi, ma);
1874     }
1875
1876     e.SendEntity = sendfunc;
1877     e.SendFlags = 0xFFFFFF;
1878
1879     if (!docull)
1880         e.effects |= EF_NODEPTHTEST;
1881
1882     if (dt)
1883     {
1884         e.nextthink = time + dt;
1885         e.think = SUB_Remove;
1886     }
1887 }
1888
1889 void adaptor_think2touch()
1890 {
1891     entity o;
1892     o = other;
1893     other = world;
1894     self.touch();
1895     other = o;
1896 }
1897
1898 void adaptor_think2use()
1899 {
1900     entity o, a;
1901     o = other;
1902     a = activator;
1903     activator = world;
1904     other = world;
1905     self.use();
1906     other = o;
1907     activator = a;
1908 }
1909
1910 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1911 {
1912         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1913                 self.projectiledeathtype |= HITTYPE_SPLASH;
1914         adaptor_think2use();
1915 }
1916
1917 // deferred dropping
1918 void DropToFloor_Handler()
1919 {
1920     droptofloor_builtin();
1921     self.dropped_origin = self.origin;
1922 }
1923
1924 void droptofloor()
1925 {
1926     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1927 }
1928
1929
1930
1931 float trace_hits_box_a0, trace_hits_box_a1;
1932
1933 float trace_hits_box_1d(float end, float thmi, float thma)
1934 {
1935     if (end == 0)
1936     {
1937         // just check if x is in range
1938         if (0 < thmi)
1939             return FALSE;
1940         if (0 > thma)
1941             return FALSE;
1942     }
1943     else
1944     {
1945         // do the trace with respect to x
1946         // 0 -> end has to stay in thmi -> thma
1947         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1948         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1949         if (trace_hits_box_a0 > trace_hits_box_a1)
1950             return FALSE;
1951     }
1952     return TRUE;
1953 }
1954
1955 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1956 {
1957     end -= start;
1958     thmi -= start;
1959     thma -= start;
1960     // now it is a trace from 0 to end
1961
1962     trace_hits_box_a0 = 0;
1963     trace_hits_box_a1 = 1;
1964
1965     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1966         return FALSE;
1967     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1968         return FALSE;
1969     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1970         return FALSE;
1971
1972     return TRUE;
1973 }
1974
1975 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1976 {
1977     return trace_hits_box(start, end, thmi - ma, thma - mi);
1978 }
1979
1980 float SUB_NoImpactCheck()
1981 {
1982         // zero hitcontents = this is not the real impact, but either the
1983         // mirror-impact of something hitting the projectile instead of the
1984         // projectile hitting the something, or a touchareagrid one. Neither of
1985         // these stop the projectile from moving, so...
1986         if(trace_dphitcontents == 0)
1987         {
1988                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1989                 checkclient();
1990         }
1991     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1992         return 1;
1993     if (other == world && self.size != '0 0 0')
1994     {
1995         vector tic;
1996         tic = self.velocity * sys_frametime;
1997         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1998         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1999         if (trace_fraction >= 1)
2000         {
2001             dprint("Odd... did not hit...?\n");
2002         }
2003         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2004         {
2005             dprint("Detected and prevented the sky-grapple bug.\n");
2006             return 1;
2007         }
2008     }
2009
2010     return 0;
2011 }
2012
2013 #define SUB_OwnerCheck() (other && (other == self.owner))
2014
2015 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2016 {
2017         if(SUB_OwnerCheck())
2018                 return TRUE;
2019         if(SUB_NoImpactCheck())
2020         {
2021                 remove(self);
2022                 return TRUE;
2023         }
2024         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2025                 UpdateCSQCProjectileNextFrame(self);
2026         return FALSE;
2027 }
2028 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2029
2030 float MAX_IPBAN_URIS           = 16;
2031                               
2032 float URI_GET_DISCARD          = 0;
2033 float URI_GET_IPBAN            = 1;
2034 float URI_GET_IPBAN_END        = 16;
2035 float URI_GET_PLAYERSTATS_SENT = 17;
2036
2037 void URI_Get_Callback(float id, float status, string data)
2038 {
2039     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2040     dprint(data);
2041     dprint("\nEnd of data.\n");
2042
2043     if (id == URI_GET_DISCARD)
2044     {
2045         // discard
2046     }
2047     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2048     {
2049         // online ban list
2050         OnlineBanList_URI_Get_Callback(id, status, data);
2051     }
2052     else if (id == URI_GET_PLAYERSTATS_SENT)
2053     {
2054         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2055     }
2056     else
2057     {
2058         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2059     }
2060 }
2061
2062 void print_to(entity e, string s)
2063 {
2064     if (e)
2065         sprint(e, strcat(s, "\n"));
2066     else
2067         print(s, "\n");
2068 }
2069
2070 string uid2name(string myuid) {
2071         string s;
2072         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2073         
2074         if(s == "")
2075                 s = "^1Unregistered Player";
2076         return s;
2077 }
2078
2079 float race_readTime(string map, float pos)
2080 {
2081         string rr;
2082         if(g_cts)
2083                 rr = CTS_RECORD;
2084         else
2085                 rr = RACE_RECORD;
2086
2087         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2088 }
2089
2090 string race_readUID(string map, float pos)
2091 {
2092         string rr;
2093         if(g_cts)
2094                 rr = CTS_RECORD;
2095         else
2096                 rr = RACE_RECORD;
2097
2098         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2099 }
2100
2101 float race_readPos(string map, float t) {
2102         float i;
2103         for (i = 1; i <= RANKINGS_CNT; ++i)
2104                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2105                         return i;
2106
2107         return 0; // pos is zero if unranked
2108 }
2109
2110 void race_writeTime(string map, float t, string myuid)
2111 {
2112         string rr;
2113         if(g_cts)
2114                 rr = CTS_RECORD;
2115         else
2116                 rr = RACE_RECORD;
2117
2118         float newpos;
2119         newpos = race_readPos(map, t);
2120
2121         float i, prevpos;
2122         for(i = 1; i <= RANKINGS_CNT; ++i)
2123         {
2124                 if(race_readUID(map, i) == myuid)
2125                         prevpos = i;
2126         }
2127         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2128                 for (i = prevpos; i > newpos; --i) {
2129                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2130                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2131                 }
2132         } else { // player has no ranked record yet
2133                 for (i = RANKINGS_CNT; i > newpos; --i) {
2134                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2135                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2136                 }
2137         }
2138
2139         // store new time itself
2140         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2141         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2142 }
2143
2144 string race_readName(string map, float pos)
2145 {
2146         string rr;
2147         if(g_cts)
2148                 rr = CTS_RECORD;
2149         else
2150                 rr = RACE_RECORD;
2151
2152         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2153 }
2154
2155 string race_placeName(float pos) {
2156         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2157         {
2158                 if(mod(pos, 10) == 1)
2159                         return strcat(ftos(pos), "st");
2160                 else if(mod(pos, 10) == 2)
2161                         return strcat(ftos(pos), "nd");
2162                 else if(mod(pos, 10) == 3)
2163                         return strcat(ftos(pos), "rd");
2164                 else
2165                         return strcat(ftos(pos), "th");
2166         }
2167         else
2168                 return strcat(ftos(pos), "th");
2169 }
2170 string getrecords(float page) // 50 records per page
2171 {
2172     float rec;
2173     string h;
2174     float r;
2175     float i;
2176     string s;
2177
2178     rec = 0;
2179
2180     s = "";
2181
2182     if (g_ctf)
2183     {
2184         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2185         {
2186             if (MapInfo_Get_ByID(i))
2187             {
2188                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2189                 if (r == 0)
2190                     continue;
2191                 // TODO: uid2name
2192                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2193                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2194                 ++rec;
2195             }
2196         }
2197     }
2198
2199     if (g_race)
2200     {
2201         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2202         {
2203             if (MapInfo_Get_ByID(i))
2204             {
2205                 r = race_readTime(MapInfo_Map_bspname, 1);
2206                 if (r == 0)
2207                     continue;
2208                 h = race_readName(MapInfo_Map_bspname, 1);
2209                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2210                 ++rec;
2211             }
2212         }
2213     }
2214
2215     if (g_cts)
2216     {
2217         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2218         {
2219             if (MapInfo_Get_ByID(i))
2220             {
2221                 r = race_readTime(MapInfo_Map_bspname, 1);
2222                 if (r == 0)
2223                     continue;
2224                 h = race_readName(MapInfo_Map_bspname, 1);
2225                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2226                 ++rec;
2227             }
2228         }
2229     }
2230
2231     MapInfo_ClearTemps();
2232
2233     if (s == "" && page == 0)
2234         return "No records are available on this server.\n";
2235     else
2236         return s;
2237 }
2238
2239 string getrankings()
2240 {
2241     string n;
2242     float t;
2243     float i;
2244     string s;
2245     string p;
2246     string map;
2247
2248     s = "";
2249
2250     map = GetMapname();
2251
2252     for (i = 1; i <= RANKINGS_CNT; ++i)
2253     {
2254         t = race_readTime(map, i);
2255         if (t == 0)
2256             continue;
2257         n = race_readName(map, i);
2258         p = race_placeName(i);
2259         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2260     }
2261
2262     MapInfo_ClearTemps();
2263
2264     if (s == "")
2265         return strcat("No records are available for the map: ", map, "\n");
2266     else
2267         return strcat("Records for ", map, ":\n", s);
2268 }
2269
2270 #define LADDER_FIRSTPOINT 100
2271 #define LADDER_CNT 10
2272         // position X still gives LADDER_FIRSTPOINT/X points
2273 #define LADDER_SIZE 30
2274         // ladder shows the top X players
2275 string top_uids[LADDER_SIZE];
2276 float top_scores[LADDER_SIZE];
2277 string getladder()
2278 {
2279     float i, j, k, uidcnt;
2280     string s, temp_s;
2281
2282     s = "";
2283     temp_s = "";
2284
2285     string rr;
2286     if(g_cts)
2287         rr = CTS_RECORD;
2288     else
2289         rr = RACE_RECORD;
2290
2291     string myuid;
2292
2293     for (k = 0; k < MapInfo_count; ++k)
2294     {
2295         if (MapInfo_Get_ByID(k))
2296         {
2297                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2298                         if(i == 0) // speed award
2299                         {
2300                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2301                                         continue;
2302
2303                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2304                         }
2305                         else // normal record, if it exists (else break)
2306                         {
2307                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2308                                         continue;
2309
2310                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2311                         }
2312
2313                         // string s contains:
2314                         // arg 0 = # of speed recs
2315                         // arg 1 = # of 1st place recs
2316                         // arg 2 = # of 2nd place recs
2317                         // ... etc
2318                         // LADDER_CNT+1 = total points
2319
2320                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2321                         if (temp_s == "")
2322                         {
2323                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2324                             ++uidcnt;
2325                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2326                             {
2327                                 if(j != LADDER_CNT + 1)
2328                                     temp_s = strcat(temp_s, "0 ");
2329                                 else
2330                                     temp_s = strcat(temp_s, "0");
2331                             }
2332                         }
2333
2334                         tokenize_console(temp_s);
2335                         s = "";
2336
2337                         if(i == 0) // speed award
2338                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2339                             {
2340                                 if(j == 0) // speed award
2341                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2342                                 else
2343                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2344                             }
2345                         else // record
2346                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2347                             {
2348                                 if(j == 0)
2349                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2350                                 else if(j == i) // wanted rec!
2351                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2352                                 else
2353                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2354                             }
2355
2356                         // total points are (by default) calculated like this:
2357                         // speedrec = floor(100 / 10) = 10 points
2358                         // 1st place = floor(100 / 1) = 100 points
2359                         // 2nd place = floor(100 / 2) = 50 points
2360                         // 3rd place = floor(100 / 3) = 33 points
2361                         // 4th place = floor(100 / 4) = 25 points
2362                         // 5th place = floor(100 / 5) = 20 points
2363                         // ... etc
2364
2365                         if(i == 0)
2366                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2367                         else
2368                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2369
2370                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2371                 }
2372         }
2373     }
2374
2375     float thiscnt;
2376     string thisuid;
2377     for (i = 0; i <= uidcnt; ++i) // for each known uid
2378     {
2379         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2380         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2381         tokenize_console(temp_s);
2382         thiscnt = stof(argv(LADDER_CNT+1));
2383
2384         if(thiscnt > top_scores[LADDER_SIZE-1])
2385         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2386         {
2387             if(thiscnt > top_scores[j])
2388             {
2389                 for (k = LADDER_SIZE-1; k >= j; --k)
2390                 {
2391                     top_uids[k] = top_uids[k-1];
2392                     top_scores[k] = top_scores[k-1];
2393                 }
2394                 top_uids[j] = thisuid;
2395                 top_scores[j] = thiscnt;
2396                 break;
2397             }
2398         }
2399     }
2400
2401     s = "^3-----------------------\n\n";
2402
2403     s = strcat(s, "Pos ^3|");
2404     s = strcat(s, " ^7Total  ^3|");
2405     for (i = 1; i <= LADDER_CNT; ++i)
2406     {
2407         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2408     }
2409     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2410
2411     s = strcat(s, "\n^3----+--------");
2412     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2413     {
2414         s = strcat(s, "+-----");
2415     }
2416 #if LADDER_CNT > 9
2417     for (i = 1; i <= LADDER_CNT - 9; ++i)
2418     {
2419         s = strcat(s, "+------");
2420     }
2421 #endif
2422
2423     s = strcat(s, "+--------------+--------------------\n");
2424
2425     for (i = 0; i < LADDER_SIZE; ++i)
2426     {
2427         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2428         tokenize_console(temp_s);
2429         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2430             continue;
2431         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2432         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2433         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2434         {
2435             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2436         }
2437 #if LADDER_CNT > 9
2438         for (j = 10; j <= LADDER_CNT; ++j)
2439         {
2440             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2441         }
2442 #endif
2443
2444         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2445         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2446     }
2447
2448     MapInfo_ClearTemps();
2449
2450     if (s == "")
2451         return "No ladder on this server!\n";
2452     else
2453         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2454 }
2455
2456
2457 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2458 {
2459     float m, i;
2460     vector start, org, delta, end, enddown, mstart;
2461
2462     m = e.dphitcontentsmask;
2463     e.dphitcontentsmask = goodcontents | badcontents;
2464
2465     org = world.mins;
2466     delta = world.maxs - world.mins;
2467
2468     for (i = 0; i < attempts; ++i)
2469     {
2470         start_x = org_x + random() * delta_x;
2471         start_y = org_y + random() * delta_y;
2472         start_z = org_z + random() * delta_z;
2473
2474         // rule 1: start inside world bounds, and outside
2475         // solid, and don't start from somewhere where you can
2476         // fall down to evil
2477         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2478         if (trace_fraction >= 1)
2479             continue;
2480         if (trace_startsolid)
2481             continue;
2482         if (trace_dphitcontents & badcontents)
2483             continue;
2484         if (trace_dphitq3surfaceflags & badsurfaceflags)
2485             continue;
2486
2487         // rule 2: if we are too high, lower the point
2488         if (trace_fraction * delta_z > maxaboveground)
2489             start = trace_endpos + '0 0 1' * maxaboveground;
2490         enddown = trace_endpos;
2491
2492         // rule 3: make sure we aren't outside the map. This only works
2493         // for somewhat well formed maps. A good rule of thumb is that
2494         // the map should have a convex outside hull.
2495         // these can be traceLINES as we already verified the starting box
2496         mstart = start + 0.5 * (e.mins + e.maxs);
2497         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2498         if (trace_fraction >= 1)
2499             continue;
2500         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2501         if (trace_fraction >= 1)
2502             continue;
2503         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2504         if (trace_fraction >= 1)
2505             continue;
2506         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2507         if (trace_fraction >= 1)
2508             continue;
2509         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2510         if (trace_fraction >= 1)
2511             continue;
2512
2513         // find a random vector to "look at"
2514         end_x = org_x + random() * delta_x;
2515         end_y = org_y + random() * delta_y;
2516         end_z = org_z + random() * delta_z;
2517         end = start + normalize(end - start) * vlen(delta);
2518
2519         // rule 4: start TO end must not be too short
2520         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2521         if (trace_startsolid)
2522             continue;
2523         if (trace_fraction < minviewdistance / vlen(delta))
2524             continue;
2525
2526         // rule 5: don't want to look at sky
2527         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2528             continue;
2529
2530         // rule 6: we must not end up in trigger_hurt
2531         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2532         {
2533             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2534             continue;
2535         }
2536
2537         break;
2538     }
2539
2540     e.dphitcontentsmask = m;
2541
2542     if (i < attempts)
2543     {
2544         setorigin(e, start);
2545         e.angles = vectoangles(end - start);
2546         dprint("Needed ", ftos(i + 1), " attempts\n");
2547         return TRUE;
2548     }
2549     else
2550         return FALSE;
2551 }
2552
2553 float zcurveparticles_effectno;
2554 vector zcurveparticles_start;
2555 float zcurveparticles_spd;
2556
2557 void endzcurveparticles()
2558 {
2559         if(zcurveparticles_effectno)
2560         {
2561                 // terminator
2562                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2563         }
2564         zcurveparticles_effectno = 0;
2565 }
2566
2567 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2568 {
2569         spd = bound(0, floor(spd / 16), 32767);
2570         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2571         {
2572                 endzcurveparticles();
2573                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2574                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2575                 WriteShort(MSG_BROADCAST, effectno);
2576                 WriteCoord(MSG_BROADCAST, start_x);
2577                 WriteCoord(MSG_BROADCAST, start_y);
2578                 WriteCoord(MSG_BROADCAST, start_z);
2579                 zcurveparticles_effectno = effectno;
2580                 zcurveparticles_start = start;
2581         }
2582         else
2583                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2584         WriteCoord(MSG_BROADCAST, end_x);
2585         WriteCoord(MSG_BROADCAST, end_y);
2586         WriteCoord(MSG_BROADCAST, end_z);
2587         WriteCoord(MSG_BROADCAST, end_dz);
2588         zcurveparticles_spd = spd;
2589 }
2590
2591 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2592 {
2593         float end_dz;
2594         vector vecxy, velxy;
2595
2596         vecxy = end - start;
2597         vecxy_z = 0;
2598         velxy = vel;
2599         velxy_z = 0;
2600
2601         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2602         {
2603                 endzcurveparticles();
2604                 trailparticles(world, effectno, start, end);
2605                 return;
2606         }
2607
2608         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2609         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2610 }
2611
2612 string GetGametype(); // g_world.qc
2613 void write_recordmarker(entity pl, float tstart, float dt)
2614 {
2615     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2616
2617     // also write a marker into demo files for demotc-race-record-extractor to find
2618     stuffcmd(pl,
2619              strcat(
2620                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2621                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2622 }
2623
2624 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2625 {
2626         switch(algn)
2627         {
2628                 case 1: // right
2629                         break;
2630
2631                 case 2: // left
2632                         vecs_y = -vecs_y;
2633                         break;
2634
2635                 default:
2636                 case 3:
2637                         if(allowcenter) // 2: allow center handedness
2638                         {
2639                                 // center
2640                                 vecs_y = 0;
2641                                 vecs_z -= 2;
2642                         }
2643                         else
2644                         {
2645                                 // right
2646                         }
2647                         break;
2648
2649                 case 4:
2650                         if(allowcenter) // 2: allow center handedness
2651                         {
2652                                 // center
2653                                 vecs_y = 0;
2654                                 vecs_z -= 2;
2655                         }
2656                         else
2657                         {
2658                                 // left
2659                                 vecs_y = -vecs_y;
2660                         }
2661                         break;
2662         }
2663         return vecs;
2664 }
2665
2666 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2667 {
2668         string s;
2669         vector v;
2670
2671         if (cvar("g_shootfromeye"))
2672         {
2673                 if (visual)
2674                 {
2675                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2676                 }
2677                 else
2678                 {
2679                         vecs_y = 0;
2680                         vecs_z = 0;
2681                 }
2682         }
2683         else if (cvar("g_shootfromcenter"))
2684         {
2685                 if (visual)
2686                 {
2687                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2688                 }
2689                 else
2690                 {
2691                         vecs_y = 0;
2692                         vecs_z -= 2;
2693                 }
2694         }
2695         else if ((s = cvar_string("g_shootfromfixedorigin")) != "")
2696         {
2697                 v = stov(s);
2698                 if (y_is_right)
2699                         v_y = -v_y;
2700                 if (v_x != 0)
2701                         vecs_x = v_x;
2702                 vecs_y = v_y;
2703                 vecs_z = v_z;
2704         }
2705         else if (cvar("g_shootfromclient"))
2706         {
2707                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (cvar("g_shootfromclient") >= 2), algn);
2708         }
2709         return vecs;
2710 }
2711
2712 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2713 {
2714         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2715 }
2716
2717
2718 void attach_sameorigin(entity e, entity to, string tag)
2719 {
2720     vector org, t_forward, t_left, t_up, e_forward, e_up;
2721     vector org0, ang0;
2722     float tagscale;
2723
2724     ang0 = e.angles;
2725     org0 = e.origin;
2726
2727     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2728     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2729     t_forward = v_forward * tagscale;
2730     t_left = v_right * -tagscale;
2731     t_up = v_up * tagscale;
2732
2733     e.origin_x = org * t_forward;
2734     e.origin_y = org * t_left;
2735     e.origin_z = org * t_up;
2736
2737     // current forward and up directions
2738     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2739                 e.angles = AnglesTransform_FromVAngles(e.angles);
2740         else
2741                 e.angles = AnglesTransform_FromAngles(e.angles);
2742     fixedmakevectors(e.angles);
2743
2744     // untransform forward, up!
2745     e_forward_x = v_forward * t_forward;
2746     e_forward_y = v_forward * t_left;
2747     e_forward_z = v_forward * t_up;
2748     e_up_x = v_up * t_forward;
2749     e_up_y = v_up * t_left;
2750     e_up_z = v_up * t_up;
2751
2752     e.angles = fixedvectoangles2(e_forward, e_up);
2753     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2754                 e.angles = AnglesTransform_ToVAngles(e.angles);
2755         else
2756                 e.angles = AnglesTransform_ToAngles(e.angles);
2757
2758     setattachment(e, to, tag);
2759     setorigin(e, e.origin);
2760 }
2761
2762 void detach_sameorigin(entity e)
2763 {
2764     vector org;
2765     org = gettaginfo(e, 0);
2766     e.angles = fixedvectoangles2(v_forward, v_up);
2767     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2768                 e.angles = AnglesTransform_ToVAngles(e.angles);
2769         else
2770                 e.angles = AnglesTransform_ToAngles(e.angles);
2771     setorigin(e, org);
2772     setattachment(e, world, "");
2773     setorigin(e, e.origin);
2774 }
2775
2776 void follow_sameorigin(entity e, entity to)
2777 {
2778     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2779     e.aiment = to; // make the hole follow bmodel
2780     e.punchangle = to.angles; // the original angles of bmodel
2781     e.view_ofs = e.origin - to.origin; // relative origin
2782     e.v_angle = e.angles - to.angles; // relative angles
2783 }
2784
2785 void unfollow_sameorigin(entity e)
2786 {
2787     e.movetype = MOVETYPE_NONE;
2788 }
2789
2790 entity gettaginfo_relative_ent;
2791 vector gettaginfo_relative(entity e, float tag)
2792 {
2793     if (!gettaginfo_relative_ent)
2794     {
2795         gettaginfo_relative_ent = spawn();
2796         gettaginfo_relative_ent.effects = EF_NODRAW;
2797     }
2798     gettaginfo_relative_ent.model = e.model;
2799     gettaginfo_relative_ent.modelindex = e.modelindex;
2800     gettaginfo_relative_ent.frame = e.frame;
2801     return gettaginfo(gettaginfo_relative_ent, tag);
2802 }
2803
2804 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2805 {
2806     float p;
2807     p = pow(2, chan);
2808     if (pl.soundentity.cnt & p)
2809         return;
2810     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2811     pl.soundentity.cnt |= p;
2812 }
2813
2814 void SoundEntity_StopSound(entity pl, float chan)
2815 {
2816     float p;
2817     p = pow(2, chan);
2818     if (pl.soundentity.cnt & p)
2819     {
2820         stopsoundto(MSG_ALL, pl.soundentity, chan);
2821         pl.soundentity.cnt &~= p;
2822     }
2823 }
2824
2825 void SoundEntity_Attach(entity pl)
2826 {
2827     pl.soundentity = spawn();
2828     pl.soundentity.classname = "soundentity";
2829     pl.soundentity.owner = pl;
2830     setattachment(pl.soundentity, pl, "");
2831     setmodel(pl.soundentity, "null");
2832 }
2833
2834 void SoundEntity_Detach(entity pl)
2835 {
2836     float i;
2837     for (i = 0; i <= 7; ++i)
2838         SoundEntity_StopSound(pl, i);
2839 }
2840
2841
2842 float ParseCommandPlayerSlotTarget_firsttoken;
2843 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2844 {
2845     string s;
2846     entity e, head;
2847     float n;
2848
2849     s = string_null;
2850
2851     ParseCommandPlayerSlotTarget_firsttoken = -1;
2852
2853     if (tokens > idx)
2854     {
2855         if (substring(argv(idx), 0, 1) == "#")
2856         {
2857             s = substring(argv(idx), 1, -1);
2858             ++idx;
2859             if (s == "")
2860                 if (tokens > idx)
2861                 {
2862                     s = argv(idx);
2863                     ++idx;
2864                 }
2865                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2866             if (s == ftos(stof(s)))
2867             {
2868                 e = edict_num(stof(s));
2869                 if (e.flags & FL_CLIENT)
2870                     return e;
2871             }
2872         }
2873         else
2874         {
2875             // it must be a nick name
2876             s = argv(idx);
2877             ++idx;
2878                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2879
2880             n = 0;
2881             FOR_EACH_CLIENT(head)
2882             if (head.netname == s)
2883             {
2884                 e = head;
2885                 ++n;
2886             }
2887             if (n == 1)
2888                 return e;
2889
2890             s = strdecolorize(s);
2891             n = 0;
2892             FOR_EACH_CLIENT(head)
2893             if (strdecolorize(head.netname) == s)
2894             {
2895                 e = head;
2896                 ++n;
2897             }
2898             if (n == 1)
2899                 return e;
2900         }
2901     }
2902
2903     return world;
2904 }
2905
2906 .float scale2;
2907
2908 float modeleffect_SendEntity(entity to, float sf)
2909 {
2910         float f;
2911         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2912
2913         f = 0;
2914         if(self.velocity != '0 0 0')
2915                 f |= 1;
2916         if(self.angles != '0 0 0')
2917                 f |= 2;
2918         if(self.avelocity != '0 0 0')
2919                 f |= 4;
2920
2921         WriteByte(MSG_ENTITY, f);
2922         WriteShort(MSG_ENTITY, self.modelindex);
2923         WriteByte(MSG_ENTITY, self.skin);
2924         WriteByte(MSG_ENTITY, self.frame);
2925         WriteCoord(MSG_ENTITY, self.origin_x);
2926         WriteCoord(MSG_ENTITY, self.origin_y);
2927         WriteCoord(MSG_ENTITY, self.origin_z);
2928         if(f & 1)
2929         {
2930                 WriteCoord(MSG_ENTITY, self.velocity_x);
2931                 WriteCoord(MSG_ENTITY, self.velocity_y);
2932                 WriteCoord(MSG_ENTITY, self.velocity_z);
2933         }
2934         if(f & 2)
2935         {
2936                 WriteCoord(MSG_ENTITY, self.angles_x);
2937                 WriteCoord(MSG_ENTITY, self.angles_y);
2938                 WriteCoord(MSG_ENTITY, self.angles_z);
2939         }
2940         if(f & 4)
2941         {
2942                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2943                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2944                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2945         }
2946         WriteShort(MSG_ENTITY, self.scale * 256.0);
2947         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2948         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2949         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2950         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2951
2952         return TRUE;
2953 }
2954
2955 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2956 {
2957         entity e;
2958         float sz;
2959         e = spawn();
2960         e.classname = "modeleffect";
2961         setmodel(e, m);
2962         e.frame = f;
2963         setorigin(e, o);
2964         e.velocity = v;
2965         e.angles = ang;
2966         e.avelocity = angv;
2967         e.alpha = a;
2968         e.teleport_time = t1;
2969         e.fade_time = t2;
2970         e.skin = s;
2971         if(s0 >= 0)
2972                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2973         else
2974                 e.scale = -s0;
2975         if(s2 >= 0)
2976                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2977         else
2978                 e.scale2 = -s2;
2979         sz = max(e.scale, e.scale2);
2980         setsize(e, e.mins * sz, e.maxs * sz);
2981         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2982 }
2983
2984 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2985 {
2986         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2987 }
2988
2989 float randombit(float bits)
2990 {
2991         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2992                 return bits;
2993
2994         float n, f, b, r;
2995
2996         r = random();
2997         b = 0;
2998         n = 0;
2999
3000         for(f = 1; f <= bits; f *= 2)
3001         {
3002                 if(bits & f)
3003                 {
3004                         ++n;
3005                         r *= n;
3006                         if(r <= 1)
3007                                 b = f;
3008                         else
3009                                 r = (r - 1) / (n - 1);
3010                 }
3011         }
3012
3013         return b;
3014 }
3015
3016 float randombits(float bits, float k, float error_return)
3017 {
3018         float r;
3019         r = 0;
3020         while(k > 0 && bits != r)
3021         {
3022                 r += randombit(bits - r);
3023                 --k;
3024         }
3025         if(error_return)
3026                 if(k > 0)
3027                         return -1; // all
3028         return r;
3029 }
3030
3031 void randombit_test(float bits, float iter)
3032 {
3033         while(iter > 0)
3034         {
3035                 print(ftos(randombit(bits)), "\n");
3036                 --iter;
3037         }
3038 }
3039
3040 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3041 {
3042         if(halflifedist > 0)
3043                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3044         else if(halflifedist < 0)
3045                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3046         else
3047                 return 1;
3048 }
3049
3050
3051
3052
3053 #ifdef RELEASE
3054 #define cvar_string_normal cvar_string_builtin
3055 #define cvar_normal cvar_builtin
3056 #else
3057 string cvar_string_normal(string n)
3058 {
3059         if not(cvar_type(n) & 1)
3060                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3061         return cvar_string_builtin(n);
3062 }
3063
3064 float cvar_normal(string n)
3065 {
3066         return stof(cvar_string_normal(n));
3067 }
3068 #endif
3069 #define cvar_set_normal cvar_set_builtin
3070
3071 void defer_think()
3072 {
3073     entity oself;
3074
3075     oself           = self;
3076     self            = self.owner;
3077     oself.think     = SUB_Remove;
3078     oself.nextthink = time;
3079
3080     oself.use();
3081 }
3082
3083 /*
3084     Execute func() after time + fdelay.
3085     self when func is executed = self when defer is called
3086 */
3087 void defer(float fdelay, void() func)
3088 {
3089     entity e;
3090
3091     e           = spawn();
3092     e.owner     = self;
3093     e.use       = func;
3094     e.think     = defer_think;
3095     e.nextthink = time + fdelay;
3096 }