qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = time + autocvar_g_start_delay + autocvar_g_freezetag_warmup;
   5         ScoreRules_freezetag();
   6 }
   7
   8 void freezetag_CheckWinner()
   9 {
  10         if(time <= game_starttime) // game didn't even start yet! nobody can win in that case.
  11                 return;
  12
  13         if(next_round || (time > warmup - autocvar_g_freezetag_warmup && time < warmup))
  14                 return; // already waiting for next round to start
  15
  16         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  17                 || (redalive >= 1 && yellowalive >= 1)
  18                 || (redalive >= 1 && pinkalive >= 1)
  19                 || (bluealive >= 1 && yellowalive >= 1)
  20                 || (bluealive >= 1 && pinkalive >= 1)
  21                 || (yellowalive >= 1 && pinkalive >= 1))
  22                 return; // we still have active players on two or more teams, nobody won yet
  23
  24         entity e, winner;
  25         string teamname;
  26         winner = world;
  27
  28         FOR_EACH_PLAYER(e)
  29         {
  30                 if(e.freezetag_frozen == 0 && e.classname == "player" && e.health >= 1) // here's one player from the winning team... good
  31                 {
  32                         winner = e;
  33                         break; // break, we found the winner
  34                 }
  35         }
  36
  37         if(winner != world) // just in case a winner wasn't found
  38         {
  39                 if(winner.team == COLOR_TEAM1)
  40                         teamname = "^1Red Team";
  41                 else if(winner.team == COLOR_TEAM2)
  42                         teamname = "^4Blue Team";
  43                 else if(winner.team == COLOR_TEAM3)
  44                         teamname = "^3Yellow Team";
  45                 else
  46                         teamname = "^6Pink Team";
  47                 FOR_EACH_PLAYER(e) {
  48                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  49                 }
  50                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  51                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  52         }
  53
  54         next_round = time + 5;
  55 }
  56
  57 // this is needed to allow the player to turn his view around (fixangle can't
  58 // be used to freeze his view, as that also changes the angles), while not
  59 // turning that ice object with the player
  60 void freezetag_Ice_Think()
  61 {
  62         setorigin(self, self.owner.origin - '0 0 16');
  63         self.nextthink = time;
  64 }
  65
  66 void freezetag_Freeze(entity attacker)
  67 {
  68         if(self.freezetag_frozen)
  69                 return;
  70         self.freezetag_frozen = 1;
  71         self.freezetag_revive_progress = 0;
  72
  73         entity ice;
  74         ice = spawn();
  75         ice.owner = self;
  76         ice.classname = "freezetag_ice";
  77         ice.think = freezetag_Ice_Think;
  78         ice.nextthink = time;
  79         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  80         setmodel(ice, "models/ice/ice.md3");
  81
  82         entity oldself;
  83         oldself = self;
  84         self = ice;
  85         freezetag_Ice_Think();
  86         self = oldself;
  87
  88         RemoveGrapplingHook(self);
  89
  90         // add waypoint
  91         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE);
  92         if(self.waypointsprite_attached)
  93         {
  94                 WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_WAYPOINT, '0.25 0.90 1');
  95         }
  96
  97         if(attacker == self)
  98         {
  99                 // you froze your own dumb self
 100                 // counted as "suicide" already
 101                 PlayerScore_Add(self, SP_SCORE, -1);
 102         }
 103         else if(attacker.classname == "player")
 104         {
 105                 // got frozen by an enemy
 106                 // counted as "kill" and "death" already
 107                 PlayerScore_Add(self, SP_SCORE, -1);
 108                 PlayerScore_Add(attacker, SP_SCORE, +1);
 109         }
 110         else
 111         {
 112                 // nothing - got frozen by the game type rules themselves
 113         }
 114 }
 115
 116 void freezetag_Unfreeze(entity attacker)
 117 {
 118         self.freezetag_frozen = 0;
 119         self.freezetag_revive_progress = 0;
 120
 121         // remove the ice block
 122         entity ice;
 123         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
 124         {
 125                 remove(ice);
 126                 break;
 127         }
 128
 129         // remove waypoint
 130         if(self.waypointsprite_attached)
 131                 WaypointSprite_Kill(self.waypointsprite_attached);
 132 }
 133
 134 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 135 {
 136         if(self.freezetag_frozen == 0)
 137         {
 138                 if(self.team == COLOR_TEAM1)
 139                         --redalive;
 140                 else if(self.team == COLOR_TEAM2)
 141                         --bluealive;
 142                 else if(self.team == COLOR_TEAM3)
 143                         --yellowalive;
 144                 else if(self.team == COLOR_TEAM4)
 145                         --pinkalive;
 146                 --totalalive;
 147         }
 148
 149         if(totalspawned > 2) // only check for winners if we had more than two players (one of them left, don't let the other player win just because of that)
 150                 freezetag_CheckWinner();
 151
 152         freezetag_Unfreeze(world);
 153
 154         return 1;
 155 }
 156
 157 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 158 {
 159         if(self.freezetag_frozen == 0)
 160         {
 161                 if(self.team == COLOR_TEAM1)
 162                         --redalive;
 163                 else if(self.team == COLOR_TEAM2)
 164                         --bluealive;
 165                 else if(self.team == COLOR_TEAM3)
 166                         --yellowalive;
 167                 else if(self.team == COLOR_TEAM4)
 168                         --pinkalive;
 169                 --totalalive;
 170
 171         freezetag_Freeze(frag_attacker);
 172         }
 173
 174     if(frag_attacker.classname == STR_PLAYER)
 175         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 176
 177         if(frag_attacker == frag_target || frag_attacker == world)
 178         {
 179         if(frag_target.classname == STR_PLAYER)
 180             centerprint(frag_target, "^1You froze yourself.\n");
 181                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 182         }
 183         else
 184         {
 185         if(frag_target.classname == STR_PLAYER)
 186             centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 187                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 188         }
 189
 190         frag_target.health = autocvar_g_balance_health_start; // "respawn" the player :P
 191
 192         freezetag_CheckWinner();
 193
 194         return 1;
 195 }
 196
 197 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 198 {
 199     freezetag_Unfreeze(world); // start by making sure that all ice blocks are removed
 200
 201         if(totalspawned == 1 && time > game_starttime) // only one player active on server, start a new match immediately
 202         if(!next_round && warmup && (time < warmup - autocvar_g_freezetag_warmup || time > warmup)) // not awaiting next round
 203         {
 204                 next_round = time;
 205                 return 1;
 206         }
 207         if(warmup && time > warmup) // spawn too late, freeze player
 208         {
 209                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 210                 freezetag_Freeze(world);
 211         }
 212
 213         return 1;
 214 }
 215
 216 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 217 {
 218         frag_score = 0; // no frags counted in Freeze Tag
 219         return 1;
 220 }
 221
 222 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 223 {
 224         float n;
 225         vector revive_extra_size;
 226
 227         revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 228
 229         entity o;
 230         o = world;
 231         n = 0;
 232         FOR_EACH_PLAYER(other) if(self != other)
 233         {
 234                 if(other.freezetag_frozen == 0)
 235                 {
 236                         if(other.team == self.team)
 237                         {
 238                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 239                                 {
 240                                         if(!o)
 241                                                 o = other;
 242                                         ++n;
 243                                 }
 244                         }
 245                 }
 246         }
 247
 248         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 249         {
 250                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 251
 252                 if(self.freezetag_revive_progress >= 1)
 253                 {
 254                         freezetag_Unfreeze(self);
 255
 256                         // EVERY team mate nearby gets a point (even if multiple!)
 257                         FOR_EACH_PLAYER(other) if(self != other)
 258                         {
 259                                 if(other.freezetag_frozen == 0)
 260                                 {
 261                                         if(other.team == self.team)
 262                                         {
 263                                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 264                                                 {
 265                                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 266                                                         PlayerScore_Add(other, SP_SCORE, +1);
 267                                                 }
 268                                         }
 269                                 }
 270                         }
 271
 272                         if(n > 1)
 273                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 274                         else
 275                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 276                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 277                         if(n > 1)
 278                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 279                         else
 280                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 281                 }
 282
 283                 // now find EVERY teammate within reviving radius, set their revive_progress values correct
 284                 FOR_EACH_PLAYER(other) if(self != other)
 285                 {
 286                         if(other.freezetag_frozen == 0)
 287                         {
 288                                 if(other.team == self.team)
 289                                 {
 290                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 291                                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 292                                 }
 293                         }
 294                 }
 295         }
 296         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 297         {
 298                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 299         }
 300         else if(!n)
 301         {
 302                 self.freezetag_revive_progress = 0; // thawing nobody
 303         }
 304
 305         return 1;
 306 }
 307
 308 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 309 {
 310         if(self.freezetag_frozen)
 311         {
 312                 self.movement = '0 0 0';
 313                 self.disableclientprediction = 1;
 314         }
 315         return 1;
 316 }
 317
 318 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 319 {
 320     if(g_freezetag)
 321     {
 322         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 323         {
 324             frag_damage = 0;
 325             frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 326         }
 327     }
 328     return 1;
 329 }
 330
 331 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 332 {
 333         if (self.freezetag_frozen)
 334                 return 1;
 335         return 0;
 336 }
 337
 338 MUTATOR_DEFINITION(gamemode_freezetag)
 339 {
 340         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 341         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 342         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 343         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 344         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 345         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 346         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 347         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 348         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_FIRST); //first, last or any? dunno.
 349
 350         MUTATOR_ONADD
 351         {
 352                 if(time > 1) // game loads at time 1
 353                         error("This is a game type and it cannot be added at runtime.");
 354                 g_freezetag = 1;
 355                 freezetag_Initialize();
 356         }
 357
 358         MUTATOR_ONREMOVE
 359         {
 360                 g_freezetag = 0;
 361                 error("This is a game type and it cannot be removed at runtime.");
 362         }
 363
 364         return 0;
 365 }