qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35 string ColoredTeamName(float t);
  36
  37 string admin_name(void)
  38 {
  39         if(autocvar_sv_adminnick != "")
  40                 return autocvar_sv_adminnick;
  41         else
  42                 return "SERVER ADMIN";
  43 }
  44
  45 float DistributeEvenly_amount;
  46 float DistributeEvenly_totalweight;
  47 void DistributeEvenly_Init(float amount, float totalweight)
  48 {
  49     if (DistributeEvenly_amount)
  50     {
  51         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  52         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  53     }
  54     if (totalweight == 0)
  55         DistributeEvenly_amount = 0;
  56     else
  57         DistributeEvenly_amount = amount;
  58     DistributeEvenly_totalweight = totalweight;
  59 }
  60 float DistributeEvenly_Get(float weight)
  61 {
  62     float f;
  63     if (weight <= 0)
  64         return 0;
  65     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  66     DistributeEvenly_totalweight -= weight;
  67     DistributeEvenly_amount -= f;
  68     return f;
  69 }
  70 float DistributeEvenly_GetRandomized(float weight)
  71 {
  72     float f;
  73     if (weight <= 0)
  74         return 0;
  75     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  76     DistributeEvenly_totalweight -= weight;
  77     DistributeEvenly_amount -= f;
  78     return f;
  79 }
  80
  81 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  82
  83
  84 string STR_PLAYER = "player";
  85 string STR_SPECTATOR = "spectator";
  86 string STR_OBSERVER = "observer";
  87
  88 #if 0
  89 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  90 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  91 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  92 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  93 #else
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  97 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  98 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if(v.classname != STR_PLAYER)
  99 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 100 #endif
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + ((ent.classname == STR_PLAYER) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void bcenterprint(string s)
 111 {
 112     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 113     entity head;
 114     FOR_EACH_PLAYER(head)
 115     if (clienttype(head) == CLIENTTYPE_REAL)
 116         centerprint(head, s);
 117 }
 118
 119 void GameLogEcho(string s)
 120 {
 121     string fn;
 122     float matches;
 123
 124     if (autocvar_sv_eventlog_files)
 125     {
 126         if (!logfile_open)
 127         {
 128             logfile_open = TRUE;
 129             matches = autocvar_sv_eventlog_files_counter + 1;
 130             cvar_set("sv_eventlog_files_counter", ftos(matches));
 131             fn = ftos(matches);
 132             if (strlen(fn) < 8)
 133                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 134             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 135             logfile = fopen(fn, FILE_APPEND);
 136             fputs(logfile, ":logversion:3\n");
 137         }
 138         if (logfile >= 0)
 139         {
 140             if (autocvar_sv_eventlog_files_timestamps)
 141                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 142             else
 143                 fputs(logfile, strcat(s, "\n"));
 144         }
 145     }
 146     if (autocvar_sv_eventlog_console)
 147     {
 148         print(s, "\n");
 149     }
 150 }
 151
 152 void GameLogInit()
 153 {
 154     logfile_open = 0;
 155     // will be opened later
 156 }
 157
 158 void GameLogClose()
 159 {
 160     if (logfile_open && logfile >= 0)
 161     {
 162         fclose(logfile);
 163         logfile = -1;
 164     }
 165 }
 166
 167 float spawnpoint_nag;
 168 void relocate_spawnpoint()
 169 {
 170     // nudge off the floor
 171     setorigin(self, self.origin + '0 0 1');
 172
 173     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 174     if (trace_startsolid)
 175     {
 176         vector o;
 177         o = self.origin;
 178         self.mins = PL_MIN;
 179         self.maxs = PL_MAX;
 180         if (!move_out_of_solid(self))
 181             objerror("could not get out of solid at all!");
 182         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 183         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 184         print(" ", ftos(self.origin_y - o_y));
 185         print(" ", ftos(self.origin_z - o_z), "'\n");
 186         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 187         {
 188             if (!spawnpoint_nag)
 189                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 190             spawnpoint_nag = 1;
 191         }
 192         else
 193         {
 194             setorigin(self, o);
 195             self.mins = self.maxs = '0 0 0';
 196             objerror("player spawn point in solid, mapper sucks!\n");
 197             return;
 198         }
 199     }
 200
 201     self.use = spawnpoint_use;
 202     self.team_saved = self.team;
 203     if (!self.cnt)
 204         self.cnt = 1;
 205
 206     if (have_team_spawns != 0)
 207         if (self.team)
 208             have_team_spawns = 1;
 209     have_team_spawns_forteam[self.team] = 1;
 210
 211     if (autocvar_r_showbboxes)
 212     {
 213         // show where spawnpoints point at too
 214         makevectors(self.angles);
 215         entity e;
 216         e = spawn();
 217         e.classname = "info_player_foo";
 218         setorigin(e, self.origin + v_forward * 24);
 219         setsize(e, '-8 -8 -8', '8 8 8');
 220         e.solid = SOLID_TRIGGER;
 221     }
 222 }
 223
 224 #define strstr strstrofs
 225 /*
 226 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 227 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 228 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 229 // BE CONSTANT OR strzoneD!
 230 float strstr(string haystack, string needle, float offset)
 231 {
 232         float len, endpos;
 233         string found;
 234         len = strlen(needle);
 235         endpos = strlen(haystack) - len;
 236         while(offset <= endpos)
 237         {
 238                 found = substring(haystack, offset, len);
 239                 if(found == needle)
 240                         return offset;
 241                 offset = offset + 1;
 242         }
 243         return -1;
 244 }
 245 */
 246
 247 float NUM_NEAREST_ENTITIES = 4;
 248 entity nearest_entity[NUM_NEAREST_ENTITIES];
 249 float nearest_length[NUM_NEAREST_ENTITIES];
 250 entity findnearest(vector point, .string field, string value, vector axismod)
 251 {
 252     entity localhead;
 253     float i;
 254     float j;
 255     float len;
 256     vector dist;
 257
 258     float num_nearest;
 259     num_nearest = 0;
 260
 261     localhead = find(world, field, value);
 262     while (localhead)
 263     {
 264         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 265             dist = localhead.oldorigin;
 266         else
 267             dist = localhead.origin;
 268         dist = dist - point;
 269         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 270         len = vlen(dist);
 271
 272         for (i = 0; i < num_nearest; ++i)
 273         {
 274             if (len < nearest_length[i])
 275                 break;
 276         }
 277
 278         // now i tells us where to insert at
 279         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 280         if (i < NUM_NEAREST_ENTITIES)
 281         {
 282             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 283             {
 284                 nearest_length[j + 1] = nearest_length[j];
 285                 nearest_entity[j + 1] = nearest_entity[j];
 286             }
 287             nearest_length[i] = len;
 288             nearest_entity[i] = localhead;
 289             if (num_nearest < NUM_NEAREST_ENTITIES)
 290                 num_nearest = num_nearest + 1;
 291         }
 292
 293         localhead = find(localhead, field, value);
 294     }
 295
 296     // now use the first one from our list that we can see
 297     for (i = 0; i < num_nearest; ++i)
 298     {
 299         traceline(point, nearest_entity[i].origin, TRUE, world);
 300         if (trace_fraction == 1)
 301         {
 302             if (i != 0)
 303             {
 304                 dprint("Nearest point (");
 305                 dprint(nearest_entity[0].netname);
 306                 dprint(") is not visible, using a visible one.\n");
 307             }
 308             return nearest_entity[i];
 309         }
 310     }
 311
 312     if (num_nearest == 0)
 313         return world;
 314
 315     dprint("Not seeing any location point, using nearest as fallback.\n");
 316     /* DEBUGGING CODE:
 317     dprint("Candidates were: ");
 318     for(j = 0; j < num_nearest; ++j)
 319     {
 320         if(j != 0)
 321                 dprint(", ");
 322         dprint(nearest_entity[j].netname);
 323     }
 324     dprint("\n");
 325     */
 326
 327     return nearest_entity[0];
 328 }
 329
 330 void spawnfunc_target_location()
 331 {
 332     self.classname = "target_location";
 333     // location name in netname
 334     // eventually support: count, teamgame selectors, line of sight?
 335 }
 336
 337 void spawnfunc_info_location()
 338 {
 339     self.classname = "target_location";
 340     self.message = self.netname;
 341 }
 342
 343 string NearestLocation(vector p)
 344 {
 345     entity loc;
 346     string ret;
 347     ret = "somewhere";
 348     loc = findnearest(p, classname, "target_location", '1 1 1');
 349     if (loc)
 350     {
 351         ret = loc.message;
 352     }
 353     else
 354     {
 355         loc = findnearest(p, target, "###item###", '1 1 4');
 356         if (loc)
 357             ret = loc.netname;
 358     }
 359     return ret;
 360 }
 361
 362 string formatmessage(string msg)
 363 {
 364         float p, p1, p2;
 365         float n;
 366         vector cursor;
 367         entity cursor_ent;
 368         string escape;
 369         string replacement;
 370         p = 0;
 371         n = 7;
 372
 373         WarpZone_crosshair_trace(self);
 374         cursor = trace_endpos;
 375         cursor_ent = trace_ent;
 376
 377         while (1) {
 378                 if (n < 1)
 379                         break; // too many replacements
 380
 381                 n = n - 1;
 382                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 383                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 384
 385                 if (p1 < 0)
 386                         p1 = p2;
 387
 388                 if (p2 < 0)
 389                         p2 = p1;
 390
 391                 p = min(p1, p2);
 392
 393                 if (p < 0)
 394                         break;
 395
 396                 replacement = substring(msg, p, 2);
 397                 escape = substring(msg, p + 1, 1);
 398
 399                 if (escape == "%")
 400                         replacement = "%";
 401                 else if (escape == "\\")
 402                         replacement = "\\";
 403                 else if (escape == "n")
 404                         replacement = "\n";
 405                 else if (escape == "a")
 406                         replacement = ftos(floor(self.armorvalue));
 407                 else if (escape == "h")
 408                         replacement = ftos(floor(self.health));
 409                 else if (escape == "l")
 410                         replacement = NearestLocation(self.origin);
 411                 else if (escape == "y")
 412                         replacement = NearestLocation(cursor);
 413                 else if (escape == "d")
 414                         replacement = NearestLocation(self.death_origin);
 415                 else if (escape == "w") {
 416                         float wep;
 417                         wep = self.weapon;
 418                         if (!wep)
 419                                 wep = self.switchweapon;
 420                         if (!wep)
 421                                 wep = self.cnt;
 422                         replacement = W_Name(wep);
 423                 } else if (escape == "W") {
 424                         if (self.items & IT_SHELLS) replacement = "shells";
 425                         else if (self.items & IT_NAILS) replacement = "bullets";
 426                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 427                         else if (self.items & IT_CELLS) replacement = "cells";
 428                         else replacement = "batteries"; // ;)
 429                 } else if (escape == "x") {
 430                         replacement = cursor_ent.netname;
 431                         if (!replacement || !cursor_ent)
 432                                 replacement = "nothing";
 433                 } else if (escape == "s")
 434                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 435                 else if (escape == "S")
 436                         replacement = ftos(vlen(self.velocity));
 437
 438                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 439                 p = p + strlen(replacement);
 440         }
 441         return msg;
 442 }
 443
 444 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 445         return (value == 0) ? FALSE : TRUE;
 446 }
 447
 448 /*
 449 =============
 450 GetCvars
 451 =============
 452 Called with:
 453   0:  sends the request
 454   >0: receives a cvar from name=argv(f) value=argv(f+1)
 455 */
 456 void GetCvars_handleString(string thisname, float f, .string field, string name)
 457 {
 458         if (f < 0)
 459         {
 460                 if (self.field)
 461                         strunzone(self.field);
 462                 self.field = string_null;
 463         }
 464         else if (f > 0)
 465         {
 466                 if (thisname == name)
 467                 {
 468                         if (self.field)
 469                                 strunzone(self.field);
 470                         self.field = strzone(argv(f + 1));
 471                 }
 472         }
 473         else
 474                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 475 }
 476 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 477 {
 478         GetCvars_handleString(thisname, f, field, name);
 479         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 480                 if (thisname == name)
 481                 {
 482                         string s;
 483                         s = func(strcat1(self.field));
 484                         if (s != self.field)
 485                         {
 486                                 strunzone(self.field);
 487                                 self.field = strzone(s);
 488                         }
 489                 }
 490 }
 491 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 492 {
 493         if (f < 0)
 494         {
 495         }
 496         else if (f > 0)
 497         {
 498                 if (thisname == name)
 499                         self.field = stof(argv(f + 1));
 500         }
 501         else
 502                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 503 }
 504 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 505 {
 506         if (f < 0)
 507         {
 508         }
 509         else if (f > 0)
 510         {
 511                 if (thisname == name)
 512                 {
 513                         if(!self.field)
 514                         {
 515                                 self.field = stof(argv(f + 1));
 516                                 if(!self.field)
 517                                         self.field = -1;
 518                         }
 519                 }
 520         }
 521         else
 522         {
 523                 if(!self.field)
 524                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 525         }
 526 }
 527 float w_getbestweapon(entity e);
 528 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 529 {
 530         string o;
 531         o = W_FixWeaponOrder_ForceComplete(wo);
 532         if(self.weaponorder_byimpulse)
 533         {
 534                 strunzone(self.weaponorder_byimpulse);
 535                 self.weaponorder_byimpulse = string_null;
 536         }
 537         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 538         return o;
 539 }
 540 void GetCvars(float f)
 541 {
 542         string s = string_null;
 543
 544         if (f > 0)
 545                 s = strcat1(argv(f));
 546
 547         get_cvars_f = f;
 548         get_cvars_s = s;
 549         MUTATOR_CALLHOOK(GetCvars);
 550         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 551         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 552         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 553         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 554         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 562         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 563         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 564         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 565         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 566         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 567         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 568         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 569         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 570         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 571         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 572         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 573
 574         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 575         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 576
 577 #ifdef ALLOW_FORCEMODELS
 578         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 579         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 580 #endif
 581         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 582         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 583         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 584         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 585         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 586
 587         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 588         if (f > 0)
 589         {
 590                 if (s == "cl_weaponpriority")
 591                         self.switchweapon = w_getbestweapon(self);
 592                 if (s == "cl_allow_uidtracking")
 593                         PlayerStats_AddPlayer(self);
 594         }
 595 }
 596
 597 void backtrace(string msg)
 598 {
 599     float dev, war;
 600     dev = autocvar_developer;
 601     war = autocvar_prvm_backtraceforwarnings;
 602     cvar_set("developer", "1");
 603     cvar_set("prvm_backtraceforwarnings", "1");
 604     print("\n");
 605     print("--- CUT HERE ---\nWARNING: ");
 606     print(msg);
 607     print("\n");
 608     remove(world); // isn't there any better way to cause a backtrace?
 609     print("\n--- CUT UNTIL HERE ---\n");
 610     cvar_set("developer", ftos(dev));
 611     cvar_set("prvm_backtraceforwarnings", ftos(war));
 612 }
 613
 614 string Team_ColorCode(float teamid)
 615 {
 616     if (teamid == COLOR_TEAM1)
 617         return "^1";
 618     else if (teamid == COLOR_TEAM2)
 619         return "^4";
 620     else if (teamid == COLOR_TEAM3)
 621         return "^3";
 622     else if (teamid == COLOR_TEAM4)
 623         return "^6";
 624     else
 625         return "^7";
 626 }
 627
 628 string Team_ColorName(float t)
 629 {
 630     // fixme: Search for team entities and get their .netname's!
 631     if (t == COLOR_TEAM1)
 632         return "Red";
 633     if (t == COLOR_TEAM2)
 634         return "Blue";
 635     if (t == COLOR_TEAM3)
 636         return "Yellow";
 637     if (t == COLOR_TEAM4)
 638         return "Pink";
 639     return "Neutral";
 640 }
 641
 642 string Team_ColorNameLowerCase(float t)
 643 {
 644     // fixme: Search for team entities and get their .netname's!
 645     if (t == COLOR_TEAM1)
 646         return "red";
 647     if (t == COLOR_TEAM2)
 648         return "blue";
 649     if (t == COLOR_TEAM3)
 650         return "yellow";
 651     if (t == COLOR_TEAM4)
 652         return "pink";
 653     return "neutral";
 654 }
 655
 656 float ColourToNumber(string team_colour)
 657 {
 658         if (team_colour == "red")
 659                 return COLOR_TEAM1;
 660
 661         if (team_colour == "blue")
 662                 return COLOR_TEAM2;
 663
 664         if (team_colour == "yellow")
 665                 return COLOR_TEAM3;
 666
 667         if (team_colour == "pink")
 668                 return COLOR_TEAM4;
 669
 670         if (team_colour == "auto")
 671                 return 0;
 672
 673         return -1;
 674 }
 675
 676 float NumberToTeamNumber(float number)
 677 {
 678         if (number == 1)
 679                 return COLOR_TEAM1;
 680
 681         if (number == 2)
 682                 return COLOR_TEAM2;
 683
 684         if (number == 3)
 685                 return COLOR_TEAM3;
 686
 687         if (number == 4)
 688                 return COLOR_TEAM4;
 689
 690         return -1;
 691 }
 692
 693 // decolorizes and team colors the player name when needed
 694 string playername(entity p)
 695 {
 696     string t;
 697     if (teamplay && !intermission_running && p.classname == "player")
 698     {
 699         t = Team_ColorCode(p.team);
 700         return strcat(t, strdecolorize(p.netname));
 701     }
 702     else
 703         return p.netname;
 704 }
 705
 706 vector randompos(vector m1, vector m2)
 707 {
 708     vector v;
 709     m2 = m2 - m1;
 710     v_x = m2_x * random() + m1_x;
 711     v_y = m2_y * random() + m1_y;
 712     v_z = m2_z * random() + m1_z;
 713     return  v;
 714 }
 715
 716 //#NO AUTOCVARS START
 717
 718 float g_pickup_shells;
 719 float g_pickup_shells_max;
 720 float g_pickup_nails;
 721 float g_pickup_nails_max;
 722 float g_pickup_rockets;
 723 float g_pickup_rockets_max;
 724 float g_pickup_cells;
 725 float g_pickup_cells_max;
 726 float g_pickup_fuel;
 727 float g_pickup_fuel_jetpack;
 728 float g_pickup_fuel_max;
 729 float g_pickup_armorsmall;
 730 float g_pickup_armorsmall_max;
 731 float g_pickup_armorsmall_anyway;
 732 float g_pickup_armormedium;
 733 float g_pickup_armormedium_max;
 734 float g_pickup_armormedium_anyway;
 735 float g_pickup_armorbig;
 736 float g_pickup_armorbig_max;
 737 float g_pickup_armorbig_anyway;
 738 float g_pickup_armorlarge;
 739 float g_pickup_armorlarge_max;
 740 float g_pickup_armorlarge_anyway;
 741 float g_pickup_healthsmall;
 742 float g_pickup_healthsmall_max;
 743 float g_pickup_healthsmall_anyway;
 744 float g_pickup_healthmedium;
 745 float g_pickup_healthmedium_max;
 746 float g_pickup_healthmedium_anyway;
 747 float g_pickup_healthlarge;
 748 float g_pickup_healthlarge_max;
 749 float g_pickup_healthlarge_anyway;
 750 float g_pickup_healthmega;
 751 float g_pickup_healthmega_max;
 752 float g_pickup_healthmega_anyway;
 753 float g_pickup_ammo_anyway;
 754 float g_pickup_weapons_anyway;
 755 float g_weaponarena;
 756 WEPSET_DECLARE_A(g_weaponarena_weapons);
 757 float g_weaponarena_random;
 758 float g_weaponarena_random_with_laser;
 759 string g_weaponarena_list;
 760 float g_weaponspeedfactor;
 761 float g_weaponratefactor;
 762 float g_weapondamagefactor;
 763 float g_weaponforcefactor;
 764 float g_weaponspreadfactor;
 765
 766 WEPSET_DECLARE_A(start_weapons);
 767 WEPSET_DECLARE_A(start_weapons_default);
 768 WEPSET_DECLARE_A(start_weapons_defaultmask);
 769 float start_items;
 770 float start_ammo_shells;
 771 float start_ammo_nails;
 772 float start_ammo_rockets;
 773 float start_ammo_cells;
 774 float start_ammo_fuel;
 775 float start_health;
 776 float start_armorvalue;
 777 WEPSET_DECLARE_A(warmup_start_weapons);
 778 WEPSET_DECLARE_A(warmup_start_weapons_default);
 779 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 780 float warmup_start_ammo_shells;
 781 float warmup_start_ammo_nails;
 782 float warmup_start_ammo_rockets;
 783 float warmup_start_ammo_cells;
 784 float warmup_start_ammo_fuel;
 785 float warmup_start_health;
 786 float warmup_start_armorvalue;
 787 float g_weapon_stay;
 788
 789 entity get_weaponinfo(float w);
 790
 791 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 792 {
 793         var float i = weaponinfo.weapon;
 794         var float d = 0;
 795
 796         if (!i)
 797                 return 0;
 798
 799         if (g_lms || g_ca || allguns)
 800         {
 801                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 802                         d = TRUE;
 803                 else
 804                         d = FALSE;
 805         }
 806         else if (g_cts)
 807                 d = (i == WEP_SHOTGUN);
 808         else if (g_nexball)
 809                 d = 0; // weapon is set a few lines later
 810         else
 811                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 812
 813         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 814                 d |= (i == WEP_HOOK);
 815         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 816                 d = 0;
 817
 818         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 819
 820         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 821
 822         // bit order in t:
 823         // 1: want or not
 824         // 2: is default?
 825         // 4: is set by default?
 826         if(t < 0)
 827                 t = 4 | (3 * d);
 828         else
 829                 t |= (2 * d);
 830
 831         return t;
 832 }
 833
 834 void readplayerstartcvars()
 835 {
 836         entity e;
 837         float i, j, t;
 838         string s;
 839
 840         // initialize starting values for players
 841         WEPSET_CLEAR_A(start_weapons);
 842         WEPSET_CLEAR_A(start_weapons_default);
 843         WEPSET_CLEAR_A(start_weapons_defaultmask);
 844         start_items = 0;
 845         start_ammo_shells = 0;
 846         start_ammo_nails = 0;
 847         start_ammo_rockets = 0;
 848         start_ammo_cells = 0;
 849         start_health = cvar("g_balance_health_start");
 850         start_armorvalue = cvar("g_balance_armor_start");
 851
 852         g_weaponarena = 0;
 853         WEPSET_CLEAR_A(g_weaponarena_weapons);
 854
 855         s = cvar_string("g_weaponarena");
 856         if (s == "0" || s == "")
 857         {
 858                 if(g_lms || g_ca)
 859                         s = "most";
 860         }
 861
 862         if (s == "0" || s == "")
 863         {
 864                 // no arena
 865         }
 866         else if (s == "off")
 867         {
 868                 // forcibly turn off weaponarena
 869         }
 870         else if (s == "all")
 871         {
 872                 g_weaponarena = 1;
 873                 g_weaponarena_list = "All Weapons";
 874                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 875                 {
 876                         e = get_weaponinfo(j);
 877                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 878                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 879                 }
 880         }
 881         else if (s == "most")
 882         {
 883                 g_weaponarena = 1;
 884                 g_weaponarena_list = "Most Weapons";
 885                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 886                 {
 887                         e = get_weaponinfo(j);
 888                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 889                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 890                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 891                 }
 892         }
 893         else if (s == "none")
 894         {
 895                 g_weaponarena = 1;
 896                 g_weaponarena_list = "No Weapons";
 897         }
 898         else
 899         {
 900                 g_weaponarena = 1;
 901                 t = tokenize_console(s);
 902                 g_weaponarena_list = "";
 903                 for (i = 0; i < t; ++i)
 904                 {
 905                         s = argv(i);
 906                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 907                         {
 908                                 e = get_weaponinfo(j);
 909                                 if (e.netname == s)
 910                                 {
 911                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 912                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 913                                         break;
 914                                 }
 915                         }
 916                         if (j > WEP_LAST)
 917                         {
 918                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 919                         }
 920                 }
 921                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 922         }
 923
 924         if(g_weaponarena)
 925                 g_weaponarena_random = cvar("g_weaponarena_random");
 926         else
 927                 g_weaponarena_random = 0;
 928         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 929
 930         if (g_weaponarena)
 931         {
 932                 g_minstagib = 0; // incompatible
 933                 g_pinata = 0; // incompatible
 934                 g_weapon_stay = 0; // incompatible
 935                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 936                 if(!(g_lms || g_ca))
 937                         start_items |= IT_UNLIMITED_AMMO;
 938         }
 939         else if (g_minstagib)
 940         {
 941                 g_pinata = 0; // incompatible
 942                 g_weapon_stay = 0; // incompatible
 943                 g_bloodloss = 0; // incompatible
 944                 start_health = 100;
 945                 start_armorvalue = 0;
 946                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 947                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 948                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 949
 950                 if (g_minstagib_invis_alpha <= 0)
 951                         g_minstagib_invis_alpha = -1;
 952         }
 953         else
 954         {
 955                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 956                 {
 957                         e = get_weaponinfo(i);
 958                         float w = want_weapon("g_start_weapon_", e, FALSE);
 959                         if(w & 1)
 960                                 WEPSET_OR_AW(start_weapons, i);
 961                         if(w & 2)
 962                                 WEPSET_OR_AW(start_weapons_default, i);
 963                         if(w & 4)
 964                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 965                 }
 966         }
 967
 968         if(!cvar("g_use_ammunition"))
 969                 start_items |= IT_UNLIMITED_AMMO;
 970
 971         if(cvar("g_nexball"))
 972                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 973
 974         if(g_minstagib)
 975         {
 976                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 977                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 978         }
 979         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 980         {
 981                 start_ammo_rockets = 999;
 982                 start_ammo_shells = 999;
 983                 start_ammo_cells = 999;
 984                 start_ammo_nails = 999;
 985                 start_ammo_fuel = 999;
 986         }
 987         else
 988         {
 989                 if(g_lms || g_ca)
 990                 {
 991                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 992                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 993                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 994                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 995                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 996                 }
 997                 else
 998                 {
 999                         start_ammo_shells = cvar("g_start_ammo_shells");
1000                         start_ammo_nails = cvar("g_start_ammo_nails");
1001                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1002                         start_ammo_cells = cvar("g_start_ammo_cells");
1003                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1004                 }
1005         }
1006
1007         if (g_lms || g_ca)
1008         {
1009                 start_health = cvar("g_lms_start_health");
1010                 start_armorvalue = cvar("g_lms_start_armor");
1011         }
1012
1013         if (inWarmupStage)
1014         {
1015                 warmup_start_ammo_shells = start_ammo_shells;
1016                 warmup_start_ammo_nails = start_ammo_nails;
1017                 warmup_start_ammo_rockets = start_ammo_rockets;
1018                 warmup_start_ammo_cells = start_ammo_cells;
1019                 warmup_start_ammo_fuel = start_ammo_fuel;
1020                 warmup_start_health = start_health;
1021                 warmup_start_armorvalue = start_armorvalue;
1022                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
1023                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
1024                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
1025
1026                 if (!g_weaponarena && !g_minstagib && !g_ca)
1027                 {
1028                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1029                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1030                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1031                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1032                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1033                         warmup_start_health = cvar("g_warmup_start_health");
1034                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1035                         WEPSET_CLEAR_A(warmup_start_weapons);
1036                         WEPSET_CLEAR_A(warmup_start_weapons_default);
1037                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
1038                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1039                         {
1040                                 e = get_weaponinfo(i);
1041                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
1042                                 if(w & 1)
1043                                         WEPSET_OR_AW(warmup_start_weapons, i);
1044                                 if(w & 2)
1045                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
1046                                 if(w & 4)
1047                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
1048                         }
1049                 }
1050         }
1051
1052         if (g_jetpack)
1053                 start_items |= IT_JETPACK;
1054
1055         MUTATOR_CALLHOOK(SetStartItems);
1056
1057         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
1058         {
1059                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1060                 start_items |= IT_FUEL_REGEN;
1061                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1062                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1063         }
1064
1065         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1066         {
1067                 e = get_weaponinfo(i);
1068                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
1069                         weapon_action(i, WR_PRECACHE);
1070         }
1071
1072         start_ammo_shells = max(0, start_ammo_shells);
1073         start_ammo_nails = max(0, start_ammo_nails);
1074         start_ammo_cells = max(0, start_ammo_cells);
1075         start_ammo_rockets = max(0, start_ammo_rockets);
1076         start_ammo_fuel = max(0, start_ammo_fuel);
1077
1078         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1079         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1080         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1081         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1082         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1083 }
1084
1085 float g_bugrigs;
1086 float g_bugrigs_planar_movement;
1087 float g_bugrigs_planar_movement_car_jumping;
1088 float g_bugrigs_reverse_spinning;
1089 float g_bugrigs_reverse_speeding;
1090 float g_bugrigs_reverse_stopping;
1091 float g_bugrigs_air_steering;
1092 float g_bugrigs_angle_smoothing;
1093 float g_bugrigs_friction_floor;
1094 float g_bugrigs_friction_brake;
1095 float g_bugrigs_friction_air;
1096 float g_bugrigs_accel;
1097 float g_bugrigs_speed_ref;
1098 float g_bugrigs_speed_pow;
1099 float g_bugrigs_steer;
1100
1101 float g_touchexplode;
1102 float g_touchexplode_radius;
1103 float g_touchexplode_damage;
1104 float g_touchexplode_edgedamage;
1105 float g_touchexplode_force;
1106
1107 float sv_autotaunt;
1108 float sv_taunt;
1109
1110 float sv_pitch_min;
1111 float sv_pitch_max;
1112 float sv_pitch_fixyaw;
1113
1114 string GetGametype(); // g_world.qc
1115 void readlevelcvars(void)
1116 {
1117         g_minstagib = cvar("g_minstagib");
1118
1119         // load ALL the mutators
1120         if(cvar("g_dodging"))
1121                 MUTATOR_ADD(mutator_dodging);
1122         if(cvar("g_spawn_near_teammate"))
1123                 MUTATOR_ADD(mutator_spawn_near_teammate);
1124         if(!g_minstagib)
1125         {
1126                 if(cvar("g_invincible_projectiles"))
1127                         MUTATOR_ADD(mutator_invincibleprojectiles);
1128                 if(cvar("g_new_toys"))
1129                         MUTATOR_ADD(mutator_new_toys);
1130                 if(cvar("g_nix"))
1131                         MUTATOR_ADD(mutator_nix);
1132                 if(cvar("g_rocket_flying"))
1133                         MUTATOR_ADD(mutator_rocketflying);
1134                 if(cvar("g_vampire"))
1135                         MUTATOR_ADD(mutator_vampire);
1136                 if(cvar("g_superspectate"))
1137                         MUTATOR_ADD(mutator_superspec);
1138         }
1139
1140         // is this a mutator? is this a mode?
1141         if(cvar("g_sandbox"))
1142                 MUTATOR_ADD(sandbox);
1143
1144         if(cvar("sv_allow_fullbright"))
1145                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1146
1147     g_bugrigs = cvar("g_bugrigs");
1148     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1149     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1150     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1151     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1152     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1153     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1154     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1155     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1156     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1157     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1158     g_bugrigs_accel = cvar("g_bugrigs_accel");
1159     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1160     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1161     g_bugrigs_steer = cvar("g_bugrigs_steer");
1162
1163     g_touchexplode = cvar("g_touchexplode");
1164     g_touchexplode_radius = cvar("g_touchexplode_radius");
1165     g_touchexplode_damage = cvar("g_touchexplode_damage");
1166     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1167     g_touchexplode_force = cvar("g_touchexplode_force");
1168
1169 #ifdef ALLOW_FORCEMODELS
1170         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1171 #endif
1172
1173         sv_clones = cvar("sv_clones");
1174         sv_foginterval = cvar("sv_foginterval");
1175         g_cloaked = cvar("g_cloaked");
1176     if(g_cts)
1177         g_cloaked = 1; // always enable cloak in CTS
1178         g_jump_grunt = cvar("g_jump_grunt");
1179         g_footsteps = cvar("g_footsteps");
1180         g_grappling_hook = cvar("g_grappling_hook");
1181         g_jetpack = cvar("g_jetpack");
1182         g_midair = cvar("g_midair");
1183         g_norecoil = cvar("g_norecoil");
1184         g_bloodloss = cvar("g_bloodloss");
1185         sv_maxidle = cvar("sv_maxidle");
1186         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1187         sv_autotaunt = cvar("sv_autotaunt");
1188         sv_taunt = cvar("sv_taunt");
1189
1190         inWarmupStage = cvar("g_warmup");
1191         g_warmup_limit = cvar("g_warmup_limit");
1192         g_warmup_allguns = cvar("g_warmup_allguns");
1193         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1194
1195         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1196                 inWarmupStage = 0; // these modes cannot work together, sorry
1197
1198         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1199         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1200         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1201         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1202         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1203         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1204         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1205         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1206         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1207         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1208         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1209         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1210         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1211         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1212
1213         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1214         g_weaponratefactor = cvar("g_weaponratefactor");
1215         g_weapondamagefactor = cvar("g_weapondamagefactor");
1216         g_weaponforcefactor = cvar("g_weaponforcefactor");
1217         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1218
1219         g_pickup_shells = cvar("g_pickup_shells");
1220         g_pickup_shells_max = cvar("g_pickup_shells_max");
1221         g_pickup_nails = cvar("g_pickup_nails");
1222         g_pickup_nails_max = cvar("g_pickup_nails_max");
1223         g_pickup_rockets = cvar("g_pickup_rockets");
1224         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1225         g_pickup_cells = cvar("g_pickup_cells");
1226         g_pickup_cells_max = cvar("g_pickup_cells_max");
1227         g_pickup_fuel = cvar("g_pickup_fuel");
1228         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1229         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1230         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1231         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1232         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1233         g_pickup_armormedium = cvar("g_pickup_armormedium");
1234         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1235         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1236         g_pickup_armorbig = cvar("g_pickup_armorbig");
1237         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1238         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1239         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1240         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1241         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1242         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1243         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1244         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1245         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1246         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1247         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1248         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1249         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1250         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1251         g_pickup_healthmega = cvar("g_pickup_healthmega");
1252         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1253         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1254
1255         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1256         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1257
1258         g_pinata = cvar("g_pinata");
1259
1260     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1261     if(!g_weapon_stay)
1262         g_weapon_stay = cvar("g_weapon_stay");
1263
1264         if not(inWarmupStage && !g_ca)
1265                 game_starttime = cvar("g_start_delay");
1266
1267         sv_pitch_min = cvar("sv_pitch_min");
1268         sv_pitch_max = cvar("sv_pitch_max");
1269         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1270
1271         readplayerstartcvars();
1272 }
1273
1274 //#NO AUTOCVARS END
1275
1276 // Sound functions
1277 string precache_sound (string s) = #19;
1278 float precache_sound_index (string s) = #19;
1279
1280 #define SND_VOLUME      1
1281 #define SND_ATTENUATION 2
1282 #define SND_LARGEENTITY 8
1283 #define SND_LARGESOUND  16
1284
1285 float sound_allowed(float dest, entity e)
1286 {
1287     // sounds from world may always pass
1288     for (;;)
1289     {
1290         if (e.classname == "body")
1291             e = e.enemy;
1292         else if (e.realowner && e.realowner != e)
1293             e = e.realowner;
1294         else if (e.owner && e.owner != e)
1295             e = e.owner;
1296         else
1297             break;
1298     }
1299     // sounds to self may always pass
1300     if (dest == MSG_ONE)
1301         if (e == msg_entity)
1302             return TRUE;
1303     // sounds by players can be removed
1304     if (autocvar_bot_sound_monopoly)
1305         if (clienttype(e) == CLIENTTYPE_REAL)
1306             return FALSE;
1307     // anything else may pass
1308     return TRUE;
1309 }
1310
1311 #ifdef COMPAT_XON010_CHANNELS
1312 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1313 void sound(entity e, float chan, string samp, float vol, float atten)
1314 {
1315     if (!sound_allowed(MSG_BROADCAST, e))
1316         return;
1317     builtin_sound(e, chan, samp, vol, atten);
1318 }
1319 #else
1320 #undef sound
1321 void sound(entity e, float chan, string samp, float vol, float atten)
1322 {
1323     if (!sound_allowed(MSG_BROADCAST, e))
1324         return;
1325     sound7(e, chan, samp, vol, atten, 0, 0);
1326 }
1327 #endif
1328
1329 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1330 {
1331     float entno, idx;
1332
1333     if (!sound_allowed(dest, e))
1334         return;
1335
1336     entno = num_for_edict(e);
1337     idx = precache_sound_index(samp);
1338
1339     float sflags;
1340     sflags = 0;
1341
1342     atten = floor(atten * 64);
1343     vol = floor(vol * 255);
1344
1345     if (vol != 255)
1346         sflags |= SND_VOLUME;
1347     if (atten != 64)
1348         sflags |= SND_ATTENUATION;
1349     if (entno >= 8192 || chan < 0 || chan > 7)
1350         sflags |= SND_LARGEENTITY;
1351     if (idx >= 256)
1352         sflags |= SND_LARGESOUND;
1353
1354     WriteByte(dest, SVC_SOUND);
1355     WriteByte(dest, sflags);
1356     if (sflags & SND_VOLUME)
1357         WriteByte(dest, vol);
1358     if (sflags & SND_ATTENUATION)
1359         WriteByte(dest, atten);
1360     if (sflags & SND_LARGEENTITY)
1361     {
1362         WriteShort(dest, entno);
1363         WriteByte(dest, chan);
1364     }
1365     else
1366     {
1367         WriteShort(dest, entno * 8 + chan);
1368     }
1369     if (sflags & SND_LARGESOUND)
1370         WriteShort(dest, idx);
1371     else
1372         WriteByte(dest, idx);
1373
1374     WriteCoord(dest, o_x);
1375     WriteCoord(dest, o_y);
1376     WriteCoord(dest, o_z);
1377 }
1378 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1379 {
1380     vector o;
1381
1382     if (!sound_allowed(dest, e))
1383         return;
1384
1385     o = e.origin + 0.5 * (e.mins + e.maxs);
1386     soundtoat(dest, e, o, chan, samp, vol, atten);
1387 }
1388 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1389 {
1390     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1391 }
1392 void stopsoundto(float dest, entity e, float chan)
1393 {
1394     float entno;
1395
1396     if (!sound_allowed(dest, e))
1397         return;
1398
1399     entno = num_for_edict(e);
1400
1401     if (entno >= 8192 || chan < 0 || chan > 7)
1402     {
1403         float idx, sflags;
1404         idx = precache_sound_index("misc/null.wav");
1405         sflags = SND_LARGEENTITY;
1406         if (idx >= 256)
1407             sflags |= SND_LARGESOUND;
1408         WriteByte(dest, SVC_SOUND);
1409         WriteByte(dest, sflags);
1410         WriteShort(dest, entno);
1411         WriteByte(dest, chan);
1412         if (sflags & SND_LARGESOUND)
1413             WriteShort(dest, idx);
1414         else
1415             WriteByte(dest, idx);
1416         WriteCoord(dest, e.origin_x);
1417         WriteCoord(dest, e.origin_y);
1418         WriteCoord(dest, e.origin_z);
1419     }
1420     else
1421     {
1422         WriteByte(dest, SVC_STOPSOUND);
1423         WriteShort(dest, entno * 8 + chan);
1424     }
1425 }
1426 void stopsound(entity e, float chan)
1427 {
1428     if (!sound_allowed(MSG_BROADCAST, e))
1429         return;
1430
1431     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1432     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1433 }
1434
1435 void play2(entity e, string filename)
1436 {
1437     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1438     msg_entity = e;
1439     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1440 }
1441
1442 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1443 .float spamtime;
1444 float spamsound(entity e, float chan, string samp, float vol, float atten)
1445 {
1446     if (!sound_allowed(MSG_BROADCAST, e))
1447         return FALSE;
1448
1449     if (time > e.spamtime)
1450     {
1451         e.spamtime = time;
1452         sound(e, chan, samp, vol, atten);
1453         return TRUE;
1454     }
1455     return FALSE;
1456 }
1457
1458 void play2team(float t, string filename)
1459 {
1460     entity head;
1461
1462     if (autocvar_bot_sound_monopoly)
1463         return;
1464
1465     FOR_EACH_REALPLAYER(head)
1466     {
1467         if (head.team == t)
1468             play2(head, filename);
1469     }
1470 }
1471
1472 void play2all(string samp)
1473 {
1474     if (autocvar_bot_sound_monopoly)
1475         return;
1476
1477     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1478 }
1479
1480 void PrecachePlayerSounds(string f);
1481 void precache_playermodel(string m)
1482 {
1483         float globhandle, i, n;
1484         string f;
1485
1486         if(substring(m, -9,5) == "_lod1")
1487                 return;
1488         if(substring(m, -9,5) == "_lod2")
1489                 return;
1490         precache_model(m);
1491         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1492         if(fexists(f))
1493                 precache_model(f);
1494         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1495         if(fexists(f))
1496                 precache_model(f);
1497
1498         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1499         if (globhandle < 0)
1500                 return;
1501         n = search_getsize(globhandle);
1502         for (i = 0; i < n; ++i)
1503         {
1504                 //print(search_getfilename(globhandle, i), "\n");
1505                 f = search_getfilename(globhandle, i);
1506                 PrecachePlayerSounds(f);
1507         }
1508         search_end(globhandle);
1509 }
1510 void precache_all_playermodels(string pattern)
1511 {
1512         float globhandle, i, n;
1513         string f;
1514
1515         globhandle = search_begin(pattern, TRUE, FALSE);
1516         if (globhandle < 0)
1517                 return;
1518         n = search_getsize(globhandle);
1519         for (i = 0; i < n; ++i)
1520         {
1521                 //print(search_getfilename(globhandle, i), "\n");
1522                 f = search_getfilename(globhandle, i);
1523                 precache_playermodel(f);
1524         }
1525         search_end(globhandle);
1526 }
1527
1528 void precache()
1529 {
1530     // gamemode related things
1531     precache_model ("models/misc/chatbubble.spr");
1532     if (g_runematch)
1533     {
1534         precache_model ("models/runematch/curse.mdl");
1535         precache_model ("models/runematch/rune.mdl");
1536     }
1537
1538 #ifdef TTURRETS_ENABLED
1539     if (autocvar_g_turrets)
1540         turrets_precash();
1541 #endif
1542
1543     // Precache all player models if desired
1544     if (autocvar_sv_precacheplayermodels)
1545     {
1546         PrecachePlayerSounds("sound/player/default.sounds");
1547         precache_all_playermodels("models/player/*.zym");
1548         precache_all_playermodels("models/player/*.dpm");
1549         precache_all_playermodels("models/player/*.md3");
1550         precache_all_playermodels("models/player/*.psk");
1551         precache_all_playermodels("models/player/*.iqm");
1552     }
1553
1554     if (autocvar_sv_defaultcharacter)
1555     {
1556         string s;
1557         s = autocvar_sv_defaultplayermodel_red;
1558         if (s != "")
1559             precache_playermodel(s);
1560         s = autocvar_sv_defaultplayermodel_blue;
1561         if (s != "")
1562             precache_playermodel(s);
1563         s = autocvar_sv_defaultplayermodel_yellow;
1564         if (s != "")
1565             precache_playermodel(s);
1566         s = autocvar_sv_defaultplayermodel_pink;
1567         if (s != "")
1568             precache_playermodel(s);
1569         s = autocvar_sv_defaultplayermodel;
1570         if (s != "")
1571             precache_playermodel(s);
1572     }
1573
1574     if (g_footsteps)
1575     {
1576         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1577         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1578     }
1579
1580     // gore and miscellaneous sounds
1581     //precache_sound ("misc/h2ohit.wav");
1582     precache_model ("models/hook.md3");
1583     precache_sound ("misc/armorimpact.wav");
1584     precache_sound ("misc/bodyimpact1.wav");
1585     precache_sound ("misc/bodyimpact2.wav");
1586     precache_sound ("misc/gib.wav");
1587     precache_sound ("misc/gib_splat01.wav");
1588     precache_sound ("misc/gib_splat02.wav");
1589     precache_sound ("misc/gib_splat03.wav");
1590     precache_sound ("misc/gib_splat04.wav");
1591     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1592     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1593     precache_sound ("misc/null.wav");
1594     precache_sound ("misc/spawn.wav");
1595     precache_sound ("misc/talk.wav");
1596     precache_sound ("misc/teleport.wav");
1597     precache_sound ("misc/poweroff.wav");
1598     precache_sound ("player/lava.wav");
1599     precache_sound ("player/slime.wav");
1600
1601     if (g_jetpack)
1602         precache_sound ("misc/jetpack_fly.wav");
1603
1604     precache_model ("models/sprites/0.spr32");
1605     precache_model ("models/sprites/1.spr32");
1606     precache_model ("models/sprites/2.spr32");
1607     precache_model ("models/sprites/3.spr32");
1608     precache_model ("models/sprites/4.spr32");
1609     precache_model ("models/sprites/5.spr32");
1610     precache_model ("models/sprites/6.spr32");
1611     precache_model ("models/sprites/7.spr32");
1612     precache_model ("models/sprites/8.spr32");
1613     precache_model ("models/sprites/9.spr32");
1614     precache_model ("models/sprites/10.spr32");
1615
1616     // common weapon precaches
1617         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1618     precache_sound ("weapons/weapon_switch.wav");
1619     precache_sound ("weapons/weaponpickup.wav");
1620     precache_sound ("weapons/unavailable.wav");
1621     precache_sound ("weapons/dryfire.wav");
1622     if (g_grappling_hook)
1623     {
1624         precache_sound ("weapons/hook_fire.wav"); // hook
1625         precache_sound ("weapons/hook_impact.wav"); // hook
1626     }
1627
1628     if(autocvar_sv_precacheweapons)
1629     {
1630         //precache weapon models/sounds
1631         float wep;
1632         wep = WEP_FIRST;
1633         while (wep <= WEP_LAST)
1634         {
1635             weapon_action(wep, WR_PRECACHE);
1636             wep = wep + 1;
1637         }
1638     }
1639
1640     precache_model("models/elaser.mdl");
1641     precache_model("models/laser.mdl");
1642     precache_model("models/ebomb.mdl");
1643
1644 #if 0
1645     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1646
1647     if (!self.noise && self.music) // quake 3 uses the music field
1648         self.noise = self.music;
1649
1650     // plays music for the level if there is any
1651     if (self.noise)
1652     {
1653         precache_sound (self.noise);
1654         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1655     }
1656 #endif
1657 }
1658
1659 // WARNING: this kills the trace globals
1660 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1661 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1662
1663 #define INITPRIO_FIRST              0
1664 #define INITPRIO_GAMETYPE           0
1665 #define INITPRIO_GAMETYPE_FALLBACK  1
1666 #define INITPRIO_FINDTARGET        10
1667 #define INITPRIO_DROPTOFLOOR       20
1668 #define INITPRIO_SETLOCATION       90
1669 #define INITPRIO_LINKDOORS         91
1670 #define INITPRIO_LAST              99
1671
1672 .void(void) initialize_entity;
1673 .float initialize_entity_order;
1674 .entity initialize_entity_next;
1675 entity initialize_entity_first;
1676
1677 void make_safe_for_remove(entity e)
1678 {
1679     if (e.initialize_entity)
1680     {
1681         entity ent, prev = world;
1682         for (ent = initialize_entity_first; ent; )
1683         {
1684             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1685             {
1686                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1687                 // skip it in linked list
1688                 if (prev)
1689                 {
1690                     prev.initialize_entity_next = ent.initialize_entity_next;
1691                     ent = prev.initialize_entity_next;
1692                 }
1693                 else
1694                 {
1695                     initialize_entity_first = ent.initialize_entity_next;
1696                     ent = initialize_entity_first;
1697                 }
1698             }
1699             else
1700             {
1701                 prev = ent;
1702                 ent = ent.initialize_entity_next;
1703             }
1704         }
1705     }
1706 }
1707
1708 void objerror(string s)
1709 {
1710     make_safe_for_remove(self);
1711     builtin_objerror(s);
1712 }
1713
1714 .float remove_except_protected_forbidden;
1715 void remove_except_protected(entity e)
1716 {
1717         if(e.remove_except_protected_forbidden)
1718                 error("not allowed to remove this at this point");
1719         builtin_remove(e);
1720 }
1721
1722 void remove_unsafely(entity e)
1723 {
1724     if(e.classname == "spike")
1725         error("Removing spikes is forbidden (crylink bug), please report");
1726     builtin_remove(e);
1727 }
1728
1729 void remove_safely(entity e)
1730 {
1731     make_safe_for_remove(e);
1732     builtin_remove(e);
1733 }
1734
1735 void InitializeEntity(entity e, void(void) func, float order)
1736 {
1737     entity prev, cur;
1738
1739     if (!e || e.initialize_entity)
1740     {
1741         // make a proxy initializer entity
1742         entity e_old;
1743         e_old = e;
1744         e = spawn();
1745         e.classname = "initialize_entity";
1746         e.enemy = e_old;
1747     }
1748
1749     e.initialize_entity = func;
1750     e.initialize_entity_order = order;
1751
1752     cur = initialize_entity_first;
1753     prev = world;
1754     for (;;)
1755     {
1756         if (!cur || cur.initialize_entity_order > order)
1757         {
1758             // insert between prev and cur
1759             if (prev)
1760                 prev.initialize_entity_next = e;
1761             else
1762                 initialize_entity_first = e;
1763             e.initialize_entity_next = cur;
1764             return;
1765         }
1766         prev = cur;
1767         cur = cur.initialize_entity_next;
1768     }
1769 }
1770 void InitializeEntitiesRun()
1771 {
1772     entity startoflist;
1773     startoflist = initialize_entity_first;
1774     initialize_entity_first = world;
1775     remove = remove_except_protected;
1776     for (self = startoflist; self; self = self.initialize_entity_next)
1777     {
1778         self.remove_except_protected_forbidden = 1;
1779     }
1780     for (self = startoflist; self; )
1781     {
1782         entity e;
1783         var void(void) func;
1784         e = self.initialize_entity_next;
1785         func = self.initialize_entity;
1786         self.initialize_entity_order = 0;
1787         self.initialize_entity = func_null;
1788         self.initialize_entity_next = world;
1789         self.remove_except_protected_forbidden = 0;
1790         if (self.classname == "initialize_entity")
1791         {
1792             entity e_old;
1793             e_old = self.enemy;
1794             builtin_remove(self);
1795             self = e_old;
1796         }
1797         //dprint("Delayed initialization: ", self.classname, "\n");
1798         if(func != func_null)
1799             func();
1800         else
1801         {
1802             eprint(self);
1803             backtrace(strcat("Null function in: ", self.classname, "\n"));
1804         }
1805         self = e;
1806     }
1807     remove = remove_unsafely;
1808 }
1809
1810 .float uncustomizeentityforclient_set;
1811 .void(void) uncustomizeentityforclient;
1812 void(void) SUB_Nullpointer = #0;
1813 void UncustomizeEntitiesRun()
1814 {
1815     entity oldself;
1816     oldself = self;
1817     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1818         self.uncustomizeentityforclient();
1819     self = oldself;
1820 }
1821 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1822 {
1823     e.customizeentityforclient = customizer;
1824     e.uncustomizeentityforclient = uncustomizer;
1825     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1826 }
1827
1828 .float nottargeted;
1829 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1830
1831 void() SUB_Remove;
1832 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1833 {
1834     vector mi, ma;
1835
1836     if (e.classname == "")
1837         e.classname = "net_linked";
1838
1839     if (e.model == "" || self.modelindex == 0)
1840     {
1841         mi = e.mins;
1842         ma = e.maxs;
1843         setmodel(e, "null");
1844         setsize(e, mi, ma);
1845     }
1846
1847     e.SendEntity = sendfunc;
1848     e.SendFlags = 0xFFFFFF;
1849
1850     if (!docull)
1851         e.effects |= EF_NODEPTHTEST;
1852
1853     if (dt)
1854     {
1855         e.nextthink = time + dt;
1856         e.think = SUB_Remove;
1857     }
1858 }
1859
1860 void adaptor_think2touch()
1861 {
1862     entity o;
1863     o = other;
1864     other = world;
1865     self.touch();
1866     other = o;
1867 }
1868
1869 void adaptor_think2use()
1870 {
1871     entity o, a;
1872     o = other;
1873     a = activator;
1874     activator = world;
1875     other = world;
1876     self.use();
1877     other = o;
1878     activator = a;
1879 }
1880
1881 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1882 {
1883         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1884                 self.projectiledeathtype |= HITTYPE_SPLASH;
1885         adaptor_think2use();
1886 }
1887
1888 // deferred dropping
1889 void DropToFloor_Handler()
1890 {
1891     builtin_droptofloor();
1892     self.dropped_origin = self.origin;
1893 }
1894
1895 void droptofloor()
1896 {
1897     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1898 }
1899
1900
1901
1902 float trace_hits_box_a0, trace_hits_box_a1;
1903
1904 float trace_hits_box_1d(float end, float thmi, float thma)
1905 {
1906     if (end == 0)
1907     {
1908         // just check if x is in range
1909         if (0 < thmi)
1910             return FALSE;
1911         if (0 > thma)
1912             return FALSE;
1913     }
1914     else
1915     {
1916         // do the trace with respect to x
1917         // 0 -> end has to stay in thmi -> thma
1918         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1919         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1920         if (trace_hits_box_a0 > trace_hits_box_a1)
1921             return FALSE;
1922     }
1923     return TRUE;
1924 }
1925
1926 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1927 {
1928     end -= start;
1929     thmi -= start;
1930     thma -= start;
1931     // now it is a trace from 0 to end
1932
1933     trace_hits_box_a0 = 0;
1934     trace_hits_box_a1 = 1;
1935
1936     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1937         return FALSE;
1938     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1939         return FALSE;
1940     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1941         return FALSE;
1942
1943     return TRUE;
1944 }
1945
1946 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1947 {
1948     return trace_hits_box(start, end, thmi - ma, thma - mi);
1949 }
1950
1951 float SUB_NoImpactCheck()
1952 {
1953         // zero hitcontents = this is not the real impact, but either the
1954         // mirror-impact of something hitting the projectile instead of the
1955         // projectile hitting the something, or a touchareagrid one. Neither of
1956         // these stop the projectile from moving, so...
1957         if(trace_dphitcontents == 0)
1958         {
1959                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1960                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1961                 checkclient();
1962         }
1963     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1964         return 1;
1965     if (other == world && self.size != '0 0 0')
1966     {
1967         vector tic;
1968         tic = self.velocity * sys_frametime;
1969         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1970         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1971         if (trace_fraction >= 1)
1972         {
1973             dprint("Odd... did not hit...?\n");
1974         }
1975         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1976         {
1977             dprint("Detected and prevented the sky-grapple bug.\n");
1978             return 1;
1979         }
1980     }
1981
1982     return 0;
1983 }
1984
1985 #define SUB_OwnerCheck() (other && (other == self.owner))
1986
1987 void RemoveGrapplingHook(entity pl);
1988 void W_Crylink_Dequeue(entity e);
1989 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1990 {
1991         if(SUB_OwnerCheck())
1992                 return TRUE;
1993         if(SUB_NoImpactCheck())
1994         {
1995                 if(self.classname == "grapplinghook")
1996                         RemoveGrapplingHook(self.realowner);
1997                 else if(self.classname == "spike")
1998                 {
1999                         W_Crylink_Dequeue(self);
2000                         remove(self);
2001                 }
2002                 else
2003                         remove(self);
2004                 return TRUE;
2005         }
2006         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2007                 UpdateCSQCProjectile(self);
2008         return FALSE;
2009 }
2010 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2011
2012 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
2013 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
2014
2015 void URI_Get_Callback(float id, float status, string data)
2016 {
2017         if(url_URI_Get_Callback(id, status, data))
2018         {
2019                 // handled
2020         }
2021         else if (id == URI_GET_DISCARD)
2022         {
2023                 // discard
2024         }
2025         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
2026         {
2027                 // sv_cmd curl
2028                 Curl_URI_Get_Callback(id, status, data);
2029         }
2030         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2031         {
2032                 // online ban list
2033                 OnlineBanList_URI_Get_Callback(id, status, data);
2034         }
2035         else
2036         {
2037                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2038         }
2039 }
2040
2041 string uid2name(string myuid) {
2042         string s;
2043         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2044
2045         // FIXME remove this later after 0.6 release
2046         // convert old style broken records to correct style
2047         if(s == "")
2048         {
2049                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2050                 if(s != "")
2051                 {
2052                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2053                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2054                 }
2055         }
2056
2057         if(s == "")
2058                 s = "^1Unregistered Player";
2059         return s;
2060 }
2061
2062 float race_readTime(string map, float pos)
2063 {
2064         string rr;
2065         if(g_cts)
2066                 rr = CTS_RECORD;
2067         else
2068                 rr = RACE_RECORD;
2069
2070         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2071 }
2072
2073 string race_readUID(string map, float pos)
2074 {
2075         string rr;
2076         if(g_cts)
2077                 rr = CTS_RECORD;
2078         else
2079                 rr = RACE_RECORD;
2080
2081         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2082 }
2083
2084 float race_readPos(string map, float t) {
2085         float i;
2086         for (i = 1; i <= RANKINGS_CNT; ++i)
2087                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2088                         return i;
2089
2090         return 0; // pos is zero if unranked
2091 }
2092
2093 void race_writeTime(string map, float t, string myuid)
2094 {
2095         string rr;
2096         if(g_cts)
2097                 rr = CTS_RECORD;
2098         else
2099                 rr = RACE_RECORD;
2100
2101         float newpos;
2102         newpos = race_readPos(map, t);
2103
2104         float i, prevpos = 0;
2105         for(i = 1; i <= RANKINGS_CNT; ++i)
2106         {
2107                 if(race_readUID(map, i) == myuid)
2108                         prevpos = i;
2109         }
2110         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2111                 for (i = prevpos; i > newpos; --i) {
2112                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2113                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2114                 }
2115         } else { // player has no ranked record yet
2116                 for (i = RANKINGS_CNT; i > newpos; --i) {
2117                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2118                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2119                 }
2120         }
2121
2122         // store new time itself
2123         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2124         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2125 }
2126
2127 string race_readName(string map, float pos)
2128 {
2129         string rr;
2130         if(g_cts)
2131                 rr = CTS_RECORD;
2132         else
2133                 rr = RACE_RECORD;
2134
2135         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2136 }
2137
2138 string race_placeName(float pos) {
2139         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2140         {
2141                 if(mod(pos, 10) == 1)
2142                         return strcat(ftos(pos), "st");
2143                 else if(mod(pos, 10) == 2)
2144                         return strcat(ftos(pos), "nd");
2145                 else if(mod(pos, 10) == 3)
2146                         return strcat(ftos(pos), "rd");
2147                 else
2148                         return strcat(ftos(pos), "th");
2149         }
2150         else
2151                 return strcat(ftos(pos), "th");
2152 }
2153
2154 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2155 {
2156     float m, i;
2157     vector start, org, delta, end, enddown, mstart;
2158     entity sp;
2159
2160     m = e.dphitcontentsmask;
2161     e.dphitcontentsmask = goodcontents | badcontents;
2162
2163     org = world.mins;
2164     delta = world.maxs - world.mins;
2165
2166     start = end = org;
2167
2168     for (i = 0; i < attempts; ++i)
2169     {
2170         start_x = org_x + random() * delta_x;
2171         start_y = org_y + random() * delta_y;
2172         start_z = org_z + random() * delta_z;
2173
2174         // rule 1: start inside world bounds, and outside
2175         // solid, and don't start from somewhere where you can
2176         // fall down to evil
2177         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2178         if (trace_fraction >= 1)
2179             continue;
2180         if (trace_startsolid)
2181             continue;
2182         if (trace_dphitcontents & badcontents)
2183             continue;
2184         if (trace_dphitq3surfaceflags & badsurfaceflags)
2185             continue;
2186
2187         // rule 2: if we are too high, lower the point
2188         if (trace_fraction * delta_z > maxaboveground)
2189             start = trace_endpos + '0 0 1' * maxaboveground;
2190         enddown = trace_endpos;
2191
2192         // rule 3: make sure we aren't outside the map. This only works
2193         // for somewhat well formed maps. A good rule of thumb is that
2194         // the map should have a convex outside hull.
2195         // these can be traceLINES as we already verified the starting box
2196         mstart = start + 0.5 * (e.mins + e.maxs);
2197         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2198         if (trace_fraction >= 1)
2199             continue;
2200         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2201         if (trace_fraction >= 1)
2202             continue;
2203         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2204         if (trace_fraction >= 1)
2205             continue;
2206         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2207         if (trace_fraction >= 1)
2208             continue;
2209         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2210         if (trace_fraction >= 1)
2211             continue;
2212
2213         // rule 4: we must "see" some spawnpoint
2214         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2215                 if(checkpvs(mstart, sp))
2216                         break;
2217         if(!sp)
2218         {
2219                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2220                         if(checkpvs(mstart, sp))
2221                                 break;
2222                 if(!sp)
2223                         continue;
2224         }
2225
2226         // find a random vector to "look at"
2227         end_x = org_x + random() * delta_x;
2228         end_y = org_y + random() * delta_y;
2229         end_z = org_z + random() * delta_z;
2230         end = start + normalize(end - start) * vlen(delta);
2231
2232         // rule 4: start TO end must not be too short
2233         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2234         if (trace_startsolid)
2235             continue;
2236         if (trace_fraction < minviewdistance / vlen(delta))
2237             continue;
2238
2239         // rule 5: don't want to look at sky
2240         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2241             continue;
2242
2243         // rule 6: we must not end up in trigger_hurt
2244         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2245             continue;
2246
2247         break;
2248     }
2249
2250     e.dphitcontentsmask = m;
2251
2252     if (i < attempts)
2253     {
2254         setorigin(e, start);
2255         e.angles = vectoangles(end - start);
2256         dprint("Needed ", ftos(i + 1), " attempts\n");
2257         return TRUE;
2258     }
2259     else
2260         return FALSE;
2261 }
2262
2263 float zcurveparticles_effectno;
2264 vector zcurveparticles_start;
2265 float zcurveparticles_spd;
2266
2267 void endzcurveparticles()
2268 {
2269         if(zcurveparticles_effectno)
2270         {
2271                 // terminator
2272                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2273         }
2274         zcurveparticles_effectno = 0;
2275 }
2276
2277 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2278 {
2279         spd = bound(0, floor(spd / 16), 32767);
2280         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2281         {
2282                 endzcurveparticles();
2283                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2284                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2285                 WriteShort(MSG_BROADCAST, effectno);
2286                 WriteCoord(MSG_BROADCAST, start_x);
2287                 WriteCoord(MSG_BROADCAST, start_y);
2288                 WriteCoord(MSG_BROADCAST, start_z);
2289                 zcurveparticles_effectno = effectno;
2290                 zcurveparticles_start = start;
2291         }
2292         else
2293                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2294         WriteCoord(MSG_BROADCAST, end_x);
2295         WriteCoord(MSG_BROADCAST, end_y);
2296         WriteCoord(MSG_BROADCAST, end_z);
2297         WriteCoord(MSG_BROADCAST, end_dz);
2298         zcurveparticles_spd = spd;
2299 }
2300
2301 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2302 {
2303         float end_dz;
2304         vector vecxy, velxy;
2305
2306         vecxy = end - start;
2307         vecxy_z = 0;
2308         velxy = vel;
2309         velxy_z = 0;
2310
2311         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2312         {
2313                 endzcurveparticles();
2314                 trailparticles(world, effectno, start, end);
2315                 return;
2316         }
2317
2318         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2319         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2320 }
2321
2322 void write_recordmarker(entity pl, float tstart, float dt)
2323 {
2324     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2325
2326     // also write a marker into demo files for demotc-race-record-extractor to find
2327     stuffcmd(pl,
2328              strcat(
2329                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2330                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2331 }
2332
2333 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2334 {
2335         switch(algn)
2336         {
2337                 default:
2338                 case 3: // right
2339                         break;
2340
2341                 case 4: // left
2342                         vecs_y = -vecs_y;
2343                         break;
2344
2345                 case 1:
2346                         if(allowcenter) // 2: allow center handedness
2347                         {
2348                                 // center
2349                                 vecs_y = 0;
2350                                 vecs_z -= 2;
2351                         }
2352                         else
2353                         {
2354                                 // right
2355                         }
2356                         break;
2357
2358                 case 2:
2359                         if(allowcenter) // 2: allow center handedness
2360                         {
2361                                 // center
2362                                 vecs_y = 0;
2363                                 vecs_z -= 2;
2364                         }
2365                         else
2366                         {
2367                                 // left
2368                                 vecs_y = -vecs_y;
2369                         }
2370                         break;
2371         }
2372         return vecs;
2373 }
2374
2375 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2376 {
2377         string s;
2378         vector v;
2379
2380         if (autocvar_g_shootfromeye)
2381         {
2382                 if (visual)
2383                 {
2384                         vecs_y = 0;
2385                         vecs_z -= 2;
2386                 }
2387                 else
2388                 {
2389                         vecs_y = 0;
2390                         vecs_z = 0;
2391                 }
2392         }
2393         else if (autocvar_g_shootfromcenter)
2394         {
2395                 vecs_y = 0;
2396                 vecs_z -= 2;
2397         }
2398         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2399         {
2400                 v = stov(s);
2401                 if (y_is_right)
2402                         v_y = -v_y;
2403                 if (v_x != 0)
2404                         vecs_x = v_x;
2405                 vecs_y = v_y;
2406                 vecs_z = v_z;
2407         }
2408         else if (autocvar_g_shootfromclient)
2409         {
2410                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2411         }
2412         return vecs;
2413 }
2414
2415 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2416 {
2417         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2418 }
2419
2420
2421 void attach_sameorigin(entity e, entity to, string tag)
2422 {
2423     vector org, t_forward, t_left, t_up, e_forward, e_up;
2424     float tagscale;
2425
2426     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2427     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2428     t_forward = v_forward * tagscale;
2429     t_left = v_right * -tagscale;
2430     t_up = v_up * tagscale;
2431
2432     e.origin_x = org * t_forward;
2433     e.origin_y = org * t_left;
2434     e.origin_z = org * t_up;
2435
2436     // current forward and up directions
2437     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2438                 e.angles = AnglesTransform_FromVAngles(e.angles);
2439         else
2440                 e.angles = AnglesTransform_FromAngles(e.angles);
2441     fixedmakevectors(e.angles);
2442
2443     // untransform forward, up!
2444     e_forward_x = v_forward * t_forward;
2445     e_forward_y = v_forward * t_left;
2446     e_forward_z = v_forward * t_up;
2447     e_up_x = v_up * t_forward;
2448     e_up_y = v_up * t_left;
2449     e_up_z = v_up * t_up;
2450
2451     e.angles = fixedvectoangles2(e_forward, e_up);
2452     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2453                 e.angles = AnglesTransform_ToVAngles(e.angles);
2454         else
2455                 e.angles = AnglesTransform_ToAngles(e.angles);
2456
2457     setattachment(e, to, tag);
2458     setorigin(e, e.origin);
2459 }
2460
2461 void detach_sameorigin(entity e)
2462 {
2463     vector org;
2464     org = gettaginfo(e, 0);
2465     e.angles = fixedvectoangles2(v_forward, v_up);
2466     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2467                 e.angles = AnglesTransform_ToVAngles(e.angles);
2468         else
2469                 e.angles = AnglesTransform_ToAngles(e.angles);
2470     setorigin(e, org);
2471     setattachment(e, world, "");
2472     setorigin(e, e.origin);
2473 }
2474
2475 void follow_sameorigin(entity e, entity to)
2476 {
2477     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2478     e.aiment = to; // make the hole follow bmodel
2479     e.punchangle = to.angles; // the original angles of bmodel
2480     e.view_ofs = e.origin - to.origin; // relative origin
2481     e.v_angle = e.angles - to.angles; // relative angles
2482 }
2483
2484 void unfollow_sameorigin(entity e)
2485 {
2486     e.movetype = MOVETYPE_NONE;
2487 }
2488
2489 entity gettaginfo_relative_ent;
2490 vector gettaginfo_relative(entity e, float tag)
2491 {
2492     if (!gettaginfo_relative_ent)
2493     {
2494         gettaginfo_relative_ent = spawn();
2495         gettaginfo_relative_ent.effects = EF_NODRAW;
2496     }
2497     gettaginfo_relative_ent.model = e.model;
2498     gettaginfo_relative_ent.modelindex = e.modelindex;
2499     gettaginfo_relative_ent.frame = e.frame;
2500     return gettaginfo(gettaginfo_relative_ent, tag);
2501 }
2502
2503 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2504 {
2505     float p;
2506     p = pow(2, chan);
2507     if (pl.soundentity.cnt & p)
2508         return;
2509     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2510     pl.soundentity.cnt |= p;
2511 }
2512
2513 void SoundEntity_StopSound(entity pl, float chan)
2514 {
2515     float p;
2516     p = pow(2, chan);
2517     if (pl.soundentity.cnt & p)
2518     {
2519         stopsoundto(MSG_ALL, pl.soundentity, chan);
2520         pl.soundentity.cnt &~= p;
2521     }
2522 }
2523
2524 void SoundEntity_Attach(entity pl)
2525 {
2526     pl.soundentity = spawn();
2527     pl.soundentity.classname = "soundentity";
2528     pl.soundentity.owner = pl;
2529     setattachment(pl.soundentity, pl, "");
2530     setmodel(pl.soundentity, "null");
2531 }
2532
2533 void SoundEntity_Detach(entity pl)
2534 {
2535     float i;
2536     for (i = 0; i <= 7; ++i)
2537         SoundEntity_StopSound(pl, i);
2538 }
2539
2540 .float scale2;
2541
2542 float modeleffect_SendEntity(entity to, float sf)
2543 {
2544         float f;
2545         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2546
2547         f = 0;
2548         if(self.velocity != '0 0 0')
2549                 f |= 1;
2550         if(self.angles != '0 0 0')
2551                 f |= 2;
2552         if(self.avelocity != '0 0 0')
2553                 f |= 4;
2554
2555         WriteByte(MSG_ENTITY, f);
2556         WriteShort(MSG_ENTITY, self.modelindex);
2557         WriteByte(MSG_ENTITY, self.skin);
2558         WriteByte(MSG_ENTITY, self.frame);
2559         WriteCoord(MSG_ENTITY, self.origin_x);
2560         WriteCoord(MSG_ENTITY, self.origin_y);
2561         WriteCoord(MSG_ENTITY, self.origin_z);
2562         if(f & 1)
2563         {
2564                 WriteCoord(MSG_ENTITY, self.velocity_x);
2565                 WriteCoord(MSG_ENTITY, self.velocity_y);
2566                 WriteCoord(MSG_ENTITY, self.velocity_z);
2567         }
2568         if(f & 2)
2569         {
2570                 WriteCoord(MSG_ENTITY, self.angles_x);
2571                 WriteCoord(MSG_ENTITY, self.angles_y);
2572                 WriteCoord(MSG_ENTITY, self.angles_z);
2573         }
2574         if(f & 4)
2575         {
2576                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2577                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2578                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2579         }
2580         WriteShort(MSG_ENTITY, self.scale * 256.0);
2581         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2582         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2583         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2584         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2585
2586         return TRUE;
2587 }
2588
2589 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2590 {
2591         entity e;
2592         float sz;
2593         e = spawn();
2594         e.classname = "modeleffect";
2595         setmodel(e, m);
2596         e.frame = f;
2597         setorigin(e, o);
2598         e.velocity = v;
2599         e.angles = ang;
2600         e.avelocity = angv;
2601         e.alpha = a;
2602         e.teleport_time = t1;
2603         e.fade_time = t2;
2604         e.skin = s;
2605         if(s0 >= 0)
2606                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2607         else
2608                 e.scale = -s0;
2609         if(s2 >= 0)
2610                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2611         else
2612                 e.scale2 = -s2;
2613         sz = max(e.scale, e.scale2);
2614         setsize(e, e.mins * sz, e.maxs * sz);
2615         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2616 }
2617
2618 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2619 {
2620         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2621 }
2622
2623 float randombit(float bits)
2624 {
2625         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2626                 return bits;
2627
2628         float n, f, b, r;
2629
2630         r = random();
2631         b = 0;
2632         n = 0;
2633
2634         for(f = 1; f <= bits; f *= 2)
2635         {
2636                 if(bits & f)
2637                 {
2638                         ++n;
2639                         r *= n;
2640                         if(r <= 1)
2641                                 b = f;
2642                         else
2643                                 r = (r - 1) / (n - 1);
2644                 }
2645         }
2646
2647         return b;
2648 }
2649
2650 float randombits(float bits, float k, float error_return)
2651 {
2652         float r;
2653         r = 0;
2654         while(k > 0 && bits != r)
2655         {
2656                 r += randombit(bits - r);
2657                 --k;
2658         }
2659         if(error_return)
2660                 if(k > 0)
2661                         return -1; // all
2662         return r;
2663 }
2664
2665 void randombit_test(float bits, float iter)
2666 {
2667         while(iter > 0)
2668         {
2669                 print(ftos(randombit(bits)), "\n");
2670                 --iter;
2671         }
2672 }
2673
2674 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2675 {
2676         if(halflifedist > 0)
2677                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2678         else if(halflifedist < 0)
2679                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2680         else
2681                 return 1;
2682 }
2683
2684
2685
2686
2687 #ifdef RELEASE
2688 #define cvar_string_normal builtin_cvar_string
2689 #define cvar_normal builtin_cvar
2690 #else
2691 string cvar_string_normal(string n)
2692 {
2693         if not(cvar_type(n) & 1)
2694                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2695         return builtin_cvar_string(n);
2696 }
2697
2698 float cvar_normal(string n)
2699 {
2700         return stof(cvar_string_normal(n));
2701 }
2702 #endif
2703 #define cvar_set_normal builtin_cvar_set
2704
2705 void defer_think()
2706 {
2707     entity oself;
2708
2709     oself           = self;
2710     self            = self.owner;
2711     oself.think     = SUB_Remove;
2712     oself.nextthink = time;
2713
2714     oself.use();
2715 }
2716
2717 /*
2718     Execute func() after time + fdelay.
2719     self when func is executed = self when defer is called
2720 */
2721 void defer(float fdelay, void() func)
2722 {
2723     entity e;
2724
2725     e           = spawn();
2726     e.owner     = self;
2727     e.use       = func;
2728     e.think     = defer_think;
2729     e.nextthink = time + fdelay;
2730 }
2731
2732 .string aiment_classname;
2733 .float aiment_deadflag;
2734 void SetMovetypeFollow(entity ent, entity e)
2735 {
2736         // FIXME this may not be warpzone aware
2737         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2738         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2739         ent.aiment = e; // make the hole follow bmodel
2740         ent.punchangle = e.angles; // the original angles of bmodel
2741         ent.view_ofs = ent.origin - e.origin; // relative origin
2742         ent.v_angle = ent.angles - e.angles; // relative angles
2743         ent.aiment_classname = strzone(e.classname);
2744         ent.aiment_deadflag = e.deadflag;
2745 }
2746 void UnsetMovetypeFollow(entity ent)
2747 {
2748         ent.movetype = MOVETYPE_FLY;
2749         PROJECTILE_MAKETRIGGER(ent);
2750         ent.aiment = world;
2751 }
2752 float LostMovetypeFollow(entity ent)
2753 {
2754 /*
2755         if(ent.movetype != MOVETYPE_FOLLOW)
2756                 if(ent.aiment)
2757                         error("???");
2758 */
2759         if(ent.aiment)
2760         {
2761                 if(ent.aiment.classname != ent.aiment_classname)
2762                         return 1;
2763                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2764                         return 1;
2765         }
2766         return 0;
2767 }
2768
2769 float isPushable(entity e)
2770 {
2771         if(e.iscreature)
2772                 return TRUE;
2773         if(e.pushable)
2774                 return TRUE;
2775         switch(e.classname)
2776         {
2777                 case "body":
2778                 case "droppedweapon":
2779                 case "keepawayball":
2780                 case "nexball_basketball":
2781                 case "nexball_football":
2782                         return TRUE;
2783                 case "bullet": // antilagged bullets can't hit this either
2784                         return FALSE;
2785         }
2786         if (e.projectiledeathtype)
2787                 return TRUE;
2788         return FALSE;
2789 }