qcsrc/server/mutators/gamemode_lms.qc

   1 #include "gamemode_lms.qh"
   2 #include "../_all.qh"
   3
   4 #include "gamemode.qh"
   5
   6 #include "../campaign.qh"
   7 #include "../command/cmd.qh"
   8
   9 // main functions
  10 float LMS_NewPlayerLives()
  11 {
  12         float fl;
  13         fl = autocvar_fraglimit;
  14         if(fl == 0)
  15                 fl = 999;
  16
  17         // first player has left the game for dying too much? Nobody else can get in.
  18         if(lms_lowest_lives < 1)
  19                 return 0;
  20
  21         if(!autocvar_g_lms_join_anytime)
  22                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  23                         return 0;
  24
  25         return bound(1, lms_lowest_lives, fl);
  26 }
  27
  28 // mutator hooks
  29 MUTATOR_HOOKFUNCTION(lms_ResetMap)
  30 {
  31         lms_lowest_lives = 999;
  32         lms_next_place = player_count;
  33
  34         return false;
  35 }
  36
  37 MUTATOR_HOOKFUNCTION(lms_ResetPlayers)
  38 {SELFPARAM();
  39         entity e;
  40         if(restart_mapalreadyrestarted || (time < game_starttime))
  41         FOR_EACH_CLIENT(e)
  42         if(IS_PLAYER(e))
  43         {
  44                 WITH(entity, self, e, PlayerScore_Add(e, SP_LMS_LIVES, LMS_NewPlayerLives()));
  45         }
  46
  47         return false;
  48 }
  49
  50 MUTATOR_HOOKFUNCTION(lms_PlayerPreSpawn)
  51 {SELFPARAM();
  52         // player is dead and becomes observer
  53         // FIXME fix LMS scoring for new system
  54         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
  55         {
  56                 self.classname = "observer";
  57                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_NOLIVES);
  58         }
  59
  60         return false;
  61 }
  62
  63 MUTATOR_HOOKFUNCTION(lms_PlayerDies)
  64 {SELFPARAM();
  65         self.respawn_flags |= RESPAWN_FORCE;
  66
  67         return false;
  68 }
  69
  70 MUTATOR_HOOKFUNCTION(lms_RemovePlayer)
  71 {SELFPARAM();
  72         // Only if the player cannot play at all
  73         if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
  74                 self.frags = FRAGS_SPECTATOR;
  75         else
  76                 self.frags = FRAGS_LMS_LOSER;
  77
  78         if(self.killcount != -666)
  79                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
  80                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
  81                 else
  82                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
  83
  84         return false;
  85 }
  86
  87 MUTATOR_HOOKFUNCTION(lms_ClientConnect)
  88 {SELFPARAM();
  89         self.classname = "player";
  90         campaign_bots_may_start = 1;
  91
  92         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
  93         {
  94                 PlayerScore_Add(self, SP_LMS_RANK, 666);
  95                 self.frags = FRAGS_SPECTATOR;
  96         }
  97
  98         return false;
  99 }
 100
 101 MUTATOR_HOOKFUNCTION(lms_PlayerThink)
 102 {SELFPARAM();
 103         if(self.deadflag == DEAD_DYING)
 104                 self.deadflag = DEAD_RESPAWNING;
 105
 106         return false;
 107 }
 108
 109 MUTATOR_HOOKFUNCTION(lms_PlayerRegen)
 110 {
 111         if(autocvar_g_lms_regenerate)
 112                 return false;
 113         return true;
 114 }
 115
 116 MUTATOR_HOOKFUNCTION(lms_ForbidThrowing)
 117 {
 118         // forbode!
 119         return true;
 120 }
 121
 122 MUTATOR_HOOKFUNCTION(lms_GiveFragsForKill)
 123 {
 124         // remove a life
 125         float tl;
 126         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 127         if(tl < lms_lowest_lives)
 128                 lms_lowest_lives = tl;
 129         if(tl <= 0)
 130         {
 131                 if(!lms_next_place)
 132                         lms_next_place = player_count;
 133                 else
 134                         lms_next_place = min(lms_next_place, player_count);
 135                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 136                 --lms_next_place;
 137         }
 138         frag_score = 0;
 139
 140         return true;
 141 }
 142
 143 MUTATOR_HOOKFUNCTION(lms_SetStartItems)
 144 {
 145         start_items &= ~IT_UNLIMITED_AMMO;
 146         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 147         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 148         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 149         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 150         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 151         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 152         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 153         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 154
 155         return false;
 156 }
 157
 158 MUTATOR_HOOKFUNCTION(lms_KeepScore)
 159 {
 160         // don't clear player score
 161         return true;
 162 }
 163
 164 MUTATOR_HOOKFUNCTION(lms_FilterItem)
 165 {SELFPARAM();
 166         if(autocvar_g_lms_extra_lives)
 167         if(self.itemdef == ITEM_HealthMega)
 168         {
 169                 self.max_health = 1;
 170                 return false;
 171         }
 172
 173         return true;
 174 }
 175
 176 MUTATOR_HOOKFUNCTION(lms_ItemTouch)
 177 {SELFPARAM();
 178         // give extra lives for mega health
 179         if (self.items & ITEM_HealthMega.m_itemid)
 180         {
 181                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 182                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 183         }
 184
 185         return MUT_ITEMTOUCH_CONTINUE;
 186 }
 187
 188 // scoreboard stuff
 189 void lms_ScoreRules()
 190 {
 191         ScoreRules_basics(0, 0, 0, false);
 192         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 193         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 194         ScoreRules_basics_end();
 195 }
 196
 197 void lms_Initialize()
 198 {
 199         lms_lowest_lives = 9999;
 200         lms_next_place = 0;
 201
 202         lms_ScoreRules();
 203 }
 204
 205 MUTATOR_DEFINITION(gamemode_lms)
 206 {
 207         MUTATOR_HOOK(reset_map_global, lms_ResetMap, CBC_ORDER_ANY);
 208         MUTATOR_HOOK(reset_map_players, lms_ResetPlayers, CBC_ORDER_ANY);
 209         MUTATOR_HOOK(PutClientInServer, lms_PlayerPreSpawn, CBC_ORDER_ANY);
 210         MUTATOR_HOOK(PlayerDies, lms_PlayerDies, CBC_ORDER_ANY);
 211         MUTATOR_HOOK(MakePlayerObserver, lms_RemovePlayer, CBC_ORDER_ANY);
 212         MUTATOR_HOOK(ClientConnect, lms_ClientConnect, CBC_ORDER_ANY);
 213         MUTATOR_HOOK(PlayerPreThink, lms_PlayerThink, CBC_ORDER_ANY);
 214         MUTATOR_HOOK(PlayerRegen, lms_PlayerRegen, CBC_ORDER_ANY);
 215         MUTATOR_HOOK(ForbidThrowCurrentWeapon, lms_ForbidThrowing, CBC_ORDER_ANY);
 216         MUTATOR_HOOK(GiveFragsForKill, lms_GiveFragsForKill, CBC_ORDER_ANY);
 217         MUTATOR_HOOK(SetStartItems, lms_SetStartItems, CBC_ORDER_ANY);
 218         MUTATOR_HOOK(ForbidPlayerScore_Clear, lms_KeepScore, CBC_ORDER_ANY);
 219         MUTATOR_HOOK(FilterItem, lms_FilterItem, CBC_ORDER_ANY);
 220         MUTATOR_HOOK(ItemTouch, lms_ItemTouch, CBC_ORDER_ANY);
 221
 222         MUTATOR_ONADD
 223         {
 224                 if(time > 1) // game loads at time 1
 225                         error("This is a game type and it cannot be added at runtime.");
 226                 lms_Initialize();
 227         }
 228
 229         MUTATOR_ONROLLBACK_OR_REMOVE
 230         {
 231                 // we actually cannot roll back lms_Initialize here
 232                 // BUT: we don't need to! If this gets called, adding always
 233                 // succeeds.
 234         }
 235
 236         MUTATOR_ONREMOVE
 237         {
 238                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
 239                 return -1;
 240         }
 241
 242         return 0;
 243 }