qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include "mutators/_mod.qh"
   9 #include "../common/t_items.qh"
  10 #include "weapons/accuracy.qh"
  11 #include "weapons/csqcprojectile.qh"
  12 #include "weapons/selection.qh"
  13 #include "../common/command/_mod.qh"
  14 #include "../common/constants.qh"
  15 #include <common/net_linked.qh>
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/notifications/all.qh"
  19 #include "../common/playerstats.qh"
  20 #include "../common/teams.qh"
  21 #include "../common/triggers/subs.qh"
  22 #include "../common/util.qh"
  23 #include "../common/turrets/sv_turrets.qh"
  24 #include <common/weapons/_all.qh>
  25 #include "../common/vehicles/sv_vehicles.qh"
  26 #include "../common/vehicles/vehicle.qh"
  27 #include "../common/items/_mod.qh"
  28 #include "../common/state.qh"
  29 #include "../common/effects/qc/globalsound.qh"
  30 #include "../common/wepent.qh"
  31 #include "../lib/csqcmodel/sv_model.qh"
  32 #include "../lib/warpzone/anglestransform.qh"
  33 #include "../lib/warpzone/server.qh"
  34
  35 void crosshair_trace(entity pl)
  36 {
  37         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  38 }
  39 .bool ctrace_solidchanged;
  40 void crosshair_trace_plusvisibletriggers(entity pl)
  41 {
  42         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  43         {
  44                 if(it.model != "")
  45                 {
  46                         it.solid = SOLID_BSP;
  47                         it.ctrace_solidchanged = true;
  48                         IL_PUSH(g_ctrace_changed, it);
  49                 }
  50         });
  51
  52         crosshair_trace(pl);
  53
  54         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
  55         {
  56                 it.solid = SOLID_TRIGGER;
  57                 it.ctrace_solidchanged = false;
  58         });
  59
  60         IL_CLEAR(g_ctrace_changed);
  61 }
  62 void WarpZone_crosshair_trace(entity pl)
  63 {
  64         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  65 }
  66
  67
  68 void GameLogEcho(string s)
  69 {
  70     string fn;
  71     int matches;
  72
  73     if (autocvar_sv_eventlog_files)
  74     {
  75         if (!logfile_open)
  76         {
  77             logfile_open = true;
  78             matches = autocvar_sv_eventlog_files_counter + 1;
  79             cvar_set("sv_eventlog_files_counter", itos(matches));
  80             fn = ftos(matches);
  81             if (strlen(fn) < 8)
  82                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  83             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  84             logfile = fopen(fn, FILE_APPEND);
  85             fputs(logfile, ":logversion:3\n");
  86         }
  87         if (logfile >= 0)
  88         {
  89             if (autocvar_sv_eventlog_files_timestamps)
  90                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  91             else
  92                 fputs(logfile, strcat(s, "\n"));
  93         }
  94     }
  95     if (autocvar_sv_eventlog_console)
  96     {
  97         dedicated_print(strcat(s, "\n"));
  98     }
  99 }
 100
 101 void GameLogInit()
 102 {
 103     logfile_open = 0;
 104     // will be opened later
 105 }
 106
 107 void GameLogClose()
 108 {
 109     if (logfile_open && logfile >= 0)
 110     {
 111         fclose(logfile);
 112         logfile = -1;
 113     }
 114 }
 115
 116 entity findnearest(vector point, bool checkitems, vector axismod)
 117 {
 118     vector dist;
 119     int num_nearest = 0;
 120
 121     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 122     {
 123         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 124             dist = it.oldorigin;
 125         else
 126             dist = it.origin;
 127         dist = dist - point;
 128         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 129         float len = vlen2(dist);
 130
 131         int l;
 132         for (l = 0; l < num_nearest; ++l)
 133         {
 134             if (len < nearest_length[l])
 135                 break;
 136         }
 137
 138         // now i tells us where to insert at
 139         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 140         if (l < NUM_NEAREST_ENTITIES)
 141         {
 142             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 143             {
 144                 nearest_length[j + 1] = nearest_length[j];
 145                 nearest_entity[j + 1] = nearest_entity[j];
 146             }
 147             nearest_length[l] = len;
 148             nearest_entity[l] = it;
 149             if (num_nearest < NUM_NEAREST_ENTITIES)
 150                 num_nearest = num_nearest + 1;
 151         }
 152     });
 153
 154     // now use the first one from our list that we can see
 155     for (int j = 0; j < num_nearest; ++j)
 156     {
 157         traceline(point, nearest_entity[j].origin, true, NULL);
 158         if (trace_fraction == 1)
 159         {
 160             if (j != 0)
 161                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 162             return nearest_entity[j];
 163         }
 164     }
 165
 166     if (num_nearest == 0)
 167         return NULL;
 168
 169     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 170     /* DEBUGGING CODE:
 171     dprint("Candidates were: ");
 172     for(j = 0; j < num_nearest; ++j)
 173     {
 174         if(j != 0)
 175                 dprint(", ");
 176         dprint(nearest_entity[j].netname);
 177     }
 178     dprint("\n");
 179     */
 180
 181     return nearest_entity[0];
 182 }
 183
 184 string NearestLocation(vector p)
 185 {
 186     string ret = "somewhere";
 187     entity loc = findnearest(p, false, '1 1 1');
 188     if (loc)
 189         ret = loc.message;
 190     else
 191     {
 192         loc = findnearest(p, true, '1 1 4');
 193         if (loc)
 194             ret = loc.netname;
 195     }
 196     return ret;
 197 }
 198
 199 string AmmoNameFromWeaponentity(entity wpn)
 200 {
 201         string ammoitems = "batteries";
 202         switch((wpn.m_weapon).ammo_field)
 203         {
 204                 case ammo_shells:  ammoitems = ITEM_Shells.m_name;      break;
 205                 case ammo_nails:   ammoitems = ITEM_Bullets.m_name;     break;
 206                 case ammo_rockets: ammoitems = ITEM_Rockets.m_name;     break;
 207                 case ammo_cells:   ammoitems = ITEM_Cells.m_name;       break;
 208                 case ammo_plasma:  ammoitems = ITEM_Plasma.m_name;      break;
 209                 case ammo_fuel:    ammoitems = ITEM_JetpackFuel.m_name; break;
 210         }
 211         return ammoitems;
 212 }
 213
 214 string formatmessage(entity this, string msg)
 215 {
 216         float p, p1, p2;
 217         float n;
 218         vector cursor;
 219         entity cursor_ent;
 220         string escape;
 221         string replacement;
 222         p = 0;
 223         n = 7;
 224
 225         WarpZone_crosshair_trace(this);
 226         cursor = trace_endpos;
 227         cursor_ent = trace_ent;
 228
 229         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 230         msg = M_ARGV(1, string);
 231
 232         while (1) {
 233                 if (n < 1)
 234                         break; // too many replacements
 235
 236                 n = n - 1;
 237                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 238                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 239
 240                 if (p1 < 0)
 241                         p1 = p2;
 242
 243                 if (p2 < 0)
 244                         p2 = p1;
 245
 246                 p = min(p1, p2);
 247
 248                 if (p < 0)
 249                         break;
 250
 251                 replacement = substring(msg, p, 2);
 252                 escape = substring(msg, p + 1, 1);
 253
 254                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 255
 256                 switch(escape)
 257                 {
 258                         case "%": replacement = "%"; break;
 259                         case "\\":replacement = "\\"; break;
 260                         case "n": replacement = "\n"; break;
 261                         case "a": replacement = ftos(floor(this.armorvalue)); break;
 262                         case "h": replacement = ftos(floor(this.health)); break;
 263                         case "l": replacement = NearestLocation(this.origin); break;
 264                         case "y": replacement = NearestLocation(cursor); break;
 265                         case "d": replacement = NearestLocation(this.death_origin); break;
 266                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 267                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity)); break;
 268                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 269                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 270                         case "S": replacement = ftos(vlen(this.velocity)); break;
 271                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 272                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 273                         default:
 274                         {
 275                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 276                                 replacement = M_ARGV(2, string);
 277                                 break;
 278                         }
 279                 }
 280
 281                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 282                 p = p + strlen(replacement);
 283         }
 284         return msg;
 285 }
 286
 287 /*
 288 =============
 289 GetCvars
 290 =============
 291 Called with:
 292   0:  sends the request
 293   >0: receives a cvar from name=argv(f) value=argv(f+1)
 294 */
 295 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 296 {
 297         if (f < 0)
 298         {
 299                 if (store.(field))
 300                         strunzone(store.(field));
 301                 store.(field) = string_null;
 302         }
 303         else if (f > 0)
 304         {
 305                 if (thisname == name)
 306                 {
 307                         if (store.(field))
 308                                 strunzone(store.(field));
 309                         store.(field) = strzone(argv(f + 1));
 310                 }
 311         }
 312         else
 313                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 314 }
 315 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 316 {
 317         GetCvars_handleString(this, store, thisname, f, field, name);
 318         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 319                 if (thisname == name)
 320                 {
 321                         string s = func(this, strcat1(store.(field)));
 322                         if (s != store.(field))
 323                         {
 324                                 strunzone(store.(field));
 325                                 store.(field) = strzone(s);
 326                         }
 327                 }
 328 }
 329 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 330 {
 331         if (f < 0)
 332         {
 333         }
 334         else if (f > 0)
 335         {
 336                 if (thisname == name)
 337                         store.(field) = stof(argv(f + 1));
 338         }
 339         else
 340                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 341 }
 342 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 343 {
 344         if (f < 0)
 345         {
 346         }
 347         else if (f > 0)
 348         {
 349                 if (thisname == name)
 350                 {
 351                         if (!store.(field))
 352                         {
 353                                 store.(field) = stof(argv(f + 1));
 354                                 if (!store.(field))
 355                                         store.(field) = -1;
 356                         }
 357                 }
 358         }
 359         else
 360         {
 361                 if (!store.(field))
 362                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 363         }
 364 }
 365 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 366 {
 367         string o;
 368         o = W_FixWeaponOrder_ForceComplete(wo);
 369         if(this.weaponorder_byimpulse)
 370         {
 371                 strunzone(this.weaponorder_byimpulse);
 372                 this.weaponorder_byimpulse = string_null;
 373         }
 374         this.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 375         return o;
 376 }
 377
 378 REPLICATE(autoswitch, bool, "cl_autoswitch");
 379
 380 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 381
 382 REPLICATE(cvar_cl_allow_eloranking, bool, "cl_allow_eloranking");
 383
 384 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 385
 386 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 387
 388 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 389
 390 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 391
 392 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 393
 394 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 395
 396 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 397
 398 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 399
 400 REPLICATE(cvar_cl_physics, string, "cl_physics");
 401
 402 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 403
 404 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 405
 406 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 407
 408 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 409
 410 /**
 411  * @param f -1: cleanup, 0: request, 1: receive
 412  */
 413 void GetCvars(entity this, entity store, int f)
 414 {
 415         string s = string_null;
 416
 417         if (f > 0)
 418                 s = strcat1(argv(f));
 419
 420         get_cvars_f = f;
 421         get_cvars_s = s;
 422         MUTATOR_CALLHOOK(GetCvars);
 423
 424         Notification_GetCvars(this);
 425
 426         ReplicateVars(this, store, s, f);
 427
 428         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 429         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 430         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 431         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 432         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 433         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 434         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 435         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 436         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 437         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 438         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 439
 440         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 441
 442         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 443         if (f > 0)
 444         {
 445                 if (s == "cl_weaponpriority")
 446                 {
 447                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 448                         {
 449                                 .entity weaponentity = weaponentities[slot];
 450                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 451                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 452                         }
 453                 }
 454                 if (s == "cl_allow_uidtracking")
 455                         PlayerStats_GameReport_AddPlayer(this);
 456         }
 457 }
 458
 459 // decolorizes and team colors the player name when needed
 460 string playername(entity p, bool team_colorize)
 461 {
 462     string t;
 463     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 464     {
 465         t = Team_ColorCode(p.team);
 466         return strcat(t, strdecolorize(p.netname));
 467     }
 468     else
 469         return p.netname;
 470 }
 471
 472 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 473 {
 474         int i = weaponinfo.m_id;
 475         int d = 0;
 476         bool allow_mutatorblocked = false;
 477
 478         if(!i)
 479                 return 0;
 480
 481         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 482         d = M_ARGV(1, float);
 483         allguns = M_ARGV(2, bool);
 484         allow_mutatorblocked = M_ARGV(3, bool);
 485
 486         if(allguns)
 487         {
 488                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 489                         d = true;
 490                 else
 491                         d = false;
 492         }
 493         else if(!mutator_returnvalue)
 494                 d = !(!weaponinfo.weaponstart);
 495
 496         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 497                 d = 0;
 498
 499         float t = weaponinfo.weaponstartoverride;
 500
 501         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 502
 503         // bit order in t:
 504         // 1: want or not
 505         // 2: is default?
 506         // 4: is set by default?
 507         if(t < 0)
 508                 t = 4 | (3 * d);
 509         else
 510                 t |= (2 * d);
 511
 512         return t;
 513 }
 514
 515 void readplayerstartcvars()
 516 {
 517         float i, t;
 518         string s;
 519
 520         // initialize starting values for players
 521         start_weapons = '0 0 0';
 522         start_weapons_default = '0 0 0';
 523         start_weapons_defaultmask = '0 0 0';
 524         start_items = 0;
 525         start_ammo_shells = 0;
 526         start_ammo_nails = 0;
 527         start_ammo_rockets = 0;
 528         start_ammo_cells = 0;
 529         start_ammo_plasma = 0;
 530         start_health = cvar("g_balance_health_start");
 531         start_armorvalue = cvar("g_balance_armor_start");
 532
 533         g_weaponarena = 0;
 534         g_weaponarena_weapons = '0 0 0';
 535
 536         s = cvar_string("g_weaponarena");
 537
 538         MUTATOR_CALLHOOK(SetWeaponArena, s);
 539         s = M_ARGV(0, string);
 540
 541         if (s == "0" || s == "")
 542         {
 543                 // no arena
 544         }
 545         else if (s == "off")
 546         {
 547                 // forcibly turn off weaponarena
 548         }
 549         else if (s == "all" || s == "1")
 550         {
 551                 g_weaponarena = 1;
 552                 g_weaponarena_list = "All Weapons";
 553                 FOREACH(Weapons, it != WEP_Null, {
 554                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 555                                 g_weaponarena_weapons |= (it.m_wepset);
 556                 });
 557         }
 558         else if (s == "devall")
 559         {
 560                 g_weaponarena = 1;
 561                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 562                 FOREACH(Weapons, it != WEP_Null,
 563                 {
 564                         g_weaponarena_weapons |= (it.m_wepset);
 565                 });
 566         }
 567         else if (s == "most")
 568         {
 569                 g_weaponarena = 1;
 570                 g_weaponarena_list = "Most Weapons";
 571                 FOREACH(Weapons, it != WEP_Null, {
 572                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 573                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 574                                         g_weaponarena_weapons |= (it.m_wepset);
 575                 });
 576         }
 577         else if (s == "none")
 578         {
 579                 g_weaponarena = 1;
 580                 g_weaponarena_list = "No Weapons";
 581         }
 582         else
 583         {
 584                 g_weaponarena = 1;
 585                 t = tokenize_console(s);
 586                 g_weaponarena_list = "";
 587                 for (i = 0; i < t; ++i)
 588                 {
 589                         s = argv(i);
 590                         FOREACH(Weapons, it != WEP_Null, {
 591                                 if(it.netname == s)
 592                                 {
 593                                         g_weaponarena_weapons |= (it.m_wepset);
 594                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 595                                         break;
 596                                 }
 597                         });
 598                 }
 599                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 600         }
 601
 602         if(g_weaponarena)
 603                 g_weaponarena_random = cvar("g_weaponarena_random");
 604         else
 605                 g_weaponarena_random = 0;
 606         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 607
 608         if (g_weaponarena)
 609         {
 610                 g_weapon_stay = 0; // incompatible
 611                 start_weapons = g_weaponarena_weapons;
 612                 start_items |= IT_UNLIMITED_AMMO;
 613         }
 614         else
 615         {
 616                 FOREACH(Weapons, it != WEP_Null, {
 617                         int w = want_weapon(it, false);
 618                         WepSet s = it.m_wepset;
 619                         if(w & 1)
 620                                 start_weapons |= s;
 621                         if(w & 2)
 622                                 start_weapons_default |= s;
 623                         if(w & 4)
 624                                 start_weapons_defaultmask |= s;
 625                 });
 626         }
 627
 628         if(!cvar("g_use_ammunition"))
 629                 start_items |= IT_UNLIMITED_AMMO;
 630
 631         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 632         {
 633                 start_ammo_shells = 999;
 634                 start_ammo_nails = 999;
 635                 start_ammo_rockets = 999;
 636                 start_ammo_cells = 999;
 637                 start_ammo_plasma = 999;
 638                 start_ammo_fuel = 999;
 639         }
 640         else
 641         {
 642                 start_ammo_shells = cvar("g_start_ammo_shells");
 643                 start_ammo_nails = cvar("g_start_ammo_nails");
 644                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 645                 start_ammo_cells = cvar("g_start_ammo_cells");
 646                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 647                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 648         }
 649
 650         if (warmup_stage)
 651         {
 652                 warmup_start_ammo_shells = start_ammo_shells;
 653                 warmup_start_ammo_nails = start_ammo_nails;
 654                 warmup_start_ammo_rockets = start_ammo_rockets;
 655                 warmup_start_ammo_cells = start_ammo_cells;
 656                 warmup_start_ammo_plasma = start_ammo_plasma;
 657                 warmup_start_ammo_fuel = start_ammo_fuel;
 658                 warmup_start_health = start_health;
 659                 warmup_start_armorvalue = start_armorvalue;
 660                 warmup_start_weapons = start_weapons;
 661                 warmup_start_weapons_default = start_weapons_default;
 662                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 663
 664                 if (!g_weaponarena && !g_ca && !g_freezetag)
 665                 {
 666                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 667                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 668                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 669                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 670                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 671                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 672                         warmup_start_health = cvar("g_warmup_start_health");
 673                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 674                         warmup_start_weapons = '0 0 0';
 675                         warmup_start_weapons_default = '0 0 0';
 676                         warmup_start_weapons_defaultmask = '0 0 0';
 677                         FOREACH(Weapons, it != WEP_Null, {
 678                                 int w = want_weapon(it, g_warmup_allguns);
 679                                 WepSet s = (it.m_wepset);
 680                                 if(w & 1)
 681                                         warmup_start_weapons |= s;
 682                                 if(w & 2)
 683                                         warmup_start_weapons_default |= s;
 684                                 if(w & 4)
 685                                         warmup_start_weapons_defaultmask |= s;
 686                         });
 687                 }
 688         }
 689
 690         if (g_jetpack)
 691                 start_items |= ITEM_Jetpack.m_itemid;
 692
 693         MUTATOR_CALLHOOK(SetStartItems);
 694
 695         if (start_items & ITEM_Jetpack.m_itemid)
 696         {
 697                 start_items |= ITEM_JetpackRegen.m_itemid;
 698                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 699                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 700         }
 701
 702         WepSet precache_weapons = start_weapons;
 703         if (g_warmup_allguns != 1)
 704                 precache_weapons |= warmup_start_weapons;
 705         FOREACH(Weapons, it != WEP_Null, {
 706                 if(precache_weapons & (it.m_wepset))
 707                         it.wr_init(it);
 708         });
 709
 710         start_ammo_shells = max(0, start_ammo_shells);
 711         start_ammo_nails = max(0, start_ammo_nails);
 712         start_ammo_rockets = max(0, start_ammo_rockets);
 713         start_ammo_cells = max(0, start_ammo_cells);
 714         start_ammo_plasma = max(0, start_ammo_plasma);
 715         start_ammo_fuel = max(0, start_ammo_fuel);
 716
 717         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 718         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 719         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 720         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 721         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 722         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 723 }
 724
 725 void precache_playermodel(string m)
 726 {
 727         float globhandle, i, n;
 728         string f;
 729
 730         if(substring(m, -9,5) == "_lod1")
 731                 return;
 732         if(substring(m, -9,5) == "_lod2")
 733                 return;
 734         precache_model(m);
 735         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 736         if(fexists(f))
 737                 precache_model(f);
 738         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 739         if(fexists(f))
 740                 precache_model(f);
 741
 742         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 743         if (globhandle < 0)
 744                 return;
 745         n = search_getsize(globhandle);
 746         for (i = 0; i < n; ++i)
 747         {
 748                 //print(search_getfilename(globhandle, i), "\n");
 749                 f = search_getfilename(globhandle, i);
 750                 PrecachePlayerSounds(f);
 751         }
 752         search_end(globhandle);
 753 }
 754 void precache_all_playermodels(string pattern)
 755 {
 756         int globhandle = search_begin(pattern, true, false);
 757         if (globhandle < 0) return;
 758         int n = search_getsize(globhandle);
 759         for (int i = 0; i < n; ++i)
 760         {
 761                 string s = search_getfilename(globhandle, i);
 762                 precache_playermodel(s);
 763         }
 764         search_end(globhandle);
 765 }
 766
 767 void precache_playermodels(string s)
 768 {
 769         FOREACH_WORD(s, true, { precache_playermodel(it); });
 770 }
 771
 772 void precache()
 773 {
 774     // gamemode related things
 775
 776     // Precache all player models if desired
 777     if (autocvar_sv_precacheplayermodels)
 778     {
 779         PrecachePlayerSounds("sound/player/default.sounds");
 780         precache_all_playermodels("models/player/*.zym");
 781         precache_all_playermodels("models/player/*.dpm");
 782         precache_all_playermodels("models/player/*.md3");
 783         precache_all_playermodels("models/player/*.psk");
 784         precache_all_playermodels("models/player/*.iqm");
 785     }
 786
 787     if (autocvar_sv_defaultcharacter)
 788     {
 789                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 790                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 791                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 792                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 793                 precache_playermodels(autocvar_sv_defaultplayermodel);
 794     }
 795
 796 #if 0
 797     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 798
 799     if (!this.noise && this.music) // quake 3 uses the music field
 800         this.noise = this.music;
 801
 802     // plays music for the level if there is any
 803     if (this.noise)
 804     {
 805         precache_sound (this.noise);
 806         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 807     }
 808 #endif
 809 }
 810
 811
 812 void make_safe_for_remove(entity e)
 813 {
 814     if (e.initialize_entity)
 815     {
 816         entity ent, prev = NULL;
 817         for (ent = initialize_entity_first; ent; )
 818         {
 819             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 820             {
 821                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 822                 // skip it in linked list
 823                 if (prev)
 824                 {
 825                     prev.initialize_entity_next = ent.initialize_entity_next;
 826                     ent = prev.initialize_entity_next;
 827                 }
 828                 else
 829                 {
 830                     initialize_entity_first = ent.initialize_entity_next;
 831                     ent = initialize_entity_first;
 832                 }
 833             }
 834             else
 835             {
 836                 prev = ent;
 837                 ent = ent.initialize_entity_next;
 838             }
 839         }
 840     }
 841 }
 842
 843 .float remove_except_protected_forbidden;
 844 void remove_except_protected(entity e)
 845 {
 846         if(e.remove_except_protected_forbidden)
 847                 error("not allowed to remove this at this point");
 848         builtin_remove(e);
 849 }
 850
 851 void remove_unsafely(entity e)
 852 {
 853     if(e.classname == "spike")
 854         error("Removing spikes is forbidden (crylink bug), please report");
 855     builtin_remove(e);
 856 }
 857
 858 void remove_safely(entity e)
 859 {
 860     make_safe_for_remove(e);
 861     builtin_remove(e);
 862 }
 863
 864 void InitializeEntity(entity e, void(entity this) func, float order)
 865 {
 866     entity prev, cur;
 867
 868     if (!e || e.initialize_entity)
 869     {
 870         // make a proxy initializer entity
 871         entity e_old = e;
 872         e = new(initialize_entity);
 873         e.enemy = e_old;
 874     }
 875
 876     e.initialize_entity = func;
 877     e.initialize_entity_order = order;
 878
 879     cur = initialize_entity_first;
 880     prev = NULL;
 881     for (;;)
 882     {
 883         if (!cur || cur.initialize_entity_order > order)
 884         {
 885             // insert between prev and cur
 886             if (prev)
 887                 prev.initialize_entity_next = e;
 888             else
 889                 initialize_entity_first = e;
 890             e.initialize_entity_next = cur;
 891             return;
 892         }
 893         prev = cur;
 894         cur = cur.initialize_entity_next;
 895     }
 896 }
 897 void InitializeEntitiesRun()
 898 {
 899     entity startoflist = initialize_entity_first;
 900     initialize_entity_first = NULL;
 901     delete_fn = remove_except_protected;
 902     for (entity e = startoflist; e; e = e.initialize_entity_next)
 903     {
 904                 e.remove_except_protected_forbidden = 1;
 905     }
 906     for (entity e = startoflist; e; )
 907     {
 908                 e.remove_except_protected_forbidden = 0;
 909         e.initialize_entity_order = 0;
 910         entity next = e.initialize_entity_next;
 911         e.initialize_entity_next = NULL;
 912         var void(entity this) func = e.initialize_entity;
 913         e.initialize_entity = func_null;
 914         if (e.classname == "initialize_entity")
 915         {
 916             entity wrappee = e.enemy;
 917             builtin_remove(e);
 918             e = wrappee;
 919         }
 920         //dprint("Delayed initialization: ", e.classname, "\n");
 921         if (func)
 922         {
 923                 func(e);
 924         }
 925         else
 926         {
 927             eprint(e);
 928             backtrace(strcat("Null function in: ", e.classname, "\n"));
 929         }
 930         e = next;
 931     }
 932     delete_fn = remove_unsafely;
 933 }
 934
 935 .float(entity) isEliminated;
 936 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 937 {
 938         Stream out = MSG_ENTITY;
 939         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 940         serialize(byte, out, sendflags);
 941         if (sendflags & 1) {
 942                 for (int i = 1; i <= maxclients; i += 8) {
 943                         int f = 0;
 944                         entity e = edict_num(i);
 945                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 946                                 if (eliminatedPlayers.isEliminated(e)) {
 947                                         f |= BIT(b);
 948                                 }
 949                         }
 950                         serialize(byte, out, f);
 951                 }
 952         }
 953         return true;
 954 }
 955
 956 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 957 {
 958         if(eliminatedPlayers)
 959         {
 960                 backtrace("Can't spawn eliminatedPlayers again!");
 961                 return;
 962         }
 963         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 964         eliminatedPlayers.isEliminated = isEliminated_func;
 965 }
 966
 967
 968
 969
 970 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 971 {
 972         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 973                 this.projectiledeathtype |= HITTYPE_SPLASH;
 974         adaptor_think2use(this);
 975 }
 976
 977 // deferred dropping
 978 void DropToFloor_Handler(entity this)
 979 {
 980     WITHSELF(this, builtin_droptofloor());
 981     this.dropped_origin = this.origin;
 982 }
 983
 984 void droptofloor(entity this)
 985 {
 986     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
 987 }
 988
 989
 990
 991 float trace_hits_box_a0, trace_hits_box_a1;
 992
 993 float trace_hits_box_1d(float end, float thmi, float thma)
 994 {
 995     if (end == 0)
 996     {
 997         // just check if x is in range
 998         if (0 < thmi)
 999             return false;
1000         if (0 > thma)
1001             return false;
1002     }
1003     else
1004     {
1005         // do the trace with respect to x
1006         // 0 -> end has to stay in thmi -> thma
1007         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1008         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1009         if (trace_hits_box_a0 > trace_hits_box_a1)
1010             return false;
1011     }
1012     return true;
1013 }
1014
1015 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1016 {
1017     end -= start;
1018     thmi -= start;
1019     thma -= start;
1020     // now it is a trace from 0 to end
1021
1022     trace_hits_box_a0 = 0;
1023     trace_hits_box_a1 = 1;
1024
1025     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1026         return false;
1027     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1028         return false;
1029     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1030         return false;
1031
1032     return true;
1033 }
1034
1035 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1036 {
1037     return trace_hits_box(start, end, thmi - ma, thma - mi);
1038 }
1039
1040 bool SUB_NoImpactCheck(entity this, entity toucher)
1041 {
1042         // zero hitcontents = this is not the real impact, but either the
1043         // mirror-impact of something hitting the projectile instead of the
1044         // projectile hitting the something, or a touchareagrid one. Neither of
1045         // these stop the projectile from moving, so...
1046         if(trace_dphitcontents == 0)
1047         {
1048                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1049                 checkclient(this);
1050         }
1051     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1052         return true;
1053     if (toucher == NULL && this.size != '0 0 0')
1054     {
1055         vector tic;
1056         tic = this.velocity * sys_frametime;
1057         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1058         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1059         if (trace_fraction >= 1)
1060         {
1061             LOG_TRACE("Odd... did not hit...?");
1062         }
1063         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1064         {
1065             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1066             return true;
1067         }
1068     }
1069
1070     return false;
1071 }
1072
1073 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1074
1075 void W_Crylink_Dequeue(entity e);
1076 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1077 {
1078         if(SUB_OwnerCheck(this, toucher))
1079                 return true;
1080         if(SUB_NoImpactCheck(this, toucher))
1081         {
1082                 if(this.classname == "nade")
1083                         return false; // no checks here
1084                 else if(this.classname == "grapplinghook")
1085                         RemoveHook(this);
1086                 else if(this.classname == "spike")
1087                 {
1088                         W_Crylink_Dequeue(this);
1089                         delete(this);
1090                 }
1091                 else
1092                         delete(this);
1093                 return true;
1094         }
1095         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1096                 UpdateCSQCProjectile(this);
1097         return false;
1098 }
1099
1100 /** engine callback */
1101 void URI_Get_Callback(float id, float status, string data)
1102 {
1103         if(url_URI_Get_Callback(id, status, data))
1104         {
1105                 // handled
1106         }
1107         else if (id == URI_GET_DISCARD)
1108         {
1109                 // discard
1110         }
1111         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1112         {
1113                 // sv_cmd curl
1114                 Curl_URI_Get_Callback(id, status, data);
1115         }
1116         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1117         {
1118                 // online ban list
1119                 OnlineBanList_URI_Get_Callback(id, status, data);
1120         }
1121         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1122         {
1123                 // handled by a mutator
1124         }
1125         else
1126         {
1127                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1128         }
1129 }
1130
1131 string uid2name(string myuid) {
1132         string s;
1133         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1134
1135         // FIXME remove this later after 0.6 release
1136         // convert old style broken records to correct style
1137         if(s == "")
1138         {
1139                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1140                 if(s != "")
1141                 {
1142                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1143                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1144                 }
1145         }
1146
1147         if(s == "")
1148                 s = "^1Unregistered Player";
1149         return s;
1150 }
1151
1152 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1153 {
1154     float m, i;
1155     vector start, org, delta, end, enddown, mstart;
1156
1157     m = e.dphitcontentsmask;
1158     e.dphitcontentsmask = goodcontents | badcontents;
1159
1160     org = boundmin;
1161     delta = boundmax - boundmin;
1162
1163     start = end = org;
1164
1165     for (i = 0; i < attempts; ++i)
1166     {
1167         start.x = org.x + random() * delta.x;
1168         start.y = org.y + random() * delta.y;
1169         start.z = org.z + random() * delta.z;
1170
1171         // rule 1: start inside world bounds, and outside
1172         // solid, and don't start from somewhere where you can
1173         // fall down to evil
1174         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1175         if (trace_fraction >= 1)
1176             continue;
1177         if (trace_startsolid)
1178             continue;
1179         if (trace_dphitcontents & badcontents)
1180             continue;
1181         if (trace_dphitq3surfaceflags & badsurfaceflags)
1182             continue;
1183
1184         // rule 2: if we are too high, lower the point
1185         if (trace_fraction * delta.z > maxaboveground)
1186             start = trace_endpos + '0 0 1' * maxaboveground;
1187         enddown = trace_endpos;
1188
1189         // rule 3: make sure we aren't outside the map. This only works
1190         // for somewhat well formed maps. A good rule of thumb is that
1191         // the map should have a convex outside hull.
1192         // these can be traceLINES as we already verified the starting box
1193         mstart = start + 0.5 * (e.mins + e.maxs);
1194         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1195         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1196             continue;
1197         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1198         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1199             continue;
1200         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1201         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1202             continue;
1203         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1204         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1205             continue;
1206         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1207         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1208             continue;
1209
1210         // rule 4: we must "see" some spawnpoint or item
1211     entity sp = NULL;
1212     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1213     {
1214         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1215         {
1216                 sp = it;
1217                 break;
1218         }
1219     });
1220         if(!sp)
1221         {
1222                 IL_EACH(g_items, checkpvs(mstart, it),
1223                 {
1224                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1225                         {
1226                                 sp = it;
1227                                 break;
1228                         }
1229                 });
1230
1231                 if(!sp)
1232                         continue;
1233         }
1234
1235         // find a random vector to "look at"
1236         end.x = org.x + random() * delta.x;
1237         end.y = org.y + random() * delta.y;
1238         end.z = org.z + random() * delta.z;
1239         end = start + normalize(end - start) * vlen(delta);
1240
1241         // rule 4: start TO end must not be too short
1242         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1243         if (trace_startsolid)
1244             continue;
1245         if (trace_fraction < minviewdistance / vlen(delta))
1246             continue;
1247
1248         // rule 5: don't want to look at sky
1249         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1250             continue;
1251
1252         // rule 6: we must not end up in trigger_hurt
1253         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1254             continue;
1255
1256         break;
1257     }
1258
1259     e.dphitcontentsmask = m;
1260
1261     if (i < attempts)
1262     {
1263         setorigin(e, start);
1264         e.angles = vectoangles(end - start);
1265         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1266         return true;
1267     }
1268     else
1269         return false;
1270 }
1271
1272 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1273 {
1274         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1275 }
1276
1277 void write_recordmarker(entity pl, float tstart, float dt)
1278 {
1279     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1280
1281     // also write a marker into demo files for demotc-race-record-extractor to find
1282     stuffcmd(pl,
1283              strcat(
1284                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1285                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1286 }
1287
1288 void attach_sameorigin(entity e, entity to, string tag)
1289 {
1290     vector org, t_forward, t_left, t_up, e_forward, e_up;
1291     float tagscale;
1292
1293     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1294     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1295     t_forward = v_forward * tagscale;
1296     t_left = v_right * -tagscale;
1297     t_up = v_up * tagscale;
1298
1299     e.origin_x = org * t_forward;
1300     e.origin_y = org * t_left;
1301     e.origin_z = org * t_up;
1302
1303     // current forward and up directions
1304     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1305                 e.angles = AnglesTransform_FromVAngles(e.angles);
1306         else
1307                 e.angles = AnglesTransform_FromAngles(e.angles);
1308     fixedmakevectors(e.angles);
1309
1310     // untransform forward, up!
1311     e_forward.x = v_forward * t_forward;
1312     e_forward.y = v_forward * t_left;
1313     e_forward.z = v_forward * t_up;
1314     e_up.x = v_up * t_forward;
1315     e_up.y = v_up * t_left;
1316     e_up.z = v_up * t_up;
1317
1318     e.angles = fixedvectoangles2(e_forward, e_up);
1319     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1320                 e.angles = AnglesTransform_ToVAngles(e.angles);
1321         else
1322                 e.angles = AnglesTransform_ToAngles(e.angles);
1323
1324     setattachment(e, to, tag);
1325     setorigin(e, e.origin);
1326 }
1327
1328 void detach_sameorigin(entity e)
1329 {
1330     vector org;
1331     org = gettaginfo(e, 0);
1332     e.angles = fixedvectoangles2(v_forward, v_up);
1333     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1334                 e.angles = AnglesTransform_ToVAngles(e.angles);
1335         else
1336                 e.angles = AnglesTransform_ToAngles(e.angles);
1337     setorigin(e, org);
1338     setattachment(e, NULL, "");
1339     setorigin(e, e.origin);
1340 }
1341
1342 void follow_sameorigin(entity e, entity to)
1343 {
1344     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1345     e.aiment = to; // make the hole follow bmodel
1346     e.punchangle = to.angles; // the original angles of bmodel
1347     e.view_ofs = e.origin - to.origin; // relative origin
1348     e.v_angle = e.angles - to.angles; // relative angles
1349 }
1350
1351 void unfollow_sameorigin(entity e)
1352 {
1353     set_movetype(e, MOVETYPE_NONE);
1354 }
1355
1356 entity gettaginfo_relative_ent;
1357 vector gettaginfo_relative(entity e, float tag)
1358 {
1359     if (!gettaginfo_relative_ent)
1360     {
1361         gettaginfo_relative_ent = spawn();
1362         gettaginfo_relative_ent.effects = EF_NODRAW;
1363     }
1364     gettaginfo_relative_ent.model = e.model;
1365     gettaginfo_relative_ent.modelindex = e.modelindex;
1366     gettaginfo_relative_ent.frame = e.frame;
1367     return gettaginfo(gettaginfo_relative_ent, tag);
1368 }
1369
1370 .string aiment_classname;
1371 .float aiment_deadflag;
1372 void SetMovetypeFollow(entity ent, entity e)
1373 {
1374         // FIXME this may not be warpzone aware
1375         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1376         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1377         ent.aiment = e; // make the hole follow bmodel
1378         ent.punchangle = e.angles; // the original angles of bmodel
1379         ent.view_ofs = ent.origin - e.origin; // relative origin
1380         ent.v_angle = ent.angles - e.angles; // relative angles
1381         ent.aiment_classname = strzone(e.classname);
1382         ent.aiment_deadflag = e.deadflag;
1383 }
1384 void UnsetMovetypeFollow(entity ent)
1385 {
1386         set_movetype(ent, MOVETYPE_FLY);
1387         PROJECTILE_MAKETRIGGER(ent);
1388         ent.aiment = NULL;
1389 }
1390 float LostMovetypeFollow(entity ent)
1391 {
1392 /*
1393         if(ent.move_movetype != MOVETYPE_FOLLOW)
1394                 if(ent.aiment)
1395                         error("???");
1396 */
1397         if(ent.aiment)
1398         {
1399                 if(ent.aiment.classname != ent.aiment_classname)
1400                         return 1;
1401                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1402                         return 1;
1403         }
1404         return 0;
1405 }
1406
1407 .bool pushable;
1408 bool isPushable(entity e)
1409 {
1410         if(e.pushable)
1411                 return true;
1412         if(IS_VEHICLE(e))
1413                 return false;
1414         if(e.iscreature)
1415                 return true;
1416         switch(e.classname)
1417         {
1418                 case "body":
1419                 case "droppedweapon":
1420                         return true;
1421                 case "bullet": // antilagged bullets can't hit this either
1422                         return false;
1423         }
1424         if (e.projectiledeathtype)
1425                 return true;
1426         return false;
1427 }