qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = time + autocvar_g_start_delay + autocvar_g_freezetag_warmup;
   5         ScoreRules_freezetag();
   6 }
   7
   8 void freezetag_CheckWinner()
   9 {
  10         if(time <= game_starttime) // game didn't even start yet! nobody can win in that case.
  11                 return;
  12
  13         if(next_round || (time > warmup - autocvar_g_freezetag_warmup && time < warmup))
  14                 return; // already waiting for next round to start
  15
  16         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  17                 || (redalive >= 1 && yellowalive >= 1)
  18                 || (redalive >= 1 && pinkalive >= 1)
  19                 || (bluealive >= 1 && yellowalive >= 1)
  20                 || (bluealive >= 1 && pinkalive >= 1)
  21                 || (yellowalive >= 1 && pinkalive >= 1))
  22                 return; // we still have active players on two or more teams, nobody won yet
  23
  24         entity e, winner;
  25         string teamname;
  26         winner = world;
  27
  28         FOR_EACH_PLAYER(e)
  29         {
  30                 if(e.freezetag_frozen == 0 && e.classname == "player" && e.health >= 1) // here's one player from the winning team... good
  31                 {
  32                         winner = e;
  33                         break; // break, we found the winner
  34                 }
  35         }
  36
  37         if(winner != world) // just in case a winner wasn't found
  38         {
  39                 if(winner.team == COLOR_TEAM1)
  40                         teamname = "^1Red Team";
  41                 else if(winner.team == COLOR_TEAM2)
  42                         teamname = "^4Blue Team";
  43                 else if(winner.team == COLOR_TEAM3)
  44                         teamname = "^3Yellow Team";
  45                 else
  46                         teamname = "^6Pink Team";
  47                 FOR_EACH_PLAYER(e) {
  48                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  49                 }
  50                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  51                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  52         }
  53
  54         next_round = time + 5;
  55 }
  56
  57 // this is needed to allow the player to turn his view around (fixangle can't
  58 // be used to freeze his view, as that also changes the angles), while not
  59 // turning that ice object with the player
  60 void freezetag_Ice_Think()
  61 {
  62         setorigin(self, self.owner.origin - '0 0 16');
  63         self.nextthink = time;
  64 }
  65
  66 void freezetag_Freeze(entity attacker)
  67 {
  68         self.freezetag_frozen = 1;
  69
  70         entity ice;
  71         ice = spawn();
  72         ice.owner = self;
  73         ice.classname = "freezetag_ice";
  74         ice.think = freezetag_Ice_Think;
  75         ice.nextthink = time;
  76         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  77         setmodel(ice, "models/ice/ice.md3");
  78
  79         entity oldself;
  80         oldself = self;
  81         self = ice;
  82         freezetag_Ice_Think();
  83         self = oldself;
  84
  85         // add waypoint
  86         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE);
  87         if(self.waypointsprite_attached)
  88         {
  89                 WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_WAYPOINT, '0.25 0.90 1');
  90         }
  91
  92         if(attacker == self)
  93         {
  94                 // you froze your own dumb self
  95                 // counted as "suicide" already
  96                 PlayerScore_Add(self, SP_SCORE, -1);
  97         }
  98         else if(attacker.classname == "player")
  99         {
 100                 // got frozen by an enemy
 101                 // counted as "kill" and "death" already
 102                 PlayerScore_Add(self, SP_SCORE, -1);
 103                 PlayerScore_Add(attacker, SP_SCORE, +1);
 104         }
 105         else
 106         {
 107                 // nothing - got frozen by the game type rules themselves
 108         }
 109 }
 110
 111 void freezetag_Unfreeze(entity attacker)
 112 {
 113         self.freezetag_frozen = 0;
 114
 115         // remove the ice block
 116         entity ice;
 117         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
 118         {
 119                 remove(ice);
 120                 break;
 121         }
 122
 123         // remove waypoint
 124         if(self.waypointsprite_attached)
 125                 WaypointSprite_Kill(self.waypointsprite_attached);
 126 }
 127
 128 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 129 {
 130         if(self.freezetag_frozen == 0)
 131         {
 132                 if(self.team == COLOR_TEAM1)
 133                         --redalive;
 134                 else if(self.team == COLOR_TEAM2)
 135                         --bluealive;
 136                 else if(self.team == COLOR_TEAM3)
 137                         --yellowalive;
 138                 else if(self.team == COLOR_TEAM4)
 139                         --pinkalive;
 140                 --totalalive;
 141         }
 142
 143         if(totalspawned > 2) // only check for winners if we had more than two players (one of them left, don't let the other player win just because of that)
 144                 freezetag_CheckWinner();
 145
 146         freezetag_Unfreeze(world);
 147
 148         return 1;
 149 }
 150
 151 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 152 {
 153         if(self.freezetag_frozen == 0)
 154         {
 155                 if(self.team == COLOR_TEAM1)
 156                         --redalive;
 157                 else if(self.team == COLOR_TEAM2)
 158                         --bluealive;
 159                 else if(self.team == COLOR_TEAM3)
 160                         --yellowalive;
 161                 else if(self.team == COLOR_TEAM4)
 162                         --pinkalive;
 163                 --totalalive;
 164
 165         freezetag_Freeze(frag_attacker);
 166         }
 167
 168     if(frag_attacker.classname == STR_PLAYER)
 169         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 170
 171         if(frag_attacker == frag_target || frag_attacker == world)
 172         {
 173         if(frag_target.classname == STR_PLAYER)
 174             centerprint(frag_target, "^1You froze yourself.\n");
 175                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 176         }
 177         else
 178         {
 179         if(frag_target.classname == STR_PLAYER)
 180             centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 181                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 182         }
 183
 184         frag_target.health = autocvar_g_balance_health_start; // "respawn" the player :P
 185
 186         freezetag_CheckWinner();
 187
 188         return 1;
 189 }
 190
 191 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 192 {
 193     freezetag_Unfreeze(world); // start by making sure that all ice blocks are removed
 194
 195         if(totalspawned == 1 && time > game_starttime) // only one player active on server, start a new match immediately
 196         if(!next_round && warmup && (time < warmup - autocvar_g_freezetag_warmup || time > warmup)) // not awaiting next round
 197         {
 198                 next_round = time;
 199                 return 1;
 200         }
 201         if(warmup && time > warmup) // spawn too late, freeze player
 202         {
 203                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 204                 freezetag_Freeze(world);
 205         }
 206
 207         return 1;
 208 }
 209
 210 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 211 {
 212         frag_score = 0; // no frags counted in Freeze Tag
 213         return 1;
 214 }
 215
 216 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 217 {
 218     vector revive_extra_size;
 219     revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 220
 221     float teammate_nearby;
 222     FOR_EACH_PLAYER(other) if(self != other)
 223     {
 224         if(other.freezetag_frozen == 0)
 225         {
 226             if(other.team == self.team)
 227             {
 228                 teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 229                 if(teammate_nearby)
 230                     break;
 231             }
 232         }
 233     }
 234
 235     if(teammate_nearby && self.freezetag_frozen == 1) // OK, there is at least one teammate reviving us
 236     {
 237         if(self.freezetag_beginrevive_time == -9999) // initialize values if this is the first frame of revival
 238         {
 239             self.freezetag_beginrevive_time = time;
 240             self.freezetag_revive_progress = 0;
 241         }
 242         else
 243         {
 244             self.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / autocvar_g_freezetag_revive_time;
 245             if(time - self.freezetag_beginrevive_time >= autocvar_g_freezetag_revive_time)
 246             {
 247                 freezetag_Unfreeze(self);
 248                 entity o;
 249                 o = other;
 250
 251                 // EVERY team mate nearby gets a point (even if multiple!)
 252                 float n;
 253                 FOR_EACH_PLAYER(other) if(self != other)
 254                 {
 255                         if(other.freezetag_frozen == 0)
 256                         {
 257                                 if(other.team == self.team)
 258                                 {
 259                                         teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 260                                         if(teammate_nearby)
 261                                         {
 262                                                 PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 263                                                 PlayerScore_Add(other, SP_SCORE, +1);
 264                                                 ++n;
 265                                         }
 266                                 }
 267                         }
 268                 }
 269
 270                 if(n > 1)
 271                         centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 272                 else
 273                         centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 274                 centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 275                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 276
 277                 self.freezetag_beginrevive_time = -9999;
 278                 self.freezetag_revive_progress = 0;
 279             }
 280         }
 281         // now find EVERY teammate within reviving radius, set their revive_progress values correct
 282         FOR_EACH_PLAYER(other) if(self != other)
 283         {
 284             if(other.freezetag_frozen == 0)
 285             {
 286                 if(other.team == self.team)
 287                 {
 288                     teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 289                     if(teammate_nearby)
 290                         other.freezetag_revive_progress = self.freezetag_revive_progress;
 291                 }
 292             }
 293         }
 294     }
 295     else if(!teammate_nearby) // only if no teammate is nearby will we reset
 296     {
 297         self.freezetag_beginrevive_time = -9999;
 298         self.freezetag_revive_progress = 0;
 299     }
 300
 301         return 1;
 302 }
 303
 304 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 305 {
 306         if(self.freezetag_frozen)
 307         {
 308                 self.movement = '0 0 0';
 309                 self.disableclientprediction = 1;
 310         }
 311         return 1;
 312 }
 313
 314 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 315 {
 316     if(g_freezetag)
 317     {
 318         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 319         {
 320             frag_damage = 0;
 321             frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 322         }
 323     }
 324     return 1;
 325 }
 326
 327 MUTATOR_DEFINITION(gamemode_freezetag)
 328 {
 329         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 330         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 331         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 332         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 333         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 334         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 335         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 336         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 337
 338         MUTATOR_ONADD
 339         {
 340                 if(time > 1) // game loads at time 1
 341                         error("This is a game type and it cannot be added at runtime.");
 342                 g_freezetag = 1;
 343                 freezetag_Initialize();
 344         }
 345
 346         MUTATOR_ONREMOVE
 347         {
 348                 g_freezetag = 0;
 349                 error("This is a game type and it cannot be removed at runtime.");
 350         }
 351
 352         return 0;
 353 }