qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include <common/weapons/weapon/crylink.qh>
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/notifications/all.qh"
  23 #include "../common/playerstats.qh"
  24 #include "../common/teams.qh"
  25 #include "../common/mapobjects/subs.qh"
  26 #include "../common/util.qh"
  27 #include "../common/turrets/sv_turrets.qh"
  28 #include <common/weapons/_all.qh>
  29 #include "../common/vehicles/sv_vehicles.qh"
  30 #include "../common/vehicles/vehicle.qh"
  31 #include "../common/items/_mod.qh"
  32 #include "../common/state.qh"
  33 #include "../common/effects/qc/globalsound.qh"
  34 #include "../common/wepent.qh"
  35 #include "../lib/csqcmodel/sv_model.qh"
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/server.qh"
  38
  39 void crosshair_trace(entity pl)
  40 {
  41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  42 }
  43
  44 void crosshair_trace_plusvisibletriggers(entity pl)
  45 {
  46         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
  47 }
  48
  49 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
  50 {
  51         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
  52 }
  53
  54 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
  55 {
  56         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  57         {
  58                 if(it.model != "")
  59                 {
  60                         it.solid = SOLID_BSP;
  61                         IL_PUSH(g_ctrace_changed, it);
  62                 }
  63         });
  64
  65         if (is_wz)
  66                 WarpZone_crosshair_trace(pl);
  67         else
  68                 crosshair_trace(pl);
  69
  70         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
  71
  72         IL_CLEAR(g_ctrace_changed);
  73 }
  74
  75 void WarpZone_crosshair_trace(entity pl)
  76 {
  77         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  78 }
  79
  80 void dedicated_print(string input)
  81 {
  82         if (server_is_dedicated) print(input);
  83 }
  84
  85 void GameLogEcho(string s)
  86 {
  87     string fn;
  88     int matches;
  89
  90     if (autocvar_sv_eventlog_files)
  91     {
  92         if (!logfile_open)
  93         {
  94             logfile_open = true;
  95             matches = autocvar_sv_eventlog_files_counter + 1;
  96             cvar_set("sv_eventlog_files_counter", itos(matches));
  97             fn = ftos(matches);
  98             if (strlen(fn) < 8)
  99                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 100             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 101             logfile = fopen(fn, FILE_APPEND);
 102             fputs(logfile, ":logversion:3\n");
 103         }
 104         if (logfile >= 0)
 105         {
 106             if (autocvar_sv_eventlog_files_timestamps)
 107                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 108             else
 109                 fputs(logfile, strcat(s, "\n"));
 110         }
 111     }
 112     if (autocvar_sv_eventlog_console)
 113     {
 114         dedicated_print(strcat(s, "\n"));
 115     }
 116 }
 117
 118 void GameLogInit()
 119 {
 120     logfile_open = 0;
 121     // will be opened later
 122 }
 123
 124 void GameLogClose()
 125 {
 126     if (logfile_open && logfile >= 0)
 127     {
 128         fclose(logfile);
 129         logfile = -1;
 130     }
 131 }
 132
 133 entity findnearest(vector point, bool checkitems, vector axismod)
 134 {
 135     vector dist;
 136     int num_nearest = 0;
 137
 138     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 139     {
 140         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 141             dist = it.oldorigin;
 142         else
 143             dist = it.origin;
 144         dist = dist - point;
 145         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 146         float len = vlen2(dist);
 147
 148         int l;
 149         for (l = 0; l < num_nearest; ++l)
 150         {
 151             if (len < nearest_length[l])
 152                 break;
 153         }
 154
 155         // now i tells us where to insert at
 156         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 157         if (l < NUM_NEAREST_ENTITIES)
 158         {
 159             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 160             {
 161                 nearest_length[j + 1] = nearest_length[j];
 162                 nearest_entity[j + 1] = nearest_entity[j];
 163             }
 164             nearest_length[l] = len;
 165             nearest_entity[l] = it;
 166             if (num_nearest < NUM_NEAREST_ENTITIES)
 167                 num_nearest = num_nearest + 1;
 168         }
 169     });
 170
 171     // now use the first one from our list that we can see
 172     for (int j = 0; j < num_nearest; ++j)
 173     {
 174         traceline(point, nearest_entity[j].origin, true, NULL);
 175         if (trace_fraction == 1)
 176         {
 177             if (j != 0)
 178                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 179             return nearest_entity[j];
 180         }
 181     }
 182
 183     if (num_nearest == 0)
 184         return NULL;
 185
 186     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 187     /* DEBUGGING CODE:
 188     dprint("Candidates were: ");
 189     for(j = 0; j < num_nearest; ++j)
 190     {
 191         if(j != 0)
 192                 dprint(", ");
 193         dprint(nearest_entity[j].netname);
 194     }
 195     dprint("\n");
 196     */
 197
 198     return nearest_entity[0];
 199 }
 200
 201 string NearestLocation(vector p)
 202 {
 203     string ret = "somewhere";
 204     entity loc = findnearest(p, false, '1 1 1');
 205     if (loc)
 206         ret = loc.message;
 207     else
 208     {
 209         loc = findnearest(p, true, '1 1 4');
 210         if (loc)
 211             ret = loc.netname;
 212     }
 213     return ret;
 214 }
 215
 216 string AmmoNameFromWeaponentity(Weapon wep)
 217 {
 218         string ammoitems = "batteries";
 219         switch (wep.ammo_type)
 220         {
 221                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 222                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 223                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 224                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 225                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 226                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 227         }
 228         return ammoitems;
 229 }
 230
 231 string formatmessage(entity this, string msg)
 232 {
 233         float p, p1, p2;
 234         float n;
 235         vector cursor = '0 0 0';
 236         entity cursor_ent = NULL;
 237         string escape;
 238         string replacement;
 239         p = 0;
 240         n = 7;
 241         bool traced = false;
 242
 243         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 244         msg = M_ARGV(1, string);
 245
 246         while (1) {
 247                 if (n < 1)
 248                         break; // too many replacements
 249
 250                 n = n - 1;
 251                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 252                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 253
 254                 if (p1 < 0)
 255                         p1 = p2;
 256
 257                 if (p2 < 0)
 258                         p2 = p1;
 259
 260                 p = min(p1, p2);
 261
 262                 if (p < 0)
 263                         break;
 264
 265                 if(!traced)
 266                 {
 267                         WarpZone_crosshair_trace_plusvisibletriggers(this);
 268                         cursor = trace_endpos;
 269                         cursor_ent = trace_ent;
 270                         traced = true;
 271                 }
 272
 273                 replacement = substring(msg, p, 2);
 274                 escape = substring(msg, p + 1, 1);
 275
 276                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 277
 278                 switch(escape)
 279                 {
 280                         case "%": replacement = "%"; break;
 281                         case "\\":replacement = "\\"; break;
 282                         case "n": replacement = "\n"; break;
 283                         case "a": replacement = ftos(floor(GetResource(this, RES_ARMOR))); break;
 284                         case "h": replacement = ftos(floor(GetResource(this, RES_HEALTH))); break;
 285                         case "l": replacement = NearestLocation(this.origin); break;
 286                         case "y": replacement = NearestLocation(cursor); break;
 287                         case "d": replacement = NearestLocation(this.death_origin); break;
 288                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 289                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 290                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 291                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 292                         case "S": replacement = ftos(vlen(this.velocity)); break;
 293                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 294                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 295                         default:
 296                         {
 297                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 298                                 replacement = M_ARGV(2, string);
 299                                 break;
 300                         }
 301                 }
 302
 303                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 304                 p = p + strlen(replacement);
 305         }
 306         return msg;
 307 }
 308
 309 /*
 310 =============
 311 GetCvars
 312 =============
 313 Called with:
 314   0:  sends the request
 315   >0: receives a cvar from name=argv(f) value=argv(f+1)
 316 */
 317 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 318 {
 319         if (f < 0)
 320         {
 321                 strfree(store.(field));
 322         }
 323         else if (f > 0)
 324         {
 325                 if (thisname == name)
 326                 {
 327                         strcpy(store.(field), argv(f + 1));
 328                 }
 329         }
 330         else
 331                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 332 }
 333 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 334 {
 335         GetCvars_handleString(this, store, thisname, f, field, name);
 336         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 337                 if (thisname == name)
 338                 {
 339                         string s = func(this, strcat1(store.(field)));
 340                         if (s != store.(field))
 341                         {
 342                                 strcpy(store.(field), s);
 343                         }
 344                 }
 345 }
 346 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 347 {
 348         if (f < 0)
 349         {
 350         }
 351         else if (f > 0)
 352         {
 353                 if (thisname == name)
 354                         store.(field) = stof(argv(f + 1));
 355         }
 356         else
 357                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 358 }
 359 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 360 {
 361         if (f < 0)
 362         {
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                 {
 368                         if (!store.(field))
 369                         {
 370                                 store.(field) = stof(argv(f + 1));
 371                                 if (!store.(field))
 372                                         store.(field) = -1;
 373                         }
 374                 }
 375         }
 376         else
 377         {
 378                 if (!store.(field))
 379                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 380         }
 381 }
 382 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 383 {
 384         string o = W_FixWeaponOrder_ForceComplete(wo);
 385         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 386         return o;
 387 }
 388
 389 REPLICATE(autoswitch, bool, "cl_autoswitch");
 390
 391 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 392
 393 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 394
 395 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 396
 397 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 398
 399 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 400
 401 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 402
 403 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 404
 405 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 406
 407 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 408
 409 REPLICATE(cvar_cl_physics, string, "cl_physics");
 410
 411 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 412
 413 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 414
 415 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 416
 417 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 418
 419 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
 420
 421 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 422
 423 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 424
 425 /**
 426  * @param f -1: cleanup, 0: request, 1: receive
 427  */
 428 void GetCvars(entity this, entity store, int f)
 429 {
 430         string s = string_null;
 431
 432         if (f == 0)
 433                 LOG_INFO("Warning: requesting cvar values is deprecated. Client should send them automatically using REPLICATE.\n");
 434
 435         if (f > 0)
 436                 s = strcat1(argv(f));
 437
 438         get_cvars_f = f;
 439         get_cvars_s = s;
 440         MUTATOR_CALLHOOK(GetCvars);
 441
 442         Notification_GetCvars(this);
 443
 444         ReplicateVars(this, store, s, f);
 445
 446         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 447         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 448         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 449         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 450         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 451         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 452         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 453         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 454         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 455         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 456         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 457
 458         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 459
 460         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 461         if (f > 0)
 462         {
 463                 if (s == "cl_weaponpriority")
 464                 {
 465                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 466                         {
 467                                 .entity weaponentity = weaponentities[slot];
 468                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 469                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 470                         }
 471                 }
 472                 if (s == "cl_allow_uidtracking")
 473                         PlayerStats_GameReport_AddPlayer(this);
 474         }
 475 }
 476
 477 // decolorizes and team colors the player name when needed
 478 string playername(entity p, bool team_colorize)
 479 {
 480     string t;
 481     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 482     {
 483         t = Team_ColorCode(p.team);
 484         return strcat(t, strdecolorize(p.netname));
 485     }
 486     else
 487         return p.netname;
 488 }
 489
 490 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 491 {
 492         int i = weaponinfo.m_id;
 493         int d = 0;
 494         bool allow_mutatorblocked = false;
 495
 496         if(!i)
 497                 return 0;
 498
 499         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 500         d = M_ARGV(1, float);
 501         allguns = M_ARGV(2, bool);
 502         allow_mutatorblocked = M_ARGV(3, bool);
 503
 504         if(allguns)
 505                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
 506         else if(!mutator_returnvalue)
 507                 d = !(!weaponinfo.weaponstart);
 508
 509         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 510                 d = 0;
 511
 512         float t = weaponinfo.weaponstartoverride;
 513
 514         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 515
 516         // bit order in t:
 517         // 1: want or not
 518         // 2: is default?
 519         // 4: is set by default?
 520         if(t < 0)
 521                 t = 4 | (3 * d);
 522         else
 523                 t |= (2 * d);
 524
 525         return t;
 526 }
 527
 528 void readplayerstartcvars()
 529 {
 530         float i, t;
 531         string s;
 532
 533         // initialize starting values for players
 534         start_weapons = '0 0 0';
 535         start_weapons_default = '0 0 0';
 536         start_weapons_defaultmask = '0 0 0';
 537         start_items = 0;
 538         start_ammo_shells = 0;
 539         start_ammo_nails = 0;
 540         start_ammo_rockets = 0;
 541         start_ammo_cells = 0;
 542         start_ammo_plasma = 0;
 543         if (random_start_ammo == NULL)
 544         {
 545                 random_start_ammo = spawn();
 546         }
 547         start_health = cvar("g_balance_health_start");
 548         start_armorvalue = cvar("g_balance_armor_start");
 549
 550         g_weaponarena = 0;
 551         g_weaponarena_weapons = '0 0 0';
 552
 553         s = cvar_string("g_weaponarena");
 554
 555         MUTATOR_CALLHOOK(SetWeaponArena, s);
 556         s = M_ARGV(0, string);
 557
 558         if (s == "0" || s == "")
 559         {
 560                 // no arena
 561         }
 562         else if (s == "off")
 563         {
 564                 // forcibly turn off weaponarena
 565         }
 566         else if (s == "all" || s == "1")
 567         {
 568                 g_weaponarena = 1;
 569                 g_weaponarena_list = "All Weapons";
 570                 FOREACH(Weapons, it != WEP_Null, {
 571                         if(!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
 572                                 g_weaponarena_weapons |= (it.m_wepset);
 573                 });
 574         }
 575         else if (s == "devall")
 576         {
 577                 g_weaponarena = 1;
 578                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 579                 FOREACH(Weapons, it != WEP_Null,
 580                 {
 581                         g_weaponarena_weapons |= (it.m_wepset);
 582                 });
 583         }
 584         else if (s == "most")
 585         {
 586                 g_weaponarena = 1;
 587                 g_weaponarena_list = "Most Weapons";
 588                 FOREACH(Weapons, it != WEP_Null, {
 589                         if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
 590                                 g_weaponarena_weapons |= (it.m_wepset);
 591                 });
 592         }
 593         else if (s == "none")
 594         {
 595                 g_weaponarena = 1;
 596                 g_weaponarena_list = "No Weapons";
 597         }
 598         else
 599         {
 600                 g_weaponarena = 1;
 601                 t = tokenize_console(s);
 602                 g_weaponarena_list = "";
 603                 for (i = 0; i < t; ++i)
 604                 {
 605                         s = argv(i);
 606                         Weapon wep = Weapons_fromstr(s);
 607                         if(wep != WEP_Null)
 608                         {
 609                                 g_weaponarena_weapons |= (wep.m_wepset);
 610                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
 611                         }
 612                 }
 613                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 614         }
 615
 616         if (g_weaponarena)
 617         {
 618                 g_weapon_stay = 0; // incompatible
 619                 start_weapons = g_weaponarena_weapons;
 620                 start_items |= IT_UNLIMITED_AMMO;
 621         }
 622         else
 623         {
 624                 FOREACH(Weapons, it != WEP_Null, {
 625                         int w = want_weapon(it, false);
 626                         WepSet s = it.m_wepset;
 627                         if(w & 1)
 628                                 start_weapons |= s;
 629                         if(w & 2)
 630                                 start_weapons_default |= s;
 631                         if(w & 4)
 632                                 start_weapons_defaultmask |= s;
 633                 });
 634         }
 635
 636         if(cvar("g_balance_superweapons_time") < 0)
 637                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 638
 639         if(!cvar("g_use_ammunition"))
 640                 start_items |= IT_UNLIMITED_AMMO;
 641
 642         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 643         {
 644                 start_ammo_shells = 999;
 645                 start_ammo_nails = 999;
 646                 start_ammo_rockets = 999;
 647                 start_ammo_cells = 999;
 648                 start_ammo_plasma = 999;
 649                 start_ammo_fuel = 999;
 650         }
 651         else
 652         {
 653                 start_ammo_shells = cvar("g_start_ammo_shells");
 654                 start_ammo_nails = cvar("g_start_ammo_nails");
 655                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 656                 start_ammo_cells = cvar("g_start_ammo_cells");
 657                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 658                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 659                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 660                 SetResource(random_start_ammo, RES_SHELLS, cvar(
 661                         "g_random_start_shells"));
 662                 SetResource(random_start_ammo, RES_BULLETS, cvar(
 663                         "g_random_start_bullets"));
 664                 SetResource(random_start_ammo, RES_ROCKETS,
 665                         cvar("g_random_start_rockets"));
 666                 SetResource(random_start_ammo, RES_CELLS, cvar(
 667                         "g_random_start_cells"));
 668                 SetResource(random_start_ammo, RES_PLASMA, cvar(
 669                         "g_random_start_plasma"));
 670         }
 671
 672         if (warmup_stage)
 673         {
 674                 warmup_start_ammo_shells = start_ammo_shells;
 675                 warmup_start_ammo_nails = start_ammo_nails;
 676                 warmup_start_ammo_rockets = start_ammo_rockets;
 677                 warmup_start_ammo_cells = start_ammo_cells;
 678                 warmup_start_ammo_plasma = start_ammo_plasma;
 679                 warmup_start_ammo_fuel = start_ammo_fuel;
 680                 warmup_start_health = start_health;
 681                 warmup_start_armorvalue = start_armorvalue;
 682                 warmup_start_weapons = start_weapons;
 683                 warmup_start_weapons_default = start_weapons_default;
 684                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 685
 686                 if (!g_weaponarena && !g_ca && !g_freezetag)
 687                 {
 688                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 689                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 690                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 691                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 692                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 693                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 694                         warmup_start_health = cvar("g_warmup_start_health");
 695                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 696                         warmup_start_weapons = '0 0 0';
 697                         warmup_start_weapons_default = '0 0 0';
 698                         warmup_start_weapons_defaultmask = '0 0 0';
 699                         FOREACH(Weapons, it != WEP_Null, {
 700                                 int w = want_weapon(it, g_warmup_allguns);
 701                                 WepSet s = (it.m_wepset);
 702                                 if(w & 1)
 703                                         warmup_start_weapons |= s;
 704                                 if(w & 2)
 705                                         warmup_start_weapons_default |= s;
 706                                 if(w & 4)
 707                                         warmup_start_weapons_defaultmask |= s;
 708                         });
 709                 }
 710         }
 711
 712         if (g_jetpack)
 713                 start_items |= ITEM_Jetpack.m_itemid;
 714
 715         MUTATOR_CALLHOOK(SetStartItems);
 716
 717         if (start_items & ITEM_Jetpack.m_itemid)
 718         {
 719                 start_items |= ITEM_JetpackRegen.m_itemid;
 720                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 721                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 722         }
 723
 724         start_ammo_shells = max(0, start_ammo_shells);
 725         start_ammo_nails = max(0, start_ammo_nails);
 726         start_ammo_rockets = max(0, start_ammo_rockets);
 727         start_ammo_cells = max(0, start_ammo_cells);
 728         start_ammo_plasma = max(0, start_ammo_plasma);
 729         start_ammo_fuel = max(0, start_ammo_fuel);
 730         SetResource(random_start_ammo, RES_SHELLS, max(0,
 731                 GetResource(random_start_ammo, RES_SHELLS)));
 732         SetResource(random_start_ammo, RES_BULLETS, max(0,
 733                 GetResource(random_start_ammo, RES_BULLETS)));
 734         SetResource(random_start_ammo, RES_ROCKETS, max(0,
 735                 GetResource(random_start_ammo, RES_ROCKETS)));
 736         SetResource(random_start_ammo, RES_CELLS, max(0,
 737                 GetResource(random_start_ammo, RES_CELLS)));
 738         SetResource(random_start_ammo, RES_PLASMA, max(0,
 739                 GetResource(random_start_ammo, RES_PLASMA)));
 740
 741         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 742         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 743         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 744         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 745         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 746         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 747 }
 748
 749 void precache_playermodel(string m)
 750 {
 751         float globhandle, i, n;
 752         string f;
 753
 754         if(substring(m, -9,5) == "_lod1")
 755                 return;
 756         if(substring(m, -9,5) == "_lod2")
 757                 return;
 758         precache_model(m);
 759         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 760         if(fexists(f))
 761                 precache_model(f);
 762         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 763         if(fexists(f))
 764                 precache_model(f);
 765
 766         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 767         if (globhandle < 0)
 768                 return;
 769         n = search_getsize(globhandle);
 770         for (i = 0; i < n; ++i)
 771         {
 772                 //print(search_getfilename(globhandle, i), "\n");
 773                 f = search_getfilename(globhandle, i);
 774                 PrecachePlayerSounds(f);
 775         }
 776         search_end(globhandle);
 777 }
 778 void precache_all_playermodels(string pattern)
 779 {
 780         int globhandle = search_begin(pattern, true, false);
 781         if (globhandle < 0) return;
 782         int n = search_getsize(globhandle);
 783         for (int i = 0; i < n; ++i)
 784         {
 785                 string s = search_getfilename(globhandle, i);
 786                 precache_playermodel(s);
 787         }
 788         search_end(globhandle);
 789 }
 790
 791 void precache_playermodels(string s)
 792 {
 793         FOREACH_WORD(s, true, { precache_playermodel(it); });
 794 }
 795
 796 void precache()
 797 {
 798     // gamemode related things
 799
 800     // Precache all player models if desired
 801     if (autocvar_sv_precacheplayermodels)
 802     {
 803         PrecachePlayerSounds("sound/player/default.sounds");
 804         precache_all_playermodels("models/player/*.zym");
 805         precache_all_playermodels("models/player/*.dpm");
 806         precache_all_playermodels("models/player/*.md3");
 807         precache_all_playermodels("models/player/*.psk");
 808         precache_all_playermodels("models/player/*.iqm");
 809     }
 810
 811     if (autocvar_sv_defaultcharacter)
 812     {
 813                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 814                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 815                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 816                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 817                 precache_playermodels(autocvar_sv_defaultplayermodel);
 818     }
 819
 820 #if 0
 821     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 822
 823     if (!this.noise && this.music) // quake 3 uses the music field
 824         this.noise = this.music;
 825
 826     // plays music for the level if there is any
 827     if (this.noise)
 828     {
 829         precache_sound (this.noise);
 830         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 831     }
 832 #endif
 833 }
 834
 835
 836 void make_safe_for_remove(entity e)
 837 {
 838     if (e.initialize_entity)
 839     {
 840         entity ent, prev = NULL;
 841         for (ent = initialize_entity_first; ent; )
 842         {
 843             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 844             {
 845                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 846                 // skip it in linked list
 847                 if (prev)
 848                 {
 849                     prev.initialize_entity_next = ent.initialize_entity_next;
 850                     ent = prev.initialize_entity_next;
 851                 }
 852                 else
 853                 {
 854                     initialize_entity_first = ent.initialize_entity_next;
 855                     ent = initialize_entity_first;
 856                 }
 857             }
 858             else
 859             {
 860                 prev = ent;
 861                 ent = ent.initialize_entity_next;
 862             }
 863         }
 864     }
 865 }
 866
 867 .float remove_except_protected_forbidden;
 868 void remove_except_protected(entity e)
 869 {
 870         if(e.remove_except_protected_forbidden)
 871                 error("not allowed to remove this at this point");
 872         builtin_remove(e);
 873 }
 874
 875 void remove_unsafely(entity e)
 876 {
 877     if(e.classname == "spike")
 878         error("Removing spikes is forbidden (crylink bug), please report");
 879     builtin_remove(e);
 880 }
 881
 882 void remove_safely(entity e)
 883 {
 884     make_safe_for_remove(e);
 885     builtin_remove(e);
 886 }
 887
 888 void InitializeEntity(entity e, void(entity this) func, int order)
 889 {
 890     entity prev, cur;
 891
 892     if (!e || e.initialize_entity)
 893     {
 894         // make a proxy initializer entity
 895         entity e_old = e;
 896         e = new(initialize_entity);
 897         e.enemy = e_old;
 898     }
 899
 900     e.initialize_entity = func;
 901     e.initialize_entity_order = order;
 902
 903     cur = initialize_entity_first;
 904     prev = NULL;
 905     for (;;)
 906     {
 907         if (!cur || cur.initialize_entity_order > order)
 908         {
 909             // insert between prev and cur
 910             if (prev)
 911                 prev.initialize_entity_next = e;
 912             else
 913                 initialize_entity_first = e;
 914             e.initialize_entity_next = cur;
 915             return;
 916         }
 917         prev = cur;
 918         cur = cur.initialize_entity_next;
 919     }
 920 }
 921 void InitializeEntitiesRun()
 922 {
 923     entity startoflist = initialize_entity_first;
 924     initialize_entity_first = NULL;
 925     delete_fn = remove_except_protected;
 926     for (entity e = startoflist; e; e = e.initialize_entity_next)
 927     {
 928                 e.remove_except_protected_forbidden = 1;
 929     }
 930     for (entity e = startoflist; e; )
 931     {
 932                 e.remove_except_protected_forbidden = 0;
 933         e.initialize_entity_order = 0;
 934         entity next = e.initialize_entity_next;
 935         e.initialize_entity_next = NULL;
 936         var void(entity this) func = e.initialize_entity;
 937         e.initialize_entity = func_null;
 938         if (e.classname == "initialize_entity")
 939         {
 940             entity wrappee = e.enemy;
 941             builtin_remove(e);
 942             e = wrappee;
 943         }
 944         //dprint("Delayed initialization: ", e.classname, "\n");
 945         if (func)
 946         {
 947                 func(e);
 948         }
 949         else
 950         {
 951             eprint(e);
 952             backtrace(strcat("Null function in: ", e.classname, "\n"));
 953         }
 954         e = next;
 955     }
 956     delete_fn = remove_unsafely;
 957 }
 958
 959 .float(entity) isEliminated;
 960 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 961 {
 962         Stream out = MSG_ENTITY;
 963         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 964         serialize(byte, out, sendflags);
 965         if (sendflags & 1) {
 966                 for (int i = 1; i <= maxclients; i += 8) {
 967                         int f = 0;
 968                         entity e = edict_num(i);
 969                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 970                                 if (eliminatedPlayers.isEliminated(e)) {
 971                                         f |= BIT(b);
 972                                 }
 973                         }
 974                         serialize(byte, out, f);
 975                 }
 976         }
 977         return true;
 978 }
 979
 980 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 981 {
 982         if(eliminatedPlayers)
 983         {
 984                 backtrace("Can't spawn eliminatedPlayers again!");
 985                 return;
 986         }
 987         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 988         eliminatedPlayers.isEliminated = isEliminated_func;
 989 }
 990
 991
 992
 993
 994 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 995 {
 996         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 997                 this.projectiledeathtype |= HITTYPE_SPLASH;
 998         adaptor_think2use(this);
 999 }
