qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string race_GetName(float pos);
  20 string race_PlaceName(float pos);
  21 string GetMapname();
  22 string ColoredTeamName(float t);
  23
  24 string admin_name(void)
  25 {
  26         if(cvar_string("sv_adminnick") != "")
  27                 return cvar_string("sv_adminnick");
  28         else
  29                 return "SERVER ADMIN";
  30 }
  31
  32 float DistributeEvenly_amount;
  33 float DistributeEvenly_totalweight;
  34 void DistributeEvenly_Init(float amount, float totalweight)
  35 {
  36     if (DistributeEvenly_amount)
  37     {
  38         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  39         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  40     }
  41     if (totalweight == 0)
  42         DistributeEvenly_amount = 0;
  43     else
  44         DistributeEvenly_amount = amount;
  45     DistributeEvenly_totalweight = totalweight;
  46 }
  47 float DistributeEvenly_Get(float weight)
  48 {
  49     float f;
  50     if (weight <= 0)
  51         return 0;
  52     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  53     DistributeEvenly_totalweight -= weight;
  54     DistributeEvenly_amount -= f;
  55     return f;
  56 }
  57
  58 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  59
  60
  61 string STR_PLAYER = "player";
  62 string STR_SPECTATOR = "spectator";
  63 string STR_OBSERVER = "observer";
  64
  65 #if 0
  66 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  67 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  69 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  70 #else
  71 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  72 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  73 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  74 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  75 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  76 #endif
  77
  78 // copies a string to a tempstring (so one can strunzone it)
  79 string strcat1(string s) = #115; // FRIK_FILE
  80
  81 float logfile_open;
  82 float logfile;
  83
  84 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  85 {
  86         local float nPlayerHealth = rint(enPlayer.health);
  87         local float nPlayerArmor = rint(enPlayer.armorvalue);
  88         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  89         local float nPlayerPing = rint(enPlayer.ping);
  90         local string strPlayerPingColor;
  91         local string strMessage;
  92         if(nPlayerPing >= 150)
  93                 strPlayerPingColor = "^1";
  94         else
  95                 strPlayerPingColor = "^2";
  96
  97         if((cvar("sv_fragmessage_information_stats")) && (enPlayer.health >= 1))
  98                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  99
 100         if(cvar("sv_fragmessage_information_ping")) {
 101                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 102                         strMessage = strcat(strMessage, " ^7(^2Bot");
 103                 else
 104                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 105                 if(cvar("sv_fragmessage_information_handicap"))
 106                         if(cvar("sv_fragmessage_information_handicap") == 2)
 107                                 if(nPlayerHandicap <= 1)
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 109                                 else
 110                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                         else if not(nPlayerHandicap <= 1)
 112                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 113                 else
 114                         strMessage = strcat(strMessage, "^7)");
 115         } else if(cvar("sv_fragmessage_information_handicap")) {
 116                 if(cvar("sv_fragmessage_information_handicap") == 2)
 117                         if(nPlayerHandicap <= 1)
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 119                         else
 120                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121                 else if(nPlayerHandicap > 1)
 122                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 123         }
 124         return strMessage;
 125 }
 126 void bcenterprint(string s)
 127 {
 128     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 129     entity head;
 130     FOR_EACH_PLAYER(head)
 131     if (clienttype(head) == CLIENTTYPE_REAL)
 132         centerprint(head, s);
 133 }
 134
 135 void GameLogEcho(string s)
 136 {
 137     string fn;
 138     float matches;
 139
 140     if (cvar("sv_eventlog_files"))
 141     {
 142         if (!logfile_open)
 143         {
 144             logfile_open = TRUE;
 145             matches = cvar("sv_eventlog_files_counter") + 1;
 146             cvar_set("sv_eventlog_files_counter", ftos(matches));
 147             fn = ftos(matches);
 148             if (strlen(fn) < 8)
 149                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 150             fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 151             logfile = fopen(fn, FILE_APPEND);
 152             fputs(logfile, ":logversion:3\n");
 153         }
 154         if (logfile >= 0)
 155         {
 156             if (cvar("sv_eventlog_files_timestamps"))
 157                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 158             else
 159                 fputs(logfile, strcat(s, "\n"));
 160         }
 161     }
 162     if (cvar("sv_eventlog_console"))
 163     {
 164         print(s, "\n");
 165     }
 166 }
 167
 168 void GameLogInit()
 169 {
 170     logfile_open = 0;
 171     // will be opened later
 172 }
 173
 174 void GameLogClose()
 175 {
 176     if (logfile_open && logfile >= 0)
 177     {
 178         fclose(logfile);
 179         logfile = -1;
 180     }
 181 }
 182
 183 vector PL_VIEW_OFS;
 184 vector PL_MIN;
 185 vector PL_MAX;
 186 vector PL_CROUCH_VIEW_OFS;
 187 vector PL_CROUCH_MIN;
 188 vector PL_CROUCH_MAX;
 189
 190 float spawnpoint_nag;
 191 void relocate_spawnpoint()
 192 {
 193     PL_VIEW_OFS                             = stov(cvar_string("sv_player_viewoffset"));
 194     PL_MIN                                  = stov(cvar_string("sv_player_mins"));
 195     PL_MAX                                  = stov(cvar_string("sv_player_maxs"));
 196     PL_CROUCH_VIEW_OFS                      = stov(cvar_string("sv_player_crouch_viewoffset"));
 197     PL_CROUCH_MIN                           = stov(cvar_string("sv_player_crouch_mins"));
 198     PL_CROUCH_MAX                           = stov(cvar_string("sv_player_crouch_maxs"));
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (cvar("g_spawnpoints_auto_move_out_of_solid"))
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239
 240     if (cvar("r_showbboxes"))
 241     {
 242         // show where spawnpoints point at too
 243         makevectors(self.angles);
 244         entity e;
 245         e = spawn();
 246         e.classname = "info_player_foo";
 247         setorigin(e, self.origin + v_forward * 24);
 248         setsize(e, '-8 -8 -8', '8 8 8');
 249         e.solid = SOLID_TRIGGER;
 250     }
 251 }
 252
 253 #define strstr strstrofs
 254 /*
 255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 258 // BE CONSTANT OR strzoneD!
 259 float strstr(string haystack, string needle, float offset)
 260 {
 261         float len, endpos;
 262         string found;
 263         len = strlen(needle);
 264         endpos = strlen(haystack) - len;
 265         while(offset <= endpos)
 266         {
 267                 found = substring(haystack, offset, len);
 268                 if(found == needle)
 269                         return offset;
 270                 offset = offset + 1;
 271         }
 272         return -1;
 273 }
 274 */
 275
 276 float NUM_NEAREST_ENTITIES = 4;
 277 entity nearest_entity[NUM_NEAREST_ENTITIES];
 278 float nearest_length[NUM_NEAREST_ENTITIES];
 279 entity findnearest(vector point, .string field, string value, vector axismod)
 280 {
 281     entity localhead;
 282     float i;
 283     float j;
 284     float len;
 285     vector dist;
 286
 287     float num_nearest;
 288     num_nearest = 0;
 289
 290     localhead = find(world, field, value);
 291     while (localhead)
 292     {
 293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 294             dist = localhead.oldorigin;
 295         else
 296             dist = localhead.origin;
 297         dist = dist - point;
 298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 299         len = vlen(dist);
 300
 301         for (i = 0; i < num_nearest; ++i)
 302         {
 303             if (len < nearest_length[i])
 304                 break;
 305         }
 306
 307         // now i tells us where to insert at
 308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 309         if (i < NUM_NEAREST_ENTITIES)
 310         {
 311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 312             {
 313                 nearest_length[j + 1] = nearest_length[j];
 314                 nearest_entity[j + 1] = nearest_entity[j];
 315             }
 316             nearest_length[i] = len;
 317             nearest_entity[i] = localhead;
 318             if (num_nearest < NUM_NEAREST_ENTITIES)
 319                 num_nearest = num_nearest + 1;
 320         }
 321
 322         localhead = find(localhead, field, value);
 323     }
 324
 325     // now use the first one from our list that we can see
 326     for (i = 0; i < num_nearest; ++i)
 327     {
 328         traceline(point, nearest_entity[i].origin, TRUE, world);
 329         if (trace_fraction == 1)
 330         {
 331             if (i != 0)
 332             {
 333                 dprint("Nearest point (");
 334                 dprint(nearest_entity[0].netname);
 335                 dprint(") is not visible, using a visible one.\n");
 336             }
 337             return nearest_entity[i];
 338         }
 339     }
 340
 341     if (num_nearest == 0)
 342         return world;
 343
 344     dprint("Not seeing any location point, using nearest as fallback.\n");
 345     /* DEBUGGING CODE:
 346     dprint("Candidates were: ");
 347     for(j = 0; j < num_nearest; ++j)
 348     {
 349         if(j != 0)
 350                 dprint(", ");
 351         dprint(nearest_entity[j].netname);
 352     }
 353     dprint("\n");
 354     */
 355
 356     return nearest_entity[0];
 357 }
 358
 359 void spawnfunc_target_location()
 360 {
 361     self.classname = "target_location";
 362     // location name in netname
 363     // eventually support: count, teamgame selectors, line of sight?
 364 };
 365
 366 void spawnfunc_info_location()
 367 {
 368     self.classname = "target_location";
 369     self.message = self.netname;
 370 };
 371
 372 string NearestLocation(vector p)
 373 {
 374     entity loc;
 375     string ret;
 376     ret = "somewhere";
 377     loc = findnearest(p, classname, "target_location", '1 1 1');
 378     if (loc)
 379     {
 380         ret = loc.message;
 381     }
 382     else
 383     {
 384         loc = findnearest(p, target, "###item###", '1 1 4');
 385         if (loc)
 386             ret = loc.netname;
 387     }
 388     return ret;
 389 }
 390
 391 string formatmessage(string msg)
 392 {
 393         float p, p1, p2;
 394         float n;
 395         vector cursor;
 396         entity cursor_ent;
 397         string escape;
 398         string replacement;
 399         p = 0;
 400         n = 7;
 401
 402         WarpZone_crosshair_trace(self);
 403         cursor = trace_endpos;
 404         cursor_ent = trace_ent;
 405
 406         while (1) {
 407                 if (n < 1)
 408                         break; // too many replacements
 409
 410                 n = n - 1;
 411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 413
 414                 if (p1 < 0)
 415                         p1 = p2;
 416
 417                 if (p2 < 0)
 418                         p2 = p1;
 419
 420                 p = min(p1, p2);
 421
 422                 if (p < 0)
 423                         break;
 424
 425                 replacement = substring(msg, p, 2);
 426                 escape = substring(msg, p + 1, 1);
 427
 428                 if (escape == "%")
 429                         replacement = "%";
 430                 else if (escape == "\\")
 431                         replacement = "\\";
 432                 else if (escape == "n")
 433                         replacement = "\n";
 434                 else if (escape == "a")
 435                         replacement = ftos(floor(self.armorvalue));
 436                 else if (escape == "h")
 437                         replacement = ftos(floor(self.health));
 438                 else if (escape == "l")
 439                         replacement = NearestLocation(self.origin);
 440                 else if (escape == "y")
 441                         replacement = NearestLocation(cursor);
 442                 else if (escape == "d")
 443                         replacement = NearestLocation(self.death_origin);
 444                 else if (escape == "w") {
 445                         float wep;
 446                         wep = self.weapon;
 447                         if (!wep)
 448                                 wep = self.switchweapon;
 449                         if (!wep)
 450                                 wep = self.cnt;
 451                         replacement = W_Name(wep);
 452                 } else if (escape == "W") {
 453                         if (self.items & IT_SHELLS) replacement = "shells";
 454                         else if (self.items & IT_NAILS) replacement = "bullets";
 455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 456                         else if (self.items & IT_CELLS) replacement = "cells";
 457                         else replacement = "batteries"; // ;)
 458                 } else if (escape == "x") {
 459                         replacement = cursor_ent.netname;
 460                         if (!replacement || !cursor_ent)
 461                                 replacement = "nothing";
 462                 } else if (escape == "p") {
 463                         if (self.last_selected_player)
 464                                 replacement = self.last_selected_player.netname;
 465                         else
 466                                 replacement = "(nobody)";
 467                 } else if (escape == "s")
 468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 469                 else if (escape == "S")
 470                         replacement = ftos(vlen(self.velocity));
 471                 else if (escape == "v") {
 472                         float weapon_number;
 473                         local entity stats;
 474
 475                         if(self.classname == "spectator")
 476                                 stats = self.enemy;
 477                         else
 478                                 stats = self;
 479
 480                         weapon_number = stats.weapon;
 481
 482                         if (!weapon_number)
 483                                 weapon_number = stats.switchweapon;
 484
 485                         if (!weapon_number)
 486                                 weapon_number = stats.cnt;
 487
 488                         if(stats.cvar_cl_accuracy_data_share && stats.stats_fired[weapon_number - 1])
 489                                 replacement = ftos(bound(0, floor(100 * stats.stats_hit[weapon_number - 1] / stats.stats_fired[weapon_number - 1]), 100));
 490                         else
 491                                 replacement = "~"; // or something to indicate NULL, not available
 492                 }
 493
 494                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 495                 p = p + strlen(replacement);
 496         }
 497         return msg;
 498 }
 499
 500 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 501         return (value == 0) ? FALSE : TRUE;
 502 }
 503
 504 /*
 505 =============
 506 GetCvars
 507 =============
 508 Called with:
 509   0:  sends the request
 510   >0: receives a cvar from name=argv(f) value=argv(f+1)
 511 */
 512 void GetCvars_handleString(string thisname, float f, .string field, string name)
 513 {
 514         if (f < 0)
 515         {
 516                 if (self.field)
 517                         strunzone(self.field);
 518                 self.field = string_null;
 519         }
 520         else if (f > 0)
 521         {
 522                 if (thisname == name)
 523                 {
 524                         if (self.field)
 525                                 strunzone(self.field);
 526                         self.field = strzone(argv(f + 1));
 527                 }
 528         }
 529         else
 530                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 531 }
 532 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 533 {
 534         GetCvars_handleString(thisname, f, field, name);
 535         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 536                 if (thisname == name)
 537                 {
 538                         string s;
 539                         s = func(strcat1(self.field));
 540                         if (s != self.field)
 541                         {
 542                                 strunzone(self.field);
 543                                 self.field = strzone(s);
 544                         }
 545                 }
 546 }
 547 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 548 {
 549         if (f < 0)
 550         {
 551         }
 552         else if (f > 0)
 553         {
 554                 if (thisname == name)
 555                         self.field = stof(argv(f + 1));
 556         }
 557         else
 558                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 559 }
 560 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 561 {
 562         if (f < 0)
 563         {
 564         }
 565         else if (f > 0)
 566         {
 567                 if (thisname == name)
 568                 {
 569                         if(!self.field)
 570                         {
 571                                 self.field = stof(argv(f + 1));
 572                                 if(!self.field)
 573                                         self.field = -1;
 574                         }
 575                 }
 576         }
 577         else
 578         {
 579                 if(!self.field)
 580                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 581         }
 582 }
 583 string W_FixWeaponOrder_ForceComplete(string s);
 584 string W_FixWeaponOrder_AllowIncomplete(string s);
 585 float w_getbestweapon(entity e);
 586 void GetCvars(float f)
 587 {
 588         string s;
 589
 590         if (f > 0)
 591                 s = strcat1(argv(f));
 592
 593         get_cvars_f = f;
 594         get_cvars_s = s;
 595         MUTATOR_CALLHOOK(GetCvars);
 596         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 597         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 598         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 599         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 600         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 601         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 602         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 603         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 604         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 605         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 606         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 607         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 608         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 609         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 610         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 611         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 612         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 613         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 614         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 615         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 616         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 617         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 618         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 619         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 620         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 621
 622         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 623         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 624
 625 #ifdef ALLOW_FORCEMODELS
 626         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 627         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 628 #endif
 629         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 630
 631         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 632         if (f > 0)
 633         {
 634                 if (s == "cl_weaponpriority")
 635                         self.switchweapon = w_getbestweapon(self);
 636         }
 637 }
 638
 639 float fexists(string f)
 640 {
 641     float fh;
 642     fh = fopen(f, FILE_READ);
 643     if (fh < 0)
 644         return FALSE;
 645     fclose(fh);
 646     return TRUE;
 647 }
 648
 649 void backtrace(string msg)
 650 {
 651     float dev, war;
 652     dev = cvar("developer");
 653     war = cvar("prvm_backtraceforwarnings");
 654     cvar_set("developer", "1");
 655     cvar_set("prvm_backtraceforwarnings", "1");
 656     print("\n");
 657     print("--- CUT HERE ---\nWARNING: ");
 658     print(msg);
 659     print("\n");
 660     remove(world); // isn't there any better way to cause a backtrace?
 661     print("\n--- CUT UNTIL HERE ---\n");
 662     cvar_set("developer", ftos(dev));
 663     cvar_set("prvm_backtraceforwarnings", ftos(war));
 664 }
 665
 666 string Team_ColorCode(float teamid)
 667 {
 668     if (teamid == COLOR_TEAM1)
 669         return "^1";
 670     else if (teamid == COLOR_TEAM2)
 671         return "^4";
 672     else if (teamid == COLOR_TEAM3)
 673         return "^3";
 674     else if (teamid == COLOR_TEAM4)
 675         return "^6";
 676     else
 677         return "^7";
 678 }
 679
 680 string Team_ColorName(float t)
 681 {
 682     // fixme: Search for team entities and get their .netname's!
 683     if (t == COLOR_TEAM1)
 684         return "Red";
 685     if (t == COLOR_TEAM2)
 686         return "Blue";
 687     if (t == COLOR_TEAM3)
 688         return "Yellow";
 689     if (t == COLOR_TEAM4)
 690         return "Pink";
 691     return "Neutral";
 692 }
 693
 694 string Team_ColorNameLowerCase(float t)
 695 {
 696     // fixme: Search for team entities and get their .netname's!
 697     if (t == COLOR_TEAM1)
 698         return "red";
 699     if (t == COLOR_TEAM2)
 700         return "blue";
 701     if (t == COLOR_TEAM3)
 702         return "yellow";
 703     if (t == COLOR_TEAM4)
 704         return "pink";
 705     return "neutral";
 706 }
 707
 708 float ColourToNumber(string team_colour)
 709 {
 710         if (team_colour == "red")
 711                 return COLOR_TEAM1;
 712
 713         if (team_colour == "blue")
 714                 return COLOR_TEAM2;
 715
 716         if (team_colour == "yellow")
 717                 return COLOR_TEAM3;
 718
 719         if (team_colour == "pink")
 720                 return COLOR_TEAM4;
 721
 722         if (team_colour == "auto")
 723                 return 0;
 724
 725         return -1;
 726 }
 727
 728 float NumberToTeamNumber(float number)
 729 {
 730         if (number == 1)
 731                 return COLOR_TEAM1;
 732
 733         if (number == 2)
 734                 return COLOR_TEAM2;
 735
 736         if (number == 3)
 737                 return COLOR_TEAM3;
 738
 739         if (number == 4)
 740                 return COLOR_TEAM4;
 741
 742         return -1;
 743 }
 744
 745 #define CENTERPRIO_POINT 1
 746 #define CENTERPRIO_SPAM 2
 747 #define CENTERPRIO_VOTE 4
 748 #define CENTERPRIO_NORMAL 5
 749 #define CENTERPRIO_SHIELDING 7
 750 #define CENTERPRIO_MAPVOTE 9
 751 #define CENTERPRIO_IDLEKICK 50
 752 #define CENTERPRIO_ADMIN 99
 753 .float centerprint_priority;
 754 .float centerprint_expires;
 755 void centerprint_atprio(entity e, float prio, string s)
 756 {
 757     if (intermission_running)
 758         if (prio < CENTERPRIO_MAPVOTE)
 759             return;
 760     if (time > e.centerprint_expires)
 761         e.centerprint_priority = 0;
 762     if (prio >= e.centerprint_priority)
 763     {
 764         e.centerprint_priority = prio;
 765         if (timeoutStatus == 2)
 766             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 767         else
 768             e.centerprint_expires = time + e.cvar_scr_centertime;
 769         centerprint_builtin(e, s);
 770     }
 771 }
 772 void centerprint_expire(entity e, float prio)
 773 {
 774     if (prio == e.centerprint_priority)
 775     {
 776         e.centerprint_priority = 0;
 777         centerprint_builtin(e, "");
 778     }
 779 }
 780 void centerprint(entity e, string s)
 781 {
 782     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 783 }
 784
 785 // decolorizes and team colors the player name when needed
 786 string playername(entity p)
 787 {
 788     string t;
 789     if (teams_matter && !intermission_running && p.classname == "player")
 790     {
 791         t = Team_ColorCode(p.team);
 792         return strcat(t, strdecolorize(p.netname));
 793     }
 794     else
 795         return p.netname;
 796 }
 797
 798 vector randompos(vector m1, vector m2)
 799 {
 800     local vector v;
 801     m2 = m2 - m1;
 802     v_x = m2_x * random() + m1_x;
 803     v_y = m2_y * random() + m1_y;
 804     v_z = m2_z * random() + m1_z;
 805     return  v;
 806 };
 807
 808 float g_pickup_shells;
 809 float g_pickup_shells_max;
 810 float g_pickup_nails;
 811 float g_pickup_nails_max;
 812 float g_pickup_rockets;
 813 float g_pickup_rockets_max;
 814 float g_pickup_cells;
 815 float g_pickup_cells_max;
 816 float g_pickup_fuel;
 817 float g_pickup_fuel_jetpack;
 818 float g_pickup_fuel_max;
 819 float g_pickup_armorsmall;
 820 float g_pickup_armorsmall_max;
 821 float g_pickup_armorsmall_anyway;
 822 float g_pickup_armormedium;
 823 float g_pickup_armormedium_max;
 824 float g_pickup_armormedium_anyway;
 825 float g_pickup_armorbig;
 826 float g_pickup_armorbig_max;
 827 float g_pickup_armorbig_anyway;
 828 float g_pickup_armorlarge;
 829 float g_pickup_armorlarge_max;
 830 float g_pickup_armorlarge_anyway;
 831 float g_pickup_healthsmall;
 832 float g_pickup_healthsmall_max;
 833 float g_pickup_healthsmall_anyway;
 834 float g_pickup_healthmedium;
 835 float g_pickup_healthmedium_max;
 836 float g_pickup_healthmedium_anyway;
 837 float g_pickup_healthlarge;
 838 float g_pickup_healthlarge_max;
 839 float g_pickup_healthlarge_anyway;
 840 float g_pickup_healthmega;
 841 float g_pickup_healthmega_max;
 842 float g_pickup_healthmega_anyway;
 843 float g_pickup_ammo_anyway;
 844 float g_pickup_weapons_anyway;
 845 float g_weaponarena;
 846 float g_weaponarena_random;
 847 string g_weaponarena_list;
 848 float g_weaponspeedfactor;
 849 float g_weaponratefactor;
 850 float g_weapondamagefactor;
 851 float g_weaponforcefactor;
 852 float g_weaponspreadfactor;
 853
 854 float start_weapons;
 855 float start_items;
 856 float start_ammo_shells;
 857 float start_ammo_nails;
 858 float start_ammo_rockets;
 859 float start_ammo_cells;
 860 float start_ammo_fuel;
 861 float start_health;
 862 float start_armorvalue;
 863 float warmup_start_weapons;
 864 float warmup_start_ammo_shells;
 865 float warmup_start_ammo_nails;
 866 float warmup_start_ammo_rockets;
 867 float warmup_start_ammo_cells;
 868 float warmup_start_ammo_fuel;
 869 float warmup_start_health;
 870 float warmup_start_armorvalue;
 871 float g_weapon_stay;
 872 float g_ghost_items;
 873
 874 entity get_weaponinfo(float w);
 875
 876 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 877 {
 878         var float i = weaponinfo.weapon;
 879
 880         if (!i)
 881                 return 0;
 882
 883         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 884
 885         if (t < 0) // "default" weapon selection
 886         {
 887                 if (g_lms || g_ca || allguns)
 888                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 889                 else if(t < -1)
 890                         t = 0;
 891                 else if (g_race || g_cts)
 892                         t = (i == WEP_LASER);
 893                 else if (g_nexball)
 894                         t = 0; // weapon is set a few lines later
 895                 else
 896                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 897                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 898                         t |= (i == WEP_HOOK);
 899         }
 900
 901         // we cannot disable porto in Nexball, we must force it
 902         if(g_nexball && i == WEP_PORTO)
 903                 t = 1;
 904
 905         return t;
 906 }
 907
 908 void readplayerstartcvars()
 909 {
 910         entity e;
 911         float i, j, t;
 912         string s;
 913
 914         // initialize starting values for players
 915         start_weapons = 0;
 916         start_items = 0;
 917         start_ammo_shells = 0;
 918         start_ammo_nails = 0;
 919         start_ammo_rockets = 0;
 920         start_ammo_cells = 0;
 921         start_health = cvar("g_balance_health_start");
 922         start_armorvalue = cvar("g_balance_armor_start");
 923
 924         g_weaponarena = 0;
 925         s = cvar_string("g_weaponarena");
 926         if (s == "0")
 927         {
 928         }
 929         else if (s == "all")
 930         {
 931                 g_weaponarena_list = "All Weapons";
 932                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 933                 {
 934                         e = get_weaponinfo(j);
 935                         g_weaponarena |= e.weapons;
 936                         weapon_action(e.weapon, WR_PRECACHE);
 937                 }
 938         }
 939         else if (s == "most")
 940         {
 941                 g_weaponarena_list = "Most Weapons";
 942                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 943                 {
 944                         e = get_weaponinfo(j);
 945                         if (e.spawnflags & WEP_FLAG_NORMAL)
 946                         {
 947                                 g_weaponarena |= e.weapons;
 948                                 weapon_action(e.weapon, WR_PRECACHE);
 949                         }
 950                 }
 951         }
 952         else if (s == "none")
 953         {
 954                 g_weaponarena_list = "No Weapons";
 955                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 956         }
 957         else
 958         {
 959                 t = tokenize_console(s);
 960                 g_weaponarena_list = "";
 961                 for (i = 0; i < t; ++i)
 962                 {
 963                         s = argv(i);
 964                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 965                         {
 966                                 e = get_weaponinfo(j);
 967                                 if (e.netname == s)
 968                                 {
 969                                         g_weaponarena |= e.weapons;
 970                                         weapon_action(e.weapon, WR_PRECACHE);
 971                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 972                                         break;
 973                                 }
 974                         }
 975                         if (j > WEP_LAST)
 976                         {
 977                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 978                         }
 979                 }
 980                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 981         }
 982
 983         if(g_weaponarena)
 984                 g_weaponarena_random = cvar("g_weaponarena_random");
 985         else
 986                 g_weaponarena_random = 0;
 987
 988         if (g_weaponarena)
 989         {
 990                 start_weapons = g_weaponarena;
 991                 if (g_weaponarena & (WEPBIT_GRENADE_LAUNCHER | WEPBIT_MINE_LAYER | WEPBIT_HAGAR | WEPBIT_ROCKET_LAUNCHER))
 992                         start_ammo_rockets = 999;
 993                 if (g_weaponarena & WEPBIT_SHOTGUN)
 994                         start_ammo_shells = 999;
 995                 if (g_weaponarena & (WEPBIT_ELECTRO | WEPBIT_CRYLINK | WEPBIT_NEX | WEPBIT_MINSTANEX | WEPBIT_HLAC | WEPBIT_HOOK))
 996                         start_ammo_cells = 999;
 997                 if (g_weaponarena & (WEPBIT_UZI | WEPBIT_CAMPINGRIFLE))
 998                         start_ammo_nails = 999;
 999                 if (g_weaponarena & WEPBIT_HOOK)
1000                         start_ammo_fuel = 999;
1001                 start_items |= IT_UNLIMITED_AMMO;
1002         }
1003         else if (g_minstagib)
1004         {
1005                 start_health = 100;
1006                 start_armorvalue = 0;
1007                 start_weapons = WEPBIT_MINSTANEX;
1008                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1009                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1010                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1011                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1012
1013                 if (g_minstagib_invis_alpha <= 0)
1014                         g_minstagib_invis_alpha = -1;
1015         }
1016         else
1017         {
1018                 if (g_lms || g_ca)
1019                 {
1020                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1021                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1022                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1023                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1024                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1025                         start_health = cvar("g_lms_start_health");
1026                         start_armorvalue = cvar("g_lms_start_armor");
1027                 }
1028                 else
1029                 {
1030                         start_ammo_shells = cvar("g_start_ammo_shells");
1031                         start_ammo_nails = cvar("g_start_ammo_nails");
1032                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1033                         start_ammo_cells = cvar("g_start_ammo_cells");
1034                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1035                 }
1036
1037                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1038                 {
1039                         e = get_weaponinfo(i);
1040                         if(want_weapon("g_start_weapon_", e, FALSE))
1041                                 start_weapons |= e.weapons;
1042                 }
1043         }
1044
1045         if (inWarmupStage)
1046         {
1047                 warmup_start_ammo_shells = start_ammo_shells;
1048                 warmup_start_ammo_nails = start_ammo_nails;
1049                 warmup_start_ammo_rockets = start_ammo_rockets;
1050                 warmup_start_ammo_cells = start_ammo_cells;
1051                 warmup_start_ammo_fuel = start_ammo_fuel;
1052                 warmup_start_health = start_health;
1053                 warmup_start_armorvalue = start_armorvalue;
1054                 warmup_start_weapons = start_weapons;
1055
1056                 if (!g_weaponarena && !g_minstagib && !g_ca)
1057                 {
1058                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1059                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1060                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1061                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1062                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1063                         warmup_start_health = cvar("g_warmup_start_health");
1064                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1065                         warmup_start_weapons = 0;
1066                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1067                         {
1068                                 e = get_weaponinfo(i);
1069                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1070                                         warmup_start_weapons |= e.weapons;
1071                         }
1072                 }
1073         }
1074
1075         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1076         {
1077                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1078                 start_items |= IT_FUEL_REGEN;
1079                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1080                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1081         }
1082
1083         if(!cvar("g_use_ammunition"))
1084         {
1085                 start_ammo_shells = cvar("g_pickup_shells_max");
1086                 start_ammo_nails = cvar("g_pickup_nails_max");
1087                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1088                 start_ammo_cells = cvar("g_pickup_cells_max");
1089                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1090                 start_items |= IT_UNLIMITED_AMMO;
1091                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1092                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1093                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1094                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1095                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1096                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1097         }
1098
1099         if (g_jetpack)
1100                 start_items |= IT_JETPACK;
1101
1102         if (g_weapon_stay == 2)
1103         {
1104                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1105                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1106                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1107                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1108                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1109                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1110                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1111                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1112                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1113                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1114         }
1115
1116         MUTATOR_CALLHOOK(SetStartItems);
1117
1118         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1119         {
1120                 e = get_weaponinfo(i);
1121                 if(e.weapons & (start_weapons | warmup_start_weapons))
1122                         weapon_action(e.weapon, WR_PRECACHE);
1123         }
1124
1125         start_ammo_shells = max(0, start_ammo_shells);
1126         start_ammo_nails = max(0, start_ammo_nails);
1127         start_ammo_cells = max(0, start_ammo_cells);
1128         start_ammo_rockets = max(0, start_ammo_rockets);
1129         start_ammo_fuel = max(0, start_ammo_fuel);
1130
1131         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1132         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1133         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1134         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1135         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1136 }
1137
1138 float g_bugrigs;
1139 float g_bugrigs_planar_movement;
1140 float g_bugrigs_planar_movement_car_jumping;
1141 float g_bugrigs_reverse_spinning;
1142 float g_bugrigs_reverse_speeding;
1143 float g_bugrigs_reverse_stopping;
1144 float g_bugrigs_air_steering;
1145 float g_bugrigs_angle_smoothing;
1146 float g_bugrigs_friction_floor;
1147 float g_bugrigs_friction_brake;
1148 float g_bugrigs_friction_air;
1149 float g_bugrigs_accel;
1150 float g_bugrigs_speed_ref;
1151 float g_bugrigs_speed_pow;
1152 float g_bugrigs_steer;
1153
1154 float g_touchexplode;
1155 float g_touchexplode_radius;
1156 float g_touchexplode_damage;
1157 float g_touchexplode_edgedamage;
1158 float g_touchexplode_force;
1159
1160 float sv_autotaunt;
1161 float sv_taunt;
1162
1163 float sv_pitch_min;
1164 float sv_pitch_max;
1165 float sv_pitch_fixyaw;
1166
1167 float sv_accuracy_data_share;
1168
1169 void readlevelcvars(void)
1170 {
1171         // first load all the mutators
1172         if(cvar("g_nix"))
1173                 MUTATOR_ADD(mutator_nix);
1174         if(cvar("g_dodging"))
1175                 MUTATOR_ADD(mutator_dodging);
1176         if(cvar("g_rocket_flying") || (cvar("g_balance_rocketlauncher_detonatedelay") == 0 && stof(cvar_defstring("g_balance_rocketlauncher_detonatedelay")) != 0))
1177                 MUTATOR_ADD(mutator_rocketflying);
1178
1179     g_bugrigs = cvar("g_bugrigs");
1180     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1181     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1182     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1183     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1184     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1185     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1186     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1187     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1188     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1189     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1190     g_bugrigs_accel = cvar("g_bugrigs_accel");
1191     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1192     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1193     g_bugrigs_steer = cvar("g_bugrigs_steer");
1194
1195     g_touchexplode = cvar("g_touchexplode");
1196     g_touchexplode_radius = cvar("g_touchexplode_radius");
1197     g_touchexplode_damage = cvar("g_touchexplode_damage");
1198     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1199     g_touchexplode_force = cvar("g_touchexplode_force");
1200
1201 #ifdef ALLOW_FORCEMODELS
1202         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1203 #endif
1204         sv_loddistance1 = cvar("sv_loddistance1");
1205         sv_loddistance2 = cvar("sv_loddistance2");
1206
1207         if(sv_loddistance2 <= sv_loddistance1)
1208                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1209
1210         sv_clones = cvar("sv_clones");
1211         sv_gentle = cvar("sv_gentle");
1212         sv_foginterval = cvar("sv_foginterval");
1213         g_cloaked = cvar("g_cloaked");
1214         g_jump_grunt = cvar("g_jump_grunt");
1215         g_footsteps = cvar("g_footsteps");
1216         g_grappling_hook = cvar("g_grappling_hook");
1217         g_jetpack = cvar("g_jetpack");
1218         g_laserguided_missile = cvar("g_laserguided_missile");
1219         g_midair = cvar("g_midair");
1220         g_minstagib = cvar("g_minstagib");
1221         g_norecoil = cvar("g_norecoil");
1222         g_vampire = cvar("g_vampire");
1223         g_bloodloss = cvar("g_bloodloss");
1224         sv_maxidle = cvar("sv_maxidle");
1225         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1226         sv_pogostick = cvar("sv_pogostick");
1227         g_ctf_reverse = cvar("g_ctf_reverse");
1228         sv_autotaunt = cvar("sv_autotaunt");
1229         sv_taunt = cvar("sv_taunt");
1230
1231         inWarmupStage = cvar("g_warmup");
1232         g_warmup_limit = cvar("g_warmup_limit");
1233         g_warmup_allguns = cvar("g_warmup_allguns");
1234         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1235
1236         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1237                 inWarmupStage = 0; // these modes cannot work together, sorry
1238
1239         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1240         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1241         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1242         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1243         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1244         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1245         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1246         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1247         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1248         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1249         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1250         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1251
1252         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1253         g_weaponratefactor = cvar("g_weaponratefactor");
1254         g_weapondamagefactor = cvar("g_weapondamagefactor");
1255         g_weaponforcefactor = cvar("g_weaponforcefactor");
1256         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1257
1258         g_pickup_shells = cvar("g_pickup_shells");
1259         g_pickup_shells_max = cvar("g_pickup_shells_max");
1260         g_pickup_nails = cvar("g_pickup_nails");
1261         g_pickup_nails_max = cvar("g_pickup_nails_max");
1262         g_pickup_rockets = cvar("g_pickup_rockets");
1263         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1264         g_pickup_cells = cvar("g_pickup_cells");
1265         g_pickup_cells_max = cvar("g_pickup_cells_max");
1266         g_pickup_fuel = cvar("g_pickup_fuel");
1267         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1268         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1269         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1270         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1271         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1272         g_pickup_armormedium = cvar("g_pickup_armormedium");
1273         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1274         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1275         g_pickup_armorbig = cvar("g_pickup_armorbig");
1276         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1277         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1278         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1279         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1280         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1281         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1282         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1283         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1284         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1285         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1286         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1287         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1288         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1289         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1290         g_pickup_healthmega = cvar("g_pickup_healthmega");
1291         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1292         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1293
1294         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1295         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1296
1297         g_pinata = cvar("g_pinata");
1298
1299         g_weapon_stay = cvar("g_weapon_stay");
1300
1301         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1302                 g_weapon_stay = 1;
1303
1304         g_ghost_items = cvar("g_ghost_items");
1305
1306         if(g_ghost_items >= 1)
1307                 g_ghost_items = 0.25; // default alpha value
1308
1309         if not(inWarmupStage && !g_ca)
1310                 game_starttime = cvar("g_start_delay");
1311
1312         sv_pitch_min = cvar("sv_pitch_min");
1313         sv_pitch_max = cvar("sv_pitch_max");
1314         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1315
1316         sv_accuracy_data_share = boolean(cvar("sv_accuracy_data_share"));
1317
1318         readplayerstartcvars();
1319 }
1320
1321 /*
1322 // TODO sound pack system
1323 string soundpack;
1324
1325 string precache_sound_builtin (string s) = #19;
1326 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1327 string precache_sound(string s)
1328 {
1329         return precache_sound_builtin(strcat(soundpack, s));
1330 }
1331 void play2(entity e, string filename)
1332 {
1333         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1334 }
1335 void sound(entity e, float chan, string samp, float vol, float atten)
1336 {
1337         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1338 }
1339 */
1340
1341 // Sound functions
1342 string precache_sound (string s) = #19;
1343 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1344 float precache_sound_index (string s) = #19;
1345
1346 #define SND_VOLUME      1
1347 #define SND_ATTENUATION 2
1348 #define SND_LARGEENTITY 8
1349 #define SND_LARGESOUND  16
1350
1351 float sound_allowed(float dest, entity e)
1352 {
1353     // sounds from world may always pass
1354     for (;;)
1355     {
1356         if (e.classname == "body")
1357             e = e.enemy;
1358         if (e.owner && e.owner != e)
1359             e = e.owner;
1360         else
1361             break;
1362     }
1363     // sounds to self may always pass
1364     if (dest == MSG_ONE)
1365         if (e == msg_entity)
1366             return TRUE;
1367     // sounds by players can be removed
1368     if (cvar("bot_sound_monopoly"))
1369         if (clienttype(e) == CLIENTTYPE_REAL)
1370             return FALSE;
1371     // anything else may pass
1372     return TRUE;
1373 }
1374
1375 void sound(entity e, float chan, string samp, float vol, float atten)
1376 {
1377     if (!sound_allowed(MSG_BROADCAST, e))
1378         return;
1379     sound_builtin(e, chan, samp, vol, atten);
1380 }
1381 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1382 {
1383     float entno, idx;
1384
1385     if (!sound_allowed(dest, e))
1386         return;
1387
1388     entno = num_for_edict(e);
1389     idx = precache_sound_index(samp);
1390
1391     float sflags;
1392     sflags = 0;
1393
1394     atten = floor(atten * 64);
1395     vol = floor(vol * 255);
1396
1397     if (vol != 255)
1398         sflags |= SND_VOLUME;
1399     if (atten != 64)
1400         sflags |= SND_ATTENUATION;
1401     if (entno >= 8192)
1402         sflags |= SND_LARGEENTITY;
1403     if (idx >= 256)
1404         sflags |= SND_LARGESOUND;
1405
1406     WriteByte(dest, SVC_SOUND);
1407     WriteByte(dest, sflags);
1408     if (sflags & SND_VOLUME)
1409         WriteByte(dest, vol);
1410     if (sflags & SND_ATTENUATION)
1411         WriteByte(dest, atten);
1412     if (sflags & SND_LARGEENTITY)
1413     {
1414         WriteShort(dest, entno);
1415         WriteByte(dest, chan);
1416     }
1417     else
1418     {
1419         WriteShort(dest, entno * 8 + chan);
1420     }
1421     if (sflags & SND_LARGESOUND)
1422         WriteShort(dest, idx);
1423     else
1424         WriteByte(dest, idx);
1425
1426     WriteCoord(dest, o_x);
1427     WriteCoord(dest, o_y);
1428     WriteCoord(dest, o_z);
1429 }
1430 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1431 {
1432     vector o;
1433
1434     if (!sound_allowed(dest, e))
1435         return;
1436
1437     o = e.origin + 0.5 * (e.mins + e.maxs);
1438     soundtoat(dest, e, o, chan, samp, vol, atten);
1439 }
1440 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1441 {
1442     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1443 }
1444 void stopsoundto(float dest, entity e, float chan)
1445 {
1446     float entno;
1447
1448     if (!sound_allowed(dest, e))
1449         return;
1450
1451     entno = num_for_edict(e);
1452
1453     if (entno >= 8192)
1454     {
1455         float idx, sflags;
1456         idx = precache_sound_index("misc/null.wav");
1457         sflags = SND_LARGEENTITY;
1458         if (idx >= 256)
1459             sflags |= SND_LARGESOUND;
1460         WriteByte(dest, SVC_SOUND);
1461         WriteByte(dest, sflags);
1462         WriteShort(dest, entno);
1463         WriteByte(dest, chan);
1464         if (sflags & SND_LARGESOUND)
1465             WriteShort(dest, idx);
1466         else
1467             WriteByte(dest, idx);
1468         WriteCoord(dest, e.origin_x);
1469         WriteCoord(dest, e.origin_y);
1470         WriteCoord(dest, e.origin_z);
1471     }
1472     else
1473     {
1474         WriteByte(dest, SVC_STOPSOUND);
1475         WriteShort(dest, entno * 8 + chan);
1476     }
1477 }
1478 void stopsound(entity e, float chan)
1479 {
1480     if (!sound_allowed(MSG_BROADCAST, e))
1481         return;
1482
1483     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1484     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1485 }
1486
1487 void play2(entity e, string filename)
1488 {
1489     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1490     msg_entity = e;
1491     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1492 }
1493
1494 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1495 .float spamtime;
1496 float spamsound(entity e, float chan, string samp, float vol, float atten)
1497 {
1498     if (!sound_allowed(MSG_BROADCAST, e))
1499         return FALSE;
1500
1501     if (time > e.spamtime)
1502     {
1503         e.spamtime = time;
1504         sound(e, chan, samp, vol, atten);
1505         return TRUE;
1506     }
1507     return FALSE;
1508 }
1509
1510 void play2team(float t, string filename)
1511 {
1512     local entity head;
1513
1514     if (cvar("bot_sound_monopoly"))
1515         return;
1516
1517     FOR_EACH_REALPLAYER(head)
1518     {
1519         if (head.team == t)
1520             play2(head, filename);
1521     }
1522 }
1523
1524 void play2all(string samp)
1525 {
1526     if (cvar("bot_sound_monopoly"))
1527         return;
1528
1529     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1530 }
1531
1532 void PrecachePlayerSounds(string f);
1533 void precache_playermodel(string m)
1534 {
1535         float globhandle, i, n;
1536         string f;
1537
1538         if(substring(m, -9,5) == "_lod1")
1539                 return;
1540         if(substring(m, -9,5) == "_lod2")
1541                 return;
1542         precache_model(m);
1543         if(sv_loddistance1)
1544         {
1545                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1546                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1547         }
1548
1549         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1550         if (globhandle < 0)
1551                 return;
1552         n = search_getsize(globhandle);
1553         for (i = 0; i < n; ++i)
1554         {
1555                 //print(search_getfilename(globhandle, i), "\n");
1556                 f = search_getfilename(globhandle, i);
1557                 PrecachePlayerSounds(f);
1558         }
1559         search_end(globhandle);
1560 }
1561 void precache_all_playermodels(string pattern)
1562 {
1563         float globhandle, i, n;
1564         string f;
1565
1566         globhandle = search_begin(pattern, TRUE, FALSE);
1567         if (globhandle < 0)
1568                 return;
1569         n = search_getsize(globhandle);
1570         for (i = 0; i < n; ++i)
1571         {
1572                 //print(search_getfilename(globhandle, i), "\n");
1573                 f = search_getfilename(globhandle, i);
1574                 precache_playermodel(f);
1575         }
1576         search_end(globhandle);
1577 }
1578
1579 void precache()
1580 {
1581     // gamemode related things
1582     precache_model ("models/misc/chatbubble.spr");
1583     precache_model ("models/misc/teambubble.spr");
1584     if (g_runematch)
1585     {
1586         precache_model ("models/runematch/curse.mdl");
1587         precache_model ("models/runematch/rune.mdl");
1588     }
1589
1590 #ifdef TTURRETS_ENABLED
1591     if (cvar("g_turrets"))
1592         turrets_precash();
1593 #endif
1594
1595     // Precache all player models if desired
1596     if (cvar("sv_precacheplayermodels"))
1597     {
1598         PrecachePlayerSounds("sound/player/default.sounds");
1599         precache_all_playermodels("models/player/*.zym");
1600         precache_all_playermodels("models/player/*.dpm");
1601         precache_all_playermodels("models/player/*.md3");
1602         precache_all_playermodels("models/player/*.psk");
1603         precache_all_playermodels("models/player/*.iqm");
1604     }
1605
1606     if (cvar("sv_defaultcharacter"))
1607     {
1608         string s;
1609         s = cvar_string("sv_defaultplayermodel_red");
1610         if (s != "")
1611             precache_playermodel(s);
1612         s = cvar_string("sv_defaultplayermodel_blue");
1613         if (s != "")
1614             precache_playermodel(s);
1615         s = cvar_string("sv_defaultplayermodel_yellow");
1616         if (s != "")
1617             precache_playermodel(s);
1618         s = cvar_string("sv_defaultplayermodel_pink");
1619         if (s != "")
1620             precache_playermodel(s);
1621         s = cvar_string("sv_defaultplayermodel");
1622         if (s != "")
1623             precache_playermodel(s);
1624     }
1625
1626     if (g_footsteps)
1627     {
1628         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1629         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1630     }
1631
1632     // gore and miscellaneous sounds
1633     //precache_sound ("misc/h2ohit.wav");
1634     precache_model ("models/hook.md3");
1635     precache_sound ("misc/armorimpact.wav");
1636     precache_sound ("misc/bodyimpact1.wav");
1637     precache_sound ("misc/bodyimpact2.wav");
1638     precache_sound ("misc/gib.wav");
1639     precache_sound ("misc/gib_splat01.wav");
1640     precache_sound ("misc/gib_splat02.wav");
1641     precache_sound ("misc/gib_splat03.wav");
1642     precache_sound ("misc/gib_splat04.wav");
1643     precache_sound ("misc/hit.wav");
1644         precache_sound ("misc/typehit.wav");
1645     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1646     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1647     precache_sound ("misc/null.wav");
1648     precache_sound ("misc/spawn.wav");
1649     precache_sound ("misc/talk.wav");
1650     precache_sound ("misc/teleport.wav");
1651     precache_sound ("misc/poweroff.wav");
1652     precache_sound ("player/lava.wav");
1653     precache_sound ("player/slime.wav");
1654
1655     if (g_jetpack)
1656         precache_sound ("misc/jetpack_fly.wav");
1657
1658     precache_model ("models/sprites/0.spr32");
1659     precache_model ("models/sprites/1.spr32");
1660     precache_model ("models/sprites/2.spr32");
1661     precache_model ("models/sprites/3.spr32");
1662     precache_model ("models/sprites/4.spr32");
1663     precache_model ("models/sprites/5.spr32");
1664     precache_model ("models/sprites/6.spr32");
1665     precache_model ("models/sprites/7.spr32");
1666     precache_model ("models/sprites/8.spr32");
1667     precache_model ("models/sprites/9.spr32");
1668     precache_model ("models/sprites/10.spr32");
1669
1670     // common weapon precaches
1671     precache_sound ("weapons/weapon_switch.wav");
1672     precache_sound ("weapons/weaponpickup.wav");
1673     precache_sound ("weapons/unavailable.wav");
1674     precache_sound ("weapons/dryfire.wav");
1675     if (g_grappling_hook)
1676     {
1677         precache_sound ("weapons/hook_fire.wav"); // hook
1678         precache_sound ("weapons/hook_impact.wav"); // hook
1679     }
1680
1681     if(cvar("sv_precacheweapons"))
1682     {
1683         //precache weapon models/sounds
1684         local float wep;
1685         wep = WEP_FIRST;
1686         while (wep <= WEP_LAST)
1687         {
1688             weapon_action(wep, WR_PRECACHE);
1689             wep = wep + 1;
1690         }
1691     }
1692
1693     precache_model("models/elaser.mdl");
1694     precache_model("models/laser.mdl");
1695     precache_model("models/ebomb.mdl");
1696
1697 #if 0
1698     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1699
1700     if (!self.noise && self.music) // quake 3 uses the music field
1701         self.noise = self.music;
1702
1703     // plays music for the level if there is any
1704     if (self.noise)
1705     {
1706         precache_sound (self.noise);
1707         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1708     }
1709 #endif
1710 }
1711
1712 // sorry, but using \ in macros breaks line numbers
1713 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1714 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1715 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1716
1717 // WARNING: this kills the trace globals
1718 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1719 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1720
1721 #define INITPRIO_FIRST              0
1722 #define INITPRIO_GAMETYPE           0
1723 #define INITPRIO_GAMETYPE_FALLBACK  1
1724 #define INITPRIO_CVARS              5
1725 #define INITPRIO_FINDTARGET        10
1726 #define INITPRIO_DROPTOFLOOR       20
1727 #define INITPRIO_SETLOCATION       90
1728 #define INITPRIO_LINKDOORS         91
1729 #define INITPRIO_LAST              99
1730
1731 .void(void) initialize_entity;
1732 .float initialize_entity_order;
1733 .entity initialize_entity_next;
1734 entity initialize_entity_first;
1735
1736 void make_safe_for_remove(entity e)
1737 {
1738     if (e.initialize_entity)
1739     {
1740         entity ent, prev;
1741         for (ent = initialize_entity_first; ent; )
1742         {
1743             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1744             {
1745                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1746                 // skip it in linked list
1747                 if (prev)
1748                 {
1749                     prev.initialize_entity_next = ent.initialize_entity_next;
1750                     ent = prev.initialize_entity_next;
1751                 }
1752                 else
1753                 {
1754                     initialize_entity_first = ent.initialize_entity_next;
1755                     ent = initialize_entity_first;
1756                 }
1757             }
1758             else
1759             {
1760                 prev = ent;
1761                 ent = ent.initialize_entity_next;
1762             }
1763         }
1764     }
1765 }
1766
1767 void objerror(string s)
1768 {
1769     make_safe_for_remove(self);
1770     objerror_builtin(s);
1771 }
1772
1773 void remove_unsafely(entity e)
1774 {
1775     remove_builtin(e);
1776 }
1777
1778 void remove_safely(entity e)
1779 {
1780     make_safe_for_remove(e);
1781     remove_builtin(e);
1782 }
1783
1784 void InitializeEntity(entity e, void(void) func, float order)
1785 {
1786     entity prev, cur;
1787
1788     if (!e || e.initialize_entity)
1789     {
1790         // make a proxy initializer entity
1791         entity e_old;
1792         e_old = e;
1793         e = spawn();
1794         e.classname = "initialize_entity";
1795         e.enemy = e_old;
1796     }
1797
1798     e.initialize_entity = func;
1799     e.initialize_entity_order = order;
1800
1801     cur = initialize_entity_first;
1802     for (;;)
1803     {
1804         if (!cur || cur.initialize_entity_order > order)
1805         {
1806             // insert between prev and cur
1807             if (prev)
1808                 prev.initialize_entity_next = e;
1809             else
1810                 initialize_entity_first = e;
1811             e.initialize_entity_next = cur;
1812             return;
1813         }
1814         prev = cur;
1815         cur = cur.initialize_entity_next;
1816     }
1817 }
1818 void InitializeEntitiesRun()
1819 {
1820     entity startoflist;
1821     startoflist = initialize_entity_first;
1822     initialize_entity_first = world;
1823     for (self = startoflist; self; )
1824     {
1825         entity e;
1826         var void(void) func;
1827         e = self.initialize_entity_next;
1828         func = self.initialize_entity;
1829         self.initialize_entity_order = 0;
1830         self.initialize_entity = func_null;
1831         self.initialize_entity_next = world;
1832         if (self.classname == "initialize_entity")
1833         {
1834             entity e_old;
1835             e_old = self.enemy;
1836             remove_builtin(self);
1837             self = e_old;
1838         }
1839         //dprint("Delayed initialization: ", self.classname, "\n");
1840         func();
1841         self = e;
1842     }
1843 }
1844
1845 .float uncustomizeentityforclient_set;
1846 .void(void) uncustomizeentityforclient;
1847 void(void) SUB_Nullpointer = #0;
1848 void UncustomizeEntitiesRun()
1849 {
1850     entity oldself;
1851     oldself = self;
1852     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1853         self.uncustomizeentityforclient();
1854     self = oldself;
1855 }
1856 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1857 {
1858     e.customizeentityforclient = customizer;
1859     e.uncustomizeentityforclient = uncustomizer;
1860     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1861 }
1862
1863 .float nottargeted;
1864 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1865
1866 void() SUB_Remove;
1867 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1868 {
1869     vector mi, ma;
1870
1871     if (e.classname == "")
1872         e.classname = "net_linked";
1873
1874     if (e.model == "" || self.modelindex == 0)
1875     {
1876         mi = e.mins;
1877         ma = e.maxs;
1878         setmodel(e, "null");
1879         setsize(e, mi, ma);
1880     }
1881
1882     e.SendEntity = sendfunc;
1883     e.SendFlags = 0xFFFFFF;
1884
1885     if (!docull)
1886         e.effects |= EF_NODEPTHTEST;
1887
1888     if (dt)
1889     {
1890         e.nextthink = time + dt;
1891         e.think = SUB_Remove;
1892     }
1893 }
1894
1895 void adaptor_think2touch()
1896 {
1897     entity o;
1898     o = other;
1899     other = world;
1900     self.touch();
1901     other = o;
1902 }
1903
1904 void adaptor_think2use()
1905 {
1906     entity o, a;
1907     o = other;
1908     a = activator;
1909     activator = world;
1910     other = world;
1911     self.use();
1912     other = o;
1913     activator = a;
1914 }
1915
1916 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1917 {
1918         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1919                 self.projectiledeathtype |= HITTYPE_SPLASH;
1920         adaptor_think2use();
1921 }
1922
1923 // deferred dropping
1924 void DropToFloor_Handler()
1925 {
1926     droptofloor_builtin();
1927     self.dropped_origin = self.origin;
1928 }
1929
1930 void droptofloor()
1931 {
1932     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1933 }
1934
1935
1936
1937 float trace_hits_box_a0, trace_hits_box_a1;
1938
1939 float trace_hits_box_1d(float end, float thmi, float thma)
1940 {
1941     if (end == 0)
1942     {
1943         // just check if x is in range
1944         if (0 < thmi)
1945             return FALSE;
1946         if (0 > thma)
1947             return FALSE;
1948     }
1949     else
1950     {
1951         // do the trace with respect to x
1952         // 0 -> end has to stay in thmi -> thma
1953         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1954         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1955         if (trace_hits_box_a0 > trace_hits_box_a1)
1956             return FALSE;
1957     }
1958     return TRUE;
1959 }
1960
1961 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1962 {
1963     end -= start;
1964     thmi -= start;
1965     thma -= start;
1966     // now it is a trace from 0 to end
1967
1968     trace_hits_box_a0 = 0;
1969     trace_hits_box_a1 = 1;
1970
1971     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1972         return FALSE;
1973     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1974         return FALSE;
1975     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1976         return FALSE;
1977
1978     return TRUE;
1979 }
1980
1981 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1982 {
1983     return trace_hits_box(start, end, thmi - ma, thma - mi);
1984 }
1985
1986 float SUB_NoImpactCheck()
1987 {
1988         // zero hitcontents = this is not the real impact, but either the
1989         // mirror-impact of something hitting the projectile instead of the
1990         // projectile hitting the something, or a touchareagrid one. Neither of
1991         // these stop the projectile from moving, so...
1992         if(trace_dphitcontents == 0)
1993         {
1994                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1995                 checkclient();
1996         }
1997     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1998         return 1;
1999     if (other == world && self.size != '0 0 0')
2000     {
2001         vector tic;
2002         tic = self.velocity * sys_frametime;
2003         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2004         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2005         if (trace_fraction >= 1)
2006         {
2007             dprint("Odd... did not hit...?\n");
2008         }
2009         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2010         {
2011             dprint("Detected and prevented the sky-grapple bug.\n");
2012             return 1;
2013         }
2014     }
2015
2016     return 0;
2017 }
2018
2019 #define SUB_OwnerCheck() (other && (other == self.owner))
2020
2021 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2022 {
2023         if(SUB_OwnerCheck())
2024                 return TRUE;
2025         if(SUB_NoImpactCheck())
2026         {
2027                 remove(self);
2028                 return TRUE;
2029         }
2030         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2031                 UpdateCSQCProjectileNextFrame(self);
2032         return FALSE;
2033 }
2034 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2035
2036 float MAX_IPBAN_URIS = 16;
2037
2038 float URI_GET_DISCARD   = 0;
2039 float URI_GET_IPBAN     = 1;
2040 float URI_GET_IPBAN_END = 16;
2041
2042 void URI_Get_Callback(float id, float status, string data)
2043 {
2044     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2045     dprint(data);
2046     dprint("\nEnd of data.\n");
2047
2048     if (id == URI_GET_DISCARD)
2049     {
2050         // discard
2051     }
2052     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2053     {
2054         // online ban list
2055         OnlineBanList_URI_Get_Callback(id, status, data);
2056     }
2057     else
2058     {
2059         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2060     }
2061 }
2062
2063 void print_to(entity e, string s)
2064 {
2065     if (e)
2066         sprint(e, strcat(s, "\n"));
2067     else
2068         print(s, "\n");
2069 }
2070
2071 string uid2name(string myuid) {
2072         // TODO TODO TODO!
2073         // store uid in separate uid2name db IF CLIENT ALLOWS THIS
2074         // - make it global for all mods
2075         // perhaps show 10 first digits here if missing name?
2076         string s;
2077         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2078
2079         if(s == "")
2080                 s = "^1Unregistered Player";
2081         return s;
2082 }
2083
2084 float race_GetTime(string map, float pos)
2085 {
2086         float rr;
2087         if(g_cts)
2088                 rr = CTS_RECORD;
2089         else
2090                 rr = RACE_RECORD;
2091
2092         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2093 }
2094
2095 string race_GetUID(string map, float pos)
2096 {
2097         float rr;
2098         if(g_cts)
2099                 rr = CTS_RECORD;
2100         else
2101                 rr = RACE_RECORD;
2102
2103         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2104 }
2105
2106 string race_GetName(string map, float pos)
2107 {
2108         float rr;
2109         if(g_cts)
2110                 rr = CTS_RECORD;
2111         else
2112                 rr = RACE_RECORD;
2113
2114         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2115 }
2116
2117 string race_PlaceName(float pos) {
2118         if(pos < 10 || pos > 20)
2119         {
2120                 if(pos % 10 == 1)
2121                         return strcat(ftos(pos), "st");
2122                 else if(pos % 10 == 2)
2123                         return strcat(ftos(pos), "nd");
2124                 else if(pos % 10 == 3)
2125                         return strcat(ftos(pos), "rd");
2126                 else
2127                         return strcat(ftos(pos), "th");
2128         }
2129         else
2130                 return strcat(ftos(pos), "th");
2131 }
2132 string getrecords(float page) // 50 records per page
2133 {
2134     float rec;
2135     string h;
2136     float r;
2137     float i;
2138     string s;
2139
2140     rec = 0;
2141
2142     s = "";
2143
2144     if (g_ctf)
2145     {
2146         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2147         {
2148             if (MapInfo_Get_ByID(i))
2149             {
2150                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2151                 if (r == 0)
2152                     continue;
2153                 // TODO: uid2name
2154                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2155                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2156                 ++rec;
2157             }
2158         }
2159     }
2160
2161     if (g_race)
2162     {
2163         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2164         {
2165             if (MapInfo_Get_ByID(i))
2166             {
2167                 r = race_GetTime(MapInfo_Map_bspname, 1);
2168                 if (r == 0)
2169                     continue;
2170                 h = race_GetName(MapInfo_Map_bspname, 1)
2171                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2172                 ++rec;
2173             }
2174         }
2175     }
2176
2177     if (g_cts)
2178     {
2179         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2180         {
2181             if (MapInfo_Get_ByID(i))
2182             {
2183                 r = race_GetTime(MapInfo_Map_bspname, 1);
2184                 if (r == 0)
2185                     continue;
2186                 h = race_GetName(MapInfo_Map_bspname, 1)
2187                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2188                 ++rec;
2189             }
2190         }
2191     }
2192
2193     MapInfo_ClearTemps();
2194
2195     if (s == "" && page == 0)
2196         return "No records are available on this server.\n";
2197     else
2198         return s;
2199 }
2200
2201 string getrankings()
2202 {
2203     string n;
2204     float t;
2205     float i;
2206     string s;
2207     string p;
2208     string map;
2209
2210     s = "";
2211
2212     map = GetMapname();
2213
2214     for (i = 1; i <= RANKINGS_CNT; ++i)
2215     {
2216         t = race_GetTime(map, i);
2217         if (t == 0)
2218             continue;
2219         n = race_GetName(map, i);
2220         p = race_PlaceName(i);
2221         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2222     }
2223
2224     MapInfo_ClearTemps();
2225
2226     if (s == "")
2227         return strcat("No records are available for the map: ", map, "\n");
2228     else
2229         return strcat("Records for ", map, ":\n", s);
2230 }
2231
2232 const float LADDER_FIRSTPOINT = 100;
2233 const float LADDER_CNT = 10; // position X still gives LADDER_FIRSTPOINT/X points
2234 const float LADDER_SIZE = 30; // ladder shows the top X players
2235 string top_uids[LADDER_SIZE];
2236 float top_scores[LADDER_SIZE];
2237 float UIDCNT;
2238 string getladder()
2239 {
2240     float i, j, k;
2241     string s, len, temp_s;
2242
2243     s = "";
2244     temp_s = "";
2245
2246     string myuid;
2247
2248     for (k = 0; k < MapInfo_count; ++k)
2249     {
2250         if (MapInfo_Get_ByID(k))
2251         {
2252                 for (i = 0; i < LADDER_CNT; ++i) {
2253                         if(stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time", ftos(Ii)))) == 0)
2254                             break;
2255
2256                         myuid = db_get(ServerProgsDB, strcat(GetMapname(), rr, "crypto_idfp", ftos(i)));
2257
2258                         // string s contains:
2259                         // arg 0 = # of speed recs
2260                         // arg 1 = # of 1st place recs
2261                         // arg 2 = # of 2nd place recs
2262                         // ... etc
2263                         // LADDER_CNT+1 = total points
2264
2265                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2266                         if (temp_s == "")
2267                         {
2268                             db_put(TemporaryDB, strcat("uid", ftos(UIDCNT)), myuid);
2269                             ++UIDCNT;
2270                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2271                             {
2272                                 if(j != LADDER_CNT + 1)
2273                                     temp_s = strcat(temp_s, "0 ");
2274                                 else
2275                                     temp_s = strcat(temp_s, "0");
2276                             }
2277                         }
2278
2279                         len = tokenize_console(temp_s);
2280                         s = "";
2281
2282                         if(i == 0) // speedrec
2283                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2284                             {
2285                                 if(j == 0) // speed rec!
2286                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2287                                 else
2288                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2289                             }
2290                         else // record
2291                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2292                             {
2293                                 if(j == 0)
2294                                     s = strcat(s, argv(j)); // speed rec, dont prefix with " "
2295                                 else if(j == i) // wanted rec!
2296                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2297                                 else
2298                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2299                             }
2300
2301                         // total points are (by default) calculated like this:
2302                         // speedrec = floor(100 / 10) = 10 points
2303                         // 1st place = floor(100 / 1) = 100 points
2304                         // 2nd place = floor(100 / 2) = 50 points
2305                         // 3rd place = floor(100 / 3) = 33 points
2306                         // 4th place = floor(100 / 4) = 25 points
2307                         // 5th place = floor(100 / 5) = 20 points
2308                         // ... etc
2309
2310                         if(i == 0)
2311                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speedrec, add LADDER_FIRSTPOINT / 10 points
2312                         else
2313                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2314
2315                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2316                 }
2317             }
2318         }
2319     }
2320
2321     float thiscnt;
2322     string thisuid;
2323     for (i = 0; i <= UIDCNT; ++i) // for each known uid
2324     {
2325         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2326         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2327         len = tokenize_console(temp_s);
2328         thiscnt = stof(argv(LADDER_CNT+1));
2329
2330         if(thiscnt > top_scores[LADDER_SIZE-1])
2331         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2332         {
2333             if(thiscnt > top_scores[j])
2334             {
2335                 for (k = LADDER_SIZE-1; k >= j; --k)
2336                 {
2337                     top_uids[k] = top_uids[k-1];
2338                     top_scores[k] = top_scores[k-1];
2339                 }
2340                 top_uids[j] = thisuid;
2341                 top_scores[j] = thiscnt;
2342                 break;
2343             }
2344         }
2345     }
2346
2347     s = "^3-----------------------\n\n";
2348
2349     s = strcat(s, "Pos ^3|");
2350     s = strcat(s, " ^7Total  ^3|");
2351     for (i = 1; i <= LADDER_CNT; ++i)
2352     {
2353         s = strcat(s, " ^7", race_PlaceName(i), " ^3|");
2354     }
2355     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2356
2357     s = strcat(s, "\n^3----+--------");
2358     for (i = 1; i <= LADDER_CNT; ++i)
2359     {
2360         s = strcat(s, "+-----");
2361     }
2362     s = strcat(s, "+--------------+--------------------\n");
2363
2364     for (i = 0; i < LADDER_SIZE; ++i)
2365     {
2366         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2367         len = tokenize_console(temp_s);
2368         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2369             continue;
2370         s = strcat(s, strpad(4, race_PlaceName(i+1)), "^3| ^7"); // pos
2371         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2372         for (j = 1; j <= LADDER_CNT; ++j)
2373         {
2374             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2375         }
2376         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed rec cnt
2377         s = strcat(s, race_GetName_OfUID(top_uids[i]), "\n"); // name
2378     }
2379
2380     MapInfo_ClearTemps();
2381
2382     if (s == "")
2383         return "No ladder on this server!\n";
2384     else
2385         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2386 }
2387
2388
2389 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2390 {
2391     float m, i;
2392     vector start, org, delta, end, enddown, mstart;
2393
2394     m = e.dphitcontentsmask;
2395     e.dphitcontentsmask = goodcontents | badcontents;
2396
2397     org = world.mins;
2398     delta = world.maxs - world.mins;
2399
2400     for (i = 0; i < attempts; ++i)
2401     {
2402         start_x = org_x + random() * delta_x;
2403         start_y = org_y + random() * delta_y;
2404         start_z = org_z + random() * delta_z;
2405
2406         // rule 1: start inside world bounds, and outside
2407         // solid, and don't start from somewhere where you can
2408         // fall down to evil
2409         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2410         if (trace_fraction >= 1)
2411             continue;
2412         if (trace_startsolid)
2413             continue;
2414         if (trace_dphitcontents & badcontents)
2415             continue;
2416         if (trace_dphitq3surfaceflags & badsurfaceflags)
2417             continue;
2418
2419         // rule 2: if we are too high, lower the point
2420         if (trace_fraction * delta_z > maxaboveground)
2421             start = trace_endpos + '0 0 1' * maxaboveground;
2422         enddown = trace_endpos;
2423
2424         // rule 3: make sure we aren't outside the map. This only works
2425         // for somewhat well formed maps. A good rule of thumb is that
2426         // the map should have a convex outside hull.
2427         // these can be traceLINES as we already verified the starting box
2428         mstart = start + 0.5 * (e.mins + e.maxs);
2429         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2430         if (trace_fraction >= 1)
2431             continue;
2432         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2433         if (trace_fraction >= 1)
2434             continue;
2435         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2436         if (trace_fraction >= 1)
2437             continue;
2438         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2439         if (trace_fraction >= 1)
2440             continue;
2441         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2442         if (trace_fraction >= 1)
2443             continue;
2444
2445         // find a random vector to "look at"
2446         end_x = org_x + random() * delta_x;
2447         end_y = org_y + random() * delta_y;
2448         end_z = org_z + random() * delta_z;
2449         end = start + normalize(end - start) * vlen(delta);
2450
2451         // rule 4: start TO end must not be too short
2452         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2453         if (trace_startsolid)
2454             continue;
2455         if (trace_fraction < minviewdistance / vlen(delta))
2456             continue;
2457
2458         // rule 5: don't want to look at sky
2459         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2460             continue;
2461
2462         // rule 6: we must not end up in trigger_hurt
2463         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2464         {
2465             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2466             continue;
2467         }
2468
2469         break;
2470     }
2471
2472     e.dphitcontentsmask = m;
2473
2474     if (i < attempts)
2475     {
2476         setorigin(e, start);
2477         e.angles = vectoangles(end - start);
2478         dprint("Needed ", ftos(i + 1), " attempts\n");
2479         return TRUE;
2480     }
2481     else
2482         return FALSE;
2483 }
2484
2485 float zcurveparticles_effectno;
2486 vector zcurveparticles_start;
2487 float zcurveparticles_spd;
2488
2489 void endzcurveparticles()
2490 {
2491         if(zcurveparticles_effectno)
2492         {
2493                 // terminator
2494                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2495         }
2496         zcurveparticles_effectno = 0;
2497 }
2498
2499 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2500 {
2501         spd = bound(0, floor(spd / 16), 32767);
2502         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2503         {
2504                 endzcurveparticles();
2505                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2506                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2507                 WriteShort(MSG_BROADCAST, effectno);
2508                 WriteCoord(MSG_BROADCAST, start_x);
2509                 WriteCoord(MSG_BROADCAST, start_y);
2510                 WriteCoord(MSG_BROADCAST, start_z);
2511                 zcurveparticles_effectno = effectno;
2512                 zcurveparticles_start = start;
2513         }
2514         else
2515                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2516         WriteCoord(MSG_BROADCAST, end_x);
2517         WriteCoord(MSG_BROADCAST, end_y);
2518         WriteCoord(MSG_BROADCAST, end_z);
2519         WriteCoord(MSG_BROADCAST, end_dz);
2520         zcurveparticles_spd = spd;
2521 }
2522
2523 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2524 {
2525         float end_dz;
2526         vector vecxy, velxy;
2527
2528         vecxy = end - start;
2529         vecxy_z = 0;
2530         velxy = vel;
2531         velxy_z = 0;
2532
2533         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2534         {
2535                 endzcurveparticles();
2536                 trailparticles(world, effectno, start, end);
2537                 return;
2538         }
2539
2540         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2541         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2542 }
2543
2544 string GetGametype(); // g_world.qc
2545 void write_recordmarker(entity pl, float tstart, float dt)
2546 {
2547     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2548
2549     // also write a marker into demo files for demotc-race-record-extractor to find
2550     stuffcmd(pl,
2551              strcat(
2552                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2553                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2554 }
2555
2556 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2557 {
2558         switch(algn)
2559         {
2560                 case 1: // right
2561                         break;
2562
2563                 case 2: // left
2564                         vecs_y = -vecs_y;
2565                         break;
2566
2567                 default:
2568                 case 3:
2569                         if(allowcenter) // 2: allow center handedness
2570                         {
2571                                 // center
2572                                 vecs_y = 0;
2573                                 vecs_z -= 2;
2574                         }
2575                         else
2576                         {
2577                                 // right
2578                         }
2579                         break;
2580
2581                 case 4:
2582                         if(allowcenter) // 2: allow center handedness
2583                         {
2584                                 // center
2585                                 vecs_y = 0;
2586                                 vecs_z -= 2;
2587                         }
2588                         else
2589                         {
2590                                 // left
2591                                 vecs_y = -vecs_y;
2592                         }
2593                         break;
2594         }
2595         return vecs;
2596 }
2597
2598 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2599 {
2600         string s;
2601         vector v;
2602
2603         if (cvar("g_shootfromeye"))
2604         {
2605                 if (visual)
2606                 {
2607                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2608                 }
2609                 else
2610                 {
2611                         vecs_y = 0;
2612                         vecs_z = 0;
2613                 }
2614         }
2615         else if (cvar("g_shootfromcenter"))
2616         {
2617                 if (visual)
2618                 {
2619                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2620                 }
2621                 else
2622                 {
2623                         vecs_y = 0;
2624                         vecs_z -= 2;
2625                 }
2626         }
2627         else if ((s = cvar_string("g_shootfromfixedorigin")) != "")
2628         {
2629                 v = stov(s);
2630                 if (y_is_right)
2631                         v_y = -v_y;
2632                 if (v_x != 0)
2633                         vecs_x = v_x;
2634                 vecs_y = v_y;
2635                 vecs_z = v_z;
2636         }
2637         else if (cvar("g_shootfromclient"))
2638         {
2639                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (cvar("g_shootfromclient") >= 2), algn);
2640         }
2641         return vecs;
2642 }
2643
2644 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2645 {
2646         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2647 }
2648
2649
2650 void attach_sameorigin(entity e, entity to, string tag)
2651 {
2652     vector org, t_forward, t_left, t_up, e_forward, e_up;
2653     vector org0, ang0;
2654     float tagscale;
2655
2656     ang0 = e.angles;
2657     org0 = e.origin;
2658
2659     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2660     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2661     t_forward = v_forward * tagscale;
2662     t_left = v_right * -tagscale;
2663     t_up = v_up * tagscale;
2664
2665     e.origin_x = org * t_forward;
2666     e.origin_y = org * t_left;
2667     e.origin_z = org * t_up;
2668
2669     // current forward and up directions
2670     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2671                 e.angles = AnglesTransform_FromVAngles(e.angles);
2672         else
2673                 e.angles = AnglesTransform_FromAngles(e.angles);
2674     fixedmakevectors(e.angles);
2675
2676     // untransform forward, up!
2677     e_forward_x = v_forward * t_forward;
2678     e_forward_y = v_forward * t_left;
2679     e_forward_z = v_forward * t_up;
2680     e_up_x = v_up * t_forward;
2681     e_up_y = v_up * t_left;
2682     e_up_z = v_up * t_up;
2683
2684     e.angles = fixedvectoangles2(e_forward, e_up);
2685     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2686                 e.angles = AnglesTransform_ToVAngles(e.angles);
2687         else
2688                 e.angles = AnglesTransform_ToAngles(e.angles);
2689
2690     setattachment(e, to, tag);
2691     setorigin(e, e.origin);
2692 }
2693
2694 void detach_sameorigin(entity e)
2695 {
2696     vector org;
2697     org = gettaginfo(e, 0);
2698     e.angles = fixedvectoangles2(v_forward, v_up);
2699     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2700                 e.angles = AnglesTransform_ToVAngles(e.angles);
2701         else
2702                 e.angles = AnglesTransform_ToAngles(e.angles);
2703     setorigin(e, org);
2704     setattachment(e, world, "");
2705     setorigin(e, e.origin);
2706 }
2707
2708 void follow_sameorigin(entity e, entity to)
2709 {
2710     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2711     e.aiment = to; // make the hole follow bmodel
2712     e.punchangle = to.angles; // the original angles of bmodel
2713     e.view_ofs = e.origin - to.origin; // relative origin
2714     e.v_angle = e.angles - to.angles; // relative angles
2715 }
2716
2717 void unfollow_sameorigin(entity e)
2718 {
2719     e.movetype = MOVETYPE_NONE;
2720 }
2721
2722 entity gettaginfo_relative_ent;
2723 vector gettaginfo_relative(entity e, float tag)
2724 {
2725     if (!gettaginfo_relative_ent)
2726     {
2727         gettaginfo_relative_ent = spawn();
2728         gettaginfo_relative_ent.effects = EF_NODRAW;
2729     }
2730     gettaginfo_relative_ent.model = e.model;
2731     gettaginfo_relative_ent.modelindex = e.modelindex;
2732     gettaginfo_relative_ent.frame = e.frame;
2733     return gettaginfo(gettaginfo_relative_ent, tag);
2734 }
2735
2736 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2737 {
2738     float p;
2739     p = pow(2, chan);
2740     if (pl.soundentity.cnt & p)
2741         return;
2742     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2743     pl.soundentity.cnt |= p;
2744 }
2745
2746 void SoundEntity_StopSound(entity pl, float chan)
2747 {
2748     float p;
2749     p = pow(2, chan);
2750     if (pl.soundentity.cnt & p)
2751     {
2752         stopsoundto(MSG_ALL, pl.soundentity, chan);
2753         pl.soundentity.cnt &~= p;
2754     }
2755 }
2756
2757 void SoundEntity_Attach(entity pl)
2758 {
2759     pl.soundentity = spawn();
2760     pl.soundentity.classname = "soundentity";
2761     pl.soundentity.owner = pl;
2762     setattachment(pl.soundentity, pl, "");
2763     setmodel(pl.soundentity, "null");
2764 }
2765
2766 void SoundEntity_Detach(entity pl)
2767 {
2768     float i;
2769     for (i = 0; i <= 7; ++i)
2770         SoundEntity_StopSound(pl, i);
2771 }
2772
2773
2774 float ParseCommandPlayerSlotTarget_firsttoken;
2775 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2776 {
2777     string s;
2778     entity e, head;
2779     float n;
2780
2781     s = string_null;
2782
2783     ParseCommandPlayerSlotTarget_firsttoken = -1;
2784
2785     if (tokens > idx)
2786     {
2787         if (substring(argv(idx), 0, 1) == "#")
2788         {
2789             s = substring(argv(idx), 1, -1);
2790             ++idx;
2791             if (s == "")
2792                 if (tokens > idx)
2793                 {
2794                     s = argv(idx);
2795                     ++idx;
2796                 }
2797                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2798             if (s == ftos(stof(s)))
2799             {
2800                 e = edict_num(stof(s));
2801                 if (e.flags & FL_CLIENT)
2802                     return e;
2803             }
2804         }
2805         else
2806         {
2807             // it must be a nick name
2808             s = argv(idx);
2809             ++idx;
2810                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2811
2812             n = 0;
2813             FOR_EACH_CLIENT(head)
2814             if (head.netname == s)
2815             {
2816                 e = head;
2817                 ++n;
2818             }
2819             if (n == 1)
2820                 return e;
2821
2822             s = strdecolorize(s);
2823             n = 0;
2824             FOR_EACH_CLIENT(head)
2825             if (strdecolorize(head.netname) == s)
2826             {
2827                 e = head;
2828                 ++n;
2829             }
2830             if (n == 1)
2831                 return e;
2832         }
2833     }
2834
2835     return world;
2836 }
2837
2838 .float scale2;
2839
2840 float modeleffect_SendEntity(entity to, float sf)
2841 {
2842         float f;
2843         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2844
2845         f = 0;
2846         if(self.velocity != '0 0 0')
2847                 f |= 1;
2848         if(self.angles != '0 0 0')
2849                 f |= 2;
2850         if(self.avelocity != '0 0 0')
2851                 f |= 4;
2852
2853         WriteByte(MSG_ENTITY, f);
2854         WriteShort(MSG_ENTITY, self.modelindex);
2855         WriteByte(MSG_ENTITY, self.skin);
2856         WriteByte(MSG_ENTITY, self.frame);
2857         WriteCoord(MSG_ENTITY, self.origin_x);
2858         WriteCoord(MSG_ENTITY, self.origin_y);
2859         WriteCoord(MSG_ENTITY, self.origin_z);
2860         if(f & 1)
2861         {
2862                 WriteCoord(MSG_ENTITY, self.velocity_x);
2863                 WriteCoord(MSG_ENTITY, self.velocity_y);
2864                 WriteCoord(MSG_ENTITY, self.velocity_z);
2865         }
2866         if(f & 2)
2867         {
2868                 WriteCoord(MSG_ENTITY, self.angles_x);
2869                 WriteCoord(MSG_ENTITY, self.angles_y);
2870                 WriteCoord(MSG_ENTITY, self.angles_z);
2871         }
2872         if(f & 4)
2873         {
2874                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2875                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2876                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2877         }
2878         WriteShort(MSG_ENTITY, self.scale * 256.0);
2879         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2880         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2881         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2882         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2883
2884         return TRUE;
2885 }
2886
2887 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2888 {
2889         entity e;
2890         float sz;
2891         e = spawn();
2892         e.classname = "modeleffect";
2893         setmodel(e, m);
2894         e.frame = f;
2895         setorigin(e, o);
2896         e.velocity = v;
2897         e.angles = ang;
2898         e.avelocity = angv;
2899         e.alpha = a;
2900         e.teleport_time = t1;
2901         e.fade_time = t2;
2902         e.skin = s;
2903         if(s0 >= 0)
2904                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2905         else
2906                 e.scale = -s0;
2907         if(s2 >= 0)
2908                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2909         else
2910                 e.scale2 = -s2;
2911         sz = max(e.scale, e.scale2);
2912         setsize(e, e.mins * sz, e.maxs * sz);
2913         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2914 }
2915
2916 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2917 {
2918         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2919 }
2920
2921 float randombit(float bits)
2922 {
2923         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2924                 return bits;
2925
2926         float n, f, b, r;
2927
2928         r = random();
2929         b = 0;
2930         n = 0;
2931
2932         for(f = 1; f <= bits; f *= 2)
2933         {
2934                 if(bits & f)
2935                 {
2936                         ++n;
2937                         r *= n;
2938                         if(r <= 1)
2939                                 b = f;
2940                         else
2941                                 r = (r - 1) / (n - 1);
2942                 }
2943         }
2944
2945         return b;
2946 }
2947
2948 float randombits(float bits, float k, float error_return)
2949 {
2950         float r;
2951         r = 0;
2952         while(k > 0 && bits != r)
2953         {
2954                 r += randombit(bits - r);
2955                 --k;
2956         }
2957         if(error_return)
2958                 if(k > 0)
2959                         return -1; // all
2960         return r;
2961 }
2962
2963 void randombit_test(float bits, float iter)
2964 {
2965         while(iter > 0)
2966         {
2967                 print(ftos(randombit(bits)), "\n");
2968                 --iter;
2969         }
2970 }
2971
2972 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2973 {
2974         if(halflifedist > 0)
2975                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2976         else if(halflifedist < 0)
2977                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2978         else
2979                 return 1;
2980 }
2981
2982
2983
2984
2985 #ifdef RELEASE
2986 #define cvar_string_normal cvar_string_builtin
2987 #define cvar_normal cvar_builtin
2988 #else
2989 string cvar_string_normal(string n)
2990 {
2991         if not(cvar_type(n) & 1)
2992                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2993         return cvar_string_builtin(n);
2994 }
2995
2996 float cvar_normal(string n)
2997 {
2998         return stof(cvar_string_normal(n));
2999 }
3000 #endif
3001 #define cvar_set_normal cvar_set_builtin
3002
3003 void defer_think()
3004 {
3005     entity oself;
3006
3007     oself           = self;
3008     self            = self.owner;
3009     oself.think     = SUB_Remove;
3010     oself.nextthink = time;
3011
3012     oself.use();
3013 }
3014
3015 /*
3016     Execute func() after time + fdelay.
3017     self when func is executed = self when defer is called
3018 */
3019 void defer(float fdelay, void() func)
3020 {
3021     entity e;
3022
3023     e           = spawn();
3024     e.owner     = self;
3025     e.use       = func;
3026     e.think     = defer_think;
3027     e.nextthink = time + fdelay;
3028 }