qcsrc/server/mutators/mutator_overkill.qc

   1 #include "mutator_overkill.qh"
   2 #include "../_all.qh"
   3
   4 #include "mutator.qh"
   5
   6 void W_Blaster_Attack(float, float, float, float, float, float, float, float, float, float);
   7 void spawnfunc_weapon_hmg();
   8 void spawnfunc_weapon_rpc();
   9
  10 void ok_DecreaseCharge(entity ent, int wep)
  11 {
  12         if(!ent.ok_use_ammocharge) return;
  13
  14         entity wepent = get_weaponinfo(wep);
  15
  16         if(wepent.weapon == 0)
  17                 return; // dummy
  18
  19         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  20 }
  21
  22 void ok_IncreaseCharge(entity ent, int wep)
  23 {
  24         entity wepent = get_weaponinfo(wep);
  25
  26         if(wepent.weapon == 0)
  27                 return; // dummy
  28
  29         if(ent.ok_use_ammocharge)
  30         if(!ent.BUTTON_ATCK) // not while attacking?
  31                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  32 }
  33
  34 float ok_CheckWeaponCharge(entity ent, int wep)
  35 {
  36         if(!ent.ok_use_ammocharge) return true;
  37
  38         entity wepent = get_weaponinfo(wep);
  39
  40         if(wepent.weapon == 0)
  41                 return 0; // dummy
  42
  43         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  44 }
  45
  46 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_Calculate)
  47 {
  48         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
  49         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER.m_id))
  50         {
  51                 frag_damage = 0;
  52
  53                 if(frag_attacker != frag_target)
  54                 if(frag_target.health > 0)
  55                 if(frag_target.frozen == 0)
  56                 if(frag_target.deadflag == DEAD_NO)
  57                 {
  58                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  59                         frag_force = '0 0 0';
  60                 }
  61         }
  62
  63         return false;
  64 }
  65
  66 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_SplitHealthArmor)
  67 {SELFPARAM();
  68         if(damage_take)
  69                 self.ok_pauseregen_finished = max(self.ok_pauseregen_finished, time + 2);
  70         return false;
  71 }
  72
  73 MUTATOR_HOOKFUNCTION(ok_PlayerDies)
  74 {SELFPARAM();
  75         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
  76
  77         if(IS_MONSTER(self))
  78         {
  79                 remove(other); // remove default item
  80                 other = world;
  81         }
  82
  83         setself(spawn());
  84         self.ok_item = true;
  85         self.noalign = true;
  86         self.pickup_anyway = true;
  87         spawnfunc_item_armor_small();
  88         self.movetype = MOVETYPE_TOSS;
  89         self.gravity = 1;
  90         self.reset = SUB_Remove;
  91         setorigin(self, frag_target.origin + '0 0 32');
  92         self.velocity = '0 0 200' + normalize(targ.origin - self.origin) * 500;
  93         self.classname = "droppedweapon"; // hax
  94         SUB_SetFade(self, time + 5, 1);
  95         setself(this);
  96
  97         self.ok_lastwep = self.switchweapon;
  98
  99         return false;
 100 }
 101
 102 MUTATOR_HOOKFUNCTION(ok_PlayerRegen)
 103 {SELFPARAM();
 104         // overkill's values are different, so use custom regen
 105         if(!self.frozen)
 106         {
 107                 self.armorvalue = CalcRotRegen(self.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 1 * frametime * (time > self.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > self.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 108                 self.health = CalcRotRegen(self.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > self.ok_pauseregen_finished), 200, 0, autocvar_g_balance_health_rotlinear, 1 * frametime * (time > self.pauserothealth_finished), autocvar_g_balance_health_limit);
 109
 110                 float minf, maxf, limitf;
 111
 112                 maxf = autocvar_g_balance_fuel_rotstable;
 113                 minf = autocvar_g_balance_fuel_regenstable;
 114                 limitf = autocvar_g_balance_fuel_limit;
 115
 116                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
 117         }
 118         return true; // return true anyway, as frozen uses no regen
 119 }
 120
 121 MUTATOR_HOOKFUNCTION(ok_ForbidThrowCurrentWeapon)
 122 {
 123         return true;
 124 }
 125
 126 MUTATOR_HOOKFUNCTION(ok_PlayerPreThink)
 127 {SELFPARAM();
 128         if(intermission_running || gameover)
 129                 return false;
 130
 131         if(self.deadflag != DEAD_NO || !IS_PLAYER(self) || self.frozen)
 132                 return false;
 133
 134         if(self.ok_lastwep)
 135         {
 136                 self.switchweapon = self.ok_lastwep;
 137                 self.ok_lastwep = 0;
 138         }
 139
 140         ok_IncreaseCharge(self, self.weapon);
 141
 142         if(self.BUTTON_ATCK2)
 143         if(!forbidWeaponUse(self) || self.weapon_blocked) // allow if weapon is blocked
 144         if(time >= self.jump_interval)
 145         {
 146                 self.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor();
 147                 makevectors(self.v_angle);
 148
 149                 int oldwep = self.weapon;
 150                 self.weapon = WEP_BLASTER.m_id;
 151                 W_Blaster_Attack(
 152                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 153                         WEP_CVAR_SEC(vaporizer, shotangle),
 154                         WEP_CVAR_SEC(vaporizer, damage),
 155                         WEP_CVAR_SEC(vaporizer, edgedamage),
 156                         WEP_CVAR_SEC(vaporizer, radius),
 157                         WEP_CVAR_SEC(vaporizer, force),
 158                         WEP_CVAR_SEC(vaporizer, speed),
 159                         WEP_CVAR_SEC(vaporizer, spread),
 160                         WEP_CVAR_SEC(vaporizer, delay),
 161                         WEP_CVAR_SEC(vaporizer, lifetime)
 162                 );
 163                 self.weapon = oldwep;
 164         }
 165
 166         self.weapon_blocked = false;
 167
 168         self.ok_ammo_charge = self.ammo_charge[self.weapon];
 169
 170         if(self.ok_use_ammocharge)
 171         if(!ok_CheckWeaponCharge(self, self.weapon))
 172         {
 173                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && self.BUTTON_ATCK && IS_REAL_CLIENT(self) && self.weapon == self.switchweapon)
 174                 {
 175                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 176                         self.ok_notice_time = time + 2;
 177                         play2(self, W_Sound("dryfire"));
 178                 }
 179                 if(self.weaponentity.state != WS_CLEAR)
 180                         w_ready();
 181
 182                 self.weapon_blocked = true;
 183         }
 184
 185         self.BUTTON_ATCK2 = 0;
 186
 187         return false;
 188 }
 189
 190 MUTATOR_HOOKFUNCTION(ok_PlayerSpawn)
 191 {SELFPARAM();
 192         if(autocvar_g_overkill_ammo_charge)
 193         {
 194                 for(int i = WEP_FIRST; i <= WEP_LAST; ++i)
 195                         self.ammo_charge[i] = autocvar_g_overkill_ammo_charge_limit;
 196
 197                 self.ok_use_ammocharge = 1;
 198                 self.ok_notice_time = time;
 199         }
 200         else
 201                 self.ok_use_ammocharge = 0;
 202
 203         self.ok_pauseregen_finished = time + 2;
 204
 205         return false;
 206 }
 207
 208 MUTATOR_HOOKFUNCTION(ok_OnEntityPreSpawn)
 209 {SELFPARAM();
 210         if(autocvar_g_powerups)
 211         if(autocvar_g_overkill_powerups_replace)
 212         {
 213                 if(self.classname == "item_strength")
 214                 {
 215                         entity wep = spawn();
 216                         setorigin(wep, self.origin);
 217                         setmodel(wep, W_Model("g_ok_hmg.md3"));
 218                         wep.classname = "weapon_hmg";
 219                         wep.ok_item = true;
 220                         wep.noalign = self.noalign;
 221                         wep.cnt = self.cnt;
 222                         wep.team = self.team;
 223                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 224                         wep.pickup_anyway = true;
 225                         wep.think = spawnfunc_weapon_hmg;
 226                         wep.nextthink = time + 0.1;
 227                         return true;
 228                 }
 229
 230                 if(self.classname == "item_invincible")
 231                 {
 232                         entity wep = spawn();
 233                         setorigin(wep, self.origin);
 234                         setmodel(wep, W_Model("g_ok_rl.md3"));
 235                         wep.classname = "weapon_rpc";
 236                         wep.ok_item = true;
 237                         wep.noalign = self.noalign;
 238                         wep.cnt = self.cnt;
 239                         wep.team = self.team;
 240                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 241                         wep.pickup_anyway = true;
 242                         wep.think = spawnfunc_weapon_rpc;
 243                         wep.nextthink = time + 0.1;
 244                         return true;
 245                 }
 246         }
 247
 248         return false;
 249 }
 250
 251 MUTATOR_HOOKFUNCTION(ok_ItemRemove)
 252 {SELFPARAM();
 253         if(self.ok_item)
 254                 return false;
 255
 256         switch(self.items)
 257         {
 258                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 259                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 260         }
 261
 262         return true;
 263 }
 264
 265 MUTATOR_HOOKFUNCTION(ok_SpectateCopy)
 266 {SELFPARAM();
 267         self.ammo_charge[self.weapon] = other.ammo_charge[other.weapon];
 268         self.ok_use_ammocharge = other.ok_use_ammocharge;
 269
 270         return false;
 271 }
 272
 273 MUTATOR_HOOKFUNCTION(ok_StartItems)
 274 {
 275         WepSet ok_start_items = (WEPSET_MACHINEGUN | WEPSET_VORTEX | WEPSET_SHOTGUN);
 276
 277         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET_RPC; }
 278         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET_HMG; }
 279
 280         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 281         start_weapons = warmup_start_weapons = ok_start_items;
 282
 283         return false;
 284 }
 285
 286 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsString)
 287 {
 288         ret_string = strcat(ret_string, ":OK");
 289         return false;
 290 }
 291
 292 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsPrettyString)
 293 {
 294         ret_string = strcat(ret_string, ", Overkill");
 295         return false;
 296 }
 297
 298 MUTATOR_HOOKFUNCTION(ok_SetModname)
 299 {
 300         modname = "Overkill";
 301         return true;
 302 }
 303
 304 void ok_SetCvars()
 305 {
 306         // hack to force overkill playermodels
 307         cvar_settemp("sv_defaultcharacter", "1");
 308         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 309         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 310         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 311 }
 312
 313 void ok_Initialize()
 314 {
 315         ok_SetCvars();
 316
 317         precache_all_playermodels("models/ok_player/*.dpm");
 318
 319         precache_model(W_Model("h_ok_mg.iqm"));
 320         precache_model(W_Model("v_ok_mg.md3"));
 321         precache_model(W_Model("g_ok_mg.md3"));
 322
 323         precache_model(W_Model("h_ok_shotgun.iqm"));
 324         precache_model(W_Model("v_ok_shotgun.md3"));
 325         precache_model(W_Model("g_ok_shotgun.md3"));
 326
 327         precache_model(W_Model("h_ok_sniper.iqm"));
 328         precache_model(W_Model("v_ok_sniper.md3"));
 329         precache_model(W_Model("g_ok_sniper.md3"));
 330
 331         precache_sound(W_Sound("dryfire"));
 332
 333         addstat(STAT_OK_AMMO_CHARGE, AS_FLOAT, ok_use_ammocharge);
 334         addstat(STAT_OK_AMMO_CHARGEPOOL, AS_FLOAT, ok_ammo_charge);
 335
 336         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 337         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 338
 339         WEP_SHOTGUN.mdl = "ok_shotgun";
 340         WEP_MACHINEGUN.mdl = "ok_mg";
 341         WEP_VORTEX.mdl = "ok_sniper";
 342 }
 343
 344 MUTATOR_DEFINITION(mutator_overkill)
 345 {
 346         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ok_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 347         MUTATOR_HOOK(PlayerPreThink, ok_PlayerPreThink, CBC_ORDER_LAST);
 348         MUTATOR_HOOK(PlayerSpawn, ok_PlayerSpawn, CBC_ORDER_ANY);
 349         MUTATOR_HOOK(PlayerDamage_Calculate, ok_PlayerDamage_Calculate, CBC_ORDER_LAST);
 350         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, ok_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 351         MUTATOR_HOOK(PlayerDies, ok_PlayerDies, CBC_ORDER_ANY);
 352         MUTATOR_HOOK(PlayerRegen, ok_PlayerRegen, CBC_ORDER_ANY);
 353         MUTATOR_HOOK(OnEntityPreSpawn, ok_OnEntityPreSpawn, CBC_ORDER_ANY);
 354         MUTATOR_HOOK(FilterItem, ok_ItemRemove, CBC_ORDER_ANY);
 355         MUTATOR_HOOK(MonsterDropItem, ok_PlayerDies, CBC_ORDER_ANY);
 356         MUTATOR_HOOK(SpectateCopy, ok_SpectateCopy, CBC_ORDER_ANY);
 357         MUTATOR_HOOK(SetStartItems, ok_StartItems, CBC_ORDER_ANY);
 358         MUTATOR_HOOK(BuildMutatorsString, ok_BuildMutatorsString, CBC_ORDER_ANY);
 359         MUTATOR_HOOK(BuildMutatorsPrettyString, ok_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 360         MUTATOR_HOOK(SetModname, ok_SetModname, CBC_ORDER_ANY);
 361
 362         MUTATOR_ONADD
 363         {
 364                 ok_Initialize();
 365         }
 366
 367         MUTATOR_ONREMOVE
 368         {
 369                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 370                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 371         }
 372
 373         return false;
 374 }