qcsrc/server/mutators/mutator/gamemode_race.qc

   1 #include "gamemode_race.qh"
   2
   3 #include <server/race.qh>
   4
   5 #define autocvar_g_race_laps_limit cvar("g_race_laps_limit")
   6 float autocvar_g_race_qualifying_timelimit;
   7 float autocvar_g_race_qualifying_timelimit_override;
   8 int autocvar_g_race_teams;
   9
  10 // legacy bot roles
  11 .float race_checkpoint;
  12 void havocbot_role_race(entity this)
  13 {
  14         if(IS_DEAD(this))
  15                 return;
  16
  17         if (navigation_goalrating_timeout(this))
  18         {
  19                 navigation_goalrating_start(this);
  20
  21                 bool raw_touch_check = true;
  22                 int cp = this.race_checkpoint;
  23
  24                 LABEL(search_racecheckpoints)
  25                 IL_EACH(g_racecheckpoints, true,
  26                 {
  27                         if(it.cnt == cp || cp == -1)
  28                         {
  29                                 // redirect bot to next goal if it touched the waypoint of an untouchable checkpoint
  30                                 // e.g. checkpoint in front of Stormkeep's warpzone
  31                                 // the same workaround is applied in CTS game mode
  32                                 if (raw_touch_check && vdist(this.origin - it.nearestwaypoint.origin, <, 30))
  33                                 {
  34                                         cp = race_NextCheckpoint(cp);
  35                                         raw_touch_check = false;
  36                                         goto search_racecheckpoints;
  37                                 }
  38                                 navigation_routerating(this, it, 1000000, 5000);
  39                         }
  40                 });
  41
  42                 navigation_goalrating_end(this);
  43
  44                 navigation_goalrating_timeout_set(this);
  45         }
  46 }
  47
  48 void race_ScoreRules()
  49 {
  50     GameRules_score_enabled(false);
  51         GameRules_scoring(race_teams, 0, 0, {
  52         if (race_teams) {
  53             field_team(ST_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  54             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  55             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  56             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  57         } else if (g_race_qualifying) {
  58             field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  59         } else {
  60             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  61             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  62             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  63         }
  64         });
  65 }
  66
  67 void race_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  68 {
  69         if(autocvar_sv_eventlog)
  70                 GameLogEcho(strcat(":race:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  71 }
  72
  73 float WinningCondition_Race(float fraglimit)
  74 {
  75         float wc;
  76         float n, c;
  77
  78         n = 0;
  79         c = 0;
  80         FOREACH_CLIENT(IS_PLAYER(it), {
  81                 ++n;
  82                 if(CS(it).race_completed)
  83                         ++c;
  84         });
  85         if(n && (n == c))
  86                 return WINNING_YES;
  87         wc = WinningCondition_Scores(fraglimit, 0);
  88
  89         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
  90         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
  91         // do NOT support equality when the laps are all raced!
  92                 return WINNING_STARTSUDDENDEATHOVERTIME;
  93         else
  94                 return WINNING_NEVER;
  95 }
  96
  97 float WinningCondition_QualifyingThenRace(float limit)
  98 {
  99         float wc;
 100         wc = WinningCondition_Scores(limit, 0);
 101
 102         // NEVER initiate overtime
 103         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
 104         {
 105                 return WINNING_YES;
 106         }
 107
 108         return wc;
 109 }
 110
 111 MUTATOR_HOOKFUNCTION(rc, ClientKill)
 112 {
 113         if(g_race_qualifying)
 114                 M_ARGV(1, float) = 0; // killtime
 115 }
 116
 117 MUTATOR_HOOKFUNCTION(rc, AbortSpeedrun)
 118 {
 119         entity player = M_ARGV(0, entity);
 120
 121         if(autocvar_g_allow_checkpoints)
 122                 race_PreparePlayer(player); // nice try
 123 }
 124
 125 MUTATOR_HOOKFUNCTION(rc, PlayerPhysics)
 126 {
 127         entity player = M_ARGV(0, entity);
 128         float dt = M_ARGV(1, float);
 129
 130         player.race_movetime_frac += dt;
 131         float f = floor(player.race_movetime_frac);
 132         player.race_movetime_frac -= f;
 133         player.race_movetime_count += f;
 134         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
 135
 136 #ifdef SVQC
 137         if(IS_PLAYER(player))
 138         {
 139                 if (player.race_penalty)
 140                         if (time > player.race_penalty)
 141                                 player.race_penalty = 0;
 142                 if(player.race_penalty)
 143                 {
 144                         player.velocity = '0 0 0';
 145                         set_movetype(player, MOVETYPE_NONE);
 146                         player.disableclientprediction = 2;
 147                 }
 148         }
 149 #endif
 150
 151         // force kbd movement for fairness
 152         float wishspeed;
 153         vector wishvel;
 154
 155         // if record times matter
 156         // ensure nothing EVIL is being done (i.e. div0_evade)
 157         // this hinders joystick users though
 158         // but it still gives SOME analog control
 159         wishvel.x = fabs(CS(player).movement.x);
 160         wishvel.y = fabs(CS(player).movement.y);
 161         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 162         {
 163                 wishvel.z = 0;
 164                 wishspeed = vlen(wishvel);
 165                 if(wishvel.x >= 2 * wishvel.y)
 166                 {
 167                         // pure X motion
 168                         if(CS(player).movement.x > 0)
 169                                 CS(player).movement_x = wishspeed;
 170                         else
 171                                 CS(player).movement_x = -wishspeed;
 172                         CS(player).movement_y = 0;
 173                 }
 174                 else if(wishvel.y >= 2 * wishvel.x)
 175                 {
 176                         // pure Y motion
 177                         CS(player).movement_x = 0;
 178                         if(CS(player).movement.y > 0)
 179                                 CS(player).movement_y = wishspeed;
 180                         else
 181                                 CS(player).movement_y = -wishspeed;
 182                 }
 183                 else
 184                 {
 185                         // diagonal
 186                         if(CS(player).movement.x > 0)
 187                                 CS(player).movement_x = M_SQRT1_2 * wishspeed;
 188                         else
 189                                 CS(player).movement_x = -M_SQRT1_2 * wishspeed;
 190                         if(CS(player).movement.y > 0)
 191                                 CS(player).movement_y = M_SQRT1_2 * wishspeed;
 192                         else
 193                                 CS(player).movement_y = -M_SQRT1_2 * wishspeed;
 194                 }
 195         }
 196 }
 197
 198 MUTATOR_HOOKFUNCTION(rc, reset_map_global)
 199 {
 200         float s;
 201
 202         Score_NicePrint(NULL);
 203
 204         race_ClearRecords();
 205         PlayerScore_Sort(race_place, 0, 1, 0);
 206
 207         FOREACH_CLIENT(true, {
 208                 if(it.race_place)
 209                 {
 210                         s = GameRules_scoring_add(it, RACE_FASTEST, 0);
 211                         if(!s)
 212                                 it.race_place = 0;
 213                 }
 214                 race_EventLog(ftos(it.race_place), it);
 215         });
 216
 217         if(g_race_qualifying == 2)
 218         {
 219                 g_race_qualifying = 0;
 220                 independent_players = 0;
 221                 cvar_set("fraglimit", ftos(race_fraglimit));
 222                 cvar_set("leadlimit", ftos(race_leadlimit));
 223                 cvar_set("timelimit", ftos(race_timelimit));
 224                 race_ScoreRules();
 225         }
 226 }
 227
 228 MUTATOR_HOOKFUNCTION(rc, ClientConnect)
 229 {
 230         entity player = M_ARGV(0, entity);
 231
 232         race_PreparePlayer(player);
 233         player.race_checkpoint = -1;
 234
 235         string rr = RACE_RECORD;
 236
 237         if(IS_REAL_CLIENT(player))
 238         {
 239                 msg_entity = player;
 240                 race_send_recordtime(MSG_ONE);
 241                 race_send_speedaward(MSG_ONE);
 242
 243                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 244                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 245                 race_send_speedaward_alltimebest(MSG_ONE);
 246
 247                 float i;
 248                 for (i = 1; i <= RANKINGS_CNT; ++i)
 249                 {
 250                         race_SendRankings(i, 0, 0, MSG_ONE);
 251                 }
 252         }
 253 }
 254
 255 MUTATOR_HOOKFUNCTION(rc, MakePlayerObserver)
 256 {
 257         entity player = M_ARGV(0, entity);
 258
 259         if(g_race_qualifying)
 260         if(GameRules_scoring_add(player, RACE_FASTEST, 0))
 261                 player.frags = FRAGS_LMS_LOSER;
 262         else
 263                 player.frags = FRAGS_SPECTATOR;
 264
 265         race_PreparePlayer(player);
 266         player.race_checkpoint = -1;
 267 }
 268
 269 MUTATOR_HOOKFUNCTION(rc, PlayerSpawn)
 270 {
 271         entity player = M_ARGV(0, entity);
 272         entity spawn_spot = M_ARGV(1, entity);
 273
 274         if(spawn_spot.target == "")
 275                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 276                 race_PreparePlayer(player);
 277
 278         // if we need to respawn, do it right
 279         player.race_respawn_checkpoint = player.race_checkpoint;
 280         player.race_respawn_spotref = spawn_spot;
 281
 282         player.race_place = 0;
 283 }
 284
 285 MUTATOR_HOOKFUNCTION(rc, PutClientInServer)
 286 {
 287         entity player = M_ARGV(0, entity);
 288
 289         if(IS_PLAYER(player))
 290         if(!game_stopped)
 291         {
 292                 if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 293                         race_PreparePlayer(player);
 294                 else // respawn
 295                         race_RetractPlayer(player);
 296
 297                 race_AbandonRaceCheck(player);
 298         }
 299 }
 300
 301 MUTATOR_HOOKFUNCTION(rc, PlayerDies)
 302 {
 303         entity frag_target = M_ARGV(2, entity);
 304
 305         frag_target.respawn_flags |= RESPAWN_FORCE;
 306         race_AbandonRaceCheck(frag_target);
 307 }
 308
 309 MUTATOR_HOOKFUNCTION(rc, HavocBot_ChooseRole)
 310 {
 311         entity bot = M_ARGV(0, entity);
 312
 313         bot.havocbot_role = havocbot_role_race;
 314         return true;
 315 }
 316
 317 MUTATOR_HOOKFUNCTION(rc, GetPressedKeys)
 318 {
 319         entity player = M_ARGV(0, entity);
 320
 321         if(CS(player).cvar_cl_allow_uidtracking == 1 && CS(player).cvar_cl_allow_uid2name == 1)
 322         {
 323                 if (!player.stored_netname)
 324                         player.stored_netname = strzone(uid2name(player.crypto_idfp));
 325                 if(player.stored_netname != player.netname)
 326                 {
 327                         db_put(ServerProgsDB, strcat("/uid2name/", player.crypto_idfp), player.netname);
 328                         strcpy(player.stored_netname, player.netname);
 329                 }
 330         }
 331
 332         if (!IS_OBSERVER(player))
 333         {
 334                 if(vdist(player.velocity - player.velocity_z * '0 0 1', >, speedaward_speed))
 335                 {
 336                         speedaward_speed = vlen(player.velocity - player.velocity_z * '0 0 1');
 337                         speedaward_holder = player.netname;
 338                         speedaward_uid = player.crypto_idfp;
 339                         speedaward_lastupdate = time;
 340                 }
 341                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 342                 {
 343                         string rr = RACE_RECORD;
 344                         race_send_speedaward(MSG_ALL);
 345                         speedaward_lastsent = speedaward_speed;
 346                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 347                         {
 348                                 speedaward_alltimebest = speedaward_speed;
 349                                 speedaward_alltimebest_holder = speedaward_holder;
 350                                 speedaward_alltimebest_uid = speedaward_uid;
 351                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 352                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 353                                 race_send_speedaward_alltimebest(MSG_ALL);
 354                         }
 355                 }
 356         }
 357 }
 358
 359 MUTATOR_HOOKFUNCTION(rc, ForbidPlayerScore_Clear)
 360 {
 361         if(g_race_qualifying)
 362                 return true; // in qualifying, you don't lose score by observing
 363 }
 364
 365 MUTATOR_HOOKFUNCTION(rc, CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 366 {
 367         M_ARGV(0, float) = race_teams;
 368 }
 369
 370 MUTATOR_HOOKFUNCTION(rc, Scores_CountFragsRemaining)
 371 {
 372         // announce remaining frags if not in qualifying mode
 373         if(!g_race_qualifying)
 374                 return true;
 375 }
 376
 377 MUTATOR_HOOKFUNCTION(rc, GetRecords)
 378 {
 379         int record_page = M_ARGV(0, int);
 380         string ret_string = M_ARGV(1, string);
 381
 382         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 383         {
 384                 if(MapInfo_Get_ByID(i))
 385                 {
 386                         float r = race_readTime(MapInfo_Map_bspname, 1);
 387
 388                         if(!r)
 389                                 continue;
 390
 391                         string h = race_readName(MapInfo_Map_bspname, 1);
 392                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 393                 }
 394         }
 395
 396         M_ARGV(1, string) = ret_string;
 397 }
 398
 399 MUTATOR_HOOKFUNCTION(rc, HideTeamNagger)
 400 {
 401         return true; // doesn't work so well
 402 }
 403
 404 MUTATOR_HOOKFUNCTION(rc, FixClientCvars)
 405 {
 406         entity player = M_ARGV(0, entity);
 407
 408         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 409 }
 410
 411 MUTATOR_HOOKFUNCTION(rc, CheckRules_World)
 412 {
 413         float checkrules_timelimit = M_ARGV(1, float);
 414         float checkrules_fraglimit = M_ARGV(2, float);
 415
 416         if(checkrules_timelimit >= 0)
 417         {
 418                 if(!g_race_qualifying)
 419                 {
 420                         M_ARGV(0, float) = WinningCondition_Race(checkrules_fraglimit);
 421                         return true;
 422                 }
 423                 else if(g_race_qualifying == 2)
 424                 {
 425                         M_ARGV(0, float) = WinningCondition_QualifyingThenRace(checkrules_fraglimit);
 426                         return true;
 427                 }
 428         }
 429 }
 430
 431 MUTATOR_HOOKFUNCTION(rc, ReadLevelCvars)
 432 {
 433         if(g_race_qualifying == 2)
 434                 warmup_stage = 0;
 435 }
 436
 437 void race_Initialize()
 438 {
 439         race_ScoreRules();
 440         if(g_race_qualifying == 2)
 441                 warmup_stage = 0;
 442 }
 443
 444 void rc_SetLimits()
 445 {
 446         int fraglimit_override, leadlimit_override;
 447         float timelimit_override, qualifying_override;
 448
 449         if(autocvar_g_race_teams)
 450         {
 451                 GameRules_teams(true);
 452                 race_teams = BITS(bound(2, autocvar_g_race_teams, 4));
 453         }
 454         else
 455                 race_teams = 0;
 456
 457         qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 458         fraglimit_override = autocvar_g_race_laps_limit;
 459         leadlimit_override = 0; // currently not supported by race
 460         timelimit_override = autocvar_timelimit_override;
 461
 462         float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
 463
 464         if(autocvar_g_campaign)
 465         {
 466                 g_race_qualifying = 1;
 467                 independent_players = 1;
 468         }
 469         else if(want_qualifying)
 470         {
 471                 g_race_qualifying = 2;
 472                 independent_players = 1;
 473                 race_fraglimit = (fraglimit_override >= 0) ? fraglimit_override : autocvar_fraglimit;
 474                 race_leadlimit = (leadlimit_override >= 0) ? leadlimit_override : autocvar_leadlimit;
 475                 race_timelimit = (timelimit_override >= 0) ? timelimit_override : autocvar_timelimit;
 476                 qualifying_override = (qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit;
 477                 fraglimit_override = 0;
 478                 leadlimit_override = 0;
 479                 timelimit_override = qualifying_override;
 480         }
 481         else
 482                 g_race_qualifying = 0;
 483     GameRules_limit_score(fraglimit_override);
 484     GameRules_limit_lead(leadlimit_override);
 485     GameRules_limit_time(timelimit_override);
 486     GameRules_limit_time_qualifying(qualifying_override);
 487 }