qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35 string ColoredTeamName(float t);
  36
  37 string admin_name(void)
  38 {
  39         if(autocvar_sv_adminnick != "")
  40                 return autocvar_sv_adminnick;
  41         else
  42                 return "SERVER ADMIN";
  43 }
  44
  45 float DistributeEvenly_amount;
  46 float DistributeEvenly_totalweight;
  47 void DistributeEvenly_Init(float amount, float totalweight)
  48 {
  49     if (DistributeEvenly_amount)
  50     {
  51         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  52         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  53     }
  54     if (totalweight == 0)
  55         DistributeEvenly_amount = 0;
  56     else
  57         DistributeEvenly_amount = amount;
  58     DistributeEvenly_totalweight = totalweight;
  59 }
  60 float DistributeEvenly_Get(float weight)
  61 {
  62     float f;
  63     if (weight <= 0)
  64         return 0;
  65     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  66     DistributeEvenly_totalweight -= weight;
  67     DistributeEvenly_amount -= f;
  68     return f;
  69 }
  70 float DistributeEvenly_GetRandomized(float weight)
  71 {
  72     float f;
  73     if (weight <= 0)
  74         return 0;
  75     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  76     DistributeEvenly_totalweight -= weight;
  77     DistributeEvenly_amount -= f;
  78     return f;
  79 }
  80
  81 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  82
  83
  84 string STR_PLAYER = "player";
  85 string STR_SPECTATOR = "spectator";
  86 string STR_OBSERVER = "observer";
  87
  88 #if 0
  89 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  90 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  91 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  92 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  93 #else
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  97 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  98 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if(v.classname != STR_PLAYER)
  99 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 100 #endif
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + ((ent.classname == STR_PLAYER) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void bcenterprint(string s)
 111 {
 112     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 113     entity head;
 114     FOR_EACH_PLAYER(head)
 115     if (clienttype(head) == CLIENTTYPE_REAL)
 116         centerprint(head, s);
 117 }
 118
 119 void GameLogEcho(string s)
 120 {
 121     string fn;
 122     float matches;
 123
 124     if (autocvar_sv_eventlog_files)
 125     {
 126         if (!logfile_open)
 127         {
 128             logfile_open = TRUE;
 129             matches = autocvar_sv_eventlog_files_counter + 1;
 130             cvar_set("sv_eventlog_files_counter", ftos(matches));
 131             fn = ftos(matches);
 132             if (strlen(fn) < 8)
 133                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 134             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 135             logfile = fopen(fn, FILE_APPEND);
 136             fputs(logfile, ":logversion:3\n");
 137         }
 138         if (logfile >= 0)
 139         {
 140             if (autocvar_sv_eventlog_files_timestamps)
 141                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 142             else
 143                 fputs(logfile, strcat(s, "\n"));
 144         }
 145     }
 146     if (autocvar_sv_eventlog_console)
 147     {
 148         print(s, "\n");
 149     }
 150 }
 151
 152 void GameLogInit()
 153 {
 154     logfile_open = 0;
 155     // will be opened later
 156 }
 157
 158 void GameLogClose()
 159 {
 160     if (logfile_open && logfile >= 0)
 161     {
 162         fclose(logfile);
 163         logfile = -1;
 164     }
 165 }
 166
 167 float spawnpoint_nag;
 168 void relocate_spawnpoint()
 169 {
 170     // nudge off the floor
 171     setorigin(self, self.origin + '0 0 1');
 172
 173     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 174     if (trace_startsolid)
 175     {
 176         vector o;
 177         o = self.origin;
 178         self.mins = PL_MIN;
 179         self.maxs = PL_MAX;
 180         if (!move_out_of_solid(self))
 181             objerror("could not get out of solid at all!");
 182         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 183         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 184         print(" ", ftos(self.origin_y - o_y));
 185         print(" ", ftos(self.origin_z - o_z), "'\n");
 186         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 187         {
 188             if (!spawnpoint_nag)
 189                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 190             spawnpoint_nag = 1;
 191         }
 192         else
 193         {
 194             setorigin(self, o);
 195             self.mins = self.maxs = '0 0 0';
 196             objerror("player spawn point in solid, mapper sucks!\n");
 197             return;
 198         }
 199     }
 200
 201     self.use = spawnpoint_use;
 202     self.team_saved = self.team;
 203     if (!self.cnt)
 204         self.cnt = 1;
 205
 206     if (have_team_spawns != 0)
 207         if (self.team)
 208             have_team_spawns = 1;
 209     have_team_spawns_forteam[self.team] = 1;
 210
 211     if (autocvar_r_showbboxes)
 212     {
 213         // show where spawnpoints point at too
 214         makevectors(self.angles);
 215         entity e;
 216         e = spawn();
 217         e.classname = "info_player_foo";
 218         setorigin(e, self.origin + v_forward * 24);
 219         setsize(e, '-8 -8 -8', '8 8 8');
 220         e.solid = SOLID_TRIGGER;
 221     }
 222 }
 223
 224 #define strstr strstrofs
 225 /*
 226 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 227 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 228 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 229 // BE CONSTANT OR strzoneD!
 230 float strstr(string haystack, string needle, float offset)
 231 {
 232         float len, endpos;
 233         string found;
 234         len = strlen(needle);
 235         endpos = strlen(haystack) - len;
 236         while(offset <= endpos)
 237         {
 238                 found = substring(haystack, offset, len);
 239                 if(found == needle)
 240                         return offset;
 241                 offset = offset + 1;
 242         }
 243         return -1;
 244 }
 245 */
 246
 247 float NUM_NEAREST_ENTITIES = 4;
 248 entity nearest_entity[NUM_NEAREST_ENTITIES];
 249 float nearest_length[NUM_NEAREST_ENTITIES];
 250 entity findnearest(vector point, .string field, string value, vector axismod)
 251 {
 252     entity localhead;
 253     float i;
 254     float j;
 255     float len;
 256     vector dist;
 257
 258     float num_nearest;
 259     num_nearest = 0;
 260
 261     localhead = find(world, field, value);
 262     while (localhead)
 263     {
 264         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 265             dist = localhead.oldorigin;
 266         else
 267             dist = localhead.origin;
 268         dist = dist - point;
 269         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 270         len = vlen(dist);
 271
 272         for (i = 0; i < num_nearest; ++i)
 273         {
 274             if (len < nearest_length[i])
 275                 break;
 276         }
 277
 278         // now i tells us where to insert at
 279         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 280         if (i < NUM_NEAREST_ENTITIES)
 281         {
 282             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 283             {
 284                 nearest_length[j + 1] = nearest_length[j];
 285                 nearest_entity[j + 1] = nearest_entity[j];
 286             }
 287             nearest_length[i] = len;
 288             nearest_entity[i] = localhead;
 289             if (num_nearest < NUM_NEAREST_ENTITIES)
 290                 num_nearest = num_nearest + 1;
 291         }
 292
 293         localhead = find(localhead, field, value);
 294     }
 295
 296     // now use the first one from our list that we can see
 297     for (i = 0; i < num_nearest; ++i)
 298     {
 299         traceline(point, nearest_entity[i].origin, TRUE, world);
 300         if (trace_fraction == 1)
 301         {
 302             if (i != 0)
 303             {
 304                 dprint("Nearest point (");
 305                 dprint(nearest_entity[0].netname);
 306                 dprint(") is not visible, using a visible one.\n");
 307             }
 308             return nearest_entity[i];
 309         }
 310     }
 311
 312     if (num_nearest == 0)
 313         return world;
 314
 315     dprint("Not seeing any location point, using nearest as fallback.\n");
 316     /* DEBUGGING CODE:
 317     dprint("Candidates were: ");
 318     for(j = 0; j < num_nearest; ++j)
 319     {
 320         if(j != 0)
 321                 dprint(", ");
 322         dprint(nearest_entity[j].netname);
 323     }
 324     dprint("\n");
 325     */
 326
 327     return nearest_entity[0];
 328 }
 329
 330 void spawnfunc_target_location()
 331 {
 332     self.classname = "target_location";
 333     // location name in netname
 334     // eventually support: count, teamgame selectors, line of sight?
 335 }
 336
 337 void spawnfunc_info_location()
 338 {
 339     self.classname = "target_location";
 340     self.message = self.netname;
 341 }
 342
 343 string NearestLocation(vector p)
 344 {
 345     entity loc;
 346     string ret;
 347     ret = "somewhere";
 348     loc = findnearest(p, classname, "target_location", '1 1 1');
 349     if (loc)
 350     {
 351         ret = loc.message;
 352     }
 353     else
 354     {
 355         loc = findnearest(p, target, "###item###", '1 1 4');
 356         if (loc)
 357             ret = loc.netname;
 358     }
 359     return ret;
 360 }
 361
 362 string formatmessage(string msg)
 363 {
 364         float p, p1, p2;
 365         float n;
 366         vector cursor;
 367         entity cursor_ent;
 368         string escape;
 369         string replacement;
 370         p = 0;
 371         n = 7;
 372
 373         WarpZone_crosshair_trace(self);
 374         cursor = trace_endpos;
 375         cursor_ent = trace_ent;
 376
 377         while (1) {
 378                 if (n < 1)
 379                         break; // too many replacements
 380
 381                 n = n - 1;
 382                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 383                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 384
 385                 if (p1 < 0)
 386                         p1 = p2;
 387
 388                 if (p2 < 0)
 389                         p2 = p1;
 390
 391                 p = min(p1, p2);
 392
 393                 if (p < 0)
 394                         break;
 395
 396                 replacement = substring(msg, p, 2);
 397                 escape = substring(msg, p + 1, 1);
 398
 399                 if (escape == "%")
 400                         replacement = "%";
 401                 else if (escape == "\\")
 402                         replacement = "\\";
 403                 else if (escape == "n")
 404                         replacement = "\n";
 405                 else if (escape == "a")
 406                         replacement = ftos(floor(self.armorvalue));
 407                 else if (escape == "h")
 408                         replacement = ftos(floor(self.health));
 409                 else if (escape == "l")
 410                         replacement = NearestLocation(self.origin);
 411                 else if (escape == "y")
 412                         replacement = NearestLocation(cursor);
 413                 else if (escape == "d")
 414                         replacement = NearestLocation(self.death_origin);
 415                 else if (escape == "w") {
 416                         float wep;
 417                         wep = self.weapon;
 418                         if (!wep)
 419                                 wep = self.switchweapon;
 420                         if (!wep)
 421                                 wep = self.cnt;
 422                         replacement = W_Name(wep);
 423                 } else if (escape == "W") {
 424                         if (self.items & IT_SHELLS) replacement = "shells";
 425                         else if (self.items & IT_NAILS) replacement = "bullets";
 426                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 427                         else if (self.items & IT_CELLS) replacement = "cells";
 428                         else replacement = "batteries"; // ;)
 429                 } else if (escape == "x") {
 430                         replacement = cursor_ent.netname;
 431                         if (replacement == "" || !cursor_ent)
 432                                 replacement = "nothing";
 433                 } else if (escape == "s")
 434                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 435                 else if (escape == "S")
 436                         replacement = ftos(vlen(self.velocity));
 437
 438                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 439                 p = p + strlen(replacement);
 440         }
 441         return msg;
 442 }
 443
 444 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 445         return (value == 0) ? FALSE : TRUE;
 446 }
 447
 448 /*
 449 =============
 450 GetCvars
 451 =============
 452 Called with:
 453   0:  sends the request
 454   >0: receives a cvar from name=argv(f) value=argv(f+1)
 455 */
 456 void GetCvars_handleString(string thisname, float f, .string field, string name)
 457 {
 458         if (f < 0)
 459         {
 460                 if (self.field)
 461                         strunzone(self.field);
 462                 self.field = string_null;
 463         }
 464         else if (f > 0)
 465         {
 466                 if (thisname == name)
 467                 {
 468                         if (self.field)
 469                                 strunzone(self.field);
 470                         self.field = strzone(argv(f + 1));
 471                 }
 472         }
 473         else
 474                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 475 }
 476 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 477 {
 478         GetCvars_handleString(thisname, f, field, name);
 479         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 480                 if (thisname == name)
 481                 {
 482                         string s;
 483                         s = func(strcat1(self.field));
 484                         if (s != self.field)
 485                         {
 486                                 strunzone(self.field);
 487                                 self.field = strzone(s);
 488                         }
 489                 }
 490 }
 491 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 492 {
 493         if (f < 0)
 494         {
 495         }
 496         else if (f > 0)
 497         {
 498                 if (thisname == name)
 499                         self.field = stof(argv(f + 1));
 500         }
 501         else
 502                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 503 }
 504 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 505 {
 506         if (f < 0)
 507         {
 508         }
 509         else if (f > 0)
 510         {
 511                 if (thisname == name)
 512                 {
 513                         if(!self.field)
 514                         {
 515                                 self.field = stof(argv(f + 1));
 516                                 if(!self.field)
 517                                         self.field = -1;
 518                         }
 519                 }
 520         }
 521         else
 522         {
 523                 if(!self.field)
 524                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 525         }
 526 }
 527 float w_getbestweapon(entity e);
 528 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 529 {
 530         string o;
 531         o = W_FixWeaponOrder_ForceComplete(wo);
 532         if(self.weaponorder_byimpulse)
 533         {
 534                 strunzone(self.weaponorder_byimpulse);
 535                 self.weaponorder_byimpulse = string_null;
 536         }
 537         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 538         return o;
 539 }
 540 void GetCvars(float f)
 541 {
 542         string s = string_null;
 543
 544         if (f > 0)
 545                 s = strcat1(argv(f));
 546
 547         get_cvars_f = f;
 548         get_cvars_s = s;
 549         MUTATOR_CALLHOOK(GetCvars);
 550         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 551         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 552         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 553         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 554         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 562         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 563         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 564         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 565         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 566         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 567         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 568         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 569         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 570         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 571         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 572         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 573
 574         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 575         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 576
 577         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 578         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 579         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 580         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 581         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 582
 583         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 584         if (f > 0)
 585         {
 586                 if (s == "cl_weaponpriority")
 587                         self.switchweapon = w_getbestweapon(self);
 588                 if (s == "cl_allow_uidtracking")
 589                         PlayerStats_AddPlayer(self);
 590         }
 591 }
 592
 593 void backtrace(string msg)
 594 {
 595     float dev, war;
 596     dev = autocvar_developer;
 597     war = autocvar_prvm_backtraceforwarnings;
 598     cvar_set("developer", "1");
 599     cvar_set("prvm_backtraceforwarnings", "1");
 600     print("\n");
 601     print("--- CUT HERE ---\nWARNING: ");
 602     print(msg);
 603     print("\n");
 604     remove(world); // isn't there any better way to cause a backtrace?
 605     print("\n--- CUT UNTIL HERE ---\n");
 606     cvar_set("developer", ftos(dev));
 607     cvar_set("prvm_backtraceforwarnings", ftos(war));
 608 }
 609
 610 string Team_ColorCode(float teamid)
 611 {
 612     if (teamid == COLOR_TEAM1)
 613         return "^1";
 614     else if (teamid == COLOR_TEAM2)
 615         return "^4";
 616     else if (teamid == COLOR_TEAM3)
 617         return "^3";
 618     else if (teamid == COLOR_TEAM4)
 619         return "^6";
 620     else
 621         return "^7";
 622 }
 623
 624 string Team_ColorName(float t)
 625 {
 626     // fixme: Search for team entities and get their .netname's!
 627     if (t == COLOR_TEAM1)
 628         return "Red";
 629     if (t == COLOR_TEAM2)
 630         return "Blue";
 631     if (t == COLOR_TEAM3)
 632         return "Yellow";
 633     if (t == COLOR_TEAM4)
 634         return "Pink";
 635     return "Neutral";
 636 }
 637
 638 string Team_ColorNameLowerCase(float t)
 639 {
 640     // fixme: Search for team entities and get their .netname's!
 641     if (t == COLOR_TEAM1)
 642         return "red";
 643     if (t == COLOR_TEAM2)
 644         return "blue";
 645     if (t == COLOR_TEAM3)
 646         return "yellow";
 647     if (t == COLOR_TEAM4)
 648         return "pink";
 649     return "neutral";
 650 }
 651
 652 float ColourToNumber(string team_colour)
 653 {
 654         if (team_colour == "red")
 655                 return COLOR_TEAM1;
 656
 657         if (team_colour == "blue")
 658                 return COLOR_TEAM2;
 659
 660         if (team_colour == "yellow")
 661                 return COLOR_TEAM3;
 662
 663         if (team_colour == "pink")
 664                 return COLOR_TEAM4;
 665
 666         if (team_colour == "auto")
 667                 return 0;
 668
 669         return -1;
 670 }
 671
 672 float NumberToTeamNumber(float number)
 673 {
 674         if (number == 1)
 675                 return COLOR_TEAM1;
 676
 677         if (number == 2)
 678                 return COLOR_TEAM2;
 679
 680         if (number == 3)
 681                 return COLOR_TEAM3;
 682
 683         if (number == 4)
 684                 return COLOR_TEAM4;
 685
 686         return -1;
 687 }
 688
 689 // decolorizes and team colors the player name when needed
 690 string playername(entity p)
 691 {
 692     string t;
 693     if (teamplay && !intermission_running && p.classname == "player")
 694     {
 695         t = Team_ColorCode(p.team);
 696         return strcat(t, strdecolorize(p.netname));
 697     }
 698     else
 699         return p.netname;
 700 }
 701
 702 vector randompos(vector m1, vector m2)
 703 {
 704     vector v;
 705     m2 = m2 - m1;
 706     v_x = m2_x * random() + m1_x;
 707     v_y = m2_y * random() + m1_y;
 708     v_z = m2_z * random() + m1_z;
 709     return  v;
 710 }
 711
 712 //#NO AUTOCVARS START
 713
 714 float g_pickup_shells;
 715 float g_pickup_shells_max;
 716 float g_pickup_nails;
 717 float g_pickup_nails_max;
 718 float g_pickup_rockets;
 719 float g_pickup_rockets_max;
 720 float g_pickup_cells;
 721 float g_pickup_cells_max;
 722 float g_pickup_fuel;
 723 float g_pickup_fuel_jetpack;
 724 float g_pickup_fuel_max;
 725 float g_pickup_armorsmall;
 726 float g_pickup_armorsmall_max;
 727 float g_pickup_armorsmall_anyway;
 728 float g_pickup_armormedium;
 729 float g_pickup_armormedium_max;
 730 float g_pickup_armormedium_anyway;
 731 float g_pickup_armorbig;
 732 float g_pickup_armorbig_max;
 733 float g_pickup_armorbig_anyway;
 734 float g_pickup_armorlarge;
 735 float g_pickup_armorlarge_max;
 736 float g_pickup_armorlarge_anyway;
 737 float g_pickup_healthsmall;
 738 float g_pickup_healthsmall_max;
 739 float g_pickup_healthsmall_anyway;
 740 float g_pickup_healthmedium;
 741 float g_pickup_healthmedium_max;
 742 float g_pickup_healthmedium_anyway;
 743 float g_pickup_healthlarge;
 744 float g_pickup_healthlarge_max;
 745 float g_pickup_healthlarge_anyway;
 746 float g_pickup_healthmega;
 747 float g_pickup_healthmega_max;
 748 float g_pickup_healthmega_anyway;
 749 float g_pickup_ammo_anyway;
 750 float g_pickup_weapons_anyway;
 751 float g_weaponarena;
 752 WEPSET_DECLARE_A(g_weaponarena_weapons);
 753 float g_weaponarena_random;
 754 float g_weaponarena_random_with_laser;
 755 string g_weaponarena_list;
 756 float g_weaponspeedfactor;
 757 float g_weaponratefactor;
 758 float g_weapondamagefactor;
 759 float g_weaponforcefactor;
 760 float g_weaponspreadfactor;
 761
 762 WEPSET_DECLARE_A(start_weapons);
 763 WEPSET_DECLARE_A(start_weapons_default);
 764 WEPSET_DECLARE_A(start_weapons_defaultmask);
 765 float start_items;
 766 float start_ammo_shells;
 767 float start_ammo_nails;
 768 float start_ammo_rockets;
 769 float start_ammo_cells;
 770 float start_ammo_fuel;
 771 float start_health;
 772 float start_armorvalue;
 773 WEPSET_DECLARE_A(warmup_start_weapons);
 774 WEPSET_DECLARE_A(warmup_start_weapons_default);
 775 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 776 float warmup_start_ammo_shells;
 777 float warmup_start_ammo_nails;
 778 float warmup_start_ammo_rockets;
 779 float warmup_start_ammo_cells;
 780 float warmup_start_ammo_fuel;
 781 float warmup_start_health;
 782 float warmup_start_armorvalue;
 783 float g_weapon_stay;
 784
 785 entity get_weaponinfo(float w);
 786
 787 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 788 {
 789         var float i = weaponinfo.weapon;
 790         var float d = 0;
 791
 792         if (!i)
 793                 return 0;
 794
 795         if (g_lms || g_ca || allguns)
 796         {
 797                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 798                         d = TRUE;
 799                 else
 800                         d = FALSE;
 801         }
 802         else if (g_cts)
 803                 d = (i == WEP_SHOTGUN);
 804         else if (g_nexball)
 805                 d = 0; // weapon is set a few lines later
 806         else
 807                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 808
 809         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 810                 d |= (i == WEP_HOOK);
 811         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 812                 d = 0;
 813
 814         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 815
 816         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 817
 818         // bit order in t:
 819         // 1: want or not
 820         // 2: is default?
 821         // 4: is set by default?
 822         if(t < 0)
 823                 t = 4 | (3 * d);
 824         else
 825                 t |= (2 * d);
 826
 827         return t;
 828 }
 829
 830 void readplayerstartcvars()
 831 {
 832         entity e;
 833         float i, j, t;
 834         string s;
 835
 836         // initialize starting values for players
 837         WEPSET_CLEAR_A(start_weapons);
 838         WEPSET_CLEAR_A(start_weapons_default);
 839         WEPSET_CLEAR_A(start_weapons_defaultmask);
 840         start_items = 0;
 841         start_ammo_shells = 0;
 842         start_ammo_nails = 0;
 843         start_ammo_rockets = 0;
 844         start_ammo_cells = 0;
 845         start_health = cvar("g_balance_health_start");
 846         start_armorvalue = cvar("g_balance_armor_start");
 847
 848         g_weaponarena = 0;
 849         WEPSET_CLEAR_A(g_weaponarena_weapons);
 850
 851         s = cvar_string("g_weaponarena");
 852         if (s == "0" || s == "")
 853         {
 854                 if(g_lms || g_ca)
 855                         s = "most";
 856         }
 857
 858         if (s == "0" || s == "")
 859         {
 860                 // no arena
 861         }
 862         else if (s == "off")
 863         {
 864                 // forcibly turn off weaponarena
 865         }
 866         else if (s == "all")
 867         {
 868                 g_weaponarena = 1;
 869                 g_weaponarena_list = "All Weapons";
 870                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 871                 {
 872                         e = get_weaponinfo(j);
 873                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 874                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 875                 }
 876         }
 877         else if (s == "most")
 878         {
 879                 g_weaponarena = 1;
 880                 g_weaponarena_list = "Most Weapons";
 881                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 882                 {
 883                         e = get_weaponinfo(j);
 884                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 885                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 886                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 887                 }
 888         }
 889         else if (s == "none")
 890         {
 891                 g_weaponarena = 1;
 892                 g_weaponarena_list = "No Weapons";
 893         }
 894         else
 895         {
 896                 g_weaponarena = 1;
 897                 t = tokenize_console(s);
 898                 g_weaponarena_list = "";
 899                 for (i = 0; i < t; ++i)
 900                 {
 901                         s = argv(i);
 902                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 903                         {
 904                                 e = get_weaponinfo(j);
 905                                 if (e.netname == s)
 906                                 {
 907                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 908                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 909                                         break;
 910                                 }
 911                         }
 912                         if (j > WEP_LAST)
 913                         {
 914                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 915                         }
 916                 }
 917                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 918         }
 919
 920         if(g_weaponarena)
 921                 g_weaponarena_random = cvar("g_weaponarena_random");
 922         else
 923                 g_weaponarena_random = 0;
 924         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 925
 926         if (g_weaponarena)
 927         {
 928                 g_minstagib = 0; // incompatible
 929                 g_pinata = 0; // incompatible
 930                 g_weapon_stay = 0; // incompatible
 931                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 932                 if(!(g_lms || g_ca))
 933                         start_items |= IT_UNLIMITED_AMMO;
 934         }
 935         else if (g_minstagib)
 936         {
 937                 g_pinata = 0; // incompatible
 938                 g_weapon_stay = 0; // incompatible
 939                 g_bloodloss = 0; // incompatible
 940                 start_health = 100;
 941                 start_armorvalue = 0;
 942                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 943                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 944                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 945
 946                 if (g_minstagib_invis_alpha <= 0)
 947                         g_minstagib_invis_alpha = -1;
 948         }
 949         else
 950         {
 951                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 952                 {
 953                         e = get_weaponinfo(i);
 954                         float w = want_weapon("g_start_weapon_", e, FALSE);
 955                         if(w & 1)
 956                                 WEPSET_OR_AW(start_weapons, i);
 957                         if(w & 2)
 958                                 WEPSET_OR_AW(start_weapons_default, i);
 959                         if(w & 4)
 960                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 961                 }
 962         }
 963
 964         if(!cvar("g_use_ammunition"))
 965                 start_items |= IT_UNLIMITED_AMMO;
 966
 967         if(cvar("g_nexball"))
 968                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 969
 970         if(g_minstagib)
 971         {
 972                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 973                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 974         }
 975         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 976         {
 977                 start_ammo_rockets = 999;
 978                 start_ammo_shells = 999;
 979                 start_ammo_cells = 999;
 980                 start_ammo_nails = 999;
 981                 start_ammo_fuel = 999;
 982         }
 983         else
 984         {
 985                 if(g_lms || g_ca)
 986                 {
 987                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 988                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 989                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 990                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 991                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 992                 }
 993                 else
 994                 {
 995                         start_ammo_shells = cvar("g_start_ammo_shells");
 996                         start_ammo_nails = cvar("g_start_ammo_nails");
 997                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 998                         start_ammo_cells = cvar("g_start_ammo_cells");
 999                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1000                 }
1001         }
1002
1003         if (g_lms || g_ca)
1004         {
1005                 start_health = cvar("g_lms_start_health");
1006                 start_armorvalue = cvar("g_lms_start_armor");
1007         }
1008
1009         if (inWarmupStage)
1010         {
1011                 warmup_start_ammo_shells = start_ammo_shells;
1012                 warmup_start_ammo_nails = start_ammo_nails;
1013                 warmup_start_ammo_rockets = start_ammo_rockets;
1014                 warmup_start_ammo_cells = start_ammo_cells;
1015                 warmup_start_ammo_fuel = start_ammo_fuel;
1016                 warmup_start_health = start_health;
1017                 warmup_start_armorvalue = start_armorvalue;
1018                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
1019                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
1020                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
1021
1022                 if (!g_weaponarena && !g_minstagib && !g_ca)
1023                 {
1024                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1025                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1026                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1027                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1028                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1029                         warmup_start_health = cvar("g_warmup_start_health");
1030                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1031                         WEPSET_CLEAR_A(warmup_start_weapons);
1032                         WEPSET_CLEAR_A(warmup_start_weapons_default);
1033                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
1034                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1035                         {
1036                                 e = get_weaponinfo(i);
1037                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
1038                                 if(w & 1)
1039                                         WEPSET_OR_AW(warmup_start_weapons, i);
1040                                 if(w & 2)
1041                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
1042                                 if(w & 4)
1043                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
1044                         }
1045                 }
1046         }
1047
1048         if (g_jetpack)
1049                 start_items |= IT_JETPACK;
1050
1051         MUTATOR_CALLHOOK(SetStartItems);
1052
1053         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
1054         {
1055                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1056                 start_items |= IT_FUEL_REGEN;
1057                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1058                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1059         }
1060
1061         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1062         {
1063                 e = get_weaponinfo(i);
1064                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
1065                         weapon_action(i, WR_PRECACHE);
1066         }
1067
1068         start_ammo_shells = max(0, start_ammo_shells);
1069         start_ammo_nails = max(0, start_ammo_nails);
1070         start_ammo_cells = max(0, start_ammo_cells);
1071         start_ammo_rockets = max(0, start_ammo_rockets);
1072         start_ammo_fuel = max(0, start_ammo_fuel);
1073
1074         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1075         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1076         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1077         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1078         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1079 }
1080
1081 float g_bugrigs;
1082 float g_bugrigs_planar_movement;
1083 float g_bugrigs_planar_movement_car_jumping;
1084 float g_bugrigs_reverse_spinning;
1085 float g_bugrigs_reverse_speeding;
1086 float g_bugrigs_reverse_stopping;
1087 float g_bugrigs_air_steering;
1088 float g_bugrigs_angle_smoothing;
1089 float g_bugrigs_friction_floor;
1090 float g_bugrigs_friction_brake;
1091 float g_bugrigs_friction_air;
1092 float g_bugrigs_accel;
1093 float g_bugrigs_speed_ref;
1094 float g_bugrigs_speed_pow;
1095 float g_bugrigs_steer;
1096
1097 float g_touchexplode;
1098 float g_touchexplode_radius;
1099 float g_touchexplode_damage;
1100 float g_touchexplode_edgedamage;
1101 float g_touchexplode_force;
1102
1103 float sv_autotaunt;
1104 float sv_taunt;
1105
1106 string GetGametype(); // g_world.qc
1107 void readlevelcvars(void)
1108 {
1109         g_minstagib = cvar("g_minstagib");
1110
1111         // load ALL the mutators
1112         if(cvar("g_dodging"))
1113                 MUTATOR_ADD(mutator_dodging);
1114         if(cvar("g_spawn_near_teammate"))
1115                 MUTATOR_ADD(mutator_spawn_near_teammate);
1116         if(cvar("g_physical_items"))
1117                 MUTATOR_ADD(mutator_physical_items);
1118         if(!g_minstagib)
1119         {
1120                 if(cvar("g_invincible_projectiles"))
1121                         MUTATOR_ADD(mutator_invincibleprojectiles);
1122                 if(cvar("g_new_toys"))
1123                         MUTATOR_ADD(mutator_new_toys);
1124                 if(cvar("g_nix"))
1125                         MUTATOR_ADD(mutator_nix);
1126                 if(cvar("g_rocket_flying"))
1127                         MUTATOR_ADD(mutator_rocketflying);
1128                 if(cvar("g_vampire"))
1129                         MUTATOR_ADD(mutator_vampire);
1130                 if(cvar("g_superspectate"))
1131                         MUTATOR_ADD(mutator_superspec);
1132         }
1133
1134         // is this a mutator? is this a mode?
1135         if(cvar("g_sandbox"))
1136                 MUTATOR_ADD(sandbox);
1137
1138         if(cvar("sv_allow_fullbright"))
1139                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1140
1141     g_bugrigs = cvar("g_bugrigs");
1142     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1143     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1144     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1145     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1146     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1147     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1148     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1149     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1150     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1151     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1152     g_bugrigs_accel = cvar("g_bugrigs_accel");
1153     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1154     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1155     g_bugrigs_steer = cvar("g_bugrigs_steer");
1156
1157     g_touchexplode = cvar("g_touchexplode");
1158     g_touchexplode_radius = cvar("g_touchexplode_radius");
1159     g_touchexplode_damage = cvar("g_touchexplode_damage");
1160     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1161     g_touchexplode_force = cvar("g_touchexplode_force");
1162
1163         sv_clones = cvar("sv_clones");
1164         sv_gentle = cvar("sv_gentle");
1165         sv_foginterval = cvar("sv_foginterval");
1166         g_cloaked = cvar("g_cloaked");
1167     if(g_cts)
1168         g_cloaked = 1; // always enable cloak in CTS
1169         g_jump_grunt = cvar("g_jump_grunt");
1170         g_footsteps = cvar("g_footsteps");
1171         g_grappling_hook = cvar("g_grappling_hook");
1172         g_jetpack = cvar("g_jetpack");
1173         g_midair = cvar("g_midair");
1174         g_norecoil = cvar("g_norecoil");
1175         g_bloodloss = cvar("g_bloodloss");
1176         sv_maxidle = cvar("sv_maxidle");
1177         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1178         sv_autotaunt = cvar("sv_autotaunt");
1179         sv_taunt = cvar("sv_taunt");
1180
1181         inWarmupStage = cvar("g_warmup");
1182         g_warmup_limit = cvar("g_warmup_limit");
1183         g_warmup_allguns = cvar("g_warmup_allguns");
1184         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1185
1186         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1187                 inWarmupStage = 0; // these modes cannot work together, sorry
1188
1189         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1190         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1191         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1192         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1193         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1194         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1195         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1196         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1197         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1198         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1199         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1200         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1201         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1202         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1203
1204         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1205         g_weaponratefactor = cvar("g_weaponratefactor");
1206         g_weapondamagefactor = cvar("g_weapondamagefactor");
1207         g_weaponforcefactor = cvar("g_weaponforcefactor");
1208         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1209
1210         g_pickup_shells = cvar("g_pickup_shells");
1211         g_pickup_shells_max = cvar("g_pickup_shells_max");
1212         g_pickup_nails = cvar("g_pickup_nails");
1213         g_pickup_nails_max = cvar("g_pickup_nails_max");
1214         g_pickup_rockets = cvar("g_pickup_rockets");
1215         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1216         g_pickup_cells = cvar("g_pickup_cells");
1217         g_pickup_cells_max = cvar("g_pickup_cells_max");
1218         g_pickup_fuel = cvar("g_pickup_fuel");
1219         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1220         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1221         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1222         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1223         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1224         g_pickup_armormedium = cvar("g_pickup_armormedium");
1225         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1226         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1227         g_pickup_armorbig = cvar("g_pickup_armorbig");
1228         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1229         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1230         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1231         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1232         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1233         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1234         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1235         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1236         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1237         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1238         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1239         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1240         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1241         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1242         g_pickup_healthmega = cvar("g_pickup_healthmega");
1243         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1244         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1245
1246         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1247         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1248
1249         g_pinata = cvar("g_pinata");
1250
1251     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1252     if(!g_weapon_stay)
1253         g_weapon_stay = cvar("g_weapon_stay");
1254
1255         if not(inWarmupStage && !g_ca)
1256                 game_starttime = cvar("g_start_delay");
1257
1258         readplayerstartcvars();
1259 }
1260
1261 //#NO AUTOCVARS END
1262
1263 // Sound functions
1264 string precache_sound (string s) = #19;
1265 float precache_sound_index (string s) = #19;
1266
1267 #define SND_VOLUME      1
1268 #define SND_ATTENUATION 2
1269 #define SND_LARGEENTITY 8
1270 #define SND_LARGESOUND  16
1271
1272 float sound_allowed(float dest, entity e)
1273 {
1274     // sounds from world may always pass
1275     for (;;)
1276     {
1277         if (e.classname == "body")
1278             e = e.enemy;
1279         else if (e.realowner && e.realowner != e)
1280             e = e.realowner;
1281         else if (e.owner && e.owner != e)
1282             e = e.owner;
1283         else
1284             break;
1285     }
1286     // sounds to self may always pass
1287     if (dest == MSG_ONE)
1288         if (e == msg_entity)
1289             return TRUE;
1290     // sounds by players can be removed
1291     if (autocvar_bot_sound_monopoly)
1292         if (clienttype(e) == CLIENTTYPE_REAL)
1293             return FALSE;
1294     // anything else may pass
1295     return TRUE;
1296 }
1297
1298 #ifdef COMPAT_XON010_CHANNELS
1299 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1300 void sound(entity e, float chan, string samp, float vol, float atten)
1301 {
1302     if (!sound_allowed(MSG_BROADCAST, e))
1303         return;
1304     builtin_sound(e, chan, samp, vol, atten);
1305 }
1306 #else
1307 #undef sound
1308 void sound(entity e, float chan, string samp, float vol, float atten)
1309 {
1310     if (!sound_allowed(MSG_BROADCAST, e))
1311         return;
1312     sound7(e, chan, samp, vol, atten, 0, 0);
1313 }
1314 #endif
1315
1316 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1317 {
1318     float entno, idx;
1319
1320     if (!sound_allowed(dest, e))
1321         return;
1322
1323     entno = num_for_edict(e);
1324     idx = precache_sound_index(samp);
1325
1326     float sflags;
1327     sflags = 0;
1328
1329     atten = floor(atten * 64);
1330     vol = floor(vol * 255);
1331
1332     if (vol != 255)
1333         sflags |= SND_VOLUME;
1334     if (atten != 64)
1335         sflags |= SND_ATTENUATION;
1336     if (entno >= 8192 || chan < 0 || chan > 7)
1337         sflags |= SND_LARGEENTITY;
1338     if (idx >= 256)
1339         sflags |= SND_LARGESOUND;
1340
1341     WriteByte(dest, SVC_SOUND);
1342     WriteByte(dest, sflags);
1343     if (sflags & SND_VOLUME)
1344         WriteByte(dest, vol);
1345     if (sflags & SND_ATTENUATION)
1346         WriteByte(dest, atten);
1347     if (sflags & SND_LARGEENTITY)
1348     {
1349         WriteShort(dest, entno);
1350         WriteByte(dest, chan);
1351     }
1352     else
1353     {
1354         WriteShort(dest, entno * 8 + chan);
1355     }
1356     if (sflags & SND_LARGESOUND)
1357         WriteShort(dest, idx);
1358     else
1359         WriteByte(dest, idx);
1360
1361     WriteCoord(dest, o_x);
1362     WriteCoord(dest, o_y);
1363     WriteCoord(dest, o_z);
1364 }
1365 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1366 {
1367     vector o;
1368
1369     if (!sound_allowed(dest, e))
1370         return;
1371
1372     o = e.origin + 0.5 * (e.mins + e.maxs);
1373     soundtoat(dest, e, o, chan, samp, vol, atten);
1374 }
1375 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1376 {
1377     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1378 }
1379 void stopsoundto(float dest, entity e, float chan)
1380 {
1381     float entno;
1382
1383     if (!sound_allowed(dest, e))
1384         return;
1385
1386     entno = num_for_edict(e);
1387
1388     if (entno >= 8192 || chan < 0 || chan > 7)
1389     {
1390         float idx, sflags;
1391         idx = precache_sound_index("misc/null.wav");
1392         sflags = SND_LARGEENTITY;
1393         if (idx >= 256)
1394             sflags |= SND_LARGESOUND;
1395         WriteByte(dest, SVC_SOUND);
1396         WriteByte(dest, sflags);
1397         WriteShort(dest, entno);
1398         WriteByte(dest, chan);
1399         if (sflags & SND_LARGESOUND)
1400             WriteShort(dest, idx);
1401         else
1402             WriteByte(dest, idx);
1403         WriteCoord(dest, e.origin_x);
1404         WriteCoord(dest, e.origin_y);
1405         WriteCoord(dest, e.origin_z);
1406     }
1407     else
1408     {
1409         WriteByte(dest, SVC_STOPSOUND);
1410         WriteShort(dest, entno * 8 + chan);
1411     }
1412 }
1413 void stopsound(entity e, float chan)
1414 {
1415     if (!sound_allowed(MSG_BROADCAST, e))
1416         return;
1417
1418     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1419     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1420 }
1421
1422 void play2(entity e, string filename)
1423 {
1424     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1425     msg_entity = e;
1426     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1427 }
1428
1429 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1430 .float spamtime;
1431 float spamsound(entity e, float chan, string samp, float vol, float atten)
1432 {
1433     if (!sound_allowed(MSG_BROADCAST, e))
1434         return FALSE;
1435
1436     if (time > e.spamtime)
1437     {
1438         e.spamtime = time;
1439         sound(e, chan, samp, vol, atten);
1440         return TRUE;
1441     }
1442     return FALSE;
1443 }
1444
1445 void play2team(float t, string filename)
1446 {
1447     entity head;
1448
1449     if (autocvar_bot_sound_monopoly)
1450         return;
1451
1452     FOR_EACH_REALPLAYER(head)
1453     {
1454         if (head.team == t)
1455             play2(head, filename);
1456     }
1457 }
1458
1459 void play2all(string samp)
1460 {
1461     if (autocvar_bot_sound_monopoly)
1462         return;
1463
1464     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1465 }
1466
1467 void PrecachePlayerSounds(string f);
1468 void precache_playermodel(string m)
1469 {
1470         float globhandle, i, n;
1471         string f;
1472
1473         if(substring(m, -9,5) == "_lod1")
1474                 return;
1475         if(substring(m, -9,5) == "_lod2")
1476                 return;
1477         precache_model(m);
1478         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1479         if(fexists(f))
1480                 precache_model(f);
1481         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1482         if(fexists(f))
1483                 precache_model(f);
1484
1485         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1486         if (globhandle < 0)
1487                 return;
1488         n = search_getsize(globhandle);
1489         for (i = 0; i < n; ++i)
1490         {
1491                 //print(search_getfilename(globhandle, i), "\n");
1492                 f = search_getfilename(globhandle, i);
1493                 PrecachePlayerSounds(f);
1494         }
1495         search_end(globhandle);
1496 }
1497 void precache_all_playermodels(string pattern)
1498 {
1499         float globhandle, i, n;
1500         string f;
1501
1502         globhandle = search_begin(pattern, TRUE, FALSE);
1503         if (globhandle < 0)
1504                 return;
1505         n = search_getsize(globhandle);
1506         for (i = 0; i < n; ++i)
1507         {
1508                 //print(search_getfilename(globhandle, i), "\n");
1509                 f = search_getfilename(globhandle, i);
1510                 precache_playermodel(f);
1511         }
1512         search_end(globhandle);
1513 }
1514
1515 void precache()
1516 {
1517     // gamemode related things
1518     precache_model ("models/misc/chatbubble.spr");
1519     if (g_runematch)
1520     {
1521         precache_model ("models/runematch/curse.mdl");
1522         precache_model ("models/runematch/rune.mdl");
1523     }
1524
1525 #ifdef TTURRETS_ENABLED
1526     if (autocvar_g_turrets)
1527         turrets_precash();
1528 #endif
1529
1530     // Precache all player models if desired
1531     if (autocvar_sv_precacheplayermodels)
1532     {
1533         PrecachePlayerSounds("sound/player/default.sounds");
1534         precache_all_playermodels("models/player/*.zym");
1535         precache_all_playermodels("models/player/*.dpm");
1536         precache_all_playermodels("models/player/*.md3");
1537         precache_all_playermodels("models/player/*.psk");
1538         precache_all_playermodels("models/player/*.iqm");
1539     }
1540
1541     if (autocvar_sv_defaultcharacter)
1542     {
1543         string s;
1544         s = autocvar_sv_defaultplayermodel_red;
1545         if (s != "")
1546             precache_playermodel(s);
1547         s = autocvar_sv_defaultplayermodel_blue;
1548         if (s != "")
1549             precache_playermodel(s);
1550         s = autocvar_sv_defaultplayermodel_yellow;
1551         if (s != "")
1552             precache_playermodel(s);
1553         s = autocvar_sv_defaultplayermodel_pink;
1554         if (s != "")
1555             precache_playermodel(s);
1556         s = autocvar_sv_defaultplayermodel;
1557         if (s != "")
1558             precache_playermodel(s);
1559     }
1560
1561     if (g_footsteps)
1562     {
1563         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1564         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1565     }
1566
1567     // gore and miscellaneous sounds
1568     //precache_sound ("misc/h2ohit.wav");
1569     precache_model ("models/hook.md3");
1570     precache_sound ("misc/armorimpact.wav");
1571     precache_sound ("misc/bodyimpact1.wav");
1572     precache_sound ("misc/bodyimpact2.wav");
1573     precache_sound ("misc/gib.wav");
1574     precache_sound ("misc/gib_splat01.wav");
1575     precache_sound ("misc/gib_splat02.wav");
1576     precache_sound ("misc/gib_splat03.wav");
1577     precache_sound ("misc/gib_splat04.wav");
1578     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1579     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1580     precache_sound ("misc/null.wav");
1581     precache_sound ("misc/spawn.wav");
1582     precache_sound ("misc/talk.wav");
1583     precache_sound ("misc/teleport.wav");
1584     precache_sound ("misc/poweroff.wav");
1585     precache_sound ("player/lava.wav");
1586     precache_sound ("player/slime.wav");
1587
1588     precache_model ("models/sprites/0.spr32");
1589     precache_model ("models/sprites/1.spr32");
1590     precache_model ("models/sprites/2.spr32");
1591     precache_model ("models/sprites/3.spr32");
1592     precache_model ("models/sprites/4.spr32");
1593     precache_model ("models/sprites/5.spr32");
1594     precache_model ("models/sprites/6.spr32");
1595     precache_model ("models/sprites/7.spr32");
1596     precache_model ("models/sprites/8.spr32");
1597     precache_model ("models/sprites/9.spr32");
1598     precache_model ("models/sprites/10.spr32");
1599
1600     // common weapon precaches
1601         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1602     precache_sound ("weapons/weapon_switch.wav");
1603     precache_sound ("weapons/weaponpickup.wav");
1604     precache_sound ("weapons/unavailable.wav");
1605     precache_sound ("weapons/dryfire.wav");
1606     if (g_grappling_hook)
1607     {
1608         precache_sound ("weapons/hook_fire.wav"); // hook
1609         precache_sound ("weapons/hook_impact.wav"); // hook
1610     }
1611
1612     if(autocvar_sv_precacheweapons)
1613     {
1614         //precache weapon models/sounds
1615         float wep;
1616         wep = WEP_FIRST;
1617         while (wep <= WEP_LAST)
1618         {
1619             weapon_action(wep, WR_PRECACHE);
1620             wep = wep + 1;
1621         }
1622     }
1623
1624     precache_model("models/elaser.mdl");
1625     precache_model("models/laser.mdl");
1626     precache_model("models/ebomb.mdl");
1627
1628 #if 0
1629     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1630
1631     if (!self.noise && self.music) // quake 3 uses the music field
1632         self.noise = self.music;
1633
1634     // plays music for the level if there is any
1635     if (self.noise)
1636     {
1637         precache_sound (self.noise);
1638         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1639     }
1640 #endif
1641 }
1642
1643 // sorry, but using \ in macros breaks line numbers
1644 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1645 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1646 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1647
1648
1649 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1650 {
1651         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
1652         {
1653                 msg_entity = e;
1654                 WRITESPECTATABLE_MSG_ONE({
1655                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1656                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1657                         WriteByte(MSG_ONE, id);
1658                         WriteString(MSG_ONE, s);
1659                         if (id != 0 && s != "")
1660                         {
1661                                 WriteByte(MSG_ONE, duration);
1662                                 WriteByte(MSG_ONE, countdown_num);
1663                         }
1664                 });
1665         }
1666 }
1667 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1668 {
1669         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1670 }
1671 // WARNING: this kills the trace globals
1672 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1673 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1674
1675 #define INITPRIO_FIRST              0
1676 #define INITPRIO_GAMETYPE           0
1677 #define INITPRIO_GAMETYPE_FALLBACK  1
1678 #define INITPRIO_FINDTARGET        10
1679 #define INITPRIO_DROPTOFLOOR       20
1680 #define INITPRIO_SETLOCATION       90
1681 #define INITPRIO_LINKDOORS         91
1682 #define INITPRIO_LAST              99
1683
1684 .void(void) initialize_entity;
1685 .float initialize_entity_order;
1686 .entity initialize_entity_next;
1687 entity initialize_entity_first;
1688
1689 void make_safe_for_remove(entity e)
1690 {
1691     if (e.initialize_entity)
1692     {
1693         entity ent, prev = world;
1694         for (ent = initialize_entity_first; ent; )
1695         {
1696             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1697             {
1698                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1699                 // skip it in linked list
1700                 if (prev)
1701                 {
1702                     prev.initialize_entity_next = ent.initialize_entity_next;
1703                     ent = prev.initialize_entity_next;
1704                 }
1705                 else
1706                 {
1707                     initialize_entity_first = ent.initialize_entity_next;
1708                     ent = initialize_entity_first;
1709                 }
1710             }
1711             else
1712             {
1713                 prev = ent;
1714                 ent = ent.initialize_entity_next;
1715             }
1716         }
1717     }
1718 }
1719
1720 void objerror(string s)
1721 {
1722     make_safe_for_remove(self);
1723     builtin_objerror(s);
1724 }
1725
1726 .float remove_except_protected_forbidden;
1727 void remove_except_protected(entity e)
1728 {
1729         if(e.remove_except_protected_forbidden)
1730                 error("not allowed to remove this at this point");
1731         builtin_remove(e);
1732 }
1733
1734 void remove_unsafely(entity e)
1735 {
1736     if(e.classname == "spike")
1737         error("Removing spikes is forbidden (crylink bug), please report");
1738     builtin_remove(e);
1739 }
1740
1741 void remove_safely(entity e)
1742 {
1743     make_safe_for_remove(e);
1744     builtin_remove(e);
1745 }
1746
1747 void InitializeEntity(entity e, void(void) func, float order)
1748 {
1749     entity prev, cur;
1750
1751     if (!e || e.initialize_entity)
1752     {
1753         // make a proxy initializer entity
1754         entity e_old;
1755         e_old = e;
1756         e = spawn();
1757         e.classname = "initialize_entity";
1758         e.enemy = e_old;
1759     }
1760
1761     e.initialize_entity = func;
1762     e.initialize_entity_order = order;
1763
1764     cur = initialize_entity_first;
1765     prev = world;
1766     for (;;)
1767     {
1768         if (!cur || cur.initialize_entity_order > order)
1769         {
1770             // insert between prev and cur
1771             if (prev)
1772                 prev.initialize_entity_next = e;
1773             else
1774                 initialize_entity_first = e;
1775             e.initialize_entity_next = cur;
1776             return;
1777         }
1778         prev = cur;
1779         cur = cur.initialize_entity_next;
1780     }
1781 }
1782 void InitializeEntitiesRun()
1783 {
1784     entity startoflist;
1785     startoflist = initialize_entity_first;
1786     initialize_entity_first = world;
1787     remove = remove_except_protected;
1788     for (self = startoflist; self; self = self.initialize_entity_next)
1789     {
1790         self.remove_except_protected_forbidden = 1;
1791     }
1792     for (self = startoflist; self; )
1793     {
1794         entity e;
1795         var void(void) func;
1796         e = self.initialize_entity_next;
1797         func = self.initialize_entity;
1798         self.initialize_entity_order = 0;
1799         self.initialize_entity = func_null;
1800         self.initialize_entity_next = world;
1801         self.remove_except_protected_forbidden = 0;
1802         if (self.classname == "initialize_entity")
1803         {
1804             entity e_old;
1805             e_old = self.enemy;
1806             builtin_remove(self);
1807             self = e_old;
1808         }
1809         //dprint("Delayed initialization: ", self.classname, "\n");
1810         if(func)
1811             func();
1812         else
1813         {
1814             eprint(self);
1815             backtrace(strcat("Null function in: ", self.classname, "\n"));
1816         }
1817         self = e;
1818     }
1819     remove = remove_unsafely;
1820 }
1821
1822 .float uncustomizeentityforclient_set;
1823 .void(void) uncustomizeentityforclient;
1824 void UncustomizeEntitiesRun()
1825 {
1826     entity oldself;
1827     oldself = self;
1828     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1829         self.uncustomizeentityforclient();
1830     self = oldself;
1831 }
1832 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1833 {
1834     e.customizeentityforclient = customizer;
1835     e.uncustomizeentityforclient = uncustomizer;
1836     e.uncustomizeentityforclient_set = !!uncustomizer;
1837 }
1838
1839 .float nottargeted;
1840 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1841
1842 void() SUB_Remove;
1843 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1844 {
1845     vector mi, ma;
1846
1847     if (e.classname == "")
1848         e.classname = "net_linked";
1849
1850     if (e.model == "" || self.modelindex == 0)
1851     {
1852         mi = e.mins;
1853         ma = e.maxs;
1854         setmodel(e, "null");
1855         setsize(e, mi, ma);
1856     }
1857
1858     e.SendEntity = sendfunc;
1859     e.SendFlags = 0xFFFFFF;
1860
1861     if (!docull)
1862         e.effects |= EF_NODEPTHTEST;
1863
1864     if (dt)
1865     {
1866         e.nextthink = time + dt;
1867         e.think = SUB_Remove;
1868     }
1869 }
1870
1871 void adaptor_think2touch()
1872 {
1873     entity o;
1874     o = other;
1875     other = world;
1876     self.touch();
1877     other = o;
1878 }
1879
1880 void adaptor_think2use()
1881 {
1882     entity o, a;
1883     o = other;
1884     a = activator;
1885     activator = world;
1886     other = world;
1887     self.use();
1888     other = o;
1889     activator = a;
1890 }
1891
1892 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1893 {
1894         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1895                 self.projectiledeathtype |= HITTYPE_SPLASH;
1896         adaptor_think2use();
1897 }
1898
1899 // deferred dropping
1900 void DropToFloor_Handler()
1901 {
1902     builtin_droptofloor();
1903     self.dropped_origin = self.origin;
1904 }
1905
1906 void droptofloor()
1907 {
1908     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1909 }
1910
1911
1912
1913 float trace_hits_box_a0, trace_hits_box_a1;
1914
1915 float trace_hits_box_1d(float end, float thmi, float thma)
1916 {
1917     if (end == 0)
1918     {
1919         // just check if x is in range
1920         if (0 < thmi)
1921             return FALSE;
1922         if (0 > thma)
1923             return FALSE;
1924     }
1925     else
1926     {
1927         // do the trace with respect to x
1928         // 0 -> end has to stay in thmi -> thma
1929         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1930         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1931         if (trace_hits_box_a0 > trace_hits_box_a1)
1932             return FALSE;
1933     }
1934     return TRUE;
1935 }
1936
1937 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1938 {
1939     end -= start;
1940     thmi -= start;
1941     thma -= start;
1942     // now it is a trace from 0 to end
1943
1944     trace_hits_box_a0 = 0;
1945     trace_hits_box_a1 = 1;
1946
1947     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1948         return FALSE;
1949     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1950         return FALSE;
1951     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1952         return FALSE;
1953
1954     return TRUE;
1955 }
1956
1957 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1958 {
1959     return trace_hits_box(start, end, thmi - ma, thma - mi);
1960 }
1961
1962 float SUB_NoImpactCheck()
1963 {
1964         // zero hitcontents = this is not the real impact, but either the
1965         // mirror-impact of something hitting the projectile instead of the
1966         // projectile hitting the something, or a touchareagrid one. Neither of
1967         // these stop the projectile from moving, so...
1968         if(trace_dphitcontents == 0)
1969         {
1970                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1971                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1972                 checkclient();
1973         }
1974     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1975         return 1;
1976     if (other == world && self.size != '0 0 0')
1977     {
1978         vector tic;
1979         tic = self.velocity * sys_frametime;
1980         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1981         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1982         if (trace_fraction >= 1)
1983         {
1984             dprint("Odd... did not hit...?\n");
1985         }
1986         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1987         {
1988             dprint("Detected and prevented the sky-grapple bug.\n");
1989             return 1;
1990         }
1991     }
1992
1993     return 0;
1994 }
1995
1996 #define SUB_OwnerCheck() (other && (other == self.owner))
1997
1998 void RemoveGrapplingHook(entity pl);
1999 void W_Crylink_Dequeue(entity e);
2000 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2001 {
2002         if(SUB_OwnerCheck())
2003                 return TRUE;
2004         if(SUB_NoImpactCheck())
2005         {
2006                 if(self.classname == "grapplinghook")
2007                         RemoveGrapplingHook(self.realowner);
2008                 else if(self.classname == "spike")
2009                 {
2010                         W_Crylink_Dequeue(self);
2011                         remove(self);
2012                 }
2013                 else
2014                         remove(self);
2015                 return TRUE;
2016         }
2017         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2018                 UpdateCSQCProjectile(self);
2019         return FALSE;
2020 }
2021 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2022
2023 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
2024 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
2025
2026 void URI_Get_Callback(float id, float status, string data)
2027 {
2028         if(url_URI_Get_Callback(id, status, data))
2029         {
2030                 // handled
2031         }
2032         else if (id == URI_GET_DISCARD)
2033         {
2034                 // discard
2035         }
2036         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
2037         {
2038                 // sv_cmd curl
2039                 Curl_URI_Get_Callback(id, status, data);
2040         }
2041         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2042         {
2043                 // online ban list
2044                 OnlineBanList_URI_Get_Callback(id, status, data);
2045         }
2046         else
2047         {
2048                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2049         }
2050 }
2051
2052 string uid2name(string myuid) {
2053         string s;
2054         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2055
2056         // FIXME remove this later after 0.6 release
2057         // convert old style broken records to correct style
2058         if(s == "")
2059         {
2060                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2061                 if(s != "")
2062                 {
2063                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2064                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2065                 }
2066         }
2067
2068         if(s == "")
2069                 s = "^1Unregistered Player";
2070         return s;
2071 }
2072
2073 float race_readTime(string map, float pos)
2074 {
2075         string rr;
2076         if(g_cts)
2077                 rr = CTS_RECORD;
2078         else
2079                 rr = RACE_RECORD;
2080
2081         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2082 }
2083
2084 string race_readUID(string map, float pos)
2085 {
2086         string rr;
2087         if(g_cts)
2088                 rr = CTS_RECORD;
2089         else
2090                 rr = RACE_RECORD;
2091
2092         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2093 }
2094
2095 float race_readPos(string map, float t) {
2096         float i;
2097         for (i = 1; i <= RANKINGS_CNT; ++i)
2098                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2099                         return i;
2100
2101         return 0; // pos is zero if unranked
2102 }
2103
2104 void race_writeTime(string map, float t, string myuid)
2105 {
2106         string rr;
2107         if(g_cts)
2108                 rr = CTS_RECORD;
2109         else
2110                 rr = RACE_RECORD;
2111
2112         float newpos;
2113         newpos = race_readPos(map, t);
2114
2115         float i, prevpos = 0;
2116         for(i = 1; i <= RANKINGS_CNT; ++i)
2117         {
2118                 if(race_readUID(map, i) == myuid)
2119                         prevpos = i;
2120         }
2121         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2122                 for (i = prevpos; i > newpos; --i) {
2123                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2124                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2125                 }
2126         } else { // player has no ranked record yet
2127                 for (i = RANKINGS_CNT; i > newpos; --i) {
2128                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2129                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2130                 }
2131         }
2132
2133         // store new time itself
2134         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2135         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2136 }
2137
2138 string race_readName(string map, float pos)
2139 {
2140         string rr;
2141         if(g_cts)
2142                 rr = CTS_RECORD;
2143         else
2144                 rr = RACE_RECORD;
2145
2146         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2147 }
2148
2149 string race_placeName(float pos) {
2150         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2151         {
2152                 if(mod(pos, 10) == 1)
2153                         return strcat(ftos(pos), "st");
2154                 else if(mod(pos, 10) == 2)
2155                         return strcat(ftos(pos), "nd");
2156                 else if(mod(pos, 10) == 3)
2157                         return strcat(ftos(pos), "rd");
2158                 else
2159                         return strcat(ftos(pos), "th");
2160         }
2161         else
2162                 return strcat(ftos(pos), "th");
2163 }
2164
2165 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2166 {
2167     float m, i;
2168     vector start, org, delta, end, enddown, mstart;
2169     entity sp;
2170
2171     m = e.dphitcontentsmask;
2172     e.dphitcontentsmask = goodcontents | badcontents;
2173
2174     org = world.mins;
2175     delta = world.maxs - world.mins;
2176
2177     start = end = org;
2178
2179     for (i = 0; i < attempts; ++i)
2180     {
2181         start_x = org_x + random() * delta_x;
2182         start_y = org_y + random() * delta_y;
2183         start_z = org_z + random() * delta_z;
2184
2185         // rule 1: start inside world bounds, and outside
2186         // solid, and don't start from somewhere where you can
2187         // fall down to evil
2188         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2189         if (trace_fraction >= 1)
2190             continue;
2191         if (trace_startsolid)
2192             continue;
2193         if (trace_dphitcontents & badcontents)
2194             continue;
2195         if (trace_dphitq3surfaceflags & badsurfaceflags)
2196             continue;
2197
2198         // rule 2: if we are too high, lower the point
2199         if (trace_fraction * delta_z > maxaboveground)
2200             start = trace_endpos + '0 0 1' * maxaboveground;
2201         enddown = trace_endpos;
2202
2203         // rule 3: make sure we aren't outside the map. This only works
2204         // for somewhat well formed maps. A good rule of thumb is that
2205         // the map should have a convex outside hull.
2206         // these can be traceLINES as we already verified the starting box
2207         mstart = start + 0.5 * (e.mins + e.maxs);
2208         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2209         if (trace_fraction >= 1)
2210             continue;
2211         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2212         if (trace_fraction >= 1)
2213             continue;
2214         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2215         if (trace_fraction >= 1)
2216             continue;
2217         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2218         if (trace_fraction >= 1)
2219             continue;
2220         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2221         if (trace_fraction >= 1)
2222             continue;
2223
2224         // rule 4: we must "see" some spawnpoint
2225         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2226                 if(checkpvs(mstart, sp))
2227                         break;
2228         if(!sp)
2229         {
2230                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2231                         if(checkpvs(mstart, sp))
2232                                 break;
2233                 if(!sp)
2234                         continue;
2235         }
2236
2237         // find a random vector to "look at"
2238         end_x = org_x + random() * delta_x;
2239         end_y = org_y + random() * delta_y;
2240         end_z = org_z + random() * delta_z;
2241         end = start + normalize(end - start) * vlen(delta);
2242
2243         // rule 4: start TO end must not be too short
2244         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2245         if (trace_startsolid)
2246             continue;
2247         if (trace_fraction < minviewdistance / vlen(delta))
2248             continue;
2249
2250         // rule 5: don't want to look at sky
2251         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2252             continue;
2253
2254         // rule 6: we must not end up in trigger_hurt
2255         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2256             continue;
2257
2258         break;
2259     }
2260
2261     e.dphitcontentsmask = m;
2262
2263     if (i < attempts)
2264     {
2265         setorigin(e, start);
2266         e.angles = vectoangles(end - start);
2267         dprint("Needed ", ftos(i + 1), " attempts\n");
2268         return TRUE;
2269     }
2270     else
2271         return FALSE;
2272 }
2273
2274 float zcurveparticles_effectno;
2275 vector zcurveparticles_start;
2276 float zcurveparticles_spd;
2277
2278 void endzcurveparticles()
2279 {
2280         if(zcurveparticles_effectno)
2281         {
2282                 // terminator
2283                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2284         }
2285         zcurveparticles_effectno = 0;
2286 }
2287
2288 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2289 {
2290         spd = bound(0, floor(spd / 16), 32767);
2291         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2292         {
2293                 endzcurveparticles();
2294                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2295                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2296                 WriteShort(MSG_BROADCAST, effectno);
2297                 WriteCoord(MSG_BROADCAST, start_x);
2298                 WriteCoord(MSG_BROADCAST, start_y);
2299                 WriteCoord(MSG_BROADCAST, start_z);
2300                 zcurveparticles_effectno = effectno;
2301                 zcurveparticles_start = start;
2302         }
2303         else
2304                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2305         WriteCoord(MSG_BROADCAST, end_x);
2306         WriteCoord(MSG_BROADCAST, end_y);
2307         WriteCoord(MSG_BROADCAST, end_z);
2308         WriteCoord(MSG_BROADCAST, end_dz);
2309         zcurveparticles_spd = spd;
2310 }
2311
2312 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2313 {
2314         float end_dz;
2315         vector vecxy, velxy;
2316
2317         vecxy = end - start;
2318         vecxy_z = 0;
2319         velxy = vel;
2320         velxy_z = 0;
2321
2322         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2323         {
2324                 endzcurveparticles();
2325                 trailparticles(world, effectno, start, end);
2326                 return;
2327         }
2328
2329         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2330         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2331 }
2332
2333 void write_recordmarker(entity pl, float tstart, float dt)
2334 {
2335     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2336
2337     // also write a marker into demo files for demotc-race-record-extractor to find
2338     stuffcmd(pl,
2339              strcat(
2340                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2341                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2342 }
2343
2344 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2345 {
2346         switch(algn)
2347         {
2348                 default:
2349                 case 3: // right
2350                         break;
2351
2352                 case 4: // left
2353                         vecs_y = -vecs_y;
2354                         break;
2355
2356                 case 1:
2357                         if(allowcenter) // 2: allow center handedness
2358                         {
2359                                 // center
2360                                 vecs_y = 0;
2361                                 vecs_z -= 2;
2362                         }
2363                         else
2364                         {
2365                                 // right
2366                         }
2367                         break;
2368
2369                 case 2:
2370                         if(allowcenter) // 2: allow center handedness
2371                         {
2372                                 // center
2373                                 vecs_y = 0;
2374                                 vecs_z -= 2;
2375                         }
2376                         else
2377                         {
2378                                 // left
2379                                 vecs_y = -vecs_y;
2380                         }
2381                         break;
2382         }
2383         return vecs;
2384 }
2385
2386 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2387 {
2388         string s;
2389         vector v;
2390
2391         if (autocvar_g_shootfromeye)
2392         {
2393                 if (visual)
2394                 {
2395                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2396                         else { vecs_y = 0; vecs_z -= 2; }
2397                 }
2398                 else
2399                 {
2400                         vecs_y = 0;
2401                         vecs_z = 0;
2402                 }
2403         }
2404         else if (autocvar_g_shootfromcenter)
2405         {
2406                 vecs_y = 0;
2407                 vecs_z -= 2;
2408         }
2409         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2410         {
2411                 v = stov(s);
2412                 if (y_is_right)
2413                         v_y = -v_y;
2414                 if (v_x != 0)
2415                         vecs_x = v_x;
2416                 vecs_y = v_y;
2417                 vecs_z = v_z;
2418         }
2419         else if (autocvar_g_shootfromclient)
2420         {
2421                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2422         }
2423         return vecs;
2424 }
2425
2426 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2427 {
2428         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2429 }
2430
2431
2432 void attach_sameorigin(entity e, entity to, string tag)
2433 {
2434     vector org, t_forward, t_left, t_up, e_forward, e_up;
2435     float tagscale;
2436
2437     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2438     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2439     t_forward = v_forward * tagscale;
2440     t_left = v_right * -tagscale;
2441     t_up = v_up * tagscale;
2442
2443     e.origin_x = org * t_forward;
2444     e.origin_y = org * t_left;
2445     e.origin_z = org * t_up;
2446
2447     // current forward and up directions
2448     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2449                 e.angles = AnglesTransform_FromVAngles(e.angles);
2450         else
2451                 e.angles = AnglesTransform_FromAngles(e.angles);
2452     fixedmakevectors(e.angles);
2453
2454     // untransform forward, up!
2455     e_forward_x = v_forward * t_forward;
2456     e_forward_y = v_forward * t_left;
2457     e_forward_z = v_forward * t_up;
2458     e_up_x = v_up * t_forward;
2459     e_up_y = v_up * t_left;
2460     e_up_z = v_up * t_up;
2461
2462     e.angles = fixedvectoangles2(e_forward, e_up);
2463     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2464                 e.angles = AnglesTransform_ToVAngles(e.angles);
2465         else
2466                 e.angles = AnglesTransform_ToAngles(e.angles);
2467
2468     setattachment(e, to, tag);
2469     setorigin(e, e.origin);
2470 }
2471
2472 void detach_sameorigin(entity e)
2473 {
2474     vector org;
2475     org = gettaginfo(e, 0);
2476     e.angles = fixedvectoangles2(v_forward, v_up);
2477     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2478                 e.angles = AnglesTransform_ToVAngles(e.angles);
2479         else
2480                 e.angles = AnglesTransform_ToAngles(e.angles);
2481     setorigin(e, org);
2482     setattachment(e, world, "");
2483     setorigin(e, e.origin);
2484 }
2485
2486 void follow_sameorigin(entity e, entity to)
2487 {
2488     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2489     e.aiment = to; // make the hole follow bmodel
2490     e.punchangle = to.angles; // the original angles of bmodel
2491     e.view_ofs = e.origin - to.origin; // relative origin
2492     e.v_angle = e.angles - to.angles; // relative angles
2493 }
2494
2495 void unfollow_sameorigin(entity e)
2496 {
2497     e.movetype = MOVETYPE_NONE;
2498 }
2499
2500 entity gettaginfo_relative_ent;
2501 vector gettaginfo_relative(entity e, float tag)
2502 {
2503     if (!gettaginfo_relative_ent)
2504     {
2505         gettaginfo_relative_ent = spawn();
2506         gettaginfo_relative_ent.effects = EF_NODRAW;
2507     }
2508     gettaginfo_relative_ent.model = e.model;
2509     gettaginfo_relative_ent.modelindex = e.modelindex;
2510     gettaginfo_relative_ent.frame = e.frame;
2511     return gettaginfo(gettaginfo_relative_ent, tag);
2512 }
2513
2514 .float scale2;
2515
2516 float modeleffect_SendEntity(entity to, float sf)
2517 {
2518         float f;
2519         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2520
2521         f = 0;
2522         if(self.velocity != '0 0 0')
2523                 f |= 1;
2524         if(self.angles != '0 0 0')
2525                 f |= 2;
2526         if(self.avelocity != '0 0 0')
2527                 f |= 4;
2528
2529         WriteByte(MSG_ENTITY, f);
2530         WriteShort(MSG_ENTITY, self.modelindex);
2531         WriteByte(MSG_ENTITY, self.skin);
2532         WriteByte(MSG_ENTITY, self.frame);
2533         WriteCoord(MSG_ENTITY, self.origin_x);
2534         WriteCoord(MSG_ENTITY, self.origin_y);
2535         WriteCoord(MSG_ENTITY, self.origin_z);
2536         if(f & 1)
2537         {
2538                 WriteCoord(MSG_ENTITY, self.velocity_x);
2539                 WriteCoord(MSG_ENTITY, self.velocity_y);
2540                 WriteCoord(MSG_ENTITY, self.velocity_z);
2541         }
2542         if(f & 2)
2543         {
2544                 WriteCoord(MSG_ENTITY, self.angles_x);
2545                 WriteCoord(MSG_ENTITY, self.angles_y);
2546                 WriteCoord(MSG_ENTITY, self.angles_z);
2547         }
2548         if(f & 4)
2549         {
2550                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2551                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2552                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2553         }
2554         WriteShort(MSG_ENTITY, self.scale * 256.0);
2555         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2556         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2557         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2558         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2559
2560         return TRUE;
2561 }
2562
2563 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2564 {
2565         entity e;
2566         float sz;
2567         e = spawn();
2568         e.classname = "modeleffect";
2569         setmodel(e, m);
2570         e.frame = f;
2571         setorigin(e, o);
2572         e.velocity = v;
2573         e.angles = ang;
2574         e.avelocity = angv;
2575         e.alpha = a;
2576         e.teleport_time = t1;
2577         e.fade_time = t2;
2578         e.skin = s;
2579         if(s0 >= 0)
2580                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2581         else
2582                 e.scale = -s0;
2583         if(s2 >= 0)
2584                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2585         else
2586                 e.scale2 = -s2;
2587         sz = max(e.scale, e.scale2);
2588         setsize(e, e.mins * sz, e.maxs * sz);
2589         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2590 }
2591
2592 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2593 {
2594         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2595 }
2596
2597 float randombit(float bits)
2598 {
2599         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2600                 return bits;
2601
2602         float n, f, b, r;
2603
2604         r = random();
2605         b = 0;
2606         n = 0;
2607
2608         for(f = 1; f <= bits; f *= 2)
2609         {
2610                 if(bits & f)
2611                 {
2612                         ++n;
2613                         r *= n;
2614                         if(r <= 1)
2615                                 b = f;
2616                         else
2617                                 r = (r - 1) / (n - 1);
2618                 }
2619         }
2620
2621         return b;
2622 }
2623
2624 float randombits(float bits, float k, float error_return)
2625 {
2626         float r;
2627         r = 0;
2628         while(k > 0 && bits != r)
2629         {
2630                 r += randombit(bits - r);
2631                 --k;
2632         }
2633         if(error_return)
2634                 if(k > 0)
2635                         return -1; // all
2636         return r;
2637 }
2638
2639 void randombit_test(float bits, float iter)
2640 {
2641         while(iter > 0)
2642         {
2643                 print(ftos(randombit(bits)), "\n");
2644                 --iter;
2645         }
2646 }
2647
2648 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2649 {
2650         if(halflifedist > 0)
2651                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2652         else if(halflifedist < 0)
2653                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2654         else
2655                 return 1;
2656 }
2657
2658
2659
2660
2661 #ifdef RELEASE
2662 #define cvar_string_normal builtin_cvar_string
2663 #define cvar_normal builtin_cvar
2664 #else
2665 string cvar_string_normal(string n)
2666 {
2667         if not(cvar_type(n) & 1)
2668                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2669         return builtin_cvar_string(n);
2670 }
2671
2672 float cvar_normal(string n)
2673 {
2674         return stof(cvar_string_normal(n));
2675 }
2676 #endif
2677 #define cvar_set_normal builtin_cvar_set
2678
2679 void defer_think()
2680 {
2681     entity oself;
2682
2683     oself           = self;
2684     self            = self.owner;
2685     oself.think     = SUB_Remove;
2686     oself.nextthink = time;
2687
2688     oself.use();
2689 }
2690
2691 /*
2692     Execute func() after time + fdelay.
2693     self when func is executed = self when defer is called
2694 */
2695 void defer(float fdelay, void() func)
2696 {
2697     entity e;
2698
2699     e           = spawn();
2700     e.owner     = self;
2701     e.use       = func;
2702     e.think     = defer_think;
2703     e.nextthink = time + fdelay;
2704 }
2705
2706 .string aiment_classname;
2707 .float aiment_deadflag;
2708 void SetMovetypeFollow(entity ent, entity e)
2709 {
2710         // FIXME this may not be warpzone aware
2711         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2712         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2713         ent.aiment = e; // make the hole follow bmodel
2714         ent.punchangle = e.angles; // the original angles of bmodel
2715         ent.view_ofs = ent.origin - e.origin; // relative origin
2716         ent.v_angle = ent.angles - e.angles; // relative angles
2717         ent.aiment_classname = strzone(e.classname);
2718         ent.aiment_deadflag = e.deadflag;
2719 }
2720 void UnsetMovetypeFollow(entity ent)
2721 {
2722         ent.movetype = MOVETYPE_FLY;
2723         PROJECTILE_MAKETRIGGER(ent);
2724         ent.aiment = world;
2725 }
2726 float LostMovetypeFollow(entity ent)
2727 {
2728 /*
2729         if(ent.movetype != MOVETYPE_FOLLOW)
2730                 if(ent.aiment)
2731                         error("???");
2732 */
2733         if(ent.aiment)
2734         {
2735                 if(ent.aiment.classname != ent.aiment_classname)
2736                         return 1;
2737                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2738                         return 1;
2739         }
2740         return 0;
2741 }
2742
2743 float isPushable(entity e)
2744 {
2745         if(e.iscreature)
2746                 return TRUE;
2747         if(e.pushable)
2748                 return TRUE;
2749         switch(e.classname)
2750         {
2751                 case "body":
2752                 case "droppedweapon":
2753                 case "keepawayball":
2754                 case "nexball_basketball":
2755                 case "nexball_football":
2756                         return TRUE;
2757                 case "bullet": // antilagged bullets can't hit this either
2758                         return FALSE;
2759         }
2760         if (e.projectiledeathtype)
2761                 return TRUE;
2762         return FALSE;
2763 }