qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = time + autocvar_g_start_delay + autocvar_g_freezetag_warmup;
   5 }
   6
   7 void freezetag_CheckWinner()
   8 {
   9         if(time <= game_starttime) // game didn't even start yet! nobody can win in that case.
  10                 return;
  11
  12         if(next_round || (time > warmup - autocvar_g_freezetag_warmup && time < warmup))
  13                 return; // already waiting for next round to start
  14
  15         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  16                 || (redalive >= 1 && yellowalive >= 1)
  17                 || (redalive >= 1 && pinkalive >= 1)
  18                 || (bluealive >= 1 && yellowalive >= 1)
  19                 || (bluealive >= 1 && pinkalive >= 1)
  20                 || (yellowalive >= 1 && pinkalive >= 1))
  21                 return; // we still have active players on two or more teams, nobody won yet
  22
  23         entity e, winner;
  24         string teamname;
  25
  26         FOR_EACH_PLAYER(e)
  27         {
  28                 if(e.freezetag_frozen == 0 && e.classname == "player" && e.health >= 1) // here's one player from the winning team... good
  29                 {
  30                         winner = e;
  31                         break; // break, we found the winner
  32                 }
  33         }
  34
  35         if(winner != world) // just in case a winner wasn't found
  36         {
  37                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  38                 if(winner.team == COLOR_TEAM1)
  39                         teamname = "^1Red Team";
  40                 else if(winner.team == COLOR_TEAM2)
  41                         teamname = "^4Blue Team";
  42                 else if(winner.team == COLOR_TEAM3)
  43                         teamname = "^3Yellow Team";
  44                 else
  45                         teamname = "^6Pink Team";
  46                 FOR_EACH_PLAYER(e) {
  47                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  48                 }
  49                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  50         }
  51
  52         next_round = time + 5;
  53 }
  54
  55 // this is needed to allow the player to turn his view around (fixangle can't
  56 // be used to freeze his view, as that also changes the angles), while not
  57 // turning that ice object with the player
  58 void freezetag_Ice_Think()
  59 {
  60         setorigin(self, self.owner.origin - '0 0 16');
  61         self.nextthink = time;
  62 }
  63
  64 void freezetag_Freeze()
  65 {
  66         self.freezetag_frozen = 1;
  67
  68         entity ice;
  69         ice = spawn();
  70         ice.owner = self;
  71         ice.classname = "freezetag_ice";
  72         ice.think = freezetag_Ice_Think;
  73         ice.nextthink = time;
  74         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  75         setmodel(ice, "models/ice/ice.md3");
  76
  77         entity oldself;
  78         oldself = self;
  79         self = ice;
  80         freezetag_Ice_Think();
  81         self = oldself;
  82
  83         // add waypoint
  84         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE);
  85         if(self.waypointsprite_attached)
  86         {
  87                 WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_WAYPOINT, '0.25 0.90 1');
  88         }
  89 }
  90
  91 void freezetag_Unfreeze()
  92 {
  93         self.freezetag_frozen = 0;
  94
  95         // remove the ice block
  96         entity ice;
  97         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
  98         {
  99                 remove(ice);
 100                 break;
 101         }
 102
 103         // remove waypoint
 104         if(self.waypointsprite_attached)
 105                 WaypointSprite_Kill(self.waypointsprite_attached);
 106 }
 107
 108 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 109 {
 110         if(self.freezetag_frozen == 0)
 111         {
 112                 if(self.team == COLOR_TEAM1)
 113                         --redalive;
 114                 else if(self.team == COLOR_TEAM2)
 115                         --bluealive;
 116                 else if(self.team == COLOR_TEAM3)
 117                         --yellowalive;
 118                 else if(self.team == COLOR_TEAM4)
 119                         --pinkalive;
 120                 --totalalive;
 121         }
 122
 123         if(totalspawned > 2) // only check for winners if we had more than two players (one of them left, don't let the other player win just because of that)
 124                 freezetag_CheckWinner();
 125
 126         freezetag_Unfreeze();
 127
 128         return 1;
 129 }
 130
 131 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 132 {
 133         if(self.freezetag_frozen == 0)
 134         {
 135                 if(self.team == COLOR_TEAM1)
 136                         --redalive;
 137                 else if(self.team == COLOR_TEAM2)
 138                         --bluealive;
 139                 else if(self.team == COLOR_TEAM3)
 140                         --yellowalive;
 141                 else if(self.team == COLOR_TEAM4)
 142                         --pinkalive;
 143                 --totalalive;
 144
 145         freezetag_Freeze();
 146         }
 147
 148     if(frag_attacker.classname == STR_PLAYER)
 149         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 150
 151         if(frag_attacker == frag_target || frag_attacker == world)
 152         {
 153         if(frag_target.classname == STR_PLAYER)
 154             centerprint(frag_target, "^1You froze yourself.\n");
 155                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 156         }
 157         else
 158         {
 159         if(frag_target.classname == STR_PLAYER)
 160             centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 161                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 162         }
 163
 164         frag_target.health = autocvar_g_balance_health_start; // "respawn" the player :P
 165
 166         freezetag_CheckWinner();
 167
 168         return 1;
 169 }
 170
 171 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 172 {
 173     freezetag_Unfreeze(); // start by making sure that all ice blocks are removed
 174
 175         if(totalspawned == 1 && time > game_starttime) // only one player active on server, start a new match immediately
 176         if(!next_round && warmup && (time < warmup - autocvar_g_freezetag_warmup || time > warmup)) // not awaiting next round
 177         {
 178                 next_round = time;
 179                 return 1;
 180         }
 181         if(warmup && time > warmup) // spawn too late, freeze player
 182         {
 183                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 184                 freezetag_Freeze();
 185         }
 186
 187         return 1;
 188 }
 189
 190 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 191 {
 192         frag_score = 0; // no frags counted in Freeze Tag
 193         return 1;
 194 }
 195
 196 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 197 {
 198     vector revive_extra_size;
 199     revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 200
 201     float teammate_nearby;
 202     FOR_EACH_PLAYER(other) if(self != other)
 203     {
 204         if(other.freezetag_frozen == 0)
 205         {
 206             if(other.team == self.team)
 207             {
 208                 teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 209                 if(teammate_nearby)
 210                     break;
 211             }
 212         }
 213     }
 214
 215     if(teammate_nearby && self.freezetag_frozen == 1) // OK, there is at least one teammate reviving us
 216     {
 217         if(self.freezetag_beginrevive_time == -9999) // initialize values if this is the first frame of revival
 218         {
 219             self.freezetag_beginrevive_time = time;
 220             self.freezetag_revive_progress = 0;
 221         }
 222         else
 223         {
 224             self.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / autocvar_g_freezetag_revive_time;
 225             if(time - self.freezetag_beginrevive_time >= autocvar_g_freezetag_revive_time)
 226             {
 227                 freezetag_Unfreeze();
 228
 229                 centerprint(self, strcat("^5You were revived by ^7", other.netname, ".\n"));
 230                 centerprint(other, strcat("^5You revived ^7", self.netname, ".\n"));
 231                 bprint("^7", other.netname, "^5 revived ^7", self.netname, ".\n");
 232
 233                 self.freezetag_beginrevive_time = -9999;
 234                 self.freezetag_revive_progress = 0;
 235             }
 236         }
 237         // now find EVERY teammate within reviving radius, set their revive_progress values correct
 238         FOR_EACH_PLAYER(other) if(self != other)
 239         {
 240             if(other.freezetag_frozen == 0)
 241             {
 242                 if(other.team == self.team)
 243                 {
 244                     teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 245                     if(teammate_nearby)
 246                         other.freezetag_revive_progress = self.freezetag_revive_progress;
 247                 }
 248             }
 249         }
 250     }
 251     else if(!teammate_nearby) // only if no teammate is nearby will we reset
 252     {
 253         self.freezetag_beginrevive_time = -9999;
 254         self.freezetag_revive_progress = 0;
 255     }
 256
 257         return 1;
 258 }
 259
 260 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 261 {
 262         if(self.freezetag_frozen)
 263         {
 264                 self.movement = '0 0 0';
 265                 self.disableclientprediction = 1;
 266         }
 267         return 1;
 268 }
 269
 270 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 271 {
 272     if(g_freezetag)
 273     {
 274         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 275         {
 276             frag_damage = 0;
 277             frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 278         }
 279     }
 280     return 1;
 281 }
 282
 283 MUTATOR_DEFINITION(gamemode_freezetag)
 284 {
 285         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 286         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 287         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 288         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 289         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 290         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 291         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 292         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 293
 294         MUTATOR_ONADD
 295         {
 296                 if(time > 1) // game loads at time 1
 297                         error("This is a game type and it cannot be added at runtime.");
 298                 g_freezetag = 1;
 299                 freezetag_Initialize();
 300         }
 301
 302         MUTATOR_ONREMOVE
 303         {
 304                 g_freezetag = 0;
 305                 error("This is a game type and it cannot be removed at runtime.");
 306         }
 307
 308         return 0;
 309 }