qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include "mutators/_mod.qh"
   9 #include "../common/t_items.qh"
  10 #include "weapons/accuracy.qh"
  11 #include "weapons/csqcprojectile.qh"
  12 #include "weapons/selection.qh"
  13 #include "../common/command/_mod.qh"
  14 #include "../common/constants.qh"
  15 #include <common/net_linked.qh>
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/notifications/all.qh"
  19 #include "../common/playerstats.qh"
  20 #include "../common/teams.qh"
  21 #include "../common/triggers/subs.qh"
  22 #include "../common/util.qh"
  23 #include "../common/turrets/sv_turrets.qh"
  24 #include <common/weapons/_all.qh>
  25 #include "../common/vehicles/sv_vehicles.qh"
  26 #include "../common/vehicles/vehicle.qh"
  27 #include "../common/items/_mod.qh"
  28 #include "../common/state.qh"
  29 #include "../common/effects/qc/globalsound.qh"
  30 #include "../common/wepent.qh"
  31 #include "../lib/csqcmodel/sv_model.qh"
  32 #include "../lib/warpzone/anglestransform.qh"
  33 #include "../lib/warpzone/server.qh"
  34
  35 void crosshair_trace(entity pl)
  36 {
  37         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  38 }
  39 .bool ctrace_solidchanged;
  40 void crosshair_trace_plusvisibletriggers(entity pl)
  41 {
  42         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  43         {
  44                 if(it.model != "")
  45                 {
  46                         it.solid = SOLID_BSP;
  47                         it.ctrace_solidchanged = true;
  48                         IL_PUSH(g_ctrace_changed, it);
  49                 }
  50         });
  51
  52         crosshair_trace(pl);
  53
  54         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
  55         {
  56                 it.solid = SOLID_TRIGGER;
  57                 it.ctrace_solidchanged = false;
  58         });
  59
  60         IL_CLEAR(g_ctrace_changed);
  61 }
  62 void WarpZone_crosshair_trace(entity pl)
  63 {
  64         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  65 }
  66
  67
  68 void GameLogEcho(string s)
  69 {
  70     string fn;
  71     int matches;
  72
  73     if (autocvar_sv_eventlog_files)
  74     {
  75         if (!logfile_open)
  76         {
  77             logfile_open = true;
  78             matches = autocvar_sv_eventlog_files_counter + 1;
  79             cvar_set("sv_eventlog_files_counter", itos(matches));
  80             fn = ftos(matches);
  81             if (strlen(fn) < 8)
  82                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  83             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  84             logfile = fopen(fn, FILE_APPEND);
  85             fputs(logfile, ":logversion:3\n");
  86         }
  87         if (logfile >= 0)
  88         {
  89             if (autocvar_sv_eventlog_files_timestamps)
  90                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  91             else
  92                 fputs(logfile, strcat(s, "\n"));
  93         }
  94     }
  95     if (autocvar_sv_eventlog_console)
  96     {
  97         dedicated_print(strcat(s, "\n"));
  98     }
  99 }
 100
 101 void GameLogInit()
 102 {
 103     logfile_open = 0;
 104     // will be opened later
 105 }
 106
 107 void GameLogClose()
 108 {
 109     if (logfile_open && logfile >= 0)
 110     {
 111         fclose(logfile);
 112         logfile = -1;
 113     }
 114 }
 115
 116 entity findnearest(vector point, bool checkitems, vector axismod)
 117 {
 118     vector dist;
 119     int num_nearest = 0;
 120
 121     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 122     {
 123         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 124             dist = it.oldorigin;
 125         else
 126             dist = it.origin;
 127         dist = dist - point;
 128         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 129         float len = vlen2(dist);
 130
 131         int l;
 132         for (l = 0; l < num_nearest; ++l)
 133         {
 134             if (len < nearest_length[l])
 135                 break;
 136         }
 137
 138         // now i tells us where to insert at
 139         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 140         if (l < NUM_NEAREST_ENTITIES)
 141         {
 142             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 143             {
 144                 nearest_length[j + 1] = nearest_length[j];
 145                 nearest_entity[j + 1] = nearest_entity[j];
 146             }
 147             nearest_length[l] = len;
 148             nearest_entity[l] = it;
 149             if (num_nearest < NUM_NEAREST_ENTITIES)
 150                 num_nearest = num_nearest + 1;
 151         }
 152     });
 153
 154     // now use the first one from our list that we can see
 155     for (int j = 0; j < num_nearest; ++j)
 156     {
 157         traceline(point, nearest_entity[j].origin, true, NULL);
 158         if (trace_fraction == 1)
 159         {
 160             if (j != 0)
 161                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 162             return nearest_entity[j];
 163         }
 164     }
 165
 166     if (num_nearest == 0)
 167         return NULL;
 168
 169     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 170     /* DEBUGGING CODE:
 171     dprint("Candidates were: ");
 172     for(j = 0; j < num_nearest; ++j)
 173     {
 174         if(j != 0)
 175                 dprint(", ");
 176         dprint(nearest_entity[j].netname);
 177     }
 178     dprint("\n");
 179     */
 180
 181     return nearest_entity[0];
 182 }
 183
 184 string NearestLocation(vector p)
 185 {
 186     string ret = "somewhere";
 187     entity loc = findnearest(p, false, '1 1 1');
 188     if (loc)
 189         ret = loc.message;
 190     else
 191     {
 192         loc = findnearest(p, true, '1 1 4');
 193         if (loc)
 194             ret = loc.netname;
 195     }
 196     return ret;
 197 }
 198
 199 string AmmoNameFromWeaponentity(entity wpn)
 200 {
 201         string ammoitems = "batteries";
 202         switch((wpn.m_weapon).ammo_field)
 203         {
 204                 case ammo_shells:  ammoitems = ITEM_Shells.m_name;      break;
 205                 case ammo_nails:   ammoitems = ITEM_Bullets.m_name;     break;
 206                 case ammo_rockets: ammoitems = ITEM_Rockets.m_name;     break;
 207                 case ammo_cells:   ammoitems = ITEM_Cells.m_name;       break;
 208                 case ammo_plasma:  ammoitems = ITEM_Plasma.m_name;      break;
 209                 case ammo_fuel:    ammoitems = ITEM_JetpackFuel.m_name; break;
 210         }
 211         return ammoitems;
 212 }
 213
 214 string formatmessage(entity this, string msg)
 215 {
 216         float p, p1, p2;
 217         float n;
 218         vector cursor;
 219         entity cursor_ent;
 220         string escape;
 221         string replacement;
 222         p = 0;
 223         n = 7;
 224
 225         WarpZone_crosshair_trace(this);
 226         cursor = trace_endpos;
 227         cursor_ent = trace_ent;
 228
 229         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 230         msg = M_ARGV(1, string);
 231
 232         while (1) {
 233                 if (n < 1)
 234                         break; // too many replacements
 235
 236                 n = n - 1;
 237                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 238                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 239
 240                 if (p1 < 0)
 241                         p1 = p2;
 242
 243                 if (p2 < 0)
 244                         p2 = p1;
 245
 246                 p = min(p1, p2);
 247
 248                 if (p < 0)
 249                         break;
 250
 251                 replacement = substring(msg, p, 2);
 252                 escape = substring(msg, p + 1, 1);
 253
 254                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 255
 256                 switch(escape)
 257                 {
 258                         case "%": replacement = "%"; break;
 259                         case "\\":replacement = "\\"; break;
 260                         case "n": replacement = "\n"; break;
 261                         case "a": replacement = ftos(floor(this.armorvalue)); break;
 262                         case "h": replacement = ftos(floor(this.health)); break;
 263                         case "l": replacement = NearestLocation(this.origin); break;
 264                         case "y": replacement = NearestLocation(cursor); break;
 265                         case "d": replacement = NearestLocation(this.death_origin); break;
 266                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 267                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity)); break;
 268                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 269                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 270                         case "S": replacement = ftos(vlen(this.velocity)); break;
 271                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 272                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 273                         default:
 274                         {
 275                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 276                                 replacement = M_ARGV(2, string);
 277                                 break;
 278                         }
 279                 }
 280
 281                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 282                 p = p + strlen(replacement);
 283         }
 284         return msg;
 285 }
 286
 287 /*
 288 =============
 289 GetCvars
 290 =============
 291 Called with:
 292   0:  sends the request
 293   >0: receives a cvar from name=argv(f) value=argv(f+1)
 294 */
 295 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 296 {
 297         if (f < 0)
 298         {
 299                 if (store.(field))
 300                         strunzone(store.(field));
 301                 store.(field) = string_null;
 302         }
 303         else if (f > 0)
 304         {
 305                 if (thisname == name)
 306                 {
 307                         if (store.(field))
 308                                 strunzone(store.(field));
 309                         store.(field) = strzone(argv(f + 1));
 310                 }
 311         }
 312         else
 313                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 314 }
 315 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 316 {
 317         GetCvars_handleString(this, store, thisname, f, field, name);
 318         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 319                 if (thisname == name)
 320                 {
 321                         string s = func(this, strcat1(store.(field)));
 322                         if (s != store.(field))
 323                         {
 324                                 strunzone(store.(field));
 325                                 store.(field) = strzone(s);
 326                         }
 327                 }
 328 }
 329 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 330 {
 331         if (f < 0)
 332         {
 333         }
 334         else if (f > 0)
 335         {
 336                 if (thisname == name)
 337                         store.(field) = stof(argv(f + 1));
 338         }
 339         else
 340                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 341 }
 342 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 343 {
 344         if (f < 0)
 345         {
 346         }
 347         else if (f > 0)
 348         {
 349                 if (thisname == name)
 350                 {
 351                         if (!store.(field))
 352                         {
 353                                 store.(field) = stof(argv(f + 1));
 354                                 if (!store.(field))
 355                                         store.(field) = -1;
 356                         }
 357                 }
 358         }
 359         else
 360         {
 361                 if (!store.(field))
 362                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 363         }
 364 }
 365 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 366 {
 367         string o;
 368         o = W_FixWeaponOrder_ForceComplete(wo);
 369         if(this.weaponorder_byimpulse)
 370         {
 371                 strunzone(this.weaponorder_byimpulse);
 372                 this.weaponorder_byimpulse = string_null;
 373         }
 374         this.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 375         return o;
 376 }
 377
 378 REPLICATE(autoswitch, bool, "cl_autoswitch");
 379
 380 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 381
 382 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 383
 384 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 385
 386 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 387
 388 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 389
 390 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 391
 392 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 393
 394 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 395
 396 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 397
 398 REPLICATE(cvar_cl_physics, string, "cl_physics");
 399
 400 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 401
 402 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 403
 404 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 405
 406 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 407
 408 /**
 409  * @param f -1: cleanup, 0: request, 1: receive
 410  */
 411 void GetCvars(entity this, entity store, int f)
 412 {
 413         string s = string_null;
 414
 415         if (f > 0)
 416                 s = strcat1(argv(f));
 417
 418         get_cvars_f = f;
 419         get_cvars_s = s;
 420         MUTATOR_CALLHOOK(GetCvars);
 421
 422         Notification_GetCvars(this);
 423
 424         ReplicateVars(this, store, s, f);
 425
 426         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 427         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 428         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 429         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 430         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 431         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 432         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 433         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 434         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 435         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 436         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 437
 438         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 439
 440         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 441         if (f > 0)
 442         {
 443                 if (s == "cl_weaponpriority")
 444                 {
 445                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 446                         {
 447                                 .entity weaponentity = weaponentities[slot];
 448                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 449                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 450                         }
 451                 }
 452                 if (s == "cl_allow_uidtracking")
 453                         PlayerStats_GameReport_AddPlayer(this);
 454         }
 455 }
 456
 457 // decolorizes and team colors the player name when needed
 458 string playername(entity p, bool team_colorize)
 459 {
 460     string t;
 461     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 462     {
 463         t = Team_ColorCode(p.team);
 464         return strcat(t, strdecolorize(p.netname));
 465     }
 466     else
 467         return p.netname;
 468 }
 469
 470 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 471 {
 472         int i = weaponinfo.m_id;
 473         int d = 0;
 474         bool allow_mutatorblocked = false;
 475
 476         if(!i)
 477                 return 0;
 478
 479         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 480         d = M_ARGV(1, float);
 481         allguns = M_ARGV(2, bool);
 482         allow_mutatorblocked = M_ARGV(3, bool);
 483
 484         if(allguns)
 485         {
 486                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 487                         d = true;
 488                 else
 489                         d = false;
 490         }
 491         else if(!mutator_returnvalue)
 492                 d = !(!weaponinfo.weaponstart);
 493
 494         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 495                 d = 0;
 496
 497         float t = weaponinfo.weaponstartoverride;
 498
 499         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 500
 501         // bit order in t:
 502         // 1: want or not
 503         // 2: is default?
 504         // 4: is set by default?
 505         if(t < 0)
 506                 t = 4 | (3 * d);
 507         else
 508                 t |= (2 * d);
 509
 510         return t;
 511 }
 512
 513 void readplayerstartcvars()
 514 {
 515         float i, t;
 516         string s;
 517
 518         // initialize starting values for players
 519         start_weapons = '0 0 0';
 520         start_weapons_default = '0 0 0';
 521         start_weapons_defaultmask = '0 0 0';
 522         start_items = 0;
 523         start_ammo_shells = 0;
 524         start_ammo_nails = 0;
 525         start_ammo_rockets = 0;
 526         start_ammo_cells = 0;
 527         start_ammo_plasma = 0;
 528         start_health = cvar("g_balance_health_start");
 529         start_armorvalue = cvar("g_balance_armor_start");
 530
 531         g_weaponarena = 0;
 532         g_weaponarena_weapons = '0 0 0';
 533
 534         s = cvar_string("g_weaponarena");
 535
 536         MUTATOR_CALLHOOK(SetWeaponArena, s);
 537         s = M_ARGV(0, string);
 538
 539         if (s == "0" || s == "")
 540         {
 541                 // no arena
 542         }
 543         else if (s == "off")
 544         {
 545                 // forcibly turn off weaponarena
 546         }
 547         else if (s == "all" || s == "1")
 548         {
 549                 g_weaponarena = 1;
 550                 g_weaponarena_list = "All Weapons";
 551                 FOREACH(Weapons, it != WEP_Null, {
 552                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 553                                 g_weaponarena_weapons |= (it.m_wepset);
 554                 });
 555         }
 556         else if (s == "devall")
 557         {
 558                 g_weaponarena = 1;
 559                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 560                 FOREACH(Weapons, it != WEP_Null,
 561                 {
 562                         g_weaponarena_weapons |= (it.m_wepset);
 563                 });
 564         }
 565         else if (s == "most")
 566         {
 567                 g_weaponarena = 1;
 568                 g_weaponarena_list = "Most Weapons";
 569                 FOREACH(Weapons, it != WEP_Null, {
 570                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 571                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 572                                         g_weaponarena_weapons |= (it.m_wepset);
 573                 });
 574         }
 575         else if (s == "none")
 576         {
 577                 g_weaponarena = 1;
 578                 g_weaponarena_list = "No Weapons";
 579         }
 580         else
 581         {
 582                 g_weaponarena = 1;
 583                 t = tokenize_console(s);
 584                 g_weaponarena_list = "";
 585                 for (i = 0; i < t; ++i)
 586                 {
 587                         s = argv(i);
 588                         FOREACH(Weapons, it != WEP_Null, {
 589                                 if(it.netname == s)
 590                                 {
 591                                         g_weaponarena_weapons |= (it.m_wepset);
 592                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 593                                         break;
 594                                 }
 595                         });
 596                 }
 597                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 598         }
 599
 600         if(g_weaponarena)
 601                 g_weaponarena_random = cvar("g_weaponarena_random");
 602         else
 603                 g_weaponarena_random = 0;
 604         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 605
 606         if (g_weaponarena)
 607         {
 608                 g_weapon_stay = 0; // incompatible
 609                 start_weapons = g_weaponarena_weapons;
 610                 start_items |= IT_UNLIMITED_AMMO;
 611         }
 612         else
 613         {
 614                 FOREACH(Weapons, it != WEP_Null, {
 615                         int w = want_weapon(it, false);
 616                         WepSet s = it.m_wepset;
 617                         if(w & 1)
 618                                 start_weapons |= s;
 619                         if(w & 2)
 620                                 start_weapons_default |= s;
 621                         if(w & 4)
 622                                 start_weapons_defaultmask |= s;
 623                 });
 624         }
 625
 626         if(!cvar("g_use_ammunition"))
 627                 start_items |= IT_UNLIMITED_AMMO;
 628
 629         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 630         {
 631                 start_ammo_shells = 999;
 632                 start_ammo_nails = 999;
 633                 start_ammo_rockets = 999;
 634                 start_ammo_cells = 999;
 635                 start_ammo_plasma = 999;
 636                 start_ammo_fuel = 999;
 637         }
 638         else
 639         {
 640                 start_ammo_shells = cvar("g_start_ammo_shells");
 641                 start_ammo_nails = cvar("g_start_ammo_nails");
 642                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 643                 start_ammo_cells = cvar("g_start_ammo_cells");
 644                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 645                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 646                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 647                 random_start_shells = cvar("g_random_start_shells");
 648                 random_start_bullets = cvar("g_random_start_bullets");
 649                 random_start_rockets = cvar("g_random_start_rockets");
 650                 random_start_cells = cvar("g_random_start_cells");
 651                 random_start_plasma = cvar("g_random_start_plasma");
 652         }
 653
 654         if (warmup_stage)
 655         {
 656                 warmup_start_ammo_shells = start_ammo_shells;
 657                 warmup_start_ammo_nails = start_ammo_nails;
 658                 warmup_start_ammo_rockets = start_ammo_rockets;
 659                 warmup_start_ammo_cells = start_ammo_cells;
 660                 warmup_start_ammo_plasma = start_ammo_plasma;
 661                 warmup_start_ammo_fuel = start_ammo_fuel;
 662                 warmup_start_health = start_health;
 663                 warmup_start_armorvalue = start_armorvalue;
 664                 warmup_start_weapons = start_weapons;
 665                 warmup_start_weapons_default = start_weapons_default;
 666                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 667
 668                 if (!g_weaponarena && !g_ca && !g_freezetag)
 669                 {
 670                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 671                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 672                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 673                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 674                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 675                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 676                         warmup_start_health = cvar("g_warmup_start_health");
 677                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 678                         warmup_start_weapons = '0 0 0';
 679                         warmup_start_weapons_default = '0 0 0';
 680                         warmup_start_weapons_defaultmask = '0 0 0';
 681                         FOREACH(Weapons, it != WEP_Null, {
 682                                 int w = want_weapon(it, g_warmup_allguns);
 683                                 WepSet s = (it.m_wepset);
 684                                 if(w & 1)
 685                                         warmup_start_weapons |= s;
 686                                 if(w & 2)
 687                                         warmup_start_weapons_default |= s;
 688                                 if(w & 4)
 689                                         warmup_start_weapons_defaultmask |= s;
 690                         });
 691                 }
 692         }
 693
 694         if (g_jetpack)
 695                 start_items |= ITEM_Jetpack.m_itemid;
 696
 697         MUTATOR_CALLHOOK(SetStartItems);
 698
 699         if (start_items & ITEM_Jetpack.m_itemid)
 700         {
 701                 start_items |= ITEM_JetpackRegen.m_itemid;
 702                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 703                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 704         }
 705
 706         WepSet precache_weapons = start_weapons;
 707         if (g_warmup_allguns != 1)
 708                 precache_weapons |= warmup_start_weapons;
 709         FOREACH(Weapons, it != WEP_Null, {
 710                 if(precache_weapons & (it.m_wepset))
 711                         it.wr_init(it);
 712         });
 713
 714         start_ammo_shells = max(0, start_ammo_shells);
 715         start_ammo_nails = max(0, start_ammo_nails);
 716         start_ammo_rockets = max(0, start_ammo_rockets);
 717         start_ammo_cells = max(0, start_ammo_cells);
 718         start_ammo_plasma = max(0, start_ammo_plasma);
 719         start_ammo_fuel = max(0, start_ammo_fuel);
 720         random_start_shells = max(0, random_start_shells);
 721         random_start_bullets = max(0, random_start_bullets);
 722         random_start_rockets = max(0, random_start_rockets);
 723         random_start_cells = max(0, random_start_cells);
 724         random_start_plasma = max(0, random_start_plasma);
 725
 726         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 727         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 728         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 729         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 730         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 731         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 732 }
 733
 734 void precache_playermodel(string m)
 735 {
 736         float globhandle, i, n;
 737         string f;
 738
 739         if(substring(m, -9,5) == "_lod1")
 740                 return;
 741         if(substring(m, -9,5) == "_lod2")
 742                 return;
 743         precache_model(m);
 744         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 745         if(fexists(f))
 746                 precache_model(f);
 747         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 748         if(fexists(f))
 749                 precache_model(f);
 750
 751         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 752         if (globhandle < 0)
 753                 return;
 754         n = search_getsize(globhandle);
 755         for (i = 0; i < n; ++i)
 756         {
 757                 //print(search_getfilename(globhandle, i), "\n");
 758                 f = search_getfilename(globhandle, i);
 759                 PrecachePlayerSounds(f);
 760         }
 761         search_end(globhandle);
 762 }
 763 void precache_all_playermodels(string pattern)
 764 {
 765         int globhandle = search_begin(pattern, true, false);
 766         if (globhandle < 0) return;
 767         int n = search_getsize(globhandle);
 768         for (int i = 0; i < n; ++i)
 769         {
 770                 string s = search_getfilename(globhandle, i);
 771                 precache_playermodel(s);
 772         }
 773         search_end(globhandle);
 774 }
 775
 776 void precache_playermodels(string s)
 777 {
 778         FOREACH_WORD(s, true, { precache_playermodel(it); });
 779 }
 780
 781 void precache()
 782 {
 783     // gamemode related things
 784
 785     // Precache all player models if desired
 786     if (autocvar_sv_precacheplayermodels)
 787     {
 788         PrecachePlayerSounds("sound/player/default.sounds");
 789         precache_all_playermodels("models/player/*.zym");
 790         precache_all_playermodels("models/player/*.dpm");
 791         precache_all_playermodels("models/player/*.md3");
 792         precache_all_playermodels("models/player/*.psk");
 793         precache_all_playermodels("models/player/*.iqm");
 794     }
 795
 796     if (autocvar_sv_defaultcharacter)
 797     {
 798                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 799                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 800                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 801                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 802                 precache_playermodels(autocvar_sv_defaultplayermodel);
 803     }
 804
 805 #if 0
 806     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 807
 808     if (!this.noise && this.music) // quake 3 uses the music field
 809         this.noise = this.music;
 810
 811     // plays music for the level if there is any
 812     if (this.noise)
 813     {
 814         precache_sound (this.noise);
 815         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 816     }
 817 #endif
 818 }
 819
 820
 821 void make_safe_for_remove(entity e)
 822 {
 823     if (e.initialize_entity)
 824     {
 825         entity ent, prev = NULL;
 826         for (ent = initialize_entity_first; ent; )
 827         {
 828             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 829             {
 830                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 831                 // skip it in linked list
 832                 if (prev)
 833                 {
 834                     prev.initialize_entity_next = ent.initialize_entity_next;
 835                     ent = prev.initialize_entity_next;
 836                 }
 837                 else
 838                 {
 839                     initialize_entity_first = ent.initialize_entity_next;
 840                     ent = initialize_entity_first;
 841                 }
 842             }
 843             else
 844             {
 845                 prev = ent;
 846                 ent = ent.initialize_entity_next;
 847             }
 848         }
 849     }
 850 }
 851
 852 .float remove_except_protected_forbidden;
 853 void remove_except_protected(entity e)
 854 {
 855         if(e.remove_except_protected_forbidden)
 856                 error("not allowed to remove this at this point");
 857         builtin_remove(e);
 858 }
 859
 860 void remove_unsafely(entity e)
 861 {
 862     if(e.classname == "spike")
 863         error("Removing spikes is forbidden (crylink bug), please report");
 864     builtin_remove(e);
 865 }
 866
 867 void remove_safely(entity e)
 868 {
 869     make_safe_for_remove(e);
 870     builtin_remove(e);
 871 }
 872
 873 void InitializeEntity(entity e, void(entity this) func, float order)
 874 {
 875     entity prev, cur;
 876
 877     if (!e || e.initialize_entity)
 878     {
 879         // make a proxy initializer entity
 880         entity e_old = e;
 881         e = new(initialize_entity);
 882         e.enemy = e_old;
 883     }
 884
 885     e.initialize_entity = func;
 886     e.initialize_entity_order = order;
 887
 888     cur = initialize_entity_first;
 889     prev = NULL;
 890     for (;;)
 891     {
 892         if (!cur || cur.initialize_entity_order > order)
 893         {
 894             // insert between prev and cur
 895             if (prev)
 896                 prev.initialize_entity_next = e;
 897             else
 898                 initialize_entity_first = e;
 899             e.initialize_entity_next = cur;
 900             return;
 901         }
 902         prev = cur;
 903         cur = cur.initialize_entity_next;
 904     }
 905 }
 906 void InitializeEntitiesRun()
 907 {
 908     entity startoflist = initialize_entity_first;
 909     initialize_entity_first = NULL;
 910     delete_fn = remove_except_protected;
 911     for (entity e = startoflist; e; e = e.initialize_entity_next)
 912     {
 913                 e.remove_except_protected_forbidden = 1;
 914     }
 915     for (entity e = startoflist; e; )
 916     {
 917                 e.remove_except_protected_forbidden = 0;
 918         e.initialize_entity_order = 0;
 919         entity next = e.initialize_entity_next;
 920         e.initialize_entity_next = NULL;
 921         var void(entity this) func = e.initialize_entity;
 922         e.initialize_entity = func_null;
 923         if (e.classname == "initialize_entity")
 924         {
 925             entity wrappee = e.enemy;
 926             builtin_remove(e);
 927             e = wrappee;
 928         }
 929         //dprint("Delayed initialization: ", e.classname, "\n");
 930         if (func)
 931         {
 932                 func(e);
 933         }
 934         else
 935         {
 936             eprint(e);
 937             backtrace(strcat("Null function in: ", e.classname, "\n"));
 938         }
 939         e = next;
 940     }
 941     delete_fn = remove_unsafely;
 942 }
 943
 944 .float(entity) isEliminated;
 945 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 946 {
 947         float i, f, b;
 948         entity e;
 949         WriteHeader(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
 950         WriteByte(MSG_ENTITY, sendflags);
 951
 952         if(sendflags & 1)
 953         {
 954                 for(i = 1; i <= maxclients; i += 8)
 955                 {
 956                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
 957                         {
 958                                 if(eliminatedPlayers.isEliminated(e))
 959                                         f |= b;
 960                         }
 961                         WriteByte(MSG_ENTITY, f);
 962                 }
 963         }
 964
 965         return true;
 966 }
 967
 968 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 969 {
 970         if(eliminatedPlayers)
 971         {
 972                 backtrace("Can't spawn eliminatedPlayers again!");
 973                 return;
 974         }
 975         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 976         eliminatedPlayers.isEliminated = isEliminated_func;
 977 }
 978
 979
 980
 981
 982 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 983 {
 984         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 985                 this.projectiledeathtype |= HITTYPE_SPLASH;
 986         adaptor_think2use(this);
 987 }
 988
 989 // deferred dropping
 990 void DropToFloor_Handler(entity this)
 991 {
 992     WITHSELF(this, builtin_droptofloor());
 993     this.dropped_origin = this.origin;
 994 }
 995
 996 void droptofloor(entity this)
 997 {
 998     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
 999 }
1000
1001
1002
1003 float trace_hits_box_a0, trace_hits_box_a1;
1004
1005 float trace_hits_box_1d(float end, float thmi, float thma)
1006 {
1007     if (end == 0)
1008     {
1009         // just check if x is in range
1010         if (0 < thmi)
1011             return false;
1012         if (0 > thma)
1013             return false;
1014     }
1015     else
1016     {
1017         // do the trace with respect to x
1018         // 0 -> end has to stay in thmi -> thma
1019         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1020         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1021         if (trace_hits_box_a0 > trace_hits_box_a1)
1022             return false;
1023     }
1024     return true;
1025 }
1026
1027 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1028 {
1029     end -= start;
1030     thmi -= start;
1031     thma -= start;
1032     // now it is a trace from 0 to end
1033
1034     trace_hits_box_a0 = 0;
1035     trace_hits_box_a1 = 1;
1036
1037     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1038         return false;
1039     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1040         return false;
1041     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1042         return false;
1043
1044     return true;
1045 }
1046
1047 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1048 {
1049     return trace_hits_box(start, end, thmi - ma, thma - mi);
1050 }
1051
1052 bool SUB_NoImpactCheck(entity this, entity toucher)
1053 {
1054         // zero hitcontents = this is not the real impact, but either the
1055         // mirror-impact of something hitting the projectile instead of the
1056         // projectile hitting the something, or a touchareagrid one. Neither of
1057         // these stop the projectile from moving, so...
1058         if(trace_dphitcontents == 0)
1059         {
1060                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1061                 checkclient(this);
1062         }
1063     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1064         return true;
1065     if (toucher == NULL && this.size != '0 0 0')
1066     {
1067         vector tic;
1068         tic = this.velocity * sys_frametime;
1069         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1070         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1071         if (trace_fraction >= 1)
1072         {
1073             LOG_TRACE("Odd... did not hit...?");
1074         }
1075         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1076         {
1077             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1078             return true;
1079         }
1080     }
1081
1082     return false;
1083 }
1084
1085 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1086
1087 void W_Crylink_Dequeue(entity e);
1088 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1089 {
1090         if(SUB_OwnerCheck(this, toucher))
1091                 return true;
1092         if(SUB_NoImpactCheck(this, toucher))
1093         {
1094                 if(this.classname == "nade")
1095                         return false; // no checks here
1096                 else if(this.classname == "grapplinghook")
1097                         RemoveHook(this);
1098                 else if(this.classname == "spike")
1099                 {
1100                         W_Crylink_Dequeue(this);
1101                         delete(this);
1102                 }
1103                 else
1104                         delete(this);
1105                 return true;
1106         }
1107         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1108                 UpdateCSQCProjectile(this);
1109         return false;
1110 }
1111
1112 /** engine callback */
1113 void URI_Get_Callback(float id, float status, string data)
1114 {
1115         if(url_URI_Get_Callback(id, status, data))
1116         {
1117                 // handled
1118         }
1119         else if (id == URI_GET_DISCARD)
1120         {
1121                 // discard
1122         }
1123         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1124         {
1125                 // sv_cmd curl
1126                 Curl_URI_Get_Callback(id, status, data);
1127         }
1128         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1129         {
1130                 // online ban list
1131                 OnlineBanList_URI_Get_Callback(id, status, data);
1132         }
1133         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1134         {
1135                 // handled by a mutator
1136         }
1137         else
1138         {
1139                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1140         }
1141 }
1142
1143 string uid2name(string myuid) {
1144         string s;
1145         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1146
1147         // FIXME remove this later after 0.6 release
1148         // convert old style broken records to correct style
1149         if(s == "")
1150         {
1151                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1152                 if(s != "")
1153                 {
1154                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1155                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1156                 }
1157         }
1158
1159         if(s == "")
1160                 s = "^1Unregistered Player";
1161         return s;
1162 }
1163
1164 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1165 {
1166     float m, i;
1167     vector start, org, delta, end, enddown, mstart;
1168
1169     m = e.dphitcontentsmask;
1170     e.dphitcontentsmask = goodcontents | badcontents;
1171
1172     org = boundmin;
1173     delta = boundmax - boundmin;
1174
1175     start = end = org;
1176
1177     for (i = 0; i < attempts; ++i)
1178     {
1179         start.x = org.x + random() * delta.x;
1180         start.y = org.y + random() * delta.y;
1181         start.z = org.z + random() * delta.z;
1182
1183         // rule 1: start inside world bounds, and outside
1184         // solid, and don't start from somewhere where you can
1185         // fall down to evil
1186         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1187         if (trace_fraction >= 1)
1188             continue;
1189         if (trace_startsolid)
1190             continue;
1191         if (trace_dphitcontents & badcontents)
1192             continue;
1193         if (trace_dphitq3surfaceflags & badsurfaceflags)
1194             continue;
1195
1196         // rule 2: if we are too high, lower the point
1197         if (trace_fraction * delta.z > maxaboveground)
1198             start = trace_endpos + '0 0 1' * maxaboveground;
1199         enddown = trace_endpos;
1200
1201         // rule 3: make sure we aren't outside the map. This only works
1202         // for somewhat well formed maps. A good rule of thumb is that
1203         // the map should have a convex outside hull.
1204         // these can be traceLINES as we already verified the starting box
1205         mstart = start + 0.5 * (e.mins + e.maxs);
1206         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1207         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1208             continue;
1209         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1210         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1211             continue;
1212         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1213         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1214             continue;
1215         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1216         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1217             continue;
1218         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1219         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1220             continue;
1221
1222         // rule 4: we must "see" some spawnpoint or item
1223     entity sp = NULL;
1224     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1225     {
1226         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1227         {
1228                 sp = it;
1229                 break;
1230         }
1231     });
1232         if(!sp)
1233         {
1234                 IL_EACH(g_items, checkpvs(mstart, it),
1235                 {
1236                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1237                         {
1238                                 sp = it;
1239                                 break;
1240                         }
1241                 });
1242
1243                 if(!sp)
1244                         continue;
1245         }
1246
1247         // find a random vector to "look at"
1248         end.x = org.x + random() * delta.x;
1249         end.y = org.y + random() * delta.y;
1250         end.z = org.z + random() * delta.z;
1251         end = start + normalize(end - start) * vlen(delta);
1252
1253         // rule 4: start TO end must not be too short
1254         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1255         if (trace_startsolid)
1256             continue;
1257         if (trace_fraction < minviewdistance / vlen(delta))
1258             continue;
1259
1260         // rule 5: don't want to look at sky
1261         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1262             continue;
1263
1264         // rule 6: we must not end up in trigger_hurt
1265         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1266             continue;
1267
1268         break;
1269     }
1270
1271     e.dphitcontentsmask = m;
1272
1273     if (i < attempts)
1274     {
1275         setorigin(e, start);
1276         e.angles = vectoangles(end - start);
1277         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1278         return true;
1279     }
1280     else
1281         return false;
1282 }
1283
1284 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1285 {
1286         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1287 }
1288
1289 void write_recordmarker(entity pl, float tstart, float dt)
1290 {
1291     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1292
1293     // also write a marker into demo files for demotc-race-record-extractor to find
1294     stuffcmd(pl,
1295              strcat(
1296                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1297                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1298 }
1299
1300 void attach_sameorigin(entity e, entity to, string tag)
1301 {
1302     vector org, t_forward, t_left, t_up, e_forward, e_up;
1303     float tagscale;
1304
1305     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1306     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1307     t_forward = v_forward * tagscale;
1308     t_left = v_right * -tagscale;
1309     t_up = v_up * tagscale;
1310
1311     e.origin_x = org * t_forward;
1312     e.origin_y = org * t_left;
1313     e.origin_z = org * t_up;
1314
1315     // current forward and up directions
1316     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1317                 e.angles = AnglesTransform_FromVAngles(e.angles);
1318         else
1319                 e.angles = AnglesTransform_FromAngles(e.angles);
1320     fixedmakevectors(e.angles);
1321
1322     // untransform forward, up!
1323     e_forward.x = v_forward * t_forward;
1324     e_forward.y = v_forward * t_left;
1325     e_forward.z = v_forward * t_up;
1326     e_up.x = v_up * t_forward;
1327     e_up.y = v_up * t_left;
1328     e_up.z = v_up * t_up;
1329
1330     e.angles = fixedvectoangles2(e_forward, e_up);
1331     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1332                 e.angles = AnglesTransform_ToVAngles(e.angles);
1333         else
1334                 e.angles = AnglesTransform_ToAngles(e.angles);
1335
1336     setattachment(e, to, tag);
1337     setorigin(e, e.origin);
1338 }
1339
1340 void detach_sameorigin(entity e)
1341 {
1342     vector org;
1343     org = gettaginfo(e, 0);
1344     e.angles = fixedvectoangles2(v_forward, v_up);
1345     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1346                 e.angles = AnglesTransform_ToVAngles(e.angles);
1347         else
1348                 e.angles = AnglesTransform_ToAngles(e.angles);
1349     setorigin(e, org);
1350     setattachment(e, NULL, "");
1351     setorigin(e, e.origin);
1352 }
1353
1354 void follow_sameorigin(entity e, entity to)
1355 {
1356     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1357     e.aiment = to; // make the hole follow bmodel
1358     e.punchangle = to.angles; // the original angles of bmodel
1359     e.view_ofs = e.origin - to.origin; // relative origin
1360     e.v_angle = e.angles - to.angles; // relative angles
1361 }
1362
1363 void unfollow_sameorigin(entity e)
1364 {
1365     set_movetype(e, MOVETYPE_NONE);
1366 }
1367
1368 entity gettaginfo_relative_ent;
1369 vector gettaginfo_relative(entity e, float tag)
1370 {
1371     if (!gettaginfo_relative_ent)
1372     {
1373         gettaginfo_relative_ent = spawn();
1374         gettaginfo_relative_ent.effects = EF_NODRAW;
1375     }
1376     gettaginfo_relative_ent.model = e.model;
1377     gettaginfo_relative_ent.modelindex = e.modelindex;
1378     gettaginfo_relative_ent.frame = e.frame;
1379     return gettaginfo(gettaginfo_relative_ent, tag);
1380 }
1381
1382 .string aiment_classname;
1383 .float aiment_deadflag;
1384 void SetMovetypeFollow(entity ent, entity e)
1385 {
1386         // FIXME this may not be warpzone aware
1387         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1388         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1389         ent.aiment = e; // make the hole follow bmodel
1390         ent.punchangle = e.angles; // the original angles of bmodel
1391         ent.view_ofs = ent.origin - e.origin; // relative origin
1392         ent.v_angle = ent.angles - e.angles; // relative angles
1393         ent.aiment_classname = strzone(e.classname);
1394         ent.aiment_deadflag = e.deadflag;
1395 }
1396 void UnsetMovetypeFollow(entity ent)
1397 {
1398         set_movetype(ent, MOVETYPE_FLY);
1399         PROJECTILE_MAKETRIGGER(ent);
1400         ent.aiment = NULL;
1401 }
1402 float LostMovetypeFollow(entity ent)
1403 {
1404 /*
1405         if(ent.move_movetype != MOVETYPE_FOLLOW)
1406                 if(ent.aiment)
1407                         error("???");
1408 */
1409         if(ent.aiment)
1410         {
1411                 if(ent.aiment.classname != ent.aiment_classname)
1412                         return 1;
1413                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1414                         return 1;
1415         }
1416         return 0;
1417 }
1418
1419 .bool pushable;
1420 bool isPushable(entity e)
1421 {
1422         if(e.pushable)
1423                 return true;
1424         if(IS_VEHICLE(e))
1425                 return false;
1426         if(e.iscreature)
1427                 return true;
1428         switch(e.classname)
1429         {
1430                 case "body":
1431                 case "droppedweapon":
1432                         return true;
1433                 case "bullet": // antilagged bullets can't hit this either
1434                         return false;
1435         }
1436         if (e.projectiledeathtype)
1437                 return true;
1438         return false;
1439 }