1000
1001 // deferred dropping
1002 void DropToFloor_Handler(entity this)
1003 {
1004     WITHSELF(this, builtin_droptofloor());
1005     this.dropped_origin = this.origin;
1006 }
1007
1008 void droptofloor(entity this)
1009 {
1010     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1011 }
1012
1013
1014
1015 float trace_hits_box_a0, trace_hits_box_a1;
1016
1017 float trace_hits_box_1d(float end, float thmi, float thma)
1018 {
1019     if (end == 0)
1020     {
1021         // just check if x is in range
1022         if (0 < thmi)
1023             return false;
1024         if (0 > thma)
1025             return false;
1026     }
1027     else
1028     {
1029         // do the trace with respect to x
1030         // 0 -> end has to stay in thmi -> thma
1031         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1032         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1033         if (trace_hits_box_a0 > trace_hits_box_a1)
1034             return false;
1035     }
1036     return true;
1037 }
1038
1039 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1040 {
1041     end -= start;
1042     thmi -= start;
1043     thma -= start;
1044     // now it is a trace from 0 to end
1045
1046     trace_hits_box_a0 = 0;
1047     trace_hits_box_a1 = 1;
1048
1049     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1050         return false;
1051     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1052         return false;
1053     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1054         return false;
1055
1056     return true;
1057 }
1058
1059 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1060 {
1061     return trace_hits_box(start, end, thmi - ma, thma - mi);
1062 }
1063
1064 bool SUB_NoImpactCheck(entity this, entity toucher)
1065 {
1066         // zero hitcontents = this is not the real impact, but either the
1067         // mirror-impact of something hitting the projectile instead of the
1068         // projectile hitting the something, or a touchareagrid one. Neither of
1069         // these stop the projectile from moving, so...
1070         if(trace_dphitcontents == 0)
1071         {
1072                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1073                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1074         }
1075     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1076         return true;
1077     if (toucher == NULL && this.size != '0 0 0')
1078     {
1079         vector tic;
1080         tic = this.velocity * sys_frametime;
1081         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1082         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1083         if (trace_fraction >= 1)
1084         {
1085             LOG_TRACE("Odd... did not hit...?");
1086         }
1087         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1088         {
1089             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1090             return true;
1091         }
1092     }
1093
1094     return false;
1095 }
1096
1097 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1098
1099 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1100 {
1101         if(SUB_OwnerCheck(this, toucher))
1102                 return true;
1103         if(SUB_NoImpactCheck(this, toucher))
1104         {
1105                 if(this.classname == "nade")
1106                         return false; // no checks here
1107                 else if(this.classname == "grapplinghook")
1108                         RemoveHook(this);
1109                 else if(this.classname == "spike")
1110                 {
1111                         W_Crylink_Dequeue(this);
1112                         delete(this);
1113                 }
1114                 else
1115                         delete(this);
1116                 return true;
1117         }
1118         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1119                 UpdateCSQCProjectile(this);
1120         return false;
1121 }
1122
1123 /** engine callback */
1124 void URI_Get_Callback(float id, float status, string data)
1125 {
1126         if(url_URI_Get_Callback(id, status, data))
1127         {
1128                 // handled
1129         }
1130         else if (id == URI_GET_DISCARD)
1131         {
1132                 // discard
1133         }
1134         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1135         {
1136                 // sv_cmd curl
1137                 Curl_URI_Get_Callback(id, status, data);
1138         }
1139         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1140         {
1141                 // online ban list
1142                 OnlineBanList_URI_Get_Callback(id, status, data);
1143         }
1144         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1145         {
1146                 // handled by a mutator
1147         }
1148         else
1149         {
1150                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1151         }
1152 }
1153
1154 string uid2name(string myuid) {
1155         string s;
1156         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1157
1158         // FIXME remove this later after 0.6 release
1159         // convert old style broken records to correct style
1160         if(s == "")
1161         {
1162                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1163                 if(s != "")
1164                 {
1165                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1166                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1167                 }
1168         }
1169
1170         if(s == "")
1171                 s = "^1Unregistered Player";
1172         return s;
1173 }
1174
1175 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1176 {
1177     float m, i;
1178     vector start, org, delta, end, enddown, mstart;
1179
1180     m = e.dphitcontentsmask;
1181     e.dphitcontentsmask = goodcontents | badcontents;
1182
1183     org = boundmin;
1184     delta = boundmax - boundmin;
1185
1186     start = end = org;
1187
1188     for (i = 0; i < attempts; ++i)
1189     {
1190         start.x = org.x + random() * delta.x;
1191         start.y = org.y + random() * delta.y;
1192         start.z = org.z + random() * delta.z;
1193
1194         // rule 1: start inside world bounds, and outside
1195         // solid, and don't start from somewhere where you can
1196         // fall down to evil
1197         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1198         if (trace_fraction >= 1)
1199             continue;
1200         if (trace_startsolid)
1201             continue;
1202         if (trace_dphitcontents & badcontents)
1203             continue;
1204         if (trace_dphitq3surfaceflags & badsurfaceflags)
1205             continue;
1206
1207         // rule 2: if we are too high, lower the point
1208         if (trace_fraction * delta.z > maxaboveground)
1209             start = trace_endpos + '0 0 1' * maxaboveground;
1210         enddown = trace_endpos;
1211
1212         // rule 3: make sure we aren't outside the map. This only works
1213         // for somewhat well formed maps. A good rule of thumb is that
1214         // the map should have a convex outside hull.
1215         // these can be traceLINES as we already verified the starting box
1216         mstart = start + 0.5 * (e.mins + e.maxs);
1217         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1218         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1219             continue;
1220         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1221         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1222             continue;
1223         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1224         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1225             continue;
1226         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1227         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1228             continue;
1229         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1230         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1231             continue;
1232
1233         // rule 4: we must "see" some spawnpoint or item
1234     entity sp = NULL;
1235     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1236     {
1237         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1238         {
1239                 sp = it;
1240                 break;
1241         }
1242     });
1243         if(!sp)
1244         {
1245                 int items_checked = 0;
1246                 IL_EACH(g_items, checkpvs(mstart, it),
1247                 {
1248                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1249                         {
1250                                 sp = it;
1251                                 break;
1252                         }
1253
1254                         ++items_checked;
1255                         if(items_checked >= attempts)
1256                                 break; // sanity
1257                 });
1258
1259                 if(!sp)
1260                         continue;
1261         }
1262
1263         // find a random vector to "look at"
1264         end.x = org.x + random() * delta.x;
1265         end.y = org.y + random() * delta.y;
1266         end.z = org.z + random() * delta.z;
1267         end = start + normalize(end - start) * vlen(delta);
1268
1269         // rule 4: start TO end must not be too short
1270         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1271         if (trace_startsolid)
1272             continue;
1273         if (trace_fraction < minviewdistance / vlen(delta))
1274             continue;
1275
1276         // rule 5: don't want to look at sky
1277         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1278             continue;
1279
1280         // rule 6: we must not end up in trigger_hurt
1281         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1282             continue;
1283
1284         break;
1285     }
1286
1287     e.dphitcontentsmask = m;
1288
1289     if (i < attempts)
1290     {
1291         setorigin(e, start);
1292         e.angles = vectoangles(end - start);
1293         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1294         return true;
1295     }
1296     else
1297         return false;
1298 }
1299
1300 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1301 {
1302         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1303 }
1304
1305 void write_recordmarker(entity pl, float tstart, float dt)
1306 {
1307     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1308
1309     // also write a marker into demo files for demotc-race-record-extractor to find
1310     stuffcmd(pl,
1311              strcat(
1312                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1313                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1314 }
1315
1316 void attach_sameorigin(entity e, entity to, string tag)
1317 {
1318     vector org, t_forward, t_left, t_up, e_forward, e_up;
1319     float tagscale;
1320
1321     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1322     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1323     t_forward = v_forward * tagscale;
1324     t_left = v_right * -tagscale;
1325     t_up = v_up * tagscale;
1326
1327     e.origin_x = org * t_forward;
1328     e.origin_y = org * t_left;
1329     e.origin_z = org * t_up;
1330
1331     // current forward and up directions
1332     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1333                 e.angles = AnglesTransform_FromVAngles(e.angles);
1334         else
1335                 e.angles = AnglesTransform_FromAngles(e.angles);
1336     fixedmakevectors(e.angles);
1337
1338     // untransform forward, up!
1339     e_forward.x = v_forward * t_forward;
1340     e_forward.y = v_forward * t_left;
1341     e_forward.z = v_forward * t_up;
1342     e_up.x = v_up * t_forward;
1343     e_up.y = v_up * t_left;
1344     e_up.z = v_up * t_up;
1345
1346     e.angles = fixedvectoangles2(e_forward, e_up);
1347     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1348                 e.angles = AnglesTransform_ToVAngles(e.angles);
1349         else
1350                 e.angles = AnglesTransform_ToAngles(e.angles);
1351
1352     setattachment(e, to, tag);
1353     setorigin(e, e.origin);
1354 }
1355
1356 void detach_sameorigin(entity e)
1357 {
1358     vector org;
1359     org = gettaginfo(e, 0);
1360     e.angles = fixedvectoangles2(v_forward, v_up);
1361     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1362                 e.angles = AnglesTransform_ToVAngles(e.angles);
1363         else
1364                 e.angles = AnglesTransform_ToAngles(e.angles);
1365     setorigin(e, org);
1366     setattachment(e, NULL, "");
1367     setorigin(e, e.origin);
1368 }
1369
1370 void follow_sameorigin(entity e, entity to)
1371 {
1372     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1373     e.aiment = to; // make the hole follow bmodel
1374     e.punchangle = to.angles; // the original angles of bmodel
1375     e.view_ofs = e.origin - to.origin; // relative origin
1376     e.v_angle = e.angles - to.angles; // relative angles
1377 }
1378
1379 void unfollow_sameorigin(entity e)
1380 {
1381     set_movetype(e, MOVETYPE_NONE);
1382 }
1383
1384 entity gettaginfo_relative_ent;
1385 vector gettaginfo_relative(entity e, float tag)
1386 {
1387     if (!gettaginfo_relative_ent)
1388     {
1389         gettaginfo_relative_ent = spawn();
1390         gettaginfo_relative_ent.effects = EF_NODRAW;
1391     }
1392     gettaginfo_relative_ent.model = e.model;
1393     gettaginfo_relative_ent.modelindex = e.modelindex;
1394     gettaginfo_relative_ent.frame = e.frame;
1395     return gettaginfo(gettaginfo_relative_ent, tag);
1396 }
1397
1398 .string aiment_classname;
1399 .float aiment_deadflag;
1400 void SetMovetypeFollow(entity ent, entity e)
1401 {
1402         // FIXME this may not be warpzone aware
1403         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1404         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1405         ent.aiment = e; // make the hole follow bmodel
1406         ent.punchangle = e.angles; // the original angles of bmodel
1407         ent.view_ofs = ent.origin - e.origin; // relative origin
1408         ent.v_angle = ent.angles - e.angles; // relative angles
1409         ent.aiment_classname = strzone(e.classname);
1410         ent.aiment_deadflag = e.deadflag;
1411 }
1412 void UnsetMovetypeFollow(entity ent)
1413 {
1414         set_movetype(ent, MOVETYPE_FLY);
1415         PROJECTILE_MAKETRIGGER(ent);
1416         ent.aiment = NULL;
1417 }
1418 float LostMovetypeFollow(entity ent)
1419 {
1420 /*
1421         if(ent.move_movetype != MOVETYPE_FOLLOW)
1422                 if(ent.aiment)
1423                         error("???");
1424 */
1425         if(ent.aiment)
1426         {
1427                 if(ent.aiment.classname != ent.aiment_classname)
1428                         return 1;
1429                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1430                         return 1;
1431         }
1432         return 0;
1433 }
1434
1435 .bool pushable;
1436 bool isPushable(entity e)
1437 {
1438         if(e.pushable)
1439                 return true;
1440         if(IS_VEHICLE(e))
1441                 return false;
1442         if(e.iscreature)
1443                 return true;
1444         if (Item_IsLoot(e))
1445         {
1446                 return true;
1447         }
1448         switch(e.classname)
1449         {
1450                 case "body":
1451                         return true;
1452                 case "bullet": // antilagged bullets can't hit this either
1453                         return false;
1454         }
1455         if (e.projectiledeathtype)
1456                 return true;
1457         return false;
1458 }