qcsrc/server/mutators/mutator/gamemode_lms.qc

   1 #include "gamemode_lms.qh"
   2 #ifndef GAMEMODE_LMS_H
   3 #define GAMEMODE_LMS_H
   4
   5 #define autocvar_g_lms_lives_override cvar("g_lms_lives_override")
   6 void lms_Initialize();
   7
   8 REGISTER_MUTATOR(lms, false)
   9 {
  10         MUTATOR_ONADD
  11         {
  12                 if (time > 1) // game loads at time 1
  13                         error("This is a game type and it cannot be added at runtime.");
  14                 lms_Initialize();
  15
  16                 SetLimits(((!autocvar_g_lms_lives_override) ? -1 : autocvar_g_lms_lives_override), 0, -1, -1);
  17         }
  18
  19         MUTATOR_ONROLLBACK_OR_REMOVE
  20         {
  21                 // we actually cannot roll back lms_Initialize here
  22                 // BUT: we don't need to! If this gets called, adding always
  23                 // succeeds.
  24         }
  25
  26         MUTATOR_ONREMOVE
  27         {
  28                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  29                 return -1;
  30         }
  31
  32         return 0;
  33 }
  34
  35 // scoreboard stuff
  36 const float SP_LMS_LIVES = 4;
  37 const float SP_LMS_RANK = 5;
  38
  39 // lives related defs
  40 float lms_lowest_lives;
  41 float lms_next_place;
  42 float LMS_NewPlayerLives();
  43
  44 #endif
  45
  46 #ifdef IMPLEMENTATION
  47
  48 #include <common/mutators/mutator/instagib/items.qc>
  49 #include <server/campaign.qh>
  50 #include <server/command/cmd.qh>
  51
  52 int autocvar_g_lms_extra_lives;
  53 bool autocvar_g_lms_join_anytime;
  54 int autocvar_g_lms_last_join;
  55 bool autocvar_g_lms_regenerate;
  56
  57 // main functions
  58 float LMS_NewPlayerLives()
  59 {
  60         float fl;
  61         fl = autocvar_fraglimit;
  62         if(fl == 0)
  63                 fl = 999;
  64
  65         // first player has left the game for dying too much? Nobody else can get in.
  66         if(lms_lowest_lives < 1)
  67                 return 0;
  68
  69         if(!autocvar_g_lms_join_anytime)
  70                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  71                         return 0;
  72
  73         return bound(1, lms_lowest_lives, fl);
  74 }
  75
  76 void ClearWinners();
  77
  78 // LMS winning condition: game terminates if and only if there's at most one
  79 // one player who's living lives. Top two scores being equal cancels the time
  80 // limit.
  81 int WinningCondition_LMS()
  82 {
  83         entity head, head2;
  84         bool have_player = false;
  85         bool have_players = false;
  86
  87         int l = LMS_NewPlayerLives();
  88
  89         head = find(world, classname, STR_PLAYER);
  90         if(head)
  91                 have_player = true;
  92         head2 = find(head, classname, STR_PLAYER);
  93         if(head2)
  94                 have_players = true;
  95
  96         if(have_player)
  97         {
  98                 // we have at least one player
  99                 if(have_players)
 100                 {
 101                         // two or more active players - continue with the game
 102                 }
 103                 else
 104                 {
 105                         // exactly one player?
 106
 107                         ClearWinners();
 108                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
 109
 110                         if(l)
 111                         {
 112                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
 113                                 return WINNING_NO;
 114                         }
 115                         else
 116                         {
 117                                 // a winner!
 118                                 // and assign him his first place
 119                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
 120                                 return WINNING_YES;
 121                         }
 122                 }
 123         }
 124         else
 125         {
 126                 // nobody is playing at all...
 127                 if(l)
 128                 {
 129                         // wait for players...
 130                 }
 131                 else
 132                 {
 133                         // SNAFU (maybe a draw game?)
 134                         ClearWinners();
 135                         LOG_TRACE("No players, ending game.\n");
 136                         return WINNING_YES;
 137                 }
 138         }
 139
 140         // When we get here, we have at least two players who are actually LIVING,
 141         // now check if the top two players have equal score.
 142         WinningConditionHelper();
 143
 144         ClearWinners();
 145         if(WinningConditionHelper_winner)
 146                 WinningConditionHelper_winner.winning = true;
 147         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
 148                 return WINNING_NEVER;
 149
 150         // Top two have different scores? Way to go for our beloved TIMELIMIT!
 151         return WINNING_NO;
 152 }
 153
 154 // mutator hooks
 155 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
 156 {
 157         lms_lowest_lives = 999;
 158         lms_next_place = player_count;
 159
 160         return false;
 161 }
 162
 163 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
 164 {
 165         if(restart_mapalreadyrestarted || (time < game_starttime))
 166         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(PlayerScore_Add(it, SP_LMS_LIVES, LMS_NewPlayerLives())));
 167         return false;
 168 }
 169
 170 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
 171 {SELFPARAM();
 172         // player is dead and becomes observer
 173         // FIXME fix LMS scoring for new system
 174         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 175         {
 176                 TRANSMUTE(Observer, self);
 177                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_NOLIVES);
 178         }
 179 }
 180
 181 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
 182 {
 183         frag_target.respawn_flags |= RESPAWN_FORCE;
 184         return false;
 185 }
 186
 187 void lms_RemovePlayer(entity player)
 188 {
 189         // Only if the player cannot play at all
 190         if(PlayerScore_Add(player, SP_LMS_RANK, 0) == 666)
 191                 player.frags = FRAGS_SPECTATOR;
 192         else
 193                 player.frags = FRAGS_LMS_LOSER;
 194
 195         if(player.killcount != FRAGS_SPECTATOR)
 196                 if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0 && player.lms_spectate_warning != 2)
 197                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
 198                 else
 199                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
 200 }
 201
 202 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
 203 {SELFPARAM();
 204         lms_RemovePlayer(self);
 205         return false;
 206 }
 207
 208 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
 209 {
 210     SELFPARAM();
 211         lms_RemovePlayer(this);
 212         return true;  // prevent team reset
 213 }
 214
 215 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
 216 {SELFPARAM();
 217         TRANSMUTE(Player, self);
 218         campaign_bots_may_start = true;
 219
 220         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 221         {
 222                 PlayerScore_Add(self, SP_LMS_RANK, 666);
 223                 self.frags = FRAGS_SPECTATOR;
 224         }
 225
 226         return false;
 227 }
 228
 229 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
 230 {SELFPARAM();
 231         if(self.deadflag == DEAD_DYING)
 232                 self.deadflag = DEAD_RESPAWNING;
 233
 234         return false;
 235 }
 236
 237 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
 238 {
 239         if(autocvar_g_lms_regenerate)
 240                 return false;
 241         return true;
 242 }
 243
 244 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
 245 {
 246         // forbode!
 247         return true;
 248 }
 249
 250 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
 251 {
 252         // remove a life
 253         float tl;
 254         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 255         if(tl < lms_lowest_lives)
 256                 lms_lowest_lives = tl;
 257         if(tl <= 0)
 258         {
 259                 if(!lms_next_place)
 260                         lms_next_place = player_count;
 261                 else
 262                         lms_next_place = min(lms_next_place, player_count);
 263                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 264                 --lms_next_place;
 265         }
 266         frag_score = 0;
 267
 268         return true;
 269 }
 270
 271 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
 272 {
 273         start_items &= ~IT_UNLIMITED_AMMO;
 274         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 275         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 276         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 277         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 278         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 279         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 280         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 281         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 282
 283         return false;
 284 }
 285
 286 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
 287 {
 288         // don't clear player score
 289         return true;
 290 }
 291
 292 MUTATOR_HOOKFUNCTION(lms, FilterItem)
 293 {SELFPARAM();
 294         if(autocvar_g_lms_extra_lives)
 295         if(self.itemdef == ITEM_ExtraLife)
 296                 return false;
 297
 298         return true;
 299 }
 300
 301 void lms_extralife()
 302 {SELFPARAM();
 303         StartItem(this, ITEM_ExtraLife);
 304 }
 305
 306 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
 307 {SELFPARAM();
 308         if (!autocvar_g_powerups) return false;
 309         if (!autocvar_g_lms_extra_lives) return false;
 310
 311         // Can't use .itemdef here
 312         if (self.classname != "item_health_mega") return false;
 313
 314         entity e = spawn();
 315         e.think = lms_extralife;
 316
 317         e.nextthink = time + 0.1;
 318         e.spawnflags = self.spawnflags;
 319         e.noalign = self.noalign;
 320         setorigin(e, self.origin);
 321
 322         return true;
 323 }
 324
 325 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
 326 {SELFPARAM();
 327         if(self.itemdef == ITEM_ExtraLife)
 328         {
 329                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 330                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 331                 return MUT_ITEMTOUCH_PICKUP;
 332         }
 333
 334         return MUT_ITEMTOUCH_CONTINUE;
 335 }
 336
 337 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 338 {
 339         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 340                 ++bot_activerealplayers;
 341                 ++bot_realplayers;
 342         ));
 343
 344         return true;
 345 }
 346
 347 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
 348 {
 349     SELFPARAM();
 350         if(self.lms_spectate_warning)
 351         {
 352                 // for the forfeit message...
 353                 self.lms_spectate_warning = 2;
 354                 // mark player as spectator
 355                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 356         }
 357         else
 358         {
 359                 self.lms_spectate_warning = 1;
 360                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 361                 return MUT_SPECCMD_RETURN;
 362         }
 363         return MUT_SPECCMD_CONTINUE;
 364 }
 365
 366 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
 367 {
 368         ret_float = WinningCondition_LMS();
 369         return true;
 370 }
 371
 372 MUTATOR_HOOKFUNCTION(lms, WantWeapon)
 373 {
 374         want_allguns = true;
 375         return false;
 376 }
 377
 378 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
 379 {
 380         return true;
 381 }
 382
 383 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
 384 {
 385         if(gameover)
 386         if(score_field == SP_LMS_RANK)
 387                 return true; // allow writing to this field in intermission as it is needed for newly joining players
 388         return false;
 389 }
 390
 391 // scoreboard stuff
 392 void lms_ScoreRules()
 393 {
 394         ScoreRules_basics(0, 0, 0, false);
 395         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 396         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 397         ScoreRules_basics_end();
 398 }
 399
 400 void lms_Initialize()
 401 {
 402         lms_lowest_lives = 9999;
 403         lms_next_place = 0;
 404
 405         lms_ScoreRules();
 406 }
 407
 408
 409 #endif