qcsrc/server/mutators/mutator/gamemode_keepaway.qc

   1 #include "gamemode_keepaway.qh"
   2
   3 int autocvar_g_keepaway_ballcarrier_effects;
   4 float autocvar_g_keepaway_ballcarrier_damage;
   5 float autocvar_g_keepaway_ballcarrier_force;
   6 float autocvar_g_keepaway_ballcarrier_highspeed;
   7 float autocvar_g_keepaway_ballcarrier_selfdamage;
   8 float autocvar_g_keepaway_ballcarrier_selfforce;
   9 float autocvar_g_keepaway_noncarrier_damage;
  10 float autocvar_g_keepaway_noncarrier_force;
  11 float autocvar_g_keepaway_noncarrier_selfdamage;
  12 float autocvar_g_keepaway_noncarrier_selfforce;
  13 bool autocvar_g_keepaway_noncarrier_warn;
  14 int autocvar_g_keepaway_score_bckill;
  15 int autocvar_g_keepaway_score_killac;
  16 int autocvar_g_keepaway_score_timepoints;
  17 float autocvar_g_keepaway_score_timeinterval;
  18 float autocvar_g_keepawayball_damageforcescale;
  19 int autocvar_g_keepawayball_effects;
  20 float autocvar_g_keepawayball_respawntime;
  21 int autocvar_g_keepawayball_trail_color;
  22
  23 bool ka_ballcarrier_waypointsprite_visible_for_player(entity this, entity player, entity view) // runs on waypoints which are attached to ballcarriers, updates once per frame
  24 {
  25         if(view.ballcarried)
  26                 if(IS_SPEC(player))
  27                         return false; // we don't want spectators of the ballcarrier to see the attached waypoint on the top of their screen
  28
  29         // TODO: Make the ballcarrier lack a waypointsprite whenever they have the invisibility powerup
  30
  31         return true;
  32 }
  33
  34 void ka_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  35 {
  36         if(autocvar_sv_eventlog)
  37                 GameLogEcho(strcat(":ka:", mode, ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  38 }
  39
  40 void ka_TouchEvent(entity this, entity toucher);
  41 void ka_RespawnBall(entity this);
  42 void ka_RespawnBall(entity this) // runs whenever the ball needs to be relocated
  43 {
  44         if(gameover) { return; }
  45         vector oldballorigin = this.origin;
  46
  47         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
  48         {
  49                 entity spot = SelectSpawnPoint(this, true);
  50                 setorigin(this, spot.origin);
  51                 this.angles = spot.angles;
  52         }
  53
  54         makevectors(this.angles);
  55         set_movetype(this, MOVETYPE_BOUNCE);
  56         this.velocity = '0 0 200';
  57         this.angles = '0 0 0';
  58         this.effects = autocvar_g_keepawayball_effects;
  59         settouch(this, ka_TouchEvent);
  60         setthink(this, ka_RespawnBall);
  61         this.nextthink = time + autocvar_g_keepawayball_respawntime;
  62
  63         Send_Effect(EFFECT_ELECTRO_COMBO, oldballorigin, '0 0 0', 1);
  64         Send_Effect(EFFECT_ELECTRO_COMBO, this.origin, '0 0 0', 1);
  65
  66         WaypointSprite_Spawn(WP_KaBall, 0, 0, this, '0 0 64', NULL, this.team, this, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
  67         WaypointSprite_Ping(this.waypointsprite_attachedforcarrier);
  68
  69         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
  70 }
  71
  72 void ka_TimeScoring(entity this)
  73 {
  74         if(this.owner.ballcarried)
  75         { // add points for holding the ball after a certain amount of time
  76                 if(autocvar_g_keepaway_score_timepoints)
  77                         PlayerScore_Add(this.owner, SP_SCORE, autocvar_g_keepaway_score_timepoints);
  78
  79                 PlayerScore_Add(this.owner, SP_KEEPAWAY_BCTIME, (autocvar_g_keepaway_score_timeinterval / 1)); // interval is divided by 1 so that time always shows "seconds"
  80                 this.nextthink = time + autocvar_g_keepaway_score_timeinterval;
  81         }
  82 }
  83
  84 void ka_TouchEvent(entity this, entity toucher) // runs any time that the ball comes in contact with something
  85 {
  86         if(gameover) { return; }
  87         if(!this) { return; }
  88         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  89         { // The ball fell off the map, respawn it since players can't get to it
  90                 ka_RespawnBall(this);
  91                 return;
  92         }
  93         if(IS_DEAD(toucher)) { return; }
  94         if(STAT(FROZEN, toucher)) { return; }
  95         if (!IS_PLAYER(toucher))
  96         {  // The ball just touched an object, most likely the world
  97                 Send_Effect(EFFECT_BALL_SPARKS, this.origin, '0 0 0', 1);
  98                 sound(this, CH_TRIGGER, SND_KA_TOUCH, VOL_BASE, ATTEN_NORM);
  99                 return;
 100         }
 101         else if(this.wait > time) { return; }
 102
 103         // attach the ball to the player
 104         this.owner = toucher;
 105         toucher.ballcarried = this;
 106         setattachment(this, toucher, "");
 107         setorigin(this, '0 0 0');
 108
 109         // make the ball invisible/unable to do anything/set up time scoring
 110         this.velocity = '0 0 0';
 111         set_movetype(this, MOVETYPE_NONE);
 112         this.effects |= EF_NODRAW;
 113         settouch(this, func_null);
 114         setthink(this, ka_TimeScoring);
 115         this.nextthink = time + autocvar_g_keepaway_score_timeinterval;
 116         this.takedamage = DAMAGE_NO;
 117
 118         // apply effects to player
 119         toucher.glow_color = autocvar_g_keepawayball_trail_color;
 120         toucher.glow_trail = true;
 121         toucher.effects |= autocvar_g_keepaway_ballcarrier_effects;
 122
 123         // messages and sounds
 124         ka_EventLog("pickup", toucher);
 125         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_PICKUP, toucher.netname);
 126         Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP, toucher.netname);
 127         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP_SELF);
 128         sound(this.owner, CH_TRIGGER, SND_KA_PICKEDUP, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 129
 130         // scoring
 131         PlayerScore_Add(toucher, SP_KEEPAWAY_PICKUPS, 1);
 132
 133         // waypoints
 134         WaypointSprite_AttachCarrier(WP_KaBallCarrier, toucher, RADARICON_FLAGCARRIER);
 135         toucher.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = ka_ballcarrier_waypointsprite_visible_for_player;
 136         WaypointSprite_UpdateRule(toucher.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 137         WaypointSprite_Ping(toucher.waypointsprite_attachedforcarrier);
 138         WaypointSprite_Kill(this.waypointsprite_attachedforcarrier);
 139 }
 140
 141 void ka_DropEvent(entity plyr) // runs any time that a player is supposed to lose the ball
 142 {
 143         entity ball;
 144         ball = plyr.ballcarried;
 145
 146         if(!ball) { return; }
 147
 148         // reset the ball
 149         setattachment(ball, NULL, "");
 150         set_movetype(ball, MOVETYPE_BOUNCE);
 151         ball.wait = time + 1;
 152         settouch(ball, ka_TouchEvent);
 153         setthink(ball, ka_RespawnBall);
 154         ball.nextthink = time + autocvar_g_keepawayball_respawntime;
 155         ball.takedamage = DAMAGE_YES;
 156         ball.effects &= ~EF_NODRAW;
 157         setorigin(ball, plyr.origin + '0 0 10');
 158         ball.velocity = '0 0 200' + '0 100 0'*crandom() + '100 0 0'*crandom();
 159         ball.owner.ballcarried = world; // I hope nothing checks to see if the world has the ball in the rest of my code :P
 160         ball.owner = NULL;
 161
 162         // reset the player effects
 163         plyr.glow_trail = false;
 164         plyr.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 165
 166         // messages and sounds
 167         ka_EventLog("dropped", plyr);
 168         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_DROPPED, plyr.netname);
 169         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEEPAWAY_DROPPED, plyr.netname);
 170         sound(NULL, CH_TRIGGER, SND_KA_DROPPED, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 171
 172         // scoring
 173         // PlayerScore_Add(plyr, SP_KEEPAWAY_DROPS, 1); Not anymore, this is 100% the same as pickups and is useless.
 174
 175         // waypoints
 176         WaypointSprite_Spawn(WP_KaBall, 0, 0, ball, '0 0 64', NULL, ball.team, ball, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
 177         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 178         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 179         WaypointSprite_Kill(plyr.waypointsprite_attachedforcarrier);
 180 }
 181
 182 /** used to clear the ballcarrier whenever the match switches from warmup to normal */
 183 void ka_Reset(entity this)
 184 {
 185         if((this.owner) && (IS_PLAYER(this.owner)))
 186                 ka_DropEvent(this.owner);
 187
 188         if(time < game_starttime)
 189         {
 190                 setthink(this, ka_RespawnBall);
 191                 settouch(this, func_null);
 192                 this.nextthink = game_starttime;
 193         }
 194         else
 195                 ka_RespawnBall(this);
 196 }
 197
 198
 199 // ================
 200 // Bot player logic
 201 // ================
 202
 203 void havocbot_goalrating_ball(entity this, float ratingscale, vector org)
 204 {
 205         float t;
 206         entity ball_owner;
 207         ball_owner = ka_ball.owner;
 208
 209         if (ball_owner == this)
 210                 return;
 211
 212         // If ball is carried by player then hunt them down.
 213         if (ball_owner)
 214         {
 215                 t = (this.health + this.armorvalue) / (ball_owner.health + ball_owner.armorvalue);
 216                 navigation_routerating(this, ball_owner, t * ratingscale, 2000);
 217         }
 218         else // Ball has been dropped so collect.
 219                 navigation_routerating(this, ka_ball, ratingscale, 2000);
 220 }
 221
 222 void havocbot_role_ka_carrier(entity this)
 223 {
 224         if (IS_DEAD(this))
 225                 return;
 226
 227         if (time > this.bot_strategytime)
 228         {
 229                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 230
 231                 navigation_goalrating_start(this);
 232                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 233                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 10000);
 234                 //havocbot_goalrating_waypoints(1, this.origin, 1000);
 235                 navigation_goalrating_end(this);
 236         }
 237
 238         if (!this.ballcarried)
 239         {
 240                 this.havocbot_role = havocbot_role_ka_collector;
 241                 this.bot_strategytime = 0;
 242         }
 243 }
 244
 245 void havocbot_role_ka_collector(entity this)
 246 {
 247         if (IS_DEAD(this))
 248                 return;
 249
 250         if (time > this.bot_strategytime)
 251         {
 252                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 253
 254                 navigation_goalrating_start(this);
 255                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 256                 havocbot_goalrating_enemyplayers(this, 1000, this.origin, 10000);
 257                 havocbot_goalrating_ball(this, 20000, this.origin);
 258                 navigation_goalrating_end(this);
 259         }
 260
 261         if (this.ballcarried)
 262         {
 263                 this.havocbot_role = havocbot_role_ka_carrier;
 264                 this.bot_strategytime = 0;
 265         }
 266 }
 267
 268
 269 // ==============
 270 // Hook Functions
 271 // ==============
 272
 273 MUTATOR_HOOKFUNCTION(ka, PlayerDies)
 274 {
 275         entity frag_attacker = M_ARGV(1, entity);
 276         entity frag_target = M_ARGV(2, entity);
 277
 278         if((frag_attacker != frag_target) && (IS_PLAYER(frag_attacker)))
 279         {
 280                 if(frag_target.ballcarried) { // add to amount of times killing carrier
 281                         PlayerScore_Add(frag_attacker, SP_KEEPAWAY_CARRIERKILLS, 1);
 282                         if(autocvar_g_keepaway_score_bckill) // add bckills to the score
 283                                 PlayerScore_Add(frag_attacker, SP_SCORE, autocvar_g_keepaway_score_bckill);
 284                 }
 285                 else if(!frag_attacker.ballcarried)
 286                         if(autocvar_g_keepaway_noncarrier_warn)
 287                                 Send_Notification(NOTIF_ONE_ONLY, frag_attacker, MSG_CENTER, CENTER_KEEPAWAY_WARN);
 288
 289                 if(frag_attacker.ballcarried) // add to amount of kills while ballcarrier
 290                         PlayerScore_Add(frag_attacker, SP_SCORE, autocvar_g_keepaway_score_killac);
 291         }
 292
 293         if(frag_target.ballcarried) { ka_DropEvent(frag_target); } // a player with the ball has died, drop it
 294 }
 295
 296 MUTATOR_HOOKFUNCTION(ka, GiveFragsForKill)
 297 {
 298         M_ARGV(2, float) = 0; // no frags counted in keepaway
 299         return true; // you deceptive little bugger ;3 This needs to be true in order for this function to even count.
 300 }
 301
 302 MUTATOR_HOOKFUNCTION(ka, PlayerPreThink)
 303 {
 304         entity player = M_ARGV(0, entity);
 305
 306         // clear the item used for the ball in keepaway
 307         player.items &= ~IT_KEY1;
 308
 309         // if the player has the ball, make sure they have the item for it (Used for HUD primarily)
 310         if(player.ballcarried)
 311                 player.items |= IT_KEY1;
 312 }
 313
 314 MUTATOR_HOOKFUNCTION(ka, PlayerUseKey)
 315 {
 316         entity player = M_ARGV(0, entity);
 317
 318         if(MUTATOR_RETURNVALUE == 0)
 319         if(player.ballcarried)
 320         {
 321                 ka_DropEvent(player);
 322                 return true;
 323         }
 324 }
 325
 326 MUTATOR_HOOKFUNCTION(ka, PlayerDamage_Calculate) // for changing damage and force values that are applied to players in g_damage.qc
 327 {
 328         entity frag_attacker = M_ARGV(1, entity);
 329         entity frag_target = M_ARGV(2, entity);
 330         float frag_damage = M_ARGV(4, float);
 331         vector frag_force = M_ARGV(6, vector);
 332
 333         if(frag_attacker.ballcarried) // if the attacker is a ballcarrier
 334         {
 335                 if(frag_target == frag_attacker) // damage done to yourself
 336                 {
 337                         frag_damage *= autocvar_g_keepaway_ballcarrier_selfdamage;
 338                         frag_force *= autocvar_g_keepaway_ballcarrier_selfforce;
 339                 }
 340                 else // damage done to noncarriers
 341                 {
 342                         frag_damage *= autocvar_g_keepaway_ballcarrier_damage;
 343                         frag_force *= autocvar_g_keepaway_ballcarrier_force;
 344                 }
 345         }
 346         else if (!frag_target.ballcarried) // if the target is a noncarrier
 347         {
 348                 if(frag_target == frag_attacker) // damage done to yourself
 349                 {
 350                         frag_damage *= autocvar_g_keepaway_noncarrier_selfdamage;
 351                         frag_force *= autocvar_g_keepaway_noncarrier_selfforce;
 352                 }
 353                 else // damage done to other noncarriers
 354                 {
 355                         frag_damage *= autocvar_g_keepaway_noncarrier_damage;
 356                         frag_force *= autocvar_g_keepaway_noncarrier_force;
 357                 }
 358         }
 359
 360         M_ARGV(4, float) = frag_damage;
 361         M_ARGV(6, vector) = frag_force;
 362 }
 363
 364 MUTATOR_HOOKFUNCTION(ka, ClientDisconnect)
 365 {
 366         entity player = M_ARGV(0, entity);
 367
 368         if(player.ballcarried) { ka_DropEvent(player); } // a player with the ball has left the match, drop it
 369 }
 370
 371 MUTATOR_HOOKFUNCTION(ka, MakePlayerObserver)
 372 {
 373         entity player = M_ARGV(0, entity);
 374
 375         if(player.ballcarried) { ka_DropEvent(player); } // a player with the ball has left the match, drop it
 376 }
 377
 378 MUTATOR_HOOKFUNCTION(ka, PlayerPowerups)
 379 {
 380         entity player = M_ARGV(0, entity);
 381
 382         // In the future this hook is supposed to allow me to do some extra stuff with waypointsprites and invisibility powerup
 383         // So bare with me until I can fix a certain bug with ka_ballcarrier_waypointsprite_visible_for_player()
 384
 385         player.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 386
 387         if(player.ballcarried)
 388                 player.effects |= autocvar_g_keepaway_ballcarrier_effects;
 389 }
 390
 391 .float stat_sv_airspeedlimit_nonqw;
 392 .float stat_sv_maxspeed;
 393
 394 MUTATOR_HOOKFUNCTION(ka, PlayerPhysics)
 395 {
 396         entity player = M_ARGV(0, entity);
 397
 398         if(player.ballcarried)
 399         {
 400                 player.stat_sv_airspeedlimit_nonqw *= autocvar_g_keepaway_ballcarrier_highspeed;
 401                 player.stat_sv_maxspeed *= autocvar_g_keepaway_ballcarrier_highspeed;
 402         }
 403 }
 404
 405 MUTATOR_HOOKFUNCTION(ka, BotShouldAttack)
 406 {
 407         entity bot = M_ARGV(0, entity);
 408         entity targ = M_ARGV(1, entity);
 409
 410         // if neither player has ball then don't attack unless the ball is on the ground
 411         if(!targ.ballcarried && !bot.ballcarried && ka_ball.owner)
 412                 return true;
 413 }
 414
 415 MUTATOR_HOOKFUNCTION(ka, HavocBot_ChooseRole)
 416 {
 417         entity bot = M_ARGV(0, entity);
 418
 419         if (bot.ballcarried)
 420                 bot.havocbot_role = havocbot_role_ka_carrier;
 421         else
 422                 bot.havocbot_role = havocbot_role_ka_collector;
 423         return true;
 424 }
 425
 426 MUTATOR_HOOKFUNCTION(ka, DropSpecialItems)
 427 {
 428         entity frag_target = M_ARGV(0, entity);
 429
 430         if(frag_target.ballcarried)
 431                 ka_DropEvent(frag_target);
 432 }
 433
 434 .bool pushable;
 435
 436 // ==============
 437 // Initialization
 438 // ==============
 439
 440 void ka_SpawnBall() // loads various values for the ball, runs only once at start of match
 441 {
 442         entity e = new(keepawayball);
 443         e.model = "models/orbs/orbblue.md3";
 444         precache_model(e.model);
 445         _setmodel(e, e.model);
 446         setsize(e, '-16 -16 -20', '16 16 20'); // 20 20 20 was too big, player is only 16 16 24... gotta cheat with the Z (20) axis so that the particle isn't cut off
 447         e.damageforcescale = autocvar_g_keepawayball_damageforcescale;
 448         e.takedamage = DAMAGE_YES;
 449         e.solid = SOLID_TRIGGER;
 450         set_movetype(e, MOVETYPE_BOUNCE);
 451         e.glow_color = autocvar_g_keepawayball_trail_color;
 452         e.glow_trail = true;
 453         e.flags = FL_ITEM;
 454         e.pushable = true;
 455         e.reset = ka_Reset;
 456         settouch(e, ka_TouchEvent);
 457         e.owner = NULL;
 458         ka_ball = e;
 459
 460         InitializeEntity(e, ka_RespawnBall, INITPRIO_SETLOCATION); // is this the right priority? Neh, I have no idea.. Well-- it works! So.
 461 }
 462
 463 void ka_ScoreRules()
 464 {
 465         ScoreRules_basics(0, SFL_SORT_PRIO_PRIMARY, 0, true); // SFL_SORT_PRIO_PRIMARY
 466         ScoreInfo_SetLabel_PlayerScore(SP_KEEPAWAY_PICKUPS,             "pickups",              0);
 467         ScoreInfo_SetLabel_PlayerScore(SP_KEEPAWAY_CARRIERKILLS,   "bckills",           0);
 468         ScoreInfo_SetLabel_PlayerScore(SP_KEEPAWAY_BCTIME,                  "bctime",           SFL_SORT_PRIO_SECONDARY);
 469         ScoreRules_basics_end();
 470 }
 471
 472 void ka_Initialize() // run at the start of a match, initiates game mode
 473 {
 474         ka_ScoreRules();
 475         ka_SpawnBall();
 476 }