qcsrc/server/mutators/mutator/gamemode_lms.qc

   1 #ifndef GAMEMODE_LMS_H
   2 #define GAMEMODE_LMS_H
   3
   4 #define autocvar_g_lms_lives_override cvar("g_lms_lives_override")
   5 void lms_Initialize();
   6
   7 REGISTER_MUTATOR(lms, false)
   8 {
   9         MUTATOR_ONADD
  10         {
  11                 if (time > 1) // game loads at time 1
  12                         error("This is a game type and it cannot be added at runtime.");
  13                 lms_Initialize();
  14
  15                 SetLimits(((!autocvar_g_lms_lives_override) ? -1 : autocvar_g_lms_lives_override), 0, -1, -1);
  16         }
  17
  18         MUTATOR_ONROLLBACK_OR_REMOVE
  19         {
  20                 // we actually cannot roll back lms_Initialize here
  21                 // BUT: we don't need to! If this gets called, adding always
  22                 // succeeds.
  23         }
  24
  25         MUTATOR_ONREMOVE
  26         {
  27                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  28                 return -1;
  29         }
  30
  31         return 0;
  32 }
  33
  34 // scoreboard stuff
  35 const float SP_LMS_LIVES = 4;
  36 const float SP_LMS_RANK = 5;
  37
  38 // lives related defs
  39 float lms_lowest_lives;
  40 float lms_next_place;
  41 float LMS_NewPlayerLives();
  42
  43 #endif
  44
  45 #ifdef IMPLEMENTATION
  46
  47 #include <server/campaign.qh>
  48 #include <server/command/cmd.qh>
  49
  50 int autocvar_g_lms_extra_lives;
  51 bool autocvar_g_lms_join_anytime;
  52 int autocvar_g_lms_last_join;
  53 bool autocvar_g_lms_regenerate;
  54
  55 // main functions
  56 float LMS_NewPlayerLives()
  57 {
  58         float fl;
  59         fl = autocvar_fraglimit;
  60         if(fl == 0)
  61                 fl = 999;
  62
  63         // first player has left the game for dying too much? Nobody else can get in.
  64         if(lms_lowest_lives < 1)
  65                 return 0;
  66
  67         if(!autocvar_g_lms_join_anytime)
  68                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  69                         return 0;
  70
  71         return bound(1, lms_lowest_lives, fl);
  72 }
  73
  74 // LMS winning condition: game terminates if and only if there's at most one
  75 // one player who's living lives. Top two scores being equal cancels the time
  76 // limit.
  77 int WinningCondition_LMS()
  78 {
  79         entity head, head2;
  80         bool have_player = false;
  81         bool have_players = false;
  82
  83         int l = LMS_NewPlayerLives();
  84
  85         head = find(world, classname, STR_PLAYER);
  86         if(head)
  87                 have_player = true;
  88         head2 = find(head, classname, STR_PLAYER);
  89         if(head2)
  90                 have_players = true;
  91
  92         if(have_player)
  93         {
  94                 // we have at least one player
  95                 if(have_players)
  96                 {
  97                         // two or more active players - continue with the game
  98                 }
  99                 else
 100                 {
 101                         // exactly one player?
 102
 103                         ClearWinners();
 104                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
 105
 106                         if(l)
 107                         {
 108                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
 109                                 return WINNING_NO;
 110                         }
 111                         else
 112                         {
 113                                 // a winner!
 114                                 // and assign him his first place
 115                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
 116                                 return WINNING_YES;
 117                         }
 118                 }
 119         }
 120         else
 121         {
 122                 // nobody is playing at all...
 123                 if(l)
 124                 {
 125                         // wait for players...
 126                 }
 127                 else
 128                 {
 129                         // SNAFU (maybe a draw game?)
 130                         ClearWinners();
 131                         LOG_TRACE("No players, ending game.\n");
 132                         return WINNING_YES;
 133                 }
 134         }
 135
 136         // When we get here, we have at least two players who are actually LIVING,
 137         // now check if the top two players have equal score.
 138         WinningConditionHelper();
 139
 140         ClearWinners();
 141         if(WinningConditionHelper_winner)
 142                 WinningConditionHelper_winner.winning = true;
 143         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
 144                 return WINNING_NEVER;
 145
 146         // Top two have different scores? Way to go for our beloved TIMELIMIT!
 147         return WINNING_NO;
 148 }
 149
 150 // mutator hooks
 151 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
 152 {
 153         lms_lowest_lives = 999;
 154         lms_next_place = player_count;
 155
 156         return false;
 157 }
 158
 159 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
 160 {
 161         if(restart_mapalreadyrestarted || (time < game_starttime))
 162         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(PlayerScore_Add(it, SP_LMS_LIVES, LMS_NewPlayerLives())));
 163         return false;
 164 }
 165
 166 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
 167 {SELFPARAM();
 168         // player is dead and becomes observer
 169         // FIXME fix LMS scoring for new system
 170         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 171         {
 172                 self.classname = STR_OBSERVER;
 173                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_NOLIVES);
 174         }
 175
 176         return false;
 177 }
 178
 179 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
 180 {SELFPARAM();
 181         self.respawn_flags |= RESPAWN_FORCE;
 182
 183         return false;
 184 }
 185
 186 void lms_RemovePlayer(entity player)
 187 {
 188         // Only if the player cannot play at all
 189         if(PlayerScore_Add(player, SP_LMS_RANK, 0) == 666)
 190                 player.frags = FRAGS_SPECTATOR;
 191         else
 192                 player.frags = FRAGS_LMS_LOSER;
 193
 194         if(player.killcount != FRAGS_SPECTATOR)
 195                 if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0 && player.lms_spectate_warning != 2)
 196                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
 197                 else
 198                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
 199 }
 200
 201 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
 202 {SELFPARAM();
 203         lms_RemovePlayer(self);
 204         return false;
 205 }
 206
 207 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
 208 {SELFPARAM();
 209         lms_RemovePlayer(self);
 210         return false;
 211 }
 212
 213 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
 214 {SELFPARAM();
 215         self.classname = STR_PLAYER;
 216         campaign_bots_may_start = 1;
 217
 218         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 219         {
 220                 PlayerScore_Add(self, SP_LMS_RANK, 666);
 221                 self.frags = FRAGS_SPECTATOR;
 222         }
 223
 224         return false;
 225 }
 226
 227 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
 228 {SELFPARAM();
 229         if(self.deadflag == DEAD_DYING)
 230                 self.deadflag = DEAD_RESPAWNING;
 231
 232         return false;
 233 }
 234
 235 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
 236 {
 237         if(autocvar_g_lms_regenerate)
 238                 return false;
 239         return true;
 240 }
 241
 242 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
 243 {
 244         // forbode!
 245         return true;
 246 }
 247
 248 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
 249 {
 250         // remove a life
 251         float tl;
 252         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 253         if(tl < lms_lowest_lives)
 254                 lms_lowest_lives = tl;
 255         if(tl <= 0)
 256         {
 257                 if(!lms_next_place)
 258                         lms_next_place = player_count;
 259                 else
 260                         lms_next_place = min(lms_next_place, player_count);
 261                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 262                 --lms_next_place;
 263         }
 264         frag_score = 0;
 265
 266         return true;
 267 }
 268
 269 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
 270 {
 271         start_items &= ~IT_UNLIMITED_AMMO;
 272         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 273         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 274         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 275         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 276         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 277         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 278         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 279         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 280
 281         return false;
 282 }
 283
 284 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
 285 {
 286         // don't clear player score
 287         return true;
 288 }
 289
 290 MUTATOR_HOOKFUNCTION(lms, FilterItem)
 291 {SELFPARAM();
 292         if(autocvar_g_lms_extra_lives)
 293         if(self.itemdef == ITEM_ExtraLife)
 294                 return false;
 295
 296         return true;
 297 }
 298
 299 void lms_extralife()
 300 {SELFPARAM();
 301         StartItem(this, ITEM_ExtraLife);
 302 }
 303
 304 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
 305 {SELFPARAM();
 306         if (!autocvar_g_powerups) return false;
 307         if (!autocvar_g_lms_extra_lives) return false;
 308
 309         // Can't use .itemdef here
 310         if (self.classname != "item_health_mega") return false;
 311
 312         entity e = spawn();
 313         e.think = lms_extralife;
 314
 315         e.nextthink = time + 0.1;
 316         e.spawnflags = self.spawnflags;
 317         e.noalign = self.noalign;
 318         setorigin(e, self.origin);
 319
 320         return true;
 321 }
 322
 323 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
 324 {SELFPARAM();
 325         if(self.itemdef == ITEM_ExtraLife)
 326         {
 327                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 328                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 329                 return MUT_ITEMTOUCH_PICKUP;
 330         }
 331
 332         return MUT_ITEMTOUCH_CONTINUE;
 333 }
 334
 335 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 336 {
 337         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 338                 ++bot_activerealplayers;
 339                 ++bot_realplayers;
 340         ));
 341
 342         return true;
 343 }
 344
 345 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
 346 {
 347         if(self.lms_spectate_warning)
 348         {
 349                 // for the forfeit message...
 350                 self.lms_spectate_warning = 2;
 351                 // mark player as spectator
 352                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 353         }
 354         else
 355         {
 356                 self.lms_spectate_warning = 1;
 357                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 358                 return MUT_SPECCMD_RETURN;
 359         }
 360         return MUT_SPECCMD_CONTINUE;
 361 }
 362
 363 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
 364 {
 365         ret_float = WinningCondition_LMS();
 366         return true;
 367 }
 368
 369 MUTATOR_HOOKFUNCTION(lms, WantWeapon)
 370 {
 371         want_allguns = true;
 372         return false;
 373 }
 374
 375 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
 376 {
 377         return true;
 378 }
 379
 380 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
 381 {
 382         if(gameover)
 383         if(score_field == SP_LMS_RANK)
 384                 return true; // allow writing to this field in intermission as it is needed for newly joining players
 385         return false;
 386 }
 387
 388 // scoreboard stuff
 389 void lms_ScoreRules()
 390 {
 391         ScoreRules_basics(0, 0, 0, false);
 392         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 393         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 394         ScoreRules_basics_end();
 395 }
 396
 397 void lms_Initialize()
 398 {
 399         lms_lowest_lives = 9999;
 400         lms_next_place = 0;
 401
 402         lms_ScoreRules();
 403 }
 404
 405
 406 #endif