qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include "mutators/_mod.qh"
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "weapons/accuracy.qh"
  13 #include "weapons/csqcprojectile.qh"
  14 #include "weapons/selection.qh"
  15 #include "../common/command/_mod.qh"
  16 #include "../common/constants.qh"
  17 #include <common/net_linked.qh>
  18 #include "../common/deathtypes/all.qh"
  19 #include "../common/mapinfo.qh"
  20 #include "../common/notifications/all.qh"
  21 #include "../common/playerstats.qh"
  22 #include "../common/teams.qh"
  23 #include "../common/triggers/subs.qh"
  24 #include "../common/util.qh"
  25 #include "../common/turrets/sv_turrets.qh"
  26 #include <common/weapons/_all.qh>
  27 #include "../common/vehicles/sv_vehicles.qh"
  28 #include "../common/vehicles/vehicle.qh"
  29 #include "../common/items/_mod.qh"
  30 #include "../common/state.qh"
  31 #include "../common/effects/qc/globalsound.qh"
  32 #include "../common/wepent.qh"
  33 #include "../lib/csqcmodel/sv_model.qh"
  34 #include "../lib/warpzone/anglestransform.qh"
  35 #include "../lib/warpzone/server.qh"
  36
  37 void crosshair_trace(entity pl)
  38 {
  39         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  40 }
  41 .bool ctrace_solidchanged;
  42 void crosshair_trace_plusvisibletriggers(entity pl)
  43 {
  44         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  45         {
  46                 if(it.model != "")
  47                 {
  48                         it.solid = SOLID_BSP;
  49                         it.ctrace_solidchanged = true;
  50                         IL_PUSH(g_ctrace_changed, it);
  51                 }
  52         });
  53
  54         crosshair_trace(pl);
  55
  56         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
  57         {
  58                 it.solid = SOLID_TRIGGER;
  59                 it.ctrace_solidchanged = false;
  60         });
  61
  62         IL_CLEAR(g_ctrace_changed);
  63 }
  64 void WarpZone_crosshair_trace(entity pl)
  65 {
  66         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  67 }
  68
  69
  70 void GameLogEcho(string s)
  71 {
  72     string fn;
  73     int matches;
  74
  75     if (autocvar_sv_eventlog_files)
  76     {
  77         if (!logfile_open)
  78         {
  79             logfile_open = true;
  80             matches = autocvar_sv_eventlog_files_counter + 1;
  81             cvar_set("sv_eventlog_files_counter", itos(matches));
  82             fn = ftos(matches);
  83             if (strlen(fn) < 8)
  84                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  85             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  86             logfile = fopen(fn, FILE_APPEND);
  87             fputs(logfile, ":logversion:3\n");
  88         }
  89         if (logfile >= 0)
  90         {
  91             if (autocvar_sv_eventlog_files_timestamps)
  92                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  93             else
  94                 fputs(logfile, strcat(s, "\n"));
  95         }
  96     }
  97     if (autocvar_sv_eventlog_console)
  98     {
  99         dedicated_print(strcat(s, "\n"));
 100     }
 101 }
 102
 103 void GameLogInit()
 104 {
 105     logfile_open = 0;
 106     // will be opened later
 107 }
 108
 109 void GameLogClose()
 110 {
 111     if (logfile_open && logfile >= 0)
 112     {
 113         fclose(logfile);
 114         logfile = -1;
 115     }
 116 }
 117
 118 entity findnearest(vector point, bool checkitems, vector axismod)
 119 {
 120     vector dist;
 121     int num_nearest = 0;
 122
 123     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 124     {
 125         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 126             dist = it.oldorigin;
 127         else
 128             dist = it.origin;
 129         dist = dist - point;
 130         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 131         float len = vlen2(dist);
 132
 133         int l;
 134         for (l = 0; l < num_nearest; ++l)
 135         {
 136             if (len < nearest_length[l])
 137                 break;
 138         }
 139
 140         // now i tells us where to insert at
 141         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 142         if (l < NUM_NEAREST_ENTITIES)
 143         {
 144             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 145             {
 146                 nearest_length[j + 1] = nearest_length[j];
 147                 nearest_entity[j + 1] = nearest_entity[j];
 148             }
 149             nearest_length[l] = len;
 150             nearest_entity[l] = it;
 151             if (num_nearest < NUM_NEAREST_ENTITIES)
 152                 num_nearest = num_nearest + 1;
 153         }
 154     });
 155
 156     // now use the first one from our list that we can see
 157     for (int j = 0; j < num_nearest; ++j)
 158     {
 159         traceline(point, nearest_entity[j].origin, true, NULL);
 160         if (trace_fraction == 1)
 161         {
 162             if (j != 0)
 163                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 164             return nearest_entity[j];
 165         }
 166     }
 167
 168     if (num_nearest == 0)
 169         return NULL;
 170
 171     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 172     /* DEBUGGING CODE:
 173     dprint("Candidates were: ");
 174     for(j = 0; j < num_nearest; ++j)
 175     {
 176         if(j != 0)
 177                 dprint(", ");
 178         dprint(nearest_entity[j].netname);
 179     }
 180     dprint("\n");
 181     */
 182
 183     return nearest_entity[0];
 184 }
 185
 186 string NearestLocation(vector p)
 187 {
 188     string ret = "somewhere";
 189     entity loc = findnearest(p, false, '1 1 1');
 190     if (loc)
 191         ret = loc.message;
 192     else
 193     {
 194         loc = findnearest(p, true, '1 1 4');
 195         if (loc)
 196             ret = loc.netname;
 197     }
 198     return ret;
 199 }
 200
 201 string AmmoNameFromWeaponentity(entity wpn)
 202 {
 203         string ammoitems = "batteries";
 204         switch ((wpn.m_weapon).ammo_type)
 205         {
 206                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 207                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 208                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 209                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 210                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 211                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 212         }
 213         return ammoitems;
 214 }
 215
 216 string formatmessage(entity this, string msg)
 217 {
 218         float p, p1, p2;
 219         float n;
 220         vector cursor;
 221         entity cursor_ent;
 222         string escape;
 223         string replacement;
 224         p = 0;
 225         n = 7;
 226
 227         WarpZone_crosshair_trace(this);
 228         cursor = trace_endpos;
 229         cursor_ent = trace_ent;
 230
 231         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 232         msg = M_ARGV(1, string);
 233
 234         while (1) {
 235                 if (n < 1)
 236                         break; // too many replacements
 237
 238                 n = n - 1;
 239                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 240                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 241
 242                 if (p1 < 0)
 243                         p1 = p2;
 244
 245                 if (p2 < 0)
 246                         p2 = p1;
 247
 248                 p = min(p1, p2);
 249
 250                 if (p < 0)
 251                         break;
 252
 253                 replacement = substring(msg, p, 2);
 254                 escape = substring(msg, p + 1, 1);
 255
 256                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 257
 258                 switch(escape)
 259                 {
 260                         case "%": replacement = "%"; break;
 261                         case "\\":replacement = "\\"; break;
 262                         case "n": replacement = "\n"; break;
 263                         case "a": replacement = ftos(floor(this.armorvalue)); break;
 264                         case "h": replacement = ftos(floor(this.health)); break;
 265                         case "l": replacement = NearestLocation(this.origin); break;
 266                         case "y": replacement = NearestLocation(cursor); break;
 267                         case "d": replacement = NearestLocation(this.death_origin); break;
 268                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 269                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity)); break;
 270                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 271                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 272                         case "S": replacement = ftos(vlen(this.velocity)); break;
 273                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 274                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 275                         default:
 276                         {
 277                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 278                                 replacement = M_ARGV(2, string);
 279                                 break;
 280                         }
 281                 }
 282
 283                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 284                 p = p + strlen(replacement);
 285         }
 286         return msg;
 287 }
 288
 289 /*
 290 =============
 291 GetCvars
 292 =============
 293 Called with:
 294   0:  sends the request
 295   >0: receives a cvar from name=argv(f) value=argv(f+1)
 296 */
 297 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 298 {
 299         if (f < 0)
 300         {
 301                 if (store.(field))
 302                         strunzone(store.(field));
 303                 store.(field) = string_null;
 304         }
 305         else if (f > 0)
 306         {
 307                 if (thisname == name)
 308                 {
 309                         if (store.(field))
 310                                 strunzone(store.(field));
 311                         store.(field) = strzone(argv(f + 1));
 312                 }
 313         }
 314         else
 315                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 316 }
 317 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 318 {
 319         GetCvars_handleString(this, store, thisname, f, field, name);
 320         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 321                 if (thisname == name)
 322                 {
 323                         string s = func(this, strcat1(store.(field)));
 324                         if (s != store.(field))
 325                         {
 326                                 strunzone(store.(field));
 327                                 store.(field) = strzone(s);
 328                         }
 329                 }
 330 }
 331 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 332 {
 333         if (f < 0)
 334         {
 335         }
 336         else if (f > 0)
 337         {
 338                 if (thisname == name)
 339                         store.(field) = stof(argv(f + 1));
 340         }
 341         else
 342                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 343 }
 344 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 345 {
 346         if (f < 0)
 347         {
 348         }
 349         else if (f > 0)
 350         {
 351                 if (thisname == name)
 352                 {
 353                         if (!store.(field))
 354                         {
 355                                 store.(field) = stof(argv(f + 1));
 356                                 if (!store.(field))
 357                                         store.(field) = -1;
 358                         }
 359                 }
 360         }
 361         else
 362         {
 363                 if (!store.(field))
 364                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 365         }
 366 }
 367 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 368 {
 369         string o;
 370         o = W_FixWeaponOrder_ForceComplete(wo);
 371         if(this.weaponorder_byimpulse)
 372         {
 373                 strunzone(this.weaponorder_byimpulse);
 374                 this.weaponorder_byimpulse = string_null;
 375         }
 376         this.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 377         return o;
 378 }
 379
 380 REPLICATE(autoswitch, bool, "cl_autoswitch");
 381
 382 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 383
 384 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 385
 386 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 387
 388 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 389
 390 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 391
 392 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 393
 394 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 395
 396 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 397
 398 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 399
 400 REPLICATE(cvar_cl_physics, string, "cl_physics");
 401
 402 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 403
 404 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 405
 406 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 407
 408 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 409
 410 /**
 411  * @param f -1: cleanup, 0: request, 1: receive
 412  */
 413 void GetCvars(entity this, entity store, int f)
 414 {
 415         string s = string_null;
 416
 417         if (f > 0)
 418                 s = strcat1(argv(f));
 419
 420         get_cvars_f = f;
 421         get_cvars_s = s;
 422         MUTATOR_CALLHOOK(GetCvars);
 423
 424         Notification_GetCvars(this);
 425
 426         ReplicateVars(this, store, s, f);
 427
 428         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 429         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 430         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 431         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 432         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 433         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 434         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 435         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 436         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 437         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 438         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 439
 440         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 441
 442         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 443         if (f > 0)
 444         {
 445                 if (s == "cl_weaponpriority")
 446                 {
 447                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 448                         {
 449                                 .entity weaponentity = weaponentities[slot];
 450                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 451                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 452                         }
 453                 }
 454                 if (s == "cl_allow_uidtracking")
 455                         PlayerStats_GameReport_AddPlayer(this);
 456         }
 457 }
 458
 459 // decolorizes and team colors the player name when needed
 460 string playername(entity p, bool team_colorize)
 461 {
 462     string t;
 463     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 464     {
 465         t = Team_ColorCode(p.team);
 466         return strcat(t, strdecolorize(p.netname));
 467     }
 468     else
 469         return p.netname;
 470 }
 471
 472 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 473 {
 474         int i = weaponinfo.m_id;
 475         int d = 0;
 476         bool allow_mutatorblocked = false;
 477
 478         if(!i)
 479                 return 0;
 480
 481         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 482         d = M_ARGV(1, float);
 483         allguns = M_ARGV(2, bool);
 484         allow_mutatorblocked = M_ARGV(3, bool);
 485
 486         if(allguns)
 487         {
 488                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 489                         d = true;
 490                 else
 491                         d = false;
 492         }
 493         else if(!mutator_returnvalue)
 494                 d = !(!weaponinfo.weaponstart);
 495
 496         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 497                 d = 0;
 498
 499         float t = weaponinfo.weaponstartoverride;
 500
 501         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 502
 503         // bit order in t:
 504         // 1: want or not
 505         // 2: is default?
 506         // 4: is set by default?
 507         if(t < 0)
 508                 t = 4 | (3 * d);
 509         else
 510                 t |= (2 * d);
 511
 512         return t;
 513 }
 514
 515 void readplayerstartcvars()
 516 {
 517         float i, t;
 518         string s;
 519
 520         // initialize starting values for players
 521         start_weapons = '0 0 0';
 522         start_weapons_default = '0 0 0';
 523         start_weapons_defaultmask = '0 0 0';
 524         start_items = 0;
 525         start_ammo_shells = 0;
 526         start_ammo_nails = 0;
 527         start_ammo_rockets = 0;
 528         start_ammo_cells = 0;
 529         start_ammo_plasma = 0;
 530         if (random_start_ammo == NULL)
 531         {
 532                 random_start_ammo = spawn();
 533         }
 534         start_health = cvar("g_balance_health_start");
 535         start_armorvalue = cvar("g_balance_armor_start");
 536
 537         g_weaponarena = 0;
 538         g_weaponarena_weapons = '0 0 0';
 539
 540         s = cvar_string("g_weaponarena");
 541
 542         MUTATOR_CALLHOOK(SetWeaponArena, s);
 543         s = M_ARGV(0, string);
 544
 545         if (s == "0" || s == "")
 546         {
 547                 // no arena
 548         }
 549         else if (s == "off")
 550         {
 551                 // forcibly turn off weaponarena
 552         }
 553         else if (s == "all" || s == "1")
 554         {
 555                 g_weaponarena = 1;
 556                 g_weaponarena_list = "All Weapons";
 557                 FOREACH(Weapons, it != WEP_Null, {
 558                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 559                                 g_weaponarena_weapons |= (it.m_wepset);
 560                 });
 561         }
 562         else if (s == "devall")
 563         {
 564                 g_weaponarena = 1;
 565                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 566                 FOREACH(Weapons, it != WEP_Null,
 567                 {
 568                         g_weaponarena_weapons |= (it.m_wepset);
 569                 });
 570         }
 571         else if (s == "most")
 572         {
 573                 g_weaponarena = 1;
 574                 g_weaponarena_list = "Most Weapons";
 575                 FOREACH(Weapons, it != WEP_Null, {
 576                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 577                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 578                                         g_weaponarena_weapons |= (it.m_wepset);
 579                 });
 580         }
 581         else if (s == "none")
 582         {
 583                 g_weaponarena = 1;
 584                 g_weaponarena_list = "No Weapons";
 585         }
 586         else
 587         {
 588                 g_weaponarena = 1;
 589                 t = tokenize_console(s);
 590                 g_weaponarena_list = "";
 591                 for (i = 0; i < t; ++i)
 592                 {
 593                         s = argv(i);
 594                         FOREACH(Weapons, it != WEP_Null, {
 595                                 if(it.netname == s)
 596                                 {
 597                                         g_weaponarena_weapons |= (it.m_wepset);
 598                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 599                                         break;
 600                                 }
 601                         });
 602                 }
 603                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 604         }
 605
 606         if(g_weaponarena)
 607                 g_weaponarena_random = cvar("g_weaponarena_random");
 608         else
 609                 g_weaponarena_random = 0;
 610         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 611
 612         if (g_weaponarena)
 613         {
 614                 g_weapon_stay = 0; // incompatible
 615                 start_weapons = g_weaponarena_weapons;
 616                 start_items |= IT_UNLIMITED_AMMO;
 617         }
 618         else
 619         {
 620                 FOREACH(Weapons, it != WEP_Null, {
 621                         int w = want_weapon(it, false);
 622                         WepSet s = it.m_wepset;
 623                         if(w & 1)
 624                                 start_weapons |= s;
 625                         if(w & 2)
 626                                 start_weapons_default |= s;
 627                         if(w & 4)
 628                                 start_weapons_defaultmask |= s;
 629                 });
 630         }
 631
 632         if(!cvar("g_use_ammunition"))
 633                 start_items |= IT_UNLIMITED_AMMO;
 634
 635         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 636         {
 637                 start_ammo_shells = 999;
 638                 start_ammo_nails = 999;
 639                 start_ammo_rockets = 999;
 640                 start_ammo_cells = 999;
 641                 start_ammo_plasma = 999;
 642                 start_ammo_fuel = 999;
 643         }
 644         else
 645         {
 646                 start_ammo_shells = cvar("g_start_ammo_shells");
 647                 start_ammo_nails = cvar("g_start_ammo_nails");
 648                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 649                 start_ammo_cells = cvar("g_start_ammo_cells");
 650                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 651                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 652                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 653                 SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, cvar(
 654                         "g_random_start_shells"));
 655                 SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, cvar(
 656                         "g_random_start_bullets"));
 657                 SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS,
 658                         cvar("g_random_start_rockets"));
 659                 SetResourceAmount(random_start_ammo, RESOURCE_CELLS, cvar(
 660                         "g_random_start_cells"));
 661                 SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, cvar(
 662                         "g_random_start_plasma"));
 663         }
 664
 665         if (warmup_stage)
 666         {
 667                 warmup_start_ammo_shells = start_ammo_shells;
 668                 warmup_start_ammo_nails = start_ammo_nails;
 669                 warmup_start_ammo_rockets = start_ammo_rockets;
 670                 warmup_start_ammo_cells = start_ammo_cells;
 671                 warmup_start_ammo_plasma = start_ammo_plasma;
 672                 warmup_start_ammo_fuel = start_ammo_fuel;
 673                 warmup_start_health = start_health;
 674                 warmup_start_armorvalue = start_armorvalue;
 675                 warmup_start_weapons = start_weapons;
 676                 warmup_start_weapons_default = start_weapons_default;
 677                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 678
 679                 if (!g_weaponarena && !g_ca && !g_freezetag)
 680                 {
 681                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 682                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 683                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 684                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 685                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 686                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 687                         warmup_start_health = cvar("g_warmup_start_health");
 688                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 689                         warmup_start_weapons = '0 0 0';
 690                         warmup_start_weapons_default = '0 0 0';
 691                         warmup_start_weapons_defaultmask = '0 0 0';
 692                         FOREACH(Weapons, it != WEP_Null, {
 693                                 int w = want_weapon(it, g_warmup_allguns);
 694                                 WepSet s = (it.m_wepset);
 695                                 if(w & 1)
 696                                         warmup_start_weapons |= s;
 697                                 if(w & 2)
 698                                         warmup_start_weapons_default |= s;
 699                                 if(w & 4)
 700                                         warmup_start_weapons_defaultmask |= s;
 701                         });
 702                 }
 703         }
 704
 705         if (g_jetpack)
 706                 start_items |= ITEM_Jetpack.m_itemid;
 707
 708         MUTATOR_CALLHOOK(SetStartItems);
 709
 710         if (start_items & ITEM_Jetpack.m_itemid)
 711         {
 712                 start_items |= ITEM_JetpackRegen.m_itemid;
 713                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 714                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 715         }
 716
 717         WepSet precache_weapons = start_weapons;
 718         if (g_warmup_allguns != 1)
 719                 precache_weapons |= warmup_start_weapons;
 720         FOREACH(Weapons, it != WEP_Null, {
 721                 if(precache_weapons & (it.m_wepset))
 722                         it.wr_init(it);
 723         });
 724
 725         start_ammo_shells = max(0, start_ammo_shells);
 726         start_ammo_nails = max(0, start_ammo_nails);
 727         start_ammo_rockets = max(0, start_ammo_rockets);
 728         start_ammo_cells = max(0, start_ammo_cells);
 729         start_ammo_plasma = max(0, start_ammo_plasma);
 730         start_ammo_fuel = max(0, start_ammo_fuel);
 731         SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, max(0,
 732                 GetResourceAmount(random_start_ammo, RESOURCE_SHELLS)));
 733         SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, max(0,
 734                 GetResourceAmount(random_start_ammo, RESOURCE_BULLETS)));
 735         SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS, max(0,
 736                 GetResourceAmount(random_start_ammo, RESOURCE_ROCKETS)));
 737         SetResourceAmount(random_start_ammo, RESOURCE_CELLS, max(0,
 738                 GetResourceAmount(random_start_ammo, RESOURCE_CELLS)));
 739         SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, max(0,
 740                 GetResourceAmount(random_start_ammo, RESOURCE_PLASMA)));
 741
 742         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 743         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 744         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 745         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 746         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 747         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 748 }
 749
 750 void precache_playermodel(string m)
 751 {
 752         float globhandle, i, n;
 753         string f;
 754
 755         if(substring(m, -9,5) == "_lod1")
 756                 return;
 757         if(substring(m, -9,5) == "_lod2")
 758                 return;
 759         precache_model(m);
 760         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 761         if(fexists(f))
 762                 precache_model(f);
 763         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 764         if(fexists(f))
 765                 precache_model(f);
 766
 767         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 768         if (globhandle < 0)
 769                 return;
 770         n = search_getsize(globhandle);
 771         for (i = 0; i < n; ++i)
 772         {
 773                 //print(search_getfilename(globhandle, i), "\n");
 774                 f = search_getfilename(globhandle, i);
 775                 PrecachePlayerSounds(f);
 776         }
 777         search_end(globhandle);
 778 }
 779 void precache_all_playermodels(string pattern)
 780 {
 781         int globhandle = search_begin(pattern, true, false);
 782         if (globhandle < 0) return;
 783         int n = search_getsize(globhandle);
 784         for (int i = 0; i < n; ++i)
 785         {
 786                 string s = search_getfilename(globhandle, i);
 787                 precache_playermodel(s);
 788         }
 789         search_end(globhandle);
 790 }
 791
 792 void precache_playermodels(string s)
 793 {
 794         FOREACH_WORD(s, true, { precache_playermodel(it); });
 795 }
 796
 797 void precache()
 798 {
 799     // gamemode related things
 800
 801     // Precache all player models if desired
 802     if (autocvar_sv_precacheplayermodels)
 803     {
 804         PrecachePlayerSounds("sound/player/default.sounds");
 805         precache_all_playermodels("models/player/*.zym");
 806         precache_all_playermodels("models/player/*.dpm");
 807         precache_all_playermodels("models/player/*.md3");
 808         precache_all_playermodels("models/player/*.psk");
 809         precache_all_playermodels("models/player/*.iqm");
 810     }
 811
 812     if (autocvar_sv_defaultcharacter)
 813     {
 814                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 815                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 816                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 817                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 818                 precache_playermodels(autocvar_sv_defaultplayermodel);
 819     }
 820
 821 #if 0
 822     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 823
 824     if (!this.noise && this.music) // quake 3 uses the music field
 825         this.noise = this.music;
 826
 827     // plays music for the level if there is any
 828     if (this.noise)
 829     {
 830         precache_sound (this.noise);
 831         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 832     }
 833 #endif
 834 }
 835
 836
 837 void make_safe_for_remove(entity e)
 838 {
 839     if (e.initialize_entity)
 840     {
 841         entity ent, prev = NULL;
 842         for (ent = initialize_entity_first; ent; )
 843         {
 844             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 845             {
 846                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 847                 // skip it in linked list
 848                 if (prev)
 849                 {
 850                     prev.initialize_entity_next = ent.initialize_entity_next;
 851                     ent = prev.initialize_entity_next;
 852                 }
 853                 else
 854                 {
 855                     initialize_entity_first = ent.initialize_entity_next;
 856                     ent = initialize_entity_first;
 857                 }
 858             }
 859             else
 860             {
 861                 prev = ent;
 862                 ent = ent.initialize_entity_next;
 863             }
 864         }
 865     }
 866 }
 867
 868 .float remove_except_protected_forbidden;
 869 void remove_except_protected(entity e)
 870 {
 871         if(e.remove_except_protected_forbidden)
 872                 error("not allowed to remove this at this point");
 873         builtin_remove(e);
 874 }
 875
 876 void remove_unsafely(entity e)
 877 {
 878     if(e.classname == "spike")
 879         error("Removing spikes is forbidden (crylink bug), please report");
 880     builtin_remove(e);
 881 }
 882
 883 void remove_safely(entity e)
 884 {
 885     make_safe_for_remove(e);
 886     builtin_remove(e);
 887 }
 888
 889 void InitializeEntity(entity e, void(entity this) func, float order)
 890 {
 891     entity prev, cur;
 892
 893     if (!e || e.initialize_entity)
 894     {
 895         // make a proxy initializer entity
 896         entity e_old = e;
 897         e = new(initialize_entity);
 898         e.enemy = e_old;
 899     }
 900
 901     e.initialize_entity = func;
 902     e.initialize_entity_order = order;
 903
 904     cur = initialize_entity_first;
 905     prev = NULL;
 906     for (;;)
 907     {
 908         if (!cur || cur.initialize_entity_order > order)
 909         {
 910             // insert between prev and cur
 911             if (prev)
 912                 prev.initialize_entity_next = e;
 913             else
 914                 initialize_entity_first = e;
 915             e.initialize_entity_next = cur;
 916             return;
 917         }
 918         prev = cur;
 919         cur = cur.initialize_entity_next;
 920     }
 921 }
 922 void InitializeEntitiesRun()
 923 {
 924     entity startoflist = initialize_entity_first;
 925     initialize_entity_first = NULL;
 926     delete_fn = remove_except_protected;
 927     for (entity e = startoflist; e; e = e.initialize_entity_next)
 928     {
 929                 e.remove_except_protected_forbidden = 1;
 930     }
 931     for (entity e = startoflist; e; )
 932     {
 933                 e.remove_except_protected_forbidden = 0;
 934         e.initialize_entity_order = 0;
 935         entity next = e.initialize_entity_next;
 936         e.initialize_entity_next = NULL;
 937         var void(entity this) func = e.initialize_entity;
 938         e.initialize_entity = func_null;
 939         if (e.classname == "initialize_entity")
 940         {
 941             entity wrappee = e.enemy;
 942             builtin_remove(e);
 943             e = wrappee;
 944         }
 945         //dprint("Delayed initialization: ", e.classname, "\n");
 946         if (func)
 947         {
 948                 func(e);
 949         }
 950         else
 951         {
 952             eprint(e);
 953             backtrace(strcat("Null function in: ", e.classname, "\n"));
 954         }
 955         e = next;
 956     }
 957     delete_fn = remove_unsafely;
 958 }
 959
 960 .float(entity) isEliminated;
 961 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 962 {
 963         Stream out = MSG_ENTITY;
 964         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 965         serialize(byte, out, sendflags);
 966         if (sendflags & 1) {
 967                 for (int i = 1; i <= maxclients; i += 8) {
 968                         int f = 0;
 969                         entity e = edict_num(i);
 970                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 971                                 if (eliminatedPlayers.isEliminated(e)) {
 972                                         f |= BIT(b);
 973                                 }
 974                         }
 975                         serialize(byte, out, f);
 976                 }
 977         }
 978         return true;
 979 }
 980
 981 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 982 {
 983         if(eliminatedPlayers)
 984         {
 985                 backtrace("Can't spawn eliminatedPlayers again!");
 986                 return;
 987         }
 988         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 989         eliminatedPlayers.isEliminated = isEliminated_func;
 990 }
 991
 992
 993
 994
 995 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 996 {
 997         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 998                 this.projectiledeathtype |= HITTYPE_SPLASH;
 999         adaptor_think2use(this);
1000 }
1001
1002 // deferred dropping
1003 void DropToFloor_Handler(entity this)
1004 {
1005     WITHSELF(this, builtin_droptofloor());
1006     this.dropped_origin = this.origin;
1007 }
1008
1009 void droptofloor(entity this)
1010 {
1011     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1012 }
1013
1014
1015
1016 float trace_hits_box_a0, trace_hits_box_a1;
1017
1018 float trace_hits_box_1d(float end, float thmi, float thma)
1019 {
1020     if (end == 0)
1021     {
1022         // just check if x is in range
1023         if (0 < thmi)
1024             return false;
1025         if (0 > thma)
1026             return false;
1027     }
1028     else
1029     {
1030         // do the trace with respect to x
1031         // 0 -> end has to stay in thmi -> thma
1032         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1033         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1034         if (trace_hits_box_a0 > trace_hits_box_a1)
1035             return false;
1036     }
1037     return true;
1038 }
1039
1040 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1041 {
1042     end -= start;
1043     thmi -= start;
1044     thma -= start;
1045     // now it is a trace from 0 to end
1046
1047     trace_hits_box_a0 = 0;
1048     trace_hits_box_a1 = 1;
1049
1050     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1051         return false;
1052     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1053         return false;
1054     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1055         return false;
1056
1057     return true;
1058 }
1059
1060 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1061 {
1062     return trace_hits_box(start, end, thmi - ma, thma - mi);
1063 }
1064
1065 bool SUB_NoImpactCheck(entity this, entity toucher)
1066 {
1067         // zero hitcontents = this is not the real impact, but either the
1068         // mirror-impact of something hitting the projectile instead of the
1069         // projectile hitting the something, or a touchareagrid one. Neither of
1070         // these stop the projectile from moving, so...
1071         if(trace_dphitcontents == 0)
1072         {
1073                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1074                 checkclient(this);
1075         }
1076     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1077         return true;
1078     if (toucher == NULL && this.size != '0 0 0')
1079     {
1080         vector tic;
1081         tic = this.velocity * sys_frametime;
1082         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1083         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1084         if (trace_fraction >= 1)
1085         {
1086             LOG_TRACE("Odd... did not hit...?");
1087         }
1088         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1089         {
1090             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1091             return true;
1092         }
1093     }
1094
1095     return false;
1096 }
1097
1098 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1099
1100 void W_Crylink_Dequeue(entity e);
1101 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1102 {
1103         if(SUB_OwnerCheck(this, toucher))
1104                 return true;
1105         if(SUB_NoImpactCheck(this, toucher))
1106         {
1107                 if(this.classname == "nade")
1108                         return false; // no checks here
1109                 else if(this.classname == "grapplinghook")
1110                         RemoveHook(this);
1111                 else if(this.classname == "spike")
1112                 {
1113                         W_Crylink_Dequeue(this);
1114                         delete(this);
1115                 }
1116                 else
1117                         delete(this);
1118                 return true;
1119         }
1120         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1121                 UpdateCSQCProjectile(this);
1122         return false;
1123 }
1124
1125 /** engine callback */
1126 void URI_Get_Callback(float id, float status, string data)
1127 {
1128         if(url_URI_Get_Callback(id, status, data))
1129         {
1130                 // handled
1131         }
1132         else if (id == URI_GET_DISCARD)
1133         {
1134                 // discard
1135         }
1136         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1137         {
1138                 // sv_cmd curl
1139                 Curl_URI_Get_Callback(id, status, data);
1140         }
1141         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1142         {
1143                 // online ban list
1144                 OnlineBanList_URI_Get_Callback(id, status, data);
1145         }
1146         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1147         {
1148                 // handled by a mutator
1149         }
1150         else
1151         {
1152                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1153         }
1154 }
1155
1156 string uid2name(string myuid) {
1157         string s;
1158         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1159
1160         // FIXME remove this later after 0.6 release
1161         // convert old style broken records to correct style
1162         if(s == "")
1163         {
1164                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1165                 if(s != "")
1166                 {
1167                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1168                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1169                 }
1170         }
1171
1172         if(s == "")
1173                 s = "^1Unregistered Player";
1174         return s;
1175 }
1176
1177 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1178 {
1179     float m, i;
1180     vector start, org, delta, end, enddown, mstart;
1181
1182     m = e.dphitcontentsmask;
1183     e.dphitcontentsmask = goodcontents | badcontents;
1184
1185     org = boundmin;
1186     delta = boundmax - boundmin;
1187
1188     start = end = org;
1189
1190     for (i = 0; i < attempts; ++i)
1191     {
1192         start.x = org.x + random() * delta.x;
1193         start.y = org.y + random() * delta.y;
1194         start.z = org.z + random() * delta.z;
1195
1196         // rule 1: start inside world bounds, and outside
1197         // solid, and don't start from somewhere where you can
1198         // fall down to evil
1199         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1200         if (trace_fraction >= 1)
1201             continue;
1202         if (trace_startsolid)
1203             continue;
1204         if (trace_dphitcontents & badcontents)
1205             continue;
1206         if (trace_dphitq3surfaceflags & badsurfaceflags)
1207             continue;
1208
1209         // rule 2: if we are too high, lower the point
1210         if (trace_fraction * delta.z > maxaboveground)
1211             start = trace_endpos + '0 0 1' * maxaboveground;
1212         enddown = trace_endpos;
1213
1214         // rule 3: make sure we aren't outside the map. This only works
1215         // for somewhat well formed maps. A good rule of thumb is that
1216         // the map should have a convex outside hull.
1217         // these can be traceLINES as we already verified the starting box
1218         mstart = start + 0.5 * (e.mins + e.maxs);
1219         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1220         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1221             continue;
1222         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1223         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1224             continue;
1225         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1226         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1227             continue;
1228         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1229         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1230             continue;
1231         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1232         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1233             continue;
1234
1235         // rule 4: we must "see" some spawnpoint or item
1236     entity sp = NULL;
1237     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1238     {
1239         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1240         {
1241                 sp = it;
1242                 break;
1243         }
1244     });
1245         if(!sp)
1246         {
1247                 int items_checked = 0;
1248                 IL_EACH(g_items, checkpvs(mstart, it),
1249                 {
1250                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1251                         {
1252                                 sp = it;
1253                                 break;
1254                         }
1255
1256                         ++items_checked;
1257                         if(items_checked >= attempts)
1258                                 break; // sanity
1259                 });
1260
1261                 if(!sp)
1262                         continue;
1263         }
1264
1265         // find a random vector to "look at"
1266         end.x = org.x + random() * delta.x;
1267         end.y = org.y + random() * delta.y;
1268         end.z = org.z + random() * delta.z;
1269         end = start + normalize(end - start) * vlen(delta);
1270
1271         // rule 4: start TO end must not be too short
1272         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1273         if (trace_startsolid)
1274             continue;
1275         if (trace_fraction < minviewdistance / vlen(delta))
1276             continue;
1277
1278         // rule 5: don't want to look at sky
1279         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1280             continue;
1281
1282         // rule 6: we must not end up in trigger_hurt
1283         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1284             continue;
1285
1286         break;
1287     }
1288
1289     e.dphitcontentsmask = m;
1290
1291     if (i < attempts)
1292     {
1293         setorigin(e, start);
1294         e.angles = vectoangles(end - start);
1295         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1296         return true;
1297     }
1298     else
1299         return false;
1300 }
1301
1302 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1303 {
1304         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1305 }
1306
1307 void write_recordmarker(entity pl, float tstart, float dt)
1308 {
1309     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1310
1311     // also write a marker into demo files for demotc-race-record-extractor to find
1312     stuffcmd(pl,
1313              strcat(
1314                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1315                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1316 }
1317
1318 void attach_sameorigin(entity e, entity to, string tag)
1319 {
1320     vector org, t_forward, t_left, t_up, e_forward, e_up;
1321     float tagscale;
1322
1323     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1324     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1325     t_forward = v_forward * tagscale;
1326     t_left = v_right * -tagscale;
1327     t_up = v_up * tagscale;
1328
1329     e.origin_x = org * t_forward;
1330     e.origin_y = org * t_left;
1331     e.origin_z = org * t_up;
1332
1333     // current forward and up directions
1334     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1335                 e.angles = AnglesTransform_FromVAngles(e.angles);
1336         else
1337                 e.angles = AnglesTransform_FromAngles(e.angles);
1338     fixedmakevectors(e.angles);
1339
1340     // untransform forward, up!
1341     e_forward.x = v_forward * t_forward;
1342     e_forward.y = v_forward * t_left;
1343     e_forward.z = v_forward * t_up;
1344     e_up.x = v_up * t_forward;
1345     e_up.y = v_up * t_left;
1346     e_up.z = v_up * t_up;
1347
1348     e.angles = fixedvectoangles2(e_forward, e_up);
1349     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1350                 e.angles = AnglesTransform_ToVAngles(e.angles);
1351         else
1352                 e.angles = AnglesTransform_ToAngles(e.angles);
1353
1354     setattachment(e, to, tag);
1355     setorigin(e, e.origin);
1356 }
1357
1358 void detach_sameorigin(entity e)
1359 {
1360     vector org;
1361     org = gettaginfo(e, 0);
1362     e.angles = fixedvectoangles2(v_forward, v_up);
1363     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1364                 e.angles = AnglesTransform_ToVAngles(e.angles);
1365         else
1366                 e.angles = AnglesTransform_ToAngles(e.angles);
1367     setorigin(e, org);
1368     setattachment(e, NULL, "");
1369     setorigin(e, e.origin);
1370 }
1371
1372 void follow_sameorigin(entity e, entity to)
1373 {
1374     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1375     e.aiment = to; // make the hole follow bmodel
1376     e.punchangle = to.angles; // the original angles of bmodel
1377     e.view_ofs = e.origin - to.origin; // relative origin
1378     e.v_angle = e.angles - to.angles; // relative angles
1379 }
1380
1381 void unfollow_sameorigin(entity e)
1382 {
1383     set_movetype(e, MOVETYPE_NONE);
1384 }
1385
1386 entity gettaginfo_relative_ent;
1387 vector gettaginfo_relative(entity e, float tag)
1388 {
1389     if (!gettaginfo_relative_ent)
1390     {
1391         gettaginfo_relative_ent = spawn();
1392         gettaginfo_relative_ent.effects = EF_NODRAW;
1393     }
1394     gettaginfo_relative_ent.model = e.model;
1395     gettaginfo_relative_ent.modelindex = e.modelindex;
1396     gettaginfo_relative_ent.frame = e.frame;
1397     return gettaginfo(gettaginfo_relative_ent, tag);
1398 }
1399
1400 .string aiment_classname;
1401 .float aiment_deadflag;
1402 void SetMovetypeFollow(entity ent, entity e)
1403 {
1404         // FIXME this may not be warpzone aware
1405         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1406         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1407         ent.aiment = e; // make the hole follow bmodel
1408         ent.punchangle = e.angles; // the original angles of bmodel
1409         ent.view_ofs = ent.origin - e.origin; // relative origin
1410         ent.v_angle = ent.angles - e.angles; // relative angles
1411         ent.aiment_classname = strzone(e.classname);
1412         ent.aiment_deadflag = e.deadflag;
1413 }
1414 void UnsetMovetypeFollow(entity ent)
1415 {
1416         set_movetype(ent, MOVETYPE_FLY);
1417         PROJECTILE_MAKETRIGGER(ent);
1418         ent.aiment = NULL;
1419 }
1420 float LostMovetypeFollow(entity ent)
1421 {
1422 /*
1423         if(ent.move_movetype != MOVETYPE_FOLLOW)
1424                 if(ent.aiment)
1425                         error("???");
1426 */
1427         if(ent.aiment)
1428         {
1429                 if(ent.aiment.classname != ent.aiment_classname)
1430                         return 1;
1431                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1432                         return 1;
1433         }
1434         return 0;
1435 }
1436
1437 .bool pushable;
1438 bool isPushable(entity e)
1439 {
1440         if(e.pushable)
1441                 return true;
1442         if(IS_VEHICLE(e))
1443                 return false;
1444         if(e.iscreature)
1445                 return true;
1446         if (Item_IsLoot(e))
1447         {
1448                 return true;
1449         }
1450         switch(e.classname)
1451         {
1452                 case "body":
1453                         return true;
1454                 case "bullet": // antilagged bullets can't hit this either
1455                         return false;
1456         }
1457         if (e.projectiledeathtype)
1458                 return true;
1459         return false;
1460 }